src/Pure/sign.ML
author wenzelm
Fri Sep 01 13:13:19 1995 +0200 (1995-09-01)
changeset 1239 2c0d94151e74
parent 1216 a2f2360ce1c8
child 1241 bfc93c86f0a1
permissions -rw-r--r--
nonempty_sort: no longer var names as args;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   structure Symtab: SYMTAB
    11   structure Syntax: SYNTAX
    12   structure Type: TYPE
    13   sharing Symtab = Type.Symtab
    14   local open Type Syntax in
    15     type sg
    16     val rep_sg: sg ->
    17       {tsig: type_sig,
    18        const_tab: typ Symtab.table,
    19        syn: syntax,
    20        stamps: string ref list}
    21     val subsig: sg * sg -> bool
    22     val eq_sg: sg * sg -> bool
    23     val is_draft: sg -> bool
    24     val const_type: sg -> string -> typ option
    25     val classes: sg -> class list
    26     val subsort: sg -> sort * sort -> bool
    27     val norm_sort: sg -> sort -> sort
    28     val nonempty_sort: sg -> sort list -> sort -> bool
    29     val print_sg: sg -> unit
    30     val pretty_sg: sg -> Pretty.T
    31     val pprint_sg: sg -> pprint_args -> unit
    32     val pretty_term: sg -> term -> Pretty.T
    33     val pretty_typ: sg -> typ -> Pretty.T
    34     val pretty_sort: sort -> Pretty.T
    35     val string_of_term: sg -> term -> string
    36     val string_of_typ: sg -> typ -> string
    37     val pprint_term: sg -> term -> pprint_args -> unit
    38     val pprint_typ: sg -> typ -> pprint_args -> unit
    39     val certify_typ: sg -> typ -> typ
    40     val certify_term: sg -> term -> term * typ * int
    41     val read_typ: sg * (indexname -> sort option) -> string -> typ
    42     val infer_types: sg -> (indexname -> typ option) ->
    43       (indexname -> sort option) -> string list -> bool
    44       -> term list * typ -> int * term * (indexname * typ) list
    45     val add_classes: (class * class list) list -> sg -> sg
    46     val add_classrel: (class * class) list -> sg -> sg
    47     val add_defsort: sort -> sg -> sg
    48     val add_types: (string * int * mixfix) list -> sg -> sg
    49     val add_tyabbrs: (string * string list * string * mixfix) list -> sg -> sg
    50     val add_tyabbrs_i: (string * string list * typ * mixfix) list -> sg -> sg
    51     val add_arities: (string * sort list * sort) list -> sg -> sg
    52     val add_consts: (string * string * mixfix) list -> sg -> sg
    53     val add_consts_i: (string * typ * mixfix) list -> sg -> sg
    54     val add_syntax: (string * string * mixfix) list -> sg -> sg
    55     val add_syntax_i: (string * typ * mixfix) list -> sg -> sg
    56     val add_trfuns:
    57       (string * (ast list -> ast)) list *
    58       (string * (term list -> term)) list *
    59       (string * (term list -> term)) list *
    60       (string * (ast list -> ast)) list -> sg -> sg
    61     val add_trrules: (string * string) trrule list -> sg -> sg
    62     val add_trrules_i: ast trrule list -> sg -> sg
    63     val add_name: string -> sg -> sg
    64     val make_draft: sg -> sg
    65     val merge: sg * sg -> sg
    66     val proto_pure: sg
    67     val pure: sg
    68     val cpure: sg
    69     val const_of_class: class -> string
    70     val class_of_const: string -> class
    71   end
    72 end;
    73 
    74 functor SignFun(structure Syntax: SYNTAX and Type: TYPE): SIGN =
    75 struct
    76 
    77 structure Symtab = Type.Symtab;
    78 structure Syntax = Syntax;
    79 structure BasicSyntax: BASIC_SYNTAX = Syntax;
    80 structure Pretty = Syntax.Pretty;
    81 structure Type = Type;
    82 open BasicSyntax Type;
    83 
    84 
    85 (** datatype sg **)
    86 
    87 (*the "ref" in stamps ensures that no two signatures are identical -- it is
    88   impossible to forge a signature*)
    89 
    90 datatype sg =
    91   Sg of {
    92     tsig: type_sig,                 (*order-sorted signature of types*)
    93     const_tab: typ Symtab.table,    (*types of constants*)
    94     syn: Syntax.syntax,             (*syntax for parsing and printing*)
    95     stamps: string ref list};       (*unique theory indentifier*)
    96 
    97 fun rep_sg (Sg args) = args;
    98 val tsig_of = #tsig o rep_sg;
    99 
   100 
   101 (* stamps *)
   102 
   103 fun is_draft (Sg {stamps = ref "#" :: _, ...}) = true
   104   | is_draft _ = false;
   105 
   106 fun subsig (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) = s1 subset s2;
   107 
   108 fun eq_sg (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) = eq_set (s1, s2);
   109 
   110 
   111 (* consts *)
   112 
   113 fun const_type (Sg {const_tab, ...}) c =
   114   Symtab.lookup (const_tab, c);
   115 
   116 
   117 (* classes and sorts *)
   118 
   119 val classes = #classes o Type.rep_tsig o tsig_of;
   120 
   121 val subsort = Type.subsort o tsig_of;
   122 val norm_sort = Type.norm_sort o tsig_of;
   123 val nonempty_sort = Type.nonempty_sort o tsig_of;
   124 
   125 fun pretty_sort [c] = Pretty.str c
   126   | pretty_sort cs = Pretty.str_list "{" "}" cs;
   127 
   128 
   129 
   130 (** print signature **)
   131 
   132 val stamp_names = rev o map !;
   133 
   134 fun print_sg sg =
   135   let
   136     fun prt_typ syn ty = Pretty.quote (Syntax.pretty_typ syn ty);
   137 
   138     fun pretty_subclass (cl, cls) = Pretty.block
   139       (Pretty.str (cl ^ " <") :: Pretty.brk 1 ::
   140         Pretty.commas (map Pretty.str cls));
   141 
   142     fun pretty_default cls = Pretty.block
   143       [Pretty.str "default:", Pretty.brk 1, pretty_sort cls];
   144 
   145     fun pretty_ty (ty, n) = Pretty.str (ty ^ " " ^ string_of_int n);
   146 
   147     fun pretty_abbr syn (ty, (vs, rhs)) = Pretty.block
   148       [prt_typ syn (Type (ty, map (fn v => TVar ((v, 0), [])) vs)),
   149         Pretty.str " =", Pretty.brk 1, prt_typ syn rhs];
   150 
   151     fun pretty_arity ty (cl, []) = Pretty.block
   152           [Pretty.str (ty ^ " ::"), Pretty.brk 1, Pretty.str cl]
   153       | pretty_arity ty (cl, srts) = Pretty.block
   154           [Pretty.str (ty ^ " ::"), Pretty.brk 1,
   155             Pretty.list "(" ")" (map pretty_sort srts),
   156             Pretty.brk 1, Pretty.str cl];
   157 
   158     fun pretty_arities (ty, ars) = map (pretty_arity ty) ars;
   159 
   160     fun pretty_const syn (c, ty) = Pretty.block
   161       [Pretty.str (quote c ^ " ::"), Pretty.brk 1, prt_typ syn ty];
   162 
   163 
   164     val Sg {tsig, const_tab, syn, stamps} = sg;
   165     val {classes, subclass, default, tycons, abbrs, arities} = rep_tsig tsig;
   166   in
   167     Pretty.writeln (Pretty.strs ("stamps:" :: stamp_names stamps));
   168     Pretty.writeln (Pretty.strs ("classes:" :: classes));
   169     Pretty.writeln (Pretty.big_list "subclass:"
   170                       (map pretty_subclass subclass));
   171     Pretty.writeln (pretty_default default);
   172     Pretty.writeln (Pretty.big_list "types:" (map pretty_ty tycons));
   173     Pretty.writeln (Pretty.big_list "abbrs:" (map (pretty_abbr syn) abbrs));
   174     Pretty.writeln (Pretty.big_list "arities:"
   175                       (flat (map pretty_arities arities)));
   176     Pretty.writeln (Pretty.big_list "consts:"
   177                       (map (pretty_const syn) (Symtab.dest const_tab)))
   178   end;
   179 
   180 
   181 fun pretty_sg (Sg {stamps, ...}) =
   182   Pretty.str_list "{" "}" (stamp_names stamps);
   183 
   184 val pprint_sg = Pretty.pprint o pretty_sg;
   185 
   186 
   187 
   188 (** pretty printing of terms and types **)
   189 
   190 fun pretty_term (Sg {syn, stamps, ...}) =
   191   let val curried = "CPure" mem (map ! stamps);
   192   in Syntax.pretty_term curried syn end;
   193 
   194 fun pretty_typ (Sg {syn, ...}) = Syntax.pretty_typ syn;
   195 
   196 fun string_of_term (Sg {syn, stamps, ...}) =
   197   let val curried = "CPure" mem (map ! stamps);
   198   in Syntax.string_of_term curried syn end;
   199 
   200 fun string_of_typ (Sg {syn, ...}) = Syntax.string_of_typ syn;
   201 
   202 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   203 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   204 
   205 
   206 
   207 (** read types **)  (*exception ERROR*)
   208 
   209 fun err_in_type s =
   210   error ("The error(s) above occurred in type " ^ quote s);
   211 
   212 fun read_raw_typ syn tsig sort_of str =
   213   Syntax.read_typ syn (fn x => if_none (sort_of x) (defaultS tsig)) str
   214     handle ERROR => err_in_type str;
   215 
   216 (*read and certify typ wrt a signature*)
   217 fun read_typ (Sg {tsig, syn, ...}, sort_of) str =
   218   cert_typ tsig (read_raw_typ syn tsig sort_of str)
   219     handle TYPE (msg, _, _) => (writeln msg; err_in_type str);
   220 
   221 
   222 
   223 (** certify types and terms **)   (*exception TYPE*)
   224 
   225 fun certify_typ (Sg {tsig, ...}) ty = cert_typ tsig ty;
   226 
   227 
   228 fun mapfilt_atoms f (Abs (_, _, t)) = mapfilt_atoms f t
   229   | mapfilt_atoms f (t $ u) = mapfilt_atoms f t @ mapfilt_atoms f u
   230   | mapfilt_atoms f a = (case f a of Some y => [y] | None => []);
   231 
   232 fun certify_term (sg as Sg {tsig, ...}) tm =
   233   let
   234     fun valid_const a T =
   235       (case const_type sg a of
   236         Some U => typ_instance (tsig, T, U)
   237       | _ => false);
   238 
   239     fun atom_err (Const (a, T)) =
   240           if valid_const a T then None
   241           else Some ("Illegal type for constant " ^ quote a ^ " :: " ^
   242             quote (string_of_typ sg T))
   243       | atom_err (Var ((x, i), _)) =
   244           if i < 0 then Some ("Negative index for Var " ^ quote x) else None
   245       | atom_err _ = None;
   246 
   247     val norm_tm =
   248       (case it_term_types (typ_errors tsig) (tm, []) of
   249         [] => map_term_types (norm_typ tsig) tm
   250       | errs => raise_type (cat_lines errs) [] [tm]);
   251   in
   252     (case mapfilt_atoms atom_err norm_tm of
   253       [] => (norm_tm, type_of norm_tm, maxidx_of_term norm_tm)
   254     | errs => raise_type (cat_lines errs) [] [norm_tm])
   255   end;
   256 
   257 
   258 
   259 (** infer_types **)         (*exception ERROR*)
   260 
   261 fun infer_types sg types sorts used freeze (ts, T) =
   262   let
   263     val Sg {tsig, ...} = sg;
   264     val show_typ = string_of_typ sg;
   265     val show_term = string_of_term sg;
   266 
   267     fun term_err [] = ""
   268       | term_err [t] = "\nInvolving this term:\n" ^ show_term t
   269       | term_err ts =
   270           "\nInvolving these terms:\n" ^ cat_lines (map show_term ts);
   271 
   272     fun exn_type_msg (msg, Ts, ts) =
   273 	"\nType checking error: " ^ msg ^ "\n" ^
   274 	cat_lines (map show_typ Ts) ^ term_err ts ^ "\n";
   275 
   276     val T' = certify_typ sg T
   277              handle TYPE arg => error (exn_type_msg arg);
   278 
   279     val ct = const_type sg;
   280 
   281     fun warn() =
   282       if length ts > 1 andalso length ts <= !Syntax.ambiguity_level
   283       then (*no warning shown yet*)
   284            writeln "Warning: Currently parsed input \
   285                    \produces more than one parse tree.\n\
   286                    \For more information lower Syntax.ambiguity_level."
   287       else ();
   288 
   289     datatype result = One of int * term * (indexname * typ) list
   290                     | Errs of (string * typ list * term list)list
   291                     | Ambigs of term list;
   292 
   293     fun process_term(res,(t,i)) =
   294        let val (u,tye) = Type.infer_types(tsig,ct,types,sorts,used,freeze,T',t)
   295        in case res of
   296             One(_,t0,_) => Ambigs([u,t0])
   297           | Errs _ => One(i,u,tye)
   298           | Ambigs(us) => Ambigs(u::us)
   299        end
   300        handle TYPE arg => (case res of Errs(errs) => Errs(arg::errs)
   301                                      | _ => res);
   302 
   303   in case foldl process_term (Errs[], ts ~~ (0 upto (length ts - 1))) of
   304        One(res) =>
   305          (if length ts > !Syntax.ambiguity_level
   306           then writeln "Fortunately, only one parse tree is type correct.\n\
   307             \It helps (speed!) if you disambiguate your grammar or your input."
   308           else ();
   309           res)
   310      | Errs(errs) => (warn(); error(cat_lines(map exn_type_msg errs)))
   311      | Ambigs(us) =>
   312          (warn();
   313           let val old_show_brackets = !show_brackets
   314               val dummy = show_brackets := true;
   315               val errs = cat_lines(map show_term us)
   316           in show_brackets := old_show_brackets;
   317              error("Error: More than one term is type correct:\n" ^ errs)
   318           end)
   319   end;
   320 
   321 
   322 (** extend signature **)    (*exception ERROR*)
   323 
   324 (** signature extension functions **)  (*exception ERROR*)
   325 
   326 fun decls_of name_of mfixs =
   327   map (fn (x, y, mx) => (name_of x mx, y)) mfixs;
   328 
   329 
   330 (* add default sort *)
   331 
   332 fun ext_defsort (syn, tsig, ctab) defsort =
   333   (syn, ext_tsig_defsort tsig defsort, ctab);
   334 
   335 
   336 (* add type constructors *)
   337 
   338 fun ext_types (syn, tsig, ctab) types =
   339   (Syntax.extend_type_gram syn types,
   340     ext_tsig_types tsig (decls_of Syntax.type_name types),
   341     ctab);
   342 
   343 
   344 (* add type abbreviations *)
   345 
   346 fun read_abbr syn tsig (t, vs, rhs_src) =
   347   (t, vs, read_raw_typ syn tsig (K None) rhs_src)
   348     handle ERROR => error ("in type abbreviation " ^ t);
   349 
   350 fun ext_abbrs rd_abbr (syn, tsig, ctab) abbrs =
   351   let
   352     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   353     val syn1 = Syntax.extend_type_gram syn (map mfix_of abbrs);
   354 
   355     fun decl_of (t, vs, rhs, mx) =
   356       rd_abbr syn1 tsig (Syntax.type_name t mx, vs, rhs);
   357   in
   358     (syn1, ext_tsig_abbrs tsig (map decl_of abbrs), ctab)
   359   end;
   360 
   361 val ext_tyabbrs_i = ext_abbrs (K (K I));
   362 val ext_tyabbrs = ext_abbrs read_abbr;
   363 
   364 
   365 (* add type arities *)
   366 
   367 fun ext_arities (syn, tsig, ctab) arities =
   368   let
   369     val tsig1 = ext_tsig_arities tsig arities;
   370     val log_types = logical_types tsig1;
   371   in
   372     (Syntax.extend_log_types syn log_types, tsig1, ctab)
   373   end;
   374 
   375 
   376 (* add term constants and syntax *)
   377 
   378 fun err_in_const c =
   379   error ("in declaration of constant " ^ quote c);
   380 
   381 fun err_dup_consts cs =
   382   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   383 
   384 
   385 fun read_const syn tsig (c, ty_src, mx) =
   386   (c, read_raw_typ syn tsig (K None) ty_src, mx)
   387     handle ERROR => err_in_const (Syntax.const_name c mx);
   388 
   389 fun ext_cnsts rd_const syn_only (syn, tsig, ctab) raw_consts =
   390   let
   391     fun prep_const (c, ty, mx) = (c, varifyT (cert_typ tsig (no_tvars ty)), mx)
   392       handle TYPE (msg, _, _) => (writeln msg; err_in_const (Syntax.const_name c mx));
   393 
   394     val consts = map (prep_const o rd_const syn tsig) raw_consts;
   395     val decls =
   396       if syn_only then []
   397       else filter_out (equal "" o fst) (decls_of Syntax.const_name consts);
   398   in
   399     (Syntax.extend_const_gram syn consts, tsig,
   400       Symtab.extend_new (ctab, decls)
   401         handle Symtab.DUPS cs => err_dup_consts cs)
   402   end;
   403 
   404 val ext_consts_i = ext_cnsts (K (K I)) false;
   405 val ext_consts = ext_cnsts read_const false;
   406 val ext_syntax_i = ext_cnsts (K (K I)) true;
   407 val ext_syntax = ext_cnsts read_const true;
   408 
   409 
   410 (* add type classes *)
   411 
   412 fun const_of_class c = c ^ "_class";
   413 
   414 fun class_of_const c_class =
   415   let
   416     val c = implode (take (size c_class - 6, explode c_class));
   417   in
   418     if const_of_class c = c_class then c
   419     else raise_term ("class_of_const: bad name " ^ quote c_class) []
   420   end;
   421 
   422 
   423 fun ext_classes (syn, tsig, ctab) classes =
   424   let
   425     val names = map fst classes;
   426     val consts =
   427       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   428   in
   429     ext_consts_i
   430       (Syntax.extend_consts syn names, ext_tsig_classes tsig classes, ctab)
   431       consts
   432   end;
   433 
   434 
   435 (* add to subclass relation *)
   436 
   437 fun ext_classrel (syn, tsig, ctab) pairs =
   438   (syn, ext_tsig_subclass tsig pairs, ctab);
   439 
   440 
   441 (* add to syntax *)
   442 
   443 fun ext_syn extfun (syn, tsig, ctab) args =
   444   (extfun syn args, tsig, ctab);
   445 
   446 
   447 (* build signature *)
   448 
   449 fun ext_stamps stamps name =
   450   let
   451     val stmps = (case stamps of ref "#" :: ss => ss | ss => ss);
   452   in
   453     if exists (equal name o !) stmps then
   454       error ("Theory already contains a " ^ quote name ^ " component")
   455     else ref name :: stmps
   456   end;
   457 
   458 fun make_sign (syn, tsig, ctab) stamps name =
   459   Sg {tsig = tsig, const_tab = ctab, syn = syn,
   460     stamps = ext_stamps stamps name};
   461 
   462 fun extend_sign extfun name decls (Sg {tsig, const_tab, syn, stamps}) =
   463   make_sign (extfun (syn, tsig, const_tab) decls) stamps name;
   464 
   465 
   466 (* the external interfaces *)
   467 
   468 val add_classes   = extend_sign ext_classes "#";
   469 val add_classrel  = extend_sign ext_classrel "#";
   470 val add_defsort   = extend_sign ext_defsort "#";
   471 val add_types     = extend_sign ext_types "#";
   472 val add_tyabbrs   = extend_sign ext_tyabbrs "#";
   473 val add_tyabbrs_i = extend_sign ext_tyabbrs_i "#";
   474 val add_arities   = extend_sign ext_arities "#";
   475 val add_consts    = extend_sign ext_consts "#";
   476 val add_consts_i  = extend_sign ext_consts_i "#";
   477 val add_syntax    = extend_sign ext_syntax "#";
   478 val add_syntax_i  = extend_sign ext_syntax_i "#";
   479 val add_trfuns    = extend_sign (ext_syn Syntax.extend_trfuns) "#";
   480 val add_trrules   = extend_sign (ext_syn Syntax.extend_trrules) "#";
   481 val add_trrules_i = extend_sign (ext_syn Syntax.extend_trrules_i) "#";
   482 
   483 fun add_name name sg = extend_sign K name () sg;
   484 val make_draft = add_name "#";
   485 
   486 
   487 
   488 (** merge signatures **)    (*exception TERM*) (*exception ERROR (* FIXME *)*)
   489 
   490 fun merge (sg1, sg2) =
   491   if subsig (sg2, sg1) then sg1
   492   else if subsig (sg1, sg2) then sg2
   493   else if is_draft sg1 orelse is_draft sg2 then
   494     raise_term "Illegal merge of draft signatures" []
   495   else
   496     (*neither is union already; must form union*)
   497     let
   498       val Sg {tsig = tsig1, const_tab = const_tab1, syn = syn1,
   499         stamps = stamps1} = sg1;
   500       val Sg {tsig = tsig2, const_tab = const_tab2, syn = syn2,
   501         stamps = stamps2} = sg2;
   502 
   503 
   504       val stamps = merge_rev_lists stamps1 stamps2;
   505       val _ =
   506         (case duplicates (stamp_names stamps) of
   507           [] => ()
   508         | dups => raise_term ("Attempt to merge different versions of theories "
   509             ^ commas_quote dups) []);
   510 
   511       val tsig = merge_tsigs (tsig1, tsig2);
   512 
   513       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
   514         handle Symtab.DUPS cs =>
   515           raise_term ("Incompatible types for constant(s) " ^ commas_quote cs) [];
   516 
   517       val syn = Syntax.merge_syntaxes syn1 syn2;
   518     in
   519       Sg {tsig = tsig, const_tab = const_tab, syn = syn, stamps = stamps}
   520     end;
   521 
   522 
   523 
   524 (** the Pure signature **)
   525 
   526 val proto_pure =
   527   make_sign (Syntax.pure_syn, tsig0, Symtab.null) [] "#"
   528   |> add_types
   529    (("fun", 2, NoSyn) ::
   530     ("prop", 0, NoSyn) ::
   531     ("itself", 1, NoSyn) ::
   532     Syntax.pure_types)
   533   |> add_classes [(logicC, [])]
   534   |> add_defsort logicS
   535   |> add_arities
   536    [("fun", [logicS, logicS], logicS),
   537     ("prop", [], logicS),
   538     ("itself", [logicS], logicS)]
   539   |> add_syntax Syntax.pure_syntax
   540   |> add_trfuns Syntax.pure_trfuns
   541   |> add_consts
   542    [("==", "['a::{}, 'a] => prop", Mixfix ("(_ ==/ _)", [3, 2], 2)),
   543     ("=?=", "['a::{}, 'a] => prop", Mixfix ("(_ =?=/ _)", [3, 2], 2)),
   544     ("==>", "[prop, prop] => prop", Mixfix ("(_ ==>/ _)", [2, 1], 1)),
   545     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   546     ("TYPE", "'a itself", NoSyn)]
   547   |> add_name "ProtoPure";
   548 
   549 val pure = proto_pure
   550   |> add_syntax Syntax.pure_appl_syntax
   551   |> add_name "Pure";
   552 
   553 val cpure = proto_pure
   554   |> add_syntax Syntax.pure_applC_syntax
   555   |> add_name "CPure";
   556 
   557 end;