author paulson <>
Mon May 23 15:33:24 2016 +0100 (2016-05-23)
changeset 63114 27afe7af7379
parent 62379 340738057c8c
child 63343 fb5d8a50c641
permissions -rw-r--r--
Lots of new material for multivariate analysis
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     6 section \<open>Filters on predicates\<close>
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    12 subsection \<open>Filters\<close>
    14 text \<open>
    15   This definition also allows non-proper filters.
    16 \<close>
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    37 subsubsection \<open>Eventually\<close>
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    42 syntax
    43   "_eventually" :: "pttrn => 'a filter => bool => bool"  ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 translations
    45   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    47 lemma eventually_Abs_filter:
    48   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    49   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    51 lemma filter_eq_iff:
    52   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    53   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    55 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    56   unfolding eventually_def
    57   by (rule is_filter.True [OF is_filter_Rep_filter])
    59 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    60 proof -
    61   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    62   thus "eventually P F" by simp
    63 qed
    65 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    66   by (auto intro: always_eventually)
    68 lemma eventually_mono:
    69   "\<lbrakk>eventually P F; \<And>x. P x \<Longrightarrow> Q x\<rbrakk> \<Longrightarrow> eventually Q F"
    70   unfolding eventually_def
    71   by (blast intro: is_filter.mono [OF is_filter_Rep_filter])
    73 lemma eventually_conj:
    74   assumes P: "eventually (\<lambda>x. P x) F"
    75   assumes Q: "eventually (\<lambda>x. Q x) F"
    76   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    77   using assms unfolding eventually_def
    78   by (rule is_filter.conj [OF is_filter_Rep_filter])
    80 lemma eventually_mp:
    81   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    82   assumes "eventually (\<lambda>x. P x) F"
    83   shows "eventually (\<lambda>x. Q x) F"
    84 proof -
    85   have "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    86     using assms by (rule eventually_conj)
    87   then show ?thesis
    88     by (blast intro: eventually_mono)
    89 qed
    91 lemma eventually_rev_mp:
    92   assumes "eventually (\<lambda>x. P x) F"
    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    94   shows "eventually (\<lambda>x. Q x) F"
    95 using assms(2) assms(1) by (rule eventually_mp)
    97 lemma eventually_conj_iff:
    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
   101 lemma eventually_elim2:
   102   assumes "eventually (\<lambda>i. P i) F"
   103   assumes "eventually (\<lambda>i. Q i) F"
   104   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   105   shows "eventually (\<lambda>i. R i) F"
   106   using assms by (auto elim!: eventually_rev_mp)
   108 lemma eventually_ball_finite_distrib:
   109   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   110   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   112 lemma eventually_ball_finite:
   113   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   114   by (auto simp: eventually_ball_finite_distrib)
   116 lemma eventually_all_finite:
   117   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   118   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   119   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   120 using eventually_ball_finite [of UNIV P] assms by simp
   122 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   123 proof
   124   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   125   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   126     by (auto intro: someI_ex eventually_mono)
   127   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   128     by auto
   129 qed (auto intro: eventually_mono)
   131 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   132   by (auto intro: eventually_mp)
   134 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   135   by (metis always_eventually)
   137 lemma eventually_subst:
   138   assumes "eventually (\<lambda>n. P n = Q n) F"
   139   shows "eventually P F = eventually Q F" (is "?L = ?R")
   140 proof -
   141   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   142       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   143     by (auto elim: eventually_mono)
   144   then show ?thesis by (auto elim: eventually_elim2)
   145 qed
   147 subsection \<open> Frequently as dual to eventually \<close>
   149 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   150   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   152 syntax
   153   "_frequently" :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   154 translations
   155   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   157 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   158   by (simp add: frequently_def)
   160 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   161   by (auto simp: frequently_def dest: not_eventuallyD)
   163 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   164   using frequently_ex[OF assms] by auto
   166 lemma frequently_mp:
   167   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   168 proof -
   169   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   170     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   171   from eventually_mp[OF this] P show ?thesis
   172     by (auto simp: frequently_def)
   173 qed
   175 lemma frequently_rev_mp:
   176   assumes "\<exists>\<^sub>Fx in F. P x"
   177   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   178   shows "\<exists>\<^sub>Fx in F. Q x"
   179 using assms(2) assms(1) by (rule frequently_mp)
   181 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   182   using frequently_mp[of P Q] by (simp add: always_eventually)
   184 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   185   by (metis frequently_mono)
   187 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   188   by (simp add: frequently_def eventually_conj_iff)
   190 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   191   by (simp add: frequently_disj_iff)
   193 lemma frequently_bex_finite_distrib:
   194   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   195   using assms by induction (auto simp: frequently_disj_iff)
   197 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   198   by (simp add: frequently_bex_finite_distrib)
   200 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   201   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   203 lemma
   204   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   205     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   206   by (auto simp: frequently_def)
   208 lemma frequently_imp_iff:
   209   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   210   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   212 lemma eventually_frequently_const_simps:
   213   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   214   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   215   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   216   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   217   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   218   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   219   by (cases C; simp add: not_frequently)+
   221 lemmas eventually_frequently_simps =
   222   eventually_frequently_const_simps
   223   not_eventually
   224   eventually_conj_iff
   225   eventually_ball_finite_distrib
   226   eventually_ex
   227   not_frequently
   228   frequently_disj_iff
   229   frequently_bex_finite_distrib
   230   frequently_all
   231   frequently_imp_iff
   233 ML \<open>
   234   fun eventually_elim_tac facts =
   235     CONTEXT_SUBGOAL (fn (goal, i) => fn (ctxt, st) =>
   236       let
   237         val mp_thms = facts RL @{thms eventually_rev_mp}
   238         val raw_elim_thm =
   239           (@{thm allI} RS @{thm always_eventually})
   240           |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   241           |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   242         val cases_prop =
   243           Thm.prop_of
   244             (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   245         val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   246       in CONTEXT_CASES cases (resolve_tac ctxt [raw_elim_thm] i) (ctxt, st) end)
   247 \<close>
   249 method_setup eventually_elim = \<open>
   250   Scan.succeed (fn _ => CONTEXT_METHOD (fn facts => eventually_elim_tac facts 1))
   251 \<close> "elimination of eventually quantifiers"
   253 subsubsection \<open>Finer-than relation\<close>
   255 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
   256 filter @{term F'}.\<close>
   258 instantiation filter :: (type) complete_lattice
   259 begin
   261 definition le_filter_def:
   262   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   264 definition
   265   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   267 definition
   268   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   270 definition
   271   "bot = Abs_filter (\<lambda>P. True)"
   273 definition
   274   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   276 definition
   277   "inf F F' = Abs_filter
   278       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   280 definition
   281   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   283 definition
   284   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   286 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   287   unfolding top_filter_def
   288   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   290 lemma eventually_bot [simp]: "eventually P bot"
   291   unfolding bot_filter_def
   292   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   294 lemma eventually_sup:
   295   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   296   unfolding sup_filter_def
   297   by (rule eventually_Abs_filter, rule is_filter.intro)
   298      (auto elim!: eventually_rev_mp)
   300 lemma eventually_inf:
   301   "eventually P (inf F F') \<longleftrightarrow>
   302    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   303   unfolding inf_filter_def
   304   apply (rule eventually_Abs_filter, rule is_filter.intro)
   305   apply (fast intro: eventually_True)
   306   apply clarify
   307   apply (intro exI conjI)
   308   apply (erule (1) eventually_conj)
   309   apply (erule (1) eventually_conj)
   310   apply simp
   311   apply auto
   312   done
   314 lemma eventually_Sup:
   315   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   316   unfolding Sup_filter_def
   317   apply (rule eventually_Abs_filter, rule is_filter.intro)
   318   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   319   done
   321 instance proof
   322   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   323   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   324     by (rule less_filter_def) }
   325   { show "F \<le> F"
   326     unfolding le_filter_def by simp }
   327   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   328     unfolding le_filter_def by simp }
   329   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   330     unfolding le_filter_def filter_eq_iff by fast }
   331   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   332     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   333   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   334     unfolding le_filter_def eventually_inf
   335     by (auto intro: eventually_mono [OF eventually_conj]) }
   336   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   337     unfolding le_filter_def eventually_sup by simp_all }
   338   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   339     unfolding le_filter_def eventually_sup by simp }
   340   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   341     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   342   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   343     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   344   { assume "F \<in> S" thus "F \<le> Sup S"
   345     unfolding le_filter_def eventually_Sup by simp }
   346   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   347     unfolding le_filter_def eventually_Sup by simp }
   348   { show "Inf {} = (top::'a filter)"
   349     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   350       (metis (full_types) top_filter_def always_eventually eventually_top) }
   351   { show "Sup {} = (bot::'a filter)"
   352     by (auto simp: bot_filter_def Sup_filter_def) }
   353 qed
   355 end
   357 lemma filter_leD:
   358   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   359   unfolding le_filter_def by simp
   361 lemma filter_leI:
   362   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   363   unfolding le_filter_def by simp
   365 lemma eventually_False:
   366   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   367   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   369 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   370   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   371   by (auto simp add: frequently_def eventually_False)
   373 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   374   by (cases P) (auto simp: eventually_False)
   376 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   377   by (simp add: eventually_const_iff)
   379 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   380   by (simp add: frequently_def eventually_const_iff)
   382 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   383   by (simp add: frequently_const_iff)
   385 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
   386   by (metis frequentlyE eventually_frequently)
   388 lemma eventually_happens':
   389   assumes "F \<noteq> bot" "eventually P F"
   390   shows   "\<exists>x. P x"
   391   using assms eventually_frequently frequentlyE by blast
   393 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   394   where "trivial_limit F \<equiv> F = bot"
   396 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   397   by (rule eventually_False [symmetric])
   399 lemma False_imp_not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
   400   by (simp add: eventually_False)
   402 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   403 proof -
   404   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   406   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   407     proof (rule eventually_Abs_filter is_filter.intro)+
   408       show "?F (\<lambda>x. True)"
   409         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   410     next
   411       fix P Q
   412       assume "?F P" then guess X ..
   413       moreover
   414       assume "?F Q" then guess Y ..
   415       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   416         by (intro exI[of _ "X \<union> Y"])
   417            (auto simp: Inf_union_distrib eventually_inf)
   418     next
   419       fix P Q
   420       assume "?F P" then guess X ..
   421       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   422       ultimately show "?F Q"
   423         by (intro exI[of _ X]) (auto elim: eventually_mono)
   424     qed }
   425   note eventually_F = this
   427   have "Inf B = Abs_filter ?F"
   428   proof (intro antisym Inf_greatest)
   429     show "Inf B \<le> Abs_filter ?F"
   430       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   431   next
   432     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   433       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   434   qed
   435   then show ?thesis
   436     by (simp add: eventually_F)
   437 qed
   439 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   440   unfolding eventually_Inf [of P "F`B"]
   441   by (metis finite_imageI image_mono finite_subset_image)
   443 lemma Inf_filter_not_bot:
   444   fixes B :: "'a filter set"
   445   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   446   unfolding trivial_limit_def eventually_Inf[of _ B]
   447     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   449 lemma INF_filter_not_bot:
   450   fixes F :: "'i \<Rightarrow> 'a filter"
   451   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   452   unfolding trivial_limit_def eventually_INF [of _ _ B]
   453     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   455 lemma eventually_Inf_base:
   456   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   457   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   458 proof (subst eventually_Inf, safe)
   459   fix X assume "finite X" "X \<subseteq> B"
   460   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   461   proof induct
   462     case empty then show ?case
   463       using \<open>B \<noteq> {}\<close> by auto
   464   next
   465     case (insert x X)
   466     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   467       by auto
   468     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
   469       by (auto intro: order_trans)
   470   qed
   471   then obtain b where "b \<in> B" "b \<le> Inf X"
   472     by (auto simp: le_Inf_iff)
   473   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   474     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   475 qed (auto intro!: exI[of _ "{x}" for x])
   477 lemma eventually_INF_base:
   478   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   479     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   480   by (subst eventually_Inf_base) auto
   482 lemma eventually_INF1: "i \<in> I \<Longrightarrow> eventually P (F i) \<Longrightarrow> eventually P (INF i:I. F i)"
   483   using filter_leD[OF INF_lower] .
   485 lemma eventually_INF_mono:
   486   assumes *: "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F i. P x"
   487   assumes T1: "\<And>Q R P. (\<And>x. Q x \<and> R x \<longrightarrow> P x) \<Longrightarrow> (\<And>x. T Q x \<Longrightarrow> T R x \<Longrightarrow> T P x)"
   488   assumes T2: "\<And>P. (\<And>x. P x) \<Longrightarrow> (\<And>x. T P x)"
   489   assumes **: "\<And>i P. i \<in> I \<Longrightarrow> \<forall>\<^sub>F x in F i. P x \<Longrightarrow> \<forall>\<^sub>F x in F' i. T P x"
   490   shows "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F' i. T P x"
   491 proof -
   492   from * obtain X where "finite X" "X \<subseteq> I" "\<forall>\<^sub>F x in \<Sqinter>i\<in>X. F i. P x"
   493     unfolding eventually_INF[of _ _ I] by auto
   494   moreover then have "eventually (T P) (INFIMUM X F')"
   495     apply (induction X arbitrary: P)
   496     apply (auto simp: eventually_inf T2)
   497     subgoal for x S P Q R
   498       apply (intro exI[of _ "T Q"])
   499       apply (auto intro!: **) []
   500       apply (intro exI[of _ "T R"])
   501       apply (auto intro: T1) []
   502       done
   503     done
   504   ultimately show "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F' i. T P x"
   505     by (subst eventually_INF) auto
   506 qed
   509 subsubsection \<open>Map function for filters\<close>
   511 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   512   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   514 lemma eventually_filtermap:
   515   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   516   unfolding filtermap_def
   517   apply (rule eventually_Abs_filter)
   518   apply (rule is_filter.intro)
   519   apply (auto elim!: eventually_rev_mp)
   520   done
   522 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   523   by (simp add: filter_eq_iff eventually_filtermap)
   525 lemma filtermap_filtermap:
   526   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   527   by (simp add: filter_eq_iff eventually_filtermap)
   529 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   530   unfolding le_filter_def eventually_filtermap by simp
   532 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   533   by (simp add: filter_eq_iff eventually_filtermap)
   535 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   536   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   538 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   539   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   541 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   542 proof -
   543   { fix X :: "'c set" assume "finite X"
   544     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   545     proof induct
   546       case (insert x X)
   547       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   548         by (rule order_trans[OF _ filtermap_inf]) simp
   549       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   550         by (intro inf_mono insert order_refl)
   551       finally show ?case
   552         by simp
   553     qed simp }
   554   then show ?thesis
   555     unfolding le_filter_def eventually_filtermap
   556     by (subst (1 2) eventually_INF) auto
   557 qed
   559 subsubsection \<open>Standard filters\<close>
   561 definition principal :: "'a set \<Rightarrow> 'a filter" where
   562   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   564 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   565   unfolding principal_def
   566   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   568 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   569   unfolding eventually_inf eventually_principal by (auto elim: eventually_mono)
   571 lemma principal_UNIV[simp]: "principal UNIV = top"
   572   by (auto simp: filter_eq_iff eventually_principal)
   574 lemma principal_empty[simp]: "principal {} = bot"
   575   by (auto simp: filter_eq_iff eventually_principal)
   577 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   578   by (auto simp add: filter_eq_iff eventually_principal)
   580 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   581   by (auto simp: le_filter_def eventually_principal)
   583 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   584   unfolding le_filter_def eventually_principal
   585   apply safe
   586   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   587   apply (auto elim: eventually_mono)
   588   done
   590 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   591   unfolding eq_iff by simp
   593 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   594   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   596 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   597   unfolding filter_eq_iff eventually_inf eventually_principal
   598   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   600 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   601   unfolding filter_eq_iff eventually_Sup by (auto simp: eventually_principal)
   603 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   604   by (induct X rule: finite_induct) auto
   606 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   607   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   609 subsubsection \<open>Order filters\<close>
   611 definition at_top :: "('a::order) filter"
   612   where "at_top = (INF k. principal {k ..})"
   614 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   615   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   617 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   618   unfolding at_top_def
   619   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   621 lemma eventually_ge_at_top:
   622   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   623   unfolding eventually_at_top_linorder by auto
   625 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   626 proof -
   627   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   628     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   629   also have "(INF k. principal {k::'a <..}) = at_top"
   630     unfolding at_top_def
   631     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   632   finally show ?thesis .
   633 qed
   635 lemma eventually_at_top_not_equal: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
   636   unfolding eventually_at_top_dense by auto
   638 lemma eventually_gt_at_top: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
   639   unfolding eventually_at_top_dense by auto
   641 lemma eventually_all_ge_at_top:
   642   assumes "eventually P (at_top :: ('a :: linorder) filter)"
   643   shows   "eventually (\<lambda>x. \<forall>y\<ge>x. P y) at_top"
   644 proof -
   645   from assms obtain x where "\<And>y. y \<ge> x \<Longrightarrow> P y" by (auto simp: eventually_at_top_linorder)
   646   hence "\<forall>z\<ge>y. P z" if "y \<ge> x" for y using that by simp
   647   thus ?thesis by (auto simp: eventually_at_top_linorder)
   648 qed
   650 definition at_bot :: "('a::order) filter"
   651   where "at_bot = (INF k. principal {.. k})"
   653 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   654   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   656 lemma eventually_at_bot_linorder:
   657   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   658   unfolding at_bot_def
   659   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   661 lemma eventually_le_at_bot:
   662   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   663   unfolding eventually_at_bot_linorder by auto
   665 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   666 proof -
   667   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   668     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   669   also have "(INF k. principal {..< k::'a}) = at_bot"
   670     unfolding at_bot_def
   671     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   672   finally show ?thesis .
   673 qed
   675 lemma eventually_at_bot_not_equal: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
   676   unfolding eventually_at_bot_dense by auto
   678 lemma eventually_gt_at_bot:
   679   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   680   unfolding eventually_at_bot_dense by auto
   682 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   683   unfolding trivial_limit_def
   684   by (metis eventually_at_bot_linorder order_refl)
   686 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   687   unfolding trivial_limit_def
   688   by (metis eventually_at_top_linorder order_refl)
   690 subsection \<open>Sequentially\<close>
   692 abbreviation sequentially :: "nat filter"
   693   where "sequentially \<equiv> at_top"
   695 lemma eventually_sequentially:
   696   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   697   by (rule eventually_at_top_linorder)
   699 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   700   unfolding filter_eq_iff eventually_sequentially by auto
   702 lemmas trivial_limit_sequentially = sequentially_bot
   704 lemma eventually_False_sequentially [simp]:
   705   "\<not> eventually (\<lambda>n. False) sequentially"
   706   by (simp add: eventually_False)
   708 lemma le_sequentially:
   709   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   710   by (simp add: at_top_def le_INF_iff le_principal)
   712 lemma eventually_sequentiallyI [intro?]:
   713   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   714   shows "eventually P sequentially"
   715 using assms by (auto simp: eventually_sequentially)
   717 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   718   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   720 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   721   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   724 subsection \<open>The cofinite filter\<close>
   726 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   728 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>\<^sub>\<infinity>" 10)
   729   where "Inf_many P \<equiv> frequently P cofinite"
   731 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>\<^sub>\<infinity>" 10)
   732   where "Alm_all P \<equiv> eventually P cofinite"
   734 notation (ASCII)
   735   Inf_many  (binder "INFM " 10) and
   736   Alm_all  (binder "MOST " 10)
   738 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   739   unfolding cofinite_def
   740 proof (rule eventually_Abs_filter, rule is_filter.intro)
   741   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   742   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   743     by (rule rev_finite_subset) auto
   744 next
   745   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   746   from * show "finite {x. \<not> Q x}"
   747     by (intro finite_subset[OF _ P]) auto
   748 qed simp
   750 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   751   by (simp add: frequently_def eventually_cofinite)
   753 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   754   unfolding trivial_limit_def eventually_cofinite by simp
   756 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   757   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   758 proof safe
   759   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   760   show "\<exists>N. \<forall>n\<ge>N. P n"
   761   proof cases
   762     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   763       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   764   qed auto
   765 next
   766   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   767   then have "{x. \<not> P x} \<subseteq> {..< N}"
   768     by (auto simp: not_le)
   769   then show "finite {x. \<not> P x}"
   770     by (blast intro: finite_subset)
   771 qed
   773 subsubsection \<open>Product of filters\<close>
   775 lemma filtermap_sequentually_ne_bot: "filtermap f sequentially \<noteq> bot"
   776   by (auto simp add: filter_eq_iff eventually_filtermap eventually_sequentially)
   778 definition prod_filter :: "'a filter \<Rightarrow> 'b filter \<Rightarrow> ('a \<times> 'b) filter" (infixr "\<times>\<^sub>F" 80) where
   779   "prod_filter F G =
   780     (INF (P, Q):{(P, Q). eventually P F \<and> eventually Q G}. principal {(x, y). P x \<and> Q y})"
   782 lemma eventually_prod_filter: "eventually P (F \<times>\<^sub>F G) \<longleftrightarrow>
   783   (\<exists>Pf Pg. eventually Pf F \<and> eventually Pg G \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P (x, y)))"
   784   unfolding prod_filter_def
   785 proof (subst eventually_INF_base, goal_cases)
   786   case 2
   787   moreover have "eventually Pf F \<Longrightarrow> eventually Qf F \<Longrightarrow> eventually Pg G \<Longrightarrow> eventually Qg G \<Longrightarrow>
   788     \<exists>P Q. eventually P F \<and> eventually Q G \<and>
   789       Collect P \<times> Collect Q \<subseteq> Collect Pf \<times> Collect Pg \<inter> Collect Qf \<times> Collect Qg" for Pf Pg Qf Qg
   790     by (intro conjI exI[of _ "inf Pf Qf"] exI[of _ "inf Pg Qg"])
   791        (auto simp: inf_fun_def eventually_conj)
   792   ultimately show ?case
   793     by auto
   794 qed (auto simp: eventually_principal intro: eventually_True)
   796 lemma eventually_prod1:
   797   assumes "B \<noteq> bot"
   798   shows "(\<forall>\<^sub>F (x, y) in A \<times>\<^sub>F B. P x) \<longleftrightarrow> (\<forall>\<^sub>F x in A. P x)"
   799   unfolding eventually_prod_filter
   800 proof safe
   801   fix R Q assume "\<forall>\<^sub>F x in A. R x" "\<forall>\<^sub>F x in B. Q x" "\<forall>x y. R x \<longrightarrow> Q y \<longrightarrow> P x"
   802   moreover with \<open>B \<noteq> bot\<close> obtain y where "Q y" by (auto dest: eventually_happens)
   803   ultimately show "eventually P A"
   804     by (force elim: eventually_mono)
   805 next
   806   assume "eventually P A"
   807   then show "\<exists>Pf Pg. eventually Pf A \<and> eventually Pg B \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P x)"
   808     by (intro exI[of _ P] exI[of _ "\<lambda>x. True"]) auto
   809 qed
   811 lemma eventually_prod2:
   812   assumes "A \<noteq> bot"
   813   shows "(\<forall>\<^sub>F (x, y) in A \<times>\<^sub>F B. P y) \<longleftrightarrow> (\<forall>\<^sub>F y in B. P y)"
   814   unfolding eventually_prod_filter
   815 proof safe
   816   fix R Q assume "\<forall>\<^sub>F x in A. R x" "\<forall>\<^sub>F x in B. Q x" "\<forall>x y. R x \<longrightarrow> Q y \<longrightarrow> P y"
   817   moreover with \<open>A \<noteq> bot\<close> obtain x where "R x" by (auto dest: eventually_happens)
   818   ultimately show "eventually P B"
   819     by (force elim: eventually_mono)
   820 next
   821   assume "eventually P B"
   822   then show "\<exists>Pf Pg. eventually Pf A \<and> eventually Pg B \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P y)"
   823     by (intro exI[of _ P] exI[of _ "\<lambda>x. True"]) auto
   824 qed
   826 lemma INF_filter_bot_base:
   827   fixes F :: "'a \<Rightarrow> 'b filter"
   828   assumes *: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> \<exists>k\<in>I. F k \<le> F i \<sqinter> F j"
   829   shows "(INF i:I. F i) = bot \<longleftrightarrow> (\<exists>i\<in>I. F i = bot)"
   830 proof cases
   831   assume "\<exists>i\<in>I. F i = bot"
   832   moreover then have "(INF i:I. F i) \<le> bot"
   833     by (auto intro: INF_lower2)
   834   ultimately show ?thesis
   835     by (auto simp: bot_unique)
   836 next
   837   assume **: "\<not> (\<exists>i\<in>I. F i = bot)"
   838   moreover have "(INF i:I. F i) \<noteq> bot"
   839   proof cases
   840     assume "I \<noteq> {}"
   841     show ?thesis
   842     proof (rule INF_filter_not_bot)
   843       fix J assume "finite J" "J \<subseteq> I"
   844       then have "\<exists>k\<in>I. F k \<le> (\<Sqinter>i\<in>J. F i)"
   845       proof (induction J)
   846         case empty then show ?case
   847           using \<open>I \<noteq> {}\<close> by auto
   848       next
   849         case (insert i J)
   850         moreover then obtain k where "k \<in> I" "F k \<le> (\<Sqinter>i\<in>J. F i)" by auto
   851         moreover note *[of i k]
   852         ultimately show ?case
   853           by auto
   854       qed
   855       with ** show "(\<Sqinter>i\<in>J. F i) \<noteq> \<bottom>"
   856         by (auto simp: bot_unique)
   857     qed
   858   qed (auto simp add: filter_eq_iff)
   859   ultimately show ?thesis
   860     by auto
   861 qed
   863 lemma Collect_empty_eq_bot: "Collect P = {} \<longleftrightarrow> P = \<bottom>"
   864   by auto
   866 lemma prod_filter_eq_bot: "A \<times>\<^sub>F B = bot \<longleftrightarrow> A = bot \<or> B = bot"
   867   unfolding prod_filter_def
   868 proof (subst INF_filter_bot_base; clarsimp simp: principal_eq_bot_iff Collect_empty_eq_bot bot_fun_def simp del: Collect_empty_eq)
   869   fix A1 A2 B1 B2 assume "\<forall>\<^sub>F x in A. A1 x" "\<forall>\<^sub>F x in A. A2 x" "\<forall>\<^sub>F x in B. B1 x" "\<forall>\<^sub>F x in B. B2 x"
   870   then show "\<exists>x. eventually x A \<and> (\<exists>y. eventually y B \<and> Collect x \<times> Collect y \<subseteq> Collect A1 \<times> Collect B1 \<and> Collect x \<times> Collect y \<subseteq> Collect A2 \<times> Collect B2)"
   871     by (intro exI[of _ "\<lambda>x. A1 x \<and> A2 x"] exI[of _ "\<lambda>x. B1 x \<and> B2 x"] conjI)
   872        (auto simp: eventually_conj_iff)
   873 next
   874   show "(\<exists>x. eventually x A \<and> (\<exists>y. eventually y B \<and> (x = (\<lambda>x. False) \<or> y = (\<lambda>x. False)))) = (A = \<bottom> \<or> B = \<bottom>)"
   875     by (auto simp: trivial_limit_def intro: eventually_True)
   876 qed
   878 lemma prod_filter_mono: "F \<le> F' \<Longrightarrow> G \<le> G' \<Longrightarrow> F \<times>\<^sub>F G \<le> F' \<times>\<^sub>F G'"
   879   by (auto simp: le_filter_def eventually_prod_filter)
   881 lemma prod_filter_mono_iff:
   882   assumes nAB: "A \<noteq> bot" "B \<noteq> bot"
   883   shows "A \<times>\<^sub>F B \<le> C \<times>\<^sub>F D \<longleftrightarrow> A \<le> C \<and> B \<le> D"
   884 proof safe
   885   assume *: "A \<times>\<^sub>F B \<le> C \<times>\<^sub>F D"
   886   moreover with assms have "A \<times>\<^sub>F B \<noteq> bot"
   887     by (auto simp: bot_unique prod_filter_eq_bot)
   888   ultimately have "C \<times>\<^sub>F D \<noteq> bot"
   889     by (auto simp: bot_unique)
   890   then have nCD: "C \<noteq> bot" "D \<noteq> bot"
   891     by (auto simp: prod_filter_eq_bot)
   893   show "A \<le> C"
   894   proof (rule filter_leI)
   895     fix P assume "eventually P C" with *[THEN filter_leD, of "\<lambda>(x, y). P x"] show "eventually P A"
   896       using nAB nCD by (simp add: eventually_prod1 eventually_prod2)
   897   qed
   899   show "B \<le> D"
   900   proof (rule filter_leI)
   901     fix P assume "eventually P D" with *[THEN filter_leD, of "\<lambda>(x, y). P y"] show "eventually P B"
   902       using nAB nCD by (simp add: eventually_prod1 eventually_prod2)
   903   qed
   904 qed (intro prod_filter_mono)
   906 lemma eventually_prod_same: "eventually P (F \<times>\<^sub>F F) \<longleftrightarrow>
   907     (\<exists>Q. eventually Q F \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y)))"
   908   unfolding eventually_prod_filter
   909   apply safe
   910   apply (rule_tac x="inf Pf Pg" in exI)
   911   apply (auto simp: inf_fun_def intro!: eventually_conj)
   912   done
   914 lemma eventually_prod_sequentially:
   915   "eventually P (sequentially \<times>\<^sub>F sequentially) \<longleftrightarrow> (\<exists>N. \<forall>m \<ge> N. \<forall>n \<ge> N. P (n, m))"
   916   unfolding eventually_prod_same eventually_sequentially by auto
   918 lemma principal_prod_principal: "principal A \<times>\<^sub>F principal B = principal (A \<times> B)"
   919   apply (simp add: filter_eq_iff eventually_prod_filter eventually_principal)
   920   apply safe
   921   apply blast
   922   apply (intro conjI exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   923   apply auto
   924   done
   926 lemma prod_filter_INF:
   927   assumes "I \<noteq> {}" "J \<noteq> {}"
   928   shows "(INF i:I. A i) \<times>\<^sub>F (INF j:J. B j) = (INF i:I. INF j:J. A i \<times>\<^sub>F B j)"
   929 proof (safe intro!: antisym INF_greatest)
   930   from \<open>I \<noteq> {}\<close> obtain i where "i \<in> I" by auto
   931   from \<open>J \<noteq> {}\<close> obtain j where "j \<in> J" by auto
   933   show "(\<Sqinter>i\<in>I. \<Sqinter>j\<in>J. A i \<times>\<^sub>F B j) \<le> (\<Sqinter>i\<in>I. A i) \<times>\<^sub>F (\<Sqinter>j\<in>J. B j)"
   934     unfolding prod_filter_def
   935   proof (safe intro!: INF_greatest)
   936     fix P Q assume P: "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. A i. P x" and Q: "\<forall>\<^sub>F x in \<Sqinter>j\<in>J. B j. Q x"
   937     let ?X = "(\<Sqinter>i\<in>I. \<Sqinter>j\<in>J. \<Sqinter>(P, Q)\<in>{(P, Q). (\<forall>\<^sub>F x in A i. P x) \<and> (\<forall>\<^sub>F x in B j. Q x)}. principal {(x, y). P x \<and> Q y})"
   938     have "?X \<le> principal {x. P (fst x)} \<sqinter> principal {x. Q (snd x)}"
   939     proof (intro inf_greatest)
   940       have "?X \<le> (\<Sqinter>i\<in>I. \<Sqinter>P\<in>{P. eventually P (A i)}. principal {x. P (fst x)})"
   941         by (auto intro!: INF_greatest INF_lower2[of j] INF_lower2 \<open>j\<in>J\<close> INF_lower2[of "(_, \<lambda>x. True)"])
   942       also have "\<dots> \<le> principal {x. P (fst x)}"
   943         unfolding le_principal
   944       proof (rule eventually_INF_mono[OF P])
   945         fix i P assume "i \<in> I" "eventually P (A i)"
   946         then show "\<forall>\<^sub>F x in \<Sqinter>P\<in>{P. eventually P (A i)}. principal {x. P (fst x)}. x \<in> {x. P (fst x)}"
   947           unfolding le_principal[symmetric] by (auto intro!: INF_lower)
   948       qed auto
   949       finally show "?X \<le> principal {x. P (fst x)}" .
   951       have "?X \<le> (\<Sqinter>i\<in>J. \<Sqinter>P\<in>{P. eventually P (B i)}. principal {x. P (snd x)})"
   952         by (auto intro!: INF_greatest INF_lower2[of i] INF_lower2 \<open>i\<in>I\<close> INF_lower2[of "(\<lambda>x. True, _)"])
   953       also have "\<dots> \<le> principal {x. Q (snd x)}"
   954         unfolding le_principal
   955       proof (rule eventually_INF_mono[OF Q])
   956         fix j Q assume "j \<in> J" "eventually Q (B j)"
   957         then show "\<forall>\<^sub>F x in \<Sqinter>P\<in>{P. eventually P (B j)}. principal {x. P (snd x)}. x \<in> {x. Q (snd x)}"
   958           unfolding le_principal[symmetric] by (auto intro!: INF_lower)
   959       qed auto
   960       finally show "?X \<le> principal {x. Q (snd x)}" .
   961     qed
   962     also have "\<dots> = principal {(x, y). P x \<and> Q y}"
   963       by auto
   964     finally show "?X \<le> principal {(x, y). P x \<and> Q y}" .
   965   qed
   966 qed (intro prod_filter_mono INF_lower)
   968 lemma filtermap_Pair: "filtermap (\<lambda>x. (f x, g x)) F \<le> filtermap f F \<times>\<^sub>F filtermap g F"
   969   by (simp add: le_filter_def eventually_filtermap eventually_prod_filter)
   970      (auto elim: eventually_elim2)
   972 lemma eventually_prodI: "eventually P F \<Longrightarrow> eventually Q G \<Longrightarrow> eventually (\<lambda>x. P (fst x) \<and> Q (snd x)) (F \<times>\<^sub>F G)"
   973   unfolding prod_filter_def
   974   by (intro eventually_INF1[of "(P, Q)"]) (auto simp: eventually_principal)
   976 lemma prod_filter_INF1: "I \<noteq> {} \<Longrightarrow> (INF i:I. A i) \<times>\<^sub>F B = (INF i:I. A i \<times>\<^sub>F B)"
   977   using prod_filter_INF[of I "{B}" A "\<lambda>x. x"] by simp
   979 lemma prod_filter_INF2: "J \<noteq> {} \<Longrightarrow> A \<times>\<^sub>F (INF i:J. B i) = (INF i:J. A \<times>\<^sub>F B i)"
   980   using prod_filter_INF[of "{A}" J "\<lambda>x. x" B] by simp
   982 subsection \<open>Limits\<close>
   984 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   985   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   987 syntax
   988   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   990 translations
   991   "LIM x F1. f :> F2" == "CONST filterlim (\<lambda>x. f) F2 F1"
   993 lemma filterlim_top [simp]: "filterlim f top F"
   994   by (simp add: filterlim_def)
   996 lemma filterlim_iff:
   997   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   998   unfolding filterlim_def le_filter_def eventually_filtermap ..
  1000 lemma filterlim_compose:
  1001   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
  1002   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
  1004 lemma filterlim_mono:
  1005   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
  1006   unfolding filterlim_def by (metis filtermap_mono order_trans)
  1008 lemma filterlim_ident: "LIM x F. x :> F"
  1009   by (simp add: filterlim_def filtermap_ident)
  1011 lemma filterlim_cong:
  1012   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
  1013   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
  1015 lemma filterlim_mono_eventually:
  1016   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
  1017   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
  1018   shows "filterlim f' F' G'"
  1019   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
  1020   apply (rule filterlim_mono[OF _ ord])
  1021   apply fact
  1022   done
  1024 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
  1025   apply (auto intro!: filtermap_mono) []
  1026   apply (auto simp: le_filter_def eventually_filtermap)
  1027   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
  1028   apply auto
  1029   done
  1031 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
  1032   by (simp add: filtermap_mono_strong eq_iff)
  1034 lemma filtermap_fun_inverse:
  1035   assumes g: "filterlim g F G"
  1036   assumes f: "filterlim f G F"
  1037   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
  1038   shows "filtermap f F = G"
  1039 proof (rule antisym)
  1040   show "filtermap f F \<le> G"
  1041     using f unfolding filterlim_def .
  1042   have "G = filtermap f (filtermap g G)"
  1043     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
  1044   also have "\<dots> \<le> filtermap f F"
  1045     using g by (intro filtermap_mono) (simp add: filterlim_def)
  1046   finally show "G \<le> filtermap f F" .
  1047 qed
  1049 lemma filterlim_principal:
  1050   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
  1051   unfolding filterlim_def eventually_filtermap le_principal ..
  1053 lemma filterlim_inf:
  1054   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
  1055   unfolding filterlim_def by simp
  1057 lemma filterlim_INF:
  1058   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
  1059   unfolding filterlim_def le_INF_iff ..
  1061 lemma filterlim_INF_INF:
  1062   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
  1063   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
  1065 lemma filterlim_base:
  1066   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow>
  1067     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
  1068   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
  1070 lemma filterlim_base_iff:
  1071   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
  1072   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
  1073     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
  1074   unfolding filterlim_INF filterlim_principal
  1075 proof (subst eventually_INF_base)
  1076   fix i j assume "i \<in> I" "j \<in> I"
  1077   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
  1078     by auto
  1079 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
  1081 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
  1082   unfolding filterlim_def filtermap_filtermap ..
  1084 lemma filterlim_sup:
  1085   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
  1086   unfolding filterlim_def filtermap_sup by auto
  1088 lemma filterlim_sequentially_Suc:
  1089   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
  1090   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
  1092 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
  1093   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
  1095 lemma filterlim_If:
  1096   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
  1097     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
  1098     LIM x F. if P x then f x else g x :> G"
  1099   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
  1101 lemma filterlim_Pair:
  1102   "LIM x F. f x :> G \<Longrightarrow> LIM x F. g x :> H \<Longrightarrow> LIM x F. (f x, g x) :> G \<times>\<^sub>F H"
  1103   unfolding filterlim_def
  1104   by (rule order_trans[OF filtermap_Pair prod_filter_mono])
  1106 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
  1108 lemma filterlim_at_top:
  1109   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1110   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1111   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_mono)
  1113 lemma filterlim_at_top_mono:
  1114   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
  1115     LIM x F. g x :> at_top"
  1116   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
  1118 lemma filterlim_at_top_dense:
  1119   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1120   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1121   by (metis eventually_mono[of _ F] eventually_gt_at_top order_less_imp_le
  1122             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1124 lemma filterlim_at_top_ge:
  1125   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1126   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1127   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
  1129 lemma filterlim_at_top_at_top:
  1130   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1131   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1132   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1133   assumes Q: "eventually Q at_top"
  1134   assumes P: "eventually P at_top"
  1135   shows "filterlim f at_top at_top"
  1136 proof -
  1137   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1138     unfolding eventually_at_top_linorder by auto
  1139   show ?thesis
  1140   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1141     fix z assume "x \<le> z"
  1142     with x have "P z" by auto
  1143     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1144       by (rule eventually_ge_at_top)
  1145     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1146       by eventually_elim (metis mono bij \<open>P z\<close>)
  1147   qed
  1148 qed
  1150 lemma filterlim_at_top_gt:
  1151   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1152   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1153   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1155 lemma filterlim_at_bot:
  1156   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1157   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1158   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_mono)
  1160 lemma filterlim_at_bot_dense:
  1161   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
  1162   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1163 proof (auto simp add: filterlim_at_bot[of f F])
  1164   fix Z :: 'b
  1165   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
  1166   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
  1167   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
  1168   thus "eventually (\<lambda>x. f x < Z) F"
  1169     apply (rule eventually_mono)
  1170     using 1 by auto
  1171   next
  1172     fix Z :: 'b
  1173     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
  1174       by (drule spec [of _ Z], erule eventually_mono, auto simp add: less_imp_le)
  1175 qed
  1177 lemma filterlim_at_bot_le:
  1178   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1179   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1180   unfolding filterlim_at_bot
  1181 proof safe
  1182   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1183   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1184     by (auto elim!: eventually_mono)
  1185 qed simp
  1187 lemma filterlim_at_bot_lt:
  1188   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1189   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1190   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1193 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
  1195 context begin interpretation lifting_syntax .
  1197 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  1198 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  1200 lemma rel_filter_eventually:
  1201   "rel_filter R F G \<longleftrightarrow>
  1202   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  1203 by(simp add: rel_filter_def eventually_def)
  1205 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  1206 by(simp add: fun_eq_iff id_def filtermap_ident)
  1208 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  1209 using filtermap_id unfolding id_def .
  1211 lemma Quotient_filter [quot_map]:
  1212   assumes Q: "Quotient R Abs Rep T"
  1213   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  1214 unfolding Quotient_alt_def
  1215 proof(intro conjI strip)
  1216   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  1217     unfolding Quotient_alt_def by blast
  1219   fix F G
  1220   assume "rel_filter T F G"
  1221   thus "filtermap Abs F = G" unfolding filter_eq_iff
  1222     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  1223 next
  1224   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  1226   fix F
  1227   show "rel_filter T (filtermap Rep F) F"
  1228     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  1229             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  1230 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  1231          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  1233 lemma eventually_parametric [transfer_rule]:
  1234   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  1235 by(simp add: rel_fun_def rel_filter_eventually)
  1237 lemma frequently_parametric [transfer_rule]:
  1238   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
  1239   unfolding frequently_def[abs_def] by transfer_prover
  1241 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  1242 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  1244 lemma rel_filter_mono [relator_mono]:
  1245   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  1246 unfolding rel_filter_eventually[abs_def]
  1247 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  1249 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  1250 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  1251 apply (safe; metis)
  1252 done
  1254 lemma is_filter_parametric_aux:
  1255   assumes "is_filter F"
  1256   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1257   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  1258   shows "is_filter G"
  1259 proof -
  1260   interpret is_filter F by fact
  1261   show ?thesis
  1262   proof
  1263     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  1264     thus "G (\<lambda>x. True)" by(simp add: True)
  1265   next
  1266     fix P' Q'
  1267     assume "G P'" "G Q'"
  1268     moreover
  1269     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1270     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1271     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  1272     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  1273     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  1274     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1275   next
  1276     fix P' Q'
  1277     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1278     moreover
  1279     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1280     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1281     have "F P = G P'" by transfer_prover
  1282     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1283     ultimately have "F Q" by(simp add: mono)
  1284     moreover have "F Q = G Q'" by transfer_prover
  1285     ultimately show "G Q'" by simp
  1286   qed
  1287 qed
  1289 lemma is_filter_parametric [transfer_rule]:
  1290   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1291   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1292 apply(rule rel_funI)
  1293 apply(rule iffI)
  1294  apply(erule (3) is_filter_parametric_aux)
  1295 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1296 apply (simp_all add: rel_fun_def)
  1297 apply metis
  1298 done
  1300 lemma left_total_rel_filter [transfer_rule]:
  1301   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1302   shows "left_total (rel_filter A)"
  1303 proof(rule left_totalI)
  1304   fix F :: "'a filter"
  1305   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
  1306   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G"
  1307     unfolding  bi_total_def by blast
  1308   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1309   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1310   ultimately have "rel_filter A F (Abs_filter G)"
  1311     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1312   thus "\<exists>G. rel_filter A F G" ..
  1313 qed
  1315 lemma right_total_rel_filter [transfer_rule]:
  1316   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1317 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1319 lemma bi_total_rel_filter [transfer_rule]:
  1320   assumes "bi_total A" "bi_unique A"
  1321   shows "bi_total (rel_filter A)"
  1322 unfolding bi_total_alt_def using assms
  1323 by(simp add: left_total_rel_filter right_total_rel_filter)
  1325 lemma left_unique_rel_filter [transfer_rule]:
  1326   assumes "left_unique A"
  1327   shows "left_unique (rel_filter A)"
  1328 proof(rule left_uniqueI)
  1329   fix F F' G
  1330   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1331   show "F = F'"
  1332     unfolding filter_eq_iff
  1333   proof
  1334     fix P :: "'a \<Rightarrow> bool"
  1335     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1336       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1337     have "eventually P F = eventually P' G"
  1338       and "eventually P F' = eventually P' G" by transfer_prover+
  1339     thus "eventually P F = eventually P F'" by simp
  1340   qed
  1341 qed
  1343 lemma right_unique_rel_filter [transfer_rule]:
  1344   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1345 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1347 lemma bi_unique_rel_filter [transfer_rule]:
  1348   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1349 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1351 lemma top_filter_parametric [transfer_rule]:
  1352   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1353 by(simp add: rel_filter_eventually All_transfer)
  1355 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1356 by(simp add: rel_filter_eventually rel_fun_def)
  1358 lemma sup_filter_parametric [transfer_rule]:
  1359   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1360 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1362 lemma Sup_filter_parametric [transfer_rule]:
  1363   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1364 proof(rule rel_funI)
  1365   fix S T
  1366   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1367   show "rel_filter A (Sup S) (Sup T)"
  1368     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1369 qed
  1371 lemma principal_parametric [transfer_rule]:
  1372   "(rel_set A ===> rel_filter A) principal principal"
  1373 proof(rule rel_funI)
  1374   fix S S'
  1375   assume [transfer_rule]: "rel_set A S S'"
  1376   show "rel_filter A (principal S) (principal S')"
  1377     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1378 qed
  1380 context
  1381   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1382   assumes [transfer_rule]: "bi_unique A"
  1383 begin
  1385 lemma le_filter_parametric [transfer_rule]:
  1386   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1387 unfolding le_filter_def[abs_def] by transfer_prover
  1389 lemma less_filter_parametric [transfer_rule]:
  1390   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1391 unfolding less_filter_def[abs_def] by transfer_prover
  1393 context
  1394   assumes [transfer_rule]: "bi_total A"
  1395 begin
  1397 lemma Inf_filter_parametric [transfer_rule]:
  1398   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1399 unfolding Inf_filter_def[abs_def] by transfer_prover
  1401 lemma inf_filter_parametric [transfer_rule]:
  1402   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1403 proof(intro rel_funI)+
  1404   fix F F' G G'
  1405   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1406   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1407   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1408 qed
  1410 end
  1412 end
  1414 end
  1416 text \<open>Code generation for filters\<close>
  1418 definition abstract_filter :: "(unit \<Rightarrow> 'a filter) \<Rightarrow> 'a filter"
  1419   where [simp]: "abstract_filter f = f ()"
  1421 code_datatype principal abstract_filter
  1423 hide_const (open) abstract_filter
  1425 declare [[code drop: filterlim prod_filter filtermap eventually
  1426   "inf :: _ filter \<Rightarrow> _" "sup :: _ filter \<Rightarrow> _" "less_eq :: _ filter \<Rightarrow> _"
  1427   Abs_filter]]
  1429 declare filterlim_principal [code]
  1430 declare principal_prod_principal [code]
  1431 declare filtermap_principal [code]
  1432 declare eventually_principal [code]
  1433 declare inf_principal [code]
  1434 declare sup_principal [code]
  1435 declare principal_le_iff [code]
  1437 lemma Rep_filter_iff_eventually [simp, code]:
  1438   "Rep_filter F P \<longleftrightarrow> eventually P F"
  1439   by (simp add: eventually_def)
  1441 lemma bot_eq_principal_empty [code]:
  1442   "bot = principal {}"
  1443   by simp
  1445 lemma top_eq_principal_UNIV [code]:
  1446   "top = principal UNIV"
  1447   by simp
  1449 instantiation filter :: (equal) equal
  1450 begin
  1452 definition equal_filter :: "'a filter \<Rightarrow> 'a filter \<Rightarrow> bool"
  1453   where "equal_filter F F' \<longleftrightarrow> F = F'"
  1455 lemma equal_filter [code]:
  1456   "HOL.equal (principal A) (principal B) \<longleftrightarrow> A = B"
  1457   by (simp add: equal_filter_def)
  1459 instance
  1460   by standard (simp add: equal_filter_def)
  1462 end
  1464 end