src/HOL/SEQ.thy
author haftmann
Mon Jul 19 16:09:44 2010 +0200 (2010-07-19)
changeset 37887 2ae085b07f2f
parent 37767 a2b7a20d6ea3
child 40811 ab0a8cc7976a
permissions -rw-r--r--
diff_minus subsumes diff_def
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits RComplete
    14 begin
    15 
    16 abbreviation
    17   LIMSEQ :: "[nat \<Rightarrow> 'a::topological_space, 'a] \<Rightarrow> bool"
    18     ("((_)/ ----> (_))" [60, 60] 60) where
    19   "X ----> L \<equiv> (X ---> L) sequentially"
    20 
    21 definition
    22   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    23     --{*Standard definition of limit using choice operator*}
    24   "lim X = (THE L. X ----> L)"
    25 
    26 definition
    27   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    28     --{*Standard definition of convergence*}
    29   "convergent X = (\<exists>L. X ----> L)"
    30 
    31 definition
    32   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    33     --{*Standard definition for bounded sequence*}
    34   "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    35 
    36 definition
    37   monoseq :: "(nat=>real)=>bool" where
    38     --{*Definition of monotonicity. 
    39         The use of disjunction here complicates proofs considerably. 
    40         One alternative is to add a Boolean argument to indicate the direction. 
    41         Another is to develop the notions of increasing and decreasing first.*}
    42   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    43 
    44 definition
    45   incseq :: "(nat=>real)=>bool" where
    46     --{*Increasing sequence*}
    47   "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    48 
    49 definition
    50   decseq :: "(nat=>real)=>bool" where
    51     --{*Increasing sequence*}
    52   "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    53 
    54 definition
    55   subseq :: "(nat => nat) => bool" where
    56     --{*Definition of subsequence*}
    57   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    58 
    59 definition
    60   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    61     --{*Standard definition of the Cauchy condition*}
    62   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    63 
    64 
    65 subsection {* Bounded Sequences *}
    66 
    67 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    68 unfolding Bseq_def
    69 proof (intro exI conjI allI)
    70   show "0 < max K 1" by simp
    71 next
    72   fix n::nat
    73   have "norm (X n) \<le> K" by (rule K)
    74   thus "norm (X n) \<le> max K 1" by simp
    75 qed
    76 
    77 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    78 unfolding Bseq_def by auto
    79 
    80 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    81 proof (rule BseqI')
    82   let ?A = "norm ` X ` {..N}"
    83   have 1: "finite ?A" by simp
    84   fix n::nat
    85   show "norm (X n) \<le> max K (Max ?A)"
    86   proof (cases rule: linorder_le_cases)
    87     assume "n \<ge> N"
    88     hence "norm (X n) \<le> K" using K by simp
    89     thus "norm (X n) \<le> max K (Max ?A)" by simp
    90   next
    91     assume "n \<le> N"
    92     hence "norm (X n) \<in> ?A" by simp
    93     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
    94     thus "norm (X n) \<le> max K (Max ?A)" by simp
    95   qed
    96 qed
    97 
    98 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    99 unfolding Bseq_def by auto
   100 
   101 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   102 apply (erule BseqE)
   103 apply (rule_tac N="k" and K="K" in BseqI2')
   104 apply clarify
   105 apply (drule_tac x="n - k" in spec, simp)
   106 done
   107 
   108 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   109 unfolding Bfun_def eventually_sequentially
   110 apply (rule iffI)
   111 apply (simp add: Bseq_def)
   112 apply (auto intro: BseqI2')
   113 done
   114 
   115 
   116 subsection {* Limits of Sequences *}
   117 
   118 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   119   by simp
   120 
   121 lemma LIMSEQ_def: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
   122 unfolding tendsto_iff eventually_sequentially ..
   123 
   124 lemma LIMSEQ_iff:
   125   fixes L :: "'a::real_normed_vector"
   126   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   127 unfolding LIMSEQ_def dist_norm ..
   128 
   129 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   130   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
   131 
   132 lemma LIMSEQ_Zfun_iff: "((\<lambda>n. X n) ----> L) = Zfun (\<lambda>n. X n - L) sequentially"
   133 by (rule tendsto_Zfun_iff)
   134 
   135 lemma metric_LIMSEQ_I:
   136   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   137 by (simp add: LIMSEQ_def)
   138 
   139 lemma metric_LIMSEQ_D:
   140   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   141 by (simp add: LIMSEQ_def)
   142 
   143 lemma LIMSEQ_I:
   144   fixes L :: "'a::real_normed_vector"
   145   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   146 by (simp add: LIMSEQ_iff)
   147 
   148 lemma LIMSEQ_D:
   149   fixes L :: "'a::real_normed_vector"
   150   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   151 by (simp add: LIMSEQ_iff)
   152 
   153 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   154 by (rule tendsto_const)
   155 
   156 lemma LIMSEQ_const_iff:
   157   fixes k l :: "'a::metric_space"
   158   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   159 by (rule tendsto_const_iff, rule sequentially_bot)
   160 
   161 lemma LIMSEQ_norm:
   162   fixes a :: "'a::real_normed_vector"
   163   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   164 by (rule tendsto_norm)
   165 
   166 lemma LIMSEQ_ignore_initial_segment:
   167   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   168 apply (rule topological_tendstoI)
   169 apply (drule (2) topological_tendstoD)
   170 apply (simp only: eventually_sequentially)
   171 apply (erule exE, rename_tac N)
   172 apply (rule_tac x=N in exI)
   173 apply simp
   174 done
   175 
   176 lemma LIMSEQ_offset:
   177   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   178 apply (rule topological_tendstoI)
   179 apply (drule (2) topological_tendstoD)
   180 apply (simp only: eventually_sequentially)
   181 apply (erule exE, rename_tac N)
   182 apply (rule_tac x="N + k" in exI)
   183 apply clarify
   184 apply (drule_tac x="n - k" in spec)
   185 apply (simp add: le_diff_conv2)
   186 done
   187 
   188 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   189 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   190 
   191 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   192 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   193 
   194 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   195 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   196 
   197 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   198   unfolding tendsto_def eventually_sequentially
   199   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   200 
   201 lemma LIMSEQ_add:
   202   fixes a b :: "'a::real_normed_vector"
   203   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   204 by (rule tendsto_add)
   205 
   206 lemma LIMSEQ_minus:
   207   fixes a :: "'a::real_normed_vector"
   208   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   209 by (rule tendsto_minus)
   210 
   211 lemma LIMSEQ_minus_cancel:
   212   fixes a :: "'a::real_normed_vector"
   213   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   214 by (rule tendsto_minus_cancel)
   215 
   216 lemma LIMSEQ_diff:
   217   fixes a b :: "'a::real_normed_vector"
   218   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   219 by (rule tendsto_diff)
   220 
   221 lemma LIMSEQ_unique:
   222   fixes a b :: "'a::metric_space"
   223   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   224 apply (rule ccontr)
   225 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   226 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   227 apply (clarify, rename_tac M N)
   228 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   229 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   230 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   231 apply (subst dist_commute, rule dist_triangle)
   232 done
   233 
   234 lemma (in bounded_linear) LIMSEQ:
   235   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   236 by (rule tendsto)
   237 
   238 lemma (in bounded_bilinear) LIMSEQ:
   239   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   240 by (rule tendsto)
   241 
   242 lemma LIMSEQ_mult:
   243   fixes a b :: "'a::real_normed_algebra"
   244   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   245 by (rule mult.tendsto)
   246 
   247 lemma increasing_LIMSEQ:
   248   fixes f :: "nat \<Rightarrow> real"
   249   assumes inc: "!!n. f n \<le> f (Suc n)"
   250       and bdd: "!!n. f n \<le> l"
   251       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   252   shows "f ----> l"
   253 proof (auto simp add: LIMSEQ_def)
   254   fix e :: real
   255   assume e: "0 < e"
   256   then obtain N where "l \<le> f N + e/2"
   257     by (metis half_gt_zero e en that)
   258   hence N: "l < f N + e" using e
   259     by simp
   260   { fix k
   261     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   262       by (simp add: bdd) 
   263     have "\<bar>f (N+k) - l\<bar> < e"
   264     proof (induct k)
   265       case 0 show ?case using N
   266         by simp   
   267     next
   268       case (Suc k) thus ?case using N inc [of "N+k"]
   269         by simp
   270     qed 
   271   } note 1 = this
   272   { fix n
   273     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   274       by simp 
   275   } note [intro] = this
   276   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   277     by (auto simp add: dist_real_def) 
   278   qed
   279 
   280 lemma Bseq_inverse_lemma:
   281   fixes x :: "'a::real_normed_div_algebra"
   282   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   283 apply (subst nonzero_norm_inverse, clarsimp)
   284 apply (erule (1) le_imp_inverse_le)
   285 done
   286 
   287 lemma Bseq_inverse:
   288   fixes a :: "'a::real_normed_div_algebra"
   289   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   290 unfolding Bseq_conv_Bfun by (rule Bfun_inverse)
   291 
   292 lemma LIMSEQ_inverse:
   293   fixes a :: "'a::real_normed_div_algebra"
   294   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   295 by (rule tendsto_inverse)
   296 
   297 lemma LIMSEQ_divide:
   298   fixes a b :: "'a::real_normed_field"
   299   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   300 by (rule tendsto_divide)
   301 
   302 lemma LIMSEQ_pow:
   303   fixes a :: "'a::{power, real_normed_algebra}"
   304   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   305 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   306 
   307 lemma LIMSEQ_setsum:
   308   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   309   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   310   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   311 using assms by (rule tendsto_setsum)
   312 
   313 lemma LIMSEQ_setprod:
   314   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   315   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   316   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   317 proof (cases "finite S")
   318   case True
   319   thus ?thesis using n
   320   proof (induct)
   321     case empty
   322     show ?case
   323       by (simp add: LIMSEQ_const)
   324   next
   325     case insert
   326     thus ?case
   327       by (simp add: LIMSEQ_mult)
   328   qed
   329 next
   330   case False
   331   thus ?thesis
   332     by (simp add: setprod_def LIMSEQ_const)
   333 qed
   334 
   335 lemma LIMSEQ_add_const: (* FIXME: delete *)
   336   fixes a :: "'a::real_normed_vector"
   337   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   338 by (intro tendsto_intros)
   339 
   340 (* FIXME: delete *)
   341 lemma LIMSEQ_add_minus:
   342   fixes a b :: "'a::real_normed_vector"
   343   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   344 by (intro tendsto_intros)
   345 
   346 lemma LIMSEQ_diff_const: (* FIXME: delete *)
   347   fixes a b :: "'a::real_normed_vector"
   348   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   349 by (intro tendsto_intros)
   350 
   351 lemma LIMSEQ_diff_approach_zero:
   352   fixes L :: "'a::real_normed_vector"
   353   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   354 by (drule (1) LIMSEQ_add, simp)
   355 
   356 lemma LIMSEQ_diff_approach_zero2:
   357   fixes L :: "'a::real_normed_vector"
   358   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
   359 by (drule (1) LIMSEQ_diff, simp)
   360 
   361 text{*A sequence tends to zero iff its abs does*}
   362 lemma LIMSEQ_norm_zero:
   363   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   364   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   365 by (simp add: LIMSEQ_iff)
   366 
   367 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   368 by (simp add: LIMSEQ_iff)
   369 
   370 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   371 by (drule LIMSEQ_norm, simp)
   372 
   373 text{*An unbounded sequence's inverse tends to 0*}
   374 
   375 lemma LIMSEQ_inverse_zero:
   376   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   377 apply (rule LIMSEQ_I)
   378 apply (drule_tac x="inverse r" in spec, safe)
   379 apply (rule_tac x="N" in exI, safe)
   380 apply (drule_tac x="n" in spec, safe)
   381 apply (frule positive_imp_inverse_positive)
   382 apply (frule (1) less_imp_inverse_less)
   383 apply (subgoal_tac "0 < X n", simp)
   384 apply (erule (1) order_less_trans)
   385 done
   386 
   387 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   388 
   389 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   390 apply (rule LIMSEQ_inverse_zero, safe)
   391 apply (cut_tac x = r in reals_Archimedean2)
   392 apply (safe, rule_tac x = n in exI)
   393 apply (auto simp add: real_of_nat_Suc)
   394 done
   395 
   396 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   397 infinity is now easily proved*}
   398 
   399 lemma LIMSEQ_inverse_real_of_nat_add:
   400      "(%n. r + inverse(real(Suc n))) ----> r"
   401 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   402 
   403 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   404      "(%n. r + -inverse(real(Suc n))) ----> r"
   405 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   406 
   407 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   408      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   409 by (cut_tac b=1 in
   410         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   411 
   412 lemma LIMSEQ_le_const:
   413   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   414 apply (rule ccontr, simp only: linorder_not_le)
   415 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   416 apply clarsimp
   417 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   418 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   419 apply simp
   420 done
   421 
   422 lemma LIMSEQ_le_const2:
   423   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   424 apply (subgoal_tac "- a \<le> - x", simp)
   425 apply (rule LIMSEQ_le_const)
   426 apply (erule LIMSEQ_minus)
   427 apply simp
   428 done
   429 
   430 lemma LIMSEQ_le:
   431   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   432 apply (subgoal_tac "0 \<le> y - x", simp)
   433 apply (rule LIMSEQ_le_const)
   434 apply (erule (1) LIMSEQ_diff)
   435 apply (simp add: le_diff_eq)
   436 done
   437 
   438 
   439 subsection {* Convergence *}
   440 
   441 lemma limI: "X ----> L ==> lim X = L"
   442 apply (simp add: lim_def)
   443 apply (blast intro: LIMSEQ_unique)
   444 done
   445 
   446 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   447 by (simp add: convergent_def)
   448 
   449 lemma convergentI: "(X ----> L) ==> convergent X"
   450 by (auto simp add: convergent_def)
   451 
   452 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   453 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   454 
   455 lemma convergent_const: "convergent (\<lambda>n. c)"
   456 by (rule convergentI, rule LIMSEQ_const)
   457 
   458 lemma convergent_add:
   459   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
   460   assumes "convergent (\<lambda>n. X n)"
   461   assumes "convergent (\<lambda>n. Y n)"
   462   shows "convergent (\<lambda>n. X n + Y n)"
   463 using assms unfolding convergent_def by (fast intro: LIMSEQ_add)
   464 
   465 lemma convergent_setsum:
   466   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
   467   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
   468   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
   469 proof (cases "finite A")
   470   case True from this and assms show ?thesis
   471     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
   472 qed (simp add: convergent_const)
   473 
   474 lemma (in bounded_linear) convergent:
   475   assumes "convergent (\<lambda>n. X n)"
   476   shows "convergent (\<lambda>n. f (X n))"
   477 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   478 
   479 lemma (in bounded_bilinear) convergent:
   480   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
   481   shows "convergent (\<lambda>n. X n ** Y n)"
   482 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   483 
   484 lemma convergent_minus_iff:
   485   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   486   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   487 apply (simp add: convergent_def)
   488 apply (auto dest: LIMSEQ_minus)
   489 apply (drule LIMSEQ_minus, auto)
   490 done
   491 
   492 lemma lim_le:
   493   fixes x :: real
   494   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   495   shows "lim f \<le> x"
   496 proof (rule classical)
   497   assume "\<not> lim f \<le> x"
   498   hence 0: "0 < lim f - x" by arith
   499   have 1: "f----> lim f"
   500     by (metis convergent_LIMSEQ_iff f) 
   501   thus ?thesis
   502     proof (simp add: LIMSEQ_iff)
   503       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   504       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   505         by (metis 0)
   506       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   507         by blast
   508       thus "lim f \<le> x"
   509         by (metis 1 LIMSEQ_le_const2 fn_le)
   510     qed
   511 qed
   512 
   513 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   514 
   515 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   516   unfolding Ex1_def
   517   apply (rule_tac x="nat_rec e f" in exI)
   518   apply (rule conjI)+
   519 apply (rule def_nat_rec_0, simp)
   520 apply (rule allI, rule def_nat_rec_Suc, simp)
   521 apply (rule allI, rule impI, rule ext)
   522 apply (erule conjE)
   523 apply (induct_tac x)
   524 apply simp
   525 apply (erule_tac x="n" in allE)
   526 apply (simp)
   527 done
   528 
   529 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   530 
   531 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   532 apply (simp add: subseq_def)
   533 apply (auto dest!: less_imp_Suc_add)
   534 apply (induct_tac k)
   535 apply (auto intro: less_trans)
   536 done
   537 
   538 lemma monoseq_Suc:
   539    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   540                  | (\<forall>n. X (Suc n) \<le> X n))"
   541 apply (simp add: monoseq_def)
   542 apply (auto dest!: le_imp_less_or_eq)
   543 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   544 apply (induct_tac "ka")
   545 apply (auto intro: order_trans)
   546 apply (erule contrapos_np)
   547 apply (induct_tac "k")
   548 apply (auto intro: order_trans)
   549 done
   550 
   551 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   552 by (simp add: monoseq_def)
   553 
   554 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   555 by (simp add: monoseq_def)
   556 
   557 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   558 by (simp add: monoseq_Suc)
   559 
   560 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   561 by (simp add: monoseq_Suc)
   562 
   563 lemma monoseq_minus: assumes "monoseq a"
   564   shows "monoseq (\<lambda> n. - a n)"
   565 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   566   case True
   567   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   568   thus ?thesis by (rule monoI2)
   569 next
   570   case False
   571   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   572   thus ?thesis by (rule monoI1)
   573 qed
   574 
   575 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   576   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   577          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   578 proof -
   579   { fix x n fix a :: "nat \<Rightarrow> real"
   580     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   581     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   582     have "a n \<le> x"
   583     proof (rule ccontr)
   584       assume "\<not> a n \<le> x" hence "x < a n" by auto
   585       hence "0 < a n - x" by auto
   586       from `a ----> x`[THEN LIMSEQ_D, OF this]
   587       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   588       hence "norm (a (max no n) - x) < a n - x" by auto
   589       moreover
   590       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   591       hence "x < a (max no n)" by auto
   592       ultimately
   593       have "a (max no n) < a n" by auto
   594       with monotone[where m=n and n="max no n"]
   595       show False by (auto simp:max_def split:split_if_asm)
   596     qed
   597   } note top_down = this
   598   { fix x n m fix a :: "nat \<Rightarrow> real"
   599     assume "a ----> x" and "monoseq a" and "a m < x"
   600     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   601     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   602       case True with top_down and `a ----> x` show ?thesis by auto
   603     next
   604       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   605       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   606       hence False using `a m < x` by auto
   607       thus ?thesis ..
   608     qed
   609   } note when_decided = this
   610 
   611   show ?thesis
   612   proof (cases "\<exists> m. a m \<noteq> x")
   613     case True then obtain m where "a m \<noteq> x" by auto
   614     show ?thesis
   615     proof (cases "a m < x")
   616       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   617       show ?thesis by blast
   618     next
   619       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   620       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   621       show ?thesis by auto
   622     qed
   623   qed auto
   624 qed
   625 
   626 text{* for any sequence, there is a mootonic subsequence *}
   627 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   628 proof-
   629   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   630     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   631     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   632     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   633     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   634       using H apply - 
   635       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   636       unfolding order_le_less by blast 
   637     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   638     {fix n
   639       have "?P (f (Suc n)) (f n)" 
   640         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   641         using H apply - 
   642       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   643       unfolding order_le_less by blast 
   644     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   645   note fSuc = this
   646     {fix p q assume pq: "p \<ge> f q"
   647       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   648         by (cases q, simp_all) }
   649     note pqth = this
   650     {fix q
   651       have "f (Suc q) > f q" apply (induct q) 
   652         using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   653     note fss = this
   654     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   655     {fix a b 
   656       have "f a \<le> f (a + b)"
   657       proof(induct b)
   658         case 0 thus ?case by simp
   659       next
   660         case (Suc b)
   661         from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   662       qed}
   663     note fmon0 = this
   664     have "monoseq (\<lambda>n. s (f n))" 
   665     proof-
   666       {fix n
   667         have "s (f n) \<ge> s (f (Suc n))" 
   668         proof(cases n)
   669           case 0
   670           assume n0: "n = 0"
   671           from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   672           from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   673         next
   674           case (Suc m)
   675           assume m: "n = Suc m"
   676           from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   677           from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   678         qed}
   679       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   680     qed
   681     with th1 have ?thesis by blast}
   682   moreover
   683   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   684     {fix p assume p: "p \<ge> Suc N" 
   685       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   686       have "m \<noteq> p" using m(2) by auto 
   687       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   688     note th0 = this
   689     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   690     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   691     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   692       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   693     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   694       using N apply - 
   695       apply (erule allE[where x="Suc N"], clarsimp)
   696       apply (rule_tac x="m" in exI)
   697       apply auto
   698       apply (subgoal_tac "Suc N \<noteq> m")
   699       apply simp
   700       apply (rule ccontr, simp)
   701       done
   702     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   703     {fix n
   704       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   705         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   706       proof (induct n)
   707         case 0 thus ?case
   708           using f0 N apply auto 
   709           apply (erule allE[where x="f 0"], clarsimp) 
   710           apply (rule_tac x="m" in exI, simp)
   711           by (subgoal_tac "f 0 \<noteq> m", auto)
   712       next
   713         case (Suc n)
   714         from Suc.hyps have Nfn: "N < f n" by blast
   715         from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   716         with Nfn have mN: "m > N" by arith
   717         note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   718         
   719         from key have th0: "f (Suc n) > N" by simp
   720         from N[rule_format, OF th0]
   721         obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   722         have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   723         hence "m' > f (Suc n)" using m'(1) by simp
   724         with key m'(2) show ?case by auto
   725       qed}
   726     note fSuc = this
   727     {fix n
   728       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   729       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   730     note thf = this
   731     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   732     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   733       apply -
   734       apply (rule disjI1)
   735       apply auto
   736       apply (rule order_less_imp_le)
   737       apply blast
   738       done
   739     then have ?thesis  using sqf by blast}
   740   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   741 qed
   742 
   743 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   744 proof(induct n)
   745   case 0 thus ?case by simp
   746 next
   747   case (Suc n)
   748   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   749   have "n < f (Suc n)" by arith 
   750   thus ?case by arith
   751 qed
   752 
   753 lemma LIMSEQ_subseq_LIMSEQ:
   754   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   755 apply (rule topological_tendstoI)
   756 apply (drule (2) topological_tendstoD)
   757 apply (simp only: eventually_sequentially)
   758 apply (clarify, rule_tac x=N in exI, clarsimp)
   759 apply (blast intro: seq_suble le_trans dest!: spec) 
   760 done
   761 
   762 subsection {* Bounded Monotonic Sequences *}
   763 
   764 
   765 text{*Bounded Sequence*}
   766 
   767 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   768 by (simp add: Bseq_def)
   769 
   770 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   771 by (auto simp add: Bseq_def)
   772 
   773 lemma lemma_NBseq_def:
   774      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   775       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   776 proof auto
   777   fix K :: real
   778   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   779   then have "K \<le> real (Suc n)" by auto
   780   assume "\<forall>m. norm (X m) \<le> K"
   781   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   782   proof
   783     fix m :: 'a
   784     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   785     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   786   qed
   787   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   788 next
   789   fix N :: nat
   790   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   791   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   792   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   793 qed
   794 
   795 
   796 text{* alternative definition for Bseq *}
   797 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   798 apply (simp add: Bseq_def)
   799 apply (simp (no_asm) add: lemma_NBseq_def)
   800 done
   801 
   802 lemma lemma_NBseq_def2:
   803      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   804 apply (subst lemma_NBseq_def, auto)
   805 apply (rule_tac x = "Suc N" in exI)
   806 apply (rule_tac [2] x = N in exI)
   807 apply (auto simp add: real_of_nat_Suc)
   808  prefer 2 apply (blast intro: order_less_imp_le)
   809 apply (drule_tac x = n in spec, simp)
   810 done
   811 
   812 (* yet another definition for Bseq *)
   813 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   814 by (simp add: Bseq_def lemma_NBseq_def2)
   815 
   816 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   817 
   818 lemma Bseq_isUb:
   819   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   820 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   821 
   822 
   823 text{* Use completeness of reals (supremum property)
   824    to show that any bounded sequence has a least upper bound*}
   825 
   826 lemma Bseq_isLub:
   827   "!!(X::nat=>real). Bseq X ==>
   828    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   829 by (blast intro: reals_complete Bseq_isUb)
   830 
   831 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   832 
   833 lemma lemma_converg1:
   834      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   835                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   836                |] ==> \<forall>n \<ge> ma. X n = X ma"
   837 apply safe
   838 apply (drule_tac y = "X n" in isLubD2)
   839 apply (blast dest: order_antisym)+
   840 done
   841 
   842 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   843 unfolding tendsto_def eventually_sequentially
   844 apply (rule_tac x = "X m" in exI, safe)
   845 apply (rule_tac x = m in exI, safe)
   846 apply (drule spec, erule impE, auto)
   847 done
   848 
   849 lemma lemma_converg2:
   850    "!!(X::nat=>real).
   851     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   852 apply safe
   853 apply (drule_tac y = "X m" in isLubD2)
   854 apply (auto dest!: order_le_imp_less_or_eq)
   855 done
   856 
   857 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   858 by (rule setleI [THEN isUbI], auto)
   859 
   860 text{* FIXME: @{term "U - T < U"} is redundant *}
   861 lemma lemma_converg4: "!!(X::nat=> real).
   862                [| \<forall>m. X m ~= U;
   863                   isLub UNIV {x. \<exists>n. X n = x} U;
   864                   0 < T;
   865                   U + - T < U
   866                |] ==> \<exists>m. U + -T < X m & X m < U"
   867 apply (drule lemma_converg2, assumption)
   868 apply (rule ccontr, simp)
   869 apply (simp add: linorder_not_less)
   870 apply (drule lemma_converg3)
   871 apply (drule isLub_le_isUb, assumption)
   872 apply (auto dest: order_less_le_trans)
   873 done
   874 
   875 text{*A standard proof of the theorem for monotone increasing sequence*}
   876 
   877 lemma Bseq_mono_convergent:
   878      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   879 apply (simp add: convergent_def)
   880 apply (frule Bseq_isLub, safe)
   881 apply (case_tac "\<exists>m. X m = U", auto)
   882 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   883 (* second case *)
   884 apply (rule_tac x = U in exI)
   885 apply (subst LIMSEQ_iff, safe)
   886 apply (frule lemma_converg2, assumption)
   887 apply (drule lemma_converg4, auto)
   888 apply (rule_tac x = m in exI, safe)
   889 apply (subgoal_tac "X m \<le> X n")
   890  prefer 2 apply blast
   891 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   892 done
   893 
   894 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   895 by (simp add: Bseq_def)
   896 
   897 text{*Main monotonicity theorem*}
   898 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   899 apply (simp add: monoseq_def, safe)
   900 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   901 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   902 apply (auto intro!: Bseq_mono_convergent)
   903 done
   904 
   905 subsubsection{*Increasing and Decreasing Series*}
   906 
   907 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   908   by (simp add: incseq_def monoseq_def) 
   909 
   910 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   911   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   912 proof
   913   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   914   thus ?thesis by simp
   915 next
   916   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   917   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   918     by (auto simp add: incseq_def intro: order_antisym)
   919   have X: "!!n. X n = X 0"
   920     by (blast intro: const [of 0]) 
   921   have "X = (\<lambda>n. X 0)"
   922     by (blast intro: ext X)
   923   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   924     by (auto intro: LIMSEQ_unique lim) 
   925   thus ?thesis
   926     by (blast intro: eq_refl X)
   927 qed
   928 
   929 lemma incseq_SucI:
   930   assumes "\<And>n. X n \<le> X (Suc n)"
   931   shows "incseq X" unfolding incseq_def
   932 proof safe
   933   fix m n :: nat
   934   { fix d m :: nat
   935     have "X m \<le> X (m + d)"
   936     proof (induct d)
   937       case (Suc d)
   938       also have "X (m + d) \<le> X (m + Suc d)"
   939         using assms by simp
   940       finally show ?case .
   941     qed simp }
   942   note this[of m "n - m"]
   943   moreover assume "m \<le> n"
   944   ultimately show "X m \<le> X n" by simp
   945 qed
   946 
   947 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   948   by (simp add: decseq_def monoseq_def)
   949 
   950 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
   951   by (simp add: decseq_def incseq_def)
   952 
   953 
   954 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   955 proof -
   956   have inc: "incseq (\<lambda>n. - X n)" using dec
   957     by (simp add: decseq_eq_incseq)
   958   have "- X n \<le> - L" 
   959     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   960   thus ?thesis
   961     by simp
   962 qed
   963 
   964 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   965 
   966 text{*alternative formulation for boundedness*}
   967 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   968 apply (unfold Bseq_def, safe)
   969 apply (rule_tac [2] x = "k + norm x" in exI)
   970 apply (rule_tac x = K in exI, simp)
   971 apply (rule exI [where x = 0], auto)
   972 apply (erule order_less_le_trans, simp)
   973 apply (drule_tac x=n in spec, fold diff_minus)
   974 apply (drule order_trans [OF norm_triangle_ineq2])
   975 apply simp
   976 done
   977 
   978 text{*alternative formulation for boundedness*}
   979 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   980 apply safe
   981 apply (simp add: Bseq_def, safe)
   982 apply (rule_tac x = "K + norm (X N)" in exI)
   983 apply auto
   984 apply (erule order_less_le_trans, simp)
   985 apply (rule_tac x = N in exI, safe)
   986 apply (drule_tac x = n in spec)
   987 apply (rule order_trans [OF norm_triangle_ineq], simp)
   988 apply (auto simp add: Bseq_iff2)
   989 done
   990 
   991 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   992 apply (simp add: Bseq_def)
   993 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   994 apply (drule_tac x = n in spec, arith)
   995 done
   996 
   997 
   998 subsection {* Cauchy Sequences *}
   999 
  1000 lemma metric_CauchyI:
  1001   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1002 by (simp add: Cauchy_def)
  1003 
  1004 lemma metric_CauchyD:
  1005   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1006 by (simp add: Cauchy_def)
  1007 
  1008 lemma Cauchy_iff:
  1009   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1010   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1011 unfolding Cauchy_def dist_norm ..
  1012 
  1013 lemma Cauchy_iff2:
  1014      "Cauchy X =
  1015       (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1016 apply (simp add: Cauchy_iff, auto)
  1017 apply (drule reals_Archimedean, safe)
  1018 apply (drule_tac x = n in spec, auto)
  1019 apply (rule_tac x = M in exI, auto)
  1020 apply (drule_tac x = m in spec, simp)
  1021 apply (drule_tac x = na in spec, auto)
  1022 done
  1023 
  1024 lemma CauchyI:
  1025   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1026   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1027 by (simp add: Cauchy_iff)
  1028 
  1029 lemma CauchyD:
  1030   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1031   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1032 by (simp add: Cauchy_iff)
  1033 
  1034 lemma Cauchy_subseq_Cauchy:
  1035   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1036 apply (auto simp add: Cauchy_def)
  1037 apply (drule_tac x=e in spec, clarify)
  1038 apply (rule_tac x=M in exI, clarify)
  1039 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1040 done
  1041 
  1042 subsubsection {* Cauchy Sequences are Bounded *}
  1043 
  1044 text{*A Cauchy sequence is bounded -- this is the standard
  1045   proof mechanization rather than the nonstandard proof*}
  1046 
  1047 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1048           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1049 apply (clarify, drule spec, drule (1) mp)
  1050 apply (simp only: norm_minus_commute)
  1051 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1052 apply simp
  1053 done
  1054 
  1055 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1056 apply (simp add: Cauchy_iff)
  1057 apply (drule spec, drule mp, rule zero_less_one, safe)
  1058 apply (drule_tac x="M" in spec, simp)
  1059 apply (drule lemmaCauchy)
  1060 apply (rule_tac k="M" in Bseq_offset)
  1061 apply (simp add: Bseq_def)
  1062 apply (rule_tac x="1 + norm (X M)" in exI)
  1063 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1064 apply (simp add: order_less_imp_le)
  1065 done
  1066 
  1067 subsubsection {* Cauchy Sequences are Convergent *}
  1068 
  1069 class complete_space =
  1070   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1071 
  1072 class banach = real_normed_vector + complete_space
  1073 
  1074 theorem LIMSEQ_imp_Cauchy:
  1075   assumes X: "X ----> a" shows "Cauchy X"
  1076 proof (rule metric_CauchyI)
  1077   fix e::real assume "0 < e"
  1078   hence "0 < e/2" by simp
  1079   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1080   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1081   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1082   proof (intro exI allI impI)
  1083     fix m assume "N \<le> m"
  1084     hence m: "dist (X m) a < e/2" using N by fast
  1085     fix n assume "N \<le> n"
  1086     hence n: "dist (X n) a < e/2" using N by fast
  1087     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1088       by (rule dist_triangle2)
  1089     also from m n have "\<dots> < e" by simp
  1090     finally show "dist (X m) (X n) < e" .
  1091   qed
  1092 qed
  1093 
  1094 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1095 unfolding convergent_def
  1096 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1097 
  1098 lemma Cauchy_convergent_iff:
  1099   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1100   shows "Cauchy X = convergent X"
  1101 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1102 
  1103 lemma convergent_subseq_convergent:
  1104   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1105   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1106   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1107 
  1108 text {*
  1109 Proof that Cauchy sequences converge based on the one from
  1110 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1111 *}
  1112 
  1113 text {*
  1114   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1115   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1116 *}
  1117 
  1118 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1119 by (simp add: isUbI setleI)
  1120 
  1121 locale real_Cauchy =
  1122   fixes X :: "nat \<Rightarrow> real"
  1123   assumes X: "Cauchy X"
  1124   fixes S :: "real set"
  1125   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1126 
  1127 lemma real_CauchyI:
  1128   assumes "Cauchy X"
  1129   shows "real_Cauchy X"
  1130   proof qed (fact assms)
  1131 
  1132 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1133 by (unfold S_def, auto)
  1134 
  1135 lemma (in real_Cauchy) bound_isUb:
  1136   assumes N: "\<forall>n\<ge>N. X n < x"
  1137   shows "isUb UNIV S x"
  1138 proof (rule isUb_UNIV_I)
  1139   fix y::real assume "y \<in> S"
  1140   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1141     by (simp add: S_def)
  1142   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1143   hence "y < X (max M N)" by simp
  1144   also have "\<dots> < x" using N by simp
  1145   finally show "y \<le> x"
  1146     by (rule order_less_imp_le)
  1147 qed
  1148 
  1149 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1150 proof (rule reals_complete)
  1151   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1152     using CauchyD [OF X zero_less_one] by auto
  1153   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1154   show "\<exists>x. x \<in> S"
  1155   proof
  1156     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1157       by (simp add: abs_diff_less_iff)
  1158     thus "X N - 1 \<in> S" by (rule mem_S)
  1159   qed
  1160   show "\<exists>u. isUb UNIV S u"
  1161   proof
  1162     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1163       by (simp add: abs_diff_less_iff)
  1164     thus "isUb UNIV S (X N + 1)"
  1165       by (rule bound_isUb)
  1166   qed
  1167 qed
  1168 
  1169 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1170   assumes x: "isLub UNIV S x"
  1171   shows "X ----> x"
  1172 proof (rule LIMSEQ_I)
  1173   fix r::real assume "0 < r"
  1174   hence r: "0 < r/2" by simp
  1175   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1176     using CauchyD [OF X r] by auto
  1177   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1178   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1179     by (simp only: real_norm_def abs_diff_less_iff)
  1180 
  1181   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1182   hence "X N - r/2 \<in> S" by (rule mem_S)
  1183   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1184 
  1185   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1186   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1187   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1188 
  1189   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1190   proof (intro exI allI impI)
  1191     fix n assume n: "N \<le> n"
  1192     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1193     thus "norm (X n - x) < r" using 1 2
  1194       by (simp add: abs_diff_less_iff)
  1195   qed
  1196 qed
  1197 
  1198 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1199 proof -
  1200   obtain x where "isLub UNIV S x"
  1201     using isLub_ex by fast
  1202   hence "X ----> x"
  1203     by (rule isLub_imp_LIMSEQ)
  1204   thus ?thesis ..
  1205 qed
  1206 
  1207 lemma real_Cauchy_convergent:
  1208   fixes X :: "nat \<Rightarrow> real"
  1209   shows "Cauchy X \<Longrightarrow> convergent X"
  1210 unfolding convergent_def
  1211 by (rule real_Cauchy.LIMSEQ_ex)
  1212  (rule real_CauchyI)
  1213 
  1214 instance real :: banach
  1215 by intro_classes (rule real_Cauchy_convergent)
  1216 
  1217 
  1218 subsection {* Power Sequences *}
  1219 
  1220 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1221 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1222   also fact that bounded and monotonic sequence converges.*}
  1223 
  1224 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1225 apply (simp add: Bseq_def)
  1226 apply (rule_tac x = 1 in exI)
  1227 apply (simp add: power_abs)
  1228 apply (auto dest: power_mono)
  1229 done
  1230 
  1231 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1232 apply (clarify intro!: mono_SucI2)
  1233 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1234 done
  1235 
  1236 lemma convergent_realpow:
  1237   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1238 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1239 
  1240 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1241   fixes x :: real
  1242   assumes x: "0 \<le> x"
  1243   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1244 apply (induct n)
  1245 apply simp
  1246 apply simp
  1247 apply (rule order_trans)
  1248 prefer 2
  1249 apply (erule mult_left_mono)
  1250 apply (rule add_increasing [OF x], simp)
  1251 apply (simp add: real_of_nat_Suc)
  1252 apply (simp add: ring_distribs)
  1253 apply (simp add: mult_nonneg_nonneg x)
  1254 done
  1255 
  1256 lemma LIMSEQ_inverse_realpow_zero:
  1257   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1258 proof (rule LIMSEQ_inverse_zero [rule_format])
  1259   fix y :: real
  1260   assume x: "1 < x"
  1261   hence "0 < x - 1" by simp
  1262   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1263     by (rule reals_Archimedean3)
  1264   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1265   then obtain N::nat where "y < real N * (x - 1)" ..
  1266   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1267   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1268     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1269   also have "\<dots> = x ^ N" by simp
  1270   finally have "y < x ^ N" .
  1271   hence "\<forall>n\<ge>N. y < x ^ n"
  1272     apply clarify
  1273     apply (erule order_less_le_trans)
  1274     apply (erule power_increasing)
  1275     apply (rule order_less_imp_le [OF x])
  1276     done
  1277   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1278 qed
  1279 
  1280 lemma LIMSEQ_realpow_zero:
  1281   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1282 proof (cases)
  1283   assume "x = 0"
  1284   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1285   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1286 next
  1287   assume "0 \<le> x" and "x \<noteq> 0"
  1288   hence x0: "0 < x" by simp
  1289   assume x1: "x < 1"
  1290   from x0 x1 have "1 < inverse x"
  1291     by (rule one_less_inverse)
  1292   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1293     by (rule LIMSEQ_inverse_realpow_zero)
  1294   thus ?thesis by (simp add: power_inverse)
  1295 qed
  1296 
  1297 lemma LIMSEQ_power_zero:
  1298   fixes x :: "'a::{real_normed_algebra_1}"
  1299   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1300 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1301 apply (simp only: LIMSEQ_Zfun_iff, erule Zfun_le)
  1302 apply (simp add: power_abs norm_power_ineq)
  1303 done
  1304 
  1305 lemma LIMSEQ_divide_realpow_zero:
  1306   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1307 apply (cut_tac a = a and x1 = "inverse x" in
  1308         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1309 apply (auto simp add: divide_inverse power_inverse)
  1310 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1311 done
  1312 
  1313 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1314 
  1315 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1316 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1317 
  1318 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1319 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1320 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1321 done
  1322 
  1323 end