src/HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
author nipkow
Thu Mar 13 07:07:07 2014 +0100 (2014-03-13)
changeset 56073 29e308b56d23
parent 56066 cce36efe32eb
child 56198 21dd034523e5
permissions -rw-r--r--
enhanced simplifier solver for preconditions of rewrite rule, can now deal with conjunctions
     1 (*  Title:      HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
     2     Author:     Amine Chaieb
     3 *)
     4 
     5 header {* Implementation and verification of multivariate polynomials *}
     6 
     7 theory Reflected_Multivariate_Polynomial
     8 imports Complex_Main Rat_Pair Polynomial_List
     9 begin
    10 
    11 subsection{* Datatype of polynomial expressions *}
    12 
    13 datatype poly = C Num | Bound nat | Add poly poly | Sub poly poly
    14   | Mul poly poly| Neg poly| Pw poly nat| CN poly nat poly
    15 
    16 abbreviation poly_0 :: "poly" ("0\<^sub>p") where "0\<^sub>p \<equiv> C (0\<^sub>N)"
    17 abbreviation poly_p :: "int \<Rightarrow> poly" ("'((_)')\<^sub>p") where "(i)\<^sub>p \<equiv> C (i)\<^sub>N"
    18 
    19 
    20 subsection{* Boundedness, substitution and all that *}
    21 
    22 primrec polysize:: "poly \<Rightarrow> nat"
    23 where
    24   "polysize (C c) = 1"
    25 | "polysize (Bound n) = 1"
    26 | "polysize (Neg p) = 1 + polysize p"
    27 | "polysize (Add p q) = 1 + polysize p + polysize q"
    28 | "polysize (Sub p q) = 1 + polysize p + polysize q"
    29 | "polysize (Mul p q) = 1 + polysize p + polysize q"
    30 | "polysize (Pw p n) = 1 + polysize p"
    31 | "polysize (CN c n p) = 4 + polysize c + polysize p"
    32 
    33 primrec polybound0:: "poly \<Rightarrow> bool" -- {* a poly is INDEPENDENT of Bound 0 *}
    34 where
    35   "polybound0 (C c) \<longleftrightarrow> True"
    36 | "polybound0 (Bound n) \<longleftrightarrow> n > 0"
    37 | "polybound0 (Neg a) \<longleftrightarrow> polybound0 a"
    38 | "polybound0 (Add a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    39 | "polybound0 (Sub a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    40 | "polybound0 (Mul a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    41 | "polybound0 (Pw p n) \<longleftrightarrow> polybound0 p"
    42 | "polybound0 (CN c n p) \<longleftrightarrow> n \<noteq> 0 \<and> polybound0 c \<and> polybound0 p"
    43 
    44 primrec polysubst0:: "poly \<Rightarrow> poly \<Rightarrow> poly" -- {* substitute a poly into a poly for Bound 0 *}
    45 where
    46   "polysubst0 t (C c) = C c"
    47 | "polysubst0 t (Bound n) = (if n = 0 then t else Bound n)"
    48 | "polysubst0 t (Neg a) = Neg (polysubst0 t a)"
    49 | "polysubst0 t (Add a b) = Add (polysubst0 t a) (polysubst0 t b)"
    50 | "polysubst0 t (Sub a b) = Sub (polysubst0 t a) (polysubst0 t b)"
    51 | "polysubst0 t (Mul a b) = Mul (polysubst0 t a) (polysubst0 t b)"
    52 | "polysubst0 t (Pw p n) = Pw (polysubst0 t p) n"
    53 | "polysubst0 t (CN c n p) =
    54     (if n = 0 then Add (polysubst0 t c) (Mul t (polysubst0 t p))
    55      else CN (polysubst0 t c) n (polysubst0 t p))"
    56 
    57 fun decrpoly:: "poly \<Rightarrow> poly"
    58 where
    59   "decrpoly (Bound n) = Bound (n - 1)"
    60 | "decrpoly (Neg a) = Neg (decrpoly a)"
    61 | "decrpoly (Add a b) = Add (decrpoly a) (decrpoly b)"
    62 | "decrpoly (Sub a b) = Sub (decrpoly a) (decrpoly b)"
    63 | "decrpoly (Mul a b) = Mul (decrpoly a) (decrpoly b)"
    64 | "decrpoly (Pw p n) = Pw (decrpoly p) n"
    65 | "decrpoly (CN c n p) = CN (decrpoly c) (n - 1) (decrpoly p)"
    66 | "decrpoly a = a"
    67 
    68 
    69 subsection{* Degrees and heads and coefficients *}
    70 
    71 fun degree:: "poly \<Rightarrow> nat"
    72 where
    73   "degree (CN c 0 p) = 1 + degree p"
    74 | "degree p = 0"
    75 
    76 fun head:: "poly \<Rightarrow> poly"
    77 where
    78   "head (CN c 0 p) = head p"
    79 | "head p = p"
    80 
    81 (* More general notions of degree and head *)
    82 fun degreen:: "poly \<Rightarrow> nat \<Rightarrow> nat"
    83 where
    84   "degreen (CN c n p) = (\<lambda>m. if n = m then 1 + degreen p n else 0)"
    85 | "degreen p = (\<lambda>m. 0)"
    86 
    87 fun headn:: "poly \<Rightarrow> nat \<Rightarrow> poly"
    88 where
    89   "headn (CN c n p) = (\<lambda>m. if n \<le> m then headn p m else CN c n p)"
    90 | "headn p = (\<lambda>m. p)"
    91 
    92 fun coefficients:: "poly \<Rightarrow> poly list"
    93 where
    94   "coefficients (CN c 0 p) = c # coefficients p"
    95 | "coefficients p = [p]"
    96 
    97 fun isconstant:: "poly \<Rightarrow> bool"
    98 where
    99   "isconstant (CN c 0 p) = False"
   100 | "isconstant p = True"
   101 
   102 fun behead:: "poly \<Rightarrow> poly"
   103 where
   104   "behead (CN c 0 p) = (let p' = behead p in if p' = 0\<^sub>p then c else CN c 0 p')"
   105 | "behead p = 0\<^sub>p"
   106 
   107 fun headconst:: "poly \<Rightarrow> Num"
   108 where
   109   "headconst (CN c n p) = headconst p"
   110 | "headconst (C n) = n"
   111 
   112 
   113 subsection{* Operations for normalization *}
   114 
   115 declare if_cong[fundef_cong del]
   116 declare let_cong[fundef_cong del]
   117 
   118 fun polyadd :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "+\<^sub>p" 60)
   119 where
   120   "polyadd (C c) (C c') = C (c +\<^sub>N c')"
   121 | "polyadd (C c) (CN c' n' p') = CN (polyadd (C c) c') n' p'"
   122 | "polyadd (CN c n p) (C c') = CN (polyadd c (C c')) n p"
   123 | "polyadd (CN c n p) (CN c' n' p') =
   124     (if n < n' then CN (polyadd c (CN c' n' p')) n p
   125      else if n' < n then CN (polyadd (CN c n p) c') n' p'
   126      else
   127       let
   128         cc' = polyadd c c';
   129         pp' = polyadd p p'
   130       in if pp' = 0\<^sub>p then cc' else CN cc' n pp')"
   131 | "polyadd a b = Add a b"
   132 
   133 
   134 fun polyneg :: "poly \<Rightarrow> poly" ("~\<^sub>p")
   135 where
   136   "polyneg (C c) = C (~\<^sub>N c)"
   137 | "polyneg (CN c n p) = CN (polyneg c) n (polyneg p)"
   138 | "polyneg a = Neg a"
   139 
   140 definition polysub :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "-\<^sub>p" 60)
   141   where "p -\<^sub>p q = polyadd p (polyneg q)"
   142 
   143 fun polymul :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "*\<^sub>p" 60)
   144 where
   145   "polymul (C c) (C c') = C (c *\<^sub>N c')"
   146 | "polymul (C c) (CN c' n' p') =
   147     (if c = 0\<^sub>N then 0\<^sub>p else CN (polymul (C c) c') n' (polymul (C c) p'))"
   148 | "polymul (CN c n p) (C c') =
   149     (if c' = 0\<^sub>N  then 0\<^sub>p else CN (polymul c (C c')) n (polymul p (C c')))"
   150 | "polymul (CN c n p) (CN c' n' p') =
   151     (if n < n' then CN (polymul c (CN c' n' p')) n (polymul p (CN c' n' p'))
   152      else if n' < n then CN (polymul (CN c n p) c') n' (polymul (CN c n p) p')
   153      else polyadd (polymul (CN c n p) c') (CN 0\<^sub>p n' (polymul (CN c n p) p')))"
   154 | "polymul a b = Mul a b"
   155 
   156 declare if_cong[fundef_cong]
   157 declare let_cong[fundef_cong]
   158 
   159 fun polypow :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   160 where
   161   "polypow 0 = (\<lambda>p. (1)\<^sub>p)"
   162 | "polypow n =
   163     (\<lambda>p.
   164       let
   165         q = polypow (n div 2) p;
   166         d = polymul q q
   167       in if even n then d else polymul p d)"
   168 
   169 abbreviation poly_pow :: "poly \<Rightarrow> nat \<Rightarrow> poly" (infixl "^\<^sub>p" 60)
   170   where "a ^\<^sub>p k \<equiv> polypow k a"
   171 
   172 function polynate :: "poly \<Rightarrow> poly"
   173 where
   174   "polynate (Bound n) = CN 0\<^sub>p n (1)\<^sub>p"
   175 | "polynate (Add p q) = polynate p +\<^sub>p polynate q"
   176 | "polynate (Sub p q) = polynate p -\<^sub>p polynate q"
   177 | "polynate (Mul p q) = polynate p *\<^sub>p polynate q"
   178 | "polynate (Neg p) = ~\<^sub>p (polynate p)"
   179 | "polynate (Pw p n) = polynate p ^\<^sub>p n"
   180 | "polynate (CN c n p) = polynate (Add c (Mul (Bound n) p))"
   181 | "polynate (C c) = C (normNum c)"
   182 by pat_completeness auto
   183 termination by (relation "measure polysize") auto
   184 
   185 fun poly_cmul :: "Num \<Rightarrow> poly \<Rightarrow> poly"
   186 where
   187   "poly_cmul y (C x) = C (y *\<^sub>N x)"
   188 | "poly_cmul y (CN c n p) = CN (poly_cmul y c) n (poly_cmul y p)"
   189 | "poly_cmul y p = C y *\<^sub>p p"
   190 
   191 definition monic :: "poly \<Rightarrow> poly \<times> bool"
   192 where
   193   "monic p =
   194     (let h = headconst p
   195      in if h = 0\<^sub>N then (p, False) else (C (Ninv h) *\<^sub>p p, 0>\<^sub>N h))"
   196 
   197 
   198 subsection {* Pseudo-division *}
   199 
   200 definition shift1 :: "poly \<Rightarrow> poly"
   201   where "shift1 p = CN 0\<^sub>p 0 p"
   202 
   203 abbreviation funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a"
   204   where "funpow \<equiv> compow"
   205 
   206 partial_function (tailrec) polydivide_aux :: "poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   207 where
   208   "polydivide_aux a n p k s =
   209     (if s = 0\<^sub>p then (k, s)
   210      else
   211       let
   212         b = head s;
   213         m = degree s
   214       in
   215         if m < n then (k,s)
   216         else
   217           let p' = funpow (m - n) shift1 p
   218           in
   219             if a = b then polydivide_aux a n p k (s -\<^sub>p p')
   220             else polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (b *\<^sub>p p')))"
   221 
   222 definition polydivide :: "poly \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   223   where "polydivide s p = polydivide_aux (head p) (degree p) p 0 s"
   224 
   225 fun poly_deriv_aux :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   226 where
   227   "poly_deriv_aux n (CN c 0 p) = CN (poly_cmul ((int n)\<^sub>N) c) 0 (poly_deriv_aux (n + 1) p)"
   228 | "poly_deriv_aux n p = poly_cmul ((int n)\<^sub>N) p"
   229 
   230 fun poly_deriv :: "poly \<Rightarrow> poly"
   231 where
   232   "poly_deriv (CN c 0 p) = poly_deriv_aux 1 p"
   233 | "poly_deriv p = 0\<^sub>p"
   234 
   235 
   236 subsection{* Semantics of the polynomial representation *}
   237 
   238 primrec Ipoly :: "'a list \<Rightarrow> poly \<Rightarrow> 'a::{field_char_0,field_inverse_zero,power}"
   239 where
   240   "Ipoly bs (C c) = INum c"
   241 | "Ipoly bs (Bound n) = bs!n"
   242 | "Ipoly bs (Neg a) = - Ipoly bs a"
   243 | "Ipoly bs (Add a b) = Ipoly bs a + Ipoly bs b"
   244 | "Ipoly bs (Sub a b) = Ipoly bs a - Ipoly bs b"
   245 | "Ipoly bs (Mul a b) = Ipoly bs a * Ipoly bs b"
   246 | "Ipoly bs (Pw t n) = Ipoly bs t ^ n"
   247 | "Ipoly bs (CN c n p) = Ipoly bs c + (bs!n) * Ipoly bs p"
   248 
   249 abbreviation Ipoly_syntax :: "poly \<Rightarrow> 'a list \<Rightarrow>'a::{field_char_0,field_inverse_zero,power}"
   250     ("\<lparr>_\<rparr>\<^sub>p\<^bsup>_\<^esup>")
   251   where "\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<equiv> Ipoly bs p"
   252 
   253 lemma Ipoly_CInt: "Ipoly bs (C (i, 1)) = of_int i"
   254   by (simp add: INum_def)
   255 
   256 lemma Ipoly_CRat: "Ipoly bs (C (i, j)) = of_int i / of_int j"
   257   by (simp  add: INum_def)
   258 
   259 lemmas RIpoly_eqs = Ipoly.simps(2-7) Ipoly_CInt Ipoly_CRat
   260 
   261 
   262 subsection {* Normal form and normalization *}
   263 
   264 fun isnpolyh:: "poly \<Rightarrow> nat \<Rightarrow> bool"
   265 where
   266   "isnpolyh (C c) = (\<lambda>k. isnormNum c)"
   267 | "isnpolyh (CN c n p) = (\<lambda>k. n \<ge> k \<and> isnpolyh c (Suc n) \<and> isnpolyh p n \<and> p \<noteq> 0\<^sub>p)"
   268 | "isnpolyh p = (\<lambda>k. False)"
   269 
   270 lemma isnpolyh_mono: "n' \<le> n \<Longrightarrow> isnpolyh p n \<Longrightarrow> isnpolyh p n'"
   271   by (induct p rule: isnpolyh.induct) auto
   272 
   273 definition isnpoly :: "poly \<Rightarrow> bool"
   274   where "isnpoly p = isnpolyh p 0"
   275 
   276 text{* polyadd preserves normal forms *}
   277 
   278 lemma polyadd_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polyadd p q) (min n0 n1)"
   279 proof (induct p q arbitrary: n0 n1 rule: polyadd.induct)
   280   case (2 ab c' n' p' n0 n1)
   281   from 2 have  th1: "isnpolyh (C ab) (Suc n')"
   282     by simp
   283   from 2(3) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   284     by simp_all
   285   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   286     by simp
   287   with 2(1)[OF th1 th2] have th3:"isnpolyh (C ab +\<^sub>p c') (Suc n')"
   288     by simp
   289   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   290     by simp
   291   then show ?case using 2 th3
   292     by simp
   293 next
   294   case (3 c' n' p' ab n1 n0)
   295   from 3 have  th1: "isnpolyh (C ab) (Suc n')"
   296     by simp
   297   from 3(2) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   298     by simp_all
   299   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   300     by simp
   301   with 3(1)[OF th2 th1] have th3:"isnpolyh (c' +\<^sub>p C ab) (Suc n')"
   302     by simp
   303   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   304     by simp
   305   then show ?case using 3 th3
   306     by simp
   307 next
   308   case (4 c n p c' n' p' n0 n1)
   309   then have nc: "isnpolyh c (Suc n)" and np: "isnpolyh p n"
   310     by simp_all
   311   from 4 have nc': "isnpolyh c' (Suc n')" and np': "isnpolyh p' n'"
   312     by simp_all
   313   from 4 have ngen0: "n \<ge> n0"
   314     by simp
   315   from 4 have n'gen1: "n' \<ge> n1"
   316     by simp
   317   have "n < n' \<or> n' < n \<or> n = n'"
   318     by auto
   319   moreover
   320   {
   321     assume eq: "n = n'"
   322     with "4.hyps"(3)[OF nc nc']
   323     have ncc':"isnpolyh (c +\<^sub>p c') (Suc n)"
   324       by auto
   325     then have ncc'n01: "isnpolyh (c +\<^sub>p c') (min n0 n1)"
   326       using isnpolyh_mono[where n'="min n0 n1" and n="Suc n"] ngen0 n'gen1
   327       by auto
   328     from eq "4.hyps"(4)[OF np np'] have npp': "isnpolyh (p +\<^sub>p p') n"
   329       by simp
   330     have minle: "min n0 n1 \<le> n'"
   331       using ngen0 n'gen1 eq by simp
   332     from minle npp' ncc'n01 4 eq ngen0 n'gen1 ncc' have ?case
   333       by (simp add: Let_def)
   334   }
   335   moreover
   336   {
   337     assume lt: "n < n'"
   338     have "min n0 n1 \<le> n0"
   339       by simp
   340     with 4 lt have th1:"min n0 n1 \<le> n"
   341       by auto
   342     from 4 have th21: "isnpolyh c (Suc n)"
   343       by simp
   344     from 4 have th22: "isnpolyh (CN c' n' p') n'"
   345       by simp
   346     from lt have th23: "min (Suc n) n' = Suc n"
   347       by arith
   348     from "4.hyps"(1)[OF th21 th22] have "isnpolyh (polyadd c (CN c' n' p')) (Suc n)"
   349       using th23 by simp
   350     with 4 lt th1 have ?case
   351       by simp
   352   }
   353   moreover
   354   {
   355     assume gt: "n' < n"
   356     then have gt': "n' < n \<and> \<not> n < n'"
   357       by simp
   358     have "min n0 n1 \<le> n1"
   359       by simp
   360     with 4 gt have th1: "min n0 n1 \<le> n'"
   361       by auto
   362     from 4 have th21: "isnpolyh c' (Suc n')"
   363       by simp_all
   364     from 4 have th22: "isnpolyh (CN c n p) n"
   365       by simp
   366     from gt have th23: "min n (Suc n') = Suc n'"
   367       by arith
   368     from "4.hyps"(2)[OF th22 th21] have "isnpolyh (polyadd (CN c n p) c') (Suc n')"
   369       using th23 by simp
   370     with 4 gt th1 have ?case
   371       by simp
   372   }
   373   ultimately show ?case by blast
   374 qed auto
   375 
   376 lemma polyadd[simp]: "Ipoly bs (polyadd p q) = Ipoly bs p + Ipoly bs q"
   377   by (induct p q rule: polyadd.induct)
   378     (auto simp add: Let_def field_simps distrib_left[symmetric] simp del: distrib_left)
   379 
   380 lemma polyadd_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polyadd p q)"
   381   using polyadd_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   382 
   383 text{* The degree of addition and other general lemmas needed for the normal form of polymul *}
   384 
   385 lemma polyadd_different_degreen:
   386   assumes "isnpolyh p n0"
   387     and "isnpolyh q n1"
   388     and "degreen p m \<noteq> degreen q m"
   389     and "m \<le> min n0 n1"
   390   shows "degreen (polyadd p q) m = max (degreen p m) (degreen q m)"
   391   using assms
   392 proof (induct p q arbitrary: m n0 n1 rule: polyadd.induct)
   393   case (4 c n p c' n' p' m n0 n1)
   394   have "n' = n \<or> n < n' \<or> n' < n" by arith
   395   then show ?case
   396   proof (elim disjE)
   397     assume [simp]: "n' = n"
   398     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   399     show ?thesis by (auto simp: Let_def)
   400   next
   401     assume "n < n'"
   402     with 4 show ?thesis by auto
   403   next
   404     assume "n' < n"
   405     with 4 show ?thesis by auto
   406   qed
   407 qed auto
   408 
   409 lemma headnz[simp]: "isnpolyh p n \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> headn p m \<noteq> 0\<^sub>p"
   410   by (induct p arbitrary: n rule: headn.induct) auto
   411 
   412 lemma degree_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> degree p = 0"
   413   by (induct p arbitrary: n rule: degree.induct) auto
   414 
   415 lemma degreen_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> degreen p m = 0"
   416   by (induct p arbitrary: n rule: degreen.induct) auto
   417 
   418 lemma degree_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> degree p = 0"
   419   by (induct p arbitrary: n rule: degree.induct) auto
   420 
   421 lemma degree_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degree c = 0"
   422   using degree_isnpolyh_Suc by auto
   423 
   424 lemma degreen_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degreen c n = 0"
   425   using degreen_0 by auto
   426 
   427 
   428 lemma degreen_polyadd:
   429   assumes np: "isnpolyh p n0"
   430     and nq: "isnpolyh q n1"
   431     and m: "m \<le> max n0 n1"
   432   shows "degreen (p +\<^sub>p q) m \<le> max (degreen p m) (degreen q m)"
   433   using np nq m
   434 proof (induct p q arbitrary: n0 n1 m rule: polyadd.induct)
   435   case (2 c c' n' p' n0 n1)
   436   then show ?case
   437     by (cases n') simp_all
   438 next
   439   case (3 c n p c' n0 n1)
   440   then show ?case
   441     by (cases n) auto
   442 next
   443   case (4 c n p c' n' p' n0 n1 m)
   444   have "n' = n \<or> n < n' \<or> n' < n" by arith
   445   then show ?case
   446   proof (elim disjE)
   447     assume [simp]: "n' = n"
   448     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   449     show ?thesis by (auto simp: Let_def)
   450   qed simp_all
   451 qed auto
   452 
   453 lemma polyadd_eq_const_degreen:
   454   assumes "isnpolyh p n0"
   455     and "isnpolyh q n1"
   456     and "polyadd p q = C c"
   457   shows "degreen p m = degreen q m"
   458   using assms
   459 proof (induct p q arbitrary: m n0 n1 c rule: polyadd.induct)
   460   case (4 c n p c' n' p' m n0 n1 x)
   461   {
   462     assume nn': "n' < n"
   463     then have ?case using 4 by simp
   464   }
   465   moreover
   466   {
   467     assume nn': "\<not> n' < n"
   468     then have "n < n' \<or> n = n'" by arith
   469     moreover { assume "n < n'" with 4 have ?case by simp }
   470     moreover
   471     {
   472       assume eq: "n = n'"
   473       then have ?case using 4
   474         apply (cases "p +\<^sub>p p' = 0\<^sub>p")
   475         apply (auto simp add: Let_def)
   476         done
   477     }
   478     ultimately have ?case by blast
   479   }
   480   ultimately show ?case by blast
   481 qed simp_all
   482 
   483 lemma polymul_properties:
   484   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   485     and np: "isnpolyh p n0"
   486     and nq: "isnpolyh q n1"
   487     and m: "m \<le> min n0 n1"
   488   shows "isnpolyh (p *\<^sub>p q) (min n0 n1)"
   489     and "p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   490     and "degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   491   using np nq m
   492 proof (induct p q arbitrary: n0 n1 m rule: polymul.induct)
   493   case (2 c c' n' p')
   494   {
   495     case (1 n0 n1)
   496     with "2.hyps"(4-6)[of n' n' n'] and "2.hyps"(1-3)[of "Suc n'" "Suc n'" n']
   497     show ?case by (auto simp add: min_def)
   498   next
   499     case (2 n0 n1)
   500     then show ?case by auto
   501   next
   502     case (3 n0 n1)
   503     then show ?case  using "2.hyps" by auto
   504   }
   505 next
   506   case (3 c n p c')
   507   {
   508     case (1 n0 n1)
   509     with "3.hyps"(4-6)[of n n n] and "3.hyps"(1-3)[of "Suc n" "Suc n" n]
   510     show ?case by (auto simp add: min_def)
   511   next
   512     case (2 n0 n1)
   513     then show ?case by auto
   514   next
   515     case (3 n0 n1)
   516     then show ?case  using "3.hyps" by auto
   517   }
   518 next
   519   case (4 c n p c' n' p')
   520   let ?cnp = "CN c n p" let ?cnp' = "CN c' n' p'"
   521   {
   522     case (1 n0 n1)
   523     then have cnp: "isnpolyh ?cnp n"
   524       and cnp': "isnpolyh ?cnp' n'"
   525       and np: "isnpolyh p n"
   526       and nc: "isnpolyh c (Suc n)"
   527       and np': "isnpolyh p' n'"
   528       and nc': "isnpolyh c' (Suc n')"
   529       and nn0: "n \<ge> n0"
   530       and nn1: "n' \<ge> n1"
   531       by simp_all
   532     {
   533       assume "n < n'"
   534       with "4.hyps"(4-5)[OF np cnp', of n] and "4.hyps"(1)[OF nc cnp', of n] nn0 cnp
   535       have ?case by (simp add: min_def)
   536     } moreover {
   537       assume "n' < n"
   538       with "4.hyps"(16-17)[OF cnp np', of "n'"] and "4.hyps"(13)[OF cnp nc', of "Suc n'"] nn1 cnp'
   539       have ?case by (cases "Suc n' = n") (simp_all add: min_def)
   540     } moreover {
   541       assume "n' = n"
   542       with "4.hyps"(16-17)[OF cnp np', of n] and "4.hyps"(13)[OF cnp nc', of n] cnp cnp' nn1 nn0
   543       have ?case
   544         apply (auto intro!: polyadd_normh)
   545         apply (simp_all add: min_def isnpolyh_mono[OF nn0])
   546         done
   547     }
   548     ultimately show ?case by arith
   549   next
   550     fix n0 n1 m
   551     assume np: "isnpolyh ?cnp n0"
   552     assume np':"isnpolyh ?cnp' n1"
   553     assume m: "m \<le> min n0 n1"
   554     let ?d = "degreen (?cnp *\<^sub>p ?cnp') m"
   555     let ?d1 = "degreen ?cnp m"
   556     let ?d2 = "degreen ?cnp' m"
   557     let ?eq = "?d = (if ?cnp = 0\<^sub>p \<or> ?cnp' = 0\<^sub>p then 0  else ?d1 + ?d2)"
   558     have "n' < n \<or> n < n' \<or> n' = n" by auto
   559     moreover
   560     {
   561       assume "n' < n \<or> n < n'"
   562       with "4.hyps"(3,6,18) np np' m have ?eq
   563         by auto
   564     }
   565     moreover
   566     {
   567       assume nn': "n' = n"
   568       then have nn: "\<not> n' < n \<and> \<not> n < n'" by arith
   569       from "4.hyps"(16,18)[of n n' n]
   570         "4.hyps"(13,14)[of n "Suc n'" n]
   571         np np' nn'
   572       have norm:
   573         "isnpolyh ?cnp n"
   574         "isnpolyh c' (Suc n)"
   575         "isnpolyh (?cnp *\<^sub>p c') n"
   576         "isnpolyh p' n"
   577         "isnpolyh (?cnp *\<^sub>p p') n"
   578         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   579         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   580         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   581         by (auto simp add: min_def)
   582       {
   583         assume mn: "m = n"
   584         from "4.hyps"(17,18)[OF norm(1,4), of n]
   585           "4.hyps"(13,15)[OF norm(1,2), of n] norm nn' mn
   586         have degs:
   587           "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else ?d1 + degreen c' n)"
   588           "degreen (?cnp *\<^sub>p p') n = ?d1  + degreen p' n"
   589           by (simp_all add: min_def)
   590         from degs norm have th1: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   591           by simp
   592         then have neq: "degreen (?cnp *\<^sub>p c') n \<noteq> degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   593           by simp
   594         have nmin: "n \<le> min n n"
   595           by (simp add: min_def)
   596         from polyadd_different_degreen[OF norm(3,6) neq nmin] th1
   597         have deg: "degreen (CN c n p *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n =
   598             degreen (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   599           by simp
   600         from "4.hyps"(16-18)[OF norm(1,4), of n]
   601           "4.hyps"(13-15)[OF norm(1,2), of n]
   602           mn norm m nn' deg
   603         have ?eq by simp
   604       }
   605       moreover
   606       {
   607         assume mn: "m \<noteq> n"
   608         then have mn': "m < n"
   609           using m np by auto
   610         from nn' m np have max1: "m \<le> max n n"
   611           by simp
   612         then have min1: "m \<le> min n n"
   613           by simp
   614         then have min2: "m \<le> min n (Suc n)"
   615           by simp
   616         from "4.hyps"(16-18)[OF norm(1,4) min1]
   617           "4.hyps"(13-15)[OF norm(1,2) min2]
   618           degreen_polyadd[OF norm(3,6) max1]
   619         have "degreen (?cnp *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (?cnp *\<^sub>p p')) m \<le>
   620             max (degreen (?cnp *\<^sub>p c') m) (degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) m)"
   621           using mn nn' np np' by simp
   622         with "4.hyps"(16-18)[OF norm(1,4) min1]
   623           "4.hyps"(13-15)[OF norm(1,2) min2]
   624           degreen_0[OF norm(3) mn']
   625         have ?eq using nn' mn np np' by clarsimp
   626       }
   627       ultimately have ?eq by blast
   628     }
   629     ultimately show ?eq by blast
   630   }
   631   {
   632     case (2 n0 n1)
   633     then have np: "isnpolyh ?cnp n0"
   634       and np': "isnpolyh ?cnp' n1"
   635       and m: "m \<le> min n0 n1"
   636       by simp_all
   637     then have mn: "m \<le> n" by simp
   638     let ?c0p = "CN 0\<^sub>p n (?cnp *\<^sub>p p')"
   639     {
   640       assume C: "?cnp *\<^sub>p c' +\<^sub>p ?c0p = 0\<^sub>p" "n' = n"
   641       then have nn: "\<not> n' < n \<and> \<not> n < n'"
   642         by simp
   643       from "4.hyps"(16-18) [of n n n]
   644         "4.hyps"(13-15)[of n "Suc n" n]
   645         np np' C(2) mn
   646       have norm:
   647         "isnpolyh ?cnp n"
   648         "isnpolyh c' (Suc n)"
   649         "isnpolyh (?cnp *\<^sub>p c') n"
   650         "isnpolyh p' n"
   651         "isnpolyh (?cnp *\<^sub>p p') n"
   652         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   653         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   654         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   655         "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else degreen ?cnp n + degreen c' n)"
   656         "degreen (?cnp *\<^sub>p p') n = degreen ?cnp n + degreen p' n"
   657         by (simp_all add: min_def)
   658       from norm have cn: "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   659         by simp
   660       have degneq: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   661         using norm by simp
   662       from polyadd_eq_const_degreen[OF norm(3) cn C(1), where m="n"] degneq
   663       have False by simp
   664     }
   665     then show ?case using "4.hyps" by clarsimp
   666   }
   667 qed auto
   668 
   669 lemma polymul[simp]: "Ipoly bs (p *\<^sub>p q) = Ipoly bs p * Ipoly bs q"
   670   by (induct p q rule: polymul.induct) (auto simp add: field_simps)
   671 
   672 lemma polymul_normh:
   673   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   674   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (p *\<^sub>p q) (min n0 n1)"
   675   using polymul_properties(1) by blast
   676 
   677 lemma polymul_eq0_iff:
   678   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   679   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   680   using polymul_properties(2) by blast
   681 
   682 lemma polymul_degreen:  (* FIXME duplicate? *)
   683   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   684   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> m \<le> min n0 n1 \<Longrightarrow>
   685     degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   686   using polymul_properties(3) by blast
   687 
   688 lemma polymul_norm:
   689   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   690   shows "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polymul p q)"
   691   using polymul_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   692 
   693 lemma headconst_zero: "isnpolyh p n0 \<Longrightarrow> headconst p = 0\<^sub>N \<longleftrightarrow> p = 0\<^sub>p"
   694   by (induct p arbitrary: n0 rule: headconst.induct) auto
   695 
   696 lemma headconst_isnormNum: "isnpolyh p n0 \<Longrightarrow> isnormNum (headconst p)"
   697   by (induct p arbitrary: n0) auto
   698 
   699 lemma monic_eqI:
   700   assumes np: "isnpolyh p n0"
   701   shows "INum (headconst p) * Ipoly bs (fst (monic p)) =
   702     (Ipoly bs p ::'a::{field_char_0,field_inverse_zero, power})"
   703   unfolding monic_def Let_def
   704 proof (cases "headconst p = 0\<^sub>N", simp_all add: headconst_zero[OF np])
   705   let ?h = "headconst p"
   706   assume pz: "p \<noteq> 0\<^sub>p"
   707   {
   708     assume hz: "INum ?h = (0::'a)"
   709     from headconst_isnormNum[OF np] have norm: "isnormNum ?h" "isnormNum 0\<^sub>N"
   710       by simp_all
   711     from isnormNum_unique[where ?'a = 'a, OF norm] hz have "?h = 0\<^sub>N"
   712       by simp
   713     with headconst_zero[OF np] have "p = 0\<^sub>p"
   714       by blast
   715     with pz have False
   716       by blast
   717   }
   718   then show "INum (headconst p) = (0::'a) \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
   719     by blast
   720 qed
   721 
   722 
   723 text{* polyneg is a negation and preserves normal forms *}
   724 
   725 lemma polyneg[simp]: "Ipoly bs (polyneg p) = - Ipoly bs p"
   726   by (induct p rule: polyneg.induct) auto
   727 
   728 lemma polyneg0: "isnpolyh p n \<Longrightarrow> (~\<^sub>p p) = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   729   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: Nneg_def)
   730 
   731 lemma polyneg_polyneg: "isnpolyh p n0 \<Longrightarrow> ~\<^sub>p (~\<^sub>p p) = p"
   732   by (induct p arbitrary: n0 rule: polyneg.induct) auto
   733 
   734 lemma polyneg_normh: "isnpolyh p n \<Longrightarrow> isnpolyh (polyneg p) n"
   735   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: polyneg0)
   736 
   737 lemma polyneg_norm: "isnpoly p \<Longrightarrow> isnpoly (polyneg p)"
   738   using isnpoly_def polyneg_normh by simp
   739 
   740 
   741 text{* polysub is a substraction and preserves normal forms *}
   742 
   743 lemma polysub[simp]: "Ipoly bs (polysub p q) = Ipoly bs p - Ipoly bs q"
   744   by (simp add: polysub_def)
   745 
   746 lemma polysub_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polysub p q) (min n0 n1)"
   747   by (simp add: polysub_def polyneg_normh polyadd_normh)
   748 
   749 lemma polysub_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polysub p q)"
   750   using polyadd_norm polyneg_norm by (simp add: polysub_def)
   751 
   752 lemma polysub_same_0[simp]:
   753   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   754   shows "isnpolyh p n0 \<Longrightarrow> polysub p p = 0\<^sub>p"
   755   unfolding polysub_def split_def fst_conv snd_conv
   756   by (induct p arbitrary: n0) (auto simp add: Let_def Nsub0[simplified Nsub_def])
   757 
   758 lemma polysub_0:
   759   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   760   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p -\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = q"
   761   unfolding polysub_def split_def fst_conv snd_conv
   762   by (induct p q arbitrary: n0 n1 rule:polyadd.induct)
   763     (auto simp: Nsub0[simplified Nsub_def] Let_def)
   764 
   765 text{* polypow is a power function and preserves normal forms *}
   766 
   767 lemma polypow[simp]:
   768   "Ipoly bs (polypow n p) = (Ipoly bs p :: 'a::{field_char_0,field_inverse_zero}) ^ n"
   769 proof (induct n rule: polypow.induct)
   770   case 1
   771   then show ?case
   772     by simp
   773 next
   774   case (2 n)
   775   let ?q = "polypow ((Suc n) div 2) p"
   776   let ?d = "polymul ?q ?q"
   777   have "odd (Suc n) \<or> even (Suc n)"
   778     by simp
   779   moreover
   780   {
   781     assume odd: "odd (Suc n)"
   782     have th: "(Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0)))) = Suc n div 2 + Suc n div 2 + 1"
   783       by arith
   784     from odd have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs (polymul p ?d)"
   785       by (simp add: Let_def)
   786     also have "\<dots> = (Ipoly bs p) * (Ipoly bs p)^(Suc n div 2) * (Ipoly bs p)^(Suc n div 2)"
   787       using "2.hyps" by simp
   788     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2 + 1)"
   789       by (simp only: power_add power_one_right) simp
   790     also have "\<dots> = (Ipoly bs p) ^ (Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0))))"
   791       by (simp only: th)
   792     finally have ?case
   793     using odd_nat_div_two_times_two_plus_one[OF odd, symmetric] by simp
   794   }
   795   moreover
   796   {
   797     assume even: "even (Suc n)"
   798     have th: "(Suc (Suc 0)) * (Suc n div Suc (Suc 0)) = Suc n div 2 + Suc n div 2"
   799       by arith
   800     from even have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs ?d"
   801       by (simp add: Let_def)
   802     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2)"
   803       using "2.hyps" by (simp only: power_add) simp
   804     finally have ?case using even_nat_div_two_times_two[OF even]
   805       by (simp only: th)
   806   }
   807   ultimately show ?case by blast
   808 qed
   809 
   810 lemma polypow_normh:
   811   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   812   shows "isnpolyh p n \<Longrightarrow> isnpolyh (polypow k p) n"
   813 proof (induct k arbitrary: n rule: polypow.induct)
   814   case 1
   815   then show ?case by auto
   816 next
   817   case (2 k n)
   818   let ?q = "polypow (Suc k div 2) p"
   819   let ?d = "polymul ?q ?q"
   820   from 2 have th1: "isnpolyh ?q n" and th2: "isnpolyh p n"
   821     by blast+
   822   from polymul_normh[OF th1 th1] have dn: "isnpolyh ?d n"
   823     by simp
   824   from polymul_normh[OF th2 dn] have on: "isnpolyh (polymul p ?d) n"
   825     by simp
   826   from dn on show ?case
   827     by (simp add: Let_def)
   828 qed
   829 
   830 lemma polypow_norm:
   831   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   832   shows "isnpoly p \<Longrightarrow> isnpoly (polypow k p)"
   833   by (simp add: polypow_normh isnpoly_def)
   834 
   835 text{* Finally the whole normalization *}
   836 
   837 lemma polynate [simp]:
   838   "Ipoly bs (polynate p) = (Ipoly bs p :: 'a ::{field_char_0,field_inverse_zero})"
   839   by (induct p rule:polynate.induct) auto
   840 
   841 lemma polynate_norm[simp]:
   842   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
   843   shows "isnpoly (polynate p)"
   844   by (induct p rule: polynate.induct)
   845      (simp_all add: polyadd_norm polymul_norm polysub_norm polyneg_norm polypow_norm,
   846       simp_all add: isnpoly_def)
   847 
   848 text{* shift1 *}
   849 
   850 
   851 lemma shift1: "Ipoly bs (shift1 p) = Ipoly bs (Mul (Bound 0) p)"
   852   by (simp add: shift1_def)
   853 
   854 lemma shift1_isnpoly:
   855   assumes pn: "isnpoly p"
   856     and pnz: "p \<noteq> 0\<^sub>p"
   857   shows "isnpoly (shift1 p) "
   858   using pn pnz by (simp add: shift1_def isnpoly_def)
   859 
   860 lemma shift1_nz[simp]:"shift1 p \<noteq> 0\<^sub>p"
   861   by (simp add: shift1_def)
   862 
   863 lemma funpow_shift1_isnpoly: "isnpoly p \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> isnpoly (funpow n shift1 p)"
   864   by (induct n arbitrary: p) (auto simp add: shift1_isnpoly funpow_swap1)
   865 
   866 lemma funpow_isnpolyh:
   867   assumes f: "\<And>p. isnpolyh p n \<Longrightarrow> isnpolyh (f p) n"
   868     and np: "isnpolyh p n"
   869   shows "isnpolyh (funpow k f p) n"
   870   using f np by (induct k arbitrary: p) auto
   871 
   872 lemma funpow_shift1:
   873   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field_inverse_zero}) =
   874     Ipoly bs (Mul (Pw (Bound 0) n) p)"
   875   by (induct n arbitrary: p) (simp_all add: shift1_isnpoly shift1)
   876 
   877 lemma shift1_isnpolyh: "isnpolyh p n0 \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> isnpolyh (shift1 p) 0"
   878   using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by (simp add: shift1_def)
   879 
   880 lemma funpow_shift1_1:
   881   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field_inverse_zero}) =
   882     Ipoly bs (funpow n shift1 (1)\<^sub>p *\<^sub>p p)"
   883   by (simp add: funpow_shift1)
   884 
   885 lemma poly_cmul[simp]: "Ipoly bs (poly_cmul c p) = Ipoly bs (Mul (C c) p)"
   886   by (induct p rule: poly_cmul.induct) (auto simp add: field_simps)
   887 
   888 lemma behead:
   889   assumes np: "isnpolyh p n"
   890   shows "Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) =
   891     (Ipoly bs p :: 'a :: {field_char_0,field_inverse_zero})"
   892   using np
   893 proof (induct p arbitrary: n rule: behead.induct)
   894   case (1 c p n)
   895   then have pn: "isnpolyh p n" by simp
   896   from 1(1)[OF pn]
   897   have th:"Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = Ipoly bs p" .
   898   then show ?case using "1.hyps"
   899     apply (simp add: Let_def,cases "behead p = 0\<^sub>p")
   900     apply (simp_all add: th[symmetric] field_simps)
   901     done
   902 qed (auto simp add: Let_def)
   903 
   904 lemma behead_isnpolyh:
   905   assumes np: "isnpolyh p n"
   906   shows "isnpolyh (behead p) n"
   907   using np by (induct p rule: behead.induct) (auto simp add: Let_def isnpolyh_mono)
   908 
   909 
   910 subsection{* Miscellaneous lemmas about indexes, decrementation, substitution  etc ... *}
   911 
   912 lemma isnpolyh_polybound0: "isnpolyh p (Suc n) \<Longrightarrow> polybound0 p"
   913 proof (induct p arbitrary: n rule: poly.induct, auto)
   914   case (goal1 c n p n')
   915   then have "n = Suc (n - 1)"
   916     by simp
   917   then have "isnpolyh p (Suc (n - 1))"
   918     using `isnpolyh p n` by simp
   919   with goal1(2) show ?case
   920     by simp
   921 qed
   922 
   923 lemma isconstant_polybound0: "isnpolyh p n0 \<Longrightarrow> isconstant p \<longleftrightarrow> polybound0 p"
   924   by (induct p arbitrary: n0 rule: isconstant.induct) (auto simp add: isnpolyh_polybound0)
   925 
   926 lemma decrpoly_zero[simp]: "decrpoly p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   927   by (induct p) auto
   928 
   929 lemma decrpoly_normh: "isnpolyh p n0 \<Longrightarrow> polybound0 p \<Longrightarrow> isnpolyh (decrpoly p) (n0 - 1)"
   930   apply (induct p arbitrary: n0)
   931   apply auto
   932   apply atomize
   933   apply (erule_tac x = "Suc nat" in allE)
   934   apply auto
   935   done
   936 
   937 lemma head_polybound0: "isnpolyh p n0 \<Longrightarrow> polybound0 (head p)"
   938   by (induct p  arbitrary: n0 rule: head.induct) (auto intro: isnpolyh_polybound0)
   939 
   940 lemma polybound0_I:
   941   assumes nb: "polybound0 a"
   942   shows "Ipoly (b # bs) a = Ipoly (b' # bs) a"
   943   using nb
   944   by (induct a rule: poly.induct) auto
   945 
   946 lemma polysubst0_I: "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b # bs) a) # bs) t"
   947   by (induct t) simp_all
   948 
   949 lemma polysubst0_I':
   950   assumes nb: "polybound0 a"
   951   shows "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b' # bs) a) # bs) t"
   952   by (induct t) (simp_all add: polybound0_I[OF nb, where b="b" and b'="b'"])
   953 
   954 lemma decrpoly:
   955   assumes nb: "polybound0 t"
   956   shows "Ipoly (x # bs) t = Ipoly bs (decrpoly t)"
   957   using nb by (induct t rule: decrpoly.induct) simp_all
   958 
   959 lemma polysubst0_polybound0:
   960   assumes nb: "polybound0 t"
   961   shows "polybound0 (polysubst0 t a)"
   962   using nb by (induct a rule: poly.induct) auto
   963 
   964 lemma degree0_polybound0: "isnpolyh p n \<Longrightarrow> degree p = 0 \<Longrightarrow> polybound0 p"
   965   by (induct p arbitrary: n rule: degree.induct) (auto simp add: isnpolyh_polybound0)
   966 
   967 primrec maxindex :: "poly \<Rightarrow> nat"
   968 where
   969   "maxindex (Bound n) = n + 1"
   970 | "maxindex (CN c n p) = max  (n + 1) (max (maxindex c) (maxindex p))"
   971 | "maxindex (Add p q) = max (maxindex p) (maxindex q)"
   972 | "maxindex (Sub p q) = max (maxindex p) (maxindex q)"
   973 | "maxindex (Mul p q) = max (maxindex p) (maxindex q)"
   974 | "maxindex (Neg p) = maxindex p"
   975 | "maxindex (Pw p n) = maxindex p"
   976 | "maxindex (C x) = 0"
   977 
   978 definition wf_bs :: "'a list \<Rightarrow> poly \<Rightarrow> bool"
   979   where "wf_bs bs p \<longleftrightarrow> length bs \<ge> maxindex p"
   980 
   981 lemma wf_bs_coefficients: "wf_bs bs p \<Longrightarrow> \<forall>c \<in> set (coefficients p). wf_bs bs c"
   982 proof (induct p rule: coefficients.induct)
   983   case (1 c p)
   984   show ?case
   985   proof
   986     fix x
   987     assume xc: "x \<in> set (coefficients (CN c 0 p))"
   988     then have "x = c \<or> x \<in> set (coefficients p)"
   989       by simp
   990     moreover
   991     {
   992       assume "x = c"
   993       then have "wf_bs bs x"
   994         using "1.prems" unfolding wf_bs_def by simp
   995     }
   996     moreover
   997     {
   998       assume H: "x \<in> set (coefficients p)"
   999       from "1.prems" have "wf_bs bs p"
  1000         unfolding wf_bs_def by simp
  1001       with "1.hyps" H have "wf_bs bs x"
  1002         by blast
  1003     }
  1004     ultimately show "wf_bs bs x"
  1005       by blast
  1006   qed
  1007 qed simp_all
  1008 
  1009 lemma maxindex_coefficients: "\<forall>c \<in> set (coefficients p). maxindex c \<le> maxindex p"
  1010   by (induct p rule: coefficients.induct) auto
  1011 
  1012 lemma wf_bs_I: "wf_bs bs p \<Longrightarrow> Ipoly (bs @ bs') p = Ipoly bs p"
  1013   unfolding wf_bs_def by (induct p) (auto simp add: nth_append)
  1014 
  1015 lemma take_maxindex_wf:
  1016   assumes wf: "wf_bs bs p"
  1017   shows "Ipoly (take (maxindex p) bs) p = Ipoly bs p"
  1018 proof -
  1019   let ?ip = "maxindex p"
  1020   let ?tbs = "take ?ip bs"
  1021   from wf have "length ?tbs = ?ip"
  1022     unfolding wf_bs_def by simp
  1023   then have wf': "wf_bs ?tbs p"
  1024     unfolding wf_bs_def by  simp
  1025   have eq: "bs = ?tbs @ drop ?ip bs"
  1026     by simp
  1027   from wf_bs_I[OF wf', of "drop ?ip bs"] show ?thesis
  1028     using eq by simp
  1029 qed
  1030 
  1031 lemma decr_maxindex: "polybound0 p \<Longrightarrow> maxindex (decrpoly p) = maxindex p - 1"
  1032   by (induct p) auto
  1033 
  1034 lemma wf_bs_insensitive: "length bs = length bs' \<Longrightarrow> wf_bs bs p = wf_bs bs' p"
  1035   unfolding wf_bs_def by simp
  1036 
  1037 lemma wf_bs_insensitive': "wf_bs (x#bs) p = wf_bs (y#bs) p"
  1038   unfolding wf_bs_def by simp
  1039 
  1040 lemma wf_bs_coefficients': "\<forall>c \<in> set (coefficients p). wf_bs bs c \<Longrightarrow> wf_bs (x#bs) p"
  1041   by (induct p rule: coefficients.induct) (auto simp add: wf_bs_def)
  1042 
  1043 lemma coefficients_Nil[simp]: "coefficients p \<noteq> []"
  1044   by (induct p rule: coefficients.induct) simp_all
  1045 
  1046 lemma coefficients_head: "last (coefficients p) = head p"
  1047   by (induct p rule: coefficients.induct) auto
  1048 
  1049 lemma wf_bs_decrpoly: "wf_bs bs (decrpoly p) \<Longrightarrow> wf_bs (x#bs) p"
  1050   unfolding wf_bs_def by (induct p rule: decrpoly.induct) auto
  1051 
  1052 lemma length_le_list_ex: "length xs \<le> n \<Longrightarrow> \<exists>ys. length (xs @ ys) = n"
  1053   apply (rule exI[where x="replicate (n - length xs) z"])
  1054   apply simp
  1055   done
  1056 
  1057 lemma isnpolyh_Suc_const: "isnpolyh p (Suc n) \<Longrightarrow> isconstant p"
  1058   apply (cases p)
  1059   apply auto
  1060   apply (case_tac "nat")
  1061   apply simp_all
  1062   done
  1063 
  1064 lemma wf_bs_polyadd: "wf_bs bs p \<and> wf_bs bs q \<longrightarrow> wf_bs bs (p +\<^sub>p q)"
  1065   unfolding wf_bs_def by (induct p q rule: polyadd.induct) (auto simp add: Let_def)
  1066 
  1067 lemma wf_bs_polyul: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p *\<^sub>p q)"
  1068   unfolding wf_bs_def
  1069   apply (induct p q arbitrary: bs rule: polymul.induct)
  1070   apply (simp_all add: wf_bs_polyadd)
  1071   apply clarsimp
  1072   apply (rule wf_bs_polyadd[unfolded wf_bs_def, rule_format])
  1073   apply auto
  1074   done
  1075 
  1076 lemma wf_bs_polyneg: "wf_bs bs p \<Longrightarrow> wf_bs bs (~\<^sub>p p)"
  1077   unfolding wf_bs_def by (induct p rule: polyneg.induct) auto
  1078 
  1079 lemma wf_bs_polysub: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p -\<^sub>p q)"
  1080   unfolding polysub_def split_def fst_conv snd_conv
  1081   using wf_bs_polyadd wf_bs_polyneg by blast
  1082 
  1083 
  1084 subsection {* Canonicity of polynomial representation, see lemma isnpolyh_unique *}
  1085 
  1086 definition "polypoly bs p = map (Ipoly bs) (coefficients p)"
  1087 definition "polypoly' bs p = map (Ipoly bs \<circ> decrpoly) (coefficients p)"
  1088 definition "poly_nate bs p = map (Ipoly bs \<circ> decrpoly) (coefficients (polynate p))"
  1089 
  1090 lemma coefficients_normh: "isnpolyh p n0 \<Longrightarrow> \<forall>q \<in> set (coefficients p). isnpolyh q n0"
  1091 proof (induct p arbitrary: n0 rule: coefficients.induct)
  1092   case (1 c p n0)
  1093   have cp: "isnpolyh (CN c 0 p) n0"
  1094     by fact
  1095   then have norm: "isnpolyh c 0" "isnpolyh p 0" "p \<noteq> 0\<^sub>p" "n0 = 0"
  1096     by (auto simp add: isnpolyh_mono[where n'=0])
  1097   from "1.hyps"[OF norm(2)] norm(1) norm(4) show ?case
  1098     by simp
  1099 qed auto
  1100 
  1101 lemma coefficients_isconst: "isnpolyh p n \<Longrightarrow> \<forall>q \<in> set (coefficients p). isconstant q"
  1102   by (induct p arbitrary: n rule: coefficients.induct) (auto simp add: isnpolyh_Suc_const)
  1103 
  1104 lemma polypoly_polypoly':
  1105   assumes np: "isnpolyh p n0"
  1106   shows "polypoly (x # bs) p = polypoly' bs p"
  1107 proof -
  1108   let ?cf = "set (coefficients p)"
  1109   from coefficients_normh[OF np] have cn_norm: "\<forall> q\<in> ?cf. isnpolyh q n0" .
  1110   {
  1111     fix q
  1112     assume q: "q \<in> ?cf"
  1113     from q cn_norm have th: "isnpolyh q n0"
  1114       by blast
  1115     from coefficients_isconst[OF np] q have "isconstant q"
  1116       by blast
  1117     with isconstant_polybound0[OF th] have "polybound0 q"
  1118       by blast
  1119   }
  1120   then have "\<forall>q \<in> ?cf. polybound0 q" ..
  1121   then have "\<forall>q \<in> ?cf. Ipoly (x # bs) q = Ipoly bs (decrpoly q)"
  1122     using polybound0_I[where b=x and bs=bs and b'=y] decrpoly[where x=x and bs=bs]
  1123     by auto
  1124   then show ?thesis
  1125     unfolding polypoly_def polypoly'_def by simp
  1126 qed
  1127 
  1128 lemma polypoly_poly:
  1129   assumes "isnpolyh p n0"
  1130   shows "Ipoly (x # bs) p = poly (polypoly (x # bs) p) x"
  1131   using assms
  1132   by (induct p arbitrary: n0 bs rule: coefficients.induct) (auto simp add: polypoly_def)
  1133 
  1134 lemma polypoly'_poly:
  1135   assumes "isnpolyh p n0"
  1136   shows "\<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup> = poly (polypoly' bs p) x"
  1137   using polypoly_poly[OF assms, simplified polypoly_polypoly'[OF assms]] .
  1138 
  1139 
  1140 lemma polypoly_poly_polybound0:
  1141   assumes "isnpolyh p n0"
  1142     and "polybound0 p"
  1143   shows "polypoly bs p = [Ipoly bs p]"
  1144   using assms
  1145   unfolding polypoly_def
  1146   apply (cases p)
  1147   apply auto
  1148   apply (case_tac nat)
  1149   apply auto
  1150   done
  1151 
  1152 lemma head_isnpolyh: "isnpolyh p n0 \<Longrightarrow> isnpolyh (head p) n0"
  1153   by (induct p rule: head.induct) auto
  1154 
  1155 lemma headn_nz[simp]: "isnpolyh p n0 \<Longrightarrow> headn p m = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  1156   by (cases p) auto
  1157 
  1158 lemma head_eq_headn0: "head p = headn p 0"
  1159   by (induct p rule: head.induct) simp_all
  1160 
  1161 lemma head_nz[simp]: "isnpolyh p n0 \<Longrightarrow> head p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  1162   by (simp add: head_eq_headn0)
  1163 
  1164 lemma isnpolyh_zero_iff:
  1165   assumes nq: "isnpolyh p n0"
  1166     and eq :"\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a::{field_char_0,field_inverse_zero, power})"
  1167   shows "p = 0\<^sub>p"
  1168   using nq eq
  1169 proof (induct "maxindex p" arbitrary: p n0 rule: less_induct)
  1170   case less
  1171   note np = `isnpolyh p n0` and zp = `\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)`
  1172   {
  1173     assume nz: "maxindex p = 0"
  1174     then obtain c where "p = C c"
  1175       using np by (cases p) auto
  1176     with zp np have "p = 0\<^sub>p"
  1177       unfolding wf_bs_def by simp
  1178   }
  1179   moreover
  1180   {
  1181     assume nz: "maxindex p \<noteq> 0"
  1182     let ?h = "head p"
  1183     let ?hd = "decrpoly ?h"
  1184     let ?ihd = "maxindex ?hd"
  1185     from head_isnpolyh[OF np] head_polybound0[OF np]
  1186     have h: "isnpolyh ?h n0" "polybound0 ?h"
  1187       by simp_all
  1188     then have nhd: "isnpolyh ?hd (n0 - 1)"
  1189       using decrpoly_normh by blast
  1190 
  1191     from maxindex_coefficients[of p] coefficients_head[of p, symmetric]
  1192     have mihn: "maxindex ?h \<le> maxindex p"
  1193       by auto
  1194     with decr_maxindex[OF h(2)] nz have ihd_lt_n: "?ihd < maxindex p"
  1195       by auto
  1196     {
  1197       fix bs :: "'a list"
  1198       assume bs: "wf_bs bs ?hd"
  1199       let ?ts = "take ?ihd bs"
  1200       let ?rs = "drop ?ihd bs"
  1201       have ts: "wf_bs ?ts ?hd"
  1202         using bs unfolding wf_bs_def by simp
  1203       have bs_ts_eq: "?ts @ ?rs = bs"
  1204         by simp
  1205       from wf_bs_decrpoly[OF ts] have tsh: " \<forall>x. wf_bs (x # ?ts) ?h"
  1206         by simp
  1207       from ihd_lt_n have "\<forall>x. length (x # ?ts) \<le> maxindex p"
  1208         by simp
  1209       with length_le_list_ex obtain xs where xs: "length ((x # ?ts) @ xs) = maxindex p"
  1210         by blast
  1211       then have "\<forall>x. wf_bs ((x # ?ts) @ xs) p"
  1212         unfolding wf_bs_def by simp
  1213       with zp have "\<forall>x. Ipoly ((x # ?ts) @ xs) p = 0"
  1214         by blast
  1215       then have "\<forall>x. Ipoly (x # (?ts @ xs)) p = 0"
  1216         by simp
  1217       with polypoly_poly[OF np, where ?'a = 'a] polypoly_polypoly'[OF np, where ?'a = 'a]
  1218       have "\<forall>x. poly (polypoly' (?ts @ xs) p) x = poly [] x"
  1219         by simp
  1220       then have "poly (polypoly' (?ts @ xs) p) = poly []"
  1221         by auto
  1222       then have "\<forall>c \<in> set (coefficients p). Ipoly (?ts @ xs) (decrpoly c) = 0"
  1223         using poly_zero[where ?'a='a] by (simp add: polypoly'_def list_all_iff)
  1224       with coefficients_head[of p, symmetric]
  1225       have th0: "Ipoly (?ts @ xs) ?hd = 0"
  1226         by simp
  1227       from bs have wf'': "wf_bs ?ts ?hd"
  1228         unfolding wf_bs_def by simp
  1229       with th0 wf_bs_I[of ?ts ?hd xs] have "Ipoly ?ts ?hd = 0"
  1230         by simp
  1231       with wf'' wf_bs_I[of ?ts ?hd ?rs] bs_ts_eq have "\<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
  1232         by simp
  1233     }
  1234     then have hdz: "\<forall>bs. wf_bs bs ?hd \<longrightarrow> \<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1235       by blast
  1236     from less(1)[OF ihd_lt_n nhd] hdz have "?hd = 0\<^sub>p"
  1237       by blast
  1238     then have "?h = 0\<^sub>p" by simp
  1239     with head_nz[OF np] have "p = 0\<^sub>p" by simp
  1240   }
  1241   ultimately show "p = 0\<^sub>p"
  1242     by blast
  1243 qed
  1244 
  1245 lemma isnpolyh_unique:
  1246   assumes np: "isnpolyh p n0"
  1247     and nq: "isnpolyh q n1"
  1248   shows "(\<forall>bs. \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (\<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup> :: 'a::{field_char_0,field_inverse_zero,power})) \<longleftrightarrow> p = q"
  1249 proof auto
  1250   assume H: "\<forall>bs. (\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> ::'a) = \<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup>"
  1251   then have "\<forall>bs.\<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup>= (0::'a)"
  1252     by simp
  1253   then have "\<forall>bs. wf_bs bs (p -\<^sub>p q) \<longrightarrow> \<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1254     using wf_bs_polysub[where p=p and q=q] by auto
  1255   with isnpolyh_zero_iff[OF polysub_normh[OF np nq]] polysub_0[OF np nq] show "p = q"
  1256     by blast
  1257 qed
  1258 
  1259 
  1260 text{* consequences of unicity on the algorithms for polynomial normalization *}
  1261 
  1262 lemma polyadd_commute:
  1263   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1264     and np: "isnpolyh p n0"
  1265     and nq: "isnpolyh q n1"
  1266   shows "p +\<^sub>p q = q +\<^sub>p p"
  1267   using isnpolyh_unique[OF polyadd_normh[OF np nq] polyadd_normh[OF nq np]]
  1268   by simp
  1269 
  1270 lemma zero_normh: "isnpolyh 0\<^sub>p n"
  1271   by simp
  1272 
  1273 lemma one_normh: "isnpolyh (1)\<^sub>p n"
  1274   by simp
  1275 
  1276 lemma polyadd_0[simp]:
  1277   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1278     and np: "isnpolyh p n0"
  1279   shows "p +\<^sub>p 0\<^sub>p = p"
  1280     and "0\<^sub>p +\<^sub>p p = p"
  1281   using isnpolyh_unique[OF polyadd_normh[OF np zero_normh] np]
  1282     isnpolyh_unique[OF polyadd_normh[OF zero_normh np] np] by simp_all
  1283 
  1284 lemma polymul_1[simp]:
  1285   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1286     and np: "isnpolyh p n0"
  1287   shows "p *\<^sub>p (1)\<^sub>p = p"
  1288     and "(1)\<^sub>p *\<^sub>p p = p"
  1289   using isnpolyh_unique[OF polymul_normh[OF np one_normh] np]
  1290     isnpolyh_unique[OF polymul_normh[OF one_normh np] np] by simp_all
  1291 
  1292 lemma polymul_0[simp]:
  1293   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1294     and np: "isnpolyh p n0"
  1295   shows "p *\<^sub>p 0\<^sub>p = 0\<^sub>p"
  1296     and "0\<^sub>p *\<^sub>p p = 0\<^sub>p"
  1297   using isnpolyh_unique[OF polymul_normh[OF np zero_normh] zero_normh]
  1298     isnpolyh_unique[OF polymul_normh[OF zero_normh np] zero_normh] by simp_all
  1299 
  1300 lemma polymul_commute:
  1301   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1302     and np: "isnpolyh p n0"
  1303     and nq: "isnpolyh q n1"
  1304   shows "p *\<^sub>p q = q *\<^sub>p p"
  1305   using isnpolyh_unique[OF polymul_normh[OF np nq] polymul_normh[OF nq np],
  1306     where ?'a = "'a::{field_char_0,field_inverse_zero, power}"]
  1307   by simp
  1308 
  1309 declare polyneg_polyneg [simp]
  1310 
  1311 lemma isnpolyh_polynate_id [simp]:
  1312   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1313     and np: "isnpolyh p n0"
  1314   shows "polynate p = p"
  1315   using isnpolyh_unique[where ?'a= "'a::{field_char_0,field_inverse_zero}",
  1316       OF polynate_norm[of p, unfolded isnpoly_def] np]
  1317     polynate[where ?'a = "'a::{field_char_0,field_inverse_zero}"]
  1318   by simp
  1319 
  1320 lemma polynate_idempotent[simp]:
  1321   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1322   shows "polynate (polynate p) = polynate p"
  1323   using isnpolyh_polynate_id[OF polynate_norm[of p, unfolded isnpoly_def]] .
  1324 
  1325 lemma poly_nate_polypoly': "poly_nate bs p = polypoly' bs (polynate p)"
  1326   unfolding poly_nate_def polypoly'_def ..
  1327 
  1328 lemma poly_nate_poly:
  1329   "poly (poly_nate bs p) = (\<lambda>x:: 'a ::{field_char_0,field_inverse_zero}. \<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup>)"
  1330   using polypoly'_poly[OF polynate_norm[unfolded isnpoly_def], symmetric, of bs p]
  1331   unfolding poly_nate_polypoly' by auto
  1332 
  1333 
  1334 subsection{* heads, degrees and all that *}
  1335 
  1336 lemma degree_eq_degreen0: "degree p = degreen p 0"
  1337   by (induct p rule: degree.induct) simp_all
  1338 
  1339 lemma degree_polyneg:
  1340   assumes "isnpolyh p n"
  1341   shows "degree (polyneg p) = degree p"
  1342   apply (induct p rule: polyneg.induct)
  1343   using assms
  1344   apply simp_all
  1345   apply (case_tac na)
  1346   apply auto
  1347   done
  1348 
  1349 lemma degree_polyadd:
  1350   assumes np: "isnpolyh p n0"
  1351     and nq: "isnpolyh q n1"
  1352   shows "degree (p +\<^sub>p q) \<le> max (degree p) (degree q)"
  1353   using degreen_polyadd[OF np nq, where m= "0"] degree_eq_degreen0 by simp
  1354 
  1355 
  1356 lemma degree_polysub:
  1357   assumes np: "isnpolyh p n0"
  1358     and nq: "isnpolyh q n1"
  1359   shows "degree (p -\<^sub>p q) \<le> max (degree p) (degree q)"
  1360 proof-
  1361   from nq have nq': "isnpolyh (~\<^sub>p q) n1"
  1362     using polyneg_normh by simp
  1363   from degree_polyadd[OF np nq'] show ?thesis
  1364     by (simp add: polysub_def degree_polyneg[OF nq])
  1365 qed
  1366 
  1367 lemma degree_polysub_samehead:
  1368   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1369     and np: "isnpolyh p n0"
  1370     and nq: "isnpolyh q n1"
  1371     and h: "head p = head q"
  1372     and d: "degree p = degree q"
  1373   shows "degree (p -\<^sub>p q) < degree p \<or> (p -\<^sub>p q = 0\<^sub>p)"
  1374   unfolding polysub_def split_def fst_conv snd_conv
  1375   using np nq h d
  1376 proof (induct p q rule: polyadd.induct)
  1377   case (1 c c')
  1378   then show ?case
  1379     by (simp add: Nsub_def Nsub0[simplified Nsub_def])
  1380 next
  1381   case (2 c c' n' p')
  1382   from 2 have "degree (C c) = degree (CN c' n' p')"
  1383     by simp
  1384   then have nz: "n' > 0"
  1385     by (cases n') auto
  1386   then have "head (CN c' n' p') = CN c' n' p'"
  1387     by (cases n') auto
  1388   with 2 show ?case
  1389     by simp
  1390 next
  1391   case (3 c n p c')
  1392   then have "degree (C c') = degree (CN c n p)"
  1393     by simp
  1394   then have nz: "n > 0"
  1395     by (cases n) auto
  1396   then have "head (CN c n p) = CN c n p"
  1397     by (cases n) auto
  1398   with 3 show ?case by simp
  1399 next
  1400   case (4 c n p c' n' p')
  1401   then have H:
  1402     "isnpolyh (CN c n p) n0"
  1403     "isnpolyh (CN c' n' p') n1"
  1404     "head (CN c n p) = head (CN c' n' p')"
  1405     "degree (CN c n p) = degree (CN c' n' p')"
  1406     by simp_all
  1407   then have degc: "degree c = 0" and degc': "degree c' = 0"
  1408     by simp_all
  1409   then have degnc: "degree (~\<^sub>p c) = 0" and degnc': "degree (~\<^sub>p c') = 0"
  1410     using H(1-2) degree_polyneg by auto
  1411   from H have cnh: "isnpolyh c (Suc n)" and c'nh: "isnpolyh c' (Suc n')"
  1412     by simp_all
  1413   from degree_polysub[OF cnh c'nh, simplified polysub_def] degc degc'
  1414   have degcmc': "degree (c +\<^sub>p  ~\<^sub>pc') = 0"
  1415     by simp
  1416   from H have pnh: "isnpolyh p n" and p'nh: "isnpolyh p' n'"
  1417     by auto
  1418   have "n = n' \<or> n < n' \<or> n > n'"
  1419     by arith
  1420   moreover
  1421   {
  1422     assume nn': "n = n'"
  1423     have "n = 0 \<or> n > 0" by arith
  1424     moreover
  1425     {
  1426       assume nz: "n = 0"
  1427       then have ?case using 4 nn'
  1428         by (auto simp add: Let_def degcmc')
  1429     }
  1430     moreover
  1431     {
  1432       assume nz: "n > 0"
  1433       with nn' H(3) have  cc': "c = c'" and pp': "p = p'"
  1434         by (cases n, auto)+
  1435       then have ?case
  1436         using polysub_same_0[OF p'nh, simplified polysub_def split_def fst_conv snd_conv]
  1437         using polysub_same_0[OF c'nh, simplified polysub_def]
  1438         using nn' 4 by (simp add: Let_def)
  1439     }
  1440     ultimately have ?case by blast
  1441   }
  1442   moreover
  1443   {
  1444     assume nn': "n < n'"
  1445     then have n'p: "n' > 0"
  1446       by simp
  1447     then have headcnp':"head (CN c' n' p') = CN c' n' p'"
  1448       by (cases n') simp_all
  1449     have degcnp': "degree (CN c' n' p') = 0"
  1450       and degcnpeq: "degree (CN c n p) = degree (CN c' n' p')"
  1451       using 4 nn' by (cases n', simp_all)
  1452     then have "n > 0"
  1453       by (cases n) simp_all
  1454     then have headcnp: "head (CN c n p) = CN c n p"
  1455       by (cases n) auto
  1456     from H(3) headcnp headcnp' nn' have ?case
  1457       by auto
  1458   }
  1459   moreover
  1460   {
  1461     assume nn': "n > n'"
  1462     then have np: "n > 0" by simp
  1463     then have headcnp:"head (CN c n p) = CN c n p"
  1464       by (cases n) simp_all
  1465     from 4 have degcnpeq: "degree (CN c' n' p') = degree (CN c n p)"
  1466       by simp
  1467     from np have degcnp: "degree (CN c n p) = 0"
  1468       by (cases n) simp_all
  1469     with degcnpeq have "n' > 0"
  1470       by (cases n') simp_all
  1471     then have headcnp': "head (CN c' n' p') = CN c' n' p'"
  1472       by (cases n') auto
  1473     from H(3) headcnp headcnp' nn' have ?case by auto
  1474   }
  1475   ultimately show ?case by blast
  1476 qed auto
  1477 
  1478 lemma shift1_head : "isnpolyh p n0 \<Longrightarrow> head (shift1 p) = head p"
  1479   by (induct p arbitrary: n0 rule: head.induct) (simp_all add: shift1_def)
  1480 
  1481 lemma funpow_shift1_head: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> head (funpow k shift1 p) = head p"
  1482 proof (induct k arbitrary: n0 p)
  1483   case 0
  1484   then show ?case by auto
  1485 next
  1486   case (Suc k n0 p)
  1487   then have "isnpolyh (shift1 p) 0"
  1488     by (simp add: shift1_isnpolyh)
  1489   with Suc have "head (funpow k shift1 (shift1 p)) = head (shift1 p)"
  1490     and "head (shift1 p) = head p"
  1491     by (simp_all add: shift1_head)
  1492   then show ?case
  1493     by (simp add: funpow_swap1)
  1494 qed
  1495 
  1496 lemma shift1_degree: "degree (shift1 p) = 1 + degree p"
  1497   by (simp add: shift1_def)
  1498 
  1499 lemma funpow_shift1_degree: "degree (funpow k shift1 p) = k + degree p "
  1500   by (induct k arbitrary: p) (auto simp add: shift1_degree)
  1501 
  1502 lemma funpow_shift1_nz: "p \<noteq> 0\<^sub>p \<Longrightarrow> funpow n shift1 p \<noteq> 0\<^sub>p"
  1503   by (induct n arbitrary: p) simp_all
  1504 
  1505 lemma head_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> head p = p"
  1506   by (induct p arbitrary: n rule: degree.induct) auto
  1507 lemma headn_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> headn p m = p"
  1508   by (induct p arbitrary: n rule: degreen.induct) auto
  1509 lemma head_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> head p = p"
  1510   by (induct p arbitrary: n rule: degree.induct) auto
  1511 lemma head_head[simp]: "isnpolyh p n0 \<Longrightarrow> head (head p) = head p"
  1512   by (induct p rule: head.induct) auto
  1513 
  1514 lemma polyadd_eq_const_degree:
  1515   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> polyadd p q = C c \<Longrightarrow> degree p = degree q"
  1516   using polyadd_eq_const_degreen degree_eq_degreen0 by simp
  1517 
  1518 lemma polyadd_head:
  1519   assumes np: "isnpolyh p n0"
  1520     and nq: "isnpolyh q n1"
  1521     and deg: "degree p \<noteq> degree q"
  1522   shows "head (p +\<^sub>p q) = (if degree p < degree q then head q else head p)"
  1523   using np nq deg
  1524   apply (induct p q arbitrary: n0 n1 rule: polyadd.induct)
  1525   using np
  1526   apply simp_all
  1527   apply (case_tac n', simp, simp)
  1528   apply (case_tac n, simp, simp)
  1529   apply (case_tac n, case_tac n', simp add: Let_def)
  1530   apply (auto simp add: polyadd_eq_const_degree)[2]
  1531   apply (metis head_nz)
  1532   apply (metis head_nz)
  1533   apply (metis degree.simps(9) gr0_conv_Suc head.simps(1) less_Suc0 not_less_eq)
  1534   done
  1535 
  1536 lemma polymul_head_polyeq:
  1537   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1538   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> q \<noteq> 0\<^sub>p \<Longrightarrow> head (p *\<^sub>p q) = head p *\<^sub>p head q"
  1539 proof (induct p q arbitrary: n0 n1 rule: polymul.induct)
  1540   case (2 c c' n' p' n0 n1)
  1541   then have "isnpolyh (head (CN c' n' p')) n1" "isnormNum c"
  1542     by (simp_all add: head_isnpolyh)
  1543   then show ?case
  1544     using 2 by (cases n') auto
  1545 next
  1546   case (3 c n p c' n0 n1)
  1547   then have "isnpolyh (head (CN c n p)) n0" "isnormNum c'"
  1548     by (simp_all add: head_isnpolyh)
  1549   then show ?case
  1550     using 3 by (cases n) auto
  1551 next
  1552   case (4 c n p c' n' p' n0 n1)
  1553   then have norm: "isnpolyh p n" "isnpolyh c (Suc n)" "isnpolyh p' n'" "isnpolyh c' (Suc n')"
  1554     "isnpolyh (CN c n p) n" "isnpolyh (CN c' n' p') n'"
  1555     by simp_all
  1556   have "n < n' \<or> n' < n \<or> n = n'" by arith
  1557   moreover
  1558   {
  1559     assume nn': "n < n'"
  1560     then have ?case
  1561       using norm "4.hyps"(2)[OF norm(1,6)] "4.hyps"(1)[OF norm(2,6)]
  1562       apply simp
  1563       apply (cases n)
  1564       apply simp
  1565       apply (cases n')
  1566       apply simp_all
  1567       done
  1568   }
  1569   moreover {
  1570     assume nn': "n'< n"
  1571     then have ?case
  1572       using norm "4.hyps"(6) [OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)]
  1573       apply simp
  1574       apply (cases n')
  1575       apply simp
  1576       apply (cases n)
  1577       apply auto
  1578       done
  1579   }
  1580   moreover
  1581   {
  1582     assume nn': "n' = n"
  1583     from nn' polymul_normh[OF norm(5,4)]
  1584     have ncnpc':"isnpolyh (CN c n p *\<^sub>p c') n" by (simp add: min_def)
  1585     from nn' polymul_normh[OF norm(5,3)] norm
  1586     have ncnpp':"isnpolyh (CN c n p *\<^sub>p p') n" by simp
  1587     from nn' ncnpp' polymul_eq0_iff[OF norm(5,3)] norm(6)
  1588     have ncnpp0':"isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
  1589     from polyadd_normh[OF ncnpc' ncnpp0']
  1590     have nth: "isnpolyh ((CN c n p *\<^sub>p c') +\<^sub>p (CN 0\<^sub>p n (CN c n p *\<^sub>p p'))) n"
  1591       by (simp add: min_def)
  1592     {
  1593       assume np: "n > 0"
  1594       with nn' head_isnpolyh_Suc'[OF np nth]
  1595         head_isnpolyh_Suc'[OF np norm(5)] head_isnpolyh_Suc'[OF np norm(6)[simplified nn']]
  1596       have ?case by simp
  1597     }
  1598     moreover
  1599     {
  1600       assume nz: "n = 0"
  1601       from polymul_degreen[OF norm(5,4), where m="0"]
  1602         polymul_degreen[OF norm(5,3), where m="0"] nn' nz degree_eq_degreen0
  1603       norm(5,6) degree_npolyhCN[OF norm(6)]
  1604     have dth: "degree (CN c 0 p *\<^sub>p c') < degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))"
  1605       by simp
  1606     then have dth': "degree (CN c 0 p *\<^sub>p c') \<noteq> degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))"
  1607       by simp
  1608     from polyadd_head[OF ncnpc'[simplified nz] ncnpp0'[simplified nz] dth'] dth
  1609     have ?case
  1610       using norm "4.hyps"(6)[OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)] nn' nz
  1611       by simp
  1612     }
  1613     ultimately have ?case
  1614       by (cases n) auto
  1615   }
  1616   ultimately show ?case by blast
  1617 qed simp_all
  1618 
  1619 lemma degree_coefficients: "degree p = length (coefficients p) - 1"
  1620   by (induct p rule: degree.induct) auto
  1621 
  1622 lemma degree_head[simp]: "degree (head p) = 0"
  1623   by (induct p rule: head.induct) auto
  1624 
  1625 lemma degree_CN: "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<le> 1 + degree p"
  1626   by (cases n) simp_all
  1627 
  1628 lemma degree_CN': "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<ge>  degree p"
  1629   by (cases n) simp_all
  1630 
  1631 lemma polyadd_different_degree:
  1632   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> degree p \<noteq> degree q \<Longrightarrow>
  1633     degree (polyadd p q) = max (degree p) (degree q)"
  1634   using polyadd_different_degreen degree_eq_degreen0 by simp
  1635 
  1636 lemma degreen_polyneg: "isnpolyh p n0 \<Longrightarrow> degreen (~\<^sub>p p) m = degreen p m"
  1637   by (induct p arbitrary: n0 rule: polyneg.induct) auto
  1638 
  1639 lemma degree_polymul:
  1640   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1641     and np: "isnpolyh p n0"
  1642     and nq: "isnpolyh q n1"
  1643   shows "degree (p *\<^sub>p q) \<le> degree p + degree q"
  1644   using polymul_degreen[OF np nq, where m="0"]  degree_eq_degreen0 by simp
  1645 
  1646 lemma polyneg_degree: "isnpolyh p n \<Longrightarrow> degree (polyneg p) = degree p"
  1647   by (induct p arbitrary: n rule: degree.induct) auto
  1648 
  1649 lemma polyneg_head: "isnpolyh p n \<Longrightarrow> head(polyneg p) = polyneg (head p)"
  1650   by (induct p arbitrary: n rule: degree.induct) auto
  1651 
  1652 
  1653 subsection {* Correctness of polynomial pseudo division *}
  1654 
  1655 lemma polydivide_aux_properties:
  1656   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1657     and np: "isnpolyh p n0"
  1658     and ns: "isnpolyh s n1"
  1659     and ap: "head p = a"
  1660     and ndp: "degree p = n" and pnz: "p \<noteq> 0\<^sub>p"
  1661   shows "polydivide_aux a n p k s = (k',r) \<longrightarrow> k' \<ge> k \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1662     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> (polypow (k' - k) a) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1663   using ns
  1664 proof (induct "degree s" arbitrary: s k k' r n1 rule: less_induct)
  1665   case less
  1666   let ?qths = "\<exists>q n1. isnpolyh q n1 \<and> (a ^\<^sub>p (k' - k) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1667   let ?ths = "polydivide_aux a n p k s = (k', r) \<longrightarrow>  k \<le> k' \<and>
  1668     (degree r = 0 \<or> degree r < degree p) \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1669   let ?b = "head s"
  1670   let ?p' = "funpow (degree s - n) shift1 p"
  1671   let ?xdn = "funpow (degree s - n) shift1 (1)\<^sub>p"
  1672   let ?akk' = "a ^\<^sub>p (k' - k)"
  1673   note ns = `isnpolyh s n1`
  1674   from np have np0: "isnpolyh p 0"
  1675     using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by simp
  1676   have np': "isnpolyh ?p' 0"
  1677     using funpow_shift1_isnpoly[OF np0[simplified isnpoly_def[symmetric]] pnz, where n="degree s - n"] isnpoly_def
  1678     by simp
  1679   have headp': "head ?p' = head p"
  1680     using funpow_shift1_head[OF np pnz] by simp
  1681   from funpow_shift1_isnpoly[where p="(1)\<^sub>p"] have nxdn: "isnpolyh ?xdn 0"
  1682     by (simp add: isnpoly_def)
  1683   from polypow_normh [OF head_isnpolyh[OF np0], where k="k' - k"] ap
  1684   have nakk':"isnpolyh ?akk' 0" by blast
  1685   {
  1686     assume sz: "s = 0\<^sub>p"
  1687     then have ?ths
  1688       using np polydivide_aux.simps
  1689       apply clarsimp
  1690       apply (rule exI[where x="0\<^sub>p"])
  1691       apply simp
  1692       done
  1693   }
  1694   moreover
  1695   {
  1696     assume sz: "s \<noteq> 0\<^sub>p"
  1697     {
  1698       assume dn: "degree s < n"
  1699       then have "?ths"
  1700         using ns ndp np polydivide_aux.simps
  1701         apply auto
  1702         apply (rule exI[where x="0\<^sub>p"])
  1703         apply simp
  1704         done
  1705     }
  1706     moreover
  1707     {
  1708       assume dn': "\<not> degree s < n"
  1709       then have dn: "degree s \<ge> n"
  1710         by arith
  1711       have degsp': "degree s = degree ?p'"
  1712         using dn ndp funpow_shift1_degree[where k = "degree s - n" and p="p"]
  1713         by simp
  1714       {
  1715         assume ba: "?b = a"
  1716         then have headsp': "head s = head ?p'"
  1717           using ap headp' by simp
  1718         have nr: "isnpolyh (s -\<^sub>p ?p') 0"
  1719           using polysub_normh[OF ns np'] by simp
  1720         from degree_polysub_samehead[OF ns np' headsp' degsp']
  1721         have "degree (s -\<^sub>p ?p') < degree s \<or> s -\<^sub>p ?p' = 0\<^sub>p" by simp
  1722         moreover
  1723         {
  1724           assume deglt:"degree (s -\<^sub>p ?p') < degree s"
  1725           from polydivide_aux.simps sz dn' ba
  1726           have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1727             by (simp add: Let_def)
  1728           {
  1729             assume h1: "polydivide_aux a n p k s = (k', r)"
  1730             from less(1)[OF deglt nr, of k k' r] trans[OF eq[symmetric] h1]
  1731             have kk': "k \<le> k'"
  1732               and nr: "\<exists>nr. isnpolyh r nr"
  1733               and dr: "degree r = 0 \<or> degree r < degree p"
  1734               and q1: "\<exists>q nq. isnpolyh q nq \<and> a ^\<^sub>p k' - k *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r"
  1735               by auto
  1736             from q1 obtain q n1 where nq: "isnpolyh q n1"
  1737               and asp: "a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r"
  1738               by blast
  1739             from nr obtain nr where nr': "isnpolyh r nr"
  1740               by blast
  1741             from polymul_normh[OF nakk' ns] have nakks': "isnpolyh (a ^\<^sub>p (k' - k) *\<^sub>p s) 0"
  1742               by simp
  1743             from polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]
  1744             have nq': "isnpolyh (?akk' *\<^sub>p ?xdn +\<^sub>p q) 0" by simp
  1745             from polyadd_normh[OF polymul_normh[OF np
  1746               polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]] nr']
  1747             have nqr': "isnpolyh (p *\<^sub>p (?akk' *\<^sub>p ?xdn +\<^sub>p q) +\<^sub>p r) 0"
  1748               by simp
  1749             from asp have "\<forall>bs :: 'a::{field_char_0,field_inverse_zero} list.
  1750               Ipoly bs (a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p')) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1751               by simp
  1752             then have "\<forall>bs :: 'a::{field_char_0,field_inverse_zero} list.
  1753               Ipoly bs (a^\<^sub>p (k' - k)*\<^sub>p s) =
  1754               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs ?p' + Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1755               by (simp add: field_simps)
  1756             then have "\<forall>bs :: 'a::{field_char_0,field_inverse_zero} list.
  1757               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1758               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p *\<^sub>p p) +
  1759               Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1760               by (auto simp only: funpow_shift1_1)
  1761             then have "\<forall>bs:: 'a::{field_char_0,field_inverse_zero} list.
  1762               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1763               Ipoly bs p * (Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p) +
  1764               Ipoly bs q) + Ipoly bs r"
  1765               by (simp add: field_simps)
  1766             then have "\<forall>bs:: 'a::{field_char_0,field_inverse_zero} list.
  1767               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1768               Ipoly bs (p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r)"
  1769               by simp
  1770             with isnpolyh_unique[OF nakks' nqr']
  1771             have "a ^\<^sub>p (k' - k) *\<^sub>p s =
  1772               p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r"
  1773               by blast
  1774             then have ?qths using nq'
  1775               apply (rule_tac x="(a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q" in exI)
  1776               apply (rule_tac x="0" in exI)
  1777               apply simp
  1778               done
  1779             with kk' nr dr have "k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1780               (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1781               by blast
  1782           }
  1783           then have ?ths by blast
  1784         }
  1785         moreover
  1786         {
  1787           assume spz:"s -\<^sub>p ?p' = 0\<^sub>p"
  1788           from spz isnpolyh_unique[OF polysub_normh[OF ns np'], where q="0\<^sub>p", symmetric, where ?'a = "'a::{field_char_0,field_inverse_zero}"]
  1789           have "\<forall>bs:: 'a::{field_char_0,field_inverse_zero} list. Ipoly bs s = Ipoly bs ?p'"
  1790             by simp
  1791           then have "\<forall>bs:: 'a::{field_char_0,field_inverse_zero} list. Ipoly bs s = Ipoly bs (?xdn *\<^sub>p p)"
  1792             using np nxdn
  1793             apply simp
  1794             apply (simp only: funpow_shift1_1)
  1795             apply simp
  1796             done
  1797           then have sp': "s = ?xdn *\<^sub>p p"
  1798             using isnpolyh_unique[OF ns polymul_normh[OF nxdn np]]
  1799             by blast
  1800           {
  1801             assume h1: "polydivide_aux a n p k s = (k',r)"
  1802             from polydivide_aux.simps sz dn' ba
  1803             have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1804               by (simp add: Let_def)
  1805             also have "\<dots> = (k,0\<^sub>p)"
  1806               using polydivide_aux.simps spz by simp
  1807             finally have "(k', r) = (k, 0\<^sub>p)"
  1808               using h1 by simp
  1809             with sp'[symmetric] ns np nxdn polyadd_0(1)[OF polymul_normh[OF np nxdn]]
  1810               polyadd_0(2)[OF polymul_normh[OF np nxdn]] have ?ths
  1811               apply auto
  1812               apply (rule exI[where x="?xdn"])
  1813               apply (auto simp add: polymul_commute[of p])
  1814               done
  1815           }
  1816         }
  1817         ultimately have ?ths by blast
  1818       }
  1819       moreover
  1820       {
  1821         assume ba: "?b \<noteq> a"
  1822         from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns]
  1823           polymul_normh[OF head_isnpolyh[OF ns] np']]
  1824         have nth: "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1825           by (simp add: min_def)
  1826         have nzths: "a *\<^sub>p s \<noteq> 0\<^sub>p" "?b *\<^sub>p ?p' \<noteq> 0\<^sub>p"
  1827           using polymul_eq0_iff[OF head_isnpolyh[OF np0, simplified ap] ns]
  1828             polymul_eq0_iff[OF head_isnpolyh[OF ns] np']head_nz[OF np0] ap pnz sz head_nz[OF ns]
  1829             funpow_shift1_nz[OF pnz]
  1830           by simp_all
  1831         from polymul_head_polyeq[OF head_isnpolyh[OF np] ns] head_nz[OF np] sz ap head_head[OF np] pnz
  1832           polymul_head_polyeq[OF head_isnpolyh[OF ns] np'] head_nz [OF ns] sz funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1833         have hdth: "head (a *\<^sub>p s) = head (?b *\<^sub>p ?p')"
  1834           using head_head[OF ns] funpow_shift1_head[OF np pnz]
  1835             polymul_commute[OF head_isnpolyh[OF np] head_isnpolyh[OF ns]]
  1836           by (simp add: ap)
  1837         from polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1838           head_nz[OF np] pnz sz ap[symmetric]
  1839           funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1840           polymul_degreen[OF head_isnpolyh[OF ns] np', where m="0"] head_nz[OF ns]
  1841           ndp dn
  1842         have degth: "degree (a *\<^sub>p s) = degree (?b *\<^sub>p ?p')"
  1843           by (simp add: degree_eq_degreen0[symmetric] funpow_shift1_degree)
  1844         {
  1845           assume dth: "degree ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) < degree s"
  1846           from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1847             polymul_normh[OF head_isnpolyh[OF ns]np']] ap
  1848           have nasbp': "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1849             by simp
  1850           {
  1851             assume h1:"polydivide_aux a n p k s = (k', r)"
  1852             from h1 polydivide_aux.simps sz dn' ba
  1853             have eq:"polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = (k',r)"
  1854               by (simp add: Let_def)
  1855             with less(1)[OF dth nasbp', of "Suc k" k' r]
  1856             obtain q nq nr where kk': "Suc k \<le> k'"
  1857               and nr: "isnpolyh r nr"
  1858               and nq: "isnpolyh q nq"
  1859               and dr: "degree r = 0 \<or> degree r < degree p"
  1860               and qr: "a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = p *\<^sub>p q +\<^sub>p r"
  1861               by auto
  1862             from kk' have kk'': "Suc (k' - Suc k) = k' - k"
  1863               by arith
  1864             {
  1865               fix bs :: "'a::{field_char_0,field_inverse_zero} list"
  1866               from qr isnpolyh_unique[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k", simplified ap] nasbp', symmetric]
  1867               have "Ipoly bs (a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p'))) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1868                 by simp
  1869               then have "Ipoly bs a ^ (Suc (k' - Suc k)) * Ipoly bs s =
  1870                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?p' + Ipoly bs r"
  1871                 by (simp add: field_simps)
  1872               then have "Ipoly bs a ^ (k' - k)  * Ipoly bs s =
  1873                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn * Ipoly bs p + Ipoly bs r"
  1874                 by (simp add: kk'' funpow_shift1_1[where n="degree s - n" and p="p"])
  1875               then have "Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1876                 Ipoly bs p * (Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn) + Ipoly bs r"
  1877                 by (simp add: field_simps)
  1878             }
  1879             then have ieq:"\<forall>bs :: 'a::{field_char_0,field_inverse_zero} list.
  1880               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1881               Ipoly bs (p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r)"
  1882               by auto
  1883             let ?q = "q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)"
  1884             from polyadd_normh[OF nq polymul_normh[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k"] head_isnpolyh[OF ns], simplified ap ] nxdn]]
  1885             have nqw: "isnpolyh ?q 0"
  1886               by simp
  1887             from ieq isnpolyh_unique[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - k"] ns, simplified ap] polyadd_normh[OF polymul_normh[OF np nqw] nr]]
  1888             have asth: "(a ^\<^sub>p (k' - k) *\<^sub>p s) = p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r"
  1889               by blast
  1890             from dr kk' nr h1 asth nqw have ?ths
  1891               apply simp
  1892               apply (rule conjI)
  1893               apply (rule exI[where x="nr"], simp)
  1894               apply (rule exI[where x="(q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn))"], simp)
  1895               apply (rule exI[where x="0"], simp)
  1896               done
  1897           }
  1898           then have ?ths by blast
  1899         }
  1900         moreover
  1901         {
  1902           assume spz: "a *\<^sub>p s -\<^sub>p (?b *\<^sub>p ?p') = 0\<^sub>p"
  1903           {
  1904             fix bs :: "'a::{field_char_0,field_inverse_zero} list"
  1905             from isnpolyh_unique[OF nth, where ?'a="'a" and q="0\<^sub>p",simplified,symmetric] spz
  1906             have "Ipoly bs (a*\<^sub>p s) = Ipoly bs ?b * Ipoly bs ?p'"
  1907               by simp
  1908             then have "Ipoly bs (a*\<^sub>p s) = Ipoly bs (?b *\<^sub>p ?xdn) * Ipoly bs p"
  1909               by (simp add: funpow_shift1_1[where n="degree s - n" and p="p"])
  1910             then have "Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))"
  1911               by simp
  1912           }
  1913           then have hth: "\<forall>bs :: 'a::{field_char_0,field_inverse_zero} list.
  1914             Ipoly bs (a *\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" ..
  1915           from hth have asq: "a *\<^sub>p s = p *\<^sub>p (?b *\<^sub>p ?xdn)"
  1916             using isnpolyh_unique[where ?'a = "'a::{field_char_0,field_inverse_zero}", OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1917                     polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]],
  1918               simplified ap]
  1919             by simp
  1920           {
  1921             assume h1: "polydivide_aux a n p k s = (k', r)"
  1922             from h1 sz ba dn' spz polydivide_aux.simps polydivide_aux.simps
  1923             have "(k', r) = (Suc k, 0\<^sub>p)"
  1924               by (simp add: Let_def)
  1925             with h1 np head_isnpolyh[OF np, simplified ap] ns polymul_normh[OF head_isnpolyh[OF ns] nxdn]
  1926               polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]] asq
  1927             have ?ths
  1928               apply (clarsimp simp add: Let_def)
  1929               apply (rule exI[where x="?b *\<^sub>p ?xdn"])
  1930               apply simp
  1931               apply (rule exI[where x="0"], simp)
  1932               done
  1933           }
  1934           then have ?ths by blast
  1935         }
  1936         ultimately have ?ths
  1937           using degree_polysub_samehead[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] polymul_normh[OF head_isnpolyh[OF ns] np'] hdth degth] polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1938             head_nz[OF np] pnz sz ap[symmetric]
  1939           by (auto simp add: degree_eq_degreen0[symmetric])
  1940       }
  1941       ultimately have ?ths by blast
  1942     }
  1943     ultimately have ?ths by blast
  1944   }
  1945   ultimately show ?ths by blast
  1946 qed
  1947 
  1948 lemma polydivide_properties:
  1949   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  1950     and np: "isnpolyh p n0"
  1951     and ns: "isnpolyh s n1"
  1952     and pnz: "p \<noteq> 0\<^sub>p"
  1953   shows "\<exists>k r. polydivide s p = (k, r) \<and>
  1954     (\<exists>nr. isnpolyh r nr) \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1955     (\<exists>q n1. isnpolyh q n1 \<and> polypow k (head p) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1956 proof -
  1957   have trv: "head p = head p" "degree p = degree p"
  1958     by simp_all
  1959   from polydivide_def[where s="s" and p="p"] have ex: "\<exists> k r. polydivide s p = (k,r)"
  1960     by auto
  1961   then obtain k r where kr: "polydivide s p = (k,r)"
  1962     by blast
  1963   from trans[OF polydivide_def[where s="s"and p="p", symmetric] kr]
  1964     polydivide_aux_properties[OF np ns trv pnz, where k="0" and k'="k" and r="r"]
  1965   have "(degree r = 0 \<or> degree r < degree p) \<and>
  1966     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> head p ^\<^sub>p k - 0 *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1967     by blast
  1968   with kr show ?thesis
  1969     apply -
  1970     apply (rule exI[where x="k"])
  1971     apply (rule exI[where x="r"])
  1972     apply simp
  1973     done
  1974 qed
  1975 
  1976 
  1977 subsection {* More about polypoly and pnormal etc *}
  1978 
  1979 definition "isnonconstant p \<longleftrightarrow> \<not> isconstant p"
  1980 
  1981 lemma isnonconstant_pnormal_iff:
  1982   assumes nc: "isnonconstant p"
  1983   shows "pnormal (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1984 proof
  1985   let ?p = "polypoly bs p"
  1986   assume H: "pnormal ?p"
  1987   have csz: "coefficients p \<noteq> []"
  1988     using nc by (cases p) auto
  1989   from coefficients_head[of p] last_map[OF csz, of "Ipoly bs"] pnormal_last_nonzero[OF H]
  1990   show "Ipoly bs (head p) \<noteq> 0"
  1991     by (simp add: polypoly_def)
  1992 next
  1993   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1994   let ?p = "polypoly bs p"
  1995   have csz: "coefficients p \<noteq> []"
  1996     using nc by (cases p) auto
  1997   then have pz: "?p \<noteq> []"
  1998     by (simp add: polypoly_def)
  1999   then have lg: "length ?p > 0"
  2000     by simp
  2001   from h coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  2002   have lz: "last ?p \<noteq> 0"
  2003     by (simp add: polypoly_def)
  2004   from pnormal_last_length[OF lg lz] show "pnormal ?p" .
  2005 qed
  2006 
  2007 lemma isnonconstant_coefficients_length: "isnonconstant p \<Longrightarrow> length (coefficients p) > 1"
  2008   unfolding isnonconstant_def
  2009   apply (cases p)
  2010   apply simp_all
  2011   apply (case_tac nat)
  2012   apply auto
  2013   done
  2014 
  2015 lemma isnonconstant_nonconstant:
  2016   assumes inc: "isnonconstant p"
  2017   shows "nonconstant (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  2018 proof
  2019   let ?p = "polypoly bs p"
  2020   assume nc: "nonconstant ?p"
  2021   from isnonconstant_pnormal_iff[OF inc, of bs] nc
  2022   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2023     unfolding nonconstant_def by blast
  2024 next
  2025   let ?p = "polypoly bs p"
  2026   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2027   from isnonconstant_pnormal_iff[OF inc, of bs] h
  2028   have pn: "pnormal ?p"
  2029     by blast
  2030   {
  2031     fix x
  2032     assume H: "?p = [x]"
  2033     from H have "length (coefficients p) = 1"
  2034       unfolding polypoly_def by auto
  2035     with isnonconstant_coefficients_length[OF inc]
  2036       have False by arith
  2037   }
  2038   then show "nonconstant ?p"
  2039     using pn unfolding nonconstant_def by blast
  2040 qed
  2041 
  2042 lemma pnormal_length: "p \<noteq> [] \<Longrightarrow> pnormal p \<longleftrightarrow> length (pnormalize p) = length p"
  2043   apply (induct p)
  2044   apply (simp_all add: pnormal_def)
  2045   apply (case_tac "p = []")
  2046   apply simp_all
  2047   done
  2048 
  2049 lemma degree_degree:
  2050   assumes inc: "isnonconstant p"
  2051   shows "degree p = Polynomial_List.degree (polypoly bs p) \<longleftrightarrow> \<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2052 proof
  2053   let ?p = "polypoly bs p"
  2054   assume H: "degree p = Polynomial_List.degree ?p"
  2055   from isnonconstant_coefficients_length[OF inc] have pz: "?p \<noteq> []"
  2056     unfolding polypoly_def by auto
  2057   from H degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  2058   have lg: "length (pnormalize ?p) = length ?p"
  2059     unfolding Polynomial_List.degree_def polypoly_def by simp
  2060   then have "pnormal ?p"
  2061     using pnormal_length[OF pz] by blast
  2062   with isnonconstant_pnormal_iff[OF inc] show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2063     by blast
  2064 next
  2065   let ?p = "polypoly bs p"
  2066   assume H: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2067   with isnonconstant_pnormal_iff[OF inc] have "pnormal ?p"
  2068     by blast
  2069   with degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  2070   show "degree p = Polynomial_List.degree ?p"
  2071     unfolding polypoly_def pnormal_def Polynomial_List.degree_def by auto
  2072 qed
  2073 
  2074 
  2075 section {* Swaps ; Division by a certain variable *}
  2076 
  2077 primrec swap :: "nat \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> poly"
  2078 where
  2079   "swap n m (C x) = C x"
  2080 | "swap n m (Bound k) = Bound (if k = n then m else if k=m then n else k)"
  2081 | "swap n m (Neg t) = Neg (swap n m t)"
  2082 | "swap n m (Add s t) = Add (swap n m s) (swap n m t)"
  2083 | "swap n m (Sub s t) = Sub (swap n m s) (swap n m t)"
  2084 | "swap n m (Mul s t) = Mul (swap n m s) (swap n m t)"
  2085 | "swap n m (Pw t k) = Pw (swap n m t) k"
  2086 | "swap n m (CN c k p) = CN (swap n m c) (if k = n then m else if k=m then n else k) (swap n m p)"
  2087 
  2088 lemma swap:
  2089   assumes "n < length bs"
  2090     and "m < length bs"
  2091   shows "Ipoly bs (swap n m t) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2092 proof (induct t)
  2093   case (Bound k)
  2094   then show ?case
  2095     using assms by simp
  2096 next
  2097   case (CN c k p)
  2098   then show ?case
  2099     using assms by simp
  2100 qed simp_all
  2101 
  2102 lemma swap_swap_id [simp]: "swap n m (swap m n t) = t"
  2103   by (induct t) simp_all
  2104 
  2105 lemma swap_commute: "swap n m p = swap m n p"
  2106   by (induct p) simp_all
  2107 
  2108 lemma swap_same_id[simp]: "swap n n t = t"
  2109   by (induct t) simp_all
  2110 
  2111 definition "swapnorm n m t = polynate (swap n m t)"
  2112 
  2113 lemma swapnorm:
  2114   assumes nbs: "n < length bs"
  2115     and mbs: "m < length bs"
  2116   shows "((Ipoly bs (swapnorm n m t) :: 'a::{field_char_0,field_inverse_zero})) =
  2117     Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2118   using swap[OF assms] swapnorm_def by simp
  2119 
  2120 lemma swapnorm_isnpoly [simp]:
  2121   assumes "SORT_CONSTRAINT('a::{field_char_0,field_inverse_zero})"
  2122   shows "isnpoly (swapnorm n m p)"
  2123   unfolding swapnorm_def by simp
  2124 
  2125 definition "polydivideby n s p =
  2126   (let
  2127     ss = swapnorm 0 n s;
  2128     sp = swapnorm 0 n p;
  2129     h = head sp;
  2130     (k, r) = polydivide ss sp
  2131    in (k, swapnorm 0 n h, swapnorm 0 n r))"
  2132 
  2133 lemma swap_nz [simp]: "swap n m p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  2134   by (induct p) simp_all
  2135 
  2136 fun isweaknpoly :: "poly \<Rightarrow> bool"
  2137 where
  2138   "isweaknpoly (C c) = True"
  2139 | "isweaknpoly (CN c n p) \<longleftrightarrow> isweaknpoly c \<and> isweaknpoly p"
  2140 | "isweaknpoly p = False"
  2141 
  2142 lemma isnpolyh_isweaknpoly: "isnpolyh p n0 \<Longrightarrow> isweaknpoly p"
  2143   by (induct p arbitrary: n0) auto
  2144 
  2145 lemma swap_isweanpoly: "isweaknpoly p \<Longrightarrow> isweaknpoly (swap n m p)"
  2146   by (induct p) auto
  2147 
  2148 end