src/HOL/SMT.thy
author boehmes
Wed Dec 15 10:12:44 2010 +0100 (2010-12-15)
changeset 41127 2ea84c8535c6
parent 41126 e0bd443c0fdd
child 41174 10eb369f8c01
permissions -rw-r--r--
re-implemented eta-expansion, lambda-lifting, and explicit application on terms (exploiting the control over the term structure);
abolished SMT interface concept in favor of solver classes (now also the translation configuration is stored in the context);
proof reconstruction is now expected to return a theorem stating False (and hence needs to discharge all hypothetical definitions);
built-in functions carry additionally their arity and their most general type;
slightly generalized the definition of fun_app
     1 (*  Title:      HOL/SMT.thy
     2     Author:     Sascha Boehme, TU Muenchen
     3 *)
     4 
     5 header {* Bindings to Satisfiability Modulo Theories (SMT) solvers *}
     6 
     7 theory SMT
     8 imports List
     9 uses
    10   "Tools/Datatype/datatype_selectors.ML"
    11   "Tools/SMT/smt_utils.ML"
    12   "Tools/SMT/smt_failure.ML"
    13   "Tools/SMT/smt_config.ML"
    14   "Tools/SMT/smt_monomorph.ML"
    15   ("Tools/SMT/smt_builtin.ML")
    16   ("Tools/SMT/smt_normalize.ML")
    17   ("Tools/SMT/smt_translate.ML")
    18   ("Tools/SMT/smt_solver.ML")
    19   ("Tools/SMT/smtlib_interface.ML")
    20   ("Tools/SMT/z3_proof_parser.ML")
    21   ("Tools/SMT/z3_proof_tools.ML")
    22   ("Tools/SMT/z3_proof_literals.ML")
    23   ("Tools/SMT/z3_proof_methods.ML")
    24   ("Tools/SMT/z3_proof_reconstruction.ML")
    25   ("Tools/SMT/z3_model.ML")
    26   ("Tools/SMT/z3_interface.ML")
    27   ("Tools/SMT/smt_setup_solvers.ML")
    28 begin
    29 
    30 
    31 
    32 subsection {* Triggers for quantifier instantiation *}
    33 
    34 text {*
    35 Some SMT solvers support patterns as a quantifier instantiation
    36 heuristics.  Patterns may either be positive terms (tagged by "pat")
    37 triggering quantifier instantiations -- when the solver finds a
    38 term matching a positive pattern, it instantiates the corresponding
    39 quantifier accordingly -- or negative terms (tagged by "nopat")
    40 inhibiting quantifier instantiations.  A list of patterns
    41 of the same kind is called a multipattern, and all patterns in a
    42 multipattern are considered conjunctively for quantifier instantiation.
    43 A list of multipatterns is called a trigger, and their multipatterns
    44 act disjunctively during quantifier instantiation.  Each multipattern
    45 should mention at least all quantified variables of the preceding
    46 quantifier block.
    47 *}
    48 
    49 datatype pattern = Pattern
    50 
    51 definition pat :: "'a \<Rightarrow> pattern" where "pat _ = Pattern"
    52 definition nopat :: "'a \<Rightarrow> pattern" where "nopat _ = Pattern"
    53 
    54 definition trigger :: "pattern list list \<Rightarrow> bool \<Rightarrow> bool"
    55 where "trigger _ P = P"
    56 
    57 
    58 
    59 subsection {* Quantifier weights *}
    60 
    61 text {*
    62 Weight annotations to quantifiers influence the priority of quantifier
    63 instantiations.  They should be handled with care for solvers, which support
    64 them, because incorrect choices of weights might render a problem unsolvable.
    65 *}
    66 
    67 definition weight :: "int \<Rightarrow> bool \<Rightarrow> bool" where "weight _ P = P"
    68 
    69 text {*
    70 Weights must be non-negative.  The value @{text 0} is equivalent to providing
    71 no weight at all.
    72 
    73 Weights should only be used at quantifiers and only inside triggers (if the
    74 quantifier has triggers).  Valid usages of weights are as follows:
    75 
    76 \begin{itemize}
    77 \item
    78 @{term "\<forall>x. trigger [[pat (P x)]] (weight 2 (P x))"}
    79 \item
    80 @{term "\<forall>x. weight 3 (P x)"}
    81 \end{itemize}
    82 *}
    83 
    84 
    85 
    86 subsection {* Higher-order encoding *}
    87 
    88 text {*
    89 Application is made explicit for constants occurring with varying
    90 numbers of arguments.  This is achieved by the introduction of the
    91 following constant.
    92 *}
    93 
    94 definition fun_app where "fun_app f = f"
    95 
    96 text {*
    97 Some solvers support a theory of arrays which can be used to encode
    98 higher-order functions.  The following set of lemmas specifies the
    99 properties of such (extensional) arrays.
   100 *}
   101 
   102 lemmas array_rules = ext fun_upd_apply fun_upd_same fun_upd_other
   103   fun_upd_upd fun_app_def
   104 
   105 
   106 
   107 subsection {* First-order logic *}
   108 
   109 text {*
   110 Some SMT solvers only accept problems in first-order logic, i.e.,
   111 where formulas and terms are syntactically separated. When
   112 translating higher-order into first-order problems, all
   113 uninterpreted constants (those not built-in in the target solver)
   114 are treated as function symbols in the first-order sense.  Their
   115 occurrences as head symbols in atoms (i.e., as predicate symbols) are
   116 turned into terms by equating such atoms with @{term True}.
   117 Whenever the boolean type occurs in first-order terms, it is replaced
   118 by the following type.
   119 *}
   120 
   121 typedecl term_bool
   122 
   123 
   124 
   125 subsection {* Integer division and modulo for Z3 *}
   126 
   127 definition z3div :: "int \<Rightarrow> int \<Rightarrow> int" where
   128   "z3div k l = (if 0 \<le> l then k div l else -(k div (-l)))"
   129 
   130 definition z3mod :: "int \<Rightarrow> int \<Rightarrow> int" where
   131   "z3mod k l = (if 0 \<le> l then k mod l else k mod (-l))"
   132 
   133 lemma div_by_z3div:
   134   "\<forall>k l. k div l = (
   135     if k = 0 \<or> l = 0 then 0
   136     else if (0 < k \<and> 0 < l) \<or> (k < 0 \<and> 0 < l) then z3div k l
   137     else z3div (-k) (-l))"
   138   by (auto simp add: z3div_def trigger_def)
   139 
   140 lemma mod_by_z3mod:
   141   "\<forall>k l. k mod l = (
   142     if l = 0 then k
   143     else if k = 0 then 0
   144     else if (0 < k \<and> 0 < l) \<or> (k < 0 \<and> 0 < l) then z3mod k l
   145     else - z3mod (-k) (-l))"
   146   by (auto simp add: z3mod_def trigger_def)
   147 
   148 
   149 
   150 subsection {* Setup *}
   151 
   152 use "Tools/SMT/smt_builtin.ML"
   153 use "Tools/SMT/smt_normalize.ML"
   154 use "Tools/SMT/smt_translate.ML"
   155 use "Tools/SMT/smt_solver.ML"
   156 use "Tools/SMT/smtlib_interface.ML"
   157 use "Tools/SMT/z3_interface.ML"
   158 use "Tools/SMT/z3_proof_parser.ML"
   159 use "Tools/SMT/z3_proof_tools.ML"
   160 use "Tools/SMT/z3_proof_literals.ML"
   161 use "Tools/SMT/z3_proof_methods.ML"
   162 use "Tools/SMT/z3_proof_reconstruction.ML"
   163 use "Tools/SMT/z3_model.ML"
   164 use "Tools/SMT/smt_setup_solvers.ML"
   165 
   166 setup {*
   167   SMT_Config.setup #>
   168   SMT_Normalize.setup #>
   169   SMT_Solver.setup #>
   170   SMTLIB_Interface.setup #>
   171   Z3_Interface.setup #>
   172   Z3_Proof_Reconstruction.setup #>
   173   SMT_Setup_Solvers.setup
   174 *}
   175 
   176 
   177 
   178 subsection {* Configuration *}
   179 
   180 text {*
   181 The current configuration can be printed by the command
   182 @{text smt_status}, which shows the values of most options.
   183 *}
   184 
   185 
   186 
   187 subsection {* General configuration options *}
   188 
   189 text {*
   190 The option @{text smt_solver} can be used to change the target SMT
   191 solver.  The possible values are @{text cvc3}, @{text yices}, and
   192 @{text z3}.  It is advisable to locally install the selected solver,
   193 although this is not necessary for @{text cvc3} and @{text z3}, which
   194 can also be used over an Internet-based service.
   195 
   196 When using local SMT solvers, the path to their binaries should be
   197 declared by setting the following environment variables:
   198 @{text CVC3_SOLVER}, @{text YICES_SOLVER}, and @{text Z3_SOLVER}.
   199 *}
   200 
   201 declare [[ smt_solver = z3 ]]
   202 
   203 text {*
   204 Since SMT solvers are potentially non-terminating, there is a timeout
   205 (given in seconds) to restrict their runtime.  A value greater than
   206 120 (seconds) is in most cases not advisable.
   207 *}
   208 
   209 declare [[ smt_timeout = 20 ]]
   210 
   211 text {*
   212 SMT solvers apply randomized heuristics.  In case a problem is not
   213 solvable by an SMT solver, changing the following option might help.
   214 *}
   215 
   216 declare [[ smt_random_seed = 1 ]]
   217 
   218 text {*
   219 In general, the binding to SMT solvers runs as an oracle, i.e, the SMT
   220 solvers are fully trusted without additional checks.  The following
   221 option can cause the SMT solver to run in proof-producing mode, giving
   222 a checkable certificate.  This is currently only implemented for Z3.
   223 *}
   224 
   225 declare [[ smt_oracle = false ]]
   226 
   227 text {*
   228 Each SMT solver provides several commandline options to tweak its
   229 behaviour.  They can be passed to the solver by setting the following
   230 options.
   231 *}
   232 
   233 declare [[ cvc3_options = "", yices_options = "", z3_options = "" ]]
   234 
   235 text {*
   236 Enable the following option to use built-in support for datatypes and
   237 records.  Currently, this is only implemented for Z3 running in oracle
   238 mode.
   239 *}
   240 
   241 declare [[ smt_datatypes = false ]]
   242 
   243 text {*
   244 The SMT method provides an inference mechanism to detect simple triggers
   245 in quantified formulas, which might increase the number of problems
   246 solvable by SMT solvers (note: triggers guide quantifier instantiations
   247 in the SMT solver).  To turn it on, set the following option.
   248 *}
   249 
   250 declare [[ smt_infer_triggers = false ]]
   251 
   252 text {*
   253 The SMT method monomorphizes the given facts, that is, it tries to
   254 instantiate all schematic type variables with fixed types occurring
   255 in the problem.  This is a (possibly nonterminating) fixed-point
   256 construction whose cycles are limited by the following option.
   257 *}
   258 
   259 declare [[ smt_monomorph_limit = 10 ]]
   260 
   261 
   262 
   263 subsection {* Certificates *}
   264 
   265 text {*
   266 By setting the option @{text smt_certificates} to the name of a file,
   267 all following applications of an SMT solver a cached in that file.
   268 Any further application of the same SMT solver (using the very same
   269 configuration) re-uses the cached certificate instead of invoking the
   270 solver.  An empty string disables caching certificates.
   271 
   272 The filename should be given as an explicit path.  It is good
   273 practice to use the name of the current theory (with ending
   274 @{text ".certs"} instead of @{text ".thy"}) as the certificates file.
   275 *}
   276 
   277 declare [[ smt_certificates = "" ]]
   278 
   279 text {*
   280 The option @{text smt_fixed} controls whether only stored
   281 certificates are should be used or invocation of an SMT solver is
   282 allowed.  When set to @{text true}, no SMT solver will ever be
   283 invoked and only the existing certificates found in the configured
   284 cache are used;  when set to @{text false} and there is no cached
   285 certificate for some proposition, then the configured SMT solver is
   286 invoked.
   287 *}
   288 
   289 declare [[ smt_fixed = false ]]
   290 
   291 
   292 
   293 subsection {* Tracing *}
   294 
   295 text {*
   296 The SMT method, when applied, traces important information.  To
   297 make it entirely silent, set the following option to @{text false}.
   298 *}
   299 
   300 declare [[ smt_verbose = true ]]
   301 
   302 text {*
   303 For tracing the generated problem file given to the SMT solver as
   304 well as the returned result of the solver, the option
   305 @{text smt_trace} should be set to @{text true}.
   306 *}
   307 
   308 declare [[ smt_trace = false ]]
   309 
   310 text {*
   311 From the set of assumptions given to the SMT solver, those assumptions
   312 used in the proof are traced when the following option is set to
   313 @{term true}.  This only works for Z3 when it runs in non-oracle mode
   314 (see options @{text smt_solver} and @{text smt_oracle} above).
   315 *}
   316 
   317 declare [[ smt_trace_used_facts = false ]]
   318 
   319 
   320 
   321 subsection {* Schematic rules for Z3 proof reconstruction *}
   322 
   323 text {*
   324 Several prof rules of Z3 are not very well documented.  There are two
   325 lemma groups which can turn failing Z3 proof reconstruction attempts
   326 into succeeding ones: the facts in @{text z3_rule} are tried prior to
   327 any implemented reconstruction procedure for all uncertain Z3 proof
   328 rules;  the facts in @{text z3_simp} are only fed to invocations of
   329 the simplifier when reconstructing theory-specific proof steps.
   330 *}
   331 
   332 lemmas [z3_rule] =
   333   refl eq_commute conj_commute disj_commute simp_thms nnf_simps
   334   ring_distribs field_simps times_divide_eq_right times_divide_eq_left
   335   if_True if_False not_not
   336 
   337 lemma [z3_rule]:
   338   "(P \<longrightarrow> Q) = (Q \<or> \<not>P)"
   339   "(\<not>P \<longrightarrow> Q) = (P \<or> Q)"
   340   "(\<not>P \<longrightarrow> Q) = (Q \<or> P)"
   341   by auto
   342 
   343 lemma [z3_rule]:
   344   "((P = Q) \<longrightarrow> R) = (R | (Q = (\<not>P)))"
   345   by auto
   346 
   347 lemma [z3_rule]:
   348   "((\<not>P) = P) = False"
   349   "(P = (\<not>P)) = False"
   350   "(P \<noteq> Q) = (Q = (\<not>P))"
   351   "(P = Q) = ((\<not>P \<or> Q) \<and> (P \<or> \<not>Q))"
   352   "(P \<noteq> Q) = ((\<not>P \<or> \<not>Q) \<and> (P \<or> Q))"
   353   by auto
   354 
   355 lemma [z3_rule]:
   356   "(if P then P else \<not>P) = True"
   357   "(if \<not>P then \<not>P else P) = True"
   358   "(if P then True else False) = P"
   359   "(if P then False else True) = (\<not>P)"
   360   "(if \<not>P then x else y) = (if P then y else x)"
   361   "f (if P then x else y) = (if P then f x else f y)"
   362   by auto
   363 
   364 lemma [z3_rule]:
   365   "P = Q \<or> P \<or> Q"
   366   "P = Q \<or> \<not>P \<or> \<not>Q"
   367   "(\<not>P) = Q \<or> \<not>P \<or> Q"
   368   "(\<not>P) = Q \<or> P \<or> \<not>Q"
   369   "P = (\<not>Q) \<or> \<not>P \<or> Q"
   370   "P = (\<not>Q) \<or> P \<or> \<not>Q"
   371   "P \<noteq> Q \<or> P \<or> \<not>Q"
   372   "P \<noteq> Q \<or> \<not>P \<or> Q"
   373   "P \<noteq> (\<not>Q) \<or> P \<or> Q"
   374   "(\<not>P) \<noteq> Q \<or> P \<or> Q"
   375   "P \<or> Q \<or> P \<noteq> (\<not>Q)"
   376   "P \<or> Q \<or> (\<not>P) \<noteq> Q"
   377   "P \<or> \<not>Q \<or> P \<noteq> Q"
   378   "\<not>P \<or> Q \<or> P \<noteq> Q"
   379   by auto
   380 
   381 lemma [z3_rule]:
   382   "0 + (x::int) = x"
   383   "x + 0 = x"
   384   "0 * x = 0"
   385   "1 * x = x"
   386   "x + y = y + x"
   387   by auto
   388 
   389 
   390 
   391 hide_type term_bool
   392 hide_type (open) pattern
   393 hide_const Pattern fun_app
   394 hide_const (open) trigger pat nopat weight z3div z3mod
   395 
   396 
   397 
   398 subsection {* Selectors for datatypes *}
   399 
   400 setup {* Datatype_Selectors.setup *}
   401 
   402 declare [[ selector Pair 1 = fst, selector Pair 2 = snd ]]
   403 declare [[ selector Cons 1 = hd, selector Cons 2 = tl ]]
   404 
   405 end