src/HOL/Nat.thy
author haftmann
Tue Jul 14 10:54:04 2009 +0200 (2009-07-14)
changeset 31998 2c7a24f74db9
parent 31714 347e9d18f372
child 32437 66f1a0dfe7d9
permissions -rw-r--r--
code attributes use common underscore convention
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Ring_and_Field
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat
    47   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc ::   "nat => nat"
    51   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    67     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    68 
    69 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    70   by (rule not_sym, rule Suc_not_Zero not_sym)
    71 
    72 rep_datatype "0 \<Colon> nat" Suc
    73   apply (unfold Zero_nat_def Suc_def)
    74      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    75      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    76      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    77     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    78       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    79       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    80       inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    81   done
    82 
    83 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    84   -- {* for backward compatibility -- names of variables differ *}
    85   fixes n
    86   assumes "P 0"
    87     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    88   shows "P n"
    89   using assms by (rule nat.induct) 
    90 
    91 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    92 
    93 lemmas nat_rec_0 = nat.recs(1)
    94   and nat_rec_Suc = nat.recs(2)
    95 
    96 lemmas nat_case_0 = nat.cases(1)
    97   and nat_case_Suc = nat.cases(2)
    98    
    99 
   100 text {* Injectiveness and distinctness lemmas *}
   101 
   102 lemma inj_Suc[simp]: "inj_on Suc N"
   103   by (simp add: inj_on_def)
   104 
   105 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   106 by (rule notE, rule Suc_not_Zero)
   107 
   108 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   109 by (rule Suc_neq_Zero, erule sym)
   110 
   111 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   112 by (rule inj_Suc [THEN injD])
   113 
   114 lemma n_not_Suc_n: "n \<noteq> Suc n"
   115 by (induct n) simp_all
   116 
   117 lemma Suc_n_not_n: "Suc n \<noteq> n"
   118 by (rule not_sym, rule n_not_Suc_n)
   119 
   120 text {* A special form of induction for reasoning
   121   about @{term "m < n"} and @{term "m - n"} *}
   122 
   123 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   124     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   125   apply (rule_tac x = m in spec)
   126   apply (induct n)
   127   prefer 2
   128   apply (rule allI)
   129   apply (induct_tac x, iprover+)
   130   done
   131 
   132 
   133 subsection {* Arithmetic operators *}
   134 
   135 instantiation nat :: "{minus, comm_monoid_add}"
   136 begin
   137 
   138 primrec plus_nat
   139 where
   140   add_0:      "0 + n = (n\<Colon>nat)"
   141   | add_Suc:  "Suc m + n = Suc (m + n)"
   142 
   143 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   144   by (induct m) simp_all
   145 
   146 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   147   by (induct m) simp_all
   148 
   149 declare add_0 [code]
   150 
   151 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   152   by simp
   153 
   154 primrec minus_nat
   155 where
   156   diff_0:     "m - 0 = (m\<Colon>nat)"
   157   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   158 
   159 declare diff_Suc [simp del]
   160 declare diff_0 [code]
   161 
   162 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   163   by (induct n) (simp_all add: diff_Suc)
   164 
   165 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   166   by (induct n) (simp_all add: diff_Suc)
   167 
   168 instance proof
   169   fix n m q :: nat
   170   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   171   show "n + m = m + n" by (induct n) simp_all
   172   show "0 + n = n" by simp
   173 qed
   174 
   175 end
   176 
   177 instantiation nat :: comm_semiring_1_cancel
   178 begin
   179 
   180 definition
   181   One_nat_def [simp]: "1 = Suc 0"
   182 
   183 primrec times_nat
   184 where
   185   mult_0:     "0 * n = (0\<Colon>nat)"
   186   | mult_Suc: "Suc m * n = n + (m * n)"
   187 
   188 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   189   by (induct m) simp_all
   190 
   191 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   192   by (induct m) (simp_all add: add_left_commute)
   193 
   194 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   195   by (induct m) (simp_all add: add_assoc)
   196 
   197 instance proof
   198   fix n m q :: nat
   199   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   200   show "1 * n = n" unfolding One_nat_def by simp
   201   show "n * m = m * n" by (induct n) simp_all
   202   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   203   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   204   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   205 qed
   206 
   207 end
   208 
   209 subsubsection {* Addition *}
   210 
   211 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   212   by (rule add_assoc)
   213 
   214 lemma nat_add_commute: "m + n = n + (m::nat)"
   215   by (rule add_commute)
   216 
   217 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   218   by (rule add_left_commute)
   219 
   220 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   221   by (rule add_left_cancel)
   222 
   223 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   224   by (rule add_right_cancel)
   225 
   226 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   227 
   228 lemma add_is_0 [iff]:
   229   fixes m n :: nat
   230   shows "(m + n = 0) = (m = 0 & n = 0)"
   231   by (cases m) simp_all
   232 
   233 lemma add_is_1:
   234   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   235   by (cases m) simp_all
   236 
   237 lemma one_is_add:
   238   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   239   by (rule trans, rule eq_commute, rule add_is_1)
   240 
   241 lemma add_eq_self_zero:
   242   fixes m n :: nat
   243   shows "m + n = m \<Longrightarrow> n = 0"
   244   by (induct m) simp_all
   245 
   246 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   247   apply (induct k)
   248    apply simp
   249   apply(drule comp_inj_on[OF _ inj_Suc])
   250   apply (simp add:o_def)
   251   done
   252 
   253 
   254 subsubsection {* Difference *}
   255 
   256 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   257   by (induct m) simp_all
   258 
   259 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   260   by (induct i j rule: diff_induct) simp_all
   261 
   262 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   263   by (simp add: diff_diff_left)
   264 
   265 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   266   by (simp add: diff_diff_left add_commute)
   267 
   268 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   269   by (induct n) simp_all
   270 
   271 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   272   by (simp add: diff_add_inverse add_commute [of m n])
   273 
   274 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   275   by (induct k) simp_all
   276 
   277 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   278   by (simp add: diff_cancel add_commute)
   279 
   280 lemma diff_add_0: "n - (n + m) = (0::nat)"
   281   by (induct n) simp_all
   282 
   283 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   284   unfolding One_nat_def by simp
   285 
   286 text {* Difference distributes over multiplication *}
   287 
   288 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   289 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   290 
   291 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   292 by (simp add: diff_mult_distrib mult_commute [of k])
   293   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   294 
   295 
   296 subsubsection {* Multiplication *}
   297 
   298 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   299   by (rule mult_assoc)
   300 
   301 lemma nat_mult_commute: "m * n = n * (m::nat)"
   302   by (rule mult_commute)
   303 
   304 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   305   by (rule right_distrib)
   306 
   307 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   308   by (induct m) auto
   309 
   310 lemmas nat_distrib =
   311   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   312 
   313 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   314   apply (induct m)
   315    apply simp
   316   apply (induct n)
   317    apply auto
   318   done
   319 
   320 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   321   apply (rule trans)
   322   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   323   done
   324 
   325 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   326   unfolding One_nat_def by (rule mult_eq_1_iff)
   327 
   328 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   329   unfolding One_nat_def by (rule one_eq_mult_iff)
   330 
   331 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   332 proof -
   333   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   334   proof (induct n arbitrary: m)
   335     case 0 then show "m = 0" by simp
   336   next
   337     case (Suc n) then show "m = Suc n"
   338       by (cases m) (simp_all add: eq_commute [of "0"])
   339   qed
   340   then show ?thesis by auto
   341 qed
   342 
   343 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   344   by (simp add: mult_commute)
   345 
   346 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   347   by (subst mult_cancel1) simp
   348 
   349 
   350 subsection {* Orders on @{typ nat} *}
   351 
   352 subsubsection {* Operation definition *}
   353 
   354 instantiation nat :: linorder
   355 begin
   356 
   357 primrec less_eq_nat where
   358   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   359   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   360 
   361 declare less_eq_nat.simps [simp del]
   362 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   363 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   364 
   365 definition less_nat where
   366   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   367 
   368 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   369   by (simp add: less_eq_nat.simps(2))
   370 
   371 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   372   unfolding less_eq_Suc_le ..
   373 
   374 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   375   by (induct n) (simp_all add: less_eq_nat.simps(2))
   376 
   377 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   378   by (simp add: less_eq_Suc_le)
   379 
   380 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   381   by simp
   382 
   383 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   384   by (simp add: less_eq_Suc_le)
   385 
   386 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   387   by (simp add: less_eq_Suc_le)
   388 
   389 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   390   by (induct m arbitrary: n)
   391     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   392 
   393 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   394   by (cases n) (auto intro: le_SucI)
   395 
   396 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   397   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   398 
   399 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   400   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   401 
   402 instance
   403 proof
   404   fix n m :: nat
   405   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   406   proof (induct n arbitrary: m)
   407     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   408   next
   409     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   410   qed
   411 next
   412   fix n :: nat show "n \<le> n" by (induct n) simp_all
   413 next
   414   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   415   then show "n = m"
   416     by (induct n arbitrary: m)
   417       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   418 next
   419   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   420   then show "n \<le> q"
   421   proof (induct n arbitrary: m q)
   422     case 0 show ?case by simp
   423   next
   424     case (Suc n) then show ?case
   425       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   426         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   427         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   428   qed
   429 next
   430   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   431     by (induct n arbitrary: m)
   432       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   433 qed
   434 
   435 end
   436 
   437 instantiation nat :: bot
   438 begin
   439 
   440 definition bot_nat :: nat where
   441   "bot_nat = 0"
   442 
   443 instance proof
   444 qed (simp add: bot_nat_def)
   445 
   446 end
   447 
   448 subsubsection {* Introduction properties *}
   449 
   450 lemma lessI [iff]: "n < Suc n"
   451   by (simp add: less_Suc_eq_le)
   452 
   453 lemma zero_less_Suc [iff]: "0 < Suc n"
   454   by (simp add: less_Suc_eq_le)
   455 
   456 
   457 subsubsection {* Elimination properties *}
   458 
   459 lemma less_not_refl: "~ n < (n::nat)"
   460   by (rule order_less_irrefl)
   461 
   462 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   463   by (rule not_sym) (rule less_imp_neq) 
   464 
   465 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   466   by (rule less_imp_neq)
   467 
   468 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   469   by (rule notE, rule less_not_refl)
   470 
   471 lemma less_zeroE: "(n::nat) < 0 ==> R"
   472   by (rule notE) (rule not_less0)
   473 
   474 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   475   unfolding less_Suc_eq_le le_less ..
   476 
   477 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   478   by (simp add: less_Suc_eq)
   479 
   480 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   481   unfolding One_nat_def by (rule less_Suc0)
   482 
   483 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   484   by simp
   485 
   486 text {* "Less than" is antisymmetric, sort of *}
   487 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   488   unfolding not_less less_Suc_eq_le by (rule antisym)
   489 
   490 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   491   by (rule linorder_neq_iff)
   492 
   493 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   494   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   495   shows "P n m"
   496   apply (rule less_linear [THEN disjE])
   497   apply (erule_tac [2] disjE)
   498   apply (erule lessCase)
   499   apply (erule sym [THEN eqCase])
   500   apply (erule major)
   501   done
   502 
   503 
   504 subsubsection {* Inductive (?) properties *}
   505 
   506 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   507   unfolding less_eq_Suc_le [of m] le_less by simp 
   508 
   509 lemma lessE:
   510   assumes major: "i < k"
   511   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   512   shows P
   513 proof -
   514   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   515     unfolding less_eq_Suc_le by (induct k) simp_all
   516   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   517     by (clarsimp simp add: less_le)
   518   with p1 p2 show P by auto
   519 qed
   520 
   521 lemma less_SucE: assumes major: "m < Suc n"
   522   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   523   apply (rule major [THEN lessE])
   524   apply (rule eq, blast)
   525   apply (rule less, blast)
   526   done
   527 
   528 lemma Suc_lessE: assumes major: "Suc i < k"
   529   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   530   apply (rule major [THEN lessE])
   531   apply (erule lessI [THEN minor])
   532   apply (erule Suc_lessD [THEN minor], assumption)
   533   done
   534 
   535 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   536   by simp
   537 
   538 lemma less_trans_Suc:
   539   assumes le: "i < j" shows "j < k ==> Suc i < k"
   540   apply (induct k, simp_all)
   541   apply (insert le)
   542   apply (simp add: less_Suc_eq)
   543   apply (blast dest: Suc_lessD)
   544   done
   545 
   546 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   547 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   548   unfolding not_less less_Suc_eq_le ..
   549 
   550 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   551   unfolding not_le Suc_le_eq ..
   552 
   553 text {* Properties of "less than or equal" *}
   554 
   555 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   556   unfolding less_Suc_eq_le .
   557 
   558 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   559   unfolding not_le less_Suc_eq_le ..
   560 
   561 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   562   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   563 
   564 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   565   by (drule le_Suc_eq [THEN iffD1], iprover+)
   566 
   567 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   568   unfolding Suc_le_eq .
   569 
   570 text {* Stronger version of @{text Suc_leD} *}
   571 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   572   unfolding Suc_le_eq .
   573 
   574 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   575   unfolding less_eq_Suc_le by (rule Suc_leD)
   576 
   577 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   578 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   579 
   580 
   581 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   582 
   583 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   584   unfolding le_less .
   585 
   586 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   587   by (rule le_less)
   588 
   589 text {* Useful with @{text blast}. *}
   590 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   591   by auto
   592 
   593 lemma le_refl: "n \<le> (n::nat)"
   594   by simp
   595 
   596 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   597   by (rule order_trans)
   598 
   599 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   600   by (rule antisym)
   601 
   602 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   603   by (rule less_le)
   604 
   605 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   606   unfolding less_le ..
   607 
   608 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   609   by (rule linear)
   610 
   611 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   612 
   613 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   614   unfolding less_Suc_eq_le by auto
   615 
   616 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   617   unfolding not_less by (rule le_less_Suc_eq)
   618 
   619 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   620 
   621 text {* These two rules ease the use of primitive recursion.
   622 NOTE USE OF @{text "=="} *}
   623 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   624 by simp
   625 
   626 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   627 by simp
   628 
   629 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   630 by (cases n) simp_all
   631 
   632 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   633 by (cases n) simp_all
   634 
   635 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   636 by (cases n) simp_all
   637 
   638 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   639 by (cases n) simp_all
   640 
   641 text {* This theorem is useful with @{text blast} *}
   642 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   643 by (rule neq0_conv[THEN iffD1], iprover)
   644 
   645 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   646 by (fast intro: not0_implies_Suc)
   647 
   648 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   649 using neq0_conv by blast
   650 
   651 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   652 by (induct m') simp_all
   653 
   654 text {* Useful in certain inductive arguments *}
   655 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   656 by (cases m) simp_all
   657 
   658 
   659 subsubsection {* @{term min} and @{term max} *}
   660 
   661 lemma mono_Suc: "mono Suc"
   662 by (rule monoI) simp
   663 
   664 lemma min_0L [simp]: "min 0 n = (0::nat)"
   665 by (rule min_leastL) simp
   666 
   667 lemma min_0R [simp]: "min n 0 = (0::nat)"
   668 by (rule min_leastR) simp
   669 
   670 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   671 by (simp add: mono_Suc min_of_mono)
   672 
   673 lemma min_Suc1:
   674    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   675 by (simp split: nat.split)
   676 
   677 lemma min_Suc2:
   678    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   679 by (simp split: nat.split)
   680 
   681 lemma max_0L [simp]: "max 0 n = (n::nat)"
   682 by (rule max_leastL) simp
   683 
   684 lemma max_0R [simp]: "max n 0 = (n::nat)"
   685 by (rule max_leastR) simp
   686 
   687 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   688 by (simp add: mono_Suc max_of_mono)
   689 
   690 lemma max_Suc1:
   691    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   692 by (simp split: nat.split)
   693 
   694 lemma max_Suc2:
   695    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   696 by (simp split: nat.split)
   697 
   698 
   699 subsubsection {* Monotonicity of Addition *}
   700 
   701 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   702 by (simp add: diff_Suc split: nat.split)
   703 
   704 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   705 unfolding One_nat_def by (rule Suc_pred)
   706 
   707 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   708 by (induct k) simp_all
   709 
   710 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   711 by (induct k) simp_all
   712 
   713 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   714 by(auto dest:gr0_implies_Suc)
   715 
   716 text {* strict, in 1st argument *}
   717 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   718 by (induct k) simp_all
   719 
   720 text {* strict, in both arguments *}
   721 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   722   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   723   apply (induct j, simp_all)
   724   done
   725 
   726 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   727 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   728   apply (induct n)
   729   apply (simp_all add: order_le_less)
   730   apply (blast elim!: less_SucE
   731                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   732   done
   733 
   734 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   735 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   736 apply(auto simp: gr0_conv_Suc)
   737 apply (induct_tac m)
   738 apply (simp_all add: add_less_mono)
   739 done
   740 
   741 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   742 instance nat :: ordered_semidom
   743 proof
   744   fix i j k :: nat
   745   show "0 < (1::nat)" by simp
   746   show "i \<le> j ==> k + i \<le> k + j" by simp
   747   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   748 qed
   749 
   750 instance nat :: no_zero_divisors
   751 proof
   752   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   753 qed
   754 
   755 lemma nat_mult_1: "(1::nat) * n = n"
   756 by simp
   757 
   758 lemma nat_mult_1_right: "n * (1::nat) = n"
   759 by simp
   760 
   761 
   762 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   763 
   764 text {* Complete induction, aka course-of-values induction *}
   765 
   766 instance nat :: wellorder proof
   767   fix P and n :: nat
   768   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   769   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   770   proof (induct n)
   771     case (0 n)
   772     have "P 0" by (rule step) auto
   773     thus ?case using 0 by auto
   774   next
   775     case (Suc m n)
   776     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   777     thus ?case
   778     proof
   779       assume "n \<le> m" thus "P n" by (rule Suc(1))
   780     next
   781       assume n: "n = Suc m"
   782       show "P n"
   783         by (rule step) (rule Suc(1), simp add: n le_simps)
   784     qed
   785   qed
   786   then show "P n" by auto
   787 qed
   788 
   789 lemma Least_Suc:
   790      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   791   apply (case_tac "n", auto)
   792   apply (frule LeastI)
   793   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   794   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   795   apply (erule_tac [2] Least_le)
   796   apply (case_tac "LEAST x. P x", auto)
   797   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   798   apply (blast intro: order_antisym)
   799   done
   800 
   801 lemma Least_Suc2:
   802    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   803   apply (erule (1) Least_Suc [THEN ssubst])
   804   apply simp
   805   done
   806 
   807 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   808   apply (cases n)
   809    apply blast
   810   apply (rule_tac x="LEAST k. P(k)" in exI)
   811   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   812   done
   813 
   814 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   815   unfolding One_nat_def
   816   apply (cases n)
   817    apply blast
   818   apply (frule (1) ex_least_nat_le)
   819   apply (erule exE)
   820   apply (case_tac k)
   821    apply simp
   822   apply (rename_tac k1)
   823   apply (rule_tac x=k1 in exI)
   824   apply (auto simp add: less_eq_Suc_le)
   825   done
   826 
   827 lemma nat_less_induct:
   828   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   829   using assms less_induct by blast
   830 
   831 lemma measure_induct_rule [case_names less]:
   832   fixes f :: "'a \<Rightarrow> nat"
   833   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   834   shows "P a"
   835 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   836 
   837 text {* old style induction rules: *}
   838 lemma measure_induct:
   839   fixes f :: "'a \<Rightarrow> nat"
   840   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   841   by (rule measure_induct_rule [of f P a]) iprover
   842 
   843 lemma full_nat_induct:
   844   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   845   shows "P n"
   846   by (rule less_induct) (auto intro: step simp:le_simps)
   847 
   848 text{*An induction rule for estabilishing binary relations*}
   849 lemma less_Suc_induct:
   850   assumes less:  "i < j"
   851      and  step:  "!!i. P i (Suc i)"
   852      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   853   shows "P i j"
   854 proof -
   855   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   856   have "P i (Suc (i + k))"
   857   proof (induct k)
   858     case 0
   859     show ?case by (simp add: step)
   860   next
   861     case (Suc k)
   862     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   863     hence "i < Suc (i + k)" by (simp add: add_commute)
   864     from trans[OF this lessI Suc step]
   865     show ?case by simp
   866   qed
   867   thus "P i j" by (simp add: j)
   868 qed
   869 
   870 text {* The method of infinite descent, frequently used in number theory.
   871 Provided by Roelof Oosterhuis.
   872 $P(n)$ is true for all $n\in\mathbb{N}$ if
   873 \begin{itemize}
   874   \item case ``0'': given $n=0$ prove $P(n)$,
   875   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   876         a smaller integer $m$ such that $\neg P(m)$.
   877 \end{itemize} *}
   878 
   879 text{* A compact version without explicit base case: *}
   880 lemma infinite_descent:
   881   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   882 by (induct n rule: less_induct, auto)
   883 
   884 lemma infinite_descent0[case_names 0 smaller]: 
   885   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   886 by (rule infinite_descent) (case_tac "n>0", auto)
   887 
   888 text {*
   889 Infinite descent using a mapping to $\mathbb{N}$:
   890 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   891 \begin{itemize}
   892 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   893 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   894 \end{itemize}
   895 NB: the proof also shows how to use the previous lemma. *}
   896 
   897 corollary infinite_descent0_measure [case_names 0 smaller]:
   898   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   899     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   900   shows "P x"
   901 proof -
   902   obtain n where "n = V x" by auto
   903   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   904   proof (induct n rule: infinite_descent0)
   905     case 0 -- "i.e. $V(x) = 0$"
   906     with A0 show "P x" by auto
   907   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   908     case (smaller n)
   909     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   910     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   911     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   912     then show ?case by auto
   913   qed
   914   ultimately show "P x" by auto
   915 qed
   916 
   917 text{* Again, without explicit base case: *}
   918 lemma infinite_descent_measure:
   919 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   920 proof -
   921   from assms obtain n where "n = V x" by auto
   922   moreover have "!!x. V x = n \<Longrightarrow> P x"
   923   proof (induct n rule: infinite_descent, auto)
   924     fix x assume "\<not> P x"
   925     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   926   qed
   927   ultimately show "P x" by auto
   928 qed
   929 
   930 text {* A [clumsy] way of lifting @{text "<"}
   931   monotonicity to @{text "\<le>"} monotonicity *}
   932 lemma less_mono_imp_le_mono:
   933   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   934 by (simp add: order_le_less) (blast)
   935 
   936 
   937 text {* non-strict, in 1st argument *}
   938 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   939 by (rule add_right_mono)
   940 
   941 text {* non-strict, in both arguments *}
   942 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   943 by (rule add_mono)
   944 
   945 lemma le_add2: "n \<le> ((m + n)::nat)"
   946 by (insert add_right_mono [of 0 m n], simp)
   947 
   948 lemma le_add1: "n \<le> ((n + m)::nat)"
   949 by (simp add: add_commute, rule le_add2)
   950 
   951 lemma less_add_Suc1: "i < Suc (i + m)"
   952 by (rule le_less_trans, rule le_add1, rule lessI)
   953 
   954 lemma less_add_Suc2: "i < Suc (m + i)"
   955 by (rule le_less_trans, rule le_add2, rule lessI)
   956 
   957 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   958 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   959 
   960 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   961 by (rule le_trans, assumption, rule le_add1)
   962 
   963 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   964 by (rule le_trans, assumption, rule le_add2)
   965 
   966 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   967 by (rule less_le_trans, assumption, rule le_add1)
   968 
   969 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   970 by (rule less_le_trans, assumption, rule le_add2)
   971 
   972 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   973 apply (rule le_less_trans [of _ "i+j"])
   974 apply (simp_all add: le_add1)
   975 done
   976 
   977 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   978 apply (rule notI)
   979 apply (drule add_lessD1)
   980 apply (erule less_irrefl [THEN notE])
   981 done
   982 
   983 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   984 by (simp add: add_commute)
   985 
   986 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   987 apply (rule order_trans [of _ "m+k"])
   988 apply (simp_all add: le_add1)
   989 done
   990 
   991 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   992 apply (simp add: add_commute)
   993 apply (erule add_leD1)
   994 done
   995 
   996 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   997 by (blast dest: add_leD1 add_leD2)
   998 
   999 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1000 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1001 by (force simp del: add_Suc_right
  1002     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1003 
  1004 
  1005 subsubsection {* More results about difference *}
  1006 
  1007 text {* Addition is the inverse of subtraction:
  1008   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1009 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1010 by (induct m n rule: diff_induct) simp_all
  1011 
  1012 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1013 by (simp add: add_diff_inverse linorder_not_less)
  1014 
  1015 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1016 by (simp add: add_commute)
  1017 
  1018 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1019 by (induct m n rule: diff_induct) simp_all
  1020 
  1021 lemma diff_less_Suc: "m - n < Suc m"
  1022 apply (induct m n rule: diff_induct)
  1023 apply (erule_tac [3] less_SucE)
  1024 apply (simp_all add: less_Suc_eq)
  1025 done
  1026 
  1027 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1028 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1029 
  1030 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1031   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1032 
  1033 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1034 by (rule le_less_trans, rule diff_le_self)
  1035 
  1036 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1037 by (cases n) (auto simp add: le_simps)
  1038 
  1039 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1040 by (induct j k rule: diff_induct) simp_all
  1041 
  1042 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1043 by (simp add: add_commute diff_add_assoc)
  1044 
  1045 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1046 by (auto simp add: diff_add_inverse2)
  1047 
  1048 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1049 by (induct m n rule: diff_induct) simp_all
  1050 
  1051 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1052 by (rule iffD2, rule diff_is_0_eq)
  1053 
  1054 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1055 by (induct m n rule: diff_induct) simp_all
  1056 
  1057 lemma less_imp_add_positive:
  1058   assumes "i < j"
  1059   shows "\<exists>k::nat. 0 < k & i + k = j"
  1060 proof
  1061   from assms show "0 < j - i & i + (j - i) = j"
  1062     by (simp add: order_less_imp_le)
  1063 qed
  1064 
  1065 text {* a nice rewrite for bounded subtraction *}
  1066 lemma nat_minus_add_max:
  1067   fixes n m :: nat
  1068   shows "n - m + m = max n m"
  1069     by (simp add: max_def not_le order_less_imp_le)
  1070 
  1071 lemma nat_diff_split:
  1072   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1073     -- {* elimination of @{text -} on @{text nat} *}
  1074 by (cases "a < b")
  1075   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1076     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1077 
  1078 lemma nat_diff_split_asm:
  1079   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1080     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1081 by (auto split: nat_diff_split)
  1082 
  1083 
  1084 subsubsection {* Monotonicity of Multiplication *}
  1085 
  1086 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1087 by (simp add: mult_right_mono)
  1088 
  1089 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1090 by (simp add: mult_left_mono)
  1091 
  1092 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1093 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1094 by (simp add: mult_mono)
  1095 
  1096 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1097 by (simp add: mult_strict_right_mono)
  1098 
  1099 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1100       there are no negative numbers.*}
  1101 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1102   apply (induct m)
  1103    apply simp
  1104   apply (case_tac n)
  1105    apply simp_all
  1106   done
  1107 
  1108 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1109   apply (induct m)
  1110    apply simp
  1111   apply (case_tac n)
  1112    apply simp_all
  1113   done
  1114 
  1115 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1116   apply (safe intro!: mult_less_mono1)
  1117   apply (case_tac k, auto)
  1118   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1119   apply (blast intro: mult_le_mono1)
  1120   done
  1121 
  1122 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1123 by (simp add: mult_commute [of k])
  1124 
  1125 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1126 by (simp add: linorder_not_less [symmetric], auto)
  1127 
  1128 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1129 by (simp add: linorder_not_less [symmetric], auto)
  1130 
  1131 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1132 by (subst mult_less_cancel1) simp
  1133 
  1134 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1135 by (subst mult_le_cancel1) simp
  1136 
  1137 lemma le_square: "m \<le> m * (m::nat)"
  1138   by (cases m) (auto intro: le_add1)
  1139 
  1140 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1141   by (cases m) (auto intro: le_add1)
  1142 
  1143 text {* Lemma for @{text gcd} *}
  1144 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1145   apply (drule sym)
  1146   apply (rule disjCI)
  1147   apply (rule nat_less_cases, erule_tac [2] _)
  1148    apply (drule_tac [2] mult_less_mono2)
  1149     apply (auto)
  1150   done
  1151 
  1152 text {* the lattice order on @{typ nat} *}
  1153 
  1154 instantiation nat :: distrib_lattice
  1155 begin
  1156 
  1157 definition
  1158   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1159 
  1160 definition
  1161   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1162 
  1163 instance by intro_classes
  1164   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1165     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1166 
  1167 end
  1168 
  1169 
  1170 subsection {* Natural operation of natural numbers on functions *}
  1171 
  1172 text {*
  1173   We use the same logical constant for the power operations on
  1174   functions and relations, in order to share the same syntax.
  1175 *}
  1176 
  1177 consts compow :: "nat \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
  1178 
  1179 abbreviation compower :: "('a \<Rightarrow> 'b) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'b" (infixr "^^" 80) where
  1180   "f ^^ n \<equiv> compow n f"
  1181 
  1182 notation (latex output)
  1183   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1184 
  1185 notation (HTML output)
  1186   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1187 
  1188 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1189 
  1190 overloading
  1191   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1192 begin
  1193 
  1194 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1195     "funpow 0 f = id"
  1196   | "funpow (Suc n) f = f o funpow n f"
  1197 
  1198 end
  1199 
  1200 text {* for code generation *}
  1201 
  1202 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1203   funpow_code_def [code_post]: "funpow = compow"
  1204 
  1205 lemmas [code_unfold] = funpow_code_def [symmetric]
  1206 
  1207 lemma [code]:
  1208   "funpow 0 f = id"
  1209   "funpow (Suc n) f = f o funpow n f"
  1210   unfolding funpow_code_def by simp_all
  1211 
  1212 hide (open) const funpow
  1213 
  1214 lemma funpow_add:
  1215   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1216   by (induct m) simp_all
  1217 
  1218 lemma funpow_swap1:
  1219   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1220 proof -
  1221   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1222   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1223   also have "\<dots> = (f ^^ n) (f x)" by simp
  1224   finally show ?thesis .
  1225 qed
  1226 
  1227 
  1228 subsection {* Embedding of the Naturals into any
  1229   @{text semiring_1}: @{term of_nat} *}
  1230 
  1231 context semiring_1
  1232 begin
  1233 
  1234 primrec
  1235   of_nat :: "nat \<Rightarrow> 'a"
  1236 where
  1237   of_nat_0:     "of_nat 0 = 0"
  1238   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1239 
  1240 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1241   unfolding One_nat_def by simp
  1242 
  1243 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1244   by (induct m) (simp_all add: add_ac)
  1245 
  1246 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1247   by (induct m) (simp_all add: add_ac left_distrib)
  1248 
  1249 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1250   "of_nat_aux inc 0 i = i"
  1251   | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1252 
  1253 lemma of_nat_code:
  1254   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1255 proof (induct n)
  1256   case 0 then show ?case by simp
  1257 next
  1258   case (Suc n)
  1259   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1260     by (induct n) simp_all
  1261   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1262     by simp
  1263   with Suc show ?case by (simp add: add_commute)
  1264 qed
  1265 
  1266 end
  1267 
  1268 declare of_nat_code [code, code_unfold, code_inline del]
  1269 
  1270 text{*Class for unital semirings with characteristic zero.
  1271  Includes non-ordered rings like the complex numbers.*}
  1272 
  1273 class semiring_char_0 = semiring_1 +
  1274   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1275 begin
  1276 
  1277 text{*Special cases where either operand is zero*}
  1278 
  1279 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1280   by (rule of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1281 
  1282 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1283   by (rule of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1284 
  1285 lemma inj_of_nat: "inj of_nat"
  1286   by (simp add: inj_on_def)
  1287 
  1288 end
  1289 
  1290 context ordered_semidom
  1291 begin
  1292 
  1293 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1294   apply (induct m, simp_all)
  1295   apply (erule order_trans)
  1296   apply (rule ord_le_eq_trans [OF _ add_commute])
  1297   apply (rule less_add_one [THEN less_imp_le])
  1298   done
  1299 
  1300 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1301   apply (induct m n rule: diff_induct, simp_all)
  1302   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1303   done
  1304 
  1305 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1306   apply (induct m n rule: diff_induct, simp_all)
  1307   apply (insert zero_le_imp_of_nat)
  1308   apply (force simp add: not_less [symmetric])
  1309   done
  1310 
  1311 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1312   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1313 
  1314 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1315   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1316 
  1317 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1318 
  1319 subclass semiring_char_0
  1320   proof qed (simp add: eq_iff order_eq_iff)
  1321 
  1322 text{*Special cases where either operand is zero*}
  1323 
  1324 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1325   by (rule of_nat_le_iff [of 0, simplified])
  1326 
  1327 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1328   by (rule of_nat_le_iff [of _ 0, simplified])
  1329 
  1330 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1331   by (rule of_nat_less_iff [of 0, simplified])
  1332 
  1333 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1334   by (rule of_nat_less_iff [of _ 0, simplified])
  1335 
  1336 end
  1337 
  1338 context ring_1
  1339 begin
  1340 
  1341 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1342 by (simp add: algebra_simps of_nat_add [symmetric])
  1343 
  1344 end
  1345 
  1346 context ordered_idom
  1347 begin
  1348 
  1349 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1350   unfolding abs_if by auto
  1351 
  1352 end
  1353 
  1354 lemma of_nat_id [simp]: "of_nat n = n"
  1355   by (induct n) (auto simp add: One_nat_def)
  1356 
  1357 lemma of_nat_eq_id [simp]: "of_nat = id"
  1358   by (auto simp add: expand_fun_eq)
  1359 
  1360 
  1361 subsection {* The Set of Natural Numbers *}
  1362 
  1363 context semiring_1
  1364 begin
  1365 
  1366 definition
  1367   Nats  :: "'a set" where
  1368   [code del]: "Nats = range of_nat"
  1369 
  1370 notation (xsymbols)
  1371   Nats  ("\<nat>")
  1372 
  1373 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1374   by (simp add: Nats_def)
  1375 
  1376 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1377 apply (simp add: Nats_def)
  1378 apply (rule range_eqI)
  1379 apply (rule of_nat_0 [symmetric])
  1380 done
  1381 
  1382 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1383 apply (simp add: Nats_def)
  1384 apply (rule range_eqI)
  1385 apply (rule of_nat_1 [symmetric])
  1386 done
  1387 
  1388 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1389 apply (auto simp add: Nats_def)
  1390 apply (rule range_eqI)
  1391 apply (rule of_nat_add [symmetric])
  1392 done
  1393 
  1394 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1395 apply (auto simp add: Nats_def)
  1396 apply (rule range_eqI)
  1397 apply (rule of_nat_mult [symmetric])
  1398 done
  1399 
  1400 end
  1401 
  1402 
  1403 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1404 
  1405 lemma subst_equals:
  1406   assumes 1: "t = s" and 2: "u = t"
  1407   shows "u = s"
  1408   using 2 1 by (rule trans)
  1409 
  1410 setup Arith_Data.setup
  1411 
  1412 use "Tools/nat_arith.ML"
  1413 declaration {* K Nat_Arith.setup *}
  1414 
  1415 use "Tools/lin_arith.ML"
  1416 setup {* Lin_Arith.global_setup *}
  1417 declaration {* K Lin_Arith.setup *}
  1418 
  1419 lemmas [arith_split] = nat_diff_split split_min split_max
  1420 
  1421 context order
  1422 begin
  1423 
  1424 lemma lift_Suc_mono_le:
  1425   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1426   shows "f n \<le> f n'"
  1427 proof (cases "n < n'")
  1428   case True
  1429   thus ?thesis
  1430     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1431 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1432 
  1433 lemma lift_Suc_mono_less:
  1434   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1435   shows "f n < f n'"
  1436 using `n < n'`
  1437 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1438 
  1439 lemma lift_Suc_mono_less_iff:
  1440   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1441 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1442          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1443 
  1444 end
  1445 
  1446 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1447 unfolding mono_def
  1448 by (auto intro:lift_Suc_mono_le[of f])
  1449 
  1450 lemma mono_nat_linear_lb:
  1451   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1452 apply(induct_tac k)
  1453  apply simp
  1454 apply(erule_tac x="m+n" in meta_allE)
  1455 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1456 apply simp
  1457 done
  1458 
  1459 
  1460 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1461 
  1462 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1463 by arith
  1464 
  1465 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1466 by arith
  1467 
  1468 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1469 by arith
  1470 
  1471 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1472 by arith
  1473 
  1474 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1475 by arith
  1476 
  1477 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1478 by arith
  1479 
  1480 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1481   second premise n\<le>m*)
  1482 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1483 by arith
  1484 
  1485 text {* Simplification of relational expressions involving subtraction *}
  1486 
  1487 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1488 by (simp split add: nat_diff_split)
  1489 
  1490 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1491 by (auto split add: nat_diff_split)
  1492 
  1493 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1494 by (auto split add: nat_diff_split)
  1495 
  1496 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1497 by (auto split add: nat_diff_split)
  1498 
  1499 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1500 
  1501 (* Monotonicity of subtraction in first argument *)
  1502 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1503 by (simp split add: nat_diff_split)
  1504 
  1505 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1506 by (simp split add: nat_diff_split)
  1507 
  1508 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1509 by (simp split add: nat_diff_split)
  1510 
  1511 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1512 by (simp split add: nat_diff_split)
  1513 
  1514 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1515 unfolding min_def by auto
  1516 
  1517 lemma inj_on_diff_nat: 
  1518   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1519   shows "inj_on (\<lambda>n. n - k) N"
  1520 proof (rule inj_onI)
  1521   fix x y
  1522   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1523   with k_le_n have "x - k + k = y - k + k" by auto
  1524   with a k_le_n show "x = y" by auto
  1525 qed
  1526 
  1527 text{*Rewriting to pull differences out*}
  1528 
  1529 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1530 by arith
  1531 
  1532 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1533 by arith
  1534 
  1535 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1536 by arith
  1537 
  1538 text{*Lemmas for ex/Factorization*}
  1539 
  1540 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1541 by (cases m) auto
  1542 
  1543 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1544 by (cases m) auto
  1545 
  1546 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1547 by (cases m) auto
  1548 
  1549 text {* Specialized induction principles that work "backwards": *}
  1550 
  1551 lemma inc_induct[consumes 1, case_names base step]:
  1552   assumes less: "i <= j"
  1553   assumes base: "P j"
  1554   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1555   shows "P i"
  1556   using less
  1557 proof (induct d=="j - i" arbitrary: i)
  1558   case (0 i)
  1559   hence "i = j" by simp
  1560   with base show ?case by simp
  1561 next
  1562   case (Suc d i)
  1563   hence "i < j" "P (Suc i)"
  1564     by simp_all
  1565   thus "P i" by (rule step)
  1566 qed
  1567 
  1568 lemma strict_inc_induct[consumes 1, case_names base step]:
  1569   assumes less: "i < j"
  1570   assumes base: "!!i. j = Suc i ==> P i"
  1571   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1572   shows "P i"
  1573   using less
  1574 proof (induct d=="j - i - 1" arbitrary: i)
  1575   case (0 i)
  1576   with `i < j` have "j = Suc i" by simp
  1577   with base show ?case by simp
  1578 next
  1579   case (Suc d i)
  1580   hence "i < j" "P (Suc i)"
  1581     by simp_all
  1582   thus "P i" by (rule step)
  1583 qed
  1584 
  1585 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1586   using inc_induct[of "k - i" k P, simplified] by blast
  1587 
  1588 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1589   using inc_induct[of 0 k P] by blast
  1590 
  1591 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1592   by auto
  1593 
  1594 (*The others are
  1595       i - j - k = i - (j + k),
  1596       k \<le> j ==> j - k + i = j + i - k,
  1597       k \<le> j ==> i + (j - k) = i + j - k *)
  1598 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1599 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1600 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1601 
  1602 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1603 Least_Suc}, since there appears to be no need.*}
  1604 
  1605 
  1606 subsection {* size of a datatype value *}
  1607 
  1608 class size =
  1609   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1610 
  1611 end