src/HOL/Library/Multiset.thy
author haftmann
Sat Jul 05 16:04:23 2014 +0200 (2014-07-05)
changeset 57518 2f640245fc6d
parent 57514 bdc2c6b40bf2
child 57966 6fab7e95587d
permissions -rw-r--r--
refrain from auxiliary abbreviation: be more explicit to the reader in situations where syntax translation does not apply;
uniform appearance of xsymbol and HTML output for sums
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4 *)
     5 
     6 header {* (Finite) multisets *}
     7 
     8 theory Multiset
     9 imports Main
    10 begin
    11 
    12 subsection {* The type of multisets *}
    13 
    14 definition "multiset = {f :: 'a => nat. finite {x. f x > 0}}"
    15 
    16 typedef 'a multiset = "multiset :: ('a => nat) set"
    17   morphisms count Abs_multiset
    18   unfolding multiset_def
    19 proof
    20   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    21 qed
    22 
    23 setup_lifting type_definition_multiset
    24 
    25 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    26   "a :# M == 0 < count M a"
    27 
    28 notation (xsymbols)
    29   Melem (infix "\<in>#" 50)
    30 
    31 lemma multiset_eq_iff:
    32   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    33   by (simp only: count_inject [symmetric] fun_eq_iff)
    34 
    35 lemma multiset_eqI:
    36   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    37   using multiset_eq_iff by auto
    38 
    39 text {*
    40  \medskip Preservation of the representing set @{term multiset}.
    41 *}
    42 
    43 lemma const0_in_multiset:
    44   "(\<lambda>a. 0) \<in> multiset"
    45   by (simp add: multiset_def)
    46 
    47 lemma only1_in_multiset:
    48   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma union_preserves_multiset:
    52   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    53   by (simp add: multiset_def)
    54 
    55 lemma diff_preserves_multiset:
    56   assumes "M \<in> multiset"
    57   shows "(\<lambda>a. M a - N a) \<in> multiset"
    58 proof -
    59   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    60     by auto
    61   with assms show ?thesis
    62     by (auto simp add: multiset_def intro: finite_subset)
    63 qed
    64 
    65 lemma filter_preserves_multiset:
    66   assumes "M \<in> multiset"
    67   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    68 proof -
    69   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    70     by auto
    71   with assms show ?thesis
    72     by (auto simp add: multiset_def intro: finite_subset)
    73 qed
    74 
    75 lemmas in_multiset = const0_in_multiset only1_in_multiset
    76   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    77 
    78 
    79 subsection {* Representing multisets *}
    80 
    81 text {* Multiset enumeration *}
    82 
    83 instantiation multiset :: (type) cancel_comm_monoid_add
    84 begin
    85 
    86 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    87 by (rule const0_in_multiset)
    88 
    89 abbreviation Mempty :: "'a multiset" ("{#}") where
    90   "Mempty \<equiv> 0"
    91 
    92 lift_definition plus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    93 by (rule union_preserves_multiset)
    94 
    95 instance
    96 by default (transfer, simp add: fun_eq_iff)+
    97 
    98 end
    99 
   100 lift_definition single :: "'a => 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   101 by (rule only1_in_multiset)
   102 
   103 syntax
   104   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
   105 translations
   106   "{#x, xs#}" == "{#x#} + {#xs#}"
   107   "{#x#}" == "CONST single x"
   108 
   109 lemma count_empty [simp]: "count {#} a = 0"
   110   by (simp add: zero_multiset.rep_eq)
   111 
   112 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   113   by (simp add: single.rep_eq)
   114 
   115 
   116 subsection {* Basic operations *}
   117 
   118 subsubsection {* Union *}
   119 
   120 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   121   by (simp add: plus_multiset.rep_eq)
   122 
   123 
   124 subsubsection {* Difference *}
   125 
   126 instantiation multiset :: (type) comm_monoid_diff
   127 begin
   128 
   129 lift_definition minus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
   130 by (rule diff_preserves_multiset)
   131  
   132 instance
   133 by default (transfer, simp add: fun_eq_iff)+
   134 
   135 end
   136 
   137 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   138   by (simp add: minus_multiset.rep_eq)
   139 
   140 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   141   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   142 
   143 lemma diff_cancel[simp]: "A - A = {#}"
   144   by (fact Groups.diff_cancel)
   145 
   146 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   147   by (fact add_diff_cancel_right')
   148 
   149 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   150   by (fact add_diff_cancel_left')
   151 
   152 lemma diff_right_commute:
   153   "(M::'a multiset) - N - Q = M - Q - N"
   154   by (fact diff_right_commute)
   155 
   156 lemma diff_add:
   157   "(M::'a multiset) - (N + Q) = M - N - Q"
   158   by (rule sym) (fact diff_diff_add)
   159   
   160 lemma insert_DiffM:
   161   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   162   by (clarsimp simp: multiset_eq_iff)
   163 
   164 lemma insert_DiffM2 [simp]:
   165   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   166   by (clarsimp simp: multiset_eq_iff)
   167 
   168 lemma diff_union_swap:
   169   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   170   by (auto simp add: multiset_eq_iff)
   171 
   172 lemma diff_union_single_conv:
   173   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   174   by (simp add: multiset_eq_iff)
   175 
   176 
   177 subsubsection {* Equality of multisets *}
   178 
   179 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   180   by (simp add: multiset_eq_iff)
   181 
   182 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   183   by (auto simp add: multiset_eq_iff)
   184 
   185 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   192   by (auto simp add: multiset_eq_iff)
   193 
   194 lemma diff_single_trivial:
   195   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   196   by (auto simp add: multiset_eq_iff)
   197 
   198 lemma diff_single_eq_union:
   199   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   200   by auto
   201 
   202 lemma union_single_eq_diff:
   203   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   204   by (auto dest: sym)
   205 
   206 lemma union_single_eq_member:
   207   "M + {#x#} = N \<Longrightarrow> x \<in># N"
   208   by auto
   209 
   210 lemma union_is_single:
   211   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")
   212 proof
   213   assume ?rhs then show ?lhs by auto
   214 next
   215   assume ?lhs then show ?rhs
   216     by (simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
   217 qed
   218 
   219 lemma single_is_union:
   220   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   221   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   222 
   223 lemma add_eq_conv_diff:
   224   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
   225 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   226 proof
   227   assume ?rhs then show ?lhs
   228   by (auto simp add: add.assoc add.commute [of "{#b#}"])
   229     (drule sym, simp add: add.assoc [symmetric])
   230 next
   231   assume ?lhs
   232   show ?rhs
   233   proof (cases "a = b")
   234     case True with `?lhs` show ?thesis by simp
   235   next
   236     case False
   237     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   238     with False have "a \<in># N" by auto
   239     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   240     moreover note False
   241     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   242   qed
   243 qed
   244 
   245 lemma insert_noteq_member: 
   246   assumes BC: "B + {#b#} = C + {#c#}"
   247    and bnotc: "b \<noteq> c"
   248   shows "c \<in># B"
   249 proof -
   250   have "c \<in># C + {#c#}" by simp
   251   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   252   then have "c \<in># B + {#b#}" using BC by simp
   253   then show "c \<in># B" using nc by simp
   254 qed
   255 
   256 lemma add_eq_conv_ex:
   257   "(M + {#a#} = N + {#b#}) =
   258     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   259   by (auto simp add: add_eq_conv_diff)
   260 
   261 lemma multi_member_split:
   262   "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   263   by (rule_tac x = "M - {#x#}" in exI, simp)
   264 
   265 
   266 subsubsection {* Pointwise ordering induced by count *}
   267 
   268 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
   269 begin
   270 
   271 lift_definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" is "\<lambda> A B. (\<forall>a. A a \<le> B a)" .
   272 
   273 lemmas mset_le_def = less_eq_multiset_def
   274 
   275 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   276   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
   277 
   278 instance
   279   by default (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
   280 
   281 end
   282 
   283 lemma mset_less_eqI:
   284   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
   285   by (simp add: mset_le_def)
   286 
   287 lemma mset_le_exists_conv:
   288   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
   289 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   290 apply (auto intro: multiset_eq_iff [THEN iffD2])
   291 done
   292 
   293 instance multiset :: (type) ordered_cancel_comm_monoid_diff
   294   by default (simp, fact mset_le_exists_conv)
   295 
   296 lemma mset_le_mono_add_right_cancel [simp]:
   297   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
   298   by (fact add_le_cancel_right)
   299 
   300 lemma mset_le_mono_add_left_cancel [simp]:
   301   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
   302   by (fact add_le_cancel_left)
   303 
   304 lemma mset_le_mono_add:
   305   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
   306   by (fact add_mono)
   307 
   308 lemma mset_le_add_left [simp]:
   309   "(A::'a multiset) \<le> A + B"
   310   unfolding mset_le_def by auto
   311 
   312 lemma mset_le_add_right [simp]:
   313   "B \<le> (A::'a multiset) + B"
   314   unfolding mset_le_def by auto
   315 
   316 lemma mset_le_single:
   317   "a :# B \<Longrightarrow> {#a#} \<le> B"
   318   by (simp add: mset_le_def)
   319 
   320 lemma multiset_diff_union_assoc:
   321   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
   322   by (simp add: multiset_eq_iff mset_le_def)
   323 
   324 lemma mset_le_multiset_union_diff_commute:
   325   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
   326 by (simp add: multiset_eq_iff mset_le_def)
   327 
   328 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
   329 by(simp add: mset_le_def)
   330 
   331 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   332 apply (clarsimp simp: mset_le_def mset_less_def)
   333 apply (erule_tac x=x in allE)
   334 apply auto
   335 done
   336 
   337 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   338 apply (clarsimp simp: mset_le_def mset_less_def)
   339 apply (erule_tac x = x in allE)
   340 apply auto
   341 done
   342   
   343 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
   344 apply (rule conjI)
   345  apply (simp add: mset_lessD)
   346 apply (clarsimp simp: mset_le_def mset_less_def)
   347 apply safe
   348  apply (erule_tac x = a in allE)
   349  apply (auto split: split_if_asm)
   350 done
   351 
   352 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
   353 apply (rule conjI)
   354  apply (simp add: mset_leD)
   355 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
   356 done
   357 
   358 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
   359   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
   360 
   361 lemma empty_le[simp]: "{#} \<le> A"
   362   unfolding mset_le_exists_conv by auto
   363 
   364 lemma le_empty[simp]: "(M \<le> {#}) = (M = {#})"
   365   unfolding mset_le_exists_conv by auto
   366 
   367 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
   368   by (auto simp: mset_le_def mset_less_def)
   369 
   370 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
   371   by simp
   372 
   373 lemma mset_less_add_bothsides:
   374   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
   375   by (fact add_less_imp_less_right)
   376 
   377 lemma mset_less_empty_nonempty:
   378   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
   379   by (auto simp: mset_le_def mset_less_def)
   380 
   381 lemma mset_less_diff_self:
   382   "c \<in># B \<Longrightarrow> B - {#c#} < B"
   383   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
   384 
   385 
   386 subsubsection {* Intersection *}
   387 
   388 instantiation multiset :: (type) semilattice_inf
   389 begin
   390 
   391 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   392   multiset_inter_def: "inf_multiset A B = A - (A - B)"
   393 
   394 instance
   395 proof -
   396   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
   397   show "OFCLASS('a multiset, semilattice_inf_class)"
   398     by default (auto simp add: multiset_inter_def mset_le_def aux)
   399 qed
   400 
   401 end
   402 
   403 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   404   "multiset_inter \<equiv> inf"
   405 
   406 lemma multiset_inter_count [simp]:
   407   "count (A #\<inter> B) x = min (count A x) (count B x)"
   408   by (simp add: multiset_inter_def)
   409 
   410 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   411   by (rule multiset_eqI) auto
   412 
   413 lemma multiset_union_diff_commute:
   414   assumes "B #\<inter> C = {#}"
   415   shows "A + B - C = A - C + B"
   416 proof (rule multiset_eqI)
   417   fix x
   418   from assms have "min (count B x) (count C x) = 0"
   419     by (auto simp add: multiset_eq_iff)
   420   then have "count B x = 0 \<or> count C x = 0"
   421     by auto
   422   then show "count (A + B - C) x = count (A - C + B) x"
   423     by auto
   424 qed
   425 
   426 lemma empty_inter [simp]:
   427   "{#} #\<inter> M = {#}"
   428   by (simp add: multiset_eq_iff)
   429 
   430 lemma inter_empty [simp]:
   431   "M #\<inter> {#} = {#}"
   432   by (simp add: multiset_eq_iff)
   433 
   434 lemma inter_add_left1:
   435   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   436   by (simp add: multiset_eq_iff)
   437 
   438 lemma inter_add_left2:
   439   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   440   by (simp add: multiset_eq_iff)
   441 
   442 lemma inter_add_right1:
   443   "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   444   by (simp add: multiset_eq_iff)
   445 
   446 lemma inter_add_right2:
   447   "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   448   by (simp add: multiset_eq_iff)
   449 
   450 
   451 subsubsection {* Bounded union *}
   452 
   453 instantiation multiset :: (type) semilattice_sup
   454 begin
   455 
   456 definition sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   457   "sup_multiset A B = A + (B - A)"
   458 
   459 instance
   460 proof -
   461   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" by arith
   462   show "OFCLASS('a multiset, semilattice_sup_class)"
   463     by default (auto simp add: sup_multiset_def mset_le_def aux)
   464 qed
   465 
   466 end
   467 
   468 abbreviation sup_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<union>" 70) where
   469   "sup_multiset \<equiv> sup"
   470 
   471 lemma sup_multiset_count [simp]:
   472   "count (A #\<union> B) x = max (count A x) (count B x)"
   473   by (simp add: sup_multiset_def)
   474 
   475 lemma empty_sup [simp]:
   476   "{#} #\<union> M = M"
   477   by (simp add: multiset_eq_iff)
   478 
   479 lemma sup_empty [simp]:
   480   "M #\<union> {#} = M"
   481   by (simp add: multiset_eq_iff)
   482 
   483 lemma sup_add_left1:
   484   "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   485   by (simp add: multiset_eq_iff)
   486 
   487 lemma sup_add_left2:
   488   "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   489   by (simp add: multiset_eq_iff)
   490 
   491 lemma sup_add_right1:
   492   "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   493   by (simp add: multiset_eq_iff)
   494 
   495 lemma sup_add_right2:
   496   "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   497   by (simp add: multiset_eq_iff)
   498 
   499 
   500 subsubsection {* Filter (with comprehension syntax) *}
   501 
   502 text {* Multiset comprehension *}
   503 
   504 lift_definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   505 by (rule filter_preserves_multiset)
   506 
   507 hide_const (open) filter
   508 
   509 lemma count_filter [simp]:
   510   "count (Multiset.filter P M) a = (if P a then count M a else 0)"
   511   by (simp add: filter.rep_eq)
   512 
   513 lemma filter_empty [simp]:
   514   "Multiset.filter P {#} = {#}"
   515   by (rule multiset_eqI) simp
   516 
   517 lemma filter_single [simp]:
   518   "Multiset.filter P {#x#} = (if P x then {#x#} else {#})"
   519   by (rule multiset_eqI) simp
   520 
   521 lemma filter_union [simp]:
   522   "Multiset.filter P (M + N) = Multiset.filter P M + Multiset.filter P N"
   523   by (rule multiset_eqI) simp
   524 
   525 lemma filter_diff [simp]:
   526   "Multiset.filter P (M - N) = Multiset.filter P M - Multiset.filter P N"
   527   by (rule multiset_eqI) simp
   528 
   529 lemma filter_inter [simp]:
   530   "Multiset.filter P (M #\<inter> N) = Multiset.filter P M #\<inter> Multiset.filter P N"
   531   by (rule multiset_eqI) simp
   532 
   533 syntax
   534   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   535 syntax (xsymbol)
   536   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   537 translations
   538   "{#x \<in># M. P#}" == "CONST Multiset.filter (\<lambda>x. P) M"
   539 
   540 
   541 subsubsection {* Set of elements *}
   542 
   543 definition set_of :: "'a multiset => 'a set" where
   544   "set_of M = {x. x :# M}"
   545 
   546 lemma set_of_empty [simp]: "set_of {#} = {}"
   547 by (simp add: set_of_def)
   548 
   549 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   550 by (simp add: set_of_def)
   551 
   552 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   553 by (auto simp add: set_of_def)
   554 
   555 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   556 by (auto simp add: set_of_def multiset_eq_iff)
   557 
   558 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   559 by (auto simp add: set_of_def)
   560 
   561 lemma set_of_filter [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   562 by (auto simp add: set_of_def)
   563 
   564 lemma finite_set_of [iff]: "finite (set_of M)"
   565   using count [of M] by (simp add: multiset_def set_of_def)
   566 
   567 lemma finite_Collect_mem [iff]: "finite {x. x :# M}"
   568   unfolding set_of_def[symmetric] by simp
   569 
   570 lemma set_of_mono: "A \<le> B \<Longrightarrow> set_of A \<subseteq> set_of B"  
   571   by (metis mset_leD subsetI mem_set_of_iff)
   572 
   573 subsubsection {* Size *}
   574 
   575 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
   576 
   577 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
   578   by (auto simp: wcount_def add_mult_distrib)
   579 
   580 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
   581   "size_multiset f M = setsum (wcount f M) (set_of M)"
   582 
   583 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
   584 
   585 instantiation multiset :: (type) size begin
   586 definition size_multiset where
   587   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
   588 instance ..
   589 end
   590 
   591 lemmas size_multiset_overloaded_eq =
   592   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
   593 
   594 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
   595 by (simp add: size_multiset_def)
   596 
   597 lemma size_empty [simp]: "size {#} = 0"
   598 by (simp add: size_multiset_overloaded_def)
   599 
   600 lemma size_multiset_single [simp]: "size_multiset f {#b#} = Suc (f b)"
   601 by (simp add: size_multiset_eq)
   602 
   603 lemma size_single [simp]: "size {#b#} = 1"
   604 by (simp add: size_multiset_overloaded_def)
   605 
   606 lemma setsum_wcount_Int:
   607   "finite A \<Longrightarrow> setsum (wcount f N) (A \<inter> set_of N) = setsum (wcount f N) A"
   608 apply (induct rule: finite_induct)
   609  apply simp
   610 apply (simp add: Int_insert_left set_of_def wcount_def)
   611 done
   612 
   613 lemma size_multiset_union [simp]:
   614   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
   615 apply (simp add: size_multiset_def setsum_Un_nat setsum.distrib setsum_wcount_Int wcount_union)
   616 apply (subst Int_commute)
   617 apply (simp add: setsum_wcount_Int)
   618 done
   619 
   620 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   621 by (auto simp add: size_multiset_overloaded_def)
   622 
   623 lemma size_multiset_eq_0_iff_empty [iff]: "(size_multiset f M = 0) = (M = {#})"
   624 by (auto simp add: size_multiset_eq multiset_eq_iff)
   625 
   626 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   627 by (auto simp add: size_multiset_overloaded_def)
   628 
   629 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   630 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   631 
   632 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   633 apply (unfold size_multiset_overloaded_eq)
   634 apply (drule setsum_SucD)
   635 apply auto
   636 done
   637 
   638 lemma size_eq_Suc_imp_eq_union:
   639   assumes "size M = Suc n"
   640   shows "\<exists>a N. M = N + {#a#}"
   641 proof -
   642   from assms obtain a where "a \<in># M"
   643     by (erule size_eq_Suc_imp_elem [THEN exE])
   644   then have "M = M - {#a#} + {#a#}" by simp
   645   then show ?thesis by blast
   646 qed
   647 
   648 
   649 subsection {* Induction and case splits *}
   650 
   651 theorem multiset_induct [case_names empty add, induct type: multiset]:
   652   assumes empty: "P {#}"
   653   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   654   shows "P M"
   655 proof (induct n \<equiv> "size M" arbitrary: M)
   656   case 0 thus "P M" by (simp add: empty)
   657 next
   658   case (Suc k)
   659   obtain N x where "M = N + {#x#}"
   660     using `Suc k = size M` [symmetric]
   661     using size_eq_Suc_imp_eq_union by fast
   662   with Suc add show "P M" by simp
   663 qed
   664 
   665 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   666 by (induct M) auto
   667 
   668 lemma multiset_cases [cases type]:
   669   obtains (empty) "M = {#}"
   670     | (add) N x where "M = N + {#x#}"
   671   using assms by (induct M) simp_all
   672 
   673 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   674 by (cases "B = {#}") (auto dest: multi_member_split)
   675 
   676 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   677 apply (subst multiset_eq_iff)
   678 apply auto
   679 done
   680 
   681 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
   682 proof (induct A arbitrary: B)
   683   case (empty M)
   684   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   685   then obtain M' x where "M = M' + {#x#}" 
   686     by (blast dest: multi_nonempty_split)
   687   then show ?case by simp
   688 next
   689   case (add S x T)
   690   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
   691   have SxsubT: "S + {#x#} < T" by fact
   692   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
   693   then obtain T' where T: "T = T' + {#x#}" 
   694     by (blast dest: multi_member_split)
   695   then have "S < T'" using SxsubT 
   696     by (blast intro: mset_less_add_bothsides)
   697   then have "size S < size T'" using IH by simp
   698   then show ?case using T by simp
   699 qed
   700 
   701 
   702 subsubsection {* Strong induction and subset induction for multisets *}
   703 
   704 text {* Well-foundedness of proper subset operator: *}
   705 
   706 text {* proper multiset subset *}
   707 
   708 definition
   709   mset_less_rel :: "('a multiset * 'a multiset) set" where
   710   "mset_less_rel = {(A,B). A < B}"
   711 
   712 lemma multiset_add_sub_el_shuffle: 
   713   assumes "c \<in># B" and "b \<noteq> c" 
   714   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   715 proof -
   716   from `c \<in># B` obtain A where B: "B = A + {#c#}" 
   717     by (blast dest: multi_member_split)
   718   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   719   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}" 
   720     by (simp add: ac_simps)
   721   then show ?thesis using B by simp
   722 qed
   723 
   724 lemma wf_mset_less_rel: "wf mset_less_rel"
   725 apply (unfold mset_less_rel_def)
   726 apply (rule wf_measure [THEN wf_subset, where f1=size])
   727 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   728 done
   729 
   730 text {* The induction rules: *}
   731 
   732 lemma full_multiset_induct [case_names less]:
   733 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
   734 shows "P B"
   735 apply (rule wf_mset_less_rel [THEN wf_induct])
   736 apply (rule ih, auto simp: mset_less_rel_def)
   737 done
   738 
   739 lemma multi_subset_induct [consumes 2, case_names empty add]:
   740 assumes "F \<le> A"
   741   and empty: "P {#}"
   742   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   743 shows "P F"
   744 proof -
   745   from `F \<le> A`
   746   show ?thesis
   747   proof (induct F)
   748     show "P {#}" by fact
   749   next
   750     fix x F
   751     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
   752     show "P (F + {#x#})"
   753     proof (rule insert)
   754       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   755       from i have "F \<le> A" by (auto dest: mset_le_insertD)
   756       with P show "P F" .
   757     qed
   758   qed
   759 qed
   760 
   761 
   762 subsection {* The fold combinator *}
   763 
   764 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   765 where
   766   "fold f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_of M)"
   767 
   768 lemma fold_mset_empty [simp]:
   769   "fold f s {#} = s"
   770   by (simp add: fold_def)
   771 
   772 context comp_fun_commute
   773 begin
   774 
   775 lemma fold_mset_insert:
   776   "fold f s (M + {#x#}) = f x (fold f s M)"
   777 proof -
   778   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   779     by (fact comp_fun_commute_funpow)
   780   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   781     by (fact comp_fun_commute_funpow)
   782   show ?thesis
   783   proof (cases "x \<in> set_of M")
   784     case False
   785     then have *: "count (M + {#x#}) x = 1" by simp
   786     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_of M) =
   787       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_of M)"
   788       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   789     with False * show ?thesis
   790       by (simp add: fold_def del: count_union)
   791   next
   792     case True
   793     def N \<equiv> "set_of M - {x}"
   794     from N_def True have *: "set_of M = insert x N" "x \<notin> N" "finite N" by auto
   795     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   796       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   797       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   798     with * show ?thesis by (simp add: fold_def del: count_union) simp
   799   qed
   800 qed
   801 
   802 corollary fold_mset_single [simp]:
   803   "fold f s {#x#} = f x s"
   804 proof -
   805   have "fold f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   806   then show ?thesis by simp
   807 qed
   808 
   809 lemma fold_mset_fun_left_comm:
   810   "f x (fold f s M) = fold f (f x s) M"
   811   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   812 
   813 lemma fold_mset_union [simp]:
   814   "fold f s (M + N) = fold f (fold f s M) N"
   815 proof (induct M)
   816   case empty then show ?case by simp
   817 next
   818   case (add M x)
   819   have "M + {#x#} + N = (M + N) + {#x#}"
   820     by (simp add: ac_simps)
   821   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   822 qed
   823 
   824 lemma fold_mset_fusion:
   825   assumes "comp_fun_commute g"
   826   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold g w A) = fold f (h w) A" (is "PROP ?P")
   827 proof -
   828   interpret comp_fun_commute g by (fact assms)
   829   show "PROP ?P" by (induct A) auto
   830 qed
   831 
   832 end
   833 
   834 text {*
   835   A note on code generation: When defining some function containing a
   836   subterm @{term "fold F"}, code generation is not automatic. When
   837   interpreting locale @{text left_commutative} with @{text F}, the
   838   would be code thms for @{const fold} become thms like
   839   @{term "fold F z {#} = z"} where @{text F} is not a pattern but
   840   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   841   constant with its own code thms needs to be introduced for @{text
   842   F}. See the image operator below.
   843 *}
   844 
   845 
   846 subsection {* Image *}
   847 
   848 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   849   "image_mset f = fold (plus o single o f) {#}"
   850 
   851 lemma comp_fun_commute_mset_image:
   852   "comp_fun_commute (plus o single o f)"
   853 proof
   854 qed (simp add: ac_simps fun_eq_iff)
   855 
   856 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   857   by (simp add: image_mset_def)
   858 
   859 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   860 proof -
   861   interpret comp_fun_commute "plus o single o f"
   862     by (fact comp_fun_commute_mset_image)
   863   show ?thesis by (simp add: image_mset_def)
   864 qed
   865 
   866 lemma image_mset_union [simp]:
   867   "image_mset f (M + N) = image_mset f M + image_mset f N"
   868 proof -
   869   interpret comp_fun_commute "plus o single o f"
   870     by (fact comp_fun_commute_mset_image)
   871   show ?thesis by (induct N) (simp_all add: image_mset_def ac_simps)
   872 qed
   873 
   874 corollary image_mset_insert:
   875   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   876   by simp
   877 
   878 lemma set_of_image_mset [simp]:
   879   "set_of (image_mset f M) = image f (set_of M)"
   880   by (induct M) simp_all
   881 
   882 lemma size_image_mset [simp]:
   883   "size (image_mset f M) = size M"
   884   by (induct M) simp_all
   885 
   886 lemma image_mset_is_empty_iff [simp]:
   887   "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   888   by (cases M) auto
   889 
   890 syntax
   891   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   892       ("({#_/. _ :# _#})")
   893 translations
   894   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
   895 
   896 syntax
   897   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   898       ("({#_/ | _ :# _./ _#})")
   899 translations
   900   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
   901 
   902 text {*
   903   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
   904   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
   905   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
   906   @{term "{#x+x|x:#M. x<c#}"}.
   907 *}
   908 
   909 functor image_mset: image_mset
   910 proof -
   911   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   912   proof
   913     fix A
   914     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   915       by (induct A) simp_all
   916   qed
   917   show "image_mset id = id"
   918   proof
   919     fix A
   920     show "image_mset id A = id A"
   921       by (induct A) simp_all
   922   qed
   923 qed
   924 
   925 declare image_mset.identity [simp]
   926 
   927 
   928 subsection {* Further conversions *}
   929 
   930 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   931   "multiset_of [] = {#}" |
   932   "multiset_of (a # x) = multiset_of x + {# a #}"
   933 
   934 lemma in_multiset_in_set:
   935   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
   936   by (induct xs) simp_all
   937 
   938 lemma count_multiset_of:
   939   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   940   by (induct xs) simp_all
   941 
   942 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
   943 by (induct x) auto
   944 
   945 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
   946 by (induct x) auto
   947 
   948 lemma set_of_multiset_of[simp]: "set_of (multiset_of x) = set x"
   949 by (induct x) auto
   950 
   951 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
   952 by (induct xs) auto
   953 
   954 lemma size_multiset_of [simp]: "size (multiset_of xs) = length xs"
   955   by (induct xs) simp_all
   956 
   957 lemma multiset_of_append [simp]:
   958   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
   959   by (induct xs arbitrary: ys) (auto simp: ac_simps)
   960 
   961 lemma multiset_of_filter:
   962   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
   963   by (induct xs) simp_all
   964 
   965 lemma multiset_of_rev [simp]:
   966   "multiset_of (rev xs) = multiset_of xs"
   967   by (induct xs) simp_all
   968 
   969 lemma surj_multiset_of: "surj multiset_of"
   970 apply (unfold surj_def)
   971 apply (rule allI)
   972 apply (rule_tac M = y in multiset_induct)
   973  apply auto
   974 apply (rule_tac x = "x # xa" in exI)
   975 apply auto
   976 done
   977 
   978 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
   979 by (induct x) auto
   980 
   981 lemma distinct_count_atmost_1:
   982   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
   983 apply (induct x, simp, rule iffI, simp_all)
   984 apply (rename_tac a b)
   985 apply (rule conjI)
   986 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
   987 apply (erule_tac x = a in allE, simp, clarify)
   988 apply (erule_tac x = aa in allE, simp)
   989 done
   990 
   991 lemma multiset_of_eq_setD:
   992   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
   993 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   994 
   995 lemma set_eq_iff_multiset_of_eq_distinct:
   996   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   997     (set x = set y) = (multiset_of x = multiset_of y)"
   998 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   999 
  1000 lemma set_eq_iff_multiset_of_remdups_eq:
  1001    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
  1002 apply (rule iffI)
  1003 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
  1004 apply (drule distinct_remdups [THEN distinct_remdups
  1005       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
  1006 apply simp
  1007 done
  1008 
  1009 lemma multiset_of_compl_union [simp]:
  1010   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
  1011   by (induct xs) (auto simp: ac_simps)
  1012 
  1013 lemma count_multiset_of_length_filter:
  1014   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
  1015   by (induct xs) auto
  1016 
  1017 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
  1018 apply (induct ls arbitrary: i)
  1019  apply simp
  1020 apply (case_tac i)
  1021  apply auto
  1022 done
  1023 
  1024 lemma multiset_of_remove1[simp]:
  1025   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
  1026 by (induct xs) (auto simp add: multiset_eq_iff)
  1027 
  1028 lemma multiset_of_eq_length:
  1029   assumes "multiset_of xs = multiset_of ys"
  1030   shows "length xs = length ys"
  1031   using assms by (metis size_multiset_of)
  1032 
  1033 lemma multiset_of_eq_length_filter:
  1034   assumes "multiset_of xs = multiset_of ys"
  1035   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1036   using assms by (metis count_multiset_of)
  1037 
  1038 lemma fold_multiset_equiv:
  1039   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1040     and equiv: "multiset_of xs = multiset_of ys"
  1041   shows "List.fold f xs = List.fold f ys"
  1042 using f equiv [symmetric]
  1043 proof (induct xs arbitrary: ys)
  1044   case Nil then show ?case by simp
  1045 next
  1046   case (Cons x xs)
  1047   then have *: "set ys = set (x # xs)" by (blast dest: multiset_of_eq_setD)
  1048   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x" 
  1049     by (rule Cons.prems(1)) (simp_all add: *)
  1050   moreover from * have "x \<in> set ys" by simp
  1051   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x" by (fact fold_remove1_split)
  1052   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)" by (auto intro: Cons.hyps)
  1053   ultimately show ?case by simp
  1054 qed
  1055 
  1056 lemma multiset_of_insort [simp]:
  1057   "multiset_of (insort x xs) = multiset_of xs + {#x#}"
  1058   by (induct xs) (simp_all add: ac_simps)
  1059 
  1060 lemma in_multiset_of:
  1061   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
  1062   by (induct xs) simp_all
  1063 
  1064 lemma multiset_of_map:
  1065   "multiset_of (map f xs) = image_mset f (multiset_of xs)"
  1066   by (induct xs) simp_all
  1067 
  1068 definition multiset_of_set :: "'a set \<Rightarrow> 'a multiset"
  1069 where
  1070   "multiset_of_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
  1071 
  1072 interpretation multiset_of_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
  1073 where
  1074   "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set"
  1075 proof -
  1076   interpret comp_fun_commute "\<lambda>x M. {#x#} + M" by default (simp add: fun_eq_iff ac_simps)
  1077   show "folding (\<lambda>x M. {#x#} + M)" by default (fact comp_fun_commute)
  1078   from multiset_of_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set" ..
  1079 qed
  1080 
  1081 lemma count_multiset_of_set [simp]:
  1082   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (multiset_of_set A) x = 1" (is "PROP ?P")
  1083   "\<not> finite A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?Q")
  1084   "x \<notin> A \<Longrightarrow> count (multiset_of_set A) x = 0" (is "PROP ?R")
  1085 proof -
  1086   { fix A
  1087     assume "x \<notin> A"
  1088     have "count (multiset_of_set A) x = 0"
  1089     proof (cases "finite A")
  1090       case False then show ?thesis by simp
  1091     next
  1092       case True from True `x \<notin> A` show ?thesis by (induct A) auto
  1093     qed
  1094   } note * = this
  1095   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1096   by (auto elim!: Set.set_insert)
  1097 qed -- {* TODO: maybe define @{const multiset_of_set} also in terms of @{const Abs_multiset} *}
  1098 
  1099 context linorder
  1100 begin
  1101 
  1102 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1103 where
  1104   "sorted_list_of_multiset M = fold insort [] M"
  1105 
  1106 lemma sorted_list_of_multiset_empty [simp]:
  1107   "sorted_list_of_multiset {#} = []"
  1108   by (simp add: sorted_list_of_multiset_def)
  1109 
  1110 lemma sorted_list_of_multiset_singleton [simp]:
  1111   "sorted_list_of_multiset {#x#} = [x]"
  1112 proof -
  1113   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1114   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1115 qed
  1116 
  1117 lemma sorted_list_of_multiset_insert [simp]:
  1118   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1119 proof -
  1120   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1121   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1122 qed
  1123 
  1124 end
  1125 
  1126 lemma multiset_of_sorted_list_of_multiset [simp]:
  1127   "multiset_of (sorted_list_of_multiset M) = M"
  1128   by (induct M) simp_all
  1129 
  1130 lemma sorted_list_of_multiset_multiset_of [simp]:
  1131   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  1132   by (induct xs) simp_all
  1133 
  1134 lemma finite_set_of_multiset_of_set:
  1135   assumes "finite A"
  1136   shows "set_of (multiset_of_set A) = A"
  1137   using assms by (induct A) simp_all
  1138 
  1139 lemma infinite_set_of_multiset_of_set:
  1140   assumes "\<not> finite A"
  1141   shows "set_of (multiset_of_set A) = {}"
  1142   using assms by simp
  1143 
  1144 lemma set_sorted_list_of_multiset [simp]:
  1145   "set (sorted_list_of_multiset M) = set_of M"
  1146   by (induct M) (simp_all add: set_insort)
  1147 
  1148 lemma sorted_list_of_multiset_of_set [simp]:
  1149   "sorted_list_of_multiset (multiset_of_set A) = sorted_list_of_set A"
  1150   by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1151 
  1152 
  1153 subsection {* Big operators *}
  1154 
  1155 no_notation times (infixl "*" 70)
  1156 no_notation Groups.one ("1")
  1157 
  1158 locale comm_monoid_mset = comm_monoid
  1159 begin
  1160 
  1161 definition F :: "'a multiset \<Rightarrow> 'a"
  1162 where
  1163   eq_fold: "F M = Multiset.fold f 1 M"
  1164 
  1165 lemma empty [simp]:
  1166   "F {#} = 1"
  1167   by (simp add: eq_fold)
  1168 
  1169 lemma singleton [simp]:
  1170   "F {#x#} = x"
  1171 proof -
  1172   interpret comp_fun_commute
  1173     by default (simp add: fun_eq_iff left_commute)
  1174   show ?thesis by (simp add: eq_fold)
  1175 qed
  1176 
  1177 lemma union [simp]:
  1178   "F (M + N) = F M * F N"
  1179 proof -
  1180   interpret comp_fun_commute f
  1181     by default (simp add: fun_eq_iff left_commute)
  1182   show ?thesis by (induct N) (simp_all add: left_commute eq_fold)
  1183 qed
  1184 
  1185 end
  1186 
  1187 notation times (infixl "*" 70)
  1188 notation Groups.one ("1")
  1189 
  1190 context comm_monoid_add
  1191 begin
  1192 
  1193 definition msetsum :: "'a multiset \<Rightarrow> 'a"
  1194 where
  1195   "msetsum = comm_monoid_mset.F plus 0"
  1196 
  1197 sublocale msetsum!: comm_monoid_mset plus 0
  1198 where
  1199   "comm_monoid_mset.F plus 0 = msetsum"
  1200 proof -
  1201   show "comm_monoid_mset plus 0" ..
  1202   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1203 qed
  1204 
  1205 lemma setsum_unfold_msetsum:
  1206   "setsum f A = msetsum (image_mset f (multiset_of_set A))"
  1207   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1208 
  1209 end
  1210 
  1211 syntax
  1212   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1213       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1214 
  1215 syntax (xsymbols)
  1216   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1217       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1218 
  1219 syntax (HTML output)
  1220   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1221       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1222 
  1223 translations
  1224   "SUM i :# A. b" == "CONST msetsum (CONST image_mset (\<lambda>i. b) A)"
  1225 
  1226 context comm_monoid_mult
  1227 begin
  1228 
  1229 definition msetprod :: "'a multiset \<Rightarrow> 'a"
  1230 where
  1231   "msetprod = comm_monoid_mset.F times 1"
  1232 
  1233 sublocale msetprod!: comm_monoid_mset times 1
  1234 where
  1235   "comm_monoid_mset.F times 1 = msetprod"
  1236 proof -
  1237   show "comm_monoid_mset times 1" ..
  1238   from msetprod_def show "comm_monoid_mset.F times 1 = msetprod" ..
  1239 qed
  1240 
  1241 lemma msetprod_empty:
  1242   "msetprod {#} = 1"
  1243   by (fact msetprod.empty)
  1244 
  1245 lemma msetprod_singleton:
  1246   "msetprod {#x#} = x"
  1247   by (fact msetprod.singleton)
  1248 
  1249 lemma msetprod_Un:
  1250   "msetprod (A + B) = msetprod A * msetprod B" 
  1251   by (fact msetprod.union)
  1252 
  1253 lemma setprod_unfold_msetprod:
  1254   "setprod f A = msetprod (image_mset f (multiset_of_set A))"
  1255   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1256 
  1257 lemma msetprod_multiplicity:
  1258   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_of M)"
  1259   by (simp add: Multiset.fold_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1260 
  1261 end
  1262 
  1263 syntax
  1264   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1265       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1266 
  1267 syntax (xsymbols)
  1268   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1269       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1270 
  1271 syntax (HTML output)
  1272   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1273       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1274 
  1275 translations
  1276   "PROD i :# A. b" == "CONST msetprod (CONST image_mset (\<lambda>i. b) A)"
  1277 
  1278 lemma (in comm_semiring_1) dvd_msetprod:
  1279   assumes "x \<in># A"
  1280   shows "x dvd msetprod A"
  1281 proof -
  1282   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1283   then obtain B where "A = B + {#x#}" ..
  1284   then show ?thesis by simp
  1285 qed
  1286 
  1287 
  1288 subsection {* Cardinality *}
  1289 
  1290 definition mcard :: "'a multiset \<Rightarrow> nat"
  1291 where
  1292   "mcard = msetsum \<circ> image_mset (\<lambda>_. 1)"
  1293 
  1294 lemma mcard_empty [simp]:
  1295   "mcard {#} = 0"
  1296   by (simp add: mcard_def)
  1297 
  1298 lemma mcard_singleton [simp]:
  1299   "mcard {#a#} = Suc 0"
  1300   by (simp add: mcard_def)
  1301 
  1302 lemma mcard_plus [simp]:
  1303   "mcard (M + N) = mcard M + mcard N"
  1304   by (simp add: mcard_def)
  1305 
  1306 lemma mcard_empty_iff [simp]:
  1307   "mcard M = 0 \<longleftrightarrow> M = {#}"
  1308   by (induct M) simp_all
  1309 
  1310 lemma mcard_unfold_setsum:
  1311   "mcard M = setsum (count M) (set_of M)"
  1312 proof (induct M)
  1313   case empty then show ?case by simp
  1314 next
  1315   case (add M x) then show ?case
  1316     by (cases "x \<in> set_of M")
  1317       (simp_all del: mem_set_of_iff add: setsum.distrib setsum.delta' insert_absorb, simp)
  1318 qed
  1319 
  1320 lemma size_eq_mcard:
  1321   "size = mcard"
  1322   by (simp add: fun_eq_iff size_multiset_overloaded_eq mcard_unfold_setsum)
  1323 
  1324 lemma mcard_multiset_of:
  1325   "mcard (multiset_of xs) = length xs"
  1326   by (induct xs) simp_all
  1327 
  1328 
  1329 subsection {* Alternative representations *}
  1330 
  1331 subsubsection {* Lists *}
  1332 
  1333 context linorder
  1334 begin
  1335 
  1336 lemma multiset_of_insort [simp]:
  1337   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
  1338   by (induct xs) (simp_all add: ac_simps)
  1339  
  1340 lemma multiset_of_sort [simp]:
  1341   "multiset_of (sort_key k xs) = multiset_of xs"
  1342   by (induct xs) (simp_all add: ac_simps)
  1343 
  1344 text {*
  1345   This lemma shows which properties suffice to show that a function
  1346   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1347 *}
  1348 
  1349 lemma properties_for_sort_key:
  1350   assumes "multiset_of ys = multiset_of xs"
  1351   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1352   and "sorted (map f ys)"
  1353   shows "sort_key f xs = ys"
  1354 using assms
  1355 proof (induct xs arbitrary: ys)
  1356   case Nil then show ?case by simp
  1357 next
  1358   case (Cons x xs)
  1359   from Cons.prems(2) have
  1360     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1361     by (simp add: filter_remove1)
  1362   with Cons.prems have "sort_key f xs = remove1 x ys"
  1363     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1364   moreover from Cons.prems have "x \<in> set ys"
  1365     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1366   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1367 qed
  1368 
  1369 lemma properties_for_sort:
  1370   assumes multiset: "multiset_of ys = multiset_of xs"
  1371   and "sorted ys"
  1372   shows "sort xs = ys"
  1373 proof (rule properties_for_sort_key)
  1374   from multiset show "multiset_of ys = multiset_of xs" .
  1375   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
  1376   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
  1377     by (rule multiset_of_eq_length_filter)
  1378   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
  1379     by simp
  1380   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
  1381     by (simp add: replicate_length_filter)
  1382 qed
  1383 
  1384 lemma sort_key_by_quicksort:
  1385   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1386     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1387     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1388 proof (rule properties_for_sort_key)
  1389   show "multiset_of ?rhs = multiset_of ?lhs"
  1390     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
  1391 next
  1392   show "sorted (map f ?rhs)"
  1393     by (auto simp add: sorted_append intro: sorted_map_same)
  1394 next
  1395   fix l
  1396   assume "l \<in> set ?rhs"
  1397   let ?pivot = "f (xs ! (length xs div 2))"
  1398   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1399   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1400     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1401   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1402   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1403   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1404     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1405   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1406   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1407   proof (cases "f l" ?pivot rule: linorder_cases)
  1408     case less
  1409     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1410     with less show ?thesis
  1411       by (simp add: filter_sort [symmetric] ** ***)
  1412   next
  1413     case equal then show ?thesis
  1414       by (simp add: * less_le)
  1415   next
  1416     case greater
  1417     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1418     with greater show ?thesis
  1419       by (simp add: filter_sort [symmetric] ** ***)
  1420   qed
  1421 qed
  1422 
  1423 lemma sort_by_quicksort:
  1424   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1425     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1426     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1427   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1428 
  1429 text {* A stable parametrized quicksort *}
  1430 
  1431 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1432   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1433 
  1434 lemma part_code [code]:
  1435   "part f pivot [] = ([], [], [])"
  1436   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1437      if x' < pivot then (x # lts, eqs, gts)
  1438      else if x' > pivot then (lts, eqs, x # gts)
  1439      else (lts, x # eqs, gts))"
  1440   by (auto simp add: part_def Let_def split_def)
  1441 
  1442 lemma sort_key_by_quicksort_code [code]:
  1443   "sort_key f xs = (case xs of [] \<Rightarrow> []
  1444     | [x] \<Rightarrow> xs
  1445     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1446     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1447        in sort_key f lts @ eqs @ sort_key f gts))"
  1448 proof (cases xs)
  1449   case Nil then show ?thesis by simp
  1450 next
  1451   case (Cons _ ys) note hyps = Cons show ?thesis
  1452   proof (cases ys)
  1453     case Nil with hyps show ?thesis by simp
  1454   next
  1455     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1456     proof (cases zs)
  1457       case Nil with hyps show ?thesis by auto
  1458     next
  1459       case Cons 
  1460       from sort_key_by_quicksort [of f xs]
  1461       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1462         in sort_key f lts @ eqs @ sort_key f gts)"
  1463       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1464       with hyps Cons show ?thesis by (simp only: list.cases)
  1465     qed
  1466   qed
  1467 qed
  1468 
  1469 end
  1470 
  1471 hide_const (open) part
  1472 
  1473 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
  1474   by (induct xs) (auto intro: order_trans)
  1475 
  1476 lemma multiset_of_update:
  1477   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
  1478 proof (induct ls arbitrary: i)
  1479   case Nil then show ?case by simp
  1480 next
  1481   case (Cons x xs)
  1482   show ?case
  1483   proof (cases i)
  1484     case 0 then show ?thesis by simp
  1485   next
  1486     case (Suc i')
  1487     with Cons show ?thesis
  1488       apply simp
  1489       apply (subst add.assoc)
  1490       apply (subst add.commute [of "{#v#}" "{#x#}"])
  1491       apply (subst add.assoc [symmetric])
  1492       apply simp
  1493       apply (rule mset_le_multiset_union_diff_commute)
  1494       apply (simp add: mset_le_single nth_mem_multiset_of)
  1495       done
  1496   qed
  1497 qed
  1498 
  1499 lemma multiset_of_swap:
  1500   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1501     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
  1502   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
  1503 
  1504 
  1505 subsection {* The multiset order *}
  1506 
  1507 subsubsection {* Well-foundedness *}
  1508 
  1509 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1510   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1511       (\<forall>b. b :# K --> (b, a) \<in> r)}"
  1512 
  1513 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1514   "mult r = (mult1 r)\<^sup>+"
  1515 
  1516 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1517 by (simp add: mult1_def)
  1518 
  1519 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
  1520     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1521     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
  1522   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
  1523 proof (unfold mult1_def)
  1524   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
  1525   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1526   let ?case1 = "?case1 {(N, M). ?R N M}"
  1527 
  1528   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
  1529   then have "\<exists>a' M0' K.
  1530       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
  1531   then show "?case1 \<or> ?case2"
  1532   proof (elim exE conjE)
  1533     fix a' M0' K
  1534     assume N: "N = M0' + K" and r: "?r K a'"
  1535     assume "M0 + {#a#} = M0' + {#a'#}"
  1536     then have "M0 = M0' \<and> a = a' \<or>
  1537         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
  1538       by (simp only: add_eq_conv_ex)
  1539     then show ?thesis
  1540     proof (elim disjE conjE exE)
  1541       assume "M0 = M0'" "a = a'"
  1542       with N r have "?r K a \<and> N = M0 + K" by simp
  1543       then have ?case2 .. then show ?thesis ..
  1544     next
  1545       fix K'
  1546       assume "M0' = K' + {#a#}"
  1547       with N have n: "N = K' + K + {#a#}" by (simp add: ac_simps)
  1548 
  1549       assume "M0 = K' + {#a'#}"
  1550       with r have "?R (K' + K) M0" by blast
  1551       with n have ?case1 by simp then show ?thesis ..
  1552     qed
  1553   qed
  1554 qed
  1555 
  1556 lemma all_accessible: "wf r ==> \<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1557 proof
  1558   let ?R = "mult1 r"
  1559   let ?W = "Wellfounded.acc ?R"
  1560   {
  1561     fix M M0 a
  1562     assume M0: "M0 \<in> ?W"
  1563       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1564       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
  1565     have "M0 + {#a#} \<in> ?W"
  1566     proof (rule accI [of "M0 + {#a#}"])
  1567       fix N
  1568       assume "(N, M0 + {#a#}) \<in> ?R"
  1569       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
  1570           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
  1571         by (rule less_add)
  1572       then show "N \<in> ?W"
  1573       proof (elim exE disjE conjE)
  1574         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
  1575         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
  1576         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
  1577         then show "N \<in> ?W" by (simp only: N)
  1578       next
  1579         fix K
  1580         assume N: "N = M0 + K"
  1581         assume "\<forall>b. b :# K --> (b, a) \<in> r"
  1582         then have "M0 + K \<in> ?W"
  1583         proof (induct K)
  1584           case empty
  1585           from M0 show "M0 + {#} \<in> ?W" by simp
  1586         next
  1587           case (add K x)
  1588           from add.prems have "(x, a) \<in> r" by simp
  1589           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1590           moreover from add have "M0 + K \<in> ?W" by simp
  1591           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1592           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add.assoc)
  1593         qed
  1594         then show "N \<in> ?W" by (simp only: N)
  1595       qed
  1596     qed
  1597   } note tedious_reasoning = this
  1598 
  1599   assume wf: "wf r"
  1600   fix M
  1601   show "M \<in> ?W"
  1602   proof (induct M)
  1603     show "{#} \<in> ?W"
  1604     proof (rule accI)
  1605       fix b assume "(b, {#}) \<in> ?R"
  1606       with not_less_empty show "b \<in> ?W" by contradiction
  1607     qed
  1608 
  1609     fix M a assume "M \<in> ?W"
  1610     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1611     proof induct
  1612       fix a
  1613       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1614       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1615       proof
  1616         fix M assume "M \<in> ?W"
  1617         then show "M + {#a#} \<in> ?W"
  1618           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1619       qed
  1620     qed
  1621     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
  1622   qed
  1623 qed
  1624 
  1625 theorem wf_mult1: "wf r ==> wf (mult1 r)"
  1626 by (rule acc_wfI) (rule all_accessible)
  1627 
  1628 theorem wf_mult: "wf r ==> wf (mult r)"
  1629 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1630 
  1631 
  1632 subsubsection {* Closure-free presentation *}
  1633 
  1634 text {* One direction. *}
  1635 
  1636 lemma mult_implies_one_step:
  1637   "trans r ==> (M, N) \<in> mult r ==>
  1638     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1639     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
  1640 apply (unfold mult_def mult1_def set_of_def)
  1641 apply (erule converse_trancl_induct, clarify)
  1642  apply (rule_tac x = M0 in exI, simp, clarify)
  1643 apply (case_tac "a :# K")
  1644  apply (rule_tac x = I in exI)
  1645  apply (simp (no_asm))
  1646  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1647  apply (simp (no_asm_simp) add: add.assoc [symmetric])
  1648  apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="?S + ?T" in arg_cong)
  1649  apply (simp add: diff_union_single_conv)
  1650  apply (simp (no_asm_use) add: trans_def)
  1651  apply blast
  1652 apply (subgoal_tac "a :# I")
  1653  apply (rule_tac x = "I - {#a#}" in exI)
  1654  apply (rule_tac x = "J + {#a#}" in exI)
  1655  apply (rule_tac x = "K + Ka" in exI)
  1656  apply (rule conjI)
  1657   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1658  apply (rule conjI)
  1659   apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="?S + ?T" in arg_cong, simp)
  1660   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1661  apply (simp (no_asm_use) add: trans_def)
  1662  apply blast
  1663 apply (subgoal_tac "a :# (M0 + {#a#})")
  1664  apply simp
  1665 apply (simp (no_asm))
  1666 done
  1667 
  1668 lemma one_step_implies_mult_aux:
  1669   "trans r ==>
  1670     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
  1671       --> (I + K, I + J) \<in> mult r"
  1672 apply (induct_tac n, auto)
  1673 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1674 apply (rename_tac "J'", simp)
  1675 apply (erule notE, auto)
  1676 apply (case_tac "J' = {#}")
  1677  apply (simp add: mult_def)
  1678  apply (rule r_into_trancl)
  1679  apply (simp add: mult1_def set_of_def, blast)
  1680 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
  1681 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1682 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
  1683 apply (erule ssubst)
  1684 apply (simp add: Ball_def, auto)
  1685 apply (subgoal_tac
  1686   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
  1687     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
  1688  prefer 2
  1689  apply force
  1690 apply (simp (no_asm_use) add: add.assoc [symmetric] mult_def)
  1691 apply (erule trancl_trans)
  1692 apply (rule r_into_trancl)
  1693 apply (simp add: mult1_def set_of_def)
  1694 apply (rule_tac x = a in exI)
  1695 apply (rule_tac x = "I + J'" in exI)
  1696 apply (simp add: ac_simps)
  1697 done
  1698 
  1699 lemma one_step_implies_mult:
  1700   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
  1701     ==> (I + K, I + J) \<in> mult r"
  1702 using one_step_implies_mult_aux by blast
  1703 
  1704 
  1705 subsubsection {* Partial-order properties *}
  1706 
  1707 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
  1708   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1709 
  1710 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
  1711   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
  1712 
  1713 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
  1714 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
  1715 
  1716 interpretation multiset_order: order le_multiset less_multiset
  1717 proof -
  1718   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
  1719   proof
  1720     fix M :: "'a multiset"
  1721     assume "M \<subset># M"
  1722     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1723     have "trans {(x'::'a, x). x' < x}"
  1724       by (rule transI) simp
  1725     moreover note MM
  1726     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1727       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
  1728       by (rule mult_implies_one_step)
  1729     then obtain I J K where "M = I + J" and "M = I + K"
  1730       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
  1731     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
  1732     have "finite (set_of K)" by simp
  1733     moreover note aux2
  1734     ultimately have "set_of K = {}"
  1735       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1736     with aux1 show False by simp
  1737   qed
  1738   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
  1739     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1740   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1741     by default (auto simp add: le_multiset_def irrefl dest: trans)
  1742 qed
  1743 
  1744 lemma mult_less_irrefl [elim!]: "M \<subset># (M::'a::order multiset) ==> R"
  1745   by simp
  1746 
  1747 
  1748 subsubsection {* Monotonicity of multiset union *}
  1749 
  1750 lemma mult1_union: "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
  1751 apply (unfold mult1_def)
  1752 apply auto
  1753 apply (rule_tac x = a in exI)
  1754 apply (rule_tac x = "C + M0" in exI)
  1755 apply (simp add: add.assoc)
  1756 done
  1757 
  1758 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
  1759 apply (unfold less_multiset_def mult_def)
  1760 apply (erule trancl_induct)
  1761  apply (blast intro: mult1_union)
  1762 apply (blast intro: mult1_union trancl_trans)
  1763 done
  1764 
  1765 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
  1766 apply (subst add.commute [of B C])
  1767 apply (subst add.commute [of D C])
  1768 apply (erule union_less_mono2)
  1769 done
  1770 
  1771 lemma union_less_mono:
  1772   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
  1773   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1774 
  1775 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1776 proof
  1777 qed (auto simp add: le_multiset_def intro: union_less_mono2)
  1778 
  1779 
  1780 subsection {* Termination proofs with multiset orders *}
  1781 
  1782 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1783   and multi_member_this: "x \<in># {# x #} + XS"
  1784   and multi_member_last: "x \<in># {# x #}"
  1785   by auto
  1786 
  1787 definition "ms_strict = mult pair_less"
  1788 definition "ms_weak = ms_strict \<union> Id"
  1789 
  1790 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1791 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1792 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1793 
  1794 lemma smsI:
  1795   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1796   unfolding ms_strict_def
  1797 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1798 
  1799 lemma wmsI:
  1800   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1801   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1802 unfolding ms_weak_def ms_strict_def
  1803 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1804 
  1805 inductive pw_leq
  1806 where
  1807   pw_leq_empty: "pw_leq {#} {#}"
  1808 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1809 
  1810 lemma pw_leq_lstep:
  1811   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1812 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1813 
  1814 lemma pw_leq_split:
  1815   assumes "pw_leq X Y"
  1816   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1817   using assms
  1818 proof (induct)
  1819   case pw_leq_empty thus ?case by auto
  1820 next
  1821   case (pw_leq_step x y X Y)
  1822   then obtain A B Z where
  1823     [simp]: "X = A + Z" "Y = B + Z" 
  1824       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})" 
  1825     by auto
  1826   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less" 
  1827     unfolding pair_leq_def by auto
  1828   thus ?case
  1829   proof
  1830     assume [simp]: "x = y"
  1831     have
  1832       "{#x#} + X = A + ({#y#}+Z) 
  1833       \<and> {#y#} + Y = B + ({#y#}+Z)
  1834       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1835       by (auto simp: ac_simps)
  1836     thus ?case by (intro exI)
  1837   next
  1838     assume A: "(x, y) \<in> pair_less"
  1839     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1840     have "{#x#} + X = ?A' + Z"
  1841       "{#y#} + Y = ?B' + Z"
  1842       by (auto simp add: ac_simps)
  1843     moreover have 
  1844       "(set_of ?A', set_of ?B') \<in> max_strict"
  1845       using 1 A unfolding max_strict_def 
  1846       by (auto elim!: max_ext.cases)
  1847     ultimately show ?thesis by blast
  1848   qed
  1849 qed
  1850 
  1851 lemma 
  1852   assumes pwleq: "pw_leq Z Z'"
  1853   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1854   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1855   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1856 proof -
  1857   from pw_leq_split[OF pwleq] 
  1858   obtain A' B' Z''
  1859     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1860     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1861     by blast
  1862   {
  1863     assume max: "(set_of A, set_of B) \<in> max_strict"
  1864     from mx_or_empty
  1865     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1866     proof
  1867       assume max': "(set_of A', set_of B') \<in> max_strict"
  1868       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1869         by (auto simp: max_strict_def intro: max_ext_additive)
  1870       thus ?thesis by (rule smsI) 
  1871     next
  1872       assume [simp]: "A' = {#} \<and> B' = {#}"
  1873       show ?thesis by (rule smsI) (auto intro: max)
  1874     qed
  1875     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:ac_simps)
  1876     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1877   }
  1878   from mx_or_empty
  1879   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1880   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:ac_simps)
  1881 qed
  1882 
  1883 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1884 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1885 and nonempty_single: "{# x #} \<noteq> {#}"
  1886 by auto
  1887 
  1888 setup {*
  1889 let
  1890   fun msetT T = Type (@{type_name multiset}, [T]);
  1891 
  1892   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1893     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1894     | mk_mset T (x :: xs) =
  1895           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1896                 mk_mset T [x] $ mk_mset T xs
  1897 
  1898   fun mset_member_tac m i =
  1899       (if m <= 0 then
  1900            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1901        else
  1902            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1903 
  1904   val mset_nonempty_tac =
  1905       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  1906 
  1907   val regroup_munion_conv =
  1908       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
  1909         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  1910 
  1911   fun unfold_pwleq_tac i =
  1912     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  1913       ORELSE (rtac @{thm pw_leq_lstep} i)
  1914       ORELSE (rtac @{thm pw_leq_empty} i)
  1915 
  1916   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  1917                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  1918 in
  1919   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset 
  1920   {
  1921     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1922     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1923     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  1924     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1925     reduction_pair= @{thm ms_reduction_pair}
  1926   })
  1927 end
  1928 *}
  1929 
  1930 
  1931 subsection {* Legacy theorem bindings *}
  1932 
  1933 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  1934 
  1935 lemma union_commute: "M + N = N + (M::'a multiset)"
  1936   by (fact add.commute)
  1937 
  1938 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1939   by (fact add.assoc)
  1940 
  1941 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1942   by (fact add.left_commute)
  1943 
  1944 lemmas union_ac = union_assoc union_commute union_lcomm
  1945 
  1946 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1947   by (fact add_right_cancel)
  1948 
  1949 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1950   by (fact add_left_cancel)
  1951 
  1952 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1953   by (fact add_imp_eq)
  1954 
  1955 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
  1956   by (fact order_less_trans)
  1957 
  1958 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  1959   by (fact inf.commute)
  1960 
  1961 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  1962   by (fact inf.assoc [symmetric])
  1963 
  1964 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  1965   by (fact inf.left_commute)
  1966 
  1967 lemmas multiset_inter_ac =
  1968   multiset_inter_commute
  1969   multiset_inter_assoc
  1970   multiset_inter_left_commute
  1971 
  1972 lemma mult_less_not_refl:
  1973   "\<not> M \<subset># (M::'a::order multiset)"
  1974   by (fact multiset_order.less_irrefl)
  1975 
  1976 lemma mult_less_trans:
  1977   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
  1978   by (fact multiset_order.less_trans)
  1979     
  1980 lemma mult_less_not_sym:
  1981   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
  1982   by (fact multiset_order.less_not_sym)
  1983 
  1984 lemma mult_less_asym:
  1985   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
  1986   by (fact multiset_order.less_asym)
  1987 
  1988 ML {*
  1989 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
  1990                       (Const _ $ t') =
  1991     let
  1992       val (maybe_opt, ps) =
  1993         Nitpick_Model.dest_plain_fun t' ||> op ~~
  1994         ||> map (apsnd (snd o HOLogic.dest_number))
  1995       fun elems_for t =
  1996         case AList.lookup (op =) ps t of
  1997           SOME n => replicate n t
  1998         | NONE => [Const (maybe_name, elem_T --> elem_T) $ t]
  1999     in
  2000       case maps elems_for (all_values elem_T) @
  2001            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
  2002             else []) of
  2003         [] => Const (@{const_name zero_class.zero}, T)
  2004       | ts => foldl1 (fn (t1, t2) =>
  2005                          Const (@{const_name plus_class.plus}, T --> T --> T)
  2006                          $ t1 $ t2)
  2007                      (map (curry (op $) (Const (@{const_name single},
  2008                                                 elem_T --> T))) ts)
  2009     end
  2010   | multiset_postproc _ _ _ _ t = t
  2011 *}
  2012 
  2013 declaration {*
  2014 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
  2015     multiset_postproc
  2016 *}
  2017 
  2018 hide_const (open) fold
  2019 
  2020 
  2021 subsection {* Naive implementation using lists *}
  2022 
  2023 code_datatype multiset_of
  2024 
  2025 lemma [code]:
  2026   "{#} = multiset_of []"
  2027   by simp
  2028 
  2029 lemma [code]:
  2030   "{#x#} = multiset_of [x]"
  2031   by simp
  2032 
  2033 lemma union_code [code]:
  2034   "multiset_of xs + multiset_of ys = multiset_of (xs @ ys)"
  2035   by simp
  2036 
  2037 lemma [code]:
  2038   "image_mset f (multiset_of xs) = multiset_of (map f xs)"
  2039   by (simp add: multiset_of_map)
  2040 
  2041 lemma [code]:
  2042   "Multiset.filter f (multiset_of xs) = multiset_of (filter f xs)"
  2043   by (simp add: multiset_of_filter)
  2044 
  2045 lemma [code]:
  2046   "multiset_of xs - multiset_of ys = multiset_of (fold remove1 ys xs)"
  2047   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2048 
  2049 lemma [code]:
  2050   "multiset_of xs #\<inter> multiset_of ys =
  2051     multiset_of (snd (fold (\<lambda>x (ys, zs).
  2052       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2053 proof -
  2054   have "\<And>zs. multiset_of (snd (fold (\<lambda>x (ys, zs).
  2055     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2056       (multiset_of xs #\<inter> multiset_of ys) + multiset_of zs"
  2057     by (induct xs arbitrary: ys)
  2058       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2059   then show ?thesis by simp
  2060 qed
  2061 
  2062 lemma [code]:
  2063   "multiset_of xs #\<union> multiset_of ys =
  2064     multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2065 proof -
  2066   have "\<And>zs. multiset_of (split append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2067       (multiset_of xs #\<union> multiset_of ys) + multiset_of zs"
  2068     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2069   then show ?thesis by simp
  2070 qed
  2071 
  2072 lemma [code_unfold]:
  2073   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
  2074   by (simp add: in_multiset_of)
  2075 
  2076 lemma [code]:
  2077   "count (multiset_of xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2078 proof -
  2079   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (multiset_of xs) x + n"
  2080     by (induct xs) simp_all
  2081   then show ?thesis by simp
  2082 qed
  2083 
  2084 lemma [code]:
  2085   "set_of (multiset_of xs) = set xs"
  2086   by simp
  2087 
  2088 lemma [code]:
  2089   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  2090   by (induct xs) simp_all
  2091 
  2092 lemma [code]: -- {* not very efficient, but representation-ignorant! *}
  2093   "multiset_of_set A = multiset_of (sorted_list_of_set A)"
  2094   apply (cases "finite A")
  2095   apply simp_all
  2096   apply (induct A rule: finite_induct)
  2097   apply (simp_all add: union_commute)
  2098   done
  2099 
  2100 lemma [code]:
  2101   "mcard (multiset_of xs) = length xs"
  2102   by (simp add: mcard_multiset_of)
  2103 
  2104 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where 
  2105   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
  2106 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of 
  2107      None \<Rightarrow> None
  2108    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
  2109 
  2110 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> multiset_of xs \<le> multiset_of ys) \<and>
  2111   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> multiset_of xs < multiset_of ys) \<and>
  2112   (ms_lesseq_impl xs ys = Some False \<longrightarrow> multiset_of xs = multiset_of ys)"
  2113 proof (induct xs arbitrary: ys)
  2114   case (Nil ys)
  2115   show ?case by (auto simp: mset_less_empty_nonempty)
  2116 next
  2117   case (Cons x xs ys)
  2118   show ?case
  2119   proof (cases "List.extract (op = x) ys")
  2120     case None
  2121     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  2122     {
  2123       assume "multiset_of (x # xs) \<le> multiset_of ys"
  2124       from set_of_mono[OF this] x have False by simp
  2125     } note nle = this
  2126     moreover
  2127     {
  2128       assume "multiset_of (x # xs) < multiset_of ys"
  2129       hence "multiset_of (x # xs) \<le> multiset_of ys" by auto
  2130       from nle[OF this] have False .
  2131     }
  2132     ultimately show ?thesis using None by auto
  2133   next
  2134     case (Some res)
  2135     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  2136     note Some = Some[unfolded res]
  2137     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  2138     hence id: "multiset_of ys = multiset_of (ys1 @ ys2) + {#x#}" 
  2139       by (auto simp: ac_simps)
  2140     show ?thesis unfolding ms_lesseq_impl.simps
  2141       unfolding Some option.simps split
  2142       unfolding id
  2143       using Cons[of "ys1 @ ys2"]
  2144       unfolding mset_le_def mset_less_def by auto
  2145   qed
  2146 qed
  2147 
  2148 lemma [code]: "multiset_of xs \<le> multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
  2149   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2150 
  2151 lemma [code]: "multiset_of xs < multiset_of ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
  2152   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2153 
  2154 instantiation multiset :: (equal) equal
  2155 begin
  2156 
  2157 definition
  2158   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  2159 lemma [code]: "HOL.equal (multiset_of xs) (multiset_of ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
  2160   unfolding equal_multiset_def
  2161   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2162 
  2163 instance
  2164   by default (simp add: equal_multiset_def)
  2165 end
  2166 
  2167 lemma [code]:
  2168   "msetsum (multiset_of xs) = listsum xs"
  2169   by (induct xs) (simp_all add: add.commute)
  2170 
  2171 lemma [code]:
  2172   "msetprod (multiset_of xs) = fold times xs 1"
  2173 proof -
  2174   have "\<And>x. fold times xs x = msetprod (multiset_of xs) * x"
  2175     by (induct xs) (simp_all add: mult.assoc)
  2176   then show ?thesis by simp
  2177 qed
  2178 
  2179 lemma [code]:
  2180   "size = mcard"
  2181   by (fact size_eq_mcard)
  2182 
  2183 text {*
  2184   Exercise for the casual reader: add implementations for @{const le_multiset}
  2185   and @{const less_multiset} (multiset order).
  2186 *}
  2187 
  2188 text {* Quickcheck generators *}
  2189 
  2190 definition (in term_syntax)
  2191   msetify :: "'a\<Colon>typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2192     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2193   [code_unfold]: "msetify xs = Code_Evaluation.valtermify multiset_of {\<cdot>} xs"
  2194 
  2195 notation fcomp (infixl "\<circ>>" 60)
  2196 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2197 
  2198 instantiation multiset :: (random) random
  2199 begin
  2200 
  2201 definition
  2202   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2203 
  2204 instance ..
  2205 
  2206 end
  2207 
  2208 no_notation fcomp (infixl "\<circ>>" 60)
  2209 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2210 
  2211 instantiation multiset :: (full_exhaustive) full_exhaustive
  2212 begin
  2213 
  2214 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2215 where
  2216   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2217 
  2218 instance ..
  2219 
  2220 end
  2221 
  2222 hide_const (open) msetify
  2223 
  2224 
  2225 subsection {* BNF setup *}
  2226 
  2227 lemma setsum_gt_0_iff:
  2228 fixes f :: "'a \<Rightarrow> nat" assumes "finite A"
  2229 shows "setsum f A > 0 \<longleftrightarrow> (\<exists> a \<in> A. f a > 0)"
  2230 (is "?L \<longleftrightarrow> ?R")
  2231 proof-
  2232   have "?L \<longleftrightarrow> \<not> setsum f A = 0" by fast
  2233   also have "... \<longleftrightarrow> (\<exists> a \<in> A. f a \<noteq> 0)" using assms by simp
  2234   also have "... \<longleftrightarrow> ?R" by simp
  2235   finally show ?thesis .
  2236 qed
  2237 
  2238 lift_definition mmap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" is
  2239   "\<lambda>h f b. setsum f {a. h a = b \<and> f a > 0} :: nat"
  2240 unfolding multiset_def proof safe
  2241   fix h :: "'a \<Rightarrow> 'b" and f :: "'a \<Rightarrow> nat"
  2242   assume fin: "finite {a. 0 < f a}"  (is "finite ?A")
  2243   show "finite {b. 0 < setsum f {a. h a = b \<and> 0 < f a}}"
  2244   (is "finite {b. 0 < setsum f (?As b)}")
  2245   proof- let ?B = "{b. 0 < setsum f (?As b)}"
  2246     have "\<And> b. finite (?As b)" using fin by simp
  2247     hence B: "?B = {b. ?As b \<noteq> {}}" by (auto simp add: setsum_gt_0_iff)
  2248     hence "?B \<subseteq> h ` ?A" by auto
  2249     thus ?thesis using finite_surj[OF fin] by auto
  2250   qed
  2251 qed
  2252 
  2253 lemma mmap_id0: "mmap id = id"
  2254 proof (intro ext multiset_eqI)
  2255   fix f a show "count (mmap id f) a = count (id f) a"
  2256   proof (cases "count f a = 0")
  2257     case False
  2258     hence 1: "{aa. aa = a \<and> aa \<in># f} = {a}" by auto
  2259     thus ?thesis by transfer auto
  2260   qed (transfer, simp)
  2261 qed
  2262 
  2263 lemma inj_on_setsum_inv:
  2264 assumes 1: "(0::nat) < setsum (count f) {a. h a = b' \<and> a \<in># f}" (is "0 < setsum (count f) ?A'")
  2265 and     2: "{a. h a = b \<and> a \<in># f} = {a. h a = b' \<and> a \<in># f}" (is "?A = ?A'")
  2266 shows "b = b'"
  2267 using assms by (auto simp add: setsum_gt_0_iff)
  2268 
  2269 lemma mmap_comp:
  2270 fixes h1 :: "'a \<Rightarrow> 'b" and h2 :: "'b \<Rightarrow> 'c"
  2271 shows "mmap (h2 o h1) = mmap h2 o mmap h1"
  2272 proof (intro ext multiset_eqI)
  2273   fix f :: "'a multiset" fix c :: 'c
  2274   let ?A = "{a. h2 (h1 a) = c \<and> a \<in># f}"
  2275   let ?As = "\<lambda> b. {a. h1 a = b \<and> a \<in># f}"
  2276   let ?B = "{b. h2 b = c \<and> 0 < setsum (count f) (?As b)}"
  2277   have 0: "{?As b | b.  b \<in> ?B} = ?As ` ?B" by auto
  2278   have "\<And> b. finite (?As b)" by transfer (simp add: multiset_def)
  2279   hence "?B = {b. h2 b = c \<and> ?As b \<noteq> {}}" by (auto simp add: setsum_gt_0_iff)
  2280   hence A: "?A = \<Union> {?As b | b.  b \<in> ?B}" by auto
  2281   have "setsum (count f) ?A = setsum (setsum (count f)) {?As b | b.  b \<in> ?B}"
  2282     unfolding A by transfer (intro setsum.Union_disjoint [simplified], auto simp: multiset_def setsum.Union_disjoint)
  2283   also have "... = setsum (setsum (count f)) (?As ` ?B)" unfolding 0 ..
  2284   also have "... = setsum (setsum (count f) o ?As) ?B"
  2285     by (intro setsum.reindex) (auto simp add: setsum_gt_0_iff inj_on_def)
  2286   also have "... = setsum (\<lambda> b. setsum (count f) (?As b)) ?B" unfolding comp_def ..
  2287   finally have "setsum (count f) ?A = setsum (\<lambda> b. setsum (count f) (?As b)) ?B" .
  2288   thus "count (mmap (h2 \<circ> h1) f) c = count ((mmap h2 \<circ> mmap h1) f) c"
  2289     by transfer (unfold comp_apply, blast)
  2290 qed
  2291 
  2292 lemma mmap_cong:
  2293 assumes "\<And>a. a \<in># M \<Longrightarrow> f a = g a"
  2294 shows "mmap f M = mmap g M"
  2295 using assms by transfer (auto intro!: setsum.cong)
  2296 
  2297 context
  2298 begin
  2299 interpretation lifting_syntax .
  2300 
  2301 lemma set_of_transfer[transfer_rule]: "(pcr_multiset op = ===> op =) (\<lambda>f. {a. 0 < f a}) set_of"
  2302   unfolding set_of_def pcr_multiset_def cr_multiset_def rel_fun_def by auto
  2303 
  2304 end
  2305 
  2306 lemma set_of_mmap: "set_of o mmap h = image h o set_of"
  2307 proof (rule ext, unfold comp_apply)
  2308   fix M show "set_of (mmap h M) = h ` set_of M"
  2309     by transfer (auto simp add: multiset_def setsum_gt_0_iff)
  2310 qed
  2311 
  2312 lemma multiset_of_surj:
  2313   "multiset_of ` {as. set as \<subseteq> A} = {M. set_of M \<subseteq> A}"
  2314 proof safe
  2315   fix M assume M: "set_of M \<subseteq> A"
  2316   obtain as where eq: "M = multiset_of as" using surj_multiset_of unfolding surj_def by auto
  2317   hence "set as \<subseteq> A" using M by auto
  2318   thus "M \<in> multiset_of ` {as. set as \<subseteq> A}" using eq by auto
  2319 next
  2320   show "\<And>x xa xb. \<lbrakk>set xa \<subseteq> A; xb \<in> set_of (multiset_of xa)\<rbrakk> \<Longrightarrow> xb \<in> A"
  2321   by (erule set_mp) (unfold set_of_multiset_of)
  2322 qed
  2323 
  2324 lemma card_of_set_of:
  2325 "(card_of {M. set_of M \<subseteq> A}, card_of {as. set as \<subseteq> A}) \<in> ordLeq"
  2326 apply(rule surj_imp_ordLeq[of _ multiset_of]) using multiset_of_surj by auto
  2327 
  2328 lemma nat_sum_induct:
  2329 assumes "\<And>n1 n2. (\<And> m1 m2. m1 + m2 < n1 + n2 \<Longrightarrow> phi m1 m2) \<Longrightarrow> phi n1 n2"
  2330 shows "phi (n1::nat) (n2::nat)"
  2331 proof-
  2332   let ?chi = "\<lambda> n1n2 :: nat * nat. phi (fst n1n2) (snd n1n2)"
  2333   have "?chi (n1,n2)"
  2334   apply(induct rule: measure_induct[of "\<lambda> n1n2. fst n1n2 + snd n1n2" ?chi])
  2335   using assms by (metis fstI sndI)
  2336   thus ?thesis by simp
  2337 qed
  2338 
  2339 lemma matrix_count:
  2340 fixes ct1 ct2 :: "nat \<Rightarrow> nat"
  2341 assumes "setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2}"
  2342 shows
  2343 "\<exists> ct. (\<forall> i1 \<le> n1. setsum (\<lambda> i2. ct i1 i2) {..<Suc n2} = ct1 i1) \<and>
  2344        (\<forall> i2 \<le> n2. setsum (\<lambda> i1. ct i1 i2) {..<Suc n1} = ct2 i2)"
  2345 (is "?phi ct1 ct2 n1 n2")
  2346 proof-
  2347   have "\<forall> ct1 ct2 :: nat \<Rightarrow> nat.
  2348         setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2} \<longrightarrow> ?phi ct1 ct2 n1 n2"
  2349   proof(induct rule: nat_sum_induct[of
  2350 "\<lambda> n1 n2. \<forall> ct1 ct2 :: nat \<Rightarrow> nat.
  2351      setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2} \<longrightarrow> ?phi ct1 ct2 n1 n2"],
  2352       clarify)
  2353   fix n1 n2 :: nat and ct1 ct2 :: "nat \<Rightarrow> nat"
  2354   assume IH: "\<And> m1 m2. m1 + m2 < n1 + n2 \<Longrightarrow>
  2355                 \<forall> dt1 dt2 :: nat \<Rightarrow> nat.
  2356                 setsum dt1 {..<Suc m1} = setsum dt2 {..<Suc m2} \<longrightarrow> ?phi dt1 dt2 m1 m2"
  2357   and ss: "setsum ct1 {..<Suc n1} = setsum ct2 {..<Suc n2}"
  2358   show "?phi ct1 ct2 n1 n2"
  2359   proof(cases n1)
  2360     case 0 note n1 = 0
  2361     show ?thesis
  2362     proof(cases n2)
  2363       case 0 note n2 = 0
  2364       let ?ct = "\<lambda> i1 i2. ct2 0"
  2365       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by simp
  2366     next
  2367       case (Suc m2) note n2 = Suc
  2368       let ?ct = "\<lambda> i1 i2. ct2 i2"
  2369       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by auto
  2370     qed
  2371   next
  2372     case (Suc m1) note n1 = Suc
  2373     show ?thesis
  2374     proof(cases n2)
  2375       case 0 note n2 = 0
  2376       let ?ct = "\<lambda> i1 i2. ct1 i1"
  2377       show ?thesis apply(rule exI[of _ ?ct]) using n1 n2 ss by auto
  2378     next
  2379       case (Suc m2) note n2 = Suc
  2380       show ?thesis
  2381       proof(cases "ct1 n1 \<le> ct2 n2")
  2382         case True
  2383         def dt2 \<equiv> "\<lambda> i2. if i2 = n2 then ct2 i2 - ct1 n1 else ct2 i2"
  2384         have "setsum ct1 {..<Suc m1} = setsum dt2 {..<Suc n2}"
  2385         unfolding dt2_def using ss n1 True by auto
  2386         hence "?phi ct1 dt2 m1 n2" using IH[of m1 n2] n1 by simp
  2387         then obtain dt where
  2388         1: "\<And> i1. i1 \<le> m1 \<Longrightarrow> setsum (\<lambda> i2. dt i1 i2) {..<Suc n2} = ct1 i1" and
  2389         2: "\<And> i2. i2 \<le> n2 \<Longrightarrow> setsum (\<lambda> i1. dt i1 i2) {..<Suc m1} = dt2 i2" by auto
  2390         let ?ct = "\<lambda> i1 i2. if i1 = n1 then (if i2 = n2 then ct1 n1 else 0)
  2391                                        else dt i1 i2"
  2392         show ?thesis apply(rule exI[of _ ?ct])
  2393         using n1 n2 1 2 True unfolding dt2_def by simp
  2394       next
  2395         case False
  2396         hence False: "ct2 n2 < ct1 n1" by simp
  2397         def dt1 \<equiv> "\<lambda> i1. if i1 = n1 then ct1 i1 - ct2 n2 else ct1 i1"
  2398         have "setsum dt1 {..<Suc n1} = setsum ct2 {..<Suc m2}"
  2399         unfolding dt1_def using ss n2 False by auto
  2400         hence "?phi dt1 ct2 n1 m2" using IH[of n1 m2] n2 by simp
  2401         then obtain dt where
  2402         1: "\<And> i1. i1 \<le> n1 \<Longrightarrow> setsum (\<lambda> i2. dt i1 i2) {..<Suc m2} = dt1 i1" and
  2403         2: "\<And> i2. i2 \<le> m2 \<Longrightarrow> setsum (\<lambda> i1. dt i1 i2) {..<Suc n1} = ct2 i2" by force
  2404         let ?ct = "\<lambda> i1 i2. if i2 = n2 then (if i1 = n1 then ct2 n2 else 0)
  2405                                        else dt i1 i2"
  2406         show ?thesis apply(rule exI[of _ ?ct])
  2407         using n1 n2 1 2 False unfolding dt1_def by simp
  2408       qed
  2409     qed
  2410   qed
  2411   qed
  2412   thus ?thesis using assms by auto
  2413 qed
  2414 
  2415 definition
  2416 "inj2 u B1 B2 \<equiv>
  2417  \<forall> b1 b1' b2 b2'. {b1,b1'} \<subseteq> B1 \<and> {b2,b2'} \<subseteq> B2 \<and> u b1 b2 = u b1' b2'
  2418                   \<longrightarrow> b1 = b1' \<and> b2 = b2'"
  2419 
  2420 lemma matrix_setsum_finite:
  2421 assumes B1: "B1 \<noteq> {}" "finite B1" and B2: "B2 \<noteq> {}" "finite B2" and u: "inj2 u B1 B2"
  2422 and ss: "setsum N1 B1 = setsum N2 B2"
  2423 shows "\<exists> M :: 'a \<Rightarrow> nat.
  2424             (\<forall> b1 \<in> B1. setsum (\<lambda> b2. M (u b1 b2)) B2 = N1 b1) \<and>
  2425             (\<forall> b2 \<in> B2. setsum (\<lambda> b1. M (u b1 b2)) B1 = N2 b2)"
  2426 proof-
  2427   obtain n1 where "card B1 = Suc n1" using B1 by (metis card_insert finite.simps)
  2428   then obtain e1 where e1: "bij_betw e1 {..<Suc n1} B1"
  2429   using ex_bij_betw_finite_nat[OF B1(2)] by (metis atLeast0LessThan bij_betw_the_inv_into)
  2430   hence e1_inj: "inj_on e1 {..<Suc n1}" and e1_surj: "e1 ` {..<Suc n1} = B1"
  2431   unfolding bij_betw_def by auto
  2432   def f1 \<equiv> "inv_into {..<Suc n1} e1"
  2433   have f1: "bij_betw f1 B1 {..<Suc n1}"
  2434   and f1e1[simp]: "\<And> i1. i1 < Suc n1 \<Longrightarrow> f1 (e1 i1) = i1"
  2435   and e1f1[simp]: "\<And> b1. b1 \<in> B1 \<Longrightarrow> e1 (f1 b1) = b1" unfolding f1_def
  2436   apply (metis bij_betw_inv_into e1, metis bij_betw_inv_into_left e1 lessThan_iff)
  2437   by (metis e1_surj f_inv_into_f)
  2438   (*  *)
  2439   obtain n2 where "card B2 = Suc n2" using B2 by (metis card_insert finite.simps)
  2440   then obtain e2 where e2: "bij_betw e2 {..<Suc n2} B2"
  2441   using ex_bij_betw_finite_nat[OF B2(2)] by (metis atLeast0LessThan bij_betw_the_inv_into)
  2442   hence e2_inj: "inj_on e2 {..<Suc n2}" and e2_surj: "e2 ` {..<Suc n2} = B2"
  2443   unfolding bij_betw_def by auto
  2444   def f2 \<equiv> "inv_into {..<Suc n2} e2"
  2445   have f2: "bij_betw f2 B2 {..<Suc n2}"
  2446   and f2e2[simp]: "\<And> i2. i2 < Suc n2 \<Longrightarrow> f2 (e2 i2) = i2"
  2447   and e2f2[simp]: "\<And> b2. b2 \<in> B2 \<Longrightarrow> e2 (f2 b2) = b2" unfolding f2_def
  2448   apply (metis bij_betw_inv_into e2, metis bij_betw_inv_into_left e2 lessThan_iff)
  2449   by (metis e2_surj f_inv_into_f)
  2450   (*  *)
  2451   let ?ct1 = "N1 o e1"  let ?ct2 = "N2 o e2"
  2452   have ss: "setsum ?ct1 {..<Suc n1} = setsum ?ct2 {..<Suc n2}"
  2453   unfolding setsum.reindex[OF e1_inj, symmetric] setsum.reindex[OF e2_inj, symmetric]
  2454   e1_surj e2_surj using ss .
  2455   obtain ct where
  2456   ct1: "\<And> i1. i1 \<le> n1 \<Longrightarrow> setsum (\<lambda> i2. ct i1 i2) {..<Suc n2} = ?ct1 i1" and
  2457   ct2: "\<And> i2. i2 \<le> n2 \<Longrightarrow> setsum (\<lambda> i1. ct i1 i2) {..<Suc n1} = ?ct2 i2"
  2458   using matrix_count[OF ss] by blast
  2459   (*  *)
  2460   def A \<equiv> "{u b1 b2 | b1 b2. b1 \<in> B1 \<and> b2 \<in> B2}"
  2461   have "\<forall> a \<in> A. \<exists> b1b2 \<in> B1 <*> B2. u (fst b1b2) (snd b1b2) = a"
  2462   unfolding A_def Ball_def mem_Collect_eq by auto
  2463   then obtain h1h2 where h12:
  2464   "\<And>a. a \<in> A \<Longrightarrow> u (fst (h1h2 a)) (snd (h1h2 a)) = a \<and> h1h2 a \<in> B1 <*> B2" by metis
  2465   def h1 \<equiv> "fst o h1h2"  def h2 \<equiv> "snd o h1h2"
  2466   have h12[simp]: "\<And>a. a \<in> A \<Longrightarrow> u (h1 a) (h2 a) = a"
  2467                   "\<And> a. a \<in> A \<Longrightarrow> h1 a \<in> B1"  "\<And> a. a \<in> A \<Longrightarrow> h2 a \<in> B2"
  2468   using h12 unfolding h1_def h2_def by force+
  2469   {fix b1 b2 assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2"
  2470    hence inA: "u b1 b2 \<in> A" unfolding A_def by auto
  2471    hence "u b1 b2 = u (h1 (u b1 b2)) (h2 (u b1 b2))" by auto
  2472    moreover have "h1 (u b1 b2) \<in> B1" "h2 (u b1 b2) \<in> B2" using inA by auto
  2473    ultimately have "h1 (u b1 b2) = b1 \<and> h2 (u b1 b2) = b2"
  2474    using u b1 b2 unfolding inj2_def by fastforce
  2475   }
  2476   hence h1[simp]: "\<And> b1 b2. \<lbrakk>b1 \<in> B1; b2 \<in> B2\<rbrakk> \<Longrightarrow> h1 (u b1 b2) = b1" and
  2477         h2[simp]: "\<And> b1 b2. \<lbrakk>b1 \<in> B1; b2 \<in> B2\<rbrakk> \<Longrightarrow> h2 (u b1 b2) = b2" by auto
  2478   def M \<equiv> "\<lambda> a. ct (f1 (h1 a)) (f2 (h2 a))"
  2479   show ?thesis
  2480   apply(rule exI[of _ M]) proof safe
  2481     fix b1 assume b1: "b1 \<in> B1"
  2482     hence f1b1: "f1 b1 \<le> n1" using f1 unfolding bij_betw_def
  2483     by (metis image_eqI lessThan_iff less_Suc_eq_le)
  2484     have "(\<Sum>b2\<in>B2. M (u b1 b2)) = (\<Sum>i2<Suc n2. ct (f1 b1) (f2 (e2 i2)))"
  2485     unfolding e2_surj[symmetric] setsum.reindex[OF e2_inj]
  2486     unfolding M_def comp_def apply(intro setsum.cong) apply force
  2487     by (metis e2_surj b1 h1 h2 imageI)
  2488     also have "... = N1 b1" using b1 ct1[OF f1b1] by simp
  2489     finally show "(\<Sum>b2\<in>B2. M (u b1 b2)) = N1 b1" .
  2490   next
  2491     fix b2 assume b2: "b2 \<in> B2"
  2492     hence f2b2: "f2 b2 \<le> n2" using f2 unfolding bij_betw_def
  2493     by (metis image_eqI lessThan_iff less_Suc_eq_le)
  2494     have "(\<Sum>b1\<in>B1. M (u b1 b2)) = (\<Sum>i1<Suc n1. ct (f1 (e1 i1)) (f2 b2))"
  2495     unfolding e1_surj[symmetric] setsum.reindex[OF e1_inj]
  2496     unfolding M_def comp_def apply(intro setsum.cong) apply force
  2497     by (metis e1_surj b2 h1 h2 imageI)
  2498     also have "... = N2 b2" using b2 ct2[OF f2b2] by simp
  2499     finally show "(\<Sum>b1\<in>B1. M (u b1 b2)) = N2 b2" .
  2500   qed
  2501 qed
  2502 
  2503 lemma supp_vimage_mmap: "set_of M \<subseteq> f -` (set_of (mmap f M))"
  2504   by transfer (auto simp: multiset_def setsum_gt_0_iff)
  2505 
  2506 lemma mmap_ge_0: "b \<in># mmap f M \<longleftrightarrow> (\<exists>a. a \<in># M \<and> f a = b)"
  2507   by transfer (auto simp: multiset_def setsum_gt_0_iff)
  2508 
  2509 lemma finite_twosets:
  2510 assumes "finite B1" and "finite B2"
  2511 shows "finite {u b1 b2 |b1 b2. b1 \<in> B1 \<and> b2 \<in> B2}"  (is "finite ?A")
  2512 proof-
  2513   have A: "?A = (\<lambda> b1b2. u (fst b1b2) (snd b1b2)) ` (B1 <*> B2)" by force
  2514   show ?thesis unfolding A using finite_cartesian_product[OF assms] by auto
  2515 qed
  2516 
  2517 (* Weak pullbacks: *)
  2518 definition wpull where
  2519 "wpull A B1 B2 f1 f2 p1 p2 \<longleftrightarrow>
  2520  (\<forall> b1 b2. b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2 \<longrightarrow> (\<exists> a \<in> A. p1 a = b1 \<and> p2 a = b2))"
  2521 
  2522 (* Weak pseudo-pullbacks *)
  2523 definition wppull where
  2524 "wppull A B1 B2 f1 f2 e1 e2 p1 p2 \<longleftrightarrow>
  2525  (\<forall> b1 b2. b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2 \<longrightarrow>
  2526            (\<exists> a \<in> A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2))"
  2527 
  2528 
  2529 (* The pullback of sets *)
  2530 definition thePull where
  2531 "thePull B1 B2 f1 f2 = {(b1,b2). b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2}"
  2532 
  2533 lemma wpull_thePull:
  2534 "wpull (thePull B1 B2 f1 f2) B1 B2 f1 f2 fst snd"
  2535 unfolding wpull_def thePull_def by auto
  2536 
  2537 lemma wppull_thePull:
  2538 assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2539 shows
  2540 "\<exists> j. \<forall> a' \<in> thePull B1 B2 f1 f2.
  2541    j a' \<in> A \<and>
  2542    e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')"
  2543 (is "\<exists> j. \<forall> a' \<in> ?A'. ?phi a' (j a')")
  2544 proof(rule bchoice[of ?A' ?phi], default)
  2545   fix a' assume a': "a' \<in> ?A'"
  2546   hence "fst a' \<in> B1" unfolding thePull_def by auto
  2547   moreover
  2548   from a' have "snd a' \<in> B2" unfolding thePull_def by auto
  2549   moreover have "f1 (fst a') = f2 (snd a')"
  2550   using a' unfolding csquare_def thePull_def by auto
  2551   ultimately show "\<exists> ja'. ?phi a' ja'"
  2552   using assms unfolding wppull_def by blast
  2553 qed
  2554 
  2555 lemma wpull_wppull:
  2556 assumes wp: "wpull A' B1 B2 f1 f2 p1' p2'" and
  2557 1: "\<forall> a' \<in> A'. j a' \<in> A \<and> e1 (p1 (j a')) = e1 (p1' a') \<and> e2 (p2 (j a')) = e2 (p2' a')"
  2558 shows "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2559 unfolding wppull_def proof safe
  2560   fix b1 b2
  2561   assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2" and f: "f1 b1 = f2 b2"
  2562   then obtain a' where a': "a' \<in> A'" and b1: "b1 = p1' a'" and b2: "b2 = p2' a'"
  2563   using wp unfolding wpull_def by blast
  2564   show "\<exists>a\<in>A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2"
  2565   apply (rule bexI[of _ "j a'"]) unfolding b1 b2 using a' 1 by auto
  2566 qed
  2567 
  2568 lemma wppull_fstOp_sndOp:
  2569 shows "wppull (Collect (split (P OO Q))) (Collect (split P)) (Collect (split Q))
  2570   snd fst fst snd (BNF_Def.fstOp P Q) (BNF_Def.sndOp P Q)"
  2571 using pick_middlep unfolding wppull_def fstOp_def sndOp_def relcompp.simps by auto
  2572 
  2573 lemma wpull_mmap:
  2574 fixes A :: "'a set" and B1 :: "'b1 set" and B2 :: "'b2 set"
  2575 assumes wp: "wpull A B1 B2 f1 f2 p1 p2"
  2576 shows
  2577 "wpull {M. set_of M \<subseteq> A}
  2578        {N1. set_of N1 \<subseteq> B1} {N2. set_of N2 \<subseteq> B2}
  2579        (mmap f1) (mmap f2) (mmap p1) (mmap p2)"
  2580 unfolding wpull_def proof (safe, unfold Bex_def mem_Collect_eq)
  2581   fix N1 :: "'b1 multiset" and N2 :: "'b2 multiset"
  2582   assume mmap': "mmap f1 N1 = mmap f2 N2"
  2583   and N1[simp]: "set_of N1 \<subseteq> B1"
  2584   and N2[simp]: "set_of N2 \<subseteq> B2"
  2585   def P \<equiv> "mmap f1 N1"
  2586   have P1: "P = mmap f1 N1" and P2: "P = mmap f2 N2" unfolding P_def using mmap' by auto
  2587   note P = P1 P2
  2588   have fin_N1[simp]: "finite (set_of N1)"
  2589    and fin_N2[simp]: "finite (set_of N2)"
  2590    and fin_P[simp]: "finite (set_of P)" by auto
  2591 
  2592   def set1 \<equiv> "\<lambda> c. {b1 \<in> set_of N1. f1 b1 = c}"
  2593   have set1[simp]: "\<And> c b1. b1 \<in> set1 c \<Longrightarrow> f1 b1 = c" unfolding set1_def by auto
  2594   have fin_set1: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (set1 c)"
  2595     using N1(1) unfolding set1_def multiset_def by auto
  2596   have set1_NE: "\<And> c. c \<in> set_of P \<Longrightarrow> set1 c \<noteq> {}"
  2597    unfolding set1_def set_of_def P mmap_ge_0 by auto
  2598   have supp_N1_set1: "set_of N1 = (\<Union> c \<in> set_of P. set1 c)"
  2599     using supp_vimage_mmap[of N1 f1] unfolding set1_def P1 by auto
  2600   hence set1_inclN1: "\<And>c. c \<in> set_of P \<Longrightarrow> set1 c \<subseteq> set_of N1" by auto
  2601   hence set1_incl: "\<And> c. c \<in> set_of P \<Longrightarrow> set1 c \<subseteq> B1" using N1 by blast
  2602   have set1_disj: "\<And> c c'. c \<noteq> c' \<Longrightarrow> set1 c \<inter> set1 c' = {}"
  2603     unfolding set1_def by auto
  2604   have setsum_set1: "\<And> c. setsum (count N1) (set1 c) = count P c"
  2605     unfolding P1 set1_def by transfer (auto intro: setsum.cong)
  2606 
  2607   def set2 \<equiv> "\<lambda> c. {b2 \<in> set_of N2. f2 b2 = c}"
  2608   have set2[simp]: "\<And> c b2. b2 \<in> set2 c \<Longrightarrow> f2 b2 = c" unfolding set2_def by auto
  2609   have fin_set2: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (set2 c)"
  2610   using N2(1) unfolding set2_def multiset_def by auto
  2611   have set2_NE: "\<And> c. c \<in> set_of P \<Longrightarrow> set2 c \<noteq> {}"
  2612     unfolding set2_def P2 mmap_ge_0 set_of_def by auto
  2613   have supp_N2_set2: "set_of N2 = (\<Union> c \<in> set_of P. set2 c)"
  2614     using supp_vimage_mmap[of N2 f2] unfolding set2_def P2 by auto
  2615   hence set2_inclN2: "\<And>c. c \<in> set_of P \<Longrightarrow> set2 c \<subseteq> set_of N2" by auto
  2616   hence set2_incl: "\<And> c. c \<in> set_of P \<Longrightarrow> set2 c \<subseteq> B2" using N2 by blast
  2617   have set2_disj: "\<And> c c'. c \<noteq> c' \<Longrightarrow> set2 c \<inter> set2 c' = {}"
  2618     unfolding set2_def by auto
  2619   have setsum_set2: "\<And> c. setsum (count N2) (set2 c) = count P c"
  2620     unfolding P2 set2_def by transfer (auto intro: setsum.cong)
  2621 
  2622   have ss: "\<And> c. c \<in> set_of P \<Longrightarrow> setsum (count N1) (set1 c) = setsum (count N2) (set2 c)"
  2623     unfolding setsum_set1 setsum_set2 ..
  2624   have "\<forall> c \<in> set_of P. \<forall> b1b2 \<in> (set1 c) \<times> (set2 c).
  2625           \<exists> a \<in> A. p1 a = fst b1b2 \<and> p2 a = snd b1b2"
  2626     using wp set1_incl set2_incl unfolding wpull_def Ball_def mem_Collect_eq
  2627     by simp (metis set1 set2 set_rev_mp)
  2628   then obtain uu where uu:
  2629   "\<forall> c \<in> set_of P. \<forall> b1b2 \<in> (set1 c) \<times> (set2 c).
  2630      uu c b1b2 \<in> A \<and> p1 (uu c b1b2) = fst b1b2 \<and> p2 (uu c b1b2) = snd b1b2" by metis
  2631   def u \<equiv> "\<lambda> c b1 b2. uu c (b1,b2)"
  2632   have u[simp]:
  2633   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> u c b1 b2 \<in> A"
  2634   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> p1 (u c b1 b2) = b1"
  2635   "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> p2 (u c b1 b2) = b2"
  2636     using uu unfolding u_def by auto
  2637   {fix c assume c: "c \<in> set_of P"
  2638    have "inj2 (u c) (set1 c) (set2 c)" unfolding inj2_def proof clarify
  2639      fix b1 b1' b2 b2'
  2640      assume "{b1, b1'} \<subseteq> set1 c" "{b2, b2'} \<subseteq> set2 c" and 0: "u c b1 b2 = u c b1' b2'"
  2641      hence "p1 (u c b1 b2) = b1 \<and> p2 (u c b1 b2) = b2 \<and>
  2642             p1 (u c b1' b2') = b1' \<and> p2 (u c b1' b2') = b2'"
  2643      using u(2)[OF c] u(3)[OF c] by simp metis
  2644      thus "b1 = b1' \<and> b2 = b2'" using 0 by auto
  2645    qed
  2646   } note inj = this
  2647   def sset \<equiv> "\<lambda> c. {u c b1 b2 | b1 b2. b1 \<in> set1 c \<and> b2 \<in> set2 c}"
  2648   have fin_sset[simp]: "\<And> c. c \<in> set_of P \<Longrightarrow> finite (sset c)" unfolding sset_def
  2649     using fin_set1 fin_set2 finite_twosets by blast
  2650   have sset_A: "\<And> c. c \<in> set_of P \<Longrightarrow> sset c \<subseteq> A" unfolding sset_def by auto
  2651   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2652    then obtain b1 b2 where b1: "b1 \<in> set1 c" and b2: "b2 \<in> set2 c"
  2653    and a: "a = u c b1 b2" unfolding sset_def by auto
  2654    have "p1 a \<in> set1 c" and p2a: "p2 a \<in> set2 c"
  2655    using ac a b1 b2 c u(2) u(3) by simp+
  2656    hence "u c (p1 a) (p2 a) = a" unfolding a using b1 b2 inj[OF c]
  2657    unfolding inj2_def by (metis c u(2) u(3))
  2658   } note u_p12[simp] = this
  2659   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2660    hence "p1 a \<in> set1 c" unfolding sset_def by auto
  2661   }note p1[simp] = this
  2662   {fix c a assume c: "c \<in> set_of P" and ac: "a \<in> sset c"
  2663    hence "p2 a \<in> set2 c" unfolding sset_def by auto
  2664   }note p2[simp] = this
  2665 
  2666   {fix c assume c: "c \<in> set_of P"
  2667    hence "\<exists> M. (\<forall> b1 \<in> set1 c. setsum (\<lambda> b2. M (u c b1 b2)) (set2 c) = count N1 b1) \<and>
  2668                (\<forall> b2 \<in> set2 c. setsum (\<lambda> b1. M (u c b1 b2)) (set1 c) = count N2 b2)"
  2669    unfolding sset_def
  2670    using matrix_setsum_finite[OF set1_NE[OF c] fin_set1[OF c]
  2671                                  set2_NE[OF c] fin_set2[OF c] inj[OF c] ss[OF c]] by auto
  2672   }
  2673   then obtain Ms where
  2674   ss1: "\<And> c b1. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c\<rbrakk> \<Longrightarrow>
  2675                    setsum (\<lambda> b2. Ms c (u c b1 b2)) (set2 c) = count N1 b1" and
  2676   ss2: "\<And> c b2. \<lbrakk>c \<in> set_of P; b2 \<in> set2 c\<rbrakk> \<Longrightarrow>
  2677                    setsum (\<lambda> b1. Ms c (u c b1 b2)) (set1 c) = count N2 b2"
  2678   by metis
  2679   def SET \<equiv> "\<Union> c \<in> set_of P. sset c"
  2680   have fin_SET[simp]: "finite SET" unfolding SET_def apply(rule finite_UN_I) by auto
  2681   have SET_A: "SET \<subseteq> A" unfolding SET_def using sset_A by blast
  2682   have u_SET[simp]: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk> \<Longrightarrow> u c b1 b2 \<in> SET"
  2683     unfolding SET_def sset_def by blast
  2684   {fix c a assume c: "c \<in> set_of P" and a: "a \<in> SET" and p1a: "p1 a \<in> set1 c"
  2685    then obtain c' where c': "c' \<in> set_of P" and ac': "a \<in> sset c'"
  2686     unfolding SET_def by auto
  2687    hence "p1 a \<in> set1 c'" unfolding sset_def by auto
  2688    hence eq: "c = c'" using p1a c c' set1_disj by auto
  2689    hence "a \<in> sset c" using ac' by simp
  2690   } note p1_rev = this
  2691   {fix c a assume c: "c \<in> set_of P" and a: "a \<in> SET" and p2a: "p2 a \<in> set2 c"
  2692    then obtain c' where c': "c' \<in> set_of P" and ac': "a \<in> sset c'"
  2693    unfolding SET_def by auto
  2694    hence "p2 a \<in> set2 c'" unfolding sset_def by auto
  2695    hence eq: "c = c'" using p2a c c' set2_disj by auto
  2696    hence "a \<in> sset c" using ac' by simp
  2697   } note p2_rev = this
  2698 
  2699   have "\<forall> a \<in> SET. \<exists> c \<in> set_of P. a \<in> sset c" unfolding SET_def by auto
  2700   then obtain h where h: "\<forall> a \<in> SET. h a \<in> set_of P \<and> a \<in> sset (h a)" by metis
  2701   have h_u[simp]: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2702                       \<Longrightarrow> h (u c b1 b2) = c"
  2703   by (metis h p2 set2 u(3) u_SET)
  2704   have h_u1: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2705                       \<Longrightarrow> h (u c b1 b2) = f1 b1"
  2706   using h unfolding sset_def by auto
  2707   have h_u2: "\<And> c b1 b2. \<lbrakk>c \<in> set_of P; b1 \<in> set1 c; b2 \<in> set2 c\<rbrakk>
  2708                       \<Longrightarrow> h (u c b1 b2) = f2 b2"
  2709   using h unfolding sset_def by auto
  2710   def M \<equiv>
  2711     "Abs_multiset (\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0)"
  2712   have "(\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0) \<in> multiset"
  2713     unfolding multiset_def by auto
  2714   hence [transfer_rule]: "pcr_multiset op = (\<lambda> a. if a \<in> SET \<and> p1 a \<in> set_of N1 \<and> p2 a \<in> set_of N2 then Ms (h a) a else 0) M"
  2715     unfolding M_def pcr_multiset_def cr_multiset_def by (auto simp: Abs_multiset_inverse)
  2716   have sM: "set_of M \<subseteq> SET" "set_of M \<subseteq> p1 -` (set_of N1)" "set_of M \<subseteq> p2 -` set_of N2"
  2717     by (transfer, auto split: split_if_asm)+
  2718   show "\<exists>M. set_of M \<subseteq> A \<and> mmap p1 M = N1 \<and> mmap p2 M = N2"
  2719   proof(rule exI[of _ M], safe)
  2720     fix a assume *: "a \<in> set_of M"
  2721     from SET_A show "a \<in> A"
  2722     proof (cases "a \<in> SET")
  2723       case False thus ?thesis using * by transfer' auto
  2724     qed blast
  2725   next
  2726     show "mmap p1 M = N1"
  2727     proof(intro multiset_eqI)
  2728       fix b1
  2729       let ?K = "{a. p1 a = b1 \<and> a \<in># M}"
  2730       have "setsum (count M) ?K = count N1 b1"
  2731       proof(cases "b1 \<in> set_of N1")
  2732         case False
  2733         hence "?K = {}" using sM(2) by auto
  2734         thus ?thesis using False by auto
  2735       next
  2736         case True
  2737         def c \<equiv> "f1 b1"
  2738         have c: "c \<in> set_of P" and b1: "b1 \<in> set1 c"
  2739           unfolding set1_def c_def P1 using True by (auto simp: comp_eq_dest[OF set_of_mmap])
  2740         with sM(1) have "setsum (count M) ?K = setsum (count M) {a. p1 a = b1 \<and> a \<in> SET}"
  2741           by transfer (force intro: setsum.mono_neutral_cong_left split: split_if_asm)
  2742         also have "... = setsum (count M) ((\<lambda> b2. u c b1 b2) ` (set2 c))"
  2743           apply(rule setsum.cong) using c b1 proof safe
  2744           fix a assume p1a: "p1 a \<in> set1 c" and "c \<in> set_of P" and "a \<in> SET"
  2745           hence ac: "a \<in> sset c" using p1_rev by auto
  2746           hence "a = u c (p1 a) (p2 a)" using c by auto
  2747           moreover have "p2 a \<in> set2 c" using ac c by auto
  2748           ultimately show "a \<in> u c (p1 a) ` set2 c" by auto
  2749         qed auto
  2750         also have "... = setsum (\<lambda> b2. count M (u c b1 b2)) (set2 c)"
  2751           unfolding comp_def[symmetric] apply(rule setsum.reindex)
  2752           using inj unfolding inj_on_def inj2_def using b1 c u(3) by blast
  2753         also have "... = count N1 b1" unfolding ss1[OF c b1, symmetric]
  2754           apply(rule setsum.cong[OF refl]) apply (transfer fixing: Ms u c b1 set2)
  2755           using True h_u[OF c b1] set2_def u(2,3)[OF c b1] u_SET[OF c b1]
  2756             [[hypsubst_thin = true]]
  2757           by fastforce
  2758         finally show ?thesis .
  2759       qed
  2760       thus "count (mmap p1 M) b1 = count N1 b1" by transfer
  2761     qed
  2762   next
  2763     show "mmap p2 M = N2"
  2764     proof(intro multiset_eqI)
  2765       fix b2
  2766       let ?K = "{a. p2 a = b2 \<and> a \<in># M}"
  2767       have "setsum (count M) ?K = count N2 b2"
  2768       proof(cases "b2 \<in> set_of N2")
  2769         case False
  2770         hence "?K = {}" using sM(3) by auto
  2771         thus ?thesis using False by auto
  2772       next
  2773         case True
  2774         def c \<equiv> "f2 b2"
  2775         have c: "c \<in> set_of P" and b2: "b2 \<in> set2 c"
  2776           unfolding set2_def c_def P2 using True by (auto simp: comp_eq_dest[OF set_of_mmap])
  2777         with sM(1) have "setsum (count M) ?K = setsum (count M) {a. p2 a = b2 \<and> a \<in> SET}"
  2778           by transfer (force intro: setsum.mono_neutral_cong_left split: split_if_asm)
  2779         also have "... = setsum (count M) ((\<lambda> b1. u c b1 b2) ` (set1 c))"
  2780           apply(rule setsum.cong) using c b2 proof safe
  2781           fix a assume p2a: "p2 a \<in> set2 c" and "c \<in> set_of P" and "a \<in> SET"
  2782           hence ac: "a \<in> sset c" using p2_rev by auto
  2783           hence "a = u c (p1 a) (p2 a)" using c by auto
  2784           moreover have "p1 a \<in> set1 c" using ac c by auto
  2785           ultimately show "a \<in> (\<lambda>x. u c x (p2 a)) ` set1 c" by auto
  2786         qed auto
  2787         also have "... = setsum (count M o (\<lambda> b1. u c b1 b2)) (set1 c)"
  2788           apply(rule setsum.reindex)
  2789           using inj unfolding inj_on_def inj2_def using b2 c u(2) by blast
  2790         also have "... = setsum (\<lambda> b1. count M (u c b1 b2)) (set1 c)" by simp
  2791         also have "... = count N2 b2" unfolding ss2[OF c b2, symmetric] comp_def
  2792           apply(rule setsum.cong[OF refl]) apply (transfer fixing: Ms u c b2 set1)
  2793           using True h_u1[OF c _ b2] u(2,3)[OF c _ b2] u_SET[OF c _ b2] set1_def
  2794             [[hypsubst_thin = true]]
  2795           by fastforce
  2796         finally show ?thesis .
  2797       qed
  2798       thus "count (mmap p2 M) b2 = count N2 b2" by transfer
  2799     qed
  2800   qed
  2801 qed
  2802 
  2803 lemma set_of_bd: "(card_of (set_of x), natLeq) \<in> ordLeq"
  2804   by transfer
  2805     (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2806 
  2807 lemma wppull_mmap:
  2808   assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
  2809   shows "wppull {M. set_of M \<subseteq> A} {N1. set_of N1 \<subseteq> B1} {N2. set_of N2 \<subseteq> B2}
  2810     (mmap f1) (mmap f2) (mmap e1) (mmap e2) (mmap p1) (mmap p2)"
  2811 proof -
  2812   from assms obtain j where j: "\<forall>a'\<in>thePull B1 B2 f1 f2.
  2813     j a' \<in> A \<and> e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')" 
  2814     by (blast dest: wppull_thePull)
  2815   then show ?thesis
  2816     by (intro wpull_wppull[OF wpull_mmap[OF wpull_thePull], of _ _ _ _ "mmap j"])
  2817       (auto simp: comp_eq_dest_lhs[OF mmap_comp[symmetric]] comp_eq_dest[OF set_of_mmap]
  2818         intro!: mmap_cong simp del: mem_set_of_iff simp: mem_set_of_iff[symmetric])
  2819 qed
  2820 
  2821 bnf "'a multiset"
  2822   map: mmap
  2823   sets: set_of 
  2824   bd: natLeq
  2825   wits: "{#}"
  2826 by (auto simp add: mmap_id0 mmap_comp set_of_mmap natLeq_card_order natLeq_cinfinite set_of_bd
  2827   Grp_def relcompp.simps intro: mmap_cong)
  2828   (metis wppull_mmap[OF wppull_fstOp_sndOp, unfolded wppull_def
  2829     o_eq_dest_lhs[OF mmap_comp[symmetric]] fstOp_def sndOp_def comp_def, simplified])
  2830 
  2831 inductive rel_multiset' where
  2832   Zero[intro]: "rel_multiset' R {#} {#}"
  2833 | Plus[intro]: "\<lbrakk>R a b; rel_multiset' R M N\<rbrakk> \<Longrightarrow> rel_multiset' R (M + {#a#}) (N + {#b#})"
  2834 
  2835 lemma map_multiset_Zero_iff[simp]: "mmap f M = {#} \<longleftrightarrow> M = {#}"
  2836 by (metis image_is_empty multiset.set_map set_of_eq_empty_iff)
  2837 
  2838 lemma map_multiset_Zero[simp]: "mmap f {#} = {#}" by simp
  2839 
  2840 lemma rel_multiset_Zero: "rel_multiset R {#} {#}"
  2841 unfolding rel_multiset_def Grp_def by auto
  2842 
  2843 declare multiset.count[simp]
  2844 declare Abs_multiset_inverse[simp]
  2845 declare multiset.count_inverse[simp]
  2846 declare union_preserves_multiset[simp]
  2847 
  2848 lemma map_multiset_Plus[simp]: "mmap f (M1 + M2) = mmap f M1 + mmap f M2"
  2849 proof (intro multiset_eqI, transfer fixing: f)
  2850   fix x :: 'a and M1 M2 :: "'b \<Rightarrow> nat"
  2851   assume "M1 \<in> multiset" "M2 \<in> multiset"
  2852   hence "setsum M1 {a. f a = x \<and> 0 < M1 a} = setsum M1 {a. f a = x \<and> 0 < M1 a + M2 a}"
  2853         "setsum M2 {a. f a = x \<and> 0 < M2 a} = setsum M2 {a. f a = x \<and> 0 < M1 a + M2 a}"
  2854     by (auto simp: multiset_def intro!: setsum.mono_neutral_cong_left)
  2855   then show "(\<Sum>a | f a = x \<and> 0 < M1 a + M2 a. M1 a + M2 a) =
  2856        setsum M1 {a. f a = x \<and> 0 < M1 a} +
  2857        setsum M2 {a. f a = x \<and> 0 < M2 a}"
  2858     by (auto simp: setsum.distrib[symmetric])
  2859 qed
  2860 
  2861 lemma map_multiset_single[simp]: "mmap f {#a#} = {#f a#}"
  2862   by transfer auto
  2863 
  2864 lemma rel_multiset_Plus:
  2865 assumes ab: "R a b" and MN: "rel_multiset R M N"
  2866 shows "rel_multiset R (M + {#a#}) (N + {#b#})"
  2867 proof-
  2868   {fix y assume "R a b" and "set_of y \<subseteq> {(x, y). R x y}"
  2869    hence "\<exists>ya. mmap fst y + {#a#} = mmap fst ya \<and>
  2870                mmap snd y + {#b#} = mmap snd ya \<and>
  2871                set_of ya \<subseteq> {(x, y). R x y}"
  2872    apply(intro exI[of _ "y + {#(a,b)#}"]) by auto
  2873   }
  2874   thus ?thesis
  2875   using assms
  2876   unfolding rel_multiset_def Grp_def by force
  2877 qed
  2878 
  2879 lemma rel_multiset'_imp_rel_multiset:
  2880 "rel_multiset' R M N \<Longrightarrow> rel_multiset R M N"
  2881 apply(induct rule: rel_multiset'.induct)
  2882 using rel_multiset_Zero rel_multiset_Plus by auto
  2883 
  2884 lemma mcard_mmap[simp]: "mcard (mmap f M) = mcard M"
  2885 proof -
  2886   def A \<equiv> "\<lambda> b. {a. f a = b \<and> a \<in># M}"
  2887   let ?B = "{b. 0 < setsum (count M) (A b)}"
  2888   have "{b. \<exists>a. f a = b \<and> a \<in># M} \<subseteq> f ` {a. a \<in># M}" by auto
  2889   moreover have "finite (f ` {a. a \<in># M})" apply(rule finite_imageI)
  2890   using finite_Collect_mem .
  2891   ultimately have fin: "finite {b. \<exists>a. f a = b \<and> a \<in># M}" by(rule finite_subset)
  2892   have i: "inj_on A ?B" unfolding inj_on_def A_def apply clarsimp
  2893     by (metis (lifting, full_types) mem_Collect_eq neq0_conv setsum.neutral)
  2894   have 0: "\<And> b. 0 < setsum (count M) (A b) \<longleftrightarrow> (\<exists> a \<in> A b. count M a > 0)"
  2895   apply safe
  2896     apply (metis less_not_refl setsum_gt_0_iff setsum.infinite)
  2897     by (metis A_def finite_Collect_conjI finite_Collect_mem setsum_gt_0_iff)
  2898   hence AB: "A ` ?B = {A b | b. \<exists> a \<in> A b. count M a > 0}" by auto
  2899 
  2900   have "setsum (\<lambda> x. setsum (count M) (A x)) ?B = setsum (setsum (count M) o A) ?B"
  2901   unfolding comp_def ..
  2902   also have "... = (\<Sum>x\<in> A ` ?B. setsum (count M) x)"
  2903   unfolding setsum.reindex [OF i, symmetric] ..
  2904   also have "... = setsum (count M) (\<Union>x\<in>A ` {b. 0 < setsum (count M) (A b)}. x)"
  2905   (is "_ = setsum (count M) ?J")
  2906   apply(rule setsum.UNION_disjoint[symmetric])
  2907   using 0 fin unfolding A_def by auto
  2908   also have "?J = {a. a \<in># M}" unfolding AB unfolding A_def by auto
  2909   finally have "setsum (\<lambda> x. setsum (count M) (A x)) ?B =
  2910                 setsum (count M) {a. a \<in># M}" .
  2911   then show ?thesis unfolding mcard_unfold_setsum A_def by transfer
  2912 qed
  2913 
  2914 lemma rel_multiset_mcard:
  2915 assumes "rel_multiset R M N"
  2916 shows "mcard M = mcard N"
  2917 using assms unfolding rel_multiset_def Grp_def by auto
  2918 
  2919 lemma multiset_induct2[case_names empty addL addR]:
  2920 assumes empty: "P {#} {#}"
  2921 and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2922 and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2923 shows "P M N"
  2924 apply(induct N rule: multiset_induct)
  2925   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2926   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2927 done
  2928 
  2929 lemma multiset_induct2_mcard[consumes 1, case_names empty add]:
  2930 assumes c: "mcard M = mcard N"
  2931 and empty: "P {#} {#}"
  2932 and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2933 shows "P M N"
  2934 using c proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
  2935   case (less M)  show ?case
  2936   proof(cases "M = {#}")
  2937     case True hence "N = {#}" using less.prems by auto
  2938     thus ?thesis using True empty by auto
  2939   next
  2940     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2941     have "N \<noteq> {#}" using False less.prems by auto
  2942     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2943     have "mcard M1 = mcard N1" using less.prems unfolding M N by auto
  2944     thus ?thesis using M N less.hyps add by auto
  2945   qed
  2946 qed
  2947 
  2948 lemma msed_map_invL:
  2949 assumes "mmap f (M + {#a#}) = N"
  2950 shows "\<exists> N1. N = N1 + {#f a#} \<and> mmap f M = N1"
  2951 proof-
  2952   have "f a \<in># N"
  2953   using assms multiset.set_map[of f "M + {#a#}"] by auto
  2954   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2955   have "mmap f M = N1" using assms unfolding N by simp
  2956   thus ?thesis using N by blast
  2957 qed
  2958 
  2959 lemma msed_map_invR:
  2960 assumes "mmap f M = N + {#b#}"
  2961 shows "\<exists> M1 a. M = M1 + {#a#} \<and> f a = b \<and> mmap f M1 = N"
  2962 proof-
  2963   obtain a where a: "a \<in># M" and fa: "f a = b"
  2964   using multiset.set_map[of f M] unfolding assms
  2965   by (metis image_iff mem_set_of_iff union_single_eq_member)
  2966   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2967   have "mmap f M1 = N" using assms unfolding M fa[symmetric] by simp
  2968   thus ?thesis using M fa by blast
  2969 qed
  2970 
  2971 lemma msed_rel_invL:
  2972 assumes "rel_multiset R (M + {#a#}) N"
  2973 shows "\<exists> N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_multiset R M N1"
  2974 proof-
  2975   obtain K where KM: "mmap fst K = M + {#a#}"
  2976   and KN: "mmap snd K = N" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2977   using assms
  2978   unfolding rel_multiset_def Grp_def by auto
  2979   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2980   and K1M: "mmap fst K1 = M" using msed_map_invR[OF KM] by auto
  2981   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "mmap snd K1 = N1"
  2982   using msed_map_invL[OF KN[unfolded K]] by auto
  2983   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2984   have "rel_multiset R M N1" using sK K1M K1N1
  2985   unfolding K rel_multiset_def Grp_def by auto
  2986   thus ?thesis using N Rab by auto
  2987 qed
  2988 
  2989 lemma msed_rel_invR:
  2990 assumes "rel_multiset R M (N + {#b#})"
  2991 shows "\<exists> M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_multiset R M1 N"
  2992 proof-
  2993   obtain K where KN: "mmap snd K = N + {#b#}"
  2994   and KM: "mmap fst K = M" and sK: "set_of K \<subseteq> {(a, b). R a b}"
  2995   using assms
  2996   unfolding rel_multiset_def Grp_def by auto
  2997   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2998   and K1N: "mmap snd K1 = N" using msed_map_invR[OF KN] by auto
  2999   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "mmap fst K1 = M1"
  3000   using msed_map_invL[OF KM[unfolded K]] by auto
  3001   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  3002   have "rel_multiset R M1 N" using sK K1N K1M1
  3003   unfolding K rel_multiset_def Grp_def by auto
  3004   thus ?thesis using M Rab by auto
  3005 qed
  3006 
  3007 lemma rel_multiset_imp_rel_multiset':
  3008 assumes "rel_multiset R M N"
  3009 shows "rel_multiset' R M N"
  3010 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of mcard])
  3011   case (less M)
  3012   have c: "mcard M = mcard N" using rel_multiset_mcard[OF less.prems] .
  3013   show ?case
  3014   proof(cases "M = {#}")
  3015     case True hence "N = {#}" using c by simp
  3016     thus ?thesis using True rel_multiset'.Zero by auto
  3017   next
  3018     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  3019     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_multiset R M1 N1"
  3020     using msed_rel_invL[OF less.prems[unfolded M]] by auto
  3021     have "rel_multiset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  3022     thus ?thesis using rel_multiset'.Plus[of R a b, OF R] unfolding M N by simp
  3023   qed
  3024 qed
  3025 
  3026 lemma rel_multiset_rel_multiset':
  3027 "rel_multiset R M N = rel_multiset' R M N"
  3028 using  rel_multiset_imp_rel_multiset' rel_multiset'_imp_rel_multiset by auto
  3029 
  3030 (* The main end product for rel_multiset: inductive characterization *)
  3031 theorems rel_multiset_induct[case_names empty add, induct pred: rel_multiset] =
  3032          rel_multiset'.induct[unfolded rel_multiset_rel_multiset'[symmetric]]
  3033 
  3034 
  3035 subsection {* Size setup *}
  3036 
  3037 lemma multiset_size_o_map: "size_multiset g \<circ> mmap f = size_multiset (g \<circ> f)"
  3038 apply (rule ext)
  3039 apply (unfold o_apply)
  3040 apply (induct_tac x)
  3041 apply auto
  3042 done
  3043 
  3044 setup {*
  3045 BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  3046   @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  3047     size_union}
  3048   @{thms multiset_size_o_map}
  3049 *}
  3050 
  3051 hide_const (open) wcount
  3052 
  3053 end