src/HOL/Library/Multiset.thy
author haftmann
Mon Jun 05 15:59:41 2017 +0200 (2017-06-05)
changeset 66010 2f7d39285a1a
parent 65547 701bb74c5f97
child 66276 acc3b7dd0b21
permissions -rw-r--r--
executable domain membership checks
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     5     Author:     Dmitriy Traytel, TU Muenchen
     6     Author:     Mathias Fleury, MPII
     7 *)
     8 
     9 section \<open>(Finite) Multisets\<close>
    10 
    11 theory Multiset
    12 imports Cancellation
    13 begin
    14 
    15 subsection \<open>The type of multisets\<close>
    16 
    17 definition "multiset = {f :: 'a \<Rightarrow> nat. finite {x. f x > 0}}"
    18 
    19 typedef 'a multiset = "multiset :: ('a \<Rightarrow> nat) set"
    20   morphisms count Abs_multiset
    21   unfolding multiset_def
    22 proof
    23   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    24 qed
    25 
    26 setup_lifting type_definition_multiset
    27 
    28 lemma multiset_eq_iff: "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    29   by (simp only: count_inject [symmetric] fun_eq_iff)
    30 
    31 lemma multiset_eqI: "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    32   using multiset_eq_iff by auto
    33 
    34 text \<open>Preservation of the representing set @{term multiset}.\<close>
    35 
    36 lemma const0_in_multiset: "(\<lambda>a. 0) \<in> multiset"
    37   by (simp add: multiset_def)
    38 
    39 lemma only1_in_multiset: "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    40   by (simp add: multiset_def)
    41 
    42 lemma union_preserves_multiset: "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    43   by (simp add: multiset_def)
    44 
    45 lemma diff_preserves_multiset:
    46   assumes "M \<in> multiset"
    47   shows "(\<lambda>a. M a - N a) \<in> multiset"
    48 proof -
    49   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    50     by auto
    51   with assms show ?thesis
    52     by (auto simp add: multiset_def intro: finite_subset)
    53 qed
    54 
    55 lemma filter_preserves_multiset:
    56   assumes "M \<in> multiset"
    57   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    58 proof -
    59   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    60     by auto
    61   with assms show ?thesis
    62     by (auto simp add: multiset_def intro: finite_subset)
    63 qed
    64 
    65 lemmas in_multiset = const0_in_multiset only1_in_multiset
    66   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    67 
    68 
    69 subsection \<open>Representing multisets\<close>
    70 
    71 text \<open>Multiset enumeration\<close>
    72 
    73 instantiation multiset :: (type) cancel_comm_monoid_add
    74 begin
    75 
    76 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    77 by (rule const0_in_multiset)
    78 
    79 abbreviation Mempty :: "'a multiset" ("{#}") where
    80   "Mempty \<equiv> 0"
    81 
    82 lift_definition plus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    83 by (rule union_preserves_multiset)
    84 
    85 lift_definition minus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
    86 by (rule diff_preserves_multiset)
    87 
    88 instance
    89   by (standard; transfer; simp add: fun_eq_iff)
    90 
    91 end
    92 
    93 context
    94 begin
    95 
    96 qualified definition is_empty :: "'a multiset \<Rightarrow> bool" where
    97   [code_abbrev]: "is_empty A \<longleftrightarrow> A = {#}"
    98 
    99 end
   100 
   101 lemma add_mset_in_multiset:
   102   assumes M: \<open>M \<in> multiset\<close>
   103   shows \<open>(\<lambda>b. if b = a then Suc (M b) else M b) \<in> multiset\<close>
   104   using assms by (simp add: multiset_def insert_Collect[symmetric])
   105 
   106 lift_definition add_mset :: "'a \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is
   107   "\<lambda>a M b. if b = a then Suc (M b) else M b"
   108 by (rule add_mset_in_multiset)
   109 
   110 syntax
   111   "_multiset" :: "args \<Rightarrow> 'a multiset"    ("{#(_)#}")
   112 translations
   113   "{#x, xs#}" == "CONST add_mset x {#xs#}"
   114   "{#x#}" == "CONST add_mset x {#}"
   115 
   116 lemma count_empty [simp]: "count {#} a = 0"
   117   by (simp add: zero_multiset.rep_eq)
   118 
   119 lemma count_add_mset [simp]:
   120   "count (add_mset b A) a = (if b = a then Suc (count A a) else count A a)"
   121   by (simp add: add_mset.rep_eq)
   122 
   123 lemma count_single: "count {#b#} a = (if b = a then 1 else 0)"
   124   by simp
   125 
   126 lemma
   127   add_mset_not_empty [simp]: \<open>add_mset a A \<noteq> {#}\<close> and
   128   empty_not_add_mset [simp]: "{#} \<noteq> add_mset a A"
   129   by (auto simp: multiset_eq_iff)
   130 
   131 lemma add_mset_add_mset_same_iff [simp]:
   132   "add_mset a A = add_mset a B \<longleftrightarrow> A = B"
   133   by (auto simp: multiset_eq_iff)
   134 
   135 lemma add_mset_commute:
   136   "add_mset x (add_mset y M) = add_mset y (add_mset x M)"
   137   by (auto simp: multiset_eq_iff)
   138 
   139 
   140 subsection \<open>Basic operations\<close>
   141 
   142 subsubsection \<open>Conversion to set and membership\<close>
   143 
   144 definition set_mset :: "'a multiset \<Rightarrow> 'a set"
   145   where "set_mset M = {x. count M x > 0}"
   146 
   147 abbreviation Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"
   148   where "Melem a M \<equiv> a \<in> set_mset M"
   149 
   150 notation
   151   Melem  ("op \<in>#") and
   152   Melem  ("(_/ \<in># _)" [51, 51] 50)
   153 
   154 notation  (ASCII)
   155   Melem  ("op :#") and
   156   Melem  ("(_/ :# _)" [51, 51] 50)
   157 
   158 abbreviation not_Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"
   159   where "not_Melem a M \<equiv> a \<notin> set_mset M"
   160 
   161 notation
   162   not_Melem  ("op \<notin>#") and
   163   not_Melem  ("(_/ \<notin># _)" [51, 51] 50)
   164 
   165 notation  (ASCII)
   166   not_Melem  ("op ~:#") and
   167   not_Melem  ("(_/ ~:# _)" [51, 51] 50)
   168 
   169 context
   170 begin
   171 
   172 qualified abbreviation Ball :: "'a multiset \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
   173   where "Ball M \<equiv> Set.Ball (set_mset M)"
   174 
   175 qualified abbreviation Bex :: "'a multiset \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
   176   where "Bex M \<equiv> Set.Bex (set_mset M)"
   177 
   178 end
   179 
   180 syntax
   181   "_MBall"       :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<forall>_\<in>#_./ _)" [0, 0, 10] 10)
   182   "_MBex"        :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>_\<in>#_./ _)" [0, 0, 10] 10)
   183 
   184 syntax  (ASCII)
   185   "_MBall"       :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<forall>_:#_./ _)" [0, 0, 10] 10)
   186   "_MBex"        :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>_:#_./ _)" [0, 0, 10] 10)
   187 
   188 translations
   189   "\<forall>x\<in>#A. P" \<rightleftharpoons> "CONST Multiset.Ball A (\<lambda>x. P)"
   190   "\<exists>x\<in>#A. P" \<rightleftharpoons> "CONST Multiset.Bex A (\<lambda>x. P)"
   191 
   192 lemma count_eq_zero_iff:
   193   "count M x = 0 \<longleftrightarrow> x \<notin># M"
   194   by (auto simp add: set_mset_def)
   195 
   196 lemma not_in_iff:
   197   "x \<notin># M \<longleftrightarrow> count M x = 0"
   198   by (auto simp add: count_eq_zero_iff)
   199 
   200 lemma count_greater_zero_iff [simp]:
   201   "count M x > 0 \<longleftrightarrow> x \<in># M"
   202   by (auto simp add: set_mset_def)
   203 
   204 lemma count_inI:
   205   assumes "count M x = 0 \<Longrightarrow> False"
   206   shows "x \<in># M"
   207 proof (rule ccontr)
   208   assume "x \<notin># M"
   209   with assms show False by (simp add: not_in_iff)
   210 qed
   211 
   212 lemma in_countE:
   213   assumes "x \<in># M"
   214   obtains n where "count M x = Suc n"
   215 proof -
   216   from assms have "count M x > 0" by simp
   217   then obtain n where "count M x = Suc n"
   218     using gr0_conv_Suc by blast
   219   with that show thesis .
   220 qed
   221 
   222 lemma count_greater_eq_Suc_zero_iff [simp]:
   223   "count M x \<ge> Suc 0 \<longleftrightarrow> x \<in># M"
   224   by (simp add: Suc_le_eq)
   225 
   226 lemma count_greater_eq_one_iff [simp]:
   227   "count M x \<ge> 1 \<longleftrightarrow> x \<in># M"
   228   by simp
   229 
   230 lemma set_mset_empty [simp]:
   231   "set_mset {#} = {}"
   232   by (simp add: set_mset_def)
   233 
   234 lemma set_mset_single:
   235   "set_mset {#b#} = {b}"
   236   by (simp add: set_mset_def)
   237 
   238 lemma set_mset_eq_empty_iff [simp]:
   239   "set_mset M = {} \<longleftrightarrow> M = {#}"
   240   by (auto simp add: multiset_eq_iff count_eq_zero_iff)
   241 
   242 lemma finite_set_mset [iff]:
   243   "finite (set_mset M)"
   244   using count [of M] by (simp add: multiset_def)
   245 
   246 lemma set_mset_add_mset_insert [simp]: \<open>set_mset (add_mset a A) = insert a (set_mset A)\<close>
   247   by (auto simp del: count_greater_eq_Suc_zero_iff
   248       simp: count_greater_eq_Suc_zero_iff[symmetric] split: if_splits)
   249 
   250 lemma multiset_nonemptyE [elim]:
   251   assumes "A \<noteq> {#}"
   252   obtains x where "x \<in># A"
   253 proof -
   254   have "\<exists>x. x \<in># A" by (rule ccontr) (insert assms, auto)
   255   with that show ?thesis by blast
   256 qed
   257 
   258 
   259 subsubsection \<open>Union\<close>
   260 
   261 lemma count_union [simp]:
   262   "count (M + N) a = count M a + count N a"
   263   by (simp add: plus_multiset.rep_eq)
   264 
   265 lemma set_mset_union [simp]:
   266   "set_mset (M + N) = set_mset M \<union> set_mset N"
   267   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] count_union) simp
   268 
   269 lemma union_mset_add_mset_left [simp]:
   270   "add_mset a A + B = add_mset a (A + B)"
   271   by (auto simp: multiset_eq_iff)
   272 
   273 lemma union_mset_add_mset_right [simp]:
   274   "A + add_mset a B = add_mset a (A + B)"
   275   by (auto simp: multiset_eq_iff)
   276 
   277 lemma add_mset_add_single: \<open>add_mset a A = A + {#a#}\<close>
   278   by (subst union_mset_add_mset_right, subst add.comm_neutral) standard
   279 
   280 
   281 subsubsection \<open>Difference\<close>
   282 
   283 instance multiset :: (type) comm_monoid_diff
   284   by standard (transfer; simp add: fun_eq_iff)
   285 
   286 lemma count_diff [simp]:
   287   "count (M - N) a = count M a - count N a"
   288   by (simp add: minus_multiset.rep_eq)
   289 
   290 lemma add_mset_diff_bothsides:
   291   \<open>add_mset a M - add_mset a A = M - A\<close>
   292   by (auto simp: multiset_eq_iff)
   293 
   294 lemma in_diff_count:
   295   "a \<in># M - N \<longleftrightarrow> count N a < count M a"
   296   by (simp add: set_mset_def)
   297 
   298 lemma count_in_diffI:
   299   assumes "\<And>n. count N x = n + count M x \<Longrightarrow> False"
   300   shows "x \<in># M - N"
   301 proof (rule ccontr)
   302   assume "x \<notin># M - N"
   303   then have "count N x = (count N x - count M x) + count M x"
   304     by (simp add: in_diff_count not_less)
   305   with assms show False by auto
   306 qed
   307 
   308 lemma in_diff_countE:
   309   assumes "x \<in># M - N"
   310   obtains n where "count M x = Suc n + count N x"
   311 proof -
   312   from assms have "count M x - count N x > 0" by (simp add: in_diff_count)
   313   then have "count M x > count N x" by simp
   314   then obtain n where "count M x = Suc n + count N x"
   315     using less_iff_Suc_add by auto
   316   with that show thesis .
   317 qed
   318 
   319 lemma in_diffD:
   320   assumes "a \<in># M - N"
   321   shows "a \<in># M"
   322 proof -
   323   have "0 \<le> count N a" by simp
   324   also from assms have "count N a < count M a"
   325     by (simp add: in_diff_count)
   326   finally show ?thesis by simp
   327 qed
   328 
   329 lemma set_mset_diff:
   330   "set_mset (M - N) = {a. count N a < count M a}"
   331   by (simp add: set_mset_def)
   332 
   333 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   334   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   335 
   336 lemma diff_cancel: "A - A = {#}"
   337   by (fact Groups.diff_cancel)
   338 
   339 lemma diff_union_cancelR: "M + N - N = (M::'a multiset)"
   340   by (fact add_diff_cancel_right')
   341 
   342 lemma diff_union_cancelL: "N + M - N = (M::'a multiset)"
   343   by (fact add_diff_cancel_left')
   344 
   345 lemma diff_right_commute:
   346   fixes M N Q :: "'a multiset"
   347   shows "M - N - Q = M - Q - N"
   348   by (fact diff_right_commute)
   349 
   350 lemma diff_add:
   351   fixes M N Q :: "'a multiset"
   352   shows "M - (N + Q) = M - N - Q"
   353   by (rule sym) (fact diff_diff_add)
   354 
   355 lemma insert_DiffM [simp]: "x \<in># M \<Longrightarrow> add_mset x (M - {#x#}) = M"
   356   by (clarsimp simp: multiset_eq_iff)
   357 
   358 lemma insert_DiffM2: "x \<in># M \<Longrightarrow> (M - {#x#}) + {#x#} = M"
   359   by simp
   360 
   361 lemma diff_union_swap: "a \<noteq> b \<Longrightarrow> add_mset b (M - {#a#}) = add_mset b M - {#a#}"
   362   by (auto simp add: multiset_eq_iff)
   363 
   364 lemma diff_add_mset_swap [simp]: "b \<notin># A \<Longrightarrow> add_mset b M - A = add_mset b (M - A)"
   365   by (auto simp add: multiset_eq_iff simp: not_in_iff)
   366 
   367 lemma diff_union_swap2 [simp]: "y \<in># M \<Longrightarrow> add_mset x M - {#y#} = add_mset x (M - {#y#})"
   368   by (metis add_mset_diff_bothsides diff_union_swap diff_zero insert_DiffM)
   369 
   370 lemma diff_diff_add_mset [simp]: "(M::'a multiset) - N - P = M - (N + P)"
   371   by (rule diff_diff_add)
   372 
   373 lemma diff_union_single_conv:
   374   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   375   by (simp add: multiset_eq_iff Suc_le_eq)
   376 
   377 lemma mset_add [elim?]:
   378   assumes "a \<in># A"
   379   obtains B where "A = add_mset a B"
   380 proof -
   381   from assms have "A = add_mset a (A - {#a#})"
   382     by simp
   383   with that show thesis .
   384 qed
   385 
   386 lemma union_iff:
   387   "a \<in># A + B \<longleftrightarrow> a \<in># A \<or> a \<in># B"
   388   by auto
   389 
   390 
   391 subsubsection \<open>Equality of multisets\<close>
   392 
   393 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   394   by (auto simp add: multiset_eq_iff)
   395 
   396 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   397   by (auto simp add: multiset_eq_iff)
   398 
   399 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   400   by (auto simp add: multiset_eq_iff)
   401 
   402 lemma multi_self_add_other_not_self [simp]: "M = add_mset x M \<longleftrightarrow> False"
   403   by (auto simp add: multiset_eq_iff)
   404 
   405 lemma add_mset_remove_trivial [simp]: \<open>add_mset x M - {#x#} = M\<close>
   406   by (auto simp: multiset_eq_iff)
   407 
   408 lemma diff_single_trivial: "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   409   by (auto simp add: multiset_eq_iff not_in_iff)
   410 
   411 lemma diff_single_eq_union: "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = add_mset x N"
   412   by auto
   413 
   414 lemma union_single_eq_diff: "add_mset x M = N \<Longrightarrow> M = N - {#x#}"
   415   unfolding add_mset_add_single[of _ M] by (fact add_implies_diff)
   416 
   417 lemma union_single_eq_member: "add_mset x M = N \<Longrightarrow> x \<in># N"
   418   by auto
   419 
   420 lemma add_mset_remove_trivial_If:
   421   "add_mset a (N - {#a#}) = (if a \<in># N then N else add_mset a N)"
   422   by (simp add: diff_single_trivial)
   423 
   424 lemma add_mset_remove_trivial_eq: \<open>N = add_mset a (N - {#a#}) \<longleftrightarrow> a \<in># N\<close>
   425   by (auto simp: add_mset_remove_trivial_If)
   426 
   427 lemma union_is_single:
   428   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N = {#} \<or> M = {#} \<and> N = {#a#}"
   429   (is "?lhs = ?rhs")
   430 proof
   431   show ?lhs if ?rhs using that by auto
   432   show ?rhs if ?lhs
   433     by (metis Multiset.diff_cancel add.commute add_diff_cancel_left' diff_add_zero diff_single_trivial insert_DiffM that)
   434 qed
   435 
   436 lemma single_is_union: "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   437   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   438 
   439 lemma add_eq_conv_diff:
   440   "add_mset a M = add_mset b N \<longleftrightarrow> M = N \<and> a = b \<or> M = add_mset b (N - {#a#}) \<and> N = add_mset a (M - {#b#})"
   441   (is "?lhs \<longleftrightarrow> ?rhs")
   442 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   443 proof
   444   show ?lhs if ?rhs
   445     using that
   446     by (auto simp add: add_mset_commute[of a b])
   447   show ?rhs if ?lhs
   448   proof (cases "a = b")
   449     case True with \<open>?lhs\<close> show ?thesis by simp
   450   next
   451     case False
   452     from \<open>?lhs\<close> have "a \<in># add_mset b N" by (rule union_single_eq_member)
   453     with False have "a \<in># N" by auto
   454     moreover from \<open>?lhs\<close> have "M = add_mset b N - {#a#}" by (rule union_single_eq_diff)
   455     moreover note False
   456     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"])
   457   qed
   458 qed
   459 
   460 lemma add_mset_eq_single [iff]: "add_mset b M = {#a#} \<longleftrightarrow> b = a \<and> M = {#}"
   461   by (auto simp: add_eq_conv_diff)
   462 
   463 lemma single_eq_add_mset [iff]: "{#a#} = add_mset b M \<longleftrightarrow> b = a \<and> M = {#}"
   464   by (auto simp: add_eq_conv_diff)
   465 
   466 lemma insert_noteq_member:
   467   assumes BC: "add_mset b B = add_mset c C"
   468    and bnotc: "b \<noteq> c"
   469   shows "c \<in># B"
   470 proof -
   471   have "c \<in># add_mset c C" by simp
   472   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   473   then have "c \<in># add_mset b B" using BC by simp
   474   then show "c \<in># B" using nc by simp
   475 qed
   476 
   477 lemma add_eq_conv_ex:
   478   "(add_mset a M = add_mset b N) =
   479     (M = N \<and> a = b \<or> (\<exists>K. M = add_mset b K \<and> N = add_mset a K))"
   480   by (auto simp add: add_eq_conv_diff)
   481 
   482 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = add_mset x A"
   483   by (rule exI [where x = "M - {#x#}"]) simp
   484 
   485 lemma multiset_add_sub_el_shuffle:
   486   assumes "c \<in># B"
   487     and "b \<noteq> c"
   488   shows "add_mset b (B - {#c#}) = add_mset b B - {#c#}"
   489 proof -
   490   from \<open>c \<in># B\<close> obtain A where B: "B = add_mset c A"
   491     by (blast dest: multi_member_split)
   492   have "add_mset b A = add_mset c (add_mset b A) - {#c#}" by simp
   493   then have "add_mset b A = add_mset b (add_mset c A) - {#c#}"
   494     by (simp add: \<open>b \<noteq> c\<close>)
   495   then show ?thesis using B by simp
   496 qed
   497 
   498 lemma add_mset_eq_singleton_iff[iff]:
   499   "add_mset x M = {#y#} \<longleftrightarrow> M = {#} \<and> x = y"
   500   by auto
   501 
   502 
   503 subsubsection \<open>Pointwise ordering induced by count\<close>
   504 
   505 definition subseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<subseteq>#" 50)
   506   where "A \<subseteq># B \<longleftrightarrow> (\<forall>a. count A a \<le> count B a)"
   507 
   508 definition subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "\<subset>#" 50)
   509   where "A \<subset># B \<longleftrightarrow> A \<subseteq># B \<and> A \<noteq> B"
   510 
   511 abbreviation (input) supseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<supseteq>#" 50)
   512   where "supseteq_mset A B \<equiv> B \<subseteq># A"
   513 
   514 abbreviation (input) supset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<supset>#" 50)
   515   where "supset_mset A B \<equiv> B \<subset># A"
   516 
   517 notation (input)
   518   subseteq_mset  (infix "\<le>#" 50) and
   519   supseteq_mset  (infix "\<ge>#" 50)
   520 
   521 notation (ASCII)
   522   subseteq_mset  (infix "<=#" 50) and
   523   subset_mset  (infix "<#" 50) and
   524   supseteq_mset  (infix ">=#" 50) and
   525   supset_mset  (infix ">#" 50)
   526 
   527 interpretation subset_mset: ordered_ab_semigroup_add_imp_le "op +" "op -" "op \<subseteq>#" "op \<subset>#"
   528   by standard (auto simp add: subset_mset_def subseteq_mset_def multiset_eq_iff intro: order_trans antisym)
   529     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   530 
   531 interpretation subset_mset: ordered_ab_semigroup_monoid_add_imp_le "op +" 0 "op -" "op \<subseteq>#" "op \<subset>#"
   532   by standard
   533     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   534 
   535 lemma mset_subset_eqI:
   536   "(\<And>a. count A a \<le> count B a) \<Longrightarrow> A \<subseteq># B"
   537   by (simp add: subseteq_mset_def)
   538 
   539 lemma mset_subset_eq_count:
   540   "A \<subseteq># B \<Longrightarrow> count A a \<le> count B a"
   541   by (simp add: subseteq_mset_def)
   542 
   543 lemma mset_subset_eq_exists_conv: "(A::'a multiset) \<subseteq># B \<longleftrightarrow> (\<exists>C. B = A + C)"
   544   unfolding subseteq_mset_def
   545   apply (rule iffI)
   546    apply (rule exI [where x = "B - A"])
   547    apply (auto intro: multiset_eq_iff [THEN iffD2])
   548   done
   549 
   550 interpretation subset_mset: ordered_cancel_comm_monoid_diff "op +" 0 "op \<subseteq>#" "op \<subset>#" "op -"
   551   by standard (simp, fact mset_subset_eq_exists_conv)
   552     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   553 
   554 declare subset_mset.add_diff_assoc[simp] subset_mset.add_diff_assoc2[simp]
   555 
   556 lemma mset_subset_eq_mono_add_right_cancel: "(A::'a multiset) + C \<subseteq># B + C \<longleftrightarrow> A \<subseteq># B"
   557    by (fact subset_mset.add_le_cancel_right)
   558 
   559 lemma mset_subset_eq_mono_add_left_cancel: "C + (A::'a multiset) \<subseteq># C + B \<longleftrightarrow> A \<subseteq># B"
   560    by (fact subset_mset.add_le_cancel_left)
   561 
   562 lemma mset_subset_eq_mono_add: "(A::'a multiset) \<subseteq># B \<Longrightarrow> C \<subseteq># D \<Longrightarrow> A + C \<subseteq># B + D"
   563    by (fact subset_mset.add_mono)
   564 
   565 lemma mset_subset_eq_add_left: "(A::'a multiset) \<subseteq># A + B"
   566    by simp
   567 
   568 lemma mset_subset_eq_add_right: "B \<subseteq># (A::'a multiset) + B"
   569    by simp
   570 
   571 lemma single_subset_iff [simp]:
   572   "{#a#} \<subseteq># M \<longleftrightarrow> a \<in># M"
   573   by (auto simp add: subseteq_mset_def Suc_le_eq)
   574 
   575 lemma mset_subset_eq_single: "a \<in># B \<Longrightarrow> {#a#} \<subseteq># B"
   576   by simp
   577 
   578 lemma mset_subset_eq_add_mset_cancel: \<open>add_mset a A \<subseteq># add_mset a B \<longleftrightarrow> A \<subseteq># B\<close>
   579   unfolding add_mset_add_single[of _ A] add_mset_add_single[of _ B]
   580   by (rule mset_subset_eq_mono_add_right_cancel)
   581 
   582 lemma multiset_diff_union_assoc:
   583   fixes A B C D :: "'a multiset"
   584   shows "C \<subseteq># B \<Longrightarrow> A + B - C = A + (B - C)"
   585   by (fact subset_mset.diff_add_assoc)
   586 
   587 lemma mset_subset_eq_multiset_union_diff_commute:
   588   fixes A B C D :: "'a multiset"
   589   shows "B \<subseteq># A \<Longrightarrow> A - B + C = A + C - B"
   590   by (fact subset_mset.add_diff_assoc2)
   591 
   592 lemma diff_subset_eq_self[simp]:
   593   "(M::'a multiset) - N \<subseteq># M"
   594   by (simp add: subseteq_mset_def)
   595 
   596 lemma mset_subset_eqD:
   597   assumes "A \<subseteq># B" and "x \<in># A"
   598   shows "x \<in># B"
   599 proof -
   600   from \<open>x \<in># A\<close> have "count A x > 0" by simp
   601   also from \<open>A \<subseteq># B\<close> have "count A x \<le> count B x"
   602     by (simp add: subseteq_mset_def)
   603   finally show ?thesis by simp
   604 qed
   605 
   606 lemma mset_subsetD:
   607   "A \<subset># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   608   by (auto intro: mset_subset_eqD [of A])
   609 
   610 lemma set_mset_mono:
   611   "A \<subseteq># B \<Longrightarrow> set_mset A \<subseteq> set_mset B"
   612   by (metis mset_subset_eqD subsetI)
   613 
   614 lemma mset_subset_eq_insertD:
   615   "add_mset x A \<subseteq># B \<Longrightarrow> x \<in># B \<and> A \<subset># B"
   616 apply (rule conjI)
   617  apply (simp add: mset_subset_eqD)
   618  apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   619  apply safe
   620   apply (erule_tac x = a in allE)
   621   apply (auto split: if_split_asm)
   622 done
   623 
   624 lemma mset_subset_insertD:
   625   "add_mset x A \<subset># B \<Longrightarrow> x \<in># B \<and> A \<subset># B"
   626   by (rule mset_subset_eq_insertD) simp
   627 
   628 lemma mset_subset_of_empty[simp]: "A \<subset># {#} \<longleftrightarrow> False"
   629   by (simp only: subset_mset.not_less_zero)
   630 
   631 lemma empty_subset_add_mset[simp]: "{#} \<subset># add_mset x M"
   632   by (auto intro: subset_mset.gr_zeroI)
   633 
   634 lemma empty_le: "{#} \<subseteq># A"
   635   by (fact subset_mset.zero_le)
   636 
   637 lemma insert_subset_eq_iff:
   638   "add_mset a A \<subseteq># B \<longleftrightarrow> a \<in># B \<and> A \<subseteq># B - {#a#}"
   639   using le_diff_conv2 [of "Suc 0" "count B a" "count A a"]
   640   apply (auto simp add: subseteq_mset_def not_in_iff Suc_le_eq)
   641   apply (rule ccontr)
   642   apply (auto simp add: not_in_iff)
   643   done
   644 
   645 lemma insert_union_subset_iff:
   646   "add_mset a A \<subset># B \<longleftrightarrow> a \<in># B \<and> A \<subset># B - {#a#}"
   647   by (auto simp add: insert_subset_eq_iff subset_mset_def)
   648 
   649 lemma subset_eq_diff_conv:
   650   "A - C \<subseteq># B \<longleftrightarrow> A \<subseteq># B + C"
   651   by (simp add: subseteq_mset_def le_diff_conv)
   652 
   653 lemma multi_psub_of_add_self [simp]: "A \<subset># add_mset x A"
   654   by (auto simp: subset_mset_def subseteq_mset_def)
   655 
   656 lemma multi_psub_self: "A \<subset># A = False"
   657   by simp
   658 
   659 lemma mset_subset_add_mset [simp]: "add_mset x N \<subset># add_mset x M \<longleftrightarrow> N \<subset># M"
   660   unfolding add_mset_add_single[of _ N] add_mset_add_single[of _ M]
   661   by (fact subset_mset.add_less_cancel_right)
   662 
   663 lemma mset_subset_diff_self: "c \<in># B \<Longrightarrow> B - {#c#} \<subset># B"
   664   by (auto simp: subset_mset_def elim: mset_add)
   665 
   666 lemma Diff_eq_empty_iff_mset: "A - B = {#} \<longleftrightarrow> A \<subseteq># B"
   667   by (auto simp: multiset_eq_iff subseteq_mset_def)
   668 
   669 lemma add_mset_subseteq_single_iff[iff]: "add_mset a M \<subseteq># {#b#} \<longleftrightarrow> M = {#} \<and> a = b"
   670 proof
   671   assume A: "add_mset a M \<subseteq># {#b#}"
   672   then have \<open>a = b\<close>
   673     by (auto dest: mset_subset_eq_insertD)
   674   then show "M={#} \<and> a=b"
   675     using A by (simp add: mset_subset_eq_add_mset_cancel)
   676 qed simp
   677 
   678 
   679 subsubsection \<open>Intersection and bounded union\<close>
   680 
   681 definition inf_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "\<inter>#" 70) where
   682   multiset_inter_def: "inf_subset_mset A B = A - (A - B)"
   683 
   684 interpretation subset_mset: semilattice_inf inf_subset_mset "op \<subseteq>#" "op \<subset>#"
   685 proof -
   686   have [simp]: "m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" for m n q :: nat
   687     by arith
   688   show "class.semilattice_inf op \<inter># op \<subseteq># op \<subset>#"
   689     by standard (auto simp add: multiset_inter_def subseteq_mset_def)
   690 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   691 
   692 definition sup_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"(infixl "\<union>#" 70)
   693   where "sup_subset_mset A B = A + (B - A)" \<comment> \<open>FIXME irregular fact name\<close>
   694 
   695 interpretation subset_mset: semilattice_sup sup_subset_mset "op \<subseteq>#" "op \<subset>#"
   696 proof -
   697   have [simp]: "m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" for m n q :: nat
   698     by arith
   699   show "class.semilattice_sup op \<union># op \<subseteq># op \<subset>#"
   700     by standard (auto simp add: sup_subset_mset_def subseteq_mset_def)
   701 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   702 
   703 interpretation subset_mset: bounded_lattice_bot "op \<inter>#" "op \<subseteq>#" "op \<subset>#"
   704   "op \<union>#" "{#}"
   705   by standard auto
   706     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   707 
   708 
   709 subsubsection \<open>Additional intersection facts\<close>
   710 
   711 lemma multiset_inter_count [simp]:
   712   fixes A B :: "'a multiset"
   713   shows "count (A \<inter># B) x = min (count A x) (count B x)"
   714   by (simp add: multiset_inter_def)
   715 
   716 lemma set_mset_inter [simp]:
   717   "set_mset (A \<inter># B) = set_mset A \<inter> set_mset B"
   718   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] multiset_inter_count) simp
   719 
   720 lemma diff_intersect_left_idem [simp]:
   721   "M - M \<inter># N = M - N"
   722   by (simp add: multiset_eq_iff min_def)
   723 
   724 lemma diff_intersect_right_idem [simp]:
   725   "M - N \<inter># M = M - N"
   726   by (simp add: multiset_eq_iff min_def)
   727 
   728 lemma multiset_inter_single[simp]: "a \<noteq> b \<Longrightarrow> {#a#} \<inter># {#b#} = {#}"
   729   by (rule multiset_eqI) auto
   730 
   731 lemma multiset_union_diff_commute:
   732   assumes "B \<inter># C = {#}"
   733   shows "A + B - C = A - C + B"
   734 proof (rule multiset_eqI)
   735   fix x
   736   from assms have "min (count B x) (count C x) = 0"
   737     by (auto simp add: multiset_eq_iff)
   738   then have "count B x = 0 \<or> count C x = 0"
   739     unfolding min_def by (auto split: if_splits)
   740   then show "count (A + B - C) x = count (A - C + B) x"
   741     by auto
   742 qed
   743 
   744 lemma disjunct_not_in:
   745   "A \<inter># B = {#} \<longleftrightarrow> (\<forall>a. a \<notin># A \<or> a \<notin># B)" (is "?P \<longleftrightarrow> ?Q")
   746 proof
   747   assume ?P
   748   show ?Q
   749   proof
   750     fix a
   751     from \<open>?P\<close> have "min (count A a) (count B a) = 0"
   752       by (simp add: multiset_eq_iff)
   753     then have "count A a = 0 \<or> count B a = 0"
   754       by (cases "count A a \<le> count B a") (simp_all add: min_def)
   755     then show "a \<notin># A \<or> a \<notin># B"
   756       by (simp add: not_in_iff)
   757   qed
   758 next
   759   assume ?Q
   760   show ?P
   761   proof (rule multiset_eqI)
   762     fix a
   763     from \<open>?Q\<close> have "count A a = 0 \<or> count B a = 0"
   764       by (auto simp add: not_in_iff)
   765     then show "count (A \<inter># B) a = count {#} a"
   766       by auto
   767   qed
   768 qed
   769 
   770 lemma inter_mset_empty_distrib_right: "A \<inter># (B + C) = {#} \<longleftrightarrow> A \<inter># B = {#} \<and> A \<inter># C = {#}"
   771   by (meson disjunct_not_in union_iff)
   772 
   773 lemma inter_mset_empty_distrib_left: "(A + B) \<inter># C = {#} \<longleftrightarrow> A \<inter># C = {#} \<and> B \<inter># C = {#}"
   774   by (meson disjunct_not_in union_iff)
   775 
   776 lemma add_mset_inter_add_mset[simp]:
   777   "add_mset a A \<inter># add_mset a B = add_mset a (A \<inter># B)"
   778   by (metis add_mset_add_single add_mset_diff_bothsides diff_subset_eq_self multiset_inter_def
   779       subset_mset.diff_add_assoc2)
   780 
   781 lemma add_mset_disjoint [simp]:
   782   "add_mset a A \<inter># B = {#} \<longleftrightarrow> a \<notin># B \<and> A \<inter># B = {#}"
   783   "{#} = add_mset a A \<inter># B \<longleftrightarrow> a \<notin># B \<and> {#} = A \<inter># B"
   784   by (auto simp: disjunct_not_in)
   785 
   786 lemma disjoint_add_mset [simp]:
   787   "B \<inter># add_mset a A = {#} \<longleftrightarrow> a \<notin># B \<and> B \<inter># A = {#}"
   788   "{#} = A \<inter># add_mset b B \<longleftrightarrow> b \<notin># A \<and> {#} = A \<inter># B"
   789   by (auto simp: disjunct_not_in)
   790 
   791 lemma inter_add_left1: "\<not> x \<in># N \<Longrightarrow> (add_mset x M) \<inter># N = M \<inter># N"
   792   by (simp add: multiset_eq_iff not_in_iff)
   793 
   794 lemma inter_add_left2: "x \<in># N \<Longrightarrow> (add_mset x M) \<inter># N = add_mset x (M \<inter># (N - {#x#}))"
   795   by (auto simp add: multiset_eq_iff elim: mset_add)
   796 
   797 lemma inter_add_right1: "\<not> x \<in># N \<Longrightarrow> N \<inter># (add_mset x M) = N \<inter># M"
   798   by (simp add: multiset_eq_iff not_in_iff)
   799 
   800 lemma inter_add_right2: "x \<in># N \<Longrightarrow> N \<inter># (add_mset x M) = add_mset x ((N - {#x#}) \<inter># M)"
   801   by (auto simp add: multiset_eq_iff elim: mset_add)
   802 
   803 lemma disjunct_set_mset_diff:
   804   assumes "M \<inter># N = {#}"
   805   shows "set_mset (M - N) = set_mset M"
   806 proof (rule set_eqI)
   807   fix a
   808   from assms have "a \<notin># M \<or> a \<notin># N"
   809     by (simp add: disjunct_not_in)
   810   then show "a \<in># M - N \<longleftrightarrow> a \<in># M"
   811     by (auto dest: in_diffD) (simp add: in_diff_count not_in_iff)
   812 qed
   813 
   814 lemma at_most_one_mset_mset_diff:
   815   assumes "a \<notin># M - {#a#}"
   816   shows "set_mset (M - {#a#}) = set_mset M - {a}"
   817   using assms by (auto simp add: not_in_iff in_diff_count set_eq_iff)
   818 
   819 lemma more_than_one_mset_mset_diff:
   820   assumes "a \<in># M - {#a#}"
   821   shows "set_mset (M - {#a#}) = set_mset M"
   822 proof (rule set_eqI)
   823   fix b
   824   have "Suc 0 < count M b \<Longrightarrow> count M b > 0" by arith
   825   then show "b \<in># M - {#a#} \<longleftrightarrow> b \<in># M"
   826     using assms by (auto simp add: in_diff_count)
   827 qed
   828 
   829 lemma inter_iff:
   830   "a \<in># A \<inter># B \<longleftrightarrow> a \<in># A \<and> a \<in># B"
   831   by simp
   832 
   833 lemma inter_union_distrib_left:
   834   "A \<inter># B + C = (A + C) \<inter># (B + C)"
   835   by (simp add: multiset_eq_iff min_add_distrib_left)
   836 
   837 lemma inter_union_distrib_right:
   838   "C + A \<inter># B = (C + A) \<inter># (C + B)"
   839   using inter_union_distrib_left [of A B C] by (simp add: ac_simps)
   840 
   841 lemma inter_subset_eq_union:
   842   "A \<inter># B \<subseteq># A + B"
   843   by (auto simp add: subseteq_mset_def)
   844 
   845 
   846 subsubsection \<open>Additional bounded union facts\<close>
   847 
   848 lemma sup_subset_mset_count [simp]: \<comment> \<open>FIXME irregular fact name\<close>
   849   "count (A \<union># B) x = max (count A x) (count B x)"
   850   by (simp add: sup_subset_mset_def)
   851 
   852 lemma set_mset_sup [simp]:
   853   "set_mset (A \<union># B) = set_mset A \<union> set_mset B"
   854   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] sup_subset_mset_count)
   855     (auto simp add: not_in_iff elim: mset_add)
   856 
   857 lemma sup_union_left1 [simp]: "\<not> x \<in># N \<Longrightarrow> (add_mset x M) \<union># N = add_mset x (M \<union># N)"
   858   by (simp add: multiset_eq_iff not_in_iff)
   859 
   860 lemma sup_union_left2: "x \<in># N \<Longrightarrow> (add_mset x M) \<union># N = add_mset x (M \<union># (N - {#x#}))"
   861   by (simp add: multiset_eq_iff)
   862 
   863 lemma sup_union_right1 [simp]: "\<not> x \<in># N \<Longrightarrow> N \<union># (add_mset x M) = add_mset x (N \<union># M)"
   864   by (simp add: multiset_eq_iff not_in_iff)
   865 
   866 lemma sup_union_right2: "x \<in># N \<Longrightarrow> N \<union># (add_mset x M) = add_mset x ((N - {#x#}) \<union># M)"
   867   by (simp add: multiset_eq_iff)
   868 
   869 lemma sup_union_distrib_left:
   870   "A \<union># B + C = (A + C) \<union># (B + C)"
   871   by (simp add: multiset_eq_iff max_add_distrib_left)
   872 
   873 lemma union_sup_distrib_right:
   874   "C + A \<union># B = (C + A) \<union># (C + B)"
   875   using sup_union_distrib_left [of A B C] by (simp add: ac_simps)
   876 
   877 lemma union_diff_inter_eq_sup:
   878   "A + B - A \<inter># B = A \<union># B"
   879   by (auto simp add: multiset_eq_iff)
   880 
   881 lemma union_diff_sup_eq_inter:
   882   "A + B - A \<union># B = A \<inter># B"
   883   by (auto simp add: multiset_eq_iff)
   884 
   885 lemma add_mset_union:
   886   \<open>add_mset a A \<union># add_mset a B = add_mset a (A \<union># B)\<close>
   887   by (auto simp: multiset_eq_iff max_def)
   888 
   889 
   890 subsection \<open>Replicate and repeat operations\<close>
   891 
   892 definition replicate_mset :: "nat \<Rightarrow> 'a \<Rightarrow> 'a multiset" where
   893   "replicate_mset n x = (add_mset x ^^ n) {#}"
   894 
   895 lemma replicate_mset_0[simp]: "replicate_mset 0 x = {#}"
   896   unfolding replicate_mset_def by simp
   897 
   898 lemma replicate_mset_Suc [simp]: "replicate_mset (Suc n) x = add_mset x (replicate_mset n x)"
   899   unfolding replicate_mset_def by (induct n) (auto intro: add.commute)
   900 
   901 lemma count_replicate_mset[simp]: "count (replicate_mset n x) y = (if y = x then n else 0)"
   902   unfolding replicate_mset_def by (induct n) auto
   903 
   904 fun repeat_mset :: "nat \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   905   "repeat_mset 0 _ = {#}" |
   906   "repeat_mset (Suc n) A = A + repeat_mset n A"
   907 
   908 lemma count_repeat_mset [simp]: "count (repeat_mset i A) a = i * count A a"
   909   by (induction i) auto
   910 
   911 lemma repeat_mset_right [simp]: "repeat_mset a (repeat_mset b A) = repeat_mset (a * b) A"
   912   by (auto simp: multiset_eq_iff left_diff_distrib')
   913 
   914 lemma left_diff_repeat_mset_distrib': \<open>repeat_mset (i - j) u = repeat_mset i u - repeat_mset j u\<close>
   915   by (auto simp: multiset_eq_iff left_diff_distrib')
   916 
   917 lemma left_add_mult_distrib_mset:
   918   "repeat_mset i u + (repeat_mset j u + k) = repeat_mset (i+j) u + k"
   919   by (auto simp: multiset_eq_iff add_mult_distrib)
   920 
   921 lemma repeat_mset_distrib:
   922   "repeat_mset (m + n) A = repeat_mset m A + repeat_mset n A"
   923   by (auto simp: multiset_eq_iff Nat.add_mult_distrib)
   924 
   925 lemma repeat_mset_distrib2[simp]:
   926   "repeat_mset n (A + B) = repeat_mset n A + repeat_mset n B"
   927   by (auto simp: multiset_eq_iff add_mult_distrib2)
   928 
   929 lemma repeat_mset_replicate_mset[simp]:
   930   "repeat_mset n {#a#} = replicate_mset n a"
   931   by (auto simp: multiset_eq_iff)
   932 
   933 lemma repeat_mset_distrib_add_mset[simp]:
   934   "repeat_mset n (add_mset a A) = replicate_mset n a + repeat_mset n A"
   935   by (auto simp: multiset_eq_iff)
   936 
   937 lemma repeat_mset_empty[simp]: "repeat_mset n {#} = {#}"
   938   by (induction n) simp_all
   939 
   940 
   941 subsubsection \<open>Simprocs\<close>
   942 
   943 lemma repeat_mset_iterate_add: \<open>repeat_mset n M = iterate_add n M\<close>
   944   unfolding iterate_add_def by (induction n) auto
   945 
   946 lemma mset_subseteq_add_iff1:
   947   "j \<le> (i::nat) \<Longrightarrow> (repeat_mset i u + m \<subseteq># repeat_mset j u + n) = (repeat_mset (i-j) u + m \<subseteq># n)"
   948   by (auto simp add: subseteq_mset_def nat_le_add_iff1)
   949 
   950 lemma mset_subseteq_add_iff2:
   951   "i \<le> (j::nat) \<Longrightarrow> (repeat_mset i u + m \<subseteq># repeat_mset j u + n) = (m \<subseteq># repeat_mset (j-i) u + n)"
   952   by (auto simp add: subseteq_mset_def nat_le_add_iff2)
   953 
   954 lemma mset_subset_add_iff1:
   955   "j \<le> (i::nat) \<Longrightarrow> (repeat_mset i u + m \<subset># repeat_mset j u + n) = (repeat_mset (i-j) u + m \<subset># n)"
   956   unfolding subset_mset_def repeat_mset_iterate_add
   957   by (simp add: iterate_add_eq_add_iff1 mset_subseteq_add_iff1[unfolded repeat_mset_iterate_add])
   958 
   959 lemma mset_subset_add_iff2:
   960   "i \<le> (j::nat) \<Longrightarrow> (repeat_mset i u + m \<subset># repeat_mset j u + n) = (m \<subset># repeat_mset (j-i) u + n)"
   961   unfolding subset_mset_def repeat_mset_iterate_add
   962   by (simp add: iterate_add_eq_add_iff2 mset_subseteq_add_iff2[unfolded repeat_mset_iterate_add])
   963 
   964 ML_file "multiset_simprocs.ML"
   965 
   966 lemma add_mset_replicate_mset_safe[cancelation_simproc_pre]: \<open>NO_MATCH {#} M \<Longrightarrow> add_mset a M = {#a#} + M\<close>
   967   by simp
   968 
   969 declare repeat_mset_iterate_add[cancelation_simproc_pre]
   970 
   971 declare iterate_add_distrib[cancelation_simproc_pre]
   972 declare repeat_mset_iterate_add[symmetric, cancelation_simproc_post]
   973 
   974 declare add_mset_not_empty[cancelation_simproc_eq_elim]
   975     empty_not_add_mset[cancelation_simproc_eq_elim]
   976     subset_mset.le_zero_eq[cancelation_simproc_eq_elim]
   977     empty_not_add_mset[cancelation_simproc_eq_elim]
   978     add_mset_not_empty[cancelation_simproc_eq_elim]
   979     subset_mset.le_zero_eq[cancelation_simproc_eq_elim]
   980     le_zero_eq[cancelation_simproc_eq_elim]
   981 
   982 simproc_setup mseteq_cancel
   983   ("(l::'a multiset) + m = n" | "(l::'a multiset) = m + n" |
   984    "add_mset a m = n" | "m = add_mset a n" |
   985    "replicate_mset p a = n" | "m = replicate_mset p a" |
   986    "repeat_mset p m = n" | "m = repeat_mset p m") =
   987   \<open>fn phi => Cancel_Simprocs.eq_cancel\<close>
   988 
   989 simproc_setup msetsubset_cancel
   990   ("(l::'a multiset) + m \<subset># n" | "(l::'a multiset) \<subset># m + n" |
   991    "add_mset a m \<subset># n" | "m \<subset># add_mset a n" |
   992    "replicate_mset p r \<subset># n" | "m \<subset># replicate_mset p r" |
   993    "repeat_mset p m \<subset># n" | "m \<subset># repeat_mset p m") =
   994   \<open>fn phi => Multiset_Simprocs.subset_cancel_msets\<close>
   995 
   996 simproc_setup msetsubset_eq_cancel
   997   ("(l::'a multiset) + m \<subseteq># n" | "(l::'a multiset) \<subseteq># m + n" |
   998    "add_mset a m \<subseteq># n" | "m \<subseteq># add_mset a n" |
   999    "replicate_mset p r \<subseteq># n" | "m \<subseteq># replicate_mset p r" |
  1000    "repeat_mset p m \<subseteq># n" | "m \<subseteq># repeat_mset p m") =
  1001   \<open>fn phi => Multiset_Simprocs.subseteq_cancel_msets\<close>
  1002 
  1003 simproc_setup msetdiff_cancel
  1004   ("((l::'a multiset) + m) - n" | "(l::'a multiset) - (m + n)" |
  1005    "add_mset a m - n" | "m - add_mset a n" |
  1006    "replicate_mset p r - n" | "m - replicate_mset p r" |
  1007    "repeat_mset p m - n" | "m - repeat_mset p m") =
  1008   \<open>fn phi => Cancel_Simprocs.diff_cancel\<close>
  1009 
  1010 
  1011 subsubsection \<open>Conditionally complete lattice\<close>
  1012 
  1013 instantiation multiset :: (type) Inf
  1014 begin
  1015 
  1016 lift_definition Inf_multiset :: "'a multiset set \<Rightarrow> 'a multiset" is
  1017   "\<lambda>A i. if A = {} then 0 else Inf ((\<lambda>f. f i) ` A)"
  1018 proof -
  1019   fix A :: "('a \<Rightarrow> nat) set" assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<in> multiset"
  1020   have "finite {i. (if A = {} then 0 else Inf ((\<lambda>f. f i) ` A)) > 0}" unfolding multiset_def
  1021   proof (cases "A = {}")
  1022     case False
  1023     then obtain f where "f \<in> A" by blast
  1024     hence "{i. Inf ((\<lambda>f. f i) ` A) > 0} \<subseteq> {i. f i > 0}"
  1025       by (auto intro: less_le_trans[OF _ cInf_lower])
  1026     moreover from \<open>f \<in> A\<close> * have "finite \<dots>" by (simp add: multiset_def)
  1027     ultimately have "finite {i. Inf ((\<lambda>f. f i) ` A) > 0}" by (rule finite_subset)
  1028     with False show ?thesis by simp
  1029   qed simp_all
  1030   thus "(\<lambda>i. if A = {} then 0 else INF f:A. f i) \<in> multiset" by (simp add: multiset_def)
  1031 qed
  1032 
  1033 instance ..
  1034 
  1035 end
  1036 
  1037 lemma Inf_multiset_empty: "Inf {} = {#}"
  1038   by transfer simp_all
  1039 
  1040 lemma count_Inf_multiset_nonempty: "A \<noteq> {} \<Longrightarrow> count (Inf A) x = Inf ((\<lambda>X. count X x) ` A)"
  1041   by transfer simp_all
  1042 
  1043 
  1044 instantiation multiset :: (type) Sup
  1045 begin
  1046 
  1047 definition Sup_multiset :: "'a multiset set \<Rightarrow> 'a multiset" where
  1048   "Sup_multiset A = (if A \<noteq> {} \<and> subset_mset.bdd_above A then
  1049            Abs_multiset (\<lambda>i. Sup ((\<lambda>X. count X i) ` A)) else {#})"
  1050 
  1051 lemma Sup_multiset_empty: "Sup {} = {#}"
  1052   by (simp add: Sup_multiset_def)
  1053 
  1054 lemma Sup_multiset_unbounded: "\<not>subset_mset.bdd_above A \<Longrightarrow> Sup A = {#}"
  1055   by (simp add: Sup_multiset_def)
  1056 
  1057 instance ..
  1058 
  1059 end
  1060 
  1061 
  1062 lemma bdd_above_multiset_imp_bdd_above_count:
  1063   assumes "subset_mset.bdd_above (A :: 'a multiset set)"
  1064   shows   "bdd_above ((\<lambda>X. count X x) ` A)"
  1065 proof -
  1066   from assms obtain Y where Y: "\<forall>X\<in>A. X \<subseteq># Y"
  1067     by (auto simp: subset_mset.bdd_above_def)
  1068   hence "count X x \<le> count Y x" if "X \<in> A" for X
  1069     using that by (auto intro: mset_subset_eq_count)
  1070   thus ?thesis by (intro bdd_aboveI[of _ "count Y x"]) auto
  1071 qed
  1072 
  1073 lemma bdd_above_multiset_imp_finite_support:
  1074   assumes "A \<noteq> {}" "subset_mset.bdd_above (A :: 'a multiset set)"
  1075   shows   "finite (\<Union>X\<in>A. {x. count X x > 0})"
  1076 proof -
  1077   from assms obtain Y where Y: "\<forall>X\<in>A. X \<subseteq># Y"
  1078     by (auto simp: subset_mset.bdd_above_def)
  1079   hence "count X x \<le> count Y x" if "X \<in> A" for X x
  1080     using that by (auto intro: mset_subset_eq_count)
  1081   hence "(\<Union>X\<in>A. {x. count X x > 0}) \<subseteq> {x. count Y x > 0}"
  1082     by safe (erule less_le_trans)
  1083   moreover have "finite \<dots>" by simp
  1084   ultimately show ?thesis by (rule finite_subset)
  1085 qed
  1086 
  1087 lemma Sup_multiset_in_multiset:
  1088   assumes "A \<noteq> {}" "subset_mset.bdd_above A"
  1089   shows   "(\<lambda>i. SUP X:A. count X i) \<in> multiset"
  1090   unfolding multiset_def
  1091 proof
  1092   have "{i. Sup ((\<lambda>X. count X i) ` A) > 0} \<subseteq> (\<Union>X\<in>A. {i. 0 < count X i})"
  1093   proof safe
  1094     fix i assume pos: "(SUP X:A. count X i) > 0"
  1095     show "i \<in> (\<Union>X\<in>A. {i. 0 < count X i})"
  1096     proof (rule ccontr)
  1097       assume "i \<notin> (\<Union>X\<in>A. {i. 0 < count X i})"
  1098       hence "\<forall>X\<in>A. count X i \<le> 0" by (auto simp: count_eq_zero_iff)
  1099       with assms have "(SUP X:A. count X i) \<le> 0"
  1100         by (intro cSup_least bdd_above_multiset_imp_bdd_above_count) auto
  1101       with pos show False by simp
  1102     qed
  1103   qed
  1104   moreover from assms have "finite \<dots>" by (rule bdd_above_multiset_imp_finite_support)
  1105   ultimately show "finite {i. Sup ((\<lambda>X. count X i) ` A) > 0}" by (rule finite_subset)
  1106 qed
  1107 
  1108 lemma count_Sup_multiset_nonempty:
  1109   assumes "A \<noteq> {}" "subset_mset.bdd_above A"
  1110   shows   "count (Sup A) x = (SUP X:A. count X x)"
  1111   using assms by (simp add: Sup_multiset_def Abs_multiset_inverse Sup_multiset_in_multiset)
  1112 
  1113 
  1114 interpretation subset_mset: conditionally_complete_lattice Inf Sup "op \<inter>#" "op \<subseteq>#" "op \<subset>#" "op \<union>#"
  1115 proof
  1116   fix X :: "'a multiset" and A
  1117   assume "X \<in> A"
  1118   show "Inf A \<subseteq># X"
  1119   proof (rule mset_subset_eqI)
  1120     fix x
  1121     from \<open>X \<in> A\<close> have "A \<noteq> {}" by auto
  1122     hence "count (Inf A) x = (INF X:A. count X x)"
  1123       by (simp add: count_Inf_multiset_nonempty)
  1124     also from \<open>X \<in> A\<close> have "\<dots> \<le> count X x"
  1125       by (intro cInf_lower) simp_all
  1126     finally show "count (Inf A) x \<le> count X x" .
  1127   qed
  1128 next
  1129   fix X :: "'a multiset" and A
  1130   assume nonempty: "A \<noteq> {}" and le: "\<And>Y. Y \<in> A \<Longrightarrow> X \<subseteq># Y"
  1131   show "X \<subseteq># Inf A"
  1132   proof (rule mset_subset_eqI)
  1133     fix x
  1134     from nonempty have "count X x \<le> (INF X:A. count X x)"
  1135       by (intro cInf_greatest) (auto intro: mset_subset_eq_count le)
  1136     also from nonempty have "\<dots> = count (Inf A) x" by (simp add: count_Inf_multiset_nonempty)
  1137     finally show "count X x \<le> count (Inf A) x" .
  1138   qed
  1139 next
  1140   fix X :: "'a multiset" and A
  1141   assume X: "X \<in> A" and bdd: "subset_mset.bdd_above A"
  1142   show "X \<subseteq># Sup A"
  1143   proof (rule mset_subset_eqI)
  1144     fix x
  1145     from X have "A \<noteq> {}" by auto
  1146     have "count X x \<le> (SUP X:A. count X x)"
  1147       by (intro cSUP_upper X bdd_above_multiset_imp_bdd_above_count bdd)
  1148     also from count_Sup_multiset_nonempty[OF \<open>A \<noteq> {}\<close> bdd]
  1149       have "(SUP X:A. count X x) = count (Sup A) x" by simp
  1150     finally show "count X x \<le> count (Sup A) x" .
  1151   qed
  1152 next
  1153   fix X :: "'a multiset" and A
  1154   assume nonempty: "A \<noteq> {}" and ge: "\<And>Y. Y \<in> A \<Longrightarrow> Y \<subseteq># X"
  1155   from ge have bdd: "subset_mset.bdd_above A" by (rule subset_mset.bdd_aboveI[of _ X])
  1156   show "Sup A \<subseteq># X"
  1157   proof (rule mset_subset_eqI)
  1158     fix x
  1159     from count_Sup_multiset_nonempty[OF \<open>A \<noteq> {}\<close> bdd]
  1160       have "count (Sup A) x = (SUP X:A. count X x)" .
  1161     also from nonempty have "\<dots> \<le> count X x"
  1162       by (intro cSup_least) (auto intro: mset_subset_eq_count ge)
  1163     finally show "count (Sup A) x \<le> count X x" .
  1164   qed
  1165 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
  1166 
  1167 lemma set_mset_Inf:
  1168   assumes "A \<noteq> {}"
  1169   shows   "set_mset (Inf A) = (\<Inter>X\<in>A. set_mset X)"
  1170 proof safe
  1171   fix x X assume "x \<in># Inf A" "X \<in> A"
  1172   hence nonempty: "A \<noteq> {}" by (auto simp: Inf_multiset_empty)
  1173   from \<open>x \<in># Inf A\<close> have "{#x#} \<subseteq># Inf A" by auto
  1174   also from \<open>X \<in> A\<close> have "\<dots> \<subseteq># X" by (rule subset_mset.cInf_lower) simp_all
  1175   finally show "x \<in># X" by simp
  1176 next
  1177   fix x assume x: "x \<in> (\<Inter>X\<in>A. set_mset X)"
  1178   hence "{#x#} \<subseteq># X" if "X \<in> A" for X using that by auto
  1179   from assms and this have "{#x#} \<subseteq># Inf A" by (rule subset_mset.cInf_greatest)
  1180   thus "x \<in># Inf A" by simp
  1181 qed
  1182 
  1183 lemma in_Inf_multiset_iff:
  1184   assumes "A \<noteq> {}"
  1185   shows   "x \<in># Inf A \<longleftrightarrow> (\<forall>X\<in>A. x \<in># X)"
  1186 proof -
  1187   from assms have "set_mset (Inf A) = (\<Inter>X\<in>A. set_mset X)" by (rule set_mset_Inf)
  1188   also have "x \<in> \<dots> \<longleftrightarrow> (\<forall>X\<in>A. x \<in># X)" by simp
  1189   finally show ?thesis .
  1190 qed
  1191 
  1192 lemma in_Inf_multisetD: "x \<in># Inf A \<Longrightarrow> X \<in> A \<Longrightarrow> x \<in># X"
  1193   by (subst (asm) in_Inf_multiset_iff) auto
  1194 
  1195 lemma set_mset_Sup:
  1196   assumes "subset_mset.bdd_above A"
  1197   shows   "set_mset (Sup A) = (\<Union>X\<in>A. set_mset X)"
  1198 proof safe
  1199   fix x assume "x \<in># Sup A"
  1200   hence nonempty: "A \<noteq> {}" by (auto simp: Sup_multiset_empty)
  1201   show "x \<in> (\<Union>X\<in>A. set_mset X)"
  1202   proof (rule ccontr)
  1203     assume x: "x \<notin> (\<Union>X\<in>A. set_mset X)"
  1204     have "count X x \<le> count (Sup A) x" if "X \<in> A" for X x
  1205       using that by (intro mset_subset_eq_count subset_mset.cSup_upper assms)
  1206     with x have "X \<subseteq># Sup A - {#x#}" if "X \<in> A" for X
  1207       using that by (auto simp: subseteq_mset_def algebra_simps not_in_iff)
  1208     hence "Sup A \<subseteq># Sup A - {#x#}" by (intro subset_mset.cSup_least nonempty)
  1209     with \<open>x \<in># Sup A\<close> show False
  1210       by (auto simp: subseteq_mset_def count_greater_zero_iff [symmetric]
  1211                simp del: count_greater_zero_iff dest!: spec[of _ x])
  1212   qed
  1213 next
  1214   fix x X assume "x \<in> set_mset X" "X \<in> A"
  1215   hence "{#x#} \<subseteq># X" by auto
  1216   also have "X \<subseteq># Sup A" by (intro subset_mset.cSup_upper \<open>X \<in> A\<close> assms)
  1217   finally show "x \<in> set_mset (Sup A)" by simp
  1218 qed
  1219 
  1220 lemma in_Sup_multiset_iff:
  1221   assumes "subset_mset.bdd_above A"
  1222   shows   "x \<in># Sup A \<longleftrightarrow> (\<exists>X\<in>A. x \<in># X)"
  1223 proof -
  1224   from assms have "set_mset (Sup A) = (\<Union>X\<in>A. set_mset X)" by (rule set_mset_Sup)
  1225   also have "x \<in> \<dots> \<longleftrightarrow> (\<exists>X\<in>A. x \<in># X)" by simp
  1226   finally show ?thesis .
  1227 qed
  1228 
  1229 lemma in_Sup_multisetD:
  1230   assumes "x \<in># Sup A"
  1231   shows   "\<exists>X\<in>A. x \<in># X"
  1232 proof -
  1233   have "subset_mset.bdd_above A"
  1234     by (rule ccontr) (insert assms, simp_all add: Sup_multiset_unbounded)
  1235   with assms show ?thesis by (simp add: in_Sup_multiset_iff)
  1236 qed
  1237 
  1238 interpretation subset_mset: distrib_lattice "op \<inter>#" "op \<subseteq>#" "op \<subset>#" "op \<union>#"
  1239 proof
  1240   fix A B C :: "'a multiset"
  1241   show "A \<union># (B \<inter># C) = A \<union># B \<inter># (A \<union># C)"
  1242     by (intro multiset_eqI) simp_all
  1243 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
  1244 
  1245 
  1246 subsubsection \<open>Filter (with comprehension syntax)\<close>
  1247 
  1248 text \<open>Multiset comprehension\<close>
  1249 
  1250 lift_definition filter_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"
  1251 is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
  1252 by (rule filter_preserves_multiset)
  1253 
  1254 syntax (ASCII)
  1255   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{#_ :# _./ _#})")
  1256 syntax
  1257   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{#_ \<in># _./ _#})")
  1258 translations
  1259   "{#x \<in># M. P#}" == "CONST filter_mset (\<lambda>x. P) M"
  1260 
  1261 lemma count_filter_mset [simp]:
  1262   "count (filter_mset P M) a = (if P a then count M a else 0)"
  1263   by (simp add: filter_mset.rep_eq)
  1264 
  1265 lemma set_mset_filter [simp]:
  1266   "set_mset (filter_mset P M) = {a \<in> set_mset M. P a}"
  1267   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] count_filter_mset) simp
  1268 
  1269 lemma filter_empty_mset [simp]: "filter_mset P {#} = {#}"
  1270   by (rule multiset_eqI) simp
  1271 
  1272 lemma filter_single_mset: "filter_mset P {#x#} = (if P x then {#x#} else {#})"
  1273   by (rule multiset_eqI) simp
  1274 
  1275 lemma filter_union_mset [simp]: "filter_mset P (M + N) = filter_mset P M + filter_mset P N"
  1276   by (rule multiset_eqI) simp
  1277 
  1278 lemma filter_diff_mset [simp]: "filter_mset P (M - N) = filter_mset P M - filter_mset P N"
  1279   by (rule multiset_eqI) simp
  1280 
  1281 lemma filter_inter_mset [simp]: "filter_mset P (M \<inter># N) = filter_mset P M \<inter># filter_mset P N"
  1282   by (rule multiset_eqI) simp
  1283 
  1284 lemma filter_sup_mset[simp]: "filter_mset P (A \<union># B) = filter_mset P A \<union># filter_mset P B"
  1285   by (rule multiset_eqI) simp
  1286 
  1287 lemma filter_mset_add_mset [simp]:
  1288    "filter_mset P (add_mset x A) =
  1289      (if P x then add_mset x (filter_mset P A) else filter_mset P A)"
  1290    by (auto simp: multiset_eq_iff)
  1291 
  1292 lemma multiset_filter_subset[simp]: "filter_mset f M \<subseteq># M"
  1293   by (simp add: mset_subset_eqI)
  1294 
  1295 lemma multiset_filter_mono:
  1296   assumes "A \<subseteq># B"
  1297   shows "filter_mset f A \<subseteq># filter_mset f B"
  1298 proof -
  1299   from assms[unfolded mset_subset_eq_exists_conv]
  1300   obtain C where B: "B = A + C" by auto
  1301   show ?thesis unfolding B by auto
  1302 qed
  1303 
  1304 lemma filter_mset_eq_conv:
  1305   "filter_mset P M = N \<longleftrightarrow> N \<subseteq># M \<and> (\<forall>b\<in>#N. P b) \<and> (\<forall>a\<in>#M - N. \<not> P a)" (is "?P \<longleftrightarrow> ?Q")
  1306 proof
  1307   assume ?P then show ?Q by auto (simp add: multiset_eq_iff in_diff_count)
  1308 next
  1309   assume ?Q
  1310   then obtain Q where M: "M = N + Q"
  1311     by (auto simp add: mset_subset_eq_exists_conv)
  1312   then have MN: "M - N = Q" by simp
  1313   show ?P
  1314   proof (rule multiset_eqI)
  1315     fix a
  1316     from \<open>?Q\<close> MN have *: "\<not> P a \<Longrightarrow> a \<notin># N" "P a \<Longrightarrow> a \<notin># Q"
  1317       by auto
  1318     show "count (filter_mset P M) a = count N a"
  1319     proof (cases "a \<in># M")
  1320       case True
  1321       with * show ?thesis
  1322         by (simp add: not_in_iff M)
  1323     next
  1324       case False then have "count M a = 0"
  1325         by (simp add: not_in_iff)
  1326       with M show ?thesis by simp
  1327     qed
  1328   qed
  1329 qed
  1330 
  1331 lemma filter_filter_mset: "filter_mset P (filter_mset Q M) = {#x \<in># M. Q x \<and> P x#}"
  1332   by (auto simp: multiset_eq_iff)
  1333 
  1334 lemma
  1335   filter_mset_True[simp]: "{#y \<in># M. True#} = M" and
  1336   filter_mset_False[simp]: "{#y \<in># M. False#} = {#}"
  1337   by (auto simp: multiset_eq_iff)
  1338 
  1339 
  1340 subsubsection \<open>Size\<close>
  1341 
  1342 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
  1343 
  1344 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
  1345   by (auto simp: wcount_def add_mult_distrib)
  1346 
  1347 lemma wcount_add_mset:
  1348   "wcount f (add_mset x M) a = (if x = a then Suc (f a) else 0) + wcount f M a"
  1349   unfolding add_mset_add_single[of _ M] wcount_union by (auto simp: wcount_def)
  1350 
  1351 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
  1352   "size_multiset f M = sum (wcount f M) (set_mset M)"
  1353 
  1354 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
  1355 
  1356 instantiation multiset :: (type) size
  1357 begin
  1358 
  1359 definition size_multiset where
  1360   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
  1361 instance ..
  1362 
  1363 end
  1364 
  1365 lemmas size_multiset_overloaded_eq =
  1366   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
  1367 
  1368 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
  1369 by (simp add: size_multiset_def)
  1370 
  1371 lemma size_empty [simp]: "size {#} = 0"
  1372 by (simp add: size_multiset_overloaded_def)
  1373 
  1374 lemma size_multiset_single : "size_multiset f {#b#} = Suc (f b)"
  1375 by (simp add: size_multiset_eq)
  1376 
  1377 lemma size_single: "size {#b#} = 1"
  1378 by (simp add: size_multiset_overloaded_def size_multiset_single)
  1379 
  1380 lemma sum_wcount_Int:
  1381   "finite A \<Longrightarrow> sum (wcount f N) (A \<inter> set_mset N) = sum (wcount f N) A"
  1382   by (induct rule: finite_induct)
  1383     (simp_all add: Int_insert_left wcount_def count_eq_zero_iff)
  1384 
  1385 lemma size_multiset_union [simp]:
  1386   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
  1387 apply (simp add: size_multiset_def sum_Un_nat sum.distrib sum_wcount_Int wcount_union)
  1388 apply (subst Int_commute)
  1389 apply (simp add: sum_wcount_Int)
  1390 done
  1391 
  1392 lemma size_multiset_add_mset [simp]:
  1393   "size_multiset f (add_mset a M) = Suc (f a) + size_multiset f M"
  1394   unfolding add_mset_add_single[of _ M] size_multiset_union by (auto simp: size_multiset_single)
  1395 
  1396 lemma size_add_mset [simp]: "size (add_mset a A) = Suc (size A)"
  1397 by (simp add: size_multiset_overloaded_def wcount_add_mset)
  1398 
  1399 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
  1400 by (auto simp add: size_multiset_overloaded_def)
  1401 
  1402 lemma size_multiset_eq_0_iff_empty [iff]:
  1403   "size_multiset f M = 0 \<longleftrightarrow> M = {#}"
  1404   by (auto simp add: size_multiset_eq count_eq_zero_iff)
  1405 
  1406 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
  1407 by (auto simp add: size_multiset_overloaded_def)
  1408 
  1409 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
  1410 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
  1411 
  1412 lemma size_eq_Suc_imp_elem: "size M = Suc n \<Longrightarrow> \<exists>a. a \<in># M"
  1413 apply (unfold size_multiset_overloaded_eq)
  1414 apply (drule sum_SucD)
  1415 apply auto
  1416 done
  1417 
  1418 lemma size_eq_Suc_imp_eq_union:
  1419   assumes "size M = Suc n"
  1420   shows "\<exists>a N. M = add_mset a N"
  1421 proof -
  1422   from assms obtain a where "a \<in># M"
  1423     by (erule size_eq_Suc_imp_elem [THEN exE])
  1424   then have "M = add_mset a (M - {#a#})" by simp
  1425   then show ?thesis by blast
  1426 qed
  1427 
  1428 lemma size_mset_mono:
  1429   fixes A B :: "'a multiset"
  1430   assumes "A \<subseteq># B"
  1431   shows "size A \<le> size B"
  1432 proof -
  1433   from assms[unfolded mset_subset_eq_exists_conv]
  1434   obtain C where B: "B = A + C" by auto
  1435   show ?thesis unfolding B by (induct C) auto
  1436 qed
  1437 
  1438 lemma size_filter_mset_lesseq[simp]: "size (filter_mset f M) \<le> size M"
  1439 by (rule size_mset_mono[OF multiset_filter_subset])
  1440 
  1441 lemma size_Diff_submset:
  1442   "M \<subseteq># M' \<Longrightarrow> size (M' - M) = size M' - size(M::'a multiset)"
  1443 by (metis add_diff_cancel_left' size_union mset_subset_eq_exists_conv)
  1444 
  1445 
  1446 subsection \<open>Induction and case splits\<close>
  1447 
  1448 theorem multiset_induct [case_names empty add, induct type: multiset]:
  1449   assumes empty: "P {#}"
  1450   assumes add: "\<And>x M. P M \<Longrightarrow> P (add_mset x M)"
  1451   shows "P M"
  1452 proof (induct "size M" arbitrary: M)
  1453   case 0 thus "P M" by (simp add: empty)
  1454 next
  1455   case (Suc k)
  1456   obtain N x where "M = add_mset x N"
  1457     using \<open>Suc k = size M\<close> [symmetric]
  1458     using size_eq_Suc_imp_eq_union by fast
  1459   with Suc add show "P M" by simp
  1460 qed
  1461 
  1462 lemma multiset_induct_min[case_names empty add]:
  1463   fixes M :: "'a::linorder multiset"
  1464   assumes
  1465     empty: "P {#}" and
  1466     add: "\<And>x M. P M \<Longrightarrow> (\<forall>y \<in># M. y \<ge> x) \<Longrightarrow> P (add_mset x M)"
  1467   shows "P M"
  1468 proof (induct "size M" arbitrary: M)
  1469   case (Suc k)
  1470   note ih = this(1) and Sk_eq_sz_M = this(2)
  1471 
  1472   let ?y = "Min (set_mset M)"
  1473   let ?N = "M - {#?y#}"
  1474 
  1475   have M: "M = add_mset ?y ?N"
  1476     by (metis Min_in Sk_eq_sz_M finite_set_mset insert_DiffM lessI not_less_zero
  1477       set_mset_eq_empty_iff size_empty)
  1478   show ?case
  1479     by (subst M, rule add, rule ih, metis M Sk_eq_sz_M nat.inject size_add_mset,
  1480       meson Min_le finite_set_mset in_diffD)
  1481 qed (simp add: empty)
  1482 
  1483 lemma multiset_induct_max[case_names empty add]:
  1484   fixes M :: "'a::linorder multiset"
  1485   assumes
  1486     empty: "P {#}" and
  1487     add: "\<And>x M. P M \<Longrightarrow> (\<forall>y \<in># M. y \<le> x) \<Longrightarrow> P (add_mset x M)"
  1488   shows "P M"
  1489 proof (induct "size M" arbitrary: M)
  1490   case (Suc k)
  1491   note ih = this(1) and Sk_eq_sz_M = this(2)
  1492 
  1493   let ?y = "Max (set_mset M)"
  1494   let ?N = "M - {#?y#}"
  1495 
  1496   have M: "M = add_mset ?y ?N"
  1497     by (metis Max_in Sk_eq_sz_M finite_set_mset insert_DiffM lessI not_less_zero
  1498       set_mset_eq_empty_iff size_empty)
  1499   show ?case
  1500     by (subst M, rule add, rule ih, metis M Sk_eq_sz_M nat.inject size_add_mset,
  1501       meson Max_ge finite_set_mset in_diffD)
  1502 qed (simp add: empty)
  1503 
  1504 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = add_mset a A"
  1505 by (induct M) auto
  1506 
  1507 lemma multiset_cases [cases type]:
  1508   obtains (empty) "M = {#}"
  1509     | (add) x N where "M = add_mset x N"
  1510   by (induct M) simp_all
  1511 
  1512 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
  1513 by (cases "B = {#}") (auto dest: multi_member_split)
  1514 
  1515 lemma multiset_partition: "M = {# x\<in>#M. P x #} + {# x\<in>#M. \<not> P x #}"
  1516 apply (subst multiset_eq_iff)
  1517 apply auto
  1518 done
  1519 
  1520 lemma mset_subset_size: "(A::'a multiset) \<subset># B \<Longrightarrow> size A < size B"
  1521 proof (induct A arbitrary: B)
  1522   case (empty M)
  1523   then have "M \<noteq> {#}" by (simp add: subset_mset.zero_less_iff_neq_zero)
  1524   then obtain M' x where "M = add_mset x M'"
  1525     by (blast dest: multi_nonempty_split)
  1526   then show ?case by simp
  1527 next
  1528   case (add x S T)
  1529   have IH: "\<And>B. S \<subset># B \<Longrightarrow> size S < size B" by fact
  1530   have SxsubT: "add_mset x S \<subset># T" by fact
  1531   then have "x \<in># T" and "S \<subset># T"
  1532     by (auto dest: mset_subset_insertD)
  1533   then obtain T' where T: "T = add_mset x T'"
  1534     by (blast dest: multi_member_split)
  1535   then have "S \<subset># T'" using SxsubT
  1536     by simp
  1537   then have "size S < size T'" using IH by simp
  1538   then show ?case using T by simp
  1539 qed
  1540 
  1541 lemma size_1_singleton_mset: "size M = 1 \<Longrightarrow> \<exists>a. M = {#a#}"
  1542 by (cases M) auto
  1543 
  1544 
  1545 subsubsection \<open>Strong induction and subset induction for multisets\<close>
  1546 
  1547 text \<open>Well-foundedness of strict subset relation\<close>
  1548 
  1549 lemma wf_subset_mset_rel: "wf {(M, N :: 'a multiset). M \<subset># N}"
  1550 apply (rule wf_measure [THEN wf_subset, where f1=size])
  1551 apply (clarsimp simp: measure_def inv_image_def mset_subset_size)
  1552 done
  1553 
  1554 lemma full_multiset_induct [case_names less]:
  1555 assumes ih: "\<And>B. \<forall>(A::'a multiset). A \<subset># B \<longrightarrow> P A \<Longrightarrow> P B"
  1556 shows "P B"
  1557 apply (rule wf_subset_mset_rel [THEN wf_induct])
  1558 apply (rule ih, auto)
  1559 done
  1560 
  1561 lemma multi_subset_induct [consumes 2, case_names empty add]:
  1562   assumes "F \<subseteq># A"
  1563     and empty: "P {#}"
  1564     and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (add_mset a F)"
  1565   shows "P F"
  1566 proof -
  1567   from \<open>F \<subseteq># A\<close>
  1568   show ?thesis
  1569   proof (induct F)
  1570     show "P {#}" by fact
  1571   next
  1572     fix x F
  1573     assume P: "F \<subseteq># A \<Longrightarrow> P F" and i: "add_mset x F \<subseteq># A"
  1574     show "P (add_mset x F)"
  1575     proof (rule insert)
  1576       from i show "x \<in># A" by (auto dest: mset_subset_eq_insertD)
  1577       from i have "F \<subseteq># A" by (auto dest: mset_subset_eq_insertD)
  1578       with P show "P F" .
  1579     qed
  1580   qed
  1581 qed
  1582 
  1583 
  1584 subsection \<open>The fold combinator\<close>
  1585 
  1586 definition fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
  1587 where
  1588   "fold_mset f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_mset M)"
  1589 
  1590 lemma fold_mset_empty [simp]: "fold_mset f s {#} = s"
  1591   by (simp add: fold_mset_def)
  1592 
  1593 context comp_fun_commute
  1594 begin
  1595 
  1596 lemma fold_mset_add_mset [simp]: "fold_mset f s (add_mset x M) = f x (fold_mset f s M)"
  1597 proof -
  1598   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
  1599     by (fact comp_fun_commute_funpow)
  1600   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (add_mset x M) y"
  1601     by (fact comp_fun_commute_funpow)
  1602   show ?thesis
  1603   proof (cases "x \<in> set_mset M")
  1604     case False
  1605     then have *: "count (add_mset x M) x = 1"
  1606       by (simp add: not_in_iff)
  1607     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (add_mset x M) y) s (set_mset M) =
  1608       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_mset M)"
  1609       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
  1610     with False * show ?thesis
  1611       by (simp add: fold_mset_def del: count_add_mset)
  1612   next
  1613     case True
  1614     define N where "N = set_mset M - {x}"
  1615     from N_def True have *: "set_mset M = insert x N" "x \<notin> N" "finite N" by auto
  1616     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (add_mset x M) y) s N =
  1617       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
  1618       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
  1619     with * show ?thesis by (simp add: fold_mset_def del: count_add_mset) simp
  1620   qed
  1621 qed
  1622 
  1623 corollary fold_mset_single: "fold_mset f s {#x#} = f x s"
  1624   by simp
  1625 
  1626 lemma fold_mset_fun_left_comm: "f x (fold_mset f s M) = fold_mset f (f x s) M"
  1627   by (induct M) (simp_all add: fun_left_comm)
  1628 
  1629 lemma fold_mset_union [simp]: "fold_mset f s (M + N) = fold_mset f (fold_mset f s M) N"
  1630   by (induct M) (simp_all add: fold_mset_fun_left_comm)
  1631 
  1632 lemma fold_mset_fusion:
  1633   assumes "comp_fun_commute g"
  1634     and *: "\<And>x y. h (g x y) = f x (h y)"
  1635   shows "h (fold_mset g w A) = fold_mset f (h w) A"
  1636 proof -
  1637   interpret comp_fun_commute g by (fact assms)
  1638   from * show ?thesis by (induct A) auto
  1639 qed
  1640 
  1641 end
  1642 
  1643 lemma union_fold_mset_add_mset: "A + B = fold_mset add_mset A B"
  1644 proof -
  1645   interpret comp_fun_commute add_mset
  1646     by standard auto
  1647   show ?thesis
  1648     by (induction B) auto
  1649 qed
  1650 
  1651 text \<open>
  1652   A note on code generation: When defining some function containing a
  1653   subterm @{term "fold_mset F"}, code generation is not automatic. When
  1654   interpreting locale \<open>left_commutative\<close> with \<open>F\<close>, the
  1655   would be code thms for @{const fold_mset} become thms like
  1656   @{term "fold_mset F z {#} = z"} where \<open>F\<close> is not a pattern but
  1657   contains defined symbols, i.e.\ is not a code thm. Hence a separate
  1658   constant with its own code thms needs to be introduced for \<open>F\<close>. See the image operator below.
  1659 \<close>
  1660 
  1661 
  1662 subsection \<open>Image\<close>
  1663 
  1664 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
  1665   "image_mset f = fold_mset (add_mset \<circ> f) {#}"
  1666 
  1667 lemma comp_fun_commute_mset_image: "comp_fun_commute (add_mset \<circ> f)"
  1668 proof
  1669 qed (simp add: fun_eq_iff)
  1670 
  1671 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
  1672   by (simp add: image_mset_def)
  1673 
  1674 lemma image_mset_single: "image_mset f {#x#} = {#f x#}"
  1675 proof -
  1676   interpret comp_fun_commute "add_mset \<circ> f"
  1677     by (fact comp_fun_commute_mset_image)
  1678   show ?thesis by (simp add: image_mset_def)
  1679 qed
  1680 
  1681 lemma image_mset_union [simp]: "image_mset f (M + N) = image_mset f M + image_mset f N"
  1682 proof -
  1683   interpret comp_fun_commute "add_mset \<circ> f"
  1684     by (fact comp_fun_commute_mset_image)
  1685   show ?thesis by (induct N) (simp_all add: image_mset_def)
  1686 qed
  1687 
  1688 corollary image_mset_add_mset [simp]:
  1689   "image_mset f (add_mset a M) = add_mset (f a) (image_mset f M)"
  1690   unfolding image_mset_union add_mset_add_single[of a M] by (simp add: image_mset_single)
  1691 
  1692 lemma set_image_mset [simp]: "set_mset (image_mset f M) = image f (set_mset M)"
  1693   by (induct M) simp_all
  1694 
  1695 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
  1696   by (induct M) simp_all
  1697 
  1698 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
  1699   by (cases M) auto
  1700 
  1701 lemma image_mset_If:
  1702   "image_mset (\<lambda>x. if P x then f x else g x) A =
  1703      image_mset f (filter_mset P A) + image_mset g (filter_mset (\<lambda>x. \<not>P x) A)"
  1704   by (induction A) auto
  1705 
  1706 lemma image_mset_Diff:
  1707   assumes "B \<subseteq># A"
  1708   shows   "image_mset f (A - B) = image_mset f A - image_mset f B"
  1709 proof -
  1710   have "image_mset f (A - B + B) = image_mset f (A - B) + image_mset f B"
  1711     by simp
  1712   also from assms have "A - B + B = A"
  1713     by (simp add: subset_mset.diff_add)
  1714   finally show ?thesis by simp
  1715 qed
  1716 
  1717 lemma count_image_mset:
  1718   "count (image_mset f A) x = (\<Sum>y\<in>f -` {x} \<inter> set_mset A. count A y)"
  1719 proof (induction A)
  1720   case empty
  1721   then show ?case by simp
  1722 next
  1723   case (add x A)
  1724   moreover have *: "(if x = y then Suc n else n) = n + (if x = y then 1 else 0)" for n y
  1725     by simp
  1726   ultimately show ?case
  1727     by (auto simp: sum.distrib sum.delta' intro!: sum.mono_neutral_left)
  1728 qed
  1729 
  1730 lemma image_mset_subseteq_mono: "A \<subseteq># B \<Longrightarrow> image_mset f A \<subseteq># image_mset f B"
  1731   by (metis image_mset_union subset_mset.le_iff_add)
  1732 
  1733 lemma image_mset_subset_mono: "M \<subset># N \<Longrightarrow> image_mset f M \<subset># image_mset f N"
  1734   by (metis (no_types) Diff_eq_empty_iff_mset image_mset_Diff image_mset_is_empty_iff
  1735     image_mset_subseteq_mono subset_mset.less_le_not_le)
  1736 
  1737 syntax (ASCII)
  1738   "_comprehension_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"  ("({#_/. _ :# _#})")
  1739 syntax
  1740   "_comprehension_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"  ("({#_/. _ \<in># _#})")
  1741 translations
  1742   "{#e. x \<in># M#}" \<rightleftharpoons> "CONST image_mset (\<lambda>x. e) M"
  1743 
  1744 syntax (ASCII)
  1745   "_comprehension_mset'" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"  ("({#_/ | _ :# _./ _#})")
  1746 syntax
  1747   "_comprehension_mset'" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"  ("({#_/ | _ \<in># _./ _#})")
  1748 translations
  1749   "{#e | x\<in>#M. P#}" \<rightharpoonup> "{#e. x \<in># {# x\<in>#M. P#}#}"
  1750 
  1751 text \<open>
  1752   This allows to write not just filters like @{term "{#x\<in>#M. x<c#}"}
  1753   but also images like @{term "{#x+x. x\<in>#M #}"} and @{term [source]
  1754   "{#x+x|x\<in>#M. x<c#}"}, where the latter is currently displayed as
  1755   @{term "{#x+x|x\<in>#M. x<c#}"}.
  1756 \<close>
  1757 
  1758 lemma in_image_mset: "y \<in># {#f x. x \<in># M#} \<longleftrightarrow> y \<in> f ` set_mset M"
  1759 by (metis set_image_mset)
  1760 
  1761 functor image_mset: image_mset
  1762 proof -
  1763   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
  1764   proof
  1765     fix A
  1766     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
  1767       by (induct A) simp_all
  1768   qed
  1769   show "image_mset id = id"
  1770   proof
  1771     fix A
  1772     show "image_mset id A = id A"
  1773       by (induct A) simp_all
  1774   qed
  1775 qed
  1776 
  1777 declare
  1778   image_mset.id [simp]
  1779   image_mset.identity [simp]
  1780 
  1781 lemma image_mset_id[simp]: "image_mset id x = x"
  1782   unfolding id_def by auto
  1783 
  1784 lemma image_mset_cong: "(\<And>x. x \<in># M \<Longrightarrow> f x = g x) \<Longrightarrow> {#f x. x \<in># M#} = {#g x. x \<in># M#}"
  1785   by (induct M) auto
  1786 
  1787 lemma image_mset_cong_pair:
  1788   "(\<forall>x y. (x, y) \<in># M \<longrightarrow> f x y = g x y) \<Longrightarrow> {#f x y. (x, y) \<in># M#} = {#g x y. (x, y) \<in># M#}"
  1789   by (metis image_mset_cong split_cong)
  1790 
  1791 lemma image_mset_const_eq:
  1792   "{#c. a \<in># M#} = replicate_mset (size M) c"
  1793   by (induct M) simp_all
  1794 
  1795 
  1796 subsection \<open>Further conversions\<close>
  1797 
  1798 primrec mset :: "'a list \<Rightarrow> 'a multiset" where
  1799   "mset [] = {#}" |
  1800   "mset (a # x) = add_mset a (mset x)"
  1801 
  1802 lemma in_multiset_in_set:
  1803   "x \<in># mset xs \<longleftrightarrow> x \<in> set xs"
  1804   by (induct xs) simp_all
  1805 
  1806 lemma count_mset:
  1807   "count (mset xs) x = length (filter (\<lambda>y. x = y) xs)"
  1808   by (induct xs) simp_all
  1809 
  1810 lemma mset_zero_iff[simp]: "(mset x = {#}) = (x = [])"
  1811   by (induct x) auto
  1812 
  1813 lemma mset_zero_iff_right[simp]: "({#} = mset x) = (x = [])"
  1814 by (induct x) auto
  1815 
  1816 lemma mset_single_iff[iff]: "mset xs = {#x#} \<longleftrightarrow> xs = [x]"
  1817   by (cases xs) auto
  1818 
  1819 lemma mset_single_iff_right[iff]: "{#x#} = mset xs \<longleftrightarrow> xs = [x]"
  1820   by (cases xs) auto
  1821 
  1822 lemma set_mset_mset[simp]: "set_mset (mset xs) = set xs"
  1823   by (induct xs) auto
  1824 
  1825 lemma set_mset_comp_mset [simp]: "set_mset \<circ> mset = set"
  1826   by (simp add: fun_eq_iff)
  1827 
  1828 lemma size_mset [simp]: "size (mset xs) = length xs"
  1829   by (induct xs) simp_all
  1830 
  1831 lemma mset_append [simp]: "mset (xs @ ys) = mset xs + mset ys"
  1832   by (induct xs arbitrary: ys) auto
  1833 
  1834 lemma mset_filter: "mset (filter P xs) = {#x \<in># mset xs. P x #}"
  1835   by (induct xs) simp_all
  1836 
  1837 lemma mset_rev [simp]:
  1838   "mset (rev xs) = mset xs"
  1839   by (induct xs) simp_all
  1840 
  1841 lemma surj_mset: "surj mset"
  1842 apply (unfold surj_def)
  1843 apply (rule allI)
  1844 apply (rule_tac M = y in multiset_induct)
  1845  apply auto
  1846 apply (rule_tac x = "x # xa" in exI)
  1847 apply auto
  1848 done
  1849 
  1850 lemma distinct_count_atmost_1:
  1851   "distinct x = (\<forall>a. count (mset x) a = (if a \<in> set x then 1 else 0))"
  1852 proof (induct x)
  1853   case Nil then show ?case by simp
  1854 next
  1855   case (Cons x xs) show ?case (is "?lhs \<longleftrightarrow> ?rhs")
  1856   proof
  1857     assume ?lhs then show ?rhs using Cons by simp
  1858   next
  1859     assume ?rhs then have "x \<notin> set xs"
  1860       by (simp split: if_splits)
  1861     moreover from \<open>?rhs\<close> have "(\<forall>a. count (mset xs) a =
  1862        (if a \<in> set xs then 1 else 0))"
  1863       by (auto split: if_splits simp add: count_eq_zero_iff)
  1864     ultimately show ?lhs using Cons by simp
  1865   qed
  1866 qed
  1867 
  1868 lemma mset_eq_setD:
  1869   assumes "mset xs = mset ys"
  1870   shows "set xs = set ys"
  1871 proof -
  1872   from assms have "set_mset (mset xs) = set_mset (mset ys)"
  1873     by simp
  1874   then show ?thesis by simp
  1875 qed
  1876 
  1877 lemma set_eq_iff_mset_eq_distinct:
  1878   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
  1879     (set x = set y) = (mset x = mset y)"
  1880 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
  1881 
  1882 lemma set_eq_iff_mset_remdups_eq:
  1883    "(set x = set y) = (mset (remdups x) = mset (remdups y))"
  1884 apply (rule iffI)
  1885 apply (simp add: set_eq_iff_mset_eq_distinct[THEN iffD1])
  1886 apply (drule distinct_remdups [THEN distinct_remdups
  1887       [THEN set_eq_iff_mset_eq_distinct [THEN iffD2]]])
  1888 apply simp
  1889 done
  1890 
  1891 lemma mset_compl_union [simp]: "mset [x\<leftarrow>xs. P x] + mset [x\<leftarrow>xs. \<not>P x] = mset xs"
  1892   by (induct xs) auto
  1893 
  1894 lemma nth_mem_mset: "i < length ls \<Longrightarrow> (ls ! i) \<in># mset ls"
  1895 proof (induct ls arbitrary: i)
  1896   case Nil
  1897   then show ?case by simp
  1898 next
  1899   case Cons
  1900   then show ?case by (cases i) auto
  1901 qed
  1902 
  1903 lemma mset_remove1[simp]: "mset (remove1 a xs) = mset xs - {#a#}"
  1904   by (induct xs) (auto simp add: multiset_eq_iff)
  1905 
  1906 lemma mset_eq_length:
  1907   assumes "mset xs = mset ys"
  1908   shows "length xs = length ys"
  1909   using assms by (metis size_mset)
  1910 
  1911 lemma mset_eq_length_filter:
  1912   assumes "mset xs = mset ys"
  1913   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1914   using assms by (metis count_mset)
  1915 
  1916 lemma fold_multiset_equiv:
  1917   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1918     and equiv: "mset xs = mset ys"
  1919   shows "List.fold f xs = List.fold f ys"
  1920   using f equiv [symmetric]
  1921 proof (induct xs arbitrary: ys)
  1922   case Nil
  1923   then show ?case by simp
  1924 next
  1925   case (Cons x xs)
  1926   then have *: "set ys = set (x # xs)"
  1927     by (blast dest: mset_eq_setD)
  1928   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1929     by (rule Cons.prems(1)) (simp_all add: *)
  1930   moreover from * have "x \<in> set ys"
  1931     by simp
  1932   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x"
  1933     by (fact fold_remove1_split)
  1934   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)"
  1935     by (auto intro: Cons.hyps)
  1936   ultimately show ?case by simp
  1937 qed
  1938 
  1939 lemma mset_shuffle: "zs \<in> shuffle xs ys \<Longrightarrow> mset zs = mset xs + mset ys"
  1940   by (induction xs ys arbitrary: zs rule: shuffle.induct) auto
  1941 
  1942 lemma mset_insort [simp]: "mset (insort x xs) = add_mset x (mset xs)"
  1943   by (induct xs) simp_all
  1944 
  1945 lemma mset_map[simp]: "mset (map f xs) = image_mset f (mset xs)"
  1946   by (induct xs) simp_all
  1947 
  1948 global_interpretation mset_set: folding add_mset "{#}"
  1949   defines mset_set = "folding.F add_mset {#}"
  1950   by standard (simp add: fun_eq_iff)
  1951 
  1952 lemma count_mset_set [simp]:
  1953   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (mset_set A) x = 1" (is "PROP ?P")
  1954   "\<not> finite A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?Q")
  1955   "x \<notin> A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?R")
  1956 proof -
  1957   have *: "count (mset_set A) x = 0" if "x \<notin> A" for A
  1958   proof (cases "finite A")
  1959     case False then show ?thesis by simp
  1960   next
  1961     case True from True \<open>x \<notin> A\<close> show ?thesis by (induct A) auto
  1962   qed
  1963   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1964   by (auto elim!: Set.set_insert)
  1965 qed \<comment> \<open>TODO: maybe define @{const mset_set} also in terms of @{const Abs_multiset}\<close>
  1966 
  1967 lemma elem_mset_set[simp, intro]: "finite A \<Longrightarrow> x \<in># mset_set A \<longleftrightarrow> x \<in> A"
  1968   by (induct A rule: finite_induct) simp_all
  1969 
  1970 lemma mset_set_Union:
  1971   "finite A \<Longrightarrow> finite B \<Longrightarrow> A \<inter> B = {} \<Longrightarrow> mset_set (A \<union> B) = mset_set A + mset_set B"
  1972   by (induction A rule: finite_induct) auto
  1973 
  1974 lemma filter_mset_mset_set [simp]:
  1975   "finite A \<Longrightarrow> filter_mset P (mset_set A) = mset_set {x\<in>A. P x}"
  1976 proof (induction A rule: finite_induct)
  1977   case (insert x A)
  1978   from insert.hyps have "filter_mset P (mset_set (insert x A)) =
  1979       filter_mset P (mset_set A) + mset_set (if P x then {x} else {})"
  1980     by simp
  1981   also have "filter_mset P (mset_set A) = mset_set {x\<in>A. P x}"
  1982     by (rule insert.IH)
  1983   also from insert.hyps
  1984     have "\<dots> + mset_set (if P x then {x} else {}) =
  1985             mset_set ({x \<in> A. P x} \<union> (if P x then {x} else {}))" (is "_ = mset_set ?A")
  1986      by (intro mset_set_Union [symmetric]) simp_all
  1987   also from insert.hyps have "?A = {y\<in>insert x A. P y}" by auto
  1988   finally show ?case .
  1989 qed simp_all
  1990 
  1991 lemma mset_set_Diff:
  1992   assumes "finite A" "B \<subseteq> A"
  1993   shows  "mset_set (A - B) = mset_set A - mset_set B"
  1994 proof -
  1995   from assms have "mset_set ((A - B) \<union> B) = mset_set (A - B) + mset_set B"
  1996     by (intro mset_set_Union) (auto dest: finite_subset)
  1997   also from assms have "A - B \<union> B = A" by blast
  1998   finally show ?thesis by simp
  1999 qed
  2000 
  2001 lemma mset_set_set: "distinct xs \<Longrightarrow> mset_set (set xs) = mset xs"
  2002   by (induction xs) simp_all
  2003 
  2004 context linorder
  2005 begin
  2006 
  2007 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  2008 where
  2009   "sorted_list_of_multiset M = fold_mset insort [] M"
  2010 
  2011 lemma sorted_list_of_multiset_empty [simp]:
  2012   "sorted_list_of_multiset {#} = []"
  2013   by (simp add: sorted_list_of_multiset_def)
  2014 
  2015 lemma sorted_list_of_multiset_singleton [simp]:
  2016   "sorted_list_of_multiset {#x#} = [x]"
  2017 proof -
  2018   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  2019   show ?thesis by (simp add: sorted_list_of_multiset_def)
  2020 qed
  2021 
  2022 lemma sorted_list_of_multiset_insert [simp]:
  2023   "sorted_list_of_multiset (add_mset x M) = List.insort x (sorted_list_of_multiset M)"
  2024 proof -
  2025   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  2026   show ?thesis by (simp add: sorted_list_of_multiset_def)
  2027 qed
  2028 
  2029 end
  2030 
  2031 lemma mset_sorted_list_of_multiset [simp]:
  2032   "mset (sorted_list_of_multiset M) = M"
  2033 by (induct M) simp_all
  2034 
  2035 lemma sorted_list_of_multiset_mset [simp]:
  2036   "sorted_list_of_multiset (mset xs) = sort xs"
  2037 by (induct xs) simp_all
  2038 
  2039 lemma finite_set_mset_mset_set[simp]:
  2040   "finite A \<Longrightarrow> set_mset (mset_set A) = A"
  2041 by (induct A rule: finite_induct) simp_all
  2042 
  2043 lemma mset_set_empty_iff: "mset_set A = {#} \<longleftrightarrow> A = {} \<or> infinite A"
  2044   using finite_set_mset_mset_set by fastforce
  2045 
  2046 lemma infinite_set_mset_mset_set:
  2047   "\<not> finite A \<Longrightarrow> set_mset (mset_set A) = {}"
  2048 by simp
  2049 
  2050 lemma set_sorted_list_of_multiset [simp]:
  2051   "set (sorted_list_of_multiset M) = set_mset M"
  2052 by (induct M) (simp_all add: set_insort)
  2053 
  2054 lemma sorted_list_of_mset_set [simp]:
  2055   "sorted_list_of_multiset (mset_set A) = sorted_list_of_set A"
  2056 by (cases "finite A") (induct A rule: finite_induct, simp_all)
  2057 
  2058 lemma mset_upt [simp]: "mset [m..<n] = mset_set {m..<n}"
  2059   by (induction n) (simp_all add: atLeastLessThanSuc)
  2060 
  2061 lemma image_mset_map_of:
  2062   "distinct (map fst xs) \<Longrightarrow> {#the (map_of xs i). i \<in># mset (map fst xs)#} = mset (map snd xs)"
  2063 proof (induction xs)
  2064   case (Cons x xs)
  2065   have "{#the (map_of (x # xs) i). i \<in># mset (map fst (x # xs))#} =
  2066           add_mset (snd x) {#the (if i = fst x then Some (snd x) else map_of xs i).
  2067              i \<in># mset (map fst xs)#}" (is "_ = add_mset _ ?A") by simp
  2068   also from Cons.prems have "?A = {#the (map_of xs i). i :# mset (map fst xs)#}"
  2069     by (cases x, intro image_mset_cong) (auto simp: in_multiset_in_set)
  2070   also from Cons.prems have "\<dots> = mset (map snd xs)" by (intro Cons.IH) simp_all
  2071   finally show ?case by simp
  2072 qed simp_all
  2073 
  2074 (* Contributed by Lukas Bulwahn *)
  2075 lemma image_mset_mset_set:
  2076   assumes "inj_on f A"
  2077   shows "image_mset f (mset_set A) = mset_set (f ` A)"
  2078 proof cases
  2079   assume "finite A"
  2080   from this \<open>inj_on f A\<close> show ?thesis
  2081     by (induct A) auto
  2082 next
  2083   assume "infinite A"
  2084   from this \<open>inj_on f A\<close> have "infinite (f ` A)"
  2085     using finite_imageD by blast
  2086   from \<open>infinite A\<close> \<open>infinite (f ` A)\<close> show ?thesis by simp
  2087 qed
  2088 
  2089 
  2090 subsection \<open>More properties of the replicate and repeat operations\<close>
  2091 
  2092 lemma in_replicate_mset[simp]: "x \<in># replicate_mset n y \<longleftrightarrow> n > 0 \<and> x = y"
  2093   unfolding replicate_mset_def by (induct n) auto
  2094 
  2095 lemma set_mset_replicate_mset_subset[simp]: "set_mset (replicate_mset n x) = (if n = 0 then {} else {x})"
  2096   by (auto split: if_splits)
  2097 
  2098 lemma size_replicate_mset[simp]: "size (replicate_mset n M) = n"
  2099   by (induct n, simp_all)
  2100 
  2101 lemma count_le_replicate_mset_subset_eq: "n \<le> count M x \<longleftrightarrow> replicate_mset n x \<subseteq># M"
  2102   by (auto simp add: mset_subset_eqI) (metis count_replicate_mset subseteq_mset_def)
  2103 
  2104 lemma filter_eq_replicate_mset: "{#y \<in># D. y = x#} = replicate_mset (count D x) x"
  2105   by (induct D) simp_all
  2106 
  2107 lemma replicate_count_mset_eq_filter_eq:
  2108   "replicate (count (mset xs) k) k = filter (HOL.eq k) xs"
  2109   by (induct xs) auto
  2110 
  2111 lemma replicate_mset_eq_empty_iff [simp]:
  2112   "replicate_mset n a = {#} \<longleftrightarrow> n = 0"
  2113   by (induct n) simp_all
  2114 
  2115 lemma replicate_mset_eq_iff:
  2116   "replicate_mset m a = replicate_mset n b \<longleftrightarrow>
  2117     m = 0 \<and> n = 0 \<or> m = n \<and> a = b"
  2118   by (auto simp add: multiset_eq_iff)
  2119 
  2120 lemma repeat_mset_cancel1: "repeat_mset a A = repeat_mset a B \<longleftrightarrow> A = B \<or> a = 0"
  2121   by (auto simp: multiset_eq_iff)
  2122 
  2123 lemma repeat_mset_cancel2: "repeat_mset a A = repeat_mset b A \<longleftrightarrow> a = b \<or> A = {#}"
  2124   by (auto simp: multiset_eq_iff)
  2125 
  2126 lemma repeat_mset_eq_empty_iff: "repeat_mset n A = {#} \<longleftrightarrow> n = 0 \<or> A = {#}"
  2127   by (cases n) auto
  2128 
  2129 lemma image_replicate_mset [simp]:
  2130   "image_mset f (replicate_mset n a) = replicate_mset n (f a)"
  2131   by (induct n) simp_all
  2132 
  2133 
  2134 subsection \<open>Big operators\<close>
  2135 
  2136 locale comm_monoid_mset = comm_monoid
  2137 begin
  2138 
  2139 interpretation comp_fun_commute f
  2140   by standard (simp add: fun_eq_iff left_commute)
  2141 
  2142 interpretation comp?: comp_fun_commute "f \<circ> g"
  2143   by (fact comp_comp_fun_commute)
  2144 
  2145 context
  2146 begin
  2147 
  2148 definition F :: "'a multiset \<Rightarrow> 'a"
  2149   where eq_fold: "F M = fold_mset f \<^bold>1 M"
  2150 
  2151 lemma empty [simp]: "F {#} = \<^bold>1"
  2152   by (simp add: eq_fold)
  2153 
  2154 lemma singleton [simp]: "F {#x#} = x"
  2155 proof -
  2156   interpret comp_fun_commute
  2157     by standard (simp add: fun_eq_iff left_commute)
  2158   show ?thesis by (simp add: eq_fold)
  2159 qed
  2160 
  2161 lemma union [simp]: "F (M + N) = F M \<^bold>* F N"
  2162 proof -
  2163   interpret comp_fun_commute f
  2164     by standard (simp add: fun_eq_iff left_commute)
  2165   show ?thesis
  2166     by (induct N) (simp_all add: left_commute eq_fold)
  2167 qed
  2168 
  2169 lemma add_mset [simp]: "F (add_mset x N) = x \<^bold>* F N"
  2170   unfolding add_mset_add_single[of x N] union by (simp add: ac_simps)
  2171 
  2172 lemma insert [simp]:
  2173   shows "F (image_mset g (add_mset x A)) = g x \<^bold>* F (image_mset g A)"
  2174   by (simp add: eq_fold)
  2175 
  2176 lemma remove:
  2177   assumes "x \<in># A"
  2178   shows "F A = x \<^bold>* F (A - {#x#})"
  2179   using multi_member_split[OF assms] by auto
  2180 
  2181 lemma neutral:
  2182   "\<forall>x\<in>#A. x = \<^bold>1 \<Longrightarrow> F A = \<^bold>1"
  2183   by (induct A) simp_all
  2184 
  2185 lemma neutral_const [simp]:
  2186   "F (image_mset (\<lambda>_. \<^bold>1) A) = \<^bold>1"
  2187   by (simp add: neutral)
  2188 
  2189 private lemma F_image_mset_product:
  2190   "F {#g x j \<^bold>* F {#g i j. i \<in># A#}. j \<in># B#} =
  2191     F (image_mset (g x) B) \<^bold>* F {#F {#g i j. i \<in># A#}. j \<in># B#}"
  2192   by (induction B) (simp_all add: left_commute semigroup.assoc semigroup_axioms)
  2193 
  2194 lemma commute:
  2195   "F (image_mset (\<lambda>i. F (image_mset (g i) B)) A) =
  2196     F (image_mset (\<lambda>j. F (image_mset (\<lambda>i. g i j) A)) B)"
  2197   apply (induction A, simp)
  2198   apply (induction B, auto simp add: F_image_mset_product ac_simps)
  2199   done
  2200 
  2201 lemma distrib: "F (image_mset (\<lambda>x. g x \<^bold>* h x) A) = F (image_mset g A) \<^bold>* F (image_mset h A)"
  2202   by (induction A) (auto simp: ac_simps)
  2203 
  2204 lemma union_disjoint:
  2205   "A \<inter># B = {#} \<Longrightarrow> F (image_mset g (A \<union># B)) = F (image_mset g A) \<^bold>* F (image_mset g B)"
  2206   by (induction A) (auto simp: ac_simps)
  2207 
  2208 end
  2209 end
  2210 
  2211 lemma comp_fun_commute_plus_mset[simp]: "comp_fun_commute (op + :: 'a multiset \<Rightarrow> _ \<Rightarrow> _)"
  2212   by standard (simp add: add_ac comp_def)
  2213 
  2214 declare comp_fun_commute.fold_mset_add_mset[OF comp_fun_commute_plus_mset, simp]
  2215 
  2216 lemma in_mset_fold_plus_iff[iff]: "x \<in># fold_mset (op +) M NN \<longleftrightarrow> x \<in># M \<or> (\<exists>N. N \<in># NN \<and> x \<in># N)"
  2217   by (induct NN) auto
  2218 
  2219 context comm_monoid_add
  2220 begin
  2221 
  2222 sublocale sum_mset: comm_monoid_mset plus 0
  2223   defines sum_mset = sum_mset.F ..
  2224 
  2225 lemma (in semiring_1) sum_mset_replicate_mset [simp]:
  2226   "sum_mset (replicate_mset n a) = of_nat n * a"
  2227   by (induct n) (simp_all add: algebra_simps)
  2228 
  2229 lemma sum_unfold_sum_mset:
  2230   "sum f A = sum_mset (image_mset f (mset_set A))"
  2231   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  2232 
  2233 lemma sum_mset_delta: "sum_mset (image_mset (\<lambda>x. if x = y then c else 0) A) = c * count A y"
  2234   by (induction A) simp_all
  2235 
  2236 lemma sum_mset_delta': "sum_mset (image_mset (\<lambda>x. if y = x then c else 0) A) = c * count A y"
  2237   by (induction A) simp_all
  2238 
  2239 end
  2240 
  2241 lemma of_nat_sum_mset [simp]:
  2242   "of_nat (sum_mset M) = sum_mset (image_mset of_nat M)"
  2243 by (induction M) auto
  2244 
  2245 lemma sum_mset_0_iff [simp]:
  2246   "sum_mset M = (0::'a::canonically_ordered_monoid_add)
  2247    \<longleftrightarrow> (\<forall>x \<in> set_mset M. x = 0)"
  2248 by(induction M) auto
  2249 
  2250 lemma sum_mset_diff:
  2251   fixes M N :: "('a :: ordered_cancel_comm_monoid_diff) multiset"
  2252   shows "N \<subseteq># M \<Longrightarrow> sum_mset (M - N) = sum_mset M - sum_mset N"
  2253   by (metis add_diff_cancel_right' sum_mset.union subset_mset.diff_add)
  2254 
  2255 lemma size_eq_sum_mset: "size M = sum_mset (image_mset (\<lambda>_. 1) M)"
  2256 proof (induct M)
  2257   case empty then show ?case by simp
  2258 next
  2259   case (add x M) then show ?case
  2260     by (cases "x \<in> set_mset M")
  2261       (simp_all add: size_multiset_overloaded_eq not_in_iff sum.If_cases Diff_eq[symmetric]
  2262         sum.remove)
  2263 qed
  2264 
  2265 lemma size_mset_set [simp]: "size (mset_set A) = card A"
  2266 by (simp only: size_eq_sum_mset card_eq_sum sum_unfold_sum_mset)
  2267 
  2268 lemma sum_mset_sum_list: "sum_mset (mset xs) = sum_list xs"
  2269   by (induction xs) auto
  2270 
  2271 syntax (ASCII)
  2272   "_sum_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"  ("(3SUM _:#_. _)" [0, 51, 10] 10)
  2273 syntax
  2274   "_sum_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"  ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  2275 translations
  2276   "\<Sum>i \<in># A. b" \<rightleftharpoons> "CONST sum_mset (CONST image_mset (\<lambda>i. b) A)"
  2277 
  2278 lemma sum_mset_distrib_left:
  2279   fixes f :: "'a \<Rightarrow> 'b::semiring_0"
  2280   shows "c * (\<Sum>x \<in># M. f x) = (\<Sum>x \<in># M. c * f(x))"
  2281 by (induction M) (simp_all add: distrib_left)
  2282 
  2283 lemma sum_mset_distrib_right:
  2284   fixes f :: "'a \<Rightarrow> 'b::semiring_0"
  2285   shows "(\<Sum>b \<in># B. f b) * a = (\<Sum>b \<in># B. f b * a)"
  2286   by (induction B) (auto simp: distrib_right)
  2287 
  2288 lemma sum_mset_constant [simp]:
  2289   fixes y :: "'b::semiring_1"
  2290   shows \<open>(\<Sum>x\<in>#A. y) = of_nat (size A) * y\<close>
  2291   by (induction A) (auto simp: algebra_simps)
  2292 
  2293 lemma (in ordered_comm_monoid_add) sum_mset_mono:
  2294   assumes "\<And>i. i \<in># K \<Longrightarrow> f i \<le> g i"
  2295   shows "sum_mset (image_mset f K) \<le> sum_mset (image_mset g K)"
  2296   using assms by (induction K) (simp_all add: local.add_mono)
  2297 
  2298 lemma sum_mset_product:
  2299   fixes f :: "'a::{comm_monoid_add,times} \<Rightarrow> 'b::semiring_0"
  2300   shows "(\<Sum>i \<in># A. f i) * (\<Sum>i \<in># B. g i) = (\<Sum>i\<in>#A. \<Sum>j\<in>#B. f i * g j)"
  2301   by (subst sum_mset.commute) (simp add: sum_mset_distrib_left sum_mset_distrib_right)
  2302 
  2303 abbreviation Union_mset :: "'a multiset multiset \<Rightarrow> 'a multiset"  ("\<Union>#_" [900] 900)
  2304   where "\<Union># MM \<equiv> sum_mset MM" \<comment> \<open>FIXME ambiguous notation --
  2305     could likewise refer to \<open>\<Squnion>#\<close>\<close>
  2306 
  2307 lemma set_mset_Union_mset[simp]: "set_mset (\<Union># MM) = (\<Union>M \<in> set_mset MM. set_mset M)"
  2308   by (induct MM) auto
  2309 
  2310 lemma in_Union_mset_iff[iff]: "x \<in># \<Union># MM \<longleftrightarrow> (\<exists>M. M \<in># MM \<and> x \<in># M)"
  2311   by (induct MM) auto
  2312 
  2313 lemma count_sum:
  2314   "count (sum f A) x = sum (\<lambda>a. count (f a) x) A"
  2315   by (induct A rule: infinite_finite_induct) simp_all
  2316 
  2317 lemma sum_eq_empty_iff:
  2318   assumes "finite A"
  2319   shows "sum f A = {#} \<longleftrightarrow> (\<forall>a\<in>A. f a = {#})"
  2320   using assms by induct simp_all
  2321 
  2322 lemma Union_mset_empty_conv[simp]: "\<Union># M = {#} \<longleftrightarrow> (\<forall>i\<in>#M. i = {#})"
  2323   by (induction M) auto
  2324 
  2325 context comm_monoid_mult
  2326 begin
  2327 
  2328 sublocale prod_mset: comm_monoid_mset times 1
  2329   defines prod_mset = prod_mset.F ..
  2330 
  2331 lemma prod_mset_empty:
  2332   "prod_mset {#} = 1"
  2333   by (fact prod_mset.empty)
  2334 
  2335 lemma prod_mset_singleton:
  2336   "prod_mset {#x#} = x"
  2337   by (fact prod_mset.singleton)
  2338 
  2339 lemma prod_mset_Un:
  2340   "prod_mset (A + B) = prod_mset A * prod_mset B"
  2341   by (fact prod_mset.union)
  2342 
  2343 lemma prod_mset_replicate_mset [simp]:
  2344   "prod_mset (replicate_mset n a) = a ^ n"
  2345   by (induct n) simp_all
  2346 
  2347 lemma prod_unfold_prod_mset:
  2348   "prod f A = prod_mset (image_mset f (mset_set A))"
  2349   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  2350 
  2351 lemma prod_mset_multiplicity:
  2352   "prod_mset M = prod (\<lambda>x. x ^ count M x) (set_mset M)"
  2353   by (simp add: fold_mset_def prod.eq_fold prod_mset.eq_fold funpow_times_power comp_def)
  2354 
  2355 lemma prod_mset_delta: "prod_mset (image_mset (\<lambda>x. if x = y then c else 1) A) = c ^ count A y"
  2356   by (induction A) simp_all
  2357 
  2358 lemma prod_mset_delta': "prod_mset (image_mset (\<lambda>x. if y = x then c else 1) A) = c ^ count A y"
  2359   by (induction A) simp_all
  2360 
  2361 end
  2362 
  2363 syntax (ASCII)
  2364   "_prod_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"  ("(3PROD _:#_. _)" [0, 51, 10] 10)
  2365 syntax
  2366   "_prod_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"  ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  2367 translations
  2368   "\<Prod>i \<in># A. b" \<rightleftharpoons> "CONST prod_mset (CONST image_mset (\<lambda>i. b) A)"
  2369 
  2370 lemma prod_mset_constant [simp]: "(\<Prod>_\<in>#A. c) = c ^ size A"
  2371   by (simp add: image_mset_const_eq)
  2372 
  2373 lemma (in comm_monoid_mult) prod_mset_subset_imp_dvd:
  2374   assumes "A \<subseteq># B"
  2375   shows   "prod_mset A dvd prod_mset B"
  2376 proof -
  2377   from assms have "B = (B - A) + A" by (simp add: subset_mset.diff_add)
  2378   also have "prod_mset \<dots> = prod_mset (B - A) * prod_mset A" by simp
  2379   also have "prod_mset A dvd \<dots>" by simp
  2380   finally show ?thesis .
  2381 qed
  2382 
  2383 lemma (in comm_monoid_mult) dvd_prod_mset:
  2384   assumes "x \<in># A"
  2385   shows "x dvd prod_mset A"
  2386   using assms prod_mset_subset_imp_dvd [of "{#x#}" A] by simp
  2387 
  2388 lemma (in semidom) prod_mset_zero_iff [iff]:
  2389   "prod_mset A = 0 \<longleftrightarrow> 0 \<in># A"
  2390   by (induct A) auto
  2391 
  2392 lemma (in semidom_divide) prod_mset_diff:
  2393   assumes "B \<subseteq># A" and "0 \<notin># B"
  2394   shows "prod_mset (A - B) = prod_mset A div prod_mset B"
  2395 proof -
  2396   from assms obtain C where "A = B + C"
  2397     by (metis subset_mset.add_diff_inverse)
  2398   with assms show ?thesis by simp
  2399 qed
  2400 
  2401 lemma (in semidom_divide) prod_mset_minus:
  2402   assumes "a \<in># A" and "a \<noteq> 0"
  2403   shows "prod_mset (A - {#a#}) = prod_mset A div a"
  2404   using assms prod_mset_diff [of "{#a#}" A] by auto
  2405 
  2406 lemma (in algebraic_semidom) is_unit_prod_mset_iff:
  2407   "is_unit (prod_mset A) \<longleftrightarrow> (\<forall>x \<in># A. is_unit x)"
  2408   by (induct A) (auto simp: is_unit_mult_iff)
  2409 
  2410 lemma (in normalization_semidom) normalize_prod_mset:
  2411   "normalize (prod_mset A) = prod_mset (image_mset normalize A)"
  2412   by (induct A) (simp_all add: normalize_mult)
  2413 
  2414 lemma (in normalization_semidom) normalized_prod_msetI:
  2415   assumes "\<And>a. a \<in># A \<Longrightarrow> normalize a = a"
  2416   shows "normalize (prod_mset A) = prod_mset A"
  2417 proof -
  2418   from assms have "image_mset normalize A = A"
  2419     by (induct A) simp_all
  2420   then show ?thesis by (simp add: normalize_prod_mset)
  2421 qed
  2422 
  2423 lemma prod_mset_prod_list: "prod_mset (mset xs) = prod_list xs"
  2424   by (induct xs) auto
  2425 
  2426 
  2427 subsection \<open>Alternative representations\<close>
  2428 
  2429 subsubsection \<open>Lists\<close>
  2430 
  2431 context linorder
  2432 begin
  2433 
  2434 lemma mset_insort [simp]:
  2435   "mset (insort_key k x xs) = add_mset x (mset xs)"
  2436   by (induct xs) simp_all
  2437 
  2438 lemma mset_sort [simp]:
  2439   "mset (sort_key k xs) = mset xs"
  2440   by (induct xs) simp_all
  2441 
  2442 text \<open>
  2443   This lemma shows which properties suffice to show that a function
  2444   \<open>f\<close> with \<open>f xs = ys\<close> behaves like sort.
  2445 \<close>
  2446 
  2447 lemma properties_for_sort_key:
  2448   assumes "mset ys = mset xs"
  2449     and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  2450     and "sorted (map f ys)"
  2451   shows "sort_key f xs = ys"
  2452   using assms
  2453 proof (induct xs arbitrary: ys)
  2454   case Nil then show ?case by simp
  2455 next
  2456   case (Cons x xs)
  2457   from Cons.prems(2) have
  2458     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  2459     by (simp add: filter_remove1)
  2460   with Cons.prems have "sort_key f xs = remove1 x ys"
  2461     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  2462   moreover from Cons.prems have "x \<in># mset ys"
  2463     by auto
  2464   then have "x \<in> set ys"
  2465     by simp
  2466   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  2467 qed
  2468 
  2469 lemma properties_for_sort:
  2470   assumes multiset: "mset ys = mset xs"
  2471     and "sorted ys"
  2472   shows "sort xs = ys"
  2473 proof (rule properties_for_sort_key)
  2474   from multiset show "mset ys = mset xs" .
  2475   from \<open>sorted ys\<close> show "sorted (map (\<lambda>x. x) ys)" by simp
  2476   from multiset have "length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)" for k
  2477     by (rule mset_eq_length_filter)
  2478   then have "replicate (length (filter (\<lambda>y. k = y) ys)) k =
  2479     replicate (length (filter (\<lambda>x. k = x) xs)) k" for k
  2480     by simp
  2481   then show "k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs" for k
  2482     by (simp add: replicate_length_filter)
  2483 qed
  2484 
  2485 lemma sort_key_inj_key_eq:
  2486   assumes mset_equal: "mset xs = mset ys"
  2487     and "inj_on f (set xs)"
  2488     and "sorted (map f ys)"
  2489   shows "sort_key f xs = ys"
  2490 proof (rule properties_for_sort_key)
  2491   from mset_equal
  2492   show "mset ys = mset xs" by simp
  2493   from \<open>sorted (map f ys)\<close>
  2494   show "sorted (map f ys)" .
  2495   show "[x\<leftarrow>ys . f k = f x] = [x\<leftarrow>xs . f k = f x]" if "k \<in> set ys" for k
  2496   proof -
  2497     from mset_equal
  2498     have set_equal: "set xs = set ys" by (rule mset_eq_setD)
  2499     with that have "insert k (set ys) = set ys" by auto
  2500     with \<open>inj_on f (set xs)\<close> have inj: "inj_on f (insert k (set ys))"
  2501       by (simp add: set_equal)
  2502     from inj have "[x\<leftarrow>ys . f k = f x] = filter (HOL.eq k) ys"
  2503       by (auto intro!: inj_on_filter_key_eq)
  2504     also have "\<dots> = replicate (count (mset ys) k) k"
  2505       by (simp add: replicate_count_mset_eq_filter_eq)
  2506     also have "\<dots> = replicate (count (mset xs) k) k"
  2507       using mset_equal by simp
  2508     also have "\<dots> = filter (HOL.eq k) xs"
  2509       by (simp add: replicate_count_mset_eq_filter_eq)
  2510     also have "\<dots> = [x\<leftarrow>xs . f k = f x]"
  2511       using inj by (auto intro!: inj_on_filter_key_eq [symmetric] simp add: set_equal)
  2512     finally show ?thesis .
  2513   qed
  2514 qed
  2515 
  2516 lemma sort_key_eq_sort_key:
  2517   assumes "mset xs = mset ys"
  2518     and "inj_on f (set xs)"
  2519   shows "sort_key f xs = sort_key f ys"
  2520   by (rule sort_key_inj_key_eq) (simp_all add: assms)
  2521 
  2522 lemma sort_key_by_quicksort:
  2523   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  2524     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  2525     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  2526 proof (rule properties_for_sort_key)
  2527   show "mset ?rhs = mset ?lhs"
  2528     by (rule multiset_eqI) (auto simp add: mset_filter)
  2529   show "sorted (map f ?rhs)"
  2530     by (auto simp add: sorted_append intro: sorted_map_same)
  2531 next
  2532   fix l
  2533   assume "l \<in> set ?rhs"
  2534   let ?pivot = "f (xs ! (length xs div 2))"
  2535   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  2536   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  2537     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  2538   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  2539   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  2540   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  2541     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  2542   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  2543   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  2544   proof (cases "f l" ?pivot rule: linorder_cases)
  2545     case less
  2546     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  2547     with less show ?thesis
  2548       by (simp add: filter_sort [symmetric] ** ***)
  2549   next
  2550     case equal then show ?thesis
  2551       by (simp add: * less_le)
  2552   next
  2553     case greater
  2554     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  2555     with greater show ?thesis
  2556       by (simp add: filter_sort [symmetric] ** ***)
  2557   qed
  2558 qed
  2559 
  2560 lemma sort_by_quicksort:
  2561   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  2562     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  2563     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  2564   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  2565 
  2566 text \<open>A stable parametrized quicksort\<close>
  2567 
  2568 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  2569   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  2570 
  2571 lemma part_code [code]:
  2572   "part f pivot [] = ([], [], [])"
  2573   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  2574      if x' < pivot then (x # lts, eqs, gts)
  2575      else if x' > pivot then (lts, eqs, x # gts)
  2576      else (lts, x # eqs, gts))"
  2577   by (auto simp add: part_def Let_def split_def)
  2578 
  2579 lemma sort_key_by_quicksort_code [code]:
  2580   "sort_key f xs =
  2581     (case xs of
  2582       [] \<Rightarrow> []
  2583     | [x] \<Rightarrow> xs
  2584     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  2585     | _ \<Rightarrow>
  2586         let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  2587         in sort_key f lts @ eqs @ sort_key f gts)"
  2588 proof (cases xs)
  2589   case Nil then show ?thesis by simp
  2590 next
  2591   case (Cons _ ys) note hyps = Cons show ?thesis
  2592   proof (cases ys)
  2593     case Nil with hyps show ?thesis by simp
  2594   next
  2595     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  2596     proof (cases zs)
  2597       case Nil with hyps show ?thesis by auto
  2598     next
  2599       case Cons
  2600       from sort_key_by_quicksort [of f xs]
  2601       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  2602         in sort_key f lts @ eqs @ sort_key f gts)"
  2603       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  2604       with hyps Cons show ?thesis by (simp only: list.cases)
  2605     qed
  2606   qed
  2607 qed
  2608 
  2609 end
  2610 
  2611 hide_const (open) part
  2612 
  2613 lemma mset_remdups_subset_eq: "mset (remdups xs) \<subseteq># mset xs"
  2614   by (induct xs) (auto intro: subset_mset.order_trans)
  2615 
  2616 lemma mset_update:
  2617   "i < length ls \<Longrightarrow> mset (ls[i := v]) = add_mset v (mset ls - {#ls ! i#})"
  2618 proof (induct ls arbitrary: i)
  2619   case Nil then show ?case by simp
  2620 next
  2621   case (Cons x xs)
  2622   show ?case
  2623   proof (cases i)
  2624     case 0 then show ?thesis by simp
  2625   next
  2626     case (Suc i')
  2627     with Cons show ?thesis
  2628       by (cases \<open>x = xs ! i'\<close>) auto
  2629   qed
  2630 qed
  2631 
  2632 lemma mset_swap:
  2633   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  2634     mset (ls[j := ls ! i, i := ls ! j]) = mset ls"
  2635   by (cases "i = j") (simp_all add: mset_update nth_mem_mset)
  2636 
  2637 
  2638 subsection \<open>The multiset order\<close>
  2639 
  2640 subsubsection \<open>Well-foundedness\<close>
  2641 
  2642 definition mult1 :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  2643   "mult1 r = {(N, M). \<exists>a M0 K. M = add_mset a M0 \<and> N = M0 + K \<and>
  2644       (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r)}"
  2645 
  2646 definition mult :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  2647   "mult r = (mult1 r)\<^sup>+"
  2648 
  2649 lemma mult1I:
  2650   assumes "M = add_mset a M0" and "N = M0 + K" and "\<And>b. b \<in># K \<Longrightarrow> (b, a) \<in> r"
  2651   shows "(N, M) \<in> mult1 r"
  2652   using assms unfolding mult1_def by blast
  2653 
  2654 lemma mult1E:
  2655   assumes "(N, M) \<in> mult1 r"
  2656   obtains a M0 K where "M = add_mset a M0" "N = M0 + K" "\<And>b. b \<in># K \<Longrightarrow> (b, a) \<in> r"
  2657   using assms unfolding mult1_def by blast
  2658 
  2659 lemma mono_mult1:
  2660   assumes "r \<subseteq> r'" shows "mult1 r \<subseteq> mult1 r'"
  2661 unfolding mult1_def using assms by blast
  2662 
  2663 lemma mono_mult:
  2664   assumes "r \<subseteq> r'" shows "mult r \<subseteq> mult r'"
  2665 unfolding mult_def using mono_mult1[OF assms] trancl_mono by blast
  2666 
  2667 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  2668 by (simp add: mult1_def)
  2669 
  2670 lemma less_add:
  2671   assumes mult1: "(N, add_mset a M0) \<in> mult1 r"
  2672   shows
  2673     "(\<exists>M. (M, M0) \<in> mult1 r \<and> N = add_mset a M) \<or>
  2674      (\<exists>K. (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r) \<and> N = M0 + K)"
  2675 proof -
  2676   let ?r = "\<lambda>K a. \<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r"
  2677   let ?R = "\<lambda>N M. \<exists>a M0 K. M = add_mset a M0 \<and> N = M0 + K \<and> ?r K a"
  2678   obtain a' M0' K where M0: "add_mset a M0 = add_mset a' M0'"
  2679     and N: "N = M0' + K"
  2680     and r: "?r K a'"
  2681     using mult1 unfolding mult1_def by auto
  2682   show ?thesis (is "?case1 \<or> ?case2")
  2683   proof -
  2684     from M0 consider "M0 = M0'" "a = a'"
  2685       | K' where "M0 = add_mset a' K'" "M0' = add_mset a K'"
  2686       by atomize_elim (simp only: add_eq_conv_ex)
  2687     then show ?thesis
  2688     proof cases
  2689       case 1
  2690       with N r have "?r K a \<and> N = M0 + K" by simp
  2691       then have ?case2 ..
  2692       then show ?thesis ..
  2693     next
  2694       case 2
  2695       from N 2(2) have n: "N = add_mset a (K' + K)" by simp
  2696       with r 2(1) have "?R (K' + K) M0" by blast
  2697       with n have ?case1 by (simp add: mult1_def)
  2698       then show ?thesis ..
  2699     qed
  2700   qed
  2701 qed
  2702 
  2703 lemma all_accessible:
  2704   assumes "wf r"
  2705   shows "\<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  2706 proof
  2707   let ?R = "mult1 r"
  2708   let ?W = "Wellfounded.acc ?R"
  2709   {
  2710     fix M M0 a
  2711     assume M0: "M0 \<in> ?W"
  2712       and wf_hyp: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. add_mset b M \<in> ?W)"
  2713       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R \<longrightarrow> add_mset a M \<in> ?W"
  2714     have "add_mset a M0 \<in> ?W"
  2715     proof (rule accI [of "add_mset a M0"])
  2716       fix N
  2717       assume "(N, add_mset a M0) \<in> ?R"
  2718       then consider M where "(M, M0) \<in> ?R" "N = add_mset a M"
  2719         | K where "\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r" "N = M0 + K"
  2720         by atomize_elim (rule less_add)
  2721       then show "N \<in> ?W"
  2722       proof cases
  2723         case 1
  2724         from acc_hyp have "(M, M0) \<in> ?R \<longrightarrow> add_mset a M \<in> ?W" ..
  2725         from this and \<open>(M, M0) \<in> ?R\<close> have "add_mset a M \<in> ?W" ..
  2726         then show "N \<in> ?W" by (simp only: \<open>N = add_mset a M\<close>)
  2727       next
  2728         case 2
  2729         from this(1) have "M0 + K \<in> ?W"
  2730         proof (induct K)
  2731           case empty
  2732           from M0 show "M0 + {#} \<in> ?W" by simp
  2733         next
  2734           case (add x K)
  2735           from add.prems have "(x, a) \<in> r" by simp
  2736           with wf_hyp have "\<forall>M \<in> ?W. add_mset x M \<in> ?W" by blast
  2737           moreover from add have "M0 + K \<in> ?W" by simp
  2738           ultimately have "add_mset x (M0 + K) \<in> ?W" ..
  2739           then show "M0 + (add_mset x K) \<in> ?W" by simp
  2740         qed
  2741         then show "N \<in> ?W" by (simp only: 2(2))
  2742       qed
  2743     qed
  2744   } note tedious_reasoning = this
  2745 
  2746   show "M \<in> ?W" for M
  2747   proof (induct M)
  2748     show "{#} \<in> ?W"
  2749     proof (rule accI)
  2750       fix b assume "(b, {#}) \<in> ?R"
  2751       with not_less_empty show "b \<in> ?W" by contradiction
  2752     qed
  2753 
  2754     fix M a assume "M \<in> ?W"
  2755     from \<open>wf r\<close> have "\<forall>M \<in> ?W. add_mset a M \<in> ?W"
  2756     proof induct
  2757       fix a
  2758       assume r: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. add_mset b M \<in> ?W)"
  2759       show "\<forall>M \<in> ?W. add_mset a M \<in> ?W"
  2760       proof
  2761         fix M assume "M \<in> ?W"
  2762         then show "add_mset a M \<in> ?W"
  2763           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  2764       qed
  2765     qed
  2766     from this and \<open>M \<in> ?W\<close> show "add_mset a M \<in> ?W" ..
  2767   qed
  2768 qed
  2769 
  2770 theorem wf_mult1: "wf r \<Longrightarrow> wf (mult1 r)"
  2771 by (rule acc_wfI) (rule all_accessible)
  2772 
  2773 theorem wf_mult: "wf r \<Longrightarrow> wf (mult r)"
  2774 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  2775 
  2776 
  2777 subsubsection \<open>Closure-free presentation\<close>
  2778 
  2779 text \<open>One direction.\<close>
  2780 lemma mult_implies_one_step:
  2781   assumes
  2782     trans: "trans r" and
  2783     MN: "(M, N) \<in> mult r"
  2784   shows "\<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)"
  2785   using MN unfolding mult_def mult1_def
  2786 proof (induction rule: converse_trancl_induct)
  2787   case (base y)
  2788   then show ?case by force
  2789 next
  2790   case (step y z) note yz = this(1) and zN = this(2) and N_decomp = this(3)
  2791   obtain I J K where
  2792     N: "N = I + J" "z = I + K" "J \<noteq> {#}" "\<forall>k\<in>#K. \<exists>j\<in>#J. (k, j) \<in> r"
  2793     using N_decomp by blast
  2794   obtain a M0 K' where
  2795     z: "z = add_mset a M0" and y: "y = M0 + K'" and K: "\<forall>b. b \<in># K' \<longrightarrow> (b, a) \<in> r"
  2796     using yz by blast
  2797   show ?case
  2798   proof (cases "a \<in># K")
  2799     case True
  2800     moreover have "\<exists>j\<in>#J. (k, j) \<in> r" if "k \<in># K'" for k
  2801       using K N trans True by (meson that transE)
  2802     ultimately show ?thesis
  2803       by (rule_tac x = I in exI, rule_tac x = J in exI, rule_tac x = "(K - {#a#}) + K'" in exI)
  2804         (use z y N in \<open>auto simp del: subset_mset.add_diff_assoc2 dest: in_diffD\<close>)
  2805   next
  2806     case False
  2807     then have "a \<in># I" by (metis N(2) union_iff union_single_eq_member z)
  2808     moreover have "M0 = I + K - {#a#}"
  2809       using N(2) z by force
  2810     ultimately show ?thesis
  2811       by (rule_tac x = "I - {#a#}" in exI, rule_tac x = "add_mset a J" in exI,
  2812           rule_tac x = "K + K'" in exI)
  2813         (use z y N False K in \<open>auto simp: add.assoc\<close>)
  2814   qed
  2815 qed
  2816 
  2817 lemma one_step_implies_mult:
  2818   assumes
  2819     "J \<noteq> {#}" and
  2820     "\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r"
  2821   shows "(I + K, I + J) \<in> mult r"
  2822   using assms
  2823 proof (induction "size J" arbitrary: I J K)
  2824   case 0
  2825   then show ?case by auto
  2826 next
  2827   case (Suc n) note IH = this(1) and size_J = this(2)[THEN sym]
  2828   obtain J' a where J: "J = add_mset a J'"
  2829     using size_J by (blast dest: size_eq_Suc_imp_eq_union)
  2830   show ?case
  2831   proof (cases "J' = {#}")
  2832     case True
  2833     then show ?thesis
  2834       using J Suc by (fastforce simp add: mult_def mult1_def)
  2835   next
  2836     case [simp]: False
  2837     have K: "K = {#x \<in># K. (x, a) \<in> r#} + {#x \<in># K. (x, a) \<notin> r#}"
  2838       by (rule multiset_partition)
  2839     have "(I + K, (I + {# x \<in># K. (x, a) \<in> r #}) + J') \<in> mult r"
  2840       using IH[of J' "{# x \<in># K. (x, a) \<notin> r#}" "I + {# x \<in># K. (x, a) \<in> r#}"]
  2841         J Suc.prems K size_J by (auto simp: ac_simps)
  2842     moreover have "(I + {#x \<in># K. (x, a) \<in> r#} + J', I + J) \<in> mult r"
  2843       by (fastforce simp: J mult1_def mult_def)
  2844     ultimately show ?thesis
  2845       unfolding mult_def by simp
  2846   qed
  2847 qed
  2848 
  2849 lemma subset_implies_mult:
  2850   assumes sub: "A \<subset># B"
  2851   shows "(A, B) \<in> mult r"
  2852 proof -
  2853   have ApBmA: "A + (B - A) = B"
  2854     using sub by simp
  2855   have BmA: "B - A \<noteq> {#}"
  2856     using sub by (simp add: Diff_eq_empty_iff_mset subset_mset.less_le_not_le)
  2857   thus ?thesis
  2858     by (rule one_step_implies_mult[of "B - A" "{#}" _ A, unfolded ApBmA, simplified])
  2859 qed
  2860 
  2861 
  2862 subsection \<open>The multiset extension is cancellative for multiset union\<close>
  2863 
  2864 lemma mult_cancel:
  2865   assumes "trans s" and "irrefl s"
  2866   shows "(X + Z, Y + Z) \<in> mult s \<longleftrightarrow> (X, Y) \<in> mult s" (is "?L \<longleftrightarrow> ?R")
  2867 proof
  2868   assume ?L thus ?R
  2869   proof (induct Z)
  2870     case (add z Z)
  2871     obtain X' Y' Z' where *: "add_mset z X + Z = Z' + X'" "add_mset z Y + Z = Z' + Y'" "Y' \<noteq> {#}"
  2872       "\<forall>x \<in> set_mset X'. \<exists>y \<in> set_mset Y'. (x, y) \<in> s"
  2873       using mult_implies_one_step[OF \<open>trans s\<close> add(2)] by auto
  2874     consider Z2 where "Z' = add_mset z Z2" | X2 Y2 where "X' = add_mset z X2" "Y' = add_mset z Y2"
  2875       using *(1,2) by (metis add_mset_remove_trivial_If insert_iff set_mset_add_mset_insert union_iff)
  2876     thus ?case
  2877     proof (cases)
  2878       case 1 thus ?thesis using * one_step_implies_mult[of Y' X' s Z2]
  2879         by (auto simp: add.commute[of _ "{#_#}"] add.assoc intro: add(1))
  2880     next
  2881       case 2 then obtain y where "y \<in> set_mset Y2" "(z, y) \<in> s" using *(4) \<open>irrefl s\<close>
  2882         by (auto simp: irrefl_def)
  2883       moreover from this transD[OF \<open>trans s\<close> _ this(2)]
  2884       have "x' \<in> set_mset X2 \<Longrightarrow> \<exists>y \<in> set_mset Y2. (x', y) \<in> s" for x'
  2885         using 2 *(4)[rule_format, of x'] by auto
  2886       ultimately show ?thesis using  * one_step_implies_mult[of Y2 X2 s Z'] 2
  2887         by (force simp: add.commute[of "{#_#}"] add.assoc[symmetric] intro: add(1))
  2888     qed
  2889   qed auto
  2890 next
  2891   assume ?R then obtain I J K
  2892     where "Y = I + J" "X = I + K" "J \<noteq> {#}" "\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> s"
  2893     using mult_implies_one_step[OF \<open>trans s\<close>] by blast
  2894   thus ?L using one_step_implies_mult[of J K s "I + Z"] by (auto simp: ac_simps)
  2895 qed
  2896 
  2897 lemmas mult_cancel_add_mset =
  2898   mult_cancel[of _ _ "{#_#}", unfolded union_mset_add_mset_right add.comm_neutral]
  2899 
  2900 lemma mult_cancel_max:
  2901   assumes "trans s" and "irrefl s"
  2902   shows "(X, Y) \<in> mult s \<longleftrightarrow> (X - X \<inter># Y, Y - X \<inter># Y) \<in> mult s" (is "?L \<longleftrightarrow> ?R")
  2903 proof -
  2904   have "X - X \<inter># Y + X \<inter># Y = X" "Y - X \<inter># Y + X \<inter># Y = Y" by (auto simp: count_inject[symmetric])
  2905   thus ?thesis using mult_cancel[OF assms, of "X - X \<inter># Y"  "X \<inter># Y" "Y - X \<inter># Y"] by auto
  2906 qed
  2907 
  2908 
  2909 subsection \<open>Quasi-executable version of the multiset extension\<close>
  2910 
  2911 text \<open>
  2912   Predicate variants of \<open>mult\<close> and the reflexive closure of \<open>mult\<close>, which are
  2913   executable whenever the given predicate \<open>P\<close> is. Together with the standard
  2914   code equations for \<open>op \<inter>#\<close> and \<open>op -\<close> this should yield quadratic
  2915   (with respect to calls to \<open>P\<close>) implementations of \<open>multp\<close> and \<open>multeqp\<close>.
  2916 \<close>
  2917 
  2918 definition multp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
  2919   "multp P N M =
  2920     (let Z = M \<inter># N; X = M - Z in
  2921     X \<noteq> {#} \<and> (let Y = N - Z in (\<forall>y \<in> set_mset Y. \<exists>x \<in> set_mset X. P y x)))"
  2922 
  2923 definition multeqp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
  2924   "multeqp P N M =
  2925     (let Z = M \<inter># N; X = M - Z; Y = N - Z in
  2926     (\<forall>y \<in> set_mset Y. \<exists>x \<in> set_mset X. P y x))"
  2927 
  2928 lemma multp_iff:
  2929   assumes "irrefl R" and "trans R" and [simp]: "\<And>x y. P x y \<longleftrightarrow> (x, y) \<in> R"
  2930   shows "multp P N M \<longleftrightarrow> (N, M) \<in> mult R" (is "?L \<longleftrightarrow> ?R")
  2931 proof -
  2932   have *: "M \<inter># N + (N - M \<inter># N) = N" "M \<inter># N + (M - M \<inter># N) = M"
  2933     "(M - M \<inter># N) \<inter># (N - M \<inter># N) = {#}" by (auto simp: count_inject[symmetric])
  2934   show ?thesis
  2935   proof
  2936     assume ?L thus ?R
  2937       using one_step_implies_mult[of "M - M \<inter># N" "N - M \<inter># N" R "M \<inter># N"] *
  2938       by (auto simp: multp_def Let_def)
  2939   next
  2940     { fix I J K :: "'a multiset" assume "(I + J) \<inter># (I + K) = {#}"
  2941       then have "I = {#}" by (metis inter_union_distrib_right union_eq_empty)
  2942     } note [dest!] = this
  2943     assume ?R thus ?L
  2944       using mult_implies_one_step[OF assms(2), of "N - M \<inter># N" "M - M \<inter># N"]
  2945         mult_cancel_max[OF assms(2,1), of "N" "M"] * by (auto simp: multp_def)
  2946   qed
  2947 qed
  2948 
  2949 lemma multeqp_iff:
  2950   assumes "irrefl R" and "trans R" and "\<And>x y. P x y \<longleftrightarrow> (x, y) \<in> R"
  2951   shows "multeqp P N M \<longleftrightarrow> (N, M) \<in> (mult R)\<^sup>="
  2952 proof -
  2953   { assume "N \<noteq> M" "M - M \<inter># N = {#}"
  2954     then obtain y where "count N y \<noteq> count M y" by (auto simp: count_inject[symmetric])
  2955     then have "\<exists>y. count M y < count N y" using \<open>M - M \<inter># N = {#}\<close>
  2956       by (auto simp: count_inject[symmetric] dest!: le_neq_implies_less fun_cong[of _ _ y])
  2957   }
  2958   then have "multeqp P N M \<longleftrightarrow> multp P N M \<or> N = M"
  2959     by (auto simp: multeqp_def multp_def Let_def in_diff_count)
  2960   thus ?thesis using multp_iff[OF assms] by simp
  2961 qed
  2962 
  2963 
  2964 subsubsection \<open>Partial-order properties\<close>
  2965 
  2966 lemma (in preorder) mult1_lessE:
  2967   assumes "(N, M) \<in> mult1 {(a, b). a < b}"
  2968   obtains a M0 K where "M = add_mset a M0" "N = M0 + K"
  2969     "a \<notin># K" "\<And>b. b \<in># K \<Longrightarrow> b < a"
  2970 proof -
  2971   from assms obtain a M0 K where "M = add_mset a M0" "N = M0 + K" and
  2972     *: "b \<in># K \<Longrightarrow> b < a" for b by (blast elim: mult1E)
  2973   moreover from * [of a] have "a \<notin># K" by auto
  2974   ultimately show thesis by (auto intro: that)
  2975 qed
  2976 
  2977 instantiation multiset :: (preorder) order
  2978 begin
  2979 
  2980 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"
  2981   where "M' < M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  2982 
  2983 definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"
  2984   where "less_eq_multiset M' M \<longleftrightarrow> M' < M \<or> M' = M"
  2985 
  2986 instance
  2987 proof -
  2988   have irrefl: "\<not> M < M" for M :: "'a multiset"
  2989   proof
  2990     assume "M < M"
  2991     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  2992     have "trans {(x'::'a, x). x' < x}"
  2993       by (metis (mono_tags, lifting) case_prodD case_prodI less_trans mem_Collect_eq transI)
  2994     moreover note MM
  2995     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  2996       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})"
  2997       by (rule mult_implies_one_step)
  2998     then obtain I J K where "M = I + J" and "M = I + K"
  2999       and "J \<noteq> {#}" and "(\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})" by blast
  3000     then have *: "K \<noteq> {#}" and **: "\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset K. k < j" by auto
  3001     have "finite (set_mset K)" by simp
  3002     moreover note **
  3003     ultimately have "set_mset K = {}"
  3004       by (induct rule: finite_induct) (auto intro: order_less_trans)
  3005     with * show False by simp
  3006   qed
  3007   have trans: "K < M \<Longrightarrow> M < N \<Longrightarrow> K < N" for K M N :: "'a multiset"
  3008     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  3009   show "OFCLASS('a multiset, order_class)"
  3010     by standard (auto simp add: less_eq_multiset_def irrefl dest: trans)
  3011 qed
  3012 end \<comment> \<open>FIXME avoid junk stemming from type class interpretation\<close>
  3013 
  3014 lemma mset_le_irrefl [elim!]:
  3015   fixes M :: "'a::preorder multiset"
  3016   shows "M < M \<Longrightarrow> R"
  3017   by simp
  3018 
  3019 
  3020 subsubsection \<open>Monotonicity of multiset union\<close>
  3021 
  3022 lemma mult1_union: "(B, D) \<in> mult1 r \<Longrightarrow> (C + B, C + D) \<in> mult1 r"
  3023   by (force simp: mult1_def)
  3024 
  3025 lemma union_le_mono2: "B < D \<Longrightarrow> C + B < C + (D::'a::preorder multiset)"
  3026 apply (unfold less_multiset_def mult_def)
  3027 apply (erule trancl_induct)
  3028  apply (blast intro: mult1_union)
  3029 apply (blast intro: mult1_union trancl_trans)
  3030 done
  3031 
  3032 lemma union_le_mono1: "B < D \<Longrightarrow> B + C < D + (C::'a::preorder multiset)"
  3033 apply (subst add.commute [of B C])
  3034 apply (subst add.commute [of D C])
  3035 apply (erule union_le_mono2)
  3036 done
  3037 
  3038 lemma union_less_mono:
  3039   fixes A B C D :: "'a::preorder multiset"
  3040   shows "A < C \<Longrightarrow> B < D \<Longrightarrow> A + B < C + D"
  3041   by (blast intro!: union_le_mono1 union_le_mono2 less_trans)
  3042 
  3043 instantiation multiset :: (preorder) ordered_ab_semigroup_add
  3044 begin
  3045 instance
  3046   by standard (auto simp add: less_eq_multiset_def intro: union_le_mono2)
  3047 end
  3048 
  3049 
  3050 subsubsection \<open>Termination proofs with multiset orders\<close>
  3051 
  3052 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  3053   and multi_member_this: "x \<in># {# x #} + XS"
  3054   and multi_member_last: "x \<in># {# x #}"
  3055   by auto
  3056 
  3057 definition "ms_strict = mult pair_less"
  3058 definition "ms_weak = ms_strict \<union> Id"
  3059 
  3060 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  3061 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  3062 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  3063 
  3064 lemma smsI:
  3065   "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  3066   unfolding ms_strict_def
  3067 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  3068 
  3069 lemma wmsI:
  3070   "(set_mset A, set_mset B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  3071   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  3072 unfolding ms_weak_def ms_strict_def
  3073 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  3074 
  3075 inductive pw_leq
  3076 where
  3077   pw_leq_empty: "pw_leq {#} {#}"
  3078 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  3079 
  3080 lemma pw_leq_lstep:
  3081   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  3082 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  3083 
  3084 lemma pw_leq_split:
  3085   assumes "pw_leq X Y"
  3086   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  3087   using assms
  3088 proof induct
  3089   case pw_leq_empty thus ?case by auto
  3090 next
  3091   case (pw_leq_step x y X Y)
  3092   then obtain A B Z where
  3093     [simp]: "X = A + Z" "Y = B + Z"
  3094       and 1[simp]: "(set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
  3095     by auto
  3096   from pw_leq_step consider "x = y" | "(x, y) \<in> pair_less"
  3097     unfolding pair_leq_def by auto
  3098   thus ?case
  3099   proof cases
  3100     case [simp]: 1
  3101     have "{#x#} + X = A + ({#y#}+Z) \<and> {#y#} + Y = B + ({#y#}+Z) \<and>
  3102       ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  3103       by auto
  3104     thus ?thesis by blast
  3105   next
  3106     case 2
  3107     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  3108     have "{#x#} + X = ?A' + Z"
  3109       "{#y#} + Y = ?B' + Z"
  3110       by auto
  3111     moreover have
  3112       "(set_mset ?A', set_mset ?B') \<in> max_strict"
  3113       using 1 2 unfolding max_strict_def
  3114       by (auto elim!: max_ext.cases)
  3115     ultimately show ?thesis by blast
  3116   qed
  3117 qed
  3118 
  3119 lemma
  3120   assumes pwleq: "pw_leq Z Z'"
  3121   shows ms_strictI: "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  3122     and ms_weakI1:  "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  3123     and ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  3124 proof -
  3125   from pw_leq_split[OF pwleq]
  3126   obtain A' B' Z''
  3127     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  3128     and mx_or_empty: "(set_mset A', set_mset B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  3129     by blast
  3130   {
  3131     assume max: "(set_mset A, set_mset B) \<in> max_strict"
  3132     from mx_or_empty
  3133     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  3134     proof
  3135       assume max': "(set_mset A', set_mset B') \<in> max_strict"
  3136       with max have "(set_mset (A + A'), set_mset (B + B')) \<in> max_strict"
  3137         by (auto simp: max_strict_def intro: max_ext_additive)
  3138       thus ?thesis by (rule smsI)
  3139     next
  3140       assume [simp]: "A' = {#} \<and> B' = {#}"
  3141       show ?thesis by (rule smsI) (auto intro: max)
  3142     qed
  3143     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add: ac_simps)
  3144     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  3145   }
  3146   from mx_or_empty
  3147   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  3148   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add: ac_simps)
  3149 qed
  3150 
  3151 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  3152 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  3153 and nonempty_single: "{# x #} \<noteq> {#}"
  3154 by auto
  3155 
  3156 setup \<open>
  3157   let
  3158     fun msetT T = Type (@{type_name multiset}, [T]);
  3159 
  3160     fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  3161       | mk_mset T [x] =
  3162         Const (@{const_name add_mset}, T --> msetT T --> msetT T) $ x $
  3163           Const (@{const_abbrev Mempty}, msetT T)
  3164       | mk_mset T (x :: xs) =
  3165         Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  3166           mk_mset T [x] $ mk_mset T xs
  3167 
  3168     fun mset_member_tac ctxt m i =
  3169       if m <= 0 then
  3170         resolve_tac ctxt @{thms multi_member_this} i ORELSE
  3171         resolve_tac ctxt @{thms multi_member_last} i
  3172       else
  3173         resolve_tac ctxt @{thms multi_member_skip} i THEN mset_member_tac ctxt (m - 1) i
  3174 
  3175     fun mset_nonempty_tac ctxt =
  3176       resolve_tac ctxt @{thms nonempty_plus} ORELSE'
  3177       resolve_tac ctxt @{thms nonempty_single}
  3178 
  3179     fun regroup_munion_conv ctxt =
  3180       Function_Lib.regroup_conv ctxt @{const_abbrev Mempty} @{const_name plus}
  3181         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  3182 
  3183     fun unfold_pwleq_tac ctxt i =
  3184       (resolve_tac ctxt @{thms pw_leq_step} i THEN (fn st => unfold_pwleq_tac ctxt (i + 1) st))
  3185         ORELSE (resolve_tac ctxt @{thms pw_leq_lstep} i)
  3186         ORELSE (resolve_tac ctxt @{thms pw_leq_empty} i)
  3187 
  3188     val set_mset_simps = [@{thm set_mset_empty}, @{thm set_mset_single}, @{thm set_mset_union},
  3189                         @{thm Un_insert_left}, @{thm Un_empty_left}]
  3190   in
  3191     ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
  3192     {
  3193       msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  3194       mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  3195       mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_mset_simps,
  3196       smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  3197       reduction_pair = @{thm ms_reduction_pair}
  3198     })
  3199   end
  3200 \<close>
  3201 
  3202 
  3203 subsection \<open>Legacy theorem bindings\<close>
  3204 
  3205 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  3206 
  3207 lemma union_commute: "M + N = N + (M::'a multiset)"
  3208   by (fact add.commute)
  3209 
  3210 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  3211   by (fact add.assoc)
  3212 
  3213 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  3214   by (fact add.left_commute)
  3215 
  3216 lemmas union_ac = union_assoc union_commute union_lcomm add_mset_commute
  3217 
  3218 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  3219   by (fact add_right_cancel)
  3220 
  3221 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  3222   by (fact add_left_cancel)
  3223 
  3224 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  3225   by (fact add_left_imp_eq)
  3226 
  3227 lemma mset_subset_trans: "(M::'a multiset) \<subset># K \<Longrightarrow> K \<subset># N \<Longrightarrow> M \<subset># N"
  3228   by (fact subset_mset.less_trans)
  3229 
  3230 lemma multiset_inter_commute: "A \<inter># B = B \<inter># A"
  3231   by (fact subset_mset.inf.commute)
  3232 
  3233 lemma multiset_inter_assoc: "A \<inter># (B \<inter># C) = A \<inter># B \<inter># C"
  3234   by (fact subset_mset.inf.assoc [symmetric])
  3235 
  3236 lemma multiset_inter_left_commute: "A \<inter># (B \<inter># C) = B \<inter># (A \<inter># C)"
  3237   by (fact subset_mset.inf.left_commute)
  3238 
  3239 lemmas multiset_inter_ac =
  3240   multiset_inter_commute
  3241   multiset_inter_assoc
  3242   multiset_inter_left_commute
  3243 
  3244 lemma mset_le_not_refl: "\<not> M < (M::'a::preorder multiset)"
  3245   by (fact less_irrefl)
  3246 
  3247 lemma mset_le_trans: "K < M \<Longrightarrow> M < N \<Longrightarrow> K < (N::'a::preorder multiset)"
  3248   by (fact less_trans)
  3249 
  3250 lemma mset_le_not_sym: "M < N \<Longrightarrow> \<not> N < (M::'a::preorder multiset)"
  3251   by (fact less_not_sym)
  3252 
  3253 lemma mset_le_asym: "M < N \<Longrightarrow> (\<not> P \<Longrightarrow> N < (M::'a::preorder multiset)) \<Longrightarrow> P"
  3254   by (fact less_asym)
  3255 
  3256 declaration \<open>
  3257   let
  3258     fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T])) (Const _ $ t') =
  3259           let
  3260             val (maybe_opt, ps) =
  3261               Nitpick_Model.dest_plain_fun t'
  3262               ||> op ~~
  3263               ||> map (apsnd (snd o HOLogic.dest_number))
  3264             fun elems_for t =
  3265               (case AList.lookup (op =) ps t of
  3266                 SOME n => replicate n t
  3267               | NONE => [Const (maybe_name, elem_T --> elem_T) $ t])
  3268           in
  3269             (case maps elems_for (all_values elem_T) @
  3270                  (if maybe_opt then [Const (Nitpick_Model.unrep_mixfix (), elem_T)] else []) of
  3271               [] => Const (@{const_name zero_class.zero}, T)
  3272             | ts =>
  3273                 foldl1 (fn (s, t) => Const (@{const_name add_mset}, elem_T --> T --> T) $ s $ t)
  3274                   ts)
  3275           end
  3276       | multiset_postproc _ _ _ _ t = t
  3277   in Nitpick_Model.register_term_postprocessor @{typ "'a multiset"} multiset_postproc end
  3278 \<close>
  3279 
  3280 
  3281 subsection \<open>Naive implementation using lists\<close>
  3282 
  3283 code_datatype mset
  3284 
  3285 lemma [code]: "{#} = mset []"
  3286   by simp
  3287 
  3288 lemma [code]: "add_mset x (mset xs) = mset (x # xs)"
  3289   by simp
  3290 
  3291 lemma [code]: "Multiset.is_empty (mset xs) \<longleftrightarrow> List.null xs"
  3292   by (simp add: Multiset.is_empty_def List.null_def)
  3293 
  3294 lemma union_code [code]: "mset xs + mset ys = mset (xs @ ys)"
  3295   by simp
  3296 
  3297 lemma [code]: "image_mset f (mset xs) = mset (map f xs)"
  3298   by simp
  3299 
  3300 lemma [code]: "filter_mset f (mset xs) = mset (filter f xs)"
  3301   by (simp add: mset_filter)
  3302 
  3303 lemma [code]: "mset xs - mset ys = mset (fold remove1 ys xs)"
  3304   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute diff_diff_add)
  3305 
  3306 lemma [code]:
  3307   "mset xs \<inter># mset ys =
  3308     mset (snd (fold (\<lambda>x (ys, zs).
  3309       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  3310 proof -
  3311   have "\<And>zs. mset (snd (fold (\<lambda>x (ys, zs).
  3312     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  3313       (mset xs \<inter># mset ys) + mset zs"
  3314     by (induct xs arbitrary: ys)
  3315       (auto simp add: inter_add_right1 inter_add_right2 ac_simps)
  3316   then show ?thesis by simp
  3317 qed
  3318 
  3319 lemma [code]:
  3320   "mset xs \<union># mset ys =
  3321     mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  3322 proof -
  3323   have "\<And>zs. mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  3324       (mset xs \<union># mset ys) + mset zs"
  3325     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  3326   then show ?thesis by simp
  3327 qed
  3328 
  3329 declare in_multiset_in_set [code_unfold]
  3330 
  3331 lemma [code]: "count (mset xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  3332 proof -
  3333   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (mset xs) x + n"
  3334     by (induct xs) simp_all
  3335   then show ?thesis by simp
  3336 qed
  3337 
  3338 declare set_mset_mset [code]
  3339 
  3340 declare sorted_list_of_multiset_mset [code]
  3341 
  3342 lemma [code]: \<comment> \<open>not very efficient, but representation-ignorant!\<close>
  3343   "mset_set A = mset (sorted_list_of_set A)"
  3344   apply (cases "finite A")
  3345   apply simp_all
  3346   apply (induct A rule: finite_induct)
  3347   apply simp_all
  3348   done
  3349 
  3350 declare size_mset [code]
  3351 
  3352 fun subset_eq_mset_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
  3353   "subset_eq_mset_impl [] ys = Some (ys \<noteq> [])"
  3354 | "subset_eq_mset_impl (Cons x xs) ys = (case List.extract (op = x) ys of
  3355      None \<Rightarrow> None
  3356    | Some (ys1,_,ys2) \<Rightarrow> subset_eq_mset_impl xs (ys1 @ ys2))"
  3357 
  3358 lemma subset_eq_mset_impl: "(subset_eq_mset_impl xs ys = None \<longleftrightarrow> \<not> mset xs \<subseteq># mset ys) \<and>
  3359   (subset_eq_mset_impl xs ys = Some True \<longleftrightarrow> mset xs \<subset># mset ys) \<and>
  3360   (subset_eq_mset_impl xs ys = Some False \<longrightarrow> mset xs = mset ys)"
  3361 proof (induct xs arbitrary: ys)
  3362   case (Nil ys)
  3363   show ?case by (auto simp: subset_mset.zero_less_iff_neq_zero)
  3364 next
  3365   case (Cons x xs ys)
  3366   show ?case
  3367   proof (cases "List.extract (op = x) ys")
  3368     case None
  3369     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  3370     {
  3371       assume "mset (x # xs) \<subseteq># mset ys"
  3372       from set_mset_mono[OF this] x have False by simp
  3373     } note nle = this
  3374     moreover
  3375     {
  3376       assume "mset (x # xs) \<subset># mset ys"
  3377       hence "mset (x # xs) \<subseteq># mset ys" by auto
  3378       from nle[OF this] have False .
  3379     }
  3380     ultimately show ?thesis using None by auto
  3381   next
  3382     case (Some res)
  3383     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  3384     note Some = Some[unfolded res]
  3385     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  3386     hence id: "mset ys = add_mset x (mset (ys1 @ ys2))"
  3387       by auto
  3388     show ?thesis unfolding subset_eq_mset_impl.simps
  3389       unfolding Some option.simps split
  3390       unfolding id
  3391       using Cons[of "ys1 @ ys2"]
  3392       unfolding subset_mset_def subseteq_mset_def by auto
  3393   qed
  3394 qed
  3395 
  3396 lemma [code]: "mset xs \<subseteq># mset ys \<longleftrightarrow> subset_eq_mset_impl xs ys \<noteq> None"
  3397   using subset_eq_mset_impl[of xs ys] by (cases "subset_eq_mset_impl xs ys", auto)
  3398 
  3399 lemma [code]: "mset xs \<subset># mset ys \<longleftrightarrow> subset_eq_mset_impl xs ys = Some True"
  3400   using subset_eq_mset_impl[of xs ys] by (cases "subset_eq_mset_impl xs ys", auto)
  3401 
  3402 instantiation multiset :: (equal) equal
  3403 begin
  3404 
  3405 definition
  3406   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  3407 lemma [code]: "HOL.equal (mset xs) (mset ys) \<longleftrightarrow> subset_eq_mset_impl xs ys = Some False"
  3408   unfolding equal_multiset_def
  3409   using subset_eq_mset_impl[of xs ys] by (cases "subset_eq_mset_impl xs ys", auto)
  3410 
  3411 instance
  3412   by standard (simp add: equal_multiset_def)
  3413 
  3414 end
  3415 
  3416 lemma [code]: "sum_mset (mset xs) = sum_list xs"
  3417   by (induct xs) simp_all
  3418 
  3419 lemma [code]: "prod_mset (mset xs) = fold times xs 1"
  3420 proof -
  3421   have "\<And>x. fold times xs x = prod_mset (mset xs) * x"
  3422     by (induct xs) (simp_all add: ac_simps)
  3423   then show ?thesis by simp
  3424 qed
  3425 
  3426 text \<open>
  3427   Exercise for the casual reader: add implementations for @{term "op \<le>"}
  3428   and @{term "op <"} (multiset order).
  3429 \<close>
  3430 
  3431 text \<open>Quickcheck generators\<close>
  3432 
  3433 definition (in term_syntax)
  3434   msetify :: "'a::typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  3435     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  3436   [code_unfold]: "msetify xs = Code_Evaluation.valtermify mset {\<cdot>} xs"
  3437 
  3438 notation fcomp (infixl "\<circ>>" 60)
  3439 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  3440 
  3441 instantiation multiset :: (random) random
  3442 begin
  3443 
  3444 definition
  3445   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  3446 
  3447 instance ..
  3448 
  3449 end
  3450 
  3451 no_notation fcomp (infixl "\<circ>>" 60)
  3452 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  3453 
  3454 instantiation multiset :: (full_exhaustive) full_exhaustive
  3455 begin
  3456 
  3457 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  3458 where
  3459   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  3460 
  3461 instance ..
  3462 
  3463 end
  3464 
  3465 hide_const (open) msetify
  3466 
  3467 
  3468 subsection \<open>BNF setup\<close>
  3469 
  3470 definition rel_mset where
  3471   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. mset xs = X \<and> mset ys = Y \<and> list_all2 R xs ys)"
  3472 
  3473 lemma mset_zip_take_Cons_drop_twice:
  3474   assumes "length xs = length ys" "j \<le> length xs"
  3475   shows "mset (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
  3476     add_mset (x,y) (mset (zip xs ys))"
  3477   using assms
  3478 proof (induct xs ys arbitrary: x y j rule: list_induct2)
  3479   case Nil
  3480   thus ?case
  3481     by simp
  3482 next
  3483   case (Cons x xs y ys)
  3484   thus ?case
  3485   proof (cases "j = 0")
  3486     case True
  3487     thus ?thesis
  3488       by simp
  3489   next
  3490     case False
  3491     then obtain k where k: "j = Suc k"
  3492       by (cases j) simp
  3493     hence "k \<le> length xs"
  3494       using Cons.prems by auto
  3495     hence "mset (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
  3496       add_mset (x,y) (mset (zip xs ys))"
  3497       by (rule Cons.hyps(2))
  3498     thus ?thesis
  3499       unfolding k by auto
  3500   qed
  3501 qed
  3502 
  3503 lemma ex_mset_zip_left:
  3504   assumes "length xs = length ys" "mset xs' = mset xs"
  3505   shows "\<exists>ys'. length ys' = length xs' \<and> mset (zip xs' ys') = mset (zip xs ys)"
  3506 using assms
  3507 proof (induct xs ys arbitrary: xs' rule: list_induct2)
  3508   case Nil
  3509   thus ?case
  3510     by auto
  3511 next
  3512   case (Cons x xs y ys xs')
  3513   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
  3514     by (metis Cons.prems in_set_conv_nth list.set_intros(1) mset_eq_setD)
  3515 
  3516   define xsa where "xsa = take j xs' @ drop (Suc j) xs'"
  3517   have "mset xs' = {#x#} + mset xsa"
  3518     unfolding xsa_def using j_len nth_j
  3519     by (metis Cons_nth_drop_Suc union_mset_add_mset_right add_mset_remove_trivial add_diff_cancel_left'
  3520         append_take_drop_id mset.simps(2) mset_append)
  3521   hence ms_x: "mset xsa = mset xs"
  3522     by (simp add: Cons.prems)
  3523   then obtain ysa where
  3524     len_a: "length ysa = length xsa" and ms_a: "mset (zip xsa ysa) = mset (zip xs ys)"
  3525     using Cons.hyps(2) by blast
  3526 
  3527   define ys' where "ys' = take j ysa @ y # drop j ysa"
  3528   have xs': "xs' = take j xsa @ x # drop j xsa"
  3529     using ms_x j_len nth_j Cons.prems xsa_def
  3530     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc Cons_nth_drop_Suc length_Cons
  3531       length_drop size_mset)
  3532   have j_len': "j \<le> length xsa"
  3533     using j_len xs' xsa_def
  3534     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
  3535   have "length ys' = length xs'"
  3536     unfolding ys'_def using Cons.prems len_a ms_x
  3537     by (metis add_Suc_right append_take_drop_id length_Cons length_append mset_eq_length)
  3538   moreover have "mset (zip xs' ys') = mset (zip (x # xs) (y # ys))"
  3539     unfolding xs' ys'_def
  3540     by (rule trans[OF mset_zip_take_Cons_drop_twice])
  3541       (auto simp: len_a ms_a j_len')
  3542   ultimately show ?case
  3543     by blast
  3544 qed
  3545 
  3546 lemma list_all2_reorder_left_invariance:
  3547   assumes rel: "list_all2 R xs ys" and ms_x: "mset xs' = mset xs"
  3548   shows "\<exists>ys'. list_all2 R xs' ys' \<and> mset ys' = mset ys"
  3549 proof -
  3550   have len: "length xs = length ys"
  3551     using rel list_all2_conv_all_nth by auto
  3552   obtain ys' where
  3553     len': "length xs' = length ys'" and ms_xy: "mset (zip xs' ys') = mset (zip xs ys)"
  3554     using len ms_x by (metis ex_mset_zip_left)
  3555   have "list_all2 R xs' ys'"
  3556     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: mset_eq_setD)
  3557   moreover have "mset ys' = mset ys"
  3558     using len len' ms_xy map_snd_zip mset_map by metis
  3559   ultimately show ?thesis
  3560     by blast
  3561 qed
  3562 
  3563 lemma ex_mset: "\<exists>xs. mset xs = X"
  3564   by (induct X) (simp, metis mset.simps(2))
  3565 
  3566 inductive pred_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> bool"
  3567 where
  3568   "pred_mset P {#}"
  3569 | "\<lbrakk>P a; pred_mset P M\<rbrakk> \<Longrightarrow> pred_mset P (add_mset a M)"
  3570 
  3571 bnf "'a multiset"
  3572   map: image_mset
  3573   sets: set_mset
  3574   bd: natLeq
  3575   wits: "{#}"
  3576   rel: rel_mset
  3577   pred: pred_mset
  3578 proof -
  3579   show "image_mset id = id"
  3580     by (rule image_mset.id)
  3581   show "image_mset (g \<circ> f) = image_mset g \<circ> image_mset f" for f g
  3582     unfolding comp_def by (rule ext) (simp add: comp_def image_mset.compositionality)
  3583   show "(\<And>z. z \<in> set_mset X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X" for f g X
  3584     by (induct X) simp_all
  3585   show "set_mset \<circ> image_mset f = op ` f \<circ> set_mset" for f
  3586     by auto
  3587   show "card_order natLeq"
  3588     by (rule natLeq_card_order)
  3589   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
  3590     by (rule natLeq_cinfinite)
  3591   show "ordLeq3 (card_of (set_mset X)) natLeq" for X
  3592     by transfer
  3593       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  3594   show "rel_mset R OO rel_mset S \<le> rel_mset (R OO S)" for R S
  3595     unfolding rel_mset_def[abs_def] OO_def
  3596     apply clarify
  3597     subgoal for X Z Y xs ys' ys zs
  3598       apply (drule list_all2_reorder_left_invariance [where xs = ys' and ys = zs and xs' = ys])
  3599       apply (auto intro: list_all2_trans)
  3600       done
  3601     done
  3602   show "rel_mset R =
  3603     (\<lambda>x y. \<exists>z. set_mset z \<subseteq> {(x, y). R x y} \<and>
  3604     image_mset fst z = x \<and> image_mset snd z = y)" for R
  3605     unfolding rel_mset_def[abs_def]
  3606     apply (rule ext)+
  3607     apply safe
  3608      apply (rule_tac x = "mset (zip xs ys)" in exI;
  3609        auto simp: in_set_zip list_all2_iff mset_map[symmetric])
  3610     apply (rename_tac XY)
  3611     apply (cut_tac X = XY in ex_mset)
  3612     apply (erule exE)
  3613     apply (rename_tac xys)
  3614     apply (rule_tac x = "map fst xys" in exI)
  3615     apply (auto simp: mset_map)
  3616     apply (rule_tac x = "map snd xys" in exI)
  3617     apply (auto simp: mset_map list_all2I subset_eq zip_map_fst_snd)
  3618     done
  3619   show "z \<in> set_mset {#} \<Longrightarrow> False" for z
  3620     by auto
  3621   show "pred_mset P = (\<lambda>x. Ball (set_mset x) P)" for P
  3622   proof (intro ext iffI)
  3623     fix x
  3624     assume "pred_mset P x"
  3625     then show "Ball (set_mset x) P" by (induct pred: pred_mset; simp)
  3626   next
  3627     fix x
  3628     assume "Ball (set_mset x) P"
  3629     then show "pred_mset P x" by (induct x; auto intro: pred_mset.intros)
  3630   qed
  3631 qed
  3632 
  3633 inductive rel_mset'
  3634 where
  3635   Zero[intro]: "rel_mset' R {#} {#}"
  3636 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (add_mset a M) (add_mset b N)"
  3637 
  3638 lemma rel_mset_Zero: "rel_mset R {#} {#}"
  3639 unfolding rel_mset_def Grp_def by auto
  3640 
  3641 declare multiset.count[simp]
  3642 declare Abs_multiset_inverse[simp]
  3643 declare multiset.count_inverse[simp]
  3644 declare union_preserves_multiset[simp]
  3645 
  3646 lemma rel_mset_Plus:
  3647   assumes ab: "R a b"
  3648     and MN: "rel_mset R M N"
  3649   shows "rel_mset R (add_mset a M) (add_mset b N)"
  3650 proof -
  3651   have "\<exists>ya. add_mset a (image_mset fst y) = image_mset fst ya \<and>
  3652     add_mset b (image_mset snd y) = image_mset snd ya \<and>
  3653     set_mset ya \<subseteq> {(x, y). R x y}"
  3654     if "R a b" and "set_mset y \<subseteq> {(x, y). R x y}" for y
  3655     using that by (intro exI[of _ "add_mset (a,b) y"]) auto
  3656   thus ?thesis
  3657   using assms
  3658   unfolding multiset.rel_compp_Grp Grp_def by blast
  3659 qed
  3660 
  3661 lemma rel_mset'_imp_rel_mset: "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
  3662   by (induct rule: rel_mset'.induct) (auto simp: rel_mset_Zero rel_mset_Plus)
  3663 
  3664 lemma rel_mset_size: "rel_mset R M N \<Longrightarrow> size M = size N"
  3665   unfolding multiset.rel_compp_Grp Grp_def by auto
  3666 
  3667 lemma multiset_induct2[case_names empty addL addR]:
  3668   assumes empty: "P {#} {#}"
  3669     and addL: "\<And>a M N. P M N \<Longrightarrow> P (add_mset a M) N"
  3670     and addR: "\<And>a M N. P M N \<Longrightarrow> P M (add_mset a N)"
  3671   shows "P M N"
  3672 apply(induct N rule: multiset_induct)
  3673   apply(induct M rule: multiset_induct, rule empty, erule addL)
  3674   apply(induct M rule: multiset_induct, erule addR, erule addR)
  3675 done
  3676 
  3677 lemma multiset_induct2_size[consumes 1, case_names empty add]:
  3678   assumes c: "size M = size N"
  3679     and empty: "P {#} {#}"
  3680     and add: "\<And>a b M N a b. P M N \<Longrightarrow> P (add_mset a M) (add_mset b N)"
  3681   shows "P M N"
  3682   using c
  3683 proof (induct M arbitrary: N rule: measure_induct_rule[of size])
  3684   case (less M)
  3685   show ?case
  3686   proof(cases "M = {#}")
  3687     case True hence "N = {#}" using less.prems by auto
  3688     thus ?thesis using True empty by auto
  3689   next
  3690     case False then obtain M1 a where M: "M = add_mset a M1" by (metis multi_nonempty_split)
  3691     have "N \<noteq> {#}" using False less.prems by auto
  3692     then obtain N1 b where N: "N = add_mset b N1" by (metis multi_nonempty_split)
  3693     have "size M1 = size N1" using less.prems unfolding M N by auto
  3694     thus ?thesis using M N less.hyps add by auto
  3695   qed
  3696 qed
  3697 
  3698 lemma msed_map_invL:
  3699   assumes "image_mset f (add_mset a M) = N"
  3700   shows "\<exists>N1. N = add_mset (f a) N1 \<and> image_mset f M = N1"
  3701 proof -
  3702   have "f a \<in># N"
  3703     using assms multiset.set_map[of f "add_mset a M"] by auto
  3704   then obtain N1 where N: "N = add_mset (f a) N1" using multi_member_split by metis
  3705   have "image_mset f M = N1" using assms unfolding N by simp
  3706   thus ?thesis using N by blast
  3707 qed
  3708 
  3709 lemma msed_map_invR:
  3710   assumes "image_mset f M = add_mset b N"
  3711   shows "\<exists>M1 a. M = add_mset a M1 \<and> f a = b \<and> image_mset f M1 = N"
  3712 proof -
  3713   obtain a where a: "a \<in># M" and fa: "f a = b"
  3714     using multiset.set_map[of f M] unfolding assms
  3715     by (metis image_iff union_single_eq_member)
  3716   then obtain M1 where M: "M = add_mset a M1" using multi_member_split by metis
  3717   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
  3718   thus ?thesis using M fa by blast
  3719 qed
  3720 
  3721 lemma msed_rel_invL:
  3722   assumes "rel_mset R (add_mset a M) N"
  3723   shows "\<exists>N1 b. N = add_mset b N1 \<and> R a b \<and> rel_mset R M N1"
  3724 proof -
  3725   obtain K where KM: "image_mset fst K = add_mset a M"
  3726     and KN: "image_mset snd K = N" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  3727     using assms
  3728     unfolding multiset.rel_compp_Grp Grp_def by auto
  3729   obtain K1 ab where K: "K = add_mset ab K1" and a: "fst ab = a"
  3730     and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
  3731   obtain N1 where N: "N = add_mset (snd ab) N1" and K1N1: "image_mset snd K1 = N1"
  3732     using msed_map_invL[OF KN[unfolded K]] by auto
  3733   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  3734   have "rel_mset R M N1" using sK K1M K1N1
  3735     unfolding K multiset.rel_compp_Grp Grp_def by auto
  3736   thus ?thesis using N Rab by auto
  3737 qed
  3738 
  3739 lemma msed_rel_invR:
  3740   assumes "rel_mset R M (add_mset b N)"
  3741   shows "\<exists>M1 a. M = add_mset a M1 \<and> R a b \<and> rel_mset R M1 N"
  3742 proof -
  3743   obtain K where KN: "image_mset snd K = add_mset b N"
  3744     and KM: "image_mset fst K = M" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  3745     using assms
  3746     unfolding multiset.rel_compp_Grp Grp_def by auto
  3747   obtain K1 ab where K: "K = add_mset ab K1" and b: "snd ab = b"
  3748     and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
  3749   obtain M1 where M: "M = add_mset (fst ab) M1" and K1M1: "image_mset fst K1 = M1"
  3750     using msed_map_invL[OF KM[unfolded K]] by auto
  3751   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  3752   have "rel_mset R M1 N" using sK K1N K1M1
  3753     unfolding K multiset.rel_compp_Grp Grp_def by auto
  3754   thus ?thesis using M Rab by auto
  3755 qed
  3756 
  3757 lemma rel_mset_imp_rel_mset':
  3758   assumes "rel_mset R M N"
  3759   shows "rel_mset' R M N"
  3760 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  3761   case (less M)
  3762   have c: "size M = size N" using rel_mset_size[OF less.prems] .
  3763   show ?case
  3764   proof(cases "M = {#}")
  3765     case True hence "N = {#}" using c by simp
  3766     thus ?thesis using True rel_mset'.Zero by auto
  3767   next
  3768     case False then obtain M1 a where M: "M = add_mset a M1" by (metis multi_nonempty_split)
  3769     obtain N1 b where N: "N = add_mset b N1" and R: "R a b" and ms: "rel_mset R M1 N1"
  3770       using msed_rel_invL[OF less.prems[unfolded M]] by auto
  3771     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  3772     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
  3773   qed
  3774 qed
  3775 
  3776 lemma rel_mset_rel_mset': "rel_mset R M N = rel_mset' R M N"
  3777   using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
  3778 
  3779 text \<open>The main end product for @{const rel_mset}: inductive characterization:\<close>
  3780 lemmas rel_mset_induct[case_names empty add, induct pred: rel_mset] =
  3781   rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
  3782 
  3783 
  3784 subsection \<open>Size setup\<close>
  3785 
  3786 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
  3787   apply (rule ext)
  3788   subgoal for x by (induct x) auto
  3789   done
  3790 
  3791 setup \<open>
  3792   BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  3793     @{thm size_multiset_overloaded_def}
  3794     @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  3795       size_union}
  3796     @{thms multiset_size_o_map}
  3797 \<close>
  3798 
  3799 subsection \<open>Lemmas about Size\<close>
  3800 
  3801 lemma size_mset_SucE: "size A = Suc n \<Longrightarrow> (\<And>a B. A = {#a#} + B \<Longrightarrow> size B = n \<Longrightarrow> P) \<Longrightarrow> P"
  3802   by (cases A) (auto simp add: ac_simps)
  3803 
  3804 lemma size_Suc_Diff1: "x \<in># M \<Longrightarrow> Suc (size (M - {#x#})) = size M"
  3805   using arg_cong[OF insert_DiffM, of _ _ size] by simp
  3806 
  3807 lemma size_Diff_singleton: "x \<in># M \<Longrightarrow> size (M - {#x#}) = size M - 1"
  3808   by (simp add: size_Suc_Diff1 [symmetric])
  3809 
  3810 lemma size_Diff_singleton_if: "size (A - {#x#}) = (if x \<in># A then size A - 1 else size A)"
  3811   by (simp add: diff_single_trivial size_Diff_singleton)
  3812 
  3813 lemma size_Un_Int: "size A + size B = size (A \<union># B) + size (A \<inter># B)"
  3814   by (metis inter_subset_eq_union size_union subset_mset.diff_add union_diff_inter_eq_sup)
  3815 
  3816 lemma size_Un_disjoint: "A \<inter># B = {#} \<Longrightarrow> size (A \<union># B) = size A + size B"
  3817   using size_Un_Int[of A B] by simp
  3818 
  3819 lemma size_Diff_subset_Int: "size (M - M') = size M - size (M \<inter># M')"
  3820   by (metis diff_intersect_left_idem size_Diff_submset subset_mset.inf_le1)
  3821 
  3822 lemma diff_size_le_size_Diff: "size (M :: _ multiset) - size M' \<le> size (M - M')"
  3823   by (simp add: diff_le_mono2 size_Diff_subset_Int size_mset_mono)
  3824 
  3825 lemma size_Diff1_less: "x\<in># M \<Longrightarrow> size (M - {#x#}) < size M"
  3826   by (rule Suc_less_SucD) (simp add: size_Suc_Diff1)
  3827 
  3828 lemma size_Diff2_less: "x\<in># M \<Longrightarrow> y\<in># M \<Longrightarrow> size (M - {#x#} - {#y#}) < size M"
  3829   by (metis less_imp_diff_less size_Diff1_less size_Diff_subset_Int)
  3830 
  3831 lemma size_Diff1_le: "size (M - {#x#}) \<le> size M"
  3832   by (cases "x \<in># M") (simp_all add: size_Diff1_less less_imp_le diff_single_trivial)
  3833 
  3834 lemma size_psubset: "M \<subseteq># M' \<Longrightarrow> size M < size M' \<Longrightarrow> M \<subset># M'"
  3835   using less_irrefl subset_mset_def by blast
  3836 
  3837 hide_const (open) wcount
  3838 
  3839 end