src/HOL/Auth/Message.thy
author paulson
Wed Jul 13 16:47:23 2005 +0200 (2005-07-13)
changeset 16818 2b82259cc7b2
parent 16796 140f1e0ea846
child 17689 a04b5b43625e
permissions -rw-r--r--
tidied
     1 (*  Title:      HOL/Auth/Message
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1996  University of Cambridge
     5 
     6 Datatypes of agents and messages;
     7 Inductive relations "parts", "analz" and "synth"
     8 *)
     9 
    10 header{*Theory of Agents and Messages for Security Protocols*}
    11 
    12 theory Message imports Main begin
    13 
    14 (*Needed occasionally with spy_analz_tac, e.g. in analz_insert_Key_newK*)
    15 lemma [simp] : "A \<union> (B \<union> A) = B \<union> A"
    16 by blast
    17 
    18 types 
    19   key = nat
    20 
    21 consts
    22   all_symmetric :: bool        --{*true if all keys are symmetric*}
    23   invKey        :: "key=>key"  --{*inverse of a symmetric key*}
    24 
    25 specification (invKey)
    26   invKey [simp]: "invKey (invKey K) = K"
    27   invKey_symmetric: "all_symmetric --> invKey = id"
    28     by (rule exI [of _ id], auto)
    29 
    30 
    31 text{*The inverse of a symmetric key is itself; that of a public key
    32       is the private key and vice versa*}
    33 
    34 constdefs
    35   symKeys :: "key set"
    36   "symKeys == {K. invKey K = K}"
    37 
    38 datatype  --{*We allow any number of friendly agents*}
    39   agent = Server | Friend nat | Spy
    40 
    41 datatype
    42      msg = Agent  agent	    --{*Agent names*}
    43          | Number nat       --{*Ordinary integers, timestamps, ...*}
    44          | Nonce  nat       --{*Unguessable nonces*}
    45          | Key    key       --{*Crypto keys*}
    46 	 | Hash   msg       --{*Hashing*}
    47 	 | MPair  msg msg   --{*Compound messages*}
    48 	 | Crypt  key msg   --{*Encryption, public- or shared-key*}
    49 
    50 
    51 text{*Concrete syntax: messages appear as {|A,B,NA|}, etc...*}
    52 syntax
    53   "@MTuple"      :: "['a, args] => 'a * 'b"       ("(2{|_,/ _|})")
    54 
    55 syntax (xsymbols)
    56   "@MTuple"      :: "['a, args] => 'a * 'b"       ("(2\<lbrace>_,/ _\<rbrace>)")
    57 
    58 translations
    59   "{|x, y, z|}"   == "{|x, {|y, z|}|}"
    60   "{|x, y|}"      == "MPair x y"
    61 
    62 
    63 constdefs
    64   HPair :: "[msg,msg] => msg"                       ("(4Hash[_] /_)" [0, 1000])
    65     --{*Message Y paired with a MAC computed with the help of X*}
    66     "Hash[X] Y == {| Hash{|X,Y|}, Y|}"
    67 
    68   keysFor :: "msg set => key set"
    69     --{*Keys useful to decrypt elements of a message set*}
    70   "keysFor H == invKey ` {K. \<exists>X. Crypt K X \<in> H}"
    71 
    72 
    73 subsubsection{*Inductive Definition of All Parts" of a Message*}
    74 
    75 consts  parts   :: "msg set => msg set"
    76 inductive "parts H"
    77   intros 
    78     Inj [intro]:               "X \<in> H ==> X \<in> parts H"
    79     Fst:         "{|X,Y|}   \<in> parts H ==> X \<in> parts H"
    80     Snd:         "{|X,Y|}   \<in> parts H ==> Y \<in> parts H"
    81     Body:        "Crypt K X \<in> parts H ==> X \<in> parts H"
    82 
    83 
    84 text{*Monotonicity*}
    85 lemma parts_mono: "G \<subseteq> H ==> parts(G) \<subseteq> parts(H)"
    86 apply auto
    87 apply (erule parts.induct) 
    88 apply (blast dest: parts.Fst parts.Snd parts.Body)+
    89 done
    90 
    91 
    92 text{*Equations hold because constructors are injective.*}
    93 lemma Friend_image_eq [simp]: "(Friend x \<in> Friend`A) = (x:A)"
    94 by auto
    95 
    96 lemma Key_image_eq [simp]: "(Key x \<in> Key`A) = (x\<in>A)"
    97 by auto
    98 
    99 lemma Nonce_Key_image_eq [simp]: "(Nonce x \<notin> Key`A)"
   100 by auto
   101 
   102 
   103 subsubsection{*Inverse of keys *}
   104 
   105 lemma invKey_eq [simp]: "(invKey K = invKey K') = (K=K')"
   106 apply safe
   107 apply (drule_tac f = invKey in arg_cong, simp)
   108 done
   109 
   110 
   111 subsection{*keysFor operator*}
   112 
   113 lemma keysFor_empty [simp]: "keysFor {} = {}"
   114 by (unfold keysFor_def, blast)
   115 
   116 lemma keysFor_Un [simp]: "keysFor (H \<union> H') = keysFor H \<union> keysFor H'"
   117 by (unfold keysFor_def, blast)
   118 
   119 lemma keysFor_UN [simp]: "keysFor (\<Union>i\<in>A. H i) = (\<Union>i\<in>A. keysFor (H i))"
   120 by (unfold keysFor_def, blast)
   121 
   122 text{*Monotonicity*}
   123 lemma keysFor_mono: "G \<subseteq> H ==> keysFor(G) \<subseteq> keysFor(H)"
   124 by (unfold keysFor_def, blast)
   125 
   126 lemma keysFor_insert_Agent [simp]: "keysFor (insert (Agent A) H) = keysFor H"
   127 by (unfold keysFor_def, auto)
   128 
   129 lemma keysFor_insert_Nonce [simp]: "keysFor (insert (Nonce N) H) = keysFor H"
   130 by (unfold keysFor_def, auto)
   131 
   132 lemma keysFor_insert_Number [simp]: "keysFor (insert (Number N) H) = keysFor H"
   133 by (unfold keysFor_def, auto)
   134 
   135 lemma keysFor_insert_Key [simp]: "keysFor (insert (Key K) H) = keysFor H"
   136 by (unfold keysFor_def, auto)
   137 
   138 lemma keysFor_insert_Hash [simp]: "keysFor (insert (Hash X) H) = keysFor H"
   139 by (unfold keysFor_def, auto)
   140 
   141 lemma keysFor_insert_MPair [simp]: "keysFor (insert {|X,Y|} H) = keysFor H"
   142 by (unfold keysFor_def, auto)
   143 
   144 lemma keysFor_insert_Crypt [simp]: 
   145     "keysFor (insert (Crypt K X) H) = insert (invKey K) (keysFor H)"
   146 by (unfold keysFor_def, auto)
   147 
   148 lemma keysFor_image_Key [simp]: "keysFor (Key`E) = {}"
   149 by (unfold keysFor_def, auto)
   150 
   151 lemma Crypt_imp_invKey_keysFor: "Crypt K X \<in> H ==> invKey K \<in> keysFor H"
   152 by (unfold keysFor_def, blast)
   153 
   154 
   155 subsection{*Inductive relation "parts"*}
   156 
   157 lemma MPair_parts:
   158      "[| {|X,Y|} \<in> parts H;        
   159          [| X \<in> parts H; Y \<in> parts H |] ==> P |] ==> P"
   160 by (blast dest: parts.Fst parts.Snd) 
   161 
   162 declare MPair_parts [elim!]  parts.Body [dest!]
   163 text{*NB These two rules are UNSAFE in the formal sense, as they discard the
   164      compound message.  They work well on THIS FILE.  
   165   @{text MPair_parts} is left as SAFE because it speeds up proofs.
   166   The Crypt rule is normally kept UNSAFE to avoid breaking up certificates.*}
   167 
   168 lemma parts_increasing: "H \<subseteq> parts(H)"
   169 by blast
   170 
   171 lemmas parts_insertI = subset_insertI [THEN parts_mono, THEN subsetD, standard]
   172 
   173 lemma parts_empty [simp]: "parts{} = {}"
   174 apply safe
   175 apply (erule parts.induct, blast+)
   176 done
   177 
   178 lemma parts_emptyE [elim!]: "X\<in> parts{} ==> P"
   179 by simp
   180 
   181 text{*WARNING: loops if H = {Y}, therefore must not be repeated!*}
   182 lemma parts_singleton: "X\<in> parts H ==> \<exists>Y\<in>H. X\<in> parts {Y}"
   183 by (erule parts.induct, blast+)
   184 
   185 
   186 subsubsection{*Unions *}
   187 
   188 lemma parts_Un_subset1: "parts(G) \<union> parts(H) \<subseteq> parts(G \<union> H)"
   189 by (intro Un_least parts_mono Un_upper1 Un_upper2)
   190 
   191 lemma parts_Un_subset2: "parts(G \<union> H) \<subseteq> parts(G) \<union> parts(H)"
   192 apply (rule subsetI)
   193 apply (erule parts.induct, blast+)
   194 done
   195 
   196 lemma parts_Un [simp]: "parts(G \<union> H) = parts(G) \<union> parts(H)"
   197 by (intro equalityI parts_Un_subset1 parts_Un_subset2)
   198 
   199 lemma parts_insert: "parts (insert X H) = parts {X} \<union> parts H"
   200 apply (subst insert_is_Un [of _ H])
   201 apply (simp only: parts_Un)
   202 done
   203 
   204 text{*TWO inserts to avoid looping.  This rewrite is better than nothing.
   205   Not suitable for Addsimps: its behaviour can be strange.*}
   206 lemma parts_insert2:
   207      "parts (insert X (insert Y H)) = parts {X} \<union> parts {Y} \<union> parts H"
   208 apply (simp add: Un_assoc)
   209 apply (simp add: parts_insert [symmetric])
   210 done
   211 
   212 lemma parts_UN_subset1: "(\<Union>x\<in>A. parts(H x)) \<subseteq> parts(\<Union>x\<in>A. H x)"
   213 by (intro UN_least parts_mono UN_upper)
   214 
   215 lemma parts_UN_subset2: "parts(\<Union>x\<in>A. H x) \<subseteq> (\<Union>x\<in>A. parts(H x))"
   216 apply (rule subsetI)
   217 apply (erule parts.induct, blast+)
   218 done
   219 
   220 lemma parts_UN [simp]: "parts(\<Union>x\<in>A. H x) = (\<Union>x\<in>A. parts(H x))"
   221 by (intro equalityI parts_UN_subset1 parts_UN_subset2)
   222 
   223 text{*Added to simplify arguments to parts, analz and synth.
   224   NOTE: the UN versions are no longer used!*}
   225 
   226 
   227 text{*This allows @{text blast} to simplify occurrences of 
   228   @{term "parts(G\<union>H)"} in the assumption.*}
   229 declare parts_Un [THEN equalityD1, THEN subsetD, THEN UnE, elim!] 
   230 
   231 
   232 lemma parts_insert_subset: "insert X (parts H) \<subseteq> parts(insert X H)"
   233 by (blast intro: parts_mono [THEN [2] rev_subsetD])
   234 
   235 subsubsection{*Idempotence and transitivity *}
   236 
   237 lemma parts_partsD [dest!]: "X\<in> parts (parts H) ==> X\<in> parts H"
   238 by (erule parts.induct, blast+)
   239 
   240 lemma parts_idem [simp]: "parts (parts H) = parts H"
   241 by blast
   242 
   243 lemma parts_trans: "[| X\<in> parts G;  G \<subseteq> parts H |] ==> X\<in> parts H"
   244 by (drule parts_mono, blast)
   245 
   246 text{*Cut*}
   247 lemma parts_cut:
   248      "[| Y\<in> parts (insert X G);  X\<in> parts H |] ==> Y\<in> parts (G \<union> H)"
   249 by (erule parts_trans, auto)
   250 
   251 lemma parts_cut_eq [simp]: "X\<in> parts H ==> parts (insert X H) = parts H"
   252 by (force dest!: parts_cut intro: parts_insertI)
   253 
   254 
   255 subsubsection{*Rewrite rules for pulling out atomic messages *}
   256 
   257 lemmas parts_insert_eq_I = equalityI [OF subsetI parts_insert_subset]
   258 
   259 
   260 lemma parts_insert_Agent [simp]:
   261      "parts (insert (Agent agt) H) = insert (Agent agt) (parts H)"
   262 apply (rule parts_insert_eq_I) 
   263 apply (erule parts.induct, auto) 
   264 done
   265 
   266 lemma parts_insert_Nonce [simp]:
   267      "parts (insert (Nonce N) H) = insert (Nonce N) (parts H)"
   268 apply (rule parts_insert_eq_I) 
   269 apply (erule parts.induct, auto) 
   270 done
   271 
   272 lemma parts_insert_Number [simp]:
   273      "parts (insert (Number N) H) = insert (Number N) (parts H)"
   274 apply (rule parts_insert_eq_I) 
   275 apply (erule parts.induct, auto) 
   276 done
   277 
   278 lemma parts_insert_Key [simp]:
   279      "parts (insert (Key K) H) = insert (Key K) (parts H)"
   280 apply (rule parts_insert_eq_I) 
   281 apply (erule parts.induct, auto) 
   282 done
   283 
   284 lemma parts_insert_Hash [simp]:
   285      "parts (insert (Hash X) H) = insert (Hash X) (parts H)"
   286 apply (rule parts_insert_eq_I) 
   287 apply (erule parts.induct, auto) 
   288 done
   289 
   290 lemma parts_insert_Crypt [simp]:
   291      "parts (insert (Crypt K X) H) =  
   292           insert (Crypt K X) (parts (insert X H))"
   293 apply (rule equalityI)
   294 apply (rule subsetI)
   295 apply (erule parts.induct, auto)
   296 apply (erule parts.induct)
   297 apply (blast intro: parts.Body)+
   298 done
   299 
   300 lemma parts_insert_MPair [simp]:
   301      "parts (insert {|X,Y|} H) =  
   302           insert {|X,Y|} (parts (insert X (insert Y H)))"
   303 apply (rule equalityI)
   304 apply (rule subsetI)
   305 apply (erule parts.induct, auto)
   306 apply (erule parts.induct)
   307 apply (blast intro: parts.Fst parts.Snd)+
   308 done
   309 
   310 lemma parts_image_Key [simp]: "parts (Key`N) = Key`N"
   311 apply auto
   312 apply (erule parts.induct, auto)
   313 done
   314 
   315 
   316 text{*In any message, there is an upper bound N on its greatest nonce.*}
   317 lemma msg_Nonce_supply: "\<exists>N. \<forall>n. N\<le>n --> Nonce n \<notin> parts {msg}"
   318 apply (induct_tac "msg")
   319 apply (simp_all (no_asm_simp) add: exI parts_insert2)
   320  txt{*MPair case: blast works out the necessary sum itself!*}
   321  prefer 2 apply (blast elim!: add_leE)
   322 txt{*Nonce case*}
   323 apply (rule_tac x = "N + Suc nat" in exI, auto) 
   324 done
   325 
   326 
   327 subsection{*Inductive relation "analz"*}
   328 
   329 text{*Inductive definition of "analz" -- what can be broken down from a set of
   330     messages, including keys.  A form of downward closure.  Pairs can
   331     be taken apart; messages decrypted with known keys.  *}
   332 
   333 consts  analz   :: "msg set => msg set"
   334 inductive "analz H"
   335   intros 
   336     Inj [intro,simp] :    "X \<in> H ==> X \<in> analz H"
   337     Fst:     "{|X,Y|} \<in> analz H ==> X \<in> analz H"
   338     Snd:     "{|X,Y|} \<in> analz H ==> Y \<in> analz H"
   339     Decrypt [dest]: 
   340              "[|Crypt K X \<in> analz H; Key(invKey K): analz H|] ==> X \<in> analz H"
   341 
   342 
   343 text{*Monotonicity; Lemma 1 of Lowe's paper*}
   344 lemma analz_mono: "G\<subseteq>H ==> analz(G) \<subseteq> analz(H)"
   345 apply auto
   346 apply (erule analz.induct) 
   347 apply (auto dest: analz.Fst analz.Snd) 
   348 done
   349 
   350 text{*Making it safe speeds up proofs*}
   351 lemma MPair_analz [elim!]:
   352      "[| {|X,Y|} \<in> analz H;        
   353              [| X \<in> analz H; Y \<in> analz H |] ==> P   
   354           |] ==> P"
   355 by (blast dest: analz.Fst analz.Snd)
   356 
   357 lemma analz_increasing: "H \<subseteq> analz(H)"
   358 by blast
   359 
   360 lemma analz_subset_parts: "analz H \<subseteq> parts H"
   361 apply (rule subsetI)
   362 apply (erule analz.induct, blast+)
   363 done
   364 
   365 lemmas analz_into_parts = analz_subset_parts [THEN subsetD, standard]
   366 
   367 lemmas not_parts_not_analz = analz_subset_parts [THEN contra_subsetD, standard]
   368 
   369 
   370 lemma parts_analz [simp]: "parts (analz H) = parts H"
   371 apply (rule equalityI)
   372 apply (rule analz_subset_parts [THEN parts_mono, THEN subset_trans], simp)
   373 apply (blast intro: analz_increasing [THEN parts_mono, THEN subsetD])
   374 done
   375 
   376 lemma analz_parts [simp]: "analz (parts H) = parts H"
   377 apply auto
   378 apply (erule analz.induct, auto)
   379 done
   380 
   381 lemmas analz_insertI = subset_insertI [THEN analz_mono, THEN [2] rev_subsetD, standard]
   382 
   383 subsubsection{*General equational properties *}
   384 
   385 lemma analz_empty [simp]: "analz{} = {}"
   386 apply safe
   387 apply (erule analz.induct, blast+)
   388 done
   389 
   390 text{*Converse fails: we can analz more from the union than from the 
   391   separate parts, as a key in one might decrypt a message in the other*}
   392 lemma analz_Un: "analz(G) \<union> analz(H) \<subseteq> analz(G \<union> H)"
   393 by (intro Un_least analz_mono Un_upper1 Un_upper2)
   394 
   395 lemma analz_insert: "insert X (analz H) \<subseteq> analz(insert X H)"
   396 by (blast intro: analz_mono [THEN [2] rev_subsetD])
   397 
   398 subsubsection{*Rewrite rules for pulling out atomic messages *}
   399 
   400 lemmas analz_insert_eq_I = equalityI [OF subsetI analz_insert]
   401 
   402 lemma analz_insert_Agent [simp]:
   403      "analz (insert (Agent agt) H) = insert (Agent agt) (analz H)"
   404 apply (rule analz_insert_eq_I) 
   405 apply (erule analz.induct, auto) 
   406 done
   407 
   408 lemma analz_insert_Nonce [simp]:
   409      "analz (insert (Nonce N) H) = insert (Nonce N) (analz H)"
   410 apply (rule analz_insert_eq_I) 
   411 apply (erule analz.induct, auto) 
   412 done
   413 
   414 lemma analz_insert_Number [simp]:
   415      "analz (insert (Number N) H) = insert (Number N) (analz H)"
   416 apply (rule analz_insert_eq_I) 
   417 apply (erule analz.induct, auto) 
   418 done
   419 
   420 lemma analz_insert_Hash [simp]:
   421      "analz (insert (Hash X) H) = insert (Hash X) (analz H)"
   422 apply (rule analz_insert_eq_I) 
   423 apply (erule analz.induct, auto) 
   424 done
   425 
   426 text{*Can only pull out Keys if they are not needed to decrypt the rest*}
   427 lemma analz_insert_Key [simp]: 
   428     "K \<notin> keysFor (analz H) ==>   
   429           analz (insert (Key K) H) = insert (Key K) (analz H)"
   430 apply (unfold keysFor_def)
   431 apply (rule analz_insert_eq_I) 
   432 apply (erule analz.induct, auto) 
   433 done
   434 
   435 lemma analz_insert_MPair [simp]:
   436      "analz (insert {|X,Y|} H) =  
   437           insert {|X,Y|} (analz (insert X (insert Y H)))"
   438 apply (rule equalityI)
   439 apply (rule subsetI)
   440 apply (erule analz.induct, auto)
   441 apply (erule analz.induct)
   442 apply (blast intro: analz.Fst analz.Snd)+
   443 done
   444 
   445 text{*Can pull out enCrypted message if the Key is not known*}
   446 lemma analz_insert_Crypt:
   447      "Key (invKey K) \<notin> analz H 
   448       ==> analz (insert (Crypt K X) H) = insert (Crypt K X) (analz H)"
   449 apply (rule analz_insert_eq_I) 
   450 apply (erule analz.induct, auto) 
   451 
   452 done
   453 
   454 lemma lemma1: "Key (invKey K) \<in> analz H ==>   
   455                analz (insert (Crypt K X) H) \<subseteq>  
   456                insert (Crypt K X) (analz (insert X H))"
   457 apply (rule subsetI)
   458 apply (erule_tac xa = x in analz.induct, auto)
   459 done
   460 
   461 lemma lemma2: "Key (invKey K) \<in> analz H ==>   
   462                insert (Crypt K X) (analz (insert X H)) \<subseteq>  
   463                analz (insert (Crypt K X) H)"
   464 apply auto
   465 apply (erule_tac xa = x in analz.induct, auto)
   466 apply (blast intro: analz_insertI analz.Decrypt)
   467 done
   468 
   469 lemma analz_insert_Decrypt:
   470      "Key (invKey K) \<in> analz H ==>   
   471                analz (insert (Crypt K X) H) =  
   472                insert (Crypt K X) (analz (insert X H))"
   473 by (intro equalityI lemma1 lemma2)
   474 
   475 text{*Case analysis: either the message is secure, or it is not! Effective,
   476 but can cause subgoals to blow up! Use with @{text "split_if"}; apparently
   477 @{text "split_tac"} does not cope with patterns such as @{term"analz (insert
   478 (Crypt K X) H)"} *} 
   479 lemma analz_Crypt_if [simp]:
   480      "analz (insert (Crypt K X) H) =                 
   481           (if (Key (invKey K) \<in> analz H)                 
   482            then insert (Crypt K X) (analz (insert X H))  
   483            else insert (Crypt K X) (analz H))"
   484 by (simp add: analz_insert_Crypt analz_insert_Decrypt)
   485 
   486 
   487 text{*This rule supposes "for the sake of argument" that we have the key.*}
   488 lemma analz_insert_Crypt_subset:
   489      "analz (insert (Crypt K X) H) \<subseteq>   
   490            insert (Crypt K X) (analz (insert X H))"
   491 apply (rule subsetI)
   492 apply (erule analz.induct, auto)
   493 done
   494 
   495 
   496 lemma analz_image_Key [simp]: "analz (Key`N) = Key`N"
   497 apply auto
   498 apply (erule analz.induct, auto)
   499 done
   500 
   501 
   502 subsubsection{*Idempotence and transitivity *}
   503 
   504 lemma analz_analzD [dest!]: "X\<in> analz (analz H) ==> X\<in> analz H"
   505 by (erule analz.induct, blast+)
   506 
   507 lemma analz_idem [simp]: "analz (analz H) = analz H"
   508 by blast
   509 
   510 lemma analz_trans: "[| X\<in> analz G;  G \<subseteq> analz H |] ==> X\<in> analz H"
   511 by (drule analz_mono, blast)
   512 
   513 text{*Cut; Lemma 2 of Lowe*}
   514 lemma analz_cut: "[| Y\<in> analz (insert X H);  X\<in> analz H |] ==> Y\<in> analz H"
   515 by (erule analz_trans, blast)
   516 
   517 (*Cut can be proved easily by induction on
   518    "Y: analz (insert X H) ==> X: analz H --> Y: analz H"
   519 *)
   520 
   521 text{*This rewrite rule helps in the simplification of messages that involve
   522   the forwarding of unknown components (X).  Without it, removing occurrences
   523   of X can be very complicated. *}
   524 lemma analz_insert_eq: "X\<in> analz H ==> analz (insert X H) = analz H"
   525 by (blast intro: analz_cut analz_insertI)
   526 
   527 
   528 text{*A congruence rule for "analz" *}
   529 
   530 lemma analz_subset_cong:
   531      "[| analz G \<subseteq> analz G'; analz H \<subseteq> analz H'  
   532                |] ==> analz (G \<union> H) \<subseteq> analz (G' \<union> H')"
   533 apply clarify
   534 apply (erule analz.induct)
   535 apply (best intro: analz_mono [THEN subsetD])+
   536 done
   537 
   538 lemma analz_cong:
   539      "[| analz G = analz G'; analz H = analz H'  
   540                |] ==> analz (G \<union> H) = analz (G' \<union> H')"
   541 by (intro equalityI analz_subset_cong, simp_all) 
   542 
   543 lemma analz_insert_cong:
   544      "analz H = analz H' ==> analz(insert X H) = analz(insert X H')"
   545 by (force simp only: insert_def intro!: analz_cong)
   546 
   547 text{*If there are no pairs or encryptions then analz does nothing*}
   548 lemma analz_trivial:
   549      "[| \<forall>X Y. {|X,Y|} \<notin> H;  \<forall>X K. Crypt K X \<notin> H |] ==> analz H = H"
   550 apply safe
   551 apply (erule analz.induct, blast+)
   552 done
   553 
   554 text{*These two are obsolete (with a single Spy) but cost little to prove...*}
   555 lemma analz_UN_analz_lemma:
   556      "X\<in> analz (\<Union>i\<in>A. analz (H i)) ==> X\<in> analz (\<Union>i\<in>A. H i)"
   557 apply (erule analz.induct)
   558 apply (blast intro: analz_mono [THEN [2] rev_subsetD])+
   559 done
   560 
   561 lemma analz_UN_analz [simp]: "analz (\<Union>i\<in>A. analz (H i)) = analz (\<Union>i\<in>A. H i)"
   562 by (blast intro: analz_UN_analz_lemma analz_mono [THEN [2] rev_subsetD])
   563 
   564 
   565 subsection{*Inductive relation "synth"*}
   566 
   567 text{*Inductive definition of "synth" -- what can be built up from a set of
   568     messages.  A form of upward closure.  Pairs can be built, messages
   569     encrypted with known keys.  Agent names are public domain.
   570     Numbers can be guessed, but Nonces cannot be.  *}
   571 
   572 consts  synth   :: "msg set => msg set"
   573 inductive "synth H"
   574   intros 
   575     Inj    [intro]:   "X \<in> H ==> X \<in> synth H"
   576     Agent  [intro]:   "Agent agt \<in> synth H"
   577     Number [intro]:   "Number n  \<in> synth H"
   578     Hash   [intro]:   "X \<in> synth H ==> Hash X \<in> synth H"
   579     MPair  [intro]:   "[|X \<in> synth H;  Y \<in> synth H|] ==> {|X,Y|} \<in> synth H"
   580     Crypt  [intro]:   "[|X \<in> synth H;  Key(K) \<in> H|] ==> Crypt K X \<in> synth H"
   581 
   582 text{*Monotonicity*}
   583 lemma synth_mono: "G\<subseteq>H ==> synth(G) \<subseteq> synth(H)"
   584   by (auto, erule synth.induct, auto)  
   585 
   586 text{*NO @{text Agent_synth}, as any Agent name can be synthesized.  
   587   The same holds for @{term Number}*}
   588 inductive_cases Nonce_synth [elim!]: "Nonce n \<in> synth H"
   589 inductive_cases Key_synth   [elim!]: "Key K \<in> synth H"
   590 inductive_cases Hash_synth  [elim!]: "Hash X \<in> synth H"
   591 inductive_cases MPair_synth [elim!]: "{|X,Y|} \<in> synth H"
   592 inductive_cases Crypt_synth [elim!]: "Crypt K X \<in> synth H"
   593 
   594 
   595 lemma synth_increasing: "H \<subseteq> synth(H)"
   596 by blast
   597 
   598 subsubsection{*Unions *}
   599 
   600 text{*Converse fails: we can synth more from the union than from the 
   601   separate parts, building a compound message using elements of each.*}
   602 lemma synth_Un: "synth(G) \<union> synth(H) \<subseteq> synth(G \<union> H)"
   603 by (intro Un_least synth_mono Un_upper1 Un_upper2)
   604 
   605 lemma synth_insert: "insert X (synth H) \<subseteq> synth(insert X H)"
   606 by (blast intro: synth_mono [THEN [2] rev_subsetD])
   607 
   608 subsubsection{*Idempotence and transitivity *}
   609 
   610 lemma synth_synthD [dest!]: "X\<in> synth (synth H) ==> X\<in> synth H"
   611 by (erule synth.induct, blast+)
   612 
   613 lemma synth_idem: "synth (synth H) = synth H"
   614 by blast
   615 
   616 lemma synth_trans: "[| X\<in> synth G;  G \<subseteq> synth H |] ==> X\<in> synth H"
   617 by (drule synth_mono, blast)
   618 
   619 text{*Cut; Lemma 2 of Lowe*}
   620 lemma synth_cut: "[| Y\<in> synth (insert X H);  X\<in> synth H |] ==> Y\<in> synth H"
   621 by (erule synth_trans, blast)
   622 
   623 lemma Agent_synth [simp]: "Agent A \<in> synth H"
   624 by blast
   625 
   626 lemma Number_synth [simp]: "Number n \<in> synth H"
   627 by blast
   628 
   629 lemma Nonce_synth_eq [simp]: "(Nonce N \<in> synth H) = (Nonce N \<in> H)"
   630 by blast
   631 
   632 lemma Key_synth_eq [simp]: "(Key K \<in> synth H) = (Key K \<in> H)"
   633 by blast
   634 
   635 lemma Crypt_synth_eq [simp]:
   636      "Key K \<notin> H ==> (Crypt K X \<in> synth H) = (Crypt K X \<in> H)"
   637 by blast
   638 
   639 
   640 lemma keysFor_synth [simp]: 
   641     "keysFor (synth H) = keysFor H \<union> invKey`{K. Key K \<in> H}"
   642 by (unfold keysFor_def, blast)
   643 
   644 
   645 subsubsection{*Combinations of parts, analz and synth *}
   646 
   647 lemma parts_synth [simp]: "parts (synth H) = parts H \<union> synth H"
   648 apply (rule equalityI)
   649 apply (rule subsetI)
   650 apply (erule parts.induct)
   651 apply (blast intro: synth_increasing [THEN parts_mono, THEN subsetD] 
   652                     parts.Fst parts.Snd parts.Body)+
   653 done
   654 
   655 lemma analz_analz_Un [simp]: "analz (analz G \<union> H) = analz (G \<union> H)"
   656 apply (intro equalityI analz_subset_cong)+
   657 apply simp_all
   658 done
   659 
   660 lemma analz_synth_Un [simp]: "analz (synth G \<union> H) = analz (G \<union> H) \<union> synth G"
   661 apply (rule equalityI)
   662 apply (rule subsetI)
   663 apply (erule analz.induct)
   664 prefer 5 apply (blast intro: analz_mono [THEN [2] rev_subsetD])
   665 apply (blast intro: analz.Fst analz.Snd analz.Decrypt)+
   666 done
   667 
   668 lemma analz_synth [simp]: "analz (synth H) = analz H \<union> synth H"
   669 apply (cut_tac H = "{}" in analz_synth_Un)
   670 apply (simp (no_asm_use))
   671 done
   672 
   673 
   674 subsubsection{*For reasoning about the Fake rule in traces *}
   675 
   676 lemma parts_insert_subset_Un: "X\<in> G ==> parts(insert X H) \<subseteq> parts G \<union> parts H"
   677 by (rule subset_trans [OF parts_mono parts_Un_subset2], blast)
   678 
   679 text{*More specifically for Fake.  Very occasionally we could do with a version
   680   of the form  @{term"parts{X} \<subseteq> synth (analz H) \<union> parts H"} *}
   681 lemma Fake_parts_insert:
   682      "X \<in> synth (analz H) ==>  
   683       parts (insert X H) \<subseteq> synth (analz H) \<union> parts H"
   684 apply (drule parts_insert_subset_Un)
   685 apply (simp (no_asm_use))
   686 apply blast
   687 done
   688 
   689 lemma Fake_parts_insert_in_Un:
   690      "[|Z \<in> parts (insert X H);  X: synth (analz H)|] 
   691       ==> Z \<in>  synth (analz H) \<union> parts H";
   692 by (blast dest: Fake_parts_insert  [THEN subsetD, dest])
   693 
   694 text{*@{term H} is sometimes @{term"Key ` KK \<union> spies evs"}, so can't put 
   695   @{term "G=H"}.*}
   696 lemma Fake_analz_insert:
   697      "X\<in> synth (analz G) ==>  
   698       analz (insert X H) \<subseteq> synth (analz G) \<union> analz (G \<union> H)"
   699 apply (rule subsetI)
   700 apply (subgoal_tac "x \<in> analz (synth (analz G) \<union> H) ")
   701 prefer 2 apply (blast intro: analz_mono [THEN [2] rev_subsetD] analz_mono [THEN synth_mono, THEN [2] rev_subsetD])
   702 apply (simp (no_asm_use))
   703 apply blast
   704 done
   705 
   706 lemma analz_conj_parts [simp]:
   707      "(X \<in> analz H & X \<in> parts H) = (X \<in> analz H)"
   708 by (blast intro: analz_subset_parts [THEN subsetD])
   709 
   710 lemma analz_disj_parts [simp]:
   711      "(X \<in> analz H | X \<in> parts H) = (X \<in> parts H)"
   712 by (blast intro: analz_subset_parts [THEN subsetD])
   713 
   714 text{*Without this equation, other rules for synth and analz would yield
   715   redundant cases*}
   716 lemma MPair_synth_analz [iff]:
   717      "({|X,Y|} \<in> synth (analz H)) =  
   718       (X \<in> synth (analz H) & Y \<in> synth (analz H))"
   719 by blast
   720 
   721 lemma Crypt_synth_analz:
   722      "[| Key K \<in> analz H;  Key (invKey K) \<in> analz H |]  
   723        ==> (Crypt K X \<in> synth (analz H)) = (X \<in> synth (analz H))"
   724 by blast
   725 
   726 
   727 lemma Hash_synth_analz [simp]:
   728      "X \<notin> synth (analz H)  
   729       ==> (Hash{|X,Y|} \<in> synth (analz H)) = (Hash{|X,Y|} \<in> analz H)"
   730 by blast
   731 
   732 
   733 subsection{*HPair: a combination of Hash and MPair*}
   734 
   735 subsubsection{*Freeness *}
   736 
   737 lemma Agent_neq_HPair: "Agent A ~= Hash[X] Y"
   738 by (unfold HPair_def, simp)
   739 
   740 lemma Nonce_neq_HPair: "Nonce N ~= Hash[X] Y"
   741 by (unfold HPair_def, simp)
   742 
   743 lemma Number_neq_HPair: "Number N ~= Hash[X] Y"
   744 by (unfold HPair_def, simp)
   745 
   746 lemma Key_neq_HPair: "Key K ~= Hash[X] Y"
   747 by (unfold HPair_def, simp)
   748 
   749 lemma Hash_neq_HPair: "Hash Z ~= Hash[X] Y"
   750 by (unfold HPair_def, simp)
   751 
   752 lemma Crypt_neq_HPair: "Crypt K X' ~= Hash[X] Y"
   753 by (unfold HPair_def, simp)
   754 
   755 lemmas HPair_neqs = Agent_neq_HPair Nonce_neq_HPair Number_neq_HPair 
   756                     Key_neq_HPair Hash_neq_HPair Crypt_neq_HPair
   757 
   758 declare HPair_neqs [iff]
   759 declare HPair_neqs [symmetric, iff]
   760 
   761 lemma HPair_eq [iff]: "(Hash[X'] Y' = Hash[X] Y) = (X' = X & Y'=Y)"
   762 by (simp add: HPair_def)
   763 
   764 lemma MPair_eq_HPair [iff]:
   765      "({|X',Y'|} = Hash[X] Y) = (X' = Hash{|X,Y|} & Y'=Y)"
   766 by (simp add: HPair_def)
   767 
   768 lemma HPair_eq_MPair [iff]:
   769      "(Hash[X] Y = {|X',Y'|}) = (X' = Hash{|X,Y|} & Y'=Y)"
   770 by (auto simp add: HPair_def)
   771 
   772 
   773 subsubsection{*Specialized laws, proved in terms of those for Hash and MPair *}
   774 
   775 lemma keysFor_insert_HPair [simp]: "keysFor (insert (Hash[X] Y) H) = keysFor H"
   776 by (simp add: HPair_def)
   777 
   778 lemma parts_insert_HPair [simp]: 
   779     "parts (insert (Hash[X] Y) H) =  
   780      insert (Hash[X] Y) (insert (Hash{|X,Y|}) (parts (insert Y H)))"
   781 by (simp add: HPair_def)
   782 
   783 lemma analz_insert_HPair [simp]: 
   784     "analz (insert (Hash[X] Y) H) =  
   785      insert (Hash[X] Y) (insert (Hash{|X,Y|}) (analz (insert Y H)))"
   786 by (simp add: HPair_def)
   787 
   788 lemma HPair_synth_analz [simp]:
   789      "X \<notin> synth (analz H)  
   790     ==> (Hash[X] Y \<in> synth (analz H)) =  
   791         (Hash {|X, Y|} \<in> analz H & Y \<in> synth (analz H))"
   792 by (simp add: HPair_def)
   793 
   794 
   795 text{*We do NOT want Crypt... messages broken up in protocols!!*}
   796 declare parts.Body [rule del]
   797 
   798 
   799 text{*Rewrites to push in Key and Crypt messages, so that other messages can
   800     be pulled out using the @{text analz_insert} rules*}
   801 ML
   802 {*
   803 fun insComm x y = inst "x" x (inst "y" y insert_commute);
   804 
   805 bind_thms ("pushKeys",
   806            map (insComm "Key ?K") 
   807                    ["Agent ?C", "Nonce ?N", "Number ?N", 
   808 		    "Hash ?X", "MPair ?X ?Y", "Crypt ?X ?K'"]);
   809 
   810 bind_thms ("pushCrypts",
   811            map (insComm "Crypt ?X ?K") 
   812                      ["Agent ?C", "Nonce ?N", "Number ?N", 
   813 		      "Hash ?X'", "MPair ?X' ?Y"]);
   814 *}
   815 
   816 text{*Cannot be added with @{text "[simp]"} -- messages should not always be
   817   re-ordered. *}
   818 lemmas pushes = pushKeys pushCrypts
   819 
   820 
   821 subsection{*Tactics useful for many protocol proofs*}
   822 ML
   823 {*
   824 val invKey = thm "invKey"
   825 val keysFor_def = thm "keysFor_def"
   826 val HPair_def = thm "HPair_def"
   827 val symKeys_def = thm "symKeys_def"
   828 val parts_mono = thm "parts_mono";
   829 val analz_mono = thm "analz_mono";
   830 val synth_mono = thm "synth_mono";
   831 val analz_increasing = thm "analz_increasing";
   832 
   833 val analz_insertI = thm "analz_insertI";
   834 val analz_subset_parts = thm "analz_subset_parts";
   835 val Fake_parts_insert = thm "Fake_parts_insert";
   836 val Fake_analz_insert = thm "Fake_analz_insert";
   837 val pushes = thms "pushes";
   838 
   839 
   840 (*Prove base case (subgoal i) and simplify others.  A typical base case
   841   concerns  Crypt K X \<notin> Key`shrK`bad  and cannot be proved by rewriting
   842   alone.*)
   843 fun prove_simple_subgoals_tac i = 
   844     force_tac (claset(), simpset() addsimps [image_eq_UN]) i THEN
   845     ALLGOALS Asm_simp_tac
   846 
   847 (*Analysis of Fake cases.  Also works for messages that forward unknown parts,
   848   but this application is no longer necessary if analz_insert_eq is used.
   849   Abstraction over i is ESSENTIAL: it delays the dereferencing of claset
   850   DEPENDS UPON "X" REFERRING TO THE FRADULENT MESSAGE *)
   851 
   852 (*Apply rules to break down assumptions of the form
   853   Y \<in> parts(insert X H)  and  Y \<in> analz(insert X H)
   854 *)
   855 val Fake_insert_tac = 
   856     dresolve_tac [impOfSubs Fake_analz_insert,
   857                   impOfSubs Fake_parts_insert] THEN'
   858     eresolve_tac [asm_rl, thm"synth.Inj"];
   859 
   860 fun Fake_insert_simp_tac ss i = 
   861     REPEAT (Fake_insert_tac i) THEN asm_full_simp_tac ss i;
   862 
   863 fun atomic_spy_analz_tac (cs,ss) = SELECT_GOAL
   864     (Fake_insert_simp_tac ss 1
   865      THEN
   866      IF_UNSOLVED (Blast.depth_tac
   867 		  (cs addIs [analz_insertI,
   868 				   impOfSubs analz_subset_parts]) 4 1))
   869 
   870 (*The explicit claset and simpset arguments help it work with Isar*)
   871 fun gen_spy_analz_tac (cs,ss) i =
   872   DETERM
   873    (SELECT_GOAL
   874      (EVERY 
   875       [  (*push in occurrences of X...*)
   876        (REPEAT o CHANGED)
   877            (res_inst_tac [("x1","X")] (insert_commute RS ssubst) 1),
   878        (*...allowing further simplifications*)
   879        simp_tac ss 1,
   880        REPEAT (FIRSTGOAL (resolve_tac [allI,impI,notI,conjI,iffI])),
   881        DEPTH_SOLVE (atomic_spy_analz_tac (cs,ss) 1)]) i)
   882 
   883 fun spy_analz_tac i = gen_spy_analz_tac (claset(), simpset()) i
   884 *}
   885 
   886 text{*By default only @{text o_apply} is built-in.  But in the presence of
   887 eta-expansion this means that some terms displayed as @{term "f o g"} will be
   888 rewritten, and others will not!*}
   889 declare o_def [simp]
   890 
   891 
   892 lemma Crypt_notin_image_Key [simp]: "Crypt K X \<notin> Key ` A"
   893 by auto
   894 
   895 lemma Hash_notin_image_Key [simp] :"Hash X \<notin> Key ` A"
   896 by auto
   897 
   898 lemma synth_analz_mono: "G\<subseteq>H ==> synth (analz(G)) \<subseteq> synth (analz(H))"
   899 by (simp add: synth_mono analz_mono) 
   900 
   901 lemma Fake_analz_eq [simp]:
   902      "X \<in> synth(analz H) ==> synth (analz (insert X H)) = synth (analz H)"
   903 apply (drule Fake_analz_insert[of _ _ "H"])
   904 apply (simp add: synth_increasing[THEN Un_absorb2])
   905 apply (drule synth_mono)
   906 apply (simp add: synth_idem)
   907 apply (blast intro: synth_analz_mono [THEN [2] rev_subsetD]) 
   908 done
   909 
   910 text{*Two generalizations of @{text analz_insert_eq}*}
   911 lemma gen_analz_insert_eq [rule_format]:
   912      "X \<in> analz H ==> ALL G. H \<subseteq> G --> analz (insert X G) = analz G";
   913 by (blast intro: analz_cut analz_insertI analz_mono [THEN [2] rev_subsetD])
   914 
   915 lemma synth_analz_insert_eq [rule_format]:
   916      "X \<in> synth (analz H) 
   917       ==> ALL G. H \<subseteq> G --> (Key K \<in> analz (insert X G)) = (Key K \<in> analz G)";
   918 apply (erule synth.induct) 
   919 apply (simp_all add: gen_analz_insert_eq subset_trans [OF _ subset_insertI]) 
   920 done
   921 
   922 lemma Fake_parts_sing:
   923      "X \<in> synth (analz H) ==> parts{X} \<subseteq> synth (analz H) \<union> parts H";
   924 apply (rule subset_trans) 
   925  apply (erule_tac [2] Fake_parts_insert) 
   926 apply (simp add: parts_mono) 
   927 done
   928 
   929 lemmas Fake_parts_sing_imp_Un = Fake_parts_sing [THEN [2] rev_subsetD]
   930 
   931 method_setup spy_analz = {*
   932     Method.ctxt_args (fn ctxt =>
   933         Method.METHOD (fn facts => 
   934             gen_spy_analz_tac (local_clasimpset_of ctxt) 1)) *}
   935     "for proving the Fake case when analz is involved"
   936 
   937 method_setup atomic_spy_analz = {*
   938     Method.ctxt_args (fn ctxt =>
   939         Method.METHOD (fn facts => 
   940             atomic_spy_analz_tac (local_clasimpset_of ctxt) 1)) *}
   941     "for debugging spy_analz"
   942 
   943 method_setup Fake_insert_simp = {*
   944     Method.ctxt_args (fn ctxt =>
   945         Method.METHOD (fn facts =>
   946             Fake_insert_simp_tac (local_simpset_of ctxt) 1)) *}
   947     "for debugging spy_analz"
   948 
   949 
   950 end