src/HOL/HOL.thy
author haftmann
Thu Aug 28 22:09:20 2008 +0200 (2008-08-28)
changeset 28054 2b84d34c5d02
parent 28012 2308843f8b66
child 28227 77221ee0f7b9
permissions -rw-r--r--
restructured and split code serializer module
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports Pure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/atomize_elim.ML"
    27   "~~/src/Tools/induct.ML"
    28   ("~~/src/Tools/induct_tacs.ML")
    29   "~~/src/Tools/code/code_name.ML"
    30   "~~/src/Tools/code/code_funcgr.ML"
    31   "~~/src/Tools/code/code_thingol.ML"
    32   "~~/src/Tools/code/code_printer.ML"
    33   "~~/src/Tools/code/code_target.ML"
    34   "~~/src/Tools/code/code_ml.ML"
    35   "~~/src/Tools/code/code_haskell.ML"
    36   "~~/src/Tools/nbe.ML"
    37 begin
    38 
    39 subsection {* Primitive logic *}
    40 
    41 subsubsection {* Core syntax *}
    42 
    43 classes type
    44 defaultsort type
    45 setup {* ObjectLogic.add_base_sort @{sort type} *}
    46 
    47 arities
    48   "fun" :: (type, type) type
    49   itself :: (type) type
    50 
    51 global
    52 
    53 typedecl bool
    54 
    55 judgment
    56   Trueprop      :: "bool => prop"                   ("(_)" 5)
    57 
    58 consts
    59   Not           :: "bool => bool"                   ("~ _" [40] 40)
    60   True          :: bool
    61   False         :: bool
    62   arbitrary     :: 'a
    63 
    64   The           :: "('a => bool) => 'a"
    65   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    66   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    67   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    68   Let           :: "['a, 'a => 'b] => 'b"
    69 
    70   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    71   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    72   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    73   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    74 
    75 local
    76 
    77 consts
    78   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    79 
    80 
    81 subsubsection {* Additional concrete syntax *}
    82 
    83 notation (output)
    84   "op ="  (infix "=" 50)
    85 
    86 abbreviation
    87   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    88   "x ~= y == ~ (x = y)"
    89 
    90 notation (output)
    91   not_equal  (infix "~=" 50)
    92 
    93 notation (xsymbols)
    94   Not  ("\<not> _" [40] 40) and
    95   "op &"  (infixr "\<and>" 35) and
    96   "op |"  (infixr "\<or>" 30) and
    97   "op -->"  (infixr "\<longrightarrow>" 25) and
    98   not_equal  (infix "\<noteq>" 50)
    99 
   100 notation (HTML output)
   101   Not  ("\<not> _" [40] 40) and
   102   "op &"  (infixr "\<and>" 35) and
   103   "op |"  (infixr "\<or>" 30) and
   104   not_equal  (infix "\<noteq>" 50)
   105 
   106 abbreviation (iff)
   107   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   108   "A <-> B == A = B"
   109 
   110 notation (xsymbols)
   111   iff  (infixr "\<longleftrightarrow>" 25)
   112 
   113 
   114 nonterminals
   115   letbinds  letbind
   116   case_syn  cases_syn
   117 
   118 syntax
   119   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   120 
   121   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   122   ""            :: "letbind => letbinds"                 ("_")
   123   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   124   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   125 
   126   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   127   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   128   ""            :: "case_syn => cases_syn"               ("_")
   129   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   130 
   131 translations
   132   "THE x. P"              == "The (%x. P)"
   133   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   134   "let x = a in e"        == "Let a (%x. e)"
   135 
   136 print_translation {*
   137 (* To avoid eta-contraction of body: *)
   138 [("The", fn [Abs abs] =>
   139      let val (x,t) = atomic_abs_tr' abs
   140      in Syntax.const "_The" $ x $ t end)]
   141 *}
   142 
   143 syntax (xsymbols)
   144   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   145 
   146 notation (xsymbols)
   147   All  (binder "\<forall>" 10) and
   148   Ex  (binder "\<exists>" 10) and
   149   Ex1  (binder "\<exists>!" 10)
   150 
   151 notation (HTML output)
   152   All  (binder "\<forall>" 10) and
   153   Ex  (binder "\<exists>" 10) and
   154   Ex1  (binder "\<exists>!" 10)
   155 
   156 notation (HOL)
   157   All  (binder "! " 10) and
   158   Ex  (binder "? " 10) and
   159   Ex1  (binder "?! " 10)
   160 
   161 
   162 subsubsection {* Axioms and basic definitions *}
   163 
   164 axioms
   165   eq_reflection:  "(x=y) ==> (x==y)"
   166 
   167   refl:           "t = (t::'a)"
   168 
   169   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   170     -- {*Extensionality is built into the meta-logic, and this rule expresses
   171          a related property.  It is an eta-expanded version of the traditional
   172          rule, and similar to the ABS rule of HOL*}
   173 
   174   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   175 
   176   impI:           "(P ==> Q) ==> P-->Q"
   177   mp:             "[| P-->Q;  P |] ==> Q"
   178 
   179 
   180 defs
   181   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   182   All_def:      "All(P)    == (P = (%x. True))"
   183   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   184   False_def:    "False     == (!P. P)"
   185   not_def:      "~ P       == P-->False"
   186   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   187   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   188   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   189 
   190 axioms
   191   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   192   True_or_False:  "(P=True) | (P=False)"
   193 
   194 defs
   195   Let_def:      "Let s f == f(s)"
   196   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   197 
   198 finalconsts
   199   "op ="
   200   "op -->"
   201   The
   202   arbitrary
   203 
   204 axiomatization
   205   undefined :: 'a
   206 
   207 axiomatization where
   208   undefined_fun: "undefined x = undefined"
   209 
   210 
   211 subsubsection {* Generic classes and algebraic operations *}
   212 
   213 class default = type +
   214   fixes default :: 'a
   215 
   216 class zero = type + 
   217   fixes zero :: 'a  ("0")
   218 
   219 class one = type +
   220   fixes one  :: 'a  ("1")
   221 
   222 hide (open) const zero one
   223 
   224 class plus = type +
   225   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   226 
   227 class minus = type +
   228   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   229 
   230 class uminus = type +
   231   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   232 
   233 class times = type +
   234   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   235 
   236 class inverse = type +
   237   fixes inverse :: "'a \<Rightarrow> 'a"
   238     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   239 
   240 class abs = type +
   241   fixes abs :: "'a \<Rightarrow> 'a"
   242 begin
   243 
   244 notation (xsymbols)
   245   abs  ("\<bar>_\<bar>")
   246 
   247 notation (HTML output)
   248   abs  ("\<bar>_\<bar>")
   249 
   250 end
   251 
   252 class sgn = type +
   253   fixes sgn :: "'a \<Rightarrow> 'a"
   254 
   255 class ord = type +
   256   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   257     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   258 begin
   259 
   260 notation
   261   less_eq  ("op <=") and
   262   less_eq  ("(_/ <= _)" [51, 51] 50) and
   263   less  ("op <") and
   264   less  ("(_/ < _)"  [51, 51] 50)
   265   
   266 notation (xsymbols)
   267   less_eq  ("op \<le>") and
   268   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   269 
   270 notation (HTML output)
   271   less_eq  ("op \<le>") and
   272   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   273 
   274 abbreviation (input)
   275   greater_eq  (infix ">=" 50) where
   276   "x >= y \<equiv> y <= x"
   277 
   278 notation (input)
   279   greater_eq  (infix "\<ge>" 50)
   280 
   281 abbreviation (input)
   282   greater  (infix ">" 50) where
   283   "x > y \<equiv> y < x"
   284 
   285 end
   286 
   287 syntax
   288   "_index1"  :: index    ("\<^sub>1")
   289 translations
   290   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   291 
   292 typed_print_translation {*
   293 let
   294   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   295     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   296     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   297 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   298 *} -- {* show types that are presumably too general *}
   299 
   300 
   301 subsection {* Fundamental rules *}
   302 
   303 subsubsection {* Equality *}
   304 
   305 text {* Thanks to Stephan Merz *}
   306 lemma subst:
   307   assumes eq: "s = t" and p: "P s"
   308   shows "P t"
   309 proof -
   310   from eq have meta: "s \<equiv> t"
   311     by (rule eq_reflection)
   312   from p show ?thesis
   313     by (unfold meta)
   314 qed
   315 
   316 lemma sym: "s = t ==> t = s"
   317   by (erule subst) (rule refl)
   318 
   319 lemma ssubst: "t = s ==> P s ==> P t"
   320   by (drule sym) (erule subst)
   321 
   322 lemma trans: "[| r=s; s=t |] ==> r=t"
   323   by (erule subst)
   324 
   325 lemma meta_eq_to_obj_eq: 
   326   assumes meq: "A == B"
   327   shows "A = B"
   328   by (unfold meq) (rule refl)
   329 
   330 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   331      (* a = b
   332         |   |
   333         c = d   *)
   334 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   335 apply (rule trans)
   336 apply (rule trans)
   337 apply (rule sym)
   338 apply assumption+
   339 done
   340 
   341 text {* For calculational reasoning: *}
   342 
   343 lemma forw_subst: "a = b ==> P b ==> P a"
   344   by (rule ssubst)
   345 
   346 lemma back_subst: "P a ==> a = b ==> P b"
   347   by (rule subst)
   348 
   349 
   350 subsubsection {*Congruence rules for application*}
   351 
   352 (*similar to AP_THM in Gordon's HOL*)
   353 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   354 apply (erule subst)
   355 apply (rule refl)
   356 done
   357 
   358 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   359 lemma arg_cong: "x=y ==> f(x)=f(y)"
   360 apply (erule subst)
   361 apply (rule refl)
   362 done
   363 
   364 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   365 apply (erule ssubst)+
   366 apply (rule refl)
   367 done
   368 
   369 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   370 apply (erule subst)+
   371 apply (rule refl)
   372 done
   373 
   374 
   375 subsubsection {*Equality of booleans -- iff*}
   376 
   377 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   378   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   379 
   380 lemma iffD2: "[| P=Q; Q |] ==> P"
   381   by (erule ssubst)
   382 
   383 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   384   by (erule iffD2)
   385 
   386 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   387   by (drule sym) (rule iffD2)
   388 
   389 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   390   by (drule sym) (rule rev_iffD2)
   391 
   392 lemma iffE:
   393   assumes major: "P=Q"
   394     and minor: "[| P --> Q; Q --> P |] ==> R"
   395   shows R
   396   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   397 
   398 
   399 subsubsection {*True*}
   400 
   401 lemma TrueI: "True"
   402   unfolding True_def by (rule refl)
   403 
   404 lemma eqTrueI: "P ==> P = True"
   405   by (iprover intro: iffI TrueI)
   406 
   407 lemma eqTrueE: "P = True ==> P"
   408   by (erule iffD2) (rule TrueI)
   409 
   410 
   411 subsubsection {*Universal quantifier*}
   412 
   413 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   414   unfolding All_def by (iprover intro: ext eqTrueI assms)
   415 
   416 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   417 apply (unfold All_def)
   418 apply (rule eqTrueE)
   419 apply (erule fun_cong)
   420 done
   421 
   422 lemma allE:
   423   assumes major: "ALL x. P(x)"
   424     and minor: "P(x) ==> R"
   425   shows R
   426   by (iprover intro: minor major [THEN spec])
   427 
   428 lemma all_dupE:
   429   assumes major: "ALL x. P(x)"
   430     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   431   shows R
   432   by (iprover intro: minor major major [THEN spec])
   433 
   434 
   435 subsubsection {* False *}
   436 
   437 text {*
   438   Depends upon @{text spec}; it is impossible to do propositional
   439   logic before quantifiers!
   440 *}
   441 
   442 lemma FalseE: "False ==> P"
   443   apply (unfold False_def)
   444   apply (erule spec)
   445   done
   446 
   447 lemma False_neq_True: "False = True ==> P"
   448   by (erule eqTrueE [THEN FalseE])
   449 
   450 
   451 subsubsection {* Negation *}
   452 
   453 lemma notI:
   454   assumes "P ==> False"
   455   shows "~P"
   456   apply (unfold not_def)
   457   apply (iprover intro: impI assms)
   458   done
   459 
   460 lemma False_not_True: "False ~= True"
   461   apply (rule notI)
   462   apply (erule False_neq_True)
   463   done
   464 
   465 lemma True_not_False: "True ~= False"
   466   apply (rule notI)
   467   apply (drule sym)
   468   apply (erule False_neq_True)
   469   done
   470 
   471 lemma notE: "[| ~P;  P |] ==> R"
   472   apply (unfold not_def)
   473   apply (erule mp [THEN FalseE])
   474   apply assumption
   475   done
   476 
   477 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   478   by (erule notE [THEN notI]) (erule meta_mp)
   479 
   480 
   481 subsubsection {*Implication*}
   482 
   483 lemma impE:
   484   assumes "P-->Q" "P" "Q ==> R"
   485   shows "R"
   486 by (iprover intro: assms mp)
   487 
   488 (* Reduces Q to P-->Q, allowing substitution in P. *)
   489 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   490 by (iprover intro: mp)
   491 
   492 lemma contrapos_nn:
   493   assumes major: "~Q"
   494       and minor: "P==>Q"
   495   shows "~P"
   496 by (iprover intro: notI minor major [THEN notE])
   497 
   498 (*not used at all, but we already have the other 3 combinations *)
   499 lemma contrapos_pn:
   500   assumes major: "Q"
   501       and minor: "P ==> ~Q"
   502   shows "~P"
   503 by (iprover intro: notI minor major notE)
   504 
   505 lemma not_sym: "t ~= s ==> s ~= t"
   506   by (erule contrapos_nn) (erule sym)
   507 
   508 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   509   by (erule subst, erule ssubst, assumption)
   510 
   511 (*still used in HOLCF*)
   512 lemma rev_contrapos:
   513   assumes pq: "P ==> Q"
   514       and nq: "~Q"
   515   shows "~P"
   516 apply (rule nq [THEN contrapos_nn])
   517 apply (erule pq)
   518 done
   519 
   520 subsubsection {*Existential quantifier*}
   521 
   522 lemma exI: "P x ==> EX x::'a. P x"
   523 apply (unfold Ex_def)
   524 apply (iprover intro: allI allE impI mp)
   525 done
   526 
   527 lemma exE:
   528   assumes major: "EX x::'a. P(x)"
   529       and minor: "!!x. P(x) ==> Q"
   530   shows "Q"
   531 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   532 apply (iprover intro: impI [THEN allI] minor)
   533 done
   534 
   535 
   536 subsubsection {*Conjunction*}
   537 
   538 lemma conjI: "[| P; Q |] ==> P&Q"
   539 apply (unfold and_def)
   540 apply (iprover intro: impI [THEN allI] mp)
   541 done
   542 
   543 lemma conjunct1: "[| P & Q |] ==> P"
   544 apply (unfold and_def)
   545 apply (iprover intro: impI dest: spec mp)
   546 done
   547 
   548 lemma conjunct2: "[| P & Q |] ==> Q"
   549 apply (unfold and_def)
   550 apply (iprover intro: impI dest: spec mp)
   551 done
   552 
   553 lemma conjE:
   554   assumes major: "P&Q"
   555       and minor: "[| P; Q |] ==> R"
   556   shows "R"
   557 apply (rule minor)
   558 apply (rule major [THEN conjunct1])
   559 apply (rule major [THEN conjunct2])
   560 done
   561 
   562 lemma context_conjI:
   563   assumes "P" "P ==> Q" shows "P & Q"
   564 by (iprover intro: conjI assms)
   565 
   566 
   567 subsubsection {*Disjunction*}
   568 
   569 lemma disjI1: "P ==> P|Q"
   570 apply (unfold or_def)
   571 apply (iprover intro: allI impI mp)
   572 done
   573 
   574 lemma disjI2: "Q ==> P|Q"
   575 apply (unfold or_def)
   576 apply (iprover intro: allI impI mp)
   577 done
   578 
   579 lemma disjE:
   580   assumes major: "P|Q"
   581       and minorP: "P ==> R"
   582       and minorQ: "Q ==> R"
   583   shows "R"
   584 by (iprover intro: minorP minorQ impI
   585                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   586 
   587 
   588 subsubsection {*Classical logic*}
   589 
   590 lemma classical:
   591   assumes prem: "~P ==> P"
   592   shows "P"
   593 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   594 apply assumption
   595 apply (rule notI [THEN prem, THEN eqTrueI])
   596 apply (erule subst)
   597 apply assumption
   598 done
   599 
   600 lemmas ccontr = FalseE [THEN classical, standard]
   601 
   602 (*notE with premises exchanged; it discharges ~R so that it can be used to
   603   make elimination rules*)
   604 lemma rev_notE:
   605   assumes premp: "P"
   606       and premnot: "~R ==> ~P"
   607   shows "R"
   608 apply (rule ccontr)
   609 apply (erule notE [OF premnot premp])
   610 done
   611 
   612 (*Double negation law*)
   613 lemma notnotD: "~~P ==> P"
   614 apply (rule classical)
   615 apply (erule notE)
   616 apply assumption
   617 done
   618 
   619 lemma contrapos_pp:
   620   assumes p1: "Q"
   621       and p2: "~P ==> ~Q"
   622   shows "P"
   623 by (iprover intro: classical p1 p2 notE)
   624 
   625 
   626 subsubsection {*Unique existence*}
   627 
   628 lemma ex1I:
   629   assumes "P a" "!!x. P(x) ==> x=a"
   630   shows "EX! x. P(x)"
   631 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   632 
   633 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   634 lemma ex_ex1I:
   635   assumes ex_prem: "EX x. P(x)"
   636       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   637   shows "EX! x. P(x)"
   638 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   639 
   640 lemma ex1E:
   641   assumes major: "EX! x. P(x)"
   642       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   643   shows "R"
   644 apply (rule major [unfolded Ex1_def, THEN exE])
   645 apply (erule conjE)
   646 apply (iprover intro: minor)
   647 done
   648 
   649 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   650 apply (erule ex1E)
   651 apply (rule exI)
   652 apply assumption
   653 done
   654 
   655 
   656 subsubsection {*THE: definite description operator*}
   657 
   658 lemma the_equality:
   659   assumes prema: "P a"
   660       and premx: "!!x. P x ==> x=a"
   661   shows "(THE x. P x) = a"
   662 apply (rule trans [OF _ the_eq_trivial])
   663 apply (rule_tac f = "The" in arg_cong)
   664 apply (rule ext)
   665 apply (rule iffI)
   666  apply (erule premx)
   667 apply (erule ssubst, rule prema)
   668 done
   669 
   670 lemma theI:
   671   assumes "P a" and "!!x. P x ==> x=a"
   672   shows "P (THE x. P x)"
   673 by (iprover intro: assms the_equality [THEN ssubst])
   674 
   675 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   676 apply (erule ex1E)
   677 apply (erule theI)
   678 apply (erule allE)
   679 apply (erule mp)
   680 apply assumption
   681 done
   682 
   683 (*Easier to apply than theI: only one occurrence of P*)
   684 lemma theI2:
   685   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   686   shows "Q (THE x. P x)"
   687 by (iprover intro: assms theI)
   688 
   689 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   690 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   691            elim:allE impE)
   692 
   693 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   694 apply (rule the_equality)
   695 apply  assumption
   696 apply (erule ex1E)
   697 apply (erule all_dupE)
   698 apply (drule mp)
   699 apply  assumption
   700 apply (erule ssubst)
   701 apply (erule allE)
   702 apply (erule mp)
   703 apply assumption
   704 done
   705 
   706 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   707 apply (rule the_equality)
   708 apply (rule refl)
   709 apply (erule sym)
   710 done
   711 
   712 
   713 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   714 
   715 lemma disjCI:
   716   assumes "~Q ==> P" shows "P|Q"
   717 apply (rule classical)
   718 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   719 done
   720 
   721 lemma excluded_middle: "~P | P"
   722 by (iprover intro: disjCI)
   723 
   724 text {*
   725   case distinction as a natural deduction rule.
   726   Note that @{term "~P"} is the second case, not the first
   727 *}
   728 lemma case_split [case_names True False]:
   729   assumes prem1: "P ==> Q"
   730       and prem2: "~P ==> Q"
   731   shows "Q"
   732 apply (rule excluded_middle [THEN disjE])
   733 apply (erule prem2)
   734 apply (erule prem1)
   735 done
   736 
   737 (*Classical implies (-->) elimination. *)
   738 lemma impCE:
   739   assumes major: "P-->Q"
   740       and minor: "~P ==> R" "Q ==> R"
   741   shows "R"
   742 apply (rule excluded_middle [of P, THEN disjE])
   743 apply (iprover intro: minor major [THEN mp])+
   744 done
   745 
   746 (*This version of --> elimination works on Q before P.  It works best for
   747   those cases in which P holds "almost everywhere".  Can't install as
   748   default: would break old proofs.*)
   749 lemma impCE':
   750   assumes major: "P-->Q"
   751       and minor: "Q ==> R" "~P ==> R"
   752   shows "R"
   753 apply (rule excluded_middle [of P, THEN disjE])
   754 apply (iprover intro: minor major [THEN mp])+
   755 done
   756 
   757 (*Classical <-> elimination. *)
   758 lemma iffCE:
   759   assumes major: "P=Q"
   760       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   761   shows "R"
   762 apply (rule major [THEN iffE])
   763 apply (iprover intro: minor elim: impCE notE)
   764 done
   765 
   766 lemma exCI:
   767   assumes "ALL x. ~P(x) ==> P(a)"
   768   shows "EX x. P(x)"
   769 apply (rule ccontr)
   770 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   771 done
   772 
   773 
   774 subsubsection {* Intuitionistic Reasoning *}
   775 
   776 lemma impE':
   777   assumes 1: "P --> Q"
   778     and 2: "Q ==> R"
   779     and 3: "P --> Q ==> P"
   780   shows R
   781 proof -
   782   from 3 and 1 have P .
   783   with 1 have Q by (rule impE)
   784   with 2 show R .
   785 qed
   786 
   787 lemma allE':
   788   assumes 1: "ALL x. P x"
   789     and 2: "P x ==> ALL x. P x ==> Q"
   790   shows Q
   791 proof -
   792   from 1 have "P x" by (rule spec)
   793   from this and 1 show Q by (rule 2)
   794 qed
   795 
   796 lemma notE':
   797   assumes 1: "~ P"
   798     and 2: "~ P ==> P"
   799   shows R
   800 proof -
   801   from 2 and 1 have P .
   802   with 1 show R by (rule notE)
   803 qed
   804 
   805 lemma TrueE: "True ==> P ==> P" .
   806 lemma notFalseE: "~ False ==> P ==> P" .
   807 
   808 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   809   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   810   and [Pure.elim 2] = allE notE' impE'
   811   and [Pure.intro] = exI disjI2 disjI1
   812 
   813 lemmas [trans] = trans
   814   and [sym] = sym not_sym
   815   and [Pure.elim?] = iffD1 iffD2 impE
   816 
   817 use "hologic.ML"
   818 
   819 
   820 subsubsection {* Atomizing meta-level connectives *}
   821 
   822 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   823 proof
   824   assume "!!x. P x"
   825   then show "ALL x. P x" ..
   826 next
   827   assume "ALL x. P x"
   828   then show "!!x. P x" by (rule allE)
   829 qed
   830 
   831 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   832 proof
   833   assume r: "A ==> B"
   834   show "A --> B" by (rule impI) (rule r)
   835 next
   836   assume "A --> B" and A
   837   then show B by (rule mp)
   838 qed
   839 
   840 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   841 proof
   842   assume r: "A ==> False"
   843   show "~A" by (rule notI) (rule r)
   844 next
   845   assume "~A" and A
   846   then show False by (rule notE)
   847 qed
   848 
   849 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   850 proof
   851   assume "x == y"
   852   show "x = y" by (unfold `x == y`) (rule refl)
   853 next
   854   assume "x = y"
   855   then show "x == y" by (rule eq_reflection)
   856 qed
   857 
   858 lemma atomize_conj [atomize]:
   859   includes meta_conjunction_syntax
   860   shows "(A && B) == Trueprop (A & B)"
   861 proof
   862   assume conj: "A && B"
   863   show "A & B"
   864   proof (rule conjI)
   865     from conj show A by (rule conjunctionD1)
   866     from conj show B by (rule conjunctionD2)
   867   qed
   868 next
   869   assume conj: "A & B"
   870   show "A && B"
   871   proof -
   872     from conj show A ..
   873     from conj show B ..
   874   qed
   875 qed
   876 
   877 lemmas [symmetric, rulify] = atomize_all atomize_imp
   878   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   879 
   880 
   881 subsubsection {* Atomizing elimination rules *}
   882 
   883 setup AtomizeElim.setup
   884 
   885 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   886   by rule iprover+
   887 
   888 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   889   by rule iprover+
   890 
   891 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   892   by rule iprover+
   893 
   894 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   895 
   896 
   897 subsection {* Package setup *}
   898 
   899 subsubsection {* Classical Reasoner setup *}
   900 
   901 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   902   by (rule classical) iprover
   903 
   904 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   905   by (rule classical) iprover
   906 
   907 lemma thin_refl:
   908   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   909 
   910 ML {*
   911 structure Hypsubst = HypsubstFun(
   912 struct
   913   structure Simplifier = Simplifier
   914   val dest_eq = HOLogic.dest_eq
   915   val dest_Trueprop = HOLogic.dest_Trueprop
   916   val dest_imp = HOLogic.dest_imp
   917   val eq_reflection = @{thm eq_reflection}
   918   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   919   val imp_intr = @{thm impI}
   920   val rev_mp = @{thm rev_mp}
   921   val subst = @{thm subst}
   922   val sym = @{thm sym}
   923   val thin_refl = @{thm thin_refl};
   924   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   925                      by (unfold prop_def) (drule eq_reflection, unfold)}
   926 end);
   927 open Hypsubst;
   928 
   929 structure Classical = ClassicalFun(
   930 struct
   931   val imp_elim = @{thm imp_elim}
   932   val not_elim = @{thm notE}
   933   val swap = @{thm swap}
   934   val classical = @{thm classical}
   935   val sizef = Drule.size_of_thm
   936   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   937 end);
   938 
   939 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   940 open BasicClassical;
   941 
   942 ML_Antiquote.value "claset"
   943   (Scan.succeed "Classical.local_claset_of (ML_Context.the_local_context ())");
   944 
   945 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   946 
   947 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   948 *}
   949 
   950 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   951   These theorems typically produce clauses that are prolific (match too many equality or
   952   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   953 
   954 setup {*
   955 let
   956   (*prevent substitution on bool*)
   957   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   958     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   959       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   960 in
   961   Hypsubst.hypsubst_setup
   962   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   963   #> Classical.setup
   964   #> ResAtpset.setup
   965   #> ResBlacklist.setup
   966 end
   967 *}
   968 
   969 declare iffI [intro!]
   970   and notI [intro!]
   971   and impI [intro!]
   972   and disjCI [intro!]
   973   and conjI [intro!]
   974   and TrueI [intro!]
   975   and refl [intro!]
   976 
   977 declare iffCE [elim!]
   978   and FalseE [elim!]
   979   and impCE [elim!]
   980   and disjE [elim!]
   981   and conjE [elim!]
   982   and conjE [elim!]
   983 
   984 declare ex_ex1I [intro!]
   985   and allI [intro!]
   986   and the_equality [intro]
   987   and exI [intro]
   988 
   989 declare exE [elim!]
   990   allE [elim]
   991 
   992 ML {* val HOL_cs = @{claset} *}
   993 
   994 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   995   apply (erule swap)
   996   apply (erule (1) meta_mp)
   997   done
   998 
   999 declare ex_ex1I [rule del, intro! 2]
  1000   and ex1I [intro]
  1001 
  1002 lemmas [intro?] = ext
  1003   and [elim?] = ex1_implies_ex
  1004 
  1005 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
  1006 lemma alt_ex1E [elim!]:
  1007   assumes major: "\<exists>!x. P x"
  1008       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
  1009   shows R
  1010 apply (rule ex1E [OF major])
  1011 apply (rule prem)
  1012 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1013 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1014 apply iprover
  1015 done
  1016 
  1017 ML {*
  1018 structure Blast = BlastFun
  1019 (
  1020   type claset = Classical.claset
  1021   val equality_name = @{const_name "op ="}
  1022   val not_name = @{const_name Not}
  1023   val notE = @{thm notE}
  1024   val ccontr = @{thm ccontr}
  1025   val contr_tac = Classical.contr_tac
  1026   val dup_intr = Classical.dup_intr
  1027   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1028   val claset = Classical.claset
  1029   val rep_cs = Classical.rep_cs
  1030   val cla_modifiers = Classical.cla_modifiers
  1031   val cla_meth' = Classical.cla_meth'
  1032 );
  1033 val Blast_tac = Blast.Blast_tac;
  1034 val blast_tac = Blast.blast_tac;
  1035 *}
  1036 
  1037 setup Blast.setup
  1038 
  1039 
  1040 subsubsection {* Simplifier *}
  1041 
  1042 lemma eta_contract_eq: "(%s. f s) = f" ..
  1043 
  1044 lemma simp_thms:
  1045   shows not_not: "(~ ~ P) = P"
  1046   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1047   and
  1048     "(P ~= Q) = (P = (~Q))"
  1049     "(P | ~P) = True"    "(~P | P) = True"
  1050     "(x = x) = True"
  1051   and not_True_eq_False: "(\<not> True) = False"
  1052   and not_False_eq_True: "(\<not> False) = True"
  1053   and
  1054     "(~P) ~= P"  "P ~= (~P)"
  1055     "(True=P) = P"
  1056   and eq_True: "(P = True) = P"
  1057   and "(False=P) = (~P)"
  1058   and eq_False: "(P = False) = (\<not> P)"
  1059   and
  1060     "(True --> P) = P"  "(False --> P) = True"
  1061     "(P --> True) = True"  "(P --> P) = True"
  1062     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1063     "(P & True) = P"  "(True & P) = P"
  1064     "(P & False) = False"  "(False & P) = False"
  1065     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1066     "(P & ~P) = False"    "(~P & P) = False"
  1067     "(P | True) = True"  "(True | P) = True"
  1068     "(P | False) = P"  "(False | P) = P"
  1069     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1070     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1071     -- {* needed for the one-point-rule quantifier simplification procs *}
  1072     -- {* essential for termination!! *} and
  1073     "!!P. (EX x. x=t & P(x)) = P(t)"
  1074     "!!P. (EX x. t=x & P(x)) = P(t)"
  1075     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1076     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1077   by (blast, blast, blast, blast, blast, iprover+)
  1078 
  1079 lemma disj_absorb: "(A | A) = A"
  1080   by blast
  1081 
  1082 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1083   by blast
  1084 
  1085 lemma conj_absorb: "(A & A) = A"
  1086   by blast
  1087 
  1088 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1089   by blast
  1090 
  1091 lemma eq_ac:
  1092   shows eq_commute: "(a=b) = (b=a)"
  1093     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1094     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1095 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1096 
  1097 lemma conj_comms:
  1098   shows conj_commute: "(P&Q) = (Q&P)"
  1099     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1100 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1101 
  1102 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1103 
  1104 lemma disj_comms:
  1105   shows disj_commute: "(P|Q) = (Q|P)"
  1106     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1107 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1108 
  1109 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1110 
  1111 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1112 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1113 
  1114 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1115 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1116 
  1117 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1118 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1119 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1120 
  1121 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1122 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1123 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1124 
  1125 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1126 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1127 
  1128 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1129   by iprover
  1130 
  1131 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1132 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1133 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1134 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1135 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1136 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1137   by blast
  1138 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1139 
  1140 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1141 
  1142 
  1143 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1144   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1145   -- {* cases boil down to the same thing. *}
  1146   by blast
  1147 
  1148 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1149 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1150 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1151 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1152 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1153 
  1154 declare All_def [noatp]
  1155 
  1156 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1157 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1158 
  1159 text {*
  1160   \medskip The @{text "&"} congruence rule: not included by default!
  1161   May slow rewrite proofs down by as much as 50\% *}
  1162 
  1163 lemma conj_cong:
  1164     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1165   by iprover
  1166 
  1167 lemma rev_conj_cong:
  1168     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1169   by iprover
  1170 
  1171 text {* The @{text "|"} congruence rule: not included by default! *}
  1172 
  1173 lemma disj_cong:
  1174     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1175   by blast
  1176 
  1177 
  1178 text {* \medskip if-then-else rules *}
  1179 
  1180 lemma if_True: "(if True then x else y) = x"
  1181   by (unfold if_def) blast
  1182 
  1183 lemma if_False: "(if False then x else y) = y"
  1184   by (unfold if_def) blast
  1185 
  1186 lemma if_P: "P ==> (if P then x else y) = x"
  1187   by (unfold if_def) blast
  1188 
  1189 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1190   by (unfold if_def) blast
  1191 
  1192 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1193   apply (rule case_split [of Q])
  1194    apply (simplesubst if_P)
  1195     prefer 3 apply (simplesubst if_not_P, blast+)
  1196   done
  1197 
  1198 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1199 by (simplesubst split_if, blast)
  1200 
  1201 lemmas if_splits [noatp] = split_if split_if_asm
  1202 
  1203 lemma if_cancel: "(if c then x else x) = x"
  1204 by (simplesubst split_if, blast)
  1205 
  1206 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1207 by (simplesubst split_if, blast)
  1208 
  1209 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1210   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1211   by (rule split_if)
  1212 
  1213 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1214   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1215   apply (simplesubst split_if, blast)
  1216   done
  1217 
  1218 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1219 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1220 
  1221 text {* \medskip let rules for simproc *}
  1222 
  1223 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1224   by (unfold Let_def)
  1225 
  1226 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1227   by (unfold Let_def)
  1228 
  1229 text {*
  1230   The following copy of the implication operator is useful for
  1231   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1232   its premise.
  1233 *}
  1234 
  1235 constdefs
  1236   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1237   [code func del]: "simp_implies \<equiv> op ==>"
  1238 
  1239 lemma simp_impliesI:
  1240   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1241   shows "PROP P =simp=> PROP Q"
  1242   apply (unfold simp_implies_def)
  1243   apply (rule PQ)
  1244   apply assumption
  1245   done
  1246 
  1247 lemma simp_impliesE:
  1248   assumes PQ: "PROP P =simp=> PROP Q"
  1249   and P: "PROP P"
  1250   and QR: "PROP Q \<Longrightarrow> PROP R"
  1251   shows "PROP R"
  1252   apply (rule QR)
  1253   apply (rule PQ [unfolded simp_implies_def])
  1254   apply (rule P)
  1255   done
  1256 
  1257 lemma simp_implies_cong:
  1258   assumes PP' :"PROP P == PROP P'"
  1259   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1260   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1261 proof (unfold simp_implies_def, rule equal_intr_rule)
  1262   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1263   and P': "PROP P'"
  1264   from PP' [symmetric] and P' have "PROP P"
  1265     by (rule equal_elim_rule1)
  1266   then have "PROP Q" by (rule PQ)
  1267   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1268 next
  1269   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1270   and P: "PROP P"
  1271   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1272   then have "PROP Q'" by (rule P'Q')
  1273   with P'QQ' [OF P', symmetric] show "PROP Q"
  1274     by (rule equal_elim_rule1)
  1275 qed
  1276 
  1277 lemma uncurry:
  1278   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1279   shows "P \<and> Q \<longrightarrow> R"
  1280   using assms by blast
  1281 
  1282 lemma iff_allI:
  1283   assumes "\<And>x. P x = Q x"
  1284   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1285   using assms by blast
  1286 
  1287 lemma iff_exI:
  1288   assumes "\<And>x. P x = Q x"
  1289   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1290   using assms by blast
  1291 
  1292 lemma all_comm:
  1293   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1294   by blast
  1295 
  1296 lemma ex_comm:
  1297   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1298   by blast
  1299 
  1300 use "simpdata.ML"
  1301 ML {* open Simpdata *}
  1302 
  1303 setup {*
  1304   Simplifier.method_setup Splitter.split_modifiers
  1305   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1306   #> Splitter.setup
  1307   #> clasimp_setup
  1308   #> EqSubst.setup
  1309 *}
  1310 
  1311 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1312 
  1313 simproc_setup neq ("x = y") = {* fn _ =>
  1314 let
  1315   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1316   fun is_neq eq lhs rhs thm =
  1317     (case Thm.prop_of thm of
  1318       _ $ (Not $ (eq' $ l' $ r')) =>
  1319         Not = HOLogic.Not andalso eq' = eq andalso
  1320         r' aconv lhs andalso l' aconv rhs
  1321     | _ => false);
  1322   fun proc ss ct =
  1323     (case Thm.term_of ct of
  1324       eq $ lhs $ rhs =>
  1325         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1326           SOME thm => SOME (thm RS neq_to_EQ_False)
  1327         | NONE => NONE)
  1328      | _ => NONE);
  1329 in proc end;
  1330 *}
  1331 
  1332 simproc_setup let_simp ("Let x f") = {*
  1333 let
  1334   val (f_Let_unfold, x_Let_unfold) =
  1335     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1336     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1337   val (f_Let_folded, x_Let_folded) =
  1338     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1339     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1340   val g_Let_folded =
  1341     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1342 
  1343   fun proc _ ss ct =
  1344     let
  1345       val ctxt = Simplifier.the_context ss;
  1346       val thy = ProofContext.theory_of ctxt;
  1347       val t = Thm.term_of ct;
  1348       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1349     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1350       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1351         if is_Free x orelse is_Bound x orelse is_Const x
  1352         then SOME @{thm Let_def}
  1353         else
  1354           let
  1355             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1356             val cx = cterm_of thy x;
  1357             val {T=xT,...} = rep_cterm cx;
  1358             val cf = cterm_of thy f;
  1359             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1360             val (_$_$g) = prop_of fx_g;
  1361             val g' = abstract_over (x,g);
  1362           in (if (g aconv g')
  1363                then
  1364                   let
  1365                     val rl =
  1366                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1367                   in SOME (rl OF [fx_g]) end
  1368                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1369                else let
  1370                      val abs_g'= Abs (n,xT,g');
  1371                      val g'x = abs_g'$x;
  1372                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1373                      val rl = cterm_instantiate
  1374                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1375                                 (g_Let_folded,cterm_of thy abs_g')]
  1376                                @{thm Let_folded};
  1377                    in SOME (rl OF [transitive fx_g g_g'x])
  1378                    end)
  1379           end
  1380       | _ => NONE)
  1381     end
  1382 in proc end *}
  1383 
  1384 
  1385 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1386 proof
  1387   assume "True \<Longrightarrow> PROP P"
  1388   from this [OF TrueI] show "PROP P" .
  1389 next
  1390   assume "PROP P"
  1391   then show "PROP P" .
  1392 qed
  1393 
  1394 lemma ex_simps:
  1395   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1396   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1397   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1398   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1399   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1400   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1401   -- {* Miniscoping: pushing in existential quantifiers. *}
  1402   by (iprover | blast)+
  1403 
  1404 lemma all_simps:
  1405   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1406   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1407   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1408   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1409   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1410   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1411   -- {* Miniscoping: pushing in universal quantifiers. *}
  1412   by (iprover | blast)+
  1413 
  1414 lemmas [simp] =
  1415   triv_forall_equality (*prunes params*)
  1416   True_implies_equals  (*prune asms `True'*)
  1417   if_True
  1418   if_False
  1419   if_cancel
  1420   if_eq_cancel
  1421   imp_disjL
  1422   (*In general it seems wrong to add distributive laws by default: they
  1423     might cause exponential blow-up.  But imp_disjL has been in for a while
  1424     and cannot be removed without affecting existing proofs.  Moreover,
  1425     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1426     grounds that it allows simplification of R in the two cases.*)
  1427   conj_assoc
  1428   disj_assoc
  1429   de_Morgan_conj
  1430   de_Morgan_disj
  1431   imp_disj1
  1432   imp_disj2
  1433   not_imp
  1434   disj_not1
  1435   not_all
  1436   not_ex
  1437   cases_simp
  1438   the_eq_trivial
  1439   the_sym_eq_trivial
  1440   ex_simps
  1441   all_simps
  1442   simp_thms
  1443 
  1444 lemmas [cong] = imp_cong simp_implies_cong
  1445 lemmas [split] = split_if
  1446 
  1447 ML {* val HOL_ss = @{simpset} *}
  1448 
  1449 text {* Simplifies x assuming c and y assuming ~c *}
  1450 lemma if_cong:
  1451   assumes "b = c"
  1452       and "c \<Longrightarrow> x = u"
  1453       and "\<not> c \<Longrightarrow> y = v"
  1454   shows "(if b then x else y) = (if c then u else v)"
  1455   unfolding if_def using assms by simp
  1456 
  1457 text {* Prevents simplification of x and y:
  1458   faster and allows the execution of functional programs. *}
  1459 lemma if_weak_cong [cong]:
  1460   assumes "b = c"
  1461   shows "(if b then x else y) = (if c then x else y)"
  1462   using assms by (rule arg_cong)
  1463 
  1464 text {* Prevents simplification of t: much faster *}
  1465 lemma let_weak_cong:
  1466   assumes "a = b"
  1467   shows "(let x = a in t x) = (let x = b in t x)"
  1468   using assms by (rule arg_cong)
  1469 
  1470 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1471 lemma eq_cong2:
  1472   assumes "u = u'"
  1473   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1474   using assms by simp
  1475 
  1476 lemma if_distrib:
  1477   "f (if c then x else y) = (if c then f x else f y)"
  1478   by simp
  1479 
  1480 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1481   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1482 lemma restrict_to_left:
  1483   assumes "x = y"
  1484   shows "(x = z) = (y = z)"
  1485   using assms by simp
  1486 
  1487 
  1488 subsubsection {* Generic cases and induction *}
  1489 
  1490 text {* Rule projections: *}
  1491 
  1492 ML {*
  1493 structure ProjectRule = ProjectRuleFun
  1494 (
  1495   val conjunct1 = @{thm conjunct1}
  1496   val conjunct2 = @{thm conjunct2}
  1497   val mp = @{thm mp}
  1498 )
  1499 *}
  1500 
  1501 constdefs
  1502   induct_forall where "induct_forall P == \<forall>x. P x"
  1503   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1504   induct_equal where "induct_equal x y == x = y"
  1505   induct_conj where "induct_conj A B == A \<and> B"
  1506 
  1507 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1508   by (unfold atomize_all induct_forall_def)
  1509 
  1510 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1511   by (unfold atomize_imp induct_implies_def)
  1512 
  1513 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1514   by (unfold atomize_eq induct_equal_def)
  1515 
  1516 lemma induct_conj_eq:
  1517   includes meta_conjunction_syntax
  1518   shows "(A && B) == Trueprop (induct_conj A B)"
  1519   by (unfold atomize_conj induct_conj_def)
  1520 
  1521 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1522 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1523 lemmas induct_rulify_fallback =
  1524   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1525 
  1526 
  1527 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1528     induct_conj (induct_forall A) (induct_forall B)"
  1529   by (unfold induct_forall_def induct_conj_def) iprover
  1530 
  1531 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1532     induct_conj (induct_implies C A) (induct_implies C B)"
  1533   by (unfold induct_implies_def induct_conj_def) iprover
  1534 
  1535 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1536 proof
  1537   assume r: "induct_conj A B ==> PROP C" and A B
  1538   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1539 next
  1540   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1541   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1542 qed
  1543 
  1544 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1545 
  1546 hide const induct_forall induct_implies induct_equal induct_conj
  1547 
  1548 text {* Method setup. *}
  1549 
  1550 ML {*
  1551 structure Induct = InductFun
  1552 (
  1553   val cases_default = @{thm case_split}
  1554   val atomize = @{thms induct_atomize}
  1555   val rulify = @{thms induct_rulify}
  1556   val rulify_fallback = @{thms induct_rulify_fallback}
  1557 )
  1558 *}
  1559 
  1560 setup Induct.setup
  1561 
  1562 use "~~/src/Tools/induct_tacs.ML"
  1563 setup InductTacs.setup
  1564 
  1565 
  1566 subsection {* Other simple lemmas and lemma duplicates *}
  1567 
  1568 lemma Let_0 [simp]: "Let 0 f = f 0"
  1569   unfolding Let_def ..
  1570 
  1571 lemma Let_1 [simp]: "Let 1 f = f 1"
  1572   unfolding Let_def ..
  1573 
  1574 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1575   by blast+
  1576 
  1577 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1578   apply (rule iffI)
  1579   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1580   apply (fast dest!: theI')
  1581   apply (fast intro: ext the1_equality [symmetric])
  1582   apply (erule ex1E)
  1583   apply (rule allI)
  1584   apply (rule ex1I)
  1585   apply (erule spec)
  1586   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1587   apply (erule impE)
  1588   apply (rule allI)
  1589   apply (case_tac "xa = x")
  1590   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1591   done
  1592 
  1593 lemma mk_left_commute:
  1594   fixes f (infix "\<otimes>" 60)
  1595   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1596           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1597   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1598   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1599 
  1600 lemmas eq_sym_conv = eq_commute
  1601 
  1602 lemma nnf_simps:
  1603   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1604   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1605   "(\<not> \<not>(P)) = P"
  1606 by blast+
  1607 
  1608 
  1609 subsection {* Basic ML bindings *}
  1610 
  1611 ML {*
  1612 val FalseE = @{thm FalseE}
  1613 val Let_def = @{thm Let_def}
  1614 val TrueI = @{thm TrueI}
  1615 val allE = @{thm allE}
  1616 val allI = @{thm allI}
  1617 val all_dupE = @{thm all_dupE}
  1618 val arg_cong = @{thm arg_cong}
  1619 val box_equals = @{thm box_equals}
  1620 val ccontr = @{thm ccontr}
  1621 val classical = @{thm classical}
  1622 val conjE = @{thm conjE}
  1623 val conjI = @{thm conjI}
  1624 val conjunct1 = @{thm conjunct1}
  1625 val conjunct2 = @{thm conjunct2}
  1626 val disjCI = @{thm disjCI}
  1627 val disjE = @{thm disjE}
  1628 val disjI1 = @{thm disjI1}
  1629 val disjI2 = @{thm disjI2}
  1630 val eq_reflection = @{thm eq_reflection}
  1631 val ex1E = @{thm ex1E}
  1632 val ex1I = @{thm ex1I}
  1633 val ex1_implies_ex = @{thm ex1_implies_ex}
  1634 val exE = @{thm exE}
  1635 val exI = @{thm exI}
  1636 val excluded_middle = @{thm excluded_middle}
  1637 val ext = @{thm ext}
  1638 val fun_cong = @{thm fun_cong}
  1639 val iffD1 = @{thm iffD1}
  1640 val iffD2 = @{thm iffD2}
  1641 val iffI = @{thm iffI}
  1642 val impE = @{thm impE}
  1643 val impI = @{thm impI}
  1644 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1645 val mp = @{thm mp}
  1646 val notE = @{thm notE}
  1647 val notI = @{thm notI}
  1648 val not_all = @{thm not_all}
  1649 val not_ex = @{thm not_ex}
  1650 val not_iff = @{thm not_iff}
  1651 val not_not = @{thm not_not}
  1652 val not_sym = @{thm not_sym}
  1653 val refl = @{thm refl}
  1654 val rev_mp = @{thm rev_mp}
  1655 val spec = @{thm spec}
  1656 val ssubst = @{thm ssubst}
  1657 val subst = @{thm subst}
  1658 val sym = @{thm sym}
  1659 val trans = @{thm trans}
  1660 *}
  1661 
  1662 
  1663 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1664 
  1665 setup {*
  1666   Code.map_pre (K HOL_basic_ss)
  1667   #> Code.map_post (K HOL_basic_ss)
  1668 *}
  1669 
  1670 code_datatype True False
  1671 
  1672 code_datatype "TYPE('a\<Colon>{})"
  1673 
  1674 code_datatype Trueprop "prop"
  1675 
  1676 lemma Let_case_cert:
  1677   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1678   shows "CASE x \<equiv> f x"
  1679   using assms by simp_all
  1680 
  1681 lemma If_case_cert:
  1682   includes meta_conjunction_syntax
  1683   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1684   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1685   using assms by simp_all
  1686 
  1687 setup {*
  1688   Code.add_case @{thm Let_case_cert}
  1689   #> Code.add_case @{thm If_case_cert}
  1690   #> Code.add_undefined @{const_name undefined}
  1691 *}
  1692 
  1693 class eq = type +
  1694   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1695   assumes eq: "eq x y \<longleftrightarrow> x = y "
  1696 begin
  1697 
  1698 lemma equals_eq [code inline, code func]: "op = \<equiv> eq"
  1699   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq)
  1700 
  1701 declare equals_eq [symmetric, code post]
  1702 
  1703 end
  1704 
  1705 hide (open) const eq
  1706 hide const eq
  1707 
  1708 setup {*
  1709   Code_Unit.add_const_alias @{thm equals_eq}
  1710   #> Code_Name.setup
  1711   #> Code_ML.setup
  1712   #> Code_Haskell.setup
  1713   #> Nbe.setup
  1714 *}
  1715 
  1716 lemma [code func]:
  1717   shows "False \<and> x \<longleftrightarrow> False"
  1718     and "True \<and> x \<longleftrightarrow> x"
  1719     and "x \<and> False \<longleftrightarrow> False"
  1720     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1721 
  1722 lemma [code func]:
  1723   shows "False \<or> x \<longleftrightarrow> x"
  1724     and "True \<or> x \<longleftrightarrow> True"
  1725     and "x \<or> False \<longleftrightarrow> x"
  1726     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1727 
  1728 lemma [code func]:
  1729   shows "\<not> True \<longleftrightarrow> False"
  1730     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1731 
  1732 lemmas [code func] = Let_def if_True if_False
  1733 
  1734 lemmas [code func, code unfold, symmetric, code post] = imp_conv_disj
  1735 
  1736 
  1737 subsection {* Legacy tactics and ML bindings *}
  1738 
  1739 ML {*
  1740 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1741 
  1742 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1743 local
  1744   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1745     | wrong_prem (Bound _) = true
  1746     | wrong_prem _ = false;
  1747   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1748 in
  1749   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1750   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1751 end;
  1752 
  1753 val all_conj_distrib = thm "all_conj_distrib";
  1754 val all_simps = thms "all_simps";
  1755 val atomize_not = thm "atomize_not";
  1756 val case_split = thm "case_split";
  1757 val cases_simp = thm "cases_simp";
  1758 val choice_eq = thm "choice_eq"
  1759 val cong = thm "cong"
  1760 val conj_comms = thms "conj_comms";
  1761 val conj_cong = thm "conj_cong";
  1762 val de_Morgan_conj = thm "de_Morgan_conj";
  1763 val de_Morgan_disj = thm "de_Morgan_disj";
  1764 val disj_assoc = thm "disj_assoc";
  1765 val disj_comms = thms "disj_comms";
  1766 val disj_cong = thm "disj_cong";
  1767 val eq_ac = thms "eq_ac";
  1768 val eq_cong2 = thm "eq_cong2"
  1769 val Eq_FalseI = thm "Eq_FalseI";
  1770 val Eq_TrueI = thm "Eq_TrueI";
  1771 val Ex1_def = thm "Ex1_def"
  1772 val ex_disj_distrib = thm "ex_disj_distrib";
  1773 val ex_simps = thms "ex_simps";
  1774 val if_cancel = thm "if_cancel";
  1775 val if_eq_cancel = thm "if_eq_cancel";
  1776 val if_False = thm "if_False";
  1777 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1778 val iff = thm "iff"
  1779 val if_splits = thms "if_splits";
  1780 val if_True = thm "if_True";
  1781 val if_weak_cong = thm "if_weak_cong"
  1782 val imp_all = thm "imp_all";
  1783 val imp_cong = thm "imp_cong";
  1784 val imp_conjL = thm "imp_conjL";
  1785 val imp_conjR = thm "imp_conjR";
  1786 val imp_conv_disj = thm "imp_conv_disj";
  1787 val simp_implies_def = thm "simp_implies_def";
  1788 val simp_thms = thms "simp_thms";
  1789 val split_if = thm "split_if";
  1790 val the1_equality = thm "the1_equality"
  1791 val theI = thm "theI"
  1792 val theI' = thm "theI'"
  1793 val True_implies_equals = thm "True_implies_equals";
  1794 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1795 
  1796 *}
  1797 
  1798 end