src/Pure/library.ML
author nipkow
Sun Jan 21 13:26:44 2007 +0100 (2007-01-21)
changeset 22142 2b54aa7586e2
parent 21962 279b129498b6
child 22256 23f3ca04d3b3
permissions -rw-r--r--
Added lists-as-multisets functions
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    27   val ? : bool * ('a -> 'a) -> 'a -> 'a
    28   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    29   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    30   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    31   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    32 
    33   (*exceptions*)
    34   exception EXCEPTION of exn * string
    35   val do_transform_failure: bool ref
    36   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    37   datatype 'a result = Result of 'a | Exn of exn
    38   val capture: ('a -> 'b) -> 'a -> 'b result
    39   val release: 'a result -> 'a
    40   val get_result: 'a result -> 'a option
    41   val get_exn: 'a result -> exn option
    42 
    43   (*errors*)
    44   exception SYS_ERROR of string
    45   val sys_error: string -> 'a
    46   exception ERROR of string
    47   val error: string -> 'a
    48   val cat_error: string -> string -> 'a
    49   val assert: bool -> string -> unit
    50   val deny: bool -> string -> unit
    51   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    52 
    53   (*pairs*)
    54   val pair: 'a -> 'b -> 'a * 'b
    55   val rpair: 'a -> 'b -> 'b * 'a
    56   val fst: 'a * 'b -> 'a
    57   val snd: 'a * 'b -> 'b
    58   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    59   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    60   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78 
    79   (*lists*)
    80   exception UnequalLengths
    81   val single: 'a -> 'a list
    82   val the_single: 'a list -> 'a
    83   val singleton: ('a list -> 'b list) -> 'a -> 'b
    84   val apply: ('a -> 'a) list -> 'a -> 'a
    85   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    86   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    87   val flat: 'a list list -> 'a list
    88   val unflat: 'a list list -> 'b list -> 'b list list
    89   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    90   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    91   val maps: ('a -> 'b list) -> 'a list -> 'b list
    92   val chop: int -> 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val nth: 'a list -> int -> 'a
    95   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    96   val nth_list: 'a list list -> int -> 'a list
    97   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    98   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val split_last: 'a list -> 'a list * 'a
   100   val find_index: ('a -> bool) -> 'a list -> int
   101   val find_index_eq: ''a -> ''a list -> int
   102   val find_first: ('a -> bool) -> 'a list -> 'a option
   103   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   104   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   105   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   106   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   107   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   108   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   109   val ~~ : 'a list * 'b list -> ('a * 'b) list
   110   val split_list: ('a * 'b) list -> 'a list * 'b list
   111   val separate: 'a -> 'a list -> 'a list
   112   val replicate: int -> 'a -> 'a list
   113   val multiply: 'a list -> 'a list list -> 'a list list
   114   val product: 'a list -> 'b list -> ('a * 'b) list
   115   val filter: ('a -> bool) -> 'a list -> 'a list
   116   val filter_out: ('a -> bool) -> 'a list -> 'a list
   117   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   118   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   119   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   120   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   121   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   122   val prefixes1: 'a list -> 'a list list
   123   val prefixes: 'a list -> 'a list list
   124   val suffixes1: 'a list -> 'a list list
   125   val suffixes: 'a list -> 'a list list
   126 
   127   (*integers*)
   128   val gcd: IntInf.int * IntInf.int -> IntInf.int
   129   val lcm: IntInf.int * IntInf.int -> IntInf.int
   130   val inc: int ref -> int
   131   val dec: int ref -> int
   132   val upto: int * int -> int list
   133   val downto: int * int -> int list
   134   val downto0: int list * int -> bool
   135   val radixpand: int * int -> int list
   136   val radixstring: int * string * int -> string
   137   val string_of_int: int -> string
   138   val signed_string_of_int: int -> string
   139   val string_of_indexname: string * int -> string
   140   val read_intinf: int -> string list -> IntInf.int * string list
   141   val read_int: string list -> int * string list
   142   val oct_char: string -> string
   143 
   144   (*strings*)
   145   val nth_string: string -> int -> string
   146   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   147   val exists_string: (string -> bool) -> string -> bool
   148   val forall_string: (string -> bool) -> string -> bool
   149   val enclose: string -> string -> string -> string
   150   val unenclose: string -> string
   151   val quote: string -> string
   152   val space_implode: string -> string list -> string
   153   val commas: string list -> string
   154   val commas_quote: string list -> string
   155   val cat_lines: string list -> string
   156   val space_explode: string -> string -> string list
   157   val split_lines: string -> string list
   158   val prefix_lines: string -> string -> string
   159   val untabify: string list -> string list
   160   val prefix: string -> string -> string
   161   val suffix: string -> string -> string
   162   val unprefix: string -> string -> string
   163   val unsuffix: string -> string -> string
   164   val replicate_string: int -> string -> string
   165   val translate_string: (string -> string) -> string -> string
   166 
   167   (*lists as sets -- see also Pure/General/ord_list.ML*)
   168   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   169   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   170   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   171   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   172   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   173   val mem: ''a * ''a list -> bool
   174   val mem_int: int * int list -> bool
   175   val mem_string: string * string list -> bool
   176   val union: ''a list * ''a list -> ''a list
   177   val union_int: int list * int list -> int list
   178   val union_string: string list * string list -> string list
   179   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   180   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   181   val inter: ''a list * ''a list -> ''a list
   182   val inter_int: int list * int list -> int list
   183   val inter_string: string list * string list -> string list
   184   val subset: ''a list * ''a list -> bool
   185   val subset_int: int list * int list -> bool
   186   val subset_string: string list * string list -> bool
   187   val eq_set: ''a list * ''a list -> bool
   188   val eq_set_string: string list * string list -> bool
   189   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   190   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   191   val \ : ''a list * ''a -> ''a list
   192   val \\ : ''a list * ''a list -> ''a list
   193   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   194   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   195   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   196 
   197   (* lists as multisets *)
   198   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   199   val gen_submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   200 
   201   (*lists as tables -- see also Pure/General/alist.ML*)
   202   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   203   val merge_lists: ''a list -> ''a list -> ''a list
   204   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   205 
   206   (*balanced trees*)
   207   exception Balance
   208   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   209   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   210   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   211 
   212   (*orders*)
   213   val is_equal: order -> bool
   214   val rev_order: order -> order
   215   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   216   val int_ord: int * int -> order
   217   val string_ord: string * string -> order
   218   val fast_string_ord: string * string -> order
   219   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   220   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   221   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   222   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   223   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   224   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   225   val sort_strings: string list -> string list
   226   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   227 
   228   (*random numbers*)
   229   exception RANDOM
   230   val random: unit -> real
   231   val random_range: int -> int -> int
   232   val one_of: 'a list -> 'a
   233   val frequency: (int * 'a) list -> 'a
   234 
   235   (*current directory*)
   236   val cd: string -> unit
   237   val pwd: unit -> string
   238 
   239   (*misc*)
   240   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   241   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   242   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   243   val gensym: string -> string
   244   val scanwords: (string -> bool) -> string list -> string list
   245   type stamp
   246   val stamp: unit -> stamp
   247   type serial
   248   val serial: unit -> serial
   249   val serial_string: unit -> string
   250   structure Object: sig type T end
   251 end;
   252 
   253 signature LIBRARY =
   254 sig
   255   include BASIC_LIBRARY
   256   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   257   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   258   val take: int * 'a list -> 'a list
   259   val drop: int * 'a list -> 'a list
   260   val last_elem: 'a list -> 'a
   261   val seq: ('a -> unit) -> 'a list -> unit
   262 end;
   263 
   264 structure Library: LIBRARY =
   265 struct
   266 
   267 (* functions *)
   268 
   269 fun I x = x;
   270 fun K x = fn _ => x;
   271 fun curry f x y = f (x, y);
   272 fun uncurry f (x, y) = f x y;
   273 
   274 (*application and structured results -- old version*)
   275 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   276 
   277 (*conditional application*)
   278 fun b ? f = fn x => if b then f x else x;
   279 
   280 (*composition with multiple args*)
   281 fun (f oo g) x y = f (g x y);
   282 fun (f ooo g) x y z = f (g x y z);
   283 fun (f oooo g) x y z w = f (g x y z w);
   284 
   285 (*function exponentiation: f(...(f x)...) with n applications of f*)
   286 fun funpow n f x =
   287   let fun rep (0, x) = x
   288         | rep (n, x) = rep (n - 1, f x)
   289   in rep (n, x) end;
   290 
   291 
   292 (* exceptions *)
   293 
   294 val do_transform_failure = ref true;
   295 
   296 fun transform_failure exn f x =
   297   if ! do_transform_failure then
   298     f x handle Interrupt => raise Interrupt | e => raise exn e
   299   else f x;
   300 
   301 exception EXCEPTION of exn * string;
   302 
   303 datatype 'a result =
   304   Result of 'a |
   305   Exn of exn;
   306 
   307 fun capture f x = Result (f x) handle e => Exn e;
   308 
   309 fun release (Result y) = y
   310   | release (Exn e) = raise e;
   311 
   312 fun get_result (Result x) = SOME x
   313   | get_result _ = NONE;
   314 
   315 fun get_exn (Exn exn) = SOME exn
   316   | get_exn _ = NONE;
   317 
   318 
   319 (* errors *)
   320 
   321 exception SYS_ERROR of string;
   322 fun sys_error msg = raise SYS_ERROR msg;
   323 
   324 exception ERROR of string;
   325 fun error msg = raise ERROR msg;
   326 
   327 fun cat_error "" msg = error msg
   328   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   329 
   330 fun assert p msg = if p then () else error msg;
   331 fun deny p msg = if p then error msg else ();
   332 
   333 fun assert_all pred list msg =
   334   let
   335     fun ass [] = ()
   336       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   337   in ass list end;
   338 
   339 
   340 (* pairs *)
   341 
   342 fun pair x y = (x, y);
   343 fun rpair x y = (y, x);
   344 
   345 fun fst (x, y) = x;
   346 fun snd (x, y) = y;
   347 
   348 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   349 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   350 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   351 
   352 fun swap (x, y) = (y, x);
   353 
   354 (*apply function to components*)
   355 fun apfst f (x, y) = (f x, y);
   356 fun apsnd f (x, y) = (x, f y);
   357 fun pairself f (x, y) = (f x, f y);
   358 
   359 
   360 (* booleans *)
   361 
   362 (*polymorphic equality*)
   363 fun equal x y = x = y;
   364 fun not_equal x y = x <> y;
   365 
   366 (*combining predicates*)
   367 fun p orf q = fn x => p x orelse q x;
   368 fun p andf q = fn x => p x andalso q x;
   369 
   370 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   371 fun exists (pred: 'a -> bool) : 'a list -> bool =
   372   let fun boolf [] = false
   373         | boolf (x :: xs) = pred x orelse boolf xs
   374   in boolf end;
   375 
   376 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   377 fun forall (pred: 'a -> bool) : 'a list -> bool =
   378   let fun boolf [] = true
   379         | boolf (x :: xs) = pred x andalso boolf xs
   380   in boolf end;
   381 
   382 
   383 (* flags *)
   384 
   385 fun set flag = (flag := true; true);
   386 fun reset flag = (flag := false; false);
   387 fun toggle flag = (flag := not (! flag); ! flag);
   388 
   389 fun change r f = r := f (! r);
   390 
   391 (*temporarily set flag during execution*)
   392 fun setmp flag value f x =
   393   let
   394     val orig_value = ! flag;
   395     val _ = flag := value;
   396     val result = capture f x;
   397     val _ = flag := orig_value;
   398   in release result end;
   399 
   400 
   401 
   402 (** lists **)
   403 
   404 exception UnequalLengths;
   405 
   406 fun single x = [x];
   407 
   408 fun the_single [x] = x
   409   | the_single _ = raise Empty;
   410 
   411 fun singleton f x = the_single (f [x]);
   412 
   413 fun apply [] x = x
   414   | apply (f :: fs) x = apply fs (f x);
   415 
   416 
   417 (* fold -- old versions *)
   418 
   419 (*the following versions of fold are designed to fit nicely with infixes*)
   420 
   421 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   422     for operators that associate to the left (TAIL RECURSIVE)*)
   423 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   424   let fun itl (e, [])  = e
   425         | itl (e, a::l) = itl (f(e, a), l)
   426   in  itl end;
   427 
   428 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   429     for operators that associate to the right (not tail recursive)*)
   430 fun foldr f (l, e) =
   431   let fun itr [] = e
   432         | itr (a::l) = f(a, itr l)
   433   in  itr l  end;
   434 
   435 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   436     for n > 0, operators that associate to the right (not tail recursive)*)
   437 fun foldr1 f [] = raise Empty
   438   | foldr1 f l =
   439       let fun itr [x] = x
   440             | itr (x::l) = f(x, itr l)
   441       in  itr l  end;
   442 
   443 fun foldl_map f =
   444   let
   445     fun fold_aux (x, []) = (x, [])
   446       | fold_aux (x, y :: ys) =
   447           let
   448             val (x', y') = f (x, y);
   449             val (x'', ys') = fold_aux (x', ys);
   450           in (x'', y' :: ys') end;
   451   in fold_aux end;
   452 
   453 
   454 (* basic list functions *)
   455 
   456 fun eq_list eq (list1, list2) =
   457   let
   458     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   459       | eq_lst _ = true;
   460   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   461 
   462 fun maps f [] = []
   463   | maps f (x :: xs) = f x @ maps f xs;
   464 
   465 fun chop n xs = unfold_rev n dest xs;
   466 
   467 (*take the first n elements from a list*)
   468 fun take (n, []) = []
   469   | take (n, x :: xs) =
   470       if n > 0 then x :: take (n - 1, xs) else [];
   471 
   472 (*drop the first n elements from a list*)
   473 fun drop (n, []) = []
   474   | drop (n, x :: xs) =
   475       if n > 0 then drop (n - 1, xs) else x :: xs;
   476 
   477 fun dropwhile P [] = []
   478   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   479 
   480 (*return nth element of a list, where 0 designates the first element;
   481   raise Subscript if list too short*)
   482 fun nth xs i = List.nth (xs, i);
   483 
   484 fun nth_list xss i = nth xss i handle Subscript => [];
   485 
   486 fun nth_map 0 f (x :: xs) = f x :: xs
   487   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   488   | nth_map _ _ [] = raise Subscript;
   489 
   490 fun map_index f =
   491   let
   492     fun mapp _ [] = []
   493       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   494   in mapp 0 end;
   495 
   496 fun fold_index f =
   497   let
   498     fun fold_aux _ [] y = y
   499       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   500   in fold_aux 0 end;
   501 
   502 val last_elem = List.last;
   503 
   504 (*rear decomposition*)
   505 fun split_last [] = raise Empty
   506   | split_last [x] = ([], x)
   507   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   508 
   509 (*find the position of an element in a list*)
   510 fun find_index pred =
   511   let fun find _ [] = ~1
   512         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   513   in find 0 end;
   514 
   515 fun find_index_eq x = find_index (equal x);
   516 
   517 (*find first element satisfying predicate*)
   518 fun find_first _ [] = NONE
   519   | find_first pred (x :: xs) =
   520       if pred x then SOME x else find_first pred xs;
   521 
   522 (*get first element by lookup function*)
   523 fun get_first _ [] = NONE
   524   | get_first f (x :: xs) =
   525       (case f x of
   526         NONE => get_first f xs
   527       | some => some);
   528 
   529 fun get_index f =
   530   let
   531     fun get _ [] = NONE
   532       | get i (x :: xs) =
   533           case f x
   534            of NONE => get (i + 1) xs
   535             | SOME y => SOME (i, y)
   536   in get 0 end;
   537 
   538 val flat = List.concat;
   539 
   540 fun unflat (xs :: xss) ys =
   541       let val (ps, qs) = chop (length xs) ys
   542       in ps :: unflat xss qs end
   543   | unflat [] [] = []
   544   | unflat _ _ = raise UnequalLengths;
   545 
   546 fun burrow f xss = unflat xss (f (flat xss));
   547 
   548 fun fold_burrow f xss s =
   549   apfst (unflat xss) (f (flat xss) s);
   550 
   551 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   552   (proc x1; ...; proc xn) for side effects*)
   553 val seq = List.app;
   554 
   555 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   556 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   557   | separate _ xs = xs;
   558 
   559 (*make the list [x, x, ..., x] of length n*)
   560 fun replicate n (x: 'a) : 'a list =
   561   let fun rep (0, xs) = xs
   562         | rep (n, xs) = rep (n - 1, x :: xs)
   563   in
   564     if n < 0 then raise Subscript
   565     else rep (n, [])
   566   end;
   567 
   568 fun translate_string f = String.translate (f o String.str);
   569 
   570 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   571 fun multiply [] _ = []
   572   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   573 
   574 (*direct product*)
   575 fun product _ [] = []
   576   | product [] _ = []
   577   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   578 
   579 
   580 (* filter *)
   581 
   582 (*copy the list preserving elements that satisfy the predicate*)
   583 val filter = List.filter;
   584 fun filter_out f = filter (not o f);
   585 val map_filter = List.mapPartial;
   586 
   587 
   588 (* lists of pairs *)
   589 
   590 exception UnequalLengths;
   591 
   592 fun map2 _ [] [] = []
   593   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   594   | map2 _ _ _ = raise UnequalLengths;
   595 
   596 fun fold2 f =
   597   let
   598     fun fold_aux [] [] z = z
   599       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   600       | fold_aux _ _ _ = raise UnequalLengths;
   601   in fold_aux end;
   602 
   603 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   604   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   605   | zip_options _ [] = []
   606   | zip_options [] _ = raise UnequalLengths;
   607 
   608 (*combine two lists forming a list of pairs:
   609   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   610 fun [] ~~ [] = []
   611   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   612   | _ ~~ _ = raise UnequalLengths;
   613 
   614 (*inverse of ~~; the old 'split':
   615   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   616 val split_list = ListPair.unzip;
   617 
   618 
   619 (* prefixes, suffixes *)
   620 
   621 fun is_prefix _ [] _ = true
   622   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   623   | is_prefix eq _ _ = false;
   624 
   625 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   626    where xi is the first element that does not satisfy the predicate*)
   627 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   628   let fun take (rxs, []) = (rev rxs, [])
   629         | take (rxs, x :: xs) =
   630             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   631   in  take([], xs)  end;
   632 
   633 fun chop_prefix eq ([], ys) = ([], ([], ys))
   634   | chop_prefix eq (xs, []) = ([], (xs, []))
   635   | chop_prefix eq (xs as x::xs', ys as y::ys') =
   636       if eq (x, y) then
   637         let val (ps', xys'') = chop_prefix eq (xs', ys')
   638         in (x::ps', xys'') end
   639       else ([], (xs, ys));
   640 
   641 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   642    where xi is the last element that does not satisfy the predicate*)
   643 fun take_suffix _ [] = ([], [])
   644   | take_suffix pred (x :: xs) =
   645       (case take_suffix pred xs of
   646         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   647       | (prfx, sffx) => (x :: prfx, sffx));
   648 
   649 fun prefixes1 [] = []
   650   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   651 
   652 fun prefixes xs = [] :: prefixes1 xs;
   653 
   654 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   655 fun suffixes xs = [] :: suffixes1 xs;
   656 
   657 (** integers **)
   658 
   659 fun gcd (x, y) =
   660   let fun gxd x y : IntInf.int =
   661     if y = IntInf.fromInt 0 then x else gxd y (x mod y)
   662   in if x < y then gxd y x else gxd x y end;
   663 
   664 fun lcm (x, y) = (x * y) div gcd (x, y);
   665 
   666 fun inc i = (i := ! i + 1; ! i);
   667 fun dec i = (i := ! i - 1; ! i);
   668 
   669 
   670 (* lists of integers *)
   671 
   672 (*make the list [from, from + 1, ..., to]*)
   673 fun (i upto j) =
   674   if i > j then [] else i :: (i + 1 upto j);
   675 
   676 (*make the list [from, from - 1, ..., to]*)
   677 fun (i downto j) =
   678   if i < j then [] else i :: (i - 1 downto j);
   679 
   680 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   681 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   682   | downto0 ([], n) = n = ~1;
   683 
   684 
   685 (* convert integers to strings *)
   686 
   687 (*expand the number in the given base;
   688   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   689 fun radixpand (base, num) : int list =
   690   let
   691     fun radix (n, tail) =
   692       if n < base then n :: tail
   693       else radix (n div base, (n mod base) :: tail)
   694   in radix (num, []) end;
   695 
   696 (*expands a number into a string of characters starting from "zerochar";
   697   example: radixstring (2, "0", 8) gives "1000"*)
   698 fun radixstring (base, zerochar, num) =
   699   let val offset = ord zerochar;
   700       fun chrof n = chr (offset + n)
   701   in implode (map chrof (radixpand (base, num))) end;
   702 
   703 
   704 val string_of_int = Int.toString;
   705 
   706 fun signed_string_of_int i =
   707   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   708 
   709 fun string_of_indexname (a,0) = a
   710   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   711 
   712 
   713 (* read integers *)
   714 
   715 fun read_intinf radix cs =
   716   let
   717     val zero = ord "0";
   718     val limit = zero + radix;
   719     fun scan (num, []) = (num, [])
   720       | scan (num, c :: cs) =
   721         if zero <= ord c andalso ord c < limit then
   722           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   723         else (num, c :: cs);
   724   in scan (IntInf.fromInt 0, cs) end;
   725 
   726 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   727 
   728 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   729 
   730 
   731 
   732 (** strings **)
   733 
   734 (* functions tuned for strings, avoiding explode *)
   735 
   736 fun nth_string str i =
   737   (case try String.substring (str, i, 1) of
   738     SOME s => s
   739   | NONE => raise Subscript);
   740 
   741 fun fold_string f str x0 =
   742   let
   743     val n = size str;
   744     fun iter (x, i) =
   745       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   746   in iter (x0, 0) end;
   747 
   748 fun exists_string pred str =
   749   let
   750     val n = size str;
   751     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   752   in ex 0 end;
   753 
   754 fun forall_string pred = not o exists_string (not o pred);
   755 
   756 (*enclose in brackets*)
   757 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   758 fun unenclose str = String.substring (str, 1, size str - 2);
   759 
   760 (*simple quoting (does not escape special chars)*)
   761 val quote = enclose "\"" "\"";
   762 
   763 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   764 fun space_implode a bs = implode (separate a bs);
   765 
   766 val commas = space_implode ", ";
   767 val commas_quote = commas o map quote;
   768 
   769 (*concatenate messages, one per line, into a string*)
   770 val cat_lines = space_implode "\n";
   771 
   772 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   773 fun space_explode _ "" = []
   774   | space_explode sep s = String.fields (fn c => str c = sep) s;
   775 
   776 val split_lines = space_explode "\n";
   777 
   778 fun prefix_lines "" txt = txt
   779   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   780 
   781 fun untabify chs =
   782   let
   783     val tab_width = 8;
   784 
   785     fun untab (_, "\n") = (0, ["\n"])
   786       | untab (pos, "\t") =
   787           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   788       | untab (pos, c) = (pos + 1, [c]);
   789   in
   790     if not (exists (fn c => c = "\t") chs) then chs
   791     else flat (#2 (foldl_map untab (0, chs)))
   792   end;
   793 
   794 fun prefix prfx s = prfx ^ s;
   795 fun suffix sffx s = s ^ sffx;
   796 
   797 fun unprefix prfx s =
   798   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   799   else raise Fail "unprefix";
   800 
   801 fun unsuffix sffx s =
   802   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   803   else raise Fail "unsuffix";
   804 
   805 fun replicate_string 0 _ = ""
   806   | replicate_string 1 a = a
   807   | replicate_string k a =
   808       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   809       else replicate_string (k div 2) (a ^ a) ^ a;
   810 
   811 
   812 (** lists as sets -- see also Pure/General/ord_list.ML **)
   813 
   814 (*canonical member, insert, remove*)
   815 fun member eq list x =
   816   let
   817     fun memb [] = false
   818       | memb (y :: ys) = eq (x, y) orelse memb ys;
   819   in memb list end;
   820 
   821 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   822 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   823 
   824 fun subtract eq = fold (remove eq);
   825 
   826 fun merge _ ([], ys) = ys
   827   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   828 
   829 (*old-style infixes*)
   830 fun x mem xs = member (op =) xs x;
   831 fun (x: int) mem_int xs = member (op =) xs x;
   832 fun (x: string) mem_string xs = member (op =) xs x;
   833 
   834 
   835 (*union of sets represented as lists: no repetitions*)
   836 fun xs union [] = xs
   837   | [] union ys = ys
   838   | (x :: xs) union ys = xs union (insert (op =) x ys);
   839 
   840 (*union of sets, optimized version for ints*)
   841 fun (xs:int list) union_int [] = xs
   842   | [] union_int ys = ys
   843   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   844 
   845 (*union of sets, optimized version for strings*)
   846 fun (xs:string list) union_string [] = xs
   847   | [] union_string ys = ys
   848   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   849 
   850 (*generalized union*)
   851 fun gen_union eq (xs, []) = xs
   852   | gen_union eq ([], ys) = ys
   853   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   854 
   855 
   856 (*intersection*)
   857 fun [] inter ys = []
   858   | (x :: xs) inter ys =
   859       if x mem ys then x :: (xs inter ys) else xs inter ys;
   860 
   861 (*intersection, optimized version for ints*)
   862 fun ([]:int list) inter_int ys = []
   863   | (x :: xs) inter_int ys =
   864       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   865 
   866 (*intersection, optimized version for strings *)
   867 fun ([]:string list) inter_string ys = []
   868   | (x :: xs) inter_string ys =
   869       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   870 
   871 (*generalized intersection*)
   872 fun gen_inter eq ([], ys) = []
   873   | gen_inter eq (x::xs, ys) =
   874       if member eq ys x then x :: gen_inter eq (xs, ys)
   875       else gen_inter eq (xs, ys);
   876 
   877 
   878 (*subset*)
   879 fun [] subset ys = true
   880   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   881 
   882 (*subset, optimized version for ints*)
   883 fun ([]: int list) subset_int ys = true
   884   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   885 
   886 (*subset, optimized version for strings*)
   887 fun ([]: string list) subset_string ys = true
   888   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   889 
   890 (*set equality*)
   891 fun eq_set (xs, ys) =
   892   xs = ys orelse (xs subset ys andalso ys subset xs);
   893 
   894 (*set equality for strings*)
   895 fun eq_set_string ((xs: string list), ys) =
   896   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   897 
   898 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   899 
   900 fun gen_eq_set eq (xs, ys) =
   901   eq_list eq (xs, ys) orelse
   902     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   903 
   904 
   905 (*removing an element from a list WITHOUT duplicates*)
   906 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   907   | [] \ x = [];
   908 fun ys \\ xs = foldl (op \) (ys,xs);
   909 
   910 
   911 (*makes a list of the distinct members of the input; preserves order, takes
   912   first of equal elements*)
   913 fun distinct eq lst =
   914   let
   915     fun dist (rev_seen, []) = rev rev_seen
   916       | dist (rev_seen, x :: xs) =
   917           if member eq rev_seen x then dist (rev_seen, xs)
   918           else dist (x :: rev_seen, xs);
   919   in dist ([], lst) end;
   920 
   921 (*returns a list containing all repeated elements exactly once; preserves
   922   order, takes first of equal elements*)
   923 fun duplicates eq lst =
   924   let
   925     fun dups (rev_dups, []) = rev rev_dups
   926       | dups (rev_dups, x :: xs) =
   927           if member eq rev_dups x orelse not (member eq xs x) then
   928             dups (rev_dups, xs)
   929           else dups (x :: rev_dups, xs);
   930   in dups ([], lst) end;
   931 
   932 fun has_duplicates eq =
   933   let
   934     fun dups [] = false
   935       | dups (x :: xs) = member eq xs x orelse dups xs;
   936   in dups end;
   937 
   938 
   939 (** lists as multisets **)
   940 
   941 fun remove1 _ _ [] = raise Empty
   942   | remove1 eq y (x::xs) = if eq(y,x) then xs else x :: remove1 eq y xs;
   943 
   944 fun gen_submultiset _  ([],    _)  = true
   945   | gen_submultiset eq (x::xs, ys) =
   946       member eq ys x  andalso  gen_submultiset eq (xs, remove1 eq x ys);
   947 
   948 
   949 (** association lists -- legacy operations **)
   950 
   951 fun gen_merge_lists _ xs [] = xs
   952   | gen_merge_lists _ [] ys = ys
   953   | gen_merge_lists eq xs ys = xs @ filter_out (member eq xs) ys;
   954 
   955 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
   956 fun merge_alists xs = gen_merge_lists (eq_fst (op =)) xs;
   957 
   958 
   959 (** balanced trees **)
   960 
   961 exception Balance;      (*indicates non-positive argument to balancing fun*)
   962 
   963 (*balanced folding; avoids deep nesting*)
   964 fun fold_bal f [x] = x
   965   | fold_bal f [] = raise Balance
   966   | fold_bal f xs =
   967       let val (ps, qs) = chop (length xs div 2) xs
   968       in  f (fold_bal f ps, fold_bal f qs)  end;
   969 
   970 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   971 fun access_bal (f, g, x) n i =
   972   let fun acc n i =     (*1<=i<=n*)
   973           if n=1 then x else
   974           let val n2 = n div 2
   975           in  if i<=n2 then f (acc n2 i)
   976                        else g (acc (n-n2) (i-n2))
   977           end
   978   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   979 
   980 (*construct ALL such accesses; could try harder to share recursive calls!*)
   981 fun accesses_bal (f, g, x) n =
   982   let fun acc n =
   983           if n=1 then [x] else
   984           let val n2 = n div 2
   985               val acc2 = acc n2
   986           in  if n-n2=n2 then map f acc2 @ map g acc2
   987                          else map f acc2 @ map g (acc (n-n2)) end
   988   in  if 1<=n then acc n else raise Balance  end;
   989 
   990 
   991 
   992 (** orders **)
   993 
   994 fun is_equal EQUAL = true
   995   | is_equal _ = false;
   996 
   997 fun rev_order LESS = GREATER
   998   | rev_order EQUAL = EQUAL
   999   | rev_order GREATER = LESS;
  1000 
  1001 (*assume rel is a linear strict order*)
  1002 fun make_ord rel (x, y) =
  1003   if rel (x, y) then LESS
  1004   else if rel (y, x) then GREATER
  1005   else EQUAL;
  1006 
  1007 val int_ord = Int.compare;
  1008 val string_ord = String.compare;
  1009 
  1010 fun fast_string_ord (s1, s2) =
  1011   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1012 
  1013 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1014   | option_ord _ (NONE, NONE) = EQUAL
  1015   | option_ord _ (NONE, SOME _) = LESS
  1016   | option_ord _ (SOME _, NONE) = GREATER;
  1017 
  1018 (*lexicographic product*)
  1019 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1020   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1021 
  1022 (*dictionary order -- in general NOT well-founded!*)
  1023 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1024       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1025   | dict_ord _ ([], []) = EQUAL
  1026   | dict_ord _ ([], _ :: _) = LESS
  1027   | dict_ord _ (_ :: _, []) = GREATER;
  1028 
  1029 (*lexicographic product of lists*)
  1030 fun list_ord elem_ord (xs, ys) =
  1031   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1032 
  1033 
  1034 (* sorting *)
  1035 
  1036 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1037 fun quicksort unique ord =
  1038   let
  1039     fun qsort [] = []
  1040       | qsort (xs as [_]) = xs
  1041       | qsort (xs as [x, y]) =
  1042           (case ord (x, y) of
  1043             LESS => xs
  1044           | EQUAL => if unique then [x] else xs
  1045           | GREATER => [y, x])
  1046       | qsort xs =
  1047           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1048           in qsort lts @ eqs @ qsort gts end
  1049     and part _ [] = ([], [], [])
  1050       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1051     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1052       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1053       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1054       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1055   in qsort end;
  1056 
  1057 fun sort ord = quicksort false ord;
  1058 fun sort_distinct ord = quicksort true ord;
  1059 
  1060 val sort_strings = sort string_ord;
  1061 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1062 
  1063 
  1064 
  1065 (** random numbers **)
  1066 
  1067 exception RANDOM;
  1068 
  1069 fun rmod x y = x - y * Real.realFloor (x / y);
  1070 
  1071 local
  1072   val a = 16807.0;
  1073   val m = 2147483647.0;
  1074   val random_seed = ref 1.0;
  1075 in
  1076 
  1077 fun random () =
  1078   let val r = rmod (a * !random_seed) m
  1079   in (random_seed := r; r) end;
  1080 
  1081 end;
  1082 
  1083 fun random_range l h =
  1084   if h < l orelse l < 0 then raise RANDOM
  1085   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1086 
  1087 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1088 
  1089 fun frequency xs =
  1090   let
  1091     val sum = foldl op + (0, map fst xs);
  1092     fun pick n ((k: int, x) :: xs) =
  1093       if n <= k then x else pick (n - k) xs
  1094   in pick (random_range 1 sum) xs end;
  1095 
  1096 
  1097 (** current directory **)
  1098 
  1099 val cd = OS.FileSys.chDir;
  1100 val pwd = OS.FileSys.getDir;
  1101 
  1102 
  1103 
  1104 (** misc **)
  1105 
  1106 fun divide_and_conquer decomp x =
  1107   let val (ys, recomb) = decomp x
  1108   in recomb (map (divide_and_conquer decomp) ys) end;
  1109 
  1110 
  1111 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1112    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1113 fun partition_list p i j =
  1114   let fun part k xs =
  1115             if k>j then
  1116               (case xs of [] => []
  1117                          | _ => raise Fail "partition_list")
  1118             else
  1119             let val (ns, rest) = List.partition (p k) xs;
  1120             in  ns :: part(k+1)rest  end
  1121   in  part i end;
  1122 
  1123 fun partition_eq (eq:'a * 'a -> bool) =
  1124   let
  1125     fun part [] = []
  1126       | part (x :: ys) =
  1127           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1128           in (x::xs)::(part xs') end
  1129   in part end;
  1130 
  1131 
  1132 
  1133 (* generating identifiers *)
  1134 
  1135 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1136 local
  1137 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1138 fun char i =      if i<26 then chr (ord "A" + i)
  1139              else if i<52 then chr (ord "a" + i - 26)
  1140              else if i<62 then chr (ord"0" + i - 52)
  1141              else if i=62 then "_"
  1142              else  (*i=63*)    "'";
  1143 
  1144 val charVec = Vector.tabulate (64, char);
  1145 
  1146 fun newid n =
  1147   let
  1148   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1149 
  1150 val seedr = ref 0;
  1151 
  1152 in
  1153 
  1154 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1155 
  1156 end;
  1157 
  1158 
  1159 (* lexical scanning *)
  1160 
  1161 (*scan a list of characters into "words" composed of "letters" (recognized by
  1162   is_let) and separated by any number of non-"letters"*)
  1163 fun scanwords is_let cs =
  1164   let fun scan1 [] = []
  1165         | scan1 cs =
  1166             let val (lets, rest) = take_prefix is_let cs
  1167             in implode lets :: scanwords is_let rest end;
  1168   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1169 
  1170 
  1171 (* stamps and serial numbers *)
  1172 
  1173 type stamp = unit ref;
  1174 val stamp: unit -> stamp = ref;
  1175 
  1176 type serial = int;
  1177 local val count = ref 0
  1178 in fun serial () = inc count end;
  1179 
  1180 val serial_string = string_of_int o serial;
  1181 
  1182 
  1183 (* generic objects *)
  1184 
  1185 (*note that the builtin exception datatype may be extended by new
  1186   constructors at any time*)
  1187 structure Object = struct type T = exn end;
  1188 
  1189 end;
  1190 
  1191 structure BasicLibrary: BASIC_LIBRARY = Library;
  1192 open BasicLibrary;