src/Pure/Isar/expression.ML
author haftmann
Sat Nov 14 08:45:51 2015 +0100 (2015-11-14)
changeset 61669 27ca6147e3b3
parent 61336 fa4ebbd350ae
child 62752 d09d71223e7a
permissions -rw-r--r--
separate ML module for interpretation
     1 (*  Title:      Pure/Isar/expression.ML
     2     Author:     Clemens Ballarin, TU Muenchen
     3 
     4 Locale expressions and user interface layer of locales.
     5 *)
     6 
     7 signature EXPRESSION =
     8 sig
     9   (* Locale expressions *)
    10   datatype 'term map = Positional of 'term option list | Named of (string * 'term) list
    11   type ('name, 'term) expr = ('name * ((string * bool) * 'term map)) list
    12   type expression_i = (string, term) expr * (binding * typ option * mixfix) list
    13   type expression = (xstring * Position.T, string) expr * (binding * string option * mixfix) list
    14 
    15   (* Processing of context statements *)
    16   val cert_statement: Element.context_i list -> Element.statement_i ->
    17     Proof.context -> (Attrib.binding * (term * term list) list) list * Proof.context
    18   val read_statement: Element.context list -> Element.statement ->
    19     Proof.context -> (Attrib.binding * (term * term list) list) list * Proof.context
    20 
    21   (* Declaring locales *)
    22   val cert_declaration: expression_i -> (Proof.context -> Proof.context) ->
    23     Element.context_i list ->
    24     Proof.context -> (((string * typ) * mixfix) list * (string * morphism) list
    25       * Element.context_i list * Proof.context) * ((string * typ) list * Proof.context)
    26   val cert_read_declaration: expression_i -> (Proof.context -> Proof.context) ->
    27     Element.context list ->
    28     Proof.context -> (((string * typ) * mixfix) list * (string * morphism) list
    29       * Element.context_i list * Proof.context) * ((string * typ) list * Proof.context)
    30       (*FIXME*)
    31   val read_declaration: expression -> (Proof.context -> Proof.context) -> Element.context list ->
    32     Proof.context -> (((string * typ) * mixfix) list * (string * morphism) list
    33       * Element.context_i list * Proof.context) * ((string * typ) list * Proof.context)
    34   val add_locale: binding -> binding ->
    35     expression_i -> Element.context_i list -> theory -> string * local_theory
    36   val add_locale_cmd: binding -> binding ->
    37     expression -> Element.context list -> theory -> string * local_theory
    38 
    39   (* Processing of locale expressions *)
    40   val cert_goal_expression: expression_i -> Proof.context ->
    41     (term list list * (string * morphism) list * morphism) * Proof.context
    42   val read_goal_expression: expression -> Proof.context ->
    43     (term list list * (string * morphism) list * morphism) * Proof.context
    44 
    45   (* Diagnostic *)
    46   val print_dependencies: Proof.context -> bool -> expression -> unit
    47 end;
    48 
    49 structure Expression : EXPRESSION =
    50 struct
    51 
    52 datatype ctxt = datatype Element.ctxt;
    53 
    54 
    55 (*** Expressions ***)
    56 
    57 datatype 'term map =
    58   Positional of 'term option list |
    59   Named of (string * 'term) list;
    60 
    61 type ('name, 'term) expr = ('name * ((string * bool) * 'term map)) list;
    62 
    63 type expression_i = (string, term) expr * (binding * typ option * mixfix) list;
    64 type expression = (xstring * Position.T, string) expr * (binding * string option * mixfix) list;
    65 
    66 
    67 (** Internalise locale names in expr **)
    68 
    69 fun check_expr thy instances = map (apfst (Locale.check thy)) instances;
    70 
    71 
    72 (** Parameters of expression **)
    73 
    74 (*Sanity check of instantiations and extraction of implicit parameters.
    75   The latter only occurs iff strict = false.
    76   Positional instantiations are extended to match full length of parameter list
    77   of instantiated locale.*)
    78 
    79 fun parameters_of thy strict (expr, fixed) =
    80   let
    81     val ctxt = Proof_Context.init_global thy;
    82 
    83     fun reject_dups message xs =
    84       (case duplicates (op =) xs of
    85         [] => ()
    86       | dups => error (message ^ commas dups));
    87 
    88     fun parm_eq ((p1: string, mx1: mixfix), (p2, mx2)) = p1 = p2 andalso
    89       (mx1 = mx2 orelse error ("Conflicting syntax for parameter " ^ quote p1 ^ " in expression"));
    90 
    91     fun params_loc loc = Locale.params_of thy loc |> map (apfst #1);
    92     fun params_inst (loc, (prfx, Positional insts)) =
    93           let
    94             val ps = params_loc loc;
    95             val d = length ps - length insts;
    96             val insts' =
    97               if d < 0 then
    98                 error ("More arguments than parameters in instantiation of locale " ^
    99                   quote (Locale.markup_name ctxt loc))
   100               else insts @ replicate d NONE;
   101             val ps' = (ps ~~ insts') |>
   102               map_filter (fn (p, NONE) => SOME p | (_, SOME _) => NONE);
   103           in (ps', (loc, (prfx, Positional insts'))) end
   104       | params_inst (loc, (prfx, Named insts)) =
   105           let
   106             val _ =
   107               reject_dups "Duplicate instantiation of the following parameter(s): "
   108                 (map fst insts);
   109             val ps' = (insts, params_loc loc) |-> fold (fn (p, _) => fn ps =>
   110               if AList.defined (op =) ps p then AList.delete (op =) p ps
   111               else error (quote p ^ " not a parameter of instantiated expression"));
   112           in (ps', (loc, (prfx, Named insts))) end;
   113     fun params_expr is =
   114       let
   115         val (is', ps') = fold_map (fn i => fn ps =>
   116           let
   117             val (ps', i') = params_inst i;
   118             val ps'' = distinct parm_eq (ps @ ps');
   119           in (i', ps'') end) is []
   120       in (ps', is') end;
   121 
   122     val (implicit, expr') = params_expr expr;
   123 
   124     val implicit' = map #1 implicit;
   125     val fixed' = map (Variable.check_name o #1) fixed;
   126     val _ = reject_dups "Duplicate fixed parameter(s): " fixed';
   127     val implicit'' =
   128       if strict then []
   129       else
   130         let
   131           val _ =
   132             reject_dups
   133               "Parameter(s) declared simultaneously in expression and for clause: "
   134               (implicit' @ fixed');
   135         in map (fn (x, mx) => (Binding.name x, NONE, mx)) implicit end;
   136 
   137   in (expr', implicit'' @ fixed) end;
   138 
   139 
   140 (** Read instantiation **)
   141 
   142 (* Parse positional or named instantiation *)
   143 
   144 local
   145 
   146 fun prep_inst prep_term ctxt parms (Positional insts) =
   147       (insts ~~ parms) |> map
   148         (fn (NONE, p) => Free (p, dummyT)
   149           | (SOME t, _) => prep_term ctxt t)
   150   | prep_inst prep_term ctxt parms (Named insts) =
   151       parms |> map (fn p =>
   152         (case AList.lookup (op =) insts p of
   153           SOME t => prep_term ctxt t |
   154           NONE => Free (p, dummyT)));
   155 
   156 in
   157 
   158 fun parse_inst x = prep_inst Syntax.parse_term x;
   159 fun make_inst x = prep_inst (K I) x;
   160 
   161 end;
   162 
   163 
   164 (* Instantiation morphism *)
   165 
   166 fun inst_morphism (parm_names, parm_types) ((prfx, mandatory), insts') ctxt =
   167   let
   168     (* parameters *)
   169     val type_parm_names = fold Term.add_tfreesT parm_types [] |> map fst;
   170 
   171     (* type inference and contexts *)
   172     val parm_types' = map (Type_Infer.paramify_vars o Logic.varifyT_global) parm_types;
   173     val type_parms = fold Term.add_tvarsT parm_types' [] |> map (Logic.mk_type o TVar);
   174     val arg = type_parms @ map2 Type.constraint parm_types' insts';
   175     val res = Syntax.check_terms ctxt arg;
   176     val ctxt' = ctxt |> fold Variable.auto_fixes res;
   177 
   178     (* instantiation *)
   179     val (type_parms'', res') = chop (length type_parms) res;
   180     val insts'' = (parm_names ~~ res') |> map_filter
   181       (fn inst as (x, Free (y, _)) => if x = y then NONE else SOME inst
   182         | inst => SOME inst);
   183     val instT = Symtab.make (type_parm_names ~~ map Logic.dest_type type_parms'');
   184     val inst = Symtab.make insts'';
   185   in
   186     (Element.inst_morphism (Proof_Context.theory_of ctxt) (instT, inst) $>
   187       Morphism.binding_morphism "Expression.inst" (Binding.prefix mandatory prfx), ctxt')
   188   end;
   189 
   190 
   191 (*** Locale processing ***)
   192 
   193 (** Parsing **)
   194 
   195 fun parse_elem prep_typ prep_term ctxt =
   196   Element.map_ctxt
   197    {binding = I,
   198     typ = prep_typ ctxt,
   199     term = prep_term (Proof_Context.set_mode Proof_Context.mode_schematic ctxt),
   200     pattern = prep_term (Proof_Context.set_mode Proof_Context.mode_pattern ctxt),
   201     fact = I,
   202     attrib = I};
   203 
   204 fun prepare_stmt prep_prop prep_obtains ctxt stmt =
   205   (case stmt of
   206     Element.Shows raw_shows =>
   207       raw_shows |> (map o apsnd o map) (fn (t, ps) =>
   208         (prep_prop (Proof_Context.set_mode Proof_Context.mode_schematic ctxt) t,
   209           map (prep_prop (Proof_Context.set_mode Proof_Context.mode_pattern ctxt)) ps))
   210   | Element.Obtains raw_obtains =>
   211       let
   212         val ((_, thesis), thesis_ctxt) = Obtain.obtain_thesis ctxt;
   213         val obtains = prep_obtains thesis_ctxt thesis raw_obtains;
   214       in map (fn (b, t) => ((b, []), [(t, [])])) obtains end);
   215 
   216 
   217 (** Simultaneous type inference: instantiations + elements + statement **)
   218 
   219 local
   220 
   221 fun mk_type T = (Logic.mk_type T, []);
   222 fun mk_term t = (t, []);
   223 fun mk_propp (p, pats) = (Type.constraint propT p, pats);
   224 
   225 fun dest_type (T, []) = Logic.dest_type T;
   226 fun dest_term (t, []) = t;
   227 fun dest_propp (p, pats) = (p, pats);
   228 
   229 fun extract_inst (_, (_, ts)) = map mk_term ts;
   230 fun restore_inst ((l, (p, _)), cs) = (l, (p, map dest_term cs));
   231 
   232 fun extract_elem (Fixes fixes) = map (#2 #> the_list #> map mk_type) fixes
   233   | extract_elem (Constrains csts) = map (#2 #> single #> map mk_type) csts
   234   | extract_elem (Assumes asms) = map (#2 #> map mk_propp) asms
   235   | extract_elem (Defines defs) = map (fn (_, (t, ps)) => [mk_propp (t, ps)]) defs
   236   | extract_elem (Notes _) = [];
   237 
   238 fun restore_elem (Fixes fixes, css) =
   239       (fixes ~~ css) |> map (fn ((x, _, mx), cs) =>
   240         (x, cs |> map dest_type |> try hd, mx)) |> Fixes
   241   | restore_elem (Constrains csts, css) =
   242       (csts ~~ css) |> map (fn ((x, _), cs) =>
   243         (x, cs |> map dest_type |> hd)) |> Constrains
   244   | restore_elem (Assumes asms, css) =
   245       (asms ~~ css) |> map (fn ((b, _), cs) => (b, map dest_propp cs)) |> Assumes
   246   | restore_elem (Defines defs, css) =
   247       (defs ~~ css) |> map (fn ((b, _), [c]) => (b, dest_propp c)) |> Defines
   248   | restore_elem (Notes notes, _) = Notes notes;
   249 
   250 fun check cs context =
   251   let
   252     fun prep (_, pats) (ctxt, t :: ts) =
   253       let val ctxt' = Variable.auto_fixes t ctxt
   254       in
   255         ((t, Syntax.check_props (Proof_Context.set_mode Proof_Context.mode_pattern ctxt') pats),
   256           (ctxt', ts))
   257       end;
   258     val (cs', (context', _)) = fold_map prep cs
   259       (context, Syntax.check_terms
   260         (Proof_Context.set_mode Proof_Context.mode_schematic context) (map fst cs));
   261   in (cs', context') end;
   262 
   263 in
   264 
   265 fun check_autofix insts elems concl ctxt =
   266   let
   267     val inst_cs = map extract_inst insts;
   268     val elem_css = map extract_elem elems;
   269     val concl_cs = (map o map) mk_propp (map snd concl);
   270     (* Type inference *)
   271     val (inst_cs' :: css', ctxt') =
   272       (fold_burrow o fold_burrow) check (inst_cs :: elem_css @ [concl_cs]) ctxt;
   273     val (elem_css', [concl_cs']) = chop (length elem_css) css';
   274   in
   275     ((map restore_inst (insts ~~ inst_cs'),
   276       map restore_elem (elems ~~ elem_css'),
   277       map fst concl ~~ concl_cs'), ctxt')
   278   end;
   279 
   280 end;
   281 
   282 
   283 (** Prepare locale elements **)
   284 
   285 fun declare_elem prep_var (Fixes fixes) ctxt =
   286       let val (vars, _) = fold_map prep_var fixes ctxt
   287       in ctxt |> Proof_Context.add_fixes vars |> snd end
   288   | declare_elem prep_var (Constrains csts) ctxt =
   289       ctxt |> fold_map (fn (x, T) => prep_var (Binding.name x, SOME T, NoSyn)) csts |> snd
   290   | declare_elem _ (Assumes _) ctxt = ctxt
   291   | declare_elem _ (Defines _) ctxt = ctxt
   292   | declare_elem _ (Notes _) ctxt = ctxt;
   293 
   294 
   295 (** Finish locale elements **)
   296 
   297 fun finish_inst ctxt (loc, (prfx, inst)) =
   298   let
   299     val thy = Proof_Context.theory_of ctxt;
   300     val (parm_names, parm_types) = Locale.params_of thy loc |> map #1 |> split_list;
   301     val (morph, _) = inst_morphism (parm_names, parm_types) (prfx, inst) ctxt;
   302   in (loc, morph) end;
   303 
   304 fun finish_fixes (parms: (string * typ) list) = map (fn (binding, _, mx) =>
   305   let val x = Binding.name_of binding
   306   in (binding, AList.lookup (op =) parms x, mx) end);
   307 
   308 local
   309 
   310 fun closeup _ _ false elem = elem
   311   | closeup (outer_ctxt, ctxt) parms true elem =
   312       let
   313         (* FIXME consider closing in syntactic phase -- before type checking *)
   314         fun close_frees t =
   315           let
   316             val rev_frees =
   317               Term.fold_aterms (fn Free (x, T) =>
   318                 if Variable.is_fixed outer_ctxt x orelse AList.defined (op =) parms x then I
   319                 else insert (op =) (x, T) | _ => I) t [];
   320           in fold (Logic.all o Free) rev_frees t end;
   321 
   322         fun no_binds [] = []
   323           | no_binds _ = error "Illegal term bindings in context element";
   324       in
   325         (case elem of
   326           Assumes asms => Assumes (asms |> map (fn (a, propps) =>
   327             (a, map (fn (t, ps) => (close_frees t, no_binds ps)) propps)))
   328         | Defines defs => Defines (defs |> map (fn ((name, atts), (t, ps)) =>
   329             let val ((c, _), t') = Local_Defs.cert_def ctxt (close_frees t)
   330             in ((Thm.def_binding_optional (Binding.name c) name, atts), (t', no_binds ps)) end))
   331         | e => e)
   332       end;
   333 
   334 in
   335 
   336 fun finish_elem _ parms _ (Fixes fixes) = Fixes (finish_fixes parms fixes)
   337   | finish_elem _ _ _ (Constrains _) = Constrains []
   338   | finish_elem ctxts parms do_close (Assumes asms) = closeup ctxts parms do_close (Assumes asms)
   339   | finish_elem ctxts parms do_close (Defines defs) = closeup ctxts parms do_close (Defines defs)
   340   | finish_elem _ _ _ (Notes facts) = Notes facts;
   341 
   342 end;
   343 
   344 
   345 (** Process full context statement: instantiations + elements + statement **)
   346 
   347 (* Interleave incremental parsing and type inference over entire parsed stretch. *)
   348 
   349 local
   350 
   351 fun prep_full_context_statement
   352     parse_typ parse_prop prep_obtains prep_var_elem prep_inst prep_var_inst prep_expr
   353     {strict, do_close, fixed_frees} raw_import init_body raw_elems raw_stmt ctxt1 =
   354   let
   355     val thy = Proof_Context.theory_of ctxt1;
   356 
   357     val (raw_insts, fixed) = parameters_of thy strict (apfst (prep_expr thy) raw_import);
   358 
   359     fun prep_insts_cumulative (loc, (prfx, inst)) (i, insts, ctxt) =
   360       let
   361         val (parm_names, parm_types) = Locale.params_of thy loc |> map #1 |> split_list;
   362         val inst' = prep_inst ctxt parm_names inst;
   363         val parm_types' = parm_types
   364           |> map (Type_Infer.paramify_vars o
   365               Term.map_type_tvar (fn ((x, _), S) => TVar ((x, i), S)) o Logic.varifyT_global);
   366         val inst'' = map2 Type.constraint parm_types' inst';
   367         val insts' = insts @ [(loc, (prfx, inst''))];
   368         val ((insts'', _, _), _) = check_autofix insts' [] [] ctxt;
   369         val inst''' = insts'' |> List.last |> snd |> snd;
   370         val (morph, _) = inst_morphism (parm_names, parm_types) (prfx, inst''') ctxt;
   371         val ctxt'' = Locale.activate_declarations (loc, morph) ctxt;
   372       in (i + 1, insts', ctxt'') end;
   373 
   374     fun prep_elem raw_elem ctxt =
   375       let
   376         val ctxt' = ctxt
   377           |> Context_Position.set_visible false
   378           |> declare_elem prep_var_elem raw_elem
   379           |> Context_Position.restore_visible ctxt;
   380         val elems' = parse_elem parse_typ parse_prop ctxt' raw_elem;
   381       in (elems', ctxt') end;
   382 
   383     val fors = fold_map prep_var_inst fixed ctxt1 |> fst;
   384     val ctxt2 = ctxt1 |> Proof_Context.add_fixes fors |> snd;
   385     val (_, insts', ctxt3) = fold prep_insts_cumulative raw_insts (0, [], ctxt2);
   386 
   387     fun prep_stmt elems ctxt =
   388       check_autofix insts' elems (prepare_stmt parse_prop prep_obtains ctxt raw_stmt) ctxt;
   389 
   390     val _ =
   391       if fixed_frees then ()
   392       else
   393         (case fold (fold (Variable.add_frees ctxt3) o snd o snd) insts' [] of
   394           [] => ()
   395         | frees => error ("Illegal free variables in expression: " ^
   396             commas_quote (map (Syntax.string_of_term ctxt3 o Free) (rev frees))));
   397 
   398     val ((insts, elems', concl), ctxt4) = ctxt3
   399       |> init_body
   400       |> fold_map prep_elem raw_elems
   401       |-> prep_stmt;
   402 
   403 
   404     (* parameters from expression and elements *)
   405 
   406     val xs = maps (fn Fixes fixes => map (Variable.check_name o #1) fixes | _ => [])
   407       (Fixes fors :: elems');
   408     val (parms, ctxt5) = fold_map Proof_Context.inferred_param xs ctxt4;
   409 
   410     val fors' = finish_fixes parms fors;
   411     val fixed = map (fn (b, SOME T, mx) => ((Binding.name_of b, T), mx)) fors';
   412     val deps = map (finish_inst ctxt5) insts;
   413     val elems'' = map (finish_elem (ctxt1, ctxt5) parms do_close) elems';
   414 
   415   in ((fixed, deps, elems'', concl), (parms, ctxt5)) end;
   416 
   417 in
   418 
   419 fun cert_full_context_statement x =
   420   prep_full_context_statement (K I) (K I) Obtain.cert_obtains
   421     Proof_Context.cert_var make_inst Proof_Context.cert_var (K I) x;
   422 
   423 fun cert_read_full_context_statement x =
   424   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop Obtain.parse_obtains
   425     Proof_Context.read_var make_inst Proof_Context.cert_var (K I) x;
   426 
   427 fun read_full_context_statement x =
   428   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop Obtain.parse_obtains
   429     Proof_Context.read_var parse_inst Proof_Context.read_var check_expr x;
   430 
   431 end;
   432 
   433 
   434 (* Context statement: elements + statement *)
   435 
   436 local
   437 
   438 fun prep_statement prep activate raw_elems raw_stmt context =
   439   let
   440     val ((_, _, elems, concl), _) =
   441       prep {strict = true, do_close = false, fixed_frees = true}
   442         ([], []) I raw_elems raw_stmt context;
   443     val (_, context') = context
   444       |> Proof_Context.set_stmt true
   445       |> fold_map activate elems;
   446   in (concl, context') end;
   447 
   448 in
   449 
   450 fun cert_statement x = prep_statement cert_full_context_statement Element.activate_i x;
   451 fun read_statement x = prep_statement read_full_context_statement Element.activate x;
   452 
   453 end;
   454 
   455 
   456 (* Locale declaration: import + elements *)
   457 
   458 fun fix_params params =
   459   Proof_Context.add_fixes (map (fn ((x, T), mx) => (Binding.name x, SOME T, mx)) params) #> snd;
   460 
   461 local
   462 
   463 fun prep_declaration prep activate raw_import init_body raw_elems context =
   464   let
   465     val ((fixed, deps, elems, _), (parms, ctxt')) =
   466       prep {strict = false, do_close = true, fixed_frees = false}
   467         raw_import init_body raw_elems (Element.Shows []) context;
   468     (* Declare parameters and imported facts *)
   469     val context' = context |>
   470       fix_params fixed |>
   471       fold (Context.proof_map o Locale.activate_facts NONE) deps;
   472     val (elems', context'') = context' |>
   473       Proof_Context.set_stmt true |>
   474       fold_map activate elems;
   475   in ((fixed, deps, elems', context''), (parms, ctxt')) end;
   476 
   477 in
   478 
   479 fun cert_declaration x = prep_declaration cert_full_context_statement Element.activate_i x;
   480 fun cert_read_declaration x = prep_declaration cert_read_full_context_statement Element.activate x;
   481 fun read_declaration x = prep_declaration read_full_context_statement Element.activate x;
   482 
   483 end;
   484 
   485 
   486 (* Locale expression to set up a goal *)
   487 
   488 local
   489 
   490 fun props_of thy (name, morph) =
   491   let
   492     val (asm, defs) = Locale.specification_of thy name;
   493   in
   494     (case asm of NONE => defs | SOME asm => asm :: defs)
   495     |> map (Morphism.term morph)
   496   end;
   497 
   498 fun prep_goal_expression prep expression context =
   499   let
   500     val thy = Proof_Context.theory_of context;
   501 
   502     val ((fixed, deps, _, _), _) =
   503       prep {strict = true, do_close = true, fixed_frees = true} expression I []
   504         (Element.Shows []) context;
   505     (* proof obligations *)
   506     val propss = map (props_of thy) deps;
   507 
   508     val goal_ctxt = context |>
   509       fix_params fixed |>
   510       (fold o fold) Variable.auto_fixes propss;
   511 
   512     val export = Variable.export_morphism goal_ctxt context;
   513     val exp_fact = Drule.zero_var_indexes_list o map Thm.strip_shyps o Morphism.fact export;
   514     val exp_term = Term_Subst.zero_var_indexes o Morphism.term export;
   515     val exp_typ = Logic.type_map exp_term;
   516     val export' =
   517       Morphism.morphism "Expression.prep_goal"
   518         {binding = [], typ = [exp_typ], term = [exp_term], fact = [exp_fact]};
   519   in ((propss, deps, export'), goal_ctxt) end;
   520 
   521 in
   522 
   523 fun cert_goal_expression x = prep_goal_expression cert_full_context_statement x;
   524 fun read_goal_expression x = prep_goal_expression read_full_context_statement x;
   525 
   526 end;
   527 
   528 
   529 (*** Locale declarations ***)
   530 
   531 (* extract specification text *)
   532 
   533 val norm_term = Envir.beta_norm oo Term.subst_atomic;
   534 
   535 fun bind_def ctxt eq (xs, env, eqs) =
   536   let
   537     val _ = Local_Defs.cert_def ctxt eq;
   538     val ((y, T), b) = Local_Defs.abs_def eq;
   539     val b' = norm_term env b;
   540     fun err msg = error (msg ^ ": " ^ quote y);
   541   in
   542     (case filter (fn (Free (y', _), _) => y = y' | _ => false) env of
   543       [] => (Term.add_frees b' xs, (Free (y, T), b') :: env, eq :: eqs)
   544     | dups =>
   545         if forall (fn (_, b'') => b' aconv b'') dups then (xs, env, eqs)
   546         else err "Attempt to redefine variable")
   547   end;
   548 
   549 (* text has the following structure:
   550        (((exts, exts'), (ints, ints')), (xs, env, defs))
   551    where
   552      exts: external assumptions (terms in assumes elements)
   553      exts': dito, normalised wrt. env
   554      ints: internal assumptions (terms in assumptions from insts)
   555      ints': dito, normalised wrt. env
   556      xs: the free variables in exts' and ints' and rhss of definitions,
   557        this includes parameters except defined parameters
   558      env: list of term pairs encoding substitutions, where the first term
   559        is a free variable; substitutions represent defines elements and
   560        the rhs is normalised wrt. the previous env
   561      defs: the equations from the defines elements
   562    *)
   563 
   564 fun eval_text _ _ (Fixes _) text = text
   565   | eval_text _ _ (Constrains _) text = text
   566   | eval_text _ is_ext (Assumes asms)
   567         (((exts, exts'), (ints, ints')), (xs, env, defs)) =
   568       let
   569         val ts = maps (map #1 o #2) asms;
   570         val ts' = map (norm_term env) ts;
   571         val spec' =
   572           if is_ext then ((exts @ ts, exts' @ ts'), (ints, ints'))
   573           else ((exts, exts'), (ints @ ts, ints' @ ts'));
   574       in (spec', (fold Term.add_frees ts' xs, env, defs)) end
   575   | eval_text ctxt _ (Defines defs) (spec, binds) =
   576       (spec, fold (bind_def ctxt o #1 o #2) defs binds)
   577   | eval_text _ _ (Notes _) text = text;
   578 
   579 fun eval_inst ctxt (loc, morph) text =
   580   let
   581     val thy = Proof_Context.theory_of ctxt;
   582     val (asm, defs) = Locale.specification_of thy loc;
   583     val asm' = Option.map (Morphism.term morph) asm;
   584     val defs' = map (Morphism.term morph) defs;
   585     val text' =
   586       text |>
   587        (if is_some asm then
   588           eval_text ctxt false (Assumes [(Attrib.empty_binding, [(the asm', [])])])
   589         else I) |>
   590        (if not (null defs) then
   591           eval_text ctxt false (Defines (map (fn def => (Attrib.empty_binding, (def, []))) defs'))
   592         else I)
   593 (* FIXME clone from locale.ML *)
   594   in text' end;
   595 
   596 fun eval_elem ctxt elem text =
   597   eval_text ctxt true elem text;
   598 
   599 fun eval ctxt deps elems =
   600   let
   601     val text' = fold (eval_inst ctxt) deps ((([], []), ([], [])), ([], [], []));
   602     val ((spec, (_, _, defs))) = fold (eval_elem ctxt) elems text';
   603   in (spec, defs) end;
   604 
   605 (* axiomsN: name of theorem set with destruct rules for locale predicates,
   606      also name suffix of delta predicates and assumptions. *)
   607 
   608 val axiomsN = "axioms";
   609 
   610 local
   611 
   612 (* introN: name of theorems for introduction rules of locale and
   613      delta predicates *)
   614 
   615 val introN = "intro";
   616 
   617 fun atomize_spec ctxt ts =
   618   let
   619     val t = Logic.mk_conjunction_balanced ts;
   620     val body = Object_Logic.atomize_term ctxt t;
   621     val bodyT = Term.fastype_of body;
   622   in
   623     if bodyT = propT
   624     then (t, propT, Thm.reflexive (Thm.cterm_of ctxt t))
   625     else (body, bodyT, Object_Logic.atomize ctxt (Thm.cterm_of ctxt t))
   626   end;
   627 
   628 (* achieve plain syntax for locale predicates (without "PROP") *)
   629 
   630 fun aprop_tr' n c =
   631   let
   632     val c' = Lexicon.mark_const c;
   633     fun tr' (_: Proof.context) T args =
   634       if T <> dummyT andalso length args = n
   635       then Syntax.const "_aprop" $ Term.list_comb (Syntax.const c', args)
   636       else raise Match;
   637   in (c', tr') end;
   638 
   639 (* define one predicate including its intro rule and axioms
   640    - binding: predicate name
   641    - parms: locale parameters
   642    - defs: thms representing substitutions from defines elements
   643    - ts: terms representing locale assumptions (not normalised wrt. defs)
   644    - norm_ts: terms representing locale assumptions (normalised wrt. defs)
   645    - thy: the theory
   646 *)
   647 
   648 fun def_pred binding parms defs ts norm_ts thy =
   649   let
   650     val name = Sign.full_name thy binding;
   651 
   652     val thy_ctxt = Proof_Context.init_global thy;
   653 
   654     val (body, bodyT, body_eq) = atomize_spec thy_ctxt norm_ts;
   655     val env = Term.add_free_names body [];
   656     val xs = filter (member (op =) env o #1) parms;
   657     val Ts = map #2 xs;
   658     val extraTs =
   659       (subtract (op =) (fold Term.add_tfreesT Ts []) (Term.add_tfrees body []))
   660       |> sort_by #1 |> map TFree;
   661     val predT = map Term.itselfT extraTs ---> Ts ---> bodyT;
   662 
   663     val args = map Logic.mk_type extraTs @ map Free xs;
   664     val head = Term.list_comb (Const (name, predT), args);
   665     val statement = Object_Logic.ensure_propT thy_ctxt head;
   666 
   667     val ([pred_def], defs_thy) =
   668       thy
   669       |> bodyT = propT ? Sign.typed_print_translation [aprop_tr' (length args) name]
   670       |> Sign.declare_const_global ((binding, predT), NoSyn) |> snd
   671       |> Global_Theory.add_defs false [((Thm.def_binding binding, Logic.mk_equals (head, body)), [])];
   672     val defs_ctxt = Proof_Context.init_global defs_thy |> Variable.declare_term head;
   673 
   674     val intro = Goal.prove_global defs_thy [] norm_ts statement
   675       (fn {context = ctxt, ...} =>
   676         rewrite_goals_tac ctxt [pred_def] THEN
   677         compose_tac defs_ctxt (false, body_eq RS Drule.equal_elim_rule1, 1) 1 THEN
   678         compose_tac defs_ctxt
   679           (false,
   680             Conjunction.intr_balanced (map (Thm.assume o Thm.cterm_of defs_ctxt) norm_ts), 0) 1);
   681 
   682     val conjuncts =
   683       (Drule.equal_elim_rule2 OF
   684         [body_eq, rewrite_rule defs_ctxt [pred_def] (Thm.assume (Thm.cterm_of defs_ctxt statement))])
   685       |> Conjunction.elim_balanced (length ts);
   686 
   687     val (_, axioms_ctxt) = defs_ctxt
   688       |> Assumption.add_assumes (maps Thm.chyps_of (defs @ conjuncts));
   689     val axioms = ts ~~ conjuncts |> map (fn (t, ax) =>
   690       Element.prove_witness axioms_ctxt t
   691        (rewrite_goals_tac axioms_ctxt defs THEN compose_tac axioms_ctxt (false, ax, 0) 1));
   692   in ((statement, intro, axioms), defs_thy) end;
   693 
   694 in
   695 
   696 (* main predicate definition function *)
   697 
   698 fun define_preds binding parms (((exts, exts'), (ints, ints')), defs) thy =
   699   let
   700     val ctxt = Proof_Context.init_global thy;
   701     val defs' = map (Thm.cterm_of ctxt #> Assumption.assume ctxt #> Drule.abs_def) defs;
   702 
   703     val (a_pred, a_intro, a_axioms, thy'') =
   704       if null exts then (NONE, NONE, [], thy)
   705       else
   706         let
   707           val abinding =
   708             if null ints then binding else Binding.suffix_name ("_" ^ axiomsN) binding;
   709           val ((statement, intro, axioms), thy') =
   710             thy
   711             |> def_pred abinding parms defs' exts exts';
   712           val (_, thy'') =
   713             thy'
   714             |> Sign.qualified_path true abinding
   715             |> Global_Theory.note_thmss ""
   716               [((Binding.name introN, []), [([intro], [Locale.unfold_add])])]
   717             ||> Sign.restore_naming thy';
   718           in (SOME statement, SOME intro, axioms, thy'') end;
   719     val (b_pred, b_intro, b_axioms, thy'''') =
   720       if null ints then (NONE, NONE, [], thy'')
   721       else
   722         let
   723           val ((statement, intro, axioms), thy''') =
   724             thy''
   725             |> def_pred binding parms defs' (ints @ the_list a_pred) (ints' @ the_list a_pred);
   726           val ctxt''' = Proof_Context.init_global thy''';
   727           val (_, thy'''') =
   728             thy'''
   729             |> Sign.qualified_path true binding
   730             |> Global_Theory.note_thmss ""
   731                  [((Binding.name introN, []), [([intro], [Locale.intro_add])]),
   732                   ((Binding.name axiomsN, []),
   733                     [(map (Drule.export_without_context o Element.conclude_witness ctxt''') axioms,
   734                       [])])]
   735             ||> Sign.restore_naming thy''';
   736         in (SOME statement, SOME intro, axioms, thy'''') end;
   737   in ((a_pred, a_intro, a_axioms), (b_pred, b_intro, b_axioms), thy'''') end;
   738 
   739 end;
   740 
   741 
   742 local
   743 
   744 fun assumes_to_notes (Assumes asms) axms =
   745       fold_map (fn (a, spec) => fn axs =>
   746           let val (ps, qs) = chop (length spec) axs
   747           in ((a, [(ps, [])]), qs) end) asms axms
   748       |> apfst (curry Notes "")
   749   | assumes_to_notes e axms = (e, axms);
   750 
   751 fun defines_to_notes ctxt (Defines defs) =
   752       Notes ("", map (fn (a, (def, _)) =>
   753         (a, [([Assumption.assume ctxt (Thm.cterm_of ctxt def)],
   754           [(Attrib.internal o K) Locale.witness_add])])) defs)
   755   | defines_to_notes _ e = e;
   756 
   757 fun is_hyp (elem as Assumes asms) = true
   758   | is_hyp (elem as Defines defs) = true
   759   | is_hyp _ = false;
   760 
   761 fun gen_add_locale prep_decl
   762     binding raw_predicate_binding raw_import raw_body thy =
   763   let
   764     val name = Sign.full_name thy binding;
   765     val _ = Locale.defined thy name andalso
   766       error ("Duplicate definition of locale " ^ quote name);
   767 
   768     val ((fixed, deps, body_elems, _), (parms, ctxt')) =
   769       prep_decl raw_import I raw_body (Proof_Context.init_global thy);
   770     val text as (((_, exts'), _), defs) = eval ctxt' deps body_elems;
   771 
   772     val extraTs =
   773       subtract (op =)
   774         (fold Term.add_tfreesT (map snd parms) [])
   775         (fold Term.add_tfrees exts' []);
   776     val _ =
   777       if null extraTs then ()
   778       else warning ("Additional type variable(s) in locale specification " ^
   779           Binding.print binding ^ ": " ^
   780           commas (map (Syntax.string_of_typ ctxt' o TFree) (sort_by #1 extraTs)));
   781 
   782     val predicate_binding =
   783       if Binding.is_empty raw_predicate_binding then binding
   784       else raw_predicate_binding;
   785     val ((a_statement, a_intro, a_axioms), (b_statement, b_intro, b_axioms), thy') =
   786       define_preds predicate_binding parms text thy;
   787     val pred_ctxt = Proof_Context.init_global thy';
   788 
   789     val a_satisfy = Element.satisfy_morphism a_axioms;
   790     val b_satisfy = Element.satisfy_morphism b_axioms;
   791 
   792     val params = fixed @
   793       maps (fn Fixes fixes =>
   794         map (fn (b, SOME T, mx) => ((Binding.name_of b, T), mx)) fixes | _ => []) body_elems;
   795     val asm = if is_some b_statement then b_statement else a_statement;
   796 
   797     val hyp_spec = filter is_hyp body_elems;
   798 
   799     val notes =
   800       if is_some asm then
   801         [("", [((Binding.suffix_name ("_" ^ axiomsN) binding, []),
   802           [([Assumption.assume pred_ctxt (Thm.cterm_of pred_ctxt (the asm))],
   803             [(Attrib.internal o K) Locale.witness_add])])])]
   804       else [];
   805 
   806     val notes' =
   807       body_elems
   808       |> map (defines_to_notes pred_ctxt)
   809       |> map (Element.transform_ctxt a_satisfy)
   810       |> (fn elems =>
   811         fold_map assumes_to_notes elems (map (Element.conclude_witness pred_ctxt) a_axioms))
   812       |> fst
   813       |> map (Element.transform_ctxt b_satisfy)
   814       |> map_filter (fn Notes notes => SOME notes | _ => NONE);
   815 
   816     val deps' = map (fn (l, morph) => (l, morph $> b_satisfy)) deps;
   817     val axioms = map (Element.conclude_witness pred_ctxt) b_axioms;
   818 
   819     val loc_ctxt = thy'
   820       |> Locale.register_locale binding (extraTs, params)
   821           (asm, rev defs) (a_intro, b_intro) axioms hyp_spec [] (rev notes) (rev deps')
   822       |> Named_Target.init name
   823       |> fold (fn (kind, facts) => Local_Theory.notes_kind kind facts #> snd) notes';
   824 
   825   in (name, loc_ctxt) end;
   826 
   827 in
   828 
   829 val add_locale = gen_add_locale cert_declaration;
   830 val add_locale_cmd = gen_add_locale read_declaration;
   831 
   832 end;
   833 
   834 
   835 (** Print the instances that would be activated by an interpretation
   836   of the expression in the current context (clean = false) or in an
   837   empty context (clean = true). **)
   838 
   839 fun print_dependencies ctxt clean expression =
   840   let
   841     val ((_, deps, export), expr_ctxt) = read_goal_expression expression ctxt;
   842     val export' = if clean then Morphism.identity else export;
   843   in
   844     Locale.print_dependencies expr_ctxt clean export' deps
   845   end;
   846 
   847 end;