src/HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
author blanchet
Fri Apr 16 14:48:34 2010 +0200 (2010-04-16)
changeset 36169 27b1cc58715e
parent 36168 0a6ed065683d
child 36170 0cdb76723c88
permissions -rw-r--r--
store nonmangled names along with mangled type names in Sledgehammer for debugging purposes
     1 (*  Title:      HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory
     3 
     4 Storing/printing FOL clauses and arity clauses.  Typed equality is
     5 treated differently.
     6 
     7 FIXME: combine with res_hol_clause!
     8 *)
     9 
    10 signature SLEDGEHAMMER_FOL_CLAUSE =
    11 sig
    12   val schematic_var_prefix: string
    13   val fixed_var_prefix: string
    14   val tvar_prefix: string
    15   val tfree_prefix: string
    16   val clause_prefix: string
    17   val const_prefix: string
    18   val tconst_prefix: string
    19   val class_prefix: string
    20   val union_all: ''a list list -> ''a list
    21   val const_trans_table: string Symtab.table
    22   val type_const_trans_table: string Symtab.table
    23   val ascii_of: string -> string
    24   val undo_ascii_of: string -> string
    25   val paren_pack : string list -> string
    26   val make_schematic_var : string * int -> string
    27   val make_fixed_var : string -> string
    28   val make_schematic_type_var : string * int -> string
    29   val make_fixed_type_var : string -> string
    30   val make_fixed_const : bool -> string -> string
    31   val make_fixed_type_const : bool -> string -> string
    32   val make_type_class : string -> string
    33   type name = string * string
    34   type name_pool = string Symtab.table * string Symtab.table
    35   val empty_name_pool : bool -> name_pool option
    36   val pool_map : ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    37   val nice_name : name -> name_pool option -> string * name_pool option
    38   datatype kind = Axiom | Conjecture
    39   type axiom_name = string
    40   datatype fol_type =
    41     TyVar of name |
    42     TyFree of name |
    43     TyConstr of name * fol_type list
    44   val string_of_fol_type : fol_type -> string
    45   datatype type_literal = LTVar of string * string | LTFree of string * string
    46   exception CLAUSE of string * term
    47   val add_typs : typ list -> type_literal list
    48   val get_tvar_strs: typ list -> string list
    49   datatype arLit =
    50       TConsLit of class * string * string list
    51     | TVarLit of class * string
    52   datatype arity_clause = ArityClause of
    53    {axiom_name: axiom_name, conclLit: arLit, premLits: arLit list}
    54   datatype classrel_clause = ClassrelClause of
    55    {axiom_name: axiom_name, subclass: class, superclass: class}
    56   val make_classrel_clauses: theory -> class list -> class list -> classrel_clause list
    57   val make_arity_clauses_dfg: bool -> theory -> string list -> class list -> class list * arity_clause list
    58   val make_arity_clauses: theory -> string list -> class list -> class list * arity_clause list
    59   val add_type_sort_preds: typ * int Symtab.table -> int Symtab.table
    60   val add_classrel_clause_preds : classrel_clause * int Symtab.table -> int Symtab.table
    61   val class_of_arityLit: arLit -> class
    62   val add_arity_clause_preds: arity_clause * int Symtab.table -> int Symtab.table
    63   val add_foltype_funcs: fol_type * int Symtab.table -> int Symtab.table
    64   val add_arity_clause_funcs: arity_clause * int Symtab.table -> int Symtab.table
    65   val init_functab: int Symtab.table
    66   val dfg_sign: bool -> string -> string
    67   val dfg_of_typeLit: bool -> type_literal -> string
    68   val gen_dfg_cls: int * string * kind * string list * string list * string list -> string
    69   val string_of_preds: (string * Int.int) list -> string
    70   val string_of_funcs: (string * int) list -> string
    71   val string_of_symbols: string -> string -> string
    72   val string_of_start: string -> string
    73   val string_of_descrip : string -> string
    74   val dfg_tfree_clause : string -> string
    75   val dfg_classrel_clause: classrel_clause -> string
    76   val dfg_arity_clause: arity_clause -> string
    77   val tptp_sign: bool -> string -> string
    78   val tptp_of_typeLit : bool -> type_literal -> string
    79   val gen_tptp_cls : int * string * kind * string list * string list -> string
    80   val tptp_tfree_clause : string -> string
    81   val tptp_arity_clause : arity_clause -> string
    82   val tptp_classrel_clause : classrel_clause -> string
    83 end
    84 
    85 structure Sledgehammer_FOL_Clause : SLEDGEHAMMER_FOL_CLAUSE =
    86 struct
    87 
    88 open Sledgehammer_Util
    89 
    90 val schematic_var_prefix = "V_";
    91 val fixed_var_prefix = "v_";
    92 
    93 val tvar_prefix = "T_";
    94 val tfree_prefix = "t_";
    95 
    96 val clause_prefix = "cls_";
    97 val arclause_prefix = "clsarity_"
    98 val clrelclause_prefix = "clsrel_";
    99 
   100 val const_prefix = "c_";
   101 val tconst_prefix = "tc_";
   102 val class_prefix = "class_";
   103 
   104 fun union_all xss = List.foldl (uncurry (union (op =))) [] xss;
   105 
   106 (* Provide readable names for the more common symbolic functions *)
   107 val const_trans_table =
   108   Symtab.make [(@{const_name "op ="}, "equal"),
   109                (@{const_name Orderings.less_eq}, "lessequals"),
   110                (@{const_name "op &"}, "and"),
   111                (@{const_name "op |"}, "or"),
   112                (@{const_name "op -->"}, "implies"),
   113                (@{const_name "op :"}, "in"),
   114                (@{const_name fequal}, "fequal"),
   115                (@{const_name COMBI}, "COMBI"),
   116                (@{const_name COMBK}, "COMBK"),
   117                (@{const_name COMBB}, "COMBB"),
   118                (@{const_name COMBC}, "COMBC"),
   119                (@{const_name COMBS}, "COMBS")];
   120 
   121 val type_const_trans_table =
   122   Symtab.make [("*", "prod"), ("+", "sum"), ("~=>", "map")];
   123 
   124 (*Escaping of special characters.
   125   Alphanumeric characters are left unchanged.
   126   The character _ goes to __
   127   Characters in the range ASCII space to / go to _A to _P, respectively.
   128   Other printing characters go to _nnn where nnn is the decimal ASCII code.*)
   129 val A_minus_space = Char.ord #"A" - Char.ord #" ";
   130 
   131 fun stringN_of_int 0 _ = ""
   132   | stringN_of_int k n = stringN_of_int (k-1) (n div 10) ^ Int.toString (n mod 10);
   133 
   134 fun ascii_of_c c =
   135   if Char.isAlphaNum c then String.str c
   136   else if c = #"_" then "__"
   137   else if #" " <= c andalso c <= #"/"
   138        then "_" ^ String.str (Char.chr (Char.ord c + A_minus_space))
   139   else if Char.isPrint c
   140        then ("_" ^ stringN_of_int 3 (Char.ord c))  (*fixed width, in case more digits follow*)
   141   else ""
   142 
   143 val ascii_of = String.translate ascii_of_c;
   144 
   145 (** Remove ASCII armouring from names in proof files **)
   146 
   147 (*We don't raise error exceptions because this code can run inside the watcher.
   148   Also, the errors are "impossible" (hah!)*)
   149 fun undo_ascii_aux rcs [] = String.implode(rev rcs)
   150   | undo_ascii_aux rcs [#"_"] = undo_ascii_aux (#"_"::rcs) []  (*ERROR*)
   151       (*Three types of _ escapes: __, _A to _P, _nnn*)
   152   | undo_ascii_aux rcs (#"_" :: #"_" :: cs) = undo_ascii_aux (#"_"::rcs) cs
   153   | undo_ascii_aux rcs (#"_" :: c :: cs) =
   154       if #"A" <= c andalso c<= #"P"  (*translation of #" " to #"/"*)
   155       then undo_ascii_aux (Char.chr(Char.ord c - A_minus_space) :: rcs) cs
   156       else
   157         let val digits = List.take (c::cs, 3) handle Subscript => []
   158         in
   159             case Int.fromString (String.implode digits) of
   160                 NONE => undo_ascii_aux (c:: #"_"::rcs) cs  (*ERROR*)
   161               | SOME n => undo_ascii_aux (Char.chr n :: rcs) (List.drop (cs, 2))
   162         end
   163   | undo_ascii_aux rcs (c::cs) = undo_ascii_aux (c::rcs) cs;
   164 
   165 val undo_ascii_of = undo_ascii_aux [] o String.explode;
   166 
   167 (* convert a list of strings into one single string; surrounded by brackets *)
   168 fun paren_pack [] = ""   (*empty argument list*)
   169   | paren_pack strings = "(" ^ commas strings ^ ")";
   170 
   171 (*TSTP format uses (...) rather than the old [...]*)
   172 fun tptp_pack strings = "(" ^ space_implode " | " strings ^ ")";
   173 
   174 
   175 (*Remove the initial ' character from a type variable, if it is present*)
   176 fun trim_type_var s =
   177   if s <> "" andalso String.sub(s,0) = #"'" then String.extract(s,1,NONE)
   178   else error ("trim_type: Malformed type variable encountered: " ^ s);
   179 
   180 fun ascii_of_indexname (v,0) = ascii_of v
   181   | ascii_of_indexname (v,i) = ascii_of v ^ "_" ^ Int.toString i;
   182 
   183 fun make_schematic_var v = schematic_var_prefix ^ (ascii_of_indexname v);
   184 fun make_fixed_var x = fixed_var_prefix ^ (ascii_of x);
   185 
   186 fun make_schematic_type_var (x,i) =
   187       tvar_prefix ^ (ascii_of_indexname (trim_type_var x,i));
   188 fun make_fixed_type_var x = tfree_prefix ^ (ascii_of (trim_type_var x));
   189 
   190 (* HACK because SPASS 3.0 truncates identifiers to 63 characters. (This is
   191    solved in 3.7 and perhaps in earlier versions too.) *)
   192 (* 32-bit hash, so we expect no collisions. *)
   193 fun controlled_length dfg s =
   194   if dfg andalso size s > 60 then Word.toString (hashw_string (s, 0w0)) else s;
   195 
   196 fun lookup_const dfg c =
   197     case Symtab.lookup const_trans_table c of
   198         SOME c' => c'
   199       | NONE => controlled_length dfg (ascii_of c);
   200 
   201 fun lookup_type_const dfg c =
   202     case Symtab.lookup type_const_trans_table c of
   203         SOME c' => c'
   204       | NONE => controlled_length dfg (ascii_of c);
   205 
   206 (* "op =" MUST BE "equal" because it's built into ATPs. *)
   207 fun make_fixed_const _ (@{const_name "op ="}) = "equal"
   208   | make_fixed_const dfg c = const_prefix ^ lookup_const dfg c;
   209 
   210 fun make_fixed_type_const dfg c = tconst_prefix ^ lookup_type_const dfg c;
   211 
   212 fun make_type_class clas = class_prefix ^ ascii_of clas;
   213 
   214 
   215 (**** name pool ****)
   216  
   217 type name = string * string
   218 type name_pool = string Symtab.table * string Symtab.table
   219 
   220 fun empty_name_pool debug = if debug then SOME (`I Symtab.empty) else NONE
   221 
   222 fun pool_map f xs =
   223   fold (fn x => fn (ys, pool) => f x pool |>> (fn y => y :: ys)) xs o pair []
   224 
   225 fun add_nice_name full_name nice_prefix j the_pool =
   226   let
   227     val nice_name = nice_prefix ^ (if j = 0 then "" else "_" ^ Int.toString j)
   228   in
   229     case Symtab.lookup (snd the_pool) nice_name of
   230       SOME full_name' =>
   231       if full_name = full_name' then (nice_name, the_pool)
   232       else add_nice_name full_name nice_prefix (j + 1) the_pool
   233     | NONE =>
   234       (nice_name, (Symtab.update_new (full_name, nice_name) (fst the_pool),
   235                    Symtab.update_new (nice_name, full_name) (snd the_pool)))
   236   end
   237 
   238 fun translate_first_char f s =
   239   String.str (f (String.sub (s, 0))) ^ String.extract (s, 1, NONE)
   240 
   241 fun clean_short_name full_name s =
   242   let
   243     val s = s |> Long_Name.base_name
   244               |> fold remove_all ["\<^sub>", "\<^bsub>", "\<^esub>", "\<^isub>"]
   245     val s' = s |> explode |> rev |> dropwhile (curry (op =) "'")
   246     val s' =
   247       (s' |> rev
   248           |> implode
   249           |> String.translate
   250                  (fn c => if Char.isAlphaNum c then String.str c else ""))
   251       ^ replicate_string (String.size s - length s') "_"
   252     val s' =
   253       if s' = "" orelse not (Char.isAlpha (String.sub (s', 0))) then "X" ^ s'
   254       else s'
   255     val s' = if s' = "op" then full_name else s'
   256   in
   257     case (Char.isLower (String.sub (full_name, 0)),
   258           Char.isLower (String.sub (s', 0))) of
   259       (true, false) => translate_first_char Char.toLower s'
   260     | (false, true) => translate_first_char Char.toUpper s'
   261     | _ => s'
   262   end
   263 
   264 fun nice_name (full_name, _) NONE = (full_name, NONE)
   265   | nice_name (full_name, desired_name) (SOME the_pool) =
   266     case Symtab.lookup (fst the_pool) full_name of
   267       SOME nice_name => (nice_name, SOME the_pool)
   268     | NONE => add_nice_name full_name (clean_short_name full_name desired_name)
   269                             0 the_pool
   270               |> apsnd SOME
   271 
   272 (**** Definitions and functions for FOL clauses, for conversion to TPTP or DFG
   273       format ****)
   274 
   275 datatype kind = Axiom | Conjecture;
   276 
   277 type axiom_name = string;
   278 
   279 (**** Isabelle FOL clauses ****)
   280 
   281 datatype fol_type =
   282   TyVar of name |
   283   TyFree of name |
   284   TyConstr of name * fol_type list
   285 
   286 fun string_of_fol_type (TyVar (s, _)) = s
   287   | string_of_fol_type (TyFree (s, _)) = s
   288   | string_of_fol_type (TyConstr ((tcon, _), tps)) =
   289       tcon ^ (paren_pack (map string_of_fol_type tps));
   290 
   291 (*First string is the type class; the second is a TVar or TFfree*)
   292 datatype type_literal = LTVar of string * string | LTFree of string * string;
   293 
   294 exception CLAUSE of string * term;
   295 
   296 fun atomic_type (TFree (a,_)) = TyFree (`make_fixed_type_var a)
   297   | atomic_type (TVar (x, _)) =
   298     TyVar (make_schematic_type_var x, string_of_indexname x)
   299 
   300 (*Make literals for sorted type variables*)
   301 fun sorts_on_typs_aux (_, [])   = []
   302   | sorts_on_typs_aux ((x,i),  s::ss) =
   303       let val sorts = sorts_on_typs_aux ((x,i), ss)
   304       in
   305           if s = "HOL.type" then sorts
   306           else if i = ~1 then LTFree(make_type_class s, make_fixed_type_var x) :: sorts
   307           else LTVar(make_type_class s, make_schematic_type_var (x,i)) :: sorts
   308       end;
   309 
   310 fun sorts_on_typs (TFree (a,s)) = sorts_on_typs_aux ((a,~1),s)
   311   | sorts_on_typs (TVar (v,s))  = sorts_on_typs_aux (v,s);
   312 
   313 fun pred_of_sort (LTVar (s,ty)) = (s,1)
   314   | pred_of_sort (LTFree (s,ty)) = (s,1)
   315 
   316 (*Given a list of sorted type variables, return a list of type literals.*)
   317 fun add_typs Ts = List.foldl (uncurry (union (op =))) [] (map sorts_on_typs Ts);
   318 
   319 (*The correct treatment of TFrees like 'a in lemmas (axiom clauses) is not clear.
   320   * Ignoring them leads to unsound proofs, since we do nothing to ensure that 'a
   321     in a lemma has the same sort as 'a in the conjecture.
   322   * Deleting such clauses will lead to problems with locales in other use of local results
   323     where 'a is fixed. Probably we should delete clauses unless the sorts agree.
   324   * Currently we include a class constraint in the clause, exactly as with TVars.
   325 *)
   326 
   327 (** make axiom and conjecture clauses. **)
   328 
   329 fun get_tvar_strs [] = []
   330   | get_tvar_strs ((TVar (indx,s))::Ts) =
   331       insert (op =) (make_schematic_type_var indx) (get_tvar_strs Ts)
   332   | get_tvar_strs((TFree _)::Ts) = get_tvar_strs Ts
   333 
   334 
   335 
   336 (**** Isabelle arities ****)
   337 
   338 exception ARCLAUSE of string;
   339 
   340 datatype arLit = TConsLit of class * string * string list
   341                | TVarLit of class * string;
   342 
   343 datatype arity_clause =
   344          ArityClause of {axiom_name: axiom_name,
   345                          conclLit: arLit,
   346                          premLits: arLit list};
   347 
   348 
   349 fun gen_TVars 0 = []
   350   | gen_TVars n = ("T_" ^ Int.toString n) :: gen_TVars (n-1);
   351 
   352 fun pack_sort(_,[])  = []
   353   | pack_sort(tvar, "HOL.type"::srt) = pack_sort(tvar, srt)   (*IGNORE sort "type"*)
   354   | pack_sort(tvar, cls::srt) =  (cls, tvar) :: pack_sort(tvar, srt);
   355 
   356 (*Arity of type constructor tcon :: (arg1,...,argN)res*)
   357 fun make_axiom_arity_clause dfg (tcons, axiom_name, (cls,args)) =
   358    let val tvars = gen_TVars (length args)
   359        val tvars_srts = ListPair.zip (tvars,args)
   360    in
   361       ArityClause {axiom_name = axiom_name, 
   362                    conclLit = TConsLit (cls, make_fixed_type_const dfg tcons, tvars),
   363                    premLits = map TVarLit (union_all(map pack_sort tvars_srts))}
   364    end;
   365 
   366 
   367 (**** Isabelle class relations ****)
   368 
   369 datatype classrel_clause =
   370          ClassrelClause of {axiom_name: axiom_name,
   371                             subclass: class,
   372                             superclass: class};
   373 
   374 (*Generate all pairs (sub,super) such that sub is a proper subclass of super in theory thy.*)
   375 fun class_pairs thy [] supers = []
   376   | class_pairs thy subs supers =
   377       let val class_less = Sorts.class_less(Sign.classes_of thy)
   378           fun add_super sub (super,pairs) =
   379                 if class_less (sub,super) then (sub,super)::pairs else pairs
   380           fun add_supers (sub,pairs) = List.foldl (add_super sub) pairs supers
   381       in  List.foldl add_supers [] subs  end;
   382 
   383 fun make_classrel_clause (sub,super) =
   384   ClassrelClause {axiom_name = clrelclause_prefix ^ ascii_of sub ^ "_" ^ ascii_of super,
   385                   subclass = make_type_class sub,
   386                   superclass = make_type_class super};
   387 
   388 fun make_classrel_clauses thy subs supers =
   389   map make_classrel_clause (class_pairs thy subs supers);
   390 
   391 
   392 (** Isabelle arities **)
   393 
   394 fun arity_clause dfg _ _ (tcons, []) = []
   395   | arity_clause dfg seen n (tcons, ("HOL.type",_)::ars) =  (*ignore*)
   396       arity_clause dfg seen n (tcons,ars)
   397   | arity_clause dfg seen n (tcons, (ar as (class,_)) :: ars) =
   398       if class mem_string seen then (*multiple arities for the same tycon, class pair*)
   399           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class ^ "_" ^ Int.toString n, ar) ::
   400           arity_clause dfg seen (n+1) (tcons,ars)
   401       else
   402           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class, ar) ::
   403           arity_clause dfg (class::seen) n (tcons,ars)
   404 
   405 fun multi_arity_clause dfg [] = []
   406   | multi_arity_clause dfg ((tcons,ars) :: tc_arlists) =
   407       arity_clause dfg [] 1 (tcons, ars)  @  multi_arity_clause dfg tc_arlists
   408 
   409 (*Generate all pairs (tycon,class,sorts) such that tycon belongs to class in theory thy
   410   provided its arguments have the corresponding sorts.*)
   411 fun type_class_pairs thy tycons classes =
   412   let val alg = Sign.classes_of thy
   413       fun domain_sorts (tycon,class) = Sorts.mg_domain alg tycon [class]
   414       fun add_class tycon (class,pairs) =
   415             (class, domain_sorts(tycon,class))::pairs
   416             handle Sorts.CLASS_ERROR _ => pairs
   417       fun try_classes tycon = (tycon, List.foldl (add_class tycon) [] classes)
   418   in  map try_classes tycons  end;
   419 
   420 (*Proving one (tycon, class) membership may require proving others, so iterate.*)
   421 fun iter_type_class_pairs thy tycons [] = ([], [])
   422   | iter_type_class_pairs thy tycons classes =
   423       let val cpairs = type_class_pairs thy tycons classes
   424           val newclasses = union_all (union_all (union_all (map (map #2 o #2) cpairs)))
   425             |> subtract (op =) classes |> subtract (op =) HOLogic.typeS
   426           val (classes', cpairs') = iter_type_class_pairs thy tycons newclasses
   427       in (union (op =) classes' classes, union (op =) cpairs' cpairs) end;
   428 
   429 fun make_arity_clauses_dfg dfg thy tycons classes =
   430   let val (classes', cpairs) = iter_type_class_pairs thy tycons classes
   431   in  (classes', multi_arity_clause dfg cpairs)  end;
   432 val make_arity_clauses = make_arity_clauses_dfg false;
   433 
   434 (**** Find occurrences of predicates in clauses ****)
   435 
   436 (*FIXME: multiple-arity checking doesn't work, as update_new is the wrong
   437   function (it flags repeated declarations of a function, even with the same arity)*)
   438 
   439 fun update_many (tab, keypairs) = List.foldl (uncurry Symtab.update) tab keypairs;
   440 
   441 fun add_type_sort_preds (T, preds) =
   442       update_many (preds, map pred_of_sort (sorts_on_typs T));
   443 
   444 fun add_classrel_clause_preds (ClassrelClause {subclass,superclass,...}, preds) =
   445   Symtab.update (subclass,1) (Symtab.update (superclass,1) preds);
   446 
   447 fun class_of_arityLit (TConsLit (tclass, _, _)) = tclass
   448   | class_of_arityLit (TVarLit (tclass, _)) = tclass;
   449 
   450 fun add_arity_clause_preds (ArityClause {conclLit,premLits,...}, preds) =
   451   let val classes = map (make_type_class o class_of_arityLit) (conclLit::premLits)
   452       fun upd (class,preds) = Symtab.update (class,1) preds
   453   in  List.foldl upd preds classes  end;
   454 
   455 (*** Find occurrences of functions in clauses ***)
   456 
   457 fun add_foltype_funcs (TyVar _, funcs) = funcs
   458   | add_foltype_funcs (TyFree (s, _), funcs) = Symtab.update (s, 0) funcs
   459   | add_foltype_funcs (TyConstr ((s, _), tys), funcs) =
   460       List.foldl add_foltype_funcs (Symtab.update (s, length tys) funcs) tys;
   461 
   462 (*TFrees are recorded as constants*)
   463 fun add_type_sort_funcs (TVar _, funcs) = funcs
   464   | add_type_sort_funcs (TFree (a, _), funcs) =
   465       Symtab.update (make_fixed_type_var a, 0) funcs
   466 
   467 fun add_arity_clause_funcs (ArityClause {conclLit,...}, funcs) =
   468   let val TConsLit (_, tcons, tvars) = conclLit
   469   in  Symtab.update (tcons, length tvars) funcs  end;
   470 
   471 (*This type can be overlooked because it is built-in...*)
   472 val init_functab = Symtab.update ("tc_itself", 1) Symtab.empty;
   473 
   474 
   475 (**** String-oriented operations ****)
   476 
   477 fun string_of_clausename (cls_id,ax_name) =
   478     clause_prefix ^ ascii_of ax_name ^ "_" ^ Int.toString cls_id;
   479 
   480 fun string_of_type_clsname (cls_id,ax_name,idx) =
   481     string_of_clausename (cls_id,ax_name) ^ "_tcs" ^ (Int.toString idx);
   482 
   483 
   484 (**** Producing DFG files ****)
   485 
   486 (*Attach sign in DFG syntax: false means negate.*)
   487 fun dfg_sign true s = s
   488   | dfg_sign false s = "not(" ^ s ^ ")"
   489 
   490 fun dfg_of_typeLit pos (LTVar (s,ty))  = dfg_sign pos (s ^ "(" ^ ty ^ ")")
   491   | dfg_of_typeLit pos (LTFree (s,ty)) = dfg_sign pos (s ^ "(" ^ ty ^ ")");
   492 
   493 (*Enclose the clause body by quantifiers, if necessary*)
   494 fun dfg_forall [] body = body
   495   | dfg_forall vars body = "forall([" ^ commas vars ^ "],\n" ^ body ^ ")"
   496 
   497 fun gen_dfg_cls (cls_id, ax_name, Axiom, lits, tylits, vars) =
   498       "clause( %(axiom)\n" ^
   499       dfg_forall vars ("or(" ^ commas (tylits@lits) ^ ")") ^ ",\n" ^
   500       string_of_clausename (cls_id,ax_name) ^  ").\n\n"
   501   | gen_dfg_cls (cls_id, ax_name, Conjecture, lits, _, vars) =
   502       "clause( %(negated_conjecture)\n" ^
   503       dfg_forall vars ("or(" ^ commas lits ^ ")") ^ ",\n" ^
   504       string_of_clausename (cls_id,ax_name) ^  ").\n\n";
   505 
   506 fun string_of_arity (name, num) =  "(" ^ name ^ "," ^ Int.toString num ^ ")"
   507 
   508 fun string_of_preds [] = ""
   509   | string_of_preds preds = "predicates[" ^ commas(map string_of_arity preds) ^ "].\n";
   510 
   511 fun string_of_funcs [] = ""
   512   | string_of_funcs funcs = "functions[" ^ commas(map string_of_arity funcs) ^ "].\n" ;
   513 
   514 fun string_of_symbols predstr funcstr =
   515   "list_of_symbols.\n" ^ predstr  ^ funcstr  ^ "end_of_list.\n\n";
   516 
   517 fun string_of_start name = "begin_problem(" ^ name ^ ").\n\n";
   518 
   519 fun string_of_descrip name =
   520   "list_of_descriptions.\nname({*" ^ name ^
   521   "*}).\nauthor({*Isabelle*}).\nstatus(unknown).\ndescription({*auto-generated*}).\nend_of_list.\n\n"
   522 
   523 fun dfg_tfree_clause tfree_lit =
   524   "clause( %(negated_conjecture)\n" ^ "or( " ^ tfree_lit ^ "),\n" ^ "tfree_tcs" ^ ").\n\n"
   525 
   526 fun dfg_of_arLit (TConsLit (c,t,args)) =
   527       dfg_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   528   | dfg_of_arLit (TVarLit (c,str)) =
   529       dfg_sign false (make_type_class c ^ "(" ^ str ^ ")")
   530 
   531 fun dfg_classrelLits sub sup =  "not(" ^ sub ^ "(T)), " ^ sup ^ "(T)";
   532 
   533 fun dfg_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   534   "clause(forall([T],\nor( " ^ dfg_classrelLits subclass superclass ^ ")),\n" ^
   535   axiom_name ^ ").\n\n";
   536 
   537 fun string_of_ar axiom_name = arclause_prefix ^ ascii_of axiom_name;
   538 
   539 fun dfg_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   540   let val TConsLit (_,_,tvars) = conclLit
   541       val lits = map dfg_of_arLit (conclLit :: premLits)
   542   in
   543       "clause( %(axiom)\n" ^
   544       dfg_forall tvars ("or( " ^ commas lits ^ ")") ^ ",\n" ^
   545       string_of_ar axiom_name ^ ").\n\n"
   546   end;
   547 
   548 
   549 (**** Produce TPTP files ****)
   550 
   551 fun tptp_sign true s = s
   552   | tptp_sign false s = "~ " ^ s
   553 
   554 fun tptp_of_typeLit pos (LTVar (s, ty))  = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   555   | tptp_of_typeLit pos (LTFree (s, ty)) = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   556 
   557 fun tptp_cnf name kind formula =
   558   "cnf(" ^ name ^ ", " ^ kind ^ ",\n    " ^ formula ^ ").\n"
   559 
   560 fun gen_tptp_cls (cls_id, ax_name, Axiom, lits, tylits) =
   561       tptp_cnf (string_of_clausename (cls_id, ax_name)) "axiom"
   562                (tptp_pack (tylits @ lits))
   563   | gen_tptp_cls (cls_id, ax_name, Conjecture, lits, _) =
   564       tptp_cnf (string_of_clausename (cls_id, ax_name)) "negated_conjecture"
   565                (tptp_pack lits)
   566 
   567 fun tptp_tfree_clause tfree_lit =
   568     tptp_cnf "tfree_tcs" "negated_conjecture" (tptp_pack [tfree_lit])
   569 
   570 fun tptp_of_arLit (TConsLit (c,t,args)) =
   571       tptp_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   572   | tptp_of_arLit (TVarLit (c,str)) =
   573       tptp_sign false (make_type_class c ^ "(" ^ str ^ ")")
   574 
   575 fun tptp_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   576   tptp_cnf (string_of_ar axiom_name) "axiom"
   577            (tptp_pack (map tptp_of_arLit (conclLit :: premLits)))
   578 
   579 fun tptp_classrelLits sub sup =
   580   let val tvar = "(T)"
   581   in  tptp_pack [tptp_sign false (sub^tvar), tptp_sign true (sup^tvar)]  end;
   582 
   583 fun tptp_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   584   tptp_cnf axiom_name "axiom" (tptp_classrelLits subclass superclass)
   585 
   586 end;