src/Pure/axclass.ML
author haftmann
Thu Dec 21 13:55:13 2006 +0100 (2006-12-21)
changeset 21893 29438dfa8a16
parent 21687 f689f729afab
child 21913 1224048fb8f9
permissions -rw-r--r--
code clarifications
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Type classes as parameter records and predicates, with explicit
     6 definitions and proofs.
     7 *)
     8 
     9 signature AX_CLASS =
    10 sig
    11   val get_definition: theory -> class -> {def: thm, intro: thm, axioms: thm list,
    12     params: (string * typ) list, operational: bool}
    13   val class_intros: theory -> thm list
    14   val class_of_param: theory -> string -> class option
    15   val params_of_class: theory -> class -> string * (string * typ) list
    16   val print_axclasses: theory -> unit
    17   val cert_classrel: theory -> class * class -> class * class
    18   val read_classrel: theory -> xstring * xstring -> class * class
    19   val add_classrel: thm -> theory -> theory
    20   val add_arity: thm -> theory -> theory
    21   val prove_classrel: class * class -> tactic -> theory -> theory
    22   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    23   val define_class: bstring * xstring list -> string list ->
    24     ((bstring * Attrib.src list) * string list) list -> theory -> class * theory
    25   val define_class_i: bstring * class list -> string list ->
    26     ((bstring * attribute list) * term list) list -> theory -> class * theory
    27   val axiomatize_class: bstring * xstring list -> theory -> theory
    28   val axiomatize_class_i: bstring * class list -> theory -> theory
    29   val axiomatize_classrel: (xstring * xstring) list -> theory -> theory
    30   val axiomatize_classrel_i: (class * class) list -> theory -> theory
    31   val axiomatize_arity: xstring * string list * string -> theory -> theory
    32   val axiomatize_arity_i: arity -> theory -> theory
    33   type cache
    34   val cache: cache
    35   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    36 end;
    37 
    38 structure AxClass: AX_CLASS =
    39 struct
    40 
    41 (** theory data **)
    42 
    43 (* class parameters (canonical order) *)
    44 
    45 type param = string * class;
    46 
    47 fun add_param pp ((x, c): param) params =
    48   (case AList.lookup (op =) params x of
    49     NONE => (x, c) :: params
    50   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    51       " for " ^ Pretty.string_of_sort pp [c] ^
    52       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    53 
    54 fun merge_params _ ([], qs) = qs
    55   | merge_params pp (ps, qs) =
    56       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    57 
    58 
    59 (* axclasses *)
    60 
    61 val introN = "intro";
    62 val superN = "super";
    63 val axiomsN = "axioms";
    64 
    65 val param_tyvarname = "'a";
    66 
    67 datatype axclass = AxClass of
    68  {def: thm,
    69   intro: thm,
    70   axioms: thm list,
    71   params: (string * typ) list,
    72   operational: bool (* == at least one class operation,
    73     or at least two operational superclasses *)};
    74 
    75 type axclasses = axclass Symtab.table * param list;
    76 
    77 fun make_axclass ((def, intro, axioms), (params, operational)) =
    78   AxClass {def = def, intro = intro, axioms = axioms, params = params,
    79     operational = operational};
    80 
    81 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    82   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    83 
    84 
    85 (* instances *)
    86 
    87 val classrel_prefix = "classrel_";
    88 val arity_prefix = "arity_";
    89 
    90 type instances =
    91   ((class * class) * thm) list *
    92   ((class * sort list) * thm) list Symtab.table;
    93 
    94 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    95  (merge (eq_fst op =) (classrel1, classrel2),
    96   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
    97 
    98 
    99 (* setup data *)
   100 
   101 structure AxClassData = TheoryDataFun
   102 (struct
   103   val name = "Pure/axclass";
   104   type T = axclasses * instances;
   105   val empty : T = ((Symtab.empty, []), ([], Symtab.empty));
   106   val copy = I;
   107   val extend = I;
   108   fun merge pp ((axclasses1, instances1), (axclasses2, instances2)) =
   109     (merge_axclasses pp (axclasses1, axclasses2), (merge_instances (instances1, instances2)));
   110   fun print _ _ = ();
   111 end);
   112 
   113 val _ = Context.add_setup AxClassData.init;
   114 
   115 
   116 (* maintain axclasses *)
   117 
   118 val get_axclasses = #1 o AxClassData.get;
   119 fun map_axclasses f = AxClassData.map (apfst f);
   120 
   121 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   122 
   123 fun get_definition thy c =
   124   (case lookup_def thy c of
   125     SOME (AxClass info) => info
   126   | NONE => error ("Undefined type class " ^ quote c));
   127 
   128 fun class_intros thy =
   129   let
   130     fun add_intro c =
   131       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   132     val classes = Sign.classes thy;
   133   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   134 
   135 
   136 fun get_params thy pred =
   137   let val params = #2 (get_axclasses thy);
   138   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   139 
   140 fun params_of thy c = get_params thy (fn c' => c' = c);
   141 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   142 
   143 fun class_of_param thy =
   144   AList.lookup (op =) (#2 (get_axclasses thy));
   145 
   146 fun params_of_class thy class =
   147   (param_tyvarname, (#params o get_definition thy) class);
   148 
   149 (* maintain instances *)
   150 
   151 val get_instances = #2 o AxClassData.get;
   152 fun map_instances f = AxClassData.map (apsnd f);
   153 
   154 
   155 fun the_classrel thy (c1, c2) =
   156   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   157     SOME th => Thm.transfer thy th
   158   | NONE => error ("Unproven class relation " ^ Sign.string_of_classrel thy [c1, c2]));
   159 
   160 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   161   (insert (eq_fst op =) arg classrel, arities));
   162 
   163 
   164 fun the_arity thy a (c, Ss) =
   165   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss)  of
   166     SOME th => Thm.transfer thy th
   167   | NONE => error ("Unproven type arity " ^ Sign.string_of_arity thy (a, Ss, [c])));
   168 
   169 fun put_arity ((t, Ss, c), th) = map_instances (fn (classrel, arities) =>
   170   (classrel, arities |> Symtab.insert_list (eq_fst op =) (t, ((c, Ss), th))));
   171 
   172 
   173 (* print data *)
   174 
   175 fun print_axclasses thy =
   176   let
   177     val axclasses = #1 (get_axclasses thy);
   178     val ctxt = ProofContext.init thy;
   179 
   180     fun pretty_axclass (class, AxClass {def, intro, axioms, params, operational}) =
   181       Pretty.block (Pretty.fbreaks
   182        [Pretty.block
   183           [Pretty.str "class ", ProofContext.pretty_sort ctxt [class], Pretty.str ":"],
   184         Pretty.strs ("parameters:" :: params_of thy class),
   185         ProofContext.pretty_fact ctxt ("def", [def]),
   186         ProofContext.pretty_fact ctxt (introN, [intro]),
   187         ProofContext.pretty_fact ctxt (axiomsN, axioms)]);
   188   in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest axclasses))) end;
   189 
   190 
   191 
   192 (** instances **)
   193 
   194 (* class relations *)
   195 
   196 fun cert_classrel thy raw_rel =
   197   let
   198     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   199     val _ = Type.add_classrel (Sign.pp thy) (c1, c2) (Sign.tsig_of thy);
   200     val _ =
   201       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   202         [] => ()
   203       | xs => raise TYPE ("Class " ^ Sign.string_of_sort thy [c1] ^ " lacks parameter(s) " ^
   204           commas_quote xs ^ " of " ^ Sign.string_of_sort thy [c2], [], []));
   205   in (c1, c2) end;
   206 
   207 fun read_classrel thy raw_rel =
   208   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   209     handle TYPE (msg, _, _) => error msg;
   210 
   211 
   212 (* primitive rules *)
   213 
   214 fun add_classrel th thy =
   215   let
   216     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   217     val prop = Drule.plain_prop_of (Thm.transfer thy th);
   218     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   219     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   220   in
   221     thy
   222     |> Sign.primitive_classrel (c1, c2)
   223     |> put_classrel ((c1, c2), Drule.unconstrainTs th)
   224   end;
   225 
   226 fun add_arity th thy =
   227   let
   228     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   229     val prop = Drule.plain_prop_of (Thm.transfer thy th);
   230     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   231     val _ = if map (Sign.certify_sort thy) Ss = Ss then () else err ();
   232   in
   233     thy
   234     |> Sign.primitive_arity (t, Ss, [c])
   235     |> put_arity ((t, Ss, c), Drule.unconstrainTs th)
   236   end;
   237 
   238 
   239 (* tactical proofs *)
   240 
   241 fun prove_classrel raw_rel tac thy =
   242   let
   243     val (c1, c2) = cert_classrel thy raw_rel;
   244     val th = Goal.prove (ProofContext.init thy) [] []
   245         (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
   246       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   247         quote (Sign.string_of_classrel thy [c1, c2]));
   248   in
   249     thy
   250     |> PureThy.add_thms [((prefix classrel_prefix (Logic.name_classrel (c1, c2)), th), [])]
   251     |-> (fn [th'] => add_classrel th')
   252   end;
   253 
   254 fun prove_arity raw_arity tac thy =
   255   let
   256     val arity = Sign.cert_arity thy raw_arity;
   257     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   258     val props = Logic.mk_arities arity;
   259     val ths = Goal.prove_multi (ProofContext.init thy) [] [] props
   260       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   261         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   262           quote (Sign.string_of_arity thy arity));
   263   in
   264     thy
   265     |> PureThy.add_thms (map (rpair []) (names ~~ ths))
   266     |-> fold add_arity
   267   end;
   268 
   269 
   270 
   271 (** class definitions **)
   272 
   273 local
   274 
   275 fun read_param thy raw_t =
   276   let
   277     val t = Sign.read_term thy raw_t
   278   in case try dest_Const t
   279    of SOME (c, _) => c
   280     | NONE => error ("Not a constant: " ^ Sign.string_of_term thy t)
   281   end;
   282 
   283 fun def_class prep_class prep_att prep_param prep_propp
   284     (bclass, raw_super) raw_params raw_specs thy =
   285   let
   286     val ctxt = ProofContext.init thy;
   287     val pp = ProofContext.pp ctxt;
   288 
   289 
   290     (* prepare specification *)
   291 
   292     val bconst = Logic.const_of_class bclass;
   293     val class = Sign.full_name thy bclass;
   294     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
   295 
   296     fun prep_axiom t =
   297       (case Term.add_tfrees t [] of
   298         [(a, S)] =>
   299           if Sign.subsort thy (super, S) then t
   300           else error ("Sort constraint of type variable " ^
   301             setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   302             " needs to be weaker than " ^ Pretty.string_of_sort pp super)
   303       | [] => t
   304       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t))
   305       |> map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   306       |> Logic.close_form;
   307 
   308     val axiomss = prep_propp (ctxt, map (map (rpair []) o snd) raw_specs)
   309       |> snd |> map (map (prep_axiom o fst));
   310     val name_atts = Attrib.map_specs (prep_att thy) raw_specs |> map fst;
   311 
   312 
   313     (* definition *)
   314 
   315     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
   316     val class_eq =
   317       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_list conjs);
   318 
   319     val ([def], def_thy) =
   320       thy
   321       |> Sign.primitive_class (bclass, super)
   322       |> PureThy.add_defs_i false [((Thm.def_name bconst, class_eq), [])];
   323     val (raw_intro, (raw_classrel, raw_axioms)) =
   324       (Conjunction.split_defined (length conjs) def) ||> chop (length super);
   325 
   326 
   327     (* facts *)
   328 
   329     val class_triv = Thm.class_triv def_thy class;
   330     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   331       def_thy
   332       |> PureThy.note_thmss_qualified "" bconst
   333         [((introN, []), [([Drule.standard raw_intro], [])]),
   334          ((superN, []), [(map Drule.standard raw_classrel, [])]),
   335          ((axiomsN, []), [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])];
   336 
   337     (* params *)
   338 
   339     val params = map (prep_param thy) raw_params;
   340     val params_typs = map (fn param =>
   341       let
   342         val ty = Sign.the_const_type thy param;
   343         val _ = case Term.typ_tvars ty
   344          of [_] => ()
   345           | _ => error ("exactly one type variable required in parameter " ^ quote param);
   346         val ty' = Term.map_type_tvar (fn _ => TFree (param_tyvarname, [class])) ty;
   347       in (param, ty') end) params;
   348     val operational = length params_typs > 0 orelse
   349       length (filter (the_default false o Option.map
   350         (fn AxClass { operational, ... } => operational) o lookup_def thy) super) > 1;
   351 
   352     (* result *)
   353 
   354     val result_thy =
   355       facts_thy
   356       |> fold put_classrel (map (pair class) super ~~ classrel)
   357       |> Sign.add_path bconst
   358       |> PureThy.note_thmss_i "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   359       |> Sign.restore_naming facts_thy
   360       |> map_axclasses (fn (axclasses, parameters) =>
   361         (Symtab.update (class, make_axclass ((def, intro, axioms), (params_typs, operational))) axclasses,
   362           fold (fn x => add_param pp (x, class)) params parameters));
   363 
   364   in (class, result_thy) end;
   365 
   366 in
   367 
   368 val define_class = def_class Sign.read_class Attrib.attribute read_param ProofContext.read_propp;
   369 val define_class_i = def_class Sign.certify_class (K I) (K I) ProofContext.cert_propp;
   370 
   371 end;
   372 
   373 
   374 
   375 (** axiomatizations **)
   376 
   377 local
   378 
   379 fun axiomatize prep mk name add raw_args thy =
   380   let
   381     val args = prep thy raw_args;
   382     val specs = mk args;
   383     val names = name args;
   384   in thy |> PureThy.add_axioms_i (map (rpair []) (names ~~ specs)) |-> fold add end;
   385 
   386 fun ax_classrel prep =
   387   axiomatize (map o prep) (map Logic.mk_classrel)
   388     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   389 
   390 fun ax_arity prep =
   391   axiomatize prep Logic.mk_arities
   392     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   393 
   394 fun class_const c =
   395   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   396 
   397 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   398   let
   399     val class = Sign.full_name thy bclass;
   400     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
   401   in
   402     thy
   403     |> Sign.primitive_class (bclass, super)
   404     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   405     |> Theory.add_deps "" (class_const class) (map class_const super)
   406   end;
   407 
   408 in
   409 
   410 val axiomatize_class = ax_class Sign.read_class read_classrel;
   411 val axiomatize_class_i = ax_class Sign.certify_class cert_classrel;
   412 val axiomatize_classrel = ax_classrel read_classrel;
   413 val axiomatize_classrel_i = ax_classrel cert_classrel;
   414 val axiomatize_arity = ax_arity Sign.read_arity;
   415 val axiomatize_arity_i = ax_arity Sign.cert_arity;
   416 
   417 end;
   418 
   419 
   420 
   421 (** explicit derivations -- cached **)
   422 
   423 datatype cache = Types of (class * thm) list Typtab.table;
   424 val cache = Types Typtab.empty;
   425 
   426 local
   427 
   428 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   429 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   430 
   431 fun derive_type _ (_, []) = []
   432   | derive_type thy (typ, sort) =
   433       let
   434         val vars = Term.fold_atyps
   435             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   436               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   437               | _ => I) typ [];
   438         val hyps = vars
   439           |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
   440         val ths = (typ, sort) |> Sorts.of_sort_derivation (Sign.pp thy) (Sign.classes_of thy)
   441            {classrel =
   442               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   443             constructor =
   444               fn a => fn dom => fn c =>
   445                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   446                 in ths MRS the_arity thy a (c, Ss) end,
   447             variable =
   448               the_default [] o AList.lookup (op =) hyps};
   449       in ths end;
   450 
   451 in
   452 
   453 fun of_sort thy (typ, sort) cache =
   454   let
   455     val sort' = filter (is_none o lookup_type cache typ) sort;
   456     val ths' = derive_type thy (typ, sort')
   457       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   458         Sign.string_of_typ thy typ ^ " :: " ^ Sign.string_of_sort thy sort');
   459     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   460     val ths =
   461       sort |> map (fn c =>
   462         Goal.finish (the (lookup_type cache' typ c) RS
   463           Goal.init (Thm.cterm_of thy (Logic.mk_inclass (typ, c))))
   464         |> Thm.adjust_maxidx_thm ~1);
   465   in (ths, cache') end;
   466 
   467 end;
   468 
   469 end;