src/HOL/Tools/Nitpick/nitpick_mono.ML
author blanchet
Thu Feb 18 18:48:07 2010 +0100 (2010-02-18)
changeset 35220 2bcdae5f4fdb
parent 35219 15a5f213ef5b
child 35280 54ab4921f826
permissions -rw-r--r--
added support for nonstandard "nat"s to Nitpick and fixed bugs in binary "nat"s and "int"s
     1 (*  Title:      HOL/Tools/Nitpick/nitpick_mono.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2009, 2010
     4 
     5 Monotonicity predicate for higher-order logic.
     6 *)
     7 
     8 signature NITPICK_MONO =
     9 sig
    10   datatype sign = Plus | Minus
    11   type hol_context = Nitpick_HOL.hol_context
    12 
    13   val formulas_monotonic :
    14     hol_context -> bool -> typ -> sign -> term list -> term list -> term -> bool
    15 end;
    16 
    17 structure Nitpick_Mono : NITPICK_MONO =
    18 struct
    19 
    20 open Nitpick_Util
    21 open Nitpick_HOL
    22 
    23 type var = int
    24 
    25 datatype sign = Plus | Minus
    26 datatype sign_atom = S of sign | V of var
    27 
    28 type literal = var * sign
    29 
    30 datatype ctype =
    31   CAlpha |
    32   CFun of ctype * sign_atom * ctype |
    33   CPair of ctype * ctype |
    34   CType of string * ctype list |
    35   CRec of string * typ list
    36 
    37 type cdata =
    38   {hol_ctxt: hol_context,
    39    binarize: bool,
    40    alpha_T: typ,
    41    max_fresh: int Unsynchronized.ref,
    42    datatype_cache: ((string * typ list) * ctype) list Unsynchronized.ref,
    43    constr_cache: (styp * ctype) list Unsynchronized.ref}
    44 
    45 exception CTYPE of string * ctype list
    46 
    47 (* string -> unit *)
    48 fun print_g (s : string) = ()
    49 
    50 (* var -> string *)
    51 val string_for_var = signed_string_of_int
    52 (* string -> var list -> string *)
    53 fun string_for_vars sep [] = "0\<^bsub>" ^ sep ^ "\<^esub>"
    54   | string_for_vars sep xs = space_implode sep (map string_for_var xs)
    55 fun subscript_string_for_vars sep xs =
    56   if null xs then "" else "\<^bsub>" ^ string_for_vars sep xs ^ "\<^esub>"
    57 
    58 (* sign -> string *)
    59 fun string_for_sign Plus = "+"
    60   | string_for_sign Minus = "-"
    61 
    62 (* sign -> sign -> sign *)
    63 fun xor sn1 sn2 = if sn1 = sn2 then Plus else Minus
    64 (* sign -> sign *)
    65 val negate = xor Minus
    66 
    67 (* sign_atom -> string *)
    68 fun string_for_sign_atom (S sn) = string_for_sign sn
    69   | string_for_sign_atom (V j) = string_for_var j
    70 
    71 (* literal -> string *)
    72 fun string_for_literal (x, sn) = string_for_var x ^ " = " ^ string_for_sign sn
    73 
    74 val bool_C = CType (@{type_name bool}, [])
    75 
    76 (* ctype -> bool *)
    77 fun is_CRec (CRec _) = true
    78   | is_CRec _ = false
    79 
    80 val no_prec = 100
    81 val prec_CFun = 1
    82 val prec_CPair = 2
    83 
    84 (* tuple_set -> int *)
    85 fun precedence_of_ctype (CFun _) = prec_CFun
    86   | precedence_of_ctype (CPair _) = prec_CPair
    87   | precedence_of_ctype _ = no_prec
    88 
    89 (* ctype -> string *)
    90 val string_for_ctype =
    91   let
    92     (* int -> ctype -> string *)
    93     fun aux outer_prec C =
    94       let
    95         val prec = precedence_of_ctype C
    96         val need_parens = (prec < outer_prec)
    97       in
    98         (if need_parens then "(" else "") ^
    99         (case C of
   100            CAlpha => "\<alpha>"
   101          | CFun (C1, a, C2) =>
   102            aux (prec + 1) C1 ^ " \<Rightarrow>\<^bsup>" ^
   103            string_for_sign_atom a ^ "\<^esup> " ^ aux prec C2
   104          | CPair (C1, C2) => aux (prec + 1) C1 ^ " \<times> " ^ aux prec C2
   105          | CType (s, []) =>
   106            if s = @{type_name prop} orelse s = @{type_name bool} then "o" else s
   107          | CType (s, Cs) => "(" ^ commas (map (aux 0) Cs) ^ ") " ^ s
   108          | CRec (s, _) => "[" ^ s ^ "]") ^
   109         (if need_parens then ")" else "")
   110       end
   111   in aux 0 end
   112 
   113 (* ctype -> ctype list *)
   114 fun flatten_ctype (CPair (C1, C2)) = maps flatten_ctype [C1, C2]
   115   | flatten_ctype (CType (_, Cs)) = maps flatten_ctype Cs
   116   | flatten_ctype C = [C]
   117 
   118 (* hol_context -> bool -> typ -> cdata *)
   119 fun initial_cdata hol_ctxt binarize alpha_T =
   120   ({hol_ctxt = hol_ctxt, binarize = binarize, alpha_T = alpha_T,
   121     max_fresh = Unsynchronized.ref 0, datatype_cache = Unsynchronized.ref [],
   122     constr_cache = Unsynchronized.ref []} : cdata)
   123 
   124 (* typ -> typ -> bool *)
   125 fun could_exist_alpha_subtype alpha_T (T as Type (_, Ts)) =
   126     T = alpha_T orelse (not (is_fp_iterator_type T) andalso
   127                         exists (could_exist_alpha_subtype alpha_T) Ts)
   128   | could_exist_alpha_subtype alpha_T T = (T = alpha_T)
   129 (* theory -> typ -> typ -> bool *)
   130 fun could_exist_alpha_sub_ctype _ (alpha_T as TFree _) T =
   131     could_exist_alpha_subtype alpha_T T
   132   | could_exist_alpha_sub_ctype thy alpha_T T =
   133     (T = alpha_T orelse is_datatype thy [(NONE, true)] T)
   134 
   135 (* ctype -> bool *)
   136 fun exists_alpha_sub_ctype CAlpha = true
   137   | exists_alpha_sub_ctype (CFun (C1, _, C2)) =
   138     exists exists_alpha_sub_ctype [C1, C2]
   139   | exists_alpha_sub_ctype (CPair (C1, C2)) =
   140     exists exists_alpha_sub_ctype [C1, C2]
   141   | exists_alpha_sub_ctype (CType (_, Cs)) = exists exists_alpha_sub_ctype Cs
   142   | exists_alpha_sub_ctype (CRec _) = true
   143 
   144 (* ctype -> bool *)
   145 fun exists_alpha_sub_ctype_fresh CAlpha = true
   146   | exists_alpha_sub_ctype_fresh (CFun (_, V _, _)) = true
   147   | exists_alpha_sub_ctype_fresh (CFun (_, _, C2)) =
   148     exists_alpha_sub_ctype_fresh C2
   149   | exists_alpha_sub_ctype_fresh (CPair (C1, C2)) =
   150     exists exists_alpha_sub_ctype_fresh [C1, C2]
   151   | exists_alpha_sub_ctype_fresh (CType (_, Cs)) =
   152     exists exists_alpha_sub_ctype_fresh Cs
   153   | exists_alpha_sub_ctype_fresh (CRec _) = true
   154 
   155 (* string * typ list -> ctype list -> ctype *)
   156 fun constr_ctype_for_binders z Cs =
   157   fold_rev (fn C => curry3 CFun C (S Minus)) Cs (CRec z)
   158 
   159 (* ((string * typ list) * ctype) list -> ctype list -> ctype -> ctype *)
   160 fun repair_ctype _ _ CAlpha = CAlpha
   161   | repair_ctype cache seen (CFun (C1, a, C2)) =
   162     CFun (repair_ctype cache seen C1, a, repair_ctype cache seen C2)
   163   | repair_ctype cache seen (CPair Cp) =
   164     CPair (pairself (repair_ctype cache seen) Cp)
   165   | repair_ctype cache seen (CType (s, Cs)) =
   166     CType (s, maps (flatten_ctype o repair_ctype cache seen) Cs)
   167   | repair_ctype cache seen (CRec (z as (s, _))) =
   168     case AList.lookup (op =) cache z |> the of
   169       CRec _ => CType (s, [])
   170     | C => if member (op =) seen C then CType (s, [])
   171            else repair_ctype cache (C :: seen) C
   172 
   173 (* ((string * typ list) * ctype) list Unsynchronized.ref -> unit *)
   174 fun repair_datatype_cache cache =
   175   let
   176     (* (string * typ list) * ctype -> unit *)
   177     fun repair_one (z, C) =
   178       Unsynchronized.change cache
   179           (AList.update (op =) (z, repair_ctype (!cache) [] C))
   180   in List.app repair_one (rev (!cache)) end
   181 
   182 (* (typ * ctype) list -> (styp * ctype) list Unsynchronized.ref -> unit *)
   183 fun repair_constr_cache dtype_cache constr_cache =
   184   let
   185     (* styp * ctype -> unit *)
   186     fun repair_one (x, C) =
   187       Unsynchronized.change constr_cache
   188           (AList.update (op =) (x, repair_ctype dtype_cache [] C))
   189   in List.app repair_one (!constr_cache) end
   190 
   191 (* cdata -> typ -> ctype *)
   192 fun fresh_ctype_for_type ({hol_ctxt as {thy, ...}, binarize, alpha_T, max_fresh,
   193                            datatype_cache, constr_cache, ...} : cdata) =
   194   let
   195     (* typ -> typ -> ctype *)
   196     fun do_fun T1 T2 =
   197       let
   198         val C1 = do_type T1
   199         val C2 = do_type T2
   200         val a = if is_boolean_type (body_type T2) andalso
   201                    exists_alpha_sub_ctype_fresh C1 then
   202                   V (Unsynchronized.inc max_fresh)
   203                 else
   204                   S Minus
   205       in CFun (C1, a, C2) end
   206     (* typ -> ctype *)
   207     and do_type T =
   208       if T = alpha_T then
   209         CAlpha
   210       else case T of
   211         Type ("fun", [T1, T2]) => do_fun T1 T2
   212       | Type (@{type_name fun_box}, [T1, T2]) => do_fun T1 T2
   213       | Type ("*", [T1, T2]) => CPair (pairself do_type (T1, T2))
   214       | Type (z as (s, _)) =>
   215         if could_exist_alpha_sub_ctype thy alpha_T T then
   216           case AList.lookup (op =) (!datatype_cache) z of
   217             SOME C => C
   218           | NONE =>
   219             let
   220               val _ = Unsynchronized.change datatype_cache (cons (z, CRec z))
   221               val xs = binarized_and_boxed_datatype_constrs hol_ctxt binarize T
   222               val (all_Cs, constr_Cs) =
   223                 fold_rev (fn (_, T') => fn (all_Cs, constr_Cs) =>
   224                              let
   225                                val binder_Cs = map do_type (binder_types T')
   226                                val new_Cs = filter exists_alpha_sub_ctype_fresh
   227                                                    binder_Cs
   228                                val constr_C = constr_ctype_for_binders z
   229                                                                        binder_Cs
   230                              in
   231                                (union (op =) new_Cs all_Cs,
   232                                 constr_C :: constr_Cs)
   233                              end)
   234                          xs ([], [])
   235               val C = CType (s, all_Cs)
   236               val _ = Unsynchronized.change datatype_cache
   237                           (AList.update (op =) (z, C))
   238               val _ = Unsynchronized.change constr_cache
   239                           (append (xs ~~ constr_Cs))
   240             in
   241               if forall (not o is_CRec o snd) (!datatype_cache) then
   242                 (repair_datatype_cache datatype_cache;
   243                  repair_constr_cache (!datatype_cache) constr_cache;
   244                  AList.lookup (op =) (!datatype_cache) z |> the)
   245               else
   246                 C
   247             end
   248         else
   249           CType (s, [])
   250       | _ => CType (Refute.string_of_typ T, [])
   251   in do_type end
   252 
   253 (* ctype -> ctype list *)
   254 fun prodC_factors (CPair (C1, C2)) = maps prodC_factors [C1, C2]
   255   | prodC_factors C = [C]
   256 (* ctype -> ctype list * ctype *)
   257 fun curried_strip_ctype (CFun (C1, S Minus, C2)) =
   258     curried_strip_ctype C2 |>> append (prodC_factors C1)
   259   | curried_strip_ctype C = ([], C)
   260 (* string -> ctype -> ctype *)
   261 fun sel_ctype_from_constr_ctype s C =
   262   let val (arg_Cs, dataC) = curried_strip_ctype C in
   263     CFun (dataC, S Minus,
   264           case sel_no_from_name s of ~1 => bool_C | n => nth arg_Cs n)
   265   end
   266 
   267 (* cdata -> styp -> ctype *)
   268 fun ctype_for_constr (cdata as {hol_ctxt as {thy, ...}, alpha_T, constr_cache,
   269                                 ...}) (x as (_, T)) =
   270   if could_exist_alpha_sub_ctype thy alpha_T T then
   271     case AList.lookup (op =) (!constr_cache) x of
   272       SOME C => C
   273     | NONE => (fresh_ctype_for_type cdata (body_type T);
   274                AList.lookup (op =) (!constr_cache) x |> the)
   275   else
   276     fresh_ctype_for_type cdata T
   277 fun ctype_for_sel (cdata as {hol_ctxt, binarize, ...}) (x as (s, _)) =
   278   x |> binarized_and_boxed_constr_for_sel hol_ctxt binarize
   279     |> ctype_for_constr cdata |> sel_ctype_from_constr_ctype s
   280 
   281 (* literal list -> ctype -> ctype *)
   282 fun instantiate_ctype lits =
   283   let
   284     (* ctype -> ctype *)
   285     fun aux CAlpha = CAlpha
   286       | aux (CFun (C1, V x, C2)) =
   287         let
   288           val a = case AList.lookup (op =) lits x of
   289                     SOME sn => S sn
   290                   | NONE => V x
   291         in CFun (aux C1, a, aux C2) end
   292       | aux (CFun (C1, a, C2)) = CFun (aux C1, a, aux C2)
   293       | aux (CPair Cp) = CPair (pairself aux Cp)
   294       | aux (CType (s, Cs)) = CType (s, map aux Cs)
   295       | aux (CRec z) = CRec z
   296   in aux end
   297 
   298 datatype comp_op = Eq | Leq
   299 
   300 type comp = sign_atom * sign_atom * comp_op * var list
   301 type sign_expr = literal list
   302 
   303 datatype constraint_set =
   304   UnsolvableCSet |
   305   CSet of literal list * comp list * sign_expr list
   306 
   307 (* comp_op -> string *)
   308 fun string_for_comp_op Eq = "="
   309   | string_for_comp_op Leq = "\<le>"
   310 
   311 (* sign_expr -> string *)
   312 fun string_for_sign_expr [] = "\<bot>"
   313   | string_for_sign_expr lits =
   314     space_implode " \<or> " (map string_for_literal lits)
   315 
   316 (* constraint_set *)
   317 val slack = CSet ([], [], [])
   318 
   319 (* literal -> literal list option -> literal list option *)
   320 fun do_literal _ NONE = NONE
   321   | do_literal (x, sn) (SOME lits) =
   322     case AList.lookup (op =) lits x of
   323       SOME sn' => if sn = sn' then SOME lits else NONE
   324     | NONE => SOME ((x, sn) :: lits)
   325 
   326 (* comp_op -> var list -> sign_atom -> sign_atom -> literal list * comp list
   327    -> (literal list * comp list) option *)
   328 fun do_sign_atom_comp Eq [] a1 a2 (accum as (lits, comps)) =
   329     (case (a1, a2) of
   330        (S sn1, S sn2) => if sn1 = sn2 then SOME accum else NONE
   331      | (V x1, S sn2) =>
   332        Option.map (rpair comps) (do_literal (x1, sn2) (SOME lits))
   333      | (V _, V _) => SOME (lits, insert (op =) (a1, a2, Eq, []) comps)
   334      | _ => do_sign_atom_comp Eq [] a2 a1 accum)
   335   | do_sign_atom_comp Leq [] a1 a2 (accum as (lits, comps)) =
   336     (case (a1, a2) of
   337        (_, S Minus) => SOME accum
   338      | (S Plus, _) => SOME accum
   339      | (S Minus, S Plus) => NONE
   340      | (V _, V _) => SOME (lits, insert (op =) (a1, a2, Leq, []) comps)
   341      | _ => do_sign_atom_comp Eq [] a1 a2 accum)
   342   | do_sign_atom_comp cmp xs a1 a2 (accum as (lits, comps)) =
   343     SOME (lits, insert (op =) (a1, a2, cmp, xs) comps)
   344 
   345 (* comp -> var list -> ctype -> ctype -> (literal list * comp list) option
   346    -> (literal list * comp list) option *)
   347 fun do_ctype_comp _ _ _ _ NONE = NONE
   348   | do_ctype_comp _ _ CAlpha CAlpha accum = accum
   349   | do_ctype_comp Eq xs (CFun (C11, a1, C12)) (CFun (C21, a2, C22))
   350                   (SOME accum) =
   351      accum |> do_sign_atom_comp Eq xs a1 a2 |> do_ctype_comp Eq xs C11 C21
   352            |> do_ctype_comp Eq xs C12 C22
   353   | do_ctype_comp Leq xs (CFun (C11, a1, C12)) (CFun (C21, a2, C22))
   354                   (SOME accum) =
   355     (if exists_alpha_sub_ctype C11 then
   356        accum |> do_sign_atom_comp Leq xs a1 a2
   357              |> do_ctype_comp Leq xs C21 C11
   358              |> (case a2 of
   359                    S Minus => I
   360                  | S Plus => do_ctype_comp Leq xs C11 C21
   361                  | V x => do_ctype_comp Leq (x :: xs) C11 C21)
   362      else
   363        SOME accum)
   364     |> do_ctype_comp Leq xs C12 C22
   365   | do_ctype_comp cmp xs (C1 as CPair (C11, C12)) (C2 as CPair (C21, C22))
   366                   accum =
   367     (accum |> fold (uncurry (do_ctype_comp cmp xs)) [(C11, C21), (C12, C22)]
   368      handle Library.UnequalLengths =>
   369             raise CTYPE ("Nitpick_Mono.do_ctype_comp", [C1, C2]))
   370   | do_ctype_comp cmp xs (CType _) (CType _) accum =
   371     accum (* no need to compare them thanks to the cache *)
   372   | do_ctype_comp _ _ C1 C2 _ =
   373     raise CTYPE ("Nitpick_Mono.do_ctype_comp", [C1, C2])
   374 
   375 (* comp_op -> ctype -> ctype -> constraint_set -> constraint_set *)
   376 fun add_ctype_comp _ _ _ UnsolvableCSet = UnsolvableCSet
   377   | add_ctype_comp cmp C1 C2 (CSet (lits, comps, sexps)) =
   378     (print_g ("*** Add " ^ string_for_ctype C1 ^ " " ^ string_for_comp_op cmp ^
   379               " " ^ string_for_ctype C2);
   380      case do_ctype_comp cmp [] C1 C2 (SOME (lits, comps)) of
   381        NONE => (print_g "**** Unsolvable"; UnsolvableCSet)
   382      | SOME (lits, comps) => CSet (lits, comps, sexps))
   383 
   384 (* ctype -> ctype -> constraint_set -> constraint_set *)
   385 val add_ctypes_equal = add_ctype_comp Eq
   386 val add_is_sub_ctype = add_ctype_comp Leq
   387 
   388 (* sign -> sign_expr -> ctype -> (literal list * sign_expr list) option
   389    -> (literal list * sign_expr list) option *)
   390 fun do_notin_ctype_fv _ _ _ NONE = NONE
   391   | do_notin_ctype_fv Minus _ CAlpha accum = accum
   392   | do_notin_ctype_fv Plus [] CAlpha _ = NONE
   393   | do_notin_ctype_fv Plus [(x, sn)] CAlpha (SOME (lits, sexps)) =
   394     SOME lits |> do_literal (x, sn) |> Option.map (rpair sexps)
   395   | do_notin_ctype_fv Plus sexp CAlpha (SOME (lits, sexps)) =
   396     SOME (lits, insert (op =) sexp sexps)
   397   | do_notin_ctype_fv sn sexp (CFun (C1, S sn', C2)) accum =
   398     accum |> (if sn' = Plus andalso sn = Plus then
   399                 do_notin_ctype_fv Plus sexp C1
   400               else
   401                 I)
   402           |> (if sn' = Minus orelse sn = Plus then
   403                 do_notin_ctype_fv Minus sexp C1
   404               else
   405                 I)
   406           |> do_notin_ctype_fv sn sexp C2
   407   | do_notin_ctype_fv Plus sexp (CFun (C1, V x, C2)) accum =
   408     accum |> (case do_literal (x, Minus) (SOME sexp) of
   409                 NONE => I
   410               | SOME sexp' => do_notin_ctype_fv Plus sexp' C1)
   411           |> do_notin_ctype_fv Minus sexp C1
   412           |> do_notin_ctype_fv Plus sexp C2
   413   | do_notin_ctype_fv Minus sexp (CFun (C1, V x, C2)) accum =
   414     accum |> (case do_literal (x, Plus) (SOME sexp) of
   415                 NONE => I
   416               | SOME sexp' => do_notin_ctype_fv Plus sexp' C1)
   417           |> do_notin_ctype_fv Minus sexp C2
   418   | do_notin_ctype_fv sn sexp (CPair (C1, C2)) accum =
   419     accum |> fold (do_notin_ctype_fv sn sexp) [C1, C2]
   420   | do_notin_ctype_fv sn sexp (CType (_, Cs)) accum =
   421     accum |> fold (do_notin_ctype_fv sn sexp) Cs
   422   | do_notin_ctype_fv _ _ C _ =
   423     raise CTYPE ("Nitpick_Mono.do_notin_ctype_fv", [C])
   424 
   425 (* sign -> ctype -> constraint_set -> constraint_set *)
   426 fun add_notin_ctype_fv _ _ UnsolvableCSet = UnsolvableCSet
   427   | add_notin_ctype_fv sn C (CSet (lits, comps, sexps)) =
   428     (print_g ("*** Add " ^ string_for_ctype C ^ " is right-" ^
   429               (case sn of Minus => "unique" | Plus => "total") ^ ".");
   430      case do_notin_ctype_fv sn [] C (SOME (lits, sexps)) of
   431        NONE => (print_g "**** Unsolvable"; UnsolvableCSet)
   432      | SOME (lits, sexps) => CSet (lits, comps, sexps))
   433 
   434 (* ctype -> constraint_set -> constraint_set *)
   435 val add_ctype_is_right_unique = add_notin_ctype_fv Minus
   436 val add_ctype_is_right_total = add_notin_ctype_fv Plus
   437 
   438 (* constraint_set -> constraint_set -> constraint_set *)
   439 fun unite (CSet (lits1, comps1, sexps1)) (CSet (lits2, comps2, sexps2)) =
   440     (case SOME lits1 |> fold do_literal lits2 of
   441        NONE => (print_g "**** Unsolvable"; UnsolvableCSet)
   442      | SOME lits => CSet (lits, comps1 @ comps2, sexps1 @ sexps2))
   443   | unite _ _ = UnsolvableCSet
   444 
   445 (* sign -> bool *)
   446 fun bool_from_sign Plus = false
   447   | bool_from_sign Minus = true
   448 (* bool -> sign *)
   449 fun sign_from_bool false = Plus
   450   | sign_from_bool true = Minus
   451 
   452 (* literal -> PropLogic.prop_formula *)
   453 fun prop_for_literal (x, sn) =
   454   (not (bool_from_sign sn) ? PropLogic.Not) (PropLogic.BoolVar x)
   455 (* sign_atom -> PropLogic.prop_formula *)
   456 fun prop_for_sign_atom_eq (S sn', sn) =
   457     if sn = sn' then PropLogic.True else PropLogic.False
   458   | prop_for_sign_atom_eq (V x, sn) = prop_for_literal (x, sn)
   459 (* sign_expr -> PropLogic.prop_formula *)
   460 fun prop_for_sign_expr xs = PropLogic.exists (map prop_for_literal xs)
   461 (* var list -> sign -> PropLogic.prop_formula *)
   462 fun prop_for_exists_eq xs sn =
   463   PropLogic.exists (map (fn x => prop_for_literal (x, sn)) xs)
   464 (* comp -> PropLogic.prop_formula *)
   465 fun prop_for_comp (a1, a2, Eq, []) =
   466     PropLogic.SAnd (prop_for_comp (a1, a2, Leq, []),
   467                     prop_for_comp (a2, a1, Leq, []))
   468   | prop_for_comp (a1, a2, Leq, []) =
   469     PropLogic.SOr (prop_for_sign_atom_eq (a1, Plus),
   470                    prop_for_sign_atom_eq (a2, Minus))
   471   | prop_for_comp (a1, a2, cmp, xs) =
   472     PropLogic.SOr (prop_for_exists_eq xs Minus, prop_for_comp (a1, a2, cmp, []))
   473 
   474 (* var -> (int -> bool option) -> literal list -> literal list *)
   475 fun literals_from_assignments max_var assigns lits =
   476   fold (fn x => fn accum =>
   477            if AList.defined (op =) lits x then
   478              accum
   479            else case assigns x of
   480              SOME b => (x, sign_from_bool b) :: accum
   481            | NONE => accum) (max_var downto 1) lits
   482 
   483 (* literal list -> sign_atom -> sign option *)
   484 fun lookup_sign_atom _ (S sn) = SOME sn
   485   | lookup_sign_atom lit (V x) = AList.lookup (op =) lit x
   486 
   487 (* comp -> string *)
   488 fun string_for_comp (a1, a2, cmp, xs) =
   489   string_for_sign_atom a1 ^ " " ^ string_for_comp_op cmp ^
   490   subscript_string_for_vars " \<and> " xs ^ " " ^ string_for_sign_atom a2
   491 
   492 (* literal list -> comp list -> sign_expr list -> unit *)
   493 fun print_problem lits comps sexps =
   494   print_g ("*** Problem:\n" ^ cat_lines (map string_for_literal lits @
   495                                          map string_for_comp comps @
   496                                          map string_for_sign_expr sexps))
   497 
   498 (* literal list -> unit *)
   499 fun print_solution lits =
   500   let val (pos, neg) = List.partition (curry (op =) Plus o snd) lits in
   501     print_g ("*** Solution:\n" ^
   502              "+: " ^ commas (map (string_for_var o fst) pos) ^ "\n" ^
   503              "-: " ^ commas (map (string_for_var o fst) neg))
   504   end
   505 
   506 (* var -> constraint_set -> literal list list option *)
   507 fun solve _ UnsolvableCSet = (print_g "*** Problem: Unsolvable"; NONE)
   508   | solve max_var (CSet (lits, comps, sexps)) =
   509     let
   510       val _ = print_problem lits comps sexps
   511       val prop = PropLogic.all (map prop_for_literal lits @
   512                                 map prop_for_comp comps @
   513                                 map prop_for_sign_expr sexps)
   514       (* use the first ML solver (to avoid startup overhead) *)
   515       val solvers = !SatSolver.solvers
   516                     |> filter (member (op =) ["dptsat", "dpll"] o fst)
   517     in
   518       case snd (hd solvers) prop of
   519         SatSolver.SATISFIABLE assigns =>
   520         SOME (literals_from_assignments max_var assigns lits
   521               |> tap print_solution)
   522       | _ => NONE
   523     end
   524 
   525 (* var -> constraint_set -> bool *)
   526 val is_solvable = is_some oo solve
   527 
   528 type ctype_schema = ctype * constraint_set
   529 type ctype_context =
   530   {bounds: ctype list,
   531    frees: (styp * ctype) list,
   532    consts: (styp * ctype) list}
   533 
   534 type accumulator = ctype_context * constraint_set
   535 
   536 val initial_gamma = {bounds = [], frees = [], consts = []}
   537 val unsolvable_accum = (initial_gamma, UnsolvableCSet)
   538 
   539 (* ctype -> ctype_context -> ctype_context *)
   540 fun push_bound C {bounds, frees, consts} =
   541   {bounds = C :: bounds, frees = frees, consts = consts}
   542 (* ctype_context -> ctype_context *)
   543 fun pop_bound {bounds, frees, consts} =
   544   {bounds = tl bounds, frees = frees, consts = consts}
   545   handle List.Empty => initial_gamma
   546 
   547 (* cdata -> term -> accumulator -> ctype * accumulator *)
   548 fun consider_term (cdata as {hol_ctxt as {thy, ctxt, stds, fast_descrs,
   549                                           def_table, ...},
   550                              alpha_T, max_fresh, ...}) =
   551   let
   552     (* typ -> ctype *)
   553     val ctype_for = fresh_ctype_for_type cdata
   554     (* ctype -> ctype *)
   555     fun pos_set_ctype_for_dom C =
   556       CFun (C, S (if exists_alpha_sub_ctype C then Plus else Minus), bool_C)
   557     (* typ -> accumulator -> ctype * accumulator *)
   558     fun do_quantifier T (gamma, cset) =
   559       let
   560         val abs_C = ctype_for (domain_type (domain_type T))
   561         val body_C = ctype_for (range_type T)
   562       in
   563         (CFun (CFun (abs_C, S Minus, body_C), S Minus, body_C),
   564          (gamma, cset |> add_ctype_is_right_total abs_C))
   565       end
   566     fun do_equals T (gamma, cset) =
   567       let val C = ctype_for (domain_type T) in
   568         (CFun (C, S Minus, CFun (C, V (Unsynchronized.inc max_fresh),
   569                                  ctype_for (nth_range_type 2 T))),
   570          (gamma, cset |> add_ctype_is_right_unique C))
   571       end
   572     fun do_robust_set_operation T (gamma, cset) =
   573       let
   574         val set_T = domain_type T
   575         val C1 = ctype_for set_T
   576         val C2 = ctype_for set_T
   577         val C3 = ctype_for set_T
   578       in
   579         (CFun (C1, S Minus, CFun (C2, S Minus, C3)),
   580          (gamma, cset |> add_is_sub_ctype C1 C3 |> add_is_sub_ctype C2 C3))
   581       end
   582     fun do_fragile_set_operation T (gamma, cset) =
   583       let
   584         val set_T = domain_type T
   585         val set_C = ctype_for set_T
   586         (* typ -> ctype *)
   587         fun custom_ctype_for (T as Type ("fun", [T1, T2])) =
   588             if T = set_T then set_C
   589             else CFun (custom_ctype_for T1, S Minus, custom_ctype_for T2)
   590           | custom_ctype_for T = ctype_for T
   591       in
   592         (custom_ctype_for T, (gamma, cset |> add_ctype_is_right_unique set_C))
   593       end
   594     (* typ -> accumulator -> ctype * accumulator *)
   595     fun do_pair_constr T accum =
   596       case ctype_for (nth_range_type 2 T) of
   597         C as CPair (a_C, b_C) =>
   598         (CFun (a_C, S Minus, CFun (b_C, S Minus, C)), accum)
   599       | C => raise CTYPE ("Nitpick_Mono.consider_term.do_pair_constr", [C])
   600     (* int -> typ -> accumulator -> ctype * accumulator *)
   601     fun do_nth_pair_sel n T =
   602       case ctype_for (domain_type T) of
   603         C as CPair (a_C, b_C) =>
   604         pair (CFun (C, S Minus, if n = 0 then a_C else b_C))
   605       | C => raise CTYPE ("Nitpick_Mono.consider_term.do_nth_pair_sel", [C])
   606     val unsolvable = (CType ("unsolvable", []), unsolvable_accum)
   607     (* typ -> term -> accumulator -> ctype * accumulator *)
   608     fun do_bounded_quantifier abs_T bound_t body_t accum =
   609       let
   610         val abs_C = ctype_for abs_T
   611         val (bound_C, accum) = accum |>> push_bound abs_C |> do_term bound_t
   612         val expected_bound_C = pos_set_ctype_for_dom abs_C
   613       in
   614         accum ||> add_ctypes_equal expected_bound_C bound_C |> do_term body_t
   615               ||> apfst pop_bound
   616       end
   617     (* term -> accumulator -> ctype * accumulator *)
   618     and do_term _ (_, UnsolvableCSet) = unsolvable
   619       | do_term t (accum as (gamma as {bounds, frees, consts}, cset)) =
   620         (case t of
   621            Const (x as (s, T)) =>
   622            (case AList.lookup (op =) consts x of
   623               SOME C => (C, accum)
   624             | NONE =>
   625               if not (could_exist_alpha_subtype alpha_T T) then
   626                 (ctype_for T, accum)
   627               else case s of
   628                 @{const_name all} => do_quantifier T accum
   629               | @{const_name "=="} => do_equals T accum
   630               | @{const_name All} => do_quantifier T accum
   631               | @{const_name Ex} => do_quantifier T accum
   632               | @{const_name "op ="} => do_equals T accum
   633               | @{const_name The} => (print_g "*** The"; unsolvable)
   634               | @{const_name Eps} => (print_g "*** Eps"; unsolvable)
   635               | @{const_name If} =>
   636                 do_robust_set_operation (range_type T) accum
   637                 |>> curry3 CFun bool_C (S Minus)
   638               | @{const_name Pair} => do_pair_constr T accum
   639               | @{const_name fst} => do_nth_pair_sel 0 T accum
   640               | @{const_name snd} => do_nth_pair_sel 1 T accum 
   641               | @{const_name Id} =>
   642                 (CFun (ctype_for (domain_type T), S Minus, bool_C), accum)
   643               | @{const_name insert} =>
   644                 let
   645                   val set_T = domain_type (range_type T)
   646                   val C1 = ctype_for (domain_type set_T)
   647                   val C1' = pos_set_ctype_for_dom C1
   648                   val C2 = ctype_for set_T
   649                   val C3 = ctype_for set_T
   650                 in
   651                   (CFun (C1, S Minus, CFun (C2, S Minus, C3)),
   652                    (gamma, cset |> add_ctype_is_right_unique C1
   653                                 |> add_is_sub_ctype C1' C3
   654                                 |> add_is_sub_ctype C2 C3))
   655                 end
   656               | @{const_name converse} =>
   657                 let
   658                   val x = Unsynchronized.inc max_fresh
   659                   (* typ -> ctype *)
   660                   fun ctype_for_set T =
   661                     CFun (ctype_for (domain_type T), V x, bool_C)
   662                   val ab_set_C = domain_type T |> ctype_for_set
   663                   val ba_set_C = range_type T |> ctype_for_set
   664                 in (CFun (ab_set_C, S Minus, ba_set_C), accum) end
   665               | @{const_name trancl} => do_fragile_set_operation T accum
   666               | @{const_name rtrancl} => (print_g "*** rtrancl"; unsolvable)
   667               | @{const_name finite} =>
   668                 let val C1 = ctype_for (domain_type (domain_type T)) in
   669                   (CFun (pos_set_ctype_for_dom C1, S Minus, bool_C), accum)
   670                 end
   671               | @{const_name rel_comp} =>
   672                 let
   673                   val x = Unsynchronized.inc max_fresh
   674                   (* typ -> ctype *)
   675                   fun ctype_for_set T =
   676                     CFun (ctype_for (domain_type T), V x, bool_C)
   677                   val bc_set_C = domain_type T |> ctype_for_set
   678                   val ab_set_C = domain_type (range_type T) |> ctype_for_set
   679                   val ac_set_C = nth_range_type 2 T |> ctype_for_set
   680                 in
   681                   (CFun (bc_set_C, S Minus, CFun (ab_set_C, S Minus, ac_set_C)),
   682                    accum)
   683                 end
   684               | @{const_name image} =>
   685                 let
   686                   val a_C = ctype_for (domain_type (domain_type T))
   687                   val b_C = ctype_for (range_type (domain_type T))
   688                 in
   689                   (CFun (CFun (a_C, S Minus, b_C), S Minus,
   690                          CFun (pos_set_ctype_for_dom a_C, S Minus,
   691                                pos_set_ctype_for_dom b_C)), accum)
   692                 end
   693               | @{const_name Sigma} =>
   694                 let
   695                   val x = Unsynchronized.inc max_fresh
   696                   (* typ -> ctype *)
   697                   fun ctype_for_set T =
   698                     CFun (ctype_for (domain_type T), V x, bool_C)
   699                   val a_set_T = domain_type T
   700                   val a_C = ctype_for (domain_type a_set_T)
   701                   val b_set_C = ctype_for_set (range_type (domain_type
   702                                                                (range_type T)))
   703                   val a_set_C = ctype_for_set a_set_T
   704                   val a_to_b_set_C = CFun (a_C, S Minus, b_set_C)
   705                   val ab_set_C = ctype_for_set (nth_range_type 2 T)
   706                 in
   707                   (CFun (a_set_C, S Minus,
   708                          CFun (a_to_b_set_C, S Minus, ab_set_C)), accum)
   709                 end
   710               | @{const_name Tha} =>
   711                 let
   712                   val a_C = ctype_for (domain_type (domain_type T))
   713                   val a_set_C = pos_set_ctype_for_dom a_C
   714                 in (CFun (a_set_C, S Minus, a_C), accum) end
   715               | @{const_name FunBox} =>
   716                 let val dom_C = ctype_for (domain_type T) in
   717                   (CFun (dom_C, S Minus, dom_C), accum)
   718                 end
   719               | _ =>
   720                 if s = @{const_name minus_class.minus} andalso
   721                    is_set_type (domain_type T) then
   722                   let
   723                     val set_T = domain_type T
   724                     val left_set_C = ctype_for set_T
   725                     val right_set_C = ctype_for set_T
   726                   in
   727                     (CFun (left_set_C, S Minus,
   728                            CFun (right_set_C, S Minus, left_set_C)),
   729                      (gamma, cset |> add_ctype_is_right_unique right_set_C
   730                                   |> add_is_sub_ctype right_set_C left_set_C))
   731                   end
   732                 else if s = @{const_name ord_class.less_eq} andalso
   733                         is_set_type (domain_type T) then
   734                   do_fragile_set_operation T accum
   735                 else if (s = @{const_name semilattice_inf_class.inf} orelse
   736                          s = @{const_name semilattice_sup_class.sup}) andalso
   737                         is_set_type (domain_type T) then
   738                   do_robust_set_operation T accum
   739                 else if is_sel s then
   740                   if constr_name_for_sel_like s = @{const_name FunBox} then
   741                     let val dom_C = ctype_for (domain_type T) in
   742                       (CFun (dom_C, S Minus, dom_C), accum)
   743                     end
   744                   else
   745                     (ctype_for_sel cdata x, accum)
   746                 else if is_constr thy stds x then
   747                   (ctype_for_constr cdata x, accum)
   748                 else if is_built_in_const thy stds fast_descrs x then
   749                   case def_of_const thy def_table x of
   750                     SOME t' => do_term t' accum
   751                   | NONE => (print_g ("*** built-in " ^ s); unsolvable)
   752                 else
   753                   let val C = ctype_for T in
   754                     (C, ({bounds = bounds, frees = frees,
   755                           consts = (x, C) :: consts}, cset))
   756                   end)
   757          | Free (x as (_, T)) =>
   758            (case AList.lookup (op =) frees x of
   759               SOME C => (C, accum)
   760             | NONE =>
   761               let val C = ctype_for T in
   762                 (C, ({bounds = bounds, frees = (x, C) :: frees,
   763                       consts = consts}, cset))
   764               end)
   765          | Var _ => (print_g "*** Var"; unsolvable)
   766          | Bound j => (nth bounds j, accum)
   767          | Abs (_, T, @{const False}) => (ctype_for (T --> bool_T), accum)
   768          | Abs (s, T, t') =>
   769            ((case t' of
   770                t1' $ Bound 0 =>
   771                if not (loose_bvar1 (t1', 0)) then
   772                  do_term (incr_boundvars ~1 t1') accum
   773                else
   774                  raise SAME ()
   775              | _ => raise SAME ())
   776             handle SAME () =>
   777                    let
   778                      val C = ctype_for T
   779                      val (C', accum) = do_term t' (accum |>> push_bound C)
   780                    in (CFun (C, S Minus, C'), accum |>> pop_bound) end)
   781          | Const (@{const_name All}, _)
   782            $ Abs (_, T', @{const "op -->"} $ (t1 $ Bound 0) $ t2) =>
   783            do_bounded_quantifier T' t1 t2 accum
   784          | Const (@{const_name Ex}, _)
   785            $ Abs (_, T', @{const "op &"} $ (t1 $ Bound 0) $ t2) =>
   786            do_bounded_quantifier T' t1 t2 accum
   787          | Const (@{const_name Let}, _) $ t1 $ t2 =>
   788            do_term (betapply (t2, t1)) accum
   789          | t1 $ t2 =>
   790            let
   791              val (C1, accum) = do_term t1 accum
   792              val (C2, accum) = do_term t2 accum
   793            in
   794              case accum of
   795                (_, UnsolvableCSet) => unsolvable
   796              | _ => case C1 of
   797                       CFun (C11, _, C12) =>
   798                       (C12, accum ||> add_is_sub_ctype C2 C11)
   799                     | _ => raise CTYPE ("Nitpick_Mono.consider_term.do_term \
   800                                         \(op $)", [C1])
   801            end)
   802         |> tap (fn (C, _) =>
   803                    print_g ("  \<Gamma> \<turnstile> " ^
   804                             Syntax.string_of_term ctxt t ^ " : " ^
   805                             string_for_ctype C))
   806   in do_term end
   807 
   808 (* cdata -> sign -> term -> accumulator -> accumulator *)
   809 fun consider_general_formula (cdata as {hol_ctxt as {ctxt, ...}, ...}) =
   810   let
   811     (* typ -> ctype *)
   812     val ctype_for = fresh_ctype_for_type cdata
   813     (* term -> accumulator -> ctype * accumulator *)
   814     val do_term = consider_term cdata
   815     (* sign -> term -> accumulator -> accumulator *)
   816     fun do_formula _ _ (_, UnsolvableCSet) = unsolvable_accum
   817       | do_formula sn t (accum as (gamma as {bounds, frees, consts}, cset)) =
   818         let
   819           (* term -> accumulator -> accumulator *)
   820           val do_co_formula = do_formula sn
   821           val do_contra_formula = do_formula (negate sn)
   822           (* string -> typ -> term -> accumulator *)
   823           fun do_quantifier quant_s abs_T body_t =
   824             let
   825               val abs_C = ctype_for abs_T
   826               val side_cond = ((sn = Minus) = (quant_s = @{const_name Ex}))
   827               val cset = cset |> side_cond ? add_ctype_is_right_total abs_C
   828             in
   829               (gamma |> push_bound abs_C, cset) |> do_co_formula body_t
   830                                                 |>> pop_bound
   831             end
   832           (* typ -> term -> accumulator *)
   833           fun do_bounded_quantifier abs_T body_t =
   834             accum |>> push_bound (ctype_for abs_T) |> do_co_formula body_t
   835                   |>> pop_bound
   836           (* term -> term -> accumulator *)
   837           fun do_equals t1 t2 =
   838             case sn of
   839               Plus => do_term t accum |> snd
   840             | Minus => let
   841                          val (C1, accum) = do_term t1 accum
   842                          val (C2, accum) = do_term t2 accum
   843                        in accum ||> add_ctypes_equal C1 C2 end
   844         in
   845           case t of
   846             Const (s0 as @{const_name all}, _) $ Abs (_, T1, t1) =>
   847             do_quantifier s0 T1 t1
   848           | Const (@{const_name "=="}, _) $ t1 $ t2 => do_equals t1 t2
   849           | @{const "==>"} $ t1 $ t2 =>
   850             accum |> do_contra_formula t1 |> do_co_formula t2
   851           | @{const Trueprop} $ t1 => do_co_formula t1 accum
   852           | @{const Not} $ t1 => do_contra_formula t1 accum
   853           | Const (@{const_name All}, _)
   854             $ Abs (_, T1, t1 as @{const "op -->"} $ (_ $ Bound 0) $ _) =>
   855             do_bounded_quantifier T1 t1
   856           | Const (s0 as @{const_name All}, _) $ Abs (_, T1, t1) =>
   857             do_quantifier s0 T1 t1
   858           | Const (@{const_name Ex}, _)
   859             $ Abs (_, T1, t1 as @{const "op &"} $ (_ $ Bound 0) $ _) =>
   860             do_bounded_quantifier T1 t1
   861           | Const (s0 as @{const_name Ex}, _) $ Abs (_, T1, t1) =>
   862             do_quantifier s0 T1 t1
   863           | Const (@{const_name "op ="}, _) $ t1 $ t2 => do_equals t1 t2
   864           | @{const "op &"} $ t1 $ t2 =>
   865             accum |> do_co_formula t1 |> do_co_formula t2
   866           | @{const "op |"} $ t1 $ t2 =>
   867             accum |> do_co_formula t1 |> do_co_formula t2
   868           | @{const "op -->"} $ t1 $ t2 =>
   869             accum |> do_contra_formula t1 |> do_co_formula t2
   870           | Const (@{const_name If}, _) $ t1 $ t2 $ t3 =>
   871             accum |> do_term t1 |> snd |> fold do_co_formula [t2, t3]
   872           | Const (@{const_name Let}, _) $ t1 $ t2 =>
   873             do_co_formula (betapply (t2, t1)) accum
   874           | _ => do_term t accum |> snd
   875         end
   876         |> tap (fn _ => print_g ("\<Gamma> \<turnstile> " ^
   877                                  Syntax.string_of_term ctxt t ^
   878                                  " : o\<^sup>" ^ string_for_sign sn))
   879   in do_formula end
   880 
   881 (* The harmless axiom optimization below is somewhat too aggressive in the face
   882    of (rather peculiar) user-defined axioms. *)
   883 val harmless_consts =
   884   [@{const_name ord_class.less}, @{const_name ord_class.less_eq}]
   885 val bounteous_consts = [@{const_name bisim}]
   886 
   887 (* term -> bool *)
   888 fun is_harmless_axiom ({thy, stds, fast_descrs, ...} : hol_context) t =
   889   Term.add_consts t []
   890   |> filter_out (is_built_in_const thy stds fast_descrs)
   891   |> (forall (member (op =) harmless_consts o original_name o fst)
   892       orf exists (member (op =) bounteous_consts o fst))
   893 
   894 (* cdata -> sign -> term -> accumulator -> accumulator *)
   895 fun consider_nondefinitional_axiom (cdata as {hol_ctxt, ...}) sn t =
   896   not (is_harmless_axiom hol_ctxt t) ? consider_general_formula cdata sn t
   897 
   898 (* cdata -> term -> accumulator -> accumulator *)
   899 fun consider_definitional_axiom (cdata as {hol_ctxt as {thy, ...}, ...}) t =
   900   if not (is_constr_pattern_formula thy t) then
   901     consider_nondefinitional_axiom cdata Plus t
   902   else if is_harmless_axiom hol_ctxt t then
   903     I
   904   else
   905     let
   906       (* term -> accumulator -> ctype * accumulator *)
   907       val do_term = consider_term cdata
   908       (* typ -> term -> accumulator -> accumulator *)
   909       fun do_all abs_T body_t accum =
   910         let val abs_C = fresh_ctype_for_type cdata abs_T in
   911           accum |>> push_bound abs_C |> do_formula body_t |>> pop_bound
   912         end
   913       (* term -> term -> accumulator -> accumulator *)
   914       and do_implies t1 t2 = do_term t1 #> snd #> do_formula t2
   915       and do_equals t1 t2 accum =
   916         let
   917           val (C1, accum) = do_term t1 accum
   918           val (C2, accum) = do_term t2 accum
   919         in accum ||> add_ctypes_equal C1 C2 end
   920       (* term -> accumulator -> accumulator *)
   921       and do_formula _ (_, UnsolvableCSet) = unsolvable_accum
   922         | do_formula t accum =
   923           case t of
   924             Const (@{const_name all}, _) $ Abs (_, T1, t1) => do_all T1 t1 accum
   925           | @{const Trueprop} $ t1 => do_formula t1 accum
   926           | Const (@{const_name "=="}, _) $ t1 $ t2 => do_equals t1 t2 accum
   927           | @{const "==>"} $ t1 $ t2 => do_implies t1 t2 accum
   928           | @{const Pure.conjunction} $ t1 $ t2 =>
   929             accum |> do_formula t1 |> do_formula t2
   930           | Const (@{const_name All}, _) $ Abs (_, T1, t1) => do_all T1 t1 accum
   931           | Const (@{const_name "op ="}, _) $ t1 $ t2 => do_equals t1 t2 accum
   932           | @{const "op &"} $ t1 $ t2 => accum |> do_formula t1 |> do_formula t2
   933           | @{const "op -->"} $ t1 $ t2 => do_implies t1 t2 accum
   934           | _ => raise TERM ("Nitpick_Mono.consider_definitional_axiom.\
   935                              \do_formula", [t])
   936     in do_formula t end
   937 
   938 (* Proof.context -> literal list -> term -> ctype -> string *)
   939 fun string_for_ctype_of_term ctxt lits t C =
   940   Syntax.string_of_term ctxt t ^ " : " ^
   941   string_for_ctype (instantiate_ctype lits C)
   942 
   943 (* theory -> literal list -> ctype_context -> unit *)
   944 fun print_ctype_context ctxt lits ({frees, consts, ...} : ctype_context) =
   945   map (fn (x, C) => string_for_ctype_of_term ctxt lits (Free x) C) frees @
   946   map (fn (x, C) => string_for_ctype_of_term ctxt lits (Const x) C) consts
   947   |> cat_lines |> print_g
   948 
   949 (* hol_context -> bool -> typ -> sign -> term list -> term list -> term
   950    -> bool *)
   951 fun formulas_monotonic (hol_ctxt as {ctxt, ...}) binarize alpha_T sn def_ts
   952                        nondef_ts core_t =
   953   let
   954     val _ = print_g ("****** " ^ string_for_ctype CAlpha ^ " is " ^
   955                      Syntax.string_of_typ ctxt alpha_T)
   956     val cdata as {max_fresh, ...} = initial_cdata hol_ctxt binarize alpha_T
   957     val (gamma, cset) =
   958       (initial_gamma, slack)
   959       |> fold (consider_definitional_axiom cdata) def_ts
   960       |> fold (consider_nondefinitional_axiom cdata Plus) nondef_ts
   961       |> consider_general_formula cdata sn core_t
   962   in
   963     case solve (!max_fresh) cset of
   964       SOME lits => (print_ctype_context ctxt lits gamma; true)
   965     | _ => false
   966   end
   967   handle CTYPE (loc, Cs) => raise BAD (loc, commas (map string_for_ctype Cs))
   968 
   969 end;