src/Pure/library.ML
author haftmann
Wed Jul 12 17:00:32 2006 +0200 (2006-07-12)
changeset 20108 289050bdfff5
parent 20095 432e914a0e95
child 20133 9ee091573fa0
permissions -rw-r--r--
added chop_prefix
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 *)
     9 
    10 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    11 infix 2 ?;
    12 infix 3 o oo ooo oooo;
    13 
    14 infix 4 ~~ upto downto;
    15 infix orf andf \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    16   union_string inter inter_int inter_string subset subset_int subset_string;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    34   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    35   val tap: ('b -> 'a) -> 'b -> 'b
    36   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    37   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    38   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    39   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    40 
    41   (*options*)
    42   val the: 'a option -> 'a
    43   val these: 'a list option -> 'a list
    44   val the_default: 'a -> 'a option -> 'a
    45   val the_list: 'a option -> 'a list
    46   val is_some: 'a option -> bool
    47   val is_none: 'a option -> bool
    48   val perhaps: ('a -> 'a option) -> 'a -> 'a
    49   val merge_opt: ('a * 'a -> bool) -> 'a option * 'a option -> 'a option
    50 
    51   (*exceptions*)
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   exception EXCEPTION of exn * string
    55   val do_transform_failure: bool ref
    56   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    57   datatype 'a result = Result of 'a | Exn of exn
    58   val capture: ('a -> 'b) -> 'a -> 'b result
    59   val release: 'a result -> 'a
    60   val get_result: 'a result -> 'a option
    61   val get_exn: 'a result -> exn option
    62 
    63   (*errors*)
    64   exception SYS_ERROR of string
    65   val sys_error: string -> 'a
    66   exception ERROR of string
    67   val error: string -> 'a
    68   val cat_error: string -> string -> 'a
    69   val assert: bool -> string -> unit
    70   val deny: bool -> string -> unit
    71   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    72 
    73   (*pairs*)
    74   val pair: 'a -> 'b -> 'a * 'b
    75   val rpair: 'a -> 'b -> 'b * 'a
    76   val fst: 'a * 'b -> 'a
    77   val snd: 'a * 'b -> 'b
    78   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    79   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    80   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    81   val swap: 'a * 'b -> 'b * 'a
    82   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    83   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    84   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    85   val string_of_pair: ('a -> string) -> ('b -> string) -> 'a * 'b -> string
    86 
    87   (*booleans*)
    88   val equal: ''a -> ''a -> bool
    89   val not_equal: ''a -> ''a -> bool
    90   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    91   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    92   val exists: ('a -> bool) -> 'a list -> bool
    93   val forall: ('a -> bool) -> 'a list -> bool
    94   val set: bool ref -> bool
    95   val reset: bool ref -> bool
    96   val toggle: bool ref -> bool
    97   val change: 'a ref -> ('a -> 'a) -> unit
    98   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    99   val conditional: bool -> (unit -> unit) -> unit
   100 
   101   (*lists*)
   102   exception UnequalLengths
   103   val cons: 'a -> 'a list -> 'a list
   104   val single: 'a -> 'a list
   105   val singleton: ('a list -> 'b list) -> 'a -> 'b
   106   val append: 'a list -> 'a list -> 'a list
   107   val apply: ('a -> 'a) list -> 'a -> 'a
   108   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   109   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   110   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   111   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   112   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   113   val flat: 'a list list -> 'a list
   114   val maps: ('a -> 'b list) -> 'a list -> 'b list
   115   val unflat: 'a list list -> 'b list -> 'b list list
   116   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
   117   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
   118   val chop: int -> 'a list -> 'a list * 'a list
   119   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   120   val nth: 'a list -> int -> 'a
   121   val nth_update: int * 'a -> 'a list -> 'a list
   122   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   123   val nth_list: 'a list list -> int -> 'a list
   124   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
   125   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   126   val split_last: 'a list -> 'a list * 'a
   127   val find_index: ('a -> bool) -> 'a list -> int
   128   val find_index_eq: ''a -> ''a list -> int
   129   val find_first: ('a -> bool) -> 'a list -> 'a option
   130   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   131   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   132   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   133   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   134   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   135   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   136   val ~~ : 'a list * 'b list -> ('a * 'b) list
   137   val split_list: ('a * 'b) list -> 'a list * 'b list
   138   val separate: 'a -> 'a list -> 'a list
   139   val replicate: int -> 'a -> 'a list
   140   val multiply: 'a list -> 'a list list -> 'a list list
   141   val product: 'a list -> 'b list -> ('a * 'b) list
   142   val filter: ('a -> bool) -> 'a list -> 'a list
   143   val filter_out: ('a -> bool) -> 'a list -> 'a list
   144   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   145   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   146   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   147   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   148   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   149   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   150   val prefixes1: 'a list -> 'a list list
   151   val prefixes: 'a list -> 'a list list
   152   val suffixes1: 'a list -> 'a list list
   153   val suffixes: 'a list -> 'a list list
   154 
   155   (*integers*)
   156   val gcd: IntInf.int * IntInf.int -> IntInf.int
   157   val lcm: IntInf.int * IntInf.int -> IntInf.int
   158   val inc: int ref -> int
   159   val dec: int ref -> int
   160   val upto: int * int -> int list
   161   val downto: int * int -> int list
   162   val downto0: int list * int -> bool
   163   val radixpand: int * int -> int list
   164   val radixstring: int * string * int -> string
   165   val string_of_int: int -> string
   166   val string_of_indexname: string * int -> string
   167   val read_intinf: int -> string list -> IntInf.int * string list
   168   val read_int: string list -> int * string list
   169   val oct_char: string -> string
   170 
   171   (*strings*)
   172   val nth_string: string -> int -> string
   173   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   174   val exists_string: (string -> bool) -> string -> bool
   175   val forall_string: (string -> bool) -> string -> bool
   176   val enclose: string -> string -> string -> string
   177   val unenclose: string -> string
   178   val quote: string -> string
   179   val space_implode: string -> string list -> string
   180   val commas: string list -> string
   181   val commas_quote: string list -> string
   182   val cat_lines: string list -> string
   183   val space_explode: string -> string -> string list
   184   val split_lines: string -> string list
   185   val prefix_lines: string -> string -> string
   186   val untabify: string list -> string list
   187   val prefix: string -> string -> string
   188   val suffix: string -> string -> string
   189   val unprefix: string -> string -> string
   190   val unsuffix: string -> string -> string
   191   val replicate_string: int -> string -> string
   192   val translate_string: (string -> string) -> string -> string
   193   val string_of_list: ('a -> string) -> 'a list -> string
   194   val string_of_option: ('a -> string) -> 'a option -> string
   195 
   196   (*lists as sets -- see also Pure/General/ord_list.ML*)
   197   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   198   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   199   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   200   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   201   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   202   val mem: ''a * ''a list -> bool
   203   val mem_int: int * int list -> bool
   204   val mem_string: string * string list -> bool
   205   val ins: ''a * ''a list -> ''a list
   206   val ins_int: int * int list -> int list
   207   val ins_string: string * string list -> string list
   208   val union: ''a list * ''a list -> ''a list
   209   val union_int: int list * int list -> int list
   210   val union_string: string list * string list -> string list
   211   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   212   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   213   val inter: ''a list * ''a list -> ''a list
   214   val inter_int: int list * int list -> int list
   215   val inter_string: string list * string list -> string list
   216   val subset: ''a list * ''a list -> bool
   217   val subset_int: int list * int list -> bool
   218   val subset_string: string list * string list -> bool
   219   val eq_set: ''a list * ''a list -> bool
   220   val eq_set_string: string list * string list -> bool
   221   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   222   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   223   val \ : ''a list * ''a -> ''a list
   224   val \\ : ''a list * ''a list -> ''a list
   225   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   226   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   227   val findrep: ''a list -> ''a list
   228   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   229   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   230   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   231 
   232   (*lists as tables -- see also Pure/General/alist.ML*)
   233   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   234   val merge_lists: ''a list -> ''a list -> ''a list
   235   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   236 
   237   (*balanced trees*)
   238   exception Balance
   239   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   240   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   241   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   242 
   243   (*orders*)
   244   val is_equal: order -> bool
   245   val rev_order: order -> order
   246   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   247   val int_ord: int * int -> order
   248   val string_ord: string * string -> order
   249   val fast_string_ord: string * string -> order
   250   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   251   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   252   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   253   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   254   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   255   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   256   val sort_strings: string list -> string list
   257   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   258 
   259   (*random numbers*)
   260   exception RANDOM
   261   val random: unit -> real
   262   val random_range: int -> int -> int
   263   val one_of: 'a list -> 'a
   264   val frequency: (int * 'a) list -> 'a
   265 
   266   (*current directory*)
   267   val cd: string -> unit
   268   val pwd: unit -> string
   269 
   270   (*misc*)
   271   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   272   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   273   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   274   val gensym: string -> string
   275   val scanwords: (string -> bool) -> string list -> string list
   276   type stamp
   277   val stamp: unit -> stamp
   278   type serial
   279   val serial: unit -> serial
   280   val serial_string: unit -> string
   281   structure Object: sig type T end
   282 end;
   283 
   284 signature LIBRARY =
   285 sig
   286   include BASIC_LIBRARY
   287   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   288   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   289   val take: int * 'a list -> 'a list
   290   val drop: int * 'a list -> 'a list
   291   val last_elem: 'a list -> 'a
   292   val seq: ('a -> unit) -> 'a list -> unit
   293 end;
   294 
   295 structure Library: LIBRARY =
   296 struct
   297 
   298 
   299 (** functions **)
   300 
   301 fun I x = x;
   302 fun K x = fn _ => x;
   303 fun curry f x y = f (x, y);
   304 fun uncurry f (x, y) = f x y;
   305 
   306 (*reverse application and structured results*)
   307 fun x |> f = f x;
   308 fun (x, y) |-> f = f x y;
   309 fun (x, y) |>> f = (f x, y);
   310 fun (x, y) ||> f = (x, f y);
   311 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   312 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   313 
   314 (*reverse composition*)
   315 fun f #> g = g o f;
   316 fun f #-> g = uncurry g o f;
   317 
   318 (*conditional application*)
   319 fun b ? f = fn x => if b x then f x else x;
   320 
   321 (*view results*)
   322 fun `f = fn x => (f x, x);
   323 fun tap f = fn x => (f x; x);
   324 
   325 (*composition with multiple args*)
   326 fun (f oo g) x y = f (g x y);
   327 fun (f ooo g) x y z = f (g x y z);
   328 fun (f oooo g) x y z w = f (g x y z w);
   329 
   330 (*function exponentiation: f(...(f x)...) with n applications of f*)
   331 fun funpow n f x =
   332   let fun rep (0, x) = x
   333         | rep (n, x) = rep (n - 1, f x)
   334   in rep (n, x) end;
   335 
   336 
   337 (** options **)
   338 
   339 val the = Option.valOf;
   340 
   341 fun these (SOME x) = x
   342   | these _ = [];
   343 
   344 fun the_default x (SOME y) = y
   345   | the_default x _ = x;
   346 
   347 fun the_list (SOME x) = [x]
   348   | the_list _ = []
   349 
   350 fun is_some (SOME _) = true
   351   | is_some NONE = false;
   352 
   353 fun is_none (SOME _) = false
   354   | is_none NONE = true;
   355 
   356 fun perhaps f x = the_default x (f x);
   357 
   358 fun merge_opt _ (NONE, y) = y
   359   | merge_opt _ (x, NONE) = x
   360   | merge_opt eq (SOME x, SOME y) = if eq (x, y) then SOME y else raise Option;
   361 
   362 
   363 (* exceptions *)
   364 
   365 val do_transform_failure = ref true;
   366 
   367 fun transform_failure exn f x =
   368   if ! do_transform_failure then
   369     f x handle Interrupt => raise Interrupt | e => raise exn e
   370   else f x;
   371 
   372 exception EXCEPTION of exn * string;
   373 
   374 
   375 fun try f x = SOME (f x)
   376   handle Interrupt => raise Interrupt | _ => NONE;
   377 
   378 fun can f x = is_some (try f x);
   379 
   380 
   381 datatype 'a result =
   382   Result of 'a |
   383   Exn of exn;
   384 
   385 fun capture f x = Result (f x) handle e => Exn e;
   386 
   387 fun release (Result y) = y
   388   | release (Exn e) = raise e;
   389 
   390 fun get_result (Result x) = SOME x
   391   | get_result _ = NONE;
   392 
   393 fun get_exn (Exn exn) = SOME exn
   394   | get_exn _ = NONE;
   395 
   396 
   397 (* errors *)
   398 
   399 exception SYS_ERROR of string;
   400 fun sys_error msg = raise SYS_ERROR msg;
   401 
   402 exception ERROR of string;
   403 fun error msg = raise ERROR msg;
   404 
   405 fun cat_error "" msg = error msg
   406   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   407 
   408 fun assert p msg = if p then () else error msg;
   409 fun deny p msg = if p then error msg else ();
   410 
   411 fun assert_all pred list msg =
   412   let
   413     fun ass [] = ()
   414       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   415   in ass list end;
   416 
   417 
   418 (** pairs **)
   419 
   420 fun pair x y = (x, y);
   421 fun rpair x y = (y, x);
   422 
   423 fun fst (x, y) = x;
   424 fun snd (x, y) = y;
   425 
   426 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   427 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   428 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   429 
   430 fun swap (x, y) = (y, x);
   431 
   432 (*apply function to components*)
   433 fun apfst f (x, y) = (f x, y);
   434 fun apsnd f (x, y) = (x, f y);
   435 fun pairself f (x, y) = (f x, f y);
   436 
   437 fun string_of_pair f1 f2 (x, y) = "(" ^ f1 x ^ ", " ^ f2 y ^ ")";
   438 
   439 
   440 (** booleans **)
   441 
   442 (* equality *)
   443 
   444 fun equal x y = x = y;
   445 fun not_equal x y = x <> y;
   446 
   447 (* operators for combining predicates *)
   448 
   449 fun p orf q = fn x => p x orelse q x;
   450 fun p andf q = fn x => p x andalso q x;
   451 
   452 (* predicates on lists *)
   453 
   454 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   455 fun exists (pred: 'a -> bool) : 'a list -> bool =
   456   let fun boolf [] = false
   457         | boolf (x :: xs) = pred x orelse boolf xs
   458   in boolf end;
   459 
   460 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   461 fun forall (pred: 'a -> bool) : 'a list -> bool =
   462   let fun boolf [] = true
   463         | boolf (x :: xs) = pred x andalso boolf xs
   464   in boolf end;
   465 
   466 
   467 (* flags *)
   468 
   469 fun set flag = (flag := true; true);
   470 fun reset flag = (flag := false; false);
   471 fun toggle flag = (flag := not (! flag); ! flag);
   472 
   473 fun change r f = r := f (! r);
   474 
   475 (*temporarily set flag during execution*)
   476 fun setmp flag value f x =
   477   let
   478     val orig_value = ! flag;
   479     val _ = flag := value;
   480     val result = capture f x;
   481     val _ = flag := orig_value;
   482   in release result end;
   483 
   484 
   485 (* conditional execution *)
   486 
   487 fun conditional b f = if b then f () else ();
   488 
   489 
   490 (** lists **)
   491 
   492 exception UnequalLengths;
   493 
   494 fun cons x xs = x :: xs;
   495 fun single x = [x];
   496 
   497 fun singleton f x = (case f [x] of [y] => y | _ => raise Empty);
   498 
   499 fun append xs ys = xs @ ys;
   500 
   501 fun apply [] x = x
   502   | apply (f :: fs) x = apply fs (f x);
   503 
   504 
   505 (* fold *)
   506 
   507 fun fold f =
   508   let
   509     fun fold_aux [] y = y
   510       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   511   in fold_aux end;
   512 
   513 fun fold_rev f =
   514   let
   515     fun fold_aux [] y = y
   516       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   517   in fold_aux end;
   518 
   519 fun fold_map f =
   520   let
   521     fun fold_aux [] y = ([], y)
   522       | fold_aux (x :: xs) y =
   523           let
   524             val (x', y') = f x y;
   525             val (xs', y'') = fold_aux xs y';
   526           in (x' :: xs', y'') end;
   527   in fold_aux end;
   528 
   529 (*the following versions of fold are designed to fit nicely with infixes*)
   530 
   531 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   532     for operators that associate to the left (TAIL RECURSIVE)*)
   533 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   534   let fun itl (e, [])  = e
   535         | itl (e, a::l) = itl (f(e, a), l)
   536   in  itl end;
   537 
   538 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   539     for operators that associate to the right (not tail recursive)*)
   540 fun foldr f (l, e) =
   541   let fun itr [] = e
   542         | itr (a::l) = f(a, itr l)
   543   in  itr l  end;
   544 
   545 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   546     for n > 0, operators that associate to the right (not tail recursive)*)
   547 fun foldr1 f l =
   548   let fun itr [x] = x
   549         | itr (x::l) = f(x, itr l)
   550   in  itr l  end;
   551 
   552 fun fold_index f =
   553   let
   554     fun fold_aux _ [] y = y
   555       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   556   in fold_aux 0 end;
   557 
   558 fun foldl_map f =
   559   let
   560     fun fold_aux (x, []) = (x, [])
   561       | fold_aux (x, y :: ys) =
   562           let
   563             val (x', y') = f (x, y);
   564             val (x'', ys') = fold_aux (x', ys);
   565           in (x'', y' :: ys') end;
   566   in fold_aux end;
   567 
   568 
   569 (* basic list functions *)
   570 
   571 fun maps f [] = []
   572   | maps f (x :: xs) = f x @ maps f xs;
   573 
   574 fun chop 0 xs = ([], xs)
   575   | chop _ [] = ([], [])
   576   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   577 
   578 (*take the first n elements from a list*)
   579 fun take (n, []) = []
   580   | take (n, x :: xs) =
   581       if n > 0 then x :: take (n - 1, xs) else [];
   582 
   583 (*drop the first n elements from a list*)
   584 fun drop (n, []) = []
   585   | drop (n, x :: xs) =
   586       if n > 0 then drop (n - 1, xs) else x :: xs;
   587 
   588 fun dropwhile P [] = []
   589   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   590 
   591 (*return nth element of a list, where 0 designates the first element;
   592   raise Subscript if list too short*)
   593 fun nth xs i = List.nth (xs, i);
   594 
   595 fun nth_list xss i = nth xss i handle Subscript => [];
   596 
   597 (*update nth element*)
   598 fun nth_update (n, x) xs =
   599   (case chop n xs of
   600     (_, []) => raise Subscript
   601   | (prfx, _ :: sffx') => prfx @ (x :: sffx'));
   602 
   603 fun nth_map 0 f (x :: xs) = f x :: xs
   604   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   605   | nth_map _ _ [] = raise Subscript;
   606 
   607 fun map_index f =
   608   let
   609     fun mapp _ [] = []
   610       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   611   in mapp 0 end;
   612 
   613 val last_elem = List.last;
   614 
   615 (*rear decomposition*)
   616 fun split_last [] = raise Empty
   617   | split_last [x] = ([], x)
   618   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   619 
   620 (*find the position of an element in a list*)
   621 fun find_index pred =
   622   let fun find _ [] = ~1
   623         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   624   in find 0 end;
   625 
   626 fun find_index_eq x = find_index (equal x);
   627 
   628 (*find first element satisfying predicate*)
   629 fun find_first _ [] = NONE
   630   | find_first pred (x :: xs) =
   631       if pred x then SOME x else find_first pred xs;
   632 
   633 (*get first element by lookup function*)
   634 fun get_first _ [] = NONE
   635   | get_first f (x :: xs) =
   636       (case f x of
   637         NONE => get_first f xs
   638       | some => some);
   639 
   640 fun get_index f =
   641   let
   642     fun get _ [] = NONE
   643       | get i (x :: xs) =
   644           case f x
   645            of NONE => get (i + 1) xs
   646             | SOME y => SOME (i, y)
   647   in get 0 end;
   648 
   649 fun eq_list _ ([], []) = true
   650   | eq_list eq (x :: xs, y :: ys) = eq (x, y) andalso eq_list eq (xs, ys)
   651   | eq_list _ _ = false;
   652 
   653 val flat = List.concat;
   654 
   655 fun unflat (xs :: xss) ys =
   656       let val (ps, qs) = chop (length xs) ys
   657       in ps :: unflat xss qs end
   658   | unflat [] [] = []
   659   | unflat _ _ = raise UnequalLengths;
   660 
   661 fun burrow f xss =
   662   unflat xss ((f o flat) xss);
   663 
   664 fun fold_burrow f xss s =
   665   apfst (unflat xss) (f (flat xss) s);
   666 
   667 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   668   (proc x1; ...; proc xn) for side effects*)
   669 val seq = List.app;
   670 
   671 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   672 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   673   | separate _ xs = xs;
   674 
   675 (*make the list [x, x, ..., x] of length n*)
   676 fun replicate n (x: 'a) : 'a list =
   677   let fun rep (0, xs) = xs
   678         | rep (n, xs) = rep (n - 1, x :: xs)
   679   in
   680     if n < 0 then raise Subscript
   681     else rep (n, [])
   682   end;
   683 
   684 fun translate_string f = String.translate (f o String.str);
   685 
   686 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   687 fun multiply [] _ = []
   688   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   689 
   690 (*direct product*)
   691 fun product _ [] = []
   692   | product [] _ = []
   693   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   694 
   695 
   696 (* filter *)
   697 
   698 (*copy the list preserving elements that satisfy the predicate*)
   699 val filter = List.filter;
   700 fun filter_out f = filter (not o f);
   701 val map_filter = List.mapPartial;
   702 
   703 
   704 (* lists of pairs *)
   705 
   706 exception UnequalLengths;
   707 
   708 fun map2 _ [] [] = []
   709   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   710   | map2 _ _ _ = raise UnequalLengths;
   711 
   712 fun fold2 f =
   713   let
   714     fun fold_aux [] [] z = z
   715       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   716       | fold_aux _ _ _ = raise UnequalLengths;
   717   in fold_aux end;
   718 
   719 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   720   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   721   | zip_options _ [] = []
   722   | zip_options [] _ = raise UnequalLengths;
   723 
   724 (*combine two lists forming a list of pairs:
   725   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   726 fun [] ~~ [] = []
   727   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   728   | _ ~~ _ = raise UnequalLengths;
   729 
   730 (*inverse of ~~; the old 'split':
   731   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   732 val split_list = ListPair.unzip;
   733 
   734 fun equal_lists eq (xs, ys) =
   735   let
   736     fun eq' [] [] = true
   737       | eq' (x :: xs) (y :: ys) = eq (x, y) andalso eq' xs ys
   738   in length xs = length ys andalso eq' xs ys end;
   739 
   740 
   741 (* prefixes, suffixes *)
   742 
   743 fun is_prefix _ [] _ = true
   744   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   745   | is_prefix eq _ _ = false;
   746 
   747 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   748    where xi is the first element that does not satisfy the predicate*)
   749 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   750   let fun take (rxs, []) = (rev rxs, [])
   751         | take (rxs, x :: xs) =
   752             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   753   in  take([], xs)  end;
   754 
   755 fun chop_prefix eq ([], ys) = ([], ([], ys))
   756   | chop_prefix eq (xs, []) = ([], (xs, []))
   757   | chop_prefix eq (xs as x::xs', ys as y::ys') =
   758       if eq (x, y) then
   759         let val (ps', xys'') = chop_prefix eq (xs', ys')
   760         in (x::ps', xys'') end
   761       else ([], (xs, ys));
   762 
   763 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   764    where xi is the last element that does not satisfy the predicate*)
   765 fun take_suffix _ [] = ([], [])
   766   | take_suffix pred (x :: xs) =
   767       (case take_suffix pred xs of
   768         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   769       | (prfx, sffx) => (x :: prfx, sffx));
   770 
   771 fun prefixes1 [] = []
   772   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   773 
   774 fun prefixes xs = [] :: prefixes1 xs;
   775 
   776 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   777 fun suffixes xs = [] :: suffixes1 xs;
   778 
   779 
   780 (** integers **)
   781 
   782 fun gcd (x, y) =
   783   let fun gxd x y : IntInf.int =
   784     if y = 0 then x else gxd y (x mod y)
   785   in if x < y then gxd y x else gxd x y end;
   786 
   787 fun lcm (x, y) = (x * y) div gcd (x, y);
   788 
   789 fun inc i = (i := ! i + 1; ! i);
   790 fun dec i = (i := ! i - 1; ! i);
   791 
   792 
   793 (* lists of integers *)
   794 
   795 (*make the list [from, from + 1, ..., to]*)
   796 fun (from upto to) =
   797   if from > to then [] else from :: ((from + 1) upto to);
   798 
   799 (*make the list [from, from - 1, ..., to]*)
   800 fun (from downto to) =
   801   if from < to then [] else from :: ((from - 1) downto to);
   802 
   803 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   804 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   805   | downto0 ([], n) = n = ~1;
   806 
   807 
   808 (* convert integers to strings *)
   809 
   810 (*expand the number in the given base;
   811   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   812 fun radixpand (base, num) : int list =
   813   let
   814     fun radix (n, tail) =
   815       if n < base then n :: tail
   816       else radix (n div base, (n mod base) :: tail)
   817   in radix (num, []) end;
   818 
   819 (*expands a number into a string of characters starting from "zerochar";
   820   example: radixstring (2, "0", 8) gives "1000"*)
   821 fun radixstring (base, zerochar, num) =
   822   let val offset = ord zerochar;
   823       fun chrof n = chr (offset + n)
   824   in implode (map chrof (radixpand (base, num))) end;
   825 
   826 
   827 val string_of_int = Int.toString;
   828 
   829 fun string_of_indexname (a,0) = a
   830   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   831 
   832 
   833 (* read integers *)
   834 
   835 fun read_intinf radix cs =
   836   let
   837     val zero = ord "0";
   838     val limit = zero + radix;
   839     fun scan (num, []) = (num, [])
   840       | scan (num, c :: cs) =
   841         if zero <= ord c andalso ord c < limit then
   842           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   843         else (num, c :: cs);
   844   in scan (0, cs) end;
   845 
   846 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   847 
   848 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   849 
   850 
   851 
   852 (** strings **)
   853 
   854 (* functions tuned for strings, avoiding explode *)
   855 
   856 fun nth_string str i =
   857   (case try String.substring (str, i, 1) of
   858     SOME s => s
   859   | NONE => raise Subscript);
   860 
   861 fun fold_string f str x0 =
   862   let
   863     val n = size str;
   864     fun iter (x, i) =
   865       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   866   in iter (x0, 0) end;
   867 
   868 fun exists_string pred str =
   869   let
   870     val n = size str;
   871     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   872   in ex 0 end;
   873 
   874 fun forall_string pred = not o exists_string (not o pred);
   875 
   876 (*enclose in brackets*)
   877 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   878 fun unenclose str = String.substring (str, 1, size str - 2);
   879 
   880 (*simple quoting (does not escape special chars)*)
   881 val quote = enclose "\"" "\"";
   882 
   883 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   884 fun space_implode a bs = implode (separate a bs);
   885 
   886 val commas = space_implode ", ";
   887 val commas_quote = commas o map quote;
   888 
   889 (*concatenate messages, one per line, into a string*)
   890 val cat_lines = space_implode "\n";
   891 
   892 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   893 fun space_explode _ "" = []
   894   | space_explode sep str =
   895       let
   896         fun expl chs =
   897           (case take_prefix (fn s => s <> sep) chs of
   898             (cs, []) => [implode cs]
   899           | (cs, _ :: cs') => implode cs :: expl cs');
   900       in expl (explode str) end;
   901 
   902 val split_lines = space_explode "\n";
   903 
   904 fun prefix_lines "" txt = txt
   905   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   906 
   907 fun untabify chs =
   908   let
   909     val tab_width = 8;
   910 
   911     fun untab (_, "\n") = (0, ["\n"])
   912       | untab (pos, "\t") =
   913           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   914       | untab (pos, c) = (pos + 1, [c]);
   915   in
   916     if not (exists (fn c => c = "\t") chs) then chs
   917     else flat (#2 (foldl_map untab (0, chs)))
   918   end;
   919 
   920 fun prefix prfx s = prfx ^ s;
   921 fun suffix sffx s = s ^ sffx;
   922 
   923 fun unprefix prfx s =
   924   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   925   else raise Fail "unprefix";
   926 
   927 fun unsuffix sffx s =
   928   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   929   else raise Fail "unsuffix";
   930 
   931 fun replicate_string 0 _ = ""
   932   | replicate_string 1 a = a
   933   | replicate_string k a =
   934       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   935       else replicate_string (k div 2) (a ^ a) ^ a;
   936 
   937 fun string_of_list f = enclose "[" "]" o commas o map f;
   938 
   939 fun string_of_option f NONE = "NONE"
   940   | string_of_option f (SOME x) = "SOME (" ^ f x ^ ")";
   941 
   942 
   943 
   944 (** lists as sets -- see also Pure/General/ord_list.ML **)
   945 
   946 (*canonical member, insert, remove*)
   947 fun member eq list x =
   948   let
   949     fun memb [] = false
   950       | memb (y :: ys) = eq (x, y) orelse memb ys;
   951   in memb list end;
   952 
   953 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   954 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   955 
   956 fun subtract eq = fold (remove eq);
   957 
   958 fun merge _ ([], ys) = ys
   959   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   960 
   961 (*old-style infixes*)
   962 fun x mem xs = member (op =) xs x;
   963 fun (x: int) mem_int xs = member (op =) xs x;
   964 fun (x: string) mem_string xs = member (op =) xs x;
   965 
   966 fun x ins xs = insert (op =) x xs;
   967 fun (x: int) ins_int xs = insert (op =) x xs;
   968 fun (x: string) ins_string xs = insert (op =) x xs;
   969 
   970 
   971 (*union of sets represented as lists: no repetitions*)
   972 fun xs union [] = xs
   973   | [] union ys = ys
   974   | (x :: xs) union ys = xs union (x ins ys);
   975 
   976 (*union of sets, optimized version for ints*)
   977 fun (xs:int list) union_int [] = xs
   978   | [] union_int ys = ys
   979   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   980 
   981 (*union of sets, optimized version for strings*)
   982 fun (xs:string list) union_string [] = xs
   983   | [] union_string ys = ys
   984   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   985 
   986 (*generalized union*)
   987 fun gen_union eq (xs, []) = xs
   988   | gen_union eq ([], ys) = ys
   989   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   990 
   991 
   992 (*intersection*)
   993 fun [] inter ys = []
   994   | (x :: xs) inter ys =
   995       if x mem ys then x :: (xs inter ys) else xs inter ys;
   996 
   997 (*intersection, optimized version for ints*)
   998 fun ([]:int list) inter_int ys = []
   999   | (x :: xs) inter_int ys =
  1000       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
  1001 
  1002 (*intersection, optimized version for strings *)
  1003 fun ([]:string list) inter_string ys = []
  1004   | (x :: xs) inter_string ys =
  1005       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
  1006 
  1007 (*generalized intersection*)
  1008 fun gen_inter eq ([], ys) = []
  1009   | gen_inter eq (x::xs, ys) =
  1010       if member eq ys x then x :: gen_inter eq (xs, ys)
  1011       else gen_inter eq (xs, ys);
  1012 
  1013 
  1014 (*subset*)
  1015 fun [] subset ys = true
  1016   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
  1017 
  1018 (*subset, optimized version for ints*)
  1019 fun ([]: int list) subset_int ys = true
  1020   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
  1021 
  1022 (*subset, optimized version for strings*)
  1023 fun ([]: string list) subset_string ys = true
  1024   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
  1025 
  1026 (*set equality*)
  1027 fun eq_set (xs, ys) =
  1028   xs = ys orelse (xs subset ys andalso ys subset xs);
  1029 
  1030 (*set equality for strings*)
  1031 fun eq_set_string ((xs: string list), ys) =
  1032   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
  1033 
  1034 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
  1035 
  1036 fun gen_eq_set eq (xs, ys) =
  1037   equal_lists eq (xs, ys) orelse
  1038     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
  1039 
  1040 
  1041 (*removing an element from a list WITHOUT duplicates*)
  1042 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
  1043   | [] \ x = [];
  1044 
  1045 fun ys \\ xs = foldl (op \) (ys,xs);
  1046 
  1047 (*removing an element from a list -- possibly WITH duplicates*)
  1048 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
  1049 fun gen_rems eq (xs, ys) = filter_out (member eq ys) xs;
  1050 
  1051 (*returns the tail beginning with the first repeated element, or []*)
  1052 fun findrep [] = []
  1053   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1054 
  1055 
  1056 (*makes a list of the distinct members of the input; preserves order, takes
  1057   first of equal elements*)
  1058 fun distinct eq lst =
  1059   let
  1060     fun dist (rev_seen, []) = rev rev_seen
  1061       | dist (rev_seen, x :: xs) =
  1062           if member eq rev_seen x then dist (rev_seen, xs)
  1063           else dist (x :: rev_seen, xs);
  1064   in dist ([], lst) end;
  1065 
  1066 (*returns a list containing all repeated elements exactly once; preserves
  1067   order, takes first of equal elements*)
  1068 fun duplicates eq lst =
  1069   let
  1070     fun dups (rev_dups, []) = rev rev_dups
  1071       | dups (rev_dups, x :: xs) =
  1072           if member eq rev_dups x orelse not (member eq xs x) then
  1073             dups (rev_dups, xs)
  1074           else dups (x :: rev_dups, xs);
  1075   in dups ([], lst) end;
  1076 
  1077 fun has_duplicates eq =
  1078   let
  1079     fun dups [] = false
  1080       | dups (x :: xs) = member eq xs x orelse dups xs;
  1081   in dups end;
  1082 
  1083 
  1084 (** association lists -- legacy operations **)
  1085 
  1086 fun gen_merge_lists _ xs [] = xs
  1087   | gen_merge_lists _ [] ys = ys
  1088   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1089 
  1090 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1091 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1092 
  1093 
  1094 (** balanced trees **)
  1095 
  1096 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1097 
  1098 (*balanced folding; avoids deep nesting*)
  1099 fun fold_bal f [x] = x
  1100   | fold_bal f [] = raise Balance
  1101   | fold_bal f xs =
  1102       let val (ps, qs) = chop (length xs div 2) xs
  1103       in  f (fold_bal f ps, fold_bal f qs)  end;
  1104 
  1105 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1106 fun access_bal (f, g, x) n i =
  1107   let fun acc n i =     (*1<=i<=n*)
  1108           if n=1 then x else
  1109           let val n2 = n div 2
  1110           in  if i<=n2 then f (acc n2 i)
  1111                        else g (acc (n-n2) (i-n2))
  1112           end
  1113   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1114 
  1115 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1116 fun accesses_bal (f, g, x) n =
  1117   let fun acc n =
  1118           if n=1 then [x] else
  1119           let val n2 = n div 2
  1120               val acc2 = acc n2
  1121           in  if n-n2=n2 then map f acc2 @ map g acc2
  1122                          else map f acc2 @ map g (acc (n-n2)) end
  1123   in  if 1<=n then acc n else raise Balance  end;
  1124 
  1125 
  1126 
  1127 (** orders **)
  1128 
  1129 fun is_equal EQUAL = true
  1130   | is_equal _ = false;
  1131 
  1132 fun rev_order LESS = GREATER
  1133   | rev_order EQUAL = EQUAL
  1134   | rev_order GREATER = LESS;
  1135 
  1136 (*assume rel is a linear strict order*)
  1137 fun make_ord rel (x, y) =
  1138   if rel (x, y) then LESS
  1139   else if rel (y, x) then GREATER
  1140   else EQUAL;
  1141 
  1142 val int_ord = Int.compare;
  1143 val string_ord = String.compare;
  1144 
  1145 fun fast_string_ord (s1, s2) =
  1146   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1147 
  1148 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1149   | option_ord _ (NONE, NONE) = EQUAL
  1150   | option_ord _ (NONE, SOME _) = LESS
  1151   | option_ord _ (SOME _, NONE) = GREATER;
  1152 
  1153 (*lexicographic product*)
  1154 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1155   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1156 
  1157 (*dictionary order -- in general NOT well-founded!*)
  1158 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1159       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1160   | dict_ord _ ([], []) = EQUAL
  1161   | dict_ord _ ([], _ :: _) = LESS
  1162   | dict_ord _ (_ :: _, []) = GREATER;
  1163 
  1164 (*lexicographic product of lists*)
  1165 fun list_ord elem_ord (xs, ys) =
  1166   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1167 
  1168 
  1169 (* sorting *)
  1170 
  1171 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1172 fun quicksort unique ord =
  1173   let
  1174     fun qsort [] = []
  1175       | qsort (xs as [_]) = xs
  1176       | qsort (xs as [x, y]) =
  1177           (case ord (x, y) of
  1178             LESS => xs
  1179           | EQUAL => if unique then [x] else xs
  1180           | GREATER => [y, x])
  1181       | qsort xs =
  1182           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1183           in qsort lts @ eqs @ qsort gts end
  1184     and part _ [] = ([], [], [])
  1185       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1186     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1187       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1188       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1189       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1190   in qsort end;
  1191 
  1192 fun sort ord = quicksort false ord;
  1193 fun sort_distinct ord = quicksort true ord;
  1194 
  1195 val sort_strings = sort string_ord;
  1196 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1197 
  1198 
  1199 
  1200 (** random numbers **)
  1201 
  1202 exception RANDOM;
  1203 
  1204 fun rmod x y = x - y * Real.realFloor (x / y);
  1205 
  1206 local
  1207   val a = 16807.0;
  1208   val m = 2147483647.0;
  1209   val random_seed = ref 1.0;
  1210 in
  1211 
  1212 fun random () =
  1213   let val r = rmod (a * !random_seed) m
  1214   in (random_seed := r; r) end;
  1215 
  1216 end;
  1217 
  1218 fun random_range l h =
  1219   if h < l orelse l < 0 then raise RANDOM
  1220   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1221 
  1222 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1223 
  1224 fun frequency xs =
  1225   let
  1226     val sum = foldl op + (0, map fst xs);
  1227     fun pick n ((k: int, x) :: xs) =
  1228       if n <= k then x else pick (n - k) xs
  1229   in pick (random_range 1 sum) xs end;
  1230 
  1231 
  1232 (** current directory **)
  1233 
  1234 val cd = OS.FileSys.chDir;
  1235 val pwd = OS.FileSys.getDir;
  1236 
  1237 
  1238 
  1239 (** misc **)
  1240 
  1241 fun divide_and_conquer decomp x =
  1242   let val (ys, recomb) = decomp x
  1243   in recomb (map (divide_and_conquer decomp) ys) end;
  1244 
  1245 
  1246 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1247    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1248 fun partition_list p i j =
  1249   let fun part k xs =
  1250             if k>j then
  1251               (case xs of [] => []
  1252                          | _ => raise Fail "partition_list")
  1253             else
  1254             let val (ns, rest) = List.partition (p k) xs;
  1255             in  ns :: part(k+1)rest  end
  1256   in  part i end;
  1257 
  1258 fun partition_eq (eq:'a * 'a -> bool) =
  1259   let
  1260     fun part [] = []
  1261       | part (x :: ys) =
  1262           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1263           in (x::xs)::(part xs') end
  1264   in part end;
  1265 
  1266 
  1267 
  1268 (* generating identifiers *)
  1269 
  1270 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1271 local
  1272 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1273 fun char i =      if i<26 then chr (ord "A" + i)
  1274              else if i<52 then chr (ord "a" + i - 26)
  1275              else if i<62 then chr (ord"0" + i - 52)
  1276              else if i=62 then "_"
  1277              else  (*i=63*)    "'";
  1278 
  1279 val charVec = Vector.tabulate (64, char);
  1280 
  1281 fun newid n =
  1282   let
  1283   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1284 
  1285 val seedr = ref 0;
  1286 
  1287 in
  1288 
  1289 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1290 
  1291 end;
  1292 
  1293 
  1294 (* lexical scanning *)
  1295 
  1296 (*scan a list of characters into "words" composed of "letters" (recognized by
  1297   is_let) and separated by any number of non-"letters"*)
  1298 fun scanwords is_let cs =
  1299   let fun scan1 [] = []
  1300         | scan1 cs =
  1301             let val (lets, rest) = take_prefix is_let cs
  1302             in implode lets :: scanwords is_let rest end;
  1303   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1304 
  1305 
  1306 (* stamps and serial numbers *)
  1307 
  1308 type stamp = unit ref;
  1309 val stamp: unit -> stamp = ref;
  1310 
  1311 type serial = int;
  1312 local val count = ref 0
  1313 in fun serial () = inc count end;
  1314 
  1315 val serial_string = string_of_int o serial;
  1316 
  1317 
  1318 (* generic objects *)
  1319 
  1320 (*note that the builtin exception datatype may be extended by new
  1321   constructors at any time*)
  1322 structure Object = struct type T = exn end;
  1323 
  1324 end;
  1325 
  1326 structure BasicLibrary: BASIC_LIBRARY = Library;
  1327 open BasicLibrary;