src/HOL/Nat.ML
author nipkow
Mon Feb 25 10:42:34 2002 +0100 (2002-02-25)
changeset 12931 2c0251fada94
parent 12486 0ed8bdd883e0
child 12949 b94843ffc0d1
permissions -rw-r--r--
solved the problem that Larry's simproce cancle_numerals(?) returns
inconsistent inequality w/o rewriting it to False.
     1 (*  Title:      HOL/Nat.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Tobias Nipkow
     4 
     5 Proofs about natural numbers and elementary arithmetic: addition,
     6 multiplication, etc.  Some from the Hoare example from Norbert Galm.
     7 *)
     8 
     9 (** conversion rules for nat_rec **)
    10 
    11 val [nat_rec_0, nat_rec_Suc] = nat.recs;
    12 bind_thm ("nat_rec_0", nat_rec_0);
    13 bind_thm ("nat_rec_Suc", nat_rec_Suc);
    14 
    15 (*These 2 rules ease the use of primitive recursion.  NOTE USE OF == *)
    16 val prems = Goal
    17     "[| !!n. f(n) == nat_rec c h n |] ==> f(0) = c";
    18 by (simp_tac (simpset() addsimps prems) 1);
    19 qed "def_nat_rec_0";
    20 
    21 val prems = Goal
    22     "[| !!n. f(n) == nat_rec c h n |] ==> f(Suc(n)) = h n (f n)";
    23 by (simp_tac (simpset() addsimps prems) 1);
    24 qed "def_nat_rec_Suc";
    25 
    26 val [nat_case_0, nat_case_Suc] = nat.cases;
    27 bind_thm ("nat_case_0", nat_case_0);
    28 bind_thm ("nat_case_Suc", nat_case_Suc);
    29 
    30 Goal "n ~= 0 ==> EX m. n = Suc m";
    31 by (case_tac "n" 1);
    32 by (REPEAT (Blast_tac 1));
    33 qed "not0_implies_Suc";
    34 
    35 Goal "!!n::nat. m<n ==> n ~= 0";
    36 by (case_tac "n" 1);
    37 by (ALLGOALS Asm_full_simp_tac);
    38 qed "gr_implies_not0";
    39 
    40 Goal "!!n::nat. (n ~= 0) = (0 < n)";
    41 by (case_tac "n" 1);
    42 by Auto_tac;
    43 qed "neq0_conv";
    44 AddIffs [neq0_conv];
    45 
    46 (*This theorem is useful with blast_tac: (n=0 ==> False) ==> 0<n *)
    47 bind_thm ("gr0I", [neq0_conv, notI] MRS iffD1);
    48 
    49 Goal "(0<n) = (EX m. n = Suc m)";
    50 by (fast_tac (claset() addIs [not0_implies_Suc]) 1);
    51 qed "gr0_conv_Suc";
    52 
    53 Goal "!!n::nat. (~(0 < n)) = (n=0)";
    54 by (rtac iffI 1);
    55  by (rtac ccontr 1);
    56  by (ALLGOALS Asm_full_simp_tac);
    57 qed "not_gr0";
    58 AddIffs [not_gr0];
    59 
    60 Goal "(Suc n <= m') --> (? m. m' = Suc m)";
    61 by (induct_tac "m'" 1);
    62 by  Auto_tac;
    63 qed_spec_mp "Suc_le_D";
    64 
    65 (*Useful in certain inductive arguments*)
    66 Goal "(m < Suc n) = (m=0 | (EX j. m = Suc j & j < n))";
    67 by (case_tac "m" 1);
    68 by Auto_tac;
    69 qed "less_Suc_eq_0_disj";
    70 
    71 val prems = Goal "[| P 0; P(Suc 0); !!k. P k ==> P (Suc (Suc k)) |] ==> P n";
    72 by (rtac nat_less_induct 1);
    73 by (case_tac "n" 1);
    74 by (case_tac "nat" 2);
    75 by (ALLGOALS (blast_tac (claset() addIs prems@[less_trans])));
    76 qed "nat_induct2";
    77 
    78 (** LEAST theorems for type "nat" by specialization **)
    79 
    80 bind_thm("LeastI", wellorder_LeastI);
    81 bind_thm("Least_le", wellorder_Least_le);
    82 bind_thm("not_less_Least", wellorder_not_less_Least);
    83 
    84 Goal "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))";
    85 by (case_tac "n" 1);
    86 by Auto_tac;  
    87 by (ftac LeastI 1); 
    88 by (dres_inst_tac [("P","%x. P (Suc x)")] LeastI 1);
    89 by (subgoal_tac "(LEAST x. P x) <= Suc (LEAST x. P (Suc x))" 1); 
    90 by (etac Least_le 2); 
    91 by (case_tac "LEAST x. P x" 1);
    92 by Auto_tac;  
    93 by (dres_inst_tac [("P","%x. P (Suc x)")] Least_le 1);
    94 by (blast_tac (claset() addIs [order_antisym]) 1); 
    95 qed "Least_Suc";
    96 
    97 Goal "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)";
    98 by (eatac (Least_Suc RS ssubst) 1 1);
    99 by (Asm_simp_tac 1);
   100 qed "Least_Suc2";
   101 
   102 
   103 (** min and max **)
   104 
   105 Goal "min 0 n = (0::nat)";
   106 by (rtac min_leastL 1);
   107 by (Simp_tac 1);
   108 qed "min_0L";
   109 
   110 Goal "min n 0 = (0::nat)";
   111 by (rtac min_leastR 1);
   112 by (Simp_tac 1);
   113 qed "min_0R";
   114 
   115 Goal "min (Suc m) (Suc n) = Suc (min m n)";
   116 by (simp_tac (simpset() addsimps [min_of_mono]) 1);
   117 qed "min_Suc_Suc";
   118 
   119 Addsimps [min_0L,min_0R,min_Suc_Suc];
   120 
   121 Goal "max 0 n = (n::nat)";
   122 by (rtac max_leastL 1);
   123 by (Simp_tac 1);
   124 qed "max_0L";
   125 
   126 Goal "max n 0 = (n::nat)";
   127 by (rtac max_leastR 1);
   128 by (Simp_tac 1);
   129 qed "max_0R";
   130 
   131 Goal "max (Suc m) (Suc n) = Suc(max m n)";
   132 by (simp_tac (simpset() addsimps [max_of_mono]) 1);
   133 qed "max_Suc_Suc";
   134 
   135 Addsimps [max_0L,max_0R,max_Suc_Suc];
   136 
   137 
   138 (*** Basic rewrite rules for the arithmetic operators ***)
   139 
   140 (** Difference **)
   141 
   142 Goal "0 - n = (0::nat)";
   143 by (induct_tac "n" 1);
   144 by (ALLGOALS Asm_simp_tac);
   145 qed "diff_0_eq_0";
   146 
   147 (*Must simplify BEFORE the induction!  (Else we get a critical pair)
   148   Suc(m) - Suc(n)   rewrites to   pred(Suc(m) - n)  *)
   149 Goal "Suc(m) - Suc(n) = m - n";
   150 by (Simp_tac 1);
   151 by (induct_tac "n" 1);
   152 by (ALLGOALS Asm_simp_tac);
   153 qed "diff_Suc_Suc";
   154 
   155 Addsimps [diff_0_eq_0, diff_Suc_Suc];
   156 
   157 (* Could be (and is, below) generalized in various ways;
   158    However, none of the generalizations are currently in the simpset,
   159    and I dread to think what happens if I put them in *)
   160 Goal "0 < n ==> Suc(n - Suc 0) = n";
   161 by (asm_simp_tac (simpset() addsplits [nat.split]) 1);
   162 qed "Suc_pred";
   163 Addsimps [Suc_pred];
   164 
   165 Delsimps [diff_Suc];
   166 
   167 
   168 (**** Inductive properties of the operators ****)
   169 
   170 (*** Addition ***)
   171 
   172 Goal "m + 0 = (m::nat)";
   173 by (induct_tac "m" 1);
   174 by (ALLGOALS Asm_simp_tac);
   175 qed "add_0_right";
   176 
   177 Goal "m + Suc(n) = Suc(m+n)";
   178 by (induct_tac "m" 1);
   179 by (ALLGOALS Asm_simp_tac);
   180 qed "add_Suc_right";
   181 
   182 Addsimps [add_0_right,add_Suc_right];
   183 
   184 
   185 (*Associative law for addition*)
   186 Goal "(m + n) + k = m + ((n + k)::nat)";
   187 by (induct_tac "m" 1);
   188 by (ALLGOALS Asm_simp_tac);
   189 qed "add_assoc";
   190 
   191 (*Commutative law for addition*)
   192 Goal "m + n = n + (m::nat)";
   193 by (induct_tac "m" 1);
   194 by (ALLGOALS Asm_simp_tac);
   195 qed "add_commute";
   196 
   197 Goal "x+(y+z)=y+((x+z)::nat)";
   198 by (rtac (add_commute RS trans) 1);
   199 by (rtac (add_assoc RS trans) 1);
   200 by (rtac (add_commute RS arg_cong) 1);
   201 qed "add_left_commute";
   202 
   203 (*Addition is an AC-operator*)
   204 bind_thms ("add_ac", [add_assoc, add_commute, add_left_commute]);
   205 
   206 Goal "(k + m = k + n) = (m=(n::nat))";
   207 by (induct_tac "k" 1);
   208 by (Simp_tac 1);
   209 by (Asm_simp_tac 1);
   210 qed "add_left_cancel";
   211 
   212 Goal "(m + k = n + k) = (m=(n::nat))";
   213 by (induct_tac "k" 1);
   214 by (Simp_tac 1);
   215 by (Asm_simp_tac 1);
   216 qed "add_right_cancel";
   217 
   218 Goal "(k + m <= k + n) = (m<=(n::nat))";
   219 by (induct_tac "k" 1);
   220 by (Simp_tac 1);
   221 by (Asm_simp_tac 1);
   222 qed "add_left_cancel_le";
   223 
   224 Goal "(k + m < k + n) = (m<(n::nat))";
   225 by (induct_tac "k" 1);
   226 by (Simp_tac 1);
   227 by (Asm_simp_tac 1);
   228 qed "add_left_cancel_less";
   229 
   230 Addsimps [add_left_cancel, add_right_cancel,
   231           add_left_cancel_le, add_left_cancel_less];
   232 
   233 (** Reasoning about m+0=0, etc. **)
   234 
   235 Goal "!!m::nat. (m+n = 0) = (m=0 & n=0)";
   236 by (case_tac "m" 1);
   237 by (Auto_tac);
   238 qed "add_is_0";
   239 AddIffs [add_is_0];
   240 
   241 Goal "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)";
   242 by (case_tac "m" 1);
   243 by (Auto_tac);
   244 qed "add_is_1";
   245 
   246 Goal "(Suc 0 = m+n) = (m = Suc 0 & n=0 | m=0 & n = Suc 0)";
   247 by (rtac ([eq_commute, add_is_1] MRS trans) 1);
   248 qed "one_is_add";
   249 
   250 Goal "!!m::nat. (0<m+n) = (0<m | 0<n)";
   251 by (simp_tac (simpset() delsimps [neq0_conv] addsimps [neq0_conv RS sym]) 1);
   252 qed "add_gr_0";
   253 AddIffs [add_gr_0];
   254 
   255 Goal "!!m::nat. m + n = m ==> n = 0";
   256 by (dtac (add_0_right RS ssubst) 1);
   257 by (asm_full_simp_tac (simpset() addsimps [add_assoc]
   258                                  delsimps [add_0_right]) 1);
   259 qed "add_eq_self_zero";
   260 
   261 (* a rather special thm needed for arith_tac: m+n = 0 may arise where m or n
   262 contain Suc. This contradiction must be detected. It cannot be detected by
   263 pulling Suc outside because this interferes with simprocs on
   264 numerals. Sigh. *)
   265 
   266 Goal "m ~= 0 ==> m+n ~= (0::nat)";
   267 by(Asm_full_simp_tac 1);
   268 qed "add_not_0_if_left_not_0";
   269 
   270 Goal "n ~= 0 ==> m+n ~= (0::nat)";
   271 by(Asm_full_simp_tac 1);
   272 qed "add_not_0_if_right_not_0";
   273 
   274 (**** Additional theorems about "less than" ****)
   275 
   276 (*Deleted less_natE; instead use less_imp_Suc_add RS exE*)
   277 Goal "m<n --> (EX k. n=Suc(m+k))";
   278 by (induct_tac "n" 1);
   279 by (ALLGOALS (simp_tac (simpset() addsimps [order_le_less])));
   280 by (blast_tac (claset() addSEs [less_SucE]
   281                         addSIs [add_0_right RS sym, add_Suc_right RS sym]) 1);
   282 qed_spec_mp "less_imp_Suc_add";
   283 
   284 Goal "n <= ((m + n)::nat)";
   285 by (induct_tac "m" 1);
   286 by (ALLGOALS Simp_tac);
   287 by (etac le_SucI 1);
   288 qed "le_add2";
   289 
   290 Goal "n <= ((n + m)::nat)";
   291 by (simp_tac (simpset() addsimps add_ac) 1);
   292 by (rtac le_add2 1);
   293 qed "le_add1";
   294 
   295 bind_thm ("less_add_Suc1", (lessI RS (le_add1 RS le_less_trans)));
   296 bind_thm ("less_add_Suc2", (lessI RS (le_add2 RS le_less_trans)));
   297 
   298 Goal "(m<n) = (EX k. n=Suc(m+k))";
   299 by (blast_tac (claset() addSIs [less_add_Suc1, less_imp_Suc_add]) 1);
   300 qed "less_iff_Suc_add";
   301 
   302 
   303 (*"i <= j ==> i <= j+m"*)
   304 bind_thm ("trans_le_add1", le_add1 RSN (2,le_trans));
   305 
   306 (*"i <= j ==> i <= m+j"*)
   307 bind_thm ("trans_le_add2", le_add2 RSN (2,le_trans));
   308 
   309 (*"i < j ==> i < j+m"*)
   310 bind_thm ("trans_less_add1", le_add1 RSN (2,less_le_trans));
   311 
   312 (*"i < j ==> i < m+j"*)
   313 bind_thm ("trans_less_add2", le_add2 RSN (2,less_le_trans));
   314 
   315 Goal "i+j < (k::nat) --> i<k";
   316 by (induct_tac "j" 1);
   317 by (ALLGOALS Asm_simp_tac);
   318 by (blast_tac (claset() addDs [Suc_lessD]) 1);
   319 qed_spec_mp "add_lessD1";
   320 
   321 Goal "~ (i+j < (i::nat))";
   322 by (rtac notI 1);
   323 by (etac (add_lessD1 RS less_irrefl) 1);
   324 qed "not_add_less1";
   325 
   326 Goal "~ (j+i < (i::nat))";
   327 by (simp_tac (simpset() addsimps [add_commute, not_add_less1]) 1);
   328 qed "not_add_less2";
   329 AddIffs [not_add_less1, not_add_less2];
   330 
   331 Goal "m+k<=n --> m<=(n::nat)";
   332 by (induct_tac "k" 1);
   333 by (ALLGOALS (asm_simp_tac (simpset() addsimps le_simps)));
   334 qed_spec_mp "add_leD1";
   335 
   336 Goal "m+k<=n ==> k<=(n::nat)";
   337 by (full_simp_tac (simpset() addsimps [add_commute]) 1);
   338 by (etac add_leD1 1);
   339 qed_spec_mp "add_leD2";
   340 
   341 Goal "m+k<=n ==> m<=n & k<=(n::nat)";
   342 by (blast_tac (claset() addDs [add_leD1, add_leD2]) 1);
   343 bind_thm ("add_leE", result() RS conjE);
   344 
   345 (*needs !!k for add_ac to work*)
   346 Goal "!!k:: nat. [| k<l;  m+l = k+n |] ==> m<n";
   347 by (force_tac (claset(),
   348               simpset() delsimps [add_Suc_right]
   349                         addsimps [less_iff_Suc_add,
   350                                   add_Suc_right RS sym] @ add_ac) 1);
   351 qed "less_add_eq_less";
   352 
   353 
   354 (*** Monotonicity of Addition ***)
   355 
   356 (*strict, in 1st argument*)
   357 Goal "i < j ==> i + k < j + (k::nat)";
   358 by (induct_tac "k" 1);
   359 by (ALLGOALS Asm_simp_tac);
   360 qed "add_less_mono1";
   361 
   362 (*strict, in both arguments*)
   363 Goal "[|i < j; k < l|] ==> i + k < j + (l::nat)";
   364 by (rtac (add_less_mono1 RS less_trans) 1);
   365 by (REPEAT (assume_tac 1));
   366 by (induct_tac "j" 1);
   367 by (ALLGOALS Asm_simp_tac);
   368 qed "add_less_mono";
   369 
   370 (*A [clumsy] way of lifting < monotonicity to <= monotonicity *)
   371 val [lt_mono,le] = Goal
   372      "[| !!i j::nat. i<j ==> f(i) < f(j);       \
   373 \        i <= j                                 \
   374 \     |] ==> f(i) <= (f(j)::nat)";
   375 by (cut_facts_tac [le] 1);
   376 by (asm_full_simp_tac (simpset() addsimps [order_le_less]) 1);
   377 by (blast_tac (claset() addSIs [lt_mono]) 1);
   378 qed "less_mono_imp_le_mono";
   379 
   380 (*non-strict, in 1st argument*)
   381 Goal "i<=j ==> i + k <= j + (k::nat)";
   382 by (res_inst_tac [("f", "%j. j+k")] less_mono_imp_le_mono 1);
   383 by (etac add_less_mono1 1);
   384 by (assume_tac 1);
   385 qed "add_le_mono1";
   386 
   387 (*non-strict, in both arguments*)
   388 Goal "[|i<=j;  k<=l |] ==> i + k <= j + (l::nat)";
   389 by (etac (add_le_mono1 RS le_trans) 1);
   390 by (simp_tac (simpset() addsimps [add_commute]) 1);
   391 qed "add_le_mono";
   392 
   393 
   394 (*** Multiplication ***)
   395 
   396 (*right annihilation in product*)
   397 Goal "!!m::nat. m * 0 = 0";
   398 by (induct_tac "m" 1);
   399 by (ALLGOALS Asm_simp_tac);
   400 qed "mult_0_right";
   401 
   402 (*right successor law for multiplication*)
   403 Goal  "m * Suc(n) = m + (m * n)";
   404 by (induct_tac "m" 1);
   405 by (ALLGOALS(asm_simp_tac (simpset() addsimps add_ac)));
   406 qed "mult_Suc_right";
   407 
   408 Addsimps [mult_0_right, mult_Suc_right];
   409 
   410 Goal "(1::nat) * n = n";
   411 by (Asm_simp_tac 1);
   412 qed "mult_1";
   413 
   414 Goal "n * (1::nat) = n";
   415 by (Asm_simp_tac 1);
   416 qed "mult_1_right";
   417 
   418 (*Commutative law for multiplication*)
   419 Goal "m * n = n * (m::nat)";
   420 by (induct_tac "m" 1);
   421 by (ALLGOALS Asm_simp_tac);
   422 qed "mult_commute";
   423 
   424 (*addition distributes over multiplication*)
   425 Goal "(m + n)*k = (m*k) + ((n*k)::nat)";
   426 by (induct_tac "m" 1);
   427 by (ALLGOALS(asm_simp_tac (simpset() addsimps add_ac)));
   428 qed "add_mult_distrib";
   429 
   430 Goal "k*(m + n) = (k*m) + ((k*n)::nat)";
   431 by (induct_tac "m" 1);
   432 by (ALLGOALS(asm_simp_tac (simpset() addsimps add_ac)));
   433 qed "add_mult_distrib2";
   434 
   435 (*Associative law for multiplication*)
   436 Goal "(m * n) * k = m * ((n * k)::nat)";
   437 by (induct_tac "m" 1);
   438 by (ALLGOALS (asm_simp_tac (simpset() addsimps [add_mult_distrib])));
   439 qed "mult_assoc";
   440 
   441 Goal "x*(y*z) = y*((x*z)::nat)";
   442 by (rtac trans 1);
   443 by (rtac mult_commute 1);
   444 by (rtac trans 1);
   445 by (rtac mult_assoc 1);
   446 by (rtac (mult_commute RS arg_cong) 1);
   447 qed "mult_left_commute";
   448 
   449 bind_thms ("mult_ac", [mult_assoc,mult_commute,mult_left_commute]);
   450 
   451 Goal "!!m::nat. (m*n = 0) = (m=0 | n=0)";
   452 by (induct_tac "m" 1);
   453 by (induct_tac "n" 2);
   454 by (ALLGOALS Asm_simp_tac);
   455 qed "mult_is_0";
   456 Addsimps [mult_is_0];
   457 
   458 
   459 (*** Difference ***)
   460 
   461 Goal "!!m::nat. m - m = 0";
   462 by (induct_tac "m" 1);
   463 by (ALLGOALS Asm_simp_tac);
   464 qed "diff_self_eq_0";
   465 
   466 Addsimps [diff_self_eq_0];
   467 
   468 (*Addition is the inverse of subtraction: if n<=m then n+(m-n) = m. *)
   469 Goal "~ m<n --> n+(m-n) = (m::nat)";
   470 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   471 by (ALLGOALS Asm_simp_tac);
   472 qed_spec_mp "add_diff_inverse";
   473 
   474 Goal "n<=m ==> n+(m-n) = (m::nat)";
   475 by (asm_simp_tac (simpset() addsimps [add_diff_inverse, not_less_iff_le]) 1);
   476 qed "le_add_diff_inverse";
   477 
   478 Goal "n<=m ==> (m-n)+n = (m::nat)";
   479 by (asm_simp_tac (simpset() addsimps [le_add_diff_inverse, add_commute]) 1);
   480 qed "le_add_diff_inverse2";
   481 
   482 Addsimps  [le_add_diff_inverse, le_add_diff_inverse2];
   483 
   484 
   485 (*** More results about difference ***)
   486 
   487 Goal "n <= m ==> Suc(m)-n = Suc(m-n)";
   488 by (etac rev_mp 1);
   489 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   490 by (ALLGOALS Asm_simp_tac);
   491 qed "Suc_diff_le";
   492 
   493 Goal "m - n < Suc(m)";
   494 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   495 by (etac less_SucE 3);
   496 by (ALLGOALS (asm_simp_tac (simpset() addsimps [less_Suc_eq])));
   497 qed "diff_less_Suc";
   498 
   499 Goal "m - n <= (m::nat)";
   500 by (res_inst_tac [("m","m"), ("n","n")] diff_induct 1);
   501 by (ALLGOALS (asm_simp_tac (simpset() addsimps [le_SucI])));
   502 qed "diff_le_self";
   503 Addsimps [diff_le_self];
   504 
   505 (* j<k ==> j-n < k *)
   506 bind_thm ("less_imp_diff_less", diff_le_self RS le_less_trans);
   507 
   508 Goal "!!i::nat. i-j-k = i - (j+k)";
   509 by (res_inst_tac [("m","i"),("n","j")] diff_induct 1);
   510 by (ALLGOALS Asm_simp_tac);
   511 qed "diff_diff_left";
   512 
   513 Goal "(Suc m - n) - Suc k = m - n - k";
   514 by (simp_tac (simpset() addsimps [diff_diff_left]) 1);
   515 qed "Suc_diff_diff";
   516 Addsimps [Suc_diff_diff];
   517 
   518 Goal "0<n ==> n - Suc i < n";
   519 by (case_tac "n" 1);
   520 by Safe_tac;
   521 by (asm_simp_tac (simpset() addsimps le_simps) 1);
   522 qed "diff_Suc_less";
   523 Addsimps [diff_Suc_less];
   524 
   525 (*This and the next few suggested by Florian Kammueller*)
   526 Goal "!!i::nat. i-j-k = i-k-j";
   527 by (simp_tac (simpset() addsimps [diff_diff_left, add_commute]) 1);
   528 qed "diff_commute";
   529 
   530 Goal "k <= (j::nat) --> (i + j) - k = i + (j - k)";
   531 by (res_inst_tac [("m","j"),("n","k")] diff_induct 1);
   532 by (ALLGOALS Asm_simp_tac);
   533 qed_spec_mp "diff_add_assoc";
   534 
   535 Goal "k <= (j::nat) --> (j + i) - k = (j - k) + i";
   536 by (asm_simp_tac (simpset() addsimps [add_commute, diff_add_assoc]) 1);
   537 qed_spec_mp "diff_add_assoc2";
   538 
   539 Goal "(n+m) - n = (m::nat)";
   540 by (induct_tac "n" 1);
   541 by (ALLGOALS Asm_simp_tac);
   542 qed "diff_add_inverse";
   543 
   544 Goal "(m+n) - n = (m::nat)";
   545 by (simp_tac (simpset() addsimps [diff_add_assoc]) 1);
   546 qed "diff_add_inverse2";
   547 
   548 Goal "i <= (j::nat) ==> (j-i=k) = (j=k+i)";
   549 by Safe_tac;
   550 by (ALLGOALS (asm_simp_tac (simpset() addsimps [diff_add_inverse2])));
   551 qed "le_imp_diff_is_add";
   552 
   553 Goal "!!m::nat. (m-n = 0) = (m <= n)";
   554 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   555 by (ALLGOALS Asm_simp_tac);
   556 qed "diff_is_0_eq";
   557 Addsimps [diff_is_0_eq];
   558 
   559 Goal "!!m::nat. (0<n-m) = (m<n)";
   560 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   561 by (ALLGOALS Asm_simp_tac);
   562 qed "zero_less_diff";
   563 Addsimps [zero_less_diff];
   564 
   565 Goal "i < j  ==> EX k::nat. 0<k & i+k = j";
   566 by (res_inst_tac [("x","j - i")] exI 1);
   567 by (asm_simp_tac (simpset() addsimps [add_diff_inverse, less_not_sym]) 1);
   568 qed "less_imp_add_positive";
   569 
   570 Goal "P(k) --> (ALL n. P(Suc(n))--> P(n)) --> P(k-i)";
   571 by (res_inst_tac [("m","k"),("n","i")] diff_induct 1);
   572 by (ALLGOALS (Clarify_tac THEN' Simp_tac THEN' TRY o Blast_tac));
   573 qed "zero_induct_lemma";
   574 
   575 val prems = Goal "[| P(k);  !!n. P(Suc(n)) ==> P(n) |] ==> P(0)";
   576 by (rtac (diff_self_eq_0 RS subst) 1);
   577 by (rtac (zero_induct_lemma RS mp RS mp) 1);
   578 by (REPEAT (ares_tac ([impI,allI]@prems) 1));
   579 qed "zero_induct";
   580 
   581 Goal "(k+m) - (k+n) = m - (n::nat)";
   582 by (induct_tac "k" 1);
   583 by (ALLGOALS Asm_simp_tac);
   584 qed "diff_cancel";
   585 
   586 Goal "(m+k) - (n+k) = m - (n::nat)";
   587 by (asm_simp_tac
   588     (simpset() addsimps [diff_cancel, inst "n" "k" add_commute]) 1);
   589 qed "diff_cancel2";
   590 
   591 Goal "n - (n+m) = (0::nat)";
   592 by (induct_tac "n" 1);
   593 by (ALLGOALS Asm_simp_tac);
   594 qed "diff_add_0";
   595 
   596 
   597 (** Difference distributes over multiplication **)
   598 
   599 Goal "!!m::nat. (m - n) * k = (m * k) - (n * k)";
   600 by (res_inst_tac [("m","m"),("n","n")] diff_induct 1);
   601 by (ALLGOALS (asm_simp_tac (simpset() addsimps [diff_cancel])));
   602 qed "diff_mult_distrib" ;
   603 
   604 Goal "!!m::nat. k * (m - n) = (k * m) - (k * n)";
   605 val mult_commute_k = read_instantiate [("m","k")] mult_commute;
   606 by (simp_tac (simpset() addsimps [diff_mult_distrib, mult_commute_k]) 1);
   607 qed "diff_mult_distrib2" ;
   608 (*NOT added as rewrites, since sometimes they are used from right-to-left*)
   609 
   610 bind_thms ("nat_distrib",
   611   [add_mult_distrib, add_mult_distrib2, diff_mult_distrib, diff_mult_distrib2]);
   612 
   613 
   614 (*** Monotonicity of Multiplication ***)
   615 
   616 Goal "i <= (j::nat) ==> i*k<=j*k";
   617 by (induct_tac "k" 1);
   618 by (ALLGOALS (asm_simp_tac (simpset() addsimps [add_le_mono])));
   619 qed "mult_le_mono1";
   620 
   621 Goal "i <= (j::nat) ==> k*i <= k*j";
   622 by (dtac mult_le_mono1 1);
   623 by (asm_simp_tac (simpset() addsimps [mult_commute]) 1);
   624 qed "mult_le_mono2";
   625 
   626 (* <= monotonicity, BOTH arguments*)
   627 Goal "[| i <= (j::nat); k <= l |] ==> i*k <= j*l";
   628 by (etac (mult_le_mono1 RS le_trans) 1);
   629 by (etac mult_le_mono2 1);
   630 qed "mult_le_mono";
   631 
   632 (*strict, in 1st argument; proof is by induction on k>0*)
   633 Goal "!!i::nat. [| i<j; 0<k |] ==> k*i < k*j";
   634 by (eres_inst_tac [("m1","0")] (less_imp_Suc_add RS exE) 1);
   635 by (Asm_simp_tac 1);
   636 by (induct_tac "x" 1);
   637 by (ALLGOALS (asm_simp_tac (simpset() addsimps [add_less_mono])));
   638 qed "mult_less_mono2";
   639 
   640 Goal "!!i::nat. [| i<j; 0<k |] ==> i*k < j*k";
   641 by (dtac mult_less_mono2 1);
   642 by (ALLGOALS (asm_full_simp_tac (simpset() addsimps [mult_commute])));
   643 qed "mult_less_mono1";
   644 
   645 Goal "!!m::nat. (0 < m*n) = (0<m & 0<n)";
   646 by (induct_tac "m" 1);
   647 by (case_tac "n" 2);
   648 by (ALLGOALS Asm_simp_tac);
   649 qed "zero_less_mult_iff";
   650 Addsimps [zero_less_mult_iff];
   651 
   652 Goal "(Suc 0 <= m*n) = (1<=m & 1<=n)";
   653 by (induct_tac "m" 1);
   654 by (case_tac "n" 2);
   655 by (ALLGOALS Asm_simp_tac);
   656 qed "one_le_mult_iff";
   657 Addsimps [one_le_mult_iff];
   658 
   659 Goal "(m*n = Suc 0) = (m=1 & n=1)";
   660 by (induct_tac "m" 1);
   661 by (Simp_tac 1);
   662 by (induct_tac "n" 1);
   663 by (Simp_tac 1);
   664 by (fast_tac (claset() addss simpset()) 1);
   665 qed "mult_eq_1_iff";
   666 Addsimps [mult_eq_1_iff];
   667 
   668 Goal "(Suc 0 = m*n) = (m=1 & n=1)";
   669 by (rtac (mult_eq_1_iff RSN (2,trans)) 1);
   670 by (fast_tac (claset() addss simpset()) 1);
   671 qed "one_eq_mult_iff";
   672 Addsimps [one_eq_mult_iff];
   673 
   674 Goal "!!m::nat. (m*k < n*k) = (0<k & m<n)";
   675 by (safe_tac (claset() addSIs [mult_less_mono1]));
   676 by (case_tac "k" 1);
   677 by Auto_tac;  
   678 by (full_simp_tac (simpset() delsimps [le_0_eq]
   679 			     addsimps [linorder_not_le RS sym]) 1);
   680 by (blast_tac (claset() addIs [mult_le_mono1]) 1); 
   681 qed "mult_less_cancel2";
   682 
   683 Goal "!!m::nat. (k*m < k*n) = (0<k & m<n)";
   684 by (simp_tac (simpset() addsimps [mult_less_cancel2, 
   685                                   inst "m" "k" mult_commute]) 1);
   686 qed "mult_less_cancel1";
   687 Addsimps [mult_less_cancel1, mult_less_cancel2];
   688 
   689 Goal "!!m::nat. (m*k <= n*k) = (0<k --> m<=n)";
   690 by (simp_tac (simpset() addsimps [linorder_not_less RS sym]) 1);
   691 by Auto_tac;  
   692 qed "mult_le_cancel2";
   693 
   694 Goal "!!m::nat. (k*m <= k*n) = (0<k --> m<=n)";
   695 by (simp_tac (simpset() addsimps [linorder_not_less RS sym]) 1);
   696 by Auto_tac;  
   697 qed "mult_le_cancel1";
   698 Addsimps [mult_le_cancel1, mult_le_cancel2];
   699 
   700 Goal "(m*k = n*k) = (m=n | (k = (0::nat)))";
   701 by (cut_facts_tac [less_linear] 1);
   702 by Safe_tac;
   703 by Auto_tac; 	
   704 by (ALLGOALS (dtac mult_less_mono1 THEN' assume_tac));
   705 by (ALLGOALS Asm_full_simp_tac);
   706 qed "mult_cancel2";
   707 
   708 Goal "(k*m = k*n) = (m=n | (k = (0::nat)))";
   709 by (simp_tac (simpset() addsimps [mult_cancel2, inst "m" "k" mult_commute]) 1);
   710 qed "mult_cancel1";
   711 Addsimps [mult_cancel1, mult_cancel2];
   712 
   713 Goal "(Suc k * m < Suc k * n) = (m < n)";
   714 by (stac mult_less_cancel1 1);
   715 by (Simp_tac 1);
   716 qed "Suc_mult_less_cancel1";
   717 
   718 Goal "(Suc k * m <= Suc k * n) = (m <= n)";
   719 by (stac mult_le_cancel1 1);
   720 by (Simp_tac 1);
   721 qed "Suc_mult_le_cancel1";
   722 
   723 Goal "(Suc k * m = Suc k * n) = (m = n)";
   724 by (stac mult_cancel1 1);
   725 by (Simp_tac 1);
   726 qed "Suc_mult_cancel1";
   727 
   728 
   729 (*Lemma for gcd*)
   730 Goal "!!m::nat. m = m*n ==> n=1 | m=0";
   731 by (dtac sym 1);
   732 by (rtac disjCI 1);
   733 by (rtac nat_less_cases 1 THEN assume_tac 2);
   734 by (fast_tac (claset() addSEs [less_SucE] addss simpset()) 1);
   735 by (best_tac (claset() addDs [mult_less_mono2] addss simpset()) 1);
   736 qed "mult_eq_self_implies_10";