src/Pure/axclass.ML
author wenzelm
Mon Jan 07 22:21:56 2013 +0100 (2013-01-07)
changeset 50764 2bbc7ae80634
parent 50760 eee13361ec0a
child 50768 2172f82de515
permissions -rw-r--r--
more precise and complete transitive closure of proven_classrel, using existing Sorts.classes_of which is already closed;
transfer theorems where they are picked from the theory;
tuned;
     1 (*  Title:      Pure/axclass.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Type classes defined as predicates, associated with a record of
     5 parameters.  Proven class relations and type arities.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   type info = {def: thm, intro: thm, axioms: thm list, params: (string * typ) list}
    11   val get_info: theory -> class -> info
    12   val class_of_param: theory -> string -> class option
    13   val instance_name: string * class -> string
    14   val thynames_of_arity: theory -> class * string -> string list
    15   val param_of_inst: theory -> string * string -> string
    16   val inst_of_param: theory -> string -> (string * string) option
    17   val unoverload: theory -> thm -> thm
    18   val overload: theory -> thm -> thm
    19   val unoverload_conv: theory -> conv
    20   val overload_conv: theory -> conv
    21   val lookup_inst_param: Consts.T -> ((string * string) * 'a) list -> string * typ -> 'a option
    22   val unoverload_const: theory -> string * typ -> string
    23   val cert_classrel: theory -> class * class -> class * class
    24   val read_classrel: theory -> xstring * xstring -> class * class
    25   val declare_overloaded: string * typ -> theory -> term * theory
    26   val define_overloaded: binding -> string * term -> theory -> thm * theory
    27   val add_classrel: thm -> theory -> theory
    28   val add_arity: thm -> theory -> theory
    29   val prove_classrel: class * class -> tactic -> theory -> theory
    30   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    31   val define_class: binding * class list -> string list ->
    32     (Thm.binding * term list) list -> theory -> class * theory
    33   val axiomatize_class: binding * class list -> theory -> theory
    34   val axiomatize_class_cmd: binding * xstring list -> theory -> theory
    35   val axiomatize_classrel: (class * class) list -> theory -> theory
    36   val axiomatize_classrel_cmd: (xstring * xstring) list -> theory -> theory
    37   val axiomatize_arity: arity -> theory -> theory
    38   val axiomatize_arity_cmd: xstring * string list * string -> theory -> theory
    39 end;
    40 
    41 structure AxClass: AX_CLASS =
    42 struct
    43 
    44 (** theory data **)
    45 
    46 (* axclass info *)
    47 
    48 type info =
    49  {def: thm,
    50   intro: thm,
    51   axioms: thm list,
    52   params: (string * typ) list};
    53 
    54 fun make_axclass (def, intro, axioms, params): info =
    55   {def = def, intro = intro, axioms = axioms, params = params};
    56 
    57 
    58 (* class parameters (canonical order) *)
    59 
    60 type param = string * class;
    61 
    62 fun add_param ctxt ((x, c): param) params =
    63   (case AList.lookup (op =) params x of
    64     NONE => (x, c) :: params
    65   | SOME c' =>
    66       error ("Duplicate class parameter " ^ quote x ^ " for " ^ Syntax.string_of_sort ctxt [c] ^
    67         (if c = c' then "" else " and " ^ Syntax.string_of_sort ctxt [c'])));
    68 
    69 
    70 (* setup data *)
    71 
    72 datatype data = Data of
    73  {axclasses: info Symtab.table,
    74   params: param list,
    75   proven_classrels: thm Symreltab.table,
    76   proven_arities: ((class * sort list) * (thm * string)) list Symtab.table,
    77     (*arity theorems with theory name*)
    78   inst_params:
    79     (string * thm) Symtab.table Symtab.table *
    80       (*constant name ~> type constructor ~> (constant name, equation)*)
    81     (string * string) Symtab.table (*constant name ~> (constant name, type constructor)*)};
    82 
    83 fun make_data
    84     (axclasses, params, proven_classrels, proven_arities, inst_params) =
    85   Data {axclasses = axclasses, params = params, proven_classrels = proven_classrels,
    86     proven_arities = proven_arities, inst_params = inst_params};
    87 
    88 structure Data = Theory_Data_PP
    89 (
    90   type T = data;
    91   val empty =
    92     make_data (Symtab.empty, [], Symreltab.empty, Symtab.empty, (Symtab.empty, Symtab.empty));
    93   val extend = I;
    94   fun merge pp
    95       (Data {axclasses = axclasses1, params = params1, proven_classrels = proven_classrels1,
    96         proven_arities = proven_arities1, inst_params = inst_params1},
    97        Data {axclasses = axclasses2, params = params2, proven_classrels = proven_classrels2,
    98         proven_arities = proven_arities2, inst_params = inst_params2}) =
    99     let
   100       val ctxt = Syntax.init_pretty pp;
   101 
   102       val axclasses' = Symtab.merge (K true) (axclasses1, axclasses2);
   103       val params' =
   104         if null params1 then params2
   105         else
   106           fold_rev (fn p => if member (op =) params1 p then I else add_param ctxt p)
   107             params2 params1;
   108 
   109       (*see Theory.at_begin hook for transitive closure of classrels and arity completion*)
   110       val proven_classrels' = Symreltab.join (K #1) (proven_classrels1, proven_classrels2);
   111       val proven_arities' =
   112         Symtab.join (K (Library.merge (eq_fst op =))) (proven_arities1, proven_arities2);
   113 
   114       val inst_params' =
   115         (Symtab.join (K (Symtab.merge (K true))) (#1 inst_params1, #1 inst_params2),
   116           Symtab.merge (K true) (#2 inst_params1, #2 inst_params2));
   117     in
   118       make_data (axclasses', params', proven_classrels', proven_arities', inst_params')
   119     end;
   120 );
   121 
   122 fun map_data f =
   123   Data.map (fn Data {axclasses, params, proven_classrels, proven_arities, inst_params} =>
   124     make_data (f (axclasses, params, proven_classrels, proven_arities, inst_params)));
   125 
   126 fun map_axclasses f =
   127   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   128     (f axclasses, params, proven_classrels, proven_arities, inst_params));
   129 
   130 fun map_params f =
   131   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   132     (axclasses, f params, proven_classrels, proven_arities, inst_params));
   133 
   134 fun map_proven_classrels f =
   135   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   136     (axclasses, params, f proven_classrels, proven_arities, inst_params));
   137 
   138 fun map_proven_arities f =
   139   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   140     (axclasses, params, proven_classrels, f proven_arities, inst_params));
   141 
   142 fun map_inst_params f =
   143   map_data (fn (axclasses, params, proven_classrels, proven_arities, inst_params) =>
   144     (axclasses, params, proven_classrels, proven_arities, f inst_params));
   145 
   146 val rep_data = Data.get #> (fn Data args => args);
   147 
   148 val axclasses_of = #axclasses o rep_data;
   149 val params_of = #params o rep_data;
   150 val proven_classrels_of = #proven_classrels o rep_data;
   151 val proven_arities_of = #proven_arities o rep_data;
   152 val inst_params_of = #inst_params o rep_data;
   153 
   154 
   155 (* axclasses with parameters *)
   156 
   157 fun get_info thy c =
   158   (case Symtab.lookup (axclasses_of thy) c of
   159     SOME info => info
   160   | NONE => error ("No such axclass: " ^ quote c));
   161 
   162 fun all_params_of thy S =
   163   let val params = params_of thy;
   164   in fold (fn (x, c) => if Sign.subsort thy (S, [c]) then cons x else I) params [] end;
   165 
   166 fun class_of_param thy = AList.lookup (op =) (params_of thy);
   167 
   168 
   169 (* maintain instances *)
   170 
   171 val classrel_prefix = "classrel_";
   172 val arity_prefix = "arity_";
   173 
   174 fun instance_name (a, c) = Long_Name.base_name c ^ "_" ^ Long_Name.base_name a;
   175 
   176 
   177 val update_classrel = map_proven_classrels o Symreltab.update;
   178 
   179 val is_classrel = Symreltab.defined o proven_classrels_of;
   180 
   181 fun the_classrel thy (c1, c2) =
   182   (case Symreltab.lookup (proven_classrels_of thy) (c1, c2) of
   183     SOME thm => Thm.transfer thy thm
   184   | NONE => error ("Unproven class relation " ^
   185       Syntax.string_of_classrel (Proof_Context.init_global thy) [c1, c2]));
   186 
   187 fun complete_classrels thy =
   188   let
   189     fun complete (c, (_, (all_preds, all_succs))) (finished1, thy1) =
   190       let
   191         val proven = is_classrel thy1;
   192         val preds = Graph.Keys.fold (fn c1 => proven (c1, c) ? cons c1) all_preds [];
   193         val succs = Graph.Keys.fold (fn c2 => proven (c, c2) ? cons c2) all_succs [];
   194 
   195         fun complete c1 c2 (finished2, thy2) =
   196           if is_classrel thy2 (c1, c2) then (finished2, thy2)
   197           else
   198             (false,
   199               thy2
   200               |> update_classrel ((c1, c2),
   201                 (the_classrel thy2 (c1, c) RS the_classrel thy2 (c, c2))
   202                 |> Drule.instantiate' [SOME (ctyp_of thy2 (TVar ((Name.aT, 0), [])))] []
   203                 |> Thm.close_derivation));
   204       in fold_product complete preds succs (finished1, thy1) end;
   205 
   206     val (finished', thy') =
   207       Graph.fold complete (Sorts.classes_of (Sign.classes_of thy)) (true, thy);
   208   in
   209     if finished' then NONE else SOME thy'
   210   end;
   211 
   212 
   213 fun the_arity thy (a, Ss, c) =
   214   (case AList.lookup (op =) (Symtab.lookup_list (proven_arities_of thy) a) (c, Ss) of
   215     SOME (thm, _) => Thm.transfer thy thm
   216   | NONE => error ("Unproven type arity " ^
   217       Syntax.string_of_arity (Proof_Context.init_global thy) (a, Ss, [c])));
   218 
   219 fun thynames_of_arity thy (c, a) =
   220   Symtab.lookup_list (proven_arities_of thy) a
   221   |> map_filter (fn ((c', _), (_, name)) => if c = c' then SOME name else NONE)
   222   |> rev;
   223 
   224 fun insert_arity_completions thy t ((c, Ss), ((th, thy_name))) (finished, arities) =
   225   let
   226     val algebra = Sign.classes_of thy;
   227     val ars = Symtab.lookup_list arities t;
   228     val super_class_completions =
   229       Sign.super_classes thy c
   230       |> filter_out (fn c1 => exists (fn ((c2, Ss2), _) =>
   231             c1 = c2 andalso Sorts.sorts_le algebra (Ss2, Ss)) ars);
   232 
   233     val names = Name.invent Name.context Name.aT (length Ss);
   234     val std_vars = map (fn a => SOME (ctyp_of thy (TVar ((a, 0), [])))) names;
   235 
   236     val completions = super_class_completions |> map (fn c1 =>
   237       let
   238         val th1 =
   239           (th RS the_classrel thy (c, c1))
   240           |> Drule.instantiate' std_vars []
   241           |> Thm.close_derivation;
   242       in ((th1, thy_name), c1) end);
   243 
   244     val finished' = finished andalso null completions;
   245     val arities' = fold (fn (th, c1) => Symtab.cons_list (t, ((c1, Ss), th))) completions arities;
   246   in (finished', arities') end;
   247 
   248 fun put_arity_completion ((t, Ss, c), th) thy =
   249   let val ar = ((c, Ss), (th, Context.theory_name thy)) in
   250     thy
   251     |> map_proven_arities
   252       (Symtab.insert_list (eq_fst op =) (t, ar) #>
   253        curry (insert_arity_completions thy t ar) true #> #2)
   254   end;
   255 
   256 fun complete_arities thy =
   257   let
   258     val arities = proven_arities_of thy;
   259     val (finished, arities') =
   260       Symtab.fold (fn (t, ars) => fold (insert_arity_completions thy t) ars) arities (true, arities);
   261   in
   262     if finished then NONE
   263     else SOME (map_proven_arities (K arities') thy)
   264   end;
   265 
   266 val _ = Context.>> (Context.map_theory
   267   (Theory.at_begin complete_classrels #>
   268    Theory.at_begin complete_arities));
   269 
   270 val _ = Proofterm.install_axclass_proofs
   271   {classrel_proof = Thm.proof_of oo the_classrel,
   272    arity_proof = Thm.proof_of oo the_arity};
   273 
   274 
   275 (* maintain instance parameters *)
   276 
   277 fun get_inst_param thy (c, tyco) =
   278   (case Symtab.lookup (the_default Symtab.empty (Symtab.lookup (#1 (inst_params_of thy)) c)) tyco of
   279     SOME c' => c'
   280   | NONE => error ("No instance parameter for constant " ^ quote c ^ " on type " ^ quote tyco));
   281 
   282 fun add_inst_param (c, tyco) inst =
   283   (map_inst_params o apfst o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   284   #> (map_inst_params o apsnd) (Symtab.update_new (#1 inst, (c, tyco)));
   285 
   286 val inst_of_param = Symtab.lookup o #2 o inst_params_of;
   287 val param_of_inst = #1 oo get_inst_param;
   288 
   289 fun inst_thms thy =
   290   Symtab.fold (Symtab.fold (cons o #2 o #2) o #2) (#1 (inst_params_of thy)) [];
   291 
   292 fun get_inst_tyco consts = try (#1 o dest_Type o the_single o Consts.typargs consts);
   293 
   294 fun unoverload thy = Raw_Simplifier.simplify true (inst_thms thy);
   295 fun overload thy = Raw_Simplifier.simplify true (map Thm.symmetric (inst_thms thy));
   296 
   297 fun unoverload_conv thy = Raw_Simplifier.rewrite true (inst_thms thy);
   298 fun overload_conv thy = Raw_Simplifier.rewrite true (map Thm.symmetric (inst_thms thy));
   299 
   300 fun lookup_inst_param consts params (c, T) =
   301   (case get_inst_tyco consts (c, T) of
   302     SOME tyco => AList.lookup (op =) params (c, tyco)
   303   | NONE => NONE);
   304 
   305 fun unoverload_const thy (c_ty as (c, _)) =
   306   if is_some (class_of_param thy c) then
   307     (case get_inst_tyco (Sign.consts_of thy) c_ty of
   308       SOME tyco => try (param_of_inst thy) (c, tyco) |> the_default c
   309     | NONE => c)
   310   else c;
   311 
   312 
   313 
   314 (** instances **)
   315 
   316 (* class relations *)
   317 
   318 fun cert_classrel thy raw_rel =
   319   let
   320     val string_of_sort = Syntax.string_of_sort_global thy;
   321     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   322     val _ = Sign.primitive_classrel (c1, c2) (Theory.copy thy);
   323     val _ =
   324       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   325         [] => ()
   326       | xs => raise TYPE ("Class " ^ string_of_sort [c1] ^ " lacks parameter(s) " ^
   327           commas_quote xs ^ " of " ^ string_of_sort [c2], [], []));
   328   in (c1, c2) end;
   329 
   330 fun read_classrel thy raw_rel =
   331   cert_classrel thy (pairself (Proof_Context.read_class (Proof_Context.init_global thy)) raw_rel)
   332     handle TYPE (msg, _, _) => error msg;
   333 
   334 
   335 (* declaration and definition of instances of overloaded constants *)
   336 
   337 fun inst_tyco_of thy (c, T) =
   338   (case get_inst_tyco (Sign.consts_of thy) (c, T) of
   339     SOME tyco => tyco
   340   | NONE => error ("Illegal type for instantiation of class parameter: " ^
   341       quote (c ^ " :: " ^ Syntax.string_of_typ_global thy T)));
   342 
   343 fun declare_overloaded (c, T) thy =
   344   let
   345     val class =
   346       (case class_of_param thy c of
   347         SOME class => class
   348       | NONE => error ("Not a class parameter: " ^ quote c));
   349     val tyco = inst_tyco_of thy (c, T);
   350     val name_inst = instance_name (tyco, class) ^ "_inst";
   351     val c' = instance_name (tyco, c);
   352     val T' = Type.strip_sorts T;
   353   in
   354     thy
   355     |> Sign.qualified_path true (Binding.name name_inst)
   356     |> Sign.declare_const_global ((Binding.name c', T'), NoSyn)
   357     |-> (fn const' as Const (c'', _) =>
   358       Thm.add_def_global false true
   359         (Binding.name (Thm.def_name c'), Logic.mk_equals (Const (c, T'), const'))
   360       #>> apsnd Thm.varifyT_global
   361       #-> (fn (_, thm) => add_inst_param (c, tyco) (c'', thm)
   362         #> Global_Theory.add_thm ((Binding.conceal (Binding.name c'), thm), [])
   363         #> #2
   364         #> pair (Const (c, T))))
   365     ||> Sign.restore_naming thy
   366   end;
   367 
   368 fun define_overloaded b (c, t) thy =
   369   let
   370     val T = Term.fastype_of t;
   371     val tyco = inst_tyco_of thy (c, T);
   372     val (c', eq) = get_inst_param thy (c, tyco);
   373     val prop = Logic.mk_equals (Const (c', T), t);
   374     val b' = Thm.def_binding_optional (Binding.name (instance_name (tyco, c))) b;
   375   in
   376     thy
   377     |> Thm.add_def_global false false (b', prop)
   378     |>> (fn (_, thm) => Drule.transitive_thm OF [eq, thm])
   379   end;
   380 
   381 
   382 (* primitive rules *)
   383 
   384 fun add_classrel raw_th thy =
   385   let
   386     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   387     val prop = Thm.plain_prop_of th;
   388     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   389     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   390     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   391     val (th', thy') = Global_Theory.store_thm
   392       (Binding.name (prefix classrel_prefix (Logic.name_classrel (c1, c2))), th) thy;
   393     val th'' = th'
   394       |> Thm.unconstrainT
   395       |> Drule.instantiate' [SOME (ctyp_of thy' (TVar ((Name.aT, 0), [])))] [];
   396   in
   397     thy'
   398     |> Sign.primitive_classrel (c1, c2)
   399     |> map_proven_classrels (Symreltab.update ((c1, c2), th''))
   400     |> perhaps complete_classrels
   401     |> perhaps complete_arities
   402   end;
   403 
   404 fun add_arity raw_th thy =
   405   let
   406     val th = Thm.strip_shyps (Thm.transfer thy raw_th);
   407     val prop = Thm.plain_prop_of th;
   408     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   409     val arity as (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   410 
   411     val (th', thy') = Global_Theory.store_thm
   412       (Binding.name (prefix arity_prefix (Logic.name_arity arity)), th) thy;
   413 
   414     val args = Name.invent_names Name.context Name.aT Ss;
   415     val T = Type (t, map TFree args);
   416     val std_vars = map (fn (a, S) => SOME (ctyp_of thy' (TVar ((a, 0), [])))) args;
   417 
   418     val missing_params = Sign.complete_sort thy' [c]
   419       |> maps (these o Option.map #params o try (get_info thy'))
   420       |> filter_out (fn (const, _) => can (get_inst_param thy') (const, t))
   421       |> (map o apsnd o map_atyps) (K T);
   422     val th'' = th'
   423       |> Thm.unconstrainT
   424       |> Drule.instantiate' std_vars [];
   425   in
   426     thy'
   427     |> fold (#2 oo declare_overloaded) missing_params
   428     |> Sign.primitive_arity (t, Ss, [c])
   429     |> put_arity_completion ((t, Ss, c), th'')
   430   end;
   431 
   432 
   433 (* tactical proofs *)
   434 
   435 fun prove_classrel raw_rel tac thy =
   436   let
   437     val ctxt = Proof_Context.init_global thy;
   438     val (c1, c2) = cert_classrel thy raw_rel;
   439     val th = Goal.prove ctxt [] [] (Logic.mk_classrel (c1, c2)) (K tac) handle ERROR msg =>
   440       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   441         quote (Syntax.string_of_classrel ctxt [c1, c2]));
   442   in
   443     thy |> add_classrel th
   444   end;
   445 
   446 fun prove_arity raw_arity tac thy =
   447   let
   448     val ctxt = Proof_Context.init_global thy;
   449     val arity = Proof_Context.cert_arity ctxt raw_arity;
   450     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   451     val props = Logic.mk_arities arity;
   452     val ths = Goal.prove_multi ctxt [] [] props
   453       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   454         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   455           quote (Syntax.string_of_arity ctxt arity));
   456   in
   457     thy |> fold add_arity ths
   458   end;
   459 
   460 
   461 
   462 (** class definitions **)
   463 
   464 fun split_defined n eq =
   465   let
   466     val intro =
   467       (eq RS Drule.equal_elim_rule2)
   468       |> Conjunction.curry_balanced n
   469       |> n = 0 ? Thm.eq_assumption 1;
   470     val dests =
   471       if n = 0 then []
   472       else
   473         (eq RS Drule.equal_elim_rule1)
   474         |> Balanced_Tree.dest (fn th =>
   475           (th RS Conjunction.conjunctionD1, th RS Conjunction.conjunctionD2)) n;
   476   in (intro, dests) end;
   477 
   478 fun define_class (bclass, raw_super) raw_params raw_specs thy =
   479   let
   480     val ctxt = Syntax.init_pretty_global thy;
   481 
   482 
   483     (* class *)
   484 
   485     val bconst = Binding.map_name Logic.const_of_class bclass;
   486     val class = Sign.full_name thy bclass;
   487     val super = Sign.minimize_sort thy (Sign.certify_sort thy raw_super);
   488 
   489     fun check_constraint (a, S) =
   490       if Sign.subsort thy (super, S) then ()
   491       else error ("Sort constraint of type variable " ^
   492         Syntax.string_of_typ (Config.put show_sorts true ctxt) (TFree (a, S)) ^
   493         " needs to be weaker than " ^ Syntax.string_of_sort ctxt super);
   494 
   495 
   496     (* params *)
   497 
   498     val params = raw_params |> map (fn p =>
   499       let
   500         val T = Sign.the_const_type thy p;
   501         val _ =
   502           (case Term.add_tvarsT T [] of
   503             [((a, _), S)] => check_constraint (a, S)
   504           | _ => error ("Exactly one type variable expected in class parameter " ^ quote p));
   505         val T' = Term.map_type_tvar (fn _ => TFree (Name.aT, [class])) T;
   506       in (p, T') end);
   507 
   508 
   509     (* axioms *)
   510 
   511     fun prep_axiom t =
   512       (case Term.add_tfrees t [] of
   513         [(a, S)] => check_constraint (a, S)
   514       | [] => ()
   515       | _ => error ("Multiple type variables in class axiom:\n" ^ Syntax.string_of_term ctxt t);
   516       t
   517       |> Term.map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   518       |> Logic.close_form);
   519 
   520     val axiomss = map (map (prep_axiom o Sign.cert_prop thy) o snd) raw_specs;
   521     val name_atts = map fst raw_specs;
   522 
   523 
   524     (* definition *)
   525 
   526     val conjs = Logic.mk_of_sort (Term.aT [], super) @ flat axiomss;
   527     val class_eq =
   528       Logic.mk_equals (Logic.mk_of_class (Term.aT [], class), Logic.mk_conjunction_balanced conjs);
   529 
   530     val ([def], def_thy) =
   531       thy
   532       |> Sign.primitive_class (bclass, super)
   533       |> Global_Theory.add_defs false [((Thm.def_binding bconst, class_eq), [])];
   534     val (raw_intro, (raw_classrel, raw_axioms)) =
   535       split_defined (length conjs) def ||> chop (length super);
   536 
   537 
   538     (* facts *)
   539 
   540     val class_triv = Thm.class_triv def_thy class;
   541     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   542       def_thy
   543       |> Sign.qualified_path true bconst
   544       |> Global_Theory.note_thmss ""
   545         [((Binding.name "intro", []), [([Drule.export_without_context raw_intro], [])]),
   546          ((Binding.name "super", []), [(map Drule.export_without_context raw_classrel, [])]),
   547          ((Binding.name "axioms", []),
   548            [(map (fn th => Drule.export_without_context (class_triv RS th)) raw_axioms, [])])]
   549       ||> Sign.restore_naming def_thy;
   550 
   551 
   552     (* result *)
   553 
   554     val axclass = make_axclass (def, intro, axioms, params);
   555     val result_thy =
   556       facts_thy
   557       |> map_proven_classrels
   558           (fold2 (fn c => fn th => Symreltab.update ((class, c), th)) super classrel)
   559       |> perhaps complete_classrels
   560       |> Sign.qualified_path false bconst
   561       |> Global_Theory.note_thmss "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms))
   562       |> #2
   563       |> Sign.restore_naming facts_thy
   564       |> map_axclasses (Symtab.update (class, axclass))
   565       |> map_params (fold (fn (x, _) => add_param ctxt (x, class)) params);
   566 
   567   in (class, result_thy) end;
   568 
   569 
   570 
   571 (** axiomatizations **)
   572 
   573 local
   574 
   575 (*old-style axioms*)
   576 fun axiomatize prep mk name add raw_args thy =
   577   let
   578     val args = prep thy raw_args;
   579     val specs = mk args;
   580     val names = name args;
   581   in
   582     thy
   583     |> fold_map Thm.add_axiom_global (map Binding.name names ~~ specs)
   584     |-> fold (add o Drule.export_without_context o snd)
   585   end;
   586 
   587 fun ax_classrel prep =
   588   axiomatize (map o prep) (map Logic.mk_classrel)
   589     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   590 
   591 fun ax_arity prep =
   592   axiomatize (prep o Proof_Context.init_global) Logic.mk_arities
   593     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   594 
   595 fun class_const c =
   596   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   597 
   598 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   599   let
   600     val class = Sign.full_name thy bclass;
   601     val super = map (prep_class thy) raw_super |> Sign.minimize_sort thy;
   602   in
   603     thy
   604     |> Sign.primitive_class (bclass, super)
   605     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   606     |> Theory.add_deps_global "" (class_const class) (map class_const super)
   607   end;
   608 
   609 in
   610 
   611 val axiomatize_class = ax_class Sign.certify_class cert_classrel;
   612 val axiomatize_class_cmd =
   613   ax_class (Proof_Context.read_class o Proof_Context.init_global) read_classrel;
   614 val axiomatize_classrel = ax_classrel cert_classrel;
   615 val axiomatize_classrel_cmd = ax_classrel read_classrel;
   616 val axiomatize_arity = ax_arity Proof_Context.cert_arity;
   617 val axiomatize_arity_cmd = ax_arity Proof_Context.read_arity;
   618 
   619 end;
   620 
   621 end;