src/HOL/Library/FuncSet.thy
 author haftmann Mon Jun 05 15:59:41 2017 +0200 (2017-06-05) changeset 66010 2f7d39285a1a parent 64917 5db5b8cf6dc6 child 66453 cc19f7ca2ed6 permissions -rw-r--r--
executable domain membership checks
```     1 (*  Title:      HOL/Library/FuncSet.thy
```
```     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
```
```     3 *)
```
```     4
```
```     5 section \<open>Pi and Function Sets\<close>
```
```     6
```
```     7 theory FuncSet
```
```     8   imports Hilbert_Choice Main
```
```     9   abbrevs PiE = "Pi\<^sub>E"
```
```    10     PIE = "\<Pi>\<^sub>E"
```
```    11 begin
```
```    12
```
```    13 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
```
```    14   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
```
```    15
```
```    16 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
```
```    17   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
```
```    18
```
```    19 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
```
```    20   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
```
```    21
```
```    22 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "\<rightarrow>" 60)
```
```    23   where "A \<rightarrow> B \<equiv> Pi A (\<lambda>_. B)"
```
```    24
```
```    25 syntax
```
```    26   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
```
```    27   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
```
```    28 translations
```
```    29   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
```
```    30   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
```
```    31
```
```    32 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
```
```    33   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
```
```    34
```
```    35
```
```    36 subsection \<open>Basic Properties of @{term Pi}\<close>
```
```    37
```
```    38 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
```
```    39   by (simp add: Pi_def)
```
```    40
```
```    41 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
```
```    42   by (simp add:Pi_def)
```
```    43
```
```    44 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
```
```    45   by (simp add: Pi_def)
```
```    46
```
```    47 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
```
```    48   by (simp add: Pi_def)
```
```    49
```
```    50 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
```
```    51   unfolding Pi_def by auto
```
```    52
```
```    53 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
```
```    54   by (auto simp: Pi_def)
```
```    55
```
```    56 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
```
```    57   by (auto simp: Pi_def)
```
```    58
```
```    59 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
```
```    60   by auto
```
```    61
```
```    62 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
```
```    63   by (simp add: Pi_def)
```
```    64
```
```    65 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
```
```    66   by auto
```
```    67
```
```    68 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
```
```    69   by auto
```
```    70
```
```    71 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
```
```    72   apply (simp add: Pi_def)
```
```    73   apply auto
```
```    74   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
```
```    75   picking an element from each non-empty @{term "B x"}\<close>
```
```    76   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
```
```    77   apply auto
```
```    78   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
```
```    79   apply auto
```
```    80   done
```
```    81
```
```    82 lemma Pi_empty [simp]: "Pi {} B = UNIV"
```
```    83   by (simp add: Pi_def)
```
```    84
```
```    85 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
```
```    86   by auto
```
```    87
```
```    88 lemma Pi_UN:
```
```    89   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
```
```    90   assumes "finite I"
```
```    91     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
```
```    92   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
```
```    93 proof (intro set_eqI iffI)
```
```    94   fix f
```
```    95   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
```
```    96   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
```
```    97     by auto
```
```    98   from bchoice[OF this] obtain n where n: "f i \<in> A (n i) i" if "i \<in> I" for i
```
```    99     by auto
```
```   100   obtain k where k: "n i \<le> k" if "i \<in> I" for i
```
```   101     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
```
```   102   have "f \<in> Pi I (A k)"
```
```   103   proof (intro Pi_I)
```
```   104     fix i
```
```   105     assume "i \<in> I"
```
```   106     from mono[OF this, of "n i" k] k[OF this] n[OF this]
```
```   107     show "f i \<in> A k i" by auto
```
```   108   qed
```
```   109   then show "f \<in> (\<Union>n. Pi I (A n))"
```
```   110     by auto
```
```   111 qed auto
```
```   112
```
```   113 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
```
```   114   by (simp add: Pi_def)
```
```   115
```
```   116 text \<open>Covariance of Pi-sets in their second argument\<close>
```
```   117 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
```
```   118   by auto
```
```   119
```
```   120 text \<open>Contravariance of Pi-sets in their first argument\<close>
```
```   121 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
```
```   122   by auto
```
```   123
```
```   124 lemma prod_final:
```
```   125   assumes 1: "fst \<circ> f \<in> Pi A B"
```
```   126     and 2: "snd \<circ> f \<in> Pi A C"
```
```   127   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
```
```   128 proof (rule Pi_I)
```
```   129   fix z
```
```   130   assume z: "z \<in> A"
```
```   131   have "f z = (fst (f z), snd (f z))"
```
```   132     by simp
```
```   133   also have "\<dots> \<in> B z \<times> C z"
```
```   134     by (metis SigmaI PiE o_apply 1 2 z)
```
```   135   finally show "f z \<in> B z \<times> C z" .
```
```   136 qed
```
```   137
```
```   138 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
```
```   139   by (auto simp: Pi_def)
```
```   140
```
```   141 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
```
```   142   by (auto simp: Pi_def)
```
```   143
```
```   144 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
```
```   145   by (auto simp: Pi_def)
```
```   146
```
```   147 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
```
```   148   by (auto simp: Pi_def)
```
```   149
```
```   150 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
```
```   151   apply auto
```
```   152   apply (drule_tac x=x in Pi_mem)
```
```   153   apply (simp_all split: if_split_asm)
```
```   154   apply (drule_tac x=i in Pi_mem)
```
```   155   apply (auto dest!: Pi_mem)
```
```   156   done
```
```   157
```
```   158
```
```   159 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
```
```   160
```
```   161 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
```
```   162   by (simp add: Pi_def compose_def restrict_def)
```
```   163
```
```   164 lemma compose_assoc:
```
```   165   assumes "f \<in> A \<rightarrow> B"
```
```   166     and "g \<in> B \<rightarrow> C"
```
```   167     and "h \<in> C \<rightarrow> D"
```
```   168   shows "compose A h (compose A g f) = compose A (compose B h g) f"
```
```   169   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
```
```   170
```
```   171 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
```
```   172   by (simp add: compose_def restrict_def)
```
```   173
```
```   174 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
```
```   175   by (auto simp add: image_def compose_eq)
```
```   176
```
```   177
```
```   178 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
```
```   179
```
```   180 lemma restrict_cong: "I = J \<Longrightarrow> (\<And>i. i \<in> J =simp=> f i = g i) \<Longrightarrow> restrict f I = restrict g J"
```
```   181   by (auto simp: restrict_def fun_eq_iff simp_implies_def)
```
```   182
```
```   183 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
```
```   184   by (simp add: Pi_def restrict_def)
```
```   185
```
```   186 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
```
```   187   by (simp add: Pi_def restrict_def)
```
```   188
```
```   189 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
```
```   190   by (simp add: restrict_def)
```
```   191
```
```   192 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
```
```   193   by simp
```
```   194
```
```   195 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
```
```   196   by (simp add: fun_eq_iff Pi_def restrict_def)
```
```   197
```
```   198 lemma restrict_UNIV: "restrict f UNIV = f"
```
```   199   by (simp add: restrict_def)
```
```   200
```
```   201 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
```
```   202   by (simp add: inj_on_def restrict_def)
```
```   203
```
```   204 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
```
```   205   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
```
```   206
```
```   207 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
```
```   208   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
```
```   209
```
```   210 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
```
```   211   by (auto simp add: restrict_def)
```
```   212
```
```   213 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
```
```   214   unfolding restrict_def by (simp add: fun_eq_iff)
```
```   215
```
```   216 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
```
```   217   by (auto simp: restrict_def)
```
```   218
```
```   219 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
```
```   220   by (auto simp: fun_eq_iff)
```
```   221
```
```   222 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
```
```   223   by (auto simp: restrict_def Pi_def)
```
```   224
```
```   225
```
```   226 subsection \<open>Bijections Between Sets\<close>
```
```   227
```
```   228 text \<open>The definition of @{const bij_betw} is in \<open>Fun.thy\<close>, but most of
```
```   229 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
```
```   230
```
```   231 lemma bij_betwI:
```
```   232   assumes "f \<in> A \<rightarrow> B"
```
```   233     and "g \<in> B \<rightarrow> A"
```
```   234     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
```
```   235     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
```
```   236   shows "bij_betw f A B"
```
```   237   unfolding bij_betw_def
```
```   238 proof
```
```   239   show "inj_on f A"
```
```   240     by (metis g_f inj_on_def)
```
```   241   have "f ` A \<subseteq> B"
```
```   242     using \<open>f \<in> A \<rightarrow> B\<close> by auto
```
```   243   moreover
```
```   244   have "B \<subseteq> f ` A"
```
```   245     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
```
```   246   ultimately show "f ` A = B"
```
```   247     by blast
```
```   248 qed
```
```   249
```
```   250 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
```
```   251   by (auto simp add: bij_betw_def)
```
```   252
```
```   253 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
```
```   254   by (auto simp add: bij_betw_def inj_on_def compose_eq)
```
```   255
```
```   256 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
```
```   257   apply (simp add: bij_betw_def compose_eq inj_on_compose)
```
```   258   apply (auto simp add: compose_def image_def)
```
```   259   done
```
```   260
```
```   261 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
```
```   262   by (simp add: bij_betw_def)
```
```   263
```
```   264
```
```   265 subsection \<open>Extensionality\<close>
```
```   266
```
```   267 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
```
```   268   unfolding extensional_def by auto
```
```   269
```
```   270 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
```
```   271   by (simp add: extensional_def)
```
```   272
```
```   273 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
```
```   274   by (simp add: restrict_def extensional_def)
```
```   275
```
```   276 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
```
```   277   by (simp add: compose_def)
```
```   278
```
```   279 lemma extensionalityI:
```
```   280   assumes "f \<in> extensional A"
```
```   281     and "g \<in> extensional A"
```
```   282     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
```
```   283   shows "f = g"
```
```   284   using assms by (force simp add: fun_eq_iff extensional_def)
```
```   285
```
```   286 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
```
```   287   by (rule extensionalityI[OF restrict_extensional]) auto
```
```   288
```
```   289 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
```
```   290   unfolding extensional_def by auto
```
```   291
```
```   292 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
```
```   293   by (unfold inv_into_def) (fast intro: someI2)
```
```   294
```
```   295 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
```
```   296   apply (simp add: bij_betw_def compose_def)
```
```   297   apply (rule restrict_ext, auto)
```
```   298   done
```
```   299
```
```   300 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
```
```   301   apply (simp add: compose_def)
```
```   302   apply (rule restrict_ext)
```
```   303   apply (simp add: f_inv_into_f)
```
```   304   done
```
```   305
```
```   306 lemma extensional_insert[intro, simp]:
```
```   307   assumes "a \<in> extensional (insert i I)"
```
```   308   shows "a(i := b) \<in> extensional (insert i I)"
```
```   309   using assms unfolding extensional_def by auto
```
```   310
```
```   311 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
```
```   312   unfolding extensional_def by auto
```
```   313
```
```   314 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
```
```   315   by (auto simp: extensional_def)
```
```   316
```
```   317 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
```
```   318   unfolding restrict_def extensional_def by auto
```
```   319
```
```   320 lemma extensional_insert_undefined[intro, simp]:
```
```   321   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
```
```   322   unfolding extensional_def by auto
```
```   323
```
```   324 lemma extensional_insert_cancel[intro, simp]:
```
```   325   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
```
```   326   unfolding extensional_def by auto
```
```   327
```
```   328
```
```   329 subsection \<open>Cardinality\<close>
```
```   330
```
```   331 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
```
```   332   by (rule card_inj_on_le) auto
```
```   333
```
```   334 lemma card_bij:
```
```   335   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
```
```   336     and "g \<in> B \<rightarrow> A" "inj_on g B"
```
```   337     and "finite A" "finite B"
```
```   338   shows "card A = card B"
```
```   339   using assms by (blast intro: card_inj order_antisym)
```
```   340
```
```   341
```
```   342 subsection \<open>Extensional Function Spaces\<close>
```
```   343
```
```   344 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
```
```   345   where "PiE S T = Pi S T \<inter> extensional S"
```
```   346
```
```   347 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
```
```   348
```
```   349 syntax
```
```   350   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
```
```   351 translations
```
```   352   "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
```
```   353
```
```   354 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "\<rightarrow>\<^sub>E" 60)
```
```   355   where "A \<rightarrow>\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
```
```   356
```
```   357 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
```
```   358   by (simp add: PiE_def)
```
```   359
```
```   360 lemma PiE_empty_domain[simp]: "Pi\<^sub>E {} T = {\<lambda>x. undefined}"
```
```   361   unfolding PiE_def by simp
```
```   362
```
```   363 lemma PiE_UNIV_domain: "Pi\<^sub>E UNIV T = Pi UNIV T"
```
```   364   unfolding PiE_def by simp
```
```   365
```
```   366 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
```
```   367   unfolding PiE_def by auto
```
```   368
```
```   369 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
```
```   370 proof
```
```   371   assume "Pi\<^sub>E I F = {}"
```
```   372   show "\<exists>i\<in>I. F i = {}"
```
```   373   proof (rule ccontr)
```
```   374     assume "\<not> ?thesis"
```
```   375     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
```
```   376       by auto
```
```   377     from choice[OF this]
```
```   378     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
```
```   379     then have "f \<in> Pi\<^sub>E I F"
```
```   380       by (auto simp: extensional_def PiE_def)
```
```   381     with \<open>Pi\<^sub>E I F = {}\<close> show False
```
```   382       by auto
```
```   383   qed
```
```   384 qed (auto simp: PiE_def)
```
```   385
```
```   386 lemma PiE_arb: "f \<in> Pi\<^sub>E S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
```
```   387   unfolding PiE_def by auto (auto dest!: extensional_arb)
```
```   388
```
```   389 lemma PiE_mem: "f \<in> Pi\<^sub>E S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
```
```   390   unfolding PiE_def by auto
```
```   391
```
```   392 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> Pi\<^sub>E S T \<Longrightarrow> f(x := y) \<in> Pi\<^sub>E (insert x S) T"
```
```   393   unfolding PiE_def extensional_def by auto
```
```   394
```
```   395 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> Pi\<^sub>E (insert x S) T \<Longrightarrow> f(x := undefined) \<in> Pi\<^sub>E S T"
```
```   396   unfolding PiE_def extensional_def by auto
```
```   397
```
```   398 lemma PiE_insert_eq: "Pi\<^sub>E (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
```
```   399 proof -
```
```   400   {
```
```   401     fix f assume "f \<in> Pi\<^sub>E (insert x S) T" "x \<notin> S"
```
```   402     then have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
```
```   403       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
```
```   404   }
```
```   405   moreover
```
```   406   {
```
```   407     fix f assume "f \<in> Pi\<^sub>E (insert x S) T" "x \<in> S"
```
```   408     then have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
```
```   409       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
```
```   410   }
```
```   411   ultimately show ?thesis
```
```   412     by (auto intro: PiE_fun_upd)
```
```   413 qed
```
```   414
```
```   415 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
```
```   416   by (auto simp: PiE_def)
```
```   417
```
```   418 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
```
```   419   unfolding PiE_def by (auto simp: Pi_cong)
```
```   420
```
```   421 lemma PiE_E [elim]:
```
```   422   assumes "f \<in> Pi\<^sub>E A B"
```
```   423   obtains "x \<in> A" and "f x \<in> B x"
```
```   424     | "x \<notin> A" and "f x = undefined"
```
```   425   using assms by (auto simp: Pi_def PiE_def extensional_def)
```
```   426
```
```   427 lemma PiE_I[intro!]:
```
```   428   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> Pi\<^sub>E A B"
```
```   429   by (simp add: PiE_def extensional_def)
```
```   430
```
```   431 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi\<^sub>E A B \<subseteq> Pi\<^sub>E A C"
```
```   432   by auto
```
```   433
```
```   434 lemma PiE_iff: "f \<in> Pi\<^sub>E I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
```
```   435   by (simp add: PiE_def Pi_iff)
```
```   436
```
```   437 lemma PiE_restrict[simp]:  "f \<in> Pi\<^sub>E A B \<Longrightarrow> restrict f A = f"
```
```   438   by (simp add: extensional_restrict PiE_def)
```
```   439
```
```   440 lemma restrict_PiE[simp]: "restrict f I \<in> Pi\<^sub>E I S \<longleftrightarrow> f \<in> Pi I S"
```
```   441   by (auto simp: PiE_iff)
```
```   442
```
```   443 lemma PiE_eq_subset:
```
```   444   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
```
```   445     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
```
```   446     and "i \<in> I"
```
```   447   shows "F i \<subseteq> F' i"
```
```   448 proof
```
```   449   fix x
```
```   450   assume "x \<in> F i"
```
```   451   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
```
```   452     by auto
```
```   453   from choice[OF this] obtain f
```
```   454     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
```
```   455   then have "f \<in> Pi\<^sub>E I F"
```
```   456     by (auto simp: extensional_def PiE_def)
```
```   457   then have "f \<in> Pi\<^sub>E I F'"
```
```   458     using assms by simp
```
```   459   then show "x \<in> F' i"
```
```   460     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
```
```   461 qed
```
```   462
```
```   463 lemma PiE_eq_iff_not_empty:
```
```   464   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
```
```   465   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
```
```   466 proof (intro iffI ballI)
```
```   467   fix i
```
```   468   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
```
```   469   assume i: "i \<in> I"
```
```   470   show "F i = F' i"
```
```   471     using PiE_eq_subset[of I F F', OF ne eq i]
```
```   472     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
```
```   473     by auto
```
```   474 qed (auto simp: PiE_def)
```
```   475
```
```   476 lemma PiE_eq_iff:
```
```   477   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
```
```   478 proof (intro iffI disjCI)
```
```   479   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
```
```   480   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
```
```   481   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
```
```   482     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
```
```   483   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
```
```   484     by auto
```
```   485 next
```
```   486   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
```
```   487   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
```
```   488     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
```
```   489 qed
```
```   490
```
```   491 lemma extensional_funcset_fun_upd_restricts_rangeI:
```
```   492   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
```
```   493   unfolding extensional_funcset_def extensional_def
```
```   494   apply auto
```
```   495   apply (case_tac "x = xa")
```
```   496   apply auto
```
```   497   done
```
```   498
```
```   499 lemma extensional_funcset_fun_upd_extends_rangeI:
```
```   500   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
```
```   501   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
```
```   502   using assms unfolding extensional_funcset_def extensional_def by auto
```
```   503
```
```   504
```
```   505 subsubsection \<open>Injective Extensional Function Spaces\<close>
```
```   506
```
```   507 lemma extensional_funcset_fun_upd_inj_onI:
```
```   508   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
```
```   509     and "inj_on f S"
```
```   510   shows "inj_on (f(x := a)) S"
```
```   511   using assms
```
```   512   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
```
```   513
```
```   514 lemma extensional_funcset_extend_domain_inj_on_eq:
```
```   515   assumes "x \<notin> S"
```
```   516   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
```
```   517     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
```
```   518   using assms
```
```   519   apply (auto del: PiE_I PiE_E)
```
```   520   apply (auto intro: extensional_funcset_fun_upd_inj_onI
```
```   521     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
```
```   522   apply (auto simp add: image_iff inj_on_def)
```
```   523   apply (rule_tac x="xa x" in exI)
```
```   524   apply (auto intro: PiE_mem del: PiE_I PiE_E)
```
```   525   apply (rule_tac x="xa(x := undefined)" in exI)
```
```   526   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
```
```   527   apply (auto dest!: PiE_mem split: if_split_asm)
```
```   528   done
```
```   529
```
```   530 lemma extensional_funcset_extend_domain_inj_onI:
```
```   531   assumes "x \<notin> S"
```
```   532   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
```
```   533   using assms
```
```   534   apply (auto intro!: inj_onI)
```
```   535   apply (metis fun_upd_same)
```
```   536   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
```
```   537   done
```
```   538
```
```   539
```
```   540 subsubsection \<open>Cardinality\<close>
```
```   541
```
```   542 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
```
```   543   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
```
```   544
```
```   545 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
```
```   546 proof (safe intro!: inj_onI ext)
```
```   547   fix f y g z
```
```   548   assume "x \<notin> S"
```
```   549   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
```
```   550   assume "f(x := y) = g(x := z)"
```
```   551   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
```
```   552     unfolding fun_eq_iff by auto
```
```   553   from this[of x] show "y = z" by simp
```
```   554   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
```
```   555     by (auto split: if_split_asm simp: PiE_def extensional_def)
```
```   556 qed
```
```   557
```
```   558 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
```
```   559 proof (induct rule: finite_induct)
```
```   560   case empty
```
```   561   then show ?case by auto
```
```   562 next
```
```   563   case (insert x S)
```
```   564   then show ?case
```
```   565     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
```
```   566 qed
```
```   567
```
```   568 end
```