src/Pure/theory.ML
author wenzelm
Mon Jun 20 22:14:09 2005 +0200 (2005-06-20)
changeset 16495 2e99aca906a7
parent 16443 82a116532e3e
child 16536 c5744af6b28a
permissions -rw-r--r--
added begin_theory, end_theory;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   type theory
    11   type theory_ref
    12   val sign_of: theory -> theory    (*obsolete*)
    13   val rep_theory: theory ->
    14    {axioms: term NameSpace.table,
    15     defs: Defs.graph,
    16     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    17   val parents_of: theory -> theory list
    18   val ancestors_of: theory -> theory list
    19   val eq_thy: theory * theory -> bool
    20   val subthy: theory * theory -> bool
    21   val cert_axm: theory -> string * term -> string * term
    22   val read_def_axm: theory * (indexname -> typ option) * (indexname -> sort option) ->
    23     string list -> string * string -> string * term
    24   val read_axm: theory -> string * string -> string * term
    25   val inferT_axm: theory -> string * term -> string * term
    26 end
    27 
    28 signature THEORY =
    29 sig
    30   include BASIC_THEORY
    31   include SIGN_THEORY
    32   val begin_theory: string -> theory list -> theory
    33   val end_theory: theory -> theory
    34   val checkpoint: theory -> theory
    35   val copy: theory -> theory
    36   val init: theory -> theory
    37   val axiom_space: theory -> NameSpace.T
    38   val oracle_space: theory -> NameSpace.T
    39   val axioms_of: theory -> (string * term) list
    40   val all_axioms_of: theory -> (string * term) list
    41   val self_ref: theory -> theory_ref
    42   val deref: theory_ref -> theory
    43   val merge: theory * theory -> theory                     (*exception TERM*)
    44   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    45   val requires: theory -> string -> string -> unit
    46   val assert_super: theory -> theory -> theory
    47   val add_axioms: (bstring * string) list -> theory -> theory
    48   val add_axioms_i: (bstring * term) list -> theory -> theory
    49   val add_defs: bool -> (bstring * string) list -> theory -> theory
    50   val add_defs_i: bool -> (bstring * term) list -> theory -> theory
    51   val add_finals: bool -> string list -> theory -> theory
    52   val add_finals_i: bool -> term list -> theory -> theory
    53   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    54 end
    55 
    56 structure Theory: THEORY =
    57 struct
    58 
    59 (** type theory **)
    60 
    61 (* context operations *)
    62 
    63 type theory = Context.theory;
    64 type theory_ref = Context.theory_ref;
    65 
    66 val eq_thy = Context.eq_thy;
    67 val subthy = Context.subthy;
    68 
    69 val parents_of = Context.parents_of;
    70 val ancestors_of = Context.ancestors_of;
    71 
    72 val self_ref = Context.self_ref;
    73 val deref = Context.deref;
    74 val merge = Context.merge;
    75 val merge_refs = Context.merge_refs;
    76 
    77 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    78 val end_theory = Context.finish_thy;
    79 val checkpoint = Context.checkpoint_thy;
    80 val copy = Context.copy_thy;
    81 
    82 
    83 (* signature operations *)
    84 
    85 val sign_of = I;
    86 
    87 structure SignTheory: SIGN_THEORY = Sign;
    88 open SignTheory;
    89 
    90 
    91 
    92 (** diagnostics **)  (* FIXME belongs to defs.ML *)
    93 
    94 fun pretty_const pp (c, T) =
    95  [Pretty.str c, Pretty.str " ::", Pretty.brk 1,
    96   Pretty.quote (Pretty.typ pp (Type.freeze_type T))];    (* FIXME zero indexes!? *)
    97 
    98 fun pretty_path pp path = fold_rev (fn (T, c, def) =>
    99   fn [] => [Pretty.block (pretty_const pp (c, T))]
   100    | prts => Pretty.block (pretty_const pp (c, T) @
   101       [Pretty.brk 1, Pretty.str ("depends via " ^ quote def ^ " on")]) :: prts) path [];
   102 
   103 fun chain_history_msg s =    (* FIXME huh!? *)
   104   if Defs.chain_history () then s ^ ": "
   105   else s ^ " (set DEFS_CHAIN_HISTORY=ON for full history): ";
   106 
   107 fun defs_circular pp path =
   108   Pretty.str (chain_history_msg "Cyclic dependency of definitions") :: pretty_path pp path
   109   |> Pretty.chunks |> Pretty.string_of;
   110 
   111 fun defs_infinite_chain pp path =
   112   Pretty.str (chain_history_msg "Infinite chain of definitions") :: pretty_path pp path
   113   |> Pretty.chunks |> Pretty.string_of;
   114 
   115 fun defs_clash def1 def2 = "Type clash in definitions " ^ quote def1 ^ " and " ^ quote def2;
   116 
   117 fun defs_final pp const =
   118   (Pretty.str "Attempt to define final constant" :: Pretty.brk 1 :: pretty_const pp const)
   119   |> Pretty.block |> Pretty.string_of;
   120 
   121 
   122 
   123 (** datatype thy **)
   124 
   125 datatype thy = Thy of
   126  {axioms: term NameSpace.table,
   127   defs: Defs.graph,
   128   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
   129 
   130 fun make_thy (axioms, defs, oracles) =
   131   Thy {axioms = axioms, defs = defs, oracles = oracles};
   132 
   133 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   134 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   135 
   136 structure ThyData = TheoryDataFun
   137 (struct
   138   val name = "Pure/thy";
   139   type T = thy;
   140   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   141   val copy = I;
   142 
   143   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   144 
   145   fun merge pp (thy1, thy2) =
   146     let
   147       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   148       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   149 
   150       val axioms = NameSpace.empty_table;
   151       val defs = Defs.merge defs1 defs2  (* FIXME produce errors in defs.ML *)
   152         handle Defs.CIRCULAR namess => error (defs_circular pp namess)
   153           | Defs.INFINITE_CHAIN namess => error (defs_infinite_chain pp namess);
   154       val oracles = NameSpace.merge_tables eq_snd (oracles1, oracles2)
   155         handle Symtab.DUPS dups => err_dup_oras dups;
   156     in make_thy (axioms, defs, oracles) end;
   157 
   158   fun print _ _ = ();
   159 end);
   160 
   161 val init = ThyData.init;
   162 
   163 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   164 
   165 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   166   make_thy (f (axioms, defs, oracles)));
   167 
   168 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   169 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   170 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   171 
   172 
   173 (* basic operations *)
   174 
   175 val axiom_space = #1 o #axioms o rep_theory;
   176 val oracle_space = #1 o #oracles o rep_theory;
   177 
   178 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   179 fun all_axioms_of thy = List.concat (map axioms_of (thy :: ancestors_of thy));
   180 
   181 fun requires thy name what =
   182   if Context.exists_name name thy then ()
   183   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   184 
   185 fun assert_super thy1 thy2 =
   186   if subthy (thy1, thy2) then thy2
   187   else raise THEORY ("Not a super theory", [thy1, thy2]);
   188 
   189 
   190 
   191 (** add axioms **)
   192 
   193 (* prepare axioms *)
   194 
   195 fun err_in_axm name =
   196   error ("The error(s) above occurred in axiom " ^ quote name);
   197 
   198 fun no_vars pp tm =
   199   (case (Term.term_vars tm, Term.term_tvars tm) of
   200     ([], []) => tm
   201   | (ts, ixns) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   202       (Pretty.str "Illegal schematic variable(s) in term:" ::
   203        map (Pretty.term pp) ts @ map (Pretty.typ pp o TVar) ixns)))));
   204 
   205 fun cert_axm thy (name, raw_tm) =
   206   let
   207     val pp = Sign.pp thy;
   208     val (t, T, _) = Sign.certify_term pp thy raw_tm
   209       handle TYPE (msg, _, _) => error msg
   210         | TERM (msg, _) => error msg;
   211   in
   212     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   213     assert (T = propT) "Term not of type prop";
   214     (name, no_vars pp t)
   215   end;
   216 
   217 fun read_def_axm (thy, types, sorts) used (name, str) =
   218   let
   219     val ts = Syntax.read (Sign.is_logtype thy) (Sign.syn_of thy) propT str;
   220     val (t, _) = Sign.infer_types (Sign.pp thy) thy types sorts used true (ts, propT);
   221   in cert_axm thy (name, t) end
   222   handle ERROR => err_in_axm name;
   223 
   224 fun read_axm thy name_str = read_def_axm (thy, K NONE, K NONE) [] name_str;
   225 
   226 fun inferT_axm thy (name, pre_tm) =
   227   let
   228     val pp = Sign.pp thy;
   229     val (t, _) = Sign.infer_types pp thy (K NONE) (K NONE) [] true ([pre_tm], propT);
   230   in (name, no_vars pp t) end
   231   handle ERROR => err_in_axm name;
   232 
   233 
   234 (* add_axioms(_i) *)
   235 
   236 local
   237 
   238 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   239   let
   240     val axms = map (apsnd (Term.compress_term o Logic.varify) o prep_axm thy) raw_axms;
   241     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   242       handle Symtab.DUPS dups => err_dup_axms dups;
   243   in axioms' end);
   244 
   245 in
   246 
   247 val add_axioms = gen_add_axioms read_axm;
   248 val add_axioms_i = gen_add_axioms cert_axm;
   249 
   250 end;
   251 
   252 
   253 
   254 (** add constant definitions **)
   255 
   256 (* overloading *)
   257 
   258 datatype overloading = Clean | Implicit | Useless;
   259 
   260 fun overloading thy overloaded declT defT =
   261   let
   262     val defT' = Term.incr_tvar (maxidx_of_typ declT + 1) (Type.varifyT defT);
   263   in
   264     if Sign.typ_instance thy (declT, defT') then Clean
   265     else if Sign.typ_instance thy (Type.strip_sorts declT, Type.strip_sorts defT') then Useless
   266     else if overloaded then Clean
   267     else Implicit
   268   end;
   269 
   270 
   271 (* dest_def *)
   272 
   273 fun dest_def pp tm =
   274   let
   275     fun err msg = raise TERM (msg, [tm]);
   276 
   277     val (lhs, rhs) = Logic.dest_equals (Logic.strip_imp_concl tm)
   278       handle TERM _ => err "Not a meta-equality (==)";
   279     val (head, args) = Term.strip_comb lhs;
   280     val (c, T) = Term.dest_Const head
   281       handle TERM _ => err "Head of lhs not a constant";
   282 
   283     fun dest_free (Free (x, _)) = x
   284       | dest_free (Const ("TYPE", Type ("itself", [TFree (x, _)]))) = x
   285       | dest_free _ = raise Match;
   286 
   287     val show_terms = commas_quote o map (Pretty.string_of_term pp);
   288     val show_frees = commas_quote o map dest_free;
   289     val show_tfrees = commas_quote o map fst;
   290 
   291     val lhs_nofrees = filter (not o can dest_free) args;
   292     val lhs_dups = duplicates args;
   293     val rhs_extras = term_frees rhs |> fold (remove op =) args;
   294     val rhs_extrasT = term_tfrees rhs |> fold (remove op =) (typ_tfrees T);
   295   in
   296     if not (null lhs_nofrees) then
   297       err ("Non-variables as arguments on lhs: " ^ show_terms lhs_nofrees)
   298     else if not (null lhs_dups) then
   299       err ("Duplicate variables on lhs: " ^ show_frees lhs_dups)
   300     else if not (null rhs_extras) then
   301       err ("Extra variables on rhs: " ^ show_frees rhs_extras)
   302     else if not (null rhs_extrasT) then
   303       err ("Extra type variables on rhs: " ^ show_tfrees rhs_extrasT)
   304     else if exists_Const (equal (c, T)) rhs then
   305       err ("Constant to be defined occurs on rhs")
   306     else ((c, T), rhs)
   307   end;
   308 
   309 
   310 (* check_def *)
   311 
   312 fun declare thy c defs =      (* FIXME move to defs.ML *)
   313   let val T = Sign.the_const_type thy c
   314   in if_none (try (Defs.declare defs) (c, T)) defs end;
   315 
   316 fun check_def thy overloaded (bname, tm) defs =
   317   let
   318     val pp = Sign.pp thy;
   319 
   320     fun err msg = error (Pretty.string_of (Pretty.chunks
   321      [Pretty.str msg, Pretty.block
   322       [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   323         Pretty.fbrk, Pretty.quote (Pretty.term pp tm)]]));
   324 
   325     fun prt_const (c, T) =
   326      [Pretty.str c, Pretty.str " ::", Pretty.brk 1,
   327       Pretty.quote (Pretty.typ pp (Type.freeze_type T))];
   328     fun string_of_def const txt =
   329       [Pretty.block (Pretty.str "Definition of " :: pretty_const pp const), Pretty.str txt]
   330       |> Pretty.chunks |> Pretty.string_of;
   331 
   332     val ((c, defT), rhs) = dest_def pp tm handle TERM (msg, _) => err msg;
   333     val rhs_consts = Term.term_constsT rhs;
   334     val declT = Sign.the_const_type thy c;
   335 
   336     val _ =
   337       (case overloading thy overloaded declT defT of
   338         Clean => ()
   339       | Implicit => warning (string_of_def (c, defT)
   340           ("is strictly less general than the declared type (see " ^ quote bname ^ ")"))
   341       | Useless => err (Library.setmp show_sorts true (string_of_def (c, defT))
   342           "imposes additional sort constraints on the declared type of the constant"));
   343 
   344     val decl_defs = defs |> declare thy c |> fold (declare thy) (map #1 rhs_consts);
   345   in
   346     Defs.define decl_defs (c, defT) (Sign.full_name thy bname) rhs_consts
   347       (* FIXME produce errors in defs.ML *)
   348       handle Defs.DEFS msg => err ("DEFS: " ^ msg)   (* FIXME sys_error!? *)
   349         | Defs.CIRCULAR path => err (defs_circular pp path)
   350         | Defs.INFINITE_CHAIN path => err (defs_infinite_chain pp path)
   351         | Defs.CLASH (_, def1, def2) => err (defs_clash def1 def2)
   352         | Defs.FINAL const => err (defs_final pp const)
   353   end;
   354 
   355 
   356 (* add_defs(_i) *)
   357 
   358 local
   359 
   360 fun gen_add_defs prep_axm overloaded raw_axms thy =
   361   let val axms = map (prep_axm thy) raw_axms in
   362     thy
   363     |> map_defs (fold (check_def thy overloaded) axms)
   364     |> add_axioms_i axms
   365   end;
   366 
   367 in
   368 
   369 val add_defs_i = gen_add_defs cert_axm;
   370 val add_defs = gen_add_defs read_axm;
   371 
   372 end;
   373 
   374 
   375 (* add_finals(_i) *)
   376 
   377 local
   378 
   379 fun gen_add_finals prep_term overloaded raw_terms thy =
   380   let
   381     fun finalize tm finals =
   382       let
   383         fun err msg = raise TERM (msg, [tm]);    (* FIXME error!? *)
   384         val (c, defT) =
   385           (case tm of Const x => x
   386           | Free _ => err "Attempt to finalize variable (or undeclared constant)"
   387           | _ => err "Attempt to finalize non-constant term");
   388         val declT = Sign.the_const_type thy c
   389           handle TYPE (msg, _, _) => err msg;
   390         val _ =    (* FIXME unify messages with defs *)
   391           (case overloading thy overloaded declT defT of
   392             Clean => ()
   393           | Implicit => warning ("Finalizing " ^ quote c ^
   394               " at a strictly less general type than declared")
   395           | Useless => err "Sort constraints stronger than declared");
   396       in Defs.finalize (if_none (try (Defs.declare finals) (c, declT)) finals) (c, defT) end;
   397   in thy |> map_defs (fold finalize (map (prep_term thy) raw_terms)) end;
   398 
   399 fun read_term thy = Sign.simple_read_term thy TypeInfer.logicT;
   400 fun cert_term thy = #1 o Sign.certify_term (Sign.pp thy) thy;
   401 
   402 in
   403 
   404 val add_finals = gen_add_finals read_term;
   405 val add_finals_i = gen_add_finals cert_term;
   406 
   407 end;
   408 
   409 
   410 
   411 (** add oracle **)
   412 
   413 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   414   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   415     handle Symtab.DUPS dups => err_dup_oras dups);
   416 
   417 end;
   418 
   419 structure BasicTheory: BASIC_THEORY = Theory;
   420 open BasicTheory;