src/HOL/Limits.thy
author hoelzl
Tue Mar 26 12:21:00 2013 +0100 (2013-03-26)
changeset 51529 2d2f59e6055a
parent 51526 155263089e7b
child 51531 f415febf4234
permissions -rw-r--r--
move theorems about compactness of real closed intervals, the intermediate value theorem, and lemmas about continuity of bijective functions from Deriv.thy to Limits.thy
     1 (*  Title:      Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 
     7 *)
     8 
     9 header {* Limits on Real Vector Spaces *}
    10 
    11 theory Limits
    12 imports Real_Vector_Spaces
    13 begin
    14 
    15 (* Unfortunately eventually_within was overwritten by Multivariate_Analysis.
    16    Hence it was references as Limits.eventually_within, but now it is Basic_Topology.eventually_within *)
    17 lemmas eventually_within = eventually_within
    18 
    19 subsection {* Filter going to infinity norm *}
    20 
    21 definition at_infinity :: "'a::real_normed_vector filter" where
    22   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    23 
    24 lemma eventually_at_infinity:
    25   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    26 unfolding at_infinity_def
    27 proof (rule eventually_Abs_filter, rule is_filter.intro)
    28   fix P Q :: "'a \<Rightarrow> bool"
    29   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    30   then obtain r s where
    31     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    32   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    33   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    34 qed auto
    35 
    36 lemma at_infinity_eq_at_top_bot:
    37   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    38   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    39 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    40   fix P :: "real \<Rightarrow> bool" assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    41   then guess r ..
    42   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    43   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    44 next
    45   fix P :: "real \<Rightarrow> bool" assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    46   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    47   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    48     by (intro exI[of _ "max p (-q)"])
    49        (auto simp: abs_real_def)
    50 qed
    51 
    52 lemma at_top_le_at_infinity:
    53   "at_top \<le> (at_infinity :: real filter)"
    54   unfolding at_infinity_eq_at_top_bot by simp
    55 
    56 lemma at_bot_le_at_infinity:
    57   "at_bot \<le> (at_infinity :: real filter)"
    58   unfolding at_infinity_eq_at_top_bot by simp
    59 
    60 subsection {* Boundedness *}
    61 
    62 lemma Bfun_def:
    63   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    64   unfolding Bfun_metric_def norm_conv_dist
    65 proof safe
    66   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    67   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    68     by (intro always_eventually) (metis dist_commute dist_triangle)
    69   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    70     by eventually_elim auto
    71   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    72     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    73 qed auto
    74 
    75 lemma BfunI:
    76   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    77 unfolding Bfun_def
    78 proof (intro exI conjI allI)
    79   show "0 < max K 1" by simp
    80 next
    81   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    82     using K by (rule eventually_elim1, simp)
    83 qed
    84 
    85 lemma BfunE:
    86   assumes "Bfun f F"
    87   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    88 using assms unfolding Bfun_def by fast
    89 
    90 subsection {* Convergence to Zero *}
    91 
    92 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
    93   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
    94 
    95 lemma ZfunI:
    96   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
    97   unfolding Zfun_def by simp
    98 
    99 lemma ZfunD:
   100   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   101   unfolding Zfun_def by simp
   102 
   103 lemma Zfun_ssubst:
   104   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   105   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   106 
   107 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   108   unfolding Zfun_def by simp
   109 
   110 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   111   unfolding Zfun_def by simp
   112 
   113 lemma Zfun_imp_Zfun:
   114   assumes f: "Zfun f F"
   115   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   116   shows "Zfun (\<lambda>x. g x) F"
   117 proof (cases)
   118   assume K: "0 < K"
   119   show ?thesis
   120   proof (rule ZfunI)
   121     fix r::real assume "0 < r"
   122     hence "0 < r / K"
   123       using K by (rule divide_pos_pos)
   124     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   125       using ZfunD [OF f] by fast
   126     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   127     proof eventually_elim
   128       case (elim x)
   129       hence "norm (f x) * K < r"
   130         by (simp add: pos_less_divide_eq K)
   131       thus ?case
   132         by (simp add: order_le_less_trans [OF elim(1)])
   133     qed
   134   qed
   135 next
   136   assume "\<not> 0 < K"
   137   hence K: "K \<le> 0" by (simp only: not_less)
   138   show ?thesis
   139   proof (rule ZfunI)
   140     fix r :: real
   141     assume "0 < r"
   142     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   143     proof eventually_elim
   144       case (elim x)
   145       also have "norm (f x) * K \<le> norm (f x) * 0"
   146         using K norm_ge_zero by (rule mult_left_mono)
   147       finally show ?case
   148         using `0 < r` by simp
   149     qed
   150   qed
   151 qed
   152 
   153 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   154   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   155 
   156 lemma Zfun_add:
   157   assumes f: "Zfun f F" and g: "Zfun g F"
   158   shows "Zfun (\<lambda>x. f x + g x) F"
   159 proof (rule ZfunI)
   160   fix r::real assume "0 < r"
   161   hence r: "0 < r / 2" by simp
   162   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   163     using f r by (rule ZfunD)
   164   moreover
   165   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   166     using g r by (rule ZfunD)
   167   ultimately
   168   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   169   proof eventually_elim
   170     case (elim x)
   171     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   172       by (rule norm_triangle_ineq)
   173     also have "\<dots> < r/2 + r/2"
   174       using elim by (rule add_strict_mono)
   175     finally show ?case
   176       by simp
   177   qed
   178 qed
   179 
   180 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   181   unfolding Zfun_def by simp
   182 
   183 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   184   by (simp only: diff_minus Zfun_add Zfun_minus)
   185 
   186 lemma (in bounded_linear) Zfun:
   187   assumes g: "Zfun g F"
   188   shows "Zfun (\<lambda>x. f (g x)) F"
   189 proof -
   190   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   191     using bounded by fast
   192   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   193     by simp
   194   with g show ?thesis
   195     by (rule Zfun_imp_Zfun)
   196 qed
   197 
   198 lemma (in bounded_bilinear) Zfun:
   199   assumes f: "Zfun f F"
   200   assumes g: "Zfun g F"
   201   shows "Zfun (\<lambda>x. f x ** g x) F"
   202 proof (rule ZfunI)
   203   fix r::real assume r: "0 < r"
   204   obtain K where K: "0 < K"
   205     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   206     using pos_bounded by fast
   207   from K have K': "0 < inverse K"
   208     by (rule positive_imp_inverse_positive)
   209   have "eventually (\<lambda>x. norm (f x) < r) F"
   210     using f r by (rule ZfunD)
   211   moreover
   212   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   213     using g K' by (rule ZfunD)
   214   ultimately
   215   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   216   proof eventually_elim
   217     case (elim x)
   218     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   219       by (rule norm_le)
   220     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   221       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   222     also from K have "r * inverse K * K = r"
   223       by simp
   224     finally show ?case .
   225   qed
   226 qed
   227 
   228 lemma (in bounded_bilinear) Zfun_left:
   229   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   230   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   231 
   232 lemma (in bounded_bilinear) Zfun_right:
   233   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   234   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   235 
   236 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   237 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   238 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   239 
   240 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   241   by (simp only: tendsto_iff Zfun_def dist_norm)
   242 
   243 subsubsection {* Distance and norms *}
   244 
   245 lemma tendsto_norm [tendsto_intros]:
   246   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   247   unfolding norm_conv_dist by (intro tendsto_intros)
   248 
   249 lemma continuous_norm [continuous_intros]:
   250   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   251   unfolding continuous_def by (rule tendsto_norm)
   252 
   253 lemma continuous_on_norm [continuous_on_intros]:
   254   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   255   unfolding continuous_on_def by (auto intro: tendsto_norm)
   256 
   257 lemma tendsto_norm_zero:
   258   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   259   by (drule tendsto_norm, simp)
   260 
   261 lemma tendsto_norm_zero_cancel:
   262   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   263   unfolding tendsto_iff dist_norm by simp
   264 
   265 lemma tendsto_norm_zero_iff:
   266   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   267   unfolding tendsto_iff dist_norm by simp
   268 
   269 lemma tendsto_rabs [tendsto_intros]:
   270   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   271   by (fold real_norm_def, rule tendsto_norm)
   272 
   273 lemma continuous_rabs [continuous_intros]:
   274   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   275   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   276 
   277 lemma continuous_on_rabs [continuous_on_intros]:
   278   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   279   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   280 
   281 lemma tendsto_rabs_zero:
   282   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   283   by (fold real_norm_def, rule tendsto_norm_zero)
   284 
   285 lemma tendsto_rabs_zero_cancel:
   286   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   287   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   288 
   289 lemma tendsto_rabs_zero_iff:
   290   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   291   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   292 
   293 subsubsection {* Addition and subtraction *}
   294 
   295 lemma tendsto_add [tendsto_intros]:
   296   fixes a b :: "'a::real_normed_vector"
   297   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   298   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   299 
   300 lemma continuous_add [continuous_intros]:
   301   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   302   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   303   unfolding continuous_def by (rule tendsto_add)
   304 
   305 lemma continuous_on_add [continuous_on_intros]:
   306   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   307   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   308   unfolding continuous_on_def by (auto intro: tendsto_add)
   309 
   310 lemma tendsto_add_zero:
   311   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   312   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   313   by (drule (1) tendsto_add, simp)
   314 
   315 lemma tendsto_minus [tendsto_intros]:
   316   fixes a :: "'a::real_normed_vector"
   317   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   318   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   319 
   320 lemma continuous_minus [continuous_intros]:
   321   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   322   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   323   unfolding continuous_def by (rule tendsto_minus)
   324 
   325 lemma continuous_on_minus [continuous_on_intros]:
   326   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   327   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   328   unfolding continuous_on_def by (auto intro: tendsto_minus)
   329 
   330 lemma tendsto_minus_cancel:
   331   fixes a :: "'a::real_normed_vector"
   332   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   333   by (drule tendsto_minus, simp)
   334 
   335 lemma tendsto_minus_cancel_left:
   336     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   337   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   338   by auto
   339 
   340 lemma tendsto_diff [tendsto_intros]:
   341   fixes a b :: "'a::real_normed_vector"
   342   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   343   by (simp add: diff_minus tendsto_add tendsto_minus)
   344 
   345 lemma continuous_diff [continuous_intros]:
   346   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   347   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   348   unfolding continuous_def by (rule tendsto_diff)
   349 
   350 lemma continuous_on_diff [continuous_on_intros]:
   351   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   352   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   353   unfolding continuous_on_def by (auto intro: tendsto_diff)
   354 
   355 lemma tendsto_setsum [tendsto_intros]:
   356   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   357   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   358   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   359 proof (cases "finite S")
   360   assume "finite S" thus ?thesis using assms
   361     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   362 next
   363   assume "\<not> finite S" thus ?thesis
   364     by (simp add: tendsto_const)
   365 qed
   366 
   367 lemma continuous_setsum [continuous_intros]:
   368   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   369   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   370   unfolding continuous_def by (rule tendsto_setsum)
   371 
   372 lemma continuous_on_setsum [continuous_intros]:
   373   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   374   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   375   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   376 
   377 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   378 
   379 subsubsection {* Linear operators and multiplication *}
   380 
   381 lemma (in bounded_linear) tendsto:
   382   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   383   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   384 
   385 lemma (in bounded_linear) continuous:
   386   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   387   using tendsto[of g _ F] by (auto simp: continuous_def)
   388 
   389 lemma (in bounded_linear) continuous_on:
   390   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   391   using tendsto[of g] by (auto simp: continuous_on_def)
   392 
   393 lemma (in bounded_linear) tendsto_zero:
   394   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   395   by (drule tendsto, simp only: zero)
   396 
   397 lemma (in bounded_bilinear) tendsto:
   398   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   399   by (simp only: tendsto_Zfun_iff prod_diff_prod
   400                  Zfun_add Zfun Zfun_left Zfun_right)
   401 
   402 lemma (in bounded_bilinear) continuous:
   403   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   404   using tendsto[of f _ F g] by (auto simp: continuous_def)
   405 
   406 lemma (in bounded_bilinear) continuous_on:
   407   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   408   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   409 
   410 lemma (in bounded_bilinear) tendsto_zero:
   411   assumes f: "(f ---> 0) F"
   412   assumes g: "(g ---> 0) F"
   413   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   414   using tendsto [OF f g] by (simp add: zero_left)
   415 
   416 lemma (in bounded_bilinear) tendsto_left_zero:
   417   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   418   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   419 
   420 lemma (in bounded_bilinear) tendsto_right_zero:
   421   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   422   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   423 
   424 lemmas tendsto_of_real [tendsto_intros] =
   425   bounded_linear.tendsto [OF bounded_linear_of_real]
   426 
   427 lemmas tendsto_scaleR [tendsto_intros] =
   428   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   429 
   430 lemmas tendsto_mult [tendsto_intros] =
   431   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   432 
   433 lemmas continuous_of_real [continuous_intros] =
   434   bounded_linear.continuous [OF bounded_linear_of_real]
   435 
   436 lemmas continuous_scaleR [continuous_intros] =
   437   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   438 
   439 lemmas continuous_mult [continuous_intros] =
   440   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   441 
   442 lemmas continuous_on_of_real [continuous_on_intros] =
   443   bounded_linear.continuous_on [OF bounded_linear_of_real]
   444 
   445 lemmas continuous_on_scaleR [continuous_on_intros] =
   446   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   447 
   448 lemmas continuous_on_mult [continuous_on_intros] =
   449   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   450 
   451 lemmas tendsto_mult_zero =
   452   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   453 
   454 lemmas tendsto_mult_left_zero =
   455   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   456 
   457 lemmas tendsto_mult_right_zero =
   458   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   459 
   460 lemma tendsto_power [tendsto_intros]:
   461   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   462   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   463   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   464 
   465 lemma continuous_power [continuous_intros]:
   466   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   467   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   468   unfolding continuous_def by (rule tendsto_power)
   469 
   470 lemma continuous_on_power [continuous_on_intros]:
   471   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   472   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   473   unfolding continuous_on_def by (auto intro: tendsto_power)
   474 
   475 lemma tendsto_setprod [tendsto_intros]:
   476   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   477   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   478   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   479 proof (cases "finite S")
   480   assume "finite S" thus ?thesis using assms
   481     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   482 next
   483   assume "\<not> finite S" thus ?thesis
   484     by (simp add: tendsto_const)
   485 qed
   486 
   487 lemma continuous_setprod [continuous_intros]:
   488   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   489   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   490   unfolding continuous_def by (rule tendsto_setprod)
   491 
   492 lemma continuous_on_setprod [continuous_intros]:
   493   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   494   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   495   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   496 
   497 subsubsection {* Inverse and division *}
   498 
   499 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   500   assumes f: "Zfun f F"
   501   assumes g: "Bfun g F"
   502   shows "Zfun (\<lambda>x. f x ** g x) F"
   503 proof -
   504   obtain K where K: "0 \<le> K"
   505     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   506     using nonneg_bounded by fast
   507   obtain B where B: "0 < B"
   508     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   509     using g by (rule BfunE)
   510   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   511   using norm_g proof eventually_elim
   512     case (elim x)
   513     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   514       by (rule norm_le)
   515     also have "\<dots> \<le> norm (f x) * B * K"
   516       by (intro mult_mono' order_refl norm_g norm_ge_zero
   517                 mult_nonneg_nonneg K elim)
   518     also have "\<dots> = norm (f x) * (B * K)"
   519       by (rule mult_assoc)
   520     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   521   qed
   522   with f show ?thesis
   523     by (rule Zfun_imp_Zfun)
   524 qed
   525 
   526 lemma (in bounded_bilinear) flip:
   527   "bounded_bilinear (\<lambda>x y. y ** x)"
   528   apply default
   529   apply (rule add_right)
   530   apply (rule add_left)
   531   apply (rule scaleR_right)
   532   apply (rule scaleR_left)
   533   apply (subst mult_commute)
   534   using bounded by fast
   535 
   536 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   537   assumes f: "Bfun f F"
   538   assumes g: "Zfun g F"
   539   shows "Zfun (\<lambda>x. f x ** g x) F"
   540   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   541 
   542 lemma Bfun_inverse_lemma:
   543   fixes x :: "'a::real_normed_div_algebra"
   544   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   545   apply (subst nonzero_norm_inverse, clarsimp)
   546   apply (erule (1) le_imp_inverse_le)
   547   done
   548 
   549 lemma Bfun_inverse:
   550   fixes a :: "'a::real_normed_div_algebra"
   551   assumes f: "(f ---> a) F"
   552   assumes a: "a \<noteq> 0"
   553   shows "Bfun (\<lambda>x. inverse (f x)) F"
   554 proof -
   555   from a have "0 < norm a" by simp
   556   hence "\<exists>r>0. r < norm a" by (rule dense)
   557   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   558   have "eventually (\<lambda>x. dist (f x) a < r) F"
   559     using tendstoD [OF f r1] by fast
   560   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   561   proof eventually_elim
   562     case (elim x)
   563     hence 1: "norm (f x - a) < r"
   564       by (simp add: dist_norm)
   565     hence 2: "f x \<noteq> 0" using r2 by auto
   566     hence "norm (inverse (f x)) = inverse (norm (f x))"
   567       by (rule nonzero_norm_inverse)
   568     also have "\<dots> \<le> inverse (norm a - r)"
   569     proof (rule le_imp_inverse_le)
   570       show "0 < norm a - r" using r2 by simp
   571     next
   572       have "norm a - norm (f x) \<le> norm (a - f x)"
   573         by (rule norm_triangle_ineq2)
   574       also have "\<dots> = norm (f x - a)"
   575         by (rule norm_minus_commute)
   576       also have "\<dots> < r" using 1 .
   577       finally show "norm a - r \<le> norm (f x)" by simp
   578     qed
   579     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   580   qed
   581   thus ?thesis by (rule BfunI)
   582 qed
   583 
   584 lemma tendsto_inverse [tendsto_intros]:
   585   fixes a :: "'a::real_normed_div_algebra"
   586   assumes f: "(f ---> a) F"
   587   assumes a: "a \<noteq> 0"
   588   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   589 proof -
   590   from a have "0 < norm a" by simp
   591   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   592     by (rule tendstoD)
   593   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   594     unfolding dist_norm by (auto elim!: eventually_elim1)
   595   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   596     - (inverse (f x) * (f x - a) * inverse a)) F"
   597     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   598   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   599     by (intro Zfun_minus Zfun_mult_left
   600       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   601       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   602   ultimately show ?thesis
   603     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   604 qed
   605 
   606 lemma continuous_inverse:
   607   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   608   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   609   shows "continuous F (\<lambda>x. inverse (f x))"
   610   using assms unfolding continuous_def by (rule tendsto_inverse)
   611 
   612 lemma continuous_at_within_inverse[continuous_intros]:
   613   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   614   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   615   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   616   using assms unfolding continuous_within by (rule tendsto_inverse)
   617 
   618 lemma isCont_inverse[continuous_intros, simp]:
   619   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   620   assumes "isCont f a" and "f a \<noteq> 0"
   621   shows "isCont (\<lambda>x. inverse (f x)) a"
   622   using assms unfolding continuous_at by (rule tendsto_inverse)
   623 
   624 lemma continuous_on_inverse[continuous_on_intros]:
   625   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   626   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   627   shows "continuous_on s (\<lambda>x. inverse (f x))"
   628   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   629 
   630 lemma tendsto_divide [tendsto_intros]:
   631   fixes a b :: "'a::real_normed_field"
   632   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   633     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   634   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   635 
   636 lemma continuous_divide:
   637   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   638   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   639   shows "continuous F (\<lambda>x. (f x) / (g x))"
   640   using assms unfolding continuous_def by (rule tendsto_divide)
   641 
   642 lemma continuous_at_within_divide[continuous_intros]:
   643   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   644   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   645   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   646   using assms unfolding continuous_within by (rule tendsto_divide)
   647 
   648 lemma isCont_divide[continuous_intros, simp]:
   649   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   650   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   651   shows "isCont (\<lambda>x. (f x) / g x) a"
   652   using assms unfolding continuous_at by (rule tendsto_divide)
   653 
   654 lemma continuous_on_divide[continuous_on_intros]:
   655   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   656   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   657   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   658   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   659 
   660 lemma tendsto_sgn [tendsto_intros]:
   661   fixes l :: "'a::real_normed_vector"
   662   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   663   unfolding sgn_div_norm by (simp add: tendsto_intros)
   664 
   665 lemma continuous_sgn:
   666   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   667   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   668   shows "continuous F (\<lambda>x. sgn (f x))"
   669   using assms unfolding continuous_def by (rule tendsto_sgn)
   670 
   671 lemma continuous_at_within_sgn[continuous_intros]:
   672   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   673   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   674   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   675   using assms unfolding continuous_within by (rule tendsto_sgn)
   676 
   677 lemma isCont_sgn[continuous_intros]:
   678   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   679   assumes "isCont f a" and "f a \<noteq> 0"
   680   shows "isCont (\<lambda>x. sgn (f x)) a"
   681   using assms unfolding continuous_at by (rule tendsto_sgn)
   682 
   683 lemma continuous_on_sgn[continuous_on_intros]:
   684   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   685   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   686   shows "continuous_on s (\<lambda>x. sgn (f x))"
   687   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   688 
   689 lemma filterlim_at_infinity:
   690   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   691   assumes "0 \<le> c"
   692   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   693   unfolding filterlim_iff eventually_at_infinity
   694 proof safe
   695   fix P :: "'a \<Rightarrow> bool" and b
   696   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   697     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   698   have "max b (c + 1) > c" by auto
   699   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   700     by auto
   701   then show "eventually (\<lambda>x. P (f x)) F"
   702   proof eventually_elim
   703     fix x assume "max b (c + 1) \<le> norm (f x)"
   704     with P show "P (f x)" by auto
   705   qed
   706 qed force
   707 
   708 
   709 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   710 
   711 text {*
   712 
   713 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   714 @{term "at_right x"} and also @{term "at_right 0"}.
   715 
   716 *}
   717 
   718 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   719 
   720 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::real)"
   721   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
   722   by (intro allI ex_cong) (auto simp: dist_real_def field_simps)
   723 
   724 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::real)"
   725   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
   726   apply (intro allI ex_cong)
   727   apply (auto simp: dist_real_def field_simps)
   728   apply (erule_tac x="-x" in allE)
   729   apply simp
   730   done
   731 
   732 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::real)"
   733   unfolding at_def filtermap_nhds_shift[symmetric]
   734   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   735 
   736 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   737   unfolding filtermap_at_shift[symmetric]
   738   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   739 
   740 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   741   using filtermap_at_right_shift[of "-a" 0] by simp
   742 
   743 lemma filterlim_at_right_to_0:
   744   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   745   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   746 
   747 lemma eventually_at_right_to_0:
   748   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   749   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   750 
   751 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::real)"
   752   unfolding at_def filtermap_nhds_minus[symmetric]
   753   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   754 
   755 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   756   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
   757 
   758 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   759   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
   760 
   761 lemma filterlim_at_left_to_right:
   762   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   763   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   764 
   765 lemma eventually_at_left_to_right:
   766   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   767   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   768 
   769 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   770   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   771   by (metis le_minus_iff minus_minus)
   772 
   773 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   774   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   775 
   776 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   777   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   778 
   779 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   780   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   781 
   782 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   783   unfolding filterlim_at_top eventually_at_bot_dense
   784   by (metis leI minus_less_iff order_less_asym)
   785 
   786 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   787   unfolding filterlim_at_bot eventually_at_top_dense
   788   by (metis leI less_minus_iff order_less_asym)
   789 
   790 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   791   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   792   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   793   by auto
   794 
   795 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   796   unfolding filterlim_uminus_at_top by simp
   797 
   798 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   799   unfolding filterlim_at_top_gt[where c=0] eventually_within at_def
   800 proof safe
   801   fix Z :: real assume [arith]: "0 < Z"
   802   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   803     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
   804   then show "eventually (\<lambda>x. x \<in> - {0} \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
   805     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
   806 qed
   807 
   808 lemma filterlim_inverse_at_top:
   809   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
   810   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
   811      (simp add: filterlim_def eventually_filtermap le_within_iff at_def eventually_elim1)
   812 
   813 lemma filterlim_inverse_at_bot_neg:
   814   "LIM x (at_left (0::real)). inverse x :> at_bot"
   815   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
   816 
   817 lemma filterlim_inverse_at_bot:
   818   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
   819   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
   820   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
   821 
   822 lemma tendsto_inverse_0:
   823   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
   824   shows "(inverse ---> (0::'a)) at_infinity"
   825   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
   826 proof safe
   827   fix r :: real assume "0 < r"
   828   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
   829   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
   830     fix x :: 'a
   831     from `0 < r` have "0 < inverse (r / 2)" by simp
   832     also assume *: "inverse (r / 2) \<le> norm x"
   833     finally show "norm (inverse x) < r"
   834       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
   835   qed
   836 qed
   837 
   838 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
   839 proof (rule antisym)
   840   have "(inverse ---> (0::real)) at_top"
   841     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
   842   then show "filtermap inverse at_top \<le> at_right (0::real)"
   843     unfolding at_within_eq
   844     by (intro le_withinI) (simp_all add: eventually_filtermap eventually_gt_at_top filterlim_def)
   845 next
   846   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
   847     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
   848   then show "at_right (0::real) \<le> filtermap inverse at_top"
   849     by (simp add: filtermap_ident filtermap_filtermap)
   850 qed
   851 
   852 lemma eventually_at_right_to_top:
   853   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
   854   unfolding at_right_to_top eventually_filtermap ..
   855 
   856 lemma filterlim_at_right_to_top:
   857   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
   858   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
   859 
   860 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
   861   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
   862 
   863 lemma eventually_at_top_to_right:
   864   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
   865   unfolding at_top_to_right eventually_filtermap ..
   866 
   867 lemma filterlim_at_top_to_right:
   868   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
   869   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
   870 
   871 lemma filterlim_inverse_at_infinity:
   872   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   873   shows "filterlim inverse at_infinity (at (0::'a))"
   874   unfolding filterlim_at_infinity[OF order_refl]
   875 proof safe
   876   fix r :: real assume "0 < r"
   877   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
   878     unfolding eventually_at norm_inverse
   879     by (intro exI[of _ "inverse r"])
   880        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
   881 qed
   882 
   883 lemma filterlim_inverse_at_iff:
   884   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   885   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
   886   unfolding filterlim_def filtermap_filtermap[symmetric]
   887 proof
   888   assume "filtermap g F \<le> at_infinity"
   889   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
   890     by (rule filtermap_mono)
   891   also have "\<dots> \<le> at 0"
   892     using tendsto_inverse_0
   893     by (auto intro!: le_withinI exI[of _ 1]
   894              simp: eventually_filtermap eventually_at_infinity filterlim_def at_def)
   895   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
   896 next
   897   assume "filtermap inverse (filtermap g F) \<le> at 0"
   898   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
   899     by (rule filtermap_mono)
   900   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
   901     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
   902 qed
   903 
   904 lemma tendsto_inverse_0_at_top:
   905   "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
   906  by (metis at_top_le_at_infinity filterlim_at filterlim_inverse_at_iff filterlim_mono order_refl)
   907 
   908 text {*
   909 
   910 We only show rules for multiplication and addition when the functions are either against a real
   911 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
   912 
   913 *}
   914 
   915 lemma filterlim_tendsto_pos_mult_at_top: 
   916   assumes f: "(f ---> c) F" and c: "0 < c"
   917   assumes g: "LIM x F. g x :> at_top"
   918   shows "LIM x F. (f x * g x :: real) :> at_top"
   919   unfolding filterlim_at_top_gt[where c=0]
   920 proof safe
   921   fix Z :: real assume "0 < Z"
   922   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
   923     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
   924              simp: dist_real_def abs_real_def split: split_if_asm)
   925   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
   926     unfolding filterlim_at_top by auto
   927   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
   928   proof eventually_elim
   929     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
   930     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
   931       by (intro mult_mono) (auto simp: zero_le_divide_iff)
   932     with `0 < c` show "Z \<le> f x * g x"
   933        by simp
   934   qed
   935 qed
   936 
   937 lemma filterlim_at_top_mult_at_top: 
   938   assumes f: "LIM x F. f x :> at_top"
   939   assumes g: "LIM x F. g x :> at_top"
   940   shows "LIM x F. (f x * g x :: real) :> at_top"
   941   unfolding filterlim_at_top_gt[where c=0]
   942 proof safe
   943   fix Z :: real assume "0 < Z"
   944   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
   945     unfolding filterlim_at_top by auto
   946   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
   947     unfolding filterlim_at_top by auto
   948   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
   949   proof eventually_elim
   950     fix x assume "1 \<le> f x" "Z \<le> g x"
   951     with `0 < Z` have "1 * Z \<le> f x * g x"
   952       by (intro mult_mono) (auto simp: zero_le_divide_iff)
   953     then show "Z \<le> f x * g x"
   954        by simp
   955   qed
   956 qed
   957 
   958 lemma filterlim_tendsto_pos_mult_at_bot:
   959   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
   960   shows "LIM x F. f x * g x :> at_bot"
   961   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
   962   unfolding filterlim_uminus_at_bot by simp
   963 
   964 lemma filterlim_tendsto_add_at_top: 
   965   assumes f: "(f ---> c) F"
   966   assumes g: "LIM x F. g x :> at_top"
   967   shows "LIM x F. (f x + g x :: real) :> at_top"
   968   unfolding filterlim_at_top_gt[where c=0]
   969 proof safe
   970   fix Z :: real assume "0 < Z"
   971   from f have "eventually (\<lambda>x. c - 1 < f x) F"
   972     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
   973   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
   974     unfolding filterlim_at_top by auto
   975   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
   976     by eventually_elim simp
   977 qed
   978 
   979 lemma LIM_at_top_divide:
   980   fixes f g :: "'a \<Rightarrow> real"
   981   assumes f: "(f ---> a) F" "0 < a"
   982   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
   983   shows "LIM x F. f x / g x :> at_top"
   984   unfolding divide_inverse
   985   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
   986 
   987 lemma filterlim_at_top_add_at_top: 
   988   assumes f: "LIM x F. f x :> at_top"
   989   assumes g: "LIM x F. g x :> at_top"
   990   shows "LIM x F. (f x + g x :: real) :> at_top"
   991   unfolding filterlim_at_top_gt[where c=0]
   992 proof safe
   993   fix Z :: real assume "0 < Z"
   994   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
   995     unfolding filterlim_at_top by auto
   996   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
   997     unfolding filterlim_at_top by auto
   998   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
   999     by eventually_elim simp
  1000 qed
  1001 
  1002 lemma tendsto_divide_0:
  1003   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1004   assumes f: "(f ---> c) F"
  1005   assumes g: "LIM x F. g x :> at_infinity"
  1006   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1007   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1008 
  1009 lemma linear_plus_1_le_power:
  1010   fixes x :: real
  1011   assumes x: "0 \<le> x"
  1012   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1013 proof (induct n)
  1014   case (Suc n)
  1015   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1016     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1017   also have "\<dots> \<le> (x + 1)^Suc n"
  1018     using Suc x by (simp add: mult_left_mono)
  1019   finally show ?case .
  1020 qed simp
  1021 
  1022 lemma filterlim_realpow_sequentially_gt1:
  1023   fixes x :: "'a :: real_normed_div_algebra"
  1024   assumes x[arith]: "1 < norm x"
  1025   shows "LIM n sequentially. x ^ n :> at_infinity"
  1026 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1027   fix y :: real assume "0 < y"
  1028   have "0 < norm x - 1" by simp
  1029   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1030   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1031   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1032   also have "\<dots> = norm x ^ N" by simp
  1033   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1034     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1035   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1036     unfolding eventually_sequentially
  1037     by (auto simp: norm_power)
  1038 qed simp
  1039 
  1040 
  1041 subsection {* Limits of Sequences *}
  1042 
  1043 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1044   by simp
  1045 
  1046 lemma LIMSEQ_iff:
  1047   fixes L :: "'a::real_normed_vector"
  1048   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1049 unfolding LIMSEQ_def dist_norm ..
  1050 
  1051 lemma LIMSEQ_I:
  1052   fixes L :: "'a::real_normed_vector"
  1053   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1054 by (simp add: LIMSEQ_iff)
  1055 
  1056 lemma LIMSEQ_D:
  1057   fixes L :: "'a::real_normed_vector"
  1058   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1059 by (simp add: LIMSEQ_iff)
  1060 
  1061 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1062   unfolding tendsto_def eventually_sequentially
  1063   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
  1064 
  1065 lemma Bseq_inverse_lemma:
  1066   fixes x :: "'a::real_normed_div_algebra"
  1067   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1068 apply (subst nonzero_norm_inverse, clarsimp)
  1069 apply (erule (1) le_imp_inverse_le)
  1070 done
  1071 
  1072 lemma Bseq_inverse:
  1073   fixes a :: "'a::real_normed_div_algebra"
  1074   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1075   by (rule Bfun_inverse)
  1076 
  1077 lemma LIMSEQ_diff_approach_zero:
  1078   fixes L :: "'a::real_normed_vector"
  1079   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
  1080   by (drule (1) tendsto_add, simp)
  1081 
  1082 lemma LIMSEQ_diff_approach_zero2:
  1083   fixes L :: "'a::real_normed_vector"
  1084   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
  1085   by (drule (1) tendsto_diff, simp)
  1086 
  1087 text{*An unbounded sequence's inverse tends to 0*}
  1088 
  1089 lemma LIMSEQ_inverse_zero:
  1090   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1091   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1092   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1093   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1094   done
  1095 
  1096 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
  1097 
  1098 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1099   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1100             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1101 
  1102 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1103 infinity is now easily proved*}
  1104 
  1105 lemma LIMSEQ_inverse_real_of_nat_add:
  1106      "(%n. r + inverse(real(Suc n))) ----> r"
  1107   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1108 
  1109 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1110      "(%n. r + -inverse(real(Suc n))) ----> r"
  1111   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1112   by auto
  1113 
  1114 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1115      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1116   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1117   by auto
  1118 
  1119 subsection {* Convergence on sequences *}
  1120 
  1121 lemma convergent_add:
  1122   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1123   assumes "convergent (\<lambda>n. X n)"
  1124   assumes "convergent (\<lambda>n. Y n)"
  1125   shows "convergent (\<lambda>n. X n + Y n)"
  1126   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1127 
  1128 lemma convergent_setsum:
  1129   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1130   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1131   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1132 proof (cases "finite A")
  1133   case True from this and assms show ?thesis
  1134     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1135 qed (simp add: convergent_const)
  1136 
  1137 lemma (in bounded_linear) convergent:
  1138   assumes "convergent (\<lambda>n. X n)"
  1139   shows "convergent (\<lambda>n. f (X n))"
  1140   using assms unfolding convergent_def by (fast intro: tendsto)
  1141 
  1142 lemma (in bounded_bilinear) convergent:
  1143   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1144   shows "convergent (\<lambda>n. X n ** Y n)"
  1145   using assms unfolding convergent_def by (fast intro: tendsto)
  1146 
  1147 lemma convergent_minus_iff:
  1148   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1149   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1150 apply (simp add: convergent_def)
  1151 apply (auto dest: tendsto_minus)
  1152 apply (drule tendsto_minus, auto)
  1153 done
  1154 
  1155 subsection {* Bounded Monotonic Sequences *}
  1156 
  1157 subsubsection {* Bounded Sequences *}
  1158 
  1159 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
  1160   by (intro BfunI) (auto simp: eventually_sequentially)
  1161 
  1162 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
  1163   by (intro BfunI) (auto simp: eventually_sequentially)
  1164 
  1165 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
  1166   unfolding Bfun_def eventually_sequentially
  1167 proof safe
  1168   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
  1169   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
  1170     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] min_max.less_supI2)
  1171        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
  1172 qed auto
  1173 
  1174 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
  1175 unfolding Bseq_def by auto
  1176 
  1177 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
  1178 by (simp add: Bseq_def)
  1179 
  1180 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
  1181 by (auto simp add: Bseq_def)
  1182 
  1183 lemma lemma_NBseq_def:
  1184   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
  1185 proof safe
  1186   fix K :: real
  1187   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
  1188   then have "K \<le> real (Suc n)" by auto
  1189   moreover assume "\<forall>m. norm (X m) \<le> K"
  1190   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
  1191     by (blast intro: order_trans)
  1192   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
  1193 qed (force simp add: real_of_nat_Suc)
  1194 
  1195 text{* alternative definition for Bseq *}
  1196 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
  1197 apply (simp add: Bseq_def)
  1198 apply (simp (no_asm) add: lemma_NBseq_def)
  1199 done
  1200 
  1201 lemma lemma_NBseq_def2:
  1202      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
  1203 apply (subst lemma_NBseq_def, auto)
  1204 apply (rule_tac x = "Suc N" in exI)
  1205 apply (rule_tac [2] x = N in exI)
  1206 apply (auto simp add: real_of_nat_Suc)
  1207  prefer 2 apply (blast intro: order_less_imp_le)
  1208 apply (drule_tac x = n in spec, simp)
  1209 done
  1210 
  1211 (* yet another definition for Bseq *)
  1212 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
  1213 by (simp add: Bseq_def lemma_NBseq_def2)
  1214 
  1215 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
  1216 
  1217 text{*alternative formulation for boundedness*}
  1218 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
  1219 apply (unfold Bseq_def, safe)
  1220 apply (rule_tac [2] x = "k + norm x" in exI)
  1221 apply (rule_tac x = K in exI, simp)
  1222 apply (rule exI [where x = 0], auto)
  1223 apply (erule order_less_le_trans, simp)
  1224 apply (drule_tac x=n in spec, fold diff_minus)
  1225 apply (drule order_trans [OF norm_triangle_ineq2])
  1226 apply simp
  1227 done
  1228 
  1229 text{*alternative formulation for boundedness*}
  1230 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
  1231 apply safe
  1232 apply (simp add: Bseq_def, safe)
  1233 apply (rule_tac x = "K + norm (X N)" in exI)
  1234 apply auto
  1235 apply (erule order_less_le_trans, simp)
  1236 apply (rule_tac x = N in exI, safe)
  1237 apply (drule_tac x = n in spec)
  1238 apply (rule order_trans [OF norm_triangle_ineq], simp)
  1239 apply (auto simp add: Bseq_iff2)
  1240 done
  1241 
  1242 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
  1243 apply (simp add: Bseq_def)
  1244 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
  1245 apply (drule_tac x = n in spec, arith)
  1246 done
  1247 
  1248 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
  1249 
  1250 lemma Bseq_isUb:
  1251   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
  1252 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
  1253 
  1254 text{* Use completeness of reals (supremum property)
  1255    to show that any bounded sequence has a least upper bound*}
  1256 
  1257 lemma Bseq_isLub:
  1258   "!!(X::nat=>real). Bseq X ==>
  1259    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
  1260 by (blast intro: reals_complete Bseq_isUb)
  1261 
  1262 subsubsection{*A Bounded and Monotonic Sequence Converges*}
  1263 
  1264 (* TODO: delete *)
  1265 (* FIXME: one use in NSA/HSEQ.thy *)
  1266 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
  1267   apply (rule_tac x="X m" in exI)
  1268   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
  1269   unfolding eventually_sequentially
  1270   apply blast
  1271   done
  1272 
  1273 text {* A monotone sequence converges to its least upper bound. *}
  1274 
  1275 lemma isLub_mono_imp_LIMSEQ:
  1276   fixes X :: "nat \<Rightarrow> real"
  1277   assumes u: "isLub UNIV {x. \<exists>n. X n = x} u" (* FIXME: use 'range X' *)
  1278   assumes X: "\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n"
  1279   shows "X ----> u"
  1280 proof (rule LIMSEQ_I)
  1281   have 1: "\<forall>n. X n \<le> u"
  1282     using isLubD2 [OF u] by auto
  1283   have "\<forall>y. (\<forall>n. X n \<le> y) \<longrightarrow> u \<le> y"
  1284     using isLub_le_isUb [OF u] by (auto simp add: isUb_def setle_def)
  1285   hence 2: "\<forall>y<u. \<exists>n. y < X n"
  1286     by (metis not_le)
  1287   fix r :: real assume "0 < r"
  1288   hence "u - r < u" by simp
  1289   hence "\<exists>m. u - r < X m" using 2 by simp
  1290   then obtain m where "u - r < X m" ..
  1291   with X have "\<forall>n\<ge>m. u - r < X n"
  1292     by (fast intro: less_le_trans)
  1293   hence "\<exists>m. \<forall>n\<ge>m. u - r < X n" ..
  1294   thus "\<exists>m. \<forall>n\<ge>m. norm (X n - u) < r"
  1295     using 1 by (simp add: diff_less_eq add_commute)
  1296 qed
  1297 
  1298 text{*A standard proof of the theorem for monotone increasing sequence*}
  1299 
  1300 lemma Bseq_mono_convergent:
  1301    "Bseq X \<Longrightarrow> \<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> convergent (X::nat=>real)"
  1302   by (metis Bseq_isLub isLub_mono_imp_LIMSEQ convergentI)
  1303 
  1304 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
  1305   by (simp add: Bseq_def)
  1306 
  1307 text{*Main monotonicity theorem*}
  1308 
  1309 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1310   by (metis monoseq_iff incseq_def decseq_eq_incseq convergent_minus_iff Bseq_minus_iff
  1311             Bseq_mono_convergent)
  1312 
  1313 lemma Cauchy_iff:
  1314   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1315   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1316   unfolding Cauchy_def dist_norm ..
  1317 
  1318 lemma CauchyI:
  1319   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1320   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1321 by (simp add: Cauchy_iff)
  1322 
  1323 lemma CauchyD:
  1324   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1325   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1326 by (simp add: Cauchy_iff)
  1327 
  1328 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
  1329   apply (simp add: subset_eq)
  1330   apply (rule BseqI'[where K="max (norm a) (norm b)"])
  1331   apply (erule_tac x=n in allE)
  1332   apply auto
  1333   done
  1334 
  1335 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
  1336   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
  1337 
  1338 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
  1339   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
  1340 
  1341 lemma incseq_convergent:
  1342   fixes X :: "nat \<Rightarrow> real"
  1343   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1344   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1345 proof atomize_elim
  1346   from incseq_bounded[OF assms] `incseq X` Bseq_monoseq_convergent[of X]
  1347   obtain L where "X ----> L"
  1348     by (auto simp: convergent_def monoseq_def incseq_def)
  1349   with `incseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1350     by (auto intro!: exI[of _ L] incseq_le)
  1351 qed
  1352 
  1353 lemma decseq_convergent:
  1354   fixes X :: "nat \<Rightarrow> real"
  1355   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1356   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1357 proof atomize_elim
  1358   from decseq_bounded[OF assms] `decseq X` Bseq_monoseq_convergent[of X]
  1359   obtain L where "X ----> L"
  1360     by (auto simp: convergent_def monoseq_def decseq_def)
  1361   with `decseq X` show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1362     by (auto intro!: exI[of _ L] decseq_le)
  1363 qed
  1364 
  1365 subsubsection {* Cauchy Sequences are Bounded *}
  1366 
  1367 text{*A Cauchy sequence is bounded -- this is the standard
  1368   proof mechanization rather than the nonstandard proof*}
  1369 
  1370 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1371           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1372 apply (clarify, drule spec, drule (1) mp)
  1373 apply (simp only: norm_minus_commute)
  1374 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1375 apply simp
  1376 done
  1377 
  1378 class banach = real_normed_vector + complete_space
  1379 
  1380 instance real :: banach by default
  1381 
  1382 subsection {* Power Sequences *}
  1383 
  1384 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1385 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1386   also fact that bounded and monotonic sequence converges.*}
  1387 
  1388 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1389 apply (simp add: Bseq_def)
  1390 apply (rule_tac x = 1 in exI)
  1391 apply (simp add: power_abs)
  1392 apply (auto dest: power_mono)
  1393 done
  1394 
  1395 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1396 apply (clarify intro!: mono_SucI2)
  1397 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1398 done
  1399 
  1400 lemma convergent_realpow:
  1401   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1402 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1403 
  1404 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1405   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1406 
  1407 lemma LIMSEQ_realpow_zero:
  1408   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1409 proof cases
  1410   assume "0 \<le> x" and "x \<noteq> 0"
  1411   hence x0: "0 < x" by simp
  1412   assume x1: "x < 1"
  1413   from x0 x1 have "1 < inverse x"
  1414     by (rule one_less_inverse)
  1415   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1416     by (rule LIMSEQ_inverse_realpow_zero)
  1417   thus ?thesis by (simp add: power_inverse)
  1418 qed (rule LIMSEQ_imp_Suc, simp add: tendsto_const)
  1419 
  1420 lemma LIMSEQ_power_zero:
  1421   fixes x :: "'a::{real_normed_algebra_1}"
  1422   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1423 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1424 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1425 apply (simp add: power_abs norm_power_ineq)
  1426 done
  1427 
  1428 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1429   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1430 
  1431 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1432 
  1433 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1434   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1435 
  1436 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1437   by (rule LIMSEQ_power_zero) simp
  1438 
  1439 
  1440 subsection {* Limits of Functions *}
  1441 
  1442 lemma LIM_eq:
  1443   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1444   shows "f -- a --> L =
  1445      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1446 by (simp add: LIM_def dist_norm)
  1447 
  1448 lemma LIM_I:
  1449   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1450   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1451       ==> f -- a --> L"
  1452 by (simp add: LIM_eq)
  1453 
  1454 lemma LIM_D:
  1455   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1456   shows "[| f -- a --> L; 0<r |]
  1457       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1458 by (simp add: LIM_eq)
  1459 
  1460 lemma LIM_offset:
  1461   fixes a :: "'a::real_normed_vector"
  1462   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1463 apply (rule topological_tendstoI)
  1464 apply (drule (2) topological_tendstoD)
  1465 apply (simp only: eventually_at dist_norm)
  1466 apply (clarify, rule_tac x=d in exI, safe)
  1467 apply (drule_tac x="x + k" in spec)
  1468 apply (simp add: algebra_simps)
  1469 done
  1470 
  1471 lemma LIM_offset_zero:
  1472   fixes a :: "'a::real_normed_vector"
  1473   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1474 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
  1475 
  1476 lemma LIM_offset_zero_cancel:
  1477   fixes a :: "'a::real_normed_vector"
  1478   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1479 by (drule_tac k="- a" in LIM_offset, simp)
  1480 
  1481 lemma LIM_zero:
  1482   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1483   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1484 unfolding tendsto_iff dist_norm by simp
  1485 
  1486 lemma LIM_zero_cancel:
  1487   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1488   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1489 unfolding tendsto_iff dist_norm by simp
  1490 
  1491 lemma LIM_zero_iff:
  1492   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1493   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1494 unfolding tendsto_iff dist_norm by simp
  1495 
  1496 lemma LIM_imp_LIM:
  1497   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1498   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1499   assumes f: "f -- a --> l"
  1500   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1501   shows "g -- a --> m"
  1502   by (rule metric_LIM_imp_LIM [OF f],
  1503     simp add: dist_norm le)
  1504 
  1505 lemma LIM_equal2:
  1506   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1507   assumes 1: "0 < R"
  1508   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1509   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1510 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1511 
  1512 lemma LIM_compose2:
  1513   fixes a :: "'a::real_normed_vector"
  1514   assumes f: "f -- a --> b"
  1515   assumes g: "g -- b --> c"
  1516   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1517   shows "(\<lambda>x. g (f x)) -- a --> c"
  1518 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1519 
  1520 lemma real_LIM_sandwich_zero:
  1521   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1522   assumes f: "f -- a --> 0"
  1523   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1524   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1525   shows "g -- a --> 0"
  1526 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1527   fix x assume x: "x \<noteq> a"
  1528   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1529   also have "g x \<le> f x" by (rule 2 [OF x])
  1530   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1531   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1532   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1533 qed
  1534 
  1535 
  1536 subsection {* Continuity *}
  1537 
  1538 lemma LIM_isCont_iff:
  1539   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1540   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1541 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1542 
  1543 lemma isCont_iff:
  1544   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1545   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1546 by (simp add: isCont_def LIM_isCont_iff)
  1547 
  1548 lemma isCont_LIM_compose2:
  1549   fixes a :: "'a::real_normed_vector"
  1550   assumes f [unfolded isCont_def]: "isCont f a"
  1551   assumes g: "g -- f a --> l"
  1552   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1553   shows "(\<lambda>x. g (f x)) -- a --> l"
  1554 by (rule LIM_compose2 [OF f g inj])
  1555 
  1556 
  1557 lemma isCont_norm [simp]:
  1558   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1559   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1560   by (fact continuous_norm)
  1561 
  1562 lemma isCont_rabs [simp]:
  1563   fixes f :: "'a::t2_space \<Rightarrow> real"
  1564   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1565   by (fact continuous_rabs)
  1566 
  1567 lemma isCont_add [simp]:
  1568   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1569   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1570   by (fact continuous_add)
  1571 
  1572 lemma isCont_minus [simp]:
  1573   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1574   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1575   by (fact continuous_minus)
  1576 
  1577 lemma isCont_diff [simp]:
  1578   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1579   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1580   by (fact continuous_diff)
  1581 
  1582 lemma isCont_mult [simp]:
  1583   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1584   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1585   by (fact continuous_mult)
  1586 
  1587 lemma (in bounded_linear) isCont:
  1588   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1589   by (fact continuous)
  1590 
  1591 lemma (in bounded_bilinear) isCont:
  1592   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1593   by (fact continuous)
  1594 
  1595 lemmas isCont_scaleR [simp] = 
  1596   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1597 
  1598 lemmas isCont_of_real [simp] =
  1599   bounded_linear.isCont [OF bounded_linear_of_real]
  1600 
  1601 lemma isCont_power [simp]:
  1602   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1603   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1604   by (fact continuous_power)
  1605 
  1606 lemma isCont_setsum [simp]:
  1607   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1608   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1609   by (auto intro: continuous_setsum)
  1610 
  1611 lemmas isCont_intros =
  1612   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
  1613   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
  1614   isCont_of_real isCont_power isCont_sgn isCont_setsum
  1615 
  1616 subsection {* Uniform Continuity *}
  1617 
  1618 lemma (in bounded_linear) isUCont: "isUCont f"
  1619 unfolding isUCont_def dist_norm
  1620 proof (intro allI impI)
  1621   fix r::real assume r: "0 < r"
  1622   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1623     using pos_bounded by fast
  1624   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1625   proof (rule exI, safe)
  1626     from r K show "0 < r / K" by (rule divide_pos_pos)
  1627   next
  1628     fix x y :: 'a
  1629     assume xy: "norm (x - y) < r / K"
  1630     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1631     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1632     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1633     finally show "norm (f x - f y) < r" .
  1634   qed
  1635 qed
  1636 
  1637 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1638 by (rule isUCont [THEN isUCont_Cauchy])
  1639 
  1640 
  1641 lemma LIM_less_bound: 
  1642   fixes f :: "real \<Rightarrow> real"
  1643   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1644   shows "0 \<le> f x"
  1645 proof (rule tendsto_le_const)
  1646   show "(f ---> f x) (at_left x)"
  1647     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
  1648   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1649     using ev by (auto simp: eventually_within_less dist_real_def intro!: exI[of _ "x - b"])
  1650 qed simp
  1651 
  1652 
  1653 subsection {* Nested Intervals and Bisection -- Needed for Compactness *}
  1654 
  1655 lemma nested_sequence_unique:
  1656   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1657   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1658 proof -
  1659   have "incseq f" unfolding incseq_Suc_iff by fact
  1660   have "decseq g" unfolding decseq_Suc_iff by fact
  1661 
  1662   { fix n
  1663     from `decseq g` have "g n \<le> g 0" by (rule decseqD) simp
  1664     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f n \<le> g 0" by auto }
  1665   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1666     using incseq_convergent[OF `incseq f`] by auto
  1667   moreover
  1668   { fix n
  1669     from `incseq f` have "f 0 \<le> f n" by (rule incseqD) simp
  1670     with `\<forall>n. f n \<le> g n`[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1671   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1672     using decseq_convergent[OF `decseq g`] by auto
  1673   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF `f ----> u` `g ----> l`]]
  1674   ultimately show ?thesis by auto
  1675 qed
  1676 
  1677 lemma Bolzano[consumes 1, case_names trans local]:
  1678   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1679   assumes [arith]: "a \<le> b"
  1680   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1681   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1682   shows "P a b"
  1683 proof -
  1684   def bisect \<equiv> "nat_rec (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1685   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1686   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1687     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1688     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1689 
  1690   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1691 
  1692   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1693   proof (safe intro!: nested_sequence_unique)
  1694     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1695   next
  1696     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1697     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1698   qed fact
  1699   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1700   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1701     using `l 0 \<le> x` `x \<le> u 0` local[of x] by auto
  1702 
  1703   show "P a b"
  1704   proof (rule ccontr)
  1705     assume "\<not> P a b" 
  1706     { fix n have "\<not> P (l n) (u n)"
  1707       proof (induct n)
  1708         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1709       qed (simp add: `\<not> P a b`) }
  1710     moreover
  1711     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1712         using `0 < d` `l ----> x` by (intro order_tendstoD[of _ x]) auto
  1713       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1714         using `0 < d` `u ----> x` by (intro order_tendstoD[of _ x]) auto
  1715       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1716       proof eventually_elim
  1717         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1718         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1719         with x show "P (l n) (u n)" by (rule d)
  1720       qed }
  1721     ultimately show False by simp
  1722   qed
  1723 qed
  1724 
  1725 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1726 proof (cases "a \<le> b", rule compactI)
  1727   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1728   def T == "{a .. b}"
  1729   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1730   proof (induct rule: Bolzano)
  1731     case (trans a b c)
  1732     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1733     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1734       by (auto simp: *)
  1735     with trans show ?case
  1736       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1737   next
  1738     case (local x)
  1739     then have "x \<in> \<Union>C" using C by auto
  1740     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1741     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1742       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1743     with `c \<in> C` show ?case
  1744       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1745   qed
  1746 qed simp
  1747 
  1748 
  1749 subsection {* Boundedness of continuous functions *}
  1750 
  1751 text{*By bisection, function continuous on closed interval is bounded above*}
  1752 
  1753 lemma isCont_eq_Ub:
  1754   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1755   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1756     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1757   using continuous_attains_sup[of "{a .. b}" f]
  1758   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1759 
  1760 lemma isCont_eq_Lb:
  1761   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1762   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1763     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1764   using continuous_attains_inf[of "{a .. b}" f]
  1765   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1766 
  1767 lemma isCont_bounded:
  1768   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1769   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1770   using isCont_eq_Ub[of a b f] by auto
  1771 
  1772 lemma isCont_has_Ub:
  1773   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1774   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1775     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1776   using isCont_eq_Ub[of a b f] by auto
  1777 
  1778 (*HOL style here: object-level formulations*)
  1779 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1780       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1781       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1782   by (blast intro: IVT)
  1783 
  1784 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1785       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1786       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1787   by (blast intro: IVT2)
  1788 
  1789 lemma isCont_Lb_Ub:
  1790   fixes f :: "real \<Rightarrow> real"
  1791   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1792   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and> 
  1793                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  1794 proof -
  1795   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  1796     using isCont_eq_Ub[OF assms] by auto
  1797   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  1798     using isCont_eq_Lb[OF assms] by auto
  1799   show ?thesis
  1800     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  1801     apply (rule_tac x="f L" in exI)
  1802     apply (rule_tac x="f M" in exI)
  1803     apply (cases "L \<le> M")
  1804     apply (simp, metis order_trans)
  1805     apply (simp, metis order_trans)
  1806     done
  1807 qed
  1808 
  1809 
  1810 text{*Continuity of inverse function*}
  1811 
  1812 lemma isCont_inverse_function:
  1813   fixes f g :: "real \<Rightarrow> real"
  1814   assumes d: "0 < d"
  1815       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  1816       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  1817   shows "isCont g (f x)"
  1818 proof -
  1819   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  1820 
  1821   have f: "continuous_on ?D f"
  1822     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  1823   then have g: "continuous_on (f`?D) g"
  1824     using inj by (intro continuous_on_inv) auto
  1825 
  1826   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  1827     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  1828   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  1829     by (rule continuous_on_subset)
  1830   moreover
  1831   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  1832     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  1833   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  1834     by auto
  1835   ultimately
  1836   show ?thesis
  1837     by (simp add: continuous_on_eq_continuous_at)
  1838 qed
  1839 
  1840 lemma isCont_inverse_function2:
  1841   fixes f g :: "real \<Rightarrow> real" shows
  1842   "\<lbrakk>a < x; x < b;
  1843     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  1844     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  1845    \<Longrightarrow> isCont g (f x)"
  1846 apply (rule isCont_inverse_function
  1847        [where f=f and d="min (x - a) (b - x)"])
  1848 apply (simp_all add: abs_le_iff)
  1849 done
  1850 
  1851 (* need to rename second isCont_inverse *)
  1852 
  1853 lemma isCont_inv_fun:
  1854   fixes f g :: "real \<Rightarrow> real"
  1855   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1856          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1857       ==> isCont g (f x)"
  1858 by (rule isCont_inverse_function)
  1859 
  1860 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1861 lemma LIM_fun_gt_zero:
  1862   fixes f :: "real \<Rightarrow> real"
  1863   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  1864 apply (drule (1) LIM_D, clarify)
  1865 apply (rule_tac x = s in exI)
  1866 apply (simp add: abs_less_iff)
  1867 done
  1868 
  1869 lemma LIM_fun_less_zero:
  1870   fixes f :: "real \<Rightarrow> real"
  1871   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  1872 apply (drule LIM_D [where r="-l"], simp, clarify)
  1873 apply (rule_tac x = s in exI)
  1874 apply (simp add: abs_less_iff)
  1875 done
  1876 
  1877 lemma LIM_fun_not_zero:
  1878   fixes f :: "real \<Rightarrow> real"
  1879   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  1880   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  1881 end
  1882