src/HOL/Relation.thy
author Andreas Lochbihler
Wed Feb 11 14:07:28 2015 +0100 (2015-02-11)
changeset 59518 28cfc60dea7a
parent 58889 5b7a9633cfa8
child 60057 86fa63ce8156
permissions -rw-r--r--
add lemma
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 section {* Relations -- as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare Inf1_I [intro!]
    34 declare INF1_I [intro!]
    35 declare Inf2_I [intro!]
    36 declare INF2_I [intro!]
    37 declare Inf1_D [elim]
    38 declare INF1_D [elim]
    39 declare Inf2_D [elim]
    40 declare INF2_D [elim]
    41 declare Inf1_E [elim]
    42 declare INF1_E [elim]
    43 declare Inf2_E [elim]
    44 declare INF2_E [elim]
    45 declare Sup1_I [intro]
    46 declare SUP1_I [intro]
    47 declare Sup2_I [intro]
    48 declare SUP2_I [intro]
    49 declare Sup1_E [elim!]
    50 declare SUP1_E [elim!]
    51 declare Sup2_E [elim!]
    52 declare SUP2_E [elim!]
    53 
    54 subsection {* Fundamental *}
    55 
    56 subsubsection {* Relations as sets of pairs *}
    57 
    58 type_synonym 'a rel = "('a * 'a) set"
    59 
    60 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    61   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    62   by auto
    63 
    64 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    65   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    66     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    67   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    68 
    69 
    70 subsubsection {* Conversions between set and predicate relations *}
    71 
    72 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    73   by (simp add: set_eq_iff fun_eq_iff)
    74 
    75 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    79   by (simp add: subset_iff le_fun_def)
    80 
    81 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    85   by (auto simp add: fun_eq_iff)
    86 
    87 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    97   by (simp add: inf_fun_def)
    98 
    99 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   103   by (simp add: sup_fun_def)
   104 
   105 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   109   by (simp add: fun_eq_iff)
   110 
   111 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   142   by (simp add: fun_eq_iff)
   143 
   144 subsection {* Properties of relations *}
   145 
   146 subsubsection {* Reflexivity *}
   147 
   148 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   149 where
   150   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   151 
   152 abbreviation refl :: "'a rel \<Rightarrow> bool"
   153 where -- {* reflexivity over a type *}
   154   "refl \<equiv> refl_on UNIV"
   155 
   156 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   157 where
   158   "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   159 
   160 lemma reflp_refl_eq [pred_set_conv]:
   161   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   165   by (unfold refl_on_def) (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   168   by (unfold refl_on_def) blast
   169 
   170 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   171   by (unfold refl_on_def) blast
   172 
   173 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   174   by (unfold refl_on_def) blast
   175 
   176 lemma reflpI:
   177   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   178   by (auto intro: refl_onI simp add: reflp_def)
   179 
   180 lemma reflpE:
   181   assumes "reflp r"
   182   obtains "r x x"
   183   using assms by (auto dest: refl_onD simp add: reflp_def)
   184 
   185 lemma reflpD:
   186   assumes "reflp r"
   187   shows "r x x"
   188   using assms by (auto elim: reflpE)
   189 
   190 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   191   by (unfold refl_on_def) blast
   192 
   193 lemma reflp_inf:
   194   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   195   by (auto intro: reflpI elim: reflpE)
   196 
   197 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   198   by (unfold refl_on_def) blast
   199 
   200 lemma reflp_sup:
   201   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   202   by (auto intro: reflpI elim: reflpE)
   203 
   204 lemma refl_on_INTER:
   205   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   206   by (unfold refl_on_def) fast
   207 
   208 lemma refl_on_UNION:
   209   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   210   by (unfold refl_on_def) blast
   211 
   212 lemma refl_on_empty [simp]: "refl_on {} {}"
   213   by (simp add:refl_on_def)
   214 
   215 lemma refl_on_def' [nitpick_unfold, code]:
   216   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   217   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   218 
   219 
   220 subsubsection {* Irreflexivity *}
   221 
   222 definition irrefl :: "'a rel \<Rightarrow> bool"
   223 where
   224   "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   225 
   226 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   227 where
   228   "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   229 
   230 lemma irreflp_irrefl_eq [pred_set_conv]:
   231   "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R" 
   232   by (simp add: irrefl_def irreflp_def)
   233 
   234 lemma irreflI:
   235   "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   236   by (simp add: irrefl_def)
   237 
   238 lemma irreflpI:
   239   "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   240   by (fact irreflI [to_pred])
   241 
   242 lemma irrefl_distinct [code]:
   243   "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   244   by (auto simp add: irrefl_def)
   245 
   246 
   247 subsubsection {* Asymmetry *}
   248 
   249 inductive asym :: "'a rel \<Rightarrow> bool"
   250 where
   251   asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   252 
   253 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   254 where
   255   asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   256 
   257 lemma asymp_asym_eq [pred_set_conv]:
   258   "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R" 
   259   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   260 
   261 
   262 subsubsection {* Symmetry *}
   263 
   264 definition sym :: "'a rel \<Rightarrow> bool"
   265 where
   266   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   267 
   268 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   269 where
   270   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   271 
   272 lemma symp_sym_eq [pred_set_conv]:
   273   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   274   by (simp add: sym_def symp_def)
   275 
   276 lemma symI:
   277   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   278   by (unfold sym_def) iprover
   279 
   280 lemma sympI:
   281   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   282   by (fact symI [to_pred])
   283 
   284 lemma symE:
   285   assumes "sym r" and "(b, a) \<in> r"
   286   obtains "(a, b) \<in> r"
   287   using assms by (simp add: sym_def)
   288 
   289 lemma sympE:
   290   assumes "symp r" and "r b a"
   291   obtains "r a b"
   292   using assms by (rule symE [to_pred])
   293 
   294 lemma symD:
   295   assumes "sym r" and "(b, a) \<in> r"
   296   shows "(a, b) \<in> r"
   297   using assms by (rule symE)
   298 
   299 lemma sympD:
   300   assumes "symp r" and "r b a"
   301   shows "r a b"
   302   using assms by (rule symD [to_pred])
   303 
   304 lemma sym_Int:
   305   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   306   by (fast intro: symI elim: symE)
   307 
   308 lemma symp_inf:
   309   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   310   by (fact sym_Int [to_pred])
   311 
   312 lemma sym_Un:
   313   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   314   by (fast intro: symI elim: symE)
   315 
   316 lemma symp_sup:
   317   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   318   by (fact sym_Un [to_pred])
   319 
   320 lemma sym_INTER:
   321   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   322   by (fast intro: symI elim: symE)
   323 
   324 lemma symp_INF:
   325   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   326   by (fact sym_INTER [to_pred])
   327 
   328 lemma sym_UNION:
   329   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   330   by (fast intro: symI elim: symE)
   331 
   332 lemma symp_SUP:
   333   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   334   by (fact sym_UNION [to_pred])
   335 
   336 
   337 subsubsection {* Antisymmetry *}
   338 
   339 definition antisym :: "'a rel \<Rightarrow> bool"
   340 where
   341   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   342 
   343 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   344 where
   345   "antisymP r \<equiv> antisym {(x, y). r x y}"
   346 
   347 lemma antisymI:
   348   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   349   by (unfold antisym_def) iprover
   350 
   351 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   352   by (unfold antisym_def) iprover
   353 
   354 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   355   by (unfold antisym_def) blast
   356 
   357 lemma antisym_empty [simp]: "antisym {}"
   358   by (unfold antisym_def) blast
   359 
   360 
   361 subsubsection {* Transitivity *}
   362 
   363 definition trans :: "'a rel \<Rightarrow> bool"
   364 where
   365   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   366 
   367 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   368 where
   369   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   370 
   371 lemma transp_trans_eq [pred_set_conv]:
   372   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   373   by (simp add: trans_def transp_def)
   374 
   375 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   376 where -- {* FIXME drop *}
   377   "transP r \<equiv> trans {(x, y). r x y}"
   378 
   379 lemma transI:
   380   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   381   by (unfold trans_def) iprover
   382 
   383 lemma transpI:
   384   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   385   by (fact transI [to_pred])
   386 
   387 lemma transE:
   388   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   389   obtains "(x, z) \<in> r"
   390   using assms by (unfold trans_def) iprover
   391 
   392 lemma transpE:
   393   assumes "transp r" and "r x y" and "r y z"
   394   obtains "r x z"
   395   using assms by (rule transE [to_pred])
   396 
   397 lemma transD:
   398   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   399   shows "(x, z) \<in> r"
   400   using assms by (rule transE)
   401 
   402 lemma transpD:
   403   assumes "transp r" and "r x y" and "r y z"
   404   shows "r x z"
   405   using assms by (rule transD [to_pred])
   406 
   407 lemma trans_Int:
   408   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   409   by (fast intro: transI elim: transE)
   410 
   411 lemma transp_inf:
   412   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   413   by (fact trans_Int [to_pred])
   414 
   415 lemma trans_INTER:
   416   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   417   by (fast intro: transI elim: transD)
   418 
   419 (* FIXME thm trans_INTER [to_pred] *)
   420 
   421 lemma trans_join [code]:
   422   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   423   by (auto simp add: trans_def)
   424 
   425 lemma transp_trans:
   426   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   427   by (simp add: trans_def transp_def)
   428 
   429 lemma transp_equality [simp]: "transp op ="
   430 by(auto intro: transpI)
   431 
   432 subsubsection {* Totality *}
   433 
   434 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   435 where
   436   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   437 
   438 abbreviation "total \<equiv> total_on UNIV"
   439 
   440 lemma total_on_empty [simp]: "total_on {} r"
   441   by (simp add: total_on_def)
   442 
   443 
   444 subsubsection {* Single valued relations *}
   445 
   446 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   447 where
   448   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   449 
   450 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   451   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   452 
   453 lemma single_valuedI:
   454   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   455   by (unfold single_valued_def)
   456 
   457 lemma single_valuedD:
   458   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   459   by (simp add: single_valued_def)
   460 
   461 lemma single_valued_empty[simp]: "single_valued {}"
   462 by(simp add: single_valued_def)
   463 
   464 lemma single_valued_subset:
   465   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   466   by (unfold single_valued_def) blast
   467 
   468 
   469 subsection {* Relation operations *}
   470 
   471 subsubsection {* The identity relation *}
   472 
   473 definition Id :: "'a rel"
   474 where
   475   [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   476 
   477 lemma IdI [intro]: "(a, a) : Id"
   478   by (simp add: Id_def)
   479 
   480 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   481   by (unfold Id_def) (iprover elim: CollectE)
   482 
   483 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   484   by (unfold Id_def) blast
   485 
   486 lemma refl_Id: "refl Id"
   487   by (simp add: refl_on_def)
   488 
   489 lemma antisym_Id: "antisym Id"
   490   -- {* A strange result, since @{text Id} is also symmetric. *}
   491   by (simp add: antisym_def)
   492 
   493 lemma sym_Id: "sym Id"
   494   by (simp add: sym_def)
   495 
   496 lemma trans_Id: "trans Id"
   497   by (simp add: trans_def)
   498 
   499 lemma single_valued_Id [simp]: "single_valued Id"
   500   by (unfold single_valued_def) blast
   501 
   502 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   503   by (simp add:irrefl_def)
   504 
   505 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   506   unfolding antisym_def trans_def by blast
   507 
   508 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   509   by (simp add: total_on_def)
   510 
   511 
   512 subsubsection {* Diagonal: identity over a set *}
   513 
   514 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   515 where
   516   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   517 
   518 lemma Id_on_empty [simp]: "Id_on {} = {}"
   519   by (simp add: Id_on_def) 
   520 
   521 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   522   by (simp add: Id_on_def)
   523 
   524 lemma Id_onI [intro!]: "a : A ==> (a, a) : Id_on A"
   525   by (rule Id_on_eqI) (rule refl)
   526 
   527 lemma Id_onE [elim!]:
   528   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   529   -- {* The general elimination rule. *}
   530   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   531 
   532 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   533   by blast
   534 
   535 lemma Id_on_def' [nitpick_unfold]:
   536   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   537   by auto
   538 
   539 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   540   by blast
   541 
   542 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   543   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   544 
   545 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   546   by (unfold antisym_def) blast
   547 
   548 lemma sym_Id_on [simp]: "sym (Id_on A)"
   549   by (rule symI) clarify
   550 
   551 lemma trans_Id_on [simp]: "trans (Id_on A)"
   552   by (fast intro: transI elim: transD)
   553 
   554 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   555   by (unfold single_valued_def) blast
   556 
   557 
   558 subsubsection {* Composition *}
   559 
   560 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   561   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   562 where
   563   relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   564 
   565 notation relcompp (infixr "OO" 75)
   566 
   567 lemmas relcomppI = relcompp.intros
   568 
   569 text {*
   570   For historic reasons, the elimination rules are not wholly corresponding.
   571   Feel free to consolidate this.
   572 *}
   573 
   574 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   575 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   576 
   577 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   578   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   579   by (cases xz) (simp, erule relcompEpair, iprover)
   580 
   581 lemma R_O_Id [simp]:
   582   "R O Id = R"
   583   by fast
   584 
   585 lemma Id_O_R [simp]:
   586   "Id O R = R"
   587   by fast
   588 
   589 lemma relcomp_empty1 [simp]:
   590   "{} O R = {}"
   591   by blast
   592 
   593 lemma relcompp_bot1 [simp]:
   594   "\<bottom> OO R = \<bottom>"
   595   by (fact relcomp_empty1 [to_pred])
   596 
   597 lemma relcomp_empty2 [simp]:
   598   "R O {} = {}"
   599   by blast
   600 
   601 lemma relcompp_bot2 [simp]:
   602   "R OO \<bottom> = \<bottom>"
   603   by (fact relcomp_empty2 [to_pred])
   604 
   605 lemma O_assoc:
   606   "(R O S) O T = R O (S O T)"
   607   by blast
   608 
   609 lemma relcompp_assoc:
   610   "(r OO s) OO t = r OO (s OO t)"
   611   by (fact O_assoc [to_pred])
   612 
   613 lemma trans_O_subset:
   614   "trans r \<Longrightarrow> r O r \<subseteq> r"
   615   by (unfold trans_def) blast
   616 
   617 lemma transp_relcompp_less_eq:
   618   "transp r \<Longrightarrow> r OO r \<le> r "
   619   by (fact trans_O_subset [to_pred])
   620 
   621 lemma relcomp_mono:
   622   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   623   by blast
   624 
   625 lemma relcompp_mono:
   626   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   627   by (fact relcomp_mono [to_pred])
   628 
   629 lemma relcomp_subset_Sigma:
   630   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   631   by blast
   632 
   633 lemma relcomp_distrib [simp]:
   634   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   635   by auto
   636 
   637 lemma relcompp_distrib [simp]:
   638   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   639   by (fact relcomp_distrib [to_pred])
   640 
   641 lemma relcomp_distrib2 [simp]:
   642   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   643   by auto
   644 
   645 lemma relcompp_distrib2 [simp]:
   646   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   647   by (fact relcomp_distrib2 [to_pred])
   648 
   649 lemma relcomp_UNION_distrib:
   650   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   651   by auto
   652 
   653 (* FIXME thm relcomp_UNION_distrib [to_pred] *)
   654 
   655 lemma relcomp_UNION_distrib2:
   656   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   657   by auto
   658 
   659 (* FIXME thm relcomp_UNION_distrib2 [to_pred] *)
   660 
   661 lemma single_valued_relcomp:
   662   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   663   by (unfold single_valued_def) blast
   664 
   665 lemma relcomp_unfold:
   666   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   667   by (auto simp add: set_eq_iff)
   668 
   669 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   670   unfolding relcomp_unfold [to_pred] ..
   671 
   672 lemma eq_OO: "op= OO R = R"
   673 by blast
   674 
   675 
   676 subsubsection {* Converse *}
   677 
   678 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   679   for r :: "('a \<times> 'b) set"
   680 where
   681   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   682 
   683 notation (xsymbols)
   684   converse  ("(_\<inverse>)" [1000] 999)
   685 
   686 notation
   687   conversep ("(_^--1)" [1000] 1000)
   688 
   689 notation (xsymbols)
   690   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   691 
   692 lemma converseI [sym]:
   693   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   694   by (fact converse.intros)
   695 
   696 lemma conversepI (* CANDIDATE [sym] *):
   697   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   698   by (fact conversep.intros)
   699 
   700 lemma converseD [sym]:
   701   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   702   by (erule converse.cases) iprover
   703 
   704 lemma conversepD (* CANDIDATE [sym] *):
   705   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   706   by (fact converseD [to_pred])
   707 
   708 lemma converseE [elim!]:
   709   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   710   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   711   by (cases yx) (simp, erule converse.cases, iprover)
   712 
   713 lemmas conversepE [elim!] = conversep.cases
   714 
   715 lemma converse_iff [iff]:
   716   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   717   by (auto intro: converseI)
   718 
   719 lemma conversep_iff [iff]:
   720   "r\<inverse>\<inverse> a b = r b a"
   721   by (fact converse_iff [to_pred])
   722 
   723 lemma converse_converse [simp]:
   724   "(r\<inverse>)\<inverse> = r"
   725   by (simp add: set_eq_iff)
   726 
   727 lemma conversep_conversep [simp]:
   728   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   729   by (fact converse_converse [to_pred])
   730 
   731 lemma converse_empty[simp]: "{}\<inverse> = {}"
   732 by auto
   733 
   734 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   735 by auto
   736 
   737 lemma converse_relcomp: "(r O s)^-1 = s^-1 O r^-1"
   738   by blast
   739 
   740 lemma converse_relcompp: "(r OO s)^--1 = s^--1 OO r^--1"
   741   by (iprover intro: order_antisym conversepI relcomppI
   742     elim: relcomppE dest: conversepD)
   743 
   744 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   745   by blast
   746 
   747 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   748   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   749 
   750 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   751   by blast
   752 
   753 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   754   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   755 
   756 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   757   by fast
   758 
   759 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   760   by blast
   761 
   762 lemma converse_mono[simp]: "r^-1 \<subseteq> s ^-1 \<longleftrightarrow> r \<subseteq> s"
   763   by auto
   764 
   765 lemma conversep_mono[simp]: "r^--1 \<le> s ^--1 \<longleftrightarrow> r \<le> s"
   766   by (fact converse_mono[to_pred])
   767 
   768 lemma converse_inject[simp]: "r^-1 = s ^-1 \<longleftrightarrow> r = s"
   769   by auto
   770 
   771 lemma conversep_inject[simp]: "r^--1 = s ^--1 \<longleftrightarrow> r = s"
   772   by (fact converse_inject[to_pred])
   773 
   774 lemma converse_subset_swap: "r \<subseteq> s ^-1 = (r ^-1 \<subseteq> s)"
   775   by auto
   776 
   777 lemma conversep_le_swap: "r \<le> s ^--1 = (r ^--1 \<le> s)"
   778   by (fact converse_subset_swap[to_pred])
   779 
   780 lemma converse_Id [simp]: "Id^-1 = Id"
   781   by blast
   782 
   783 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   784   by blast
   785 
   786 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   787   by (unfold refl_on_def) auto
   788 
   789 lemma sym_converse [simp]: "sym (converse r) = sym r"
   790   by (unfold sym_def) blast
   791 
   792 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   793   by (unfold antisym_def) blast
   794 
   795 lemma trans_converse [simp]: "trans (converse r) = trans r"
   796   by (unfold trans_def) blast
   797 
   798 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   799   by (unfold sym_def) fast
   800 
   801 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   802   by (unfold sym_def) blast
   803 
   804 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   805   by (unfold sym_def) blast
   806 
   807 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   808   by (auto simp: total_on_def)
   809 
   810 lemma finite_converse [iff]: "finite (r^-1) = finite r"  
   811   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   812   by (auto elim: finite_imageD simp: inj_on_def)
   813 
   814 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   815   by (auto simp add: fun_eq_iff)
   816 
   817 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   818   by (auto simp add: fun_eq_iff)
   819 
   820 lemma converse_unfold [code]:
   821   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   822   by (simp add: set_eq_iff)
   823 
   824 
   825 subsubsection {* Domain, range and field *}
   826 
   827 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   828   for r :: "('a \<times> 'b) set"
   829 where
   830   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   831 
   832 abbreviation (input) "DomainP \<equiv> Domainp"
   833 
   834 lemmas DomainPI = Domainp.DomainI
   835 
   836 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   837 inductive_cases DomainpE [elim!]: "Domainp r a"
   838 
   839 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   840   for r :: "('a \<times> 'b) set"
   841 where
   842   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   843 
   844 abbreviation (input) "RangeP \<equiv> Rangep"
   845 
   846 lemmas RangePI = Rangep.RangeI
   847 
   848 inductive_cases RangeE [elim!]: "b \<in> Range r"
   849 inductive_cases RangepE [elim!]: "Rangep r b"
   850 
   851 definition Field :: "'a rel \<Rightarrow> 'a set"
   852 where
   853   "Field r = Domain r \<union> Range r"
   854 
   855 lemma Domain_fst [code]:
   856   "Domain r = fst ` r"
   857   by force
   858 
   859 lemma Range_snd [code]:
   860   "Range r = snd ` r"
   861   by force
   862 
   863 lemma fst_eq_Domain: "fst ` R = Domain R"
   864   by force
   865 
   866 lemma snd_eq_Range: "snd ` R = Range R"
   867   by force
   868 
   869 lemma Domain_empty [simp]: "Domain {} = {}"
   870   by auto
   871 
   872 lemma Range_empty [simp]: "Range {} = {}"
   873   by auto
   874 
   875 lemma Field_empty [simp]: "Field {} = {}"
   876   by (simp add: Field_def)
   877 
   878 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   879   by auto
   880 
   881 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   882   by auto
   883 
   884 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   885   by blast
   886 
   887 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   888   by blast
   889 
   890 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   891   by (auto simp add: Field_def)
   892 
   893 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   894   by blast
   895 
   896 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   897   by blast
   898 
   899 lemma Domain_Id [simp]: "Domain Id = UNIV"
   900   by blast
   901 
   902 lemma Range_Id [simp]: "Range Id = UNIV"
   903   by blast
   904 
   905 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   906   by blast
   907 
   908 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   909   by blast
   910 
   911 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   912   by blast
   913 
   914 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   915   by blast
   916 
   917 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   918   by (auto simp: Field_def)
   919 
   920 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   921   by blast
   922 
   923 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   924   by blast
   925 
   926 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   927   by blast
   928 
   929 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   930   by blast
   931 
   932 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   933   by blast
   934 
   935 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   936   by blast
   937 
   938 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   939   by (auto simp: Field_def)
   940 
   941 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   942   by auto
   943 
   944 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   945   by blast
   946 
   947 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   948   by (auto simp: Field_def)
   949 
   950 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   951   by auto
   952 
   953 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   954   by auto
   955 
   956 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   957   by (induct set: finite) auto
   958 
   959 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   960   by (induct set: finite) auto
   961 
   962 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   963   by (simp add: Field_def finite_Domain finite_Range)
   964 
   965 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   966   by blast
   967 
   968 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   969   by blast
   970 
   971 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   972   by (auto simp: Field_def Domain_def Range_def)
   973 
   974 lemma Domain_unfold:
   975   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   976   by blast
   977 
   978 
   979 subsubsection {* Image of a set under a relation *}
   980 
   981 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixr "``" 90)
   982 where
   983   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   984 
   985 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   986   by (simp add: Image_def)
   987 
   988 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   989   by (simp add: Image_def)
   990 
   991 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   992   by (rule Image_iff [THEN trans]) simp
   993 
   994 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
   995   by (unfold Image_def) blast
   996 
   997 lemma ImageE [elim!]:
   998   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   999   by (unfold Image_def) (iprover elim!: CollectE bexE)
  1000 
  1001 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
  1002   -- {* This version's more effective when we already have the required @{text a} *}
  1003   by blast
  1004 
  1005 lemma Image_empty [simp]: "R``{} = {}"
  1006   by blast
  1007 
  1008 lemma Image_Id [simp]: "Id `` A = A"
  1009   by blast
  1010 
  1011 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1012   by blast
  1013 
  1014 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1015   by blast
  1016 
  1017 lemma Image_Int_eq:
  1018   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1019   by (simp add: single_valued_def, blast) 
  1020 
  1021 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1022   by blast
  1023 
  1024 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1025   by blast
  1026 
  1027 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
  1028   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1029 
  1030 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1031   -- {* NOT suitable for rewriting *}
  1032   by blast
  1033 
  1034 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
  1035   by blast
  1036 
  1037 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1038   by blast
  1039 
  1040 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1041   by auto
  1042 
  1043 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1044   by blast
  1045 
  1046 text{*Converse inclusion requires some assumptions*}
  1047 lemma Image_INT_eq:
  1048      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1049 apply (rule equalityI)
  1050  apply (rule Image_INT_subset) 
  1051 apply  (simp add: single_valued_def, blast)
  1052 done
  1053 
  1054 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
  1055   by blast
  1056 
  1057 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1058   by auto
  1059 
  1060 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1061   by auto
  1062 
  1063 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1064   by auto
  1065 
  1066 subsubsection {* Inverse image *}
  1067 
  1068 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1069 where
  1070   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1071 
  1072 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1073 where
  1074   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1075 
  1076 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1077   by (simp add: inv_image_def inv_imagep_def)
  1078 
  1079 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1080   by (unfold sym_def inv_image_def) blast
  1081 
  1082 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1083   apply (unfold trans_def inv_image_def)
  1084   apply (simp (no_asm))
  1085   apply blast
  1086   done
  1087 
  1088 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1089   by (auto simp:inv_image_def)
  1090 
  1091 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1092   unfolding inv_image_def converse_unfold by auto
  1093 
  1094 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1095   by (simp add: inv_imagep_def)
  1096 
  1097 
  1098 subsubsection {* Powerset *}
  1099 
  1100 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1101 where
  1102   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1103 
  1104 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1105   by (auto simp add: Powp_def fun_eq_iff)
  1106 
  1107 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1108 
  1109 subsubsection {* Expressing relation operations via @{const Finite_Set.fold} *}
  1110 
  1111 lemma Id_on_fold:
  1112   assumes "finite A"
  1113   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1114 proof -
  1115   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)" by default auto
  1116   show ?thesis using assms unfolding Id_on_def by (induct A) simp_all
  1117 qed
  1118 
  1119 lemma comp_fun_commute_Image_fold:
  1120   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1121 proof -
  1122   interpret comp_fun_idem Set.insert
  1123       by (fact comp_fun_idem_insert)
  1124   show ?thesis 
  1125   by default (auto simp add: fun_eq_iff comp_fun_commute split:prod.split)
  1126 qed
  1127 
  1128 lemma Image_fold:
  1129   assumes "finite R"
  1130   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1131 proof -
  1132   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)" 
  1133     by (rule comp_fun_commute_Image_fold)
  1134   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1135     by (force intro: rev_ImageI)
  1136   show ?thesis using assms by (induct R) (auto simp: *)
  1137 qed
  1138 
  1139 lemma insert_relcomp_union_fold:
  1140   assumes "finite S"
  1141   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1142 proof -
  1143   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1144   proof - 
  1145     interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
  1146     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1147     by default (auto simp add: fun_eq_iff split:prod.split)
  1148   qed
  1149   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x,z) \<in> S}" by (auto simp: relcomp_unfold intro!: exI)
  1150   show ?thesis unfolding *
  1151   using `finite S` by (induct S) (auto split: prod.split)
  1152 qed
  1153 
  1154 lemma insert_relcomp_fold:
  1155   assumes "finite S"
  1156   shows "Set.insert x R O S = 
  1157     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1158 proof -
  1159   have "Set.insert x R O S = ({x} O S) \<union> (R O S)" by auto
  1160   then show ?thesis by (auto simp: insert_relcomp_union_fold[OF assms])
  1161 qed
  1162 
  1163 lemma comp_fun_commute_relcomp_fold:
  1164   assumes "finite S"
  1165   shows "comp_fun_commute (\<lambda>(x,y) A. 
  1166     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1167 proof -
  1168   have *: "\<And>a b A. 
  1169     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1170     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1171   show ?thesis by default (auto simp: *)
  1172 qed
  1173 
  1174 lemma relcomp_fold:
  1175   assumes "finite R"
  1176   assumes "finite S"
  1177   shows "R O S = Finite_Set.fold 
  1178     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1179   using assms by (induct R)
  1180     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1181       cong: if_cong)
  1182 
  1183 end