src/HOL/SEQ.thy
author huffman
Fri Apr 30 13:31:32 2010 -0700 (2010-04-30)
changeset 36625 2ba6525f9905
parent 35748 5f35613d9a65
child 36647 edc381bf7200
child 36657 f376af79f6b7
permissions -rw-r--r--
add lemmas about convergent
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits
    14 begin
    15 
    16 definition
    17   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    18     --{*Standard definition of sequence converging to zero*}
    19   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    20 
    21 definition
    22   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    23     ("((_)/ ----> (_))" [60, 60] 60) where
    24     --{*Standard definition of convergence of sequence*}
    25   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    26 
    27 definition
    28   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    29     --{*Standard definition of limit using choice operator*}
    30   "lim X = (THE L. X ----> L)"
    31 
    32 definition
    33   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    34     --{*Standard definition of convergence*}
    35   "convergent X = (\<exists>L. X ----> L)"
    36 
    37 definition
    38   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    39     --{*Standard definition for bounded sequence*}
    40   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    41 
    42 definition
    43   monoseq :: "(nat=>real)=>bool" where
    44     --{*Definition of monotonicity. 
    45         The use of disjunction here complicates proofs considerably. 
    46         One alternative is to add a Boolean argument to indicate the direction. 
    47         Another is to develop the notions of increasing and decreasing first.*}
    48   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    49 
    50 definition
    51   incseq :: "(nat=>real)=>bool" where
    52     --{*Increasing sequence*}
    53   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    54 
    55 definition
    56   decseq :: "(nat=>real)=>bool" where
    57     --{*Increasing sequence*}
    58   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    59 
    60 definition
    61   subseq :: "(nat => nat) => bool" where
    62     --{*Definition of subsequence*}
    63   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    64 
    65 definition
    66   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    67     --{*Standard definition of the Cauchy condition*}
    68   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    69 
    70 
    71 subsection {* Bounded Sequences *}
    72 
    73 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    74 unfolding Bseq_def
    75 proof (intro exI conjI allI)
    76   show "0 < max K 1" by simp
    77 next
    78   fix n::nat
    79   have "norm (X n) \<le> K" by (rule K)
    80   thus "norm (X n) \<le> max K 1" by simp
    81 qed
    82 
    83 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    84 unfolding Bseq_def by auto
    85 
    86 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    87 proof (rule BseqI')
    88   let ?A = "norm ` X ` {..N}"
    89   have 1: "finite ?A" by simp
    90   fix n::nat
    91   show "norm (X n) \<le> max K (Max ?A)"
    92   proof (cases rule: linorder_le_cases)
    93     assume "n \<ge> N"
    94     hence "norm (X n) \<le> K" using K by simp
    95     thus "norm (X n) \<le> max K (Max ?A)" by simp
    96   next
    97     assume "n \<le> N"
    98     hence "norm (X n) \<in> ?A" by simp
    99     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
   100     thus "norm (X n) \<le> max K (Max ?A)" by simp
   101   qed
   102 qed
   103 
   104 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   105 unfolding Bseq_def by auto
   106 
   107 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   108 apply (erule BseqE)
   109 apply (rule_tac N="k" and K="K" in BseqI2')
   110 apply clarify
   111 apply (drule_tac x="n - k" in spec, simp)
   112 done
   113 
   114 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   115 unfolding Bfun_def eventually_sequentially
   116 apply (rule iffI)
   117 apply (simp add: Bseq_def)
   118 apply (auto intro: BseqI2')
   119 done
   120 
   121 
   122 subsection {* Sequences That Converge to Zero *}
   123 
   124 lemma ZseqI:
   125   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   126 unfolding Zseq_def by simp
   127 
   128 lemma ZseqD:
   129   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   130 unfolding Zseq_def by simp
   131 
   132 lemma Zseq_conv_Zfun: "Zseq X \<longleftrightarrow> Zfun X sequentially"
   133 unfolding Zseq_def Zfun_def eventually_sequentially ..
   134 
   135 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   136 unfolding Zseq_def by simp
   137 
   138 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   139 unfolding Zseq_def by force
   140 
   141 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   142 unfolding Zseq_def by simp
   143 
   144 lemma Zseq_imp_Zseq:
   145   assumes X: "Zseq X"
   146   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   147   shows "Zseq (\<lambda>n. Y n)"
   148 using X Y Zfun_imp_Zfun [of X sequentially Y K]
   149 unfolding Zseq_conv_Zfun by simp
   150 
   151 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   152 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   153 
   154 lemma Zseq_add:
   155   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n + Y n)"
   156 unfolding Zseq_conv_Zfun by (rule Zfun_add)
   157 
   158 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   159 unfolding Zseq_def by simp
   160 
   161 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   162 by (simp only: diff_minus Zseq_add Zseq_minus)
   163 
   164 lemma (in bounded_linear) Zseq:
   165   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. f (X n))"
   166 unfolding Zseq_conv_Zfun by (rule Zfun)
   167 
   168 lemma (in bounded_bilinear) Zseq:
   169   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   170 unfolding Zseq_conv_Zfun by (rule Zfun)
   171 
   172 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   173   "Zseq X \<Longrightarrow> Bseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   174 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   175 by (rule Zfun_prod_Bfun)
   176 
   177 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   178   "Bseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   179 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   180 by (rule Bfun_prod_Zfun)
   181 
   182 lemma (in bounded_bilinear) Zseq_left:
   183   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   184 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   185 
   186 lemma (in bounded_bilinear) Zseq_right:
   187   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   188 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   189 
   190 lemmas Zseq_mult = mult.Zseq
   191 lemmas Zseq_mult_right = mult.Zseq_right
   192 lemmas Zseq_mult_left = mult.Zseq_left
   193 
   194 
   195 subsection {* Limits of Sequences *}
   196 
   197 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   198   by simp
   199 
   200 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   201 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   202 
   203 lemma LIMSEQ_iff:
   204   fixes L :: "'a::real_normed_vector"
   205   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   206 unfolding LIMSEQ_def dist_norm ..
   207 
   208 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   209   by (auto simp add: LIMSEQ_def) (metis Suc_leD zero_less_Suc)  
   210 
   211 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   212 by (simp only: LIMSEQ_iff Zseq_def)
   213 
   214 lemma metric_LIMSEQ_I:
   215   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   216 by (simp add: LIMSEQ_def)
   217 
   218 lemma metric_LIMSEQ_D:
   219   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   220 by (simp add: LIMSEQ_def)
   221 
   222 lemma LIMSEQ_I:
   223   fixes L :: "'a::real_normed_vector"
   224   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   225 by (simp add: LIMSEQ_iff)
   226 
   227 lemma LIMSEQ_D:
   228   fixes L :: "'a::real_normed_vector"
   229   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   230 by (simp add: LIMSEQ_iff)
   231 
   232 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   233 by (simp add: LIMSEQ_def)
   234 
   235 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   236 apply (safe intro!: LIMSEQ_const)
   237 apply (rule ccontr)
   238 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   239 apply (simp add: zero_less_dist_iff)
   240 apply auto
   241 done
   242 
   243 lemma LIMSEQ_norm:
   244   fixes a :: "'a::real_normed_vector"
   245   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   246 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   247 
   248 lemma LIMSEQ_ignore_initial_segment:
   249   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   250 apply (rule metric_LIMSEQ_I)
   251 apply (drule (1) metric_LIMSEQ_D)
   252 apply (erule exE, rename_tac N)
   253 apply (rule_tac x=N in exI)
   254 apply simp
   255 done
   256 
   257 lemma LIMSEQ_offset:
   258   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   259 apply (rule metric_LIMSEQ_I)
   260 apply (drule (1) metric_LIMSEQ_D)
   261 apply (erule exE, rename_tac N)
   262 apply (rule_tac x="N + k" in exI)
   263 apply clarify
   264 apply (drule_tac x="n - k" in spec)
   265 apply (simp add: le_diff_conv2)
   266 done
   267 
   268 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   269 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   270 
   271 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   272 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   273 
   274 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   275 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   276 
   277 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   278   unfolding LIMSEQ_def
   279   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   280 
   281 lemma LIMSEQ_add:
   282   fixes a b :: "'a::real_normed_vector"
   283   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   284 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   285 
   286 lemma LIMSEQ_minus:
   287   fixes a :: "'a::real_normed_vector"
   288   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   289 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   290 
   291 lemma LIMSEQ_minus_cancel:
   292   fixes a :: "'a::real_normed_vector"
   293   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   294 by (drule LIMSEQ_minus, simp)
   295 
   296 lemma LIMSEQ_diff:
   297   fixes a b :: "'a::real_normed_vector"
   298   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   299 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   300 
   301 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   302 apply (rule ccontr)
   303 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   304 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   305 apply (clarify, rename_tac M N)
   306 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   307 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   308 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   309 apply (subst dist_commute, rule dist_triangle)
   310 done
   311 
   312 lemma (in bounded_linear) LIMSEQ:
   313   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   314 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   315 
   316 lemma (in bounded_bilinear) LIMSEQ:
   317   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   318 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   319 
   320 lemma LIMSEQ_mult:
   321   fixes a b :: "'a::real_normed_algebra"
   322   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   323 by (rule mult.LIMSEQ)
   324 
   325 lemma increasing_LIMSEQ:
   326   fixes f :: "nat \<Rightarrow> real"
   327   assumes inc: "!!n. f n \<le> f (Suc n)"
   328       and bdd: "!!n. f n \<le> l"
   329       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   330   shows "f ----> l"
   331 proof (auto simp add: LIMSEQ_def)
   332   fix e :: real
   333   assume e: "0 < e"
   334   then obtain N where "l \<le> f N + e/2"
   335     by (metis half_gt_zero e en that)
   336   hence N: "l < f N + e" using e
   337     by simp
   338   { fix k
   339     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   340       by (simp add: bdd) 
   341     have "\<bar>f (N+k) - l\<bar> < e"
   342     proof (induct k)
   343       case 0 show ?case using N
   344         by simp   
   345     next
   346       case (Suc k) thus ?case using N inc [of "N+k"]
   347         by simp
   348     qed 
   349   } note 1 = this
   350   { fix n
   351     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   352       by simp 
   353   } note [intro] = this
   354   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   355     by (auto simp add: dist_real_def) 
   356   qed
   357 
   358 lemma Bseq_inverse_lemma:
   359   fixes x :: "'a::real_normed_div_algebra"
   360   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   361 apply (subst nonzero_norm_inverse, clarsimp)
   362 apply (erule (1) le_imp_inverse_le)
   363 done
   364 
   365 lemma Bseq_inverse:
   366   fixes a :: "'a::real_normed_div_algebra"
   367   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   368 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   369 by (rule Bfun_inverse)
   370 
   371 lemma LIMSEQ_inverse:
   372   fixes a :: "'a::real_normed_div_algebra"
   373   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   374 unfolding LIMSEQ_conv_tendsto
   375 by (rule tendsto_inverse)
   376 
   377 lemma LIMSEQ_divide:
   378   fixes a b :: "'a::real_normed_field"
   379   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   380 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   381 
   382 lemma LIMSEQ_pow:
   383   fixes a :: "'a::{power, real_normed_algebra}"
   384   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   385 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   386 
   387 lemma LIMSEQ_setsum:
   388   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   389   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   390   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   391 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   392 
   393 lemma LIMSEQ_setprod:
   394   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   395   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   396   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   397 proof (cases "finite S")
   398   case True
   399   thus ?thesis using n
   400   proof (induct)
   401     case empty
   402     show ?case
   403       by (simp add: LIMSEQ_const)
   404   next
   405     case insert
   406     thus ?case
   407       by (simp add: LIMSEQ_mult)
   408   qed
   409 next
   410   case False
   411   thus ?thesis
   412     by (simp add: setprod_def LIMSEQ_const)
   413 qed
   414 
   415 lemma LIMSEQ_add_const:
   416   fixes a :: "'a::real_normed_vector"
   417   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   418 by (simp add: LIMSEQ_add LIMSEQ_const)
   419 
   420 (* FIXME: delete *)
   421 lemma LIMSEQ_add_minus:
   422   fixes a b :: "'a::real_normed_vector"
   423   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   424 by (simp only: LIMSEQ_add LIMSEQ_minus)
   425 
   426 lemma LIMSEQ_diff_const:
   427   fixes a b :: "'a::real_normed_vector"
   428   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   429 by (simp add: LIMSEQ_diff LIMSEQ_const)
   430 
   431 lemma LIMSEQ_diff_approach_zero:
   432   fixes L :: "'a::real_normed_vector"
   433   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   434 by (drule (1) LIMSEQ_add, simp)
   435 
   436 lemma LIMSEQ_diff_approach_zero2:
   437   fixes L :: "'a::real_normed_vector"
   438   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
   439 by (drule (1) LIMSEQ_diff, simp)
   440 
   441 text{*A sequence tends to zero iff its abs does*}
   442 lemma LIMSEQ_norm_zero:
   443   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   444   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   445 by (simp add: LIMSEQ_iff)
   446 
   447 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   448 by (simp add: LIMSEQ_iff)
   449 
   450 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   451 by (drule LIMSEQ_norm, simp)
   452 
   453 text{*An unbounded sequence's inverse tends to 0*}
   454 
   455 lemma LIMSEQ_inverse_zero:
   456   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   457 apply (rule LIMSEQ_I)
   458 apply (drule_tac x="inverse r" in spec, safe)
   459 apply (rule_tac x="N" in exI, safe)
   460 apply (drule_tac x="n" in spec, safe)
   461 apply (frule positive_imp_inverse_positive)
   462 apply (frule (1) less_imp_inverse_less)
   463 apply (subgoal_tac "0 < X n", simp)
   464 apply (erule (1) order_less_trans)
   465 done
   466 
   467 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   468 
   469 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   470 apply (rule LIMSEQ_inverse_zero, safe)
   471 apply (cut_tac x = r in reals_Archimedean2)
   472 apply (safe, rule_tac x = n in exI)
   473 apply (auto simp add: real_of_nat_Suc)
   474 done
   475 
   476 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   477 infinity is now easily proved*}
   478 
   479 lemma LIMSEQ_inverse_real_of_nat_add:
   480      "(%n. r + inverse(real(Suc n))) ----> r"
   481 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   482 
   483 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   484      "(%n. r + -inverse(real(Suc n))) ----> r"
   485 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   486 
   487 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   488      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   489 by (cut_tac b=1 in
   490         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   491 
   492 lemma LIMSEQ_le_const:
   493   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   494 apply (rule ccontr, simp only: linorder_not_le)
   495 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   496 apply clarsimp
   497 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   498 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   499 apply simp
   500 done
   501 
   502 lemma LIMSEQ_le_const2:
   503   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   504 apply (subgoal_tac "- a \<le> - x", simp)
   505 apply (rule LIMSEQ_le_const)
   506 apply (erule LIMSEQ_minus)
   507 apply simp
   508 done
   509 
   510 lemma LIMSEQ_le:
   511   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   512 apply (subgoal_tac "0 \<le> y - x", simp)
   513 apply (rule LIMSEQ_le_const)
   514 apply (erule (1) LIMSEQ_diff)
   515 apply (simp add: le_diff_eq)
   516 done
   517 
   518 
   519 subsection {* Convergence *}
   520 
   521 lemma limI: "X ----> L ==> lim X = L"
   522 apply (simp add: lim_def)
   523 apply (blast intro: LIMSEQ_unique)
   524 done
   525 
   526 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   527 by (simp add: convergent_def)
   528 
   529 lemma convergentI: "(X ----> L) ==> convergent X"
   530 by (auto simp add: convergent_def)
   531 
   532 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   533 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   534 
   535 lemma convergent_const: "convergent (\<lambda>n. c)"
   536 by (rule convergentI, rule LIMSEQ_const)
   537 
   538 lemma convergent_add:
   539   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
   540   assumes "convergent (\<lambda>n. X n)"
   541   assumes "convergent (\<lambda>n. Y n)"
   542   shows "convergent (\<lambda>n. X n + Y n)"
   543 using assms unfolding convergent_def by (fast intro: LIMSEQ_add)
   544 
   545 lemma convergent_setsum:
   546   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
   547   assumes "finite A" and "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
   548   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
   549 using assms
   550 by (induct A set: finite, simp_all add: convergent_const convergent_add)
   551 
   552 lemma (in bounded_linear) convergent:
   553   assumes "convergent (\<lambda>n. X n)"
   554   shows "convergent (\<lambda>n. f (X n))"
   555 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   556 
   557 lemma (in bounded_bilinear) convergent:
   558   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
   559   shows "convergent (\<lambda>n. X n ** Y n)"
   560 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   561 
   562 lemma convergent_minus_iff:
   563   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   564   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   565 apply (simp add: convergent_def)
   566 apply (auto dest: LIMSEQ_minus)
   567 apply (drule LIMSEQ_minus, auto)
   568 done
   569 
   570 lemma lim_le:
   571   fixes x :: real
   572   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   573   shows "lim f \<le> x"
   574 proof (rule classical)
   575   assume "\<not> lim f \<le> x"
   576   hence 0: "0 < lim f - x" by arith
   577   have 1: "f----> lim f"
   578     by (metis convergent_LIMSEQ_iff f) 
   579   thus ?thesis
   580     proof (simp add: LIMSEQ_iff)
   581       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   582       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   583         by (metis 0)
   584       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   585         by blast
   586       thus "lim f \<le> x"
   587         by (metis add_cancel_end add_minus_cancel diff_def linorder_linear 
   588                   linorder_not_le minus_diff_eq abs_diff_less_iff fn_le) 
   589     qed
   590 qed
   591 
   592 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   593 
   594 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   595   unfolding Ex1_def
   596   apply (rule_tac x="nat_rec e f" in exI)
   597   apply (rule conjI)+
   598 apply (rule def_nat_rec_0, simp)
   599 apply (rule allI, rule def_nat_rec_Suc, simp)
   600 apply (rule allI, rule impI, rule ext)
   601 apply (erule conjE)
   602 apply (induct_tac x)
   603 apply simp
   604 apply (erule_tac x="n" in allE)
   605 apply (simp)
   606 done
   607 
   608 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   609 
   610 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   611 apply (simp add: subseq_def)
   612 apply (auto dest!: less_imp_Suc_add)
   613 apply (induct_tac k)
   614 apply (auto intro: less_trans)
   615 done
   616 
   617 lemma monoseq_Suc:
   618    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   619                  | (\<forall>n. X (Suc n) \<le> X n))"
   620 apply (simp add: monoseq_def)
   621 apply (auto dest!: le_imp_less_or_eq)
   622 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   623 apply (induct_tac "ka")
   624 apply (auto intro: order_trans)
   625 apply (erule contrapos_np)
   626 apply (induct_tac "k")
   627 apply (auto intro: order_trans)
   628 done
   629 
   630 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   631 by (simp add: monoseq_def)
   632 
   633 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   634 by (simp add: monoseq_def)
   635 
   636 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   637 by (simp add: monoseq_Suc)
   638 
   639 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   640 by (simp add: monoseq_Suc)
   641 
   642 lemma monoseq_minus: assumes "monoseq a"
   643   shows "monoseq (\<lambda> n. - a n)"
   644 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   645   case True
   646   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   647   thus ?thesis by (rule monoI2)
   648 next
   649   case False
   650   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   651   thus ?thesis by (rule monoI1)
   652 qed
   653 
   654 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   655   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   656          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   657 proof -
   658   { fix x n fix a :: "nat \<Rightarrow> real"
   659     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   660     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   661     have "a n \<le> x"
   662     proof (rule ccontr)
   663       assume "\<not> a n \<le> x" hence "x < a n" by auto
   664       hence "0 < a n - x" by auto
   665       from `a ----> x`[THEN LIMSEQ_D, OF this]
   666       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   667       hence "norm (a (max no n) - x) < a n - x" by auto
   668       moreover
   669       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   670       hence "x < a (max no n)" by auto
   671       ultimately
   672       have "a (max no n) < a n" by auto
   673       with monotone[where m=n and n="max no n"]
   674       show False by (auto simp:max_def split:split_if_asm)
   675     qed
   676   } note top_down = this
   677   { fix x n m fix a :: "nat \<Rightarrow> real"
   678     assume "a ----> x" and "monoseq a" and "a m < x"
   679     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   680     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   681       case True with top_down and `a ----> x` show ?thesis by auto
   682     next
   683       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   684       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   685       hence False using `a m < x` by auto
   686       thus ?thesis ..
   687     qed
   688   } note when_decided = this
   689 
   690   show ?thesis
   691   proof (cases "\<exists> m. a m \<noteq> x")
   692     case True then obtain m where "a m \<noteq> x" by auto
   693     show ?thesis
   694     proof (cases "a m < x")
   695       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   696       show ?thesis by blast
   697     next
   698       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   699       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   700       show ?thesis by auto
   701     qed
   702   qed auto
   703 qed
   704 
   705 text{* for any sequence, there is a mootonic subsequence *}
   706 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   707 proof-
   708   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   709     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   710     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   711     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   712     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   713       using H apply - 
   714       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   715       unfolding order_le_less by blast 
   716     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   717     {fix n
   718       have "?P (f (Suc n)) (f n)" 
   719         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   720         using H apply - 
   721       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   722       unfolding order_le_less by blast 
   723     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   724   note fSuc = this
   725     {fix p q assume pq: "p \<ge> f q"
   726       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   727         by (cases q, simp_all) }
   728     note pqth = this
   729     {fix q
   730       have "f (Suc q) > f q" apply (induct q) 
   731         using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   732     note fss = this
   733     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   734     {fix a b 
   735       have "f a \<le> f (a + b)"
   736       proof(induct b)
   737         case 0 thus ?case by simp
   738       next
   739         case (Suc b)
   740         from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   741       qed}
   742     note fmon0 = this
   743     have "monoseq (\<lambda>n. s (f n))" 
   744     proof-
   745       {fix n
   746         have "s (f n) \<ge> s (f (Suc n))" 
   747         proof(cases n)
   748           case 0
   749           assume n0: "n = 0"
   750           from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   751           from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   752         next
   753           case (Suc m)
   754           assume m: "n = Suc m"
   755           from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   756           from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   757         qed}
   758       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   759     qed
   760     with th1 have ?thesis by blast}
   761   moreover
   762   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   763     {fix p assume p: "p \<ge> Suc N" 
   764       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   765       have "m \<noteq> p" using m(2) by auto 
   766       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   767     note th0 = this
   768     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   769     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   770     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   771       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   772     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   773       using N apply - 
   774       apply (erule allE[where x="Suc N"], clarsimp)
   775       apply (rule_tac x="m" in exI)
   776       apply auto
   777       apply (subgoal_tac "Suc N \<noteq> m")
   778       apply simp
   779       apply (rule ccontr, simp)
   780       done
   781     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   782     {fix n
   783       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   784         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   785       proof (induct n)
   786         case 0 thus ?case
   787           using f0 N apply auto 
   788           apply (erule allE[where x="f 0"], clarsimp) 
   789           apply (rule_tac x="m" in exI, simp)
   790           by (subgoal_tac "f 0 \<noteq> m", auto)
   791       next
   792         case (Suc n)
   793         from Suc.hyps have Nfn: "N < f n" by blast
   794         from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   795         with Nfn have mN: "m > N" by arith
   796         note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   797         
   798         from key have th0: "f (Suc n) > N" by simp
   799         from N[rule_format, OF th0]
   800         obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   801         have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   802         hence "m' > f (Suc n)" using m'(1) by simp
   803         with key m'(2) show ?case by auto
   804       qed}
   805     note fSuc = this
   806     {fix n
   807       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   808       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   809     note thf = this
   810     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   811     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   812       apply -
   813       apply (rule disjI1)
   814       apply auto
   815       apply (rule order_less_imp_le)
   816       apply blast
   817       done
   818     then have ?thesis  using sqf by blast}
   819   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   820 qed
   821 
   822 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   823 proof(induct n)
   824   case 0 thus ?case by simp
   825 next
   826   case (Suc n)
   827   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   828   have "n < f (Suc n)" by arith 
   829   thus ?case by arith
   830 qed
   831 
   832 lemma LIMSEQ_subseq_LIMSEQ:
   833   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   834 apply (auto simp add: LIMSEQ_def) 
   835 apply (drule_tac x=r in spec, clarify)  
   836 apply (rule_tac x=no in exI, clarify) 
   837 apply (blast intro: seq_suble le_trans dest!: spec) 
   838 done
   839 
   840 subsection {* Bounded Monotonic Sequences *}
   841 
   842 
   843 text{*Bounded Sequence*}
   844 
   845 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   846 by (simp add: Bseq_def)
   847 
   848 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   849 by (auto simp add: Bseq_def)
   850 
   851 lemma lemma_NBseq_def:
   852      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   853       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   854 proof auto
   855   fix K :: real
   856   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   857   then have "K \<le> real (Suc n)" by auto
   858   assume "\<forall>m. norm (X m) \<le> K"
   859   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   860   proof
   861     fix m :: 'a
   862     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   863     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   864   qed
   865   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   866 next
   867   fix N :: nat
   868   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   869   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   870   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   871 qed
   872 
   873 
   874 text{* alternative definition for Bseq *}
   875 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   876 apply (simp add: Bseq_def)
   877 apply (simp (no_asm) add: lemma_NBseq_def)
   878 done
   879 
   880 lemma lemma_NBseq_def2:
   881      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   882 apply (subst lemma_NBseq_def, auto)
   883 apply (rule_tac x = "Suc N" in exI)
   884 apply (rule_tac [2] x = N in exI)
   885 apply (auto simp add: real_of_nat_Suc)
   886  prefer 2 apply (blast intro: order_less_imp_le)
   887 apply (drule_tac x = n in spec, simp)
   888 done
   889 
   890 (* yet another definition for Bseq *)
   891 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   892 by (simp add: Bseq_def lemma_NBseq_def2)
   893 
   894 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   895 
   896 lemma Bseq_isUb:
   897   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   898 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   899 
   900 
   901 text{* Use completeness of reals (supremum property)
   902    to show that any bounded sequence has a least upper bound*}
   903 
   904 lemma Bseq_isLub:
   905   "!!(X::nat=>real). Bseq X ==>
   906    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   907 by (blast intro: reals_complete Bseq_isUb)
   908 
   909 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   910 
   911 lemma lemma_converg1:
   912      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   913                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   914                |] ==> \<forall>n \<ge> ma. X n = X ma"
   915 apply safe
   916 apply (drule_tac y = "X n" in isLubD2)
   917 apply (blast dest: order_antisym)+
   918 done
   919 
   920 text{* The best of both worlds: Easier to prove this result as a standard
   921    theorem and then use equivalence to "transfer" it into the
   922    equivalent nonstandard form if needed!*}
   923 
   924 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   925 apply (simp add: LIMSEQ_def)
   926 apply (rule_tac x = "X m" in exI, safe)
   927 apply (rule_tac x = m in exI, safe)
   928 apply (drule spec, erule impE, auto)
   929 done
   930 
   931 lemma lemma_converg2:
   932    "!!(X::nat=>real).
   933     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   934 apply safe
   935 apply (drule_tac y = "X m" in isLubD2)
   936 apply (auto dest!: order_le_imp_less_or_eq)
   937 done
   938 
   939 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   940 by (rule setleI [THEN isUbI], auto)
   941 
   942 text{* FIXME: @{term "U - T < U"} is redundant *}
   943 lemma lemma_converg4: "!!(X::nat=> real).
   944                [| \<forall>m. X m ~= U;
   945                   isLub UNIV {x. \<exists>n. X n = x} U;
   946                   0 < T;
   947                   U + - T < U
   948                |] ==> \<exists>m. U + -T < X m & X m < U"
   949 apply (drule lemma_converg2, assumption)
   950 apply (rule ccontr, simp)
   951 apply (simp add: linorder_not_less)
   952 apply (drule lemma_converg3)
   953 apply (drule isLub_le_isUb, assumption)
   954 apply (auto dest: order_less_le_trans)
   955 done
   956 
   957 text{*A standard proof of the theorem for monotone increasing sequence*}
   958 
   959 lemma Bseq_mono_convergent:
   960      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   961 apply (simp add: convergent_def)
   962 apply (frule Bseq_isLub, safe)
   963 apply (case_tac "\<exists>m. X m = U", auto)
   964 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   965 (* second case *)
   966 apply (rule_tac x = U in exI)
   967 apply (subst LIMSEQ_iff, safe)
   968 apply (frule lemma_converg2, assumption)
   969 apply (drule lemma_converg4, auto)
   970 apply (rule_tac x = m in exI, safe)
   971 apply (subgoal_tac "X m \<le> X n")
   972  prefer 2 apply blast
   973 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   974 done
   975 
   976 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   977 by (simp add: Bseq_def)
   978 
   979 text{*Main monotonicity theorem*}
   980 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   981 apply (simp add: monoseq_def, safe)
   982 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   983 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   984 apply (auto intro!: Bseq_mono_convergent)
   985 done
   986 
   987 subsubsection{*Increasing and Decreasing Series*}
   988 
   989 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   990   by (simp add: incseq_def monoseq_def) 
   991 
   992 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   993   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   994 proof
   995   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   996   thus ?thesis by simp
   997 next
   998   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   999   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
  1000     by (auto simp add: incseq_def intro: order_antisym)
  1001   have X: "!!n. X n = X 0"
  1002     by (blast intro: const [of 0]) 
  1003   have "X = (\<lambda>n. X 0)"
  1004     by (blast intro: ext X)
  1005   hence "L = X 0" using LIMSEQ_const [of "X 0"]
  1006     by (auto intro: LIMSEQ_unique lim) 
  1007   thus ?thesis
  1008     by (blast intro: eq_refl X)
  1009 qed
  1010 
  1011 lemma incseq_SucI:
  1012   assumes "\<And>n. X n \<le> X (Suc n)"
  1013   shows "incseq X" unfolding incseq_def
  1014 proof safe
  1015   fix m n :: nat
  1016   { fix d m :: nat
  1017     have "X m \<le> X (m + d)"
  1018     proof (induct d)
  1019       case (Suc d)
  1020       also have "X (m + d) \<le> X (m + Suc d)"
  1021         using assms by simp
  1022       finally show ?case .
  1023     qed simp }
  1024   note this[of m "n - m"]
  1025   moreover assume "m \<le> n"
  1026   ultimately show "X m \<le> X n" by simp
  1027 qed
  1028 
  1029 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1030   by (simp add: decseq_def monoseq_def)
  1031 
  1032 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
  1033   by (simp add: decseq_def incseq_def)
  1034 
  1035 
  1036 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
  1037 proof -
  1038   have inc: "incseq (\<lambda>n. - X n)" using dec
  1039     by (simp add: decseq_eq_incseq)
  1040   have "- X n \<le> - L" 
  1041     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
  1042   thus ?thesis
  1043     by simp
  1044 qed
  1045 
  1046 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
  1047 
  1048 text{*alternative formulation for boundedness*}
  1049 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
  1050 apply (unfold Bseq_def, safe)
  1051 apply (rule_tac [2] x = "k + norm x" in exI)
  1052 apply (rule_tac x = K in exI, simp)
  1053 apply (rule exI [where x = 0], auto)
  1054 apply (erule order_less_le_trans, simp)
  1055 apply (drule_tac x=n in spec, fold diff_def)
  1056 apply (drule order_trans [OF norm_triangle_ineq2])
  1057 apply simp
  1058 done
  1059 
  1060 text{*alternative formulation for boundedness*}
  1061 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
  1062 apply safe
  1063 apply (simp add: Bseq_def, safe)
  1064 apply (rule_tac x = "K + norm (X N)" in exI)
  1065 apply auto
  1066 apply (erule order_less_le_trans, simp)
  1067 apply (rule_tac x = N in exI, safe)
  1068 apply (drule_tac x = n in spec)
  1069 apply (rule order_trans [OF norm_triangle_ineq], simp)
  1070 apply (auto simp add: Bseq_iff2)
  1071 done
  1072 
  1073 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
  1074 apply (simp add: Bseq_def)
  1075 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
  1076 apply (drule_tac x = n in spec, arith)
  1077 done
  1078 
  1079 
  1080 subsection {* Cauchy Sequences *}
  1081 
  1082 lemma metric_CauchyI:
  1083   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1084 by (simp add: Cauchy_def)
  1085 
  1086 lemma metric_CauchyD:
  1087   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1088 by (simp add: Cauchy_def)
  1089 
  1090 lemma Cauchy_iff:
  1091   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1092   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1093 unfolding Cauchy_def dist_norm ..
  1094 
  1095 lemma Cauchy_iff2:
  1096      "Cauchy X =
  1097       (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1098 apply (simp add: Cauchy_iff, auto)
  1099 apply (drule reals_Archimedean, safe)
  1100 apply (drule_tac x = n in spec, auto)
  1101 apply (rule_tac x = M in exI, auto)
  1102 apply (drule_tac x = m in spec, simp)
  1103 apply (drule_tac x = na in spec, auto)
  1104 done
  1105 
  1106 lemma CauchyI:
  1107   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1108   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1109 by (simp add: Cauchy_iff)
  1110 
  1111 lemma CauchyD:
  1112   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1113   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1114 by (simp add: Cauchy_iff)
  1115 
  1116 lemma Cauchy_subseq_Cauchy:
  1117   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1118 apply (auto simp add: Cauchy_def)
  1119 apply (drule_tac x=e in spec, clarify)
  1120 apply (rule_tac x=M in exI, clarify)
  1121 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1122 done
  1123 
  1124 subsubsection {* Cauchy Sequences are Bounded *}
  1125 
  1126 text{*A Cauchy sequence is bounded -- this is the standard
  1127   proof mechanization rather than the nonstandard proof*}
  1128 
  1129 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1130           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1131 apply (clarify, drule spec, drule (1) mp)
  1132 apply (simp only: norm_minus_commute)
  1133 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1134 apply simp
  1135 done
  1136 
  1137 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1138 apply (simp add: Cauchy_iff)
  1139 apply (drule spec, drule mp, rule zero_less_one, safe)
  1140 apply (drule_tac x="M" in spec, simp)
  1141 apply (drule lemmaCauchy)
  1142 apply (rule_tac k="M" in Bseq_offset)
  1143 apply (simp add: Bseq_def)
  1144 apply (rule_tac x="1 + norm (X M)" in exI)
  1145 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1146 apply (simp add: order_less_imp_le)
  1147 done
  1148 
  1149 subsubsection {* Cauchy Sequences are Convergent *}
  1150 
  1151 class complete_space =
  1152   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1153 
  1154 class banach = real_normed_vector + complete_space
  1155 
  1156 theorem LIMSEQ_imp_Cauchy:
  1157   assumes X: "X ----> a" shows "Cauchy X"
  1158 proof (rule metric_CauchyI)
  1159   fix e::real assume "0 < e"
  1160   hence "0 < e/2" by simp
  1161   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1162   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1163   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1164   proof (intro exI allI impI)
  1165     fix m assume "N \<le> m"
  1166     hence m: "dist (X m) a < e/2" using N by fast
  1167     fix n assume "N \<le> n"
  1168     hence n: "dist (X n) a < e/2" using N by fast
  1169     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1170       by (rule dist_triangle2)
  1171     also from m n have "\<dots> < e" by simp
  1172     finally show "dist (X m) (X n) < e" .
  1173   qed
  1174 qed
  1175 
  1176 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1177 unfolding convergent_def
  1178 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1179 
  1180 lemma Cauchy_convergent_iff:
  1181   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1182   shows "Cauchy X = convergent X"
  1183 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1184 
  1185 lemma convergent_subseq_convergent:
  1186   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1187   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1188   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1189 
  1190 text {*
  1191 Proof that Cauchy sequences converge based on the one from
  1192 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1193 *}
  1194 
  1195 text {*
  1196   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1197   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1198 *}
  1199 
  1200 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1201 by (simp add: isUbI setleI)
  1202 
  1203 locale real_Cauchy =
  1204   fixes X :: "nat \<Rightarrow> real"
  1205   assumes X: "Cauchy X"
  1206   fixes S :: "real set"
  1207   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1208 
  1209 lemma real_CauchyI:
  1210   assumes "Cauchy X"
  1211   shows "real_Cauchy X"
  1212   proof qed (fact assms)
  1213 
  1214 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1215 by (unfold S_def, auto)
  1216 
  1217 lemma (in real_Cauchy) bound_isUb:
  1218   assumes N: "\<forall>n\<ge>N. X n < x"
  1219   shows "isUb UNIV S x"
  1220 proof (rule isUb_UNIV_I)
  1221   fix y::real assume "y \<in> S"
  1222   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1223     by (simp add: S_def)
  1224   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1225   hence "y < X (max M N)" by simp
  1226   also have "\<dots> < x" using N by simp
  1227   finally show "y \<le> x"
  1228     by (rule order_less_imp_le)
  1229 qed
  1230 
  1231 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1232 proof (rule reals_complete)
  1233   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1234     using CauchyD [OF X zero_less_one] by auto
  1235   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1236   show "\<exists>x. x \<in> S"
  1237   proof
  1238     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1239       by (simp add: abs_diff_less_iff)
  1240     thus "X N - 1 \<in> S" by (rule mem_S)
  1241   qed
  1242   show "\<exists>u. isUb UNIV S u"
  1243   proof
  1244     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1245       by (simp add: abs_diff_less_iff)
  1246     thus "isUb UNIV S (X N + 1)"
  1247       by (rule bound_isUb)
  1248   qed
  1249 qed
  1250 
  1251 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1252   assumes x: "isLub UNIV S x"
  1253   shows "X ----> x"
  1254 proof (rule LIMSEQ_I)
  1255   fix r::real assume "0 < r"
  1256   hence r: "0 < r/2" by simp
  1257   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1258     using CauchyD [OF X r] by auto
  1259   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1260   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1261     by (simp only: real_norm_def abs_diff_less_iff)
  1262 
  1263   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1264   hence "X N - r/2 \<in> S" by (rule mem_S)
  1265   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1266 
  1267   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1268   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1269   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1270 
  1271   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1272   proof (intro exI allI impI)
  1273     fix n assume n: "N \<le> n"
  1274     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1275     thus "norm (X n - x) < r" using 1 2
  1276       by (simp add: abs_diff_less_iff)
  1277   qed
  1278 qed
  1279 
  1280 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1281 proof -
  1282   obtain x where "isLub UNIV S x"
  1283     using isLub_ex by fast
  1284   hence "X ----> x"
  1285     by (rule isLub_imp_LIMSEQ)
  1286   thus ?thesis ..
  1287 qed
  1288 
  1289 lemma real_Cauchy_convergent:
  1290   fixes X :: "nat \<Rightarrow> real"
  1291   shows "Cauchy X \<Longrightarrow> convergent X"
  1292 unfolding convergent_def
  1293 by (rule real_Cauchy.LIMSEQ_ex)
  1294  (rule real_CauchyI)
  1295 
  1296 instance real :: banach
  1297 by intro_classes (rule real_Cauchy_convergent)
  1298 
  1299 
  1300 subsection {* Power Sequences *}
  1301 
  1302 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1303 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1304   also fact that bounded and monotonic sequence converges.*}
  1305 
  1306 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1307 apply (simp add: Bseq_def)
  1308 apply (rule_tac x = 1 in exI)
  1309 apply (simp add: power_abs)
  1310 apply (auto dest: power_mono)
  1311 done
  1312 
  1313 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1314 apply (clarify intro!: mono_SucI2)
  1315 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1316 done
  1317 
  1318 lemma convergent_realpow:
  1319   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1320 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1321 
  1322 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1323   fixes x :: real
  1324   assumes x: "0 \<le> x"
  1325   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1326 apply (induct n)
  1327 apply simp
  1328 apply simp
  1329 apply (rule order_trans)
  1330 prefer 2
  1331 apply (erule mult_left_mono)
  1332 apply (rule add_increasing [OF x], simp)
  1333 apply (simp add: real_of_nat_Suc)
  1334 apply (simp add: ring_distribs)
  1335 apply (simp add: mult_nonneg_nonneg x)
  1336 done
  1337 
  1338 lemma LIMSEQ_inverse_realpow_zero:
  1339   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1340 proof (rule LIMSEQ_inverse_zero [rule_format])
  1341   fix y :: real
  1342   assume x: "1 < x"
  1343   hence "0 < x - 1" by simp
  1344   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1345     by (rule reals_Archimedean3)
  1346   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1347   then obtain N::nat where "y < real N * (x - 1)" ..
  1348   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1349   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1350     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1351   also have "\<dots> = x ^ N" by simp
  1352   finally have "y < x ^ N" .
  1353   hence "\<forall>n\<ge>N. y < x ^ n"
  1354     apply clarify
  1355     apply (erule order_less_le_trans)
  1356     apply (erule power_increasing)
  1357     apply (rule order_less_imp_le [OF x])
  1358     done
  1359   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1360 qed
  1361 
  1362 lemma LIMSEQ_realpow_zero:
  1363   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1364 proof (cases)
  1365   assume "x = 0"
  1366   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1367   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1368 next
  1369   assume "0 \<le> x" and "x \<noteq> 0"
  1370   hence x0: "0 < x" by simp
  1371   assume x1: "x < 1"
  1372   from x0 x1 have "1 < inverse x"
  1373     by (rule real_inverse_gt_one)
  1374   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1375     by (rule LIMSEQ_inverse_realpow_zero)
  1376   thus ?thesis by (simp add: power_inverse)
  1377 qed
  1378 
  1379 lemma LIMSEQ_power_zero:
  1380   fixes x :: "'a::{real_normed_algebra_1}"
  1381   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1382 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1383 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1384 apply (simp add: power_abs norm_power_ineq)
  1385 done
  1386 
  1387 lemma LIMSEQ_divide_realpow_zero:
  1388   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1389 apply (cut_tac a = a and x1 = "inverse x" in
  1390         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1391 apply (auto simp add: divide_inverse power_inverse)
  1392 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1393 done
  1394 
  1395 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1396 
  1397 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1398 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1399 
  1400 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1401 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1402 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1403 done
  1404 
  1405 end