src/Pure/Thy/export_theory.ML
author wenzelm
Sun Sep 30 11:58:59 2018 +0200 (12 months ago)
changeset 69086 2859dcdbc849
parent 69083 6f8ae6ddc26b
child 69087 06017b2c4552
permissions -rw-r--r--
obsolete (see 6f8ae6ddc26b);
     1 (*  Title:      Pure/Thy/export_theory.ML
     2     Author:     Makarius
     3 
     4 Export foundational theory content and locale/class structure.
     5 *)
     6 
     7 signature EXPORT_THEORY =
     8 sig
     9   val setup_presentation: (Thy_Info.presentation_context -> theory -> unit) -> unit
    10   val export_body: theory -> string -> XML.body -> unit
    11 end;
    12 
    13 structure Export_Theory: EXPORT_THEORY =
    14 struct
    15 
    16 (* approximative syntax *)
    17 
    18 val get_syntax = Syntax.get_approx o Proof_Context.syn_of;
    19 fun get_syntax_type ctxt = get_syntax ctxt o Lexicon.mark_type;
    20 fun get_syntax_const ctxt = get_syntax ctxt o Lexicon.mark_const;
    21 fun get_syntax_fixed ctxt = get_syntax ctxt o Lexicon.mark_fixed;
    22 
    23 fun get_syntax_param ctxt loc x =
    24   let val thy = Proof_Context.theory_of ctxt in
    25     if Class.is_class thy loc then
    26       (case AList.lookup (op =) (Class.these_params thy [loc]) x of
    27         NONE => NONE
    28       | SOME (_, (c, _)) => get_syntax_const ctxt c)
    29     else get_syntax_fixed ctxt x
    30   end;
    31 
    32 val encode_syntax =
    33   XML.Encode.variant
    34    [fn NONE => ([], []),
    35     fn SOME (Syntax.Prefix delim) => ([delim], []),
    36     fn SOME (Syntax.Infix {assoc, delim, pri}) =>
    37       let
    38         val ass =
    39           (case assoc of
    40             Printer.No_Assoc => 0
    41           | Printer.Left_Assoc => 1
    42           | Printer.Right_Assoc => 2);
    43         open XML.Encode Term_XML.Encode;
    44       in ([], triple int string int (ass, delim, pri)) end];
    45 
    46 
    47 (* standardization of variables: only frees and named bounds *)
    48 
    49 local
    50 
    51 fun declare_names (Abs (_, _, b)) = declare_names b
    52   | declare_names (t $ u) = declare_names t #> declare_names u
    53   | declare_names (Const (c, _)) = Name.declare (Long_Name.base_name c)
    54   | declare_names (Free (x, _)) = Name.declare x
    55   | declare_names _ = I;
    56 
    57 fun variant_abs bs (Abs (x, T, t)) =
    58       let
    59         val names = fold Name.declare bs (declare_names t Name.context);
    60         val x' = #1 (Name.variant x names);
    61         val t' = variant_abs (x' :: bs) t;
    62       in Abs (x', T, t') end
    63   | variant_abs bs (t $ u) = variant_abs bs t $ variant_abs bs u
    64   | variant_abs _ t = t;
    65 
    66 in
    67 
    68 fun standard_vars used =
    69   let
    70     fun zero_var_indexes tm =
    71       Term_Subst.instantiate (Term_Subst.zero_var_indexes_inst used [tm]) tm;
    72 
    73     fun unvarifyT ty = ty |> Term.map_atyps
    74       (fn TVar ((a, _), S) => TFree (a, S)
    75         | T as TFree (a, _) =>
    76             if Name.is_declared used a then T
    77             else raise TYPE (Logic.bad_fixed a, [ty], []));
    78 
    79     fun unvarify tm = tm |> Term.map_aterms
    80       (fn Var ((x, _), T) => Free (x, T)
    81         | t as Free (x, _) =>
    82             if Name.is_declared used x then t
    83             else raise TERM (Logic.bad_fixed x, [tm])
    84         | t => t);
    85 
    86   in zero_var_indexes #> map_types unvarifyT #> unvarify #> variant_abs [] end;
    87 
    88 val standard_vars_global = standard_vars Name.context;
    89 
    90 end;
    91 
    92 
    93 (* free variables: not declared in the context *)
    94 
    95 val is_free = not oo Name.is_declared;
    96 
    97 fun add_frees used =
    98   fold_aterms (fn Free (x, T) => is_free used x ? insert (op =) (x, T) | _ => I);
    99 
   100 fun add_tfrees used =
   101   (fold_types o fold_atyps) (fn TFree (a, S) => is_free used a ? insert (op =) (a, S) | _ => I);
   102 
   103 
   104 (* locale content *)
   105 
   106 fun locale_content thy loc =
   107   let
   108     val ctxt = Locale.init loc thy;
   109     val args =
   110       Locale.params_of thy loc
   111       |> map (fn ((x, T), _) => ((x, T), get_syntax_param ctxt loc x));
   112     val axioms =
   113       let
   114         val (asm, defs) = Locale.specification_of thy loc;
   115         val cprops = map (Thm.cterm_of ctxt) (the_list asm @ defs);
   116         val (intro1, intro2) = Locale.intros_of thy loc;
   117         val intros_tac = Method.try_intros_tac ctxt (the_list intro1 @ the_list intro2) [];
   118         val res =
   119           Goal.init (Conjunction.mk_conjunction_balanced cprops)
   120           |> (ALLGOALS Goal.conjunction_tac THEN intros_tac)
   121           |> try Seq.hd;
   122       in
   123         (case res of
   124           SOME goal => Thm.prems_of goal
   125         | NONE => raise Fail ("Cannot unfold locale " ^ quote loc))
   126       end;
   127     val typargs = rev (fold Term.add_tfrees (map (Free o #1) args @ axioms) []);
   128   in {typargs = typargs, args = args, axioms = axioms} end;
   129 
   130 fun locale_dependency_subst thy (dep: Locale.locale_dependency) =
   131   let
   132     val (type_params, params) = Locale.parameters_of thy (#source dep);
   133     val typargs = fold (Term.add_tfreesT o #2 o #1) params type_params;
   134     val substT =
   135       typargs |> map_filter (fn v =>
   136         let
   137           val T = TFree v;
   138           val T' = Morphism.typ (#morphism dep) T;
   139         in if T = T' then NONE else SOME (v, T') end);
   140     val subst =
   141       params |> map_filter (fn (v, _) =>
   142         let
   143           val t = Free v;
   144           val t' = Morphism.term (#morphism dep) t;
   145         in if t aconv t' then NONE else SOME (v, t') end);
   146   in (substT, subst) end;
   147 
   148 
   149 (* general setup *)
   150 
   151 fun setup_presentation f =
   152   Theory.setup (Thy_Info.add_presentation (fn context => fn thy =>
   153     if Options.bool (#options context) "export_theory" then f context thy else ()));
   154 
   155 fun export_body thy name body =
   156   Export.export thy ("theory/" ^ name) (Buffer.chunks (YXML.buffer_body body Buffer.empty));
   157 
   158 
   159 (* presentation *)
   160 
   161 val _ = setup_presentation (fn {adjust_pos, ...} => fn thy =>
   162   let
   163     val parents = Theory.parents_of thy;
   164     val rep_tsig = Type.rep_tsig (Sign.tsig_of thy);
   165 
   166     val thy_ctxt = Proof_Context.init_global thy;
   167 
   168 
   169     (* entities *)
   170 
   171     fun make_entity_markup name xname pos serial =
   172       let
   173         val props =
   174           Position.offset_properties_of (adjust_pos pos) @
   175           Position.id_properties_of pos @
   176           Markup.serial_properties serial;
   177       in (Markup.entityN, (Markup.nameN, name) :: (Markup.xnameN, xname) :: props) end;
   178 
   179     fun entity_markup space name =
   180       let
   181         val xname = Name_Space.extern_shortest thy_ctxt space name;
   182         val {serial, pos, ...} = Name_Space.the_entry space name;
   183       in make_entity_markup name xname pos serial end;
   184 
   185     fun export_entities export_name export get_space decls =
   186       let val elems =
   187         let
   188           val parent_spaces = map get_space parents;
   189           val space = get_space thy;
   190         in
   191           (decls, []) |-> fold (fn (name, decl) =>
   192             if exists (fn space => Name_Space.declared space name) parent_spaces then I
   193             else
   194               (case export name decl of
   195                 NONE => I
   196               | SOME body =>
   197                   cons (#serial (Name_Space.the_entry space name),
   198                     XML.Elem (entity_markup space name, body))))
   199           |> sort (int_ord o apply2 #1) |> map #2
   200         end;
   201       in if null elems then () else export_body thy export_name elems end;
   202 
   203 
   204     (* types *)
   205 
   206     val encode_type =
   207       let open XML.Encode Term_XML.Encode
   208       in triple encode_syntax (list string) (option typ) end;
   209 
   210     fun export_type c (Type.LogicalType n) =
   211           SOME (encode_type (get_syntax_type thy_ctxt c, Name.invent Name.context Name.aT n, NONE))
   212       | export_type c (Type.Abbreviation (args, U, false)) =
   213           SOME (encode_type (get_syntax_type thy_ctxt c, args, SOME U))
   214       | export_type _ _ = NONE;
   215 
   216     val _ =
   217       export_entities "types" export_type Sign.type_space
   218         (Name_Space.dest_table (#types rep_tsig));
   219 
   220 
   221     (* consts *)
   222 
   223     val encode_const =
   224       let open XML.Encode Term_XML.Encode
   225       in pair encode_syntax (pair (list string) (pair typ (option term))) end;
   226 
   227     fun export_const c (T, abbrev) =
   228       let
   229         val syntax = get_syntax_const thy_ctxt c;
   230         val T' = T |> Logic.unvarifyT_global |> Type.strip_sorts;
   231         val abbrev' = abbrev |> Option.map (standard_vars_global #> map_types Type.strip_sorts);
   232         val args = map (#1 o dest_TFree) (Consts.typargs (Sign.consts_of thy) (c, T'));
   233       in encode_const (syntax, (args, (T', abbrev'))) end;
   234 
   235     val _ =
   236       export_entities "consts" (SOME oo export_const) Sign.const_space
   237         (#constants (Consts.dest (Sign.consts_of thy)));
   238 
   239 
   240     (* axioms and facts *)
   241 
   242     fun prop_of raw_thm =
   243       let
   244         val thm = raw_thm
   245           |> Thm.transfer thy
   246           |> Thm.check_hyps (Context.Theory thy)
   247           |> Thm.strip_shyps;
   248         val prop = thm
   249           |> Thm.full_prop_of;
   250       in (Thm.extra_shyps thm, prop) end;
   251 
   252     fun encode_prop used (Ss, raw_prop) =
   253       let
   254         val prop = standard_vars used raw_prop;
   255         val args = rev (add_frees used prop []);
   256         val typargs = rev (add_tfrees used prop []);
   257         val used' = fold (Name.declare o #1) typargs used;
   258         val sorts = Name.invent used' Name.aT (length Ss) ~~ Ss;
   259       in
   260         (sorts @ typargs, args, prop) |>
   261           let open XML.Encode Term_XML.Encode
   262           in triple (list (pair string sort)) (list (pair string typ)) term end
   263       end;
   264 
   265     fun encode_axiom used t = encode_prop used ([], t);
   266 
   267     val encode_fact_single = encode_prop Name.context o prop_of;
   268     val encode_fact_multi = XML.Encode.list (encode_prop Name.context) o map prop_of;
   269 
   270     val _ =
   271       export_entities "axioms" (fn _ => fn t => SOME (encode_axiom Name.context t))
   272         Theory.axiom_space (Theory.axioms_of thy);
   273     val _ =
   274       export_entities "facts" (K (SOME o encode_fact_multi))
   275         (Facts.space_of o Global_Theory.facts_of)
   276         (Facts.dest_static true [] (Global_Theory.facts_of thy));
   277 
   278 
   279     (* type classes *)
   280 
   281     val encode_class =
   282       let open XML.Encode Term_XML.Encode
   283       in pair (list (pair string typ)) (list encode_fact_single) end;
   284 
   285     fun export_class name =
   286       (case try (Axclass.get_info thy) name of
   287         NONE => ([], [])
   288       | SOME {params, axioms, ...} => (params, axioms))
   289       |> encode_class |> SOME;
   290 
   291     val _ =
   292       export_entities "classes" (fn name => fn () => export_class name)
   293         Sign.class_space (map (rpair ()) (Graph.keys (Sorts.classes_of (#2 (#classes rep_tsig)))));
   294 
   295 
   296     (* sort algebra *)
   297 
   298     val {classrel, arities} =
   299       Sorts.dest_algebra (map (#2 o #classes o Type.rep_tsig o Sign.tsig_of) parents)
   300         (#2 (#classes rep_tsig));
   301 
   302     val encode_classrel =
   303       let open XML.Encode
   304       in list (pair string (list string)) end;
   305 
   306     val encode_arities =
   307       let open XML.Encode Term_XML.Encode
   308       in list (triple string (list sort) string) end;
   309 
   310     val _ = if null classrel then () else export_body thy "classrel" (encode_classrel classrel);
   311     val _ = if null arities then () else export_body thy "arities" (encode_arities arities);
   312 
   313 
   314     (* locales *)
   315 
   316     fun encode_locale used =
   317       let open XML.Encode Term_XML.Encode in
   318         triple (list (pair string sort)) (list (pair (pair string typ) encode_syntax))
   319           (list (encode_axiom used))
   320       end;
   321 
   322     fun export_locale loc =
   323       let
   324         val {typargs, args, axioms} = locale_content thy loc;
   325         val used = fold Name.declare (map #1 typargs @ map (#1 o #1) args) Name.context;
   326       in encode_locale used (typargs, args, axioms) end
   327       handle ERROR msg =>
   328         cat_error msg ("The error(s) above occurred in locale " ^
   329           quote (Locale.markup_name thy_ctxt loc));
   330 
   331     val _ =
   332       export_entities "locales" (fn loc => fn () => SOME (export_locale loc))
   333         Locale.locale_space
   334         (map (rpair ()) (Locale.get_locales thy));
   335 
   336 
   337     (* locale dependencies *)
   338 
   339     fun encode_locale_dependency (dep: Locale.locale_dependency) =
   340       (#source dep, (#target dep, (#prefix dep, locale_dependency_subst thy dep))) |>
   341         let
   342           open XML.Encode Term_XML.Encode;
   343           val encode_subst =
   344             pair (list (pair (pair string sort) typ)) (list (pair (pair string typ) term));
   345         in pair string (pair string (pair (list (pair string bool)) encode_subst)) end;
   346 
   347     val _ =
   348       (case Locale.dest_dependencies parents thy of
   349         [] => ()
   350       | deps =>
   351           deps |> map_index (fn (i, dep) =>
   352             let
   353               val xname = string_of_int (i + 1);
   354               val name = Long_Name.implode [Context.theory_name thy, xname];
   355               val body = encode_locale_dependency dep;
   356             in XML.Elem (make_entity_markup name xname (#pos dep) (#serial dep), body) end)
   357           |> export_body thy "locale_dependencies");
   358 
   359 
   360     (* parents *)
   361 
   362     val _ =
   363       export_body thy "parents"
   364         (XML.Encode.string (cat_lines (map Context.theory_long_name parents)));
   365 
   366   in () end);
   367 
   368 end;