src/HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
author wenzelm
Thu Jul 09 00:40:57 2015 +0200 (2015-07-09)
changeset 60698 29e8bdc41f90
parent 60580 7e741e22d7fc
child 61166 5976fe402824
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
     2     Author:     Amine Chaieb
     3 *)
     4 
     5 section \<open>Implementation and verification of multivariate polynomials\<close>
     6 
     7 theory Reflected_Multivariate_Polynomial
     8 imports Complex_Main Rat_Pair Polynomial_List
     9 begin
    10 
    11 subsection \<open>Datatype of polynomial expressions\<close>
    12 
    13 datatype poly = C Num | Bound nat | Add poly poly | Sub poly poly
    14   | Mul poly poly| Neg poly| Pw poly nat| CN poly nat poly
    15 
    16 abbreviation poly_0 :: "poly" ("0\<^sub>p") where "0\<^sub>p \<equiv> C (0\<^sub>N)"
    17 abbreviation poly_p :: "int \<Rightarrow> poly" ("'((_)')\<^sub>p") where "(i)\<^sub>p \<equiv> C (i)\<^sub>N"
    18 
    19 
    20 subsection\<open>Boundedness, substitution and all that\<close>
    21 
    22 primrec polysize:: "poly \<Rightarrow> nat"
    23 where
    24   "polysize (C c) = 1"
    25 | "polysize (Bound n) = 1"
    26 | "polysize (Neg p) = 1 + polysize p"
    27 | "polysize (Add p q) = 1 + polysize p + polysize q"
    28 | "polysize (Sub p q) = 1 + polysize p + polysize q"
    29 | "polysize (Mul p q) = 1 + polysize p + polysize q"
    30 | "polysize (Pw p n) = 1 + polysize p"
    31 | "polysize (CN c n p) = 4 + polysize c + polysize p"
    32 
    33 primrec polybound0:: "poly \<Rightarrow> bool" -- \<open>a poly is INDEPENDENT of Bound 0\<close>
    34 where
    35   "polybound0 (C c) \<longleftrightarrow> True"
    36 | "polybound0 (Bound n) \<longleftrightarrow> n > 0"
    37 | "polybound0 (Neg a) \<longleftrightarrow> polybound0 a"
    38 | "polybound0 (Add a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    39 | "polybound0 (Sub a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    40 | "polybound0 (Mul a b) \<longleftrightarrow> polybound0 a \<and> polybound0 b"
    41 | "polybound0 (Pw p n) \<longleftrightarrow> polybound0 p"
    42 | "polybound0 (CN c n p) \<longleftrightarrow> n \<noteq> 0 \<and> polybound0 c \<and> polybound0 p"
    43 
    44 primrec polysubst0:: "poly \<Rightarrow> poly \<Rightarrow> poly" -- \<open>substitute a poly into a poly for Bound 0\<close>
    45 where
    46   "polysubst0 t (C c) = C c"
    47 | "polysubst0 t (Bound n) = (if n = 0 then t else Bound n)"
    48 | "polysubst0 t (Neg a) = Neg (polysubst0 t a)"
    49 | "polysubst0 t (Add a b) = Add (polysubst0 t a) (polysubst0 t b)"
    50 | "polysubst0 t (Sub a b) = Sub (polysubst0 t a) (polysubst0 t b)"
    51 | "polysubst0 t (Mul a b) = Mul (polysubst0 t a) (polysubst0 t b)"
    52 | "polysubst0 t (Pw p n) = Pw (polysubst0 t p) n"
    53 | "polysubst0 t (CN c n p) =
    54     (if n = 0 then Add (polysubst0 t c) (Mul t (polysubst0 t p))
    55      else CN (polysubst0 t c) n (polysubst0 t p))"
    56 
    57 fun decrpoly:: "poly \<Rightarrow> poly"
    58 where
    59   "decrpoly (Bound n) = Bound (n - 1)"
    60 | "decrpoly (Neg a) = Neg (decrpoly a)"
    61 | "decrpoly (Add a b) = Add (decrpoly a) (decrpoly b)"
    62 | "decrpoly (Sub a b) = Sub (decrpoly a) (decrpoly b)"
    63 | "decrpoly (Mul a b) = Mul (decrpoly a) (decrpoly b)"
    64 | "decrpoly (Pw p n) = Pw (decrpoly p) n"
    65 | "decrpoly (CN c n p) = CN (decrpoly c) (n - 1) (decrpoly p)"
    66 | "decrpoly a = a"
    67 
    68 
    69 subsection \<open>Degrees and heads and coefficients\<close>
    70 
    71 fun degree :: "poly \<Rightarrow> nat"
    72 where
    73   "degree (CN c 0 p) = 1 + degree p"
    74 | "degree p = 0"
    75 
    76 fun head :: "poly \<Rightarrow> poly"
    77 where
    78   "head (CN c 0 p) = head p"
    79 | "head p = p"
    80 
    81 text \<open>More general notions of degree and head.\<close>
    82 
    83 fun degreen :: "poly \<Rightarrow> nat \<Rightarrow> nat"
    84 where
    85   "degreen (CN c n p) = (\<lambda>m. if n = m then 1 + degreen p n else 0)"
    86 | "degreen p = (\<lambda>m. 0)"
    87 
    88 fun headn :: "poly \<Rightarrow> nat \<Rightarrow> poly"
    89 where
    90   "headn (CN c n p) = (\<lambda>m. if n \<le> m then headn p m else CN c n p)"
    91 | "headn p = (\<lambda>m. p)"
    92 
    93 fun coefficients :: "poly \<Rightarrow> poly list"
    94 where
    95   "coefficients (CN c 0 p) = c # coefficients p"
    96 | "coefficients p = [p]"
    97 
    98 fun isconstant :: "poly \<Rightarrow> bool"
    99 where
   100   "isconstant (CN c 0 p) = False"
   101 | "isconstant p = True"
   102 
   103 fun behead :: "poly \<Rightarrow> poly"
   104 where
   105   "behead (CN c 0 p) = (let p' = behead p in if p' = 0\<^sub>p then c else CN c 0 p')"
   106 | "behead p = 0\<^sub>p"
   107 
   108 fun headconst :: "poly \<Rightarrow> Num"
   109 where
   110   "headconst (CN c n p) = headconst p"
   111 | "headconst (C n) = n"
   112 
   113 
   114 subsection \<open>Operations for normalization\<close>
   115 
   116 declare if_cong[fundef_cong del]
   117 declare let_cong[fundef_cong del]
   118 
   119 fun polyadd :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "+\<^sub>p" 60)
   120 where
   121   "polyadd (C c) (C c') = C (c +\<^sub>N c')"
   122 | "polyadd (C c) (CN c' n' p') = CN (polyadd (C c) c') n' p'"
   123 | "polyadd (CN c n p) (C c') = CN (polyadd c (C c')) n p"
   124 | "polyadd (CN c n p) (CN c' n' p') =
   125     (if n < n' then CN (polyadd c (CN c' n' p')) n p
   126      else if n' < n then CN (polyadd (CN c n p) c') n' p'
   127      else
   128       let
   129         cc' = polyadd c c';
   130         pp' = polyadd p p'
   131       in if pp' = 0\<^sub>p then cc' else CN cc' n pp')"
   132 | "polyadd a b = Add a b"
   133 
   134 
   135 fun polyneg :: "poly \<Rightarrow> poly" ("~\<^sub>p")
   136 where
   137   "polyneg (C c) = C (~\<^sub>N c)"
   138 | "polyneg (CN c n p) = CN (polyneg c) n (polyneg p)"
   139 | "polyneg a = Neg a"
   140 
   141 definition polysub :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "-\<^sub>p" 60)
   142   where "p -\<^sub>p q = polyadd p (polyneg q)"
   143 
   144 fun polymul :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "*\<^sub>p" 60)
   145 where
   146   "polymul (C c) (C c') = C (c *\<^sub>N c')"
   147 | "polymul (C c) (CN c' n' p') =
   148     (if c = 0\<^sub>N then 0\<^sub>p else CN (polymul (C c) c') n' (polymul (C c) p'))"
   149 | "polymul (CN c n p) (C c') =
   150     (if c' = 0\<^sub>N  then 0\<^sub>p else CN (polymul c (C c')) n (polymul p (C c')))"
   151 | "polymul (CN c n p) (CN c' n' p') =
   152     (if n < n' then CN (polymul c (CN c' n' p')) n (polymul p (CN c' n' p'))
   153      else if n' < n then CN (polymul (CN c n p) c') n' (polymul (CN c n p) p')
   154      else polyadd (polymul (CN c n p) c') (CN 0\<^sub>p n' (polymul (CN c n p) p')))"
   155 | "polymul a b = Mul a b"
   156 
   157 declare if_cong[fundef_cong]
   158 declare let_cong[fundef_cong]
   159 
   160 fun polypow :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   161 where
   162   "polypow 0 = (\<lambda>p. (1)\<^sub>p)"
   163 | "polypow n =
   164     (\<lambda>p.
   165       let
   166         q = polypow (n div 2) p;
   167         d = polymul q q
   168       in if even n then d else polymul p d)"
   169 
   170 abbreviation poly_pow :: "poly \<Rightarrow> nat \<Rightarrow> poly" (infixl "^\<^sub>p" 60)
   171   where "a ^\<^sub>p k \<equiv> polypow k a"
   172 
   173 function polynate :: "poly \<Rightarrow> poly"
   174 where
   175   "polynate (Bound n) = CN 0\<^sub>p n (1)\<^sub>p"
   176 | "polynate (Add p q) = polynate p +\<^sub>p polynate q"
   177 | "polynate (Sub p q) = polynate p -\<^sub>p polynate q"
   178 | "polynate (Mul p q) = polynate p *\<^sub>p polynate q"
   179 | "polynate (Neg p) = ~\<^sub>p (polynate p)"
   180 | "polynate (Pw p n) = polynate p ^\<^sub>p n"
   181 | "polynate (CN c n p) = polynate (Add c (Mul (Bound n) p))"
   182 | "polynate (C c) = C (normNum c)"
   183   by pat_completeness auto
   184 termination by (relation "measure polysize") auto
   185 
   186 fun poly_cmul :: "Num \<Rightarrow> poly \<Rightarrow> poly"
   187 where
   188   "poly_cmul y (C x) = C (y *\<^sub>N x)"
   189 | "poly_cmul y (CN c n p) = CN (poly_cmul y c) n (poly_cmul y p)"
   190 | "poly_cmul y p = C y *\<^sub>p p"
   191 
   192 definition monic :: "poly \<Rightarrow> poly \<times> bool"
   193 where
   194   "monic p =
   195     (let h = headconst p
   196      in if h = 0\<^sub>N then (p, False) else (C (Ninv h) *\<^sub>p p, 0>\<^sub>N h))"
   197 
   198 
   199 subsection \<open>Pseudo-division\<close>
   200 
   201 definition shift1 :: "poly \<Rightarrow> poly"
   202   where "shift1 p = CN 0\<^sub>p 0 p"
   203 
   204 abbreviation funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a"
   205   where "funpow \<equiv> compow"
   206 
   207 partial_function (tailrec) polydivide_aux :: "poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   208 where
   209   "polydivide_aux a n p k s =
   210     (if s = 0\<^sub>p then (k, s)
   211      else
   212       let
   213         b = head s;
   214         m = degree s
   215       in
   216         if m < n then (k,s)
   217         else
   218           let p' = funpow (m - n) shift1 p
   219           in
   220             if a = b then polydivide_aux a n p k (s -\<^sub>p p')
   221             else polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (b *\<^sub>p p')))"
   222 
   223 definition polydivide :: "poly \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   224   where "polydivide s p = polydivide_aux (head p) (degree p) p 0 s"
   225 
   226 fun poly_deriv_aux :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   227 where
   228   "poly_deriv_aux n (CN c 0 p) = CN (poly_cmul ((int n)\<^sub>N) c) 0 (poly_deriv_aux (n + 1) p)"
   229 | "poly_deriv_aux n p = poly_cmul ((int n)\<^sub>N) p"
   230 
   231 fun poly_deriv :: "poly \<Rightarrow> poly"
   232 where
   233   "poly_deriv (CN c 0 p) = poly_deriv_aux 1 p"
   234 | "poly_deriv p = 0\<^sub>p"
   235 
   236 
   237 subsection \<open>Semantics of the polynomial representation\<close>
   238 
   239 primrec Ipoly :: "'a list \<Rightarrow> poly \<Rightarrow> 'a::{field_char_0,field,power}"
   240 where
   241   "Ipoly bs (C c) = INum c"
   242 | "Ipoly bs (Bound n) = bs!n"
   243 | "Ipoly bs (Neg a) = - Ipoly bs a"
   244 | "Ipoly bs (Add a b) = Ipoly bs a + Ipoly bs b"
   245 | "Ipoly bs (Sub a b) = Ipoly bs a - Ipoly bs b"
   246 | "Ipoly bs (Mul a b) = Ipoly bs a * Ipoly bs b"
   247 | "Ipoly bs (Pw t n) = Ipoly bs t ^ n"
   248 | "Ipoly bs (CN c n p) = Ipoly bs c + (bs!n) * Ipoly bs p"
   249 
   250 abbreviation Ipoly_syntax :: "poly \<Rightarrow> 'a list \<Rightarrow>'a::{field_char_0,field,power}"  ("\<lparr>_\<rparr>\<^sub>p\<^bsup>_\<^esup>")
   251   where "\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<equiv> Ipoly bs p"
   252 
   253 lemma Ipoly_CInt: "Ipoly bs (C (i, 1)) = of_int i"
   254   by (simp add: INum_def)
   255 
   256 lemma Ipoly_CRat: "Ipoly bs (C (i, j)) = of_int i / of_int j"
   257   by (simp  add: INum_def)
   258 
   259 lemmas RIpoly_eqs = Ipoly.simps(2-7) Ipoly_CInt Ipoly_CRat
   260 
   261 
   262 subsection \<open>Normal form and normalization\<close>
   263 
   264 fun isnpolyh:: "poly \<Rightarrow> nat \<Rightarrow> bool"
   265 where
   266   "isnpolyh (C c) = (\<lambda>k. isnormNum c)"
   267 | "isnpolyh (CN c n p) = (\<lambda>k. n \<ge> k \<and> isnpolyh c (Suc n) \<and> isnpolyh p n \<and> p \<noteq> 0\<^sub>p)"
   268 | "isnpolyh p = (\<lambda>k. False)"
   269 
   270 lemma isnpolyh_mono: "n' \<le> n \<Longrightarrow> isnpolyh p n \<Longrightarrow> isnpolyh p n'"
   271   by (induct p rule: isnpolyh.induct) auto
   272 
   273 definition isnpoly :: "poly \<Rightarrow> bool"
   274   where "isnpoly p = isnpolyh p 0"
   275 
   276 text \<open>polyadd preserves normal forms\<close>
   277 
   278 lemma polyadd_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polyadd p q) (min n0 n1)"
   279 proof (induct p q arbitrary: n0 n1 rule: polyadd.induct)
   280   case (2 ab c' n' p' n0 n1)
   281   from 2 have  th1: "isnpolyh (C ab) (Suc n')"
   282     by simp
   283   from 2(3) have th2: "isnpolyh c' (Suc n')" and nplen1: "n' \<ge> n1"
   284     by simp_all
   285   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   286     by simp
   287   with 2(1)[OF th1 th2] have th3:"isnpolyh (C ab +\<^sub>p c') (Suc n')"
   288     by simp
   289   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   290     by simp
   291   then show ?case using 2 th3
   292     by simp
   293 next
   294   case (3 c' n' p' ab n1 n0)
   295   from 3 have  th1: "isnpolyh (C ab) (Suc n')"
   296     by simp
   297   from 3(2) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1"
   298     by simp_all
   299   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')"
   300     by simp
   301   with 3(1)[OF th2 th1] have th3:"isnpolyh (c' +\<^sub>p C ab) (Suc n')"
   302     by simp
   303   from nplen1 have n01len1: "min n0 n1 \<le> n'"
   304     by simp
   305   then show ?case using 3 th3
   306     by simp
   307 next
   308   case (4 c n p c' n' p' n0 n1)
   309   then have nc: "isnpolyh c (Suc n)" and np: "isnpolyh p n"
   310     by simp_all
   311   from 4 have nc': "isnpolyh c' (Suc n')" and np': "isnpolyh p' n'"
   312     by simp_all
   313   from 4 have ngen0: "n \<ge> n0"
   314     by simp
   315   from 4 have n'gen1: "n' \<ge> n1"
   316     by simp
   317   consider (eq) "n = n'" | (lt) "n < n'" | (gt) "n > n'"
   318     by arith
   319   then show ?case
   320   proof cases
   321     case eq
   322     with "4.hyps"(3)[OF nc nc']
   323     have ncc':"isnpolyh (c +\<^sub>p c') (Suc n)"
   324       by auto
   325     then have ncc'n01: "isnpolyh (c +\<^sub>p c') (min n0 n1)"
   326       using isnpolyh_mono[where n'="min n0 n1" and n="Suc n"] ngen0 n'gen1
   327       by auto
   328     from eq "4.hyps"(4)[OF np np'] have npp': "isnpolyh (p +\<^sub>p p') n"
   329       by simp
   330     have minle: "min n0 n1 \<le> n'"
   331       using ngen0 n'gen1 eq by simp
   332     from minle npp' ncc'n01 4 eq ngen0 n'gen1 ncc' show ?thesis
   333       by (simp add: Let_def)
   334   next
   335     case lt
   336     have "min n0 n1 \<le> n0"
   337       by simp
   338     with 4 lt have th1:"min n0 n1 \<le> n"
   339       by auto
   340     from 4 have th21: "isnpolyh c (Suc n)"
   341       by simp
   342     from 4 have th22: "isnpolyh (CN c' n' p') n'"
   343       by simp
   344     from lt have th23: "min (Suc n) n' = Suc n"
   345       by arith
   346     from "4.hyps"(1)[OF th21 th22] have "isnpolyh (polyadd c (CN c' n' p')) (Suc n)"
   347       using th23 by simp
   348     with 4 lt th1 show ?thesis
   349       by simp
   350   next
   351     case gt
   352     then have gt': "n' < n \<and> \<not> n < n'"
   353       by simp
   354     have "min n0 n1 \<le> n1"
   355       by simp
   356     with 4 gt have th1: "min n0 n1 \<le> n'"
   357       by auto
   358     from 4 have th21: "isnpolyh c' (Suc n')"
   359       by simp_all
   360     from 4 have th22: "isnpolyh (CN c n p) n"
   361       by simp
   362     from gt have th23: "min n (Suc n') = Suc n'"
   363       by arith
   364     from "4.hyps"(2)[OF th22 th21] have "isnpolyh (polyadd (CN c n p) c') (Suc n')"
   365       using th23 by simp
   366     with 4 gt th1 show ?thesis
   367       by simp
   368   qed
   369 qed auto
   370 
   371 lemma polyadd[simp]: "Ipoly bs (polyadd p q) = Ipoly bs p + Ipoly bs q"
   372   by (induct p q rule: polyadd.induct)
   373      (auto simp add: Let_def field_simps distrib_left[symmetric] simp del: distrib_left_NO_MATCH)
   374 
   375 lemma polyadd_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polyadd p q)"
   376   using polyadd_normh[of p 0 q 0] isnpoly_def by simp
   377 
   378 text \<open>The degree of addition and other general lemmas needed for the normal form of polymul.\<close>
   379 
   380 lemma polyadd_different_degreen:
   381   assumes "isnpolyh p n0"
   382     and "isnpolyh q n1"
   383     and "degreen p m \<noteq> degreen q m"
   384     and "m \<le> min n0 n1"
   385   shows "degreen (polyadd p q) m = max (degreen p m) (degreen q m)"
   386   using assms
   387 proof (induct p q arbitrary: m n0 n1 rule: polyadd.induct)
   388   case (4 c n p c' n' p' m n0 n1)
   389   show ?case
   390   proof (cases "n = n'")
   391     case True
   392     with 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   393     show ?thesis by (auto simp: Let_def)
   394   next
   395     case False
   396     with 4 show ?thesis by auto
   397   qed
   398 qed auto
   399 
   400 lemma headnz[simp]: "isnpolyh p n \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> headn p m \<noteq> 0\<^sub>p"
   401   by (induct p arbitrary: n rule: headn.induct) auto
   402 
   403 lemma degree_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> degree p = 0"
   404   by (induct p arbitrary: n rule: degree.induct) auto
   405 
   406 lemma degreen_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> degreen p m = 0"
   407   by (induct p arbitrary: n rule: degreen.induct) auto
   408 
   409 lemma degree_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> degree p = 0"
   410   by (induct p arbitrary: n rule: degree.induct) auto
   411 
   412 lemma degree_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degree c = 0"
   413   using degree_isnpolyh_Suc by auto
   414 
   415 lemma degreen_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degreen c n = 0"
   416   using degreen_0 by auto
   417 
   418 
   419 lemma degreen_polyadd:
   420   assumes np: "isnpolyh p n0"
   421     and nq: "isnpolyh q n1"
   422     and m: "m \<le> max n0 n1"
   423   shows "degreen (p +\<^sub>p q) m \<le> max (degreen p m) (degreen q m)"
   424   using np nq m
   425 proof (induct p q arbitrary: n0 n1 m rule: polyadd.induct)
   426   case (2 c c' n' p' n0 n1)
   427   then show ?case
   428     by (cases n') simp_all
   429 next
   430   case (3 c n p c' n0 n1)
   431   then show ?case
   432     by (cases n) auto
   433 next
   434   case (4 c n p c' n' p' n0 n1 m)
   435   show ?case
   436   proof (cases "n = n'")
   437     case True
   438     with 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   439     show ?thesis by (auto simp: Let_def)
   440   next
   441     case False
   442     then show ?thesis by simp
   443   qed
   444 qed auto
   445 
   446 lemma polyadd_eq_const_degreen:
   447   assumes "isnpolyh p n0"
   448     and "isnpolyh q n1"
   449     and "polyadd p q = C c"
   450   shows "degreen p m = degreen q m"
   451   using assms
   452 proof (induct p q arbitrary: m n0 n1 c rule: polyadd.induct)
   453   case (4 c n p c' n' p' m n0 n1 x)
   454   consider "n = n'" | "n > n' \<or> n < n'" by arith
   455   then show ?case
   456   proof cases
   457     case 1
   458     with 4 show ?thesis
   459       by (cases "p +\<^sub>p p' = 0\<^sub>p") (auto simp add: Let_def)
   460   next
   461     case 2
   462     with 4 show ?thesis by auto
   463   qed
   464 qed simp_all
   465 
   466 lemma polymul_properties:
   467   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   468     and np: "isnpolyh p n0"
   469     and nq: "isnpolyh q n1"
   470     and m: "m \<le> min n0 n1"
   471   shows "isnpolyh (p *\<^sub>p q) (min n0 n1)"
   472     and "p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   473     and "degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   474   using np nq m
   475 proof (induct p q arbitrary: n0 n1 m rule: polymul.induct)
   476   case (2 c c' n' p')
   477   {
   478     case (1 n0 n1)
   479     with "2.hyps"(4-6)[of n' n' n'] and "2.hyps"(1-3)[of "Suc n'" "Suc n'" n']
   480     show ?case by (auto simp add: min_def)
   481   next
   482     case (2 n0 n1)
   483     then show ?case by auto
   484   next
   485     case (3 n0 n1)
   486     then show ?case using "2.hyps" by auto
   487   }
   488 next
   489   case (3 c n p c')
   490   {
   491     case (1 n0 n1)
   492     with "3.hyps"(4-6)[of n n n] and "3.hyps"(1-3)[of "Suc n" "Suc n" n]
   493     show ?case by (auto simp add: min_def)
   494   next
   495     case (2 n0 n1)
   496     then show ?case by auto
   497   next
   498     case (3 n0 n1)
   499     then show ?case  using "3.hyps" by auto
   500   }
   501 next
   502   case (4 c n p c' n' p')
   503   let ?cnp = "CN c n p" let ?cnp' = "CN c' n' p'"
   504   {
   505     case (1 n0 n1)
   506     then have cnp: "isnpolyh ?cnp n"
   507       and cnp': "isnpolyh ?cnp' n'"
   508       and np: "isnpolyh p n"
   509       and nc: "isnpolyh c (Suc n)"
   510       and np': "isnpolyh p' n'"
   511       and nc': "isnpolyh c' (Suc n')"
   512       and nn0: "n \<ge> n0"
   513       and nn1: "n' \<ge> n1"
   514       by simp_all
   515     {
   516       assume "n < n'"
   517       with "4.hyps"(4-5)[OF np cnp', of n] and "4.hyps"(1)[OF nc cnp', of n] nn0 cnp
   518       have ?case by (simp add: min_def)
   519     } moreover {
   520       assume "n' < n"
   521       with "4.hyps"(16-17)[OF cnp np', of "n'"] and "4.hyps"(13)[OF cnp nc', of "Suc n'"] nn1 cnp'
   522       have ?case by (cases "Suc n' = n") (simp_all add: min_def)
   523     } moreover {
   524       assume "n' = n"
   525       with "4.hyps"(16-17)[OF cnp np', of n] and "4.hyps"(13)[OF cnp nc', of n] cnp cnp' nn1 nn0
   526       have ?case
   527         apply (auto intro!: polyadd_normh)
   528         apply (simp_all add: min_def isnpolyh_mono[OF nn0])
   529         done
   530     }
   531     ultimately show ?case by arith
   532   next
   533     fix n0 n1 m
   534     assume np: "isnpolyh ?cnp n0"
   535     assume np':"isnpolyh ?cnp' n1"
   536     assume m: "m \<le> min n0 n1"
   537     let ?d = "degreen (?cnp *\<^sub>p ?cnp') m"
   538     let ?d1 = "degreen ?cnp m"
   539     let ?d2 = "degreen ?cnp' m"
   540     let ?eq = "?d = (if ?cnp = 0\<^sub>p \<or> ?cnp' = 0\<^sub>p then 0  else ?d1 + ?d2)"
   541     have "n' < n \<or> n < n' \<or> n' = n" by auto
   542     moreover
   543     {
   544       assume "n' < n \<or> n < n'"
   545       with "4.hyps"(3,6,18) np np' m have ?eq
   546         by auto
   547     }
   548     moreover
   549     {
   550       assume nn': "n' = n"
   551       then have nn: "\<not> n' < n \<and> \<not> n < n'" by arith
   552       from "4.hyps"(16,18)[of n n' n]
   553         "4.hyps"(13,14)[of n "Suc n'" n]
   554         np np' nn'
   555       have norm:
   556         "isnpolyh ?cnp n"
   557         "isnpolyh c' (Suc n)"
   558         "isnpolyh (?cnp *\<^sub>p c') n"
   559         "isnpolyh p' n"
   560         "isnpolyh (?cnp *\<^sub>p p') n"
   561         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   562         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   563         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   564         by (auto simp add: min_def)
   565       {
   566         assume mn: "m = n"
   567         from "4.hyps"(17,18)[OF norm(1,4), of n]
   568           "4.hyps"(13,15)[OF norm(1,2), of n] norm nn' mn
   569         have degs:
   570           "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else ?d1 + degreen c' n)"
   571           "degreen (?cnp *\<^sub>p p') n = ?d1  + degreen p' n"
   572           by (simp_all add: min_def)
   573         from degs norm have th1: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   574           by simp
   575         then have neq: "degreen (?cnp *\<^sub>p c') n \<noteq> degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   576           by simp
   577         have nmin: "n \<le> min n n"
   578           by (simp add: min_def)
   579         from polyadd_different_degreen[OF norm(3,6) neq nmin] th1
   580         have deg: "degreen (CN c n p *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n =
   581             degreen (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   582           by simp
   583         from "4.hyps"(16-18)[OF norm(1,4), of n]
   584           "4.hyps"(13-15)[OF norm(1,2), of n]
   585           mn norm m nn' deg
   586         have ?eq by simp
   587       }
   588       moreover
   589       {
   590         assume mn: "m \<noteq> n"
   591         then have mn': "m < n"
   592           using m np by auto
   593         from nn' m np have max1: "m \<le> max n n"
   594           by simp
   595         then have min1: "m \<le> min n n"
   596           by simp
   597         then have min2: "m \<le> min n (Suc n)"
   598           by simp
   599         from "4.hyps"(16-18)[OF norm(1,4) min1]
   600           "4.hyps"(13-15)[OF norm(1,2) min2]
   601           degreen_polyadd[OF norm(3,6) max1]
   602         have "degreen (?cnp *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (?cnp *\<^sub>p p')) m \<le>
   603             max (degreen (?cnp *\<^sub>p c') m) (degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) m)"
   604           using mn nn' np np' by simp
   605         with "4.hyps"(16-18)[OF norm(1,4) min1]
   606           "4.hyps"(13-15)[OF norm(1,2) min2]
   607           degreen_0[OF norm(3) mn']
   608         have ?eq using nn' mn np np' by clarsimp
   609       }
   610       ultimately have ?eq by blast
   611     }
   612     ultimately show ?eq by blast
   613   }
   614   {
   615     case (2 n0 n1)
   616     then have np: "isnpolyh ?cnp n0"
   617       and np': "isnpolyh ?cnp' n1"
   618       and m: "m \<le> min n0 n1"
   619       by simp_all
   620     then have mn: "m \<le> n" by simp
   621     let ?c0p = "CN 0\<^sub>p n (?cnp *\<^sub>p p')"
   622     {
   623       assume C: "?cnp *\<^sub>p c' +\<^sub>p ?c0p = 0\<^sub>p" "n' = n"
   624       then have nn: "\<not> n' < n \<and> \<not> n < n'"
   625         by simp
   626       from "4.hyps"(16-18) [of n n n]
   627         "4.hyps"(13-15)[of n "Suc n" n]
   628         np np' C(2) mn
   629       have norm:
   630         "isnpolyh ?cnp n"
   631         "isnpolyh c' (Suc n)"
   632         "isnpolyh (?cnp *\<^sub>p c') n"
   633         "isnpolyh p' n"
   634         "isnpolyh (?cnp *\<^sub>p p') n"
   635         "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   636         "?cnp *\<^sub>p c' = 0\<^sub>p \<longleftrightarrow> c' = 0\<^sub>p"
   637         "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p"
   638         "degreen (?cnp *\<^sub>p c') n = (if c' = 0\<^sub>p then 0 else degreen ?cnp n + degreen c' n)"
   639         "degreen (?cnp *\<^sub>p p') n = degreen ?cnp n + degreen p' n"
   640         by (simp_all add: min_def)
   641       from norm have cn: "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   642         by simp
   643       have degneq: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   644         using norm by simp
   645       from polyadd_eq_const_degreen[OF norm(3) cn C(1), where m="n"] degneq
   646       have False by simp
   647     }
   648     then show ?case using "4.hyps" by clarsimp
   649   }
   650 qed auto
   651 
   652 lemma polymul[simp]: "Ipoly bs (p *\<^sub>p q) = Ipoly bs p * Ipoly bs q"
   653   by (induct p q rule: polymul.induct) (auto simp add: field_simps)
   654 
   655 lemma polymul_normh:
   656   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   657   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (p *\<^sub>p q) (min n0 n1)"
   658   using polymul_properties(1) by blast
   659 
   660 lemma polymul_eq0_iff:
   661   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   662   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p *\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p \<or> q = 0\<^sub>p"
   663   using polymul_properties(2) by blast
   664 
   665 lemma polymul_degreen:
   666   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   667   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> m \<le> min n0 n1 \<Longrightarrow>
   668     degreen (p *\<^sub>p q) m = (if p = 0\<^sub>p \<or> q = 0\<^sub>p then 0 else degreen p m + degreen q m)"
   669   by (fact polymul_properties(3))
   670 
   671 lemma polymul_norm:
   672   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   673   shows "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polymul p q)"
   674   using polymul_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   675 
   676 lemma headconst_zero: "isnpolyh p n0 \<Longrightarrow> headconst p = 0\<^sub>N \<longleftrightarrow> p = 0\<^sub>p"
   677   by (induct p arbitrary: n0 rule: headconst.induct) auto
   678 
   679 lemma headconst_isnormNum: "isnpolyh p n0 \<Longrightarrow> isnormNum (headconst p)"
   680   by (induct p arbitrary: n0) auto
   681 
   682 lemma monic_eqI:
   683   assumes np: "isnpolyh p n0"
   684   shows "INum (headconst p) * Ipoly bs (fst (monic p)) =
   685     (Ipoly bs p ::'a::{field_char_0,field, power})"
   686   unfolding monic_def Let_def
   687 proof (cases "headconst p = 0\<^sub>N", simp_all add: headconst_zero[OF np])
   688   let ?h = "headconst p"
   689   assume pz: "p \<noteq> 0\<^sub>p"
   690   {
   691     assume hz: "INum ?h = (0::'a)"
   692     from headconst_isnormNum[OF np] have norm: "isnormNum ?h" "isnormNum 0\<^sub>N"
   693       by simp_all
   694     from isnormNum_unique[where ?'a = 'a, OF norm] hz have "?h = 0\<^sub>N"
   695       by simp
   696     with headconst_zero[OF np] have "p = 0\<^sub>p"
   697       by blast
   698     with pz have False
   699       by blast
   700   }
   701   then show "INum (headconst p) = (0::'a) \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
   702     by blast
   703 qed
   704 
   705 
   706 text \<open>polyneg is a negation and preserves normal forms\<close>
   707 
   708 lemma polyneg[simp]: "Ipoly bs (polyneg p) = - Ipoly bs p"
   709   by (induct p rule: polyneg.induct) auto
   710 
   711 lemma polyneg0: "isnpolyh p n \<Longrightarrow> (~\<^sub>p p) = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   712   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: Nneg_def)
   713 
   714 lemma polyneg_polyneg: "isnpolyh p n0 \<Longrightarrow> ~\<^sub>p (~\<^sub>p p) = p"
   715   by (induct p arbitrary: n0 rule: polyneg.induct) auto
   716 
   717 lemma polyneg_normh: "isnpolyh p n \<Longrightarrow> isnpolyh (polyneg p) n"
   718   by (induct p arbitrary: n rule: polyneg.induct) (auto simp add: polyneg0)
   719 
   720 lemma polyneg_norm: "isnpoly p \<Longrightarrow> isnpoly (polyneg p)"
   721   using isnpoly_def polyneg_normh by simp
   722 
   723 
   724 text \<open>polysub is a substraction and preserves normal forms\<close>
   725 
   726 lemma polysub[simp]: "Ipoly bs (polysub p q) = Ipoly bs p - Ipoly bs q"
   727   by (simp add: polysub_def)
   728 
   729 lemma polysub_normh: "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> isnpolyh (polysub p q) (min n0 n1)"
   730   by (simp add: polysub_def polyneg_normh polyadd_normh)
   731 
   732 lemma polysub_norm: "isnpoly p \<Longrightarrow> isnpoly q \<Longrightarrow> isnpoly (polysub p q)"
   733   using polyadd_norm polyneg_norm by (simp add: polysub_def)
   734 
   735 lemma polysub_same_0[simp]:
   736   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   737   shows "isnpolyh p n0 \<Longrightarrow> polysub p p = 0\<^sub>p"
   738   unfolding polysub_def split_def fst_conv snd_conv
   739   by (induct p arbitrary: n0) (auto simp add: Let_def Nsub0[simplified Nsub_def])
   740 
   741 lemma polysub_0:
   742   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   743   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p -\<^sub>p q = 0\<^sub>p \<longleftrightarrow> p = q"
   744   unfolding polysub_def split_def fst_conv snd_conv
   745   by (induct p q arbitrary: n0 n1 rule:polyadd.induct)
   746     (auto simp: Nsub0[simplified Nsub_def] Let_def)
   747 
   748 text \<open>polypow is a power function and preserves normal forms\<close>
   749 
   750 lemma polypow[simp]:
   751   "Ipoly bs (polypow n p) = (Ipoly bs p :: 'a::{field_char_0,field}) ^ n"
   752 proof (induct n rule: polypow.induct)
   753   case 1
   754   then show ?case
   755     by simp
   756 next
   757   case (2 n)
   758   let ?q = "polypow ((Suc n) div 2) p"
   759   let ?d = "polymul ?q ?q"
   760   have "odd (Suc n) \<or> even (Suc n)"
   761     by simp
   762   moreover
   763   {
   764     assume odd: "odd (Suc n)"
   765     have th: "(Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0)))) = Suc n div 2 + Suc n div 2 + 1"
   766       by arith
   767     from odd have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs (polymul p ?d)"
   768       by (simp add: Let_def)
   769     also have "\<dots> = (Ipoly bs p) * (Ipoly bs p)^(Suc n div 2) * (Ipoly bs p)^(Suc n div 2)"
   770       using "2.hyps" by simp
   771     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2 + 1)"
   772       by (simp only: power_add power_one_right) simp
   773     also have "\<dots> = (Ipoly bs p) ^ (Suc (Suc (Suc 0) * (Suc n div Suc (Suc 0))))"
   774       by (simp only: th)
   775     finally have ?case unfolding numeral_2_eq_2 [symmetric]
   776     using odd_two_times_div_two_nat [OF odd] by simp
   777   }
   778   moreover
   779   {
   780     assume even: "even (Suc n)"
   781     from even have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs ?d"
   782       by (simp add: Let_def)
   783     also have "\<dots> = (Ipoly bs p) ^ (2 * (Suc n div 2))"
   784       using "2.hyps" by (simp only: mult_2 power_add) simp
   785     finally have ?case using even_two_times_div_two [OF even]
   786       by simp
   787   }
   788   ultimately show ?case by blast
   789 qed
   790 
   791 lemma polypow_normh:
   792   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   793   shows "isnpolyh p n \<Longrightarrow> isnpolyh (polypow k p) n"
   794 proof (induct k arbitrary: n rule: polypow.induct)
   795   case 1
   796   then show ?case by auto
   797 next
   798   case (2 k n)
   799   let ?q = "polypow (Suc k div 2) p"
   800   let ?d = "polymul ?q ?q"
   801   from 2 have th1: "isnpolyh ?q n" and th2: "isnpolyh p n"
   802     by blast+
   803   from polymul_normh[OF th1 th1] have dn: "isnpolyh ?d n"
   804     by simp
   805   from polymul_normh[OF th2 dn] have on: "isnpolyh (polymul p ?d) n"
   806     by simp
   807   from dn on show ?case by (simp, unfold Let_def) auto
   808     
   809 qed
   810 
   811 lemma polypow_norm:
   812   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   813   shows "isnpoly p \<Longrightarrow> isnpoly (polypow k p)"
   814   by (simp add: polypow_normh isnpoly_def)
   815 
   816 text \<open>Finally the whole normalization\<close>
   817 
   818 lemma polynate [simp]:
   819   "Ipoly bs (polynate p) = (Ipoly bs p :: 'a ::{field_char_0,field})"
   820   by (induct p rule:polynate.induct) auto
   821 
   822 lemma polynate_norm[simp]:
   823   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
   824   shows "isnpoly (polynate p)"
   825   by (induct p rule: polynate.induct)
   826      (simp_all add: polyadd_norm polymul_norm polysub_norm polyneg_norm polypow_norm,
   827       simp_all add: isnpoly_def)
   828 
   829 text \<open>shift1\<close>
   830 
   831 
   832 lemma shift1: "Ipoly bs (shift1 p) = Ipoly bs (Mul (Bound 0) p)"
   833   by (simp add: shift1_def)
   834 
   835 lemma shift1_isnpoly:
   836   assumes "isnpoly p"
   837     and "p \<noteq> 0\<^sub>p"
   838   shows "isnpoly (shift1 p) "
   839   using assms by (simp add: shift1_def isnpoly_def)
   840 
   841 lemma shift1_nz[simp]:"shift1 p \<noteq> 0\<^sub>p"
   842   by (simp add: shift1_def)
   843 
   844 lemma funpow_shift1_isnpoly: "isnpoly p \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> isnpoly (funpow n shift1 p)"
   845   by (induct n arbitrary: p) (auto simp add: shift1_isnpoly funpow_swap1)
   846 
   847 lemma funpow_isnpolyh:
   848   assumes "\<And>p. isnpolyh p n \<Longrightarrow> isnpolyh (f p) n"
   849     and "isnpolyh p n"
   850   shows "isnpolyh (funpow k f p) n"
   851   using assms by (induct k arbitrary: p) auto
   852 
   853 lemma funpow_shift1:
   854   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field}) =
   855     Ipoly bs (Mul (Pw (Bound 0) n) p)"
   856   by (induct n arbitrary: p) (simp_all add: shift1_isnpoly shift1)
   857 
   858 lemma shift1_isnpolyh: "isnpolyh p n0 \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> isnpolyh (shift1 p) 0"
   859   using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by (simp add: shift1_def)
   860 
   861 lemma funpow_shift1_1:
   862   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0,field}) =
   863     Ipoly bs (funpow n shift1 (1)\<^sub>p *\<^sub>p p)"
   864   by (simp add: funpow_shift1)
   865 
   866 lemma poly_cmul[simp]: "Ipoly bs (poly_cmul c p) = Ipoly bs (Mul (C c) p)"
   867   by (induct p rule: poly_cmul.induct) (auto simp add: field_simps)
   868 
   869 lemma behead:
   870   assumes "isnpolyh p n"
   871   shows "Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) =
   872     (Ipoly bs p :: 'a :: {field_char_0,field})"
   873   using assms
   874 proof (induct p arbitrary: n rule: behead.induct)
   875   case (1 c p n)
   876   then have pn: "isnpolyh p n" by simp
   877   from 1(1)[OF pn]
   878   have th:"Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = Ipoly bs p" .
   879   then show ?case using "1.hyps"
   880     apply (simp add: Let_def,cases "behead p = 0\<^sub>p")
   881     apply (simp_all add: th[symmetric] field_simps)
   882     done
   883 qed (auto simp add: Let_def)
   884 
   885 lemma behead_isnpolyh:
   886   assumes "isnpolyh p n"
   887   shows "isnpolyh (behead p) n"
   888   using assms by (induct p rule: behead.induct) (auto simp add: Let_def isnpolyh_mono)
   889 
   890 
   891 subsection \<open>Miscellaneous lemmas about indexes, decrementation, substitution  etc ...\<close>
   892 
   893 lemma isnpolyh_polybound0: "isnpolyh p (Suc n) \<Longrightarrow> polybound0 p"
   894 proof (induct p arbitrary: n rule: poly.induct, auto, goals)
   895   case prems: (1 c n p n')
   896   then have "n = Suc (n - 1)"
   897     by simp
   898   then have "isnpolyh p (Suc (n - 1))"
   899     using \<open>isnpolyh p n\<close> by simp
   900   with prems(2) show ?case
   901     by simp
   902 qed
   903 
   904 lemma isconstant_polybound0: "isnpolyh p n0 \<Longrightarrow> isconstant p \<longleftrightarrow> polybound0 p"
   905   by (induct p arbitrary: n0 rule: isconstant.induct) (auto simp add: isnpolyh_polybound0)
   906 
   907 lemma decrpoly_zero[simp]: "decrpoly p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
   908   by (induct p) auto
   909 
   910 lemma decrpoly_normh: "isnpolyh p n0 \<Longrightarrow> polybound0 p \<Longrightarrow> isnpolyh (decrpoly p) (n0 - 1)"
   911   apply (induct p arbitrary: n0)
   912   apply auto
   913   apply atomize
   914   apply (rename_tac nat a b, erule_tac x = "Suc nat" in allE)
   915   apply auto
   916   done
   917 
   918 lemma head_polybound0: "isnpolyh p n0 \<Longrightarrow> polybound0 (head p)"
   919   by (induct p  arbitrary: n0 rule: head.induct) (auto intro: isnpolyh_polybound0)
   920 
   921 lemma polybound0_I:
   922   assumes "polybound0 a"
   923   shows "Ipoly (b # bs) a = Ipoly (b' # bs) a"
   924   using assms by (induct a rule: poly.induct) auto
   925 
   926 lemma polysubst0_I: "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b # bs) a) # bs) t"
   927   by (induct t) simp_all
   928 
   929 lemma polysubst0_I':
   930   assumes "polybound0 a"
   931   shows "Ipoly (b # bs) (polysubst0 a t) = Ipoly ((Ipoly (b' # bs) a) # bs) t"
   932   by (induct t) (simp_all add: polybound0_I[OF assms, where b="b" and b'="b'"])
   933 
   934 lemma decrpoly:
   935   assumes "polybound0 t"
   936   shows "Ipoly (x # bs) t = Ipoly bs (decrpoly t)"
   937   using assms by (induct t rule: decrpoly.induct) simp_all
   938 
   939 lemma polysubst0_polybound0:
   940   assumes "polybound0 t"
   941   shows "polybound0 (polysubst0 t a)"
   942   using assms by (induct a rule: poly.induct) auto
   943 
   944 lemma degree0_polybound0: "isnpolyh p n \<Longrightarrow> degree p = 0 \<Longrightarrow> polybound0 p"
   945   by (induct p arbitrary: n rule: degree.induct) (auto simp add: isnpolyh_polybound0)
   946 
   947 primrec maxindex :: "poly \<Rightarrow> nat"
   948 where
   949   "maxindex (Bound n) = n + 1"
   950 | "maxindex (CN c n p) = max  (n + 1) (max (maxindex c) (maxindex p))"
   951 | "maxindex (Add p q) = max (maxindex p) (maxindex q)"
   952 | "maxindex (Sub p q) = max (maxindex p) (maxindex q)"
   953 | "maxindex (Mul p q) = max (maxindex p) (maxindex q)"
   954 | "maxindex (Neg p) = maxindex p"
   955 | "maxindex (Pw p n) = maxindex p"
   956 | "maxindex (C x) = 0"
   957 
   958 definition wf_bs :: "'a list \<Rightarrow> poly \<Rightarrow> bool"
   959   where "wf_bs bs p \<longleftrightarrow> length bs \<ge> maxindex p"
   960 
   961 lemma wf_bs_coefficients: "wf_bs bs p \<Longrightarrow> \<forall>c \<in> set (coefficients p). wf_bs bs c"
   962 proof (induct p rule: coefficients.induct)
   963   case (1 c p)
   964   show ?case
   965   proof
   966     fix x
   967     assume xc: "x \<in> set (coefficients (CN c 0 p))"
   968     then have "x = c \<or> x \<in> set (coefficients p)"
   969       by simp
   970     moreover
   971     {
   972       assume "x = c"
   973       then have "wf_bs bs x"
   974         using "1.prems" unfolding wf_bs_def by simp
   975     }
   976     moreover
   977     {
   978       assume H: "x \<in> set (coefficients p)"
   979       from "1.prems" have "wf_bs bs p"
   980         unfolding wf_bs_def by simp
   981       with "1.hyps" H have "wf_bs bs x"
   982         by blast
   983     }
   984     ultimately show "wf_bs bs x"
   985       by blast
   986   qed
   987 qed simp_all
   988 
   989 lemma maxindex_coefficients: "\<forall>c \<in> set (coefficients p). maxindex c \<le> maxindex p"
   990   by (induct p rule: coefficients.induct) auto
   991 
   992 lemma wf_bs_I: "wf_bs bs p \<Longrightarrow> Ipoly (bs @ bs') p = Ipoly bs p"
   993   unfolding wf_bs_def by (induct p) (auto simp add: nth_append)
   994 
   995 lemma take_maxindex_wf:
   996   assumes wf: "wf_bs bs p"
   997   shows "Ipoly (take (maxindex p) bs) p = Ipoly bs p"
   998 proof -
   999   let ?ip = "maxindex p"
  1000   let ?tbs = "take ?ip bs"
  1001   from wf have "length ?tbs = ?ip"
  1002     unfolding wf_bs_def by simp
  1003   then have wf': "wf_bs ?tbs p"
  1004     unfolding wf_bs_def by  simp
  1005   have eq: "bs = ?tbs @ drop ?ip bs"
  1006     by simp
  1007   from wf_bs_I[OF wf', of "drop ?ip bs"] show ?thesis
  1008     using eq by simp
  1009 qed
  1010 
  1011 lemma decr_maxindex: "polybound0 p \<Longrightarrow> maxindex (decrpoly p) = maxindex p - 1"
  1012   by (induct p) auto
  1013 
  1014 lemma wf_bs_insensitive: "length bs = length bs' \<Longrightarrow> wf_bs bs p = wf_bs bs' p"
  1015   unfolding wf_bs_def by simp
  1016 
  1017 lemma wf_bs_insensitive': "wf_bs (x # bs) p = wf_bs (y # bs) p"
  1018   unfolding wf_bs_def by simp
  1019 
  1020 lemma wf_bs_coefficients': "\<forall>c \<in> set (coefficients p). wf_bs bs c \<Longrightarrow> wf_bs (x # bs) p"
  1021   by (induct p rule: coefficients.induct) (auto simp add: wf_bs_def)
  1022 
  1023 lemma coefficients_Nil[simp]: "coefficients p \<noteq> []"
  1024   by (induct p rule: coefficients.induct) simp_all
  1025 
  1026 lemma coefficients_head: "last (coefficients p) = head p"
  1027   by (induct p rule: coefficients.induct) auto
  1028 
  1029 lemma wf_bs_decrpoly: "wf_bs bs (decrpoly p) \<Longrightarrow> wf_bs (x # bs) p"
  1030   unfolding wf_bs_def by (induct p rule: decrpoly.induct) auto
  1031 
  1032 lemma length_le_list_ex: "length xs \<le> n \<Longrightarrow> \<exists>ys. length (xs @ ys) = n"
  1033   apply (rule exI[where x="replicate (n - length xs) z" for z])
  1034   apply simp
  1035   done
  1036 
  1037 lemma isnpolyh_Suc_const: "isnpolyh p (Suc n) \<Longrightarrow> isconstant p"
  1038   apply (cases p)
  1039   apply auto
  1040   apply (rename_tac nat a, case_tac "nat")
  1041   apply simp_all
  1042   done
  1043 
  1044 lemma wf_bs_polyadd: "wf_bs bs p \<and> wf_bs bs q \<longrightarrow> wf_bs bs (p +\<^sub>p q)"
  1045   unfolding wf_bs_def by (induct p q rule: polyadd.induct) (auto simp add: Let_def)
  1046 
  1047 lemma wf_bs_polyul: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p *\<^sub>p q)"
  1048   unfolding wf_bs_def
  1049   apply (induct p q arbitrary: bs rule: polymul.induct)
  1050   apply (simp_all add: wf_bs_polyadd)
  1051   apply clarsimp
  1052   apply (rule wf_bs_polyadd[unfolded wf_bs_def, rule_format])
  1053   apply auto
  1054   done
  1055 
  1056 lemma wf_bs_polyneg: "wf_bs bs p \<Longrightarrow> wf_bs bs (~\<^sub>p p)"
  1057   unfolding wf_bs_def by (induct p rule: polyneg.induct) auto
  1058 
  1059 lemma wf_bs_polysub: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p -\<^sub>p q)"
  1060   unfolding polysub_def split_def fst_conv snd_conv
  1061   using wf_bs_polyadd wf_bs_polyneg by blast
  1062 
  1063 
  1064 subsection \<open>Canonicity of polynomial representation, see lemma isnpolyh_unique\<close>
  1065 
  1066 definition "polypoly bs p = map (Ipoly bs) (coefficients p)"
  1067 definition "polypoly' bs p = map (Ipoly bs \<circ> decrpoly) (coefficients p)"
  1068 definition "poly_nate bs p = map (Ipoly bs \<circ> decrpoly) (coefficients (polynate p))"
  1069 
  1070 lemma coefficients_normh: "isnpolyh p n0 \<Longrightarrow> \<forall>q \<in> set (coefficients p). isnpolyh q n0"
  1071 proof (induct p arbitrary: n0 rule: coefficients.induct)
  1072   case (1 c p n0)
  1073   have cp: "isnpolyh (CN c 0 p) n0"
  1074     by fact
  1075   then have norm: "isnpolyh c 0" "isnpolyh p 0" "p \<noteq> 0\<^sub>p" "n0 = 0"
  1076     by (auto simp add: isnpolyh_mono[where n'=0])
  1077   from "1.hyps"[OF norm(2)] norm(1) norm(4) show ?case
  1078     by simp
  1079 qed auto
  1080 
  1081 lemma coefficients_isconst: "isnpolyh p n \<Longrightarrow> \<forall>q \<in> set (coefficients p). isconstant q"
  1082   by (induct p arbitrary: n rule: coefficients.induct) (auto simp add: isnpolyh_Suc_const)
  1083 
  1084 lemma polypoly_polypoly':
  1085   assumes np: "isnpolyh p n0"
  1086   shows "polypoly (x # bs) p = polypoly' bs p"
  1087 proof -
  1088   let ?cf = "set (coefficients p)"
  1089   from coefficients_normh[OF np] have cn_norm: "\<forall> q\<in> ?cf. isnpolyh q n0" .
  1090   {
  1091     fix q
  1092     assume q: "q \<in> ?cf"
  1093     from q cn_norm have th: "isnpolyh q n0"
  1094       by blast
  1095     from coefficients_isconst[OF np] q have "isconstant q"
  1096       by blast
  1097     with isconstant_polybound0[OF th] have "polybound0 q"
  1098       by blast
  1099   }
  1100   then have "\<forall>q \<in> ?cf. polybound0 q" ..
  1101   then have "\<forall>q \<in> ?cf. Ipoly (x # bs) q = Ipoly bs (decrpoly q)"
  1102     using polybound0_I[where b=x and bs=bs and b'=y] decrpoly[where x=x and bs=bs]
  1103     by auto
  1104   then show ?thesis
  1105     unfolding polypoly_def polypoly'_def by simp
  1106 qed
  1107 
  1108 lemma polypoly_poly:
  1109   assumes "isnpolyh p n0"
  1110   shows "Ipoly (x # bs) p = poly (polypoly (x # bs) p) x"
  1111   using assms
  1112   by (induct p arbitrary: n0 bs rule: coefficients.induct) (auto simp add: polypoly_def)
  1113 
  1114 lemma polypoly'_poly:
  1115   assumes "isnpolyh p n0"
  1116   shows "\<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup> = poly (polypoly' bs p) x"
  1117   using polypoly_poly[OF assms, simplified polypoly_polypoly'[OF assms]] .
  1118 
  1119 
  1120 lemma polypoly_poly_polybound0:
  1121   assumes "isnpolyh p n0"
  1122     and "polybound0 p"
  1123   shows "polypoly bs p = [Ipoly bs p]"
  1124   using assms
  1125   unfolding polypoly_def
  1126   apply (cases p)
  1127   apply auto
  1128   apply (rename_tac nat a, case_tac nat)
  1129   apply auto
  1130   done
  1131 
  1132 lemma head_isnpolyh: "isnpolyh p n0 \<Longrightarrow> isnpolyh (head p) n0"
  1133   by (induct p rule: head.induct) auto
  1134 
  1135 lemma headn_nz[simp]: "isnpolyh p n0 \<Longrightarrow> headn p m = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  1136   by (cases p) auto
  1137 
  1138 lemma head_eq_headn0: "head p = headn p 0"
  1139   by (induct p rule: head.induct) simp_all
  1140 
  1141 lemma head_nz[simp]: "isnpolyh p n0 \<Longrightarrow> head p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  1142   by (simp add: head_eq_headn0)
  1143 
  1144 lemma isnpolyh_zero_iff:
  1145   assumes nq: "isnpolyh p n0"
  1146     and eq :"\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a::{field_char_0,field, power})"
  1147   shows "p = 0\<^sub>p"
  1148   using nq eq
  1149 proof (induct "maxindex p" arbitrary: p n0 rule: less_induct)
  1150   case less
  1151   note np = \<open>isnpolyh p n0\<close> and zp = \<open>\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)\<close>
  1152   {
  1153     assume nz: "maxindex p = 0"
  1154     then obtain c where "p = C c"
  1155       using np by (cases p) auto
  1156     with zp np have "p = 0\<^sub>p"
  1157       unfolding wf_bs_def by simp
  1158   }
  1159   moreover
  1160   {
  1161     assume nz: "maxindex p \<noteq> 0"
  1162     let ?h = "head p"
  1163     let ?hd = "decrpoly ?h"
  1164     let ?ihd = "maxindex ?hd"
  1165     from head_isnpolyh[OF np] head_polybound0[OF np]
  1166     have h: "isnpolyh ?h n0" "polybound0 ?h"
  1167       by simp_all
  1168     then have nhd: "isnpolyh ?hd (n0 - 1)"
  1169       using decrpoly_normh by blast
  1170 
  1171     from maxindex_coefficients[of p] coefficients_head[of p, symmetric]
  1172     have mihn: "maxindex ?h \<le> maxindex p"
  1173       by auto
  1174     with decr_maxindex[OF h(2)] nz have ihd_lt_n: "?ihd < maxindex p"
  1175       by auto
  1176     {
  1177       fix bs :: "'a list"
  1178       assume bs: "wf_bs bs ?hd"
  1179       let ?ts = "take ?ihd bs"
  1180       let ?rs = "drop ?ihd bs"
  1181       have ts: "wf_bs ?ts ?hd"
  1182         using bs unfolding wf_bs_def by simp
  1183       have bs_ts_eq: "?ts @ ?rs = bs"
  1184         by simp
  1185       from wf_bs_decrpoly[OF ts] have tsh: " \<forall>x. wf_bs (x # ?ts) ?h"
  1186         by simp
  1187       from ihd_lt_n have "\<forall>x. length (x # ?ts) \<le> maxindex p"
  1188         by simp
  1189       with length_le_list_ex obtain xs where xs: "length ((x # ?ts) @ xs) = maxindex p"
  1190         by blast
  1191       then have "\<forall>x. wf_bs ((x # ?ts) @ xs) p"
  1192         unfolding wf_bs_def by simp
  1193       with zp have "\<forall>x. Ipoly ((x # ?ts) @ xs) p = 0"
  1194         by blast
  1195       then have "\<forall>x. Ipoly (x # (?ts @ xs)) p = 0"
  1196         by simp
  1197       with polypoly_poly[OF np, where ?'a = 'a] polypoly_polypoly'[OF np, where ?'a = 'a]
  1198       have "\<forall>x. poly (polypoly' (?ts @ xs) p) x = poly [] x"
  1199         by simp
  1200       then have "poly (polypoly' (?ts @ xs) p) = poly []"
  1201         by auto
  1202       then have "\<forall>c \<in> set (coefficients p). Ipoly (?ts @ xs) (decrpoly c) = 0"
  1203         using poly_zero[where ?'a='a] by (simp add: polypoly'_def)
  1204       with coefficients_head[of p, symmetric]
  1205       have th0: "Ipoly (?ts @ xs) ?hd = 0"
  1206         by simp
  1207       from bs have wf'': "wf_bs ?ts ?hd"
  1208         unfolding wf_bs_def by simp
  1209       with th0 wf_bs_I[of ?ts ?hd xs] have "Ipoly ?ts ?hd = 0"
  1210         by simp
  1211       with wf'' wf_bs_I[of ?ts ?hd ?rs] bs_ts_eq have "\<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0"
  1212         by simp
  1213     }
  1214     then have hdz: "\<forall>bs. wf_bs bs ?hd \<longrightarrow> \<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1215       by blast
  1216     from less(1)[OF ihd_lt_n nhd] hdz have "?hd = 0\<^sub>p"
  1217       by blast
  1218     then have "?h = 0\<^sub>p" by simp
  1219     with head_nz[OF np] have "p = 0\<^sub>p" by simp
  1220   }
  1221   ultimately show "p = 0\<^sub>p"
  1222     by blast
  1223 qed
  1224 
  1225 lemma isnpolyh_unique:
  1226   assumes np: "isnpolyh p n0"
  1227     and nq: "isnpolyh q n1"
  1228   shows "(\<forall>bs. \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (\<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup> :: 'a::{field_char_0,field,power})) \<longleftrightarrow> p = q"
  1229 proof auto
  1230   assume H: "\<forall>bs. (\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> ::'a) = \<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup>"
  1231   then have "\<forall>bs.\<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup>= (0::'a)"
  1232     by simp
  1233   then have "\<forall>bs. wf_bs bs (p -\<^sub>p q) \<longrightarrow> \<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)"
  1234     using wf_bs_polysub[where p=p and q=q] by auto
  1235   with isnpolyh_zero_iff[OF polysub_normh[OF np nq]] polysub_0[OF np nq] show "p = q"
  1236     by blast
  1237 qed
  1238 
  1239 
  1240 text \<open>consequences of unicity on the algorithms for polynomial normalization\<close>
  1241 
  1242 lemma polyadd_commute:
  1243   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1244     and np: "isnpolyh p n0"
  1245     and nq: "isnpolyh q n1"
  1246   shows "p +\<^sub>p q = q +\<^sub>p p"
  1247   using isnpolyh_unique[OF polyadd_normh[OF np nq] polyadd_normh[OF nq np]]
  1248   by simp
  1249 
  1250 lemma zero_normh: "isnpolyh 0\<^sub>p n"
  1251   by simp
  1252 
  1253 lemma one_normh: "isnpolyh (1)\<^sub>p n"
  1254   by simp
  1255 
  1256 lemma polyadd_0[simp]:
  1257   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1258     and np: "isnpolyh p n0"
  1259   shows "p +\<^sub>p 0\<^sub>p = p"
  1260     and "0\<^sub>p +\<^sub>p p = p"
  1261   using isnpolyh_unique[OF polyadd_normh[OF np zero_normh] np]
  1262     isnpolyh_unique[OF polyadd_normh[OF zero_normh np] np] by simp_all
  1263 
  1264 lemma polymul_1[simp]:
  1265   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1266     and np: "isnpolyh p n0"
  1267   shows "p *\<^sub>p (1)\<^sub>p = p"
  1268     and "(1)\<^sub>p *\<^sub>p p = p"
  1269   using isnpolyh_unique[OF polymul_normh[OF np one_normh] np]
  1270     isnpolyh_unique[OF polymul_normh[OF one_normh np] np] by simp_all
  1271 
  1272 lemma polymul_0[simp]:
  1273   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1274     and np: "isnpolyh p n0"
  1275   shows "p *\<^sub>p 0\<^sub>p = 0\<^sub>p"
  1276     and "0\<^sub>p *\<^sub>p p = 0\<^sub>p"
  1277   using isnpolyh_unique[OF polymul_normh[OF np zero_normh] zero_normh]
  1278     isnpolyh_unique[OF polymul_normh[OF zero_normh np] zero_normh] by simp_all
  1279 
  1280 lemma polymul_commute:
  1281   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1282     and np: "isnpolyh p n0"
  1283     and nq: "isnpolyh q n1"
  1284   shows "p *\<^sub>p q = q *\<^sub>p p"
  1285   using isnpolyh_unique[OF polymul_normh[OF np nq] polymul_normh[OF nq np],
  1286     where ?'a = "'a::{field_char_0,field, power}"]
  1287   by simp
  1288 
  1289 declare polyneg_polyneg [simp]
  1290 
  1291 lemma isnpolyh_polynate_id [simp]:
  1292   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1293     and np: "isnpolyh p n0"
  1294   shows "polynate p = p"
  1295   using isnpolyh_unique[where ?'a= "'a::{field_char_0,field}",
  1296       OF polynate_norm[of p, unfolded isnpoly_def] np]
  1297     polynate[where ?'a = "'a::{field_char_0,field}"]
  1298   by simp
  1299 
  1300 lemma polynate_idempotent[simp]:
  1301   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1302   shows "polynate (polynate p) = polynate p"
  1303   using isnpolyh_polynate_id[OF polynate_norm[of p, unfolded isnpoly_def]] .
  1304 
  1305 lemma poly_nate_polypoly': "poly_nate bs p = polypoly' bs (polynate p)"
  1306   unfolding poly_nate_def polypoly'_def ..
  1307 
  1308 lemma poly_nate_poly:
  1309   "poly (poly_nate bs p) = (\<lambda>x:: 'a ::{field_char_0,field}. \<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup>)"
  1310   using polypoly'_poly[OF polynate_norm[unfolded isnpoly_def], symmetric, of bs p]
  1311   unfolding poly_nate_polypoly' by auto
  1312 
  1313 
  1314 subsection \<open>heads, degrees and all that\<close>
  1315 
  1316 lemma degree_eq_degreen0: "degree p = degreen p 0"
  1317   by (induct p rule: degree.induct) simp_all
  1318 
  1319 lemma degree_polyneg:
  1320   assumes "isnpolyh p n"
  1321   shows "degree (polyneg p) = degree p"
  1322   apply (induct p rule: polyneg.induct)
  1323   using assms
  1324   apply simp_all
  1325   apply (case_tac na)
  1326   apply auto
  1327   done
  1328 
  1329 lemma degree_polyadd:
  1330   assumes np: "isnpolyh p n0"
  1331     and nq: "isnpolyh q n1"
  1332   shows "degree (p +\<^sub>p q) \<le> max (degree p) (degree q)"
  1333   using degreen_polyadd[OF np nq, where m= "0"] degree_eq_degreen0 by simp
  1334 
  1335 
  1336 lemma degree_polysub:
  1337   assumes np: "isnpolyh p n0"
  1338     and nq: "isnpolyh q n1"
  1339   shows "degree (p -\<^sub>p q) \<le> max (degree p) (degree q)"
  1340 proof-
  1341   from nq have nq': "isnpolyh (~\<^sub>p q) n1"
  1342     using polyneg_normh by simp
  1343   from degree_polyadd[OF np nq'] show ?thesis
  1344     by (simp add: polysub_def degree_polyneg[OF nq])
  1345 qed
  1346 
  1347 lemma degree_polysub_samehead:
  1348   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1349     and np: "isnpolyh p n0"
  1350     and nq: "isnpolyh q n1"
  1351     and h: "head p = head q"
  1352     and d: "degree p = degree q"
  1353   shows "degree (p -\<^sub>p q) < degree p \<or> (p -\<^sub>p q = 0\<^sub>p)"
  1354   unfolding polysub_def split_def fst_conv snd_conv
  1355   using np nq h d
  1356 proof (induct p q rule: polyadd.induct)
  1357   case (1 c c')
  1358   then show ?case
  1359     by (simp add: Nsub_def Nsub0[simplified Nsub_def])
  1360 next
  1361   case (2 c c' n' p')
  1362   from 2 have "degree (C c) = degree (CN c' n' p')"
  1363     by simp
  1364   then have nz: "n' > 0"
  1365     by (cases n') auto
  1366   then have "head (CN c' n' p') = CN c' n' p'"
  1367     by (cases n') auto
  1368   with 2 show ?case
  1369     by simp
  1370 next
  1371   case (3 c n p c')
  1372   then have "degree (C c') = degree (CN c n p)"
  1373     by simp
  1374   then have nz: "n > 0"
  1375     by (cases n) auto
  1376   then have "head (CN c n p) = CN c n p"
  1377     by (cases n) auto
  1378   with 3 show ?case by simp
  1379 next
  1380   case (4 c n p c' n' p')
  1381   then have H:
  1382     "isnpolyh (CN c n p) n0"
  1383     "isnpolyh (CN c' n' p') n1"
  1384     "head (CN c n p) = head (CN c' n' p')"
  1385     "degree (CN c n p) = degree (CN c' n' p')"
  1386     by simp_all
  1387   then have degc: "degree c = 0" and degc': "degree c' = 0"
  1388     by simp_all
  1389   then have degnc: "degree (~\<^sub>p c) = 0" and degnc': "degree (~\<^sub>p c') = 0"
  1390     using H(1-2) degree_polyneg by auto
  1391   from H have cnh: "isnpolyh c (Suc n)" and c'nh: "isnpolyh c' (Suc n')"
  1392     by simp_all
  1393   from degree_polysub[OF cnh c'nh, simplified polysub_def] degc degc'
  1394   have degcmc': "degree (c +\<^sub>p  ~\<^sub>pc') = 0"
  1395     by simp
  1396   from H have pnh: "isnpolyh p n" and p'nh: "isnpolyh p' n'"
  1397     by auto
  1398   have "n = n' \<or> n < n' \<or> n > n'"
  1399     by arith
  1400   moreover
  1401   {
  1402     assume nn': "n = n'"
  1403     have "n = 0 \<or> n > 0" by arith
  1404     moreover
  1405     {
  1406       assume nz: "n = 0"
  1407       then have ?case using 4 nn'
  1408         by (auto simp add: Let_def degcmc')
  1409     }
  1410     moreover
  1411     {
  1412       assume nz: "n > 0"
  1413       with nn' H(3) have  cc': "c = c'" and pp': "p = p'"
  1414         by (cases n, auto)+
  1415       then have ?case
  1416         using polysub_same_0[OF p'nh, simplified polysub_def split_def fst_conv snd_conv]
  1417         using polysub_same_0[OF c'nh, simplified polysub_def]
  1418         using nn' 4 by (simp add: Let_def)
  1419     }
  1420     ultimately have ?case by blast
  1421   }
  1422   moreover
  1423   {
  1424     assume nn': "n < n'"
  1425     then have n'p: "n' > 0"
  1426       by simp
  1427     then have headcnp':"head (CN c' n' p') = CN c' n' p'"
  1428       by (cases n') simp_all
  1429     have degcnp': "degree (CN c' n' p') = 0"
  1430       and degcnpeq: "degree (CN c n p) = degree (CN c' n' p')"
  1431       using 4 nn' by (cases n', simp_all)
  1432     then have "n > 0"
  1433       by (cases n) simp_all
  1434     then have headcnp: "head (CN c n p) = CN c n p"
  1435       by (cases n) auto
  1436     from H(3) headcnp headcnp' nn' have ?case
  1437       by auto
  1438   }
  1439   moreover
  1440   {
  1441     assume nn': "n > n'"
  1442     then have np: "n > 0" by simp
  1443     then have headcnp:"head (CN c n p) = CN c n p"
  1444       by (cases n) simp_all
  1445     from 4 have degcnpeq: "degree (CN c' n' p') = degree (CN c n p)"
  1446       by simp
  1447     from np have degcnp: "degree (CN c n p) = 0"
  1448       by (cases n) simp_all
  1449     with degcnpeq have "n' > 0"
  1450       by (cases n') simp_all
  1451     then have headcnp': "head (CN c' n' p') = CN c' n' p'"
  1452       by (cases n') auto
  1453     from H(3) headcnp headcnp' nn' have ?case by auto
  1454   }
  1455   ultimately show ?case by blast
  1456 qed auto
  1457 
  1458 lemma shift1_head : "isnpolyh p n0 \<Longrightarrow> head (shift1 p) = head p"
  1459   by (induct p arbitrary: n0 rule: head.induct) (simp_all add: shift1_def)
  1460 
  1461 lemma funpow_shift1_head: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> head (funpow k shift1 p) = head p"
  1462 proof (induct k arbitrary: n0 p)
  1463   case 0
  1464   then show ?case
  1465     by auto
  1466 next
  1467   case (Suc k n0 p)
  1468   then have "isnpolyh (shift1 p) 0"
  1469     by (simp add: shift1_isnpolyh)
  1470   with Suc have "head (funpow k shift1 (shift1 p)) = head (shift1 p)"
  1471     and "head (shift1 p) = head p"
  1472     by (simp_all add: shift1_head)
  1473   then show ?case
  1474     by (simp add: funpow_swap1)
  1475 qed
  1476 
  1477 lemma shift1_degree: "degree (shift1 p) = 1 + degree p"
  1478   by (simp add: shift1_def)
  1479 
  1480 lemma funpow_shift1_degree: "degree (funpow k shift1 p) = k + degree p "
  1481   by (induct k arbitrary: p) (auto simp add: shift1_degree)
  1482 
  1483 lemma funpow_shift1_nz: "p \<noteq> 0\<^sub>p \<Longrightarrow> funpow n shift1 p \<noteq> 0\<^sub>p"
  1484   by (induct n arbitrary: p) simp_all
  1485 
  1486 lemma head_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> head p = p"
  1487   by (induct p arbitrary: n rule: degree.induct) auto
  1488 lemma headn_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> headn p m = p"
  1489   by (induct p arbitrary: n rule: degreen.induct) auto
  1490 lemma head_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> head p = p"
  1491   by (induct p arbitrary: n rule: degree.induct) auto
  1492 lemma head_head[simp]: "isnpolyh p n0 \<Longrightarrow> head (head p) = head p"
  1493   by (induct p rule: head.induct) auto
  1494 
  1495 lemma polyadd_eq_const_degree:
  1496   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> polyadd p q = C c \<Longrightarrow> degree p = degree q"
  1497   using polyadd_eq_const_degreen degree_eq_degreen0 by simp
  1498 
  1499 lemma polyadd_head:
  1500   assumes np: "isnpolyh p n0"
  1501     and nq: "isnpolyh q n1"
  1502     and deg: "degree p \<noteq> degree q"
  1503   shows "head (p +\<^sub>p q) = (if degree p < degree q then head q else head p)"
  1504   using np nq deg
  1505   apply (induct p q arbitrary: n0 n1 rule: polyadd.induct)
  1506   apply simp_all
  1507   apply (case_tac n', simp, simp)
  1508   apply (case_tac n, simp, simp)
  1509   apply (case_tac n, case_tac n', simp add: Let_def)
  1510   apply (auto simp add: polyadd_eq_const_degree)[2]
  1511   apply (metis head_nz)
  1512   apply (metis head_nz)
  1513   apply (metis degree.simps(9) gr0_conv_Suc head.simps(1) less_Suc0 not_less_eq)
  1514   done
  1515 
  1516 lemma polymul_head_polyeq:
  1517   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1518   shows "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> p \<noteq> 0\<^sub>p \<Longrightarrow> q \<noteq> 0\<^sub>p \<Longrightarrow> head (p *\<^sub>p q) = head p *\<^sub>p head q"
  1519 proof (induct p q arbitrary: n0 n1 rule: polymul.induct)
  1520   case (2 c c' n' p' n0 n1)
  1521   then have "isnpolyh (head (CN c' n' p')) n1" "isnormNum c"
  1522     by (simp_all add: head_isnpolyh)
  1523   then show ?case
  1524     using 2 by (cases n') auto
  1525 next
  1526   case (3 c n p c' n0 n1)
  1527   then have "isnpolyh (head (CN c n p)) n0" "isnormNum c'"
  1528     by (simp_all add: head_isnpolyh)
  1529   then show ?case
  1530     using 3 by (cases n) auto
  1531 next
  1532   case (4 c n p c' n' p' n0 n1)
  1533   then have norm: "isnpolyh p n" "isnpolyh c (Suc n)" "isnpolyh p' n'" "isnpolyh c' (Suc n')"
  1534     "isnpolyh (CN c n p) n" "isnpolyh (CN c' n' p') n'"
  1535     by simp_all
  1536   have "n < n' \<or> n' < n \<or> n = n'" by arith
  1537   moreover
  1538   {
  1539     assume nn': "n < n'"
  1540     then have ?case
  1541       using norm "4.hyps"(2)[OF norm(1,6)] "4.hyps"(1)[OF norm(2,6)]
  1542       apply simp
  1543       apply (cases n)
  1544       apply simp
  1545       apply (cases n')
  1546       apply simp_all
  1547       done
  1548   }
  1549   moreover {
  1550     assume nn': "n'< n"
  1551     then have ?case
  1552       using norm "4.hyps"(6) [OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)]
  1553       apply simp
  1554       apply (cases n')
  1555       apply simp
  1556       apply (cases n)
  1557       apply auto
  1558       done
  1559   }
  1560   moreover
  1561   {
  1562     assume nn': "n' = n"
  1563     from nn' polymul_normh[OF norm(5,4)]
  1564     have ncnpc':"isnpolyh (CN c n p *\<^sub>p c') n" by (simp add: min_def)
  1565     from nn' polymul_normh[OF norm(5,3)] norm
  1566     have ncnpp':"isnpolyh (CN c n p *\<^sub>p p') n" by simp
  1567     from nn' ncnpp' polymul_eq0_iff[OF norm(5,3)] norm(6)
  1568     have ncnpp0':"isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
  1569     from polyadd_normh[OF ncnpc' ncnpp0']
  1570     have nth: "isnpolyh ((CN c n p *\<^sub>p c') +\<^sub>p (CN 0\<^sub>p n (CN c n p *\<^sub>p p'))) n"
  1571       by (simp add: min_def)
  1572     {
  1573       assume np: "n > 0"
  1574       with nn' head_isnpolyh_Suc'[OF np nth]
  1575         head_isnpolyh_Suc'[OF np norm(5)] head_isnpolyh_Suc'[OF np norm(6)[simplified nn']]
  1576       have ?case by simp
  1577     }
  1578     moreover
  1579     {
  1580       assume nz: "n = 0"
  1581       from polymul_degreen[OF norm(5,4), where m="0"]
  1582         polymul_degreen[OF norm(5,3), where m="0"] nn' nz degree_eq_degreen0
  1583       norm(5,6) degree_npolyhCN[OF norm(6)]
  1584     have dth: "degree (CN c 0 p *\<^sub>p c') < degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))"
  1585       by simp
  1586     then have dth': "degree (CN c 0 p *\<^sub>p c') \<noteq> degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))"
  1587       by simp
  1588     from polyadd_head[OF ncnpc'[simplified nz] ncnpp0'[simplified nz] dth'] dth
  1589     have ?case
  1590       using norm "4.hyps"(6)[OF norm(5,3)] "4.hyps"(5)[OF norm(5,4)] nn' nz
  1591       by simp
  1592     }
  1593     ultimately have ?case
  1594       by (cases n) auto
  1595   }
  1596   ultimately show ?case by blast
  1597 qed simp_all
  1598 
  1599 lemma degree_coefficients: "degree p = length (coefficients p) - 1"
  1600   by (induct p rule: degree.induct) auto
  1601 
  1602 lemma degree_head[simp]: "degree (head p) = 0"
  1603   by (induct p rule: head.induct) auto
  1604 
  1605 lemma degree_CN: "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<le> 1 + degree p"
  1606   by (cases n) simp_all
  1607 
  1608 lemma degree_CN': "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<ge>  degree p"
  1609   by (cases n) simp_all
  1610 
  1611 lemma polyadd_different_degree:
  1612   "isnpolyh p n0 \<Longrightarrow> isnpolyh q n1 \<Longrightarrow> degree p \<noteq> degree q \<Longrightarrow>
  1613     degree (polyadd p q) = max (degree p) (degree q)"
  1614   using polyadd_different_degreen degree_eq_degreen0 by simp
  1615 
  1616 lemma degreen_polyneg: "isnpolyh p n0 \<Longrightarrow> degreen (~\<^sub>p p) m = degreen p m"
  1617   by (induct p arbitrary: n0 rule: polyneg.induct) auto
  1618 
  1619 lemma degree_polymul:
  1620   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1621     and np: "isnpolyh p n0"
  1622     and nq: "isnpolyh q n1"
  1623   shows "degree (p *\<^sub>p q) \<le> degree p + degree q"
  1624   using polymul_degreen[OF np nq, where m="0"]  degree_eq_degreen0 by simp
  1625 
  1626 lemma polyneg_degree: "isnpolyh p n \<Longrightarrow> degree (polyneg p) = degree p"
  1627   by (induct p arbitrary: n rule: degree.induct) auto
  1628 
  1629 lemma polyneg_head: "isnpolyh p n \<Longrightarrow> head (polyneg p) = polyneg (head p)"
  1630   by (induct p arbitrary: n rule: degree.induct) auto
  1631 
  1632 
  1633 subsection \<open>Correctness of polynomial pseudo division\<close>
  1634 
  1635 lemma polydivide_aux_properties:
  1636   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1637     and np: "isnpolyh p n0"
  1638     and ns: "isnpolyh s n1"
  1639     and ap: "head p = a"
  1640     and ndp: "degree p = n"
  1641     and pnz: "p \<noteq> 0\<^sub>p"
  1642   shows "polydivide_aux a n p k s = (k', r) \<longrightarrow> k' \<ge> k \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1643     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> (polypow (k' - k) a) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1644   using ns
  1645 proof (induct "degree s" arbitrary: s k k' r n1 rule: less_induct)
  1646   case less
  1647   let ?qths = "\<exists>q n1. isnpolyh q n1 \<and> (a ^\<^sub>p (k' - k) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1648   let ?ths = "polydivide_aux a n p k s = (k', r) \<longrightarrow>  k \<le> k' \<and>
  1649     (degree r = 0 \<or> degree r < degree p) \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1650   let ?b = "head s"
  1651   let ?p' = "funpow (degree s - n) shift1 p"
  1652   let ?xdn = "funpow (degree s - n) shift1 (1)\<^sub>p"
  1653   let ?akk' = "a ^\<^sub>p (k' - k)"
  1654   note ns = \<open>isnpolyh s n1\<close>
  1655   from np have np0: "isnpolyh p 0"
  1656     using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by simp
  1657   have np': "isnpolyh ?p' 0"
  1658     using funpow_shift1_isnpoly[OF np0[simplified isnpoly_def[symmetric]] pnz, where n="degree s - n"] isnpoly_def
  1659     by simp
  1660   have headp': "head ?p' = head p"
  1661     using funpow_shift1_head[OF np pnz] by simp
  1662   from funpow_shift1_isnpoly[where p="(1)\<^sub>p"] have nxdn: "isnpolyh ?xdn 0"
  1663     by (simp add: isnpoly_def)
  1664   from polypow_normh [OF head_isnpolyh[OF np0], where k="k' - k"] ap
  1665   have nakk':"isnpolyh ?akk' 0" by blast
  1666   {
  1667     assume sz: "s = 0\<^sub>p"
  1668     then have ?ths
  1669       using np polydivide_aux.simps
  1670       apply clarsimp
  1671       apply (rule exI[where x="0\<^sub>p"])
  1672       apply simp
  1673       done
  1674   }
  1675   moreover
  1676   {
  1677     assume sz: "s \<noteq> 0\<^sub>p"
  1678     {
  1679       assume dn: "degree s < n"
  1680       then have "?ths"
  1681         using ns ndp np polydivide_aux.simps
  1682         apply auto
  1683         apply (rule exI[where x="0\<^sub>p"])
  1684         apply simp
  1685         done
  1686     }
  1687     moreover
  1688     {
  1689       assume dn': "\<not> degree s < n"
  1690       then have dn: "degree s \<ge> n"
  1691         by arith
  1692       have degsp': "degree s = degree ?p'"
  1693         using dn ndp funpow_shift1_degree[where k = "degree s - n" and p="p"]
  1694         by simp
  1695       {
  1696         assume ba: "?b = a"
  1697         then have headsp': "head s = head ?p'"
  1698           using ap headp' by simp
  1699         have nr: "isnpolyh (s -\<^sub>p ?p') 0"
  1700           using polysub_normh[OF ns np'] by simp
  1701         from degree_polysub_samehead[OF ns np' headsp' degsp']
  1702         have "degree (s -\<^sub>p ?p') < degree s \<or> s -\<^sub>p ?p' = 0\<^sub>p"
  1703           by simp
  1704         moreover
  1705         {
  1706           assume deglt:"degree (s -\<^sub>p ?p') < degree s"
  1707           from polydivide_aux.simps sz dn' ba
  1708           have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1709             by (simp add: Let_def)
  1710           {
  1711             assume h1: "polydivide_aux a n p k s = (k', r)"
  1712             from less(1)[OF deglt nr, of k k' r] trans[OF eq[symmetric] h1]
  1713             have kk': "k \<le> k'"
  1714               and nr: "\<exists>nr. isnpolyh r nr"
  1715               and dr: "degree r = 0 \<or> degree r < degree p"
  1716               and q1: "\<exists>q nq. isnpolyh q nq \<and> a ^\<^sub>p k' - k *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r"
  1717               by auto
  1718             from q1 obtain q n1 where nq: "isnpolyh q n1"
  1719               and asp: "a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r"
  1720               by blast
  1721             from nr obtain nr where nr': "isnpolyh r nr"
  1722               by blast
  1723             from polymul_normh[OF nakk' ns] have nakks': "isnpolyh (a ^\<^sub>p (k' - k) *\<^sub>p s) 0"
  1724               by simp
  1725             from polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]
  1726             have nq': "isnpolyh (?akk' *\<^sub>p ?xdn +\<^sub>p q) 0" by simp
  1727             from polyadd_normh[OF polymul_normh[OF np
  1728               polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]] nr']
  1729             have nqr': "isnpolyh (p *\<^sub>p (?akk' *\<^sub>p ?xdn +\<^sub>p q) +\<^sub>p r) 0"
  1730               by simp
  1731             from asp have "\<forall>bs :: 'a::{field_char_0,field} list.
  1732               Ipoly bs (a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p')) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1733               by simp
  1734             then have "\<forall>bs :: 'a::{field_char_0,field} list.
  1735               Ipoly bs (a^\<^sub>p (k' - k)*\<^sub>p s) =
  1736               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs ?p' + Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1737               by (simp add: field_simps)
  1738             then have "\<forall>bs :: 'a::{field_char_0,field} list.
  1739               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1740               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p *\<^sub>p p) +
  1741               Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1742               by (auto simp only: funpow_shift1_1)
  1743             then have "\<forall>bs:: 'a::{field_char_0,field} list.
  1744               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1745               Ipoly bs p * (Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 (1)\<^sub>p) +
  1746               Ipoly bs q) + Ipoly bs r"
  1747               by (simp add: field_simps)
  1748             then have "\<forall>bs:: 'a::{field_char_0,field} list.
  1749               Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1750               Ipoly bs (p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r)"
  1751               by simp
  1752             with isnpolyh_unique[OF nakks' nqr']
  1753             have "a ^\<^sub>p (k' - k) *\<^sub>p s =
  1754               p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q) +\<^sub>p r"
  1755               by blast
  1756             then have ?qths using nq'
  1757               apply (rule_tac x="(a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 (1)\<^sub>p) +\<^sub>p q" in exI)
  1758               apply (rule_tac x="0" in exI)
  1759               apply simp
  1760               done
  1761             with kk' nr dr have "k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1762               (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1763               by blast
  1764           }
  1765           then have ?ths by blast
  1766         }
  1767         moreover
  1768         {
  1769           assume spz:"s -\<^sub>p ?p' = 0\<^sub>p"
  1770           from spz isnpolyh_unique[OF polysub_normh[OF ns np'], where q="0\<^sub>p", symmetric, where ?'a = "'a::{field_char_0,field}"]
  1771           have "\<forall>bs:: 'a::{field_char_0,field} list. Ipoly bs s = Ipoly bs ?p'"
  1772             by simp
  1773           then have "\<forall>bs:: 'a::{field_char_0,field} list. Ipoly bs s = Ipoly bs (?xdn *\<^sub>p p)"
  1774             using np nxdn
  1775             apply simp
  1776             apply (simp only: funpow_shift1_1)
  1777             apply simp
  1778             done
  1779           then have sp': "s = ?xdn *\<^sub>p p"
  1780             using isnpolyh_unique[OF ns polymul_normh[OF nxdn np]]
  1781             by blast
  1782           {
  1783             assume h1: "polydivide_aux a n p k s = (k', r)"
  1784             from polydivide_aux.simps sz dn' ba
  1785             have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1786               by (simp add: Let_def)
  1787             also have "\<dots> = (k,0\<^sub>p)"
  1788               using polydivide_aux.simps spz by simp
  1789             finally have "(k', r) = (k, 0\<^sub>p)"
  1790               using h1 by simp
  1791             with sp'[symmetric] ns np nxdn polyadd_0(1)[OF polymul_normh[OF np nxdn]]
  1792               polyadd_0(2)[OF polymul_normh[OF np nxdn]] have ?ths
  1793               apply auto
  1794               apply (rule exI[where x="?xdn"])
  1795               apply (auto simp add: polymul_commute[of p])
  1796               done
  1797           }
  1798         }
  1799         ultimately have ?ths by blast
  1800       }
  1801       moreover
  1802       {
  1803         assume ba: "?b \<noteq> a"
  1804         from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns]
  1805           polymul_normh[OF head_isnpolyh[OF ns] np']]
  1806         have nth: "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1807           by (simp add: min_def)
  1808         have nzths: "a *\<^sub>p s \<noteq> 0\<^sub>p" "?b *\<^sub>p ?p' \<noteq> 0\<^sub>p"
  1809           using polymul_eq0_iff[OF head_isnpolyh[OF np0, simplified ap] ns]
  1810             polymul_eq0_iff[OF head_isnpolyh[OF ns] np']head_nz[OF np0] ap pnz sz head_nz[OF ns]
  1811             funpow_shift1_nz[OF pnz]
  1812           by simp_all
  1813         from polymul_head_polyeq[OF head_isnpolyh[OF np] ns] head_nz[OF np] sz ap head_head[OF np] pnz
  1814           polymul_head_polyeq[OF head_isnpolyh[OF ns] np'] head_nz [OF ns] sz funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1815         have hdth: "head (a *\<^sub>p s) = head (?b *\<^sub>p ?p')"
  1816           using head_head[OF ns] funpow_shift1_head[OF np pnz]
  1817             polymul_commute[OF head_isnpolyh[OF np] head_isnpolyh[OF ns]]
  1818           by (simp add: ap)
  1819         from polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1820           head_nz[OF np] pnz sz ap[symmetric]
  1821           funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1822           polymul_degreen[OF head_isnpolyh[OF ns] np', where m="0"] head_nz[OF ns]
  1823           ndp dn
  1824         have degth: "degree (a *\<^sub>p s) = degree (?b *\<^sub>p ?p')"
  1825           by (simp add: degree_eq_degreen0[symmetric] funpow_shift1_degree)
  1826         {
  1827           assume dth: "degree ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) < degree s"
  1828           from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1829             polymul_normh[OF head_isnpolyh[OF ns]np']] ap
  1830           have nasbp': "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0"
  1831             by simp
  1832           {
  1833             assume h1:"polydivide_aux a n p k s = (k', r)"
  1834             from h1 polydivide_aux.simps sz dn' ba
  1835             have eq:"polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = (k',r)"
  1836               by (simp add: Let_def)
  1837             with less(1)[OF dth nasbp', of "Suc k" k' r]
  1838             obtain q nq nr where kk': "Suc k \<le> k'"
  1839               and nr: "isnpolyh r nr"
  1840               and nq: "isnpolyh q nq"
  1841               and dr: "degree r = 0 \<or> degree r < degree p"
  1842               and qr: "a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = p *\<^sub>p q +\<^sub>p r"
  1843               by auto
  1844             from kk' have kk'': "Suc (k' - Suc k) = k' - k"
  1845               by arith
  1846             {
  1847               fix bs :: "'a::{field_char_0,field} list"
  1848               from qr isnpolyh_unique[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k", simplified ap] nasbp', symmetric]
  1849               have "Ipoly bs (a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p'))) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)"
  1850                 by simp
  1851               then have "Ipoly bs a ^ (Suc (k' - Suc k)) * Ipoly bs s =
  1852                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?p' + Ipoly bs r"
  1853                 by (simp add: field_simps)
  1854               then have "Ipoly bs a ^ (k' - k)  * Ipoly bs s =
  1855                 Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn * Ipoly bs p + Ipoly bs r"
  1856                 by (simp add: kk'' funpow_shift1_1[where n="degree s - n" and p="p"])
  1857               then have "Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1858                 Ipoly bs p * (Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn) + Ipoly bs r"
  1859                 by (simp add: field_simps)
  1860             }
  1861             then have ieq:"\<forall>bs :: 'a::{field_char_0,field} list.
  1862                 Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) =
  1863                 Ipoly bs (p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r)"
  1864               by auto
  1865             let ?q = "q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)"
  1866             from polyadd_normh[OF nq polymul_normh[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k"] head_isnpolyh[OF ns], simplified ap] nxdn]]
  1867             have nqw: "isnpolyh ?q 0"
  1868               by simp
  1869             from ieq isnpolyh_unique[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - k"] ns, simplified ap] polyadd_normh[OF polymul_normh[OF np nqw] nr]]
  1870             have asth: "(a ^\<^sub>p (k' - k) *\<^sub>p s) = p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r"
  1871               by blast
  1872             from dr kk' nr h1 asth nqw have ?ths
  1873               apply simp
  1874               apply (rule conjI)
  1875               apply (rule exI[where x="nr"], simp)
  1876               apply (rule exI[where x="(q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn))"], simp)
  1877               apply (rule exI[where x="0"], simp)
  1878               done
  1879           }
  1880           then have ?ths by blast
  1881         }
  1882         moreover
  1883         {
  1884           assume spz: "a *\<^sub>p s -\<^sub>p (?b *\<^sub>p ?p') = 0\<^sub>p"
  1885           {
  1886             fix bs :: "'a::{field_char_0,field} list"
  1887             from isnpolyh_unique[OF nth, where ?'a="'a" and q="0\<^sub>p",simplified,symmetric] spz
  1888             have "Ipoly bs (a*\<^sub>p s) = Ipoly bs ?b * Ipoly bs ?p'"
  1889               by simp
  1890             then have "Ipoly bs (a*\<^sub>p s) = Ipoly bs (?b *\<^sub>p ?xdn) * Ipoly bs p"
  1891               by (simp add: funpow_shift1_1[where n="degree s - n" and p="p"])
  1892             then have "Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))"
  1893               by simp
  1894           }
  1895           then have hth: "\<forall>bs :: 'a::{field_char_0,field} list.
  1896             Ipoly bs (a *\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" ..
  1897           from hth have asq: "a *\<^sub>p s = p *\<^sub>p (?b *\<^sub>p ?xdn)"
  1898             using isnpolyh_unique[where ?'a = "'a::{field_char_0,field}", OF polymul_normh[OF head_isnpolyh[OF np] ns]
  1899                     polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]],
  1900               simplified ap]
  1901             by simp
  1902           {
  1903             assume h1: "polydivide_aux a n p k s = (k', r)"
  1904             from h1 sz ba dn' spz polydivide_aux.simps polydivide_aux.simps
  1905             have "(k', r) = (Suc k, 0\<^sub>p)"
  1906               by (simp add: Let_def)
  1907             with h1 np head_isnpolyh[OF np, simplified ap] ns polymul_normh[OF head_isnpolyh[OF ns] nxdn]
  1908               polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]] asq
  1909             have ?ths
  1910               apply (clarsimp simp add: Let_def)
  1911               apply (rule exI[where x="?b *\<^sub>p ?xdn"])
  1912               apply simp
  1913               apply (rule exI[where x="0"], simp)
  1914               done
  1915           }
  1916           then have ?ths by blast
  1917         }
  1918         ultimately have ?ths
  1919           using degree_polysub_samehead[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] polymul_normh[OF head_isnpolyh[OF ns] np'] hdth degth] polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1920             head_nz[OF np] pnz sz ap[symmetric]
  1921           by (auto simp add: degree_eq_degreen0[symmetric])
  1922       }
  1923       ultimately have ?ths by blast
  1924     }
  1925     ultimately have ?ths by blast
  1926   }
  1927   ultimately show ?ths by blast
  1928 qed
  1929 
  1930 lemma polydivide_properties:
  1931   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  1932     and np: "isnpolyh p n0"
  1933     and ns: "isnpolyh s n1"
  1934     and pnz: "p \<noteq> 0\<^sub>p"
  1935   shows "\<exists>k r. polydivide s p = (k, r) \<and>
  1936     (\<exists>nr. isnpolyh r nr) \<and> (degree r = 0 \<or> degree r < degree p) \<and>
  1937     (\<exists>q n1. isnpolyh q n1 \<and> polypow k (head p) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1938 proof -
  1939   have trv: "head p = head p" "degree p = degree p"
  1940     by simp_all
  1941   from polydivide_def[where s="s" and p="p"] have ex: "\<exists> k r. polydivide s p = (k,r)"
  1942     by auto
  1943   then obtain k r where kr: "polydivide s p = (k,r)"
  1944     by blast
  1945   from trans[OF polydivide_def[where s="s"and p="p", symmetric] kr]
  1946     polydivide_aux_properties[OF np ns trv pnz, where k="0" and k'="k" and r="r"]
  1947   have "(degree r = 0 \<or> degree r < degree p) \<and>
  1948     (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> head p ^\<^sub>p k - 0 *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1949     by blast
  1950   with kr show ?thesis
  1951     apply -
  1952     apply (rule exI[where x="k"])
  1953     apply (rule exI[where x="r"])
  1954     apply simp
  1955     done
  1956 qed
  1957 
  1958 
  1959 subsection \<open>More about polypoly and pnormal etc\<close>
  1960 
  1961 definition "isnonconstant p \<longleftrightarrow> \<not> isconstant p"
  1962 
  1963 lemma isnonconstant_pnormal_iff:
  1964   assumes "isnonconstant p"
  1965   shows "pnormal (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1966 proof
  1967   let ?p = "polypoly bs p"
  1968   assume H: "pnormal ?p"
  1969   have csz: "coefficients p \<noteq> []"
  1970     using assms by (cases p) auto
  1971   from coefficients_head[of p] last_map[OF csz, of "Ipoly bs"] pnormal_last_nonzero[OF H]
  1972   show "Ipoly bs (head p) \<noteq> 0"
  1973     by (simp add: polypoly_def)
  1974 next
  1975   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1976   let ?p = "polypoly bs p"
  1977   have csz: "coefficients p \<noteq> []"
  1978     using assms by (cases p) auto
  1979   then have pz: "?p \<noteq> []"
  1980     by (simp add: polypoly_def)
  1981   then have lg: "length ?p > 0"
  1982     by simp
  1983   from h coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]
  1984   have lz: "last ?p \<noteq> 0"
  1985     by (simp add: polypoly_def)
  1986   from pnormal_last_length[OF lg lz] show "pnormal ?p" .
  1987 qed
  1988 
  1989 lemma isnonconstant_coefficients_length: "isnonconstant p \<Longrightarrow> length (coefficients p) > 1"
  1990   unfolding isnonconstant_def
  1991   apply (cases p)
  1992   apply simp_all
  1993   apply (rename_tac nat a, case_tac nat)
  1994   apply auto
  1995   done
  1996 
  1997 lemma isnonconstant_nonconstant:
  1998   assumes "isnonconstant p"
  1999   shows "nonconstant (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  2000 proof
  2001   let ?p = "polypoly bs p"
  2002   assume nc: "nonconstant ?p"
  2003   from isnonconstant_pnormal_iff[OF assms, of bs] nc
  2004   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2005     unfolding nonconstant_def by blast
  2006 next
  2007   let ?p = "polypoly bs p"
  2008   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2009   from isnonconstant_pnormal_iff[OF assms, of bs] h
  2010   have pn: "pnormal ?p"
  2011     by blast
  2012   {
  2013     fix x
  2014     assume H: "?p = [x]"
  2015     from H have "length (coefficients p) = 1"
  2016       unfolding polypoly_def by auto
  2017     with isnonconstant_coefficients_length[OF assms]
  2018     have False by arith
  2019   }
  2020   then show "nonconstant ?p"
  2021     using pn unfolding nonconstant_def by blast
  2022 qed
  2023 
  2024 lemma pnormal_length: "p \<noteq> [] \<Longrightarrow> pnormal p \<longleftrightarrow> length (pnormalize p) = length p"
  2025   apply (induct p)
  2026   apply (simp_all add: pnormal_def)
  2027   apply (case_tac "p = []")
  2028   apply simp_all
  2029   done
  2030 
  2031 lemma degree_degree:
  2032   assumes "isnonconstant p"
  2033   shows "degree p = Polynomial_List.degree (polypoly bs p) \<longleftrightarrow> \<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2034 proof
  2035   let ?p = "polypoly bs p"
  2036   assume H: "degree p = Polynomial_List.degree ?p"
  2037   from isnonconstant_coefficients_length[OF assms] have pz: "?p \<noteq> []"
  2038     unfolding polypoly_def by auto
  2039   from H degree_coefficients[of p] isnonconstant_coefficients_length[OF assms]
  2040   have lg: "length (pnormalize ?p) = length ?p"
  2041     unfolding Polynomial_List.degree_def polypoly_def by simp
  2042   then have "pnormal ?p"
  2043     using pnormal_length[OF pz] by blast
  2044   with isnonconstant_pnormal_iff[OF assms] show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2045     by blast
  2046 next
  2047   let ?p = "polypoly bs p"
  2048   assume H: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  2049   with isnonconstant_pnormal_iff[OF assms] have "pnormal ?p"
  2050     by blast
  2051   with degree_coefficients[of p] isnonconstant_coefficients_length[OF assms]
  2052   show "degree p = Polynomial_List.degree ?p"
  2053     unfolding polypoly_def pnormal_def Polynomial_List.degree_def by auto
  2054 qed
  2055 
  2056 
  2057 section \<open>Swaps ; Division by a certain variable\<close>
  2058 
  2059 primrec swap :: "nat \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> poly"
  2060 where
  2061   "swap n m (C x) = C x"
  2062 | "swap n m (Bound k) = Bound (if k = n then m else if k = m then n else k)"
  2063 | "swap n m (Neg t) = Neg (swap n m t)"
  2064 | "swap n m (Add s t) = Add (swap n m s) (swap n m t)"
  2065 | "swap n m (Sub s t) = Sub (swap n m s) (swap n m t)"
  2066 | "swap n m (Mul s t) = Mul (swap n m s) (swap n m t)"
  2067 | "swap n m (Pw t k) = Pw (swap n m t) k"
  2068 | "swap n m (CN c k p) = CN (swap n m c) (if k = n then m else if k=m then n else k) (swap n m p)"
  2069 
  2070 lemma swap:
  2071   assumes "n < length bs"
  2072     and "m < length bs"
  2073   shows "Ipoly bs (swap n m t) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2074 proof (induct t)
  2075   case (Bound k)
  2076   then show ?case
  2077     using assms by simp
  2078 next
  2079   case (CN c k p)
  2080   then show ?case
  2081     using assms by simp
  2082 qed simp_all
  2083 
  2084 lemma swap_swap_id [simp]: "swap n m (swap m n t) = t"
  2085   by (induct t) simp_all
  2086 
  2087 lemma swap_commute: "swap n m p = swap m n p"
  2088   by (induct p) simp_all
  2089 
  2090 lemma swap_same_id[simp]: "swap n n t = t"
  2091   by (induct t) simp_all
  2092 
  2093 definition "swapnorm n m t = polynate (swap n m t)"
  2094 
  2095 lemma swapnorm:
  2096   assumes nbs: "n < length bs"
  2097     and mbs: "m < length bs"
  2098   shows "((Ipoly bs (swapnorm n m t) :: 'a::{field_char_0,field})) =
  2099     Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  2100   using swap[OF assms] swapnorm_def by simp
  2101 
  2102 lemma swapnorm_isnpoly [simp]:
  2103   assumes "SORT_CONSTRAINT('a::{field_char_0,field})"
  2104   shows "isnpoly (swapnorm n m p)"
  2105   unfolding swapnorm_def by simp
  2106 
  2107 definition "polydivideby n s p =
  2108   (let
  2109     ss = swapnorm 0 n s;
  2110     sp = swapnorm 0 n p;
  2111     h = head sp;
  2112     (k, r) = polydivide ss sp
  2113    in (k, swapnorm 0 n h, swapnorm 0 n r))"
  2114 
  2115 lemma swap_nz [simp]: "swap n m p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p"
  2116   by (induct p) simp_all
  2117 
  2118 fun isweaknpoly :: "poly \<Rightarrow> bool"
  2119 where
  2120   "isweaknpoly (C c) = True"
  2121 | "isweaknpoly (CN c n p) \<longleftrightarrow> isweaknpoly c \<and> isweaknpoly p"
  2122 | "isweaknpoly p = False"
  2123 
  2124 lemma isnpolyh_isweaknpoly: "isnpolyh p n0 \<Longrightarrow> isweaknpoly p"
  2125   by (induct p arbitrary: n0) auto
  2126 
  2127 lemma swap_isweanpoly: "isweaknpoly p \<Longrightarrow> isweaknpoly (swap n m p)"
  2128   by (induct p) auto
  2129 
  2130 end