src/Pure/drule.ML
author berghofe
Mon Sep 30 16:37:44 2002 +0200 (2002-09-30)
changeset 13606 2f121149acfe
parent 13569 69a6b3aa0f38
child 13650 31bd2a8cdbe2
permissions -rw-r--r--
Removed nRS again because extract_rews now takes care of preserving names.
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val skip_flexpairs    : cterm -> cterm
    18   val strip_imp_prems   : cterm -> cterm list
    19   val strip_imp_concl   : cterm -> cterm
    20   val cprems_of         : thm -> cterm list
    21   val read_insts        :
    22           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> string list -> (string*string)list
    25                   -> (indexname*ctyp)list * (cterm*cterm)list
    26   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    27   val strip_shyps_warning : thm -> thm
    28   val forall_intr_list  : cterm list -> thm -> thm
    29   val forall_intr_frees : thm -> thm
    30   val forall_intr_vars  : thm -> thm
    31   val forall_elim_list  : cterm list -> thm -> thm
    32   val forall_elim_var   : int -> thm -> thm
    33   val forall_elim_vars  : int -> thm -> thm
    34   val gen_all           : thm -> thm
    35   val freeze_thaw       : thm -> thm * (thm -> thm)
    36   val implies_elim_list : thm -> thm list -> thm
    37   val implies_intr_list : cterm list -> thm -> thm
    38   val instantiate       :
    39     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes  : thm -> thm
    41   val standard          : thm -> thm
    42   val standard'         : thm -> thm
    43   val rotate_prems      : int -> thm -> thm
    44   val rearrange_prems   : int list -> thm -> thm
    45   val assume_ax         : theory -> string -> thm
    46   val RSN               : thm * (int * thm) -> thm
    47   val RS                : thm * thm -> thm
    48   val RLN               : thm list * (int * thm list) -> thm list
    49   val RL                : thm list * thm list -> thm list
    50   val MRS               : thm list * thm -> thm
    51   val MRL               : thm list list * thm list -> thm list
    52   val OF                : thm * thm list -> thm
    53   val compose           : thm * int * thm -> thm list
    54   val COMP              : thm * thm -> thm
    55   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    56   val read_instantiate  : (string*string)list -> thm -> thm
    57   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    58   val eq_thm_sg         : thm * thm -> bool
    59   val eq_thm_prop	: thm * thm -> bool
    60   val weak_eq_thm       : thm * thm -> bool
    61   val size_of_thm       : thm -> int
    62   val reflexive_thm     : thm
    63   val symmetric_thm     : thm
    64   val transitive_thm    : thm
    65   val refl_implies      : thm
    66   val symmetric_fun     : thm -> thm
    67   val extensional       : thm -> thm
    68   val imp_cong          : thm
    69   val swap_prems_eq     : thm
    70   val equal_abs_elim    : cterm  -> thm -> thm
    71   val equal_abs_elim_list: cterm list -> thm -> thm
    72   val flexpair_abs_elim_list: cterm list -> thm -> thm
    73   val asm_rl            : thm
    74   val cut_rl            : thm
    75   val revcut_rl         : thm
    76   val thin_rl           : thm
    77   val triv_forall_equality: thm
    78   val swap_prems_rl     : thm
    79   val equal_intr_rule   : thm
    80   val equal_elim_rule1  : thm
    81   val inst              : string -> string -> thm -> thm
    82   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    83   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    84 end;
    85 
    86 signature DRULE =
    87 sig
    88   include BASIC_DRULE
    89   val strip_comb: cterm -> cterm * cterm list
    90   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    91   val tag_rule: tag -> thm -> thm
    92   val untag_rule: string -> thm -> thm
    93   val tag: tag -> 'a attribute
    94   val untag: string -> 'a attribute
    95   val get_kind: thm -> string
    96   val kind: string -> 'a attribute
    97   val theoremK: string
    98   val lemmaK: string
    99   val corollaryK: string
   100   val internalK: string
   101   val kind_internal: 'a attribute
   102   val has_internal: tag list -> bool
   103   val impose_hyps: cterm list -> thm -> thm
   104   val satisfy_hyps: thm list -> thm -> thm
   105   val close_derivation: thm -> thm
   106   val local_standard: thm -> thm
   107   val compose_single: thm * int * thm -> thm
   108   val add_rule: thm -> thm list -> thm list
   109   val del_rule: thm -> thm list -> thm list
   110   val add_rules: thm list -> thm list -> thm list
   111   val del_rules: thm list -> thm list -> thm list
   112   val merge_rules: thm list * thm list -> thm list
   113   val norm_hhf_eq: thm
   114   val is_norm_hhf: term -> bool
   115   val norm_hhf: Sign.sg -> term -> term
   116   val triv_goal: thm
   117   val rev_triv_goal: thm
   118   val implies_intr_goals: cterm list -> thm -> thm
   119   val freeze_all: thm -> thm
   120   val mk_triv_goal: cterm -> thm
   121   val tvars_of_terms: term list -> (indexname * sort) list
   122   val vars_of_terms: term list -> (indexname * typ) list
   123   val tvars_of: thm -> (indexname * sort) list
   124   val vars_of: thm -> (indexname * typ) list
   125   val unvarifyT: thm -> thm
   126   val unvarify: thm -> thm
   127   val tvars_intr_list: string list -> thm -> thm * (string * indexname) list
   128   val remdups_rl: thm
   129   val conj_intr: thm -> thm -> thm
   130   val conj_intr_list: thm list -> thm
   131   val conj_elim: thm -> thm * thm
   132   val conj_elim_list: thm -> thm list
   133   val conj_elim_precise: int -> thm -> thm list
   134   val conj_intr_thm: thm
   135   val abs_def: thm -> thm
   136 end;
   137 
   138 structure Drule: DRULE =
   139 struct
   140 
   141 
   142 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   143 
   144 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   145 
   146 (*dest_implies for cterms. Note T=prop below*)
   147 fun dest_implies ct =
   148     case term_of ct of
   149         (Const("==>", _) $ _ $ _) =>
   150             let val (ct1,ct2) = Thm.dest_comb ct
   151             in  (#2 (Thm.dest_comb ct1), ct2)  end
   152       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   153 
   154 fun dest_equals ct =
   155     case term_of ct of
   156         (Const("==", _) $ _ $ _) =>
   157             let val (ct1,ct2) = Thm.dest_comb ct
   158             in  (#2 (Thm.dest_comb ct1), ct2)  end
   159       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   160 
   161 
   162 (*Discard flexflex pairs; return a cterm*)
   163 fun skip_flexpairs ct =
   164     case term_of ct of
   165         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   166             skip_flexpairs (#2 (dest_implies ct))
   167       | _ => ct;
   168 
   169 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   170 fun strip_imp_prems ct =
   171     let val (cA,cB) = dest_implies ct
   172     in  cA :: strip_imp_prems cB  end
   173     handle TERM _ => [];
   174 
   175 (* A1==>...An==>B  goes to B, where B is not an implication *)
   176 fun strip_imp_concl ct =
   177     case term_of ct of (Const("==>", _) $ _ $ _) =>
   178         strip_imp_concl (#2 (Thm.dest_comb ct))
   179   | _ => ct;
   180 
   181 (*The premises of a theorem, as a cterm list*)
   182 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   183 
   184 val proto_sign = Theory.sign_of ProtoPure.thy;
   185 
   186 val implies = cterm_of proto_sign Term.implies;
   187 
   188 (*cterm version of mk_implies*)
   189 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   190 
   191 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   192 fun list_implies([], B) = B
   193   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   194 
   195 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   196 fun strip_comb ct = 
   197   let
   198     fun stripc (p as (ct, cts)) =
   199       let val (ct1, ct2) = Thm.dest_comb ct
   200       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   201   in stripc (ct, []) end;
   202 
   203 
   204 (** reading of instantiations **)
   205 
   206 fun absent ixn =
   207   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   208 
   209 fun inst_failure ixn =
   210   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   211 
   212 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   213 let
   214     fun split([],tvs,vs) = (tvs,vs)
   215       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   216                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   217                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   218     val (tvs,vs) = split(insts,[],[]);
   219     fun readT((a,i),st) =
   220         let val ixn = ("'" ^ a,i);
   221             val S = case rsorts ixn of Some S => S | None => absent ixn;
   222             val T = Sign.read_typ (sign,sorts) st;
   223         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   224            else inst_failure ixn
   225         end
   226     val tye = map readT tvs;
   227     fun mkty(ixn,st) = (case rtypes ixn of
   228                           Some T => (ixn,(st,typ_subst_TVars tye T))
   229                         | None => absent ixn);
   230     val ixnsTs = map mkty vs;
   231     val ixns = map fst ixnsTs
   232     and sTs  = map snd ixnsTs
   233     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   234     fun mkcVar(ixn,T) =
   235         let val U = typ_subst_TVars tye2 T
   236         in cterm_of sign (Var(ixn,U)) end
   237     val ixnTs = ListPair.zip(ixns, map snd sTs)
   238 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   239     ListPair.zip(map mkcVar ixnTs,cts))
   240 end;
   241 
   242 
   243 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   244      Used for establishing default types (of variables) and sorts (of
   245      type variables) when reading another term.
   246      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   247 ***)
   248 
   249 fun types_sorts thm =
   250     let val {prop,hyps,...} = rep_thm thm;
   251         val big = list_comb(prop,hyps); (* bogus term! *)
   252         val vars = map dest_Var (term_vars big);
   253         val frees = map dest_Free (term_frees big);
   254         val tvars = term_tvars big;
   255         val tfrees = term_tfrees big;
   256         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   257         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   258     in (typ,sort) end;
   259 
   260 
   261 
   262 (** basic attributes **)
   263 
   264 (* dependent rules *)
   265 
   266 fun rule_attribute f (x, thm) = (x, (f x thm));
   267 
   268 
   269 (* add / delete tags *)
   270 
   271 fun map_tags f thm =
   272   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   273 
   274 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   275 fun untag_rule s = map_tags (filter_out (equal s o #1));
   276 
   277 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   278 fun untag s x = rule_attribute (K (untag_rule s)) x;
   279 
   280 fun simple_tag name x = tag (name, []) x;
   281 
   282 
   283 (* theorem kinds *)
   284 
   285 val theoremK = "theorem";
   286 val lemmaK = "lemma";
   287 val corollaryK = "corollary";
   288 val internalK = "internal";
   289 
   290 fun get_kind thm =
   291   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   292     Some (k :: _) => k
   293   | _ => "unknown");
   294 
   295 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   296 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   297 fun kind_internal x = kind internalK x;
   298 fun has_internal tags = exists (equal internalK o fst) tags;
   299 
   300 
   301 
   302 (** Standardization of rules **)
   303 
   304 (*Strip extraneous shyps as far as possible*)
   305 fun strip_shyps_warning thm =
   306   let
   307     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   308     val thm' = Thm.strip_shyps thm;
   309     val xshyps = Thm.extra_shyps thm';
   310   in
   311     if null xshyps then ()
   312     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   313     thm'
   314   end;
   315 
   316 (*Generalization over a list of variables, IGNORING bad ones*)
   317 fun forall_intr_list [] th = th
   318   | forall_intr_list (y::ys) th =
   319         let val gth = forall_intr_list ys th
   320         in  forall_intr y gth   handle THM _ =>  gth  end;
   321 
   322 (*Generalization over all suitable Free variables*)
   323 fun forall_intr_frees th =
   324     let val {prop,sign,...} = rep_thm th
   325     in  forall_intr_list
   326          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   327          th
   328     end;
   329 
   330 val forall_elim_var = PureThy.forall_elim_var;
   331 val forall_elim_vars = PureThy.forall_elim_vars;
   332 
   333 fun gen_all thm =
   334   let
   335     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   336     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   337     val vs = Term.strip_all_vars prop;
   338   in foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   339 
   340 (*Specialization over a list of cterms*)
   341 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   342 
   343 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   344 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   345 
   346 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   347 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   348 
   349 (* maps |- B to A1,...,An |- B *)
   350 fun impose_hyps chyps th =
   351   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   352   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   353 
   354 (* maps A1,...,An and A1,...,An |- B to |- B *)
   355 fun satisfy_hyps ths th =
   356   implies_elim_list (implies_intr_list (map (#prop o Thm.crep_thm) ths) th) ths;
   357 
   358 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   359 fun zero_var_indexes th =
   360     let val {prop,sign,...} = rep_thm th;
   361         val vars = term_vars prop
   362         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   363         val inrs = add_term_tvars(prop,[]);
   364         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   365         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   366                      (inrs, nms')
   367         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   368         fun varpairs([],[]) = []
   369           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   370                 let val T' = typ_subst_TVars tye T
   371                 in (cterm_of sign (Var(v,T')),
   372                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   373                 end
   374           | varpairs _ = raise TERM("varpairs", []);
   375     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   376 
   377 
   378 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   379     all generality expressed by Vars having index 0.*)
   380 
   381 fun close_derivation thm =
   382   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   383   else thm;
   384 
   385 fun standard' th =
   386   let val {maxidx,...} = rep_thm th in
   387     th
   388     |> implies_intr_hyps
   389     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   390     |> strip_shyps_warning
   391     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   392   end;
   393 
   394 val standard = close_derivation o standard';
   395 
   396 fun local_standard th =
   397   th |> strip_shyps |> zero_var_indexes
   398   |> Thm.compress |> close_derivation;
   399 
   400 
   401 (*Convert all Vars in a theorem to Frees.  Also return a function for
   402   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   403   Similar code in type/freeze_thaw*)
   404 fun freeze_thaw th =
   405  let val fth = freezeT th
   406      val {prop,sign,...} = rep_thm fth
   407  in
   408    case term_vars prop of
   409        [] => (fth, fn x => x)
   410      | vars =>
   411          let fun newName (Var(ix,_), (pairs,used)) =
   412                    let val v = variant used (string_of_indexname ix)
   413                    in  ((ix,v)::pairs, v::used)  end;
   414              val (alist, _) = foldr newName
   415                                 (vars, ([], add_term_names (prop, [])))
   416              fun mk_inst (Var(v,T)) =
   417                  (cterm_of sign (Var(v,T)),
   418                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   419              val insts = map mk_inst vars
   420              fun thaw th' =
   421                  th' |> forall_intr_list (map #2 insts)
   422                      |> forall_elim_list (map #1 insts)
   423          in  (Thm.instantiate ([],insts) fth, thaw)  end
   424  end;
   425 
   426 
   427 (*Rotates a rule's premises to the left by k*)
   428 val rotate_prems = permute_prems 0;
   429 
   430 (* permute prems, where the i-th position in the argument list (counting from 0)
   431    gives the position within the original thm to be transferred to position i.
   432    Any remaining trailing positions are left unchanged. *)
   433 val rearrange_prems = let
   434   fun rearr new []      thm = thm
   435   |   rearr new (p::ps) thm = rearr (new+1)
   436      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   437      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   438   in rearr 0 end;
   439 
   440 (*Assume a new formula, read following the same conventions as axioms.
   441   Generalizes over Free variables,
   442   creates the assumption, and then strips quantifiers.
   443   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   444              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   445 fun assume_ax thy sP =
   446     let val sign = Theory.sign_of thy
   447         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   448     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   449 
   450 (*Resolution: exactly one resolvent must be produced.*)
   451 fun tha RSN (i,thb) =
   452   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   453       ([th],_) => th
   454     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   455     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   456 
   457 (*resolution: P==>Q, Q==>R gives P==>R. *)
   458 fun tha RS thb = tha RSN (1,thb);
   459 
   460 (*For joining lists of rules*)
   461 fun thas RLN (i,thbs) =
   462   let val resolve = biresolution false (map (pair false) thas) i
   463       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   464   in  List.concat (map resb thbs)  end;
   465 
   466 fun thas RL thbs = thas RLN (1,thbs);
   467 
   468 (*Resolve a list of rules against bottom_rl from right to left;
   469   makes proof trees*)
   470 fun rls MRS bottom_rl =
   471   let fun rs_aux i [] = bottom_rl
   472         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   473   in  rs_aux 1 rls  end;
   474 
   475 (*As above, but for rule lists*)
   476 fun rlss MRL bottom_rls =
   477   let fun rs_aux i [] = bottom_rls
   478         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   479   in  rs_aux 1 rlss  end;
   480 
   481 (*A version of MRS with more appropriate argument order*)
   482 fun bottom_rl OF rls = rls MRS bottom_rl;
   483 
   484 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   485   with no lifting or renaming!  Q may contain ==> or meta-quants
   486   ALWAYS deletes premise i *)
   487 fun compose(tha,i,thb) =
   488     Seq.list_of (bicompose false (false,tha,0) i thb);
   489 
   490 fun compose_single (tha,i,thb) =
   491   (case compose (tha,i,thb) of
   492     [th] => th
   493   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   494 
   495 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   496 fun tha COMP thb =
   497     case compose(tha,1,thb) of
   498         [th] => th
   499       | _ =>   raise THM("COMP", 1, [tha,thb]);
   500 
   501 
   502 (** theorem equality **)
   503 
   504 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   505 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   506 
   507 (*Useful "distance" function for BEST_FIRST*)
   508 val size_of_thm = size_of_term o prop_of;
   509 
   510 (*maintain lists of theorems --- preserving canonical order*)
   511 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   512 fun add_rules rs rules = rs @ del_rules rs rules;
   513 val del_rule = del_rules o single;
   514 val add_rule = add_rules o single;
   515 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   516 
   517 
   518 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   519     (some) type variable renaming **)
   520 
   521  (* Can't use term_vars, because it sorts the resulting list of variable names.
   522     We instead need the unique list noramlised by the order of appearance
   523     in the term. *)
   524 fun term_vars' (t as Var(v,T)) = [t]
   525   | term_vars' (Abs(_,_,b)) = term_vars' b
   526   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   527   | term_vars' _ = [];
   528 
   529 fun forall_intr_vars th =
   530   let val {prop,sign,...} = rep_thm th;
   531       val vars = distinct (term_vars' prop);
   532   in forall_intr_list (map (cterm_of sign) vars) th end;
   533 
   534 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   535 
   536 
   537 (*** Meta-Rewriting Rules ***)
   538 
   539 fun read_prop s = read_cterm proto_sign (s, propT);
   540 
   541 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   542 fun store_standard_thm name thm = store_thm name (standard thm);
   543 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   544 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   545 
   546 val reflexive_thm =
   547   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   548   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   549 
   550 val symmetric_thm =
   551   let val xy = read_prop "x::'a::logic == y"
   552   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   553 
   554 val transitive_thm =
   555   let val xy = read_prop "x::'a::logic == y"
   556       val yz = read_prop "y::'a::logic == z"
   557       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   558   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   559 
   560 fun symmetric_fun thm = thm RS symmetric_thm;
   561 
   562 fun extensional eq =
   563   let val eq' =
   564     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   565   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   566 
   567 val imp_cong =
   568   let
   569     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   570     val AB = read_prop "PROP A ==> PROP B"
   571     val AC = read_prop "PROP A ==> PROP C"
   572     val A = read_prop "PROP A"
   573   in
   574     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   575       (implies_intr AB (implies_intr A
   576         (equal_elim (implies_elim (assume ABC) (assume A))
   577           (implies_elim (assume AB) (assume A)))))
   578       (implies_intr AC (implies_intr A
   579         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   580           (implies_elim (assume AC) (assume A)))))))
   581   end;
   582 
   583 val swap_prems_eq =
   584   let
   585     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   586     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   587     val A = read_prop "PROP A"
   588     val B = read_prop "PROP B"
   589   in
   590     store_standard_thm_open "swap_prems_eq" (equal_intr
   591       (implies_intr ABC (implies_intr B (implies_intr A
   592         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   593       (implies_intr BAC (implies_intr A (implies_intr B
   594         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   595   end;
   596 
   597 val refl_implies = reflexive implies;
   598 
   599 fun abs_def thm =
   600   let
   601     val (_, cvs) = strip_comb (fst (dest_equals (cprop_of thm)));
   602     val thm' = foldr (fn (ct, thm) => Thm.abstract_rule
   603       (case term_of ct of Var ((a, _), _) => a | Free (a, _) => a | _ => "x")
   604         ct thm) (cvs, thm)
   605   in transitive
   606     (symmetric (eta_conversion (fst (dest_equals (cprop_of thm'))))) thm'
   607   end;
   608 
   609 
   610 (*** Some useful meta-theorems ***)
   611 
   612 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   613 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   614 val _ = store_thm "_" asm_rl;
   615 
   616 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   617 val cut_rl =
   618   store_standard_thm_open "cut_rl"
   619     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   620 
   621 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   622      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   623 val revcut_rl =
   624   let val V = read_prop "PROP V"
   625       and VW = read_prop "PROP V ==> PROP W";
   626   in
   627     store_standard_thm_open "revcut_rl"
   628       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   629   end;
   630 
   631 (*for deleting an unwanted assumption*)
   632 val thin_rl =
   633   let val V = read_prop "PROP V"
   634       and W = read_prop "PROP W";
   635   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   636 
   637 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   638 val triv_forall_equality =
   639   let val V  = read_prop "PROP V"
   640       and QV = read_prop "!!x::'a. PROP V"
   641       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   642   in
   643     store_standard_thm_open "triv_forall_equality"
   644       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   645         (implies_intr V  (forall_intr x (assume V))))
   646   end;
   647 
   648 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   649    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   650    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   651 *)
   652 val swap_prems_rl =
   653   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   654       val major = assume cmajor;
   655       val cminor1 = read_prop "PROP PhiA";
   656       val minor1 = assume cminor1;
   657       val cminor2 = read_prop "PROP PhiB";
   658       val minor2 = assume cminor2;
   659   in store_standard_thm_open "swap_prems_rl"
   660        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   661          (implies_elim (implies_elim major minor1) minor2))))
   662   end;
   663 
   664 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   665    ==> PROP ?phi == PROP ?psi
   666    Introduction rule for == as a meta-theorem.
   667 *)
   668 val equal_intr_rule =
   669   let val PQ = read_prop "PROP phi ==> PROP psi"
   670       and QP = read_prop "PROP psi ==> PROP phi"
   671   in
   672     store_standard_thm_open "equal_intr_rule"
   673       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   674   end;
   675 
   676 (* [| PROP ?phi == PROP ?psi; PROP ?phi |] ==> PROP ?psi *)
   677 val equal_elim_rule1 =
   678   let val eq = read_prop "PROP phi == PROP psi"
   679       and P = read_prop "PROP phi"
   680   in store_standard_thm_open "equal_elim_rule1"
   681     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   682   end;
   683 
   684 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   685 
   686 val remdups_rl =
   687   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   688   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   689 
   690 
   691 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   692   Rewrite rule for HHF normalization.*)
   693 
   694 val norm_hhf_eq =
   695   let
   696     val cert = Thm.cterm_of proto_sign;
   697     val aT = TFree ("'a", Term.logicS);
   698     val all = Term.all aT;
   699     val x = Free ("x", aT);
   700     val phi = Free ("phi", propT);
   701     val psi = Free ("psi", aT --> propT);
   702 
   703     val cx = cert x;
   704     val cphi = cert phi;
   705     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   706     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   707   in
   708     Thm.equal_intr
   709       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   710         |> Thm.forall_elim cx
   711         |> Thm.implies_intr cphi
   712         |> Thm.forall_intr cx
   713         |> Thm.implies_intr lhs)
   714       (Thm.implies_elim
   715           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   716         |> Thm.forall_intr cx
   717         |> Thm.implies_intr cphi
   718         |> Thm.implies_intr rhs)
   719     |> store_standard_thm_open "norm_hhf_eq"
   720   end;
   721 
   722 fun is_norm_hhf tm =
   723   let
   724     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   725       | is_norm (t $ u) = is_norm t andalso is_norm u
   726       | is_norm (Abs (_, _, t)) = is_norm t
   727       | is_norm _ = true;
   728   in is_norm (Pattern.beta_eta_contract tm) end;
   729 
   730 fun norm_hhf sg t =
   731   if is_norm_hhf t then t
   732   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] [] t;
   733 
   734 
   735 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   736 
   737 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   738 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   739 
   740 fun read_instantiate_sg sg sinsts th =
   741     let val ts = types_sorts th;
   742         val used = add_term_tvarnames (prop_of th, []);
   743     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   744 
   745 (*Instantiate theorem th, reading instantiations under theory of th*)
   746 fun read_instantiate sinsts th =
   747     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   748 
   749 
   750 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   751   Instantiates distinct Vars by terms, inferring type instantiations. *)
   752 local
   753   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   754     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   755         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   756         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   757         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   758         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) (tye, maxi) (T, U)
   759           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   760     in  (sign', tye', maxi')  end;
   761 in
   762 fun cterm_instantiate ctpairs0 th =
   763   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   764       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   765                          in (cterm_fun inst ct, cterm_fun inst cu) end
   766       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   767   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   768   handle TERM _ =>
   769            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   770        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   771 end;
   772 
   773 
   774 (** Derived rules mainly for METAHYPS **)
   775 
   776 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   777 fun equal_abs_elim ca eqth =
   778   let val {sign=signa, t=a, ...} = rep_cterm ca
   779       and combth = combination eqth (reflexive ca)
   780       val {sign,prop,...} = rep_thm eqth
   781       val (abst,absu) = Logic.dest_equals prop
   782       val cterm = cterm_of (Sign.merge (sign,signa))
   783   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   784            (transitive combth (beta_conversion false (cterm (absu$a))))
   785   end
   786   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   787 
   788 (*Calling equal_abs_elim with multiple terms*)
   789 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   790 
   791 local
   792   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   793   fun err th = raise THM("flexpair_inst: ", 0, [th])
   794   fun flexpair_inst def th =
   795     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   796         val cterm = cterm_of sign
   797         fun cvar a = cterm(Var((a,0),alpha))
   798         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   799                    def
   800     in  equal_elim def' th
   801     end
   802     handle THM _ => err th | Bind => err th
   803 in
   804 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   805 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   806 end;
   807 
   808 (*Version for flexflex pairs -- this supports lifting.*)
   809 fun flexpair_abs_elim_list cts =
   810     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   811 
   812 
   813 (*** Goal (PROP A) <==> PROP A ***)
   814 
   815 local
   816   val cert = Thm.cterm_of proto_sign;
   817   val A = Free ("A", propT);
   818   val G = Logic.mk_goal A;
   819   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   820 in
   821   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   822       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   823   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   824       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   825 end;
   826 
   827 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   828 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   829 
   830 fun implies_intr_goals cprops thm =
   831   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   832   |> implies_intr_list (map mk_cgoal cprops);
   833 
   834 
   835 
   836 (** variations on instantiate **)
   837 
   838 (*shorthand for instantiating just one variable in the current theory*)
   839 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   840 
   841 
   842 (* collect vars in left-to-right order *)
   843 
   844 fun tvars_of_terms ts = rev (foldl Term.add_tvars ([], ts));
   845 fun vars_of_terms ts = rev (foldl Term.add_vars ([], ts));
   846 
   847 fun tvars_of thm = tvars_of_terms [prop_of thm];
   848 fun vars_of thm = vars_of_terms [prop_of thm];
   849 
   850 
   851 (* instantiate by left-to-right occurrence of variables *)
   852 
   853 fun instantiate' cTs cts thm =
   854   let
   855     fun err msg =
   856       raise TYPE ("instantiate': " ^ msg,
   857         mapfilter (apsome Thm.typ_of) cTs,
   858         mapfilter (apsome Thm.term_of) cts);
   859 
   860     fun inst_of (v, ct) =
   861       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   862         handle TYPE (msg, _, _) => err msg;
   863 
   864     fun zip_vars _ [] = []
   865       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   866       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   867       | zip_vars [] _ = err "more instantiations than variables in thm";
   868 
   869     (*instantiate types first!*)
   870     val thm' =
   871       if forall is_none cTs then thm
   872       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   873     in
   874       if forall is_none cts then thm'
   875       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   876     end;
   877 
   878 
   879 (* unvarify(T) *)
   880 
   881 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   882 
   883 fun unvarifyT thm =
   884   let
   885     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   886     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   887   in instantiate' tfrees [] thm end;
   888 
   889 fun unvarify raw_thm =
   890   let
   891     val thm = unvarifyT raw_thm;
   892     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   893     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   894   in instantiate' [] frees thm end;
   895 
   896 
   897 (* tvars_intr_list *)
   898 
   899 fun tfrees_of thm =
   900   let val {hyps, prop, ...} = Thm.rep_thm thm
   901   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   902 
   903 fun tvars_intr_list tfrees thm =
   904   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   905 
   906 
   907 (* increment var indexes *)
   908 
   909 fun incr_indexes_wrt is cTs cts thms =
   910   let
   911     val maxidx =
   912       foldl Int.max (~1, is @
   913         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   914         map (#maxidx o Thm.rep_cterm) cts @
   915         map (#maxidx o Thm.rep_thm) thms);
   916   in Thm.incr_indexes (maxidx + 1) end;
   917 
   918 
   919 (* freeze_all *)
   920 
   921 (*freeze all (T)Vars; assumes thm in standard form*)
   922 
   923 fun freeze_all_TVars thm =
   924   (case tvars_of thm of
   925     [] => thm
   926   | tvars =>
   927       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   928       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   929 
   930 fun freeze_all_Vars thm =
   931   (case vars_of thm of
   932     [] => thm
   933   | vars =>
   934       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   935       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   936 
   937 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   938 
   939 
   940 (* mk_triv_goal *)
   941 
   942 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   943 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   944 
   945 
   946 
   947 (** meta-level conjunction **)
   948 
   949 local
   950   val A = read_prop "PROP A";
   951   val B = read_prop "PROP B";
   952   val C = read_prop "PROP C";
   953   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   954 
   955   val proj1 =
   956     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   957     |> forall_elim_vars 0;
   958 
   959   val proj2 =
   960     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   961     |> forall_elim_vars 0;
   962 
   963   val conj_intr_rule =
   964     forall_intr_list [A, B] (implies_intr_list [A, B]
   965       (Thm.forall_intr C (Thm.implies_intr ABC
   966         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   967     |> forall_elim_vars 0;
   968 
   969   val incr = incr_indexes_wrt [] [] [];
   970 in
   971 
   972 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   973 
   974 fun conj_intr_list [] = asm_rl
   975   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
   976 
   977 fun conj_elim th =
   978   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
   979   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
   980 
   981 fun conj_elim_list th =
   982   let val (th1, th2) = conj_elim th
   983   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
   984 
   985 fun conj_elim_precise 0 _ = []
   986   | conj_elim_precise 1 th = [th]
   987   | conj_elim_precise n th =
   988       let val (th1, th2) = conj_elim th
   989       in th1 :: conj_elim_precise (n - 1) th2 end;
   990 
   991 val conj_intr_thm = store_standard_thm_open "conjunctionI"
   992   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
   993 
   994 end;
   995 
   996 end;
   997 
   998 structure BasicDrule: BASIC_DRULE = Drule;
   999 open BasicDrule;