src/HOL/Product_Type.thy
author haftmann
Wed Nov 25 11:16:57 2009 +0100 (2009-11-25)
changeset 33959 2afc55e8ed27
parent 33638 548a34929e98
child 34886 873c31d9f10d
permissions -rw-r--r--
bootstrap datatype_rep_proofs in Datatype.thy (avoids unchecked dynamic name references)
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13 begin
    14 
    15 subsection {* @{typ bool} is a datatype *}
    16 
    17 rep_datatype True False by (auto intro: bool_induct)
    18 
    19 declare case_split [cases type: bool]
    20   -- "prefer plain propositional version"
    21 
    22 lemma
    23   shows [code]: "eq_class.eq False P \<longleftrightarrow> \<not> P"
    24     and [code]: "eq_class.eq True P \<longleftrightarrow> P" 
    25     and [code]: "eq_class.eq P False \<longleftrightarrow> \<not> P" 
    26     and [code]: "eq_class.eq P True \<longleftrightarrow> P"
    27     and [code nbe]: "eq_class.eq P P \<longleftrightarrow> True"
    28   by (simp_all add: eq)
    29 
    30 code_const "eq_class.eq \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    31   (Haskell infixl 4 "==")
    32 
    33 code_instance bool :: eq
    34   (Haskell -)
    35 
    36 
    37 subsection {* Unit *}
    38 
    39 typedef unit = "{True}"
    40 proof
    41   show "True : ?unit" ..
    42 qed
    43 
    44 definition
    45   Unity :: unit    ("'(')")
    46 where
    47   "() = Abs_unit True"
    48 
    49 lemma unit_eq [noatp]: "u = ()"
    50   by (induct u) (simp add: unit_def Unity_def)
    51 
    52 text {*
    53   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    54   this rule directly --- it loops!
    55 *}
    56 
    57 ML {*
    58   val unit_eq_proc =
    59     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    60       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    61       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    62     end;
    63 
    64   Addsimprocs [unit_eq_proc];
    65 *}
    66 
    67 rep_datatype "()" by simp
    68 
    69 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    70   by simp
    71 
    72 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    73   by (rule triv_forall_equality)
    74 
    75 text {*
    76   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    77   [source] "%u::unit. f u"}, replacing it by @{term [source]
    78   f} rather than by @{term [source] "%u. f ()"}.
    79 *}
    80 
    81 lemma unit_abs_eta_conv [simp,noatp]: "(%u::unit. f ()) = f"
    82   by (rule ext) simp
    83 
    84 instantiation unit :: default
    85 begin
    86 
    87 definition "default = ()"
    88 
    89 instance ..
    90 
    91 end
    92 
    93 text {* code generator setup *}
    94 
    95 lemma [code]:
    96   "eq_class.eq (u\<Colon>unit) v \<longleftrightarrow> True" unfolding eq unit_eq [of u] unit_eq [of v] by rule+
    97 
    98 code_type unit
    99   (SML "unit")
   100   (OCaml "unit")
   101   (Haskell "()")
   102 
   103 code_instance unit :: eq
   104   (Haskell -)
   105 
   106 code_const "eq_class.eq \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   107   (Haskell infixl 4 "==")
   108 
   109 code_const Unity
   110   (SML "()")
   111   (OCaml "()")
   112   (Haskell "()")
   113 
   114 code_reserved SML
   115   unit
   116 
   117 code_reserved OCaml
   118   unit
   119 
   120 
   121 subsection {* Pairs *}
   122 
   123 subsubsection {* Product type, basic operations and concrete syntax *}
   124 
   125 definition
   126   Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
   127 where
   128   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   129 
   130 global
   131 
   132 typedef (Prod)
   133   ('a, 'b) "*"    (infixr "*" 20)
   134     = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   135 proof
   136   fix a b show "Pair_Rep a b \<in> ?Prod"
   137     by rule+
   138 qed
   139 
   140 syntax (xsymbols)
   141   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   142 syntax (HTML output)
   143   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   144 
   145 consts
   146   Pair     :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b"
   147   fst      :: "'a \<times> 'b \<Rightarrow> 'a"
   148   snd      :: "'a \<times> 'b \<Rightarrow> 'b"
   149   split    :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   150   curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c"
   151 
   152 local
   153 
   154 defs
   155   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   156   fst_def:      "fst p == THE a. EX b. p = Pair a b"
   157   snd_def:      "snd p == THE b. EX a. p = Pair a b"
   158   split_def:    "split == (%c p. c (fst p) (snd p))"
   159   curry_def:    "curry == (%c x y. c (Pair x y))"
   160 
   161 text {*
   162   Patterns -- extends pre-defined type @{typ pttrn} used in
   163   abstractions.
   164 *}
   165 
   166 nonterminals
   167   tuple_args patterns
   168 
   169 syntax
   170   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   171   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   172   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   173   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   174   ""            :: "pttrn => patterns"                  ("_")
   175   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   176 
   177 translations
   178   "(x, y)"       == "Pair x y"
   179   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   180   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   181   "%(x,y).b"     == "split(%x y. b)"
   182   "_abs (Pair x y) t" => "%(x,y).t"
   183   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   184      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   185 
   186 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   187 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   188 print_translation {*
   189 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   190       (* split (%x y. t) => %(x,y) t *)
   191       let val (y,t') = atomic_abs_tr' abs;
   192           val (x',t'') = atomic_abs_tr' (x,T,t');
   193     
   194       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   195     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   196        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   197        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   198            val (x',t'') = atomic_abs_tr' (x,T,t');
   199        in Syntax.const "_abs"$ 
   200            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   201     | split_tr' [Const ("split",_)$t] =
   202        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   203        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   204     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   205        (* split (%pttrn z. t) => %(pttrn,z). t *)
   206        let val (z,t) = atomic_abs_tr' abs;
   207        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   208     | split_tr' _ =  raise Match;
   209 in [("split", split_tr')]
   210 end
   211 *}
   212 
   213 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   214 typed_print_translation {*
   215 let
   216   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   217     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   218         (case (head_of t) of
   219            Const ("split",_) => raise Match
   220          | _ => let 
   221                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   222                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   223                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   224                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   225     | split_guess_names_tr' _ T [t] =
   226        (case (head_of t) of
   227            Const ("split",_) => raise Match 
   228          | _ => let 
   229                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   230                   val (y,t') = 
   231                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   232                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   233                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   234     | split_guess_names_tr' _ _ _ = raise Match;
   235 in [("split", split_guess_names_tr')]
   236 end 
   237 *}
   238 
   239 
   240 text {* Towards a datatype declaration *}
   241 
   242 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   243   apply (unfold Pair_def)
   244   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   245   apply (erule exE, erule exE, rule exI, rule exI)
   246   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   247   apply (erule arg_cong)
   248   done
   249 
   250 lemma PairE [cases type: *]:
   251   obtains x y where "p = (x, y)"
   252   using surj_pair [of p] by blast
   253 
   254 lemma ProdI: "Pair_Rep a b \<in> Prod"
   255   unfolding Prod_def by rule+
   256 
   257 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' \<Longrightarrow> a = a' \<and> b = b'"
   258   unfolding Pair_Rep_def by (drule fun_cong, drule fun_cong) blast
   259 
   260 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   261   apply (rule inj_on_inverseI)
   262   apply (erule Abs_Prod_inverse)
   263   done
   264 
   265 lemma Pair_inject:
   266   assumes "(a, b) = (a', b')"
   267     and "a = a' ==> b = b' ==> R"
   268   shows R
   269   apply (insert prems [unfolded Pair_def])
   270   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   271   apply (assumption | rule ProdI)+
   272   done
   273 
   274 rep_datatype (prod) Pair
   275 proof -
   276   fix P p
   277   assume "\<And>x y. P (x, y)"
   278   then show "P p" by (cases p) simp
   279 qed (auto elim: Pair_inject)
   280 
   281 lemmas Pair_eq = prod.inject
   282 
   283 lemma fst_conv [simp, code]: "fst (a, b) = a"
   284   unfolding fst_def by blast
   285 
   286 lemma snd_conv [simp, code]: "snd (a, b) = b"
   287   unfolding snd_def by blast
   288 
   289 
   290 subsubsection {* Basic rules and proof tools *}
   291 
   292 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   293   by simp
   294 
   295 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   296   by simp
   297 
   298 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   299   by (cases p) simp
   300 
   301 lemmas surjective_pairing = pair_collapse [symmetric]
   302 
   303 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   304 proof
   305   fix a b
   306   assume "!!x. PROP P x"
   307   then show "PROP P (a, b)" .
   308 next
   309   fix x
   310   assume "!!a b. PROP P (a, b)"
   311   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   312 qed
   313 
   314 text {*
   315   The rule @{thm [source] split_paired_all} does not work with the
   316   Simplifier because it also affects premises in congrence rules,
   317   where this can lead to premises of the form @{text "!!a b. ... =
   318   ?P(a, b)"} which cannot be solved by reflexivity.
   319 *}
   320 
   321 lemmas split_tupled_all = split_paired_all unit_all_eq2
   322 
   323 ML {*
   324   (* replace parameters of product type by individual component parameters *)
   325   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   326   local (* filtering with exists_paired_all is an essential optimization *)
   327     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   328           can HOLogic.dest_prodT T orelse exists_paired_all t
   329       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   330       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   331       | exists_paired_all _ = false;
   332     val ss = HOL_basic_ss
   333       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   334       addsimprocs [unit_eq_proc];
   335   in
   336     val split_all_tac = SUBGOAL (fn (t, i) =>
   337       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   338     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   339       if exists_paired_all t then full_simp_tac ss i else no_tac);
   340     fun split_all th =
   341    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   342   end;
   343 *}
   344 
   345 declaration {* fn _ =>
   346   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   347 *}
   348 
   349 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   350   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   351   by fast
   352 
   353 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   354   by fast
   355 
   356 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   357   by (cases s, cases t) simp
   358 
   359 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   360   by (simp add: Pair_fst_snd_eq)
   361 
   362 
   363 subsubsection {* @{text split} and @{text curry} *}
   364 
   365 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   366   by (simp add: split_def)
   367 
   368 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   369   by (simp add: curry_def)
   370 
   371 lemmas split = split_conv  -- {* for backwards compatibility *}
   372 
   373 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   374   by (rule split_conv [THEN iffD2])
   375 
   376 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   377   by (rule split_conv [THEN iffD1])
   378 
   379 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   380   by (simp add: curry_def)
   381 
   382 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   383   by (simp add: curry_def)
   384 
   385 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   386   by (simp add: curry_def)
   387 
   388 lemma curry_split [simp]: "curry (split f) = f"
   389   by (simp add: curry_def split_def)
   390 
   391 lemma split_curry [simp]: "split (curry f) = f"
   392   by (simp add: curry_def split_def)
   393 
   394 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   395   by (simp add: split_def id_def)
   396 
   397 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   398   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity Datatype. *}
   399   by (rule ext) auto
   400 
   401 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   402   by (cases x) simp
   403 
   404 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   405   unfolding split_def ..
   406 
   407 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   408   -- {* Can't be added to simpset: loops! *}
   409   by (simp add: split_eta)
   410 
   411 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   412   by (simp add: split_def)
   413 
   414 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   415   -- {* Prevents simplification of @{term c}: much faster *}
   416   by (erule arg_cong)
   417 
   418 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   419   by (simp add: split_eta)
   420 
   421 text {*
   422   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   423   @{thm [source] split_eta} as a rewrite rule is not general enough,
   424   and using @{thm [source] cond_split_eta} directly would render some
   425   existing proofs very inefficient; similarly for @{text
   426   split_beta}.
   427 *}
   428 
   429 ML {*
   430 
   431 local
   432   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   433   fun  Pair_pat k 0 (Bound m) = (m = k)
   434   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   435                         m = k+i andalso Pair_pat k (i-1) t
   436   |    Pair_pat _ _ _ = false;
   437   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   438   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   439   |   no_args k i (Bound m) = m < k orelse m > k+i
   440   |   no_args _ _ _ = true;
   441   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   442   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   443   |   split_pat tp i _ = NONE;
   444   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   445         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   446         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   447 
   448   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   449   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   450                         (beta_term_pat k i t andalso beta_term_pat k i u)
   451   |   beta_term_pat k i t = no_args k i t;
   452   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   453   |    eta_term_pat _ _ _ = false;
   454   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   455   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   456                               else (subst arg k i t $ subst arg k i u)
   457   |   subst arg k i t = t;
   458   fun beta_proc ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   459         (case split_pat beta_term_pat 1 t of
   460         SOME (i,f) => SOME (metaeq ss s (subst arg 0 i f))
   461         | NONE => NONE)
   462   |   beta_proc _ _ = NONE;
   463   fun eta_proc ss (s as Const ("split", _) $ Abs (_, _, t)) =
   464         (case split_pat eta_term_pat 1 t of
   465           SOME (_,ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   466         | NONE => NONE)
   467   |   eta_proc _ _ = NONE;
   468 in
   469   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   470   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   471 end;
   472 
   473 Addsimprocs [split_beta_proc, split_eta_proc];
   474 *}
   475 
   476 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   477   by (subst surjective_pairing, rule split_conv)
   478 
   479 lemma split_split [noatp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   480   -- {* For use with @{text split} and the Simplifier. *}
   481   by (insert surj_pair [of p], clarify, simp)
   482 
   483 text {*
   484   @{thm [source] split_split} could be declared as @{text "[split]"}
   485   done after the Splitter has been speeded up significantly;
   486   precompute the constants involved and don't do anything unless the
   487   current goal contains one of those constants.
   488 *}
   489 
   490 lemma split_split_asm [noatp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   491 by (subst split_split, simp)
   492 
   493 
   494 text {*
   495   \medskip @{term split} used as a logical connective or set former.
   496 
   497   \medskip These rules are for use with @{text blast}; could instead
   498   call @{text simp} using @{thm [source] split} as rewrite. *}
   499 
   500 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   501   apply (simp only: split_tupled_all)
   502   apply (simp (no_asm_simp))
   503   done
   504 
   505 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   506   apply (simp only: split_tupled_all)
   507   apply (simp (no_asm_simp))
   508   done
   509 
   510 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   511   by (induct p) (auto simp add: split_def)
   512 
   513 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   514   by (induct p) (auto simp add: split_def)
   515 
   516 lemma splitE2:
   517   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   518 proof -
   519   assume q: "Q (split P z)"
   520   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   521   show R
   522     apply (rule r surjective_pairing)+
   523     apply (rule split_beta [THEN subst], rule q)
   524     done
   525 qed
   526 
   527 lemma splitD': "split R (a,b) c ==> R a b c"
   528   by simp
   529 
   530 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   531   by simp
   532 
   533 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   534 by (simp only: split_tupled_all, simp)
   535 
   536 lemma mem_splitE:
   537   assumes major: "z: split c p"
   538     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   539   shows Q
   540   by (rule major [unfolded split_def] cases surjective_pairing)+
   541 
   542 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   543 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   544 
   545 ML {*
   546 local (* filtering with exists_p_split is an essential optimization *)
   547   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   548     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   549     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   550     | exists_p_split _ = false;
   551   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   552 in
   553 val split_conv_tac = SUBGOAL (fn (t, i) =>
   554     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   555 end;
   556 *}
   557 
   558 (* This prevents applications of splitE for already splitted arguments leading
   559    to quite time-consuming computations (in particular for nested tuples) *)
   560 declaration {* fn _ =>
   561   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   562 *}
   563 
   564 lemma split_eta_SetCompr [simp,noatp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   565   by (rule ext) fast
   566 
   567 lemma split_eta_SetCompr2 [simp,noatp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   568   by (rule ext) fast
   569 
   570 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   571   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   572   by (rule ext) blast
   573 
   574 (* Do NOT make this a simp rule as it
   575    a) only helps in special situations
   576    b) can lead to nontermination in the presence of split_def
   577 *)
   578 lemma split_comp_eq: 
   579   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   580   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   581   by (rule ext) auto
   582 
   583 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   584   apply (rule_tac x = "(a, b)" in image_eqI)
   585    apply auto
   586   done
   587 
   588 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   589   by blast
   590 
   591 (*
   592 the following  would be slightly more general,
   593 but cannot be used as rewrite rule:
   594 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   595 ### ?y = .x
   596 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   597 by (rtac some_equality 1)
   598 by ( Simp_tac 1)
   599 by (split_all_tac 1)
   600 by (Asm_full_simp_tac 1)
   601 qed "The_split_eq";
   602 *)
   603 
   604 text {*
   605   Setup of internal @{text split_rule}.
   606 *}
   607 
   608 definition
   609   internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   610 where
   611   "internal_split == split"
   612 
   613 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   614   by (simp only: internal_split_def split_conv)
   615 
   616 hide const internal_split
   617 
   618 use "Tools/split_rule.ML"
   619 setup SplitRule.setup
   620 
   621 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   622 
   623 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   624   by auto
   625 
   626 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   627   by (auto simp: split_tupled_all)
   628 
   629 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   630   by (induct p) auto
   631 
   632 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   633   by (induct p) auto
   634 
   635 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   636   by (simp add: expand_fun_eq)
   637 
   638 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   639 declare prod_caseE' [elim!] prod_caseE [elim!]
   640 
   641 lemma prod_case_split:
   642   "prod_case = split"
   643   by (auto simp add: expand_fun_eq)
   644 
   645 lemma prod_case_beta:
   646   "prod_case f p = f (fst p) (snd p)"
   647   unfolding prod_case_split split_beta ..
   648 
   649 
   650 subsection {* Further cases/induct rules for tuples *}
   651 
   652 lemma prod_cases3 [cases type]:
   653   obtains (fields) a b c where "y = (a, b, c)"
   654   by (cases y, case_tac b) blast
   655 
   656 lemma prod_induct3 [case_names fields, induct type]:
   657     "(!!a b c. P (a, b, c)) ==> P x"
   658   by (cases x) blast
   659 
   660 lemma prod_cases4 [cases type]:
   661   obtains (fields) a b c d where "y = (a, b, c, d)"
   662   by (cases y, case_tac c) blast
   663 
   664 lemma prod_induct4 [case_names fields, induct type]:
   665     "(!!a b c d. P (a, b, c, d)) ==> P x"
   666   by (cases x) blast
   667 
   668 lemma prod_cases5 [cases type]:
   669   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   670   by (cases y, case_tac d) blast
   671 
   672 lemma prod_induct5 [case_names fields, induct type]:
   673     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   674   by (cases x) blast
   675 
   676 lemma prod_cases6 [cases type]:
   677   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   678   by (cases y, case_tac e) blast
   679 
   680 lemma prod_induct6 [case_names fields, induct type]:
   681     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   682   by (cases x) blast
   683 
   684 lemma prod_cases7 [cases type]:
   685   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   686   by (cases y, case_tac f) blast
   687 
   688 lemma prod_induct7 [case_names fields, induct type]:
   689     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   690   by (cases x) blast
   691 
   692 
   693 subsubsection {* Derived operations *}
   694 
   695 text {*
   696   The composition-uncurry combinator.
   697 *}
   698 
   699 notation fcomp (infixl "o>" 60)
   700 
   701 definition
   702   scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "o\<rightarrow>" 60)
   703 where
   704   "f o\<rightarrow> g = (\<lambda>x. split g (f x))"
   705 
   706 lemma scomp_apply:  "(f o\<rightarrow> g) x = split g (f x)"
   707   by (simp add: scomp_def)
   708 
   709 lemma Pair_scomp: "Pair x o\<rightarrow> f = f x"
   710   by (simp add: expand_fun_eq scomp_apply)
   711 
   712 lemma scomp_Pair: "x o\<rightarrow> Pair = x"
   713   by (simp add: expand_fun_eq scomp_apply)
   714 
   715 lemma scomp_scomp: "(f o\<rightarrow> g) o\<rightarrow> h = f o\<rightarrow> (\<lambda>x. g x o\<rightarrow> h)"
   716   by (simp add: expand_fun_eq split_twice scomp_def)
   717 
   718 lemma scomp_fcomp: "(f o\<rightarrow> g) o> h = f o\<rightarrow> (\<lambda>x. g x o> h)"
   719   by (simp add: expand_fun_eq scomp_apply fcomp_def split_def)
   720 
   721 lemma fcomp_scomp: "(f o> g) o\<rightarrow> h = f o> (g o\<rightarrow> h)"
   722   by (simp add: expand_fun_eq scomp_apply fcomp_apply)
   723 
   724 code_const scomp
   725   (Eval infixl 3 "#->")
   726 
   727 no_notation fcomp (infixl "o>" 60)
   728 no_notation scomp (infixl "o\<rightarrow>" 60)
   729 
   730 
   731 text {*
   732   @{term prod_fun} --- action of the product functor upon
   733   Datatypes.
   734 *}
   735 
   736 definition prod_fun :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   737   [code del]: "prod_fun f g = (\<lambda>(x, y). (f x, g y))"
   738 
   739 lemma prod_fun [simp, code]: "prod_fun f g (a, b) = (f a, g b)"
   740   by (simp add: prod_fun_def)
   741 
   742 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   743   by (rule ext) auto
   744 
   745 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   746   by (rule ext) auto
   747 
   748 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   749   apply (rule image_eqI)
   750   apply (rule prod_fun [symmetric], assumption)
   751   done
   752 
   753 lemma prod_fun_imageE [elim!]:
   754   assumes major: "c: (prod_fun f g)`r"
   755     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   756   shows P
   757   apply (rule major [THEN imageE])
   758   apply (rule_tac p = x in PairE)
   759   apply (rule cases)
   760    apply (blast intro: prod_fun)
   761   apply blast
   762   done
   763 
   764 definition
   765   apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b"
   766 where
   767   [code del]: "apfst f = prod_fun f id"
   768 
   769 definition
   770   apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c"
   771 where
   772   [code del]: "apsnd f = prod_fun id f"
   773 
   774 lemma apfst_conv [simp, code]:
   775   "apfst f (x, y) = (f x, y)" 
   776   by (simp add: apfst_def)
   777 
   778 lemma apsnd_conv [simp, code]:
   779   "apsnd f (x, y) = (x, f y)" 
   780   by (simp add: apsnd_def)
   781 
   782 lemma fst_apfst [simp]:
   783   "fst (apfst f x) = f (fst x)"
   784   by (cases x) simp
   785 
   786 lemma fst_apsnd [simp]:
   787   "fst (apsnd f x) = fst x"
   788   by (cases x) simp
   789 
   790 lemma snd_apfst [simp]:
   791   "snd (apfst f x) = snd x"
   792   by (cases x) simp
   793 
   794 lemma snd_apsnd [simp]:
   795   "snd (apsnd f x) = f (snd x)"
   796   by (cases x) simp
   797 
   798 lemma apfst_compose:
   799   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   800   by (cases x) simp
   801 
   802 lemma apsnd_compose:
   803   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   804   by (cases x) simp
   805 
   806 lemma apfst_apsnd [simp]:
   807   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   808   by (cases x) simp
   809 
   810 lemma apsnd_apfst [simp]:
   811   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   812   by (cases x) simp
   813 
   814 lemma apfst_id [simp] :
   815   "apfst id = id"
   816   by (simp add: expand_fun_eq)
   817 
   818 lemma apsnd_id [simp] :
   819   "apsnd id = id"
   820   by (simp add: expand_fun_eq)
   821 
   822 lemma apfst_eq_conv [simp]:
   823   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   824   by (cases x) simp
   825 
   826 lemma apsnd_eq_conv [simp]:
   827   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   828   by (cases x) simp
   829 
   830 lemma apsnd_apfst_commute:
   831   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   832   by simp
   833 
   834 text {*
   835   Disjoint union of a family of sets -- Sigma.
   836 *}
   837 
   838 definition  Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   839   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   840 
   841 abbreviation
   842   Times :: "['a set, 'b set] => ('a * 'b) set"
   843     (infixr "<*>" 80) where
   844   "A <*> B == Sigma A (%_. B)"
   845 
   846 notation (xsymbols)
   847   Times  (infixr "\<times>" 80)
   848 
   849 notation (HTML output)
   850   Times  (infixr "\<times>" 80)
   851 
   852 syntax
   853   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   854 
   855 translations
   856   "SIGMA x:A. B" == "Product_Type.Sigma A (%x. B)"
   857 
   858 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   859   by (unfold Sigma_def) blast
   860 
   861 lemma SigmaE [elim!]:
   862     "[| c: Sigma A B;
   863         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   864      |] ==> P"
   865   -- {* The general elimination rule. *}
   866   by (unfold Sigma_def) blast
   867 
   868 text {*
   869   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   870   eigenvariables.
   871 *}
   872 
   873 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   874   by blast
   875 
   876 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   877   by blast
   878 
   879 lemma SigmaE2:
   880     "[| (a, b) : Sigma A B;
   881         [| a:A;  b:B(a) |] ==> P
   882      |] ==> P"
   883   by blast
   884 
   885 lemma Sigma_cong:
   886      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   887       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   888   by auto
   889 
   890 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   891   by blast
   892 
   893 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   894   by blast
   895 
   896 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   897   by blast
   898 
   899 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   900   by auto
   901 
   902 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   903   by auto
   904 
   905 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   906   by auto
   907 
   908 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   909   by blast
   910 
   911 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   912   by blast
   913 
   914 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   915   by (blast elim: equalityE)
   916 
   917 lemma SetCompr_Sigma_eq:
   918     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   919   by blast
   920 
   921 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   922   by blast
   923 
   924 lemma UN_Times_distrib:
   925   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   926   -- {* Suggested by Pierre Chartier *}
   927   by blast
   928 
   929 lemma split_paired_Ball_Sigma [simp,noatp]:
   930     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   931   by blast
   932 
   933 lemma split_paired_Bex_Sigma [simp,noatp]:
   934     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   935   by blast
   936 
   937 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   938   by blast
   939 
   940 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   941   by blast
   942 
   943 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   944   by blast
   945 
   946 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   947   by blast
   948 
   949 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   950   by blast
   951 
   952 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   953   by blast
   954 
   955 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   956   by blast
   957 
   958 text {*
   959   Non-dependent versions are needed to avoid the need for higher-order
   960   matching, especially when the rules are re-oriented.
   961 *}
   962 
   963 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   964 by blast
   965 
   966 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   967 by blast
   968 
   969 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   970 by blast
   971 
   972 lemma insert_times_insert[simp]:
   973   "insert a A \<times> insert b B =
   974    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
   975 by blast
   976 
   977 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
   978   by (auto, rule_tac p = "f x" in PairE, auto)
   979 
   980 subsubsection {* Code generator setup *}
   981 
   982 lemma [code]:
   983   "eq_class.eq (x1\<Colon>'a\<Colon>eq, y1\<Colon>'b\<Colon>eq) (x2, y2) \<longleftrightarrow> x1 = x2 \<and> y1 = y2" by (simp add: eq)
   984 
   985 lemma split_case_cert:
   986   assumes "CASE \<equiv> split f"
   987   shows "CASE (a, b) \<equiv> f a b"
   988   using assms by simp
   989 
   990 setup {*
   991   Code.add_case @{thm split_case_cert}
   992 *}
   993 
   994 code_type *
   995   (SML infix 2 "*")
   996   (OCaml infix 2 "*")
   997   (Haskell "!((_),/ (_))")
   998 
   999 code_instance * :: eq
  1000   (Haskell -)
  1001 
  1002 code_const "eq_class.eq \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
  1003   (Haskell infixl 4 "==")
  1004 
  1005 code_const Pair
  1006   (SML "!((_),/ (_))")
  1007   (OCaml "!((_),/ (_))")
  1008   (Haskell "!((_),/ (_))")
  1009 
  1010 code_const fst and snd
  1011   (Haskell "fst" and "snd")
  1012 
  1013 types_code
  1014   "*"     ("(_ */ _)")
  1015 attach (term_of) {*
  1016 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
  1017 *}
  1018 attach (test) {*
  1019 fun gen_id_42 aG aT bG bT i =
  1020   let
  1021     val (x, t) = aG i;
  1022     val (y, u) = bG i
  1023   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
  1024 *}
  1025 
  1026 consts_code
  1027   "Pair"    ("(_,/ _)")
  1028 
  1029 setup {*
  1030 
  1031 let
  1032 
  1033 fun strip_abs_split 0 t = ([], t)
  1034   | strip_abs_split i (Abs (s, T, t)) =
  1035       let
  1036         val s' = Codegen.new_name t s;
  1037         val v = Free (s', T)
  1038       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
  1039   | strip_abs_split i (u as Const ("split", _) $ t) = (case strip_abs_split (i+1) t of
  1040         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
  1041       | _ => ([], u))
  1042   | strip_abs_split i t =
  1043       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
  1044 
  1045 fun let_codegen thy defs dep thyname brack t gr = (case strip_comb t of
  1046     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
  1047     let
  1048       fun dest_let (l as Const ("Let", _) $ t $ u) =
  1049           (case strip_abs_split 1 u of
  1050              ([p], u') => apfst (cons (p, t)) (dest_let u')
  1051            | _ => ([], l))
  1052         | dest_let t = ([], t);
  1053       fun mk_code (l, r) gr =
  1054         let
  1055           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
  1056           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
  1057         in ((pl, pr), gr2) end
  1058     in case dest_let (t1 $ t2 $ t3) of
  1059         ([], _) => NONE
  1060       | (ps, u) =>
  1061           let
  1062             val (qs, gr1) = fold_map mk_code ps gr;
  1063             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
  1064             val (pargs, gr3) = fold_map
  1065               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
  1066           in
  1067             SOME (Codegen.mk_app brack
  1068               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
  1069                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
  1070                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
  1071                        Pretty.brk 1, pr]]) qs))),
  1072                 Pretty.brk 1, Codegen.str "in ", pu,
  1073                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
  1074           end
  1075     end
  1076   | _ => NONE);
  1077 
  1078 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
  1079     (t1 as Const ("split", _), t2 :: ts) =>
  1080       let
  1081         val ([p], u) = strip_abs_split 1 (t1 $ t2);
  1082         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
  1083         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
  1084         val (pargs, gr3) = fold_map
  1085           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
  1086       in
  1087         SOME (Codegen.mk_app brack
  1088           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
  1089             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
  1090       end
  1091   | _ => NONE);
  1092 
  1093 in
  1094 
  1095   Codegen.add_codegen "let_codegen" let_codegen
  1096   #> Codegen.add_codegen "split_codegen" split_codegen
  1097 
  1098 end
  1099 *}
  1100 
  1101 
  1102 subsection {* Legacy bindings *}
  1103 
  1104 ML {*
  1105 val Collect_split = thm "Collect_split";
  1106 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
  1107 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
  1108 val PairE = thm "PairE";
  1109 val Pair_Rep_inject = thm "Pair_Rep_inject";
  1110 val Pair_def = thm "Pair_def";
  1111 val Pair_eq = @{thm "prod.inject"};
  1112 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
  1113 val ProdI = thm "ProdI";
  1114 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
  1115 val SigmaD1 = thm "SigmaD1";
  1116 val SigmaD2 = thm "SigmaD2";
  1117 val SigmaE = thm "SigmaE";
  1118 val SigmaE2 = thm "SigmaE2";
  1119 val SigmaI = thm "SigmaI";
  1120 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
  1121 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
  1122 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
  1123 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
  1124 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
  1125 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
  1126 val Sigma_Union = thm "Sigma_Union";
  1127 val Sigma_def = thm "Sigma_def";
  1128 val Sigma_empty1 = thm "Sigma_empty1";
  1129 val Sigma_empty2 = thm "Sigma_empty2";
  1130 val Sigma_mono = thm "Sigma_mono";
  1131 val The_split = thm "The_split";
  1132 val The_split_eq = thm "The_split_eq";
  1133 val The_split_eq = thm "The_split_eq";
  1134 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
  1135 val Times_Int_distrib1 = thm "Times_Int_distrib1";
  1136 val Times_Un_distrib1 = thm "Times_Un_distrib1";
  1137 val Times_eq_cancel2 = thm "Times_eq_cancel2";
  1138 val Times_subset_cancel2 = thm "Times_subset_cancel2";
  1139 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
  1140 val UN_Times_distrib = thm "UN_Times_distrib";
  1141 val Unity_def = thm "Unity_def";
  1142 val cond_split_eta = thm "cond_split_eta";
  1143 val fst_conv = thm "fst_conv";
  1144 val fst_def = thm "fst_def";
  1145 val fst_eqD = thm "fst_eqD";
  1146 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
  1147 val mem_Sigma_iff = thm "mem_Sigma_iff";
  1148 val mem_splitE = thm "mem_splitE";
  1149 val mem_splitI = thm "mem_splitI";
  1150 val mem_splitI2 = thm "mem_splitI2";
  1151 val prod_eqI = thm "prod_eqI";
  1152 val prod_fun = thm "prod_fun";
  1153 val prod_fun_compose = thm "prod_fun_compose";
  1154 val prod_fun_def = thm "prod_fun_def";
  1155 val prod_fun_ident = thm "prod_fun_ident";
  1156 val prod_fun_imageE = thm "prod_fun_imageE";
  1157 val prod_fun_imageI = thm "prod_fun_imageI";
  1158 val prod_induct = thm "prod.induct";
  1159 val snd_conv = thm "snd_conv";
  1160 val snd_def = thm "snd_def";
  1161 val snd_eqD = thm "snd_eqD";
  1162 val split = thm "split";
  1163 val splitD = thm "splitD";
  1164 val splitD' = thm "splitD'";
  1165 val splitE = thm "splitE";
  1166 val splitE' = thm "splitE'";
  1167 val splitE2 = thm "splitE2";
  1168 val splitI = thm "splitI";
  1169 val splitI2 = thm "splitI2";
  1170 val splitI2' = thm "splitI2'";
  1171 val split_beta = thm "split_beta";
  1172 val split_conv = thm "split_conv";
  1173 val split_def = thm "split_def";
  1174 val split_eta = thm "split_eta";
  1175 val split_eta_SetCompr = thm "split_eta_SetCompr";
  1176 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
  1177 val split_paired_All = thm "split_paired_All";
  1178 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
  1179 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
  1180 val split_paired_Ex = thm "split_paired_Ex";
  1181 val split_paired_The = thm "split_paired_The";
  1182 val split_paired_all = thm "split_paired_all";
  1183 val split_part = thm "split_part";
  1184 val split_split = thm "split_split";
  1185 val split_split_asm = thm "split_split_asm";
  1186 val split_tupled_all = thms "split_tupled_all";
  1187 val split_weak_cong = thm "split_weak_cong";
  1188 val surj_pair = thm "surj_pair";
  1189 val surjective_pairing = thm "surjective_pairing";
  1190 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
  1191 val unit_all_eq1 = thm "unit_all_eq1";
  1192 val unit_all_eq2 = thm "unit_all_eq2";
  1193 val unit_eq = thm "unit_eq";
  1194 *}
  1195 
  1196 use "Tools/inductive_set.ML"
  1197 setup Inductive_Set.setup
  1198 
  1199 end