src/Pure/sign.ML
author wenzelm
Tue Nov 07 11:46:48 2006 +0100 (2006-11-07)
changeset 21206 2af4c7b3f7ef
parent 21183 a76f457b6d86
child 21269 c605503bb4ef
permissions -rw-r--r--
replaced const_syntax by notation, which operates on terms;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_const_constraint: xstring * string option -> theory -> theory
    27   val add_const_constraint_i: string * typ option -> theory -> theory
    28   val primitive_class: string * class list -> theory -> theory
    29   val primitive_classrel: class * class -> theory -> theory
    30   val primitive_arity: arity -> theory -> theory
    31   val add_trfuns:
    32     (string * (ast list -> ast)) list *
    33     (string * (term list -> term)) list *
    34     (string * (term list -> term)) list *
    35     (string * (ast list -> ast)) list -> theory -> theory
    36   val add_trfunsT:
    37     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    38   val add_advanced_trfuns:
    39     (string * (Context.generic -> ast list -> ast)) list *
    40     (string * (Context.generic -> term list -> term)) list *
    41     (string * (Context.generic -> term list -> term)) list *
    42     (string * (Context.generic -> ast list -> ast)) list -> theory -> theory
    43   val add_advanced_trfunsT:
    44     (string * (Context.generic -> bool -> typ -> term list -> term)) list -> theory -> theory
    45   val add_tokentrfuns:
    46     (string * string * (string -> string * real)) list -> theory -> theory
    47   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    48     -> theory -> theory
    49   val parse_ast_translation: bool * string -> theory -> theory
    50   val parse_translation: bool * string -> theory -> theory
    51   val print_translation: bool * string -> theory -> theory
    52   val typed_print_translation: bool * string -> theory -> theory
    53   val print_ast_translation: bool * string -> theory -> theory
    54   val token_translation: string -> theory -> theory
    55   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    56   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    57   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    58   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    59   val add_path: string -> theory -> theory
    60   val parent_path: theory -> theory
    61   val root_path: theory -> theory
    62   val absolute_path: theory -> theory
    63   val local_path: theory -> theory
    64   val no_base_names: theory -> theory
    65   val qualified_names: theory -> theory
    66   val sticky_prefix: string -> theory -> theory
    67   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    68     theory -> theory
    69   val restore_naming: theory -> theory -> theory
    70   val hide_classes: bool -> xstring list -> theory -> theory
    71   val hide_classes_i: bool -> string list -> theory -> theory
    72   val hide_types: bool -> xstring list -> theory -> theory
    73   val hide_types_i: bool -> string list -> theory -> theory
    74   val hide_consts: bool -> xstring list -> theory -> theory
    75   val hide_consts_i: bool -> string list -> theory -> theory
    76   val hide_names: bool -> string * xstring list -> theory -> theory
    77   val hide_names_i: bool -> string * string list -> theory -> theory
    78 end
    79 
    80 signature SIGN =
    81 sig
    82   val init_data: theory -> theory
    83   val rep_sg: theory ->
    84    {naming: NameSpace.naming,
    85     syn: Syntax.syntax,
    86     tsig: Type.tsig,
    87     consts: Consts.T}
    88   val naming_of: theory -> NameSpace.naming
    89   val base_name: string -> bstring
    90   val full_name: theory -> bstring -> string
    91   val full_name_path: theory -> string -> bstring -> string
    92   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    93   val syn_of: theory -> Syntax.syntax
    94   val tsig_of: theory -> Type.tsig
    95   val classes_of: theory -> Sorts.algebra
    96   val classes: theory -> class list
    97   val super_classes: theory -> class -> class list
    98   val defaultS: theory -> sort
    99   val subsort: theory -> sort * sort -> bool
   100   val of_sort: theory -> typ * sort -> bool
   101   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   102   val universal_witness: theory -> (typ * sort) option
   103   val all_sorts_nonempty: theory -> bool
   104   val typ_instance: theory -> typ * typ -> bool
   105   val typ_equiv: theory -> typ * typ -> bool
   106   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   107   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   108   val is_logtype: theory -> string -> bool
   109   val consts_of: theory -> Consts.T
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val const_monomorphic: theory -> string -> bool
   117   val const_syntax_name: theory -> string -> string
   118   val const_typargs: theory -> string * typ -> typ list
   119   val const_instance: theory -> string * typ list -> typ
   120   val class_space: theory -> NameSpace.T
   121   val type_space: theory -> NameSpace.T
   122   val const_space: theory -> NameSpace.T
   123   val intern_class: theory -> xstring -> string
   124   val extern_class: theory -> string -> xstring
   125   val intern_type: theory -> xstring -> string
   126   val extern_type: theory -> string -> xstring
   127   val intern_const: theory -> xstring -> string
   128   val extern_const: theory -> string -> xstring
   129   val intern_sort: theory -> sort -> sort
   130   val extern_sort: theory -> sort -> sort
   131   val intern_typ: theory -> typ -> typ
   132   val extern_typ: theory -> typ -> typ
   133   val intern_term: theory -> term -> term
   134   val extern_term: (string -> xstring) -> theory -> term -> term
   135   val intern_tycons: theory -> typ -> typ
   136   val pretty_term': Context.generic -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   137   val pretty_term: theory -> term -> Pretty.T
   138   val pretty_typ: theory -> typ -> Pretty.T
   139   val pretty_sort: theory -> sort -> Pretty.T
   140   val pretty_classrel: theory -> class list -> Pretty.T
   141   val pretty_arity: theory -> arity -> Pretty.T
   142   val string_of_term: theory -> term -> string
   143   val string_of_typ: theory -> typ -> string
   144   val string_of_sort: theory -> sort -> string
   145   val string_of_classrel: theory -> class list -> string
   146   val string_of_arity: theory -> arity -> string
   147   val pp: theory -> Pretty.pp
   148   val arity_number: theory -> string -> int
   149   val arity_sorts: theory -> string -> sort -> sort list
   150   val certify_class: theory -> class -> class
   151   val certify_sort: theory -> sort -> sort
   152   val certify_typ: theory -> typ -> typ
   153   val certify_typ_syntax: theory -> typ -> typ
   154   val certify_typ_abbrev: theory -> typ -> typ
   155   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   156   val certify_term: theory -> term -> term * typ * int
   157   val certify_prop: theory -> term -> term * typ * int
   158   val cert_term: theory -> term -> term
   159   val cert_prop: theory -> term -> term
   160   val no_vars: Pretty.pp -> term -> term
   161   val cert_def: Pretty.pp -> term -> (string * typ) * term
   162   val read_class: theory -> xstring -> class
   163   val read_sort': Syntax.syntax -> Context.generic -> string -> sort
   164   val read_sort: theory -> string -> sort
   165   val read_arity: theory -> xstring * string list * string -> arity
   166   val cert_arity: theory -> arity -> arity
   167   val read_typ': Syntax.syntax -> Context.generic ->
   168     (indexname -> sort option) -> string -> typ
   169   val read_typ_syntax': Syntax.syntax -> Context.generic ->
   170     (indexname -> sort option) -> string -> typ
   171   val read_typ_abbrev': Syntax.syntax -> Context.generic ->
   172     (indexname -> sort option) -> string -> typ
   173   val read_typ: theory * (indexname -> sort option) -> string -> typ
   174   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   175   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   176   val read_tyname: theory -> string -> typ
   177   val read_const: theory -> string -> term
   178   val infer_types_simult: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   179     (indexname -> sort option) -> Name.context -> bool
   180     -> (term list * typ) list -> term list * (indexname * typ) list
   181   val infer_types: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   182     (indexname -> sort option) -> Name.context -> bool
   183     -> term list * typ -> term * (indexname * typ) list
   184   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   185     Context.generic -> (indexname -> typ option) * (indexname -> sort option) ->
   186     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   187   val read_def_terms:
   188     theory * (indexname -> typ option) * (indexname -> sort option) ->
   189     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   190   val simple_read_term: theory -> typ -> string -> term
   191   val read_term: theory -> string -> term
   192   val read_prop: theory -> string -> term
   193   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   194   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   195   val add_abbrevs: Syntax.mode -> ((bstring * mixfix) * term) list -> theory -> theory
   196   include SIGN_THEORY
   197 end
   198 
   199 structure Sign: SIGN =
   200 struct
   201 
   202 
   203 (** datatype sign **)
   204 
   205 datatype sign = Sign of
   206  {naming: NameSpace.naming,     (*common naming conventions*)
   207   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   208   tsig: Type.tsig,              (*order-sorted signature of types*)
   209   consts: Consts.T};            (*polymorphic constants*)
   210 
   211 fun make_sign (naming, syn, tsig, consts) =
   212   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   213 
   214 structure SignData = TheoryDataFun
   215 (struct
   216   val name = "Pure/sign";
   217   type T = sign;
   218   val copy = I;
   219   fun extend (Sign {syn, tsig, consts, ...}) =
   220     make_sign (NameSpace.default_naming, syn, tsig, consts);
   221 
   222   val empty =
   223     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   224 
   225   fun merge pp (sign1, sign2) =
   226     let
   227       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   228       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   229 
   230       val naming = NameSpace.default_naming;
   231       val syn = Syntax.merge_syntaxes syn1 syn2;
   232       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   233       val consts = Consts.merge (consts1, consts2);
   234     in make_sign (naming, syn, tsig, consts) end;
   235 
   236   fun print _ _ = ();
   237 end);
   238 
   239 val init_data = SignData.init;
   240 
   241 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   242 
   243 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   244   make_sign (f (naming, syn, tsig, consts)));
   245 
   246 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   247 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   248 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   249 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   250 
   251 
   252 (* naming *)
   253 
   254 val naming_of = #naming o rep_sg;
   255 val base_name = NameSpace.base;
   256 val full_name = NameSpace.full o naming_of;
   257 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   258 val declare_name = NameSpace.declare o naming_of;
   259 
   260 
   261 (* syntax *)
   262 
   263 val syn_of = #syn o rep_sg;
   264 
   265 
   266 (* type signature *)
   267 
   268 val tsig_of = #tsig o rep_sg;
   269 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   270 val classes = Sorts.classes o classes_of;
   271 val super_classes = Sorts.super_classes o classes_of;
   272 val defaultS = Type.defaultS o tsig_of;
   273 val subsort = Type.subsort o tsig_of;
   274 val of_sort = Type.of_sort o tsig_of;
   275 val witness_sorts = Type.witness_sorts o tsig_of;
   276 val universal_witness = Type.universal_witness o tsig_of;
   277 val all_sorts_nonempty = is_some o universal_witness;
   278 val typ_instance = Type.typ_instance o tsig_of;
   279 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   280 val typ_match = Type.typ_match o tsig_of;
   281 val typ_unify = Type.unify o tsig_of;
   282 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   283 
   284 
   285 (* polymorphic constants *)
   286 
   287 val consts_of = #consts o rep_sg;
   288 val the_const_constraint = Consts.constraint o consts_of;
   289 val const_constraint = try o the_const_constraint;
   290 val the_const_type = Consts.declaration o consts_of;
   291 val const_type = try o the_const_type;
   292 val const_monomorphic = Consts.monomorphic o consts_of;
   293 val const_syntax_name = Consts.syntax_name o consts_of;
   294 val const_typargs = Consts.typargs o consts_of;
   295 val const_instance = Consts.instance o consts_of;
   296 
   297 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   298 val declared_const = is_some oo const_constraint;
   299 
   300 
   301 
   302 (** intern / extern names **)
   303 
   304 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   305 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   306 val const_space = Consts.space_of o consts_of;
   307 
   308 val intern_class = NameSpace.intern o class_space;
   309 val extern_class = NameSpace.extern o class_space;
   310 val intern_type = NameSpace.intern o type_space;
   311 val extern_type = NameSpace.extern o type_space;
   312 val intern_const = NameSpace.intern o const_space;
   313 val extern_const = NameSpace.extern o const_space;
   314 
   315 val intern_sort = map o intern_class;
   316 val extern_sort = map o extern_class;
   317 
   318 local
   319 
   320 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   321   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   322   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   323 
   324 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   325   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   326   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   327   | map_term _ _ _ (t as Bound _) = t
   328   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   329   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   330 
   331 val add_classesT = Term.fold_atyps
   332   (fn TFree (_, S) => fold (insert (op =)) S
   333     | TVar (_, S) => fold (insert (op =)) S
   334     | _ => I);
   335 
   336 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   337   | add_tyconsT _ = I;
   338 
   339 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   340 
   341 fun mapping add_names f t =
   342   let
   343     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   344     val tab = map_filter f' (add_names t []);
   345     fun get x = the_default x (AList.lookup (op =) tab x);
   346   in get end;
   347 
   348 fun typ_mapping f g thy T =
   349   T |> map_typ
   350     (mapping add_classesT (f thy) T)
   351     (mapping add_tyconsT (g thy) T);
   352 
   353 fun term_mapping f g h thy t =
   354   t |> map_term
   355     (mapping (Term.fold_types add_classesT) (f thy) t)
   356     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   357     (mapping add_consts (h thy) t);
   358 
   359 in
   360 
   361 val intern_typ = typ_mapping intern_class intern_type;
   362 val extern_typ = typ_mapping extern_class extern_type;
   363 val intern_term = term_mapping intern_class intern_type intern_const;
   364 fun extern_term h = term_mapping extern_class extern_type (K h);
   365 val intern_tycons = typ_mapping (K I) intern_type;
   366 
   367 end;
   368 
   369 
   370 
   371 (** pretty printing of terms, types etc. **)
   372 
   373 fun pretty_term' context syn ext t =
   374   let val curried = Context.exists_name Context.CPureN (Context.theory_of context)
   375   in Syntax.pretty_term ext context syn curried t end;
   376 
   377 fun pretty_term thy t =
   378   pretty_term' (Context.Theory thy) (syn_of thy) (Consts.extern (consts_of thy))
   379     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   380 
   381 fun pretty_typ thy T = Syntax.pretty_typ (Context.Theory thy) (syn_of thy) (extern_typ thy T);
   382 fun pretty_sort thy S = Syntax.pretty_sort (Context.Theory thy) (syn_of thy) (extern_sort thy S);
   383 
   384 fun pretty_classrel thy cs = Pretty.block (flat
   385   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   386 
   387 fun pretty_arity thy (a, Ss, S) =
   388   let
   389     val a' = extern_type thy a;
   390     val dom =
   391       if null Ss then []
   392       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   393   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   394 
   395 val string_of_term = Pretty.string_of oo pretty_term;
   396 val string_of_typ = Pretty.string_of oo pretty_typ;
   397 val string_of_sort = Pretty.string_of oo pretty_sort;
   398 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   399 val string_of_arity = Pretty.string_of oo pretty_arity;
   400 
   401 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   402   pretty_classrel thy, pretty_arity thy);
   403 
   404 
   405 
   406 (** certify entities **)    (*exception TYPE*)
   407 
   408 (* certify wrt. type signature *)
   409 
   410 val arity_number = Type.arity_number o tsig_of;
   411 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   412 
   413 fun certify cert = cert o tsig_of o Context.check_thy;
   414 
   415 val certify_class      = certify Type.cert_class;
   416 val certify_sort       = certify Type.cert_sort;
   417 val certify_typ        = certify Type.cert_typ;
   418 val certify_typ_syntax = certify Type.cert_typ_syntax;
   419 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   420 
   421 
   422 (* certify term/prop *)
   423 
   424 local
   425 
   426 fun type_check pp tm =
   427   let
   428     fun err_appl why bs t T u U =
   429       let
   430         val xs = map Free bs;           (*we do not rename here*)
   431         val t' = subst_bounds (xs, t);
   432         val u' = subst_bounds (xs, u);
   433         val msg = cat_lines
   434           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   435       in raise TYPE (msg, [T, U], [t', u']) end;
   436 
   437     fun typ_of (_, Const (_, T)) = T
   438       | typ_of (_, Free  (_, T)) = T
   439       | typ_of (_, Var (_, T)) = T
   440       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   441           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   442       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   443       | typ_of (bs, t $ u) =
   444           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   445             (case T of
   446               Type ("fun", [T1, T2]) =>
   447                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   448             | _ => err_appl "Operator not of function type" bs t T u U)
   449           end;
   450   in typ_of ([], tm) end;
   451 
   452 fun err msg = raise TYPE (msg, [], []);
   453 
   454 fun check_vars (t $ u) = (check_vars t; check_vars u)
   455   | check_vars (Abs (_, _, t)) = check_vars t
   456   | check_vars (Var (xi as (_, i), _)) =
   457       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   458   | check_vars _ = ();
   459 
   460 in
   461 
   462 fun certify' normalize prop pp consts thy tm =
   463   let
   464     val _ = Context.check_thy thy;
   465     val _ = check_vars tm;
   466     val tm' = Term.map_types (certify_typ thy) tm;
   467     val T = type_check pp tm';
   468     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   469     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   470     val tm'' = if normalize then tm'' else tm';
   471   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   472 
   473 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   474 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   475 
   476 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   477 val cert_term = #1 oo certify_term;
   478 val cert_prop = #1 oo certify_prop;
   479 
   480 end;
   481 
   482 
   483 (* specifications *)
   484 
   485 fun no_vars pp tm =
   486   (case (Term.add_vars tm [], Term.add_tvars tm []) of
   487     ([], []) => tm
   488   | (vars, tvars) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   489       (Pretty.str "Illegal schematic variable(s) in term:" ::
   490        map (Pretty.term pp o Var) vars @ map (Pretty.typ pp o TVar) tvars)))));
   491 
   492 fun cert_def pp tm =
   493   let val ((lhs, rhs), _) = tm
   494     |> no_vars pp
   495     |> Logic.strip_imp_concl
   496     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   497   in (Term.dest_Const (Term.head_of lhs), rhs) end
   498   handle TERM (msg, _) => error msg;
   499 
   500 
   501 
   502 (** read and certify entities **)    (*exception ERROR*)
   503 
   504 (* classes and sorts *)
   505 
   506 fun read_class thy c = certify_class thy (intern_class thy c)
   507   handle TYPE (msg, _, _) => error msg;
   508 
   509 fun read_sort' syn context str =
   510   let
   511     val thy = Context.theory_of context;
   512     val _ = Context.check_thy thy;
   513     val S = intern_sort thy (Syntax.read_sort context syn str);
   514   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   515 
   516 fun read_sort thy str = read_sort' (syn_of thy) (Context.Theory thy) str;
   517 
   518 
   519 (* type arities *)
   520 
   521 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   522   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   523   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   524 
   525 val read_arity = prep_arity intern_type read_sort;
   526 val cert_arity = prep_arity (K I) certify_sort;
   527 
   528 
   529 (* types *)
   530 
   531 local
   532 
   533 fun gen_read_typ' cert syn context def_sort str =
   534   let
   535     val thy = Context.theory_of context;
   536     val _ = Context.check_thy thy;
   537     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   538     val T = intern_tycons thy (Syntax.read_typ context syn get_sort (intern_sort thy) str);
   539   in cert thy T handle TYPE (msg, _, _) => error msg end
   540   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   541 
   542 fun gen_read_typ cert (thy, def_sort) str =
   543   gen_read_typ' cert (syn_of thy) (Context.Theory thy) def_sort str;
   544 
   545 in
   546 
   547 fun no_def_sort thy = (thy: theory, K NONE);
   548 
   549 val read_typ'        = gen_read_typ' certify_typ;
   550 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   551 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   552 val read_typ         = gen_read_typ certify_typ;
   553 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   554 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   555 
   556 end;
   557 
   558 
   559 (* type and constant names *)
   560 
   561 fun read_tyname thy raw_c =
   562   let val c = intern_type thy raw_c
   563   in Type (c, replicate (arity_number thy c) dummyT) end;
   564 
   565 val read_const = Consts.read_const o consts_of;
   566 
   567 
   568 
   569 (** infer_types **)         (*exception ERROR*)
   570 
   571 (*
   572   def_type: partial map from indexnames to types (constrains Frees and Vars)
   573   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   574   used: context of already used type variables
   575   freeze: if true then generated parameters are turned into TFrees, else TVars
   576 
   577   termss: lists of alternative parses (only one combination should be type-correct)
   578   typs: expected types
   579 *)
   580 
   581 fun infer_types_simult pp thy consts def_type def_sort used freeze args =
   582   let
   583     val termss = fold_rev (multiply o fst) args [[]];
   584     val typs =
   585       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   586 
   587     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   588         (try (Consts.constraint consts)) def_type def_sort (Consts.intern consts)
   589         (intern_tycons thy) (intern_sort thy) used freeze typs ts)
   590       handle TYPE (msg, _, _) => Exn (ERROR msg);
   591 
   592     val err_results = map infer termss;
   593     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   594     val results = map_filter get_result err_results;
   595 
   596     val ambiguity = length termss;
   597     fun ambig_msg () =
   598       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   599         "Got more than one parse tree.\n\
   600         \Retry with smaller Syntax.ambiguity_level for more information."
   601       else "";
   602   in
   603     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   604     else if length results = 1 then
   605       (if ambiguity > ! Syntax.ambiguity_level then
   606         warning "Fortunately, only one parse tree is type correct.\n\
   607           \You may still want to disambiguate your grammar or your input."
   608       else (); hd results)
   609     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   610       cat_lines (map (Pretty.string_of_term pp) (maps fst results))))
   611   end;
   612 
   613 fun infer_types pp thy consts def_type def_sort used freeze tsT =
   614   apfst hd (infer_types_simult pp thy consts def_type def_sort used freeze [tsT]);
   615 
   616 
   617 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   618 
   619 fun read_def_terms' pp is_logtype syn consts context (types, sorts) used freeze sTs =
   620   let
   621     val thy = Context.theory_of context;
   622     fun read (s, T) =
   623       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   624       in (Syntax.read context is_logtype syn T' s, T') end;
   625   in infer_types_simult pp thy consts types sorts used freeze (map read sTs) end;
   626 
   627 fun read_def_terms (thy, types, sorts) used freeze sTs =
   628   let
   629     val pp = pp thy;
   630     val consts = consts_of thy;
   631     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   632     val (ts, inst) =
   633       read_def_terms' pp (is_logtype thy) (syn_of thy) consts
   634         (Context.Theory thy) (types, sorts) (Name.make_context used) freeze sTs;
   635   in (map cert_consts ts, inst) end;
   636 
   637 fun simple_read_term thy T s =
   638   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   639   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   640 
   641 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   642 fun read_prop thy = simple_read_term thy propT;
   643 
   644 
   645 
   646 (** signature extension functions **)  (*exception ERROR/TYPE*)
   647 
   648 (* add default sort *)
   649 
   650 fun gen_add_defsort prep_sort s thy =
   651   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   652 
   653 val add_defsort = gen_add_defsort read_sort;
   654 val add_defsort_i = gen_add_defsort certify_sort;
   655 
   656 
   657 (* add type constructors *)
   658 
   659 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   660   let
   661     val syn' = Syntax.extend_type_gram types syn;
   662     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   663     val tsig' = Type.add_types naming decls tsig;
   664   in (naming, syn', tsig', consts) end);
   665 
   666 fun add_typedecls decls thy =
   667   let
   668     fun type_of (a, vs: string list, mx) =
   669       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   670       else error ("Duplicate parameters in type declaration: " ^ quote a);
   671   in add_types (map type_of decls) thy end;
   672 
   673 
   674 (* add nonterminals *)
   675 
   676 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   677   let
   678     val syn' = Syntax.extend_consts ns syn;
   679     val tsig' = Type.add_nonterminals naming ns tsig;
   680   in (naming, syn', tsig', consts) end);
   681 
   682 
   683 (* add type abbreviations *)
   684 
   685 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   686   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   687     let
   688       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   689       val a' = Syntax.type_name a mx;
   690       val abbr = (a', vs, prep_typ thy rhs)
   691         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   692       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   693     in (naming, syn', tsig', consts) end);
   694 
   695 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   696 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   697 
   698 
   699 (* modify syntax *)
   700 
   701 fun gen_syntax change_gram prep_typ mode args thy =
   702   let
   703     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   704       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   705   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   706 
   707 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   708 
   709 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   710 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   711 val add_syntax = add_modesyntax Syntax.default_mode;
   712 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   713 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   714 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   715 
   716 fun const_syntax thy (Const (c, _), mx) = SOME (Consts.syntax (consts_of thy) (c, mx))
   717   | const_syntax _ _ = NONE;
   718 
   719 fun add_notation mode args thy =
   720   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   721 
   722 
   723 (* add constants *)
   724 
   725 local
   726 
   727 fun gen_add_consts prep_typ authentic raw_args thy =
   728   let
   729     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   730     fun prep (raw_c, raw_T, raw_mx) =
   731       let
   732         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   733         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   734         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   735           cat_error msg ("in declaration of constant " ^ quote c);
   736       in (((c, T), authentic), (c', T, mx)) end;
   737     val args = map prep raw_args;
   738   in
   739     thy
   740     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   741     |> add_syntax_i (map #2 args)
   742   end;
   743 
   744 in
   745 
   746 val add_consts = gen_add_consts (read_typ o no_def_sort) false;
   747 val add_consts_i = gen_add_consts certify_typ false;
   748 val add_consts_authentic = gen_add_consts certify_typ true;
   749 
   750 end;
   751 
   752 
   753 (* add abbreviations *)
   754 
   755 fun add_abbrevs (mode, inout) = fold (fn ((raw_c, raw_mx), raw_t) => fn thy =>
   756   let
   757     val prep_tm = Compress.term thy o Logic.varify o no_vars (pp thy) o
   758       Term.no_dummy_patterns o cert_term_abbrev thy;
   759 
   760     val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   761     val c' = Syntax.constN ^ full_name thy c;
   762     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   763       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   764     val T = Term.fastype_of t;
   765   in
   766     thy
   767     |> map_consts (Consts.abbreviate (pp thy) (tsig_of thy) (naming_of thy) mode ((c, t), true))
   768     |> add_modesyntax_i (mode, inout) [(c', T, mx)]
   769   end);
   770 
   771 
   772 (* add constraints *)
   773 
   774 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   775   let
   776     val c = int_const thy raw_c;
   777     fun prepT raw_T =
   778       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   779       in cert_term thy (Const (c, T)); T end
   780       handle TYPE (msg, _, _) => error msg;
   781   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   782 
   783 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   784 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   785 
   786 
   787 (* primitive classes and arities *)
   788 
   789 fun primitive_class (bclass, classes) thy =
   790   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   791     let
   792       val syn' = Syntax.extend_consts [bclass] syn;
   793       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   794     in (naming, syn', tsig', consts) end)
   795   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   796 
   797 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   798 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   799 
   800 
   801 (* add translation functions *)
   802 
   803 local
   804 
   805 fun mk trs = map Syntax.mk_trfun trs;
   806 
   807 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   808   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   809 
   810 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   811 
   812 in
   813 
   814 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   815 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   816 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   817 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   818 
   819 end;
   820 
   821 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   822 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   823 
   824 
   825 (* compile translation functions *)
   826 
   827 local
   828 
   829 fun advancedT false = ""
   830   | advancedT true = "Context.generic -> ";
   831 
   832 fun advancedN false = ""
   833   | advancedN true = "advanced_";
   834 
   835 in
   836 
   837 fun parse_ast_translation (a, txt) =
   838   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   839       "Syntax.ast list -> Syntax.ast)) list")
   840     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   841 
   842 fun parse_translation (a, txt) =
   843   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   844       "term list -> term)) list")
   845     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   846 
   847 fun print_translation (a, txt) =
   848   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   849       "term list -> term)) list")
   850     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   851 
   852 fun print_ast_translation (a, txt) =
   853   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   854       "Syntax.ast list -> Syntax.ast)) list")
   855     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   856 
   857 fun typed_print_translation (a, txt) =
   858   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   859       "bool -> typ -> term list -> term)) list")
   860     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   861 
   862 val token_translation =
   863   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   864     "Sign.add_tokentrfuns token_translation";
   865 
   866 end;
   867 
   868 
   869 (* translation rules *)
   870 
   871 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   872   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   873   in f (Context.Theory thy) (is_logtype thy) syn rules syn end);
   874 
   875 val add_trrules = gen_trrules Syntax.extend_trrules;
   876 val del_trrules = gen_trrules Syntax.remove_trrules;
   877 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   878 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   879 
   880 
   881 (* modify naming *)
   882 
   883 val add_path        = map_naming o NameSpace.add_path;
   884 val no_base_names   = map_naming NameSpace.no_base_names;
   885 val qualified_names = map_naming NameSpace.qualified_names;
   886 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   887 val set_policy      = map_naming o NameSpace.set_policy;
   888 val restore_naming  = map_naming o K o naming_of;
   889 
   890 val parent_path   = add_path "..";
   891 val root_path     = add_path "/";
   892 val absolute_path = add_path "//";
   893 
   894 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   895 
   896 
   897 (* hide names *)
   898 
   899 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   900 val hide_classes_i = map_tsig oo Type.hide_classes;
   901 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   902 val hide_types_i = map_tsig oo Type.hide_types;
   903 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   904 val hide_consts_i = map_consts oo (fold o Consts.hide);
   905 
   906 local
   907 
   908 val kinds =
   909  [("class", (intern_class, can o certify_class, hide_classes_i)),
   910   ("type", (intern_type, declared_tyname, hide_types_i)),
   911   ("const", (intern_const, declared_const, hide_consts_i))];
   912 
   913 fun gen_hide int b (kind, xnames) thy =
   914   (case AList.lookup (op =) kinds kind of
   915     SOME (intern, check, hide) =>
   916       let
   917         val names = if int then map (intern thy) xnames else xnames;
   918         val bads = filter_out (check thy) names;
   919       in
   920         if null bads then hide b names thy
   921         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   922       end
   923   | NONE => error ("Bad name space specification: " ^ quote kind));
   924 
   925 in
   926 
   927 val hide_names = gen_hide true;
   928 val hide_names_i = gen_hide false;
   929 
   930 end;
   931 
   932 end;