src/HOL/Divides.thy
author huffman
Sun Mar 25 20:15:39 2012 +0200 (2012-03-25)
changeset 47108 2a1953f0d20d
parent 46560 8e252a608765
child 47134 28c1db43d4d0
permissions -rw-r--r--
merged fork with new numeral representation (see NEWS)
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastforce simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 subclass ring_1_no_zero_divisors ..
   383 
   384 text {* Negation respects modular equivalence. *}
   385 
   386 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   387 proof -
   388   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   389     by (simp only: mod_div_equality)
   390   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   391     by (simp only: minus_add_distrib minus_mult_left add_ac)
   392   also have "\<dots> = (- (a mod b)) mod b"
   393     by (rule mod_mult_self1)
   394   finally show ?thesis .
   395 qed
   396 
   397 lemma mod_minus_cong:
   398   assumes "a mod b = a' mod b"
   399   shows "(- a) mod b = (- a') mod b"
   400 proof -
   401   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   402     unfolding assms ..
   403   thus ?thesis
   404     by (simp only: mod_minus_eq [symmetric])
   405 qed
   406 
   407 text {* Subtraction respects modular equivalence. *}
   408 
   409 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   410   unfolding diff_minus
   411   by (intro mod_add_cong mod_minus_cong) simp_all
   412 
   413 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   414   unfolding diff_minus
   415   by (intro mod_add_cong mod_minus_cong) simp_all
   416 
   417 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   418   unfolding diff_minus
   419   by (intro mod_add_cong mod_minus_cong) simp_all
   420 
   421 lemma mod_diff_cong:
   422   assumes "a mod c = a' mod c"
   423   assumes "b mod c = b' mod c"
   424   shows "(a - b) mod c = (a' - b') mod c"
   425   unfolding diff_minus using assms
   426   by (intro mod_add_cong mod_minus_cong)
   427 
   428 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   429 apply (case_tac "y = 0") apply simp
   430 apply (auto simp add: dvd_def)
   431 apply (subgoal_tac "-(y * k) = y * - k")
   432  apply (erule ssubst)
   433  apply (erule div_mult_self1_is_id)
   434 apply simp
   435 done
   436 
   437 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   438 apply (case_tac "y = 0") apply simp
   439 apply (auto simp add: dvd_def)
   440 apply (subgoal_tac "y * k = -y * -k")
   441  apply (erule ssubst)
   442  apply (rule div_mult_self1_is_id)
   443  apply simp
   444 apply simp
   445 done
   446 
   447 end
   448 
   449 
   450 subsection {* Division on @{typ nat} *}
   451 
   452 text {*
   453   We define @{const div} and @{const mod} on @{typ nat} by means
   454   of a characteristic relation with two input arguments
   455   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   456   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   457 *}
   458 
   459 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   460   "divmod_nat_rel m n qr \<longleftrightarrow>
   461     m = fst qr * n + snd qr \<and>
   462       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   463 
   464 text {* @{const divmod_nat_rel} is total: *}
   465 
   466 lemma divmod_nat_rel_ex:
   467   obtains q r where "divmod_nat_rel m n (q, r)"
   468 proof (cases "n = 0")
   469   case True  with that show thesis
   470     by (auto simp add: divmod_nat_rel_def)
   471 next
   472   case False
   473   have "\<exists>q r. m = q * n + r \<and> r < n"
   474   proof (induct m)
   475     case 0 with `n \<noteq> 0`
   476     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   477     then show ?case by blast
   478   next
   479     case (Suc m) then obtain q' r'
   480       where m: "m = q' * n + r'" and n: "r' < n" by auto
   481     then show ?case proof (cases "Suc r' < n")
   482       case True
   483       from m n have "Suc m = q' * n + Suc r'" by simp
   484       with True show ?thesis by blast
   485     next
   486       case False then have "n \<le> Suc r'" by auto
   487       moreover from n have "Suc r' \<le> n" by auto
   488       ultimately have "n = Suc r'" by auto
   489       with m have "Suc m = Suc q' * n + 0" by simp
   490       with `n \<noteq> 0` show ?thesis by blast
   491     qed
   492   qed
   493   with that show thesis
   494     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   495 qed
   496 
   497 text {* @{const divmod_nat_rel} is injective: *}
   498 
   499 lemma divmod_nat_rel_unique:
   500   assumes "divmod_nat_rel m n qr"
   501     and "divmod_nat_rel m n qr'"
   502   shows "qr = qr'"
   503 proof (cases "n = 0")
   504   case True with assms show ?thesis
   505     by (cases qr, cases qr')
   506       (simp add: divmod_nat_rel_def)
   507 next
   508   case False
   509   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   510   apply (rule leI)
   511   apply (subst less_iff_Suc_add)
   512   apply (auto simp add: add_mult_distrib)
   513   done
   514   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   515     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   516   moreover from this assms have "snd qr = snd qr'"
   517     by (simp add: divmod_nat_rel_def)
   518   ultimately show ?thesis by (cases qr, cases qr') simp
   519 qed
   520 
   521 text {*
   522   We instantiate divisibility on the natural numbers by
   523   means of @{const divmod_nat_rel}:
   524 *}
   525 
   526 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   527   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   528 
   529 lemma divmod_nat_rel_divmod_nat:
   530   "divmod_nat_rel m n (divmod_nat m n)"
   531 proof -
   532   from divmod_nat_rel_ex
   533     obtain qr where rel: "divmod_nat_rel m n qr" .
   534   then show ?thesis
   535   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   536 qed
   537 
   538 lemma divmod_nat_eq:
   539   assumes "divmod_nat_rel m n qr" 
   540   shows "divmod_nat m n = qr"
   541   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   542 
   543 instantiation nat :: semiring_div
   544 begin
   545 
   546 definition div_nat where
   547   "m div n = fst (divmod_nat m n)"
   548 
   549 lemma fst_divmod_nat [simp]:
   550   "fst (divmod_nat m n) = m div n"
   551   by (simp add: div_nat_def)
   552 
   553 definition mod_nat where
   554   "m mod n = snd (divmod_nat m n)"
   555 
   556 lemma snd_divmod_nat [simp]:
   557   "snd (divmod_nat m n) = m mod n"
   558   by (simp add: mod_nat_def)
   559 
   560 lemma divmod_nat_div_mod:
   561   "divmod_nat m n = (m div n, m mod n)"
   562   by (simp add: prod_eq_iff)
   563 
   564 lemma div_eq:
   565   assumes "divmod_nat_rel m n (q, r)" 
   566   shows "m div n = q"
   567   using assms by (auto dest!: divmod_nat_eq simp add: prod_eq_iff)
   568 
   569 lemma mod_eq:
   570   assumes "divmod_nat_rel m n (q, r)" 
   571   shows "m mod n = r"
   572   using assms by (auto dest!: divmod_nat_eq simp add: prod_eq_iff)
   573 
   574 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   575   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   576 
   577 lemma divmod_nat_zero:
   578   "divmod_nat m 0 = (0, m)"
   579 proof -
   580   from divmod_nat_rel [of m 0] show ?thesis
   581     unfolding divmod_nat_div_mod divmod_nat_rel_def by simp
   582 qed
   583 
   584 lemma divmod_nat_base:
   585   assumes "m < n"
   586   shows "divmod_nat m n = (0, m)"
   587 proof -
   588   from divmod_nat_rel [of m n] show ?thesis
   589     unfolding divmod_nat_div_mod divmod_nat_rel_def
   590     using assms by (cases "m div n = 0")
   591       (auto simp add: gr0_conv_Suc [of "m div n"])
   592 qed
   593 
   594 lemma divmod_nat_step:
   595   assumes "0 < n" and "n \<le> m"
   596   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   597 proof -
   598   from divmod_nat_rel have divmod_nat_m_n: "divmod_nat_rel m n (m div n, m mod n)" .
   599   with assms have m_div_n: "m div n \<ge> 1"
   600     by (cases "m div n") (auto simp add: divmod_nat_rel_def)
   601   have "divmod_nat_rel (m - n) n (m div n - Suc 0, m mod n)"
   602   proof -
   603     from assms have
   604       "n \<noteq> 0"
   605       "\<And>k. m = Suc k * n + m mod n ==> m - n = (Suc k - Suc 0) * n + m mod n"
   606       by simp_all
   607     then show ?thesis using assms divmod_nat_m_n 
   608       by (cases "m div n")
   609          (simp_all only: divmod_nat_rel_def fst_conv snd_conv, simp_all)
   610   qed
   611   with divmod_nat_eq have "divmod_nat (m - n) n = (m div n - Suc 0, m mod n)" by simp
   612   moreover from divmod_nat_div_mod have "divmod_nat (m - n) n = ((m - n) div n, (m - n) mod n)" .
   613   ultimately have "m div n = Suc ((m - n) div n)"
   614     and "m mod n = (m - n) mod n" using m_div_n by simp_all
   615   then show ?thesis using divmod_nat_div_mod by simp
   616 qed
   617 
   618 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   619 
   620 lemma div_less [simp]:
   621   fixes m n :: nat
   622   assumes "m < n"
   623   shows "m div n = 0"
   624   using assms divmod_nat_base by (simp add: prod_eq_iff)
   625 
   626 lemma le_div_geq:
   627   fixes m n :: nat
   628   assumes "0 < n" and "n \<le> m"
   629   shows "m div n = Suc ((m - n) div n)"
   630   using assms divmod_nat_step by (simp add: prod_eq_iff)
   631 
   632 lemma mod_less [simp]:
   633   fixes m n :: nat
   634   assumes "m < n"
   635   shows "m mod n = m"
   636   using assms divmod_nat_base by (simp add: prod_eq_iff)
   637 
   638 lemma le_mod_geq:
   639   fixes m n :: nat
   640   assumes "n \<le> m"
   641   shows "m mod n = (m - n) mod n"
   642   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   643 
   644 instance proof -
   645   have [simp]: "\<And>n::nat. n div 0 = 0"
   646     by (simp add: div_nat_def divmod_nat_zero)
   647   have [simp]: "\<And>n::nat. 0 div n = 0"
   648   proof -
   649     fix n :: nat
   650     show "0 div n = 0"
   651       by (cases "n = 0") simp_all
   652   qed
   653   show "OFCLASS(nat, semiring_div_class)" proof
   654     fix m n :: nat
   655     show "m div n * n + m mod n = m"
   656       using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   657   next
   658     fix m n q :: nat
   659     assume "n \<noteq> 0"
   660     then show "(q + m * n) div n = m + q div n"
   661       by (induct m) (simp_all add: le_div_geq)
   662   next
   663     fix m n q :: nat
   664     assume "m \<noteq> 0"
   665     then show "(m * n) div (m * q) = n div q"
   666     proof (cases "n \<noteq> 0 \<and> q \<noteq> 0")
   667       case False then show ?thesis by auto
   668     next
   669       case True with `m \<noteq> 0`
   670         have "m > 0" and "n > 0" and "q > 0" by auto
   671       then have "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   672         by (auto simp add: divmod_nat_rel_def) (simp_all add: algebra_simps)
   673       moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   674       ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   675       then show ?thesis by (simp add: div_eq)
   676     qed
   677   qed simp_all
   678 qed
   679 
   680 end
   681 
   682 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   683   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   684   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   685 
   686 text {* Simproc for cancelling @{const div} and @{const mod} *}
   687 
   688 ML {*
   689 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   690 (
   691   val div_name = @{const_name div};
   692   val mod_name = @{const_name mod};
   693   val mk_binop = HOLogic.mk_binop;
   694   val mk_sum = Nat_Arith.mk_sum;
   695   val dest_sum = Nat_Arith.dest_sum;
   696 
   697   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   698 
   699   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   700     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   701 )
   702 *}
   703 
   704 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   705 
   706 
   707 subsubsection {* Quotient *}
   708 
   709 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   710 by (simp add: le_div_geq linorder_not_less)
   711 
   712 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   713 by (simp add: div_geq)
   714 
   715 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   716 by simp
   717 
   718 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   719 by simp
   720 
   721 
   722 subsubsection {* Remainder *}
   723 
   724 lemma mod_less_divisor [simp]:
   725   fixes m n :: nat
   726   assumes "n > 0"
   727   shows "m mod n < (n::nat)"
   728   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   729 
   730 lemma mod_less_eq_dividend [simp]:
   731   fixes m n :: nat
   732   shows "m mod n \<le> m"
   733 proof (rule add_leD2)
   734   from mod_div_equality have "m div n * n + m mod n = m" .
   735   then show "m div n * n + m mod n \<le> m" by auto
   736 qed
   737 
   738 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   739 by (simp add: le_mod_geq linorder_not_less)
   740 
   741 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   742 by (simp add: le_mod_geq)
   743 
   744 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   745 by (induct m) (simp_all add: mod_geq)
   746 
   747 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   748   apply (cases "n = 0", simp)
   749   apply (cases "k = 0", simp)
   750   apply (induct m rule: nat_less_induct)
   751   apply (subst mod_if, simp)
   752   apply (simp add: mod_geq diff_mult_distrib)
   753   done
   754 
   755 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   756 by (simp add: mult_commute [of k] mod_mult_distrib)
   757 
   758 (* a simple rearrangement of mod_div_equality: *)
   759 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   760 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   761 
   762 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   763   apply (drule mod_less_divisor [where m = m])
   764   apply simp
   765   done
   766 
   767 subsubsection {* Quotient and Remainder *}
   768 
   769 lemma divmod_nat_rel_mult1_eq:
   770   "divmod_nat_rel b c (q, r)
   771    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   772 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   773 
   774 lemma div_mult1_eq:
   775   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   776 by (blast intro: divmod_nat_rel [THEN divmod_nat_rel_mult1_eq, THEN div_eq])
   777 
   778 lemma divmod_nat_rel_add1_eq:
   779   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   780    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   781 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   782 
   783 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   784 lemma div_add1_eq:
   785   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   786 by (blast intro: divmod_nat_rel_add1_eq [THEN div_eq] divmod_nat_rel)
   787 
   788 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   789   apply (cut_tac m = q and n = c in mod_less_divisor)
   790   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   791   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   792   apply (simp add: add_mult_distrib2)
   793   done
   794 
   795 lemma divmod_nat_rel_mult2_eq:
   796   "divmod_nat_rel a b (q, r)
   797    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   798 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   799 
   800 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   801 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_eq])
   802 
   803 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   804 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_eq])
   805 
   806 
   807 subsubsection {* Further Facts about Quotient and Remainder *}
   808 
   809 lemma div_1 [simp]: "m div Suc 0 = m"
   810 by (induct m) (simp_all add: div_geq)
   811 
   812 (* Monotonicity of div in first argument *)
   813 lemma div_le_mono [rule_format (no_asm)]:
   814     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   815 apply (case_tac "k=0", simp)
   816 apply (induct "n" rule: nat_less_induct, clarify)
   817 apply (case_tac "n<k")
   818 (* 1  case n<k *)
   819 apply simp
   820 (* 2  case n >= k *)
   821 apply (case_tac "m<k")
   822 (* 2.1  case m<k *)
   823 apply simp
   824 (* 2.2  case m>=k *)
   825 apply (simp add: div_geq diff_le_mono)
   826 done
   827 
   828 (* Antimonotonicity of div in second argument *)
   829 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   830 apply (subgoal_tac "0<n")
   831  prefer 2 apply simp
   832 apply (induct_tac k rule: nat_less_induct)
   833 apply (rename_tac "k")
   834 apply (case_tac "k<n", simp)
   835 apply (subgoal_tac "~ (k<m) ")
   836  prefer 2 apply simp
   837 apply (simp add: div_geq)
   838 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   839  prefer 2
   840  apply (blast intro: div_le_mono diff_le_mono2)
   841 apply (rule le_trans, simp)
   842 apply (simp)
   843 done
   844 
   845 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   846 apply (case_tac "n=0", simp)
   847 apply (subgoal_tac "m div n \<le> m div 1", simp)
   848 apply (rule div_le_mono2)
   849 apply (simp_all (no_asm_simp))
   850 done
   851 
   852 (* Similar for "less than" *)
   853 lemma div_less_dividend [rule_format]:
   854      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   855 apply (induct_tac m rule: nat_less_induct)
   856 apply (rename_tac "m")
   857 apply (case_tac "m<n", simp)
   858 apply (subgoal_tac "0<n")
   859  prefer 2 apply simp
   860 apply (simp add: div_geq)
   861 apply (case_tac "n<m")
   862  apply (subgoal_tac "(m-n) div n < (m-n) ")
   863   apply (rule impI less_trans_Suc)+
   864 apply assumption
   865   apply (simp_all)
   866 done
   867 
   868 declare div_less_dividend [simp]
   869 
   870 text{*A fact for the mutilated chess board*}
   871 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   872 apply (case_tac "n=0", simp)
   873 apply (induct "m" rule: nat_less_induct)
   874 apply (case_tac "Suc (na) <n")
   875 (* case Suc(na) < n *)
   876 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   877 (* case n \<le> Suc(na) *)
   878 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   879 apply (auto simp add: Suc_diff_le le_mod_geq)
   880 done
   881 
   882 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   883 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   884 
   885 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   886 
   887 (*Loses information, namely we also have r<d provided d is nonzero*)
   888 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   889   apply (cut_tac a = m in mod_div_equality)
   890   apply (simp only: add_ac)
   891   apply (blast intro: sym)
   892   done
   893 
   894 lemma split_div:
   895  "P(n div k :: nat) =
   896  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   897  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   898 proof
   899   assume P: ?P
   900   show ?Q
   901   proof (cases)
   902     assume "k = 0"
   903     with P show ?Q by simp
   904   next
   905     assume not0: "k \<noteq> 0"
   906     thus ?Q
   907     proof (simp, intro allI impI)
   908       fix i j
   909       assume n: "n = k*i + j" and j: "j < k"
   910       show "P i"
   911       proof (cases)
   912         assume "i = 0"
   913         with n j P show "P i" by simp
   914       next
   915         assume "i \<noteq> 0"
   916         with not0 n j P show "P i" by(simp add:add_ac)
   917       qed
   918     qed
   919   qed
   920 next
   921   assume Q: ?Q
   922   show ?P
   923   proof (cases)
   924     assume "k = 0"
   925     with Q show ?P by simp
   926   next
   927     assume not0: "k \<noteq> 0"
   928     with Q have R: ?R by simp
   929     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   930     show ?P by simp
   931   qed
   932 qed
   933 
   934 lemma split_div_lemma:
   935   assumes "0 < n"
   936   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   937 proof
   938   assume ?rhs
   939   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   940   then have A: "n * q \<le> m" by simp
   941   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   942   then have "m < m + (n - (m mod n))" by simp
   943   then have "m < n + (m - (m mod n))" by simp
   944   with nq have "m < n + n * q" by simp
   945   then have B: "m < n * Suc q" by simp
   946   from A B show ?lhs ..
   947 next
   948   assume P: ?lhs
   949   then have "divmod_nat_rel m n (q, m - n * q)"
   950     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   951   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   952   have "(q, m - n * q) = (m div n, m mod n)" by auto
   953   then show ?rhs by simp
   954 qed
   955 
   956 theorem split_div':
   957   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   958    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   959   apply (case_tac "0 < n")
   960   apply (simp only: add: split_div_lemma)
   961   apply simp_all
   962   done
   963 
   964 lemma split_mod:
   965  "P(n mod k :: nat) =
   966  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   967  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   968 proof
   969   assume P: ?P
   970   show ?Q
   971   proof (cases)
   972     assume "k = 0"
   973     with P show ?Q by simp
   974   next
   975     assume not0: "k \<noteq> 0"
   976     thus ?Q
   977     proof (simp, intro allI impI)
   978       fix i j
   979       assume "n = k*i + j" "j < k"
   980       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   981     qed
   982   qed
   983 next
   984   assume Q: ?Q
   985   show ?P
   986   proof (cases)
   987     assume "k = 0"
   988     with Q show ?P by simp
   989   next
   990     assume not0: "k \<noteq> 0"
   991     with Q have R: ?R by simp
   992     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   993     show ?P by simp
   994   qed
   995 qed
   996 
   997 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   998   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
   999     subst [OF mod_div_equality [of _ n]])
  1000   apply arith
  1001   done
  1002 
  1003 lemma div_mod_equality':
  1004   fixes m n :: nat
  1005   shows "m div n * n = m - m mod n"
  1006 proof -
  1007   have "m mod n \<le> m mod n" ..
  1008   from div_mod_equality have 
  1009     "m div n * n + m mod n - m mod n = m - m mod n" by simp
  1010   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
  1011     "m div n * n + (m mod n - m mod n) = m - m mod n"
  1012     by simp
  1013   then show ?thesis by simp
  1014 qed
  1015 
  1016 
  1017 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1018 
  1019 lemma mod_induct_0:
  1020   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1021   and base: "P i" and i: "i<p"
  1022   shows "P 0"
  1023 proof (rule ccontr)
  1024   assume contra: "\<not>(P 0)"
  1025   from i have p: "0<p" by simp
  1026   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1027   proof
  1028     fix k
  1029     show "?A k"
  1030     proof (induct k)
  1031       show "?A 0" by simp  -- "by contradiction"
  1032     next
  1033       fix n
  1034       assume ih: "?A n"
  1035       show "?A (Suc n)"
  1036       proof (clarsimp)
  1037         assume y: "P (p - Suc n)"
  1038         have n: "Suc n < p"
  1039         proof (rule ccontr)
  1040           assume "\<not>(Suc n < p)"
  1041           hence "p - Suc n = 0"
  1042             by simp
  1043           with y contra show "False"
  1044             by simp
  1045         qed
  1046         hence n2: "Suc (p - Suc n) = p-n" by arith
  1047         from p have "p - Suc n < p" by arith
  1048         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1049           by blast
  1050         show "False"
  1051         proof (cases "n=0")
  1052           case True
  1053           with z n2 contra show ?thesis by simp
  1054         next
  1055           case False
  1056           with p have "p-n < p" by arith
  1057           with z n2 False ih show ?thesis by simp
  1058         qed
  1059       qed
  1060     qed
  1061   qed
  1062   moreover
  1063   from i obtain k where "0<k \<and> i+k=p"
  1064     by (blast dest: less_imp_add_positive)
  1065   hence "0<k \<and> i=p-k" by auto
  1066   moreover
  1067   note base
  1068   ultimately
  1069   show "False" by blast
  1070 qed
  1071 
  1072 lemma mod_induct:
  1073   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1074   and base: "P i" and i: "i<p" and j: "j<p"
  1075   shows "P j"
  1076 proof -
  1077   have "\<forall>j<p. P j"
  1078   proof
  1079     fix j
  1080     show "j<p \<longrightarrow> P j" (is "?A j")
  1081     proof (induct j)
  1082       from step base i show "?A 0"
  1083         by (auto elim: mod_induct_0)
  1084     next
  1085       fix k
  1086       assume ih: "?A k"
  1087       show "?A (Suc k)"
  1088       proof
  1089         assume suc: "Suc k < p"
  1090         hence k: "k<p" by simp
  1091         with ih have "P k" ..
  1092         with step k have "P (Suc k mod p)"
  1093           by blast
  1094         moreover
  1095         from suc have "Suc k mod p = Suc k"
  1096           by simp
  1097         ultimately
  1098         show "P (Suc k)" by simp
  1099       qed
  1100     qed
  1101   qed
  1102   with j show ?thesis by blast
  1103 qed
  1104 
  1105 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1106 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1107 
  1108 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1109 by (simp add: nat_mult_2 [symmetric])
  1110 
  1111 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1112 apply (subgoal_tac "m mod 2 < 2")
  1113 apply (erule less_2_cases [THEN disjE])
  1114 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1115 done
  1116 
  1117 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1118 proof -
  1119   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1120   moreover have "m mod 2 < 2" by simp
  1121   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1122   then show ?thesis by auto
  1123 qed
  1124 
  1125 text{*These lemmas collapse some needless occurrences of Suc:
  1126     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1127     We already have some rules to simplify operands smaller than 3.*}
  1128 
  1129 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1130 by (simp add: Suc3_eq_add_3)
  1131 
  1132 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1133 by (simp add: Suc3_eq_add_3)
  1134 
  1135 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1136 by (simp add: Suc3_eq_add_3)
  1137 
  1138 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1139 by (simp add: Suc3_eq_add_3)
  1140 
  1141 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1142 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1143 
  1144 
  1145 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1146 apply (induct "m")
  1147 apply (simp_all add: mod_Suc)
  1148 done
  1149 
  1150 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1151 
  1152 lemma [simp]: "n div k \<le> (Suc n) div k"
  1153 by (simp add: div_le_mono) 
  1154 
  1155 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1156 by (cases n) simp_all
  1157 
  1158 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1159 proof -
  1160   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1161   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1162 qed
  1163 
  1164   (* Potential use of algebra : Equality modulo n*)
  1165 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1166 by (simp add: mult_ac add_ac)
  1167 
  1168 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1169 proof -
  1170   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1171   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1172   finally show ?thesis .
  1173 qed
  1174 
  1175 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1176 apply (subst mod_Suc [of m]) 
  1177 apply (subst mod_Suc [of "m mod n"], simp) 
  1178 done
  1179 
  1180 lemma mod_2_not_eq_zero_eq_one_nat:
  1181   fixes n :: nat
  1182   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1183   by simp
  1184 
  1185 
  1186 subsection {* Division on @{typ int} *}
  1187 
  1188 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1189     --{*definition of quotient and remainder*}
  1190     "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1191                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1192 
  1193 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1194     --{*for the division algorithm*}
  1195     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1196                          else (2 * q, r))"
  1197 
  1198 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1199 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1200   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1201      else adjust b (posDivAlg a (2 * b)))"
  1202 by auto
  1203 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1204   (auto simp add: mult_2)
  1205 
  1206 text{*algorithm for the case @{text "a<0, b>0"}*}
  1207 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1208   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1209      else adjust b (negDivAlg a (2 * b)))"
  1210 by auto
  1211 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1212   (auto simp add: mult_2)
  1213 
  1214 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1215 
  1216 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1217     --{*The full division algorithm considers all possible signs for a, b
  1218        including the special case @{text "a=0, b<0"} because 
  1219        @{term negDivAlg} requires @{term "a<0"}.*}
  1220   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1221                   else if a = 0 then (0, 0)
  1222                        else apsnd uminus (negDivAlg (-a) (-b))
  1223                else 
  1224                   if 0 < b then negDivAlg a b
  1225                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1226 
  1227 instantiation int :: Divides.div
  1228 begin
  1229 
  1230 definition div_int where
  1231   "a div b = fst (divmod_int a b)"
  1232 
  1233 lemma fst_divmod_int [simp]:
  1234   "fst (divmod_int a b) = a div b"
  1235   by (simp add: div_int_def)
  1236 
  1237 definition mod_int where
  1238   "a mod b = snd (divmod_int a b)"
  1239 
  1240 lemma snd_divmod_int [simp]:
  1241   "snd (divmod_int a b) = a mod b"
  1242   by (simp add: mod_int_def)
  1243 
  1244 instance ..
  1245 
  1246 end
  1247 
  1248 lemma divmod_int_mod_div:
  1249   "divmod_int p q = (p div q, p mod q)"
  1250   by (simp add: prod_eq_iff)
  1251 
  1252 text{*
  1253 Here is the division algorithm in ML:
  1254 
  1255 \begin{verbatim}
  1256     fun posDivAlg (a,b) =
  1257       if a<b then (0,a)
  1258       else let val (q,r) = posDivAlg(a, 2*b)
  1259                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1260            end
  1261 
  1262     fun negDivAlg (a,b) =
  1263       if 0\<le>a+b then (~1,a+b)
  1264       else let val (q,r) = negDivAlg(a, 2*b)
  1265                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1266            end;
  1267 
  1268     fun negateSnd (q,r:int) = (q,~r);
  1269 
  1270     fun divmod (a,b) = if 0\<le>a then 
  1271                           if b>0 then posDivAlg (a,b) 
  1272                            else if a=0 then (0,0)
  1273                                 else negateSnd (negDivAlg (~a,~b))
  1274                        else 
  1275                           if 0<b then negDivAlg (a,b)
  1276                           else        negateSnd (posDivAlg (~a,~b));
  1277 \end{verbatim}
  1278 *}
  1279 
  1280 
  1281 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1282 
  1283 lemma unique_quotient_lemma:
  1284      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1285       ==> q' \<le> (q::int)"
  1286 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1287  prefer 2 apply (simp add: right_diff_distrib)
  1288 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1289 apply (erule_tac [2] order_le_less_trans)
  1290  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1291 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1292  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1293 apply (simp add: mult_less_cancel_left)
  1294 done
  1295 
  1296 lemma unique_quotient_lemma_neg:
  1297      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1298       ==> q \<le> (q'::int)"
  1299 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1300     auto)
  1301 
  1302 lemma unique_quotient:
  1303      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1304       ==> q = q'"
  1305 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1306 apply (blast intro: order_antisym
  1307              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1308              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1309 done
  1310 
  1311 
  1312 lemma unique_remainder:
  1313      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1314       ==> r = r'"
  1315 apply (subgoal_tac "q = q'")
  1316  apply (simp add: divmod_int_rel_def)
  1317 apply (blast intro: unique_quotient)
  1318 done
  1319 
  1320 
  1321 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1322 
  1323 text{*And positive divisors*}
  1324 
  1325 lemma adjust_eq [simp]:
  1326      "adjust b (q, r) = 
  1327       (let diff = r - b in  
  1328         if 0 \<le> diff then (2 * q + 1, diff)   
  1329                      else (2*q, r))"
  1330   by (simp add: Let_def adjust_def)
  1331 
  1332 declare posDivAlg.simps [simp del]
  1333 
  1334 text{*use with a simproc to avoid repeatedly proving the premise*}
  1335 lemma posDivAlg_eqn:
  1336      "0 < b ==>  
  1337       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1338 by (rule posDivAlg.simps [THEN trans], simp)
  1339 
  1340 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1341 theorem posDivAlg_correct:
  1342   assumes "0 \<le> a" and "0 < b"
  1343   shows "divmod_int_rel a b (posDivAlg a b)"
  1344   using assms
  1345   apply (induct a b rule: posDivAlg.induct)
  1346   apply auto
  1347   apply (simp add: divmod_int_rel_def)
  1348   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1349   apply (case_tac "a < b")
  1350   apply simp_all
  1351   apply (erule splitE)
  1352   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1353   done
  1354 
  1355 
  1356 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1357 
  1358 text{*And positive divisors*}
  1359 
  1360 declare negDivAlg.simps [simp del]
  1361 
  1362 text{*use with a simproc to avoid repeatedly proving the premise*}
  1363 lemma negDivAlg_eqn:
  1364      "0 < b ==>  
  1365       negDivAlg a b =       
  1366        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1367 by (rule negDivAlg.simps [THEN trans], simp)
  1368 
  1369 (*Correctness of negDivAlg: it computes quotients correctly
  1370   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1371 lemma negDivAlg_correct:
  1372   assumes "a < 0" and "b > 0"
  1373   shows "divmod_int_rel a b (negDivAlg a b)"
  1374   using assms
  1375   apply (induct a b rule: negDivAlg.induct)
  1376   apply (auto simp add: linorder_not_le)
  1377   apply (simp add: divmod_int_rel_def)
  1378   apply (subst negDivAlg_eqn, assumption)
  1379   apply (case_tac "a + b < (0\<Colon>int)")
  1380   apply simp_all
  1381   apply (erule splitE)
  1382   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1383   done
  1384 
  1385 
  1386 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1387 
  1388 (*the case a=0*)
  1389 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1390 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1391 
  1392 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1393 by (subst posDivAlg.simps, auto)
  1394 
  1395 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1396 by (subst negDivAlg.simps, auto)
  1397 
  1398 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1399 by (auto simp add: split_ifs divmod_int_rel_def)
  1400 
  1401 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1402 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1403                     posDivAlg_correct negDivAlg_correct)
  1404 
  1405 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1406     certain equations.*}
  1407 
  1408 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1409 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1410 
  1411 
  1412 text{*Basic laws about division and remainder*}
  1413 
  1414 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1415 apply (case_tac "b = 0", simp)
  1416 apply (cut_tac a = a and b = b in divmod_int_correct)
  1417 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1418 done
  1419 
  1420 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1421 by(simp add: zmod_zdiv_equality[symmetric])
  1422 
  1423 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1424 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1425 
  1426 text {* Tool setup *}
  1427 
  1428 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1429 lemmas add_0s = add_0_left add_0_right
  1430 
  1431 ML {*
  1432 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1433 (
  1434   val div_name = @{const_name div};
  1435   val mod_name = @{const_name mod};
  1436   val mk_binop = HOLogic.mk_binop;
  1437   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1438   val dest_sum = Arith_Data.dest_sum;
  1439 
  1440   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1441 
  1442   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1443     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1444 )
  1445 *}
  1446 
  1447 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1448 
  1449 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1450 apply (cut_tac a = a and b = b in divmod_int_correct)
  1451 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1452 done
  1453 
  1454 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1455    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1456 
  1457 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1458 apply (cut_tac a = a and b = b in divmod_int_correct)
  1459 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1460 done
  1461 
  1462 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1463    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1464 
  1465 
  1466 subsubsection {* General Properties of div and mod *}
  1467 
  1468 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1469 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1470 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1471 done
  1472 
  1473 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r) |] ==> a div b = q"
  1474 apply (cases "b = 0")
  1475 apply (simp add: divmod_int_rel_def)
  1476 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1477 
  1478 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r) |] ==> a mod b = r"
  1479 apply (cases "b = 0")
  1480 apply (simp add: divmod_int_rel_def)
  1481 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1482 
  1483 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1484 apply (rule divmod_int_rel_div)
  1485 apply (auto simp add: divmod_int_rel_def)
  1486 done
  1487 
  1488 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1489 apply (rule divmod_int_rel_div)
  1490 apply (auto simp add: divmod_int_rel_def)
  1491 done
  1492 
  1493 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1494 apply (rule divmod_int_rel_div)
  1495 apply (auto simp add: divmod_int_rel_def)
  1496 done
  1497 
  1498 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1499 
  1500 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1501 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1502 apply (auto simp add: divmod_int_rel_def)
  1503 done
  1504 
  1505 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1506 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1507 apply (auto simp add: divmod_int_rel_def)
  1508 done
  1509 
  1510 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1511 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1512 apply (auto simp add: divmod_int_rel_def)
  1513 done
  1514 
  1515 text{*There is no @{text mod_neg_pos_trivial}.*}
  1516 
  1517 
  1518 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1519 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1520 apply (case_tac "b = 0", simp)
  1521 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1522                                  THEN divmod_int_rel_div, THEN sym])
  1523 
  1524 done
  1525 
  1526 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1527 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1528 apply (case_tac "b = 0", simp)
  1529 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1530        auto)
  1531 done
  1532 
  1533 
  1534 subsubsection {* Laws for div and mod with Unary Minus *}
  1535 
  1536 lemma zminus1_lemma:
  1537      "divmod_int_rel a b (q, r)
  1538       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1539                           if r=0 then 0 else b-r)"
  1540 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1541 
  1542 
  1543 lemma zdiv_zminus1_eq_if:
  1544      "b \<noteq> (0::int)  
  1545       ==> (-a) div b =  
  1546           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1547 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1548 
  1549 lemma zmod_zminus1_eq_if:
  1550      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1551 apply (case_tac "b = 0", simp)
  1552 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1553 done
  1554 
  1555 lemma zmod_zminus1_not_zero:
  1556   fixes k l :: int
  1557   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1558   unfolding zmod_zminus1_eq_if by auto
  1559 
  1560 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1561 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1562 
  1563 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1564 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1565 
  1566 lemma zdiv_zminus2_eq_if:
  1567      "b \<noteq> (0::int)  
  1568       ==> a div (-b) =  
  1569           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1570 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1571 
  1572 lemma zmod_zminus2_eq_if:
  1573      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1574 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1575 
  1576 lemma zmod_zminus2_not_zero:
  1577   fixes k l :: int
  1578   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1579   unfolding zmod_zminus2_eq_if by auto 
  1580 
  1581 
  1582 subsubsection {* Division of a Number by Itself *}
  1583 
  1584 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1585 apply (subgoal_tac "0 < a*q")
  1586  apply (simp add: zero_less_mult_iff, arith)
  1587 done
  1588 
  1589 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1590 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1591  apply (simp add: zero_le_mult_iff)
  1592 apply (simp add: right_diff_distrib)
  1593 done
  1594 
  1595 lemma self_quotient: "[| divmod_int_rel a a (q, r) |] ==> q = 1"
  1596 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1597 apply (rule order_antisym, safe, simp_all)
  1598 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1599 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1600 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1601 done
  1602 
  1603 lemma self_remainder: "[| divmod_int_rel a a (q, r) |] ==> r = 0"
  1604 apply (frule self_quotient)
  1605 apply (simp add: divmod_int_rel_def)
  1606 done
  1607 
  1608 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1609 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1610 
  1611 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1612 lemma zmod_self [simp]: "a mod a = (0::int)"
  1613 apply (case_tac "a = 0", simp)
  1614 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1615 done
  1616 
  1617 
  1618 subsubsection {* Computation of Division and Remainder *}
  1619 
  1620 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1621 by (simp add: div_int_def divmod_int_def)
  1622 
  1623 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1624 by (simp add: div_int_def divmod_int_def)
  1625 
  1626 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1627 by (simp add: mod_int_def divmod_int_def)
  1628 
  1629 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1630 by (simp add: mod_int_def divmod_int_def)
  1631 
  1632 text{*a positive, b positive *}
  1633 
  1634 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1635 by (simp add: div_int_def divmod_int_def)
  1636 
  1637 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1638 by (simp add: mod_int_def divmod_int_def)
  1639 
  1640 text{*a negative, b positive *}
  1641 
  1642 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1643 by (simp add: div_int_def divmod_int_def)
  1644 
  1645 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1646 by (simp add: mod_int_def divmod_int_def)
  1647 
  1648 text{*a positive, b negative *}
  1649 
  1650 lemma div_pos_neg:
  1651      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1652 by (simp add: div_int_def divmod_int_def)
  1653 
  1654 lemma mod_pos_neg:
  1655      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1656 by (simp add: mod_int_def divmod_int_def)
  1657 
  1658 text{*a negative, b negative *}
  1659 
  1660 lemma div_neg_neg:
  1661      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1662 by (simp add: div_int_def divmod_int_def)
  1663 
  1664 lemma mod_neg_neg:
  1665      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1666 by (simp add: mod_int_def divmod_int_def)
  1667 
  1668 text {*Simplify expresions in which div and mod combine numerical constants*}
  1669 
  1670 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1671   by (rule divmod_int_rel_div [of a b q r]) (simp add: divmod_int_rel_def)
  1672 
  1673 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1674   by (rule divmod_int_rel_div [of a b q r],
  1675     simp add: divmod_int_rel_def)
  1676 
  1677 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1678   by (rule divmod_int_rel_mod [of a b q r],
  1679     simp add: divmod_int_rel_def)
  1680 
  1681 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1682   by (rule divmod_int_rel_mod [of a b q r],
  1683     simp add: divmod_int_rel_def)
  1684 
  1685 (* simprocs adapted from HOL/ex/Binary.thy *)
  1686 ML {*
  1687 local
  1688   val mk_number = HOLogic.mk_number HOLogic.intT
  1689   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1690   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1691   val zero = @{term "0 :: int"}
  1692   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1693   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1694   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1695     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1696   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1697     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1698   fun binary_proc proc ss ct =
  1699     (case Thm.term_of ct of
  1700       _ $ t $ u =>
  1701       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1702         SOME args => proc (Simplifier.the_context ss) args
  1703       | NONE => NONE)
  1704     | _ => NONE);
  1705 in
  1706   fun divmod_proc posrule negrule =
  1707     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1708       if b = 0 then NONE else let
  1709         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1710         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1711         val (goal2, goal3, rule) = if b > 0
  1712           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1713           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1714       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1715 end
  1716 *}
  1717 
  1718 simproc_setup binary_int_div
  1719   ("numeral m div numeral n :: int" |
  1720    "numeral m div neg_numeral n :: int" |
  1721    "neg_numeral m div numeral n :: int" |
  1722    "neg_numeral m div neg_numeral n :: int") =
  1723   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1724 
  1725 simproc_setup binary_int_mod
  1726   ("numeral m mod numeral n :: int" |
  1727    "numeral m mod neg_numeral n :: int" |
  1728    "neg_numeral m mod numeral n :: int" |
  1729    "neg_numeral m mod neg_numeral n :: int") =
  1730   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1731 
  1732 lemmas posDivAlg_eqn_numeral [simp] =
  1733     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1734 
  1735 lemmas negDivAlg_eqn_numeral [simp] =
  1736     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1737 
  1738 
  1739 text{*Special-case simplification *}
  1740 
  1741 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1742 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1743 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1744 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1745 done
  1746 
  1747 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1748 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1749 
  1750 (** The last remaining special cases for constant arithmetic:
  1751     1 div z and 1 mod z **)
  1752 
  1753 lemmas div_pos_pos_1_numeral [simp] =
  1754   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1755 
  1756 lemmas div_pos_neg_1_numeral [simp] =
  1757   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1758   OF neg_numeral_less_zero] for w
  1759 
  1760 lemmas mod_pos_pos_1_numeral [simp] =
  1761   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1762 
  1763 lemmas mod_pos_neg_1_numeral [simp] =
  1764   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1765   OF neg_numeral_less_zero] for w
  1766 
  1767 lemmas posDivAlg_eqn_1_numeral [simp] =
  1768     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1769 
  1770 lemmas negDivAlg_eqn_1_numeral [simp] =
  1771     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1772 
  1773 
  1774 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1775 
  1776 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1777 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1778 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1779 apply (rule unique_quotient_lemma)
  1780 apply (erule subst)
  1781 apply (erule subst, simp_all)
  1782 done
  1783 
  1784 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1785 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1786 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1787 apply (rule unique_quotient_lemma_neg)
  1788 apply (erule subst)
  1789 apply (erule subst, simp_all)
  1790 done
  1791 
  1792 
  1793 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1794 
  1795 lemma q_pos_lemma:
  1796      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1797 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1798  apply (simp add: zero_less_mult_iff)
  1799 apply (simp add: right_distrib)
  1800 done
  1801 
  1802 lemma zdiv_mono2_lemma:
  1803      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1804          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1805       ==> q \<le> (q'::int)"
  1806 apply (frule q_pos_lemma, assumption+) 
  1807 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1808  apply (simp add: mult_less_cancel_left)
  1809 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1810  prefer 2 apply simp
  1811 apply (simp (no_asm_simp) add: right_distrib)
  1812 apply (subst add_commute, rule add_less_le_mono, arith)
  1813 apply (rule mult_right_mono, auto)
  1814 done
  1815 
  1816 lemma zdiv_mono2:
  1817      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1818 apply (subgoal_tac "b \<noteq> 0")
  1819  prefer 2 apply arith
  1820 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1821 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1822 apply (rule zdiv_mono2_lemma)
  1823 apply (erule subst)
  1824 apply (erule subst, simp_all)
  1825 done
  1826 
  1827 lemma q_neg_lemma:
  1828      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1829 apply (subgoal_tac "b'*q' < 0")
  1830  apply (simp add: mult_less_0_iff, arith)
  1831 done
  1832 
  1833 lemma zdiv_mono2_neg_lemma:
  1834      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1835          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1836       ==> q' \<le> (q::int)"
  1837 apply (frule q_neg_lemma, assumption+) 
  1838 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1839  apply (simp add: mult_less_cancel_left)
  1840 apply (simp add: right_distrib)
  1841 apply (subgoal_tac "b*q' \<le> b'*q'")
  1842  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1843 done
  1844 
  1845 lemma zdiv_mono2_neg:
  1846      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1847 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1848 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1849 apply (rule zdiv_mono2_neg_lemma)
  1850 apply (erule subst)
  1851 apply (erule subst, simp_all)
  1852 done
  1853 
  1854 
  1855 subsubsection {* More Algebraic Laws for div and mod *}
  1856 
  1857 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1858 
  1859 lemma zmult1_lemma:
  1860      "[| divmod_int_rel b c (q, r) |]  
  1861       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1862 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1863 
  1864 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1865 apply (case_tac "c = 0", simp)
  1866 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1867 done
  1868 
  1869 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1870 apply (case_tac "c = 0", simp)
  1871 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1872 done
  1873 
  1874 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1875 apply (case_tac "b = 0", simp)
  1876 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1877 done
  1878 
  1879 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1880 
  1881 lemma zadd1_lemma:
  1882      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1883       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1884 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1885 
  1886 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1887 lemma zdiv_zadd1_eq:
  1888      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1889 apply (case_tac "c = 0", simp)
  1890 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1891 done
  1892 
  1893 instance int :: ring_div
  1894 proof
  1895   fix a b c :: int
  1896   assume not0: "b \<noteq> 0"
  1897   show "(a + c * b) div b = c + a div b"
  1898     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1899       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1900 next
  1901   fix a b c :: int
  1902   assume "a \<noteq> 0"
  1903   then show "(a * b) div (a * c) = b div c"
  1904   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1905     case False then show ?thesis by auto
  1906   next
  1907     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1908     with `a \<noteq> 0`
  1909     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1910       apply (auto simp add: divmod_int_rel_def) 
  1911       apply (auto simp add: algebra_simps)
  1912       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1913       done
  1914     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1915     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1916     from this show ?thesis by (rule divmod_int_rel_div)
  1917   qed
  1918 qed auto
  1919 
  1920 lemma posDivAlg_div_mod:
  1921   assumes "k \<ge> 0"
  1922   and "l \<ge> 0"
  1923   shows "posDivAlg k l = (k div l, k mod l)"
  1924 proof (cases "l = 0")
  1925   case True then show ?thesis by (simp add: posDivAlg.simps)
  1926 next
  1927   case False with assms posDivAlg_correct
  1928     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1929     by simp
  1930   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1931   show ?thesis by simp
  1932 qed
  1933 
  1934 lemma negDivAlg_div_mod:
  1935   assumes "k < 0"
  1936   and "l > 0"
  1937   shows "negDivAlg k l = (k div l, k mod l)"
  1938 proof -
  1939   from assms have "l \<noteq> 0" by simp
  1940   from assms negDivAlg_correct
  1941     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1942     by simp
  1943   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1944   show ?thesis by simp
  1945 qed
  1946 
  1947 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1948 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1949 
  1950 (* REVISIT: should this be generalized to all semiring_div types? *)
  1951 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1952 
  1953 lemma zmod_zdiv_equality':
  1954   "(m\<Colon>int) mod n = m - (m div n) * n"
  1955   by (rule_tac P="%x. m mod n = x - (m div n) * n" in subst [OF mod_div_equality [of _ n]])
  1956     arith
  1957 
  1958 
  1959 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1960 
  1961 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1962   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1963   to cause particular problems.*)
  1964 
  1965 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1966 
  1967 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1968 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1969  apply (simp add: algebra_simps)
  1970 apply (rule order_le_less_trans)
  1971  apply (erule_tac [2] mult_strict_right_mono)
  1972  apply (rule mult_left_mono_neg)
  1973   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1974  apply (simp)
  1975 apply (simp)
  1976 done
  1977 
  1978 lemma zmult2_lemma_aux2:
  1979      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1980 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1981  apply arith
  1982 apply (simp add: mult_le_0_iff)
  1983 done
  1984 
  1985 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1986 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1987 apply arith
  1988 apply (simp add: zero_le_mult_iff)
  1989 done
  1990 
  1991 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1992 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1993  apply (simp add: right_diff_distrib)
  1994 apply (rule order_less_le_trans)
  1995  apply (erule mult_strict_right_mono)
  1996  apply (rule_tac [2] mult_left_mono)
  1997   apply simp
  1998  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1999 apply simp
  2000 done
  2001 
  2002 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  2003       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  2004 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  2005                    zero_less_mult_iff right_distrib [symmetric] 
  2006                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  2007 
  2008 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  2009 apply (case_tac "b = 0", simp)
  2010 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  2011 done
  2012 
  2013 lemma zmod_zmult2_eq:
  2014      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  2015 apply (case_tac "b = 0", simp)
  2016 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  2017 done
  2018 
  2019 lemma div_pos_geq:
  2020   fixes k l :: int
  2021   assumes "0 < l" and "l \<le> k"
  2022   shows "k div l = (k - l) div l + 1"
  2023 proof -
  2024   have "k = (k - l) + l" by simp
  2025   then obtain j where k: "k = j + l" ..
  2026   with assms show ?thesis by simp
  2027 qed
  2028 
  2029 lemma mod_pos_geq:
  2030   fixes k l :: int
  2031   assumes "0 < l" and "l \<le> k"
  2032   shows "k mod l = (k - l) mod l"
  2033 proof -
  2034   have "k = (k - l) + l" by simp
  2035   then obtain j where k: "k = j + l" ..
  2036   with assms show ?thesis by simp
  2037 qed
  2038 
  2039 
  2040 subsubsection {* Splitting Rules for div and mod *}
  2041 
  2042 text{*The proofs of the two lemmas below are essentially identical*}
  2043 
  2044 lemma split_pos_lemma:
  2045  "0<k ==> 
  2046     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2047 apply (rule iffI, clarify)
  2048  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2049  apply (subst mod_add_eq) 
  2050  apply (subst zdiv_zadd1_eq) 
  2051  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2052 txt{*converse direction*}
  2053 apply (drule_tac x = "n div k" in spec) 
  2054 apply (drule_tac x = "n mod k" in spec, simp)
  2055 done
  2056 
  2057 lemma split_neg_lemma:
  2058  "k<0 ==>
  2059     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2060 apply (rule iffI, clarify)
  2061  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2062  apply (subst mod_add_eq) 
  2063  apply (subst zdiv_zadd1_eq) 
  2064  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2065 txt{*converse direction*}
  2066 apply (drule_tac x = "n div k" in spec) 
  2067 apply (drule_tac x = "n mod k" in spec, simp)
  2068 done
  2069 
  2070 lemma split_zdiv:
  2071  "P(n div k :: int) =
  2072   ((k = 0 --> P 0) & 
  2073    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2074    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2075 apply (case_tac "k=0", simp)
  2076 apply (simp only: linorder_neq_iff)
  2077 apply (erule disjE) 
  2078  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2079                       split_neg_lemma [of concl: "%x y. P x"])
  2080 done
  2081 
  2082 lemma split_zmod:
  2083  "P(n mod k :: int) =
  2084   ((k = 0 --> P n) & 
  2085    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2086    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2087 apply (case_tac "k=0", simp)
  2088 apply (simp only: linorder_neq_iff)
  2089 apply (erule disjE) 
  2090  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2091                       split_neg_lemma [of concl: "%x y. P y"])
  2092 done
  2093 
  2094 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2095   when these are applied to some constant that is of the form
  2096   @{term "numeral k"}: *}
  2097 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  2098 declare split_zmod [of _ _ "numeral k", arith_split] for k
  2099 
  2100 
  2101 subsubsection {* Speeding up the Division Algorithm with Shifting *}
  2102 
  2103 text{*computing div by shifting *}
  2104 
  2105 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2106 proof cases
  2107   assume "a=0"
  2108     thus ?thesis by simp
  2109 next
  2110   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2111   hence a_pos: "1 \<le> a" by arith
  2112   hence one_less_a2: "1 < 2 * a" by arith
  2113   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2114     unfolding mult_le_cancel_left
  2115     by (simp add: add1_zle_eq add_commute [of 1])
  2116   with a_pos have "0 \<le> b mod a" by simp
  2117   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2118     by (simp add: mod_pos_pos_trivial one_less_a2)
  2119   with  le_2a
  2120   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2121     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2122                   right_distrib) 
  2123   thus ?thesis
  2124     by (subst zdiv_zadd1_eq,
  2125         simp add: mod_mult_mult1 one_less_a2
  2126                   div_pos_pos_trivial)
  2127 qed
  2128 
  2129 lemma neg_zdiv_mult_2: 
  2130   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2131 proof -
  2132   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2133   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2134     by (rule pos_zdiv_mult_2, simp add: A)
  2135   thus ?thesis
  2136     by (simp only: R zdiv_zminus_zminus diff_minus
  2137       minus_add_distrib [symmetric] mult_minus_right)
  2138 qed
  2139 
  2140 (* FIXME: add rules for negative numerals *)
  2141 lemma zdiv_numeral_Bit0 [simp]:
  2142   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2143     numeral v div (numeral w :: int)"
  2144   unfolding numeral.simps unfolding mult_2 [symmetric]
  2145   by (rule div_mult_mult1, simp)
  2146 
  2147 lemma zdiv_numeral_Bit1 [simp]:
  2148   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2149     (numeral v div (numeral w :: int))"
  2150   unfolding numeral.simps
  2151   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2152   by (rule pos_zdiv_mult_2, simp)
  2153 
  2154 
  2155 subsubsection {* Computing mod by Shifting (proofs resemble those for div) *}
  2156 
  2157 lemma pos_zmod_mult_2:
  2158   fixes a b :: int
  2159   assumes "0 \<le> a"
  2160   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2161 proof (cases "0 < a")
  2162   case False with assms show ?thesis by simp
  2163 next
  2164   case True
  2165   then have "b mod a < a" by (rule pos_mod_bound)
  2166   then have "1 + b mod a \<le> a" by simp
  2167   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2168   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2169   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2170   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2171     using `0 < a` and A
  2172     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2173   then show ?thesis by (subst mod_add_eq)
  2174 qed
  2175 
  2176 lemma neg_zmod_mult_2:
  2177   fixes a b :: int
  2178   assumes "a \<le> 0"
  2179   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2180 proof -
  2181   from assms have "0 \<le> - a" by auto
  2182   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2183     by (rule pos_zmod_mult_2)
  2184   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2185      (simp add: diff_minus add_ac)
  2186 qed
  2187 
  2188 (* FIXME: add rules for negative numerals *)
  2189 lemma zmod_numeral_Bit0 [simp]:
  2190   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2191     (2::int) * (numeral v mod numeral w)"
  2192   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2193   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2194 
  2195 lemma zmod_numeral_Bit1 [simp]:
  2196   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2197     2 * (numeral v mod numeral w) + (1::int)"
  2198   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2199   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2200   by (rule pos_zmod_mult_2, simp)
  2201 
  2202 lemma zdiv_eq_0_iff:
  2203  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2204 proof
  2205   assume ?L
  2206   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2207   with `?L` show ?R by blast
  2208 next
  2209   assume ?R thus ?L
  2210     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2211 qed
  2212 
  2213 
  2214 subsubsection {* Quotients of Signs *}
  2215 
  2216 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2217 apply (subgoal_tac "a div b \<le> -1", force)
  2218 apply (rule order_trans)
  2219 apply (rule_tac a' = "-1" in zdiv_mono1)
  2220 apply (auto simp add: div_eq_minus1)
  2221 done
  2222 
  2223 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2224 by (drule zdiv_mono1_neg, auto)
  2225 
  2226 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2227 by (drule zdiv_mono1, auto)
  2228 
  2229 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2230 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2231 They should all be simp rules unless that causes too much search. *}
  2232 
  2233 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2234 apply auto
  2235 apply (drule_tac [2] zdiv_mono1)
  2236 apply (auto simp add: linorder_neq_iff)
  2237 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2238 apply (blast intro: div_neg_pos_less0)
  2239 done
  2240 
  2241 lemma neg_imp_zdiv_nonneg_iff:
  2242   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2243 apply (subst zdiv_zminus_zminus [symmetric])
  2244 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2245 done
  2246 
  2247 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2248 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2249 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2250 
  2251 lemma pos_imp_zdiv_pos_iff:
  2252   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2253 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2254 by arith
  2255 
  2256 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2257 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2258 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2259 
  2260 lemma nonneg1_imp_zdiv_pos_iff:
  2261   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2262 apply rule
  2263  apply rule
  2264   using div_pos_pos_trivial[of a b]apply arith
  2265  apply(cases "b=0")apply simp
  2266  using div_nonneg_neg_le0[of a b]apply arith
  2267 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2268 done
  2269 
  2270 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2271 apply (rule split_zmod[THEN iffD2])
  2272 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2273 done
  2274 
  2275 
  2276 subsubsection {* The Divides Relation *}
  2277 
  2278 lemmas zdvd_iff_zmod_eq_0_numeral [simp] =
  2279   dvd_eq_mod_eq_0 [of "numeral x::int" "numeral y::int"]
  2280   dvd_eq_mod_eq_0 [of "numeral x::int" "neg_numeral y::int"]
  2281   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "numeral y::int"]
  2282   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "neg_numeral y::int"] for x y
  2283 
  2284 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2285   by (rule dvd_mod) (* TODO: remove *)
  2286 
  2287 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2288   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2289 
  2290 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2291   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2292 
  2293 
  2294 subsubsection {* Further properties *}
  2295 
  2296 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2297   using zmod_zdiv_equality[where a="m" and b="n"]
  2298   by (simp add: algebra_simps)
  2299 
  2300 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2301 apply (induct "y", auto)
  2302 apply (rule zmod_zmult1_eq [THEN trans])
  2303 apply (simp (no_asm_simp))
  2304 apply (rule mod_mult_eq [symmetric])
  2305 done
  2306 
  2307 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2308 apply (subst split_div, auto)
  2309 apply (subst split_zdiv, auto)
  2310 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2311 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2312 done
  2313 
  2314 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2315 apply (subst split_mod, auto)
  2316 apply (subst split_zmod, auto)
  2317 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2318        in unique_remainder)
  2319 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2320 done
  2321 
  2322 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2323 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2324 
  2325 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2326 apply (subgoal_tac "m mod n = 0")
  2327  apply (simp add: zmult_div_cancel)
  2328 apply (simp only: dvd_eq_mod_eq_0)
  2329 done
  2330 
  2331 text{*Suggested by Matthias Daum*}
  2332 lemma int_power_div_base:
  2333      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2334 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2335  apply (erule ssubst)
  2336  apply (simp only: power_add)
  2337  apply simp_all
  2338 done
  2339 
  2340 text {* by Brian Huffman *}
  2341 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2342 by (rule mod_minus_eq [symmetric])
  2343 
  2344 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2345 by (rule mod_diff_left_eq [symmetric])
  2346 
  2347 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2348 by (rule mod_diff_right_eq [symmetric])
  2349 
  2350 lemmas zmod_simps =
  2351   mod_add_left_eq  [symmetric]
  2352   mod_add_right_eq [symmetric]
  2353   zmod_zmult1_eq   [symmetric]
  2354   mod_mult_left_eq [symmetric]
  2355   zpower_zmod
  2356   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2357 
  2358 text {* Distributive laws for function @{text nat}. *}
  2359 
  2360 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2361 apply (rule linorder_cases [of y 0])
  2362 apply (simp add: div_nonneg_neg_le0)
  2363 apply simp
  2364 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2365 done
  2366 
  2367 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2368 lemma nat_mod_distrib:
  2369   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2370 apply (case_tac "y = 0", simp)
  2371 apply (simp add: nat_eq_iff zmod_int)
  2372 done
  2373 
  2374 text  {* transfer setup *}
  2375 
  2376 lemma transfer_nat_int_functions:
  2377     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2378     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2379   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2380 
  2381 lemma transfer_nat_int_function_closures:
  2382     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2383     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2384   apply (cases "y = 0")
  2385   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2386   apply (cases "y = 0")
  2387   apply auto
  2388 done
  2389 
  2390 declare transfer_morphism_nat_int [transfer add return:
  2391   transfer_nat_int_functions
  2392   transfer_nat_int_function_closures
  2393 ]
  2394 
  2395 lemma transfer_int_nat_functions:
  2396     "(int x) div (int y) = int (x div y)"
  2397     "(int x) mod (int y) = int (x mod y)"
  2398   by (auto simp add: zdiv_int zmod_int)
  2399 
  2400 lemma transfer_int_nat_function_closures:
  2401     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2402     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2403   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2404 
  2405 declare transfer_morphism_int_nat [transfer add return:
  2406   transfer_int_nat_functions
  2407   transfer_int_nat_function_closures
  2408 ]
  2409 
  2410 text{*Suggested by Matthias Daum*}
  2411 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2412 apply (subgoal_tac "nat x div nat k < nat x")
  2413  apply (simp add: nat_div_distrib [symmetric])
  2414 apply (rule Divides.div_less_dividend, simp_all)
  2415 done
  2416 
  2417 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2418 proof
  2419   assume H: "x mod n = y mod n"
  2420   hence "x mod n - y mod n = 0" by simp
  2421   hence "(x mod n - y mod n) mod n = 0" by simp 
  2422   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2423   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2424 next
  2425   assume H: "n dvd x - y"
  2426   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2427   hence "x = n*k + y" by simp
  2428   hence "x mod n = (n*k + y) mod n" by simp
  2429   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2430 qed
  2431 
  2432 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2433   shows "\<exists>q. x = y + n * q"
  2434 proof-
  2435   from xy have th: "int x - int y = int (x - y)" by simp 
  2436   from xyn have "int x mod int n = int y mod int n" 
  2437     by (simp add: zmod_int [symmetric])
  2438   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2439   hence "n dvd x - y" by (simp add: th zdvd_int)
  2440   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2441 qed
  2442 
  2443 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2444   (is "?lhs = ?rhs")
  2445 proof
  2446   assume H: "x mod n = y mod n"
  2447   {assume xy: "x \<le> y"
  2448     from H have th: "y mod n = x mod n" by simp
  2449     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2450       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2451   moreover
  2452   {assume xy: "y \<le> x"
  2453     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2454       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2455   ultimately  show ?rhs using linear[of x y] by blast  
  2456 next
  2457   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2458   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2459   thus  ?lhs by simp
  2460 qed
  2461 
  2462 lemma div_nat_numeral [simp]:
  2463   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2464   by (simp add: nat_div_distrib)
  2465 
  2466 lemma one_div_nat_numeral [simp]:
  2467   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2468   by (subst nat_div_distrib, simp_all)
  2469 
  2470 lemma mod_nat_numeral [simp]:
  2471   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2472   by (simp add: nat_mod_distrib)
  2473 
  2474 lemma one_mod_nat_numeral [simp]:
  2475   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2476   by (subst nat_mod_distrib) simp_all
  2477 
  2478 lemma mod_2_not_eq_zero_eq_one_int:
  2479   fixes k :: int
  2480   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2481   by auto
  2482 
  2483 
  2484 subsubsection {* Tools setup *}
  2485 
  2486 text {* Nitpick *}
  2487 
  2488 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2489 
  2490 
  2491 subsubsection {* Code generation *}
  2492 
  2493 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2494   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2495 
  2496 lemma pdivmod_posDivAlg [code]:
  2497   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2498 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2499 
  2500 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2501   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2502     then pdivmod k l
  2503     else (let (r, s) = pdivmod k l in
  2504        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2505 proof -
  2506   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2507   show ?thesis
  2508     by (simp add: divmod_int_mod_div pdivmod_def)
  2509       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2510       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2511 qed
  2512 
  2513 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2514   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2515     then pdivmod k l
  2516     else (let (r, s) = pdivmod k l in
  2517       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2518 proof -
  2519   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2520     by (auto simp add: not_less sgn_if)
  2521   then show ?thesis by (simp add: divmod_int_pdivmod)
  2522 qed
  2523 
  2524 code_modulename SML
  2525   Divides Arith
  2526 
  2527 code_modulename OCaml
  2528   Divides Arith
  2529 
  2530 code_modulename Haskell
  2531   Divides Arith
  2532 
  2533 end