src/HOL/Topological_Spaces.thy
author paulson <lp15@cam.ac.uk>
Mon May 23 15:33:24 2016 +0100 (2016-05-23)
changeset 63114 27afe7af7379
parent 63092 a949b2a5f51d
child 63170 eae6549dbea2
permissions -rw-r--r--
Lots of new material for multivariate analysis
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Topological Spaces\<close>
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 named_theorems continuous_intros "structural introduction rules for continuity"
    13 
    14 subsection \<open>Topological space\<close>
    15 
    16 class "open" =
    17   fixes "open" :: "'a set \<Rightarrow> bool"
    18 
    19 class topological_space = "open" +
    20   assumes open_UNIV [simp, intro]: "open UNIV"
    21   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    22   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union>K)"
    23 begin
    24 
    25 definition
    26   closed :: "'a set \<Rightarrow> bool" where
    27   "closed S \<longleftrightarrow> open (- S)"
    28 
    29 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    30   using open_Union [of "{}"] by simp
    31 
    32 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    33   using open_Union [of "{S, T}"] by simp
    34 
    35 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    36   using open_Union [of "B ` A"] by simp
    37 
    38 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    39   by (induct set: finite) auto
    40 
    41 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    42   using open_Inter [of "B ` A"] by simp
    43 
    44 lemma openI:
    45   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    46   shows "open S"
    47 proof -
    48   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    49   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    50   ultimately show "open S" by simp
    51 qed
    52 
    53 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    54   unfolding closed_def by simp
    55 
    56 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    57   unfolding closed_def by auto
    58 
    59 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    60   unfolding closed_def by simp
    61 
    62 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    63   unfolding closed_def by auto
    64 
    65 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    66   unfolding closed_def by auto
    67 
    68 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter>K)"
    69   unfolding closed_def uminus_Inf by auto
    70 
    71 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    72   by (induct set: finite) auto
    73 
    74 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    75   using closed_Union [of "B ` A"] by simp
    76 
    77 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    78   unfolding closed_def by simp
    79 
    80 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    81   unfolding closed_def by simp
    82 
    83 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    84   unfolding closed_open Diff_eq by (rule open_Int)
    85 
    86 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    87   unfolding open_closed Diff_eq by (rule closed_Int)
    88 
    89 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
    90   unfolding closed_open .
    91 
    92 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
    93   unfolding open_closed .
    94 
    95 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
    96   unfolding Collect_neg_eq by (rule open_Compl)
    97 
    98 lemma open_Collect_conj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<and> Q x}"
    99   using open_Int[OF assms] by (simp add: Int_def)
   100 
   101 lemma open_Collect_disj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<or> Q x}"
   102   using open_Un[OF assms] by (simp add: Un_def)
   103 
   104 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   105   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp
   106 
   107 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   108   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   109 
   110 lemma open_Collect_const: "open {x. P}"
   111   by (cases P) auto
   112 
   113 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   114   unfolding Collect_neg_eq by (rule closed_Compl)
   115 
   116 lemma closed_Collect_conj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<and> Q x}"
   117   using closed_Int[OF assms] by (simp add: Int_def)
   118 
   119 lemma closed_Collect_disj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<or> Q x}"
   120   using closed_Un[OF assms] by (simp add: Un_def)
   121 
   122 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   123   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_all_eq by simp
   124 
   125 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   126   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   127 
   128 lemma closed_Collect_const: "closed {x. P}"
   129   by (cases P) auto
   130 
   131 end
   132 
   133 subsection\<open>Hausdorff and other separation properties\<close>
   134 
   135 class t0_space = topological_space +
   136   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   137 
   138 class t1_space = topological_space +
   139   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   140 
   141 instance t1_space \<subseteq> t0_space
   142 proof qed (fast dest: t1_space)
   143 
   144 lemma separation_t1:
   145   fixes x y :: "'a::t1_space"
   146   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   147   using t1_space[of x y] by blast
   148 
   149 lemma closed_singleton:
   150   fixes a :: "'a::t1_space"
   151   shows "closed {a}"
   152 proof -
   153   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   154   have "open ?T" by (simp add: open_Union)
   155   also have "?T = - {a}"
   156     by (simp add: set_eq_iff separation_t1, auto)
   157   finally show "closed {a}" unfolding closed_def .
   158 qed
   159 
   160 lemma closed_insert [continuous_intros, simp]:
   161   fixes a :: "'a::t1_space"
   162   assumes "closed S" shows "closed (insert a S)"
   163 proof -
   164   from closed_singleton assms
   165   have "closed ({a} \<union> S)" by (rule closed_Un)
   166   thus "closed (insert a S)" by simp
   167 qed
   168 
   169 lemma finite_imp_closed:
   170   fixes S :: "'a::t1_space set"
   171   shows "finite S \<Longrightarrow> closed S"
   172 by (induct set: finite, simp_all)
   173 
   174 text \<open>T2 spaces are also known as Hausdorff spaces.\<close>
   175 
   176 class t2_space = topological_space +
   177   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   178 
   179 instance t2_space \<subseteq> t1_space
   180 proof qed (fast dest: hausdorff)
   181 
   182 lemma separation_t2:
   183   fixes x y :: "'a::t2_space"
   184   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   185   using hausdorff[of x y] by blast
   186 
   187 lemma separation_t0:
   188   fixes x y :: "'a::t0_space"
   189   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   190   using t0_space[of x y] by blast
   191 
   192 text \<open>A perfect space is a topological space with no isolated points.\<close>
   193 
   194 class perfect_space = topological_space +
   195   assumes not_open_singleton: "\<not> open {x}"
   196 
   197 lemma UNIV_not_singleton: "UNIV \<noteq> {x::'a::perfect_space}"
   198   by (metis open_UNIV not_open_singleton)
   199 
   200 
   201 subsection \<open>Generators for toplogies\<close>
   202 
   203 inductive generate_topology for S where
   204   UNIV: "generate_topology S UNIV"
   205 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   206 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   207 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   208 
   209 hide_fact (open) UNIV Int UN Basis
   210 
   211 lemma generate_topology_Union:
   212   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   213   using generate_topology.UN [of "K ` I"] by auto
   214 
   215 lemma topological_space_generate_topology:
   216   "class.topological_space (generate_topology S)"
   217   by standard (auto intro: generate_topology.intros)
   218 
   219 subsection \<open>Order topologies\<close>
   220 
   221 class order_topology = order + "open" +
   222   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   223 begin
   224 
   225 subclass topological_space
   226   unfolding open_generated_order
   227   by (rule topological_space_generate_topology)
   228 
   229 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   230   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   231 
   232 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   233   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   234 
   235 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   236    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   237 
   238 end
   239 
   240 class linorder_topology = linorder + order_topology
   241 
   242 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   243   by (simp add: closed_open)
   244 
   245 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   246   by (simp add: closed_open)
   247 
   248 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   249 proof -
   250   have "{a .. b} = {a ..} \<inter> {.. b}"
   251     by auto
   252   then show ?thesis
   253     by (simp add: closed_Int)
   254 qed
   255 
   256 lemma (in linorder) less_separate:
   257   assumes "x < y"
   258   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   259 proof (cases "\<exists>z. x < z \<and> z < y")
   260   case True
   261   then obtain z where "x < z \<and> z < y" ..
   262   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   263     by auto
   264   then show ?thesis by blast
   265 next
   266   case False
   267   with \<open>x < y\<close> have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   268     by auto
   269   then show ?thesis by blast
   270 qed
   271 
   272 instance linorder_topology \<subseteq> t2_space
   273 proof
   274   fix x y :: 'a
   275   from less_separate[of x y] less_separate[of y x]
   276   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   277     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   278 qed
   279 
   280 lemma (in linorder_topology) open_right:
   281   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   282   using assms unfolding open_generated_order
   283 proof induction
   284   case (Int A B)
   285   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   286   then show ?case by (auto intro!: exI[of _ "min a b"])
   287 next
   288   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   289 qed blast+
   290 
   291 lemma (in linorder_topology) open_left:
   292   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   293   using assms unfolding open_generated_order
   294 proof induction
   295   case (Int A B)
   296   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   297   then show ?case by (auto intro!: exI[of _ "max a b"])
   298 next
   299   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   300 qed blast+
   301 
   302 subsection \<open>Setup some topologies\<close>
   303 
   304 subsubsection \<open>Boolean is an order topology\<close>
   305 
   306 text \<open>It is a discrete topology, but don't have a type class for it (yet).\<close>
   307 
   308 class discrete_topology = topological_space +
   309   assumes open_discrete: "\<And>A. open A"
   310 
   311 instance discrete_topology < t2_space
   312 proof
   313   fix x y :: 'a assume "x \<noteq> y" then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   314     by (intro exI[of _ "{_}"]) (auto intro!: open_discrete)
   315 qed
   316 
   317 instantiation bool :: linorder_topology
   318 begin
   319 
   320 definition open_bool :: "bool set \<Rightarrow> bool" where
   321   "open_bool = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   322 
   323 instance
   324   proof qed (rule open_bool_def)
   325 
   326 end
   327 
   328 instance bool :: discrete_topology
   329 proof
   330   fix A :: "bool set"
   331   have *: "{False <..} = {True}" "{..< True} = {False}"
   332     by auto
   333   have "A = UNIV \<or> A = {} \<or> A = {False <..} \<or> A = {..< True}"
   334     using subset_UNIV[of A] unfolding UNIV_bool * by auto
   335   then show "open A"
   336     by auto
   337 qed
   338 
   339 instantiation nat :: linorder_topology
   340 begin
   341 
   342 definition open_nat :: "nat set \<Rightarrow> bool" where
   343   "open_nat = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   344 
   345 instance
   346   proof qed (rule open_nat_def)
   347 
   348 end
   349 
   350 instance nat :: discrete_topology
   351 proof
   352   fix A :: "nat set"
   353   have "open {n}" for n :: nat
   354   proof (cases n)
   355     case 0
   356     moreover have "{0} = {..<1::nat}"
   357       by auto
   358     ultimately show ?thesis
   359        by auto
   360   next
   361     case (Suc n')
   362     moreover then have "{n} = {..<Suc n} \<inter> {n' <..}"
   363       by auto
   364     ultimately show ?thesis
   365       by (auto intro: open_lessThan open_greaterThan)
   366   qed
   367   then have "open (\<Union>a\<in>A. {a})"
   368     by (intro open_UN) auto
   369   then show "open A"
   370     by simp
   371 qed
   372 
   373 instantiation int :: linorder_topology
   374 begin
   375 
   376 definition open_int :: "int set \<Rightarrow> bool" where
   377   "open_int = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   378 
   379 instance
   380   proof qed (rule open_int_def)
   381 
   382 end
   383 
   384 instance int :: discrete_topology
   385 proof
   386   fix A :: "int set"
   387   have "{..<i + 1} \<inter> {i-1 <..} = {i}" for i :: int
   388     by auto
   389   then have "open {i}" for i :: int
   390     using open_Int[OF open_lessThan[of "i + 1"] open_greaterThan[of "i - 1"]] by auto
   391   then have "open (\<Union>a\<in>A. {a})"
   392     by (intro open_UN) auto
   393   then show "open A"
   394     by simp
   395 qed
   396 
   397 subsubsection \<open>Topological filters\<close>
   398 
   399 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   400   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   401 
   402 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_)/ within (_)" [1000, 60] 60)
   403   where "at a within s = inf (nhds a) (principal (s - {a}))"
   404 
   405 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   406   "at x \<equiv> at x within (CONST UNIV)"
   407 
   408 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   409   "at_right x \<equiv> at x within {x <..}"
   410 
   411 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   412   "at_left x \<equiv> at x within {..< x}"
   413 
   414 lemma (in topological_space) nhds_generated_topology:
   415   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   416   unfolding nhds_def
   417 proof (safe intro!: antisym INF_greatest)
   418   fix S assume "generate_topology T S" "x \<in> S"
   419   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   420     by induction
   421        (auto intro: INF_lower order_trans simp add: inf_principal[symmetric] simp del: inf_principal)
   422 qed (auto intro!: INF_lower intro: generate_topology.intros)
   423 
   424 lemma (in topological_space) eventually_nhds:
   425   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   426   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   427 
   428 lemma (in topological_space) eventually_nhds_in_open:
   429   "open s \<Longrightarrow> x \<in> s \<Longrightarrow> eventually (\<lambda>y. y \<in> s) (nhds x)"
   430   by (subst eventually_nhds) blast
   431 
   432 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   433   unfolding trivial_limit_def eventually_nhds by simp
   434 
   435 lemma (in t1_space) t1_space_nhds:
   436   "x \<noteq> y \<Longrightarrow> (\<forall>\<^sub>F x in nhds x. x \<noteq> y)"
   437   by (drule t1_space) (auto simp: eventually_nhds)
   438 
   439 lemma (in topological_space) nhds_discrete_open: "open {x} \<Longrightarrow> nhds x = principal {x}"
   440   by (auto simp: nhds_def intro!: antisym INF_greatest INF_lower2[of "{x}"])
   441 
   442 lemma (in discrete_topology) nhds_discrete: "nhds x = principal {x}"
   443   by (simp add: nhds_discrete_open open_discrete)
   444 
   445 lemma (in discrete_topology) at_discrete: "at x within S = bot"
   446   unfolding at_within_def nhds_discrete by simp
   447 
   448 lemma at_within_eq: "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   449   unfolding nhds_def at_within_def by (subst INF_inf_const2[symmetric]) (auto simp add: Diff_Int_distrib)
   450 
   451 lemma eventually_at_filter:
   452   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   453   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   454 
   455 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   456   unfolding at_within_def by (intro inf_mono) auto
   457 
   458 lemma eventually_at_topological:
   459   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   460   unfolding eventually_nhds eventually_at_filter by simp
   461 
   462 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   463   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   464 
   465 lemma at_within_open_NO_MATCH:
   466   "a \<in> s \<Longrightarrow> open s \<Longrightarrow> NO_MATCH UNIV s \<Longrightarrow> at a within s = at a"
   467   by (simp only: at_within_open)
   468 
   469 lemma at_within_nhd:
   470   assumes "x \<in> S" "open S" "T \<inter> S - {x} = U \<inter> S - {x}"
   471   shows "at x within T = at x within U"
   472   unfolding filter_eq_iff eventually_at_filter
   473 proof (intro allI eventually_subst)
   474   have "eventually (\<lambda>x. x \<in> S) (nhds x)"
   475     using \<open>x \<in> S\<close> \<open>open S\<close> by (auto simp: eventually_nhds)
   476   then show "\<forall>\<^sub>F n in nhds x. (n \<noteq> x \<longrightarrow> n \<in> T \<longrightarrow> P n) = (n \<noteq> x \<longrightarrow> n \<in> U \<longrightarrow> P n)" for P
   477     by eventually_elim (insert \<open>T \<inter> S - {x} = U \<inter> S - {x}\<close>, blast)
   478 qed
   479 
   480 lemma at_within_empty [simp]: "at a within {} = bot"
   481   unfolding at_within_def by simp
   482 
   483 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   484   unfolding filter_eq_iff eventually_sup eventually_at_filter
   485   by (auto elim!: eventually_rev_mp)
   486 
   487 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   488   unfolding trivial_limit_def eventually_at_topological
   489   by (safe, case_tac "S = {a}", simp, fast, fast)
   490 
   491 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   492   by (simp add: at_eq_bot_iff not_open_singleton)
   493 
   494 lemma (in order_topology) nhds_order: "nhds x =
   495   inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   496 proof -
   497   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} =
   498       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   499     by auto
   500   show ?thesis
   501     unfolding nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def ..
   502 qed
   503 
   504 lemma (in linorder_topology) at_within_order: "UNIV \<noteq> {x} \<Longrightarrow>
   505   at x within s = inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   506                       (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   507 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split[case_product case_split])
   508   assume "UNIV \<noteq> {x}" "{x<..} = {}" "{..< x} = {}"
   509   moreover have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   510     by auto
   511   ultimately show ?thesis
   512     by auto
   513 qed (auto simp: at_within_def nhds_order Int_Diff inf_principal[symmetric] INF_inf_const2
   514                 inf_sup_aci[where 'a="'a filter"]
   515           simp del: inf_principal)
   516 
   517 lemma (in linorder_topology) at_left_eq:
   518   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   519   by (subst at_within_order)
   520      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   521            intro!: INF_lower2 inf_absorb2)
   522 
   523 lemma (in linorder_topology) eventually_at_left:
   524   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   525   unfolding at_left_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   526 
   527 lemma (in linorder_topology) at_right_eq:
   528   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   529   by (subst at_within_order)
   530      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   531            intro!: INF_lower2 inf_absorb1)
   532 
   533 lemma (in linorder_topology) eventually_at_right:
   534   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   535   unfolding at_right_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   536 
   537 lemma eventually_at_right_less: "\<forall>\<^sub>F y in at_right (x::'a::{linorder_topology, no_top}). x < y"
   538   using gt_ex[of x] eventually_at_right[of x] by auto
   539 
   540 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top, linorder_topology}) = bot"
   541   unfolding filter_eq_iff eventually_at_topological by auto
   542 
   543 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot, linorder_topology}) = bot"
   544   unfolding filter_eq_iff eventually_at_topological by auto
   545 
   546 lemma trivial_limit_at_left_real [simp]:
   547   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_order, linorder_topology}))"
   548   using lt_ex[of x]
   549   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   550 
   551 lemma trivial_limit_at_right_real [simp]:
   552   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_order, linorder_topology}))"
   553   using gt_ex[of x]
   554   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   555 
   556 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   557   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup
   558            elim: eventually_elim2 eventually_mono)
   559 
   560 lemma eventually_at_split:
   561   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   562   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   563 
   564 subsubsection \<open>Tendsto\<close>
   565 
   566 abbreviation (in topological_space)
   567   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "\<longlongrightarrow>" 55) where
   568   "(f \<longlongrightarrow> l) F \<equiv> filterlim f (nhds l) F"
   569 
   570 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   571   "Lim A f = (THE l. (f \<longlongrightarrow> l) A)"
   572 
   573 lemma tendsto_eq_rhs: "(f \<longlongrightarrow> x) F \<Longrightarrow> x = y \<Longrightarrow> (f \<longlongrightarrow> y) F"
   574   by simp
   575 
   576 named_theorems tendsto_intros "introduction rules for tendsto"
   577 setup \<open>
   578   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   579     fn context =>
   580       Named_Theorems.get (Context.proof_of context) @{named_theorems tendsto_intros}
   581       |> map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])))
   582 \<close>
   583 
   584 lemma (in topological_space) tendsto_def:
   585    "(f \<longlongrightarrow> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   586    unfolding nhds_def filterlim_INF filterlim_principal by auto
   587 
   588 lemma tendsto_cong:
   589   assumes "eventually (\<lambda>x. f x = g x) F"
   590   shows   "(f \<longlongrightarrow> c) F \<longleftrightarrow> (g \<longlongrightarrow> c) F"
   591   by (rule filterlim_cong[OF refl refl assms])
   592 
   593 
   594 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f \<longlongrightarrow> l) F' \<Longrightarrow> (f \<longlongrightarrow> l) F"
   595   unfolding tendsto_def le_filter_def by fast
   596 
   597 lemma tendsto_within_subset: "(f \<longlongrightarrow> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f \<longlongrightarrow> l) (at x within T)"
   598   by (blast intro: tendsto_mono at_le)
   599 
   600 lemma filterlim_at:
   601   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f \<longlongrightarrow> b) F)"
   602   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   603 
   604 lemma (in topological_space) topological_tendstoI:
   605   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f \<longlongrightarrow> l) F"
   606   unfolding tendsto_def by auto
   607 
   608 lemma (in topological_space) topological_tendstoD:
   609   "(f \<longlongrightarrow> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   610   unfolding tendsto_def by auto
   611 
   612 lemma (in order_topology) order_tendsto_iff:
   613   "(f \<longlongrightarrow> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   614   unfolding nhds_order filterlim_inf filterlim_INF filterlim_principal by auto
   615 
   616 lemma (in order_topology) order_tendstoI:
   617   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
   618     (f \<longlongrightarrow> y) F"
   619   unfolding order_tendsto_iff by auto
   620 
   621 lemma (in order_topology) order_tendstoD:
   622   assumes "(f \<longlongrightarrow> y) F"
   623   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   624     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   625   using assms unfolding order_tendsto_iff by auto
   626 
   627 lemma tendsto_bot [simp]: "(f \<longlongrightarrow> a) bot"
   628   unfolding tendsto_def by simp
   629 
   630 lemma (in linorder_topology) tendsto_max:
   631   assumes X: "(X \<longlongrightarrow> x) net"
   632   assumes Y: "(Y \<longlongrightarrow> y) net"
   633   shows "((\<lambda>x. max (X x) (Y x)) \<longlongrightarrow> max x y) net"
   634 proof (rule order_tendstoI)
   635   fix a assume "a < max x y"
   636   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
   637     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   638     by (auto simp: less_max_iff_disj elim: eventually_mono)
   639 next
   640   fix a assume "max x y < a"
   641   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
   642     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   643     by (auto simp: eventually_conj_iff)
   644 qed
   645 
   646 lemma (in linorder_topology) tendsto_min:
   647   assumes X: "(X \<longlongrightarrow> x) net"
   648   assumes Y: "(Y \<longlongrightarrow> y) net"
   649   shows "((\<lambda>x. min (X x) (Y x)) \<longlongrightarrow> min x y) net"
   650 proof (rule order_tendstoI)
   651   fix a assume "a < min x y"
   652   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
   653     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   654     by (auto simp: eventually_conj_iff)
   655 next
   656   fix a assume "min x y < a"
   657   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
   658     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   659     by (auto simp: min_less_iff_disj elim: eventually_mono)
   660 qed
   661 
   662 lemma tendsto_ident_at [tendsto_intros, simp, intro]: "((\<lambda>x. x) \<longlongrightarrow> a) (at a within s)"
   663   unfolding tendsto_def eventually_at_topological by auto
   664 
   665 lemma (in topological_space) tendsto_const [tendsto_intros, simp, intro]: "((\<lambda>x. k) \<longlongrightarrow> k) F"
   666   by (simp add: tendsto_def)
   667 
   668 lemma (in t2_space) tendsto_unique:
   669   assumes "F \<noteq> bot" and "(f \<longlongrightarrow> a) F" and "(f \<longlongrightarrow> b) F"
   670   shows "a = b"
   671 proof (rule ccontr)
   672   assume "a \<noteq> b"
   673   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   674     using hausdorff [OF \<open>a \<noteq> b\<close>] by fast
   675   have "eventually (\<lambda>x. f x \<in> U) F"
   676     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open U\<close> \<open>a \<in> U\<close> by (rule topological_tendstoD)
   677   moreover
   678   have "eventually (\<lambda>x. f x \<in> V) F"
   679     using \<open>(f \<longlongrightarrow> b) F\<close> \<open>open V\<close> \<open>b \<in> V\<close> by (rule topological_tendstoD)
   680   ultimately
   681   have "eventually (\<lambda>x. False) F"
   682   proof eventually_elim
   683     case (elim x)
   684     hence "f x \<in> U \<inter> V" by simp
   685     with \<open>U \<inter> V = {}\<close> show ?case by simp
   686   qed
   687   with \<open>\<not> trivial_limit F\<close> show "False"
   688     by (simp add: trivial_limit_def)
   689 qed
   690 
   691 lemma (in t2_space) tendsto_const_iff:
   692   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) \<longlongrightarrow> b) F \<longleftrightarrow> a = b"
   693   by (auto intro!: tendsto_unique [OF assms tendsto_const])
   694 
   695 lemma increasing_tendsto:
   696   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   697   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   698       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   699   shows "(f \<longlongrightarrow> l) F"
   700   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   701 
   702 lemma decreasing_tendsto:
   703   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   704   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   705       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   706   shows "(f \<longlongrightarrow> l) F"
   707   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   708 
   709 lemma tendsto_sandwich:
   710   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
   711   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   712   assumes lim: "(f \<longlongrightarrow> c) net" "(h \<longlongrightarrow> c) net"
   713   shows "(g \<longlongrightarrow> c) net"
   714 proof (rule order_tendstoI)
   715   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
   716     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
   717 next
   718   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
   719     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
   720 qed
   721 
   722 lemma limit_frequently_eq:
   723   assumes "F \<noteq> bot"
   724   assumes "frequently (\<lambda>x. f x = c) F"
   725   assumes "(f \<longlongrightarrow> d) F"
   726   shows   "d = (c :: 'a :: t1_space)"
   727 proof (rule ccontr)
   728   assume "d \<noteq> c"
   729   from t1_space[OF this] obtain U where "open U" "d \<in> U" "c \<notin> U" by blast
   730   from this assms have "eventually (\<lambda>x. f x \<in> U) F" unfolding tendsto_def by blast
   731   hence "eventually (\<lambda>x. f x \<noteq> c) F" by eventually_elim (insert \<open>c \<notin> U\<close>, blast)
   732   with assms(2) show False unfolding frequently_def by contradiction
   733 qed
   734 
   735 lemma tendsto_imp_eventually_ne:
   736   assumes "F \<noteq> bot" "(f \<longlongrightarrow> c) F" "c \<noteq> (c' :: 'a :: t1_space)"
   737   shows   "eventually (\<lambda>z. f z \<noteq> c') F"
   738 proof (rule ccontr)
   739   assume "\<not>eventually (\<lambda>z. f z \<noteq> c') F"
   740   hence "frequently (\<lambda>z. f z = c') F" by (simp add: frequently_def)
   741   from limit_frequently_eq[OF assms(1) this assms(2)] and assms(3) show False by contradiction
   742 qed
   743 
   744 lemma tendsto_le:
   745   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
   746   assumes F: "\<not> trivial_limit F"
   747   assumes x: "(f \<longlongrightarrow> x) F" and y: "(g \<longlongrightarrow> y) F"
   748   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
   749   shows "y \<le> x"
   750 proof (rule ccontr)
   751   assume "\<not> y \<le> x"
   752   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
   753     by (auto simp: not_le)
   754   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
   755     using x y by (auto intro: order_tendstoD)
   756   with ev have "eventually (\<lambda>x. False) F"
   757     by eventually_elim (insert xy, fastforce)
   758   with F show False
   759     by (simp add: eventually_False)
   760 qed
   761 
   762 lemma tendsto_le_const:
   763   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
   764   assumes F: "\<not> trivial_limit F"
   765   assumes x: "(f \<longlongrightarrow> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
   766   shows "a \<le> x"
   767   using F x tendsto_const a by (rule tendsto_le)
   768 
   769 lemma tendsto_ge_const:
   770   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
   771   assumes F: "\<not> trivial_limit F"
   772   assumes x: "(f \<longlongrightarrow> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
   773   shows "a \<ge> x"
   774   by (rule tendsto_le [OF F tendsto_const x a])
   775 
   776 
   777 subsubsection \<open>Rules about @{const Lim}\<close>
   778 
   779 lemma tendsto_Lim:
   780   "\<not>(trivial_limit net) \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> Lim net f = l"
   781   unfolding Lim_def using tendsto_unique[of net f] by auto
   782 
   783 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
   784   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
   785 
   786 lemma filterlim_at_bot_at_right:
   787   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   788   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   789   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   790   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
   791   assumes P: "eventually P at_bot"
   792   shows "filterlim f at_bot (at_right a)"
   793 proof -
   794   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
   795     unfolding eventually_at_bot_linorder by auto
   796   show ?thesis
   797   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
   798     fix z assume "z \<le> x"
   799     with x have "P z" by auto
   800     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
   801       using bound[OF bij(2)[OF \<open>P z\<close>]]
   802       unfolding eventually_at_right[OF bound[OF bij(2)[OF \<open>P z\<close>]]] by (auto intro!: exI[of _ "g z"])
   803     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
   804       by eventually_elim (metis bij \<open>P z\<close> mono)
   805   qed
   806 qed
   807 
   808 lemma filterlim_at_top_at_left:
   809   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   810   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   811   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   812   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
   813   assumes P: "eventually P at_top"
   814   shows "filterlim f at_top (at_left a)"
   815 proof -
   816   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   817     unfolding eventually_at_top_linorder by auto
   818   show ?thesis
   819   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   820     fix z assume "x \<le> z"
   821     with x have "P z" by auto
   822     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
   823       using bound[OF bij(2)[OF \<open>P z\<close>]]
   824       unfolding eventually_at_left[OF bound[OF bij(2)[OF \<open>P z\<close>]]] by (auto intro!: exI[of _ "g z"])
   825     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
   826       by eventually_elim (metis bij \<open>P z\<close> mono)
   827   qed
   828 qed
   829 
   830 lemma filterlim_split_at:
   831   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
   832   by (subst at_eq_sup_left_right) (rule filterlim_sup)
   833 
   834 lemma filterlim_at_split:
   835   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
   836   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
   837 
   838 lemma eventually_nhds_top:
   839   fixes P :: "'a :: {order_top, linorder_topology} \<Rightarrow> bool"
   840   assumes "(b::'a) < top"
   841   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
   842   unfolding eventually_nhds
   843 proof safe
   844   fix S :: "'a set" assume "open S" "top \<in> S"
   845   note open_left[OF this \<open>b < top\<close>]
   846   moreover assume "\<forall>s\<in>S. P s"
   847   ultimately show "\<exists>b<top. \<forall>z>b. P z"
   848     by (auto simp: subset_eq Ball_def)
   849 next
   850   fix b assume "b < top" "\<forall>z>b. P z"
   851   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
   852     by (intro exI[of _ "{b <..}"]) auto
   853 qed
   854 
   855 lemma tendsto_at_within_iff_tendsto_nhds:
   856   "(g \<longlongrightarrow> g l) (at l within S) \<longleftrightarrow> (g \<longlongrightarrow> g l) (inf (nhds l) (principal S))"
   857   unfolding tendsto_def eventually_at_filter eventually_inf_principal
   858   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
   859 
   860 subsection \<open>Limits on sequences\<close>
   861 
   862 abbreviation (in topological_space)
   863   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   864     ("((_)/ \<longlonglongrightarrow> (_))" [60, 60] 60) where
   865   "X \<longlonglongrightarrow> L \<equiv> (X \<longlongrightarrow> L) sequentially"
   866 
   867 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
   868   "lim X \<equiv> Lim sequentially X"
   869 
   870 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   871   "convergent X = (\<exists>L. X \<longlonglongrightarrow> L)"
   872 
   873 lemma lim_def: "lim X = (THE L. X \<longlonglongrightarrow> L)"
   874   unfolding Lim_def ..
   875 
   876 subsubsection \<open>Monotone sequences and subsequences\<close>
   877 
   878 definition
   879   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
   880     \<comment>\<open>Definition of monotonicity.
   881         The use of disjunction here complicates proofs considerably.
   882         One alternative is to add a Boolean argument to indicate the direction.
   883         Another is to develop the notions of increasing and decreasing first.\<close>
   884   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
   885 
   886 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
   887   "incseq X \<equiv> mono X"
   888 
   889 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
   890   unfolding mono_def ..
   891 
   892 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
   893   "decseq X \<equiv> antimono X"
   894 
   895 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
   896   unfolding antimono_def ..
   897 
   898 definition
   899   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
   900     \<comment>\<open>Definition of subsequence\<close>
   901   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
   902 
   903 lemma incseq_SucI:
   904   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
   905   using lift_Suc_mono_le[of X]
   906   by (auto simp: incseq_def)
   907 
   908 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
   909   by (auto simp: incseq_def)
   910 
   911 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
   912   using incseqD[of A i "Suc i"] by auto
   913 
   914 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
   915   by (auto intro: incseq_SucI dest: incseq_SucD)
   916 
   917 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
   918   unfolding incseq_def by auto
   919 
   920 lemma decseq_SucI:
   921   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
   922   using order.lift_Suc_mono_le[OF dual_order, of X]
   923   by (auto simp: decseq_def)
   924 
   925 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
   926   by (auto simp: decseq_def)
   927 
   928 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
   929   using decseqD[of A i "Suc i"] by auto
   930 
   931 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
   932   by (auto intro: decseq_SucI dest: decseq_SucD)
   933 
   934 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
   935   unfolding decseq_def by auto
   936 
   937 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
   938   unfolding monoseq_def incseq_def decseq_def ..
   939 
   940 lemma monoseq_Suc:
   941   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
   942   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
   943 
   944 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   945 by (simp add: monoseq_def)
   946 
   947 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   948 by (simp add: monoseq_def)
   949 
   950 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   951 by (simp add: monoseq_Suc)
   952 
   953 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   954 by (simp add: monoseq_Suc)
   955 
   956 lemma monoseq_minus:
   957   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
   958   assumes "monoseq a"
   959   shows "monoseq (\<lambda> n. - a n)"
   960 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   961   case True
   962   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   963   thus ?thesis by (rule monoI2)
   964 next
   965   case False
   966   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using \<open>monoseq a\<close>[unfolded monoseq_def] by auto
   967   thus ?thesis by (rule monoI1)
   968 qed
   969 
   970 text\<open>Subsequence (alternative definition, (e.g. Hoskins)\<close>
   971 
   972 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   973 apply (simp add: subseq_def)
   974 apply (auto dest!: less_imp_Suc_add)
   975 apply (induct_tac k)
   976 apply (auto intro: less_trans)
   977 done
   978 
   979 text\<open>for any sequence, there is a monotonic subsequence\<close>
   980 lemma seq_monosub:
   981   fixes s :: "nat => 'a::linorder"
   982   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
   983 proof cases
   984   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p"
   985   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
   986     by (intro dependent_nat_choice) (auto simp: conj_commute)
   987   then obtain f where "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
   988     by (auto simp: subseq_Suc_iff)
   989   moreover
   990   then have "incseq f"
   991     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
   992   then have "monoseq (\<lambda>n. s (f n))"
   993     by (auto simp add: incseq_def intro!: mono monoI2)
   994   ultimately show ?thesis
   995     by auto
   996 next
   997   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
   998   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
   999   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
  1000   proof (intro dependent_nat_choice)
  1001     fix x assume "N < x" with N[of x] show "\<exists>y>N. x < y \<and> s x \<le> s y"
  1002       by (auto intro: less_trans)
  1003   qed auto
  1004   then show ?thesis
  1005     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
  1006 qed
  1007 
  1008 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1009 proof(induct n)
  1010   case 0 thus ?case by simp
  1011 next
  1012   case (Suc n)
  1013   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1014   have "n < f (Suc n)" by arith
  1015   thus ?case by arith
  1016 qed
  1017 
  1018 lemma eventually_subseq:
  1019   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1020   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1021 
  1022 lemma not_eventually_sequentiallyD:
  1023   assumes P: "\<not> eventually P sequentially"
  1024   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1025 proof -
  1026   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1027     unfolding eventually_sequentially by (simp add: not_less)
  1028   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1029     by (auto simp: choice_iff)
  1030   then show ?thesis
  1031     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1032              simp: less_eq_Suc_le subseq_Suc_iff)
  1033 qed
  1034 
  1035 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1036   unfolding filterlim_iff by (metis eventually_subseq)
  1037 
  1038 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1039   unfolding subseq_def by simp
  1040 
  1041 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1042   using assms by (auto simp: subseq_def)
  1043 
  1044 lemma subseq_imp_inj_on: "subseq g \<Longrightarrow> inj_on g A"
  1045 proof (rule inj_onI)
  1046   assume g: "subseq g"
  1047   fix x y assume "g x = g y"
  1048   with subseq_mono[OF g, of x y] subseq_mono[OF g, of y x] show "x = y"
  1049     by (cases x y rule: linorder_cases) simp_all
  1050 qed
  1051 
  1052 lemma subseq_strict_mono: "subseq g \<Longrightarrow> strict_mono g"
  1053   by (intro strict_monoI subseq_mono[of g])
  1054 
  1055 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1056   by (simp add: incseq_def monoseq_def)
  1057 
  1058 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1059   by (simp add: decseq_def monoseq_def)
  1060 
  1061 lemma decseq_eq_incseq:
  1062   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)"
  1063   by (simp add: decseq_def incseq_def)
  1064 
  1065 lemma INT_decseq_offset:
  1066   assumes "decseq F"
  1067   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1068 proof safe
  1069   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1070   show "x \<in> F i"
  1071   proof cases
  1072     from x have "x \<in> F n" by auto
  1073     also assume "i \<le> n" with \<open>decseq F\<close> have "F n \<subseteq> F i"
  1074       unfolding decseq_def by simp
  1075     finally show ?thesis .
  1076   qed (insert x, simp)
  1077 qed auto
  1078 
  1079 lemma LIMSEQ_const_iff:
  1080   fixes k l :: "'a::t2_space"
  1081   shows "(\<lambda>n. k) \<longlonglongrightarrow> l \<longleftrightarrow> k = l"
  1082   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1083 
  1084 lemma LIMSEQ_SUP:
  1085   "incseq X \<Longrightarrow> X \<longlonglongrightarrow> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1086   by (intro increasing_tendsto)
  1087      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1088 
  1089 lemma LIMSEQ_INF:
  1090   "decseq X \<Longrightarrow> X \<longlonglongrightarrow> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1091   by (intro decreasing_tendsto)
  1092      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1093 
  1094 lemma LIMSEQ_ignore_initial_segment:
  1095   "f \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. f (n + k)) \<longlonglongrightarrow> a"
  1096   unfolding tendsto_def
  1097   by (subst eventually_sequentially_seg[where k=k])
  1098 
  1099 lemma LIMSEQ_offset:
  1100   "(\<lambda>n. f (n + k)) \<longlonglongrightarrow> a \<Longrightarrow> f \<longlonglongrightarrow> a"
  1101   unfolding tendsto_def
  1102   by (subst (asm) eventually_sequentially_seg[where k=k])
  1103 
  1104 lemma LIMSEQ_Suc: "f \<longlonglongrightarrow> l \<Longrightarrow> (\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l"
  1105 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1106 
  1107 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l \<Longrightarrow> f \<longlonglongrightarrow> l"
  1108 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1109 
  1110 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l = f \<longlonglongrightarrow> l"
  1111 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1112 
  1113 lemma LIMSEQ_unique:
  1114   fixes a b :: "'a::t2_space"
  1115   shows "\<lbrakk>X \<longlonglongrightarrow> a; X \<longlonglongrightarrow> b\<rbrakk> \<Longrightarrow> a = b"
  1116   using trivial_limit_sequentially by (rule tendsto_unique)
  1117 
  1118 lemma LIMSEQ_le_const:
  1119   "\<lbrakk>X \<longlonglongrightarrow> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1120   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1121 
  1122 lemma LIMSEQ_le:
  1123   "\<lbrakk>X \<longlonglongrightarrow> x; Y \<longlonglongrightarrow> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1124   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1125 
  1126 lemma LIMSEQ_le_const2:
  1127   "\<lbrakk>X \<longlonglongrightarrow> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1128   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) auto
  1129 
  1130 lemma convergentD: "convergent X ==> \<exists>L. (X \<longlonglongrightarrow> L)"
  1131 by (simp add: convergent_def)
  1132 
  1133 lemma convergentI: "(X \<longlonglongrightarrow> L) ==> convergent X"
  1134 by (auto simp add: convergent_def)
  1135 
  1136 lemma convergent_LIMSEQ_iff: "convergent X = (X \<longlonglongrightarrow> lim X)"
  1137 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1138 
  1139 lemma convergent_const: "convergent (\<lambda>n. c)"
  1140   by (rule convergentI, rule tendsto_const)
  1141 
  1142 lemma monoseq_le:
  1143   "monoseq a \<Longrightarrow> a \<longlonglongrightarrow> (x::'a::linorder_topology) \<Longrightarrow>
  1144     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1145   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1146 
  1147 lemma LIMSEQ_subseq_LIMSEQ:
  1148   "\<lbrakk> X \<longlonglongrightarrow> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) \<longlonglongrightarrow> L"
  1149   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1150 
  1151 lemma convergent_subseq_convergent:
  1152   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1153   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1154 
  1155 lemma limI: "X \<longlonglongrightarrow> L ==> lim X = L"
  1156   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1157 
  1158 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1159   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1160 
  1161 lemma lim_const [simp]: "lim (\<lambda>m. a) = a"
  1162   by (simp add: limI)
  1163 
  1164 subsubsection\<open>Increasing and Decreasing Series\<close>
  1165 
  1166 lemma incseq_le: "incseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1167   by (metis incseq_def LIMSEQ_le_const)
  1168 
  1169 lemma decseq_le: "decseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1170   by (metis decseq_def LIMSEQ_le_const2)
  1171 
  1172 subsection \<open>First countable topologies\<close>
  1173 
  1174 class first_countable_topology = topological_space +
  1175   assumes first_countable_basis:
  1176     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1177 
  1178 lemma (in first_countable_topology) countable_basis_at_decseq:
  1179   obtains A :: "nat \<Rightarrow> 'a set" where
  1180     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1181     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1182 proof atomize_elim
  1183   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1184     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1185     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1186   define F where "F n = (\<Inter>i\<le>n. A i)" for n
  1187   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1188       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1189   proof (safe intro!: exI[of _ F])
  1190     fix i
  1191     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1192     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1193   next
  1194     fix S assume "open S" "x \<in> S"
  1195     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1196     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1197       by (auto simp: F_def)
  1198     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1199       by (auto simp: eventually_sequentially)
  1200   qed
  1201 qed
  1202 
  1203 lemma (in first_countable_topology) nhds_countable:
  1204   obtains X :: "nat \<Rightarrow> 'a set"
  1205   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1206 proof -
  1207   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1208     where A: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1209     by metis
  1210   show thesis
  1211   proof
  1212     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1213       by (auto simp: decseq_def)
  1214     show "\<And>n. x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)"
  1215       using A by auto
  1216     show "nhds x = (INF n. principal (\<Inter>i\<le>n. A i))"
  1217       using A unfolding nhds_def
  1218       apply -
  1219       apply (rule INF_eq)
  1220       apply simp_all
  1221       apply fastforce
  1222       apply (intro exI [of _ "\<Inter>i\<le>n. A i" for n] conjI open_INT)
  1223       apply auto
  1224       done
  1225   qed
  1226 qed
  1227 
  1228 lemma (in first_countable_topology) countable_basis:
  1229   obtains A :: "nat \<Rightarrow> 'a set" where
  1230     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1231     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F \<longlonglongrightarrow> x"
  1232 proof atomize_elim
  1233   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1234     "\<And>i. open (A i)"
  1235     "\<And>i. x \<in> A i"
  1236     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1237     by (rule countable_basis_at_decseq) blast
  1238   {
  1239     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1240     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1241       by (auto elim: eventually_mono simp: subset_eq)
  1242   }
  1243   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F \<longlonglongrightarrow> x)"
  1244     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1245 qed
  1246 
  1247 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1248   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1249   shows "eventually P (inf (nhds a) (principal s))"
  1250 proof (rule ccontr)
  1251   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1252     "\<And>i. open (A i)"
  1253     "\<And>i. a \<in> A i"
  1254     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F \<longlonglongrightarrow> a"
  1255     by (rule countable_basis) blast
  1256   assume "\<not> ?thesis"
  1257   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1258     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1259   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1260     by blast
  1261   with A have "F \<longlonglongrightarrow> a" by auto
  1262   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1263     using assms F0 by simp
  1264   thus "False" by (simp add: F3)
  1265 qed
  1266 
  1267 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1268   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow>
  1269     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1270 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1271   assume "eventually P (inf (nhds a) (principal s))"
  1272   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1273     by (auto simp: eventually_inf_principal eventually_nhds)
  1274   moreover fix f assume "\<forall>n. f n \<in> s" "f \<longlonglongrightarrow> a"
  1275   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1276     by (auto dest!: topological_tendstoD elim: eventually_mono)
  1277 qed
  1278 
  1279 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1280   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1281   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1282 
  1283 lemma tendsto_at_iff_sequentially:
  1284   fixes f :: "'a :: first_countable_topology \<Rightarrow> _"
  1285   shows "(f \<longlongrightarrow> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X \<longlonglongrightarrow> x \<longrightarrow> ((f \<circ> X) \<longlonglongrightarrow> a))"
  1286   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap at_within_def eventually_nhds_within_iff_sequentially comp_def
  1287   by metis
  1288 
  1289 subsection \<open>Function limit at a point\<close>
  1290 
  1291 abbreviation
  1292   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1293         ("((_)/ \<midarrow>(_)/\<rightarrow> (_))" [60, 0, 60] 60) where
  1294   "f \<midarrow>a\<rightarrow> L \<equiv> (f \<longlongrightarrow> L) (at a)"
  1295 
  1296 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l) (at a within S) \<longleftrightarrow> (f \<midarrow>a\<rightarrow> l)"
  1297   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1298 
  1299 lemma tendsto_within_open_NO_MATCH:
  1300   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1301   shows "a \<in> S \<Longrightarrow> NO_MATCH UNIV S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l)(at a within S) \<longleftrightarrow> (f \<longlongrightarrow> l)(at a)"
  1302 using tendsto_within_open by blast
  1303 
  1304 lemma LIM_const_not_eq[tendsto_intros]:
  1305   fixes a :: "'a::perfect_space"
  1306   fixes k L :: "'b::t2_space"
  1307   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) \<midarrow>a\<rightarrow> L"
  1308   by (simp add: tendsto_const_iff)
  1309 
  1310 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1311 
  1312 lemma LIM_const_eq:
  1313   fixes a :: "'a::perfect_space"
  1314   fixes k L :: "'b::t2_space"
  1315   shows "(\<lambda>x. k) \<midarrow>a\<rightarrow> L \<Longrightarrow> k = L"
  1316   by (simp add: tendsto_const_iff)
  1317 
  1318 lemma LIM_unique:
  1319   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1320   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> M \<Longrightarrow> L = M"
  1321   using at_neq_bot by (rule tendsto_unique)
  1322 
  1323 text \<open>Limits are equal for functions equal except at limit point\<close>
  1324 
  1325 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>a\<rightarrow> l)"
  1326   unfolding tendsto_def eventually_at_topological by simp
  1327 
  1328 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>b\<rightarrow> m)"
  1329   by (simp add: LIM_equal)
  1330 
  1331 lemma LIM_cong_limit: "f \<midarrow>x\<rightarrow> L \<Longrightarrow> K = L \<Longrightarrow> f \<midarrow>x\<rightarrow> K"
  1332   by simp
  1333 
  1334 lemma tendsto_at_iff_tendsto_nhds:
  1335   "g \<midarrow>l\<rightarrow> g l \<longleftrightarrow> (g \<longlongrightarrow> g l) (nhds l)"
  1336   unfolding tendsto_def eventually_at_filter
  1337   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
  1338 
  1339 lemma tendsto_compose:
  1340   "g \<midarrow>l\<rightarrow> g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1341   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1342 
  1343 lemma LIM_o: "\<lbrakk>g \<midarrow>l\<rightarrow> g l; f \<midarrow>a\<rightarrow> l\<rbrakk> \<Longrightarrow> (g \<circ> f) \<midarrow>a\<rightarrow> g l"
  1344   unfolding o_def by (rule tendsto_compose)
  1345 
  1346 lemma tendsto_compose_eventually:
  1347   "g \<midarrow>l\<rightarrow> m \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> m) F"
  1348   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1349 
  1350 lemma LIM_compose_eventually:
  1351   assumes f: "f \<midarrow>a\<rightarrow> b"
  1352   assumes g: "g \<midarrow>b\<rightarrow> c"
  1353   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1354   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  1355   using g f inj by (rule tendsto_compose_eventually)
  1356 
  1357 lemma tendsto_compose_filtermap: "((g \<circ> f) \<longlongrightarrow> T) F \<longleftrightarrow> (g \<longlongrightarrow> T) (filtermap f F)"
  1358   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1359 
  1360 subsubsection \<open>Relation of LIM and LIMSEQ\<close>
  1361 
  1362 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1363   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1364     eventually P (at a within s)"
  1365   unfolding at_within_def
  1366   by (intro sequentially_imp_eventually_nhds_within) auto
  1367 
  1368 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1369   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1370   using sequentially_imp_eventually_within [where s=UNIV] by simp
  1371 
  1372 lemma LIMSEQ_SEQ_conv1:
  1373   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1374   assumes f: "f \<midarrow>a\<rightarrow> l"
  1375   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1376   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1377 
  1378 lemma LIMSEQ_SEQ_conv2:
  1379   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1380   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1381   shows "f \<midarrow>a\<rightarrow> l"
  1382   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1383 
  1384 lemma LIMSEQ_SEQ_conv:
  1385   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L) =
  1386    (X \<midarrow>a\<rightarrow> (L::'b::topological_space))"
  1387   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1388 
  1389 lemma sequentially_imp_eventually_at_left:
  1390   fixes a :: "'a :: {linorder_topology, first_countable_topology}"
  1391   assumes b[simp]: "b < a"
  1392   assumes *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1393   shows "eventually P (at_left a)"
  1394 proof (safe intro!: sequentially_imp_eventually_within)
  1395   fix X assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1396   show "eventually (\<lambda>n. P (X n)) sequentially"
  1397   proof (rule ccontr)
  1398     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1399     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1400     proof (rule dependent_nat_choice)
  1401       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1402         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1403       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1404         by (auto dest!: not_eventuallyD)
  1405     next
  1406       fix x n
  1407       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1408         using X by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1409       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1410         by (auto dest!: not_eventuallyD)
  1411     qed
  1412     then guess s ..
  1413     then have "\<And>n. b < X (s n)" "\<And>n. X (s n) < a" "incseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a" "\<And>n. \<not> P (X (s n))"
  1414       using X by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1415     from *[OF this(1,2,3,4)] this(5) show False by auto
  1416   qed
  1417 qed
  1418 
  1419 lemma tendsto_at_left_sequentially:
  1420   fixes a :: "_ :: {linorder_topology, first_countable_topology}"
  1421   assumes "b < a"
  1422   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1423   shows "(X \<longlongrightarrow> L) (at_left a)"
  1424   using assms unfolding tendsto_def [where l=L]
  1425   by (simp add: sequentially_imp_eventually_at_left)
  1426 
  1427 lemma sequentially_imp_eventually_at_right:
  1428   fixes a :: "'a :: {linorder_topology, first_countable_topology}"
  1429   assumes b[simp]: "a < b"
  1430   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1431   shows "eventually P (at_right a)"
  1432 proof (safe intro!: sequentially_imp_eventually_within)
  1433   fix X assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1434   show "eventually (\<lambda>n. P (X n)) sequentially"
  1435   proof (rule ccontr)
  1436     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1437     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  1438     proof (rule dependent_nat_choice)
  1439       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  1440         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  1441       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  1442         by (auto dest!: not_eventuallyD)
  1443     next
  1444       fix x n
  1445       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  1446         using X by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  1447       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  1448         by (auto dest!: not_eventuallyD)
  1449     qed
  1450     then guess s ..
  1451     then have "\<And>n. a < X (s n)" "\<And>n. X (s n) < b" "decseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a" "\<And>n. \<not> P (X (s n))"
  1452       using X by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1453     from *[OF this(1,2,3,4)] this(5) show False by auto
  1454   qed
  1455 qed
  1456 
  1457 lemma tendsto_at_right_sequentially:
  1458   fixes a :: "_ :: {linorder_topology, first_countable_topology}"
  1459   assumes "a < b"
  1460   assumes *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1461   shows "(X \<longlongrightarrow> L) (at_right a)"
  1462   using assms unfolding tendsto_def [where l=L]
  1463   by (simp add: sequentially_imp_eventually_at_right)
  1464 
  1465 subsection \<open>Continuity\<close>
  1466 
  1467 subsubsection \<open>Continuity on a set\<close>
  1468 
  1469 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1470   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f \<longlongrightarrow> f x) (at x within s))"
  1471 
  1472 lemma continuous_on_cong [cong]:
  1473   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1474   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1475 
  1476 lemma continuous_on_topological:
  1477   "continuous_on s f \<longleftrightarrow>
  1478     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1479   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1480 
  1481 lemma continuous_on_open_invariant:
  1482   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1483 proof safe
  1484   fix B :: "'b set" assume "continuous_on s f" "open B"
  1485   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1486     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1487   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1488     unfolding bchoice_iff ..
  1489   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1490     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1491 next
  1492   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1493   show "continuous_on s f"
  1494     unfolding continuous_on_topological
  1495   proof safe
  1496     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1497     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1498     with \<open>x \<in> s\<close> \<open>f x \<in> B\<close> show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1499       by (intro exI[of _ A]) auto
  1500   qed
  1501 qed
  1502 
  1503 lemma continuous_on_open_vimage:
  1504   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1505   unfolding continuous_on_open_invariant
  1506   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1507 
  1508 corollary continuous_imp_open_vimage:
  1509   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1510     shows "open (f -` B)"
  1511 by (metis assms continuous_on_open_vimage le_iff_inf)
  1512 
  1513 corollary open_vimage[continuous_intros]:
  1514   assumes "open s" and "continuous_on UNIV f"
  1515   shows "open (f -` s)"
  1516   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  1517   by simp
  1518 
  1519 lemma continuous_on_closed_invariant:
  1520   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1521 proof -
  1522   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1523     by (metis double_compl)
  1524   show ?thesis
  1525     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1526 qed
  1527 
  1528 lemma continuous_on_closed_vimage:
  1529   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1530   unfolding continuous_on_closed_invariant
  1531   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1532 
  1533 corollary closed_vimage_Int[continuous_intros]:
  1534   assumes "closed s" and "continuous_on t f" and t: "closed t"
  1535   shows "closed (f -` s \<inter> t)"
  1536   using assms unfolding continuous_on_closed_vimage [OF t]  by simp
  1537 
  1538 corollary closed_vimage[continuous_intros]:
  1539   assumes "closed s" and "continuous_on UNIV f"
  1540   shows "closed (f -` s)"
  1541   using closed_vimage_Int [OF assms] by simp
  1542 
  1543 lemma continuous_on_empty [simp]: "continuous_on {} f"
  1544   by (simp add: continuous_on_def)
  1545 
  1546 lemma continuous_on_sing [simp]: "continuous_on {x} f"
  1547   by (simp add: continuous_on_def at_within_def)
  1548 
  1549 lemma continuous_on_open_Union:
  1550   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1551   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1552 
  1553 lemma continuous_on_open_UN:
  1554   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1555   by (rule continuous_on_open_Union) auto
  1556 
  1557 lemma continuous_on_open_Un:
  1558   "open s \<Longrightarrow> open t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1559   using continuous_on_open_Union [of "{s,t}"] by auto
  1560 
  1561 lemma continuous_on_closed_Un:
  1562   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1563   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1564 
  1565 lemma continuous_on_If:
  1566   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1567     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1568   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1569 proof-
  1570   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1571     by auto
  1572   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1573     by simp_all
  1574   with closed show ?thesis
  1575     by (rule continuous_on_closed_Un)
  1576 qed
  1577 
  1578 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  1579   unfolding continuous_on_def by fast
  1580 
  1581 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  1582   unfolding continuous_on_def by auto
  1583 
  1584 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1585   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1586 
  1587 lemma continuous_on_compose[continuous_intros]:
  1588   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1589   unfolding continuous_on_topological by simp metis
  1590 
  1591 lemma continuous_on_compose2:
  1592   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1593   using continuous_on_compose[of s f g] continuous_on_subset by (force simp add: comp_def)
  1594 
  1595 lemma continuous_on_generate_topology:
  1596   assumes *: "open = generate_topology X"
  1597   assumes **: "\<And>B. B \<in> X \<Longrightarrow> \<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1598   shows "continuous_on A f"
  1599   unfolding continuous_on_open_invariant
  1600 proof safe
  1601   fix B :: "'a set" assume "open B" then show "\<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1602     unfolding *
  1603   proof induction
  1604     case (UN K)
  1605     then obtain C where "\<And>k. k \<in> K \<Longrightarrow> open (C k)" "\<And>k. k \<in> K \<Longrightarrow> C k \<inter> A = f -` k \<inter> A"
  1606       by metis
  1607     then show ?case
  1608       by (intro exI[of _ "\<Union>k\<in>K. C k"]) blast
  1609   qed (auto intro: **)
  1610 qed
  1611 
  1612 lemma continuous_onI_mono:
  1613   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::{dense_order, linorder_topology}"
  1614   assumes "open (f`A)"
  1615   assumes mono: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1616   shows "continuous_on A f"
  1617 proof (rule continuous_on_generate_topology[OF open_generated_order], safe)
  1618   have monoD: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> f x < f y \<Longrightarrow> x < y"
  1619     by (auto simp: not_le[symmetric] mono)
  1620 
  1621   { fix a b assume "a \<in> A" "f a < b"
  1622     moreover
  1623     with open_right[OF \<open>open (f`A)\<close>, of "f a" b] obtain y where "f a < y" "{f a ..< y} \<subseteq> f`A"
  1624       by auto
  1625     moreover then obtain z where "f a < z" "z < min b y"
  1626       using dense[of "f a" "min b y"] \<open>f a < y\<close> \<open>f a < b\<close> by auto
  1627     moreover then obtain c where "z = f c" "c \<in> A"
  1628       using \<open>{f a ..< y} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1629     ultimately have "\<exists>x. x \<in> A \<and> f x < b \<and> a < x"
  1630       by (auto intro!: exI[of _ c] simp: monoD) }
  1631   then show "\<exists>C. open C \<and> C \<inter> A = f -` {..<b} \<inter> A" for b
  1632     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. f x < b}. {..< x})"])
  1633        (auto intro: le_less_trans[OF mono] less_imp_le)
  1634 
  1635   { fix a b assume "a \<in> A" "b < f a"
  1636     moreover
  1637     with open_left[OF \<open>open (f`A)\<close>, of "f a" b] obtain y where "y < f a" "{y <.. f a} \<subseteq> f`A"
  1638       by auto
  1639     moreover then obtain z where "max b y < z" "z < f a"
  1640       using dense[of "max b y" "f a"] \<open>y < f a\<close> \<open>b < f a\<close> by auto
  1641     moreover then obtain c where "z = f c" "c \<in> A"
  1642       using \<open>{y <.. f a} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1643     ultimately have "\<exists>x. x \<in> A \<and> b < f x \<and> x < a"
  1644       by (auto intro!: exI[of _ c] simp: monoD) }
  1645   then show "\<exists>C. open C \<and> C \<inter> A = f -` {b <..} \<inter> A" for b
  1646     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. b < f x}. {x <..})"])
  1647        (auto intro: less_le_trans[OF _ mono] less_imp_le)
  1648 qed
  1649 
  1650 subsubsection \<open>Continuity at a point\<close>
  1651 
  1652 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1653   "continuous F f \<longleftrightarrow> (f \<longlongrightarrow> f (Lim F (\<lambda>x. x))) F"
  1654 
  1655 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1656   unfolding continuous_def by auto
  1657 
  1658 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1659   by simp
  1660 
  1661 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f \<longlongrightarrow> f x) (at x within s)"
  1662   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1663 
  1664 lemma continuous_within_topological:
  1665   "continuous (at x within s) f \<longleftrightarrow>
  1666     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1667   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1668 
  1669 lemma continuous_within_compose[continuous_intros]:
  1670   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1671   continuous (at x within s) (g o f)"
  1672   by (simp add: continuous_within_topological) metis
  1673 
  1674 lemma continuous_within_compose2:
  1675   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1676   continuous (at x within s) (\<lambda>x. g (f x))"
  1677   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1678 
  1679 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f \<midarrow>x\<rightarrow> f x"
  1680   using continuous_within[of x UNIV f] by simp
  1681 
  1682 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1683   unfolding continuous_within by (rule tendsto_ident_at)
  1684 
  1685 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1686   unfolding continuous_def by (rule tendsto_const)
  1687 
  1688 lemma continuous_on_eq_continuous_within:
  1689   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1690   unfolding continuous_on_def continuous_within ..
  1691 
  1692 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1693   "isCont f a \<equiv> continuous (at a) f"
  1694 
  1695 lemma isCont_def: "isCont f a \<longleftrightarrow> f \<midarrow>a\<rightarrow> f a"
  1696   by (rule continuous_at)
  1697 
  1698 lemma continuous_at_imp_continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1699   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1700 
  1701 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1702   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1703 
  1704 lemma continuous_within_open: "a \<in> A \<Longrightarrow> open A \<Longrightarrow> continuous (at a within A) f \<longleftrightarrow> isCont f a"
  1705   by (simp add: at_within_open_NO_MATCH)
  1706 
  1707 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1708   by (auto intro: continuous_at_imp_continuous_at_within simp: continuous_on_eq_continuous_within)
  1709 
  1710 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1711   unfolding isCont_def by (rule tendsto_compose)
  1712 
  1713 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1714   unfolding o_def by (rule isCont_o2)
  1715 
  1716 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1717   unfolding isCont_def by (rule tendsto_compose)
  1718 
  1719 lemma continuous_on_tendsto_compose:
  1720   assumes f_cont: "continuous_on s f"
  1721   assumes g: "(g \<longlongrightarrow> l) F"
  1722   assumes l: "l \<in> s"
  1723   assumes ev: "\<forall>\<^sub>F x in F. g x \<in> s"
  1724   shows "((\<lambda>x. f (g x)) \<longlongrightarrow> f l) F"
  1725 proof -
  1726   from f_cont l have f: "(f \<longlongrightarrow> f l) (at l within s)"
  1727     by (simp add: continuous_on_def)
  1728   have i: "((\<lambda>x. if g x = l then f l else f (g x)) \<longlongrightarrow> f l) F"
  1729     by (rule filterlim_If)
  1730        (auto intro!: filterlim_compose[OF f] eventually_conj tendsto_mono[OF _ g]
  1731              simp: filterlim_at eventually_inf_principal eventually_mono[OF ev])
  1732   show ?thesis
  1733     by (rule filterlim_cong[THEN iffD1[OF _ i]]) auto
  1734 qed
  1735 
  1736 lemma continuous_within_compose3:
  1737   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1738   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_imp_continuous_at_within)
  1739 
  1740 lemma filtermap_nhds_open_map:
  1741   assumes cont: "isCont f a" and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  1742   shows "filtermap f (nhds a) = nhds (f a)"
  1743   unfolding filter_eq_iff
  1744 proof safe
  1745   fix P assume "eventually P (filtermap f (nhds a))"
  1746   then guess S unfolding eventually_filtermap eventually_nhds ..
  1747   then show "eventually P (nhds (f a))"
  1748     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  1749 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  1750 
  1751 lemma continuous_at_split:
  1752   "continuous (at (x::'a::linorder_topology)) f = (continuous (at_left x) f \<and> continuous (at_right x) f)"
  1753   by (simp add: continuous_within filterlim_at_split)
  1754 
  1755 subsubsection \<open>Open-cover compactness\<close>
  1756 
  1757 context topological_space
  1758 begin
  1759 
  1760 definition compact :: "'a set \<Rightarrow> bool" where
  1761   compact_eq_heine_borel: \<comment> "This name is used for backwards compatibility"
  1762     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1763 
  1764 lemma compactI:
  1765   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union>C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union>C'"
  1766   shows "compact s"
  1767   unfolding compact_eq_heine_borel using assms by metis
  1768 
  1769 lemma compact_empty[simp]: "compact {}"
  1770   by (auto intro!: compactI)
  1771 
  1772 lemma compactE:
  1773   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1774   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1775   using assms unfolding compact_eq_heine_borel by metis
  1776 
  1777 lemma compactE_image:
  1778   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1779   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1780   using assms unfolding ball_simps [symmetric]
  1781   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1782 
  1783 lemma compact_Int_closed [intro]:
  1784   assumes "compact s" and "closed t"
  1785   shows "compact (s \<inter> t)"
  1786 proof (rule compactI)
  1787   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1788   from C \<open>closed t\<close> have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1789   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1790   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1791     using \<open>compact s\<close> unfolding compact_eq_heine_borel by auto
  1792   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  1793   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1794     by (intro exI[of _ "D - {-t}"]) auto
  1795 qed
  1796 
  1797 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  1798   by (auto simp: inj_on_def)
  1799 
  1800 lemma compact_fip:
  1801   "compact U \<longleftrightarrow>
  1802     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  1803   (is "_ \<longleftrightarrow> ?R")
  1804 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  1805   fix A
  1806   assume "compact U"
  1807     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  1808     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  1809   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  1810     by auto
  1811   with \<open>compact U\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  1812     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  1813   with fi[THEN spec, of B] show False
  1814     by (auto dest: finite_imageD intro: inj_setminus)
  1815 next
  1816   fix A
  1817   assume ?R
  1818   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  1819   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  1820     by auto
  1821   with \<open>?R\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  1822     by (metis subset_image_iff)
  1823   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  1824     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  1825 qed
  1826 
  1827 lemma compact_imp_fip:
  1828     "\<lbrakk>compact S;
  1829       \<And>T. T \<in> F \<Longrightarrow> closed T;
  1830       \<And>F'. \<lbrakk>finite F'; F' \<subseteq> F\<rbrakk> \<Longrightarrow> S \<inter> (\<Inter>F') \<noteq> {}\<rbrakk>
  1831      \<Longrightarrow> S \<inter> (\<Inter>F) \<noteq> {}"
  1832   unfolding compact_fip by auto
  1833 
  1834 lemma compact_imp_fip_image:
  1835   assumes "compact s"
  1836     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  1837     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  1838   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  1839 proof -
  1840   note \<open>compact s\<close>
  1841   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  1842   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  1843   proof (rule, rule, erule conjE)
  1844     fix A :: "'a set set"
  1845     assume "finite A"
  1846     moreover assume "A \<subseteq> f ` I"
  1847     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  1848       using finite_subset_image [of A f I] by blast
  1849     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  1850   qed
  1851   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (metis compact_imp_fip)
  1852   then show ?thesis by simp
  1853 qed
  1854 
  1855 end
  1856 
  1857 lemma (in t2_space) compact_imp_closed:
  1858   assumes "compact s" shows "closed s"
  1859 unfolding closed_def
  1860 proof (rule openI)
  1861   fix y assume "y \<in> - s"
  1862   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  1863   note \<open>compact s\<close>
  1864   moreover have "\<forall>u\<in>?C. open u" by simp
  1865   moreover have "s \<subseteq> \<Union>?C"
  1866   proof
  1867     fix x assume "x \<in> s"
  1868     with \<open>y \<in> - s\<close> have "x \<noteq> y" by clarsimp
  1869     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  1870       by (rule hausdorff)
  1871     with \<open>x \<in> s\<close> show "x \<in> \<Union>?C"
  1872       unfolding eventually_nhds by auto
  1873   qed
  1874   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  1875     by (rule compactE)
  1876   from \<open>D \<subseteq> ?C\<close> have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  1877   with \<open>finite D\<close> have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  1878     by (simp add: eventually_ball_finite)
  1879   with \<open>s \<subseteq> \<Union>D\<close> have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  1880     by (auto elim!: eventually_mono)
  1881   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  1882     by (simp add: eventually_nhds subset_eq)
  1883 qed
  1884 
  1885 lemma compact_continuous_image:
  1886   assumes f: "continuous_on s f" and s: "compact s"
  1887   shows "compact (f ` s)"
  1888 proof (rule compactI)
  1889   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  1890   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  1891     unfolding continuous_on_open_invariant by blast
  1892   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  1893     unfolding bchoice_iff ..
  1894   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  1895     by (fastforce simp add: subset_eq set_eq_iff)+
  1896   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  1897   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  1898     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  1899 qed
  1900 
  1901 lemma continuous_on_inv:
  1902   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1903   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  1904   shows "continuous_on (f ` s) g"
  1905 unfolding continuous_on_topological
  1906 proof (clarsimp simp add: assms(3))
  1907   fix x :: 'a and B :: "'a set"
  1908   assume "x \<in> s" and "open B" and "x \<in> B"
  1909   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  1910     using assms(3) by (auto, metis)
  1911   have "continuous_on (s - B) f"
  1912     using \<open>continuous_on s f\<close> Diff_subset
  1913     by (rule continuous_on_subset)
  1914   moreover have "compact (s - B)"
  1915     using \<open>open B\<close> and \<open>compact s\<close>
  1916     unfolding Diff_eq by (intro compact_Int_closed closed_Compl)
  1917   ultimately have "compact (f ` (s - B))"
  1918     by (rule compact_continuous_image)
  1919   hence "closed (f ` (s - B))"
  1920     by (rule compact_imp_closed)
  1921   hence "open (- f ` (s - B))"
  1922     by (rule open_Compl)
  1923   moreover have "f x \<in> - f ` (s - B)"
  1924     using \<open>x \<in> s\<close> and \<open>x \<in> B\<close> by (simp add: 1)
  1925   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  1926     by (simp add: 1)
  1927   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  1928     by fast
  1929 qed
  1930 
  1931 lemma continuous_on_inv_into:
  1932   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1933   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  1934   shows "continuous_on (f ` s) (the_inv_into s f)"
  1935   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  1936 
  1937 lemma (in linorder_topology) compact_attains_sup:
  1938   assumes "compact S" "S \<noteq> {}"
  1939   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  1940 proof (rule classical)
  1941   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  1942   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  1943     by (metis not_le)
  1944   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  1945     by auto
  1946   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  1947     by (erule compactE_image)
  1948   with \<open>S \<noteq> {}\<close> have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  1949     by (auto intro!: Max_in)
  1950   with C have "S \<subseteq> {..< Max (t`C)}"
  1951     by (auto intro: less_le_trans simp: subset_eq)
  1952   with t Max \<open>C \<subseteq> S\<close> show ?thesis
  1953     by fastforce
  1954 qed
  1955 
  1956 lemma (in linorder_topology) compact_attains_inf:
  1957   assumes "compact S" "S \<noteq> {}"
  1958   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  1959 proof (rule classical)
  1960   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  1961   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  1962     by (metis not_le)
  1963   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  1964     by auto
  1965   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  1966     by (erule compactE_image)
  1967   with \<open>S \<noteq> {}\<close> have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  1968     by (auto intro!: Min_in)
  1969   with C have "S \<subseteq> {Min (t`C) <..}"
  1970     by (auto intro: le_less_trans simp: subset_eq)
  1971   with t Min \<open>C \<subseteq> S\<close> show ?thesis
  1972     by fastforce
  1973 qed
  1974 
  1975 lemma continuous_attains_sup:
  1976   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  1977   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  1978   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  1979 
  1980 lemma continuous_attains_inf:
  1981   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  1982   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  1983   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  1984 
  1985 subsection \<open>Connectedness\<close>
  1986 
  1987 context topological_space
  1988 begin
  1989 
  1990 definition "connected S \<longleftrightarrow>
  1991   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  1992 
  1993 lemma connectedI:
  1994   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  1995   \<Longrightarrow> connected U"
  1996   by (auto simp: connected_def)
  1997 
  1998 lemma connected_empty [simp]: "connected {}"
  1999   by (auto intro!: connectedI)
  2000 
  2001 lemma connected_sing [simp]: "connected {x}"
  2002   by (auto intro!: connectedI)
  2003 
  2004 lemma connectedD:
  2005   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}"
  2006   by (auto simp: connected_def)
  2007 
  2008 end
  2009 
  2010 lemma connected_closed:
  2011     "connected s \<longleftrightarrow>
  2012      ~ (\<exists>A B. closed A \<and> closed B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {})"
  2013 apply (simp add: connected_def del: ex_simps, safe)
  2014 apply (drule_tac x="-A" in spec)
  2015 apply (drule_tac x="-B" in spec)
  2016 apply (fastforce simp add: closed_def [symmetric])
  2017 apply (drule_tac x="-A" in spec)
  2018 apply (drule_tac x="-B" in spec)
  2019 apply (fastforce simp add: open_closed [symmetric])
  2020 done
  2021 
  2022 lemma connected_closedD:
  2023     "\<lbrakk>connected s; A \<inter> B \<inter> s = {}; s \<subseteq> A \<union> B; closed A; closed B\<rbrakk> \<Longrightarrow> A \<inter> s = {} \<or> B \<inter> s = {}"
  2024 by (simp add: connected_closed)
  2025 
  2026 lemma connected_Union:
  2027   assumes cs: "\<And>s. s \<in> S \<Longrightarrow> connected s" and ne: "\<Inter>S \<noteq> {}"
  2028     shows "connected(\<Union>S)"
  2029 proof (rule connectedI)
  2030   fix A B
  2031   assume A: "open A" and B: "open B" and Alap: "A \<inter> \<Union>S \<noteq> {}" and Blap: "B \<inter> \<Union>S \<noteq> {}"
  2032      and disj: "A \<inter> B \<inter> \<Union>S = {}" and cover: "\<Union>S \<subseteq> A \<union> B"
  2033   have disjs:"\<And>s. s \<in> S \<Longrightarrow> A \<inter> B \<inter> s = {}"
  2034     using disj by auto
  2035   obtain sa where sa: "sa \<in> S" "A \<inter> sa \<noteq> {}"
  2036     using Alap by auto
  2037   obtain sb where sb: "sb \<in> S" "B \<inter> sb \<noteq> {}"
  2038     using Blap by auto
  2039   obtain x where x: "\<And>s. s \<in> S \<Longrightarrow> x \<in> s"
  2040     using ne by auto
  2041   then have "x \<in> \<Union>S"
  2042     using \<open>sa \<in> S\<close> by blast
  2043   then have "x \<in> A \<or> x \<in> B"
  2044     using cover by auto
  2045   then show False
  2046     using cs [unfolded connected_def]
  2047     by (metis A B IntI Sup_upper sa sb disjs x cover empty_iff subset_trans)
  2048 qed
  2049 
  2050 lemma connected_Un: "\<lbrakk>connected s; connected t; s \<inter> t \<noteq> {}\<rbrakk> \<Longrightarrow> connected (s \<union> t)"
  2051   using connected_Union [of "{s,t}"] by auto
  2052 
  2053 lemma connected_diff_open_from_closed:
  2054   assumes st: "s \<subseteq> t" and tu: "t \<subseteq> u" and s: "open s"
  2055       and t: "closed t" and u: "connected u" and ts: "connected (t - s)"
  2056   shows "connected(u - s)"
  2057 proof (rule connectedI)
  2058   fix A B
  2059   assume AB: "open A" "open B" "A \<inter> (u - s) \<noteq> {}" "B \<inter> (u - s) \<noteq> {}"
  2060      and disj: "A \<inter> B \<inter> (u - s) = {}" and cover: "u - s \<subseteq> A \<union> B"
  2061   then consider "A \<inter> (t - s) = {}" | "B \<inter> (t - s) = {}"
  2062     using st ts tu connectedD [of "t-s" "A" "B"]
  2063     by auto
  2064   then show False
  2065   proof cases
  2066     case 1
  2067     then have "(A - t) \<inter> (B \<union> s) \<inter> u = {}"
  2068       using disj st by auto
  2069     moreover have  "u \<subseteq> (A - t) \<union> (B \<union> s)" using 1 cover by auto
  2070     ultimately show False
  2071       using connectedD [of u "A - t" "B \<union> s"] AB s t 1 u
  2072       by auto
  2073   next
  2074     case 2
  2075     then have "(A \<union> s) \<inter> (B - t) \<inter> u = {}"
  2076       using disj st
  2077       by auto
  2078     moreover have "u \<subseteq> (A \<union> s) \<union> (B - t)" using 2 cover by auto
  2079     ultimately show False
  2080       using connectedD [of u "A \<union> s" "B - t"] AB s t 2 u
  2081       by auto
  2082   qed
  2083 qed
  2084 
  2085 lemma connected_iff_const:
  2086   fixes S :: "'a::topological_space set"
  2087   shows "connected S \<longleftrightarrow> (\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c))"
  2088 proof safe
  2089   fix P :: "'a \<Rightarrow> bool" assume "connected S" "continuous_on S P"
  2090   then have "\<And>b. \<exists>A. open A \<and> A \<inter> S = P -` {b} \<inter> S"
  2091     unfolding continuous_on_open_invariant by (simp add: open_discrete)
  2092   from this[of True] this[of False]
  2093   obtain t f where "open t" "open f" and *: "f \<inter> S = P -` {False} \<inter> S" "t \<inter> S = P -` {True} \<inter> S"
  2094     by auto
  2095   then have "t \<inter> S = {} \<or> f \<inter> S = {}"
  2096     by (intro connectedD[OF \<open>connected S\<close>])  auto
  2097   then show "\<exists>c. \<forall>s\<in>S. P s = c"
  2098   proof (rule disjE)
  2099     assume "t \<inter> S = {}" then show ?thesis
  2100       unfolding * by (intro exI[of _ False]) auto
  2101   next
  2102     assume "f \<inter> S = {}" then show ?thesis
  2103       unfolding * by (intro exI[of _ True]) auto
  2104   qed
  2105 next
  2106   assume P: "\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c)"
  2107   show "connected S"
  2108   proof (rule connectedI)
  2109     fix A B assume *: "open A" "open B" "A \<inter> S \<noteq> {}" "B \<inter> S \<noteq> {}" "A \<inter> B \<inter> S = {}" "S \<subseteq> A \<union> B"
  2110     have "continuous_on S (\<lambda>x. x \<in> A)"
  2111       unfolding continuous_on_open_invariant
  2112     proof safe
  2113       fix C :: "bool set"
  2114       have "C = UNIV \<or> C = {True} \<or> C = {False} \<or> C = {}"
  2115         using subset_UNIV[of C] unfolding UNIV_bool by auto
  2116       with * show "\<exists>T. open T \<and> T \<inter> S = (\<lambda>x. x \<in> A) -` C \<inter> S"
  2117         by (intro exI[of _ "(if True \<in> C then A else {}) \<union> (if False \<in> C then B else {})"]) auto
  2118     qed
  2119     from P[rule_format, OF this] obtain c where "\<And>s. s \<in> S \<Longrightarrow> (s \<in> A) = c" by blast
  2120     with * show False
  2121       by (cases c) auto
  2122   qed
  2123 qed
  2124 
  2125 lemma connectedD_const:
  2126   fixes P :: "'a::topological_space \<Rightarrow> bool"
  2127   shows "connected S \<Longrightarrow> continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c"
  2128   unfolding connected_iff_const by auto
  2129 
  2130 lemma connectedI_const:
  2131   "(\<And>P::'a::topological_space \<Rightarrow> bool. continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c) \<Longrightarrow> connected S"
  2132   unfolding connected_iff_const by auto
  2133 
  2134 lemma connected_local_const:
  2135   assumes "connected A" "a \<in> A" "b \<in> A"
  2136   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2137   shows "f a = f b"
  2138 proof -
  2139   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2140     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2141     using * unfolding eventually_at_topological by metis
  2142 
  2143   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2144   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2145     using \<open>connected A\<close> S \<open>a\<in>A\<close>
  2146     by (intro connectedD) (auto, metis)
  2147   then show "f a = f b"
  2148   proof
  2149     assume "?N \<inter> A = {}"
  2150     then have "\<forall>x\<in>A. f a = f x"
  2151       using S(1) by auto
  2152     with \<open>b\<in>A\<close> show ?thesis by auto
  2153   next
  2154     assume "?P \<inter> A = {}" then show ?thesis
  2155       using \<open>a \<in> A\<close> S(1)[of a] by auto
  2156   qed
  2157 qed
  2158 
  2159 lemma (in linorder_topology) connectedD_interval:
  2160   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2161   shows "z \<in> U"
  2162 proof -
  2163   have eq: "{..<z} \<union> {z<..} = - {z}"
  2164     by auto
  2165   { assume "z \<notin> U" "x < z" "z < y"
  2166     with xy have "\<not> connected U"
  2167       unfolding connected_def simp_thms
  2168       apply (rule_tac exI[of _ "{..< z}"])
  2169       apply (rule_tac exI[of _ "{z <..}"])
  2170       apply (auto simp add: eq)
  2171       done }
  2172   with assms show "z \<in> U"
  2173     by (metis less_le)
  2174 qed
  2175 
  2176 lemma connected_continuous_image:
  2177   assumes *: "continuous_on s f"
  2178   assumes "connected s"
  2179   shows "connected (f ` s)"
  2180 proof (rule connectedI_const)
  2181   fix P :: "'b \<Rightarrow> bool" assume "continuous_on (f ` s) P"
  2182   then have "continuous_on s (P \<circ> f)"
  2183     by (rule continuous_on_compose[OF *])
  2184   from connectedD_const[OF \<open>connected s\<close> this] show "\<exists>c. \<forall>s\<in>f ` s. P s = c"
  2185     by auto
  2186 qed
  2187 
  2188 
  2189 section \<open>Linear Continuum Topologies\<close>
  2190 
  2191 class linear_continuum_topology = linorder_topology + linear_continuum
  2192 begin
  2193 
  2194 lemma Inf_notin_open:
  2195   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2196   shows "Inf A \<notin> A"
  2197 proof
  2198   assume "Inf A \<in> A"
  2199   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2200     using open_left[of A "Inf A" x] assms by auto
  2201   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2202     by (auto simp: subset_eq)
  2203   then show False
  2204     using cInf_lower[OF \<open>c \<in> A\<close>] bnd by (metis not_le less_imp_le bdd_belowI)
  2205 qed
  2206 
  2207 lemma Sup_notin_open:
  2208   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2209   shows "Sup A \<notin> A"
  2210 proof
  2211   assume "Sup A \<in> A"
  2212   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2213     using open_right[of A "Sup A" x] assms by auto
  2214   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2215     by (auto simp: subset_eq)
  2216   then show False
  2217     using cSup_upper[OF \<open>c \<in> A\<close>] bnd by (metis less_imp_le not_le bdd_aboveI)
  2218 qed
  2219 
  2220 end
  2221 
  2222 instance linear_continuum_topology \<subseteq> perfect_space
  2223 proof
  2224   fix x :: 'a
  2225   obtain y where "x < y \<or> y < x"
  2226     using ex_gt_or_lt [of x] ..
  2227   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2228   show "\<not> open {x}"
  2229     by auto
  2230 qed
  2231 
  2232 lemma connectedI_interval:
  2233   fixes U :: "'a :: linear_continuum_topology set"
  2234   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2235   shows "connected U"
  2236 proof (rule connectedI)
  2237   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2238     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2239 
  2240     let ?z = "Inf (B \<inter> {x <..})"
  2241 
  2242     have "x \<le> ?z" "?z \<le> y"
  2243       using \<open>y \<in> B\<close> \<open>x < y\<close> by (auto intro: cInf_lower cInf_greatest)
  2244     with \<open>x \<in> U\<close> \<open>y \<in> U\<close> have "?z \<in> U"
  2245       by (rule *)
  2246     moreover have "?z \<notin> B \<inter> {x <..}"
  2247       using \<open>open B\<close> by (intro Inf_notin_open) auto
  2248     ultimately have "?z \<in> A"
  2249       using \<open>x \<le> ?z\<close> \<open>A \<inter> B \<inter> U = {}\<close> \<open>x \<in> A\<close> \<open>U \<subseteq> A \<union> B\<close> by auto
  2250 
  2251     { assume "?z < y"
  2252       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2253         using open_right[OF \<open>open A\<close> \<open>?z \<in> A\<close> \<open>?z < y\<close>] by auto
  2254       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2255         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] \<open>?z < a\<close> \<open>?z < y\<close> \<open>x < y\<close> \<open>y \<in> B\<close>
  2256         by (auto intro: less_imp_le)
  2257       moreover have "?z \<le> b"
  2258         using \<open>b \<in> B\<close> \<open>x < b\<close>
  2259         by (intro cInf_lower) auto
  2260       moreover have "b \<in> U"
  2261         using \<open>x \<le> ?z\<close> \<open>?z \<le> b\<close> \<open>b < min a y\<close>
  2262         by (intro *[OF \<open>x \<in> U\<close> \<open>y \<in> U\<close>]) (auto simp: less_imp_le)
  2263       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2264         by (intro bexI[of _ b]) auto }
  2265     then have False
  2266       using \<open>?z \<le> y\<close> \<open>?z \<in> A\<close> \<open>y \<in> B\<close> \<open>y \<in> U\<close> \<open>A \<inter> B \<inter> U = {}\<close> unfolding le_less by blast }
  2267   note not_disjoint = this
  2268 
  2269   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2270   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2271   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2272   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2273   ultimately show False by (cases x y rule: linorder_cases) auto
  2274 qed
  2275 
  2276 lemma connected_iff_interval:
  2277   fixes U :: "'a :: linear_continuum_topology set"
  2278   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2279   by (auto intro: connectedI_interval dest: connectedD_interval)
  2280 
  2281 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2282   unfolding connected_iff_interval by auto
  2283 
  2284 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2285   unfolding connected_iff_interval by auto
  2286 
  2287 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2288   unfolding connected_iff_interval by auto
  2289 
  2290 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2291   unfolding connected_iff_interval by auto
  2292 
  2293 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2294   unfolding connected_iff_interval by auto
  2295 
  2296 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2297   unfolding connected_iff_interval by auto
  2298 
  2299 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2300   unfolding connected_iff_interval by auto
  2301 
  2302 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2303   unfolding connected_iff_interval by auto
  2304 
  2305 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2306   unfolding connected_iff_interval by auto
  2307 
  2308 lemma connected_contains_Ioo:
  2309   fixes A :: "'a :: linorder_topology set"
  2310   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2311   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2312 
  2313 lemma connected_contains_Icc:
  2314   assumes "connected (A :: ('a :: {linorder_topology}) set)" "a \<in> A" "b \<in> A"
  2315   shows   "{a..b} \<subseteq> A"
  2316 proof
  2317   fix x assume "x \<in> {a..b}"
  2318   hence "x = a \<or> x = b \<or> x \<in> {a<..<b}" by auto
  2319   thus "x \<in> A" using assms connected_contains_Ioo[of A a b] by auto
  2320 qed
  2321 
  2322 subsection \<open>Intermediate Value Theorem\<close>
  2323 
  2324 lemma IVT':
  2325   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2326   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2327   assumes *: "continuous_on {a .. b} f"
  2328   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2329 proof -
  2330   have "connected {a..b}"
  2331     unfolding connected_iff_interval by auto
  2332   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2333   show ?thesis
  2334     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2335 qed
  2336 
  2337 lemma IVT2':
  2338   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2339   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2340   assumes *: "continuous_on {a .. b} f"
  2341   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2342 proof -
  2343   have "connected {a..b}"
  2344     unfolding connected_iff_interval by auto
  2345   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2346   show ?thesis
  2347     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2348 qed
  2349 
  2350 lemma IVT:
  2351   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2352   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2353   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2354 
  2355 lemma IVT2:
  2356   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2357   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2358   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2359 
  2360 lemma continuous_inj_imp_mono:
  2361   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2362   assumes x: "a < x" "x < b"
  2363   assumes cont: "continuous_on {a..b} f"
  2364   assumes inj: "inj_on f {a..b}"
  2365   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2366 proof -
  2367   note I = inj_on_eq_iff[OF inj]
  2368   { assume "f x < f a" "f x < f b"
  2369     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2370       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2371       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2372     with x I have False by auto }
  2373   moreover
  2374   { assume "f a < f x" "f b < f x"
  2375     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2376       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2377       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2378     with x I have False by auto }
  2379   ultimately show ?thesis
  2380     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2381 qed
  2382 
  2383 lemma continuous_at_Sup_mono:
  2384   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2385   assumes "mono f"
  2386   assumes cont: "continuous (at_left (Sup S)) f"
  2387   assumes S: "S \<noteq> {}" "bdd_above S"
  2388   shows "f (Sup S) = (SUP s:S. f s)"
  2389 proof (rule antisym)
  2390   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2391     using cont unfolding continuous_within .
  2392 
  2393   show "f (Sup S) \<le> (SUP s:S. f s)"
  2394   proof cases
  2395     assume "Sup S \<in> S" then show ?thesis
  2396       by (rule cSUP_upper) (auto intro: bdd_above_image_mono S \<open>mono f\<close>)
  2397   next
  2398     assume "Sup S \<notin> S"
  2399     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2400       by auto
  2401     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2402       unfolding less_le by (blast intro: cSup_upper)
  2403     show ?thesis
  2404     proof (rule ccontr)
  2405       assume "\<not> ?thesis"
  2406       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "b < Sup S"
  2407         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> (SUP s:S. f s) < f y"
  2408         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2409       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2410         using less_cSupD[of S b] by auto
  2411       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2412         unfolding less_le by (blast intro: cSup_upper)
  2413       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_mono[of f]]
  2414       show False
  2415         by (auto simp: assms)
  2416     qed
  2417   qed
  2418 qed (intro cSUP_least \<open>mono f\<close>[THEN monoD] cSup_upper S)
  2419 
  2420 lemma continuous_at_Sup_antimono:
  2421   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2422   assumes "antimono f"
  2423   assumes cont: "continuous (at_left (Sup S)) f"
  2424   assumes S: "S \<noteq> {}" "bdd_above S"
  2425   shows "f (Sup S) = (INF s:S. f s)"
  2426 proof (rule antisym)
  2427   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2428     using cont unfolding continuous_within .
  2429 
  2430   show "(INF s:S. f s) \<le> f (Sup S)"
  2431   proof cases
  2432     assume "Sup S \<in> S" then show ?thesis
  2433       by (intro cINF_lower) (auto intro: bdd_below_image_antimono S \<open>antimono f\<close>)
  2434   next
  2435     assume "Sup S \<notin> S"
  2436     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2437       by auto
  2438     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2439       unfolding less_le by (blast intro: cSup_upper)
  2440     show ?thesis
  2441     proof (rule ccontr)
  2442       assume "\<not> ?thesis"
  2443       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "b < Sup S"
  2444         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> f y < (INF s:S. f s)"
  2445         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2446       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2447         using less_cSupD[of S b] by auto
  2448       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2449         unfolding less_le by (blast intro: cSup_upper)
  2450       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cINF_lower[OF bdd_below_image_antimono, of f S c] \<open>c \<in> S\<close>
  2451       show False
  2452         by (auto simp: assms)
  2453     qed
  2454   qed
  2455 qed (intro cINF_greatest \<open>antimono f\<close>[THEN antimonoD] cSup_upper S)
  2456 
  2457 lemma continuous_at_Inf_mono:
  2458   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2459   assumes "mono f"
  2460   assumes cont: "continuous (at_right (Inf S)) f"
  2461   assumes S: "S \<noteq> {}" "bdd_below S"
  2462   shows "f (Inf S) = (INF s:S. f s)"
  2463 proof (rule antisym)
  2464   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2465     using cont unfolding continuous_within .
  2466 
  2467   show "(INF s:S. f s) \<le> f (Inf S)"
  2468   proof cases
  2469     assume "Inf S \<in> S" then show ?thesis
  2470       by (rule cINF_lower[rotated]) (auto intro: bdd_below_image_mono S \<open>mono f\<close>)
  2471   next
  2472     assume "Inf S \<notin> S"
  2473     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2474       by auto
  2475     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2476       unfolding less_le by (blast intro: cInf_lower)
  2477     show ?thesis
  2478     proof (rule ccontr)
  2479       assume "\<not> ?thesis"
  2480       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "Inf S < b"
  2481         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> f y < (INF s:S. f s)"
  2482         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2483       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2484         using cInf_lessD[of S b] by auto
  2485       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2486         unfolding less_le by (blast intro: cInf_lower)
  2487       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cINF_lower[OF bdd_below_image_mono[of f] \<open>c \<in> S\<close>]
  2488       show False
  2489         by (auto simp: assms)
  2490     qed
  2491   qed
  2492 qed (intro cINF_greatest \<open>mono f\<close>[THEN monoD] cInf_lower \<open>bdd_below S\<close> \<open>S \<noteq> {}\<close>)
  2493 
  2494 lemma continuous_at_Inf_antimono:
  2495   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2496   assumes "antimono f"
  2497   assumes cont: "continuous (at_right (Inf S)) f"
  2498   assumes S: "S \<noteq> {}" "bdd_below S"
  2499   shows "f (Inf S) = (SUP s:S. f s)"
  2500 proof (rule antisym)
  2501   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2502     using cont unfolding continuous_within .
  2503 
  2504   show "f (Inf S) \<le> (SUP s:S. f s)"
  2505   proof cases
  2506     assume "Inf S \<in> S" then show ?thesis
  2507       by (rule cSUP_upper) (auto intro: bdd_above_image_antimono S \<open>antimono f\<close>)
  2508   next
  2509     assume "Inf S \<notin> S"
  2510     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2511       by auto
  2512     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2513       unfolding less_le by (blast intro: cInf_lower)
  2514     show ?thesis
  2515     proof (rule ccontr)
  2516       assume "\<not> ?thesis"
  2517       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "Inf S < b"
  2518         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> (SUP s:S. f s) < f y"
  2519         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2520       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2521         using cInf_lessD[of S b] by auto
  2522       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2523         unfolding less_le by (blast intro: cInf_lower)
  2524       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_antimono[of f]]
  2525       show False
  2526         by (auto simp: assms)
  2527     qed
  2528   qed
  2529 qed (intro cSUP_least \<open>antimono f\<close>[THEN antimonoD] cInf_lower S)
  2530 
  2531 subsection \<open>Uniform spaces\<close>
  2532 
  2533 class uniformity =
  2534   fixes uniformity :: "('a \<times> 'a) filter"
  2535 begin
  2536 
  2537 abbreviation uniformity_on :: "'a set \<Rightarrow> ('a \<times> 'a) filter" where
  2538   "uniformity_on s \<equiv> inf uniformity (principal (s\<times>s))"
  2539 
  2540 end
  2541 
  2542 lemma uniformity_Abort:
  2543   "uniformity =
  2544     Filter.abstract_filter (\<lambda>u. Code.abort (STR ''uniformity is not executable'') (\<lambda>u. uniformity))"
  2545   by simp
  2546 
  2547 class open_uniformity = "open" + uniformity +
  2548   assumes open_uniformity: "\<And>U. open U \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
  2549 
  2550 class uniform_space = open_uniformity +
  2551   assumes uniformity_refl: "eventually E uniformity \<Longrightarrow> E (x, x)"
  2552   assumes uniformity_sym: "eventually E uniformity \<Longrightarrow> eventually (\<lambda>(x, y). E (y, x)) uniformity"
  2553   assumes uniformity_trans: "eventually E uniformity \<Longrightarrow> \<exists>D. eventually D uniformity \<and> (\<forall>x y z. D (x, y) \<longrightarrow> D (y, z) \<longrightarrow> E (x, z))"
  2554 begin
  2555 
  2556 subclass topological_space
  2557   proof qed (force elim: eventually_mono eventually_elim2 simp: split_beta' open_uniformity)+
  2558 
  2559 lemma uniformity_bot: "uniformity \<noteq> bot"
  2560   using uniformity_refl by auto
  2561 
  2562 lemma uniformity_trans':
  2563   "eventually E uniformity \<Longrightarrow> eventually (\<lambda>((x, y), (y', z)). y = y' \<longrightarrow> E (x, z)) (uniformity \<times>\<^sub>F uniformity)"
  2564   by (drule uniformity_trans) (auto simp add: eventually_prod_same)
  2565 
  2566 lemma uniformity_transE:
  2567   assumes E: "eventually E uniformity"
  2568   obtains D where "eventually D uniformity" "\<And>x y z. D (x, y) \<Longrightarrow> D (y, z) \<Longrightarrow> E (x, z)"
  2569   using uniformity_trans[OF E] by auto
  2570 
  2571 lemma eventually_nhds_uniformity:
  2572   "eventually P (nhds x) \<longleftrightarrow> eventually (\<lambda>(x', y). x' = x \<longrightarrow> P y) uniformity" (is "_ \<longleftrightarrow> ?N P x")
  2573   unfolding eventually_nhds
  2574 proof safe
  2575   assume *: "?N P x"
  2576   { fix x assume "?N P x"
  2577     then guess D by (rule uniformity_transE) note D = this
  2578     from D(1) have "?N (?N P) x"
  2579       by eventually_elim (insert D, force elim: eventually_mono split: prod.split) }
  2580   then have "open {x. ?N P x}"
  2581     by (simp add: open_uniformity)
  2582   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>x\<in>S. P x)"
  2583     by (intro exI[of _ "{x. ?N P x}"]) (auto dest: uniformity_refl simp: *)
  2584 qed (force simp add: open_uniformity elim: eventually_mono)
  2585 
  2586 subsubsection \<open>Totally bounded sets\<close>
  2587 
  2588 definition totally_bounded :: "'a set \<Rightarrow> bool" where
  2589   "totally_bounded S \<longleftrightarrow>
  2590     (\<forall>E. eventually E uniformity \<longrightarrow> (\<exists>X. finite X \<and> (\<forall>s\<in>S. \<exists>x\<in>X. E (x, s))))"
  2591 
  2592 lemma totally_bounded_empty[iff]: "totally_bounded {}"
  2593   by (auto simp add: totally_bounded_def)
  2594 
  2595 lemma totally_bounded_subset: "totally_bounded S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> totally_bounded T"
  2596   by (force simp add: totally_bounded_def)
  2597 
  2598 lemma totally_bounded_Union[intro]:
  2599   assumes M: "finite M" "\<And>S. S \<in> M \<Longrightarrow> totally_bounded S" shows "totally_bounded (\<Union>M)"
  2600   unfolding totally_bounded_def
  2601 proof safe
  2602   fix E assume "eventually E uniformity"
  2603   with M obtain X where "\<forall>S\<in>M. finite (X S) \<and> (\<forall>s\<in>S. \<exists>x\<in>X S. E (x, s))"
  2604     by (metis totally_bounded_def)
  2605   with \<open>finite M\<close> show "\<exists>X. finite X \<and> (\<forall>s\<in>\<Union>M. \<exists>x\<in>X. E (x, s))"
  2606     by (intro exI[of _ "\<Union>S\<in>M. X S"]) force
  2607 qed
  2608 
  2609 subsubsection \<open>Cauchy filter\<close>
  2610 
  2611 definition cauchy_filter :: "'a filter \<Rightarrow> bool" where
  2612   "cauchy_filter F \<longleftrightarrow> F \<times>\<^sub>F F \<le> uniformity"
  2613 
  2614 definition Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  2615   Cauchy_uniform: "Cauchy X = cauchy_filter (filtermap X sequentially)"
  2616 
  2617 lemma Cauchy_uniform_iff:
  2618   "Cauchy X \<longleftrightarrow> (\<forall>P. eventually P uniformity \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m)))"
  2619   unfolding Cauchy_uniform cauchy_filter_def le_filter_def eventually_prod_same
  2620     eventually_filtermap eventually_sequentially
  2621 proof safe
  2622   let ?U = "\<lambda>P. eventually P uniformity"
  2623   { fix P assume "?U P" "\<forall>P. ?U P \<longrightarrow> (\<exists>Q. (\<exists>N. \<forall>n\<ge>N. Q (X n)) \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y)))"
  2624     then obtain Q N where "\<And>n. n \<ge> N \<Longrightarrow> Q (X n)" "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> P (x, y)"
  2625       by metis
  2626     then show "\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m)"
  2627       by blast }
  2628   { fix P assume "?U P" and P: "\<forall>P. ?U P \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m))"
  2629     then obtain Q where "?U Q" and Q: "\<And>x y z. Q (x, y) \<Longrightarrow> Q (y, z) \<Longrightarrow> P (x, z)"
  2630       by (auto elim: uniformity_transE)
  2631     then have "?U (\<lambda>x. Q x \<and> (\<lambda>(x, y). Q (y, x)) x)"
  2632       unfolding eventually_conj_iff by (simp add: uniformity_sym)
  2633     from P[rule_format, OF this]
  2634     obtain N where N: "\<And>n m. n \<ge> N \<Longrightarrow> m \<ge> N \<Longrightarrow> Q (X n, X m) \<and> Q (X m, X n)"
  2635       by auto
  2636     show "\<exists>Q. (\<exists>N. \<forall>n\<ge>N. Q (X n)) \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y))"
  2637     proof (safe intro!: exI[of _ "\<lambda>x. \<forall>n\<ge>N. Q (x, X n) \<and> Q (X n, x)"] exI[of _ N] N)
  2638       fix x y assume "\<forall>n\<ge>N. Q (x, X n) \<and> Q (X n, x)" "\<forall>n\<ge>N. Q (y, X n) \<and> Q (X n, y)"
  2639       then have "Q (x, X N)" "Q (X N, y)" by auto
  2640       then show "P (x, y)"
  2641         by (rule Q)
  2642     qed }
  2643 qed
  2644 
  2645 lemma nhds_imp_cauchy_filter:
  2646   assumes *: "F \<le> nhds x" shows "cauchy_filter F"
  2647 proof -
  2648   have "F \<times>\<^sub>F F \<le> nhds x \<times>\<^sub>F nhds x"
  2649     by (intro prod_filter_mono *)
  2650   also have "\<dots> \<le> uniformity"
  2651     unfolding le_filter_def eventually_nhds_uniformity eventually_prod_same
  2652   proof safe
  2653     fix P assume "eventually P uniformity"
  2654     then guess Ql by (rule uniformity_transE) note Ql = this
  2655     moreover note Ql(1)[THEN uniformity_sym]
  2656     ultimately show "\<exists>Q. eventually (\<lambda>(x', y). x' = x \<longrightarrow> Q y) uniformity \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y))"
  2657       by (rule_tac exI[of _ "\<lambda>y. Ql (y, x) \<and> Ql (x, y)"]) (fastforce elim: eventually_elim2)
  2658   qed
  2659   finally show ?thesis
  2660     by (simp add: cauchy_filter_def)
  2661 qed
  2662 
  2663 lemma LIMSEQ_imp_Cauchy: "X \<longlonglongrightarrow> x \<Longrightarrow> Cauchy X"
  2664   unfolding Cauchy_uniform filterlim_def by (intro nhds_imp_cauchy_filter)
  2665 
  2666 lemma Cauchy_subseq_Cauchy: assumes "Cauchy X" "subseq f" shows "Cauchy (X \<circ> f)"
  2667   unfolding Cauchy_uniform comp_def filtermap_filtermap[symmetric] cauchy_filter_def
  2668   by (rule order_trans[OF _ \<open>Cauchy X\<close>[unfolded Cauchy_uniform cauchy_filter_def]])
  2669      (intro prod_filter_mono filtermap_mono filterlim_subseq[OF \<open>subseq f\<close>, unfolded filterlim_def])
  2670 
  2671 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  2672   unfolding convergent_def by (erule exE, erule LIMSEQ_imp_Cauchy)
  2673 
  2674 definition complete :: "'a set \<Rightarrow> bool" where
  2675   complete_uniform: "complete S \<longleftrightarrow> (\<forall>F \<le> principal S. F \<noteq> bot \<longrightarrow> cauchy_filter F \<longrightarrow> (\<exists>x\<in>S. F \<le> nhds x))"
  2676 
  2677 end
  2678 
  2679 subsubsection \<open>Uniformly continuous functions\<close>
  2680 
  2681 definition uniformly_continuous_on :: "'a set \<Rightarrow> ('a::uniform_space \<Rightarrow> 'b::uniform_space) \<Rightarrow> bool" where
  2682   uniformly_continuous_on_uniformity: "uniformly_continuous_on s f \<longleftrightarrow>
  2683     (LIM (x, y) (uniformity_on s). (f x, f y) :> uniformity)"
  2684 
  2685 lemma uniformly_continuous_onD:
  2686   "uniformly_continuous_on s f \<Longrightarrow> eventually E uniformity
  2687     \<Longrightarrow> eventually (\<lambda>(x, y). x \<in> s \<longrightarrow> y \<in> s \<longrightarrow> E (f x, f y)) uniformity"
  2688   by (simp add: uniformly_continuous_on_uniformity filterlim_iff eventually_inf_principal split_beta' mem_Times_iff imp_conjL)
  2689 
  2690 lemma uniformly_continuous_on_const[continuous_intros]: "uniformly_continuous_on s (\<lambda>x. c)"
  2691   by (auto simp: uniformly_continuous_on_uniformity filterlim_iff uniformity_refl)
  2692 
  2693 lemma uniformly_continuous_on_id[continuous_intros]: "uniformly_continuous_on s (\<lambda>x. x)"
  2694   by (auto simp: uniformly_continuous_on_uniformity filterlim_def)
  2695 
  2696 lemma uniformly_continuous_on_compose[continuous_intros]:
  2697   "uniformly_continuous_on s g \<Longrightarrow> uniformly_continuous_on (g`s) f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f (g x))"
  2698   using filterlim_compose[of "\<lambda>(x, y). (f x, f y)" uniformity "uniformity_on (g`s)"  "\<lambda>(x, y). (g x, g y)" "uniformity_on s"]
  2699   by (simp add: split_beta' uniformly_continuous_on_uniformity filterlim_inf filterlim_principal eventually_inf_principal mem_Times_iff)
  2700 
  2701 lemma uniformly_continuous_imp_continuous: assumes f: "uniformly_continuous_on s f" shows "continuous_on s f"
  2702   by (auto simp: filterlim_iff eventually_at_filter eventually_nhds_uniformity continuous_on_def
  2703            elim: eventually_mono dest!: uniformly_continuous_onD[OF f])
  2704 
  2705 section \<open>Product Topology\<close>
  2706 
  2707 
  2708 subsection \<open>Product is a topological space\<close>
  2709 
  2710 instantiation prod :: (topological_space, topological_space) topological_space
  2711 begin
  2712 
  2713 definition open_prod_def[code del]:
  2714   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
  2715     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
  2716 
  2717 lemma open_prod_elim:
  2718   assumes "open S" and "x \<in> S"
  2719   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
  2720 using assms unfolding open_prod_def by fast
  2721 
  2722 lemma open_prod_intro:
  2723   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
  2724   shows "open S"
  2725 using assms unfolding open_prod_def by fast
  2726 
  2727 instance
  2728 proof
  2729   show "open (UNIV :: ('a \<times> 'b) set)"
  2730     unfolding open_prod_def by auto
  2731 next
  2732   fix S T :: "('a \<times> 'b) set"
  2733   assume "open S" "open T"
  2734   show "open (S \<inter> T)"
  2735   proof (rule open_prod_intro)
  2736     fix x assume x: "x \<in> S \<inter> T"
  2737     from x have "x \<in> S" by simp
  2738     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
  2739       using \<open>open S\<close> and \<open>x \<in> S\<close> by (rule open_prod_elim)
  2740     from x have "x \<in> T" by simp
  2741     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
  2742       using \<open>open T\<close> and \<open>x \<in> T\<close> by (rule open_prod_elim)
  2743     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
  2744     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
  2745       using A B by (auto simp add: open_Int)
  2746     thus "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
  2747       by fast
  2748   qed
  2749 next
  2750   fix K :: "('a \<times> 'b) set set"
  2751   assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
  2752     unfolding open_prod_def by fast
  2753 qed
  2754 
  2755 end
  2756 
  2757 declare [[code abort: "open::('a::topological_space*'b::topological_space) set \<Rightarrow> bool"]]
  2758 
  2759 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
  2760 unfolding open_prod_def by auto
  2761 
  2762 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
  2763 by auto
  2764 
  2765 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
  2766 by auto
  2767 
  2768 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
  2769 by (simp add: fst_vimage_eq_Times open_Times)
  2770 
  2771 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
  2772 by (simp add: snd_vimage_eq_Times open_Times)
  2773 
  2774 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
  2775 unfolding closed_open vimage_Compl [symmetric]
  2776 by (rule open_vimage_fst)
  2777 
  2778 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
  2779 unfolding closed_open vimage_Compl [symmetric]
  2780 by (rule open_vimage_snd)
  2781 
  2782 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
  2783 proof -
  2784   have "S \<times> T = (fst -` S) \<inter> (snd -` T)" by auto
  2785   thus "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
  2786     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
  2787 qed
  2788 
  2789 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
  2790   unfolding image_def subset_eq by force
  2791 
  2792 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
  2793   unfolding image_def subset_eq by force
  2794 
  2795 lemma open_image_fst: assumes "open S" shows "open (fst ` S)"
  2796 proof (rule openI)
  2797   fix x assume "x \<in> fst ` S"
  2798   then obtain y where "(x, y) \<in> S" by auto
  2799   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
  2800     using \<open>open S\<close> unfolding open_prod_def by auto
  2801   from \<open>A \<times> B \<subseteq> S\<close> \<open>y \<in> B\<close> have "A \<subseteq> fst ` S" by (rule subset_fst_imageI)
  2802   with \<open>open A\<close> \<open>x \<in> A\<close> have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S" by simp
  2803   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" by - (rule exI)
  2804 qed
  2805 
  2806 lemma open_image_snd: assumes "open S" shows "open (snd ` S)"
  2807 proof (rule openI)
  2808   fix y assume "y \<in> snd ` S"
  2809   then obtain x where "(x, y) \<in> S" by auto
  2810   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
  2811     using \<open>open S\<close> unfolding open_prod_def by auto
  2812   from \<open>A \<times> B \<subseteq> S\<close> \<open>x \<in> A\<close> have "B \<subseteq> snd ` S" by (rule subset_snd_imageI)
  2813   with \<open>open B\<close> \<open>y \<in> B\<close> have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S" by simp
  2814   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" by - (rule exI)
  2815 qed
  2816 
  2817 lemma nhds_prod: "nhds (a, b) = nhds a \<times>\<^sub>F nhds b"
  2818   unfolding nhds_def
  2819 proof (subst prod_filter_INF, auto intro!: antisym INF_greatest simp: principal_prod_principal)
  2820   fix S T assume "open S" "a \<in> S" "open T" "b \<in> T"
  2821   then show "(INF x : {S. open S \<and> (a, b) \<in> S}. principal x) \<le> principal (S \<times> T)"
  2822     by (intro INF_lower) (auto intro!: open_Times)
  2823 next
  2824   fix S' assume "open S'" "(a, b) \<in> S'"
  2825   then obtain S T where "open S" "a \<in> S" "open T" "b \<in> T" "S \<times> T \<subseteq> S'"
  2826     by (auto elim: open_prod_elim)
  2827   then show "(INF x : {S. open S \<and> a \<in> S}. INF y : {S. open S \<and> b \<in> S}. principal (x \<times> y)) \<le> principal S'"
  2828     by (auto intro!: INF_lower2)
  2829 qed
  2830 
  2831 subsubsection \<open>Continuity of operations\<close>
  2832 
  2833 lemma tendsto_fst [tendsto_intros]:
  2834   assumes "(f \<longlongrightarrow> a) F"
  2835   shows "((\<lambda>x. fst (f x)) \<longlongrightarrow> fst a) F"
  2836 proof (rule topological_tendstoI)
  2837   fix S assume "open S" and "fst a \<in> S"
  2838   then have "open (fst -` S)" and "a \<in> fst -` S"
  2839     by (simp_all add: open_vimage_fst)
  2840   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) F"
  2841     by (rule topological_tendstoD)
  2842   then show "eventually (\<lambda>x. fst (f x) \<in> S) F"
  2843     by simp
  2844 qed
  2845 
  2846 lemma tendsto_snd [tendsto_intros]:
  2847   assumes "(f \<longlongrightarrow> a) F"
  2848   shows "((\<lambda>x. snd (f x)) \<longlongrightarrow> snd a) F"
  2849 proof (rule topological_tendstoI)
  2850   fix S assume "open S" and "snd a \<in> S"
  2851   then have "open (snd -` S)" and "a \<in> snd -` S"
  2852     by (simp_all add: open_vimage_snd)
  2853   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) F"
  2854     by (rule topological_tendstoD)
  2855   then show "eventually (\<lambda>x. snd (f x) \<in> S) F"
  2856     by simp
  2857 qed
  2858 
  2859 lemma tendsto_Pair [tendsto_intros]:
  2860   assumes "(f \<longlongrightarrow> a) F" and "(g \<longlongrightarrow> b) F"
  2861   shows "((\<lambda>x. (f x, g x)) \<longlongrightarrow> (a, b)) F"
  2862 proof (rule topological_tendstoI)
  2863   fix S assume "open S" and "(a, b) \<in> S"
  2864   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
  2865     unfolding open_prod_def by fast
  2866   have "eventually (\<lambda>x. f x \<in> A) F"
  2867     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open A\<close> \<open>a \<in> A\<close>
  2868     by (rule topological_tendstoD)
  2869   moreover
  2870   have "eventually (\<lambda>x. g x \<in> B) F"
  2871     using \<open>(g \<longlongrightarrow> b) F\<close> \<open>open B\<close> \<open>b \<in> B\<close>
  2872     by (rule topological_tendstoD)
  2873   ultimately
  2874   show "eventually (\<lambda>x. (f x, g x) \<in> S) F"
  2875     by (rule eventually_elim2)
  2876        (simp add: subsetD [OF \<open>A \<times> B \<subseteq> S\<close>])
  2877 qed
  2878 
  2879 lemma continuous_fst[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. fst (f x))"
  2880   unfolding continuous_def by (rule tendsto_fst)
  2881 
  2882 lemma continuous_snd[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. snd (f x))"
  2883   unfolding continuous_def by (rule tendsto_snd)
  2884 
  2885 lemma continuous_Pair[continuous_intros]: "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. (f x, g x))"
  2886   unfolding continuous_def by (rule tendsto_Pair)
  2887 
  2888 lemma continuous_on_fst[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. fst (f x))"
  2889   unfolding continuous_on_def by (auto intro: tendsto_fst)
  2890 
  2891 lemma continuous_on_snd[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. snd (f x))"
  2892   unfolding continuous_on_def by (auto intro: tendsto_snd)
  2893 
  2894 lemma continuous_on_Pair[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. (f x, g x))"
  2895   unfolding continuous_on_def by (auto intro: tendsto_Pair)
  2896 
  2897 lemma continuous_on_swap[continuous_intros]: "continuous_on A prod.swap"
  2898   by (simp add: prod.swap_def continuous_on_fst continuous_on_snd continuous_on_Pair continuous_on_id)
  2899 
  2900 lemma continuous_on_swap_args:
  2901   assumes "continuous_on (A\<times>B) (\<lambda>(x,y). d x y)"
  2902     shows "continuous_on (B\<times>A) (\<lambda>(x,y). d y x)"
  2903 proof -
  2904   have "(\<lambda>(x,y). d y x) = (\<lambda>(x,y). d x y) o prod.swap"
  2905     by force
  2906   then show ?thesis
  2907     apply (rule ssubst)
  2908     apply (rule continuous_on_compose)
  2909      apply (force intro: continuous_on_subset [OF continuous_on_swap])
  2910     apply (force intro: continuous_on_subset [OF assms])
  2911     done
  2912 qed
  2913 
  2914 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
  2915   by (fact continuous_fst)
  2916 
  2917 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
  2918   by (fact continuous_snd)
  2919 
  2920 lemma isCont_Pair [simp]: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
  2921   by (fact continuous_Pair)
  2922 
  2923 subsubsection \<open>Separation axioms\<close>
  2924 
  2925 instance prod :: (t0_space, t0_space) t0_space
  2926 proof
  2927   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
  2928   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  2929     by (simp add: prod_eq_iff)
  2930   thus "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
  2931     by (fast dest: t0_space elim: open_vimage_fst open_vimage_snd)
  2932 qed
  2933 
  2934 instance prod :: (t1_space, t1_space) t1_space
  2935 proof
  2936   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
  2937   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  2938     by (simp add: prod_eq_iff)
  2939   thus "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
  2940     by (fast dest: t1_space elim: open_vimage_fst open_vimage_snd)
  2941 qed
  2942 
  2943 instance prod :: (t2_space, t2_space) t2_space
  2944 proof
  2945   fix x y :: "'a \<times> 'b" assume "x \<noteq> y"
  2946   hence "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  2947     by (simp add: prod_eq_iff)
  2948   thus "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  2949     by (fast dest: hausdorff elim: open_vimage_fst open_vimage_snd)
  2950 qed
  2951 
  2952 lemma isCont_swap[continuous_intros]: "isCont prod.swap a"
  2953   using continuous_on_eq_continuous_within continuous_on_swap by blast
  2954 
  2955 end