src/HOL/Multivariate_Analysis/Topology_Euclidean_Space.thy
author immler
Mon Dec 16 17:08:22 2013 +0100 (2013-12-16)
changeset 54775 2d3df8633dad
parent 54489 03ff4d1e6784
child 54780 6fae499e0827
permissions -rw-r--r--
prefer box over greaterThanLessThan on euclidean_space
     1 (*  title:      HOL/Library/Topology_Euclidian_Space.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3     Author:     Robert Himmelmann, TU Muenchen
     4     Author:     Brian Huffman, Portland State University
     5 *)
     6 
     7 header {* Elementary topology in Euclidean space. *}
     8 
     9 theory Topology_Euclidean_Space
    10 imports
    11   Complex_Main
    12   "~~/src/HOL/Library/Countable_Set"
    13   "~~/src/HOL/Library/FuncSet"
    14   Linear_Algebra
    15   Norm_Arith
    16 begin
    17 
    18 lemma dist_0_norm:
    19   fixes x :: "'a::real_normed_vector"
    20   shows "dist 0 x = norm x"
    21 unfolding dist_norm by simp
    22 
    23 lemma dist_double: "dist x y < d / 2 \<Longrightarrow> dist x z < d / 2 \<Longrightarrow> dist y z < d"
    24   using dist_triangle[of y z x] by (simp add: dist_commute)
    25 
    26 (* LEGACY *)
    27 lemma lim_subseq: "subseq r \<Longrightarrow> s ----> l \<Longrightarrow> (s \<circ> r) ----> l"
    28   by (rule LIMSEQ_subseq_LIMSEQ)
    29 
    30 lemma countable_PiE:
    31   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> countable (F i)) \<Longrightarrow> countable (PiE I F)"
    32   by (induct I arbitrary: F rule: finite_induct) (auto simp: PiE_insert_eq)
    33 
    34 lemma Lim_within_open:
    35   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
    36   shows "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l)(at a within S) \<longleftrightarrow> (f ---> l)(at a)"
    37   by (fact tendsto_within_open)
    38 
    39 lemma continuous_on_union:
    40   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
    41   by (fact continuous_on_closed_Un)
    42 
    43 lemma continuous_on_cases:
    44   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t g \<Longrightarrow>
    45     \<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x \<Longrightarrow>
    46     continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
    47   by (rule continuous_on_If) auto
    48 
    49 
    50 subsection {* Topological Basis *}
    51 
    52 context topological_space
    53 begin
    54 
    55 definition "topological_basis B \<longleftrightarrow>
    56   (\<forall>b\<in>B. open b) \<and> (\<forall>x. open x \<longrightarrow> (\<exists>B'. B' \<subseteq> B \<and> \<Union>B' = x))"
    57 
    58 lemma topological_basis:
    59   "topological_basis B \<longleftrightarrow> (\<forall>x. open x \<longleftrightarrow> (\<exists>B'. B' \<subseteq> B \<and> \<Union>B' = x))"
    60   unfolding topological_basis_def
    61   apply safe
    62      apply fastforce
    63     apply fastforce
    64    apply (erule_tac x="x" in allE)
    65    apply simp
    66    apply (rule_tac x="{x}" in exI)
    67   apply auto
    68   done
    69 
    70 lemma topological_basis_iff:
    71   assumes "\<And>B'. B' \<in> B \<Longrightarrow> open B'"
    72   shows "topological_basis B \<longleftrightarrow> (\<forall>O'. open O' \<longrightarrow> (\<forall>x\<in>O'. \<exists>B'\<in>B. x \<in> B' \<and> B' \<subseteq> O'))"
    73     (is "_ \<longleftrightarrow> ?rhs")
    74 proof safe
    75   fix O' and x::'a
    76   assume H: "topological_basis B" "open O'" "x \<in> O'"
    77   then have "(\<exists>B'\<subseteq>B. \<Union>B' = O')" by (simp add: topological_basis_def)
    78   then obtain B' where "B' \<subseteq> B" "O' = \<Union>B'" by auto
    79   then show "\<exists>B'\<in>B. x \<in> B' \<and> B' \<subseteq> O'" using H by auto
    80 next
    81   assume H: ?rhs
    82   show "topological_basis B"
    83     using assms unfolding topological_basis_def
    84   proof safe
    85     fix O' :: "'a set"
    86     assume "open O'"
    87     with H obtain f where "\<forall>x\<in>O'. f x \<in> B \<and> x \<in> f x \<and> f x \<subseteq> O'"
    88       by (force intro: bchoice simp: Bex_def)
    89     then show "\<exists>B'\<subseteq>B. \<Union>B' = O'"
    90       by (auto intro: exI[where x="{f x |x. x \<in> O'}"])
    91   qed
    92 qed
    93 
    94 lemma topological_basisI:
    95   assumes "\<And>B'. B' \<in> B \<Longrightarrow> open B'"
    96     and "\<And>O' x. open O' \<Longrightarrow> x \<in> O' \<Longrightarrow> \<exists>B'\<in>B. x \<in> B' \<and> B' \<subseteq> O'"
    97   shows "topological_basis B"
    98   using assms by (subst topological_basis_iff) auto
    99 
   100 lemma topological_basisE:
   101   fixes O'
   102   assumes "topological_basis B"
   103     and "open O'"
   104     and "x \<in> O'"
   105   obtains B' where "B' \<in> B" "x \<in> B'" "B' \<subseteq> O'"
   106 proof atomize_elim
   107   from assms have "\<And>B'. B'\<in>B \<Longrightarrow> open B'"
   108     by (simp add: topological_basis_def)
   109   with topological_basis_iff assms
   110   show  "\<exists>B'. B' \<in> B \<and> x \<in> B' \<and> B' \<subseteq> O'"
   111     using assms by (simp add: Bex_def)
   112 qed
   113 
   114 lemma topological_basis_open:
   115   assumes "topological_basis B"
   116     and "X \<in> B"
   117   shows "open X"
   118   using assms by (simp add: topological_basis_def)
   119 
   120 lemma topological_basis_imp_subbasis:
   121   assumes B: "topological_basis B"
   122   shows "open = generate_topology B"
   123 proof (intro ext iffI)
   124   fix S :: "'a set"
   125   assume "open S"
   126   with B obtain B' where "B' \<subseteq> B" "S = \<Union>B'"
   127     unfolding topological_basis_def by blast
   128   then show "generate_topology B S"
   129     by (auto intro: generate_topology.intros dest: topological_basis_open)
   130 next
   131   fix S :: "'a set"
   132   assume "generate_topology B S"
   133   then show "open S"
   134     by induct (auto dest: topological_basis_open[OF B])
   135 qed
   136 
   137 lemma basis_dense:
   138   fixes B :: "'a set set"
   139     and f :: "'a set \<Rightarrow> 'a"
   140   assumes "topological_basis B"
   141     and choosefrom_basis: "\<And>B'. B' \<noteq> {} \<Longrightarrow> f B' \<in> B'"
   142   shows "(\<forall>X. open X \<longrightarrow> X \<noteq> {} \<longrightarrow> (\<exists>B' \<in> B. f B' \<in> X))"
   143 proof (intro allI impI)
   144   fix X :: "'a set"
   145   assume "open X" and "X \<noteq> {}"
   146   from topological_basisE[OF `topological_basis B` `open X` choosefrom_basis[OF `X \<noteq> {}`]]
   147   guess B' . note B' = this
   148   then show "\<exists>B'\<in>B. f B' \<in> X"
   149     by (auto intro!: choosefrom_basis)
   150 qed
   151 
   152 end
   153 
   154 lemma topological_basis_prod:
   155   assumes A: "topological_basis A"
   156     and B: "topological_basis B"
   157   shows "topological_basis ((\<lambda>(a, b). a \<times> b) ` (A \<times> B))"
   158   unfolding topological_basis_def
   159 proof (safe, simp_all del: ex_simps add: subset_image_iff ex_simps(1)[symmetric])
   160   fix S :: "('a \<times> 'b) set"
   161   assume "open S"
   162   then show "\<exists>X\<subseteq>A \<times> B. (\<Union>(a,b)\<in>X. a \<times> b) = S"
   163   proof (safe intro!: exI[of _ "{x\<in>A \<times> B. fst x \<times> snd x \<subseteq> S}"])
   164     fix x y
   165     assume "(x, y) \<in> S"
   166     from open_prod_elim[OF `open S` this]
   167     obtain a b where a: "open a""x \<in> a" and b: "open b" "y \<in> b" and "a \<times> b \<subseteq> S"
   168       by (metis mem_Sigma_iff)
   169     moreover from topological_basisE[OF A a] guess A0 .
   170     moreover from topological_basisE[OF B b] guess B0 .
   171     ultimately show "(x, y) \<in> (\<Union>(a, b)\<in>{X \<in> A \<times> B. fst X \<times> snd X \<subseteq> S}. a \<times> b)"
   172       by (intro UN_I[of "(A0, B0)"]) auto
   173   qed auto
   174 qed (metis A B topological_basis_open open_Times)
   175 
   176 
   177 subsection {* Countable Basis *}
   178 
   179 locale countable_basis =
   180   fixes B :: "'a::topological_space set set"
   181   assumes is_basis: "topological_basis B"
   182     and countable_basis: "countable B"
   183 begin
   184 
   185 lemma open_countable_basis_ex:
   186   assumes "open X"
   187   shows "\<exists>B' \<subseteq> B. X = Union B'"
   188   using assms countable_basis is_basis
   189   unfolding topological_basis_def by blast
   190 
   191 lemma open_countable_basisE:
   192   assumes "open X"
   193   obtains B' where "B' \<subseteq> B" "X = Union B'"
   194   using assms open_countable_basis_ex
   195   by (atomize_elim) simp
   196 
   197 lemma countable_dense_exists:
   198   "\<exists>D::'a set. countable D \<and> (\<forall>X. open X \<longrightarrow> X \<noteq> {} \<longrightarrow> (\<exists>d \<in> D. d \<in> X))"
   199 proof -
   200   let ?f = "(\<lambda>B'. SOME x. x \<in> B')"
   201   have "countable (?f ` B)" using countable_basis by simp
   202   with basis_dense[OF is_basis, of ?f] show ?thesis
   203     by (intro exI[where x="?f ` B"]) (metis (mono_tags) all_not_in_conv imageI someI)
   204 qed
   205 
   206 lemma countable_dense_setE:
   207   obtains D :: "'a set"
   208   where "countable D" "\<And>X. open X \<Longrightarrow> X \<noteq> {} \<Longrightarrow> \<exists>d \<in> D. d \<in> X"
   209   using countable_dense_exists by blast
   210 
   211 end
   212 
   213 lemma (in first_countable_topology) first_countable_basisE:
   214   obtains A where "countable A" "\<And>a. a \<in> A \<Longrightarrow> x \<in> a" "\<And>a. a \<in> A \<Longrightarrow> open a"
   215     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> (\<exists>a\<in>A. a \<subseteq> S)"
   216   using first_countable_basis[of x]
   217   apply atomize_elim
   218   apply (elim exE)
   219   apply (rule_tac x="range A" in exI)
   220   apply auto
   221   done
   222 
   223 lemma (in first_countable_topology) first_countable_basis_Int_stableE:
   224   obtains A where "countable A" "\<And>a. a \<in> A \<Longrightarrow> x \<in> a" "\<And>a. a \<in> A \<Longrightarrow> open a"
   225     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> (\<exists>a\<in>A. a \<subseteq> S)"
   226     "\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<inter> b \<in> A"
   227 proof atomize_elim
   228   from first_countable_basisE[of x] guess A' . note A' = this
   229   def A \<equiv> "(\<lambda>N. \<Inter>((\<lambda>n. from_nat_into A' n) ` N)) ` (Collect finite::nat set set)"
   230   then show "\<exists>A. countable A \<and> (\<forall>a. a \<in> A \<longrightarrow> x \<in> a) \<and> (\<forall>a. a \<in> A \<longrightarrow> open a) \<and>
   231         (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> (\<exists>a\<in>A. a \<subseteq> S)) \<and> (\<forall>a b. a \<in> A \<longrightarrow> b \<in> A \<longrightarrow> a \<inter> b \<in> A)"
   232   proof (safe intro!: exI[where x=A])
   233     show "countable A"
   234       unfolding A_def by (intro countable_image countable_Collect_finite)
   235     fix a
   236     assume "a \<in> A"
   237     then show "x \<in> a" "open a"
   238       using A'(4)[OF open_UNIV] by (auto simp: A_def intro: A' from_nat_into)
   239   next
   240     let ?int = "\<lambda>N. \<Inter>(from_nat_into A' ` N)"
   241     fix a b
   242     assume "a \<in> A" "b \<in> A"
   243     then obtain N M where "a = ?int N" "b = ?int M" "finite (N \<union> M)"
   244       by (auto simp: A_def)
   245     then show "a \<inter> b \<in> A"
   246       by (auto simp: A_def intro!: image_eqI[where x="N \<union> M"])
   247   next
   248     fix S
   249     assume "open S" "x \<in> S"
   250     then obtain a where a: "a\<in>A'" "a \<subseteq> S" using A' by blast
   251     then show "\<exists>a\<in>A. a \<subseteq> S" using a A'
   252       by (intro bexI[where x=a]) (auto simp: A_def intro: image_eqI[where x="{to_nat_on A' a}"])
   253   qed
   254 qed
   255 
   256 lemma (in topological_space) first_countableI:
   257   assumes "countable A"
   258     and 1: "\<And>a. a \<in> A \<Longrightarrow> x \<in> a" "\<And>a. a \<in> A \<Longrightarrow> open a"
   259     and 2: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>a\<in>A. a \<subseteq> S"
   260   shows "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   261 proof (safe intro!: exI[of _ "from_nat_into A"])
   262   fix i
   263   have "A \<noteq> {}" using 2[of UNIV] by auto
   264   show "x \<in> from_nat_into A i" "open (from_nat_into A i)"
   265     using range_from_nat_into_subset[OF `A \<noteq> {}`] 1 by auto
   266 next
   267   fix S
   268   assume "open S" "x\<in>S" from 2[OF this]
   269   show "\<exists>i. from_nat_into A i \<subseteq> S"
   270     using subset_range_from_nat_into[OF `countable A`] by auto
   271 qed
   272 
   273 instance prod :: (first_countable_topology, first_countable_topology) first_countable_topology
   274 proof
   275   fix x :: "'a \<times> 'b"
   276   from first_countable_basisE[of "fst x"] guess A :: "'a set set" . note A = this
   277   from first_countable_basisE[of "snd x"] guess B :: "'b set set" . note B = this
   278   show "\<exists>A::nat \<Rightarrow> ('a \<times> 'b) set.
   279     (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   280   proof (rule first_countableI[of "(\<lambda>(a, b). a \<times> b) ` (A \<times> B)"], safe)
   281     fix a b
   282     assume x: "a \<in> A" "b \<in> B"
   283     with A(2, 3)[of a] B(2, 3)[of b] show "x \<in> a \<times> b" and "open (a \<times> b)"
   284       unfolding mem_Times_iff
   285       by (auto intro: open_Times)
   286   next
   287     fix S
   288     assume "open S" "x \<in> S"
   289     from open_prod_elim[OF this] guess a' b' . note a'b' = this
   290     moreover from a'b' A(4)[of a'] B(4)[of b']
   291     obtain a b where "a \<in> A" "a \<subseteq> a'" "b \<in> B" "b \<subseteq> b'" by auto
   292     ultimately show "\<exists>a\<in>(\<lambda>(a, b). a \<times> b) ` (A \<times> B). a \<subseteq> S"
   293       by (auto intro!: bexI[of _ "a \<times> b"] bexI[of _ a] bexI[of _ b])
   294   qed (simp add: A B)
   295 qed
   296 
   297 class second_countable_topology = topological_space +
   298   assumes ex_countable_subbasis:
   299     "\<exists>B::'a::topological_space set set. countable B \<and> open = generate_topology B"
   300 begin
   301 
   302 lemma ex_countable_basis: "\<exists>B::'a set set. countable B \<and> topological_basis B"
   303 proof -
   304   from ex_countable_subbasis obtain B where B: "countable B" "open = generate_topology B"
   305     by blast
   306   let ?B = "Inter ` {b. finite b \<and> b \<subseteq> B }"
   307 
   308   show ?thesis
   309   proof (intro exI conjI)
   310     show "countable ?B"
   311       by (intro countable_image countable_Collect_finite_subset B)
   312     {
   313       fix S
   314       assume "open S"
   315       then have "\<exists>B'\<subseteq>{b. finite b \<and> b \<subseteq> B}. (\<Union>b\<in>B'. \<Inter>b) = S"
   316         unfolding B
   317       proof induct
   318         case UNIV
   319         show ?case by (intro exI[of _ "{{}}"]) simp
   320       next
   321         case (Int a b)
   322         then obtain x y where x: "a = UNION x Inter" "\<And>i. i \<in> x \<Longrightarrow> finite i \<and> i \<subseteq> B"
   323           and y: "b = UNION y Inter" "\<And>i. i \<in> y \<Longrightarrow> finite i \<and> i \<subseteq> B"
   324           by blast
   325         show ?case
   326           unfolding x y Int_UN_distrib2
   327           by (intro exI[of _ "{i \<union> j| i j.  i \<in> x \<and> j \<in> y}"]) (auto dest: x(2) y(2))
   328       next
   329         case (UN K)
   330         then have "\<forall>k\<in>K. \<exists>B'\<subseteq>{b. finite b \<and> b \<subseteq> B}. UNION B' Inter = k" by auto
   331         then guess k unfolding bchoice_iff ..
   332         then show "\<exists>B'\<subseteq>{b. finite b \<and> b \<subseteq> B}. UNION B' Inter = \<Union>K"
   333           by (intro exI[of _ "UNION K k"]) auto
   334       next
   335         case (Basis S)
   336         then show ?case
   337           by (intro exI[of _ "{{S}}"]) auto
   338       qed
   339       then have "(\<exists>B'\<subseteq>Inter ` {b. finite b \<and> b \<subseteq> B}. \<Union>B' = S)"
   340         unfolding subset_image_iff by blast }
   341     then show "topological_basis ?B"
   342       unfolding topological_space_class.topological_basis_def
   343       by (safe intro!: topological_space_class.open_Inter)
   344          (simp_all add: B generate_topology.Basis subset_eq)
   345   qed
   346 qed
   347 
   348 end
   349 
   350 sublocale second_countable_topology <
   351   countable_basis "SOME B. countable B \<and> topological_basis B"
   352   using someI_ex[OF ex_countable_basis]
   353   by unfold_locales safe
   354 
   355 instance prod :: (second_countable_topology, second_countable_topology) second_countable_topology
   356 proof
   357   obtain A :: "'a set set" where "countable A" "topological_basis A"
   358     using ex_countable_basis by auto
   359   moreover
   360   obtain B :: "'b set set" where "countable B" "topological_basis B"
   361     using ex_countable_basis by auto
   362   ultimately show "\<exists>B::('a \<times> 'b) set set. countable B \<and> open = generate_topology B"
   363     by (auto intro!: exI[of _ "(\<lambda>(a, b). a \<times> b) ` (A \<times> B)"] topological_basis_prod
   364       topological_basis_imp_subbasis)
   365 qed
   366 
   367 instance second_countable_topology \<subseteq> first_countable_topology
   368 proof
   369   fix x :: 'a
   370   def B \<equiv> "SOME B::'a set set. countable B \<and> topological_basis B"
   371   then have B: "countable B" "topological_basis B"
   372     using countable_basis is_basis
   373     by (auto simp: countable_basis is_basis)
   374   then show "\<exists>A::nat \<Rightarrow> 'a set.
   375     (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   376     by (intro first_countableI[of "{b\<in>B. x \<in> b}"])
   377        (fastforce simp: topological_space_class.topological_basis_def)+
   378 qed
   379 
   380 
   381 subsection {* Polish spaces *}
   382 
   383 text {* Textbooks define Polish spaces as completely metrizable.
   384   We assume the topology to be complete for a given metric. *}
   385 
   386 class polish_space = complete_space + second_countable_topology
   387 
   388 subsection {* General notion of a topology as a value *}
   389 
   390 definition "istopology L \<longleftrightarrow>
   391   L {} \<and> (\<forall>S T. L S \<longrightarrow> L T \<longrightarrow> L (S \<inter> T)) \<and> (\<forall>K. Ball K L \<longrightarrow> L (\<Union> K))"
   392 
   393 typedef 'a topology = "{L::('a set) \<Rightarrow> bool. istopology L}"
   394   morphisms "openin" "topology"
   395   unfolding istopology_def by blast
   396 
   397 lemma istopology_open_in[intro]: "istopology(openin U)"
   398   using openin[of U] by blast
   399 
   400 lemma topology_inverse': "istopology U \<Longrightarrow> openin (topology U) = U"
   401   using topology_inverse[unfolded mem_Collect_eq] .
   402 
   403 lemma topology_inverse_iff: "istopology U \<longleftrightarrow> openin (topology U) = U"
   404   using topology_inverse[of U] istopology_open_in[of "topology U"] by auto
   405 
   406 lemma topology_eq: "T1 = T2 \<longleftrightarrow> (\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S)"
   407 proof
   408   assume "T1 = T2"
   409   then show "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S" by simp
   410 next
   411   assume H: "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S"
   412   then have "openin T1 = openin T2" by (simp add: fun_eq_iff)
   413   then have "topology (openin T1) = topology (openin T2)" by simp
   414   then show "T1 = T2" unfolding openin_inverse .
   415 qed
   416 
   417 text{* Infer the "universe" from union of all sets in the topology. *}
   418 
   419 definition "topspace T = \<Union>{S. openin T S}"
   420 
   421 subsubsection {* Main properties of open sets *}
   422 
   423 lemma openin_clauses:
   424   fixes U :: "'a topology"
   425   shows
   426     "openin U {}"
   427     "\<And>S T. openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S\<inter>T)"
   428     "\<And>K. (\<forall>S \<in> K. openin U S) \<Longrightarrow> openin U (\<Union>K)"
   429   using openin[of U] unfolding istopology_def mem_Collect_eq by fast+
   430 
   431 lemma openin_subset[intro]: "openin U S \<Longrightarrow> S \<subseteq> topspace U"
   432   unfolding topspace_def by blast
   433 
   434 lemma openin_empty[simp]: "openin U {}"
   435   by (simp add: openin_clauses)
   436 
   437 lemma openin_Int[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<inter> T)"
   438   using openin_clauses by simp
   439 
   440 lemma openin_Union[intro]: "(\<forall>S \<in>K. openin U S) \<Longrightarrow> openin U (\<Union> K)"
   441   using openin_clauses by simp
   442 
   443 lemma openin_Un[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<union> T)"
   444   using openin_Union[of "{S,T}" U] by auto
   445 
   446 lemma openin_topspace[intro, simp]: "openin U (topspace U)"
   447   by (simp add: openin_Union topspace_def)
   448 
   449 lemma openin_subopen: "openin U S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>T. openin U T \<and> x \<in> T \<and> T \<subseteq> S)"
   450   (is "?lhs \<longleftrightarrow> ?rhs")
   451 proof
   452   assume ?lhs
   453   then show ?rhs by auto
   454 next
   455   assume H: ?rhs
   456   let ?t = "\<Union>{T. openin U T \<and> T \<subseteq> S}"
   457   have "openin U ?t" by (simp add: openin_Union)
   458   also have "?t = S" using H by auto
   459   finally show "openin U S" .
   460 qed
   461 
   462 
   463 subsubsection {* Closed sets *}
   464 
   465 definition "closedin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> openin U (topspace U - S)"
   466 
   467 lemma closedin_subset: "closedin U S \<Longrightarrow> S \<subseteq> topspace U"
   468   by (metis closedin_def)
   469 
   470 lemma closedin_empty[simp]: "closedin U {}"
   471   by (simp add: closedin_def)
   472 
   473 lemma closedin_topspace[intro, simp]: "closedin U (topspace U)"
   474   by (simp add: closedin_def)
   475 
   476 lemma closedin_Un[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<union> T)"
   477   by (auto simp add: Diff_Un closedin_def)
   478 
   479 lemma Diff_Inter[intro]: "A - \<Inter>S = \<Union> {A - s|s. s\<in>S}"
   480   by auto
   481 
   482 lemma closedin_Inter[intro]:
   483   assumes Ke: "K \<noteq> {}"
   484     and Kc: "\<forall>S \<in>K. closedin U S"
   485   shows "closedin U (\<Inter> K)"
   486   using Ke Kc unfolding closedin_def Diff_Inter by auto
   487 
   488 lemma closedin_Int[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<inter> T)"
   489   using closedin_Inter[of "{S,T}" U] by auto
   490 
   491 lemma Diff_Diff_Int: "A - (A - B) = A \<inter> B"
   492   by blast
   493 
   494 lemma openin_closedin_eq: "openin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> closedin U (topspace U - S)"
   495   apply (auto simp add: closedin_def Diff_Diff_Int inf_absorb2)
   496   apply (metis openin_subset subset_eq)
   497   done
   498 
   499 lemma openin_closedin: "S \<subseteq> topspace U \<Longrightarrow> (openin U S \<longleftrightarrow> closedin U (topspace U - S))"
   500   by (simp add: openin_closedin_eq)
   501 
   502 lemma openin_diff[intro]:
   503   assumes oS: "openin U S"
   504     and cT: "closedin U T"
   505   shows "openin U (S - T)"
   506 proof -
   507   have "S - T = S \<inter> (topspace U - T)" using openin_subset[of U S]  oS cT
   508     by (auto simp add: topspace_def openin_subset)
   509   then show ?thesis using oS cT
   510     by (auto simp add: closedin_def)
   511 qed
   512 
   513 lemma closedin_diff[intro]:
   514   assumes oS: "closedin U S"
   515     and cT: "openin U T"
   516   shows "closedin U (S - T)"
   517 proof -
   518   have "S - T = S \<inter> (topspace U - T)"
   519     using closedin_subset[of U S] oS cT by (auto simp add: topspace_def)
   520   then show ?thesis
   521     using oS cT by (auto simp add: openin_closedin_eq)
   522 qed
   523 
   524 
   525 subsubsection {* Subspace topology *}
   526 
   527 definition "subtopology U V = topology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   528 
   529 lemma istopology_subtopology: "istopology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   530   (is "istopology ?L")
   531 proof -
   532   have "?L {}" by blast
   533   {
   534     fix A B
   535     assume A: "?L A" and B: "?L B"
   536     from A B obtain Sa and Sb where Sa: "openin U Sa" "A = Sa \<inter> V" and Sb: "openin U Sb" "B = Sb \<inter> V"
   537       by blast
   538     have "A \<inter> B = (Sa \<inter> Sb) \<inter> V" "openin U (Sa \<inter> Sb)"
   539       using Sa Sb by blast+
   540     then have "?L (A \<inter> B)" by blast
   541   }
   542   moreover
   543   {
   544     fix K
   545     assume K: "K \<subseteq> Collect ?L"
   546     have th0: "Collect ?L = (\<lambda>S. S \<inter> V) ` Collect (openin U)"
   547       apply (rule set_eqI)
   548       apply (simp add: Ball_def image_iff)
   549       apply metis
   550       done
   551     from K[unfolded th0 subset_image_iff]
   552     obtain Sk where Sk: "Sk \<subseteq> Collect (openin U)" "K = (\<lambda>S. S \<inter> V) ` Sk"
   553       by blast
   554     have "\<Union>K = (\<Union>Sk) \<inter> V"
   555       using Sk by auto
   556     moreover have "openin U (\<Union> Sk)"
   557       using Sk by (auto simp add: subset_eq)
   558     ultimately have "?L (\<Union>K)" by blast
   559   }
   560   ultimately show ?thesis
   561     unfolding subset_eq mem_Collect_eq istopology_def by blast
   562 qed
   563 
   564 lemma openin_subtopology: "openin (subtopology U V) S \<longleftrightarrow> (\<exists>T. openin U T \<and> S = T \<inter> V)"
   565   unfolding subtopology_def topology_inverse'[OF istopology_subtopology]
   566   by auto
   567 
   568 lemma topspace_subtopology: "topspace (subtopology U V) = topspace U \<inter> V"
   569   by (auto simp add: topspace_def openin_subtopology)
   570 
   571 lemma closedin_subtopology: "closedin (subtopology U V) S \<longleftrightarrow> (\<exists>T. closedin U T \<and> S = T \<inter> V)"
   572   unfolding closedin_def topspace_subtopology
   573   apply (simp add: openin_subtopology)
   574   apply (rule iffI)
   575   apply clarify
   576   apply (rule_tac x="topspace U - T" in exI)
   577   apply auto
   578   done
   579 
   580 lemma openin_subtopology_refl: "openin (subtopology U V) V \<longleftrightarrow> V \<subseteq> topspace U"
   581   unfolding openin_subtopology
   582   apply (rule iffI, clarify)
   583   apply (frule openin_subset[of U])
   584   apply blast
   585   apply (rule exI[where x="topspace U"])
   586   apply auto
   587   done
   588 
   589 lemma subtopology_superset:
   590   assumes UV: "topspace U \<subseteq> V"
   591   shows "subtopology U V = U"
   592 proof -
   593   {
   594     fix S
   595     {
   596       fix T
   597       assume T: "openin U T" "S = T \<inter> V"
   598       from T openin_subset[OF T(1)] UV have eq: "S = T"
   599         by blast
   600       have "openin U S"
   601         unfolding eq using T by blast
   602     }
   603     moreover
   604     {
   605       assume S: "openin U S"
   606       then have "\<exists>T. openin U T \<and> S = T \<inter> V"
   607         using openin_subset[OF S] UV by auto
   608     }
   609     ultimately have "(\<exists>T. openin U T \<and> S = T \<inter> V) \<longleftrightarrow> openin U S"
   610       by blast
   611   }
   612   then show ?thesis
   613     unfolding topology_eq openin_subtopology by blast
   614 qed
   615 
   616 lemma subtopology_topspace[simp]: "subtopology U (topspace U) = U"
   617   by (simp add: subtopology_superset)
   618 
   619 lemma subtopology_UNIV[simp]: "subtopology U UNIV = U"
   620   by (simp add: subtopology_superset)
   621 
   622 
   623 subsubsection {* The standard Euclidean topology *}
   624 
   625 definition euclidean :: "'a::topological_space topology"
   626   where "euclidean = topology open"
   627 
   628 lemma open_openin: "open S \<longleftrightarrow> openin euclidean S"
   629   unfolding euclidean_def
   630   apply (rule cong[where x=S and y=S])
   631   apply (rule topology_inverse[symmetric])
   632   apply (auto simp add: istopology_def)
   633   done
   634 
   635 lemma topspace_euclidean: "topspace euclidean = UNIV"
   636   apply (simp add: topspace_def)
   637   apply (rule set_eqI)
   638   apply (auto simp add: open_openin[symmetric])
   639   done
   640 
   641 lemma topspace_euclidean_subtopology[simp]: "topspace (subtopology euclidean S) = S"
   642   by (simp add: topspace_euclidean topspace_subtopology)
   643 
   644 lemma closed_closedin: "closed S \<longleftrightarrow> closedin euclidean S"
   645   by (simp add: closed_def closedin_def topspace_euclidean open_openin Compl_eq_Diff_UNIV)
   646 
   647 lemma open_subopen: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S)"
   648   by (simp add: open_openin openin_subopen[symmetric])
   649 
   650 text {* Basic "localization" results are handy for connectedness. *}
   651 
   652 lemma openin_open: "openin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. open T \<and> (S = U \<inter> T))"
   653   by (auto simp add: openin_subtopology open_openin[symmetric])
   654 
   655 lemma openin_open_Int[intro]: "open S \<Longrightarrow> openin (subtopology euclidean U) (U \<inter> S)"
   656   by (auto simp add: openin_open)
   657 
   658 lemma open_openin_trans[trans]:
   659   "open S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> openin (subtopology euclidean S) T"
   660   by (metis Int_absorb1  openin_open_Int)
   661 
   662 lemma open_subset: "S \<subseteq> T \<Longrightarrow> open S \<Longrightarrow> openin (subtopology euclidean T) S"
   663   by (auto simp add: openin_open)
   664 
   665 lemma closedin_closed: "closedin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. closed T \<and> S = U \<inter> T)"
   666   by (simp add: closedin_subtopology closed_closedin Int_ac)
   667 
   668 lemma closedin_closed_Int: "closed S \<Longrightarrow> closedin (subtopology euclidean U) (U \<inter> S)"
   669   by (metis closedin_closed)
   670 
   671 lemma closed_closedin_trans:
   672   "closed S \<Longrightarrow> closed T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> closedin (subtopology euclidean S) T"
   673   apply (subgoal_tac "S \<inter> T = T" )
   674   apply auto
   675   apply (frule closedin_closed_Int[of T S])
   676   apply simp
   677   done
   678 
   679 lemma closed_subset: "S \<subseteq> T \<Longrightarrow> closed S \<Longrightarrow> closedin (subtopology euclidean T) S"
   680   by (auto simp add: closedin_closed)
   681 
   682 lemma openin_euclidean_subtopology_iff:
   683   fixes S U :: "'a::metric_space set"
   684   shows "openin (subtopology euclidean U) S \<longleftrightarrow>
   685     S \<subseteq> U \<and> (\<forall>x\<in>S. \<exists>e>0. \<forall>x'\<in>U. dist x' x < e \<longrightarrow> x'\<in> S)"
   686   (is "?lhs \<longleftrightarrow> ?rhs")
   687 proof
   688   assume ?lhs
   689   then show ?rhs
   690     unfolding openin_open open_dist by blast
   691 next
   692   def T \<equiv> "{x. \<exists>a\<in>S. \<exists>d>0. (\<forall>y\<in>U. dist y a < d \<longrightarrow> y \<in> S) \<and> dist x a < d}"
   693   have 1: "\<forall>x\<in>T. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> T"
   694     unfolding T_def
   695     apply clarsimp
   696     apply (rule_tac x="d - dist x a" in exI)
   697     apply (clarsimp simp add: less_diff_eq)
   698     apply (erule rev_bexI)
   699     apply (rule_tac x=d in exI, clarify)
   700     apply (erule le_less_trans [OF dist_triangle])
   701     done
   702   assume ?rhs then have 2: "S = U \<inter> T"
   703     unfolding T_def
   704     apply auto
   705     apply (drule (1) bspec, erule rev_bexI)
   706     apply auto
   707     done
   708   from 1 2 show ?lhs
   709     unfolding openin_open open_dist by fast
   710 qed
   711 
   712 text {* These "transitivity" results are handy too *}
   713 
   714 lemma openin_trans[trans]:
   715   "openin (subtopology euclidean T) S \<Longrightarrow> openin (subtopology euclidean U) T \<Longrightarrow>
   716     openin (subtopology euclidean U) S"
   717   unfolding open_openin openin_open by blast
   718 
   719 lemma openin_open_trans: "openin (subtopology euclidean T) S \<Longrightarrow> open T \<Longrightarrow> open S"
   720   by (auto simp add: openin_open intro: openin_trans)
   721 
   722 lemma closedin_trans[trans]:
   723   "closedin (subtopology euclidean T) S \<Longrightarrow> closedin (subtopology euclidean U) T \<Longrightarrow>
   724     closedin (subtopology euclidean U) S"
   725   by (auto simp add: closedin_closed closed_closedin closed_Inter Int_assoc)
   726 
   727 lemma closedin_closed_trans: "closedin (subtopology euclidean T) S \<Longrightarrow> closed T \<Longrightarrow> closed S"
   728   by (auto simp add: closedin_closed intro: closedin_trans)
   729 
   730 
   731 subsection {* Open and closed balls *}
   732 
   733 definition ball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set"
   734   where "ball x e = {y. dist x y < e}"
   735 
   736 definition cball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set"
   737   where "cball x e = {y. dist x y \<le> e}"
   738 
   739 lemma mem_ball [simp]: "y \<in> ball x e \<longleftrightarrow> dist x y < e"
   740   by (simp add: ball_def)
   741 
   742 lemma mem_cball [simp]: "y \<in> cball x e \<longleftrightarrow> dist x y \<le> e"
   743   by (simp add: cball_def)
   744 
   745 lemma mem_ball_0:
   746   fixes x :: "'a::real_normed_vector"
   747   shows "x \<in> ball 0 e \<longleftrightarrow> norm x < e"
   748   by (simp add: dist_norm)
   749 
   750 lemma mem_cball_0:
   751   fixes x :: "'a::real_normed_vector"
   752   shows "x \<in> cball 0 e \<longleftrightarrow> norm x \<le> e"
   753   by (simp add: dist_norm)
   754 
   755 lemma centre_in_ball: "x \<in> ball x e \<longleftrightarrow> 0 < e"
   756   by simp
   757 
   758 lemma centre_in_cball: "x \<in> cball x e \<longleftrightarrow> 0 \<le> e"
   759   by simp
   760 
   761 lemma ball_subset_cball[simp,intro]: "ball x e \<subseteq> cball x e"
   762   by (simp add: subset_eq)
   763 
   764 lemma subset_ball[intro]: "d \<le> e \<Longrightarrow> ball x d \<subseteq> ball x e"
   765   by (simp add: subset_eq)
   766 
   767 lemma subset_cball[intro]: "d \<le> e \<Longrightarrow> cball x d \<subseteq> cball x e"
   768   by (simp add: subset_eq)
   769 
   770 lemma ball_max_Un: "ball a (max r s) = ball a r \<union> ball a s"
   771   by (simp add: set_eq_iff) arith
   772 
   773 lemma ball_min_Int: "ball a (min r s) = ball a r \<inter> ball a s"
   774   by (simp add: set_eq_iff)
   775 
   776 lemma diff_less_iff:
   777   "(a::real) - b > 0 \<longleftrightarrow> a > b"
   778   "(a::real) - b < 0 \<longleftrightarrow> a < b"
   779   "a - b < c \<longleftrightarrow> a < c + b" "a - b > c \<longleftrightarrow> a > c + b"
   780   by arith+
   781 
   782 lemma diff_le_iff:
   783   "(a::real) - b \<ge> 0 \<longleftrightarrow> a \<ge> b"
   784   "(a::real) - b \<le> 0 \<longleftrightarrow> a \<le> b"
   785   "a - b \<le> c \<longleftrightarrow> a \<le> c + b"
   786   "a - b \<ge> c \<longleftrightarrow> a \<ge> c + b"
   787   by arith+
   788 
   789 lemma open_vimage: (* TODO: move to Topological_Spaces.thy *)
   790   assumes "open s" and "continuous_on UNIV f"
   791   shows "open (vimage f s)"
   792   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
   793   by simp
   794 
   795 lemma open_ball [intro, simp]: "open (ball x e)"
   796 proof -
   797   have "open (dist x -` {..<e})"
   798     by (intro open_vimage open_lessThan continuous_on_intros)
   799   also have "dist x -` {..<e} = ball x e"
   800     by auto
   801   finally show ?thesis .
   802 qed
   803 
   804 lemma open_contains_ball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. ball x e \<subseteq> S)"
   805   unfolding open_dist subset_eq mem_ball Ball_def dist_commute ..
   806 
   807 lemma openE[elim?]:
   808   assumes "open S" "x\<in>S"
   809   obtains e where "e>0" "ball x e \<subseteq> S"
   810   using assms unfolding open_contains_ball by auto
   811 
   812 lemma open_contains_ball_eq: "open S \<Longrightarrow> \<forall>x. x\<in>S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   813   by (metis open_contains_ball subset_eq centre_in_ball)
   814 
   815 lemma ball_eq_empty[simp]: "ball x e = {} \<longleftrightarrow> e \<le> 0"
   816   unfolding mem_ball set_eq_iff
   817   apply (simp add: not_less)
   818   apply (metis zero_le_dist order_trans dist_self)
   819   done
   820 
   821 lemma ball_empty[intro]: "e \<le> 0 \<Longrightarrow> ball x e = {}" by simp
   822 
   823 lemma euclidean_dist_l2:
   824   fixes x y :: "'a :: euclidean_space"
   825   shows "dist x y = setL2 (\<lambda>i. dist (x \<bullet> i) (y \<bullet> i)) Basis"
   826   unfolding dist_norm norm_eq_sqrt_inner setL2_def
   827   by (subst euclidean_inner) (simp add: power2_eq_square inner_diff_left)
   828 
   829 definition (in euclidean_space) eucl_less (infix "<e" 50)
   830   where "eucl_less a b \<longleftrightarrow> (\<forall>i\<in>Basis. a \<bullet> i < b \<bullet> i)"
   831 
   832 definition box_eucl_less: "box a b = {x. a <e x \<and> x <e b}"
   833 
   834 lemma box_def: "box a b = {x. \<forall>i\<in>Basis. a \<bullet> i < x \<bullet> i \<and> x \<bullet> i < b \<bullet> i}"
   835   and in_box_eucl_less: "x \<in> box a b \<longleftrightarrow> a <e x \<and> x <e b"
   836   by (auto simp: box_eucl_less eucl_less_def)
   837 
   838 lemma rational_boxes:
   839   fixes x :: "'a\<Colon>euclidean_space"
   840   assumes "e > 0"
   841   shows "\<exists>a b. (\<forall>i\<in>Basis. a \<bullet> i \<in> \<rat> \<and> b \<bullet> i \<in> \<rat> ) \<and> x \<in> box a b \<and> box a b \<subseteq> ball x e"
   842 proof -
   843   def e' \<equiv> "e / (2 * sqrt (real (DIM ('a))))"
   844   then have e: "e' > 0"
   845     using assms by (auto intro!: divide_pos_pos simp: DIM_positive)
   846   have "\<forall>i. \<exists>y. y \<in> \<rat> \<and> y < x \<bullet> i \<and> x \<bullet> i - y < e'" (is "\<forall>i. ?th i")
   847   proof
   848     fix i
   849     from Rats_dense_in_real[of "x \<bullet> i - e'" "x \<bullet> i"] e
   850     show "?th i" by auto
   851   qed
   852   from choice[OF this] guess a .. note a = this
   853   have "\<forall>i. \<exists>y. y \<in> \<rat> \<and> x \<bullet> i < y \<and> y - x \<bullet> i < e'" (is "\<forall>i. ?th i")
   854   proof
   855     fix i
   856     from Rats_dense_in_real[of "x \<bullet> i" "x \<bullet> i + e'"] e
   857     show "?th i" by auto
   858   qed
   859   from choice[OF this] guess b .. note b = this
   860   let ?a = "\<Sum>i\<in>Basis. a i *\<^sub>R i" and ?b = "\<Sum>i\<in>Basis. b i *\<^sub>R i"
   861   show ?thesis
   862   proof (rule exI[of _ ?a], rule exI[of _ ?b], safe)
   863     fix y :: 'a
   864     assume *: "y \<in> box ?a ?b"
   865     have "dist x y = sqrt (\<Sum>i\<in>Basis. (dist (x \<bullet> i) (y \<bullet> i))\<^sup>2)"
   866       unfolding setL2_def[symmetric] by (rule euclidean_dist_l2)
   867     also have "\<dots> < sqrt (\<Sum>(i::'a)\<in>Basis. e^2 / real (DIM('a)))"
   868     proof (rule real_sqrt_less_mono, rule setsum_strict_mono)
   869       fix i :: "'a"
   870       assume i: "i \<in> Basis"
   871       have "a i < y\<bullet>i \<and> y\<bullet>i < b i"
   872         using * i by (auto simp: box_def)
   873       moreover have "a i < x\<bullet>i" "x\<bullet>i - a i < e'"
   874         using a by auto
   875       moreover have "x\<bullet>i < b i" "b i - x\<bullet>i < e'"
   876         using b by auto
   877       ultimately have "\<bar>x\<bullet>i - y\<bullet>i\<bar> < 2 * e'"
   878         by auto
   879       then have "dist (x \<bullet> i) (y \<bullet> i) < e/sqrt (real (DIM('a)))"
   880         unfolding e'_def by (auto simp: dist_real_def)
   881       then have "(dist (x \<bullet> i) (y \<bullet> i))\<^sup>2 < (e/sqrt (real (DIM('a))))\<^sup>2"
   882         by (rule power_strict_mono) auto
   883       then show "(dist (x \<bullet> i) (y \<bullet> i))\<^sup>2 < e\<^sup>2 / real DIM('a)"
   884         by (simp add: power_divide)
   885     qed auto
   886     also have "\<dots> = e"
   887       using `0 < e` by (simp add: real_eq_of_nat)
   888     finally show "y \<in> ball x e"
   889       by (auto simp: ball_def)
   890   qed (insert a b, auto simp: box_def)
   891 qed
   892 
   893 lemma open_UNION_box:
   894   fixes M :: "'a\<Colon>euclidean_space set"
   895   assumes "open M"
   896   defines "a' \<equiv> \<lambda>f :: 'a \<Rightarrow> real \<times> real. (\<Sum>(i::'a)\<in>Basis. fst (f i) *\<^sub>R i)"
   897   defines "b' \<equiv> \<lambda>f :: 'a \<Rightarrow> real \<times> real. (\<Sum>(i::'a)\<in>Basis. snd (f i) *\<^sub>R i)"
   898   defines "I \<equiv> {f\<in>Basis \<rightarrow>\<^sub>E \<rat> \<times> \<rat>. box (a' f) (b' f) \<subseteq> M}"
   899   shows "M = (\<Union>f\<in>I. box (a' f) (b' f))"
   900 proof -
   901   {
   902     fix x assume "x \<in> M"
   903     obtain e where e: "e > 0" "ball x e \<subseteq> M"
   904       using openE[OF `open M` `x \<in> M`] by auto
   905     moreover obtain a b where ab:
   906       "x \<in> box a b"
   907       "\<forall>i \<in> Basis. a \<bullet> i \<in> \<rat>"
   908       "\<forall>i\<in>Basis. b \<bullet> i \<in> \<rat>"
   909       "box a b \<subseteq> ball x e"
   910       using rational_boxes[OF e(1)] by metis
   911     ultimately have "x \<in> (\<Union>f\<in>I. box (a' f) (b' f))"
   912        by (intro UN_I[of "\<lambda>i\<in>Basis. (a \<bullet> i, b \<bullet> i)"])
   913           (auto simp: euclidean_representation I_def a'_def b'_def)
   914   }
   915   then show ?thesis by (auto simp: I_def)
   916 qed
   917 
   918 
   919 subsection{* Connectedness *}
   920 
   921 lemma connected_local:
   922  "connected S \<longleftrightarrow>
   923   \<not> (\<exists>e1 e2.
   924       openin (subtopology euclidean S) e1 \<and>
   925       openin (subtopology euclidean S) e2 \<and>
   926       S \<subseteq> e1 \<union> e2 \<and>
   927       e1 \<inter> e2 = {} \<and>
   928       e1 \<noteq> {} \<and>
   929       e2 \<noteq> {})"
   930   unfolding connected_def openin_open
   931   apply safe
   932   apply blast+
   933   done
   934 
   935 lemma exists_diff:
   936   fixes P :: "'a set \<Rightarrow> bool"
   937   shows "(\<exists>S. P(- S)) \<longleftrightarrow> (\<exists>S. P S)" (is "?lhs \<longleftrightarrow> ?rhs")
   938 proof -
   939   {
   940     assume "?lhs"
   941     then have ?rhs by blast
   942   }
   943   moreover
   944   {
   945     fix S
   946     assume H: "P S"
   947     have "S = - (- S)" by auto
   948     with H have "P (- (- S))" by metis
   949   }
   950   ultimately show ?thesis by metis
   951 qed
   952 
   953 lemma connected_clopen: "connected S \<longleftrightarrow>
   954   (\<forall>T. openin (subtopology euclidean S) T \<and>
   955      closedin (subtopology euclidean S) T \<longrightarrow> T = {} \<or> T = S)" (is "?lhs \<longleftrightarrow> ?rhs")
   956 proof -
   957   have "\<not> connected S \<longleftrightarrow>
   958     (\<exists>e1 e2. open e1 \<and> open (- e2) \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   959     unfolding connected_def openin_open closedin_closed
   960     apply (subst exists_diff)
   961     apply blast
   962     done
   963   then have th0: "connected S \<longleftrightarrow>
   964     \<not> (\<exists>e2 e1. closed e2 \<and> open e1 \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   965     (is " _ \<longleftrightarrow> \<not> (\<exists>e2 e1. ?P e2 e1)")
   966     apply (simp add: closed_def)
   967     apply metis
   968     done
   969   have th1: "?rhs \<longleftrightarrow> \<not> (\<exists>t' t. closed t'\<and>t = S\<inter>t' \<and> t\<noteq>{} \<and> t\<noteq>S \<and> (\<exists>t'. open t' \<and> t = S \<inter> t'))"
   970     (is "_ \<longleftrightarrow> \<not> (\<exists>t' t. ?Q t' t)")
   971     unfolding connected_def openin_open closedin_closed by auto
   972   {
   973     fix e2
   974     {
   975       fix e1
   976       have "?P e2 e1 \<longleftrightarrow> (\<exists>t. closed e2 \<and> t = S\<inter>e2 \<and> open e1 \<and> t = S\<inter>e1 \<and> t\<noteq>{} \<and> t \<noteq> S)"
   977         by auto
   978     }
   979     then have "(\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)"
   980       by metis
   981   }
   982   then have "\<forall>e2. (\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)"
   983     by blast
   984   then show ?thesis
   985     unfolding th0 th1 by simp
   986 qed
   987 
   988 
   989 subsection{* Limit points *}
   990 
   991 definition (in topological_space) islimpt:: "'a \<Rightarrow> 'a set \<Rightarrow> bool"  (infixr "islimpt" 60)
   992   where "x islimpt S \<longleftrightarrow> (\<forall>T. x\<in>T \<longrightarrow> open T \<longrightarrow> (\<exists>y\<in>S. y\<in>T \<and> y\<noteq>x))"
   993 
   994 lemma islimptI:
   995   assumes "\<And>T. x \<in> T \<Longrightarrow> open T \<Longrightarrow> \<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
   996   shows "x islimpt S"
   997   using assms unfolding islimpt_def by auto
   998 
   999 lemma islimptE:
  1000   assumes "x islimpt S" and "x \<in> T" and "open T"
  1001   obtains y where "y \<in> S" and "y \<in> T" and "y \<noteq> x"
  1002   using assms unfolding islimpt_def by auto
  1003 
  1004 lemma islimpt_iff_eventually: "x islimpt S \<longleftrightarrow> \<not> eventually (\<lambda>y. y \<notin> S) (at x)"
  1005   unfolding islimpt_def eventually_at_topological by auto
  1006 
  1007 lemma islimpt_subset: "x islimpt S \<Longrightarrow> S \<subseteq> T \<Longrightarrow> x islimpt T"
  1008   unfolding islimpt_def by fast
  1009 
  1010 lemma islimpt_approachable:
  1011   fixes x :: "'a::metric_space"
  1012   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e)"
  1013   unfolding islimpt_iff_eventually eventually_at by fast
  1014 
  1015 lemma islimpt_approachable_le:
  1016   fixes x :: "'a::metric_space"
  1017   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in> S. x' \<noteq> x \<and> dist x' x \<le> e)"
  1018   unfolding islimpt_approachable
  1019   using approachable_lt_le [where f="\<lambda>y. dist y x" and P="\<lambda>y. y \<notin> S \<or> y = x",
  1020     THEN arg_cong [where f=Not]]
  1021   by (simp add: Bex_def conj_commute conj_left_commute)
  1022 
  1023 lemma islimpt_UNIV_iff: "x islimpt UNIV \<longleftrightarrow> \<not> open {x}"
  1024   unfolding islimpt_def by (safe, fast, case_tac "T = {x}", fast, fast)
  1025 
  1026 lemma islimpt_punctured: "x islimpt S = x islimpt (S-{x})"
  1027   unfolding islimpt_def by blast
  1028 
  1029 text {* A perfect space has no isolated points. *}
  1030 
  1031 lemma islimpt_UNIV [simp, intro]: "(x::'a::perfect_space) islimpt UNIV"
  1032   unfolding islimpt_UNIV_iff by (rule not_open_singleton)
  1033 
  1034 lemma perfect_choose_dist:
  1035   fixes x :: "'a::{perfect_space, metric_space}"
  1036   shows "0 < r \<Longrightarrow> \<exists>a. a \<noteq> x \<and> dist a x < r"
  1037   using islimpt_UNIV [of x]
  1038   by (simp add: islimpt_approachable)
  1039 
  1040 lemma closed_limpt: "closed S \<longleftrightarrow> (\<forall>x. x islimpt S \<longrightarrow> x \<in> S)"
  1041   unfolding closed_def
  1042   apply (subst open_subopen)
  1043   apply (simp add: islimpt_def subset_eq)
  1044   apply (metis ComplE ComplI)
  1045   done
  1046 
  1047 lemma islimpt_EMPTY[simp]: "\<not> x islimpt {}"
  1048   unfolding islimpt_def by auto
  1049 
  1050 lemma finite_set_avoid:
  1051   fixes a :: "'a::metric_space"
  1052   assumes fS: "finite S"
  1053   shows  "\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<longrightarrow> d \<le> dist a x"
  1054 proof (induct rule: finite_induct[OF fS])
  1055   case 1
  1056   then show ?case by (auto intro: zero_less_one)
  1057 next
  1058   case (2 x F)
  1059   from 2 obtain d where d: "d >0" "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> d \<le> dist a x"
  1060     by blast
  1061   show ?case
  1062   proof (cases "x = a")
  1063     case True
  1064     then show ?thesis using d by auto
  1065   next
  1066     case False
  1067     let ?d = "min d (dist a x)"
  1068     have dp: "?d > 0"
  1069       using False d(1) using dist_nz by auto
  1070     from d have d': "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> ?d \<le> dist a x"
  1071       by auto
  1072     with dp False show ?thesis
  1073       by (auto intro!: exI[where x="?d"])
  1074   qed
  1075 qed
  1076 
  1077 lemma islimpt_Un: "x islimpt (S \<union> T) \<longleftrightarrow> x islimpt S \<or> x islimpt T"
  1078   by (simp add: islimpt_iff_eventually eventually_conj_iff)
  1079 
  1080 lemma discrete_imp_closed:
  1081   fixes S :: "'a::metric_space set"
  1082   assumes e: "0 < e"
  1083     and d: "\<forall>x \<in> S. \<forall>y \<in> S. dist y x < e \<longrightarrow> y = x"
  1084   shows "closed S"
  1085 proof -
  1086   {
  1087     fix x
  1088     assume C: "\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e"
  1089     from e have e2: "e/2 > 0" by arith
  1090     from C[rule_format, OF e2] obtain y where y: "y \<in> S" "y \<noteq> x" "dist y x < e/2"
  1091       by blast
  1092     let ?m = "min (e/2) (dist x y) "
  1093     from e2 y(2) have mp: "?m > 0"
  1094       by (simp add: dist_nz[symmetric])
  1095     from C[rule_format, OF mp] obtain z where z: "z \<in> S" "z \<noteq> x" "dist z x < ?m"
  1096       by blast
  1097     have th: "dist z y < e" using z y
  1098       by (intro dist_triangle_lt [where z=x], simp)
  1099     from d[rule_format, OF y(1) z(1) th] y z
  1100     have False by (auto simp add: dist_commute)}
  1101   then show ?thesis
  1102     by (metis islimpt_approachable closed_limpt [where 'a='a])
  1103 qed
  1104 
  1105 
  1106 subsection {* Interior of a Set *}
  1107 
  1108 definition "interior S = \<Union>{T. open T \<and> T \<subseteq> S}"
  1109 
  1110 lemma interiorI [intro?]:
  1111   assumes "open T" and "x \<in> T" and "T \<subseteq> S"
  1112   shows "x \<in> interior S"
  1113   using assms unfolding interior_def by fast
  1114 
  1115 lemma interiorE [elim?]:
  1116   assumes "x \<in> interior S"
  1117   obtains T where "open T" and "x \<in> T" and "T \<subseteq> S"
  1118   using assms unfolding interior_def by fast
  1119 
  1120 lemma open_interior [simp, intro]: "open (interior S)"
  1121   by (simp add: interior_def open_Union)
  1122 
  1123 lemma interior_subset: "interior S \<subseteq> S"
  1124   by (auto simp add: interior_def)
  1125 
  1126 lemma interior_maximal: "T \<subseteq> S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> interior S"
  1127   by (auto simp add: interior_def)
  1128 
  1129 lemma interior_open: "open S \<Longrightarrow> interior S = S"
  1130   by (intro equalityI interior_subset interior_maximal subset_refl)
  1131 
  1132 lemma interior_eq: "interior S = S \<longleftrightarrow> open S"
  1133   by (metis open_interior interior_open)
  1134 
  1135 lemma open_subset_interior: "open S \<Longrightarrow> S \<subseteq> interior T \<longleftrightarrow> S \<subseteq> T"
  1136   by (metis interior_maximal interior_subset subset_trans)
  1137 
  1138 lemma interior_empty [simp]: "interior {} = {}"
  1139   using open_empty by (rule interior_open)
  1140 
  1141 lemma interior_UNIV [simp]: "interior UNIV = UNIV"
  1142   using open_UNIV by (rule interior_open)
  1143 
  1144 lemma interior_interior [simp]: "interior (interior S) = interior S"
  1145   using open_interior by (rule interior_open)
  1146 
  1147 lemma interior_mono: "S \<subseteq> T \<Longrightarrow> interior S \<subseteq> interior T"
  1148   by (auto simp add: interior_def)
  1149 
  1150 lemma interior_unique:
  1151   assumes "T \<subseteq> S" and "open T"
  1152   assumes "\<And>T'. T' \<subseteq> S \<Longrightarrow> open T' \<Longrightarrow> T' \<subseteq> T"
  1153   shows "interior S = T"
  1154   by (intro equalityI assms interior_subset open_interior interior_maximal)
  1155 
  1156 lemma interior_inter [simp]: "interior (S \<inter> T) = interior S \<inter> interior T"
  1157   by (intro equalityI Int_mono Int_greatest interior_mono Int_lower1
  1158     Int_lower2 interior_maximal interior_subset open_Int open_interior)
  1159 
  1160 lemma mem_interior: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
  1161   using open_contains_ball_eq [where S="interior S"]
  1162   by (simp add: open_subset_interior)
  1163 
  1164 lemma interior_limit_point [intro]:
  1165   fixes x :: "'a::perfect_space"
  1166   assumes x: "x \<in> interior S"
  1167   shows "x islimpt S"
  1168   using x islimpt_UNIV [of x]
  1169   unfolding interior_def islimpt_def
  1170   apply (clarsimp, rename_tac T T')
  1171   apply (drule_tac x="T \<inter> T'" in spec)
  1172   apply (auto simp add: open_Int)
  1173   done
  1174 
  1175 lemma interior_closed_Un_empty_interior:
  1176   assumes cS: "closed S"
  1177     and iT: "interior T = {}"
  1178   shows "interior (S \<union> T) = interior S"
  1179 proof
  1180   show "interior S \<subseteq> interior (S \<union> T)"
  1181     by (rule interior_mono) (rule Un_upper1)
  1182   show "interior (S \<union> T) \<subseteq> interior S"
  1183   proof
  1184     fix x
  1185     assume "x \<in> interior (S \<union> T)"
  1186     then obtain R where "open R" "x \<in> R" "R \<subseteq> S \<union> T" ..
  1187     show "x \<in> interior S"
  1188     proof (rule ccontr)
  1189       assume "x \<notin> interior S"
  1190       with `x \<in> R` `open R` obtain y where "y \<in> R - S"
  1191         unfolding interior_def by fast
  1192       from `open R` `closed S` have "open (R - S)"
  1193         by (rule open_Diff)
  1194       from `R \<subseteq> S \<union> T` have "R - S \<subseteq> T"
  1195         by fast
  1196       from `y \<in> R - S` `open (R - S)` `R - S \<subseteq> T` `interior T = {}` show False
  1197         unfolding interior_def by fast
  1198     qed
  1199   qed
  1200 qed
  1201 
  1202 lemma interior_Times: "interior (A \<times> B) = interior A \<times> interior B"
  1203 proof (rule interior_unique)
  1204   show "interior A \<times> interior B \<subseteq> A \<times> B"
  1205     by (intro Sigma_mono interior_subset)
  1206   show "open (interior A \<times> interior B)"
  1207     by (intro open_Times open_interior)
  1208   fix T
  1209   assume "T \<subseteq> A \<times> B" and "open T"
  1210   then show "T \<subseteq> interior A \<times> interior B"
  1211   proof safe
  1212     fix x y
  1213     assume "(x, y) \<in> T"
  1214     then obtain C D where "open C" "open D" "C \<times> D \<subseteq> T" "x \<in> C" "y \<in> D"
  1215       using `open T` unfolding open_prod_def by fast
  1216     then have "open C" "open D" "C \<subseteq> A" "D \<subseteq> B" "x \<in> C" "y \<in> D"
  1217       using `T \<subseteq> A \<times> B` by auto
  1218     then show "x \<in> interior A" and "y \<in> interior B"
  1219       by (auto intro: interiorI)
  1220   qed
  1221 qed
  1222 
  1223 
  1224 subsection {* Closure of a Set *}
  1225 
  1226 definition "closure S = S \<union> {x | x. x islimpt S}"
  1227 
  1228 lemma interior_closure: "interior S = - (closure (- S))"
  1229   unfolding interior_def closure_def islimpt_def by auto
  1230 
  1231 lemma closure_interior: "closure S = - interior (- S)"
  1232   unfolding interior_closure by simp
  1233 
  1234 lemma closed_closure[simp, intro]: "closed (closure S)"
  1235   unfolding closure_interior by (simp add: closed_Compl)
  1236 
  1237 lemma closure_subset: "S \<subseteq> closure S"
  1238   unfolding closure_def by simp
  1239 
  1240 lemma closure_hull: "closure S = closed hull S"
  1241   unfolding hull_def closure_interior interior_def by auto
  1242 
  1243 lemma closure_eq: "closure S = S \<longleftrightarrow> closed S"
  1244   unfolding closure_hull using closed_Inter by (rule hull_eq)
  1245 
  1246 lemma closure_closed [simp]: "closed S \<Longrightarrow> closure S = S"
  1247   unfolding closure_eq .
  1248 
  1249 lemma closure_closure [simp]: "closure (closure S) = closure S"
  1250   unfolding closure_hull by (rule hull_hull)
  1251 
  1252 lemma closure_mono: "S \<subseteq> T \<Longrightarrow> closure S \<subseteq> closure T"
  1253   unfolding closure_hull by (rule hull_mono)
  1254 
  1255 lemma closure_minimal: "S \<subseteq> T \<Longrightarrow> closed T \<Longrightarrow> closure S \<subseteq> T"
  1256   unfolding closure_hull by (rule hull_minimal)
  1257 
  1258 lemma closure_unique:
  1259   assumes "S \<subseteq> T"
  1260     and "closed T"
  1261     and "\<And>T'. S \<subseteq> T' \<Longrightarrow> closed T' \<Longrightarrow> T \<subseteq> T'"
  1262   shows "closure S = T"
  1263   using assms unfolding closure_hull by (rule hull_unique)
  1264 
  1265 lemma closure_empty [simp]: "closure {} = {}"
  1266   using closed_empty by (rule closure_closed)
  1267 
  1268 lemma closure_UNIV [simp]: "closure UNIV = UNIV"
  1269   using closed_UNIV by (rule closure_closed)
  1270 
  1271 lemma closure_union [simp]: "closure (S \<union> T) = closure S \<union> closure T"
  1272   unfolding closure_interior by simp
  1273 
  1274 lemma closure_eq_empty: "closure S = {} \<longleftrightarrow> S = {}"
  1275   using closure_empty closure_subset[of S]
  1276   by blast
  1277 
  1278 lemma closure_subset_eq: "closure S \<subseteq> S \<longleftrightarrow> closed S"
  1279   using closure_eq[of S] closure_subset[of S]
  1280   by simp
  1281 
  1282 lemma open_inter_closure_eq_empty:
  1283   "open S \<Longrightarrow> (S \<inter> closure T) = {} \<longleftrightarrow> S \<inter> T = {}"
  1284   using open_subset_interior[of S "- T"]
  1285   using interior_subset[of "- T"]
  1286   unfolding closure_interior
  1287   by auto
  1288 
  1289 lemma open_inter_closure_subset:
  1290   "open S \<Longrightarrow> (S \<inter> (closure T)) \<subseteq> closure(S \<inter> T)"
  1291 proof
  1292   fix x
  1293   assume as: "open S" "x \<in> S \<inter> closure T"
  1294   {
  1295     assume *: "x islimpt T"
  1296     have "x islimpt (S \<inter> T)"
  1297     proof (rule islimptI)
  1298       fix A
  1299       assume "x \<in> A" "open A"
  1300       with as have "x \<in> A \<inter> S" "open (A \<inter> S)"
  1301         by (simp_all add: open_Int)
  1302       with * obtain y where "y \<in> T" "y \<in> A \<inter> S" "y \<noteq> x"
  1303         by (rule islimptE)
  1304       then have "y \<in> S \<inter> T" "y \<in> A \<and> y \<noteq> x"
  1305         by simp_all
  1306       then show "\<exists>y\<in>(S \<inter> T). y \<in> A \<and> y \<noteq> x" ..
  1307     qed
  1308   }
  1309   then show "x \<in> closure (S \<inter> T)" using as
  1310     unfolding closure_def
  1311     by blast
  1312 qed
  1313 
  1314 lemma closure_complement: "closure (- S) = - interior S"
  1315   unfolding closure_interior by simp
  1316 
  1317 lemma interior_complement: "interior (- S) = - closure S"
  1318   unfolding closure_interior by simp
  1319 
  1320 lemma closure_Times: "closure (A \<times> B) = closure A \<times> closure B"
  1321 proof (rule closure_unique)
  1322   show "A \<times> B \<subseteq> closure A \<times> closure B"
  1323     by (intro Sigma_mono closure_subset)
  1324   show "closed (closure A \<times> closure B)"
  1325     by (intro closed_Times closed_closure)
  1326   fix T
  1327   assume "A \<times> B \<subseteq> T" and "closed T"
  1328   then show "closure A \<times> closure B \<subseteq> T"
  1329     apply (simp add: closed_def open_prod_def, clarify)
  1330     apply (rule ccontr)
  1331     apply (drule_tac x="(a, b)" in bspec, simp, clarify, rename_tac C D)
  1332     apply (simp add: closure_interior interior_def)
  1333     apply (drule_tac x=C in spec)
  1334     apply (drule_tac x=D in spec)
  1335     apply auto
  1336     done
  1337 qed
  1338 
  1339 lemma islimpt_in_closure: "(x islimpt S) = (x:closure(S-{x}))"
  1340   unfolding closure_def using islimpt_punctured by blast
  1341 
  1342 
  1343 subsection {* Frontier (aka boundary) *}
  1344 
  1345 definition "frontier S = closure S - interior S"
  1346 
  1347 lemma frontier_closed: "closed (frontier S)"
  1348   by (simp add: frontier_def closed_Diff)
  1349 
  1350 lemma frontier_closures: "frontier S = (closure S) \<inter> (closure(- S))"
  1351   by (auto simp add: frontier_def interior_closure)
  1352 
  1353 lemma frontier_straddle:
  1354   fixes a :: "'a::metric_space"
  1355   shows "a \<in> frontier S \<longleftrightarrow> (\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e))"
  1356   unfolding frontier_def closure_interior
  1357   by (auto simp add: mem_interior subset_eq ball_def)
  1358 
  1359 lemma frontier_subset_closed: "closed S \<Longrightarrow> frontier S \<subseteq> S"
  1360   by (metis frontier_def closure_closed Diff_subset)
  1361 
  1362 lemma frontier_empty[simp]: "frontier {} = {}"
  1363   by (simp add: frontier_def)
  1364 
  1365 lemma frontier_subset_eq: "frontier S \<subseteq> S \<longleftrightarrow> closed S"
  1366 proof-
  1367   {
  1368     assume "frontier S \<subseteq> S"
  1369     then have "closure S \<subseteq> S"
  1370       using interior_subset unfolding frontier_def by auto
  1371     then have "closed S"
  1372       using closure_subset_eq by auto
  1373   }
  1374   then show ?thesis using frontier_subset_closed[of S] ..
  1375 qed
  1376 
  1377 lemma frontier_complement: "frontier(- S) = frontier S"
  1378   by (auto simp add: frontier_def closure_complement interior_complement)
  1379 
  1380 lemma frontier_disjoint_eq: "frontier S \<inter> S = {} \<longleftrightarrow> open S"
  1381   using frontier_complement frontier_subset_eq[of "- S"]
  1382   unfolding open_closed by auto
  1383 
  1384 subsection {* Filters and the ``eventually true'' quantifier *}
  1385 
  1386 definition indirection :: "'a::real_normed_vector \<Rightarrow> 'a \<Rightarrow> 'a filter"
  1387     (infixr "indirection" 70)
  1388   where "a indirection v = at a within {b. \<exists>c\<ge>0. b - a = scaleR c v}"
  1389 
  1390 text {* Identify Trivial limits, where we can't approach arbitrarily closely. *}
  1391 
  1392 lemma trivial_limit_within: "trivial_limit (at a within S) \<longleftrightarrow> \<not> a islimpt S"
  1393 proof
  1394   assume "trivial_limit (at a within S)"
  1395   then show "\<not> a islimpt S"
  1396     unfolding trivial_limit_def
  1397     unfolding eventually_at_topological
  1398     unfolding islimpt_def
  1399     apply (clarsimp simp add: set_eq_iff)
  1400     apply (rename_tac T, rule_tac x=T in exI)
  1401     apply (clarsimp, drule_tac x=y in bspec, simp_all)
  1402     done
  1403 next
  1404   assume "\<not> a islimpt S"
  1405   then show "trivial_limit (at a within S)"
  1406     unfolding trivial_limit_def
  1407     unfolding eventually_at_topological
  1408     unfolding islimpt_def
  1409     apply clarsimp
  1410     apply (rule_tac x=T in exI)
  1411     apply auto
  1412     done
  1413 qed
  1414 
  1415 lemma trivial_limit_at_iff: "trivial_limit (at a) \<longleftrightarrow> \<not> a islimpt UNIV"
  1416   using trivial_limit_within [of a UNIV] by simp
  1417 
  1418 lemma trivial_limit_at:
  1419   fixes a :: "'a::perfect_space"
  1420   shows "\<not> trivial_limit (at a)"
  1421   by (rule at_neq_bot)
  1422 
  1423 lemma trivial_limit_at_infinity:
  1424   "\<not> trivial_limit (at_infinity :: ('a::{real_normed_vector,perfect_space}) filter)"
  1425   unfolding trivial_limit_def eventually_at_infinity
  1426   apply clarsimp
  1427   apply (subgoal_tac "\<exists>x::'a. x \<noteq> 0", clarify)
  1428    apply (rule_tac x="scaleR (b / norm x) x" in exI, simp)
  1429   apply (cut_tac islimpt_UNIV [of "0::'a", unfolded islimpt_def])
  1430   apply (drule_tac x=UNIV in spec, simp)
  1431   done
  1432 
  1433 lemma not_trivial_limit_within: "\<not> trivial_limit (at x within S) = (x \<in> closure (S - {x}))"
  1434   using islimpt_in_closure
  1435   by (metis trivial_limit_within)
  1436 
  1437 text {* Some property holds "sufficiently close" to the limit point. *}
  1438 
  1439 lemma eventually_at2:
  1440   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1441   unfolding eventually_at dist_nz by auto
  1442 
  1443 lemma eventually_happens: "eventually P net \<Longrightarrow> trivial_limit net \<or> (\<exists>x. P x)"
  1444   unfolding trivial_limit_def
  1445   by (auto elim: eventually_rev_mp)
  1446 
  1447 lemma trivial_limit_eventually: "trivial_limit net \<Longrightarrow> eventually P net"
  1448   by simp
  1449 
  1450 lemma trivial_limit_eq: "trivial_limit net \<longleftrightarrow> (\<forall>P. eventually P net)"
  1451   by (simp add: filter_eq_iff)
  1452 
  1453 text{* Combining theorems for "eventually" *}
  1454 
  1455 lemma eventually_rev_mono:
  1456   "eventually P net \<Longrightarrow> (\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually Q net"
  1457   using eventually_mono [of P Q] by fast
  1458 
  1459 lemma not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
  1460   by (simp add: eventually_False)
  1461 
  1462 
  1463 subsection {* Limits *}
  1464 
  1465 lemma Lim:
  1466   "(f ---> l) net \<longleftrightarrow>
  1467         trivial_limit net \<or>
  1468         (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
  1469   unfolding tendsto_iff trivial_limit_eq by auto
  1470 
  1471 text{* Show that they yield usual definitions in the various cases. *}
  1472 
  1473 lemma Lim_within_le: "(f ---> l)(at a within S) \<longleftrightarrow>
  1474     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a \<le> d \<longrightarrow> dist (f x) l < e)"
  1475   by (auto simp add: tendsto_iff eventually_at_le dist_nz)
  1476 
  1477 lemma Lim_within: "(f ---> l) (at a within S) \<longleftrightarrow>
  1478     (\<forall>e >0. \<exists>d>0. \<forall>x \<in> S. 0 < dist x a \<and> dist x a  < d \<longrightarrow> dist (f x) l < e)"
  1479   by (auto simp add: tendsto_iff eventually_at dist_nz)
  1480 
  1481 lemma Lim_at: "(f ---> l) (at a) \<longleftrightarrow>
  1482     (\<forall>e >0. \<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d  \<longrightarrow> dist (f x) l < e)"
  1483   by (auto simp add: tendsto_iff eventually_at2)
  1484 
  1485 lemma Lim_at_infinity:
  1486   "(f ---> l) at_infinity \<longleftrightarrow> (\<forall>e>0. \<exists>b. \<forall>x. norm x \<ge> b \<longrightarrow> dist (f x) l < e)"
  1487   by (auto simp add: tendsto_iff eventually_at_infinity)
  1488 
  1489 lemma Lim_eventually: "eventually (\<lambda>x. f x = l) net \<Longrightarrow> (f ---> l) net"
  1490   by (rule topological_tendstoI, auto elim: eventually_rev_mono)
  1491 
  1492 text{* The expected monotonicity property. *}
  1493 
  1494 lemma Lim_Un:
  1495   assumes "(f ---> l) (at x within S)" "(f ---> l) (at x within T)"
  1496   shows "(f ---> l) (at x within (S \<union> T))"
  1497   using assms unfolding at_within_union by (rule filterlim_sup)
  1498 
  1499 lemma Lim_Un_univ:
  1500   "(f ---> l) (at x within S) \<Longrightarrow> (f ---> l) (at x within T) \<Longrightarrow>
  1501     S \<union> T = UNIV \<Longrightarrow> (f ---> l) (at x)"
  1502   by (metis Lim_Un)
  1503 
  1504 text{* Interrelations between restricted and unrestricted limits. *}
  1505 
  1506 lemma Lim_at_within: (* FIXME: rename *)
  1507   "(f ---> l) (at x) \<Longrightarrow> (f ---> l) (at x within S)"
  1508   by (metis order_refl filterlim_mono subset_UNIV at_le)
  1509 
  1510 lemma eventually_within_interior:
  1511   assumes "x \<in> interior S"
  1512   shows "eventually P (at x within S) \<longleftrightarrow> eventually P (at x)"
  1513   (is "?lhs = ?rhs")
  1514 proof
  1515   from assms obtain T where T: "open T" "x \<in> T" "T \<subseteq> S" ..
  1516   {
  1517     assume "?lhs"
  1518     then obtain A where "open A" and "x \<in> A" and "\<forall>y\<in>A. y \<noteq> x \<longrightarrow> y \<in> S \<longrightarrow> P y"
  1519       unfolding eventually_at_topological
  1520       by auto
  1521     with T have "open (A \<inter> T)" and "x \<in> A \<inter> T" and "\<forall>y \<in> A \<inter> T. y \<noteq> x \<longrightarrow> P y"
  1522       by auto
  1523     then show "?rhs"
  1524       unfolding eventually_at_topological by auto
  1525   next
  1526     assume "?rhs"
  1527     then show "?lhs"
  1528       by (auto elim: eventually_elim1 simp: eventually_at_filter)
  1529   }
  1530 qed
  1531 
  1532 lemma at_within_interior:
  1533   "x \<in> interior S \<Longrightarrow> at x within S = at x"
  1534   unfolding filter_eq_iff by (intro allI eventually_within_interior)
  1535 
  1536 lemma Lim_within_LIMSEQ:
  1537   fixes a :: "'a::first_countable_topology"
  1538   assumes "\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1539   shows "(X ---> L) (at a within T)"
  1540   using assms unfolding tendsto_def [where l=L]
  1541   by (simp add: sequentially_imp_eventually_within)
  1542 
  1543 lemma Lim_right_bound:
  1544   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder, no_top} \<Rightarrow>
  1545     'b::{linorder_topology, conditionally_complete_linorder}"
  1546   assumes mono: "\<And>a b. a \<in> I \<Longrightarrow> b \<in> I \<Longrightarrow> x < a \<Longrightarrow> a \<le> b \<Longrightarrow> f a \<le> f b"
  1547     and bnd: "\<And>a. a \<in> I \<Longrightarrow> x < a \<Longrightarrow> K \<le> f a"
  1548   shows "(f ---> Inf (f ` ({x<..} \<inter> I))) (at x within ({x<..} \<inter> I))"
  1549 proof (cases "{x<..} \<inter> I = {}")
  1550   case True
  1551   then show ?thesis by simp
  1552 next
  1553   case False
  1554   show ?thesis
  1555   proof (rule order_tendstoI)
  1556     fix a
  1557     assume a: "a < Inf (f ` ({x<..} \<inter> I))"
  1558     {
  1559       fix y
  1560       assume "y \<in> {x<..} \<inter> I"
  1561       with False bnd have "Inf (f ` ({x<..} \<inter> I)) \<le> f y"
  1562         by (auto intro!: cInf_lower bdd_belowI2)
  1563       with a have "a < f y"
  1564         by (blast intro: less_le_trans)
  1565     }
  1566     then show "eventually (\<lambda>x. a < f x) (at x within ({x<..} \<inter> I))"
  1567       by (auto simp: eventually_at_filter intro: exI[of _ 1] zero_less_one)
  1568   next
  1569     fix a
  1570     assume "Inf (f ` ({x<..} \<inter> I)) < a"
  1571     from cInf_lessD[OF _ this] False obtain y where y: "x < y" "y \<in> I" "f y < a"
  1572       by auto
  1573     then have "eventually (\<lambda>x. x \<in> I \<longrightarrow> f x < a) (at_right x)"
  1574       unfolding eventually_at_right by (metis less_imp_le le_less_trans mono)
  1575     then show "eventually (\<lambda>x. f x < a) (at x within ({x<..} \<inter> I))"
  1576       unfolding eventually_at_filter by eventually_elim simp
  1577   qed
  1578 qed
  1579 
  1580 text{* Another limit point characterization. *}
  1581 
  1582 lemma islimpt_sequential:
  1583   fixes x :: "'a::first_countable_topology"
  1584   shows "x islimpt S \<longleftrightarrow> (\<exists>f. (\<forall>n::nat. f n \<in> S - {x}) \<and> (f ---> x) sequentially)"
  1585     (is "?lhs = ?rhs")
  1586 proof
  1587   assume ?lhs
  1588   from countable_basis_at_decseq[of x] guess A . note A = this
  1589   def f \<equiv> "\<lambda>n. SOME y. y \<in> S \<and> y \<in> A n \<and> x \<noteq> y"
  1590   {
  1591     fix n
  1592     from `?lhs` have "\<exists>y. y \<in> S \<and> y \<in> A n \<and> x \<noteq> y"
  1593       unfolding islimpt_def using A(1,2)[of n] by auto
  1594     then have "f n \<in> S \<and> f n \<in> A n \<and> x \<noteq> f n"
  1595       unfolding f_def by (rule someI_ex)
  1596     then have "f n \<in> S" "f n \<in> A n" "x \<noteq> f n" by auto
  1597   }
  1598   then have "\<forall>n. f n \<in> S - {x}" by auto
  1599   moreover have "(\<lambda>n. f n) ----> x"
  1600   proof (rule topological_tendstoI)
  1601     fix S
  1602     assume "open S" "x \<in> S"
  1603     from A(3)[OF this] `\<And>n. f n \<in> A n`
  1604     show "eventually (\<lambda>x. f x \<in> S) sequentially"
  1605       by (auto elim!: eventually_elim1)
  1606   qed
  1607   ultimately show ?rhs by fast
  1608 next
  1609   assume ?rhs
  1610   then obtain f :: "nat \<Rightarrow> 'a" where f: "\<And>n. f n \<in> S - {x}" and lim: "f ----> x"
  1611     by auto
  1612   show ?lhs
  1613     unfolding islimpt_def
  1614   proof safe
  1615     fix T
  1616     assume "open T" "x \<in> T"
  1617     from lim[THEN topological_tendstoD, OF this] f
  1618     show "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
  1619       unfolding eventually_sequentially by auto
  1620   qed
  1621 qed
  1622 
  1623 lemma Lim_null:
  1624   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1625   shows "(f ---> l) net \<longleftrightarrow> ((\<lambda>x. f(x) - l) ---> 0) net"
  1626   by (simp add: Lim dist_norm)
  1627 
  1628 lemma Lim_null_comparison:
  1629   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1630   assumes "eventually (\<lambda>x. norm (f x) \<le> g x) net" "(g ---> 0) net"
  1631   shows "(f ---> 0) net"
  1632   using assms(2)
  1633 proof (rule metric_tendsto_imp_tendsto)
  1634   show "eventually (\<lambda>x. dist (f x) 0 \<le> dist (g x) 0) net"
  1635     using assms(1) by (rule eventually_elim1) (simp add: dist_norm)
  1636 qed
  1637 
  1638 lemma Lim_transform_bound:
  1639   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1640     and g :: "'a \<Rightarrow> 'c::real_normed_vector"
  1641   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) net"
  1642     and "(g ---> 0) net"
  1643   shows "(f ---> 0) net"
  1644   using assms(1) tendsto_norm_zero [OF assms(2)]
  1645   by (rule Lim_null_comparison)
  1646 
  1647 text{* Deducing things about the limit from the elements. *}
  1648 
  1649 lemma Lim_in_closed_set:
  1650   assumes "closed S"
  1651     and "eventually (\<lambda>x. f(x) \<in> S) net"
  1652     and "\<not> trivial_limit net" "(f ---> l) net"
  1653   shows "l \<in> S"
  1654 proof (rule ccontr)
  1655   assume "l \<notin> S"
  1656   with `closed S` have "open (- S)" "l \<in> - S"
  1657     by (simp_all add: open_Compl)
  1658   with assms(4) have "eventually (\<lambda>x. f x \<in> - S) net"
  1659     by (rule topological_tendstoD)
  1660   with assms(2) have "eventually (\<lambda>x. False) net"
  1661     by (rule eventually_elim2) simp
  1662   with assms(3) show "False"
  1663     by (simp add: eventually_False)
  1664 qed
  1665 
  1666 text{* Need to prove closed(cball(x,e)) before deducing this as a corollary. *}
  1667 
  1668 lemma Lim_dist_ubound:
  1669   assumes "\<not>(trivial_limit net)"
  1670     and "(f ---> l) net"
  1671     and "eventually (\<lambda>x. dist a (f x) \<le> e) net"
  1672   shows "dist a l \<le> e"
  1673 proof -
  1674   have "dist a l \<in> {..e}"
  1675   proof (rule Lim_in_closed_set)
  1676     show "closed {..e}"
  1677       by simp
  1678     show "eventually (\<lambda>x. dist a (f x) \<in> {..e}) net"
  1679       by (simp add: assms)
  1680     show "\<not> trivial_limit net"
  1681       by fact
  1682     show "((\<lambda>x. dist a (f x)) ---> dist a l) net"
  1683       by (intro tendsto_intros assms)
  1684   qed
  1685   then show ?thesis by simp
  1686 qed
  1687 
  1688 lemma Lim_norm_ubound:
  1689   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1690   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. norm(f x) \<le> e) net"
  1691   shows "norm(l) \<le> e"
  1692 proof -
  1693   have "norm l \<in> {..e}"
  1694   proof (rule Lim_in_closed_set)
  1695     show "closed {..e}"
  1696       by simp
  1697     show "eventually (\<lambda>x. norm (f x) \<in> {..e}) net"
  1698       by (simp add: assms)
  1699     show "\<not> trivial_limit net"
  1700       by fact
  1701     show "((\<lambda>x. norm (f x)) ---> norm l) net"
  1702       by (intro tendsto_intros assms)
  1703   qed
  1704   then show ?thesis by simp
  1705 qed
  1706 
  1707 lemma Lim_norm_lbound:
  1708   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1709   assumes "\<not> trivial_limit net"
  1710     and "(f ---> l) net"
  1711     and "eventually (\<lambda>x. e \<le> norm (f x)) net"
  1712   shows "e \<le> norm l"
  1713 proof -
  1714   have "norm l \<in> {e..}"
  1715   proof (rule Lim_in_closed_set)
  1716     show "closed {e..}"
  1717       by simp
  1718     show "eventually (\<lambda>x. norm (f x) \<in> {e..}) net"
  1719       by (simp add: assms)
  1720     show "\<not> trivial_limit net"
  1721       by fact
  1722     show "((\<lambda>x. norm (f x)) ---> norm l) net"
  1723       by (intro tendsto_intros assms)
  1724   qed
  1725   then show ?thesis by simp
  1726 qed
  1727 
  1728 text{* Limit under bilinear function *}
  1729 
  1730 lemma Lim_bilinear:
  1731   assumes "(f ---> l) net"
  1732     and "(g ---> m) net"
  1733     and "bounded_bilinear h"
  1734   shows "((\<lambda>x. h (f x) (g x)) ---> (h l m)) net"
  1735   using `bounded_bilinear h` `(f ---> l) net` `(g ---> m) net`
  1736   by (rule bounded_bilinear.tendsto)
  1737 
  1738 text{* These are special for limits out of the same vector space. *}
  1739 
  1740 lemma Lim_within_id: "(id ---> a) (at a within s)"
  1741   unfolding id_def by (rule tendsto_ident_at)
  1742 
  1743 lemma Lim_at_id: "(id ---> a) (at a)"
  1744   unfolding id_def by (rule tendsto_ident_at)
  1745 
  1746 lemma Lim_at_zero:
  1747   fixes a :: "'a::real_normed_vector"
  1748     and l :: "'b::topological_space"
  1749   shows "(f ---> l) (at a) \<longleftrightarrow> ((\<lambda>x. f(a + x)) ---> l) (at 0)"
  1750   using LIM_offset_zero LIM_offset_zero_cancel ..
  1751 
  1752 text{* It's also sometimes useful to extract the limit point from the filter. *}
  1753 
  1754 abbreviation netlimit :: "'a::t2_space filter \<Rightarrow> 'a"
  1755   where "netlimit F \<equiv> Lim F (\<lambda>x. x)"
  1756 
  1757 lemma netlimit_within: "\<not> trivial_limit (at a within S) \<Longrightarrow> netlimit (at a within S) = a"
  1758   by (rule tendsto_Lim) (auto intro: tendsto_intros)
  1759 
  1760 lemma netlimit_at:
  1761   fixes a :: "'a::{perfect_space,t2_space}"
  1762   shows "netlimit (at a) = a"
  1763   using netlimit_within [of a UNIV] by simp
  1764 
  1765 lemma lim_within_interior:
  1766   "x \<in> interior S \<Longrightarrow> (f ---> l) (at x within S) \<longleftrightarrow> (f ---> l) (at x)"
  1767   by (metis at_within_interior)
  1768 
  1769 lemma netlimit_within_interior:
  1770   fixes x :: "'a::{t2_space,perfect_space}"
  1771   assumes "x \<in> interior S"
  1772   shows "netlimit (at x within S) = x"
  1773   using assms by (metis at_within_interior netlimit_at)
  1774 
  1775 text{* Transformation of limit. *}
  1776 
  1777 lemma Lim_transform:
  1778   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  1779   assumes "((\<lambda>x. f x - g x) ---> 0) net" "(f ---> l) net"
  1780   shows "(g ---> l) net"
  1781   using tendsto_diff [OF assms(2) assms(1)] by simp
  1782 
  1783 lemma Lim_transform_eventually:
  1784   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1785   apply (rule topological_tendstoI)
  1786   apply (drule (2) topological_tendstoD)
  1787   apply (erule (1) eventually_elim2, simp)
  1788   done
  1789 
  1790 lemma Lim_transform_within:
  1791   assumes "0 < d"
  1792     and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1793     and "(f ---> l) (at x within S)"
  1794   shows "(g ---> l) (at x within S)"
  1795 proof (rule Lim_transform_eventually)
  1796   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1797     using assms(1,2) by (auto simp: dist_nz eventually_at)
  1798   show "(f ---> l) (at x within S)" by fact
  1799 qed
  1800 
  1801 lemma Lim_transform_at:
  1802   assumes "0 < d"
  1803     and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1804     and "(f ---> l) (at x)"
  1805   shows "(g ---> l) (at x)"
  1806   using _ assms(3)
  1807 proof (rule Lim_transform_eventually)
  1808   show "eventually (\<lambda>x. f x = g x) (at x)"
  1809     unfolding eventually_at2
  1810     using assms(1,2) by auto
  1811 qed
  1812 
  1813 text{* Common case assuming being away from some crucial point like 0. *}
  1814 
  1815 lemma Lim_transform_away_within:
  1816   fixes a b :: "'a::t1_space"
  1817   assumes "a \<noteq> b"
  1818     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1819     and "(f ---> l) (at a within S)"
  1820   shows "(g ---> l) (at a within S)"
  1821 proof (rule Lim_transform_eventually)
  1822   show "(f ---> l) (at a within S)" by fact
  1823   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1824     unfolding eventually_at_topological
  1825     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1826 qed
  1827 
  1828 lemma Lim_transform_away_at:
  1829   fixes a b :: "'a::t1_space"
  1830   assumes ab: "a\<noteq>b"
  1831     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1832     and fl: "(f ---> l) (at a)"
  1833   shows "(g ---> l) (at a)"
  1834   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1835 
  1836 text{* Alternatively, within an open set. *}
  1837 
  1838 lemma Lim_transform_within_open:
  1839   assumes "open S" and "a \<in> S"
  1840     and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1841     and "(f ---> l) (at a)"
  1842   shows "(g ---> l) (at a)"
  1843 proof (rule Lim_transform_eventually)
  1844   show "eventually (\<lambda>x. f x = g x) (at a)"
  1845     unfolding eventually_at_topological
  1846     using assms(1,2,3) by auto
  1847   show "(f ---> l) (at a)" by fact
  1848 qed
  1849 
  1850 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  1851 
  1852 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1853 
  1854 lemma Lim_cong_within(*[cong add]*):
  1855   assumes "a = b"
  1856     and "x = y"
  1857     and "S = T"
  1858     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1859   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1860   unfolding tendsto_def eventually_at_topological
  1861   using assms by simp
  1862 
  1863 lemma Lim_cong_at(*[cong add]*):
  1864   assumes "a = b" "x = y"
  1865     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1866   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1867   unfolding tendsto_def eventually_at_topological
  1868   using assms by simp
  1869 
  1870 text{* Useful lemmas on closure and set of possible sequential limits.*}
  1871 
  1872 lemma closure_sequential:
  1873   fixes l :: "'a::first_countable_topology"
  1874   shows "l \<in> closure S \<longleftrightarrow> (\<exists>x. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially)"
  1875   (is "?lhs = ?rhs")
  1876 proof
  1877   assume "?lhs"
  1878   moreover
  1879   {
  1880     assume "l \<in> S"
  1881     then have "?rhs" using tendsto_const[of l sequentially] by auto
  1882   }
  1883   moreover
  1884   {
  1885     assume "l islimpt S"
  1886     then have "?rhs" unfolding islimpt_sequential by auto
  1887   }
  1888   ultimately show "?rhs"
  1889     unfolding closure_def by auto
  1890 next
  1891   assume "?rhs"
  1892   then show "?lhs" unfolding closure_def islimpt_sequential by auto
  1893 qed
  1894 
  1895 lemma closed_sequential_limits:
  1896   fixes S :: "'a::first_countable_topology set"
  1897   shows "closed S \<longleftrightarrow> (\<forall>x l. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially \<longrightarrow> l \<in> S)"
  1898   using closure_sequential [where 'a='a] closure_closed [where 'a='a]
  1899     closed_limpt [where 'a='a] islimpt_sequential [where 'a='a] mem_delete [where 'a='a]
  1900   by metis
  1901 
  1902 lemma closure_approachable:
  1903   fixes S :: "'a::metric_space set"
  1904   shows "x \<in> closure S \<longleftrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e)"
  1905   apply (auto simp add: closure_def islimpt_approachable)
  1906   apply (metis dist_self)
  1907   done
  1908 
  1909 lemma closed_approachable:
  1910   fixes S :: "'a::metric_space set"
  1911   shows "closed S \<Longrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e) \<longleftrightarrow> x \<in> S"
  1912   by (metis closure_closed closure_approachable)
  1913 
  1914 lemma closure_contains_Inf:
  1915   fixes S :: "real set"
  1916   assumes "S \<noteq> {}" "bdd_below S"
  1917   shows "Inf S \<in> closure S"
  1918 proof -
  1919   have *: "\<forall>x\<in>S. Inf S \<le> x"
  1920     using cInf_lower[of _ S] assms by metis
  1921   {
  1922     fix e :: real
  1923     assume "e > 0"
  1924     then have "Inf S < Inf S + e" by simp
  1925     with assms obtain x where "x \<in> S" "x < Inf S + e"
  1926       by (subst (asm) cInf_less_iff) auto
  1927     with * have "\<exists>x\<in>S. dist x (Inf S) < e"
  1928       by (intro bexI[of _ x]) (auto simp add: dist_real_def)
  1929   }
  1930   then show ?thesis unfolding closure_approachable by auto
  1931 qed
  1932 
  1933 lemma closed_contains_Inf:
  1934   fixes S :: "real set"
  1935   shows "S \<noteq> {} \<Longrightarrow> bdd_below S \<Longrightarrow> closed S \<Longrightarrow> Inf S \<in> S"
  1936   by (metis closure_contains_Inf closure_closed assms)
  1937 
  1938 lemma not_trivial_limit_within_ball:
  1939   "\<not> trivial_limit (at x within S) \<longleftrightarrow> (\<forall>e>0. S \<inter> ball x e - {x} \<noteq> {})"
  1940   (is "?lhs = ?rhs")
  1941 proof -
  1942   {
  1943     assume "?lhs"
  1944     {
  1945       fix e :: real
  1946       assume "e > 0"
  1947       then obtain y where "y \<in> S - {x}" and "dist y x < e"
  1948         using `?lhs` not_trivial_limit_within[of x S] closure_approachable[of x "S - {x}"]
  1949         by auto
  1950       then have "y \<in> S \<inter> ball x e - {x}"
  1951         unfolding ball_def by (simp add: dist_commute)
  1952       then have "S \<inter> ball x e - {x} \<noteq> {}" by blast
  1953     }
  1954     then have "?rhs" by auto
  1955   }
  1956   moreover
  1957   {
  1958     assume "?rhs"
  1959     {
  1960       fix e :: real
  1961       assume "e > 0"
  1962       then obtain y where "y \<in> S \<inter> ball x e - {x}"
  1963         using `?rhs` by blast
  1964       then have "y \<in> S - {x}" and "dist y x < e"
  1965         unfolding ball_def by (simp_all add: dist_commute)
  1966       then have "\<exists>y \<in> S - {x}. dist y x < e"
  1967         by auto
  1968     }
  1969     then have "?lhs"
  1970       using not_trivial_limit_within[of x S] closure_approachable[of x "S - {x}"]
  1971       by auto
  1972   }
  1973   ultimately show ?thesis by auto
  1974 qed
  1975 
  1976 
  1977 subsection {* Infimum Distance *}
  1978 
  1979 definition "infdist x A = (if A = {} then 0 else INF a:A. dist x a)"
  1980 
  1981 lemma bdd_below_infdist[intro, simp]: "bdd_below (dist x`A)"
  1982   by (auto intro!: zero_le_dist)
  1983 
  1984 lemma infdist_notempty: "A \<noteq> {} \<Longrightarrow> infdist x A = (INF a:A. dist x a)"
  1985   by (simp add: infdist_def)
  1986 
  1987 lemma infdist_nonneg: "0 \<le> infdist x A"
  1988   by (auto simp add: infdist_def intro: cINF_greatest)
  1989 
  1990 lemma infdist_le: "a \<in> A \<Longrightarrow> infdist x A \<le> dist x a"
  1991   by (auto intro: cINF_lower simp add: infdist_def)
  1992 
  1993 lemma infdist_le2: "a \<in> A \<Longrightarrow> dist x a \<le> d \<Longrightarrow> infdist x A \<le> d"
  1994   by (auto intro!: cINF_lower2 simp add: infdist_def)
  1995 
  1996 lemma infdist_zero[simp]: "a \<in> A \<Longrightarrow> infdist a A = 0"
  1997   by (auto intro!: antisym infdist_nonneg infdist_le2)
  1998 
  1999 lemma infdist_triangle: "infdist x A \<le> infdist y A + dist x y"
  2000 proof (cases "A = {}")
  2001   case True
  2002   then show ?thesis by (simp add: infdist_def)
  2003 next
  2004   case False
  2005   then obtain a where "a \<in> A" by auto
  2006   have "infdist x A \<le> Inf {dist x y + dist y a |a. a \<in> A}"
  2007   proof (rule cInf_greatest)
  2008     from `A \<noteq> {}` show "{dist x y + dist y a |a. a \<in> A} \<noteq> {}"
  2009       by simp
  2010     fix d
  2011     assume "d \<in> {dist x y + dist y a |a. a \<in> A}"
  2012     then obtain a where d: "d = dist x y + dist y a" "a \<in> A"
  2013       by auto
  2014     show "infdist x A \<le> d"
  2015       unfolding infdist_notempty[OF `A \<noteq> {}`]
  2016     proof (rule cINF_lower2)
  2017       show "a \<in> A" by fact
  2018       show "dist x a \<le> d"
  2019         unfolding d by (rule dist_triangle)
  2020     qed simp
  2021   qed
  2022   also have "\<dots> = dist x y + infdist y A"
  2023   proof (rule cInf_eq, safe)
  2024     fix a
  2025     assume "a \<in> A"
  2026     then show "dist x y + infdist y A \<le> dist x y + dist y a"
  2027       by (auto intro: infdist_le)
  2028   next
  2029     fix i
  2030     assume inf: "\<And>d. d \<in> {dist x y + dist y a |a. a \<in> A} \<Longrightarrow> i \<le> d"
  2031     then have "i - dist x y \<le> infdist y A"
  2032       unfolding infdist_notempty[OF `A \<noteq> {}`] using `a \<in> A`
  2033       by (intro cINF_greatest) (auto simp: field_simps)
  2034     then show "i \<le> dist x y + infdist y A"
  2035       by simp
  2036   qed
  2037   finally show ?thesis by simp
  2038 qed
  2039 
  2040 lemma in_closure_iff_infdist_zero:
  2041   assumes "A \<noteq> {}"
  2042   shows "x \<in> closure A \<longleftrightarrow> infdist x A = 0"
  2043 proof
  2044   assume "x \<in> closure A"
  2045   show "infdist x A = 0"
  2046   proof (rule ccontr)
  2047     assume "infdist x A \<noteq> 0"
  2048     with infdist_nonneg[of x A] have "infdist x A > 0"
  2049       by auto
  2050     then have "ball x (infdist x A) \<inter> closure A = {}"
  2051       apply auto
  2052       apply (metis `x \<in> closure A` closure_approachable dist_commute infdist_le not_less)
  2053       done
  2054     then have "x \<notin> closure A"
  2055       by (metis `0 < infdist x A` centre_in_ball disjoint_iff_not_equal)
  2056     then show False using `x \<in> closure A` by simp
  2057   qed
  2058 next
  2059   assume x: "infdist x A = 0"
  2060   then obtain a where "a \<in> A"
  2061     by atomize_elim (metis all_not_in_conv assms)
  2062   show "x \<in> closure A"
  2063     unfolding closure_approachable
  2064     apply safe
  2065   proof (rule ccontr)
  2066     fix e :: real
  2067     assume "e > 0"
  2068     assume "\<not> (\<exists>y\<in>A. dist y x < e)"
  2069     then have "infdist x A \<ge> e" using `a \<in> A`
  2070       unfolding infdist_def
  2071       by (force simp: dist_commute intro: cINF_greatest)
  2072     with x `e > 0` show False by auto
  2073   qed
  2074 qed
  2075 
  2076 lemma in_closed_iff_infdist_zero:
  2077   assumes "closed A" "A \<noteq> {}"
  2078   shows "x \<in> A \<longleftrightarrow> infdist x A = 0"
  2079 proof -
  2080   have "x \<in> closure A \<longleftrightarrow> infdist x A = 0"
  2081     by (rule in_closure_iff_infdist_zero) fact
  2082   with assms show ?thesis by simp
  2083 qed
  2084 
  2085 lemma tendsto_infdist [tendsto_intros]:
  2086   assumes f: "(f ---> l) F"
  2087   shows "((\<lambda>x. infdist (f x) A) ---> infdist l A) F"
  2088 proof (rule tendstoI)
  2089   fix e ::real
  2090   assume "e > 0"
  2091   from tendstoD[OF f this]
  2092   show "eventually (\<lambda>x. dist (infdist (f x) A) (infdist l A) < e) F"
  2093   proof (eventually_elim)
  2094     fix x
  2095     from infdist_triangle[of l A "f x"] infdist_triangle[of "f x" A l]
  2096     have "dist (infdist (f x) A) (infdist l A) \<le> dist (f x) l"
  2097       by (simp add: dist_commute dist_real_def)
  2098     also assume "dist (f x) l < e"
  2099     finally show "dist (infdist (f x) A) (infdist l A) < e" .
  2100   qed
  2101 qed
  2102 
  2103 text{* Some other lemmas about sequences. *}
  2104 
  2105 lemma sequentially_offset: (* TODO: move to Topological_Spaces.thy *)
  2106   assumes "eventually (\<lambda>i. P i) sequentially"
  2107   shows "eventually (\<lambda>i. P (i + k)) sequentially"
  2108   using assms by (rule eventually_sequentially_seg [THEN iffD2])
  2109 
  2110 lemma seq_offset_neg: (* TODO: move to Topological_Spaces.thy *)
  2111   "(f ---> l) sequentially \<Longrightarrow> ((\<lambda>i. f(i - k)) ---> l) sequentially"
  2112   apply (erule filterlim_compose)
  2113   apply (simp add: filterlim_def le_sequentially eventually_filtermap eventually_sequentially)
  2114   apply arith
  2115   done
  2116 
  2117 lemma seq_harmonic: "((\<lambda>n. inverse (real n)) ---> 0) sequentially"
  2118   using LIMSEQ_inverse_real_of_nat by (rule LIMSEQ_imp_Suc) (* TODO: move to Limits.thy *)
  2119 
  2120 subsection {* More properties of closed balls *}
  2121 
  2122 lemma closed_vimage: (* TODO: move to Topological_Spaces.thy *)
  2123   assumes "closed s" and "continuous_on UNIV f"
  2124   shows "closed (vimage f s)"
  2125   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  2126   by simp
  2127 
  2128 lemma closed_cball: "closed (cball x e)"
  2129 proof -
  2130   have "closed (dist x -` {..e})"
  2131     by (intro closed_vimage closed_atMost continuous_on_intros)
  2132   also have "dist x -` {..e} = cball x e"
  2133     by auto
  2134   finally show ?thesis .
  2135 qed
  2136 
  2137 lemma open_contains_cball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0.  cball x e \<subseteq> S)"
  2138 proof -
  2139   {
  2140     fix x and e::real
  2141     assume "x\<in>S" "e>0" "ball x e \<subseteq> S"
  2142     then have "\<exists>d>0. cball x d \<subseteq> S" unfolding subset_eq by (rule_tac x="e/2" in exI, auto)
  2143   }
  2144   moreover
  2145   {
  2146     fix x and e::real
  2147     assume "x\<in>S" "e>0" "cball x e \<subseteq> S"
  2148     then have "\<exists>d>0. ball x d \<subseteq> S"
  2149       unfolding subset_eq
  2150       apply(rule_tac x="e/2" in exI)
  2151       apply auto
  2152       done
  2153   }
  2154   ultimately show ?thesis
  2155     unfolding open_contains_ball by auto
  2156 qed
  2157 
  2158 lemma open_contains_cball_eq: "open S \<Longrightarrow> (\<forall>x. x \<in> S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S))"
  2159   by (metis open_contains_cball subset_eq order_less_imp_le centre_in_cball)
  2160 
  2161 lemma mem_interior_cball: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S)"
  2162   apply (simp add: interior_def, safe)
  2163   apply (force simp add: open_contains_cball)
  2164   apply (rule_tac x="ball x e" in exI)
  2165   apply (simp add: subset_trans [OF ball_subset_cball])
  2166   done
  2167 
  2168 lemma islimpt_ball:
  2169   fixes x y :: "'a::{real_normed_vector,perfect_space}"
  2170   shows "y islimpt ball x e \<longleftrightarrow> 0 < e \<and> y \<in> cball x e"
  2171   (is "?lhs = ?rhs")
  2172 proof
  2173   assume "?lhs"
  2174   {
  2175     assume "e \<le> 0"
  2176     then have *:"ball x e = {}"
  2177       using ball_eq_empty[of x e] by auto
  2178     have False using `?lhs`
  2179       unfolding * using islimpt_EMPTY[of y] by auto
  2180   }
  2181   then have "e > 0" by (metis not_less)
  2182   moreover
  2183   have "y \<in> cball x e"
  2184     using closed_cball[of x e] islimpt_subset[of y "ball x e" "cball x e"]
  2185       ball_subset_cball[of x e] `?lhs`
  2186     unfolding closed_limpt by auto
  2187   ultimately show "?rhs" by auto
  2188 next
  2189   assume "?rhs"
  2190   then have "e > 0" by auto
  2191   {
  2192     fix d :: real
  2193     assume "d > 0"
  2194     have "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2195     proof (cases "d \<le> dist x y")
  2196       case True
  2197       then show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2198       proof (cases "x = y")
  2199         case True
  2200         then have False
  2201           using `d \<le> dist x y` `d>0` by auto
  2202         then show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2203           by auto
  2204       next
  2205         case False
  2206         have "dist x (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) =
  2207           norm (x - y + (d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  2208           unfolding mem_cball mem_ball dist_norm diff_diff_eq2 diff_add_eq[symmetric]
  2209           by auto
  2210         also have "\<dots> = \<bar>- 1 + d / (2 * norm (x - y))\<bar> * norm (x - y)"
  2211           using scaleR_left_distrib[of "- 1" "d / (2 * norm (y - x))", symmetric, of "y - x"]
  2212           unfolding scaleR_minus_left scaleR_one
  2213           by (auto simp add: norm_minus_commute)
  2214         also have "\<dots> = \<bar>- norm (x - y) + d / 2\<bar>"
  2215           unfolding abs_mult_pos[of "norm (x - y)", OF norm_ge_zero[of "x - y"]]
  2216           unfolding distrib_right using `x\<noteq>y`[unfolded dist_nz, unfolded dist_norm]
  2217           by auto
  2218         also have "\<dots> \<le> e - d/2" using `d \<le> dist x y` and `d>0` and `?rhs`
  2219           by (auto simp add: dist_norm)
  2220         finally have "y - (d / (2 * dist y x)) *\<^sub>R (y - x) \<in> ball x e" using `d>0`
  2221           by auto
  2222         moreover
  2223         have "(d / (2*dist y x)) *\<^sub>R (y - x) \<noteq> 0"
  2224           using `x\<noteq>y`[unfolded dist_nz] `d>0` unfolding scaleR_eq_0_iff
  2225           by (auto simp add: dist_commute)
  2226         moreover
  2227         have "dist (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) y < d"
  2228           unfolding dist_norm
  2229           apply simp
  2230           unfolding norm_minus_cancel
  2231           using `d > 0` `x\<noteq>y`[unfolded dist_nz] dist_commute[of x y]
  2232           unfolding dist_norm
  2233           apply auto
  2234           done
  2235         ultimately show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2236           apply (rule_tac x = "y - (d / (2*dist y x)) *\<^sub>R (y - x)" in bexI)
  2237           apply auto
  2238           done
  2239       qed
  2240     next
  2241       case False
  2242       then have "d > dist x y" by auto
  2243       show "\<exists>x' \<in> ball x e. x' \<noteq> y \<and> dist x' y < d"
  2244       proof (cases "x = y")
  2245         case True
  2246         obtain z where **: "z \<noteq> y" "dist z y < min e d"
  2247           using perfect_choose_dist[of "min e d" y]
  2248           using `d > 0` `e>0` by auto
  2249         show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2250           unfolding `x = y`
  2251           using `z \<noteq> y` **
  2252           apply (rule_tac x=z in bexI)
  2253           apply (auto simp add: dist_commute)
  2254           done
  2255       next
  2256         case False
  2257         then show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2258           using `d>0` `d > dist x y` `?rhs`
  2259           apply (rule_tac x=x in bexI)
  2260           apply auto
  2261           done
  2262       qed
  2263     qed
  2264   }
  2265   then show "?lhs"
  2266     unfolding mem_cball islimpt_approachable mem_ball by auto
  2267 qed
  2268 
  2269 lemma closure_ball_lemma:
  2270   fixes x y :: "'a::real_normed_vector"
  2271   assumes "x \<noteq> y"
  2272   shows "y islimpt ball x (dist x y)"
  2273 proof (rule islimptI)
  2274   fix T
  2275   assume "y \<in> T" "open T"
  2276   then obtain r where "0 < r" "\<forall>z. dist z y < r \<longrightarrow> z \<in> T"
  2277     unfolding open_dist by fast
  2278   (* choose point between x and y, within distance r of y. *)
  2279   def k \<equiv> "min 1 (r / (2 * dist x y))"
  2280   def z \<equiv> "y + scaleR k (x - y)"
  2281   have z_def2: "z = x + scaleR (1 - k) (y - x)"
  2282     unfolding z_def by (simp add: algebra_simps)
  2283   have "dist z y < r"
  2284     unfolding z_def k_def using `0 < r`
  2285     by (simp add: dist_norm min_def)
  2286   then have "z \<in> T"
  2287     using `\<forall>z. dist z y < r \<longrightarrow> z \<in> T` by simp
  2288   have "dist x z < dist x y"
  2289     unfolding z_def2 dist_norm
  2290     apply (simp add: norm_minus_commute)
  2291     apply (simp only: dist_norm [symmetric])
  2292     apply (subgoal_tac "\<bar>1 - k\<bar> * dist x y < 1 * dist x y", simp)
  2293     apply (rule mult_strict_right_mono)
  2294     apply (simp add: k_def divide_pos_pos zero_less_dist_iff `0 < r` `x \<noteq> y`)
  2295     apply (simp add: zero_less_dist_iff `x \<noteq> y`)
  2296     done
  2297   then have "z \<in> ball x (dist x y)"
  2298     by simp
  2299   have "z \<noteq> y"
  2300     unfolding z_def k_def using `x \<noteq> y` `0 < r`
  2301     by (simp add: min_def)
  2302   show "\<exists>z\<in>ball x (dist x y). z \<in> T \<and> z \<noteq> y"
  2303     using `z \<in> ball x (dist x y)` `z \<in> T` `z \<noteq> y`
  2304     by fast
  2305 qed
  2306 
  2307 lemma closure_ball:
  2308   fixes x :: "'a::real_normed_vector"
  2309   shows "0 < e \<Longrightarrow> closure (ball x e) = cball x e"
  2310   apply (rule equalityI)
  2311   apply (rule closure_minimal)
  2312   apply (rule ball_subset_cball)
  2313   apply (rule closed_cball)
  2314   apply (rule subsetI, rename_tac y)
  2315   apply (simp add: le_less [where 'a=real])
  2316   apply (erule disjE)
  2317   apply (rule subsetD [OF closure_subset], simp)
  2318   apply (simp add: closure_def)
  2319   apply clarify
  2320   apply (rule closure_ball_lemma)
  2321   apply (simp add: zero_less_dist_iff)
  2322   done
  2323 
  2324 (* In a trivial vector space, this fails for e = 0. *)
  2325 lemma interior_cball:
  2326   fixes x :: "'a::{real_normed_vector, perfect_space}"
  2327   shows "interior (cball x e) = ball x e"
  2328 proof (cases "e \<ge> 0")
  2329   case False note cs = this
  2330   from cs have "ball x e = {}"
  2331     using ball_empty[of e x] by auto
  2332   moreover
  2333   {
  2334     fix y
  2335     assume "y \<in> cball x e"
  2336     then have False
  2337       unfolding mem_cball using dist_nz[of x y] cs by auto
  2338   }
  2339   then have "cball x e = {}" by auto
  2340   then have "interior (cball x e) = {}"
  2341     using interior_empty by auto
  2342   ultimately show ?thesis by blast
  2343 next
  2344   case True note cs = this
  2345   have "ball x e \<subseteq> cball x e"
  2346     using ball_subset_cball by auto
  2347   moreover
  2348   {
  2349     fix S y
  2350     assume as: "S \<subseteq> cball x e" "open S" "y\<in>S"
  2351     then obtain d where "d>0" and d: "\<forall>x'. dist x' y < d \<longrightarrow> x' \<in> S"
  2352       unfolding open_dist by blast
  2353     then obtain xa where xa_y: "xa \<noteq> y" and xa: "dist xa y < d"
  2354       using perfect_choose_dist [of d] by auto
  2355     have "xa \<in> S"
  2356       using d[THEN spec[where x = xa]]
  2357       using xa by (auto simp add: dist_commute)
  2358     then have xa_cball: "xa \<in> cball x e"
  2359       using as(1) by auto
  2360     then have "y \<in> ball x e"
  2361     proof (cases "x = y")
  2362       case True
  2363       then have "e > 0"
  2364         using xa_y[unfolded dist_nz] xa_cball[unfolded mem_cball]
  2365         by (auto simp add: dist_commute)
  2366       then show "y \<in> ball x e"
  2367         using `x = y ` by simp
  2368     next
  2369       case False
  2370       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) y < d"
  2371         unfolding dist_norm
  2372         using `d>0` norm_ge_zero[of "y - x"] `x \<noteq> y` by auto
  2373       then have *: "y + (d / 2 / dist y x) *\<^sub>R (y - x) \<in> cball x e"
  2374         using d as(1)[unfolded subset_eq] by blast
  2375       have "y - x \<noteq> 0" using `x \<noteq> y` by auto
  2376       then have **:"d / (2 * norm (y - x)) > 0"
  2377         unfolding zero_less_norm_iff[symmetric]
  2378         using `d>0` divide_pos_pos[of d "2*norm (y - x)"] by auto
  2379       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) x =
  2380         norm (y + (d / (2 * norm (y - x))) *\<^sub>R y - (d / (2 * norm (y - x))) *\<^sub>R x - x)"
  2381         by (auto simp add: dist_norm algebra_simps)
  2382       also have "\<dots> = norm ((1 + d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  2383         by (auto simp add: algebra_simps)
  2384       also have "\<dots> = \<bar>1 + d / (2 * norm (y - x))\<bar> * norm (y - x)"
  2385         using ** by auto
  2386       also have "\<dots> = (dist y x) + d/2"
  2387         using ** by (auto simp add: distrib_right dist_norm)
  2388       finally have "e \<ge> dist x y +d/2"
  2389         using *[unfolded mem_cball] by (auto simp add: dist_commute)
  2390       then show "y \<in> ball x e"
  2391         unfolding mem_ball using `d>0` by auto
  2392     qed
  2393   }
  2394   then have "\<forall>S \<subseteq> cball x e. open S \<longrightarrow> S \<subseteq> ball x e"
  2395     by auto
  2396   ultimately show ?thesis
  2397     using interior_unique[of "ball x e" "cball x e"]
  2398     using open_ball[of x e]
  2399     by auto
  2400 qed
  2401 
  2402 lemma frontier_ball:
  2403   fixes a :: "'a::real_normed_vector"
  2404   shows "0 < e \<Longrightarrow> frontier(ball a e) = {x. dist a x = e}"
  2405   apply (simp add: frontier_def closure_ball interior_open order_less_imp_le)
  2406   apply (simp add: set_eq_iff)
  2407   apply arith
  2408   done
  2409 
  2410 lemma frontier_cball:
  2411   fixes a :: "'a::{real_normed_vector, perfect_space}"
  2412   shows "frontier (cball a e) = {x. dist a x = e}"
  2413   apply (simp add: frontier_def interior_cball closed_cball order_less_imp_le)
  2414   apply (simp add: set_eq_iff)
  2415   apply arith
  2416   done
  2417 
  2418 lemma cball_eq_empty: "cball x e = {} \<longleftrightarrow> e < 0"
  2419   apply (simp add: set_eq_iff not_le)
  2420   apply (metis zero_le_dist dist_self order_less_le_trans)
  2421   done
  2422 
  2423 lemma cball_empty: "e < 0 \<Longrightarrow> cball x e = {}"
  2424   by (simp add: cball_eq_empty)
  2425 
  2426 lemma cball_eq_sing:
  2427   fixes x :: "'a::{metric_space,perfect_space}"
  2428   shows "cball x e = {x} \<longleftrightarrow> e = 0"
  2429 proof (rule linorder_cases)
  2430   assume e: "0 < e"
  2431   obtain a where "a \<noteq> x" "dist a x < e"
  2432     using perfect_choose_dist [OF e] by auto
  2433   then have "a \<noteq> x" "dist x a \<le> e"
  2434     by (auto simp add: dist_commute)
  2435   with e show ?thesis by (auto simp add: set_eq_iff)
  2436 qed auto
  2437 
  2438 lemma cball_sing:
  2439   fixes x :: "'a::metric_space"
  2440   shows "e = 0 \<Longrightarrow> cball x e = {x}"
  2441   by (auto simp add: set_eq_iff)
  2442 
  2443 
  2444 subsection {* Boundedness *}
  2445 
  2446   (* FIXME: This has to be unified with BSEQ!! *)
  2447 definition (in metric_space) bounded :: "'a set \<Rightarrow> bool"
  2448   where "bounded S \<longleftrightarrow> (\<exists>x e. \<forall>y\<in>S. dist x y \<le> e)"
  2449 
  2450 lemma bounded_subset_cball: "bounded S \<longleftrightarrow> (\<exists>e x. S \<subseteq> cball x e)"
  2451   unfolding bounded_def subset_eq by auto
  2452 
  2453 lemma bounded_any_center: "bounded S \<longleftrightarrow> (\<exists>e. \<forall>y\<in>S. dist a y \<le> e)"
  2454   unfolding bounded_def
  2455   apply safe
  2456   apply (rule_tac x="dist a x + e" in exI)
  2457   apply clarify
  2458   apply (drule (1) bspec)
  2459   apply (erule order_trans [OF dist_triangle add_left_mono])
  2460   apply auto
  2461   done
  2462 
  2463 lemma bounded_iff: "bounded S \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. norm x \<le> a)"
  2464   unfolding bounded_any_center [where a=0]
  2465   by (simp add: dist_norm)
  2466 
  2467 lemma bounded_realI:
  2468   assumes "\<forall>x\<in>s. abs (x::real) \<le> B"
  2469   shows "bounded s"
  2470   unfolding bounded_def dist_real_def
  2471   apply (rule_tac x=0 in exI)
  2472   using assms
  2473   apply auto
  2474   done
  2475 
  2476 lemma bounded_empty [simp]: "bounded {}"
  2477   by (simp add: bounded_def)
  2478 
  2479 lemma bounded_subset: "bounded T \<Longrightarrow> S \<subseteq> T \<Longrightarrow> bounded S"
  2480   by (metis bounded_def subset_eq)
  2481 
  2482 lemma bounded_interior[intro]: "bounded S \<Longrightarrow> bounded(interior S)"
  2483   by (metis bounded_subset interior_subset)
  2484 
  2485 lemma bounded_closure[intro]:
  2486   assumes "bounded S"
  2487   shows "bounded (closure S)"
  2488 proof -
  2489   from assms obtain x and a where a: "\<forall>y\<in>S. dist x y \<le> a"
  2490     unfolding bounded_def by auto
  2491   {
  2492     fix y
  2493     assume "y \<in> closure S"
  2494     then obtain f where f: "\<forall>n. f n \<in> S"  "(f ---> y) sequentially"
  2495       unfolding closure_sequential by auto
  2496     have "\<forall>n. f n \<in> S \<longrightarrow> dist x (f n) \<le> a" using a by simp
  2497     then have "eventually (\<lambda>n. dist x (f n) \<le> a) sequentially"
  2498       by (rule eventually_mono, simp add: f(1))
  2499     have "dist x y \<le> a"
  2500       apply (rule Lim_dist_ubound [of sequentially f])
  2501       apply (rule trivial_limit_sequentially)
  2502       apply (rule f(2))
  2503       apply fact
  2504       done
  2505   }
  2506   then show ?thesis
  2507     unfolding bounded_def by auto
  2508 qed
  2509 
  2510 lemma bounded_cball[simp,intro]: "bounded (cball x e)"
  2511   apply (simp add: bounded_def)
  2512   apply (rule_tac x=x in exI)
  2513   apply (rule_tac x=e in exI)
  2514   apply auto
  2515   done
  2516 
  2517 lemma bounded_ball[simp,intro]: "bounded (ball x e)"
  2518   by (metis ball_subset_cball bounded_cball bounded_subset)
  2519 
  2520 lemma bounded_Un[simp]: "bounded (S \<union> T) \<longleftrightarrow> bounded S \<and> bounded T"
  2521   apply (auto simp add: bounded_def)
  2522   apply (rename_tac x y r s)
  2523   apply (rule_tac x=x in exI)
  2524   apply (rule_tac x="max r (dist x y + s)" in exI)
  2525   apply (rule ballI)
  2526   apply safe
  2527   apply (drule (1) bspec)
  2528   apply simp
  2529   apply (drule (1) bspec)
  2530   apply (rule min_max.le_supI2)
  2531   apply (erule order_trans [OF dist_triangle add_left_mono])
  2532   done
  2533 
  2534 lemma bounded_Union[intro]: "finite F \<Longrightarrow> \<forall>S\<in>F. bounded S \<Longrightarrow> bounded (\<Union>F)"
  2535   by (induct rule: finite_induct[of F]) auto
  2536 
  2537 lemma bounded_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. bounded (B x) \<Longrightarrow> bounded (\<Union>x\<in>A. B x)"
  2538   by (induct set: finite) auto
  2539 
  2540 lemma bounded_insert [simp]: "bounded (insert x S) \<longleftrightarrow> bounded S"
  2541 proof -
  2542   have "\<forall>y\<in>{x}. dist x y \<le> 0"
  2543     by simp
  2544   then have "bounded {x}"
  2545     unfolding bounded_def by fast
  2546   then show ?thesis
  2547     by (metis insert_is_Un bounded_Un)
  2548 qed
  2549 
  2550 lemma finite_imp_bounded [intro]: "finite S \<Longrightarrow> bounded S"
  2551   by (induct set: finite) simp_all
  2552 
  2553 lemma bounded_pos: "bounded S \<longleftrightarrow> (\<exists>b>0. \<forall>x\<in> S. norm x \<le> b)"
  2554   apply (simp add: bounded_iff)
  2555   apply (subgoal_tac "\<And>x (y::real). 0 < 1 + abs y \<and> (x \<le> y \<longrightarrow> x \<le> 1 + abs y)")
  2556   apply metis
  2557   apply arith
  2558   done
  2559 
  2560 lemma Bseq_eq_bounded:
  2561   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
  2562   shows "Bseq f \<longleftrightarrow> bounded (range f)"
  2563   unfolding Bseq_def bounded_pos by auto
  2564 
  2565 lemma bounded_Int[intro]: "bounded S \<or> bounded T \<Longrightarrow> bounded (S \<inter> T)"
  2566   by (metis Int_lower1 Int_lower2 bounded_subset)
  2567 
  2568 lemma bounded_diff[intro]: "bounded S \<Longrightarrow> bounded (S - T)"
  2569   by (metis Diff_subset bounded_subset)
  2570 
  2571 lemma not_bounded_UNIV[simp, intro]:
  2572   "\<not> bounded (UNIV :: 'a::{real_normed_vector, perfect_space} set)"
  2573 proof (auto simp add: bounded_pos not_le)
  2574   obtain x :: 'a where "x \<noteq> 0"
  2575     using perfect_choose_dist [OF zero_less_one] by fast
  2576   fix b :: real
  2577   assume b: "b >0"
  2578   have b1: "b +1 \<ge> 0"
  2579     using b by simp
  2580   with `x \<noteq> 0` have "b < norm (scaleR (b + 1) (sgn x))"
  2581     by (simp add: norm_sgn)
  2582   then show "\<exists>x::'a. b < norm x" ..
  2583 qed
  2584 
  2585 lemma bounded_linear_image:
  2586   assumes "bounded S"
  2587     and "bounded_linear f"
  2588   shows "bounded (f ` S)"
  2589 proof -
  2590   from assms(1) obtain b where b: "b > 0" "\<forall>x\<in>S. norm x \<le> b"
  2591     unfolding bounded_pos by auto
  2592   from assms(2) obtain B where B: "B > 0" "\<forall>x. norm (f x) \<le> B * norm x"
  2593     using bounded_linear.pos_bounded by (auto simp add: mult_ac)
  2594   {
  2595     fix x
  2596     assume "x \<in> S"
  2597     then have "norm x \<le> b"
  2598       using b by auto
  2599     then have "norm (f x) \<le> B * b"
  2600       using B(2)
  2601       apply (erule_tac x=x in allE)
  2602       apply (metis B(1) B(2) order_trans mult_le_cancel_left_pos)
  2603       done
  2604   }
  2605   then show ?thesis
  2606     unfolding bounded_pos
  2607     apply (rule_tac x="b*B" in exI)
  2608     using b B mult_pos_pos [of b B]
  2609     apply (auto simp add: mult_commute)
  2610     done
  2611 qed
  2612 
  2613 lemma bounded_scaling:
  2614   fixes S :: "'a::real_normed_vector set"
  2615   shows "bounded S \<Longrightarrow> bounded ((\<lambda>x. c *\<^sub>R x) ` S)"
  2616   apply (rule bounded_linear_image)
  2617   apply assumption
  2618   apply (rule bounded_linear_scaleR_right)
  2619   done
  2620 
  2621 lemma bounded_translation:
  2622   fixes S :: "'a::real_normed_vector set"
  2623   assumes "bounded S"
  2624   shows "bounded ((\<lambda>x. a + x) ` S)"
  2625 proof -
  2626   from assms obtain b where b: "b > 0" "\<forall>x\<in>S. norm x \<le> b"
  2627     unfolding bounded_pos by auto
  2628   {
  2629     fix x
  2630     assume "x \<in> S"
  2631     then have "norm (a + x) \<le> b + norm a"
  2632       using norm_triangle_ineq[of a x] b by auto
  2633   }
  2634   then show ?thesis
  2635     unfolding bounded_pos
  2636     using norm_ge_zero[of a] b(1) and add_strict_increasing[of b 0 "norm a"]
  2637     by (auto intro!: exI[of _ "b + norm a"])
  2638 qed
  2639 
  2640 
  2641 text{* Some theorems on sups and infs using the notion "bounded". *}
  2642 
  2643 lemma bounded_real: "bounded (S::real set) \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. \<bar>x\<bar> \<le> a)"
  2644   by (simp add: bounded_iff)
  2645 
  2646 lemma bounded_imp_bdd_above: "bounded S \<Longrightarrow> bdd_above (S :: real set)"
  2647   by (auto simp: bounded_def bdd_above_def dist_real_def)
  2648      (metis abs_le_D1 abs_minus_commute diff_le_eq)
  2649 
  2650 lemma bounded_imp_bdd_below: "bounded S \<Longrightarrow> bdd_below (S :: real set)"
  2651   by (auto simp: bounded_def bdd_below_def dist_real_def)
  2652      (metis abs_le_D1 add_commute diff_le_eq)
  2653 
  2654 (* TODO: remove the following lemmas about Inf and Sup, is now in conditionally complete lattice *)
  2655 
  2656 lemma bounded_has_Sup:
  2657   fixes S :: "real set"
  2658   assumes "bounded S"
  2659     and "S \<noteq> {}"
  2660   shows "\<forall>x\<in>S. x \<le> Sup S"
  2661     and "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b"
  2662 proof
  2663   show "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b"
  2664     using assms by (metis cSup_least)
  2665 qed (metis cSup_upper assms(1) bounded_imp_bdd_above)
  2666 
  2667 lemma Sup_insert:
  2668   fixes S :: "real set"
  2669   shows "bounded S \<Longrightarrow> Sup (insert x S) = (if S = {} then x else max x (Sup S))"
  2670   by (auto simp: bounded_imp_bdd_above sup_max cSup_insert_If)
  2671 
  2672 lemma Sup_insert_finite:
  2673   fixes S :: "real set"
  2674   shows "finite S \<Longrightarrow> Sup (insert x S) = (if S = {} then x else max x (Sup S))"
  2675   apply (rule Sup_insert)
  2676   apply (rule finite_imp_bounded)
  2677   apply simp
  2678   done
  2679 
  2680 lemma bounded_has_Inf:
  2681   fixes S :: "real set"
  2682   assumes "bounded S"
  2683     and "S \<noteq> {}"
  2684   shows "\<forall>x\<in>S. x \<ge> Inf S"
  2685     and "\<forall>b. (\<forall>x\<in>S. x \<ge> b) \<longrightarrow> Inf S \<ge> b"
  2686 proof
  2687   show "\<forall>b. (\<forall>x\<in>S. x \<ge> b) \<longrightarrow> Inf S \<ge> b"
  2688     using assms by (metis cInf_greatest)
  2689 qed (metis cInf_lower assms(1) bounded_imp_bdd_below)
  2690 
  2691 lemma Inf_insert:
  2692   fixes S :: "real set"
  2693   shows "bounded S \<Longrightarrow> Inf (insert x S) = (if S = {} then x else min x (Inf S))"
  2694   by (auto simp: bounded_imp_bdd_below inf_min cInf_insert_If)
  2695 
  2696 lemma Inf_insert_finite:
  2697   fixes S :: "real set"
  2698   shows "finite S \<Longrightarrow> Inf (insert x S) = (if S = {} then x else min x (Inf S))"
  2699   apply (rule Inf_insert)
  2700   apply (rule finite_imp_bounded)
  2701   apply simp
  2702   done
  2703 
  2704 subsection {* Compactness *}
  2705 
  2706 subsubsection {* Bolzano-Weierstrass property *}
  2707 
  2708 lemma heine_borel_imp_bolzano_weierstrass:
  2709   assumes "compact s"
  2710     and "infinite t"
  2711     and "t \<subseteq> s"
  2712   shows "\<exists>x \<in> s. x islimpt t"
  2713 proof (rule ccontr)
  2714   assume "\<not> (\<exists>x \<in> s. x islimpt t)"
  2715   then obtain f where f: "\<forall>x\<in>s. x \<in> f x \<and> open (f x) \<and> (\<forall>y\<in>t. y \<in> f x \<longrightarrow> y = x)"
  2716     unfolding islimpt_def
  2717     using bchoice[of s "\<lambda> x T. x \<in> T \<and> open T \<and> (\<forall>y\<in>t. y \<in> T \<longrightarrow> y = x)"]
  2718     by auto
  2719   obtain g where g: "g \<subseteq> {t. \<exists>x. x \<in> s \<and> t = f x}" "finite g" "s \<subseteq> \<Union>g"
  2720     using assms(1)[unfolded compact_eq_heine_borel, THEN spec[where x="{t. \<exists>x. x\<in>s \<and> t = f x}"]]
  2721     using f by auto
  2722   from g(1,3) have g':"\<forall>x\<in>g. \<exists>xa \<in> s. x = f xa"
  2723     by auto
  2724   {
  2725     fix x y
  2726     assume "x \<in> t" "y \<in> t" "f x = f y"
  2727     then have "x \<in> f x"  "y \<in> f x \<longrightarrow> y = x"
  2728       using f[THEN bspec[where x=x]] and `t \<subseteq> s` by auto
  2729     then have "x = y"
  2730       using `f x = f y` and f[THEN bspec[where x=y]] and `y \<in> t` and `t \<subseteq> s`
  2731       by auto
  2732   }
  2733   then have "inj_on f t"
  2734     unfolding inj_on_def by simp
  2735   then have "infinite (f ` t)"
  2736     using assms(2) using finite_imageD by auto
  2737   moreover
  2738   {
  2739     fix x
  2740     assume "x \<in> t" "f x \<notin> g"
  2741     from g(3) assms(3) `x \<in> t` obtain h where "h \<in> g" and "x \<in> h"
  2742       by auto
  2743     then obtain y where "y \<in> s" "h = f y"
  2744       using g'[THEN bspec[where x=h]] by auto
  2745     then have "y = x"
  2746       using f[THEN bspec[where x=y]] and `x\<in>t` and `x\<in>h`[unfolded `h = f y`]
  2747       by auto
  2748     then have False
  2749       using `f x \<notin> g` `h \<in> g` unfolding `h = f y`
  2750       by auto
  2751   }
  2752   then have "f ` t \<subseteq> g" by auto
  2753   ultimately show False
  2754     using g(2) using finite_subset by auto
  2755 qed
  2756 
  2757 lemma acc_point_range_imp_convergent_subsequence:
  2758   fixes l :: "'a :: first_countable_topology"
  2759   assumes l: "\<forall>U. l\<in>U \<longrightarrow> open U \<longrightarrow> infinite (U \<inter> range f)"
  2760   shows "\<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  2761 proof -
  2762   from countable_basis_at_decseq[of l] guess A . note A = this
  2763 
  2764   def s \<equiv> "\<lambda>n i. SOME j. i < j \<and> f j \<in> A (Suc n)"
  2765   {
  2766     fix n i
  2767     have "infinite (A (Suc n) \<inter> range f - f`{.. i})"
  2768       using l A by auto
  2769     then have "\<exists>x. x \<in> A (Suc n) \<inter> range f - f`{.. i}"
  2770       unfolding ex_in_conv by (intro notI) simp
  2771     then have "\<exists>j. f j \<in> A (Suc n) \<and> j \<notin> {.. i}"
  2772       by auto
  2773     then have "\<exists>a. i < a \<and> f a \<in> A (Suc n)"
  2774       by (auto simp: not_le)
  2775     then have "i < s n i" "f (s n i) \<in> A (Suc n)"
  2776       unfolding s_def by (auto intro: someI2_ex)
  2777   }
  2778   note s = this
  2779   def r \<equiv> "nat_rec (s 0 0) s"
  2780   have "subseq r"
  2781     by (auto simp: r_def s subseq_Suc_iff)
  2782   moreover
  2783   have "(\<lambda>n. f (r n)) ----> l"
  2784   proof (rule topological_tendstoI)
  2785     fix S
  2786     assume "open S" "l \<in> S"
  2787     with A(3) have "eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  2788       by auto
  2789     moreover
  2790     {
  2791       fix i
  2792       assume "Suc 0 \<le> i"
  2793       then have "f (r i) \<in> A i"
  2794         by (cases i) (simp_all add: r_def s)
  2795     }
  2796     then have "eventually (\<lambda>i. f (r i) \<in> A i) sequentially"
  2797       by (auto simp: eventually_sequentially)
  2798     ultimately show "eventually (\<lambda>i. f (r i) \<in> S) sequentially"
  2799       by eventually_elim auto
  2800   qed
  2801   ultimately show "\<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  2802     by (auto simp: convergent_def comp_def)
  2803 qed
  2804 
  2805 lemma sequence_infinite_lemma:
  2806   fixes f :: "nat \<Rightarrow> 'a::t1_space"
  2807   assumes "\<forall>n. f n \<noteq> l"
  2808     and "(f ---> l) sequentially"
  2809   shows "infinite (range f)"
  2810 proof
  2811   assume "finite (range f)"
  2812   then have "closed (range f)"
  2813     by (rule finite_imp_closed)
  2814   then have "open (- range f)"
  2815     by (rule open_Compl)
  2816   from assms(1) have "l \<in> - range f"
  2817     by auto
  2818   from assms(2) have "eventually (\<lambda>n. f n \<in> - range f) sequentially"
  2819     using `open (- range f)` `l \<in> - range f`
  2820     by (rule topological_tendstoD)
  2821   then show False
  2822     unfolding eventually_sequentially
  2823     by auto
  2824 qed
  2825 
  2826 lemma closure_insert:
  2827   fixes x :: "'a::t1_space"
  2828   shows "closure (insert x s) = insert x (closure s)"
  2829   apply (rule closure_unique)
  2830   apply (rule insert_mono [OF closure_subset])
  2831   apply (rule closed_insert [OF closed_closure])
  2832   apply (simp add: closure_minimal)
  2833   done
  2834 
  2835 lemma islimpt_insert:
  2836   fixes x :: "'a::t1_space"
  2837   shows "x islimpt (insert a s) \<longleftrightarrow> x islimpt s"
  2838 proof
  2839   assume *: "x islimpt (insert a s)"
  2840   show "x islimpt s"
  2841   proof (rule islimptI)
  2842     fix t
  2843     assume t: "x \<in> t" "open t"
  2844     show "\<exists>y\<in>s. y \<in> t \<and> y \<noteq> x"
  2845     proof (cases "x = a")
  2846       case True
  2847       obtain y where "y \<in> insert a s" "y \<in> t" "y \<noteq> x"
  2848         using * t by (rule islimptE)
  2849       with `x = a` show ?thesis by auto
  2850     next
  2851       case False
  2852       with t have t': "x \<in> t - {a}" "open (t - {a})"
  2853         by (simp_all add: open_Diff)
  2854       obtain y where "y \<in> insert a s" "y \<in> t - {a}" "y \<noteq> x"
  2855         using * t' by (rule islimptE)
  2856       then show ?thesis by auto
  2857     qed
  2858   qed
  2859 next
  2860   assume "x islimpt s"
  2861   then show "x islimpt (insert a s)"
  2862     by (rule islimpt_subset) auto
  2863 qed
  2864 
  2865 lemma islimpt_finite:
  2866   fixes x :: "'a::t1_space"
  2867   shows "finite s \<Longrightarrow> \<not> x islimpt s"
  2868   by (induct set: finite) (simp_all add: islimpt_insert)
  2869 
  2870 lemma islimpt_union_finite:
  2871   fixes x :: "'a::t1_space"
  2872   shows "finite s \<Longrightarrow> x islimpt (s \<union> t) \<longleftrightarrow> x islimpt t"
  2873   by (simp add: islimpt_Un islimpt_finite)
  2874 
  2875 lemma islimpt_eq_acc_point:
  2876   fixes l :: "'a :: t1_space"
  2877   shows "l islimpt S \<longleftrightarrow> (\<forall>U. l\<in>U \<longrightarrow> open U \<longrightarrow> infinite (U \<inter> S))"
  2878 proof (safe intro!: islimptI)
  2879   fix U
  2880   assume "l islimpt S" "l \<in> U" "open U" "finite (U \<inter> S)"
  2881   then have "l islimpt S" "l \<in> (U - (U \<inter> S - {l}))" "open (U - (U \<inter> S - {l}))"
  2882     by (auto intro: finite_imp_closed)
  2883   then show False
  2884     by (rule islimptE) auto
  2885 next
  2886   fix T
  2887   assume *: "\<forall>U. l\<in>U \<longrightarrow> open U \<longrightarrow> infinite (U \<inter> S)" "l \<in> T" "open T"
  2888   then have "infinite (T \<inter> S - {l})"
  2889     by auto
  2890   then have "\<exists>x. x \<in> (T \<inter> S - {l})"
  2891     unfolding ex_in_conv by (intro notI) simp
  2892   then show "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> l"
  2893     by auto
  2894 qed
  2895 
  2896 lemma islimpt_range_imp_convergent_subsequence:
  2897   fixes l :: "'a :: {t1_space, first_countable_topology}"
  2898   assumes l: "l islimpt (range f)"
  2899   shows "\<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  2900   using l unfolding islimpt_eq_acc_point
  2901   by (rule acc_point_range_imp_convergent_subsequence)
  2902 
  2903 lemma sequence_unique_limpt:
  2904   fixes f :: "nat \<Rightarrow> 'a::t2_space"
  2905   assumes "(f ---> l) sequentially"
  2906     and "l' islimpt (range f)"
  2907   shows "l' = l"
  2908 proof (rule ccontr)
  2909   assume "l' \<noteq> l"
  2910   obtain s t where "open s" "open t" "l' \<in> s" "l \<in> t" "s \<inter> t = {}"
  2911     using hausdorff [OF `l' \<noteq> l`] by auto
  2912   have "eventually (\<lambda>n. f n \<in> t) sequentially"
  2913     using assms(1) `open t` `l \<in> t` by (rule topological_tendstoD)
  2914   then obtain N where "\<forall>n\<ge>N. f n \<in> t"
  2915     unfolding eventually_sequentially by auto
  2916 
  2917   have "UNIV = {..<N} \<union> {N..}"
  2918     by auto
  2919   then have "l' islimpt (f ` ({..<N} \<union> {N..}))"
  2920     using assms(2) by simp
  2921   then have "l' islimpt (f ` {..<N} \<union> f ` {N..})"
  2922     by (simp add: image_Un)
  2923   then have "l' islimpt (f ` {N..})"
  2924     by (simp add: islimpt_union_finite)
  2925   then obtain y where "y \<in> f ` {N..}" "y \<in> s" "y \<noteq> l'"
  2926     using `l' \<in> s` `open s` by (rule islimptE)
  2927   then obtain n where "N \<le> n" "f n \<in> s" "f n \<noteq> l'"
  2928     by auto
  2929   with `\<forall>n\<ge>N. f n \<in> t` have "f n \<in> s \<inter> t"
  2930     by simp
  2931   with `s \<inter> t = {}` show False
  2932     by simp
  2933 qed
  2934 
  2935 lemma bolzano_weierstrass_imp_closed:
  2936   fixes s :: "'a::{first_countable_topology,t2_space} set"
  2937   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2938   shows "closed s"
  2939 proof -
  2940   {
  2941     fix x l
  2942     assume as: "\<forall>n::nat. x n \<in> s" "(x ---> l) sequentially"
  2943     then have "l \<in> s"
  2944     proof (cases "\<forall>n. x n \<noteq> l")
  2945       case False
  2946       then show "l\<in>s" using as(1) by auto
  2947     next
  2948       case True note cas = this
  2949       with as(2) have "infinite (range x)"
  2950         using sequence_infinite_lemma[of x l] by auto
  2951       then obtain l' where "l'\<in>s" "l' islimpt (range x)"
  2952         using assms[THEN spec[where x="range x"]] as(1) by auto
  2953       then show "l\<in>s" using sequence_unique_limpt[of x l l']
  2954         using as cas by auto
  2955     qed
  2956   }
  2957   then show ?thesis
  2958     unfolding closed_sequential_limits by fast
  2959 qed
  2960 
  2961 lemma compact_imp_bounded:
  2962   assumes "compact U"
  2963   shows "bounded U"
  2964 proof -
  2965   have "compact U" "\<forall>x\<in>U. open (ball x 1)" "U \<subseteq> (\<Union>x\<in>U. ball x 1)"
  2966     using assms by auto
  2967   then obtain D where D: "D \<subseteq> U" "finite D" "U \<subseteq> (\<Union>x\<in>D. ball x 1)"
  2968     by (rule compactE_image)
  2969   from `finite D` have "bounded (\<Union>x\<in>D. ball x 1)"
  2970     by (simp add: bounded_UN)
  2971   then show "bounded U" using `U \<subseteq> (\<Union>x\<in>D. ball x 1)`
  2972     by (rule bounded_subset)
  2973 qed
  2974 
  2975 text{* In particular, some common special cases. *}
  2976 
  2977 lemma compact_union [intro]:
  2978   assumes "compact s"
  2979     and "compact t"
  2980   shows " compact (s \<union> t)"
  2981 proof (rule compactI)
  2982   fix f
  2983   assume *: "Ball f open" "s \<union> t \<subseteq> \<Union>f"
  2984   from * `compact s` obtain s' where "s' \<subseteq> f \<and> finite s' \<and> s \<subseteq> \<Union>s'"
  2985     unfolding compact_eq_heine_borel by (auto elim!: allE[of _ f]) metis
  2986   moreover
  2987   from * `compact t` obtain t' where "t' \<subseteq> f \<and> finite t' \<and> t \<subseteq> \<Union>t'"
  2988     unfolding compact_eq_heine_borel by (auto elim!: allE[of _ f]) metis
  2989   ultimately show "\<exists>f'\<subseteq>f. finite f' \<and> s \<union> t \<subseteq> \<Union>f'"
  2990     by (auto intro!: exI[of _ "s' \<union> t'"])
  2991 qed
  2992 
  2993 lemma compact_Union [intro]: "finite S \<Longrightarrow> (\<And>T. T \<in> S \<Longrightarrow> compact T) \<Longrightarrow> compact (\<Union>S)"
  2994   by (induct set: finite) auto
  2995 
  2996 lemma compact_UN [intro]:
  2997   "finite A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> compact (B x)) \<Longrightarrow> compact (\<Union>x\<in>A. B x)"
  2998   unfolding SUP_def by (rule compact_Union) auto
  2999 
  3000 lemma closed_inter_compact [intro]:
  3001   assumes "closed s"
  3002     and "compact t"
  3003   shows "compact (s \<inter> t)"
  3004   using compact_inter_closed [of t s] assms
  3005   by (simp add: Int_commute)
  3006 
  3007 lemma compact_inter [intro]:
  3008   fixes s t :: "'a :: t2_space set"
  3009   assumes "compact s"
  3010     and "compact t"
  3011   shows "compact (s \<inter> t)"
  3012   using assms by (intro compact_inter_closed compact_imp_closed)
  3013 
  3014 lemma compact_sing [simp]: "compact {a}"
  3015   unfolding compact_eq_heine_borel by auto
  3016 
  3017 lemma compact_insert [simp]:
  3018   assumes "compact s"
  3019   shows "compact (insert x s)"
  3020 proof -
  3021   have "compact ({x} \<union> s)"
  3022     using compact_sing assms by (rule compact_union)
  3023   then show ?thesis by simp
  3024 qed
  3025 
  3026 lemma finite_imp_compact: "finite s \<Longrightarrow> compact s"
  3027   by (induct set: finite) simp_all
  3028 
  3029 lemma open_delete:
  3030   fixes s :: "'a::t1_space set"
  3031   shows "open s \<Longrightarrow> open (s - {x})"
  3032   by (simp add: open_Diff)
  3033 
  3034 text{* Finite intersection property *}
  3035 
  3036 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  3037   by (auto simp: inj_on_def)
  3038 
  3039 lemma compact_fip:
  3040   "compact U \<longleftrightarrow>
  3041     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  3042   (is "_ \<longleftrightarrow> ?R")
  3043 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  3044   fix A
  3045   assume "compact U"
  3046     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  3047     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  3048   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  3049     by auto
  3050   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  3051     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  3052   with fi[THEN spec, of B] show False
  3053     by (auto dest: finite_imageD intro: inj_setminus)
  3054 next
  3055   fix A
  3056   assume ?R
  3057   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  3058   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  3059     by auto
  3060   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  3061     by (metis subset_image_iff)
  3062   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  3063     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  3064 qed
  3065 
  3066 lemma compact_imp_fip:
  3067   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  3068     s \<inter> (\<Inter> f) \<noteq> {}"
  3069   unfolding compact_fip by auto
  3070 
  3071 text{*Compactness expressed with filters*}
  3072 
  3073 definition "filter_from_subbase B = Abs_filter (\<lambda>P. \<exists>X \<subseteq> B. finite X \<and> Inf X \<le> P)"
  3074 
  3075 lemma eventually_filter_from_subbase:
  3076   "eventually P (filter_from_subbase B) \<longleftrightarrow> (\<exists>X \<subseteq> B. finite X \<and> Inf X \<le> P)"
  3077     (is "_ \<longleftrightarrow> ?R P")
  3078   unfolding filter_from_subbase_def
  3079 proof (rule eventually_Abs_filter is_filter.intro)+
  3080   show "?R (\<lambda>x. True)"
  3081     by (rule exI[of _ "{}"]) (simp add: le_fun_def)
  3082 next
  3083   fix P Q assume "?R P" then guess X ..
  3084   moreover assume "?R Q" then guess Y ..
  3085   ultimately show "?R (\<lambda>x. P x \<and> Q x)"
  3086     by (intro exI[of _ "X \<union> Y"]) auto
  3087 next
  3088   fix P Q
  3089   assume "?R P" then guess X ..
  3090   moreover assume "\<forall>x. P x \<longrightarrow> Q x"
  3091   ultimately show "?R Q"
  3092     by (intro exI[of _ X]) auto
  3093 qed
  3094 
  3095 lemma eventually_filter_from_subbaseI: "P \<in> B \<Longrightarrow> eventually P (filter_from_subbase B)"
  3096   by (subst eventually_filter_from_subbase) (auto intro!: exI[of _ "{P}"])
  3097 
  3098 lemma filter_from_subbase_not_bot:
  3099   "\<forall>X \<subseteq> B. finite X \<longrightarrow> Inf X \<noteq> bot \<Longrightarrow> filter_from_subbase B \<noteq> bot"
  3100   unfolding trivial_limit_def eventually_filter_from_subbase by auto
  3101 
  3102 lemma closure_iff_nhds_not_empty:
  3103   "x \<in> closure X \<longleftrightarrow> (\<forall>A. \<forall>S\<subseteq>A. open S \<longrightarrow> x \<in> S \<longrightarrow> X \<inter> A \<noteq> {})"
  3104 proof safe
  3105   assume x: "x \<in> closure X"
  3106   fix S A
  3107   assume "open S" "x \<in> S" "X \<inter> A = {}" "S \<subseteq> A"
  3108   then have "x \<notin> closure (-S)"
  3109     by (auto simp: closure_complement subset_eq[symmetric] intro: interiorI)
  3110   with x have "x \<in> closure X - closure (-S)"
  3111     by auto
  3112   also have "\<dots> \<subseteq> closure (X \<inter> S)"
  3113     using `open S` open_inter_closure_subset[of S X] by (simp add: closed_Compl ac_simps)
  3114   finally have "X \<inter> S \<noteq> {}" by auto
  3115   then show False using `X \<inter> A = {}` `S \<subseteq> A` by auto
  3116 next
  3117   assume "\<forall>A S. S \<subseteq> A \<longrightarrow> open S \<longrightarrow> x \<in> S \<longrightarrow> X \<inter> A \<noteq> {}"
  3118   from this[THEN spec, of "- X", THEN spec, of "- closure X"]
  3119   show "x \<in> closure X"
  3120     by (simp add: closure_subset open_Compl)
  3121 qed
  3122 
  3123 lemma compact_filter:
  3124   "compact U \<longleftrightarrow> (\<forall>F. F \<noteq> bot \<longrightarrow> eventually (\<lambda>x. x \<in> U) F \<longrightarrow> (\<exists>x\<in>U. inf (nhds x) F \<noteq> bot))"
  3125 proof (intro allI iffI impI compact_fip[THEN iffD2] notI)
  3126   fix F
  3127   assume "compact U"
  3128   assume F: "F \<noteq> bot" "eventually (\<lambda>x. x \<in> U) F"
  3129   then have "U \<noteq> {}"
  3130     by (auto simp: eventually_False)
  3131 
  3132   def Z \<equiv> "closure ` {A. eventually (\<lambda>x. x \<in> A) F}"
  3133   then have "\<forall>z\<in>Z. closed z"
  3134     by auto
  3135   moreover
  3136   have ev_Z: "\<And>z. z \<in> Z \<Longrightarrow> eventually (\<lambda>x. x \<in> z) F"
  3137     unfolding Z_def by (auto elim: eventually_elim1 intro: set_mp[OF closure_subset])
  3138   have "(\<forall>B \<subseteq> Z. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {})"
  3139   proof (intro allI impI)
  3140     fix B assume "finite B" "B \<subseteq> Z"
  3141     with `finite B` ev_Z have "eventually (\<lambda>x. \<forall>b\<in>B. x \<in> b) F"
  3142       by (auto intro!: eventually_Ball_finite)
  3143     with F(2) have "eventually (\<lambda>x. x \<in> U \<inter> (\<Inter>B)) F"
  3144       by eventually_elim auto
  3145     with F show "U \<inter> \<Inter>B \<noteq> {}"
  3146       by (intro notI) (simp add: eventually_False)
  3147   qed
  3148   ultimately have "U \<inter> \<Inter>Z \<noteq> {}"
  3149     using `compact U` unfolding compact_fip by blast
  3150   then obtain x where "x \<in> U" and x: "\<And>z. z \<in> Z \<Longrightarrow> x \<in> z"
  3151     by auto
  3152 
  3153   have "\<And>P. eventually P (inf (nhds x) F) \<Longrightarrow> P \<noteq> bot"
  3154     unfolding eventually_inf eventually_nhds
  3155   proof safe
  3156     fix P Q R S
  3157     assume "eventually R F" "open S" "x \<in> S"
  3158     with open_inter_closure_eq_empty[of S "{x. R x}"] x[of "closure {x. R x}"]
  3159     have "S \<inter> {x. R x} \<noteq> {}" by (auto simp: Z_def)
  3160     moreover assume "Ball S Q" "\<forall>x. Q x \<and> R x \<longrightarrow> bot x"
  3161     ultimately show False by (auto simp: set_eq_iff)
  3162   qed
  3163   with `x \<in> U` show "\<exists>x\<in>U. inf (nhds x) F \<noteq> bot"
  3164     by (metis eventually_bot)
  3165 next
  3166   fix A
  3167   assume A: "\<forall>a\<in>A. closed a" "\<forall>B\<subseteq>A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}" "U \<inter> \<Inter>A = {}"
  3168   def P' \<equiv> "(\<lambda>a (x::'a). x \<in> a)"
  3169   then have inj_P': "\<And>A. inj_on P' A"
  3170     by (auto intro!: inj_onI simp: fun_eq_iff)
  3171   def F \<equiv> "filter_from_subbase (P' ` insert U A)"
  3172   have "F \<noteq> bot"
  3173     unfolding F_def
  3174   proof (safe intro!: filter_from_subbase_not_bot)
  3175     fix X
  3176     assume "X \<subseteq> P' ` insert U A" "finite X" "Inf X = bot"
  3177     then obtain B where "B \<subseteq> insert U A" "finite B" and B: "Inf (P' ` B) = bot"
  3178       unfolding subset_image_iff by (auto intro: inj_P' finite_imageD)
  3179     with A(2)[THEN spec, of "B - {U}"] have "U \<inter> \<Inter>(B - {U}) \<noteq> {}"
  3180       by auto
  3181     with B show False
  3182       by (auto simp: P'_def fun_eq_iff)
  3183   qed
  3184   moreover have "eventually (\<lambda>x. x \<in> U) F"
  3185     unfolding F_def by (rule eventually_filter_from_subbaseI) (auto simp: P'_def)
  3186   moreover
  3187   assume "\<forall>F. F \<noteq> bot \<longrightarrow> eventually (\<lambda>x. x \<in> U) F \<longrightarrow> (\<exists>x\<in>U. inf (nhds x) F \<noteq> bot)"
  3188   ultimately obtain x where "x \<in> U" and x: "inf (nhds x) F \<noteq> bot"
  3189     by auto
  3190 
  3191   {
  3192     fix V
  3193     assume "V \<in> A"
  3194     then have V: "eventually (\<lambda>x. x \<in> V) F"
  3195       by (auto simp add: F_def image_iff P'_def intro!: eventually_filter_from_subbaseI)
  3196     have "x \<in> closure V"
  3197       unfolding closure_iff_nhds_not_empty
  3198     proof (intro impI allI)
  3199       fix S A
  3200       assume "open S" "x \<in> S" "S \<subseteq> A"
  3201       then have "eventually (\<lambda>x. x \<in> A) (nhds x)"
  3202         by (auto simp: eventually_nhds)
  3203       with V have "eventually (\<lambda>x. x \<in> V \<inter> A) (inf (nhds x) F)"
  3204         by (auto simp: eventually_inf)
  3205       with x show "V \<inter> A \<noteq> {}"
  3206         by (auto simp del: Int_iff simp add: trivial_limit_def)
  3207     qed
  3208     then have "x \<in> V"
  3209       using `V \<in> A` A(1) by simp
  3210   }
  3211   with `x\<in>U` have "x \<in> U \<inter> \<Inter>A" by auto
  3212   with `U \<inter> \<Inter>A = {}` show False by auto
  3213 qed
  3214 
  3215 definition "countably_compact U \<longleftrightarrow>
  3216     (\<forall>A. countable A \<longrightarrow> (\<forall>a\<in>A. open a) \<longrightarrow> U \<subseteq> \<Union>A \<longrightarrow> (\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T))"
  3217 
  3218 lemma countably_compactE:
  3219   assumes "countably_compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C" "countable C"
  3220   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  3221   using assms unfolding countably_compact_def by metis
  3222 
  3223 lemma countably_compactI:
  3224   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union>C \<Longrightarrow> countable C \<Longrightarrow> (\<exists>C'\<subseteq>C. finite C' \<and> s \<subseteq> \<Union>C')"
  3225   shows "countably_compact s"
  3226   using assms unfolding countably_compact_def by metis
  3227 
  3228 lemma compact_imp_countably_compact: "compact U \<Longrightarrow> countably_compact U"
  3229   by (auto simp: compact_eq_heine_borel countably_compact_def)
  3230 
  3231 lemma countably_compact_imp_compact:
  3232   assumes "countably_compact U"
  3233     and ccover: "countable B" "\<forall>b\<in>B. open b"
  3234     and basis: "\<And>T x. open T \<Longrightarrow> x \<in> T \<Longrightarrow> x \<in> U \<Longrightarrow> \<exists>b\<in>B. x \<in> b \<and> b \<inter> U \<subseteq> T"
  3235   shows "compact U"
  3236   using `countably_compact U`
  3237   unfolding compact_eq_heine_borel countably_compact_def
  3238 proof safe
  3239   fix A
  3240   assume A: "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  3241   assume *: "\<forall>A. countable A \<longrightarrow> (\<forall>a\<in>A. open a) \<longrightarrow> U \<subseteq> \<Union>A \<longrightarrow> (\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T)"
  3242 
  3243   moreover def C \<equiv> "{b\<in>B. \<exists>a\<in>A. b \<inter> U \<subseteq> a}"
  3244   ultimately have "countable C" "\<forall>a\<in>C. open a"
  3245     unfolding C_def using ccover by auto
  3246   moreover
  3247   have "\<Union>A \<inter> U \<subseteq> \<Union>C"
  3248   proof safe
  3249     fix x a
  3250     assume "x \<in> U" "x \<in> a" "a \<in> A"
  3251     with basis[of a x] A obtain b where "b \<in> B" "x \<in> b" "b \<inter> U \<subseteq> a"
  3252       by blast
  3253     with `a \<in> A` show "x \<in> \<Union>C"
  3254       unfolding C_def by auto
  3255   qed
  3256   then have "U \<subseteq> \<Union>C" using `U \<subseteq> \<Union>A` by auto
  3257   ultimately obtain T where T: "T\<subseteq>C" "finite T" "U \<subseteq> \<Union>T"
  3258     using * by metis
  3259   then have "\<forall>t\<in>T. \<exists>a\<in>A. t \<inter> U \<subseteq> a"
  3260     by (auto simp: C_def)
  3261   then guess f unfolding bchoice_iff Bex_def ..
  3262   with T show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  3263     unfolding C_def by (intro exI[of _ "f`T"]) fastforce
  3264 qed
  3265 
  3266 lemma countably_compact_imp_compact_second_countable:
  3267   "countably_compact U \<Longrightarrow> compact (U :: 'a :: second_countable_topology set)"
  3268 proof (rule countably_compact_imp_compact)
  3269   fix T and x :: 'a
  3270   assume "open T" "x \<in> T"
  3271   from topological_basisE[OF is_basis this] guess b .
  3272   then show "\<exists>b\<in>SOME B. countable B \<and> topological_basis B. x \<in> b \<and> b \<inter> U \<subseteq> T"
  3273     by auto
  3274 qed (insert countable_basis topological_basis_open[OF is_basis], auto)
  3275 
  3276 lemma countably_compact_eq_compact:
  3277   "countably_compact U \<longleftrightarrow> compact (U :: 'a :: second_countable_topology set)"
  3278   using countably_compact_imp_compact_second_countable compact_imp_countably_compact by blast
  3279 
  3280 subsubsection{* Sequential compactness *}
  3281 
  3282 definition seq_compact :: "'a::topological_space set \<Rightarrow> bool"
  3283   where "seq_compact S \<longleftrightarrow>
  3284     (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow> (\<exists>l\<in>S. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially))"
  3285 
  3286 lemma seq_compactI:
  3287   assumes "\<And>f. \<forall>n. f n \<in> S \<Longrightarrow> \<exists>l\<in>S. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3288   shows "seq_compact S"
  3289   unfolding seq_compact_def using assms by fast
  3290 
  3291 lemma seq_compactE:
  3292   assumes "seq_compact S" "\<forall>n. f n \<in> S"
  3293   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
  3294   using assms unfolding seq_compact_def by fast
  3295 
  3296 lemma closed_sequentially: (* TODO: move upwards *)
  3297   assumes "closed s" and "\<forall>n. f n \<in> s" and "f ----> l"
  3298   shows "l \<in> s"
  3299 proof (rule ccontr)
  3300   assume "l \<notin> s"
  3301   with `closed s` and `f ----> l` have "eventually (\<lambda>n. f n \<in> - s) sequentially"
  3302     by (fast intro: topological_tendstoD)
  3303   with `\<forall>n. f n \<in> s` show "False"
  3304     by simp
  3305 qed
  3306 
  3307 lemma seq_compact_inter_closed:
  3308   assumes "seq_compact s" and "closed t"
  3309   shows "seq_compact (s \<inter> t)"
  3310 proof (rule seq_compactI)
  3311   fix f assume "\<forall>n::nat. f n \<in> s \<inter> t"
  3312   hence "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t"
  3313     by simp_all
  3314   from `seq_compact s` and `\<forall>n. f n \<in> s`
  3315   obtain l r where "l \<in> s" and r: "subseq r" and l: "(f \<circ> r) ----> l"
  3316     by (rule seq_compactE)
  3317   from `\<forall>n. f n \<in> t` have "\<forall>n. (f \<circ> r) n \<in> t"
  3318     by simp
  3319   from `closed t` and this and l have "l \<in> t"
  3320     by (rule closed_sequentially)
  3321   with `l \<in> s` and r and l show "\<exists>l\<in>s \<inter> t. \<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  3322     by fast
  3323 qed
  3324 
  3325 lemma seq_compact_closed_subset:
  3326   assumes "closed s" and "s \<subseteq> t" and "seq_compact t"
  3327   shows "seq_compact s"
  3328   using assms seq_compact_inter_closed [of t s] by (simp add: Int_absorb1)
  3329 
  3330 lemma seq_compact_imp_countably_compact:
  3331   fixes U :: "'a :: first_countable_topology set"
  3332   assumes "seq_compact U"
  3333   shows "countably_compact U"
  3334 proof (safe intro!: countably_compactI)
  3335   fix A
  3336   assume A: "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A" "countable A"
  3337   have subseq: "\<And>X. range X \<subseteq> U \<Longrightarrow> \<exists>r x. x \<in> U \<and> subseq r \<and> (X \<circ> r) ----> x"
  3338     using `seq_compact U` by (fastforce simp: seq_compact_def subset_eq)
  3339   show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  3340   proof cases
  3341     assume "finite A"
  3342     with A show ?thesis by auto
  3343   next
  3344     assume "infinite A"
  3345     then have "A \<noteq> {}" by auto
  3346     show ?thesis
  3347     proof (rule ccontr)
  3348       assume "\<not> (\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T)"
  3349       then have "\<forall>T. \<exists>x. T \<subseteq> A \<and> finite T \<longrightarrow> (x \<in> U - \<Union>T)"
  3350         by auto
  3351       then obtain X' where T: "\<And>T. T \<subseteq> A \<Longrightarrow> finite T \<Longrightarrow> X' T \<in> U - \<Union>T"
  3352         by metis
  3353       def X \<equiv> "\<lambda>n. X' (from_nat_into A ` {.. n})"
  3354       have X: "\<And>n. X n \<in> U - (\<Union>i\<le>n. from_nat_into A i)"
  3355         using `A \<noteq> {}` unfolding X_def SUP_def by (intro T) (auto intro: from_nat_into)
  3356       then have "range X \<subseteq> U"
  3357         by auto
  3358       with subseq[of X] obtain r x where "x \<in> U" and r: "subseq r" "(X \<circ> r) ----> x"
  3359         by auto
  3360       from `x\<in>U` `U \<subseteq> \<Union>A` from_nat_into_surj[OF `countable A`]
  3361       obtain n where "x \<in> from_nat_into A n" by auto
  3362       with r(2) A(1) from_nat_into[OF `A \<noteq> {}`, of n]
  3363       have "eventually (\<lambda>i. X (r i) \<in> from_nat_into A n) sequentially"
  3364         unfolding tendsto_def by (auto simp: comp_def)
  3365       then obtain N where "\<And>i. N \<le> i \<Longrightarrow> X (r i) \<in> from_nat_into A n"
  3366         by (auto simp: eventually_sequentially)
  3367       moreover from X have "\<And>i. n \<le> r i \<Longrightarrow> X (r i) \<notin> from_nat_into A n"
  3368         by auto
  3369       moreover from `subseq r`[THEN seq_suble, of "max n N"] have "\<exists>i. n \<le> r i \<and> N \<le> i"
  3370         by (auto intro!: exI[of _ "max n N"])
  3371       ultimately show False
  3372         by auto
  3373     qed
  3374   qed
  3375 qed
  3376 
  3377 lemma compact_imp_seq_compact:
  3378   fixes U :: "'a :: first_countable_topology set"
  3379   assumes "compact U"
  3380   shows "seq_compact U"
  3381   unfolding seq_compact_def
  3382 proof safe
  3383   fix X :: "nat \<Rightarrow> 'a"
  3384   assume "\<forall>n. X n \<in> U"
  3385   then have "eventually (\<lambda>x. x \<in> U) (filtermap X sequentially)"
  3386     by (auto simp: eventually_filtermap)
  3387   moreover
  3388   have "filtermap X sequentially \<noteq> bot"
  3389     by (simp add: trivial_limit_def eventually_filtermap)
  3390   ultimately
  3391   obtain x where "x \<in> U" and x: "inf (nhds x) (filtermap X sequentially) \<noteq> bot" (is "?F \<noteq> _")
  3392     using `compact U` by (auto simp: compact_filter)
  3393 
  3394   from countable_basis_at_decseq[of x] guess A . note A = this
  3395   def s \<equiv> "\<lambda>n i. SOME j. i < j \<and> X j \<in> A (Suc n)"
  3396   {
  3397     fix n i
  3398     have "\<exists>a. i < a \<and> X a \<in> A (Suc n)"
  3399     proof (rule ccontr)
  3400       assume "\<not> (\<exists>a>i. X a \<in> A (Suc n))"
  3401       then have "\<And>a. Suc i \<le> a \<Longrightarrow> X a \<notin> A (Suc n)"
  3402         by auto
  3403       then have "eventually (\<lambda>x. x \<notin> A (Suc n)) (filtermap X sequentially)"
  3404         by (auto simp: eventually_filtermap eventually_sequentially)
  3405       moreover have "eventually (\<lambda>x. x \<in> A (Suc n)) (nhds x)"
  3406         using A(1,2)[of "Suc n"] by (auto simp: eventually_nhds)
  3407       ultimately have "eventually (\<lambda>x. False) ?F"
  3408         by (auto simp add: eventually_inf)
  3409       with x show False
  3410         by (simp add: eventually_False)
  3411     qed
  3412     then have "i < s n i" "X (s n i) \<in> A (Suc n)"
  3413       unfolding s_def by (auto intro: someI2_ex)
  3414   }
  3415   note s = this
  3416   def r \<equiv> "nat_rec (s 0 0) s"
  3417   have "subseq r"
  3418     by (auto simp: r_def s subseq_Suc_iff)
  3419   moreover
  3420   have "(\<lambda>n. X (r n)) ----> x"
  3421   proof (rule topological_tendstoI)
  3422     fix S
  3423     assume "open S" "x \<in> S"
  3424     with A(3) have "eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  3425       by auto
  3426     moreover
  3427     {
  3428       fix i
  3429       assume "Suc 0 \<le> i"
  3430       then have "X (r i) \<in> A i"
  3431         by (cases i) (simp_all add: r_def s)
  3432     }
  3433     then have "eventually (\<lambda>i. X (r i) \<in> A i) sequentially"
  3434       by (auto simp: eventually_sequentially)
  3435     ultimately show "eventually (\<lambda>i. X (r i) \<in> S) sequentially"
  3436       by eventually_elim auto
  3437   qed
  3438   ultimately show "\<exists>x \<in> U. \<exists>r. subseq r \<and> (X \<circ> r) ----> x"
  3439     using `x \<in> U` by (auto simp: convergent_def comp_def)
  3440 qed
  3441 
  3442 lemma countably_compact_imp_acc_point:
  3443   assumes "countably_compact s"
  3444     and "countable t"
  3445     and "infinite t"
  3446     and "t \<subseteq> s"
  3447   shows "\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t)"
  3448 proof (rule ccontr)
  3449   def C \<equiv> "(\<lambda>F. interior (F \<union> (- t))) ` {F. finite F \<and> F \<subseteq> t }"
  3450   note `countably_compact s`
  3451   moreover have "\<forall>t\<in>C. open t"
  3452     by (auto simp: C_def)
  3453   moreover
  3454   assume "\<not> (\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t))"
  3455   then have s: "\<And>x. x \<in> s \<Longrightarrow> \<exists>U. x\<in>U \<and> open U \<and> finite (U \<inter> t)" by metis
  3456   have "s \<subseteq> \<Union>C"
  3457     using `t \<subseteq> s`
  3458     unfolding C_def Union_image_eq
  3459     apply (safe dest!: s)
  3460     apply (rule_tac a="U \<inter> t" in UN_I)
  3461     apply (auto intro!: interiorI simp add: finite_subset)
  3462     done
  3463   moreover
  3464   from `countable t` have "countable C"
  3465     unfolding C_def by (auto intro: countable_Collect_finite_subset)
  3466   ultimately guess D by (rule countably_compactE)
  3467   then obtain E where E: "E \<subseteq> {F. finite F \<and> F \<subseteq> t }" "finite E"
  3468     and s: "s \<subseteq> (\<Union>F\<in>E. interior (F \<union> (- t)))"
  3469     by (metis (lifting) Union_image_eq finite_subset_image C_def)
  3470   from s `t \<subseteq> s` have "t \<subseteq> \<Union>E"
  3471     using interior_subset by blast
  3472   moreover have "finite (\<Union>E)"
  3473     using E by auto
  3474   ultimately show False using `infinite t`
  3475     by (auto simp: finite_subset)
  3476 qed
  3477 
  3478 lemma countable_acc_point_imp_seq_compact:
  3479   fixes s :: "'a::first_countable_topology set"
  3480   assumes "\<forall>t. infinite t \<and> countable t \<and> t \<subseteq> s \<longrightarrow>
  3481     (\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t))"
  3482   shows "seq_compact s"
  3483 proof -
  3484   {
  3485     fix f :: "nat \<Rightarrow> 'a"
  3486     assume f: "\<forall>n. f n \<in> s"
  3487     have "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3488     proof (cases "finite (range f)")
  3489       case True
  3490       obtain l where "infinite {n. f n = f l}"
  3491         using pigeonhole_infinite[OF _ True] by auto
  3492       then obtain r where "subseq r" and fr: "\<forall>n. f (r n) = f l"
  3493         using infinite_enumerate by blast
  3494       then have "subseq r \<and> (f \<circ> r) ----> f l"
  3495         by (simp add: fr tendsto_const o_def)
  3496       with f show "\<exists>l\<in>s. \<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  3497         by auto
  3498     next
  3499       case False
  3500       with f assms have "\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> range f)"
  3501         by auto
  3502       then obtain l where "l \<in> s" "\<forall>U. l\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> range f)" ..
  3503       from this(2) have "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3504         using acc_point_range_imp_convergent_subsequence[of l f] by auto
  3505       with `l \<in> s` show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" ..
  3506     qed
  3507   }
  3508   then show ?thesis
  3509     unfolding seq_compact_def by auto
  3510 qed
  3511 
  3512 lemma seq_compact_eq_countably_compact:
  3513   fixes U :: "'a :: first_countable_topology set"
  3514   shows "seq_compact U \<longleftrightarrow> countably_compact U"
  3515   using
  3516     countable_acc_point_imp_seq_compact
  3517     countably_compact_imp_acc_point
  3518     seq_compact_imp_countably_compact
  3519   by metis
  3520 
  3521 lemma seq_compact_eq_acc_point:
  3522   fixes s :: "'a :: first_countable_topology set"
  3523   shows "seq_compact s \<longleftrightarrow>
  3524     (\<forall>t. infinite t \<and> countable t \<and> t \<subseteq> s --> (\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t)))"
  3525   using
  3526     countable_acc_point_imp_seq_compact[of s]
  3527     countably_compact_imp_acc_point[of s]
  3528     seq_compact_imp_countably_compact[of s]
  3529   by metis
  3530 
  3531 lemma seq_compact_eq_compact:
  3532   fixes U :: "'a :: second_countable_topology set"
  3533   shows "seq_compact U \<longleftrightarrow> compact U"
  3534   using seq_compact_eq_countably_compact countably_compact_eq_compact by blast
  3535 
  3536 lemma bolzano_weierstrass_imp_seq_compact:
  3537   fixes s :: "'a::{t1_space, first_countable_topology} set"
  3538   shows "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t) \<Longrightarrow> seq_compact s"
  3539   by (rule countable_acc_point_imp_seq_compact) (metis islimpt_eq_acc_point)
  3540 
  3541 subsubsection{* Total boundedness *}
  3542 
  3543 lemma cauchy_def: "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m n. m \<ge> N \<and> n \<ge> N --> dist(s m)(s n) < e)"
  3544   unfolding Cauchy_def by metis
  3545 
  3546 fun helper_1 :: "('a::metric_space set) \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> 'a"
  3547 where
  3548   "helper_1 s e n = (SOME y::'a. y \<in> s \<and> (\<forall>m<n. \<not> (dist (helper_1 s e m) y < e)))"
  3549 declare helper_1.simps[simp del]
  3550 
  3551 lemma seq_compact_imp_totally_bounded:
  3552   assumes "seq_compact s"
  3553   shows "\<forall>e>0. \<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k))"
  3554 proof (rule, rule, rule ccontr)
  3555   fix e::real
  3556   assume "e > 0"
  3557   assume assm: "\<not> (\<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>((\<lambda>x. ball x e) ` k))"
  3558   def x \<equiv> "helper_1 s e"
  3559   {
  3560     fix n
  3561     have "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  3562     proof (induct n rule: nat_less_induct)
  3563       fix n
  3564       def Q \<equiv> "(\<lambda>y. y \<in> s \<and> (\<forall>m<n. \<not> dist (x m) y < e))"
  3565       assume as: "\<forall>m<n. x m \<in> s \<and> (\<forall>ma<m. \<not> dist (x ma) (x m) < e)"
  3566       have "\<not> s \<subseteq> (\<Union>x\<in>x ` {0..<n}. ball x e)"
  3567         using assm
  3568         apply simp
  3569         apply (erule_tac x="x ` {0 ..< n}" in allE)
  3570         using as
  3571         apply auto
  3572         done
  3573       then obtain z where z:"z\<in>s" "z \<notin> (\<Union>x\<in>x ` {0..<n}. ball x e)"
  3574         unfolding subset_eq by auto
  3575       have "Q (x n)"
  3576         unfolding x_def and helper_1.simps[of s e n]
  3577         apply (rule someI2[where a=z])
  3578         unfolding x_def[symmetric] and Q_def
  3579         using z
  3580         apply auto
  3581         done
  3582       then show "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  3583         unfolding Q_def by auto
  3584     qed
  3585   }
  3586   then have "\<forall>n::nat. x n \<in> s" and x:"\<forall>n. \<forall>m < n. \<not> (dist (x m) (x n) < e)"
  3587     by blast+
  3588   then obtain l r where "l\<in>s" and r:"subseq r" and "((x \<circ> r) ---> l) sequentially"
  3589     using assms(1)[unfolded seq_compact_def, THEN spec[where x=x]] by auto
  3590   from this(3) have "Cauchy (x \<circ> r)"
  3591     using LIMSEQ_imp_Cauchy by auto
  3592   then obtain N::nat where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist ((x \<circ> r) m) ((x \<circ> r) n) < e"
  3593     unfolding cauchy_def using `e>0` by auto
  3594   show False
  3595     using N[THEN spec[where x=N], THEN spec[where x="N+1"]]
  3596     using r[unfolded subseq_def, THEN spec[where x=N], THEN spec[where x="N+1"]]
  3597     using x[THEN spec[where x="r (N+1)"], THEN spec[where x="r (N)"]]
  3598     by auto
  3599 qed
  3600 
  3601 subsubsection{* Heine-Borel theorem *}
  3602 
  3603 lemma seq_compact_imp_heine_borel:
  3604   fixes s :: "'a :: metric_space set"
  3605   assumes "seq_compact s"
  3606   shows "compact s"
  3607 proof -
  3608   from seq_compact_imp_totally_bounded[OF `seq_compact s`]
  3609   guess f unfolding choice_iff' .. note f = this
  3610   def K \<equiv> "(\<lambda>(x, r). ball x r) ` ((\<Union>e \<in> \<rat> \<inter> {0 <..}. f e) \<times> \<rat>)"
  3611   have "countably_compact s"
  3612     using `seq_compact s` by (rule seq_compact_imp_countably_compact)
  3613   then show "compact s"
  3614   proof (rule countably_compact_imp_compact)
  3615     show "countable K"
  3616       unfolding K_def using f
  3617       by (auto intro: countable_finite countable_subset countable_rat
  3618                intro!: countable_image countable_SIGMA countable_UN)
  3619     show "\<forall>b\<in>K. open b" by (auto simp: K_def)
  3620   next
  3621     fix T x
  3622     assume T: "open T" "x \<in> T" and x: "x \<in> s"
  3623     from openE[OF T] obtain e where "0 < e" "ball x e \<subseteq> T"
  3624       by auto
  3625     then have "0 < e / 2" "ball x (e / 2) \<subseteq> T"
  3626       by auto
  3627     from Rats_dense_in_real[OF `0 < e / 2`] obtain r where "r \<in> \<rat>" "0 < r" "r < e / 2"
  3628       by auto
  3629     from f[rule_format, of r] `0 < r` `x \<in> s` obtain k where "k \<in> f r" "x \<in> ball k r"
  3630       unfolding Union_image_eq by auto
  3631     from `r \<in> \<rat>` `0 < r` `k \<in> f r` have "ball k r \<in> K"
  3632       by (auto simp: K_def)
  3633     then show "\<exists>b\<in>K. x \<in> b \<and> b \<inter> s \<subseteq> T"
  3634     proof (rule bexI[rotated], safe)
  3635       fix y
  3636       assume "y \<in> ball k r"
  3637       with `r < e / 2` `x \<in> ball k r` have "dist x y < e"
  3638         by (intro dist_double[where x = k and d=e]) (auto simp: dist_commute)
  3639       with `ball x e \<subseteq> T` show "y \<in> T"
  3640         by auto
  3641     next
  3642       show "x \<in> ball k r" by fact
  3643     qed
  3644   qed
  3645 qed
  3646 
  3647 lemma compact_eq_seq_compact_metric:
  3648   "compact (s :: 'a::metric_space set) \<longleftrightarrow> seq_compact s"
  3649   using compact_imp_seq_compact seq_compact_imp_heine_borel by blast
  3650 
  3651 lemma compact_def:
  3652   "compact (S :: 'a::metric_space set) \<longleftrightarrow>
  3653    (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow> (\<exists>l\<in>S. \<exists>r. subseq r \<and> (f \<circ> r) ----> l))"
  3654   unfolding compact_eq_seq_compact_metric seq_compact_def by auto
  3655 
  3656 subsubsection {* Complete the chain of compactness variants *}
  3657 
  3658 lemma compact_eq_bolzano_weierstrass:
  3659   fixes s :: "'a::metric_space set"
  3660   shows "compact s \<longleftrightarrow> (\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t))"
  3661   (is "?lhs = ?rhs")
  3662 proof
  3663   assume ?lhs
  3664   then show ?rhs
  3665     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  3666 next
  3667   assume ?rhs
  3668   then show ?lhs
  3669     unfolding compact_eq_seq_compact_metric by (rule bolzano_weierstrass_imp_seq_compact)
  3670 qed
  3671 
  3672 lemma bolzano_weierstrass_imp_bounded:
  3673   "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t) \<Longrightarrow> bounded s"
  3674   using compact_imp_bounded unfolding compact_eq_bolzano_weierstrass .
  3675 
  3676 subsection {* Metric spaces with the Heine-Borel property *}
  3677 
  3678 text {*
  3679   A metric space (or topological vector space) is said to have the
  3680   Heine-Borel property if every closed and bounded subset is compact.
  3681 *}
  3682 
  3683 class heine_borel = metric_space +
  3684   assumes bounded_imp_convergent_subsequence:
  3685     "bounded (range f) \<Longrightarrow> \<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3686 
  3687 lemma bounded_closed_imp_seq_compact:
  3688   fixes s::"'a::heine_borel set"
  3689   assumes "bounded s"
  3690     and "closed s"
  3691   shows "seq_compact s"
  3692 proof (unfold seq_compact_def, clarify)
  3693   fix f :: "nat \<Rightarrow> 'a"
  3694   assume f: "\<forall>n. f n \<in> s"
  3695   with `bounded s` have "bounded (range f)"
  3696     by (auto intro: bounded_subset)
  3697   obtain l r where r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  3698     using bounded_imp_convergent_subsequence [OF `bounded (range f)`] by auto
  3699   from f have fr: "\<forall>n. (f \<circ> r) n \<in> s"
  3700     by simp
  3701   have "l \<in> s" using `closed s` fr l
  3702     by (rule closed_sequentially)
  3703   show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3704     using `l \<in> s` r l by blast
  3705 qed
  3706 
  3707 lemma compact_eq_bounded_closed:
  3708   fixes s :: "'a::heine_borel set"
  3709   shows "compact s \<longleftrightarrow> bounded s \<and> closed s"
  3710   (is "?lhs = ?rhs")
  3711 proof
  3712   assume ?lhs
  3713   then show ?rhs
  3714     using compact_imp_closed compact_imp_bounded
  3715     by blast
  3716 next
  3717   assume ?rhs
  3718   then show ?lhs
  3719     using bounded_closed_imp_seq_compact[of s]
  3720     unfolding compact_eq_seq_compact_metric
  3721     by auto
  3722 qed
  3723 
  3724 (* TODO: is this lemma necessary? *)
  3725 lemma bounded_increasing_convergent:
  3726   fixes s :: "nat \<Rightarrow> real"
  3727   shows "bounded {s n| n. True} \<Longrightarrow> \<forall>n. s n \<le> s (Suc n) \<Longrightarrow> \<exists>l. s ----> l"
  3728   using Bseq_mono_convergent[of s] incseq_Suc_iff[of s]
  3729   by (auto simp: image_def Bseq_eq_bounded convergent_def incseq_def)
  3730 
  3731 instance real :: heine_borel
  3732 proof
  3733   fix f :: "nat \<Rightarrow> real"
  3734   assume f: "bounded (range f)"
  3735   obtain r where r: "subseq r" "monoseq (f \<circ> r)"
  3736     unfolding comp_def by (metis seq_monosub)
  3737   then have "Bseq (f \<circ> r)"
  3738     unfolding Bseq_eq_bounded using f by (auto intro: bounded_subset)
  3739   with r show "\<exists>l r. subseq r \<and> (f \<circ> r) ----> l"
  3740     using Bseq_monoseq_convergent[of "f \<circ> r"] by (auto simp: convergent_def)
  3741 qed
  3742 
  3743 lemma compact_lemma:
  3744   fixes f :: "nat \<Rightarrow> 'a::euclidean_space"
  3745   assumes "bounded (range f)"
  3746   shows "\<forall>d\<subseteq>Basis. \<exists>l::'a. \<exists> r.
  3747     subseq r \<and> (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially)"
  3748 proof safe
  3749   fix d :: "'a set"
  3750   assume d: "d \<subseteq> Basis"
  3751   with finite_Basis have "finite d"
  3752     by (blast intro: finite_subset)
  3753   from this d show "\<exists>l::'a. \<exists>r. subseq r \<and>
  3754     (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially)"
  3755   proof (induct d)
  3756     case empty
  3757     then show ?case
  3758       unfolding subseq_def by auto
  3759   next
  3760     case (insert k d)
  3761     have k[intro]: "k \<in> Basis"
  3762       using insert by auto
  3763     have s': "bounded ((\<lambda>x. x \<bullet> k) ` range f)"
  3764       using `bounded (range f)`
  3765       by (auto intro!: bounded_linear_image bounded_linear_inner_left)
  3766     obtain l1::"'a" and r1 where r1: "subseq r1"
  3767       and lr1: "\<forall>e > 0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) \<bullet> i) (l1 \<bullet> i) < e) sequentially"
  3768       using insert(3) using insert(4) by auto
  3769     have f': "\<forall>n. f (r1 n) \<bullet> k \<in> (\<lambda>x. x \<bullet> k) ` range f"
  3770       by simp
  3771     have "bounded (range (\<lambda>i. f (r1 i) \<bullet> k))"
  3772       by (metis (lifting) bounded_subset f' image_subsetI s')
  3773     then obtain l2 r2 where r2:"subseq r2" and lr2:"((\<lambda>i. f (r1 (r2 i)) \<bullet> k) ---> l2) sequentially"
  3774       using bounded_imp_convergent_subsequence[of "\<lambda>i. f (r1 i) \<bullet> k"]
  3775       by (auto simp: o_def)
  3776     def r \<equiv> "r1 \<circ> r2"
  3777     have r:"subseq r"
  3778       using r1 and r2 unfolding r_def o_def subseq_def by auto
  3779     moreover
  3780     def l \<equiv> "(\<Sum>i\<in>Basis. (if i = k then l2 else l1\<bullet>i) *\<^sub>R i)::'a"
  3781     {
  3782       fix e::real
  3783       assume "e > 0"
  3784       from lr1 `e > 0` have N1: "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) \<bullet> i) (l1 \<bullet> i) < e) sequentially"
  3785         by blast
  3786       from lr2 `e > 0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) \<bullet> k) l2 < e) sequentially"
  3787         by (rule tendstoD)
  3788       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) \<bullet> i) (l1 \<bullet> i) < e) sequentially"
  3789         by (rule eventually_subseq)
  3790       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially"
  3791         using N1' N2
  3792         by eventually_elim (insert insert.prems, auto simp: l_def r_def o_def)
  3793     }
  3794     ultimately show ?case by auto
  3795   qed
  3796 qed
  3797 
  3798 instance euclidean_space \<subseteq> heine_borel
  3799 proof
  3800   fix f :: "nat \<Rightarrow> 'a"
  3801   assume f: "bounded (range f)"
  3802   then obtain l::'a and r where r: "subseq r"
  3803     and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially"
  3804     using compact_lemma [OF f] by blast
  3805   {
  3806     fix e::real
  3807     assume "e > 0"
  3808     then have "e / real_of_nat DIM('a) > 0"
  3809       by (auto intro!: divide_pos_pos DIM_positive)
  3810     with l have "eventually (\<lambda>n. \<forall>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i) < e / (real_of_nat DIM('a))) sequentially"
  3811       by simp
  3812     moreover
  3813     {
  3814       fix n
  3815       assume n: "\<forall>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i) < e / (real_of_nat DIM('a))"
  3816       have "dist (f (r n)) l \<le> (\<Sum>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i))"
  3817         apply (subst euclidean_dist_l2)
  3818         using zero_le_dist
  3819         apply (rule setL2_le_setsum)
  3820         done
  3821       also have "\<dots> < (\<Sum>i\<in>(Basis::'a set). e / (real_of_nat DIM('a)))"
  3822         apply (rule setsum_strict_mono)
  3823         using n
  3824         apply auto
  3825         done
  3826       finally have "dist (f (r n)) l < e"
  3827         by auto
  3828     }
  3829     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  3830       by (rule eventually_elim1)
  3831   }
  3832   then have *: "((f \<circ> r) ---> l) sequentially"
  3833     unfolding o_def tendsto_iff by simp
  3834   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3835     by auto
  3836 qed
  3837 
  3838 lemma bounded_fst: "bounded s \<Longrightarrow> bounded (fst ` s)"
  3839   unfolding bounded_def
  3840   apply clarify
  3841   apply (rule_tac x="a" in exI)
  3842   apply (rule_tac x="e" in exI)
  3843   apply clarsimp
  3844   apply (drule (1) bspec)
  3845   apply (simp add: dist_Pair_Pair)
  3846   apply (erule order_trans [OF real_sqrt_sum_squares_ge1])
  3847   done
  3848 
  3849 lemma bounded_snd: "bounded s \<Longrightarrow> bounded (snd ` s)"
  3850   unfolding bounded_def
  3851   apply clarify
  3852   apply (rule_tac x="b" in exI)
  3853   apply (rule_tac x="e" in exI)
  3854   apply clarsimp
  3855   apply (drule (1) bspec)
  3856   apply (simp add: dist_Pair_Pair)
  3857   apply (erule order_trans [OF real_sqrt_sum_squares_ge2])
  3858   done
  3859 
  3860 instance prod :: (heine_borel, heine_borel) heine_borel
  3861 proof
  3862   fix f :: "nat \<Rightarrow> 'a \<times> 'b"
  3863   assume f: "bounded (range f)"
  3864   from f have s1: "bounded (range (fst \<circ> f))"
  3865     unfolding image_comp by (rule bounded_fst)
  3866   obtain l1 r1 where r1: "subseq r1" and l1: "(\<lambda>n. fst (f (r1 n))) ----> l1"
  3867     using bounded_imp_convergent_subsequence [OF s1] unfolding o_def by fast
  3868   from f have s2: "bounded (range (snd \<circ> f \<circ> r1))"
  3869     by (auto simp add: image_comp intro: bounded_snd bounded_subset)
  3870   obtain l2 r2 where r2: "subseq r2" and l2: "((\<lambda>n. snd (f (r1 (r2 n)))) ---> l2) sequentially"
  3871     using bounded_imp_convergent_subsequence [OF s2]
  3872     unfolding o_def by fast
  3873   have l1': "((\<lambda>n. fst (f (r1 (r2 n)))) ---> l1) sequentially"
  3874     using LIMSEQ_subseq_LIMSEQ [OF l1 r2] unfolding o_def .
  3875   have l: "((f \<circ> (r1 \<circ> r2)) ---> (l1, l2)) sequentially"
  3876     using tendsto_Pair [OF l1' l2] unfolding o_def by simp
  3877   have r: "subseq (r1 \<circ> r2)"
  3878     using r1 r2 unfolding subseq_def by simp
  3879   show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3880     using l r by fast
  3881 qed
  3882 
  3883 subsubsection {* Completeness *}
  3884 
  3885 definition complete :: "'a::metric_space set \<Rightarrow> bool"
  3886   where "complete s \<longleftrightarrow> (\<forall>f. (\<forall>n. f n \<in> s) \<and> Cauchy f \<longrightarrow> (\<exists>l\<in>s. f ----> l))"
  3887 
  3888 lemma completeI:
  3889   assumes "\<And>f. \<forall>n. f n \<in> s \<Longrightarrow> Cauchy f \<Longrightarrow> \<exists>l\<in>s. f ----> l"
  3890   shows "complete s"
  3891   using assms unfolding complete_def by fast
  3892 
  3893 lemma completeE:
  3894   assumes "complete s" and "\<forall>n. f n \<in> s" and "Cauchy f"
  3895   obtains l where "l \<in> s" and "f ----> l"
  3896   using assms unfolding complete_def by fast
  3897 
  3898 lemma compact_imp_complete:
  3899   assumes "compact s"
  3900   shows "complete s"
  3901 proof -
  3902   {
  3903     fix f
  3904     assume as: "(\<forall>n::nat. f n \<in> s)" "Cauchy f"
  3905     from as(1) obtain l r where lr: "l\<in>s" "subseq r" "(f \<circ> r) ----> l"
  3906       using assms unfolding compact_def by blast
  3907 
  3908     note lr' = seq_suble [OF lr(2)]
  3909 
  3910     {
  3911       fix e :: real
  3912       assume "e > 0"
  3913       from as(2) obtain N where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (f m) (f n) < e/2"
  3914         unfolding cauchy_def
  3915         using `e > 0`
  3916         apply (erule_tac x="e/2" in allE)
  3917         apply auto
  3918         done
  3919       from lr(3)[unfolded LIMSEQ_def, THEN spec[where x="e/2"]]
  3920       obtain M where M:"\<forall>n\<ge>M. dist ((f \<circ> r) n) l < e/2"
  3921         using `e > 0` by auto
  3922       {
  3923         fix n :: nat
  3924         assume n: "n \<ge> max N M"
  3925         have "dist ((f \<circ> r) n) l < e/2"
  3926           using n M by auto
  3927         moreover have "r n \<ge> N"
  3928           using lr'[of n] n by auto
  3929         then have "dist (f n) ((f \<circ> r) n) < e / 2"
  3930           using N and n by auto
  3931         ultimately have "dist (f n) l < e"
  3932           using dist_triangle_half_r[of "f (r n)" "f n" e l]
  3933           by (auto simp add: dist_commute)
  3934       }
  3935       then have "\<exists>N. \<forall>n\<ge>N. dist (f n) l < e" by blast
  3936     }
  3937     then have "\<exists>l\<in>s. (f ---> l) sequentially" using `l\<in>s`
  3938       unfolding LIMSEQ_def by auto
  3939   }
  3940   then show ?thesis unfolding complete_def by auto
  3941 qed
  3942 
  3943 lemma nat_approx_posE:
  3944   fixes e::real
  3945   assumes "0 < e"
  3946   obtains n :: nat where "1 / (Suc n) < e"
  3947 proof atomize_elim
  3948   have " 1 / real (Suc (nat (ceiling (1/e)))) < 1 / (ceiling (1/e))"
  3949     by (rule divide_strict_left_mono) (auto intro!: mult_pos_pos simp: `0 < e`)
  3950   also have "1 / (ceiling (1/e)) \<le> 1 / (1/e)"
  3951     by (rule divide_left_mono) (auto intro!: divide_pos_pos simp: `0 < e`)
  3952   also have "\<dots> = e" by simp
  3953   finally show  "\<exists>n. 1 / real (Suc n) < e" ..
  3954 qed
  3955 
  3956 lemma compact_eq_totally_bounded:
  3957   "compact s \<longleftrightarrow> complete s \<and> (\<forall>e>0. \<exists>k. finite k \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k)))"
  3958     (is "_ \<longleftrightarrow> ?rhs")
  3959 proof
  3960   assume assms: "?rhs"
  3961   then obtain k where k: "\<And>e. 0 < e \<Longrightarrow> finite (k e)" "\<And>e. 0 < e \<Longrightarrow> s \<subseteq> (\<Union>x\<in>k e. ball x e)"
  3962     by (auto simp: choice_iff')
  3963 
  3964   show "compact s"
  3965   proof cases
  3966     assume "s = {}"
  3967     then show "compact s" by (simp add: compact_def)
  3968   next
  3969     assume "s \<noteq> {}"
  3970     show ?thesis
  3971       unfolding compact_def
  3972     proof safe
  3973       fix f :: "nat \<Rightarrow> 'a"
  3974       assume f: "\<forall>n. f n \<in> s"
  3975 
  3976       def e \<equiv> "\<lambda>n. 1 / (2 * Suc n)"
  3977       then have [simp]: "\<And>n. 0 < e n" by auto
  3978       def B \<equiv> "\<lambda>n U. SOME b. infinite {n. f n \<in> b} \<and> (\<exists>x. b \<subseteq> ball x (e n) \<inter> U)"
  3979       {
  3980         fix n U
  3981         assume "infinite {n. f n \<in> U}"
  3982         then have "\<exists>b\<in>k (e n). infinite {i\<in>{n. f n \<in> U}. f i \<in> ball b (e n)}"
  3983           using k f by (intro pigeonhole_infinite_rel) (auto simp: subset_eq)
  3984         then guess a ..
  3985         then have "\<exists>b. infinite {i. f i \<in> b} \<and> (\<exists>x. b \<subseteq> ball x (e n) \<inter> U)"
  3986           by (intro exI[of _ "ball a (e n) \<inter> U"] exI[of _ a]) (auto simp: ac_simps)
  3987         from someI_ex[OF this]
  3988         have "infinite {i. f i \<in> B n U}" "\<exists>x. B n U \<subseteq> ball x (e n) \<inter> U"
  3989           unfolding B_def by auto
  3990       }
  3991       note B = this
  3992 
  3993       def F \<equiv> "nat_rec (B 0 UNIV) B"
  3994       {
  3995         fix n
  3996         have "infinite {i. f i \<in> F n}"
  3997           by (induct n) (auto simp: F_def B)
  3998       }
  3999       then have F: "\<And>n. \<exists>x. F (Suc n) \<subseteq> ball x (e n) \<inter> F n"
  4000         using B by (simp add: F_def)
  4001       then have F_dec: "\<And>m n. m \<le> n \<Longrightarrow> F n \<subseteq> F m"
  4002         using decseq_SucI[of F] by (auto simp: decseq_def)
  4003 
  4004       obtain sel where sel: "\<And>k i. i < sel k i" "\<And>k i. f (sel k i) \<in> F k"
  4005       proof (atomize_elim, unfold all_conj_distrib[symmetric], intro choice allI)
  4006         fix k i
  4007         have "infinite ({n. f n \<in> F k} - {.. i})"
  4008           using `infinite {n. f n \<in> F k}` by auto
  4009         from infinite_imp_nonempty[OF this]
  4010         show "\<exists>x>i. f x \<in> F k"
  4011           by (simp add: set_eq_iff not_le conj_commute)
  4012       qed
  4013 
  4014       def t \<equiv> "nat_rec (sel 0 0) (\<lambda>n i. sel (Suc n) i)"
  4015       have "subseq t"
  4016         unfolding subseq_Suc_iff by (simp add: t_def sel)
  4017       moreover have "\<forall>i. (f \<circ> t) i \<in> s"
  4018         using f by auto
  4019       moreover
  4020       {
  4021         fix n
  4022         have "(f \<circ> t) n \<in> F n"
  4023           by (cases n) (simp_all add: t_def sel)
  4024       }
  4025       note t = this
  4026 
  4027       have "Cauchy (f \<circ> t)"
  4028       proof (safe intro!: metric_CauchyI exI elim!: nat_approx_posE)
  4029         fix r :: real and N n m
  4030         assume "1 / Suc N < r" "Suc N \<le> n" "Suc N \<le> m"
  4031         then have "(f \<circ> t) n \<in> F (Suc N)" "(f \<circ> t) m \<in> F (Suc N)" "2 * e N < r"
  4032           using F_dec t by (auto simp: e_def field_simps real_of_nat_Suc)
  4033         with F[of N] obtain x where "dist x ((f \<circ> t) n) < e N" "dist x ((f \<circ> t) m) < e N"
  4034           by (auto simp: subset_eq)
  4035         with dist_triangle[of "(f \<circ> t) m" "(f \<circ> t) n" x] `2 * e N < r`
  4036         show "dist ((f \<circ> t) m) ((f \<circ> t) n) < r"
  4037           by (simp add: dist_commute)
  4038       qed
  4039 
  4040       ultimately show "\<exists>l\<in>s. \<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  4041         using assms unfolding complete_def by blast
  4042     qed
  4043   qed
  4044 qed (metis compact_imp_complete compact_imp_seq_compact seq_compact_imp_totally_bounded)
  4045 
  4046 lemma cauchy: "Cauchy s \<longleftrightarrow> (\<forall>e>0.\<exists> N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  4047 proof -
  4048   {
  4049     assume ?rhs
  4050     {
  4051       fix e::real
  4052       assume "e>0"
  4053       with `?rhs` obtain N where N:"\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  4054         by (erule_tac x="e/2" in allE) auto
  4055       {
  4056         fix n m
  4057         assume nm:"N \<le> m \<and> N \<le> n"
  4058         then have "dist (s m) (s n) < e" using N
  4059           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  4060           by blast
  4061       }
  4062       then have "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  4063         by blast
  4064     }
  4065     then have ?lhs
  4066       unfolding cauchy_def
  4067       by blast
  4068   }
  4069   then show ?thesis
  4070     unfolding cauchy_def
  4071     using dist_triangle_half_l
  4072     by blast
  4073 qed
  4074 
  4075 lemma cauchy_imp_bounded:
  4076   assumes "Cauchy s"
  4077   shows "bounded (range s)"
  4078 proof -
  4079   from assms obtain N :: nat where "\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < 1"
  4080     unfolding cauchy_def
  4081     apply (erule_tac x= 1 in allE)
  4082     apply auto
  4083     done
  4084   then have N:"\<forall>n. N \<le> n \<longrightarrow> dist (s N) (s n) < 1" by auto
  4085   moreover
  4086   have "bounded (s ` {0..N})"
  4087     using finite_imp_bounded[of "s ` {1..N}"] by auto
  4088   then obtain a where a:"\<forall>x\<in>s ` {0..N}. dist (s N) x \<le> a"
  4089     unfolding bounded_any_center [where a="s N"] by auto
  4090   ultimately show "?thesis"
  4091     unfolding bounded_any_center [where a="s N"]
  4092     apply (rule_tac x="max a 1" in exI)
  4093     apply auto
  4094     apply (erule_tac x=y in allE)
  4095     apply (erule_tac x=y in ballE)
  4096     apply auto
  4097     done
  4098 qed
  4099 
  4100 instance heine_borel < complete_space
  4101 proof
  4102   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  4103   then have "bounded (range f)"
  4104     by (rule cauchy_imp_bounded)
  4105   then have "compact (closure (range f))"
  4106     unfolding compact_eq_bounded_closed by auto
  4107   then have "complete (closure (range f))"
  4108     by (rule compact_imp_complete)
  4109   moreover have "\<forall>n. f n \<in> closure (range f)"
  4110     using closure_subset [of "range f"] by auto
  4111   ultimately have "\<exists>l\<in>closure (range f). (f ---> l) sequentially"
  4112     using `Cauchy f` unfolding complete_def by auto
  4113   then show "convergent f"
  4114     unfolding convergent_def by auto
  4115 qed
  4116 
  4117 instance euclidean_space \<subseteq> banach ..
  4118 
  4119 lemma complete_UNIV: "complete (UNIV :: ('a::complete_space) set)"
  4120 proof (rule completeI)
  4121   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  4122   then have "convergent f" by (rule Cauchy_convergent)
  4123   then show "\<exists>l\<in>UNIV. f ----> l" unfolding convergent_def by simp
  4124 qed
  4125 
  4126 lemma complete_imp_closed:
  4127   assumes "complete s"
  4128   shows "closed s"
  4129 proof (unfold closed_sequential_limits, clarify)
  4130   fix f x assume "\<forall>n. f n \<in> s" and "f ----> x"
  4131   from `f ----> x` have "Cauchy f"
  4132     by (rule LIMSEQ_imp_Cauchy)
  4133   with `complete s` and `\<forall>n. f n \<in> s` obtain l where "l \<in> s" and "f ----> l"
  4134     by (rule completeE)
  4135   from `f ----> x` and `f ----> l` have "x = l"
  4136     by (rule LIMSEQ_unique)
  4137   with `l \<in> s` show "x \<in> s"
  4138     by simp
  4139 qed
  4140 
  4141 lemma complete_inter_closed:
  4142   assumes "complete s" and "closed t"
  4143   shows "complete (s \<inter> t)"
  4144 proof (rule completeI)
  4145   fix f assume "\<forall>n. f n \<in> s \<inter> t" and "Cauchy f"
  4146   then have "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t"
  4147     by simp_all
  4148   from `complete s` obtain l where "l \<in> s" and "f ----> l"
  4149     using `\<forall>n. f n \<in> s` and `Cauchy f` by (rule completeE)
  4150   from `closed t` and `\<forall>n. f n \<in> t` and `f ----> l` have "l \<in> t"
  4151     by (rule closed_sequentially)
  4152   with `l \<in> s` and `f ----> l` show "\<exists>l\<in>s \<inter> t. f ----> l"
  4153     by fast
  4154 qed
  4155 
  4156 lemma complete_closed_subset:
  4157   assumes "closed s" and "s \<subseteq> t" and "complete t"
  4158   shows "complete s"
  4159   using assms complete_inter_closed [of t s] by (simp add: Int_absorb1)
  4160 
  4161 lemma complete_eq_closed:
  4162   fixes s :: "('a::complete_space) set"
  4163   shows "complete s \<longleftrightarrow> closed s"
  4164 proof
  4165   assume "closed s" then show "complete s"
  4166     using subset_UNIV complete_UNIV by (rule complete_closed_subset)
  4167 next
  4168   assume "complete s" then show "closed s"
  4169     by (rule complete_imp_closed)
  4170 qed
  4171 
  4172 lemma convergent_eq_cauchy:
  4173   fixes s :: "nat \<Rightarrow> 'a::complete_space"
  4174   shows "(\<exists>l. (s ---> l) sequentially) \<longleftrightarrow> Cauchy s"
  4175   unfolding Cauchy_convergent_iff convergent_def ..
  4176 
  4177 lemma convergent_imp_bounded:
  4178   fixes s :: "nat \<Rightarrow> 'a::metric_space"
  4179   shows "(s ---> l) sequentially \<Longrightarrow> bounded (range s)"
  4180   by (intro cauchy_imp_bounded LIMSEQ_imp_Cauchy)
  4181 
  4182 lemma compact_cball[simp]:
  4183   fixes x :: "'a::heine_borel"
  4184   shows "compact (cball x e)"
  4185   using compact_eq_bounded_closed bounded_cball closed_cball
  4186   by blast
  4187 
  4188 lemma compact_frontier_bounded[intro]:
  4189   fixes s :: "'a::heine_borel set"
  4190   shows "bounded s \<Longrightarrow> compact (frontier s)"
  4191   unfolding frontier_def
  4192   using compact_eq_bounded_closed
  4193   by blast
  4194 
  4195 lemma compact_frontier[intro]:
  4196   fixes s :: "'a::heine_borel set"
  4197   shows "compact s \<Longrightarrow> compact (frontier s)"
  4198   using compact_eq_bounded_closed compact_frontier_bounded
  4199   by blast
  4200 
  4201 lemma frontier_subset_compact:
  4202   fixes s :: "'a::heine_borel set"
  4203   shows "compact s \<Longrightarrow> frontier s \<subseteq> s"
  4204   using frontier_subset_closed compact_eq_bounded_closed
  4205   by blast
  4206 
  4207 subsection {* Bounded closed nest property (proof does not use Heine-Borel) *}
  4208 
  4209 lemma bounded_closed_nest:
  4210   fixes s :: "nat \<Rightarrow> ('a::heine_borel) set"
  4211   assumes "\<forall>n. closed (s n)"
  4212     and "\<forall>n. s n \<noteq> {}"
  4213     and "\<forall>m n. m \<le> n \<longrightarrow> s n \<subseteq> s m"
  4214     and "bounded (s 0)"
  4215   shows "\<exists>a. \<forall>n. a \<in> s n"
  4216 proof -
  4217   from assms(2) obtain x where x: "\<forall>n. x n \<in> s n"
  4218     using choice[of "\<lambda>n x. x \<in> s n"] by auto
  4219   from assms(4,1) have "seq_compact (s 0)"
  4220     by (simp add: bounded_closed_imp_seq_compact)
  4221   then obtain l r where lr: "l \<in> s 0" "subseq r" "(x \<circ> r) ----> l"
  4222     using x and assms(3) unfolding seq_compact_def by blast
  4223   have "\<forall>n. l \<in> s n"
  4224   proof
  4225     fix n :: nat
  4226     have "closed (s n)"
  4227       using assms(1) by simp
  4228     moreover have "\<forall>i. (x \<circ> r) i \<in> s i"
  4229       using x and assms(3) and lr(2) [THEN seq_suble] by auto
  4230     then have "\<forall>i. (x \<circ> r) (i + n) \<in> s n"
  4231       using assms(3) by (fast intro!: le_add2)
  4232     moreover have "(\<lambda>i. (x \<circ> r) (i + n)) ----> l"
  4233       using lr(3) by (rule LIMSEQ_ignore_initial_segment)
  4234     ultimately show "l \<in> s n"
  4235       by (rule closed_sequentially)
  4236   qed
  4237   then show ?thesis ..
  4238 qed
  4239 
  4240 text {* Decreasing case does not even need compactness, just completeness. *}
  4241 
  4242 lemma decreasing_closed_nest:
  4243   fixes s :: "nat \<Rightarrow> ('a::complete_space) set"
  4244   assumes
  4245     "\<forall>n. closed (s n)"
  4246     "\<forall>n. s n \<noteq> {}"
  4247     "\<forall>m n. m \<le> n \<longrightarrow> s n \<subseteq> s m"
  4248     "\<forall>e>0. \<exists>n. \<forall>x\<in>s n. \<forall>y\<in>s n. dist x y < e"
  4249   shows "\<exists>a. \<forall>n. a \<in> s n"
  4250 proof -
  4251   have "\<forall>n. \<exists>x. x \<in> s n"
  4252     using assms(2) by auto
  4253   then have "\<exists>t. \<forall>n. t n \<in> s n"
  4254     using choice[of "\<lambda>n x. x \<in> s n"] by auto
  4255   then obtain t where t: "\<forall>n. t n \<in> s n" by auto
  4256   {
  4257     fix e :: real
  4258     assume "e > 0"
  4259     then obtain N where N:"\<forall>x\<in>s N. \<forall>y\<in>s N. dist x y < e"
  4260       using assms(4) by auto
  4261     {
  4262       fix m n :: nat
  4263       assume "N \<le> m \<and> N \<le> n"
  4264       then have "t m \<in> s N" "t n \<in> s N"
  4265         using assms(3) t unfolding  subset_eq t by blast+
  4266       then have "dist (t m) (t n) < e"
  4267         using N by auto
  4268     }
  4269     then have "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (t m) (t n) < e"
  4270       by auto
  4271   }
  4272   then have "Cauchy t"
  4273     unfolding cauchy_def by auto
  4274   then obtain l where l:"(t ---> l) sequentially"
  4275     using complete_UNIV unfolding complete_def by auto
  4276   {
  4277     fix n :: nat
  4278     {
  4279       fix e :: real
  4280       assume "e > 0"
  4281       then obtain N :: nat where N: "\<forall>n\<ge>N. dist (t n) l < e"
  4282         using l[unfolded LIMSEQ_def] by auto
  4283       have "t (max n N) \<in> s n"
  4284         using assms(3)
  4285         unfolding subset_eq
  4286         apply (erule_tac x=n in allE)
  4287         apply (erule_tac x="max n N" in allE)
  4288         using t
  4289         apply auto
  4290         done
  4291       then have "\<exists>y\<in>s n. dist y l < e"
  4292         apply (rule_tac x="t (max n N)" in bexI)
  4293         using N
  4294         apply auto
  4295         done
  4296     }
  4297     then have "l \<in> s n"
  4298       using closed_approachable[of "s n" l] assms(1) by auto
  4299   }
  4300   then show ?thesis by auto
  4301 qed
  4302 
  4303 text {* Strengthen it to the intersection actually being a singleton. *}
  4304 
  4305 lemma decreasing_closed_nest_sing:
  4306   fixes s :: "nat \<Rightarrow> 'a::complete_space set"
  4307   assumes
  4308     "\<forall>n. closed(s n)"
  4309     "\<forall>n. s n \<noteq> {}"
  4310     "\<forall>m n. m \<le> n \<longrightarrow> s n \<subseteq> s m"
  4311     "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y\<in>(s n). dist x y < e"
  4312   shows "\<exists>a. \<Inter>(range s) = {a}"
  4313 proof -
  4314   obtain a where a: "\<forall>n. a \<in> s n"
  4315     using decreasing_closed_nest[of s] using assms by auto
  4316   {
  4317     fix b
  4318     assume b: "b \<in> \<Inter>(range s)"
  4319     {
  4320       fix e :: real
  4321       assume "e > 0"
  4322       then have "dist a b < e"
  4323         using assms(4) and b and a by blast
  4324     }
  4325     then have "dist a b = 0"
  4326       by (metis dist_eq_0_iff dist_nz less_le)
  4327   }
  4328   with a have "\<Inter>(range s) = {a}"
  4329     unfolding image_def by auto
  4330   then show ?thesis ..
  4331 qed
  4332 
  4333 text{* Cauchy-type criteria for uniform convergence. *}
  4334 
  4335 lemma uniformly_convergent_eq_cauchy:
  4336   fixes s::"nat \<Rightarrow> 'b \<Rightarrow> 'a::complete_space"
  4337   shows
  4338     "(\<exists>l. \<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e) \<longleftrightarrow>
  4339       (\<forall>e>0. \<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  \<longrightarrow> dist (s m x) (s n x) < e)"
  4340   (is "?lhs = ?rhs")
  4341 proof
  4342   assume ?lhs
  4343   then obtain l where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e"
  4344     by auto
  4345   {
  4346     fix e :: real
  4347     assume "e > 0"
  4348     then obtain N :: nat where N: "\<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e / 2"
  4349       using l[THEN spec[where x="e/2"]] by auto
  4350     {
  4351       fix n m :: nat and x :: "'b"
  4352       assume "N \<le> m \<and> N \<le> n \<and> P x"
  4353       then have "dist (s m x) (s n x) < e"
  4354         using N[THEN spec[where x=m], THEN spec[where x=x]]
  4355         using N[THEN spec[where x=n], THEN spec[where x=x]]
  4356         using dist_triangle_half_l[of "s m x" "l x" e "s n x"] by auto
  4357     }
  4358     then have "\<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e"  by auto
  4359   }
  4360   then show ?rhs by auto
  4361 next
  4362   assume ?rhs
  4363   then have "\<forall>x. P x \<longrightarrow> Cauchy (\<lambda>n. s n x)"
  4364     unfolding cauchy_def
  4365     apply auto
  4366     apply (erule_tac x=e in allE)
  4367     apply auto
  4368     done
  4369   then obtain l where l: "\<forall>x. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l x) sequentially"
  4370     unfolding convergent_eq_cauchy[symmetric]
  4371     using choice[of "\<lambda>x l. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l) sequentially"]
  4372     by auto
  4373   {
  4374     fix e :: real
  4375     assume "e > 0"
  4376     then obtain N where N:"\<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x \<longrightarrow> dist (s m x) (s n x) < e/2"
  4377       using `?rhs`[THEN spec[where x="e/2"]] by auto
  4378     {
  4379       fix x
  4380       assume "P x"
  4381       then obtain M where M:"\<forall>n\<ge>M. dist (s n x) (l x) < e/2"
  4382         using l[THEN spec[where x=x], unfolded LIMSEQ_def] and `e > 0`
  4383         by (auto elim!: allE[where x="e/2"])
  4384       fix n :: nat
  4385       assume "n \<ge> N"
  4386       then have "dist(s n x)(l x) < e"
  4387         using `P x`and N[THEN spec[where x=n], THEN spec[where x="N+M"], THEN spec[where x=x]]
  4388         using M[THEN spec[where x="N+M"]] and dist_triangle_half_l[of "s n x" "s (N+M) x" e "l x"]
  4389         by (auto simp add: dist_commute)
  4390     }
  4391     then have "\<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e"
  4392       by auto
  4393   }
  4394   then show ?lhs by auto
  4395 qed
  4396 
  4397 lemma uniformly_cauchy_imp_uniformly_convergent:
  4398   fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::complete_space"
  4399   assumes "\<forall>e>0.\<exists>N. \<forall>m (n::nat) x. N \<le> m \<and> N \<le> n \<and> P x --> dist(s m x)(s n x) < e"
  4400     and "\<forall>x. P x --> (\<forall>e>0. \<exists>N. \<forall>n. N \<le> n \<longrightarrow> dist(s n x)(l x) < e)"
  4401   shows "\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e"
  4402 proof -
  4403   obtain l' where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l' x) < e"
  4404     using assms(1) unfolding uniformly_convergent_eq_cauchy[symmetric] by auto
  4405   moreover
  4406   {
  4407     fix x
  4408     assume "P x"
  4409     then have "l x = l' x"
  4410       using tendsto_unique[OF trivial_limit_sequentially, of "\<lambda>n. s n x" "l x" "l' x"]
  4411       using l and assms(2) unfolding LIMSEQ_def by blast
  4412   }
  4413   ultimately show ?thesis by auto
  4414 qed
  4415 
  4416 
  4417 subsection {* Continuity *}
  4418 
  4419 text{* Derive the epsilon-delta forms, which we often use as "definitions" *}
  4420 
  4421 lemma continuous_within_eps_delta:
  4422   "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'\<in> s.  dist x' x < d --> dist (f x') (f x) < e)"
  4423   unfolding continuous_within and Lim_within
  4424   apply auto
  4425   unfolding dist_nz[symmetric]
  4426   apply (auto del: allE elim!:allE)
  4427   apply(rule_tac x=d in exI)
  4428   apply auto
  4429   done
  4430 
  4431 lemma continuous_at_eps_delta:
  4432   "continuous (at x) f \<longleftrightarrow> (\<forall>e > 0. \<exists>d > 0. \<forall>x'. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  4433   using continuous_within_eps_delta [of x UNIV f] by simp
  4434 
  4435 text{* Versions in terms of open balls. *}
  4436 
  4437 lemma continuous_within_ball:
  4438   "continuous (at x within s) f \<longleftrightarrow>
  4439     (\<forall>e > 0. \<exists>d > 0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e)"
  4440   (is "?lhs = ?rhs")
  4441 proof
  4442   assume ?lhs
  4443   {
  4444     fix e :: real
  4445     assume "e > 0"
  4446     then obtain d where d: "d>0" "\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < e"
  4447       using `?lhs`[unfolded continuous_within Lim_within] by auto
  4448     {
  4449       fix y
  4450       assume "y \<in> f ` (ball x d \<inter> s)"
  4451       then have "y \<in> ball (f x) e"
  4452         using d(2)
  4453         unfolding dist_nz[symmetric]
  4454         apply (auto simp add: dist_commute)
  4455         apply (erule_tac x=xa in ballE)
  4456         apply auto
  4457         using `e > 0`
  4458         apply auto
  4459         done
  4460     }
  4461     then have "\<exists>d>0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e"
  4462       using `d > 0`
  4463       unfolding subset_eq ball_def by (auto simp add: dist_commute)
  4464   }
  4465   then show ?rhs by auto
  4466 next
  4467   assume ?rhs
  4468   then show ?lhs
  4469     unfolding continuous_within Lim_within ball_def subset_eq
  4470     apply (auto simp add: dist_commute)
  4471     apply (erule_tac x=e in allE)
  4472     apply auto
  4473     done
  4474 qed
  4475 
  4476 lemma continuous_at_ball:
  4477   "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. f ` (ball x d) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  4478 proof
  4479   assume ?lhs
  4480   then show ?rhs
  4481     unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  4482     apply auto
  4483     apply (erule_tac x=e in allE)
  4484     apply auto
  4485     apply (rule_tac x=d in exI)
  4486     apply auto
  4487     apply (erule_tac x=xa in allE)
  4488     apply (auto simp add: dist_commute dist_nz)
  4489     unfolding dist_nz[symmetric]
  4490     apply auto
  4491     done
  4492 next
  4493   assume ?rhs
  4494   then show ?lhs
  4495     unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  4496     apply auto
  4497     apply (erule_tac x=e in allE)
  4498     apply auto
  4499     apply (rule_tac x=d in exI)
  4500     apply auto
  4501     apply (erule_tac x="f xa" in allE)
  4502     apply (auto simp add: dist_commute dist_nz)
  4503     done
  4504 qed
  4505 
  4506 text{* Define setwise continuity in terms of limits within the set. *}
  4507 
  4508 lemma continuous_on_iff:
  4509   "continuous_on s f \<longleftrightarrow>
  4510     (\<forall>x\<in>s. \<forall>e>0. \<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  4511   unfolding continuous_on_def Lim_within
  4512   apply (intro ball_cong [OF refl] all_cong ex_cong)
  4513   apply (rename_tac y, case_tac "y = x")
  4514   apply simp
  4515   apply (simp add: dist_nz)
  4516   done
  4517 
  4518 definition uniformly_continuous_on :: "'a set \<Rightarrow> ('a::metric_space \<Rightarrow> 'b::metric_space) \<Rightarrow> bool"
  4519   where "uniformly_continuous_on s f \<longleftrightarrow>
  4520     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  4521 
  4522 text{* Some simple consequential lemmas. *}
  4523 
  4524 lemma uniformly_continuous_imp_continuous:
  4525   "uniformly_continuous_on s f \<Longrightarrow> continuous_on s f"
  4526   unfolding uniformly_continuous_on_def continuous_on_iff by blast
  4527 
  4528 lemma continuous_at_imp_continuous_within:
  4529   "continuous (at x) f \<Longrightarrow> continuous (at x within s) f"
  4530   unfolding continuous_within continuous_at using Lim_at_within by auto
  4531 
  4532 lemma Lim_trivial_limit: "trivial_limit net \<Longrightarrow> (f ---> l) net"
  4533   by simp
  4534 
  4535 lemmas continuous_on = continuous_on_def -- "legacy theorem name"
  4536 
  4537 lemma continuous_within_subset:
  4538   "continuous (at x within s) f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous (at x within t) f"
  4539   unfolding continuous_within by(metis tendsto_within_subset)
  4540 
  4541 lemma continuous_on_interior:
  4542   "continuous_on s f \<Longrightarrow> x \<in> interior s \<Longrightarrow> continuous (at x) f"
  4543   apply (erule interiorE)
  4544   apply (drule (1) continuous_on_subset)
  4545   apply (simp add: continuous_on_eq_continuous_at)
  4546   done
  4547 
  4548 lemma continuous_on_eq:
  4549   "(\<forall>x \<in> s. f x = g x) \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on s g"
  4550   unfolding continuous_on_def tendsto_def eventually_at_topological
  4551   by simp
  4552 
  4553 text {* Characterization of various kinds of continuity in terms of sequences. *}
  4554 
  4555 lemma continuous_within_sequentially:
  4556   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4557   shows "continuous (at a within s) f \<longleftrightarrow>
  4558     (\<forall>x. (\<forall>n::nat. x n \<in> s) \<and> (x ---> a) sequentially
  4559          \<longrightarrow> ((f \<circ> x) ---> f a) sequentially)"
  4560   (is "?lhs = ?rhs")
  4561 proof
  4562   assume ?lhs
  4563   {
  4564     fix x :: "nat \<Rightarrow> 'a"
  4565     assume x: "\<forall>n. x n \<in> s" "\<forall>e>0. eventually (\<lambda>n. dist (x n) a < e) sequentially"
  4566     fix T :: "'b set"
  4567     assume "open T" and "f a \<in> T"
  4568     with `?lhs` obtain d where "d>0" and d:"\<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> f x \<in> T"
  4569       unfolding continuous_within tendsto_def eventually_at by (auto simp: dist_nz)
  4570     have "eventually (\<lambda>n. dist (x n) a < d) sequentially"
  4571       using x(2) `d>0` by simp
  4572     then have "eventually (\<lambda>n. (f \<circ> x) n \<in> T) sequentially"
  4573     proof eventually_elim
  4574       case (elim n)
  4575       then show ?case
  4576         using d x(1) `f a \<in> T` unfolding dist_nz[symmetric] by auto
  4577     qed
  4578   }
  4579   then show ?rhs
  4580     unfolding tendsto_iff tendsto_def by simp
  4581 next
  4582   assume ?rhs
  4583   then show ?lhs
  4584     unfolding continuous_within tendsto_def [where l="f a"]
  4585     by (simp add: sequentially_imp_eventually_within)
  4586 qed
  4587 
  4588 lemma continuous_at_sequentially:
  4589   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4590   shows "continuous (at a) f \<longleftrightarrow>
  4591     (\<forall>x. (x ---> a) sequentially --> ((f \<circ> x) ---> f a) sequentially)"
  4592   using continuous_within_sequentially[of a UNIV f] by simp
  4593 
  4594 lemma continuous_on_sequentially:
  4595   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4596   shows "continuous_on s f \<longleftrightarrow>
  4597     (\<forall>x. \<forall>a \<in> s. (\<forall>n. x(n) \<in> s) \<and> (x ---> a) sequentially
  4598       --> ((f \<circ> x) ---> f a) sequentially)"
  4599   (is "?lhs = ?rhs")
  4600 proof
  4601   assume ?rhs
  4602   then show ?lhs
  4603     using continuous_within_sequentially[of _ s f]
  4604     unfolding continuous_on_eq_continuous_within
  4605     by auto
  4606 next
  4607   assume ?lhs
  4608   then show ?rhs
  4609     unfolding continuous_on_eq_continuous_within
  4610     using continuous_within_sequentially[of _ s f]
  4611     by auto
  4612 qed
  4613 
  4614 lemma uniformly_continuous_on_sequentially:
  4615   "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  4616                     ((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially
  4617                     \<longrightarrow> ((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially)" (is "?lhs = ?rhs")
  4618 proof
  4619   assume ?lhs
  4620   {
  4621     fix x y
  4622     assume x: "\<forall>n. x n \<in> s"
  4623       and y: "\<forall>n. y n \<in> s"
  4624       and xy: "((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially"
  4625     {
  4626       fix e :: real
  4627       assume "e > 0"
  4628       then obtain d where "d > 0" and d: "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  4629         using `?lhs`[unfolded uniformly_continuous_on_def, THEN spec[where x=e]] by auto
  4630       obtain N where N: "\<forall>n\<ge>N. dist (x n) (y n) < d"
  4631         using xy[unfolded LIMSEQ_def dist_norm] and `d>0` by auto
  4632       {
  4633         fix n
  4634         assume "n\<ge>N"
  4635         then have "dist (f (x n)) (f (y n)) < e"
  4636           using N[THEN spec[where x=n]]
  4637           using d[THEN bspec[where x="x n"], THEN bspec[where x="y n"]]
  4638           using x and y
  4639           unfolding dist_commute
  4640           by simp
  4641       }
  4642       then have "\<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"
  4643         by auto
  4644     }
  4645     then have "((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially"
  4646       unfolding LIMSEQ_def and dist_real_def by auto
  4647   }
  4648   then show ?rhs by auto
  4649 next
  4650   assume ?rhs
  4651   {
  4652     assume "\<not> ?lhs"
  4653     then obtain e where "e > 0" "\<forall>d>0. \<exists>x\<in>s. \<exists>x'\<in>s. dist x' x < d \<and> \<not> dist (f x') (f x) < e"
  4654       unfolding uniformly_continuous_on_def by auto
  4655     then obtain fa where fa:
  4656       "\<forall>x. 0 < x \<longrightarrow> fst (fa x) \<in> s \<and> snd (fa x) \<in> s \<and> dist (fst (fa x)) (snd (fa x)) < x \<and> \<not> dist (f (fst (fa x))) (f (snd (fa x))) < e"
  4657       using choice[of "\<lambda>d x. d>0 \<longrightarrow> fst x \<in> s \<and> snd x \<in> s \<and> dist (snd x) (fst x) < d \<and> \<not> dist (f (snd x)) (f (fst x)) < e"]
  4658       unfolding Bex_def
  4659       by (auto simp add: dist_commute)
  4660     def x \<equiv> "\<lambda>n::nat. fst (fa (inverse (real n + 1)))"
  4661     def y \<equiv> "\<lambda>n::nat. snd (fa (inverse (real n + 1)))"
  4662     have xyn: "\<forall>n. x n \<in> s \<and> y n \<in> s"
  4663       and xy0: "\<forall>n. dist (x n) (y n) < inverse (real n + 1)"
  4664       and fxy:"\<forall>n. \<not> dist (f (x n)) (f (y n)) < e"
  4665       unfolding x_def and y_def using fa
  4666       by auto
  4667     {
  4668       fix e :: real
  4669       assume "e > 0"
  4670       then obtain N :: nat where "N \<noteq> 0" and N: "0 < inverse (real N) \<and> inverse (real N) < e"
  4671         unfolding real_arch_inv[of e] by auto
  4672       {
  4673         fix n :: nat
  4674         assume "n \<ge> N"
  4675         then have "inverse (real n + 1) < inverse (real N)"
  4676           using real_of_nat_ge_zero and `N\<noteq>0` by auto
  4677         also have "\<dots> < e" using N by auto
  4678         finally have "inverse (real n + 1) < e" by auto
  4679         then have "dist (x n) (y n) < e"
  4680           using xy0[THEN spec[where x=n]] by auto
  4681       }
  4682       then have "\<exists>N. \<forall>n\<ge>N. dist (x n) (y n) < e" by auto
  4683     }
  4684     then have "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"
  4685       using `?rhs`[THEN spec[where x=x], THEN spec[where x=y]] and xyn
  4686       unfolding LIMSEQ_def dist_real_def by auto
  4687     then have False using fxy and `e>0` by auto
  4688   }
  4689   then show ?lhs
  4690     unfolding uniformly_continuous_on_def by blast
  4691 qed
  4692 
  4693 text{* The usual transformation theorems. *}
  4694 
  4695 lemma continuous_transform_within:
  4696   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4697   assumes "0 < d"
  4698     and "x \<in> s"
  4699     and "\<forall>x' \<in> s. dist x' x < d --> f x' = g x'"
  4700     and "continuous (at x within s) f"
  4701   shows "continuous (at x within s) g"
  4702   unfolding continuous_within
  4703 proof (rule Lim_transform_within)
  4704   show "0 < d" by fact
  4705   show "\<forall>x'\<in>s. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  4706     using assms(3) by auto
  4707   have "f x = g x"
  4708     using assms(1,2,3) by auto
  4709   then show "(f ---> g x) (at x within s)"
  4710     using assms(4) unfolding continuous_within by simp
  4711 qed
  4712 
  4713 lemma continuous_transform_at:
  4714   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4715   assumes "0 < d"
  4716     and "\<forall>x'. dist x' x < d --> f x' = g x'"
  4717     and "continuous (at x) f"
  4718   shows "continuous (at x) g"
  4719   using continuous_transform_within [of d x UNIV f g] assms by simp
  4720 
  4721 
  4722 subsubsection {* Structural rules for pointwise continuity *}
  4723 
  4724 lemmas continuous_within_id = continuous_ident
  4725 
  4726 lemmas continuous_at_id = isCont_ident
  4727 
  4728 lemma continuous_infdist[continuous_intros]:
  4729   assumes "continuous F f"
  4730   shows "continuous F (\<lambda>x. infdist (f x) A)"
  4731   using assms unfolding continuous_def by (rule tendsto_infdist)
  4732 
  4733 lemma continuous_infnorm[continuous_intros]:
  4734   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. infnorm (f x))"
  4735   unfolding continuous_def by (rule tendsto_infnorm)
  4736 
  4737 lemma continuous_inner[continuous_intros]:
  4738   assumes "continuous F f"
  4739     and "continuous F g"
  4740   shows "continuous F (\<lambda>x. inner (f x) (g x))"
  4741   using assms unfolding continuous_def by (rule tendsto_inner)
  4742 
  4743 lemmas continuous_at_inverse = isCont_inverse
  4744 
  4745 subsubsection {* Structural rules for setwise continuity *}
  4746 
  4747 lemma continuous_on_infnorm[continuous_on_intros]:
  4748   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. infnorm (f x))"
  4749   unfolding continuous_on by (fast intro: tendsto_infnorm)
  4750 
  4751 lemma continuous_on_inner[continuous_on_intros]:
  4752   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_inner"
  4753   assumes "continuous_on s f"
  4754     and "continuous_on s g"
  4755   shows "continuous_on s (\<lambda>x. inner (f x) (g x))"
  4756   using bounded_bilinear_inner assms
  4757   by (rule bounded_bilinear.continuous_on)
  4758 
  4759 subsubsection {* Structural rules for uniform continuity *}
  4760 
  4761 lemma uniformly_continuous_on_id[continuous_on_intros]:
  4762   "uniformly_continuous_on s (\<lambda>x. x)"
  4763   unfolding uniformly_continuous_on_def by auto
  4764 
  4765 lemma uniformly_continuous_on_const[continuous_on_intros]:
  4766   "uniformly_continuous_on s (\<lambda>x. c)"
  4767   unfolding uniformly_continuous_on_def by simp
  4768 
  4769 lemma uniformly_continuous_on_dist[continuous_on_intros]:
  4770   fixes f g :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  4771   assumes "uniformly_continuous_on s f"
  4772     and "uniformly_continuous_on s g"
  4773   shows "uniformly_continuous_on s (\<lambda>x. dist (f x) (g x))"
  4774 proof -
  4775   {
  4776     fix a b c d :: 'b
  4777     have "\<bar>dist a b - dist c d\<bar> \<le> dist a c + dist b d"
  4778       using dist_triangle2 [of a b c] dist_triangle2 [of b c d]
  4779       using dist_triangle3 [of c d a] dist_triangle [of a d b]
  4780       by arith
  4781   } note le = this
  4782   {
  4783     fix x y
  4784     assume f: "(\<lambda>n. dist (f (x n)) (f (y n))) ----> 0"
  4785     assume g: "(\<lambda>n. dist (g (x n)) (g (y n))) ----> 0"
  4786     have "(\<lambda>n. \<bar>dist (f (x n)) (g (x n)) - dist (f (y n)) (g (y n))\<bar>) ----> 0"
  4787       by (rule Lim_transform_bound [OF _ tendsto_add_zero [OF f g]],
  4788         simp add: le)
  4789   }
  4790   then show ?thesis
  4791     using assms unfolding uniformly_continuous_on_sequentially
  4792     unfolding dist_real_def by simp
  4793 qed
  4794 
  4795 lemma uniformly_continuous_on_norm[continuous_on_intros]:
  4796   assumes "uniformly_continuous_on s f"
  4797   shows "uniformly_continuous_on s (\<lambda>x. norm (f x))"
  4798   unfolding norm_conv_dist using assms
  4799   by (intro uniformly_continuous_on_dist uniformly_continuous_on_const)
  4800 
  4801 lemma (in bounded_linear) uniformly_continuous_on[continuous_on_intros]:
  4802   assumes "uniformly_continuous_on s g"
  4803   shows "uniformly_continuous_on s (\<lambda>x. f (g x))"
  4804   using assms unfolding uniformly_continuous_on_sequentially
  4805   unfolding dist_norm tendsto_norm_zero_iff diff[symmetric]
  4806   by (auto intro: tendsto_zero)
  4807 
  4808 lemma uniformly_continuous_on_cmul[continuous_on_intros]:
  4809   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  4810   assumes "uniformly_continuous_on s f"
  4811   shows "uniformly_continuous_on s (\<lambda>x. c *\<^sub>R f(x))"
  4812   using bounded_linear_scaleR_right assms
  4813   by (rule bounded_linear.uniformly_continuous_on)
  4814 
  4815 lemma dist_minus:
  4816   fixes x y :: "'a::real_normed_vector"
  4817   shows "dist (- x) (- y) = dist x y"
  4818   unfolding dist_norm minus_diff_minus norm_minus_cancel ..
  4819 
  4820 lemma uniformly_continuous_on_minus[continuous_on_intros]:
  4821   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  4822   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. - f x)"
  4823   unfolding uniformly_continuous_on_def dist_minus .
  4824 
  4825 lemma uniformly_continuous_on_add[continuous_on_intros]:
  4826   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  4827   assumes "uniformly_continuous_on s f"
  4828     and "uniformly_continuous_on s g"
  4829   shows "uniformly_continuous_on s (\<lambda>x. f x + g x)"
  4830   using assms
  4831   unfolding uniformly_continuous_on_sequentially
  4832   unfolding dist_norm tendsto_norm_zero_iff add_diff_add
  4833   by (auto intro: tendsto_add_zero)
  4834 
  4835 lemma uniformly_continuous_on_diff[continuous_on_intros]:
  4836   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  4837   assumes "uniformly_continuous_on s f"
  4838     and "uniformly_continuous_on s g"
  4839   shows "uniformly_continuous_on s (\<lambda>x. f x - g x)"
  4840   using assms uniformly_continuous_on_add [of s f "- g"]
  4841     by (simp add: fun_Compl_def uniformly_continuous_on_minus)
  4842 
  4843 text{* Continuity of all kinds is preserved under composition. *}
  4844 
  4845 lemmas continuous_at_compose = isCont_o
  4846 
  4847 lemma uniformly_continuous_on_compose[continuous_on_intros]:
  4848   assumes "uniformly_continuous_on s f"  "uniformly_continuous_on (f ` s) g"
  4849   shows "uniformly_continuous_on s (g \<circ> f)"
  4850 proof -
  4851   {
  4852     fix e :: real
  4853     assume "e > 0"
  4854     then obtain d where "d > 0"
  4855       and d: "\<forall>x\<in>f ` s. \<forall>x'\<in>f ` s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  4856       using assms(2) unfolding uniformly_continuous_on_def by auto
  4857     obtain d' where "d'>0" "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d' \<longrightarrow> dist (f x') (f x) < d"
  4858       using `d > 0` using assms(1) unfolding uniformly_continuous_on_def by auto
  4859     then have "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist ((g \<circ> f) x') ((g \<circ> f) x) < e"
  4860       using `d>0` using d by auto
  4861   }
  4862   then show ?thesis
  4863     using assms unfolding uniformly_continuous_on_def by auto
  4864 qed
  4865 
  4866 text{* Continuity in terms of open preimages. *}
  4867 
  4868 lemma continuous_at_open:
  4869   "continuous (at x) f \<longleftrightarrow> (\<forall>t. open t \<and> f x \<in> t --> (\<exists>s. open s \<and> x \<in> s \<and> (\<forall>x' \<in> s. (f x') \<in> t)))"
  4870   unfolding continuous_within_topological [of x UNIV f]
  4871   unfolding imp_conjL
  4872   by (intro all_cong imp_cong ex_cong conj_cong refl) auto
  4873 
  4874 lemma continuous_imp_tendsto:
  4875   assumes "continuous (at x0) f"
  4876     and "x ----> x0"
  4877   shows "(f \<circ> x) ----> (f x0)"
  4878 proof (rule topological_tendstoI)
  4879   fix S
  4880   assume "open S" "f x0 \<in> S"
  4881   then obtain T where T_def: "open T" "x0 \<in> T" "\<forall>x\<in>T. f x \<in> S"
  4882      using assms continuous_at_open by metis
  4883   then have "eventually (\<lambda>n. x n \<in> T) sequentially"
  4884     using assms T_def by (auto simp: tendsto_def)
  4885   then show "eventually (\<lambda>n. (f \<circ> x) n \<in> S) sequentially"
  4886     using T_def by (auto elim!: eventually_elim1)
  4887 qed
  4888 
  4889 lemma continuous_on_open:
  4890   "continuous_on s f \<longleftrightarrow>
  4891     (\<forall>t. openin (subtopology euclidean (f ` s)) t \<longrightarrow>
  4892       openin (subtopology euclidean s) {x \<in> s. f x \<in> t})"
  4893   unfolding continuous_on_open_invariant openin_open Int_def vimage_def Int_commute
  4894   by (simp add: imp_ex imageI conj_commute eq_commute cong: conj_cong)
  4895 
  4896 text {* Similarly in terms of closed sets. *}
  4897 
  4898 lemma continuous_on_closed:
  4899   "continuous_on s f \<longleftrightarrow>
  4900     (\<forall>t. closedin (subtopology euclidean (f ` s)) t \<longrightarrow>
  4901       closedin (subtopology euclidean s) {x \<in> s. f x \<in> t})"
  4902   unfolding continuous_on_closed_invariant closedin_closed Int_def vimage_def Int_commute
  4903   by (simp add: imp_ex imageI conj_commute eq_commute cong: conj_cong)
  4904 
  4905 text {* Half-global and completely global cases. *}
  4906 
  4907 lemma continuous_open_in_preimage:
  4908   assumes "continuous_on s f"  "open t"
  4909   shows "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  4910 proof -
  4911   have *: "\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)"
  4912     by auto
  4913   have "openin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  4914     using openin_open_Int[of t "f ` s", OF assms(2)] unfolding openin_open by auto
  4915   then show ?thesis
  4916     using assms(1)[unfolded continuous_on_open, THEN spec[where x="t \<inter> f ` s"]]
  4917     using * by auto
  4918 qed
  4919 
  4920 lemma continuous_closed_in_preimage:
  4921   assumes "continuous_on s f" and "closed t"
  4922   shows "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  4923 proof -
  4924   have *: "\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)"
  4925     by auto
  4926   have "closedin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  4927     using closedin_closed_Int[of t "f ` s", OF assms(2)] unfolding Int_commute
  4928     by auto
  4929   then show ?thesis
  4930     using assms(1)[unfolded continuous_on_closed, THEN spec[where x="t \<inter> f ` s"]]
  4931     using * by auto
  4932 qed
  4933 
  4934 lemma continuous_open_preimage:
  4935   assumes "continuous_on s f"
  4936     and "open s"
  4937     and "open t"
  4938   shows "open {x \<in> s. f x \<in> t}"
  4939 proof-
  4940   obtain T where T: "open T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  4941     using continuous_open_in_preimage[OF assms(1,3)] unfolding openin_open by auto
  4942   then show ?thesis
  4943     using open_Int[of s T, OF assms(2)] by auto
  4944 qed
  4945 
  4946 lemma continuous_closed_preimage:
  4947   assumes "continuous_on s f"
  4948     and "closed s"
  4949     and "closed t"
  4950   shows "closed {x \<in> s. f x \<in> t}"
  4951 proof-
  4952   obtain T where "closed T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  4953     using continuous_closed_in_preimage[OF assms(1,3)]
  4954     unfolding closedin_closed by auto
  4955   then show ?thesis using closed_Int[of s T, OF assms(2)] by auto
  4956 qed
  4957 
  4958 lemma continuous_open_preimage_univ:
  4959   "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open {x. f x \<in> s}"
  4960   using continuous_open_preimage[of UNIV f s] open_UNIV continuous_at_imp_continuous_on by auto
  4961 
  4962 lemma continuous_closed_preimage_univ:
  4963   "(\<forall>x. continuous (at x) f) \<Longrightarrow> closed s \<Longrightarrow> closed {x. f x \<in> s}"
  4964   using continuous_closed_preimage[of UNIV f s] closed_UNIV continuous_at_imp_continuous_on by auto
  4965 
  4966 lemma continuous_open_vimage: "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open (f -` s)"
  4967   unfolding vimage_def by (rule continuous_open_preimage_univ)
  4968 
  4969 lemma continuous_closed_vimage: "\<forall>x. continuous (at x) f \<Longrightarrow> closed s \<Longrightarrow> closed (f -` s)"
  4970   unfolding vimage_def by (rule continuous_closed_preimage_univ)
  4971 
  4972 lemma interior_image_subset:
  4973   assumes "\<forall>x. continuous (at x) f"
  4974     and "inj f"
  4975   shows "interior (f ` s) \<subseteq> f ` (interior s)"
  4976 proof
  4977   fix x assume "x \<in> interior (f ` s)"
  4978   then obtain T where as: "open T" "x \<in> T" "T \<subseteq> f ` s" ..
  4979   then have "x \<in> f ` s" by auto
  4980   then obtain y where y: "y \<in> s" "x = f y" by auto
  4981   have "open (vimage f T)"
  4982     using assms(1) `open T` by (rule continuous_open_vimage)
  4983   moreover have "y \<in> vimage f T"
  4984     using `x = f y` `x \<in> T` by simp
  4985   moreover have "vimage f T \<subseteq> s"
  4986     using `T \<subseteq> image f s` `inj f` unfolding inj_on_def subset_eq by auto
  4987   ultimately have "y \<in> interior s" ..
  4988   with `x = f y` show "x \<in> f ` interior s" ..
  4989 qed
  4990 
  4991 text {* Equality of continuous functions on closure and related results. *}
  4992 
  4993 lemma continuous_closed_in_preimage_constant:
  4994   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  4995   shows "continuous_on s f \<Longrightarrow> closedin (subtopology euclidean s) {x \<in> s. f x = a}"
  4996   using continuous_closed_in_preimage[of s f "{a}"] by auto
  4997 
  4998 lemma continuous_closed_preimage_constant:
  4999   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5000   shows "continuous_on s f \<Longrightarrow> closed s \<Longrightarrow> closed {x \<in> s. f x = a}"
  5001   using continuous_closed_preimage[of s f "{a}"] by auto
  5002 
  5003 lemma continuous_constant_on_closure:
  5004   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5005   assumes "continuous_on (closure s) f"
  5006     and "\<forall>x \<in> s. f x = a"
  5007   shows "\<forall>x \<in> (closure s). f x = a"
  5008     using continuous_closed_preimage_constant[of "closure s" f a]
  5009       assms closure_minimal[of s "{x \<in> closure s. f x = a}"] closure_subset
  5010     unfolding subset_eq
  5011     by auto
  5012 
  5013 lemma image_closure_subset:
  5014   assumes "continuous_on (closure s) f"
  5015     and "closed t"
  5016     and "(f ` s) \<subseteq> t"
  5017   shows "f ` (closure s) \<subseteq> t"
  5018 proof -
  5019   have "s \<subseteq> {x \<in> closure s. f x \<in> t}"
  5020     using assms(3) closure_subset by auto
  5021   moreover have "closed {x \<in> closure s. f x \<in> t}"
  5022     using continuous_closed_preimage[OF assms(1)] and assms(2) by auto
  5023   ultimately have "closure s = {x \<in> closure s . f x \<in> t}"
  5024     using closure_minimal[of s "{x \<in> closure s. f x \<in> t}"] by auto
  5025   then show ?thesis by auto
  5026 qed
  5027 
  5028 lemma continuous_on_closure_norm_le:
  5029   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  5030   assumes "continuous_on (closure s) f"
  5031     and "\<forall>y \<in> s. norm(f y) \<le> b"
  5032     and "x \<in> (closure s)"
  5033   shows "norm (f x) \<le> b"
  5034 proof -
  5035   have *: "f ` s \<subseteq> cball 0 b"
  5036     using assms(2)[unfolded mem_cball_0[symmetric]] by auto
  5037   show ?thesis
  5038     using image_closure_subset[OF assms(1) closed_cball[of 0 b] *] assms(3)
  5039     unfolding subset_eq
  5040     apply (erule_tac x="f x" in ballE)
  5041     apply (auto simp add: dist_norm)
  5042     done
  5043 qed
  5044 
  5045 text {* Making a continuous function avoid some value in a neighbourhood. *}
  5046 
  5047 lemma continuous_within_avoid:
  5048   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5049   assumes "continuous (at x within s) f"
  5050     and "f x \<noteq> a"
  5051   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e --> f y \<noteq> a"
  5052 proof -
  5053   obtain U where "open U" and "f x \<in> U" and "a \<notin> U"
  5054     using t1_space [OF `f x \<noteq> a`] by fast
  5055   have "(f ---> f x) (at x within s)"
  5056     using assms(1) by (simp add: continuous_within)
  5057   then have "eventually (\<lambda>y. f y \<in> U) (at x within s)"
  5058     using `open U` and `f x \<in> U`
  5059     unfolding tendsto_def by fast
  5060   then have "eventually (\<lambda>y. f y \<noteq> a) (at x within s)"
  5061     using `a \<notin> U` by (fast elim: eventually_mono [rotated])
  5062   then show ?thesis
  5063     using `f x \<noteq> a` by (auto simp: dist_commute zero_less_dist_iff eventually_at)
  5064 qed
  5065 
  5066 lemma continuous_at_avoid:
  5067   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5068   assumes "continuous (at x) f"
  5069     and "f x \<noteq> a"
  5070   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  5071   using assms continuous_within_avoid[of x UNIV f a] by simp
  5072 
  5073 lemma continuous_on_avoid:
  5074   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5075   assumes "continuous_on s f"
  5076     and "x \<in> s"
  5077     and "f x \<noteq> a"
  5078   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e \<longrightarrow> f y \<noteq> a"
  5079   using assms(1)[unfolded continuous_on_eq_continuous_within, THEN bspec[where x=x],
  5080     OF assms(2)] continuous_within_avoid[of x s f a]
  5081   using assms(3)
  5082   by auto
  5083 
  5084 lemma continuous_on_open_avoid:
  5085   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5086   assumes "continuous_on s f"
  5087     and "open s"
  5088     and "x \<in> s"
  5089     and "f x \<noteq> a"
  5090   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  5091   using assms(1)[unfolded continuous_on_eq_continuous_at[OF assms(2)], THEN bspec[where x=x], OF assms(3)]
  5092   using continuous_at_avoid[of x f a] assms(4)
  5093   by auto
  5094 
  5095 text {* Proving a function is constant by proving open-ness of level set. *}
  5096 
  5097 lemma continuous_levelset_open_in_cases:
  5098   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5099   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  5100         openin (subtopology euclidean s) {x \<in> s. f x = a}
  5101         \<Longrightarrow> (\<forall>x \<in> s. f x \<noteq> a) \<or> (\<forall>x \<in> s. f x = a)"
  5102   unfolding connected_clopen
  5103   using continuous_closed_in_preimage_constant by auto
  5104 
  5105 lemma continuous_levelset_open_in:
  5106   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5107   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  5108         openin (subtopology euclidean s) {x \<in> s. f x = a} \<Longrightarrow>
  5109         (\<exists>x \<in> s. f x = a)  \<Longrightarrow> (\<forall>x \<in> s. f x = a)"
  5110   using continuous_levelset_open_in_cases[of s f ]
  5111   by meson
  5112 
  5113 lemma continuous_levelset_open:
  5114   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5115   assumes "connected s"
  5116     and "continuous_on s f"
  5117     and "open {x \<in> s. f x = a}"
  5118     and "\<exists>x \<in> s.  f x = a"
  5119   shows "\<forall>x \<in> s. f x = a"
  5120   using continuous_levelset_open_in[OF assms(1,2), of a, unfolded openin_open]
  5121   using assms (3,4)
  5122   by fast
  5123 
  5124 text {* Some arithmetical combinations (more to prove). *}
  5125 
  5126 lemma open_scaling[intro]:
  5127   fixes s :: "'a::real_normed_vector set"
  5128   assumes "c \<noteq> 0"
  5129     and "open s"
  5130   shows "open((\<lambda>x. c *\<^sub>R x) ` s)"
  5131 proof -
  5132   {
  5133     fix x
  5134     assume "x \<in> s"
  5135     then obtain e where "e>0"
  5136       and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> s" using assms(2)[unfolded open_dist, THEN bspec[where x=x]]
  5137       by auto
  5138     have "e * abs c > 0"
  5139       using assms(1)[unfolded zero_less_abs_iff[symmetric]]
  5140       using mult_pos_pos[OF `e>0`]
  5141       by auto
  5142     moreover
  5143     {
  5144       fix y
  5145       assume "dist y (c *\<^sub>R x) < e * \<bar>c\<bar>"
  5146       then have "norm ((1 / c) *\<^sub>R y - x) < e"
  5147         unfolding dist_norm
  5148         using norm_scaleR[of c "(1 / c) *\<^sub>R y - x", unfolded scaleR_right_diff_distrib, unfolded scaleR_scaleR] assms(1)
  5149           assms(1)[unfolded zero_less_abs_iff[symmetric]] by (simp del:zero_less_abs_iff)
  5150       then have "y \<in> op *\<^sub>R c ` s"
  5151         using rev_image_eqI[of "(1 / c) *\<^sub>R y" s y "op *\<^sub>R c"]
  5152         using e[THEN spec[where x="(1 / c) *\<^sub>R y"]]
  5153         using assms(1)
  5154         unfolding dist_norm scaleR_scaleR
  5155         by auto
  5156     }
  5157     ultimately have "\<exists>e>0. \<forall>x'. dist x' (c *\<^sub>R x) < e \<longrightarrow> x' \<in> op *\<^sub>R c ` s"
  5158       apply (rule_tac x="e * abs c" in exI)
  5159       apply auto
  5160       done
  5161   }
  5162   then show ?thesis unfolding open_dist by auto
  5163 qed
  5164 
  5165 lemma minus_image_eq_vimage:
  5166   fixes A :: "'a::ab_group_add set"
  5167   shows "(\<lambda>x. - x) ` A = (\<lambda>x. - x) -` A"
  5168   by (auto intro!: image_eqI [where f="\<lambda>x. - x"])
  5169 
  5170 lemma open_negations:
  5171   fixes s :: "'a::real_normed_vector set"
  5172   shows "open s \<Longrightarrow> open ((\<lambda>x. - x) ` s)"
  5173   using open_scaling [of "- 1" s] by simp
  5174 
  5175 lemma open_translation:
  5176   fixes s :: "'a::real_normed_vector set"
  5177   assumes "open s"
  5178   shows "open((\<lambda>x. a + x) ` s)"
  5179 proof -
  5180   {
  5181     fix x
  5182     have "continuous (at x) (\<lambda>x. x - a)"
  5183       by (intro continuous_diff continuous_at_id continuous_const)
  5184   }
  5185   moreover have "{x. x - a \<in> s} = op + a ` s"
  5186     by force
  5187   ultimately show ?thesis using continuous_open_preimage_univ[of "\<lambda>x. x - a" s]
  5188     using assms by auto
  5189 qed
  5190 
  5191 lemma open_affinity:
  5192   fixes s :: "'a::real_normed_vector set"
  5193   assumes "open s"  "c \<noteq> 0"
  5194   shows "open ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5195 proof -
  5196   have *: "(\<lambda>x. a + c *\<^sub>R x) = (\<lambda>x. a + x) \<circ> (\<lambda>x. c *\<^sub>R x)"
  5197     unfolding o_def ..
  5198   have "op + a ` op *\<^sub>R c ` s = (op + a \<circ> op *\<^sub>R c) ` s"
  5199     by auto
  5200   then show ?thesis
  5201     using assms open_translation[of "op *\<^sub>R c ` s" a]
  5202     unfolding *
  5203     by auto
  5204 qed
  5205 
  5206 lemma interior_translation:
  5207   fixes s :: "'a::real_normed_vector set"
  5208   shows "interior ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (interior s)"
  5209 proof (rule set_eqI, rule)
  5210   fix x
  5211   assume "x \<in> interior (op + a ` s)"
  5212   then obtain e where "e > 0" and e: "ball x e \<subseteq> op + a ` s"
  5213     unfolding mem_interior by auto
  5214   then have "ball (x - a) e \<subseteq> s"
  5215     unfolding subset_eq Ball_def mem_ball dist_norm
  5216     apply auto
  5217     apply (erule_tac x="a + xa" in allE)
  5218     unfolding ab_group_add_class.diff_diff_eq[symmetric]
  5219     apply auto
  5220     done
  5221   then show "x \<in> op + a ` interior s"
  5222     unfolding image_iff
  5223     apply (rule_tac x="x - a" in bexI)
  5224     unfolding mem_interior
  5225     using `e > 0`
  5226     apply auto
  5227     done
  5228 next
  5229   fix x
  5230   assume "x \<in> op + a ` interior s"
  5231   then obtain y e where "e > 0" and e: "ball y e \<subseteq> s" and y: "x = a + y"
  5232     unfolding image_iff Bex_def mem_interior by auto
  5233   {
  5234     fix z
  5235     have *: "a + y - z = y + a - z" by auto
  5236     assume "z \<in> ball x e"
  5237     then have "z - a \<in> s"
  5238       using e[unfolded subset_eq, THEN bspec[where x="z - a"]]
  5239       unfolding mem_ball dist_norm y group_add_class.diff_diff_eq2 *
  5240       by auto
  5241     then have "z \<in> op + a ` s"
  5242       unfolding image_iff by (auto intro!: bexI[where x="z - a"])
  5243   }
  5244   then have "ball x e \<subseteq> op + a ` s"
  5245     unfolding subset_eq by auto
  5246   then show "x \<in> interior (op + a ` s)"
  5247     unfolding mem_interior using `e > 0` by auto
  5248 qed
  5249 
  5250 text {* Topological properties of linear functions. *}
  5251 
  5252 lemma linear_lim_0:
  5253   assumes "bounded_linear f"
  5254   shows "(f ---> 0) (at (0))"
  5255 proof -
  5256   interpret f: bounded_linear f by fact
  5257   have "(f ---> f 0) (at 0)"
  5258     using tendsto_ident_at by (rule f.tendsto)
  5259   then show ?thesis unfolding f.zero .
  5260 qed
  5261 
  5262 lemma linear_continuous_at:
  5263   assumes "bounded_linear f"
  5264   shows "continuous (at a) f"
  5265   unfolding continuous_at using assms
  5266   apply (rule bounded_linear.tendsto)
  5267   apply (rule tendsto_ident_at)
  5268   done
  5269 
  5270 lemma linear_continuous_within:
  5271   "bounded_linear f \<Longrightarrow> continuous (at x within s) f"
  5272   using continuous_at_imp_continuous_within[of x f s] using linear_continuous_at[of f] by auto
  5273 
  5274 lemma linear_continuous_on:
  5275   "bounded_linear f \<Longrightarrow> continuous_on s f"
  5276   using continuous_at_imp_continuous_on[of s f] using linear_continuous_at[of f] by auto
  5277 
  5278 text {* Also bilinear functions, in composition form. *}
  5279 
  5280 lemma bilinear_continuous_at_compose:
  5281   "continuous (at x) f \<Longrightarrow> continuous (at x) g \<Longrightarrow> bounded_bilinear h \<Longrightarrow>
  5282     continuous (at x) (\<lambda>x. h (f x) (g x))"
  5283   unfolding continuous_at
  5284   using Lim_bilinear[of f "f x" "(at x)" g "g x" h]
  5285   by auto
  5286 
  5287 lemma bilinear_continuous_within_compose:
  5288   "continuous (at x within s) f \<Longrightarrow> continuous (at x within s) g \<Longrightarrow> bounded_bilinear h \<Longrightarrow>
  5289     continuous (at x within s) (\<lambda>x. h (f x) (g x))"
  5290   unfolding continuous_within
  5291   using Lim_bilinear[of f "f x"]
  5292   by auto
  5293 
  5294 lemma bilinear_continuous_on_compose:
  5295   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> bounded_bilinear h \<Longrightarrow>
  5296     continuous_on s (\<lambda>x. h (f x) (g x))"
  5297   unfolding continuous_on_def
  5298   by (fast elim: bounded_bilinear.tendsto)
  5299 
  5300 text {* Preservation of compactness and connectedness under continuous function. *}
  5301 
  5302 lemma compact_eq_openin_cover:
  5303   "compact S \<longleftrightarrow>
  5304     (\<forall>C. (\<forall>c\<in>C. openin (subtopology euclidean S) c) \<and> S \<subseteq> \<Union>C \<longrightarrow>
  5305       (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  5306 proof safe
  5307   fix C
  5308   assume "compact S" and "\<forall>c\<in>C. openin (subtopology euclidean S) c" and "S \<subseteq> \<Union>C"
  5309   then have "\<forall>c\<in>{T. open T \<and> S \<inter> T \<in> C}. open c" and "S \<subseteq> \<Union>{T. open T \<and> S \<inter> T \<in> C}"
  5310     unfolding openin_open by force+
  5311   with `compact S` obtain D where "D \<subseteq> {T. open T \<and> S \<inter> T \<in> C}" and "finite D" and "S \<subseteq> \<Union>D"
  5312     by (rule compactE)
  5313   then have "image (\<lambda>T. S \<inter> T) D \<subseteq> C \<and> finite (image (\<lambda>T. S \<inter> T) D) \<and> S \<subseteq> \<Union>(image (\<lambda>T. S \<inter> T) D)"
  5314     by auto
  5315   then show "\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D" ..
  5316 next
  5317   assume 1: "\<forall>C. (\<forall>c\<in>C. openin (subtopology euclidean S) c) \<and> S \<subseteq> \<Union>C \<longrightarrow>
  5318         (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D)"
  5319   show "compact S"
  5320   proof (rule compactI)
  5321     fix C
  5322     let ?C = "image (\<lambda>T. S \<inter> T) C"
  5323     assume "\<forall>t\<in>C. open t" and "S \<subseteq> \<Union>C"
  5324     then have "(\<forall>c\<in>?C. openin (subtopology euclidean S) c) \<and> S \<subseteq> \<Union>?C"
  5325       unfolding openin_open by auto
  5326     with 1 obtain D where "D \<subseteq> ?C" and "finite D" and "S \<subseteq> \<Union>D"
  5327       by metis
  5328     let ?D = "inv_into C (\<lambda>T. S \<inter> T) ` D"
  5329     have "?D \<subseteq> C \<and> finite ?D \<and> S \<subseteq> \<Union>?D"
  5330     proof (intro conjI)
  5331       from `D \<subseteq> ?C` show "?D \<subseteq> C"
  5332         by (fast intro: inv_into_into)
  5333       from `finite D` show "finite ?D"
  5334         by (rule finite_imageI)
  5335       from `S \<subseteq> \<Union>D` show "S \<subseteq> \<Union>?D"
  5336         apply (rule subset_trans)
  5337         apply clarsimp
  5338         apply (frule subsetD [OF `D \<subseteq> ?C`, THEN f_inv_into_f])
  5339         apply (erule rev_bexI, fast)
  5340         done
  5341     qed
  5342     then show "\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D" ..
  5343   qed
  5344 qed
  5345 
  5346 lemma connected_continuous_image:
  5347   assumes "continuous_on s f"
  5348     and "connected s"
  5349   shows "connected(f ` s)"
  5350 proof -
  5351   {
  5352     fix T
  5353     assume as:
  5354       "T \<noteq> {}"
  5355       "T \<noteq> f ` s"
  5356       "openin (subtopology euclidean (f ` s)) T"
  5357       "closedin (subtopology euclidean (f ` s)) T"
  5358     have "{x \<in> s. f x \<in> T} = {} \<or> {x \<in> s. f x \<in> T} = s"
  5359       using assms(1)[unfolded continuous_on_open, THEN spec[where x=T]]
  5360       using assms(1)[unfolded continuous_on_closed, THEN spec[where x=T]]
  5361       using assms(2)[unfolded connected_clopen, THEN spec[where x="{x \<in> s. f x \<in> T}"]] as(3,4) by auto
  5362     then have False using as(1,2)
  5363       using as(4)[unfolded closedin_def topspace_euclidean_subtopology] by auto
  5364   }
  5365   then show ?thesis
  5366     unfolding connected_clopen by auto
  5367 qed
  5368 
  5369 text {* Continuity implies uniform continuity on a compact domain. *}
  5370 
  5371 lemma compact_uniformly_continuous:
  5372   assumes f: "continuous_on s f"
  5373     and s: "compact s"
  5374   shows "uniformly_continuous_on s f"
  5375   unfolding uniformly_continuous_on_def
  5376 proof (cases, safe)
  5377   fix e :: real
  5378   assume "0 < e" "s \<noteq> {}"
  5379   def [simp]: R \<equiv> "{(y, d). y \<in> s \<and> 0 < d \<and> ball y d \<inter> s \<subseteq> {x \<in> s. f x \<in> ball (f y) (e/2) } }"
  5380   let ?b = "(\<lambda>(y, d). ball y (d/2))"
  5381   have "(\<forall>r\<in>R. open (?b r))" "s \<subseteq> (\<Union>r\<in>R. ?b r)"
  5382   proof safe
  5383     fix y
  5384     assume "y \<in> s"
  5385     from continuous_open_in_preimage[OF f open_ball]
  5386     obtain T where "open T" and T: "{x \<in> s. f x \<in> ball (f y) (e/2)} = T \<inter> s"
  5387       unfolding openin_subtopology open_openin by metis
  5388     then obtain d where "ball y d \<subseteq> T" "0 < d"
  5389       using `0 < e` `y \<in> s` by (auto elim!: openE)
  5390     with T `y \<in> s` show "y \<in> (\<Union>r\<in>R. ?b r)"
  5391       by (intro UN_I[of "(y, d)"]) auto
  5392   qed auto
  5393   with s obtain D where D: "finite D" "D \<subseteq> R" "s \<subseteq> (\<Union>(y, d)\<in>D. ball y (d/2))"
  5394     by (rule compactE_image)
  5395   with `s \<noteq> {}` have [simp]: "\<And>x. x < Min (snd ` D) \<longleftrightarrow> (\<forall>(y, d)\<in>D. x < d)"
  5396     by (subst Min_gr_iff) auto
  5397   show "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  5398   proof (rule, safe)
  5399     fix x x'
  5400     assume in_s: "x' \<in> s" "x \<in> s"
  5401     with D obtain y d where x: "x \<in> ball y (d/2)" "(y, d) \<in> D"
  5402       by blast
  5403     moreover assume "dist x x' < Min (snd`D) / 2"
  5404     ultimately have "dist y x' < d"
  5405       by (intro dist_double[where x=x and d=d]) (auto simp: dist_commute)
  5406     with D x in_s show  "dist (f x) (f x') < e"
  5407       by (intro dist_double[where x="f y" and d=e]) (auto simp: dist_commute subset_eq)
  5408   qed (insert D, auto)
  5409 qed auto
  5410 
  5411 text {* A uniformly convergent limit of continuous functions is continuous. *}
  5412 
  5413 lemma continuous_uniform_limit:
  5414   fixes f :: "'a \<Rightarrow> 'b::metric_space \<Rightarrow> 'c::metric_space"
  5415   assumes "\<not> trivial_limit F"
  5416     and "eventually (\<lambda>n. continuous_on s (f n)) F"
  5417     and "\<forall>e>0. eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e) F"
  5418   shows "continuous_on s g"
  5419 proof -
  5420   {
  5421     fix x and e :: real
  5422     assume "x\<in>s" "e>0"
  5423     have "eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e / 3) F"
  5424       using `e>0` assms(3)[THEN spec[where x="e/3"]] by auto
  5425     from eventually_happens [OF eventually_conj [OF this assms(2)]]
  5426     obtain n where n:"\<forall>x\<in>s. dist (f n x) (g x) < e / 3"  "continuous_on s (f n)"
  5427       using assms(1) by blast
  5428     have "e / 3 > 0" using `e>0` by auto
  5429     then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f n x') (f n x) < e / 3"
  5430       using n(2)[unfolded continuous_on_iff, THEN bspec[where x=x], OF `x\<in>s`, THEN spec[where x="e/3"]] by blast
  5431     {
  5432       fix y
  5433       assume "y \<in> s" and "dist y x < d"
  5434       then have "dist (f n y) (f n x) < e / 3"
  5435         by (rule d [rule_format])
  5436       then have "dist (f n y) (g x) < 2 * e / 3"
  5437         using dist_triangle [of "f n y" "g x" "f n x"]
  5438         using n(1)[THEN bspec[where x=x], OF `x\<in>s`]
  5439         by auto
  5440       then have "dist (g y) (g x) < e"
  5441         using n(1)[THEN bspec[where x=y], OF `y\<in>s`]
  5442         using dist_triangle3 [of "g y" "g x" "f n y"]
  5443         by auto
  5444     }
  5445     then have "\<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  5446       using `d>0` by auto
  5447   }
  5448   then show ?thesis
  5449     unfolding continuous_on_iff by auto
  5450 qed
  5451 
  5452 
  5453 subsection {* Topological stuff lifted from and dropped to R *}
  5454 
  5455 lemma open_real:
  5456   fixes s :: "real set"
  5457   shows "open s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>e>0. \<forall>x'. abs(x' - x) < e --> x' \<in> s)"
  5458   unfolding open_dist dist_norm by simp
  5459 
  5460 lemma islimpt_approachable_real:
  5461   fixes s :: "real set"
  5462   shows "x islimpt s \<longleftrightarrow> (\<forall>e>0.  \<exists>x'\<in> s. x' \<noteq> x \<and> abs(x' - x) < e)"
  5463   unfolding islimpt_approachable dist_norm by simp
  5464 
  5465 lemma closed_real:
  5466   fixes s :: "real set"
  5467   shows "closed s \<longleftrightarrow> (\<forall>x. (\<forall>e>0.  \<exists>x' \<in> s. x' \<noteq> x \<and> abs(x' - x) < e) \<longrightarrow> x \<in> s)"
  5468   unfolding closed_limpt islimpt_approachable dist_norm by simp
  5469 
  5470 lemma continuous_at_real_range:
  5471   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  5472   shows "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'. norm(x' - x) < d --> abs(f x' - f x) < e)"
  5473   unfolding continuous_at
  5474   unfolding Lim_at
  5475   unfolding dist_nz[symmetric]
  5476   unfolding dist_norm
  5477   apply auto
  5478   apply (erule_tac x=e in allE)
  5479   apply auto
  5480   apply (rule_tac x=d in exI)
  5481   apply auto
  5482   apply (erule_tac x=x' in allE)
  5483   apply auto
  5484   apply (erule_tac x=e in allE)
  5485   apply auto
  5486   done
  5487 
  5488 lemma continuous_on_real_range:
  5489   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  5490   shows "continuous_on s f \<longleftrightarrow>
  5491     (\<forall>x \<in> s. \<forall>e>0. \<exists>d>0. (\<forall>x' \<in> s. norm(x' - x) < d \<longrightarrow> abs(f x' - f x) < e))"
  5492   unfolding continuous_on_iff dist_norm by simp
  5493 
  5494 text {* Hence some handy theorems on distance, diameter etc. of/from a set. *}
  5495 
  5496 lemma distance_attains_sup:
  5497   assumes "compact s" "s \<noteq> {}"
  5498   shows "\<exists>x\<in>s. \<forall>y\<in>s. dist a y \<le> dist a x"
  5499 proof (rule continuous_attains_sup [OF assms])
  5500   {
  5501     fix x
  5502     assume "x\<in>s"
  5503     have "(dist a ---> dist a x) (at x within s)"
  5504       by (intro tendsto_dist tendsto_const tendsto_ident_at)
  5505   }
  5506   then show "continuous_on s (dist a)"
  5507     unfolding continuous_on ..
  5508 qed
  5509 
  5510 text {* For \emph{minimal} distance, we only need closure, not compactness. *}
  5511 
  5512 lemma distance_attains_inf:
  5513   fixes a :: "'a::heine_borel"
  5514   assumes "closed s"
  5515     and "s \<noteq> {}"
  5516   shows "\<exists>x\<in>s. \<forall>y\<in>s. dist a x \<le> dist a y"
  5517 proof -
  5518   from assms(2) obtain b where "b \<in> s" by auto
  5519   let ?B = "s \<inter> cball a (dist b a)"
  5520   have "?B \<noteq> {}" using `b \<in> s`
  5521     by (auto simp add: dist_commute)
  5522   moreover have "continuous_on ?B (dist a)"
  5523     by (auto intro!: continuous_at_imp_continuous_on continuous_dist continuous_at_id continuous_const)
  5524   moreover have "compact ?B"
  5525     by (intro closed_inter_compact `closed s` compact_cball)
  5526   ultimately obtain x where "x \<in> ?B" "\<forall>y\<in>?B. dist a x \<le> dist a y"
  5527     by (metis continuous_attains_inf)
  5528   then show ?thesis by fastforce
  5529 qed
  5530 
  5531 
  5532 subsection {* Pasted sets *}
  5533 
  5534 lemma bounded_Times:
  5535   assumes "bounded s" "bounded t"
  5536   shows "bounded (s \<times> t)"
  5537 proof -
  5538   obtain x y a b where "\<forall>z\<in>s. dist x z \<le> a" "\<forall>z\<in>t. dist y z \<le> b"
  5539     using assms [unfolded bounded_def] by auto
  5540   then have "\<forall>z\<in>s \<times> t. dist (x, y) z \<le> sqrt (a\<^sup>2 + b\<^sup>2)"
  5541     by (auto simp add: dist_Pair_Pair real_sqrt_le_mono add_mono power_mono)
  5542   then show ?thesis unfolding bounded_any_center [where a="(x, y)"] by auto
  5543 qed
  5544 
  5545 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
  5546   by (induct x) simp
  5547 
  5548 lemma seq_compact_Times: "seq_compact s \<Longrightarrow> seq_compact t \<Longrightarrow> seq_compact (s \<times> t)"
  5549   unfolding seq_compact_def
  5550   apply clarify
  5551   apply (drule_tac x="fst \<circ> f" in spec)
  5552   apply (drule mp, simp add: mem_Times_iff)
  5553   apply (clarify, rename_tac l1 r1)
  5554   apply (drule_tac x="snd \<circ> f \<circ> r1" in spec)
  5555   apply (drule mp, simp add: mem_Times_iff)
  5556   apply (clarify, rename_tac l2 r2)
  5557   apply (rule_tac x="(l1, l2)" in rev_bexI, simp)
  5558   apply (rule_tac x="r1 \<circ> r2" in exI)
  5559   apply (rule conjI, simp add: subseq_def)
  5560   apply (drule_tac f=r2 in LIMSEQ_subseq_LIMSEQ, assumption)
  5561   apply (drule (1) tendsto_Pair) back
  5562   apply (simp add: o_def)
  5563   done
  5564 
  5565 lemma compact_Times:
  5566   assumes "compact s" "compact t"
  5567   shows "compact (s \<times> t)"
  5568 proof (rule compactI)
  5569   fix C
  5570   assume C: "\<forall>t\<in>C. open t" "s \<times> t \<subseteq> \<Union>C"
  5571   have "\<forall>x\<in>s. \<exists>a. open a \<and> x \<in> a \<and> (\<exists>d\<subseteq>C. finite d \<and> a \<times> t \<subseteq> \<Union>d)"
  5572   proof
  5573     fix x
  5574     assume "x \<in> s"
  5575     have "\<forall>y\<in>t. \<exists>a b c. c \<in> C \<and> open a \<and> open b \<and> x \<in> a \<and> y \<in> b \<and> a \<times> b \<subseteq> c" (is "\<forall>y\<in>t. ?P y")
  5576     proof
  5577       fix y
  5578       assume "y \<in> t"
  5579       with `x \<in> s` C obtain c where "c \<in> C" "(x, y) \<in> c" "open c" by auto
  5580       then show "?P y" by (auto elim!: open_prod_elim)
  5581     qed
  5582     then obtain a b c where b: "\<And>y. y \<in> t \<Longrightarrow> open (b y)"
  5583       and c: "\<And>y. y \<in> t \<Longrightarrow> c y \<in> C \<and> open (a y) \<and> open (b y) \<and> x \<in> a y \<and> y \<in> b y \<and> a y \<times> b y \<subseteq> c y"
  5584       by metis
  5585     then have "\<forall>y\<in>t. open (b y)" "t \<subseteq> (\<Union>y\<in>t. b y)" by auto
  5586     from compactE_image[OF `compact t` this] obtain D where D: "D \<subseteq> t" "finite D" "t \<subseteq> (\<Union>y\<in>D. b y)"
  5587       by auto
  5588     moreover from D c have "(\<Inter>y\<in>D. a y) \<times> t \<subseteq> (\<Union>y\<in>D. c y)"
  5589       by (fastforce simp: subset_eq)
  5590     ultimately show "\<exists>a. open a \<and> x \<in> a \<and> (\<exists>d\<subseteq>C. finite d \<and> a \<times> t \<subseteq> \<Union>d)"
  5591       using c by (intro exI[of _ "c`D"] exI[of _ "\<Inter>(a`D)"] conjI) (auto intro!: open_INT)
  5592   qed
  5593   then obtain a d where a: "\<forall>x\<in>s. open (a x)" "s \<subseteq> (\<Union>x\<in>s. a x)"
  5594     and d: "\<And>x. x \<in> s \<Longrightarrow> d x \<subseteq> C \<and> finite (d x) \<and> a x \<times> t \<subseteq> \<Union>d x"
  5595     unfolding subset_eq UN_iff by metis
  5596   moreover
  5597   from compactE_image[OF `compact s` a]
  5598   obtain e where e: "e \<subseteq> s" "finite e" and s: "s \<subseteq> (\<Union>x\<in>e. a x)"
  5599     by auto
  5600   moreover
  5601   {
  5602     from s have "s \<times> t \<subseteq> (\<Union>x\<in>e. a x \<times> t)"
  5603       by auto
  5604     also have "\<dots> \<subseteq> (\<Union>x\<in>e. \<Union>d x)"
  5605       using d `e \<subseteq> s` by (intro UN_mono) auto
  5606     finally have "s \<times> t \<subseteq> (\<Union>x\<in>e. \<Union>d x)" .
  5607   }
  5608   ultimately show "\<exists>C'\<subseteq>C. finite C' \<and> s \<times> t \<subseteq> \<Union>C'"
  5609     by (intro exI[of _ "(\<Union>x\<in>e. d x)"]) (auto simp add: subset_eq)
  5610 qed
  5611 
  5612 text{* Hence some useful properties follow quite easily. *}
  5613 
  5614 lemma compact_scaling:
  5615   fixes s :: "'a::real_normed_vector set"
  5616   assumes "compact s"
  5617   shows "compact ((\<lambda>x. c *\<^sub>R x) ` s)"
  5618 proof -
  5619   let ?f = "\<lambda>x. scaleR c x"
  5620   have *: "bounded_linear ?f" by (rule bounded_linear_scaleR_right)
  5621   show ?thesis
  5622     using compact_continuous_image[of s ?f] continuous_at_imp_continuous_on[of s ?f]
  5623     using linear_continuous_at[OF *] assms
  5624     by auto
  5625 qed
  5626 
  5627 lemma compact_negations:
  5628   fixes s :: "'a::real_normed_vector set"
  5629   assumes "compact s"
  5630   shows "compact ((\<lambda>x. - x) ` s)"
  5631   using compact_scaling [OF assms, of "- 1"] by auto
  5632 
  5633 lemma compact_sums:
  5634   fixes s t :: "'a::real_normed_vector set"
  5635   assumes "compact s"
  5636     and "compact t"
  5637   shows "compact {x + y | x y. x \<in> s \<and> y \<in> t}"
  5638 proof -
  5639   have *: "{x + y | x y. x \<in> s \<and> y \<in> t} = (\<lambda>z. fst z + snd z) ` (s \<times> t)"
  5640     apply auto
  5641     unfolding image_iff
  5642     apply (rule_tac x="(xa, y)" in bexI)
  5643     apply auto
  5644     done
  5645   have "continuous_on (s \<times> t) (\<lambda>z. fst z + snd z)"
  5646     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  5647   then show ?thesis
  5648     unfolding * using compact_continuous_image compact_Times [OF assms] by auto
  5649 qed
  5650 
  5651 lemma compact_differences:
  5652   fixes s t :: "'a::real_normed_vector set"
  5653   assumes "compact s"
  5654     and "compact t"
  5655   shows "compact {x - y | x y. x \<in> s \<and> y \<in> t}"
  5656 proof-
  5657   have "{x - y | x y. x\<in>s \<and> y \<in> t} =  {x + y | x y. x \<in> s \<and> y \<in> (uminus ` t)}"
  5658     apply auto
  5659     apply (rule_tac x= xa in exI)
  5660     apply auto
  5661     done
  5662   then show ?thesis
  5663     using compact_sums[OF assms(1) compact_negations[OF assms(2)]] by auto
  5664 qed
  5665 
  5666 lemma compact_translation:
  5667   fixes s :: "'a::real_normed_vector set"
  5668   assumes "compact s"
  5669   shows "compact ((\<lambda>x. a + x) ` s)"
  5670 proof -
  5671   have "{x + y |x y. x \<in> s \<and> y \<in> {a}} = (\<lambda>x. a + x) ` s"
  5672     by auto
  5673   then show ?thesis
  5674     using compact_sums[OF assms compact_sing[of a]] by auto
  5675 qed
  5676 
  5677 lemma compact_affinity:
  5678   fixes s :: "'a::real_normed_vector set"
  5679   assumes "compact s"
  5680   shows "compact ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5681 proof -
  5682   have "op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s"
  5683     by auto
  5684   then show ?thesis
  5685     using compact_translation[OF compact_scaling[OF assms], of a c] by auto
  5686 qed
  5687 
  5688 text {* Hence we get the following. *}
  5689 
  5690 lemma compact_sup_maxdistance:
  5691   fixes s :: "'a::metric_space set"
  5692   assumes "compact s"
  5693     and "s \<noteq> {}"
  5694   shows "\<exists>x\<in>s. \<exists>y\<in>s. \<forall>u\<in>s. \<forall>v\<in>s. dist u v \<le> dist x y"
  5695 proof -
  5696   have "compact (s \<times> s)"
  5697     using `compact s` by (intro compact_Times)
  5698   moreover have "s \<times> s \<noteq> {}"
  5699     using `s \<noteq> {}` by auto
  5700   moreover have "continuous_on (s \<times> s) (\<lambda>x. dist (fst x) (snd x))"
  5701     by (intro continuous_at_imp_continuous_on ballI continuous_intros)
  5702   ultimately show ?thesis
  5703     using continuous_attains_sup[of "s \<times> s" "\<lambda>x. dist (fst x) (snd x)"] by auto
  5704 qed
  5705 
  5706 text {* We can state this in terms of diameter of a set. *}
  5707 
  5708 definition diameter :: "'a::metric_space set \<Rightarrow> real" where
  5709   "diameter S = (if S = {} then 0 else SUP (x,y):S\<times>S. dist x y)"
  5710 
  5711 lemma diameter_bounded_bound:
  5712   fixes s :: "'a :: metric_space set"
  5713   assumes s: "bounded s" "x \<in> s" "y \<in> s"
  5714   shows "dist x y \<le> diameter s"
  5715 proof -
  5716   from s obtain z d where z: "\<And>x. x \<in> s \<Longrightarrow> dist z x \<le> d"
  5717     unfolding bounded_def by auto
  5718   have "bdd_above (split dist ` (s\<times>s))"
  5719   proof (intro bdd_aboveI, safe)
  5720     fix a b
  5721     assume "a \<in> s" "b \<in> s"
  5722     with z[of a] z[of b] dist_triangle[of a b z]
  5723     show "dist a b \<le> 2 * d"
  5724       by (simp add: dist_commute)
  5725   qed
  5726   moreover have "(x,y) \<in> s\<times>s" using s by auto
  5727   ultimately have "dist x y \<le> (SUP (x,y):s\<times>s. dist x y)"
  5728     by (rule cSUP_upper2) simp
  5729   with `x \<in> s` show ?thesis
  5730     by (auto simp add: diameter_def)
  5731 qed
  5732 
  5733 lemma diameter_lower_bounded:
  5734   fixes s :: "'a :: metric_space set"
  5735   assumes s: "bounded s"
  5736     and d: "0 < d" "d < diameter s"
  5737   shows "\<exists>x\<in>s. \<exists>y\<in>s. d < dist x y"
  5738 proof (rule ccontr)
  5739   assume contr: "\<not> ?thesis"
  5740   moreover have "s \<noteq> {}"
  5741     using d by (auto simp add: diameter_def)
  5742   ultimately have "diameter s \<le> d"
  5743     by (auto simp: not_less diameter_def intro!: cSUP_least)
  5744   with `d < diameter s` show False by auto
  5745 qed
  5746 
  5747 lemma diameter_bounded:
  5748   assumes "bounded s"
  5749   shows "\<forall>x\<in>s. \<forall>y\<in>s. dist x y \<le> diameter s"
  5750     and "\<forall>d>0. d < diameter s \<longrightarrow> (\<exists>x\<in>s. \<exists>y\<in>s. dist x y > d)"
  5751   using diameter_bounded_bound[of s] diameter_lower_bounded[of s] assms
  5752   by auto
  5753 
  5754 lemma diameter_compact_attained:
  5755   assumes "compact s"
  5756     and "s \<noteq> {}"
  5757   shows "\<exists>x\<in>s. \<exists>y\<in>s. dist x y = diameter s"
  5758 proof -
  5759   have b: "bounded s" using assms(1)
  5760     by (rule compact_imp_bounded)
  5761   then obtain x y where xys: "x\<in>s" "y\<in>s"
  5762     and xy: "\<forall>u\<in>s. \<forall>v\<in>s. dist u v \<le> dist x y"
  5763     using compact_sup_maxdistance[OF assms] by auto
  5764   then have "diameter s \<le> dist x y"
  5765     unfolding diameter_def
  5766     apply clarsimp
  5767     apply (rule cSUP_least)
  5768     apply fast+
  5769     done
  5770   then show ?thesis
  5771     by (metis b diameter_bounded_bound order_antisym xys)
  5772 qed
  5773 
  5774 text {* Related results with closure as the conclusion. *}
  5775 
  5776 lemma closed_scaling:
  5777   fixes s :: "'a::real_normed_vector set"
  5778   assumes "closed s"
  5779   shows "closed ((\<lambda>x. c *\<^sub>R x) ` s)"
  5780 proof (cases "c = 0")
  5781   case True then show ?thesis
  5782     by (auto simp add: image_constant_conv)
  5783 next
  5784   case False
  5785   from assms have "closed ((\<lambda>x. inverse c *\<^sub>R x) -` s)"
  5786     by (simp add: continuous_closed_vimage)
  5787   also have "(\<lambda>x. inverse c *\<^sub>R x) -` s = (\<lambda>x. c *\<^sub>R x) ` s"
  5788     using `c \<noteq> 0` by (auto elim: image_eqI [rotated])
  5789   finally show ?thesis .
  5790 qed
  5791 
  5792 lemma closed_negations:
  5793   fixes s :: "'a::real_normed_vector set"
  5794   assumes "closed s"
  5795   shows "closed ((\<lambda>x. -x) ` s)"
  5796   using closed_scaling[OF assms, of "- 1"] by simp
  5797 
  5798 lemma compact_closed_sums:
  5799   fixes s :: "'a::real_normed_vector set"
  5800   assumes "compact s" and "closed t"
  5801   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  5802 proof -
  5803   let ?S = "{x + y |x y. x \<in> s \<and> y \<in> t}"
  5804   {
  5805     fix x l
  5806     assume as: "\<forall>n. x n \<in> ?S"  "(x ---> l) sequentially"
  5807     from as(1) obtain f where f: "\<forall>n. x n = fst (f n) + snd (f n)"  "\<forall>n. fst (f n) \<in> s"  "\<forall>n. snd (f n) \<in> t"
  5808       using choice[of "\<lambda>n y. x n = (fst y) + (snd y) \<and> fst y \<in> s \<and> snd y \<in> t"] by auto
  5809     obtain l' r where "l'\<in>s" and r: "subseq r" and lr: "(((\<lambda>n. fst (f n)) \<circ> r) ---> l') sequentially"
  5810       using assms(1)[unfolded compact_def, THEN spec[where x="\<lambda> n. fst (f n)"]] using f(2) by auto
  5811     have "((\<lambda>n. snd (f (r n))) ---> l - l') sequentially"
  5812       using tendsto_diff[OF LIMSEQ_subseq_LIMSEQ[OF as(2) r] lr] and f(1)
  5813       unfolding o_def
  5814       by auto
  5815     then have "l - l' \<in> t"
  5816       using assms(2)[unfolded closed_sequential_limits,
  5817         THEN spec[where x="\<lambda> n. snd (f (r n))"],
  5818         THEN spec[where x="l - l'"]]
  5819       using f(3)
  5820       by auto
  5821     then have "l \<in> ?S"
  5822       using `l' \<in> s`
  5823       apply auto
  5824       apply (rule_tac x=l' in exI)
  5825       apply (rule_tac x="l - l'" in exI)
  5826       apply auto
  5827       done
  5828   }
  5829   then show ?thesis
  5830     unfolding closed_sequential_limits by fast
  5831 qed
  5832 
  5833 lemma closed_compact_sums:
  5834   fixes s t :: "'a::real_normed_vector set"
  5835   assumes "closed s"
  5836     and "compact t"
  5837   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  5838 proof -
  5839   have "{x + y |x y. x \<in> t \<and> y \<in> s} = {x + y |x y. x \<in> s \<and> y \<in> t}"
  5840     apply auto
  5841     apply (rule_tac x=y in exI)
  5842     apply auto
  5843     apply (rule_tac x=y in exI)
  5844     apply auto
  5845     done
  5846   then show ?thesis
  5847     using compact_closed_sums[OF assms(2,1)] by simp
  5848 qed
  5849 
  5850 lemma compact_closed_differences:
  5851   fixes s t :: "'a::real_normed_vector set"
  5852   assumes "compact s"
  5853     and "closed t"
  5854   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  5855 proof -
  5856   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} =  {x - y |x y. x \<in> s \<and> y \<in> t}"
  5857     apply auto
  5858     apply (rule_tac x=xa in exI)
  5859     apply auto
  5860     apply (rule_tac x=xa in exI)
  5861     apply auto
  5862     done
  5863   then show ?thesis
  5864     using compact_closed_sums[OF assms(1) closed_negations[OF assms(2)]] by auto
  5865 qed
  5866 
  5867 lemma closed_compact_differences:
  5868   fixes s t :: "'a::real_normed_vector set"
  5869   assumes "closed s"
  5870     and "compact t"
  5871   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  5872 proof -
  5873   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} = {x - y |x y. x \<in> s \<and> y \<in> t}"
  5874     apply auto
  5875     apply (rule_tac x=xa in exI)
  5876     apply auto
  5877     apply (rule_tac x=xa in exI)
  5878     apply auto
  5879     done
  5880  then show ?thesis
  5881   using closed_compact_sums[OF assms(1) compact_negations[OF assms(2)]] by simp
  5882 qed
  5883 
  5884 lemma closed_translation:
  5885   fixes a :: "'a::real_normed_vector"
  5886   assumes "closed s"
  5887   shows "closed ((\<lambda>x. a + x) ` s)"
  5888 proof -
  5889   have "{a + y |y. y \<in> s} = (op + a ` s)" by auto
  5890   then show ?thesis
  5891     using compact_closed_sums[OF compact_sing[of a] assms] by auto
  5892 qed
  5893 
  5894 lemma translation_Compl:
  5895   fixes a :: "'a::ab_group_add"
  5896   shows "(\<lambda>x. a + x) ` (- t) = - ((\<lambda>x. a + x) ` t)"
  5897   apply (auto simp add: image_iff)
  5898   apply (rule_tac x="x - a" in bexI)
  5899   apply auto
  5900   done
  5901 
  5902 lemma translation_UNIV:
  5903   fixes a :: "'a::ab_group_add"
  5904   shows "range (\<lambda>x. a + x) = UNIV"
  5905   apply (auto simp add: image_iff)
  5906   apply (rule_tac x="x - a" in exI)
  5907   apply auto
  5908   done
  5909 
  5910 lemma translation_diff:
  5911   fixes a :: "'a::ab_group_add"
  5912   shows "(\<lambda>x. a + x) ` (s - t) = ((\<lambda>x. a + x) ` s) - ((\<lambda>x. a + x) ` t)"
  5913   by auto
  5914 
  5915 lemma closure_translation:
  5916   fixes a :: "'a::real_normed_vector"
  5917   shows "closure ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (closure s)"
  5918 proof -
  5919   have *: "op + a ` (- s) = - op + a ` s"
  5920     apply auto
  5921     unfolding image_iff
  5922     apply (rule_tac x="x - a" in bexI)
  5923     apply auto
  5924     done
  5925   show ?thesis
  5926     unfolding closure_interior translation_Compl
  5927     using interior_translation[of a "- s"]
  5928     unfolding *
  5929     by auto
  5930 qed
  5931 
  5932 lemma frontier_translation:
  5933   fixes a :: "'a::real_normed_vector"
  5934   shows "frontier((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (frontier s)"
  5935   unfolding frontier_def translation_diff interior_translation closure_translation
  5936   by auto
  5937 
  5938 
  5939 subsection {* Separation between points and sets *}
  5940 
  5941 lemma separate_point_closed:
  5942   fixes s :: "'a::heine_borel set"
  5943   assumes "closed s"
  5944     and "a \<notin> s"
  5945   shows "\<exists>d>0. \<forall>x\<in>s. d \<le> dist a x"
  5946 proof (cases "s = {}")
  5947   case True
  5948   then show ?thesis by(auto intro!: exI[where x=1])
  5949 next
  5950   case False
  5951   from assms obtain x where "x\<in>s" "\<forall>y\<in>s. dist a x \<le> dist a y"
  5952     using `s \<noteq> {}` distance_attains_inf [of s a] by blast
  5953   with `x\<in>s` show ?thesis using dist_pos_lt[of a x] and`a \<notin> s`
  5954     by blast
  5955 qed
  5956 
  5957 lemma separate_compact_closed:
  5958   fixes s t :: "'a::heine_borel set"
  5959   assumes "compact s"
  5960     and t: "closed t" "s \<inter> t = {}"
  5961   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  5962 proof cases
  5963   assume "s \<noteq> {} \<and> t \<noteq> {}"
  5964   then have "s \<noteq> {}" "t \<noteq> {}" by auto
  5965   let ?inf = "\<lambda>x. infdist x t"
  5966   have "continuous_on s ?inf"
  5967     by (auto intro!: continuous_at_imp_continuous_on continuous_infdist continuous_at_id)
  5968   then obtain x where x: "x \<in> s" "\<forall>y\<in>s. ?inf x \<le> ?inf y"
  5969     using continuous_attains_inf[OF `compact s` `s \<noteq> {}`] by auto
  5970   then have "0 < ?inf x"
  5971     using t `t \<noteq> {}` in_closed_iff_infdist_zero by (auto simp: less_le infdist_nonneg)
  5972   moreover have "\<forall>x'\<in>s. \<forall>y\<in>t. ?inf x \<le> dist x' y"
  5973     using x by (auto intro: order_trans infdist_le)
  5974   ultimately show ?thesis by auto
  5975 qed (auto intro!: exI[of _ 1])
  5976 
  5977 lemma separate_closed_compact:
  5978   fixes s t :: "'a::heine_borel set"
  5979   assumes "closed s"
  5980     and "compact t"
  5981     and "s \<inter> t = {}"
  5982   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  5983 proof -
  5984   have *: "t \<inter> s = {}"
  5985     using assms(3) by auto
  5986   show ?thesis
  5987     using separate_compact_closed[OF assms(2,1) *]
  5988     apply auto
  5989     apply (rule_tac x=d in exI)
  5990     apply auto
  5991     apply (erule_tac x=y in ballE)
  5992     apply (auto simp add: dist_commute)
  5993     done
  5994 qed
  5995 
  5996 
  5997 subsection {* Intervals *}
  5998 
  5999 lemma interval:
  6000   fixes a :: "'a::ordered_euclidean_space"
  6001   shows "box a b = {x::'a. \<forall>i\<in>Basis. a\<bullet>i < x\<bullet>i \<and> x\<bullet>i < b\<bullet>i}"
  6002     and "{a .. b} = {x::'a. \<forall>i\<in>Basis. a\<bullet>i \<le> x\<bullet>i \<and> x\<bullet>i \<le> b\<bullet>i}"
  6003   by (auto simp add:set_eq_iff eucl_le[where 'a='a] box_def)
  6004 
  6005 lemma mem_interval:
  6006   fixes a :: "'a::ordered_euclidean_space"
  6007   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i\<in>Basis. a\<bullet>i < x\<bullet>i \<and> x\<bullet>i < b\<bullet>i)"
  6008     and "x \<in> {a .. b} \<longleftrightarrow> (\<forall>i\<in>Basis. a\<bullet>i \<le> x\<bullet>i \<and> x\<bullet>i \<le> b\<bullet>i)"
  6009   using interval[of a b]
  6010   by auto
  6011 
  6012 lemma interval_eq_empty:
  6013   fixes a :: "'a::ordered_euclidean_space"
  6014   shows "(box a b = {} \<longleftrightarrow> (\<exists>i\<in>Basis. b\<bullet>i \<le> a\<bullet>i))" (is ?th1)
  6015     and "({a  ..  b} = {} \<longleftrightarrow> (\<exists>i\<in>Basis. b\<bullet>i < a\<bullet>i))" (is ?th2)
  6016 proof -
  6017   {
  6018     fix i x
  6019     assume i: "i\<in>Basis" and as:"b\<bullet>i \<le> a\<bullet>i" and x:"x\<in>box a b"
  6020     then have "a \<bullet> i < x \<bullet> i \<and> x \<bullet> i < b \<bullet> i"
  6021       unfolding mem_interval by auto
  6022     then have "a\<bullet>i < b\<bullet>i" by auto
  6023     then have False using as by auto
  6024   }
  6025   moreover
  6026   {
  6027     assume as: "\<forall>i\<in>Basis. \<not> (b\<bullet>i \<le> a\<bullet>i)"
  6028     let ?x = "(1/2) *\<^sub>R (a + b)"
  6029     {
  6030       fix i :: 'a
  6031       assume i: "i \<in> Basis"
  6032       have "a\<bullet>i < b\<bullet>i"
  6033         using as[THEN bspec[where x=i]] i by auto
  6034       then have "a\<bullet>i < ((1/2) *\<^sub>R (a+b)) \<bullet> i" "((1/2) *\<^sub>R (a+b)) \<bullet> i < b\<bullet>i"
  6035         by (auto simp: inner_add_left)
  6036     }
  6037     then have "box a b \<noteq> {}"
  6038       using mem_interval(1)[of "?x" a b] by auto
  6039   }
  6040   ultimately show ?th1 by blast
  6041 
  6042   {
  6043     fix i x
  6044     assume i: "i \<in> Basis" and as:"b\<bullet>i < a\<bullet>i" and x:"x\<in>{a .. b}"
  6045     then have "a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i"
  6046       unfolding mem_interval by auto
  6047     then have "a\<bullet>i \<le> b\<bullet>i" by auto
  6048     then have False using as by auto
  6049   }
  6050   moreover
  6051   {
  6052     assume as:"\<forall>i\<in>Basis. \<not> (b\<bullet>i < a\<bullet>i)"
  6053     let ?x = "(1/2) *\<^sub>R (a + b)"
  6054     {
  6055       fix i :: 'a
  6056       assume i:"i \<in> Basis"
  6057       have "a\<bullet>i \<le> b\<bullet>i"
  6058         using as[THEN bspec[where x=i]] i by auto
  6059       then have "a\<bullet>i \<le> ((1/2) *\<^sub>R (a+b)) \<bullet> i" "((1/2) *\<^sub>R (a+b)) \<bullet> i \<le> b\<bullet>i"
  6060         by (auto simp: inner_add_left)
  6061     }
  6062     then have "{a .. b} \<noteq> {}"
  6063       using mem_interval(2)[of "?x" a b] by auto
  6064   }
  6065   ultimately show ?th2 by blast
<