src/HOL/Rat.thy
author wenzelm
Tue Oct 10 19:23:03 2017 +0200 (23 months ago)
changeset 66831 29ea2b900a05
parent 66806 a4e82b58d833
child 67051 e7e54a0b9197
permissions -rw-r--r--
tuned: each session has at most one defining entry;
     1 (*  Title:      HOL/Rat.thy
     2     Author:     Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 section \<open>Rational numbers\<close>
     6 
     7 theory Rat
     8   imports Archimedean_Field
     9 begin
    10 
    11 subsection \<open>Rational numbers as quotient\<close>
    12 
    13 subsubsection \<open>Construction of the type of rational numbers\<close>
    14 
    15 definition ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool"
    16   where "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    17 
    18 lemma ratrel_iff [simp]: "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    19   by (simp add: ratrel_def)
    20 
    21 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    22   by (auto intro!: one_neq_zero)
    23 
    24 lemma symp_ratrel: "symp ratrel"
    25   by (simp add: ratrel_def symp_def)
    26 
    27 lemma transp_ratrel: "transp ratrel"
    28 proof (rule transpI, unfold split_paired_all)
    29   fix a b a' b' a'' b'' :: int
    30   assume *: "ratrel (a, b) (a', b')"
    31   assume **: "ratrel (a', b') (a'', b'')"
    32   have "b' * (a * b'') = b'' * (a * b')" by simp
    33   also from * have "a * b' = a' * b" by auto
    34   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    35   also from ** have "a' * b'' = a'' * b'" by auto
    36   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    37   finally have "b' * (a * b'') = b' * (a'' * b)" .
    38   moreover from ** have "b' \<noteq> 0" by auto
    39   ultimately have "a * b'' = a'' * b" by simp
    40   with * ** show "ratrel (a, b) (a'', b'')" by auto
    41 qed
    42 
    43 lemma part_equivp_ratrel: "part_equivp ratrel"
    44   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    45 
    46 quotient_type rat = "int \<times> int" / partial: "ratrel"
    47   morphisms Rep_Rat Abs_Rat
    48   by (rule part_equivp_ratrel)
    49 
    50 lemma Domainp_cr_rat [transfer_domain_rule]: "Domainp pcr_rat = (\<lambda>x. snd x \<noteq> 0)"
    51   by (simp add: rat.domain_eq)
    52 
    53 
    54 subsubsection \<open>Representation and basic operations\<close>
    55 
    56 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    57   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    58   by simp
    59 
    60 lemma eq_rat:
    61   "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    62   "\<And>a. Fract a 0 = Fract 0 1"
    63   "\<And>a c. Fract 0 a = Fract 0 c"
    64   by (transfer, simp)+
    65 
    66 lemma Rat_cases [case_names Fract, cases type: rat]:
    67   assumes that: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    68   shows C
    69 proof -
    70   obtain a b :: int where q: "q = Fract a b" and b: "b \<noteq> 0"
    71     by transfer simp
    72   let ?a = "a div gcd a b"
    73   let ?b = "b div gcd a b"
    74   from b have "?b * gcd a b = b"
    75     by simp
    76   with b have "?b \<noteq> 0"
    77     by fastforce
    78   with q b have q2: "q = Fract ?a ?b"
    79     by (simp add: eq_rat dvd_div_mult mult.commute [of a])
    80   from b have coprime: "coprime ?a ?b"
    81     by (auto intro: div_gcd_coprime)
    82   show C
    83   proof (cases "b > 0")
    84     case True
    85     then have "?b > 0"
    86       by (simp add: nonneg1_imp_zdiv_pos_iff)
    87     from q2 this coprime show C by (rule that)
    88   next
    89     case False
    90     have "q = Fract (- ?a) (- ?b)"
    91       unfolding q2 by transfer simp
    92     moreover from False b have "- ?b > 0"
    93       by (simp add: pos_imp_zdiv_neg_iff)
    94     moreover from coprime have "coprime (- ?a) (- ?b)"
    95       by simp
    96     ultimately show C
    97       by (rule that)
    98   qed
    99 qed
   100 
   101 lemma Rat_induct [case_names Fract, induct type: rat]:
   102   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   103   shows "P q"
   104   using assms by (cases q) simp
   105 
   106 instantiation rat :: field
   107 begin
   108 
   109 lift_definition zero_rat :: "rat" is "(0, 1)"
   110   by simp
   111 
   112 lift_definition one_rat :: "rat" is "(1, 1)"
   113   by simp
   114 
   115 lemma Zero_rat_def: "0 = Fract 0 1"
   116   by transfer simp
   117 
   118 lemma One_rat_def: "1 = Fract 1 1"
   119   by transfer simp
   120 
   121 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   122   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   123   by (auto simp: distrib_right) (simp add: ac_simps)
   124 
   125 lemma add_rat [simp]:
   126   assumes "b \<noteq> 0" and "d \<noteq> 0"
   127   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   128   using assms by transfer simp
   129 
   130 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   131   by simp
   132 
   133 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   134   by transfer simp
   135 
   136 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   137   by (cases "b = 0") (simp_all add: eq_rat)
   138 
   139 definition diff_rat_def: "q - r = q + - r" for q r :: rat
   140 
   141 lemma diff_rat [simp]:
   142   "b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   143   by (simp add: diff_rat_def)
   144 
   145 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   146   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   147   by (simp add: ac_simps)
   148 
   149 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   150   by transfer simp
   151 
   152 lemma mult_rat_cancel: "c \<noteq> 0 \<Longrightarrow> Fract (c * a) (c * b) = Fract a b"
   153   by transfer simp
   154 
   155 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   156   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   157   by (auto simp add: mult.commute)
   158 
   159 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   160   by transfer simp
   161 
   162 definition divide_rat_def: "q div r = q * inverse r" for q r :: rat
   163 
   164 lemma divide_rat [simp]: "Fract a b div Fract c d = Fract (a * d) (b * c)"
   165   by (simp add: divide_rat_def)
   166 
   167 instance
   168 proof
   169   fix q r s :: rat
   170   show "(q * r) * s = q * (r * s)"
   171     by transfer simp
   172   show "q * r = r * q"
   173     by transfer simp
   174   show "1 * q = q"
   175     by transfer simp
   176   show "(q + r) + s = q + (r + s)"
   177     by transfer (simp add: algebra_simps)
   178   show "q + r = r + q"
   179     by transfer simp
   180   show "0 + q = q"
   181     by transfer simp
   182   show "- q + q = 0"
   183     by transfer simp
   184   show "q - r = q + - r"
   185     by (fact diff_rat_def)
   186   show "(q + r) * s = q * s + r * s"
   187     by transfer (simp add: algebra_simps)
   188   show "(0::rat) \<noteq> 1"
   189     by transfer simp
   190   show "inverse q * q = 1" if "q \<noteq> 0"
   191     using that by transfer simp
   192   show "q div r = q * inverse r"
   193     by (fact divide_rat_def)
   194   show "inverse 0 = (0::rat)"
   195     by transfer simp
   196 qed
   197 
   198 end
   199 
   200 (* We cannot state these two rules earlier because of pending sort hypotheses *)
   201 lemma div_add_self1_no_field [simp]:
   202   assumes "NO_MATCH (x :: 'b :: field) b" "(b :: 'a :: euclidean_semiring_cancel) \<noteq> 0"
   203   shows "(b + a) div b = a div b + 1"
   204   using assms(2) by (fact div_add_self1)
   205 
   206 lemma div_add_self2_no_field [simp]:
   207   assumes "NO_MATCH (x :: 'b :: field) b" "(b :: 'a :: euclidean_semiring_cancel) \<noteq> 0"
   208   shows "(a + b) div b = a div b + 1"
   209   using assms(2) by (fact div_add_self2)
   210 
   211 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   212   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   213 
   214 lemma of_int_rat: "of_int k = Fract k 1"
   215   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   216 
   217 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   218   by (rule of_nat_rat [symmetric])
   219 
   220 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   221   by (rule of_int_rat [symmetric])
   222 
   223 lemma rat_number_collapse:
   224   "Fract 0 k = 0"
   225   "Fract 1 1 = 1"
   226   "Fract (numeral w) 1 = numeral w"
   227   "Fract (- numeral w) 1 = - numeral w"
   228   "Fract (- 1) 1 = - 1"
   229   "Fract k 0 = 0"
   230   using Fract_of_int_eq [of "numeral w"]
   231     and Fract_of_int_eq [of "- numeral w"]
   232   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   233 
   234 lemma rat_number_expand:
   235   "0 = Fract 0 1"
   236   "1 = Fract 1 1"
   237   "numeral k = Fract (numeral k) 1"
   238   "- 1 = Fract (- 1) 1"
   239   "- numeral k = Fract (- numeral k) 1"
   240   by (simp_all add: rat_number_collapse)
   241 
   242 lemma Rat_cases_nonzero [case_names Fract 0]:
   243   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   244     and 0: "q = 0 \<Longrightarrow> C"
   245   shows C
   246 proof (cases "q = 0")
   247   case True
   248   then show C using 0 by auto
   249 next
   250   case False
   251   then obtain a b where *: "q = Fract a b" "b > 0" "coprime a b"
   252     by (cases q) auto
   253   with False have "0 \<noteq> Fract a b"
   254     by simp
   255   with \<open>b > 0\<close> have "a \<noteq> 0"
   256     by (simp add: Zero_rat_def eq_rat)
   257   with Fract * show C by blast
   258 qed
   259 
   260 
   261 subsubsection \<open>Function \<open>normalize\<close>\<close>
   262 
   263 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   264 proof (cases "b = 0")
   265   case True
   266   then show ?thesis
   267     by (simp add: eq_rat)
   268 next
   269   case False
   270   moreover have "b div gcd a b * gcd a b = b"
   271     by (rule dvd_div_mult_self) simp
   272   ultimately have "b div gcd a b * gcd a b \<noteq> 0"
   273     by simp
   274   then have "b div gcd a b \<noteq> 0"
   275     by fastforce
   276   with False show ?thesis
   277     by (simp add: eq_rat dvd_div_mult mult.commute [of a])
   278 qed
   279 
   280 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int"
   281   where "normalize p =
   282    (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   283     else if snd p = 0 then (0, 1)
   284     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   285 
   286 lemma normalize_crossproduct:
   287   assumes "q \<noteq> 0" "s \<noteq> 0"
   288   assumes "normalize (p, q) = normalize (r, s)"
   289   shows "p * s = r * q"
   290 proof -
   291   have *: "p * s = q * r"
   292     if "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   293   proof -
   294     from that have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) =
   295         (q * gcd r s) * (sgn (q * s) * r * gcd p q)"
   296       by simp
   297     with assms show ?thesis
   298       by (auto simp add: ac_simps sgn_mult sgn_0_0)
   299   qed
   300   from assms show ?thesis
   301     by (auto simp: normalize_def Let_def dvd_div_div_eq_mult mult.commute sgn_mult
   302         split: if_splits intro: *)
   303 qed
   304 
   305 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   306   by (auto simp: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   307       split: if_split_asm)
   308 
   309 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   310   by (auto simp: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   311       split: if_split_asm)
   312 
   313 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   314   by (auto simp: normalize_def Let_def dvd_div_neg div_gcd_coprime split: if_split_asm)
   315 
   316 lemma normalize_stable [simp]: "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   317   by (simp add: normalize_def)
   318 
   319 lemma normalize_denom_zero [simp]: "normalize (p, 0) = (0, 1)"
   320   by (simp add: normalize_def)
   321 
   322 lemma normalize_negative [simp]: "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   323   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   324 
   325 text\<open>
   326   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   327 \<close>
   328 
   329 definition quotient_of :: "rat \<Rightarrow> int \<times> int"
   330   where "quotient_of x =
   331     (THE pair. x = Fract (fst pair) (snd pair) \<and> snd pair > 0 \<and> coprime (fst pair) (snd pair))"
   332 
   333 lemma quotient_of_unique: "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   334 proof (cases r)
   335   case (Fract a b)
   336   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and>
   337       snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))"
   338     by auto
   339   then show ?thesis
   340   proof (rule ex1I)
   341     fix p
   342     assume r: "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   343     obtain c d where p: "p = (c, d)" by (cases p)
   344     with r have Fract': "r = Fract c d" "d > 0" "coprime c d"
   345       by simp_all
   346     have "(c, d) = (a, b)"
   347     proof (cases "a = 0")
   348       case True
   349       with Fract Fract' show ?thesis
   350         by (simp add: eq_rat)
   351     next
   352       case False
   353       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0"
   354         by (auto simp add: eq_rat)
   355       then have "c * b > 0 \<longleftrightarrow> a * d > 0"
   356         by auto
   357       with \<open>b > 0\<close> \<open>d > 0\<close> have "a > 0 \<longleftrightarrow> c > 0"
   358         by (simp add: zero_less_mult_iff)
   359       with \<open>a \<noteq> 0\<close> \<open>c \<noteq> 0\<close> have sgn: "sgn a = sgn c"
   360         by (auto simp add: not_less)
   361       from \<open>coprime a b\<close> \<open>coprime c d\<close> have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   362         by (simp add: coprime_crossproduct_int)
   363       with \<open>b > 0\<close> \<open>d > 0\<close> have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b"
   364         by simp
   365       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b"
   366         by (simp add: abs_sgn)
   367       with sgn * show ?thesis
   368         by (auto simp add: sgn_0_0)
   369     qed
   370     with p show "p = (a, b)"
   371       by simp
   372   qed
   373 qed
   374 
   375 lemma quotient_of_Fract [code]: "quotient_of (Fract a b) = normalize (a, b)"
   376 proof -
   377   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   378     by (rule sym) (auto intro: normalize_eq)
   379   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos)
   380     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   381   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   382     by (rule normalize_coprime) simp
   383   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   384   then have "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and>
   385     coprime (fst p) (snd p)) = normalize (a, b)"
   386     by (rule the1_equality [OF quotient_of_unique])
   387   then show ?thesis by (simp add: quotient_of_def)
   388 qed
   389 
   390 lemma quotient_of_number [simp]:
   391   "quotient_of 0 = (0, 1)"
   392   "quotient_of 1 = (1, 1)"
   393   "quotient_of (numeral k) = (numeral k, 1)"
   394   "quotient_of (- 1) = (- 1, 1)"
   395   "quotient_of (- numeral k) = (- numeral k, 1)"
   396   by (simp_all add: rat_number_expand quotient_of_Fract)
   397 
   398 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   399   by (simp add: quotient_of_Fract normalize_eq)
   400 
   401 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   402   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   403 
   404 lemma quotient_of_denom_pos': "snd (quotient_of r) > 0"
   405   using quotient_of_denom_pos [of r] by (simp add: prod_eq_iff)
   406 
   407 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   408   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   409 
   410 lemma quotient_of_inject:
   411   assumes "quotient_of a = quotient_of b"
   412   shows "a = b"
   413 proof -
   414   obtain p q r s where a: "a = Fract p q" and b: "b = Fract r s" and "q > 0" and "s > 0"
   415     by (cases a, cases b)
   416   with assms show ?thesis
   417     by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   418 qed
   419 
   420 lemma quotient_of_inject_eq: "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   421   by (auto simp add: quotient_of_inject)
   422 
   423 
   424 subsubsection \<open>Various\<close>
   425 
   426 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   427   by (simp add: Fract_of_int_eq [symmetric])
   428 
   429 lemma Fract_add_one: "n \<noteq> 0 \<Longrightarrow> Fract (m + n) n = Fract m n + 1"
   430   by (simp add: rat_number_expand)
   431 
   432 lemma quotient_of_div:
   433   assumes r: "quotient_of r = (n,d)"
   434   shows "r = of_int n / of_int d"
   435 proof -
   436   from theI'[OF quotient_of_unique[of r], unfolded r[unfolded quotient_of_def]]
   437   have "r = Fract n d" by simp
   438   then show ?thesis using Fract_of_int_quotient
   439     by simp
   440 qed
   441 
   442 
   443 subsubsection \<open>The ordered field of rational numbers\<close>
   444 
   445 lift_definition positive :: "rat \<Rightarrow> bool"
   446   is "\<lambda>x. 0 < fst x * snd x"
   447 proof clarsimp
   448   fix a b c d :: int
   449   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   450   then have "a * d * b * d = c * b * b * d"
   451     by simp
   452   then have "a * b * d\<^sup>2 = c * d * b\<^sup>2"
   453     unfolding power2_eq_square by (simp add: ac_simps)
   454   then have "0 < a * b * d\<^sup>2 \<longleftrightarrow> 0 < c * d * b\<^sup>2"
   455     by simp
   456   then show "0 < a * b \<longleftrightarrow> 0 < c * d"
   457     using \<open>b \<noteq> 0\<close> and \<open>d \<noteq> 0\<close>
   458     by (simp add: zero_less_mult_iff)
   459 qed
   460 
   461 lemma positive_zero: "\<not> positive 0"
   462   by transfer simp
   463 
   464 lemma positive_add: "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   465   apply transfer
   466   apply (simp add: zero_less_mult_iff)
   467   apply (elim disjE)
   468      apply (simp_all add: add_pos_pos add_neg_neg mult_pos_neg mult_neg_pos mult_neg_neg)
   469   done
   470 
   471 lemma positive_mult: "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   472   apply transfer
   473   apply (drule (1) mult_pos_pos)
   474   apply (simp add: ac_simps)
   475   done
   476 
   477 lemma positive_minus: "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   478   by transfer (auto simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   479 
   480 instantiation rat :: linordered_field
   481 begin
   482 
   483 definition "x < y \<longleftrightarrow> positive (y - x)"
   484 
   485 definition "x \<le> y \<longleftrightarrow> x < y \<or> x = y" for x y :: rat
   486 
   487 definition "\<bar>a\<bar> = (if a < 0 then - a else a)" for a :: rat
   488 
   489 definition "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)" for a :: rat
   490 
   491 instance
   492 proof
   493   fix a b c :: rat
   494   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   495     by (rule abs_rat_def)
   496   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   497     unfolding less_eq_rat_def less_rat_def
   498     apply auto
   499      apply (drule (1) positive_add)
   500      apply (simp_all add: positive_zero)
   501     done
   502   show "a \<le> a"
   503     unfolding less_eq_rat_def by simp
   504   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   505     unfolding less_eq_rat_def less_rat_def
   506     apply auto
   507     apply (drule (1) positive_add)
   508     apply (simp add: algebra_simps)
   509     done
   510   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   511     unfolding less_eq_rat_def less_rat_def
   512     apply auto
   513     apply (drule (1) positive_add)
   514     apply (simp add: positive_zero)
   515     done
   516   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   517     unfolding less_eq_rat_def less_rat_def by auto
   518   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   519     by (rule sgn_rat_def)
   520   show "a \<le> b \<or> b \<le> a"
   521     unfolding less_eq_rat_def less_rat_def
   522     by (auto dest!: positive_minus)
   523   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   524     unfolding less_rat_def
   525     apply (drule (1) positive_mult)
   526     apply (simp add: algebra_simps)
   527     done
   528 qed
   529 
   530 end
   531 
   532 instantiation rat :: distrib_lattice
   533 begin
   534 
   535 definition "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   536 
   537 definition "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   538 
   539 instance
   540   by standard (auto simp add: inf_rat_def sup_rat_def max_min_distrib2)
   541 
   542 end
   543 
   544 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   545   by transfer simp
   546 
   547 lemma less_rat [simp]:
   548   "b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   549   by (simp add: less_rat_def positive_rat algebra_simps)
   550 
   551 lemma le_rat [simp]:
   552   "b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   553   by (simp add: le_less eq_rat)
   554 
   555 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   556   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   557 
   558 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   559   unfolding Fract_of_int_eq
   560   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   561     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   562 
   563 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   564   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   565   shows "P q"
   566 proof (cases q)
   567   case (Fract a b)
   568   have step': "P (Fract a b)" if b: "b < 0" for a b :: int
   569   proof -
   570     from b have "0 < - b"
   571       by simp
   572     then have "P (Fract (- a) (- b))"
   573       by (rule step)
   574     then show "P (Fract a b)"
   575       by (simp add: order_less_imp_not_eq [OF b])
   576   qed
   577   from Fract show "P q"
   578     by (auto simp add: linorder_neq_iff step step')
   579 qed
   580 
   581 lemma zero_less_Fract_iff: "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   582   by (simp add: Zero_rat_def zero_less_mult_iff)
   583 
   584 lemma Fract_less_zero_iff: "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   585   by (simp add: Zero_rat_def mult_less_0_iff)
   586 
   587 lemma zero_le_Fract_iff: "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   588   by (simp add: Zero_rat_def zero_le_mult_iff)
   589 
   590 lemma Fract_le_zero_iff: "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   591   by (simp add: Zero_rat_def mult_le_0_iff)
   592 
   593 lemma one_less_Fract_iff: "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   594   by (simp add: One_rat_def mult_less_cancel_right_disj)
   595 
   596 lemma Fract_less_one_iff: "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   597   by (simp add: One_rat_def mult_less_cancel_right_disj)
   598 
   599 lemma one_le_Fract_iff: "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   600   by (simp add: One_rat_def mult_le_cancel_right)
   601 
   602 lemma Fract_le_one_iff: "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   603   by (simp add: One_rat_def mult_le_cancel_right)
   604 
   605 
   606 subsubsection \<open>Rationals are an Archimedean field\<close>
   607 
   608 lemma rat_floor_lemma: "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   609 proof -
   610   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   611     by (cases "b = 0") (simp, simp add: of_int_rat)
   612   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   613     unfolding Fract_of_int_quotient
   614     by (rule linorder_cases [of b 0]) (simp_all add: divide_nonpos_neg)
   615   ultimately show ?thesis by simp
   616 qed
   617 
   618 instance rat :: archimedean_field
   619 proof
   620   show "\<exists>z. r \<le> of_int z" for r :: rat
   621   proof (induct r)
   622     case (Fract a b)
   623     have "Fract a b \<le> of_int (a div b + 1)"
   624       using rat_floor_lemma [of a b] by simp
   625     then show "\<exists>z. Fract a b \<le> of_int z" ..
   626   qed
   627 qed
   628 
   629 instantiation rat :: floor_ceiling
   630 begin
   631 
   632 definition [code del]: "\<lfloor>x\<rfloor> = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))" for x :: rat
   633 
   634 instance
   635 proof
   636   show "of_int \<lfloor>x\<rfloor> \<le> x \<and> x < of_int (\<lfloor>x\<rfloor> + 1)" for x :: rat
   637     unfolding floor_rat_def using floor_exists1 by (rule theI')
   638 qed
   639 
   640 end
   641 
   642 lemma floor_Fract: "\<lfloor>Fract a b\<rfloor> = a div b"
   643   by (simp add: Fract_of_int_quotient floor_divide_of_int_eq)
   644 
   645 
   646 subsection \<open>Linear arithmetic setup\<close>
   647 
   648 declaration \<open>
   649   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   650     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   651   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   652     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   653   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   654       @{thm True_implies_equals},
   655       @{thm distrib_left [where a = "numeral v" for v]},
   656       @{thm distrib_left [where a = "- numeral v" for v]},
   657       @{thm div_by_1}, @{thm div_0},
   658       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   659       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   660       @{thm add_divide_distrib}, @{thm diff_divide_distrib},
   661       @{thm of_int_minus}, @{thm of_int_diff},
   662       @{thm of_int_of_nat_eq}]
   663   #> Lin_Arith.add_simprocs [Numeral_Simprocs.field_divide_cancel_numeral_factor]
   664   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat \<Rightarrow> rat"})
   665   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int \<Rightarrow> rat"}))
   666 \<close>
   667 
   668 
   669 subsection \<open>Embedding from Rationals to other Fields\<close>
   670 
   671 context field_char_0
   672 begin
   673 
   674 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   675   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   676   by (auto simp: nonzero_divide_eq_eq nonzero_eq_divide_eq) (simp only: of_int_mult [symmetric])
   677 
   678 end
   679 
   680 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   681   by transfer simp
   682 
   683 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   684   by transfer simp
   685 
   686 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   687   by transfer simp
   688 
   689 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   690   by transfer (simp add: add_frac_eq)
   691 
   692 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   693   by transfer simp
   694 
   695 lemma of_rat_neg_one [simp]: "of_rat (- 1) = - 1"
   696   by (simp add: of_rat_minus)
   697 
   698 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   699   using of_rat_add [of a "- b"] by (simp add: of_rat_minus)
   700 
   701 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   702   by transfer (simp add: divide_inverse nonzero_inverse_mult_distrib ac_simps)
   703 
   704 lemma of_rat_sum: "of_rat (\<Sum>a\<in>A. f a) = (\<Sum>a\<in>A. of_rat (f a))"
   705   by (induct rule: infinite_finite_induct) (auto simp: of_rat_add)
   706 
   707 lemma of_rat_prod: "of_rat (\<Prod>a\<in>A. f a) = (\<Prod>a\<in>A. of_rat (f a))"
   708   by (induct rule: infinite_finite_induct) (auto simp: of_rat_mult)
   709 
   710 lemma nonzero_of_rat_inverse: "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   711   by (rule inverse_unique [symmetric]) (simp add: of_rat_mult [symmetric])
   712 
   713 lemma of_rat_inverse: "(of_rat (inverse a) :: 'a::{field_char_0,field}) = inverse (of_rat a)"
   714   by (cases "a = 0") (simp_all add: nonzero_of_rat_inverse)
   715 
   716 lemma nonzero_of_rat_divide: "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   717   by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   718 
   719 lemma of_rat_divide: "(of_rat (a / b) :: 'a::{field_char_0,field}) = of_rat a / of_rat b"
   720   by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   721 
   722 lemma of_rat_power: "(of_rat (a ^ n) :: 'a::field_char_0) = of_rat a ^ n"
   723   by (induct n) (simp_all add: of_rat_mult)
   724 
   725 lemma of_rat_eq_iff [simp]: "of_rat a = of_rat b \<longleftrightarrow> a = b"
   726   apply transfer
   727   apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   728   apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   729   done
   730 
   731 lemma of_rat_eq_0_iff [simp]: "of_rat a = 0 \<longleftrightarrow> a = 0"
   732   using of_rat_eq_iff [of _ 0] by simp
   733 
   734 lemma zero_eq_of_rat_iff [simp]: "0 = of_rat a \<longleftrightarrow> 0 = a"
   735   by simp
   736 
   737 lemma of_rat_eq_1_iff [simp]: "of_rat a = 1 \<longleftrightarrow> a = 1"
   738   using of_rat_eq_iff [of _ 1] by simp
   739 
   740 lemma one_eq_of_rat_iff [simp]: "1 = of_rat a \<longleftrightarrow> 1 = a"
   741   by simp
   742 
   743 lemma of_rat_less: "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   744 proof (induct r, induct s)
   745   fix a b c d :: int
   746   assume not_zero: "b > 0" "d > 0"
   747   then have "b * d > 0" by simp
   748   have of_int_divide_less_eq:
   749     "(of_int a :: 'a) / of_int b < of_int c / of_int d \<longleftrightarrow>
   750       (of_int a :: 'a) * of_int d < of_int c * of_int b"
   751     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   752   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d) \<longleftrightarrow>
   753       Fract a b < Fract c d"
   754     using not_zero \<open>b * d > 0\<close>
   755     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   756 qed
   757 
   758 lemma of_rat_less_eq: "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   759   unfolding le_less by (auto simp add: of_rat_less)
   760 
   761 lemma of_rat_le_0_iff [simp]: "(of_rat r :: 'a::linordered_field) \<le> 0 \<longleftrightarrow> r \<le> 0"
   762   using of_rat_less_eq [of r 0, where 'a = 'a] by simp
   763 
   764 lemma zero_le_of_rat_iff [simp]: "0 \<le> (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 0 \<le> r"
   765   using of_rat_less_eq [of 0 r, where 'a = 'a] by simp
   766 
   767 lemma of_rat_le_1_iff [simp]: "(of_rat r :: 'a::linordered_field) \<le> 1 \<longleftrightarrow> r \<le> 1"
   768   using of_rat_less_eq [of r 1] by simp
   769 
   770 lemma one_le_of_rat_iff [simp]: "1 \<le> (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 1 \<le> r"
   771   using of_rat_less_eq [of 1 r] by simp
   772 
   773 lemma of_rat_less_0_iff [simp]: "(of_rat r :: 'a::linordered_field) < 0 \<longleftrightarrow> r < 0"
   774   using of_rat_less [of r 0, where 'a = 'a] by simp
   775 
   776 lemma zero_less_of_rat_iff [simp]: "0 < (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 0 < r"
   777   using of_rat_less [of 0 r, where 'a = 'a] by simp
   778 
   779 lemma of_rat_less_1_iff [simp]: "(of_rat r :: 'a::linordered_field) < 1 \<longleftrightarrow> r < 1"
   780   using of_rat_less [of r 1] by simp
   781 
   782 lemma one_less_of_rat_iff [simp]: "1 < (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 1 < r"
   783   using of_rat_less [of 1 r] by simp
   784 
   785 lemma of_rat_eq_id [simp]: "of_rat = id"
   786 proof
   787   show "of_rat a = id a" for a
   788     by (induct a) (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   789 qed
   790 
   791 text \<open>Collapse nested embeddings.\<close>
   792 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   793   by (induct n) (simp_all add: of_rat_add)
   794 
   795 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   796   by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   797 
   798 lemma of_rat_numeral_eq [simp]: "of_rat (numeral w) = numeral w"
   799   using of_rat_of_int_eq [of "numeral w"] by simp
   800 
   801 lemma of_rat_neg_numeral_eq [simp]: "of_rat (- numeral w) = - numeral w"
   802   using of_rat_of_int_eq [of "- numeral w"] by simp
   803 
   804 lemmas zero_rat = Zero_rat_def
   805 lemmas one_rat = One_rat_def
   806 
   807 abbreviation rat_of_nat :: "nat \<Rightarrow> rat"
   808   where "rat_of_nat \<equiv> of_nat"
   809 
   810 abbreviation rat_of_int :: "int \<Rightarrow> rat"
   811   where "rat_of_int \<equiv> of_int"
   812 
   813 
   814 subsection \<open>The Set of Rational Numbers\<close>
   815 
   816 context field_char_0
   817 begin
   818 
   819 definition Rats :: "'a set" ("\<rat>")
   820   where "\<rat> = range of_rat"
   821 
   822 end
   823 
   824 lemma Rats_of_rat [simp]: "of_rat r \<in> \<rat>"
   825   by (simp add: Rats_def)
   826 
   827 lemma Rats_of_int [simp]: "of_int z \<in> \<rat>"
   828   by (subst of_rat_of_int_eq [symmetric]) (rule Rats_of_rat)
   829 
   830 lemma Ints_subset_Rats: "\<int> \<subseteq> \<rat>"
   831   using Ints_cases Rats_of_int by blast
   832 
   833 lemma Rats_of_nat [simp]: "of_nat n \<in> \<rat>"
   834   by (subst of_rat_of_nat_eq [symmetric]) (rule Rats_of_rat)
   835 
   836 lemma Nats_subset_Rats: "\<nat> \<subseteq> \<rat>"
   837   using Ints_subset_Rats Nats_subset_Ints by blast
   838 
   839 lemma Rats_number_of [simp]: "numeral w \<in> \<rat>"
   840   by (subst of_rat_numeral_eq [symmetric]) (rule Rats_of_rat)
   841 
   842 lemma Rats_0 [simp]: "0 \<in> \<rat>"
   843   unfolding Rats_def by (rule range_eqI) (rule of_rat_0 [symmetric])
   844 
   845 lemma Rats_1 [simp]: "1 \<in> \<rat>"
   846   unfolding Rats_def by (rule range_eqI) (rule of_rat_1 [symmetric])
   847 
   848 lemma Rats_add [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a + b \<in> \<rat>"
   849   apply (auto simp add: Rats_def)
   850   apply (rule range_eqI)
   851   apply (rule of_rat_add [symmetric])
   852   done
   853 
   854 lemma Rats_minus [simp]: "a \<in> \<rat> \<Longrightarrow> - a \<in> \<rat>"
   855   apply (auto simp add: Rats_def)
   856   apply (rule range_eqI)
   857   apply (rule of_rat_minus [symmetric])
   858   done
   859 
   860 lemma Rats_diff [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a - b \<in> \<rat>"
   861   apply (auto simp add: Rats_def)
   862   apply (rule range_eqI)
   863   apply (rule of_rat_diff [symmetric])
   864   done
   865 
   866 lemma Rats_mult [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a * b \<in> \<rat>"
   867   apply (auto simp add: Rats_def)
   868   apply (rule range_eqI)
   869   apply (rule of_rat_mult [symmetric])
   870   done
   871 
   872 lemma nonzero_Rats_inverse: "a \<in> \<rat> \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> inverse a \<in> \<rat>"
   873   for a :: "'a::field_char_0"
   874   apply (auto simp add: Rats_def)
   875   apply (rule range_eqI)
   876   apply (erule nonzero_of_rat_inverse [symmetric])
   877   done
   878 
   879 lemma Rats_inverse [simp]: "a \<in> \<rat> \<Longrightarrow> inverse a \<in> \<rat>"
   880   for a :: "'a::{field_char_0,field}"
   881   apply (auto simp add: Rats_def)
   882   apply (rule range_eqI)
   883   apply (rule of_rat_inverse [symmetric])
   884   done
   885 
   886 lemma nonzero_Rats_divide: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a / b \<in> \<rat>"
   887   for a b :: "'a::field_char_0"
   888   apply (auto simp add: Rats_def)
   889   apply (rule range_eqI)
   890   apply (erule nonzero_of_rat_divide [symmetric])
   891   done
   892 
   893 lemma Rats_divide [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a / b \<in> \<rat>"
   894   for a b :: "'a::{field_char_0, field}"
   895   apply (auto simp add: Rats_def)
   896   apply (rule range_eqI)
   897   apply (rule of_rat_divide [symmetric])
   898   done
   899 
   900 lemma Rats_power [simp]: "a \<in> \<rat> \<Longrightarrow> a ^ n \<in> \<rat>"
   901   for a :: "'a::field_char_0"
   902   apply (auto simp add: Rats_def)
   903   apply (rule range_eqI)
   904   apply (rule of_rat_power [symmetric])
   905   done
   906 
   907 lemma Rats_cases [cases set: Rats]:
   908   assumes "q \<in> \<rat>"
   909   obtains (of_rat) r where "q = of_rat r"
   910 proof -
   911   from \<open>q \<in> \<rat>\<close> have "q \<in> range of_rat"
   912     by (simp only: Rats_def)
   913   then obtain r where "q = of_rat r" ..
   914   then show thesis ..
   915 qed
   916 
   917 lemma Rats_induct [case_names of_rat, induct set: Rats]: "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   918   by (rule Rats_cases) auto
   919 
   920 lemma Rats_infinite: "\<not> finite \<rat>"
   921   by (auto dest!: finite_imageD simp: inj_on_def infinite_UNIV_char_0 Rats_def)
   922 
   923 
   924 subsection \<open>Implementation of rational numbers as pairs of integers\<close>
   925 
   926 text \<open>Formal constructor\<close>
   927 
   928 definition Frct :: "int \<times> int \<Rightarrow> rat"
   929   where [simp]: "Frct p = Fract (fst p) (snd p)"
   930 
   931 lemma [code abstype]: "Frct (quotient_of q) = q"
   932   by (cases q) (auto intro: quotient_of_eq)
   933 
   934 
   935 text \<open>Numerals\<close>
   936 
   937 declare quotient_of_Fract [code abstract]
   938 
   939 definition of_int :: "int \<Rightarrow> rat"
   940   where [code_abbrev]: "of_int = Int.of_int"
   941 
   942 hide_const (open) of_int
   943 
   944 lemma quotient_of_int [code abstract]: "quotient_of (Rat.of_int a) = (a, 1)"
   945   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   946 
   947 lemma [code_unfold]: "numeral k = Rat.of_int (numeral k)"
   948   by (simp add: Rat.of_int_def)
   949 
   950 lemma [code_unfold]: "- numeral k = Rat.of_int (- numeral k)"
   951   by (simp add: Rat.of_int_def)
   952 
   953 lemma Frct_code_post [code_post]:
   954   "Frct (0, a) = 0"
   955   "Frct (a, 0) = 0"
   956   "Frct (1, 1) = 1"
   957   "Frct (numeral k, 1) = numeral k"
   958   "Frct (1, numeral k) = 1 / numeral k"
   959   "Frct (numeral k, numeral l) = numeral k / numeral l"
   960   "Frct (- a, b) = - Frct (a, b)"
   961   "Frct (a, - b) = - Frct (a, b)"
   962   "- (- Frct q) = Frct q"
   963   by (simp_all add: Fract_of_int_quotient)
   964 
   965 
   966 text \<open>Operations\<close>
   967 
   968 lemma rat_zero_code [code abstract]: "quotient_of 0 = (0, 1)"
   969   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   970 
   971 lemma rat_one_code [code abstract]: "quotient_of 1 = (1, 1)"
   972   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   973 
   974 lemma rat_plus_code [code abstract]:
   975   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   976      in normalize (a * d + b * c, c * d))"
   977   by (cases p, cases q) (simp add: quotient_of_Fract)
   978 
   979 lemma rat_uminus_code [code abstract]:
   980   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   981   by (cases p) (simp add: quotient_of_Fract)
   982 
   983 lemma rat_minus_code [code abstract]:
   984   "quotient_of (p - q) =
   985     (let (a, c) = quotient_of p; (b, d) = quotient_of q
   986      in normalize (a * d - b * c, c * d))"
   987   by (cases p, cases q) (simp add: quotient_of_Fract)
   988 
   989 lemma rat_times_code [code abstract]:
   990   "quotient_of (p * q) =
   991     (let (a, c) = quotient_of p; (b, d) = quotient_of q
   992      in normalize (a * b, c * d))"
   993   by (cases p, cases q) (simp add: quotient_of_Fract)
   994 
   995 lemma rat_inverse_code [code abstract]:
   996   "quotient_of (inverse p) =
   997     (let (a, b) = quotient_of p
   998      in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
   999 proof (cases p)
  1000   case (Fract a b)
  1001   then show ?thesis
  1002     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd.commute)
  1003 qed
  1004 
  1005 lemma rat_divide_code [code abstract]:
  1006   "quotient_of (p / q) =
  1007     (let (a, c) = quotient_of p; (b, d) = quotient_of q
  1008      in normalize (a * d, c * b))"
  1009   by (cases p, cases q) (simp add: quotient_of_Fract)
  1010 
  1011 lemma rat_abs_code [code abstract]: "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
  1012   by (cases p) (simp add: quotient_of_Fract)
  1013 
  1014 lemma rat_sgn_code [code abstract]: "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
  1015 proof (cases p)
  1016   case (Fract a b)
  1017   then show ?thesis
  1018     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
  1019 qed
  1020 
  1021 lemma rat_floor_code [code]: "\<lfloor>p\<rfloor> = (let (a, b) = quotient_of p in a div b)"
  1022   by (cases p) (simp add: quotient_of_Fract floor_Fract)
  1023 
  1024 instantiation rat :: equal
  1025 begin
  1026 
  1027 definition [code]: "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
  1028 
  1029 instance
  1030   by standard (simp add: equal_rat_def quotient_of_inject_eq)
  1031 
  1032 lemma rat_eq_refl [code nbe]: "HOL.equal (r::rat) r \<longleftrightarrow> True"
  1033   by (rule equal_refl)
  1034 
  1035 end
  1036 
  1037 lemma rat_less_eq_code [code]:
  1038   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1039   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1040 
  1041 lemma rat_less_code [code]:
  1042   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1043   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1044 
  1045 lemma [code]: "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1046   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1047 
  1048 
  1049 text \<open>Quickcheck\<close>
  1050 
  1051 definition (in term_syntax)
  1052   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow>
  1053     int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow>
  1054     rat \<times> (unit \<Rightarrow> Code_Evaluation.term)"
  1055   where [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1056 
  1057 notation fcomp (infixl "\<circ>>" 60)
  1058 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1059 
  1060 instantiation rat :: random
  1061 begin
  1062 
  1063 definition
  1064   "Quickcheck_Random.random i =
  1065     Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair
  1066       (let j = int_of_integer (integer_of_natural (denom + 1))
  1067        in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1068 
  1069 instance ..
  1070 
  1071 end
  1072 
  1073 no_notation fcomp (infixl "\<circ>>" 60)
  1074 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1075 
  1076 instantiation rat :: exhaustive
  1077 begin
  1078 
  1079 definition
  1080   "exhaustive_rat f d =
  1081     Quickcheck_Exhaustive.exhaustive
  1082       (\<lambda>l. Quickcheck_Exhaustive.exhaustive
  1083         (\<lambda>k. f (Fract k (int_of_integer (integer_of_natural l) + 1))) d) d"
  1084 
  1085 instance ..
  1086 
  1087 end
  1088 
  1089 instantiation rat :: full_exhaustive
  1090 begin
  1091 
  1092 definition
  1093   "full_exhaustive_rat f d =
  1094     Quickcheck_Exhaustive.full_exhaustive
  1095       (\<lambda>(l, _). Quickcheck_Exhaustive.full_exhaustive
  1096         (\<lambda>k. f
  1097           (let j = int_of_integer (integer_of_natural l) + 1
  1098            in valterm_fract k (j, \<lambda>_. Code_Evaluation.term_of j))) d) d"
  1099 
  1100 instance ..
  1101 
  1102 end
  1103 
  1104 instance rat :: partial_term_of ..
  1105 
  1106 lemma [code]:
  1107   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) \<equiv>
  1108     Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1109   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) \<equiv>
  1110     Code_Evaluation.App
  1111       (Code_Evaluation.Const (STR ''Rat.Frct'')
  1112         (Typerep.Typerep (STR ''fun'')
  1113           [Typerep.Typerep (STR ''Product_Type.prod'')
  1114            [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1115            Typerep.Typerep (STR ''Rat.rat'') []]))
  1116       (Code_Evaluation.App
  1117         (Code_Evaluation.App
  1118           (Code_Evaluation.Const (STR ''Product_Type.Pair'')
  1119             (Typerep.Typerep (STR ''fun'')
  1120               [Typerep.Typerep (STR ''Int.int'') [],
  1121                Typerep.Typerep (STR ''fun'')
  1122                 [Typerep.Typerep (STR ''Int.int'') [],
  1123                  Typerep.Typerep (STR ''Product_Type.prod'')
  1124                  [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]]))
  1125           (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1126   by (rule partial_term_of_anything)+
  1127 
  1128 instantiation rat :: narrowing
  1129 begin
  1130 
  1131 definition
  1132   "narrowing =
  1133     Quickcheck_Narrowing.apply
  1134       (Quickcheck_Narrowing.apply
  1135         (Quickcheck_Narrowing.cons (\<lambda>nom denom. Fract nom denom)) narrowing) narrowing"
  1136 
  1137 instance ..
  1138 
  1139 end
  1140 
  1141 
  1142 subsection \<open>Setup for Nitpick\<close>
  1143 
  1144 declaration \<open>
  1145   Nitpick_HOL.register_frac_type @{type_name rat}
  1146     [(@{const_name Abs_Rat}, @{const_name Nitpick.Abs_Frac}),
  1147      (@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1148      (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1149      (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1150      (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1151      (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1152      (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1153      (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1154      (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1155      (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1156 \<close>
  1157 
  1158 lemmas [nitpick_unfold] =
  1159   inverse_rat_inst.inverse_rat
  1160   one_rat_inst.one_rat ord_rat_inst.less_rat
  1161   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1162   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1163 
  1164 
  1165 subsection \<open>Float syntax\<close>
  1166 
  1167 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1168 
  1169 parse_translation \<open>
  1170   let
  1171     fun mk_frac str =
  1172       let
  1173         val {mant = i, exp = n} = Lexicon.read_float str;
  1174         val exp = Syntax.const @{const_syntax Power.power};
  1175         val ten = Numeral.mk_number_syntax 10;
  1176         val exp10 = if n = 1 then ten else exp $ ten $ Numeral.mk_number_syntax n;
  1177       in Syntax.const @{const_syntax Fields.inverse_divide} $ Numeral.mk_number_syntax i $ exp10 end;
  1178 
  1179     fun float_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] = c $ float_tr [t] $ u
  1180       | float_tr [t as Const (str, _)] = mk_frac str
  1181       | float_tr ts = raise TERM ("float_tr", ts);
  1182   in [(@{syntax_const "_Float"}, K float_tr)] end
  1183 \<close>
  1184 
  1185 text\<open>Test:\<close>
  1186 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1187   by simp
  1188 
  1189 
  1190 subsection \<open>Hiding implementation details\<close>
  1191 
  1192 hide_const (open) normalize positive
  1193 
  1194 lifting_update rat.lifting
  1195 lifting_forget rat.lifting
  1196 
  1197 end