src/HOL/Library/Mapping.thy
author haftmann
Mon Jun 05 15:59:41 2017 +0200 (2017-06-05)
changeset 66010 2f7d39285a1a
parent 63476 ff1d86b07751
child 66251 cd935b7cb3fb
permissions -rw-r--r--
executable domain membership checks
     1 (*  Title:      HOL/Library/Mapping.thy
     2     Author:     Florian Haftmann and Ondrej Kuncar
     3 *)
     4 
     5 section \<open>An abstract view on maps for code generation.\<close>
     6 
     7 theory Mapping
     8 imports Main
     9 begin
    10 
    11 subsection \<open>Parametricity transfer rules\<close>
    12 
    13 lemma map_of_foldr: "map_of xs = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) xs Map.empty"  (* FIXME move *)
    14   using map_add_map_of_foldr [of Map.empty] by auto
    15 
    16 context includes lifting_syntax
    17 begin
    18 
    19 lemma empty_parametric: "(A ===> rel_option B) Map.empty Map.empty"
    20   by transfer_prover
    21 
    22 lemma lookup_parametric: "((A ===> B) ===> A ===> B) (\<lambda>m k. m k) (\<lambda>m k. m k)"
    23   by transfer_prover
    24 
    25 lemma update_parametric:
    26   assumes [transfer_rule]: "bi_unique A"
    27   shows "(A ===> B ===> (A ===> rel_option B) ===> A ===> rel_option B)
    28     (\<lambda>k v m. m(k \<mapsto> v)) (\<lambda>k v m. m(k \<mapsto> v))"
    29   by transfer_prover
    30 
    31 lemma delete_parametric:
    32   assumes [transfer_rule]: "bi_unique A"
    33   shows "(A ===> (A ===> rel_option B) ===> A ===> rel_option B)
    34     (\<lambda>k m. m(k := None)) (\<lambda>k m. m(k := None))"
    35   by transfer_prover
    36 
    37 lemma is_none_parametric [transfer_rule]:
    38   "(rel_option A ===> HOL.eq) Option.is_none Option.is_none"
    39   by (auto simp add: Option.is_none_def rel_fun_def rel_option_iff split: option.split)
    40 
    41 lemma dom_parametric:
    42   assumes [transfer_rule]: "bi_total A"
    43   shows "((A ===> rel_option B) ===> rel_set A) dom dom"
    44   unfolding dom_def [abs_def] Option.is_none_def [symmetric] by transfer_prover
    45 
    46 lemma map_of_parametric [transfer_rule]:
    47   assumes [transfer_rule]: "bi_unique R1"
    48   shows "(list_all2 (rel_prod R1 R2) ===> R1 ===> rel_option R2) map_of map_of"
    49   unfolding map_of_def by transfer_prover
    50 
    51 lemma map_entry_parametric [transfer_rule]:
    52   assumes [transfer_rule]: "bi_unique A"
    53   shows "(A ===> (B ===> B) ===> (A ===> rel_option B) ===> A ===> rel_option B)
    54     (\<lambda>k f m. (case m k of None \<Rightarrow> m
    55       | Some v \<Rightarrow> m (k \<mapsto> (f v)))) (\<lambda>k f m. (case m k of None \<Rightarrow> m
    56       | Some v \<Rightarrow> m (k \<mapsto> (f v))))"
    57   by transfer_prover
    58 
    59 lemma tabulate_parametric:
    60   assumes [transfer_rule]: "bi_unique A"
    61   shows "(list_all2 A ===> (A ===> B) ===> A ===> rel_option B)
    62     (\<lambda>ks f. (map_of (map (\<lambda>k. (k, f k)) ks))) (\<lambda>ks f. (map_of (map (\<lambda>k. (k, f k)) ks)))"
    63   by transfer_prover
    64 
    65 lemma bulkload_parametric:
    66   "(list_all2 A ===> HOL.eq ===> rel_option A)
    67     (\<lambda>xs k. if k < length xs then Some (xs ! k) else None)
    68     (\<lambda>xs k. if k < length xs then Some (xs ! k) else None)"
    69 proof
    70   fix xs ys
    71   assume "list_all2 A xs ys"
    72   then show
    73     "(HOL.eq ===> rel_option A)
    74       (\<lambda>k. if k < length xs then Some (xs ! k) else None)
    75       (\<lambda>k. if k < length ys then Some (ys ! k) else None)"
    76     apply induct
    77      apply auto
    78     unfolding rel_fun_def
    79     apply clarsimp
    80     apply (case_tac xa)
    81      apply (auto dest: list_all2_lengthD list_all2_nthD)
    82     done
    83 qed
    84 
    85 lemma map_parametric:
    86   "((A ===> B) ===> (C ===> D) ===> (B ===> rel_option C) ===> A ===> rel_option D)
    87      (\<lambda>f g m. (map_option g \<circ> m \<circ> f)) (\<lambda>f g m. (map_option g \<circ> m \<circ> f))"
    88   by transfer_prover
    89 
    90 lemma combine_with_key_parametric:
    91   "((A ===> B ===> B ===> B) ===> (A ===> rel_option B) ===> (A ===> rel_option B) ===>
    92     (A ===> rel_option B)) (\<lambda>f m1 m2 x. combine_options (f x) (m1 x) (m2 x))
    93     (\<lambda>f m1 m2 x. combine_options (f x) (m1 x) (m2 x))"
    94   unfolding combine_options_def by transfer_prover
    95 
    96 lemma combine_parametric:
    97   "((B ===> B ===> B) ===> (A ===> rel_option B) ===> (A ===> rel_option B) ===>
    98     (A ===> rel_option B)) (\<lambda>f m1 m2 x. combine_options f (m1 x) (m2 x))
    99     (\<lambda>f m1 m2 x. combine_options f (m1 x) (m2 x))"
   100   unfolding combine_options_def by transfer_prover
   101 
   102 end
   103 
   104 
   105 subsection \<open>Type definition and primitive operations\<close>
   106 
   107 typedef ('a, 'b) mapping = "UNIV :: ('a \<rightharpoonup> 'b) set"
   108   morphisms rep Mapping ..
   109 
   110 setup_lifting type_definition_mapping
   111 
   112 lift_definition empty :: "('a, 'b) mapping"
   113   is Map.empty parametric empty_parametric .
   114 
   115 lift_definition lookup :: "('a, 'b) mapping \<Rightarrow> 'a \<Rightarrow> 'b option"
   116   is "\<lambda>m k. m k" parametric lookup_parametric .
   117 
   118 definition "lookup_default d m k = (case Mapping.lookup m k of None \<Rightarrow> d | Some v \<Rightarrow> v)"
   119 
   120 declare [[code drop: Mapping.lookup]]
   121 setup \<open>Code.add_eqn (Code.Equation, true) @{thm Mapping.lookup.abs_eq}\<close>  (* FIXME lifting *)
   122 
   123 lift_definition update :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping"
   124   is "\<lambda>k v m. m(k \<mapsto> v)" parametric update_parametric .
   125 
   126 lift_definition delete :: "'a \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping"
   127   is "\<lambda>k m. m(k := None)" parametric delete_parametric .
   128 
   129 lift_definition filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping"
   130   is "\<lambda>P m k. case m k of None \<Rightarrow> None | Some v \<Rightarrow> if P k v then Some v else None" .
   131 
   132 lift_definition keys :: "('a, 'b) mapping \<Rightarrow> 'a set"
   133   is dom parametric dom_parametric .
   134 
   135 lift_definition tabulate :: "'a list \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) mapping"
   136   is "\<lambda>ks f. (map_of (List.map (\<lambda>k. (k, f k)) ks))" parametric tabulate_parametric .
   137 
   138 lift_definition bulkload :: "'a list \<Rightarrow> (nat, 'a) mapping"
   139   is "\<lambda>xs k. if k < length xs then Some (xs ! k) else None" parametric bulkload_parametric .
   140 
   141 lift_definition map :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('c, 'd) mapping"
   142   is "\<lambda>f g m. (map_option g \<circ> m \<circ> f)" parametric map_parametric .
   143 
   144 lift_definition map_values :: "('c \<Rightarrow> 'a \<Rightarrow> 'b) \<Rightarrow> ('c, 'a) mapping \<Rightarrow> ('c, 'b) mapping"
   145   is "\<lambda>f m x. map_option (f x) (m x)" .
   146 
   147 lift_definition combine_with_key ::
   148   "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a,'b) mapping \<Rightarrow> ('a,'b) mapping \<Rightarrow> ('a,'b) mapping"
   149   is "\<lambda>f m1 m2 x. combine_options (f x) (m1 x) (m2 x)" parametric combine_with_key_parametric .
   150 
   151 lift_definition combine ::
   152   "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a,'b) mapping \<Rightarrow> ('a,'b) mapping \<Rightarrow> ('a,'b) mapping"
   153   is "\<lambda>f m1 m2 x. combine_options f (m1 x) (m2 x)" parametric combine_parametric .
   154 
   155 definition "All_mapping m P \<longleftrightarrow>
   156   (\<forall>x. case Mapping.lookup m x of None \<Rightarrow> True | Some y \<Rightarrow> P x y)"
   157 
   158 declare [[code drop: map]]
   159 
   160 
   161 subsection \<open>Functorial structure\<close>
   162 
   163 functor map: map
   164   by (transfer, auto simp add: fun_eq_iff option.map_comp option.map_id)+
   165 
   166 
   167 subsection \<open>Derived operations\<close>
   168 
   169 definition ordered_keys :: "('a::linorder, 'b) mapping \<Rightarrow> 'a list"
   170   where "ordered_keys m = (if finite (keys m) then sorted_list_of_set (keys m) else [])"
   171 
   172 definition is_empty :: "('a, 'b) mapping \<Rightarrow> bool"
   173   where "is_empty m \<longleftrightarrow> keys m = {}"
   174 
   175 definition size :: "('a, 'b) mapping \<Rightarrow> nat"
   176   where "size m = (if finite (keys m) then card (keys m) else 0)"
   177 
   178 definition replace :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping"
   179   where "replace k v m = (if k \<in> keys m then update k v m else m)"
   180 
   181 definition default :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping"
   182   where "default k v m = (if k \<in> keys m then m else update k v m)"
   183 
   184 text \<open>Manual derivation of transfer rule is non-trivial\<close>
   185 
   186 lift_definition map_entry :: "'a \<Rightarrow> ('b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" is
   187   "\<lambda>k f m.
   188     (case m k of
   189       None \<Rightarrow> m
   190     | Some v \<Rightarrow> m (k \<mapsto> (f v)))" parametric map_entry_parametric .
   191 
   192 lemma map_entry_code [code]:
   193   "map_entry k f m =
   194     (case lookup m k of
   195       None \<Rightarrow> m
   196     | Some v \<Rightarrow> update k (f v) m)"
   197   by transfer rule
   198 
   199 definition map_default :: "'a \<Rightarrow> 'b \<Rightarrow> ('b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping"
   200   where "map_default k v f m = map_entry k f (default k v m)"
   201 
   202 definition of_alist :: "('k \<times> 'v) list \<Rightarrow> ('k, 'v) mapping"
   203   where "of_alist xs = foldr (\<lambda>(k, v) m. update k v m) xs empty"
   204 
   205 instantiation mapping :: (type, type) equal
   206 begin
   207 
   208 definition "HOL.equal m1 m2 \<longleftrightarrow> (\<forall>k. lookup m1 k = lookup m2 k)"
   209 
   210 instance
   211   apply standard
   212   unfolding equal_mapping_def
   213   apply transfer
   214   apply auto
   215   done
   216 
   217 end
   218 
   219 context includes lifting_syntax
   220 begin
   221 
   222 lemma [transfer_rule]:
   223   assumes [transfer_rule]: "bi_total A"
   224     and [transfer_rule]: "bi_unique B"
   225   shows "(pcr_mapping A B ===> pcr_mapping A B ===> op=) HOL.eq HOL.equal"
   226   unfolding equal by transfer_prover
   227 
   228 lemma of_alist_transfer [transfer_rule]:
   229   assumes [transfer_rule]: "bi_unique R1"
   230   shows "(list_all2 (rel_prod R1 R2) ===> pcr_mapping R1 R2) map_of of_alist"
   231   unfolding of_alist_def [abs_def] map_of_foldr [abs_def] by transfer_prover
   232 
   233 end
   234 
   235 
   236 subsection \<open>Properties\<close>
   237 
   238 lemma mapping_eqI: "(\<And>x. lookup m x = lookup m' x) \<Longrightarrow> m = m'"
   239   by transfer (simp add: fun_eq_iff)
   240 
   241 lemma mapping_eqI':
   242   assumes "\<And>x. x \<in> Mapping.keys m \<Longrightarrow> Mapping.lookup_default d m x = Mapping.lookup_default d m' x"
   243     and "Mapping.keys m = Mapping.keys m'"
   244   shows "m = m'"
   245 proof (intro mapping_eqI)
   246   show "Mapping.lookup m x = Mapping.lookup m' x" for x
   247   proof (cases "Mapping.lookup m x")
   248     case None
   249     then have "x \<notin> Mapping.keys m"
   250       by transfer (simp add: dom_def)
   251     then have "x \<notin> Mapping.keys m'"
   252       by (simp add: assms)
   253     then have "Mapping.lookup m' x = None"
   254       by transfer (simp add: dom_def)
   255     with None show ?thesis
   256       by simp
   257   next
   258     case (Some y)
   259     then have A: "x \<in> Mapping.keys m"
   260       by transfer (simp add: dom_def)
   261     then have "x \<in> Mapping.keys m'"
   262       by (simp add: assms)
   263     then have "\<exists>y'. Mapping.lookup m' x = Some y'"
   264       by transfer (simp add: dom_def)
   265     with Some assms(1)[OF A] show ?thesis
   266       by (auto simp add: lookup_default_def)
   267   qed
   268 qed
   269 
   270 lemma lookup_update: "lookup (update k v m) k = Some v"
   271   by transfer simp
   272 
   273 lemma lookup_update_neq: "k \<noteq> k' \<Longrightarrow> lookup (update k v m) k' = lookup m k'"
   274   by transfer simp
   275 
   276 lemma lookup_update': "Mapping.lookup (update k v m) k' = (if k = k' then Some v else lookup m k')"
   277   by (auto simp: lookup_update lookup_update_neq)
   278 
   279 lemma lookup_empty: "lookup empty k = None"
   280   by transfer simp
   281 
   282 lemma lookup_filter:
   283   "lookup (filter P m) k =
   284     (case lookup m k of
   285       None \<Rightarrow> None
   286     | Some v \<Rightarrow> if P k v then Some v else None)"
   287   by transfer simp_all
   288 
   289 lemma lookup_map_values: "lookup (map_values f m) k = map_option (f k) (lookup m k)"
   290   by transfer simp_all
   291 
   292 lemma lookup_default_empty: "lookup_default d empty k = d"
   293   by (simp add: lookup_default_def lookup_empty)
   294 
   295 lemma lookup_default_update: "lookup_default d (update k v m) k = v"
   296   by (simp add: lookup_default_def lookup_update)
   297 
   298 lemma lookup_default_update_neq:
   299   "k \<noteq> k' \<Longrightarrow> lookup_default d (update k v m) k' = lookup_default d m k'"
   300   by (simp add: lookup_default_def lookup_update_neq)
   301 
   302 lemma lookup_default_update':
   303   "lookup_default d (update k v m) k' = (if k = k' then v else lookup_default d m k')"
   304   by (auto simp: lookup_default_update lookup_default_update_neq)
   305 
   306 lemma lookup_default_filter:
   307   "lookup_default d (filter P m) k =
   308      (if P k (lookup_default d m k) then lookup_default d m k else d)"
   309   by (simp add: lookup_default_def lookup_filter split: option.splits)
   310 
   311 lemma lookup_default_map_values:
   312   "lookup_default (f k d) (map_values f m) k = f k (lookup_default d m k)"
   313   by (simp add: lookup_default_def lookup_map_values split: option.splits)
   314 
   315 lemma lookup_combine_with_key:
   316   "Mapping.lookup (combine_with_key f m1 m2) x =
   317     combine_options (f x) (Mapping.lookup m1 x) (Mapping.lookup m2 x)"
   318   by transfer (auto split: option.splits)
   319 
   320 lemma combine_altdef: "combine f m1 m2 = combine_with_key (\<lambda>_. f) m1 m2"
   321   by transfer' (rule refl)
   322 
   323 lemma lookup_combine:
   324   "Mapping.lookup (combine f m1 m2) x =
   325      combine_options f (Mapping.lookup m1 x) (Mapping.lookup m2 x)"
   326   by transfer (auto split: option.splits)
   327 
   328 lemma lookup_default_neutral_combine_with_key:
   329   assumes "\<And>x. f k d x = x" "\<And>x. f k x d = x"
   330   shows "Mapping.lookup_default d (combine_with_key f m1 m2) k =
   331     f k (Mapping.lookup_default d m1 k) (Mapping.lookup_default d m2 k)"
   332   by (auto simp: lookup_default_def lookup_combine_with_key assms split: option.splits)
   333 
   334 lemma lookup_default_neutral_combine:
   335   assumes "\<And>x. f d x = x" "\<And>x. f x d = x"
   336   shows "Mapping.lookup_default d (combine f m1 m2) x =
   337     f (Mapping.lookup_default d m1 x) (Mapping.lookup_default d m2 x)"
   338   by (auto simp: lookup_default_def lookup_combine assms split: option.splits)
   339 
   340 lemma lookup_map_entry: "lookup (map_entry x f m) x = map_option f (lookup m x)"
   341   by transfer (auto split: option.splits)
   342 
   343 lemma lookup_map_entry_neq: "x \<noteq> y \<Longrightarrow> lookup (map_entry x f m) y = lookup m y"
   344   by transfer (auto split: option.splits)
   345 
   346 lemma lookup_map_entry':
   347   "lookup (map_entry x f m) y =
   348      (if x = y then map_option f (lookup m y) else lookup m y)"
   349   by transfer (auto split: option.splits)
   350 
   351 lemma lookup_default: "lookup (default x d m) x = Some (lookup_default d m x)"
   352   unfolding lookup_default_def default_def
   353   by transfer (auto split: option.splits)
   354 
   355 lemma lookup_default_neq: "x \<noteq> y \<Longrightarrow> lookup (default x d m) y = lookup m y"
   356   unfolding lookup_default_def default_def
   357   by transfer (auto split: option.splits)
   358 
   359 lemma lookup_default':
   360   "lookup (default x d m) y =
   361     (if x = y then Some (lookup_default d m x) else lookup m y)"
   362   unfolding lookup_default_def default_def
   363   by transfer (auto split: option.splits)
   364 
   365 lemma lookup_map_default: "lookup (map_default x d f m) x = Some (f (lookup_default d m x))"
   366   unfolding lookup_default_def default_def
   367   by (simp add: map_default_def lookup_map_entry lookup_default lookup_default_def)
   368 
   369 lemma lookup_map_default_neq: "x \<noteq> y \<Longrightarrow> lookup (map_default x d f m) y = lookup m y"
   370   unfolding lookup_default_def default_def
   371   by (simp add: map_default_def lookup_map_entry_neq lookup_default_neq)
   372 
   373 lemma lookup_map_default':
   374   "lookup (map_default x d f m) y =
   375     (if x = y then Some (f (lookup_default d m x)) else lookup m y)"
   376   unfolding lookup_default_def default_def
   377   by (simp add: map_default_def lookup_map_entry' lookup_default' lookup_default_def)
   378 
   379 lemma lookup_tabulate:
   380   assumes "distinct xs"
   381   shows "Mapping.lookup (Mapping.tabulate xs f) x = (if x \<in> set xs then Some (f x) else None)"
   382   using assms by transfer (auto simp: map_of_eq_None_iff o_def dest!: map_of_SomeD)
   383 
   384 lemma lookup_of_alist: "Mapping.lookup (Mapping.of_alist xs) k = map_of xs k"
   385   by transfer simp_all
   386 
   387 lemma keys_is_none_rep [code_unfold]: "k \<in> keys m \<longleftrightarrow> \<not> (Option.is_none (lookup m k))"
   388   by transfer (auto simp add: Option.is_none_def)
   389 
   390 lemma update_update:
   391   "update k v (update k w m) = update k v m"
   392   "k \<noteq> l \<Longrightarrow> update k v (update l w m) = update l w (update k v m)"
   393   by (transfer; simp add: fun_upd_twist)+
   394 
   395 lemma update_delete [simp]: "update k v (delete k m) = update k v m"
   396   by transfer simp
   397 
   398 lemma delete_update:
   399   "delete k (update k v m) = delete k m"
   400   "k \<noteq> l \<Longrightarrow> delete k (update l v m) = update l v (delete k m)"
   401   by (transfer; simp add: fun_upd_twist)+
   402 
   403 lemma delete_empty [simp]: "delete k empty = empty"
   404   by transfer simp
   405 
   406 lemma replace_update:
   407   "k \<notin> keys m \<Longrightarrow> replace k v m = m"
   408   "k \<in> keys m \<Longrightarrow> replace k v m = update k v m"
   409   by (transfer; auto simp add: replace_def fun_upd_twist)+
   410 
   411 lemma map_values_update: "map_values f (update k v m) = update k (f k v) (map_values f m)"
   412   by transfer (simp_all add: fun_eq_iff)
   413 
   414 lemma size_mono: "finite (keys m') \<Longrightarrow> keys m \<subseteq> keys m' \<Longrightarrow> size m \<le> size m'"
   415   unfolding size_def by (auto intro: card_mono)
   416 
   417 lemma size_empty [simp]: "size empty = 0"
   418   unfolding size_def by transfer simp
   419 
   420 lemma size_update:
   421   "finite (keys m) \<Longrightarrow> size (update k v m) =
   422     (if k \<in> keys m then size m else Suc (size m))"
   423   unfolding size_def by transfer (auto simp add: insert_dom)
   424 
   425 lemma size_delete: "size (delete k m) = (if k \<in> keys m then size m - 1 else size m)"
   426   unfolding size_def by transfer simp
   427 
   428 lemma size_tabulate [simp]: "size (tabulate ks f) = length (remdups ks)"
   429   unfolding size_def by transfer (auto simp add: map_of_map_restrict card_set comp_def)
   430 
   431 lemma keys_filter: "keys (filter P m) \<subseteq> keys m"
   432   by transfer (auto split: option.splits)
   433 
   434 lemma size_filter: "finite (keys m) \<Longrightarrow> size (filter P m) \<le> size m"
   435   by (intro size_mono keys_filter)
   436 
   437 lemma bulkload_tabulate: "bulkload xs = tabulate [0..<length xs] (nth xs)"
   438   by transfer (auto simp add: map_of_map_restrict)
   439 
   440 lemma is_empty_empty [simp]: "is_empty empty"
   441   unfolding is_empty_def by transfer simp
   442 
   443 lemma is_empty_update [simp]: "\<not> is_empty (update k v m)"
   444   unfolding is_empty_def by transfer simp
   445 
   446 lemma is_empty_delete: "is_empty (delete k m) \<longleftrightarrow> is_empty m \<or> keys m = {k}"
   447   unfolding is_empty_def by transfer (auto simp del: dom_eq_empty_conv)
   448 
   449 lemma is_empty_replace [simp]: "is_empty (replace k v m) \<longleftrightarrow> is_empty m"
   450   unfolding is_empty_def replace_def by transfer auto
   451 
   452 lemma is_empty_default [simp]: "\<not> is_empty (default k v m)"
   453   unfolding is_empty_def default_def by transfer auto
   454 
   455 lemma is_empty_map_entry [simp]: "is_empty (map_entry k f m) \<longleftrightarrow> is_empty m"
   456   unfolding is_empty_def by transfer (auto split: option.split)
   457 
   458 lemma is_empty_map_values [simp]: "is_empty (map_values f m) \<longleftrightarrow> is_empty m"
   459   unfolding is_empty_def by transfer (auto simp: fun_eq_iff)
   460 
   461 lemma is_empty_map_default [simp]: "\<not> is_empty (map_default k v f m)"
   462   by (simp add: map_default_def)
   463 
   464 lemma keys_dom_lookup: "keys m = dom (Mapping.lookup m)"
   465   by transfer rule
   466 
   467 lemma keys_empty [simp]: "keys empty = {}"
   468   by transfer simp
   469 
   470 lemma keys_update [simp]: "keys (update k v m) = insert k (keys m)"
   471   by transfer simp
   472 
   473 lemma keys_delete [simp]: "keys (delete k m) = keys m - {k}"
   474   by transfer simp
   475 
   476 lemma keys_replace [simp]: "keys (replace k v m) = keys m"
   477   unfolding replace_def by transfer (simp add: insert_absorb)
   478 
   479 lemma keys_default [simp]: "keys (default k v m) = insert k (keys m)"
   480   unfolding default_def by transfer (simp add: insert_absorb)
   481 
   482 lemma keys_map_entry [simp]: "keys (map_entry k f m) = keys m"
   483   by transfer (auto split: option.split)
   484 
   485 lemma keys_map_default [simp]: "keys (map_default k v f m) = insert k (keys m)"
   486   by (simp add: map_default_def)
   487 
   488 lemma keys_map_values [simp]: "keys (map_values f m) = keys m"
   489   by transfer (simp_all add: dom_def)
   490 
   491 lemma keys_combine_with_key [simp]:
   492   "Mapping.keys (combine_with_key f m1 m2) = Mapping.keys m1 \<union> Mapping.keys m2"
   493   by transfer (auto simp: dom_def combine_options_def split: option.splits)
   494 
   495 lemma keys_combine [simp]: "Mapping.keys (combine f m1 m2) = Mapping.keys m1 \<union> Mapping.keys m2"
   496   by (simp add: combine_altdef)
   497 
   498 lemma keys_tabulate [simp]: "keys (tabulate ks f) = set ks"
   499   by transfer (simp add: map_of_map_restrict o_def)
   500 
   501 lemma keys_of_alist [simp]: "keys (of_alist xs) = set (List.map fst xs)"
   502   by transfer (simp_all add: dom_map_of_conv_image_fst)
   503 
   504 lemma keys_bulkload [simp]: "keys (bulkload xs) = {0..<length xs}"
   505   by (simp add: bulkload_tabulate)
   506 
   507 lemma distinct_ordered_keys [simp]: "distinct (ordered_keys m)"
   508   by (simp add: ordered_keys_def)
   509 
   510 lemma ordered_keys_infinite [simp]: "\<not> finite (keys m) \<Longrightarrow> ordered_keys m = []"
   511   by (simp add: ordered_keys_def)
   512 
   513 lemma ordered_keys_empty [simp]: "ordered_keys empty = []"
   514   by (simp add: ordered_keys_def)
   515 
   516 lemma ordered_keys_update [simp]:
   517   "k \<in> keys m \<Longrightarrow> ordered_keys (update k v m) = ordered_keys m"
   518   "finite (keys m) \<Longrightarrow> k \<notin> keys m \<Longrightarrow>
   519     ordered_keys (update k v m) = insort k (ordered_keys m)"
   520   by (simp_all add: ordered_keys_def)
   521     (auto simp only: sorted_list_of_set_insert [symmetric] insert_absorb)
   522 
   523 lemma ordered_keys_delete [simp]: "ordered_keys (delete k m) = remove1 k (ordered_keys m)"
   524 proof (cases "finite (keys m)")
   525   case False
   526   then show ?thesis by simp
   527 next
   528   case fin: True
   529   show ?thesis
   530   proof (cases "k \<in> keys m")
   531     case False
   532     with fin have "k \<notin> set (sorted_list_of_set (keys m))"
   533       by simp
   534     with False show ?thesis
   535       by (simp add: ordered_keys_def remove1_idem)
   536   next
   537     case True
   538     with fin show ?thesis
   539       by (simp add: ordered_keys_def sorted_list_of_set_remove)
   540   qed
   541 qed
   542 
   543 lemma ordered_keys_replace [simp]: "ordered_keys (replace k v m) = ordered_keys m"
   544   by (simp add: replace_def)
   545 
   546 lemma ordered_keys_default [simp]:
   547   "k \<in> keys m \<Longrightarrow> ordered_keys (default k v m) = ordered_keys m"
   548   "finite (keys m) \<Longrightarrow> k \<notin> keys m \<Longrightarrow> ordered_keys (default k v m) = insort k (ordered_keys m)"
   549   by (simp_all add: default_def)
   550 
   551 lemma ordered_keys_map_entry [simp]: "ordered_keys (map_entry k f m) = ordered_keys m"
   552   by (simp add: ordered_keys_def)
   553 
   554 lemma ordered_keys_map_default [simp]:
   555   "k \<in> keys m \<Longrightarrow> ordered_keys (map_default k v f m) = ordered_keys m"
   556   "finite (keys m) \<Longrightarrow> k \<notin> keys m \<Longrightarrow> ordered_keys (map_default k v f m) = insort k (ordered_keys m)"
   557   by (simp_all add: map_default_def)
   558 
   559 lemma ordered_keys_tabulate [simp]: "ordered_keys (tabulate ks f) = sort (remdups ks)"
   560   by (simp add: ordered_keys_def sorted_list_of_set_sort_remdups)
   561 
   562 lemma ordered_keys_bulkload [simp]: "ordered_keys (bulkload ks) = [0..<length ks]"
   563   by (simp add: ordered_keys_def)
   564 
   565 lemma tabulate_fold: "tabulate xs f = fold (\<lambda>k m. update k (f k) m) xs empty"
   566 proof transfer
   567   fix f :: "'a \<Rightarrow> 'b" and xs
   568   have "map_of (List.map (\<lambda>k. (k, f k)) xs) = foldr (\<lambda>k m. m(k \<mapsto> f k)) xs Map.empty"
   569     by (simp add: foldr_map comp_def map_of_foldr)
   570   also have "foldr (\<lambda>k m. m(k \<mapsto> f k)) xs = fold (\<lambda>k m. m(k \<mapsto> f k)) xs"
   571     by (rule foldr_fold) (simp add: fun_eq_iff)
   572   ultimately show "map_of (List.map (\<lambda>k. (k, f k)) xs) = fold (\<lambda>k m. m(k \<mapsto> f k)) xs Map.empty"
   573     by simp
   574 qed
   575 
   576 lemma All_mapping_mono:
   577   "(\<And>k v. k \<in> keys m \<Longrightarrow> P k v \<Longrightarrow> Q k v) \<Longrightarrow> All_mapping m P \<Longrightarrow> All_mapping m Q"
   578   unfolding All_mapping_def by transfer (auto simp: All_mapping_def dom_def split: option.splits)
   579 
   580 lemma All_mapping_empty [simp]: "All_mapping Mapping.empty P"
   581   by (auto simp: All_mapping_def lookup_empty)
   582 
   583 lemma All_mapping_update_iff:
   584   "All_mapping (Mapping.update k v m) P \<longleftrightarrow> P k v \<and> All_mapping m (\<lambda>k' v'. k = k' \<or> P k' v')"
   585   unfolding All_mapping_def
   586 proof safe
   587   assume "\<forall>x. case Mapping.lookup (Mapping.update k v m) x of None \<Rightarrow> True | Some y \<Rightarrow> P x y"
   588   then have *: "case Mapping.lookup (Mapping.update k v m) x of None \<Rightarrow> True | Some y \<Rightarrow> P x y" for x
   589     by blast
   590   from *[of k] show "P k v"
   591     by (simp add: lookup_update)
   592   show "case Mapping.lookup m x of None \<Rightarrow> True | Some v' \<Rightarrow> k = x \<or> P x v'" for x
   593     using *[of x] by (auto simp add: lookup_update' split: if_splits option.splits)
   594 next
   595   assume "P k v"
   596   assume "\<forall>x. case Mapping.lookup m x of None \<Rightarrow> True | Some v' \<Rightarrow> k = x \<or> P x v'"
   597   then have A: "case Mapping.lookup m x of None \<Rightarrow> True | Some v' \<Rightarrow> k = x \<or> P x v'" for x
   598     by blast
   599   show "case Mapping.lookup (Mapping.update k v m) x of None \<Rightarrow> True | Some xa \<Rightarrow> P x xa" for x
   600     using \<open>P k v\<close> A[of x] by (auto simp: lookup_update' split: option.splits)
   601 qed
   602 
   603 lemma All_mapping_update:
   604   "P k v \<Longrightarrow> All_mapping m (\<lambda>k' v'. k = k' \<or> P k' v') \<Longrightarrow> All_mapping (Mapping.update k v m) P"
   605   by (simp add: All_mapping_update_iff)
   606 
   607 lemma All_mapping_filter_iff: "All_mapping (filter P m) Q \<longleftrightarrow> All_mapping m (\<lambda>k v. P k v \<longrightarrow> Q k v)"
   608   by (auto simp: All_mapping_def lookup_filter split: option.splits)
   609 
   610 lemma All_mapping_filter: "All_mapping m Q \<Longrightarrow> All_mapping (filter P m) Q"
   611   by (auto simp: All_mapping_filter_iff intro: All_mapping_mono)
   612 
   613 lemma All_mapping_map_values: "All_mapping (map_values f m) P \<longleftrightarrow> All_mapping m (\<lambda>k v. P k (f k v))"
   614   by (auto simp: All_mapping_def lookup_map_values split: option.splits)
   615 
   616 lemma All_mapping_tabulate: "(\<forall>x\<in>set xs. P x (f x)) \<Longrightarrow> All_mapping (Mapping.tabulate xs f) P"
   617   unfolding All_mapping_def
   618   apply (intro allI)
   619   apply transfer
   620   apply (auto split: option.split dest!: map_of_SomeD)
   621   done
   622 
   623 lemma All_mapping_alist:
   624   "(\<And>k v. (k, v) \<in> set xs \<Longrightarrow> P k v) \<Longrightarrow> All_mapping (Mapping.of_alist xs) P"
   625   by (auto simp: All_mapping_def lookup_of_alist dest!: map_of_SomeD split: option.splits)
   626 
   627 lemma combine_empty [simp]: "combine f Mapping.empty y = y" "combine f y Mapping.empty = y"
   628   by (transfer; force)+
   629 
   630 lemma (in abel_semigroup) comm_monoid_set_combine: "comm_monoid_set (combine f) Mapping.empty"
   631   by standard (transfer fixing: f, simp add: combine_options_ac[of f] ac_simps)+
   632 
   633 locale combine_mapping_abel_semigroup = abel_semigroup
   634 begin
   635 
   636 sublocale combine: comm_monoid_set "combine f" Mapping.empty
   637   by (rule comm_monoid_set_combine)
   638 
   639 lemma fold_combine_code:
   640   "combine.F g (set xs) = foldr (\<lambda>x. combine f (g x)) (remdups xs) Mapping.empty"
   641 proof -
   642   have "combine.F g (set xs) = foldr (\<lambda>x. combine f (g x)) xs Mapping.empty"
   643     if "distinct xs" for xs
   644     using that by (induction xs) simp_all
   645   from this[of "remdups xs"] show ?thesis by simp
   646 qed
   647 
   648 lemma keys_fold_combine: "finite A \<Longrightarrow> Mapping.keys (combine.F g A) = (\<Union>x\<in>A. Mapping.keys (g x))"
   649   by (induct A rule: finite_induct) simp_all
   650 
   651 end
   652 
   653 
   654 subsection \<open>Code generator setup\<close>
   655 
   656 hide_const (open) empty is_empty rep lookup lookup_default filter update delete ordered_keys
   657   keys size replace default map_entry map_default tabulate bulkload map map_values combine of_alist
   658 
   659 end