src/Pure/Proof/extraction.ML
author wenzelm
Wed Aug 31 15:46:40 2005 +0200 (2005-08-31)
changeset 17203 29b2563f5c11
parent 17057 0934ac31985f
child 17223 430edc6b7826
permissions -rw-r--r--
refer to theory instead of low-level tsig;
     1 (*  Title:      Pure/Proof/extraction.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4 
     5 Extraction of programs from proofs.
     6 *)
     7 
     8 signature EXTRACTION =
     9 sig
    10   val set_preprocessor : (theory -> Proofterm.proof -> Proofterm.proof) -> theory -> theory
    11   val add_realizes_eqns_i : ((term * term) list * (term * term)) list -> theory -> theory
    12   val add_realizes_eqns : string list -> theory -> theory
    13   val add_typeof_eqns_i : ((term * term) list * (term * term)) list -> theory -> theory
    14   val add_typeof_eqns : string list -> theory -> theory
    15   val add_realizers_i : (string * (string list * term * Proofterm.proof)) list
    16     -> theory -> theory
    17   val add_realizers : (thm * (string list * string * string)) list
    18     -> theory -> theory
    19   val add_expand_thms : thm list -> theory -> theory
    20   val add_types : (xstring * ((term -> term option) list *
    21     (term -> typ -> term -> typ -> term) option)) list -> theory -> theory
    22   val extract : (thm * string list) list -> theory -> theory
    23   val nullT : typ
    24   val nullt : term
    25   val mk_typ : typ -> term
    26   val etype_of : theory -> string list -> typ list -> term -> typ
    27   val realizes_of: theory -> string list -> term -> term -> term
    28 end;
    29 
    30 structure Extraction : EXTRACTION =
    31 struct
    32 
    33 open Proofterm;
    34 
    35 (**** tools ****)
    36 
    37 fun add_syntax thy =
    38   thy
    39   |> Theory.copy
    40   |> Theory.root_path
    41   |> Theory.add_types [("Type", 0, NoSyn), ("Null", 0, NoSyn)]
    42   |> Theory.add_consts
    43       [("typeof", "'b::{} => Type", NoSyn),
    44        ("Type", "'a::{} itself => Type", NoSyn),
    45        ("Null", "Null", NoSyn),
    46        ("realizes", "'a::{} => 'b::{} => 'b", NoSyn)];
    47 
    48 val nullT = Type ("Null", []);
    49 val nullt = Const ("Null", nullT);
    50 
    51 fun mk_typ T =
    52   Const ("Type", itselfT T --> Type ("Type", [])) $ Logic.mk_type T;
    53 
    54 fun typeof_proc defaultS vs (Const ("typeof", _) $ u) =
    55       SOME (mk_typ (case strip_comb u of
    56           (Var ((a, i), _), _) =>
    57             if a mem vs then TFree ("'" ^ a ^ ":" ^ string_of_int i, defaultS)
    58             else nullT
    59         | (Free (a, _), _) =>
    60             if a mem vs then TFree ("'" ^ a, defaultS) else nullT
    61         | _ => nullT))
    62   | typeof_proc _ _ _ = NONE;
    63 
    64 fun rlz_proc (Const ("realizes", Type (_, [Type ("Null", []), _])) $ r $ t) = SOME t
    65   | rlz_proc (Const ("realizes", Type (_, [T, _])) $ r $ t) =
    66       (case strip_comb t of
    67          (Var (ixn, U), ts) => SOME (list_comb (Var (ixn, T --> U), r :: ts))
    68        | (Free (s, U), ts) => SOME (list_comb (Free (s, T --> U), r :: ts))
    69        | _ => NONE)
    70   | rlz_proc _ = NONE;
    71 
    72 val unpack_ixn = apfst implode o apsnd (fst o read_int o tl) o
    73   take_prefix (not o equal ":") o explode;
    74 
    75 type rules =
    76   {next: int, rs: ((term * term) list * (term * term)) list,
    77    net: (int * ((term * term) list * (term * term))) Net.net};
    78 
    79 val empty_rules : rules = {next = 0, rs = [], net = Net.empty};
    80 
    81 fun add_rule (r as (_, (lhs, _)), {next, rs, net} : rules) =
    82   {next = next - 1, rs = r :: rs, net = Net.insert_term (K false)
    83      (Pattern.eta_contract lhs, (next, r)) net};
    84 
    85 fun merge_rules
    86   ({next, rs = rs1, net} : rules) ({next = next2, rs = rs2, ...} : rules) =
    87   foldr add_rule {next = next, rs = rs1, net = net} (rs2 \\ rs1);
    88 
    89 fun condrew thy rules procs =
    90   let
    91     fun rew tm =
    92       Pattern.rewrite_term thy [] (condrew' :: procs) tm
    93     and condrew' tm =
    94       let
    95         val cache = ref ([] : (term * term) list);
    96         fun lookup f x = (case gen_assoc (op =) (!cache, x) of
    97             NONE =>
    98               let val y = f x
    99               in (cache := (x, y) :: !cache; y) end
   100           | SOME y => y);
   101       in
   102         get_first (fn (_, (prems, (tm1, tm2))) =>
   103         let
   104           fun ren t = getOpt (Term.rename_abs tm1 tm t, t);
   105           val inc = Logic.incr_indexes ([], maxidx_of_term tm + 1);
   106           val env as (Tenv, tenv) = Pattern.match thy (inc tm1, tm);
   107           val prems' = map (pairself (Envir.subst_vars env o inc o ren)) prems;
   108           val env' = Envir.Envir
   109             {maxidx = Library.foldl Int.max
   110               (~1, map (Int.max o pairself maxidx_of_term) prems'),
   111              iTs = Tenv, asol = tenv};
   112           val env'' = Library.foldl (fn (env, p) =>
   113             Pattern.unify (thy, env, [pairself (lookup rew) p])) (env', prems')
   114         in SOME (Envir.norm_term env'' (inc (ren tm2)))
   115         end handle Pattern.MATCH => NONE | Pattern.Unif => NONE)
   116           (sort (int_ord o pairself fst)
   117             (Net.match_term rules (Pattern.eta_contract tm)))
   118       end;
   119 
   120   in rew end;
   121 
   122 val chtype = change_type o SOME;
   123 
   124 fun extr_name s vs = NameSpace.append "extr" (space_implode "_" (s :: vs));
   125 fun corr_name s vs = extr_name s vs ^ "_correctness";
   126 
   127 fun msg d s = priority (Symbol.spaces d ^ s);
   128 
   129 fun vars_of t = rev (fold_aterms (fn v as Var _ => insert (op =) v | _ => I) t []);
   130 fun vfs_of t = vars_of t @ sort Term.term_ord (term_frees t);
   131 
   132 fun forall_intr (t, prop) =
   133   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   134   in all T $ Abs (a, T, abstract_over (t, prop)) end;
   135 
   136 fun forall_intr_prf (t, prf) =
   137   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   138   in Abst (a, SOME T, prf_abstract_over t prf) end;
   139 
   140 val mkabs = foldr (fn (v, t) => Abs ("x", fastype_of v, abstract_over (v, t)));
   141 
   142 fun strip_abs 0 t = t
   143   | strip_abs n (Abs (_, _, t)) = strip_abs (n-1) t
   144   | strip_abs _ _ = error "strip_abs: not an abstraction";
   145 
   146 fun prf_subst_TVars tye =
   147   map_proof_terms (subst_TVars tye) (typ_subst_TVars tye);
   148 
   149 fun relevant_vars types prop = foldr (fn
   150       (Var ((a, i), T), vs) => (case strip_type T of
   151         (_, Type (s, _)) => if s mem types then a :: vs else vs
   152       | _ => vs)
   153     | (_, vs) => vs) [] (vars_of prop);
   154 
   155 fun tname_of (Type (s, _)) = s
   156   | tname_of _ = "";
   157 
   158 fun get_var_type t =
   159   let
   160     val vs = Term.add_vars t [];
   161     val fs = Term.add_frees t [];
   162   in fn 
   163       Var (ixn, _) => (case assoc_string_int (vs, ixn) of
   164           NONE => error "get_var_type: no such variable in term"
   165         | SOME T => Var (ixn, T))
   166     | Free (s, _) => (case assoc_string (fs, s) of
   167           NONE => error "get_var_type: no such variable in term"
   168         | SOME T => Free (s, T))
   169     | _ => error "get_var_type: not a variable"
   170   end;
   171 
   172 
   173 (**** theory data ****)
   174 
   175 (* data kind 'Pure/extraction' *)
   176 
   177 structure ExtractionData = TheoryDataFun
   178 (struct
   179   val name = "Pure/extraction";
   180   type T =
   181     {realizes_eqns : rules,
   182      typeof_eqns : rules,
   183      types : (string * ((term -> term option) list *
   184        (term -> typ -> term -> typ -> term) option)) list,
   185      realizers : (string list * (term * proof)) list Symtab.table,
   186      defs : thm list,
   187      expand : (string * term) list,
   188      prep : (theory -> proof -> proof) option}
   189 
   190   val empty =
   191     {realizes_eqns = empty_rules,
   192      typeof_eqns = empty_rules,
   193      types = [],
   194      realizers = Symtab.empty,
   195      defs = [],
   196      expand = [],
   197      prep = NONE};
   198   val copy = I;
   199   val extend = I;
   200 
   201   fun merge _
   202     (({realizes_eqns = realizes_eqns1, typeof_eqns = typeof_eqns1, types = types1,
   203        realizers = realizers1, defs = defs1, expand = expand1, prep = prep1},
   204       {realizes_eqns = realizes_eqns2, typeof_eqns = typeof_eqns2, types = types2,
   205        realizers = realizers2, defs = defs2, expand = expand2, prep = prep2}) : T * T) =
   206     {realizes_eqns = merge_rules realizes_eqns1 realizes_eqns2,
   207      typeof_eqns = merge_rules typeof_eqns1 typeof_eqns2,
   208      types = merge_alists types1 types2,
   209      realizers = Symtab.merge_multi' (eq_set o pairself #1)
   210        (realizers1, realizers2),
   211      defs = gen_merge_lists eq_thm defs1 defs2,
   212      expand = merge_lists expand1 expand2,
   213      prep = (case prep1 of NONE => prep2 | _ => prep1)};
   214 
   215   fun print _ _ = ();
   216 end);
   217 
   218 val _ = Context.add_setup [ExtractionData.init];
   219 
   220 fun read_condeq thy =
   221   let val thy' = add_syntax thy
   222   in fn s =>
   223     let val t = Logic.varify (term_of (read_cterm thy' (s, propT)))
   224     in (map Logic.dest_equals (Logic.strip_imp_prems t),
   225       Logic.dest_equals (Logic.strip_imp_concl t))
   226     end handle TERM _ => error ("Not a (conditional) meta equality:\n" ^ s)
   227   end;
   228 
   229 (** preprocessor **)
   230 
   231 fun set_preprocessor prep thy =
   232   let val {realizes_eqns, typeof_eqns, types, realizers,
   233     defs, expand, ...} = ExtractionData.get thy
   234   in
   235     ExtractionData.put
   236       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   237        realizers = realizers, defs = defs, expand = expand, prep = SOME prep} thy
   238   end;
   239 
   240 (** equations characterizing realizability **)
   241 
   242 fun gen_add_realizes_eqns prep_eq eqns thy =
   243   let val {realizes_eqns, typeof_eqns, types, realizers,
   244     defs, expand, prep} = ExtractionData.get thy;
   245   in
   246     ExtractionData.put
   247       {realizes_eqns = foldr add_rule realizes_eqns (map (prep_eq thy) eqns),
   248        typeof_eqns = typeof_eqns, types = types, realizers = realizers,
   249        defs = defs, expand = expand, prep = prep} thy
   250   end
   251 
   252 val add_realizes_eqns_i = gen_add_realizes_eqns (K I);
   253 val add_realizes_eqns = gen_add_realizes_eqns read_condeq;
   254 
   255 (** equations characterizing type of extracted program **)
   256 
   257 fun gen_add_typeof_eqns prep_eq eqns thy =
   258   let
   259     val {realizes_eqns, typeof_eqns, types, realizers,
   260       defs, expand, prep} = ExtractionData.get thy;
   261     val eqns' = map (prep_eq thy) eqns
   262   in
   263     ExtractionData.put
   264       {realizes_eqns = realizes_eqns, realizers = realizers,
   265        typeof_eqns = foldr add_rule typeof_eqns eqns',
   266        types = types, defs = defs, expand = expand, prep = prep} thy
   267   end
   268 
   269 val add_typeof_eqns_i = gen_add_typeof_eqns (K I);
   270 val add_typeof_eqns = gen_add_typeof_eqns read_condeq;
   271 
   272 fun thaw (T as TFree (a, S)) =
   273       if exists_string (equal ":") a then TVar (unpack_ixn a, S) else T
   274   | thaw (Type (a, Ts)) = Type (a, map thaw Ts)
   275   | thaw T = T;
   276 
   277 fun freeze (TVar ((a, i), S)) = TFree (a ^ ":" ^ string_of_int i, S)
   278   | freeze (Type (a, Ts)) = Type (a, map freeze Ts)
   279   | freeze T = T;
   280 
   281 fun freeze_thaw f x =
   282   map_term_types thaw (f (map_term_types freeze x));
   283 
   284 fun etype_of thy vs Ts t =
   285   let
   286     val {typeof_eqns, ...} = ExtractionData.get thy;
   287     fun err () = error ("Unable to determine type of extracted program for\n" ^
   288       Sign.string_of_term thy t)
   289   in case strip_abs_body (freeze_thaw (condrew thy (#net typeof_eqns)
   290     [typeof_proc (Sign.defaultS thy) vs]) (list_abs (map (pair "x") (rev Ts),
   291       Const ("typeof", fastype_of1 (Ts, t) --> Type ("Type", [])) $ t))) of
   292       Const ("Type", _) $ u => (Logic.dest_type u handle TERM _ => err ())
   293     | _ => err ()
   294   end;
   295 
   296 (** realizers for axioms / theorems, together with correctness proofs **)
   297 
   298 fun gen_add_realizers prep_rlz rs thy =
   299   let val {realizes_eqns, typeof_eqns, types, realizers,
   300     defs, expand, prep} = ExtractionData.get thy
   301   in
   302     ExtractionData.put
   303       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   304        realizers = foldr Symtab.update_multi
   305          realizers (map (prep_rlz thy) (rev rs)),
   306        defs = defs, expand = expand, prep = prep} thy
   307   end
   308 
   309 fun prep_realizer thy =
   310   let
   311     val {realizes_eqns, typeof_eqns, defs, types, ...} =
   312       ExtractionData.get thy;
   313     val procs = List.concat (map (fst o snd) types);
   314     val rtypes = map fst types;
   315     val eqns = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   316     val thy' = add_syntax thy;
   317     val rd = ProofSyntax.read_proof thy' false
   318   in fn (thm, (vs, s1, s2)) =>
   319     let
   320       val name = Thm.name_of_thm thm;
   321       val _ = assert (name <> "") "add_realizers: unnamed theorem";
   322       val prop = Pattern.rewrite_term thy'
   323         (map (Logic.dest_equals o prop_of) defs) [] (prop_of thm);
   324       val vars = vars_of prop;
   325       val vars' = filter_out (fn v =>
   326         tname_of (body_type (fastype_of v)) mem rtypes) vars;
   327       val T = etype_of thy' vs [] prop;
   328       val (T', thw) = Type.freeze_thaw_type
   329         (if T = nullT then nullT else map fastype_of vars' ---> T);
   330       val t = map_term_types thw (term_of (read_cterm thy' (s1, T')));
   331       val r' = freeze_thaw (condrew thy' eqns
   332         (procs @ [typeof_proc (Sign.defaultS thy') vs, rlz_proc]))
   333           (Const ("realizes", T --> propT --> propT) $
   334             (if T = nullT then t else list_comb (t, vars')) $ prop);
   335       val r = foldr forall_intr r' (map (get_var_type r') vars);
   336       val prf = Reconstruct.reconstruct_proof thy' r (rd s2);
   337     in (name, (vs, (t, prf))) end
   338   end;
   339 
   340 val add_realizers_i = gen_add_realizers
   341   (fn _ => fn (name, (vs, t, prf)) => (name, (vs, (t, prf))));
   342 val add_realizers = gen_add_realizers prep_realizer;
   343 
   344 fun realizes_of thy vs t prop =
   345   let
   346     val thy' = add_syntax thy;
   347     val {realizes_eqns, typeof_eqns, defs, types, ...} =
   348       ExtractionData.get thy';
   349     val procs = List.concat (map (fst o snd) types);
   350     val eqns = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   351     val prop' = Pattern.rewrite_term thy'
   352       (map (Logic.dest_equals o prop_of) defs) [] prop;
   353   in freeze_thaw (condrew thy' eqns
   354     (procs @ [typeof_proc (Sign.defaultS thy') vs, rlz_proc]))
   355       (Const ("realizes", fastype_of t --> propT --> propT) $ t $ prop')
   356   end;
   357 
   358 (** expanding theorems / definitions **)
   359 
   360 fun add_expand_thm (thy, thm) =
   361   let
   362     val {realizes_eqns, typeof_eqns, types, realizers,
   363       defs, expand, prep} = ExtractionData.get thy;
   364 
   365     val name = Thm.name_of_thm thm;
   366     val _ = assert (name <> "") "add_expand_thms: unnamed theorem";
   367 
   368     val is_def =
   369       (case strip_comb (fst (Logic.dest_equals (prop_of thm))) of
   370          (Const _, ts) => forall is_Var ts andalso null (duplicates ts)
   371            andalso can (Thm.get_axiom_i thy) name
   372        | _ => false) handle TERM _ => false;
   373   in
   374     (ExtractionData.put (if is_def then
   375         {realizes_eqns = realizes_eqns,
   376          typeof_eqns = add_rule (([],
   377            Logic.dest_equals (prop_of (Drule.abs_def thm))), typeof_eqns),
   378          types = types,
   379          realizers = realizers, defs = gen_ins eq_thm (thm, defs),
   380          expand = expand, prep = prep}
   381       else
   382         {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   383          realizers = realizers, defs = defs,
   384          expand = (name, prop_of thm) ins expand, prep = prep}) thy, thm)
   385   end;
   386 
   387 fun add_expand_thms thms thy = Library.foldl (fst o add_expand_thm) (thy, thms);
   388 
   389 
   390 (** types with computational content **)
   391 
   392 fun add_types tys thy =
   393   let val {realizes_eqns, typeof_eqns, types, realizers,
   394     defs, expand, prep} = ExtractionData.get thy;
   395   in
   396     ExtractionData.put
   397       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns,
   398        types = map (apfst (Sign.intern_type thy)) tys @ types,
   399        realizers = realizers, defs = defs, expand = expand, prep = prep} thy
   400   end;
   401 
   402 
   403 (** Pure setup **)
   404 
   405 val _ = Context.add_setup
   406   [add_types [("prop", ([], NONE))],
   407 
   408    add_typeof_eqns
   409      ["(typeof (PROP P)) == (Type (TYPE(Null))) ==>  \
   410     \  (typeof (PROP Q)) == (Type (TYPE('Q))) ==>  \
   411     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE('Q)))",
   412 
   413       "(typeof (PROP Q)) == (Type (TYPE(Null))) ==>  \
   414     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE(Null)))",
   415 
   416       "(typeof (PROP P)) == (Type (TYPE('P))) ==>  \
   417     \  (typeof (PROP Q)) == (Type (TYPE('Q))) ==>  \
   418     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE('P => 'Q)))",
   419 
   420       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE(Null))) ==>  \
   421     \    (typeof (!!x. PROP P (x))) == (Type (TYPE(Null)))",
   422 
   423       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE('P))) ==>  \
   424     \    (typeof (!!x::'a. PROP P (x))) == (Type (TYPE('a => 'P)))",
   425 
   426       "(%x. typeof (f (x))) == (%x. Type (TYPE('f))) ==>  \
   427     \    (typeof (f)) == (Type (TYPE('f)))"],
   428 
   429    add_realizes_eqns
   430      ["(typeof (PROP P)) == (Type (TYPE(Null))) ==>  \
   431     \    (realizes (r) (PROP P ==> PROP Q)) ==  \
   432     \    (PROP realizes (Null) (PROP P) ==> PROP realizes (r) (PROP Q))",
   433 
   434       "(typeof (PROP P)) == (Type (TYPE('P))) ==>  \
   435     \  (typeof (PROP Q)) == (Type (TYPE(Null))) ==>  \
   436     \    (realizes (r) (PROP P ==> PROP Q)) ==  \
   437     \    (!!x::'P. PROP realizes (x) (PROP P) ==> PROP realizes (Null) (PROP Q))",
   438 
   439       "(realizes (r) (PROP P ==> PROP Q)) ==  \
   440     \  (!!x. PROP realizes (x) (PROP P) ==> PROP realizes (r (x)) (PROP Q))",
   441 
   442       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE(Null))) ==>  \
   443     \    (realizes (r) (!!x. PROP P (x))) ==  \
   444     \    (!!x. PROP realizes (Null) (PROP P (x)))",
   445 
   446       "(realizes (r) (!!x. PROP P (x))) ==  \
   447     \  (!!x. PROP realizes (r (x)) (PROP P (x)))"],
   448 
   449    Attrib.add_attributes
   450      [("extraction_expand",
   451        (Attrib.no_args add_expand_thm, K Attrib.undef_local_attribute),
   452        "specify theorems / definitions to be expanded during extraction")]];
   453 
   454 
   455 (**** extract program ****)
   456 
   457 val dummyt = Const ("dummy", dummyT);
   458 
   459 fun extract thms thy =
   460   let
   461     val thy' = add_syntax thy;
   462     val {realizes_eqns, typeof_eqns, types, realizers, defs, expand, prep} =
   463       ExtractionData.get thy;
   464     val procs = List.concat (map (fst o snd) types);
   465     val rtypes = map fst types;
   466     val typroc = typeof_proc (Sign.defaultS thy');
   467     val prep = getOpt (prep, K I) thy' o ProofRewriteRules.elim_defs thy' false defs o
   468       Reconstruct.expand_proof thy' (("", NONE) :: map (apsnd SOME) expand);
   469     val rrews = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   470 
   471     fun find_inst prop Ts ts vs =
   472       let
   473         val rvs = relevant_vars rtypes prop;
   474         val vars = vars_of prop;
   475         val n = Int.min (length vars, length ts);
   476 
   477         fun add_args ((Var ((a, i), _), t), (vs', tye)) =
   478           if a mem rvs then
   479             let val T = etype_of thy' vs Ts t
   480             in if T = nullT then (vs', tye)
   481                else (a :: vs', (("'" ^ a, i), T) :: tye)
   482             end
   483           else (vs', tye)
   484 
   485       in foldr add_args ([], []) (Library.take (n, vars) ~~ Library.take (n, ts)) end;
   486 
   487     fun find vs = Option.map snd o find_first (curry eq_set vs o fst);
   488     fun find' s = map snd o List.filter (equal s o fst)
   489 
   490     fun app_rlz_rews Ts vs t = strip_abs (length Ts) (freeze_thaw
   491       (condrew thy' rrews (procs @ [typroc vs, rlz_proc])) (list_abs
   492         (map (pair "x") (rev Ts), t)));
   493 
   494     fun realizes_null vs prop = app_rlz_rews [] vs
   495       (Const ("realizes", nullT --> propT --> propT) $ nullt $ prop);
   496 
   497     fun corr d defs vs ts Ts hs (PBound i) _ _ = (defs, PBound i)
   498 
   499       | corr d defs vs ts Ts hs (Abst (s, SOME T, prf)) (Abst (_, _, prf')) t =
   500           let val (defs', corr_prf) = corr d defs vs [] (T :: Ts)
   501             (dummyt :: hs) prf (incr_pboundvars 1 0 prf')
   502             (case t of SOME (Abs (_, _, u)) => SOME u | _ => NONE)
   503           in (defs', Abst (s, SOME T, corr_prf)) end
   504 
   505       | corr d defs vs ts Ts hs (AbsP (s, SOME prop, prf)) (AbsP (_, _, prf')) t =
   506           let
   507             val T = etype_of thy' vs Ts prop;
   508             val u = if T = nullT then 
   509                 (case t of SOME u => SOME (incr_boundvars 1 u) | NONE => NONE)
   510               else (case t of SOME (Abs (_, _, u)) => SOME u | _ => NONE);
   511             val (defs', corr_prf) = corr d defs vs [] (T :: Ts) (prop :: hs)
   512               (incr_pboundvars 0 1 prf) (incr_pboundvars 0 1 prf') u;
   513             val rlz = Const ("realizes", T --> propT --> propT)
   514           in (defs',
   515             if T = nullT then AbsP ("R",
   516               SOME (app_rlz_rews Ts vs (rlz $ nullt $ prop)),
   517                 prf_subst_bounds [nullt] corr_prf)
   518             else Abst (s, SOME T, AbsP ("R",
   519               SOME (app_rlz_rews (T :: Ts) vs
   520                 (rlz $ Bound 0 $ incr_boundvars 1 prop)), corr_prf)))
   521           end
   522 
   523       | corr d defs vs ts Ts hs (prf % SOME t) (prf' % _) t' =
   524           let
   525             val (Us, T) = strip_type (fastype_of1 (Ts, t));
   526             val (defs', corr_prf) = corr d defs vs (t :: ts) Ts hs prf prf'
   527               (if tname_of T mem rtypes then t'
   528                else (case t' of SOME (u $ _) => SOME u | _ => NONE));
   529             val u = if not (tname_of T mem rtypes) then t else
   530               let
   531                 val eT = etype_of thy' vs Ts t;
   532                 val (r, Us') = if eT = nullT then (nullt, Us) else
   533                   (Bound (length Us), eT :: Us);
   534                 val u = list_comb (incr_boundvars (length Us') t,
   535                   map Bound (length Us - 1 downto 0));
   536                 val u' = (case assoc_string (types, tname_of T) of
   537                     SOME ((_, SOME f)) => f r eT u T
   538                   | _ => Const ("realizes", eT --> T --> T) $ r $ u)
   539               in app_rlz_rews Ts vs (list_abs (map (pair "x") Us', u')) end
   540           in (defs', corr_prf % SOME u) end
   541 
   542       | corr d defs vs ts Ts hs (prf1 %% prf2) (prf1' %% prf2') t =
   543           let
   544             val prop = Reconstruct.prop_of' hs prf2';
   545             val T = etype_of thy' vs Ts prop;
   546             val (defs1, f, u) = if T = nullT then (defs, t, NONE) else
   547               (case t of
   548                  SOME (f $ u) => (defs, SOME f, SOME u)
   549                | _ =>
   550                  let val (defs1, u) = extr d defs vs [] Ts hs prf2'
   551                  in (defs1, NONE, SOME u) end)
   552             val (defs2, corr_prf1) = corr d defs1 vs [] Ts hs prf1 prf1' f;
   553             val (defs3, corr_prf2) = corr d defs2 vs [] Ts hs prf2 prf2' u;
   554           in
   555             if T = nullT then (defs3, corr_prf1 %% corr_prf2) else
   556               (defs3, corr_prf1 % u %% corr_prf2)
   557           end
   558 
   559       | corr d defs vs ts Ts hs (prf0 as PThm ((name, _), prf, prop, SOME Ts')) _ _ =
   560           let
   561             val (vs', tye) = find_inst prop Ts ts vs;
   562             val tye' = (map fst (term_tvars prop) ~~ Ts') @ tye;
   563             val T = etype_of thy' vs' [] prop;
   564             val defs' = if T = nullT then defs
   565               else fst (extr d defs vs ts Ts hs prf0)
   566           in
   567             if T = nullT andalso realizes_null vs' prop aconv prop then (defs, prf0)
   568             else case Symtab.lookup (realizers, name) of
   569               NONE => (case find vs' (find' name defs') of
   570                 NONE =>
   571                   let
   572                     val _ = assert (T = nullT) "corr: internal error";
   573                     val _ = msg d ("Building correctness proof for " ^ quote name ^
   574                       (if null vs' then ""
   575                        else " (relevant variables: " ^ commas_quote vs' ^ ")"));
   576                     val prf' = prep (Reconstruct.reconstruct_proof thy' prop prf);
   577                     val (defs'', corr_prf) =
   578                       corr (d + 1) defs' vs' [] [] [] prf' prf' NONE;
   579                     val corr_prop = Reconstruct.prop_of corr_prf;
   580                     val corr_prf' = foldr forall_intr_prf
   581                       (proof_combt
   582                          (PThm ((corr_name name vs', []), corr_prf, corr_prop,
   583                              SOME (map TVar (term_tvars corr_prop))), vfs_of corr_prop))
   584 		      (map (get_var_type corr_prop) (vfs_of prop))
   585                   in
   586                     ((name, (vs', ((nullt, nullt), (corr_prf, corr_prf')))) :: defs'',
   587                      prf_subst_TVars tye' corr_prf')
   588                   end
   589               | SOME (_, (_, prf')) => (defs', prf_subst_TVars tye' prf'))
   590             | SOME rs => (case find vs' rs of
   591                 SOME (_, prf') => (defs', prf_subst_TVars tye' prf')
   592               | NONE => error ("corr: no realizer for instance of theorem " ^
   593                   quote name ^ ":\n" ^ Sign.string_of_term thy' (Envir.beta_norm
   594                     (Reconstruct.prop_of (proof_combt (prf0, ts))))))
   595           end
   596 
   597       | corr d defs vs ts Ts hs (prf0 as PAxm (s, prop, SOME Ts')) _ _ =
   598           let
   599             val (vs', tye) = find_inst prop Ts ts vs;
   600             val tye' = (map fst (term_tvars prop) ~~ Ts') @ tye
   601           in
   602             if etype_of thy' vs' [] prop = nullT andalso
   603               realizes_null vs' prop aconv prop then (defs, prf0)
   604             else case find vs' (Symtab.lookup_multi (realizers, s)) of
   605               SOME (_, prf) => (defs, prf_subst_TVars tye' prf)
   606             | NONE => error ("corr: no realizer for instance of axiom " ^
   607                 quote s ^ ":\n" ^ Sign.string_of_term thy' (Envir.beta_norm
   608                   (Reconstruct.prop_of (proof_combt (prf0, ts)))))
   609           end
   610 
   611       | corr d defs vs ts Ts hs _ _ _ = error "corr: bad proof"
   612 
   613     and extr d defs vs ts Ts hs (PBound i) = (defs, Bound i)
   614 
   615       | extr d defs vs ts Ts hs (Abst (s, SOME T, prf)) =
   616           let val (defs', t) = extr d defs vs []
   617             (T :: Ts) (dummyt :: hs) (incr_pboundvars 1 0 prf)
   618           in (defs', Abs (s, T, t)) end
   619 
   620       | extr d defs vs ts Ts hs (AbsP (s, SOME t, prf)) =
   621           let
   622             val T = etype_of thy' vs Ts t;
   623             val (defs', t) = extr d defs vs [] (T :: Ts) (t :: hs)
   624               (incr_pboundvars 0 1 prf)
   625           in (defs',
   626             if T = nullT then subst_bound (nullt, t) else Abs (s, T, t))
   627           end
   628 
   629       | extr d defs vs ts Ts hs (prf % SOME t) =
   630           let val (defs', u) = extr d defs vs (t :: ts) Ts hs prf
   631           in (defs',
   632             if tname_of (body_type (fastype_of1 (Ts, t))) mem rtypes then u
   633             else u $ t)
   634           end
   635 
   636       | extr d defs vs ts Ts hs (prf1 %% prf2) =
   637           let
   638             val (defs', f) = extr d defs vs [] Ts hs prf1;
   639             val prop = Reconstruct.prop_of' hs prf2;
   640             val T = etype_of thy' vs Ts prop
   641           in
   642             if T = nullT then (defs', f) else
   643               let val (defs'', t) = extr d defs' vs [] Ts hs prf2
   644               in (defs'', f $ t) end
   645           end
   646 
   647       | extr d defs vs ts Ts hs (prf0 as PThm ((s, _), prf, prop, SOME Ts')) =
   648           let
   649             val (vs', tye) = find_inst prop Ts ts vs;
   650             val tye' = (map fst (term_tvars prop) ~~ Ts') @ tye
   651           in
   652             case Symtab.lookup (realizers, s) of
   653               NONE => (case find vs' (find' s defs) of
   654                 NONE =>
   655                   let
   656                     val _ = msg d ("Extracting " ^ quote s ^
   657                       (if null vs' then ""
   658                        else " (relevant variables: " ^ commas_quote vs' ^ ")"));
   659                     val prf' = prep (Reconstruct.reconstruct_proof thy' prop prf);
   660                     val (defs', t) = extr (d + 1) defs vs' [] [] [] prf';
   661                     val (defs'', corr_prf) =
   662                       corr (d + 1) defs' vs' [] [] [] prf' prf' (SOME t);
   663 
   664                     val nt = Envir.beta_norm t;
   665                     val args = filter_out (fn v => tname_of (body_type
   666                       (fastype_of v)) mem rtypes) (vfs_of prop);
   667                     val args' = List.filter (fn v => Logic.occs (v, nt)) args;
   668                     val t' = mkabs nt args';
   669                     val T = fastype_of t';
   670                     val cname = extr_name s vs';
   671                     val c = Const (cname, T);
   672                     val u = mkabs (list_comb (c, args')) args;
   673                     val eqn = Logic.mk_equals (c, t');
   674                     val rlz =
   675                       Const ("realizes", fastype_of nt --> propT --> propT);
   676                     val lhs = app_rlz_rews [] vs' (rlz $ nt $ prop);
   677                     val rhs = app_rlz_rews [] vs' (rlz $ list_comb (c, args') $ prop);
   678                     val f = app_rlz_rews [] vs'
   679                       (Abs ("x", T, rlz $ list_comb (Bound 0, args') $ prop));
   680 
   681                     val corr_prf' =
   682                       chtype [] equal_elim_axm %> lhs %> rhs %%
   683                        (chtype [propT] symmetric_axm %> rhs %> lhs %%
   684                          (chtype [propT, T] combination_axm %> f %> f %> c %> t' %%
   685                            (chtype [T --> propT] reflexive_axm %> f) %%
   686                            PAxm (cname ^ "_def", eqn,
   687                              SOME (map TVar (term_tvars eqn))))) %% corr_prf;
   688                     val corr_prop = Reconstruct.prop_of corr_prf';
   689                     val corr_prf'' = foldr forall_intr_prf
   690                       (proof_combt
   691                         (PThm ((corr_name s vs', []), corr_prf', corr_prop,
   692                           SOME (map TVar (term_tvars corr_prop))),  vfs_of corr_prop))
   693 		      (map (get_var_type corr_prop) (vfs_of prop));
   694                   in
   695                     ((s, (vs', ((t', u), (corr_prf', corr_prf'')))) :: defs'',
   696                      subst_TVars tye' u)
   697                   end
   698               | SOME ((_, u), _) => (defs, subst_TVars tye' u))
   699             | SOME rs => (case find vs' rs of
   700                 SOME (t, _) => (defs, subst_TVars tye' t)
   701               | NONE => error ("extr: no realizer for instance of theorem " ^
   702                   quote s ^ ":\n" ^ Sign.string_of_term thy' (Envir.beta_norm
   703                     (Reconstruct.prop_of (proof_combt (prf0, ts))))))
   704           end
   705 
   706       | extr d defs vs ts Ts hs (prf0 as PAxm (s, prop, SOME Ts')) =
   707           let
   708             val (vs', tye) = find_inst prop Ts ts vs;
   709             val tye' = (map fst (term_tvars prop) ~~ Ts') @ tye
   710           in
   711             case find vs' (Symtab.lookup_multi (realizers, s)) of
   712               SOME (t, _) => (defs, subst_TVars tye' t)
   713             | NONE => error ("extr: no realizer for instance of axiom " ^
   714                 quote s ^ ":\n" ^ Sign.string_of_term thy' (Envir.beta_norm
   715                   (Reconstruct.prop_of (proof_combt (prf0, ts)))))
   716           end
   717 
   718       | extr d defs vs ts Ts hs _ = error "extr: bad proof";
   719 
   720     fun prep_thm (thm, vs) =
   721       let
   722         val {prop, der = (_, prf), sign, ...} = rep_thm thm;
   723         val name = Thm.name_of_thm thm;
   724         val _ = assert (name <> "") "extraction: unnamed theorem";
   725         val _ = assert (etype_of thy' vs [] prop <> nullT) ("theorem " ^
   726           quote name ^ " has no computational content")
   727       in (Reconstruct.reconstruct_proof sign prop prf, vs) end;
   728 
   729     val defs = Library.foldl (fn (defs, (prf, vs)) =>
   730       fst (extr 0 defs vs [] [] [] prf)) ([], map prep_thm thms);
   731 
   732     fun add_def (s, (vs, ((t, u), (prf, _)))) thy =
   733       (case Sign.const_type thy (extr_name s vs) of
   734          NONE =>
   735            let
   736              val corr_prop = Reconstruct.prop_of prf;
   737              val ft = Type.freeze t;
   738              val fu = Type.freeze u;
   739              val thy' = if t = nullt then thy else thy |>
   740                Theory.add_consts_i [(extr_name s vs, fastype_of ft, NoSyn)] |>
   741                fst o PureThy.add_defs_i false [((extr_name s vs ^ "_def",
   742                  Logic.mk_equals (head_of (strip_abs_body fu), ft)), [])];
   743            in
   744              fst (PureThy.store_thm ((corr_name s vs,
   745                Thm.varifyT (funpow (length (term_vars corr_prop))
   746                  (forall_elim_var 0) (forall_intr_frees
   747                    (ProofChecker.thm_of_proof thy'
   748                      (fst (Proofterm.freeze_thaw_prf prf)))))), []) thy')
   749            end
   750        | SOME _ => thy);
   751 
   752   in
   753     thy
   754     |> Theory.absolute_path
   755     |> fold_rev add_def defs
   756     |> Theory.restore_naming thy
   757   end;
   758 
   759 
   760 (**** interface ****)
   761 
   762 structure P = OuterParse and K = OuterKeyword;
   763 
   764 val parse_vars = Scan.optional (P.$$$ "(" |-- P.list1 P.name --| P.$$$ ")") [];
   765 
   766 val realizersP =
   767   OuterSyntax.command "realizers"
   768   "specify realizers for primitive axioms / theorems, together with correctness proof"
   769   K.thy_decl
   770     (Scan.repeat1 (P.xname -- parse_vars --| P.$$$ ":" -- P.string -- P.string) >>
   771      (fn xs => Toplevel.theory (fn thy => add_realizers
   772        (map (fn (((a, vs), s1), s2) =>
   773          (PureThy.get_thm thy (Name a), (vs, s1, s2))) xs) thy)));
   774 
   775 val realizabilityP =
   776   OuterSyntax.command "realizability"
   777   "add equations characterizing realizability" K.thy_decl
   778   (Scan.repeat1 P.string >> (Toplevel.theory o add_realizes_eqns));
   779 
   780 val typeofP =
   781   OuterSyntax.command "extract_type"
   782   "add equations characterizing type of extracted program" K.thy_decl
   783   (Scan.repeat1 P.string >> (Toplevel.theory o add_typeof_eqns));
   784 
   785 val extractP =
   786   OuterSyntax.command "extract" "extract terms from proofs" K.thy_decl
   787     (Scan.repeat1 (P.xname -- parse_vars) >> (fn xs => Toplevel.theory
   788       (fn thy => extract (map (apfst (PureThy.get_thm thy o Name)) xs) thy)));
   789 
   790 val _ = OuterSyntax.add_parsers [realizersP, realizabilityP, typeofP, extractP];
   791 
   792 val etype_of = etype_of o add_syntax;
   793 
   794 end;