src/HOL/Metis_Examples/Message.thy
 author haftmann Mon Jun 05 15:59:41 2017 +0200 (2017-06-05) changeset 66010 2f7d39285a1a parent 63167 0909deb8059b child 67443 3abf6a722518 permissions -rw-r--r--
executable domain membership checks
```     1 (*  Title:      HOL/Metis_Examples/Message.thy
```
```     2     Author:     Lawrence C. Paulson, Cambridge University Computer Laboratory
```
```     3     Author:     Jasmin Blanchette, TU Muenchen
```
```     4
```
```     5 Metis example featuring message authentication.
```
```     6 *)
```
```     7
```
```     8 section \<open>Metis Example Featuring Message Authentication\<close>
```
```     9
```
```    10 theory Message
```
```    11 imports Main
```
```    12 begin
```
```    13
```
```    14 declare [[metis_new_skolem]]
```
```    15
```
```    16 lemma strange_Un_eq [simp]: "A \<union> (B \<union> A) = B \<union> A"
```
```    17 by (metis Un_commute Un_left_absorb)
```
```    18
```
```    19 type_synonym key = nat
```
```    20
```
```    21 consts
```
```    22   all_symmetric :: bool        \<comment>\<open>true if all keys are symmetric\<close>
```
```    23   invKey        :: "key=>key"  \<comment>\<open>inverse of a symmetric key\<close>
```
```    24
```
```    25 specification (invKey)
```
```    26   invKey [simp]: "invKey (invKey K) = K"
```
```    27   invKey_symmetric: "all_symmetric --> invKey = id"
```
```    28 by (metis id_apply)
```
```    29
```
```    30
```
```    31 text\<open>The inverse of a symmetric key is itself; that of a public key
```
```    32       is the private key and vice versa\<close>
```
```    33
```
```    34 definition symKeys :: "key set" where
```
```    35   "symKeys == {K. invKey K = K}"
```
```    36
```
```    37 datatype  \<comment>\<open>We allow any number of friendly agents\<close>
```
```    38   agent = Server | Friend nat | Spy
```
```    39
```
```    40 datatype
```
```    41      msg = Agent  agent     \<comment>\<open>Agent names\<close>
```
```    42          | Number nat       \<comment>\<open>Ordinary integers, timestamps, ...\<close>
```
```    43          | Nonce  nat       \<comment>\<open>Unguessable nonces\<close>
```
```    44          | Key    key       \<comment>\<open>Crypto keys\<close>
```
```    45          | Hash   msg       \<comment>\<open>Hashing\<close>
```
```    46          | MPair  msg msg   \<comment>\<open>Compound messages\<close>
```
```    47          | Crypt  key msg   \<comment>\<open>Encryption, public- or shared-key\<close>
```
```    48
```
```    49
```
```    50 text\<open>Concrete syntax: messages appear as \<open>\<lbrace>A,B,NA\<rbrace>\<close>, etc...\<close>
```
```    51 syntax
```
```    52   "_MTuple"      :: "['a, args] => 'a * 'b"       ("(2\<lbrace>_,/ _\<rbrace>)")
```
```    53 translations
```
```    54   "\<lbrace>x, y, z\<rbrace>"   == "\<lbrace>x, \<lbrace>y, z\<rbrace>\<rbrace>"
```
```    55   "\<lbrace>x, y\<rbrace>"      == "CONST MPair x y"
```
```    56
```
```    57
```
```    58 definition HPair :: "[msg,msg] => msg" ("(4Hash[_] /_)" [0, 1000]) where
```
```    59     \<comment>\<open>Message Y paired with a MAC computed with the help of X\<close>
```
```    60     "Hash[X] Y == \<lbrace> Hash\<lbrace>X,Y\<rbrace>, Y\<rbrace>"
```
```    61
```
```    62 definition keysFor :: "msg set => key set" where
```
```    63     \<comment>\<open>Keys useful to decrypt elements of a message set\<close>
```
```    64   "keysFor H == invKey ` {K. \<exists>X. Crypt K X \<in> H}"
```
```    65
```
```    66
```
```    67 subsubsection\<open>Inductive Definition of All Parts" of a Message\<close>
```
```    68
```
```    69 inductive_set
```
```    70   parts :: "msg set => msg set"
```
```    71   for H :: "msg set"
```
```    72   where
```
```    73     Inj [intro]:               "X \<in> H ==> X \<in> parts H"
```
```    74   | Fst:         "\<lbrace>X,Y\<rbrace>   \<in> parts H ==> X \<in> parts H"
```
```    75   | Snd:         "\<lbrace>X,Y\<rbrace>   \<in> parts H ==> Y \<in> parts H"
```
```    76   | Body:        "Crypt K X \<in> parts H ==> X \<in> parts H"
```
```    77
```
```    78 lemma parts_mono: "G \<subseteq> H ==> parts(G) \<subseteq> parts(H)"
```
```    79 apply auto
```
```    80 apply (erule parts.induct)
```
```    81    apply (metis parts.Inj set_rev_mp)
```
```    82   apply (metis parts.Fst)
```
```    83  apply (metis parts.Snd)
```
```    84 by (metis parts.Body)
```
```    85
```
```    86 text\<open>Equations hold because constructors are injective.\<close>
```
```    87 lemma Friend_image_eq [simp]: "(Friend x \<in> Friend`A) = (x:A)"
```
```    88 by (metis agent.inject image_iff)
```
```    89
```
```    90 lemma Key_image_eq [simp]: "(Key x \<in> Key`A) = (x \<in> A)"
```
```    91 by (metis image_iff msg.inject(4))
```
```    92
```
```    93 lemma Nonce_Key_image_eq [simp]: "Nonce x \<notin> Key`A"
```
```    94 by (metis image_iff msg.distinct(23))
```
```    95
```
```    96
```
```    97 subsubsection\<open>Inverse of keys\<close>
```
```    98
```
```    99 lemma invKey_eq [simp]: "(invKey K = invKey K') = (K = K')"
```
```   100 by (metis invKey)
```
```   101
```
```   102
```
```   103 subsection\<open>keysFor operator\<close>
```
```   104
```
```   105 lemma keysFor_empty [simp]: "keysFor {} = {}"
```
```   106 by (unfold keysFor_def, blast)
```
```   107
```
```   108 lemma keysFor_Un [simp]: "keysFor (H \<union> H') = keysFor H \<union> keysFor H'"
```
```   109 by (unfold keysFor_def, blast)
```
```   110
```
```   111 lemma keysFor_UN [simp]: "keysFor (\<Union>i\<in>A. H i) = (\<Union>i\<in>A. keysFor (H i))"
```
```   112 by (unfold keysFor_def, blast)
```
```   113
```
```   114 text\<open>Monotonicity\<close>
```
```   115 lemma keysFor_mono: "G \<subseteq> H ==> keysFor(G) \<subseteq> keysFor(H)"
```
```   116 by (unfold keysFor_def, blast)
```
```   117
```
```   118 lemma keysFor_insert_Agent [simp]: "keysFor (insert (Agent A) H) = keysFor H"
```
```   119 by (unfold keysFor_def, auto)
```
```   120
```
```   121 lemma keysFor_insert_Nonce [simp]: "keysFor (insert (Nonce N) H) = keysFor H"
```
```   122 by (unfold keysFor_def, auto)
```
```   123
```
```   124 lemma keysFor_insert_Number [simp]: "keysFor (insert (Number N) H) = keysFor H"
```
```   125 by (unfold keysFor_def, auto)
```
```   126
```
```   127 lemma keysFor_insert_Key [simp]: "keysFor (insert (Key K) H) = keysFor H"
```
```   128 by (unfold keysFor_def, auto)
```
```   129
```
```   130 lemma keysFor_insert_Hash [simp]: "keysFor (insert (Hash X) H) = keysFor H"
```
```   131 by (unfold keysFor_def, auto)
```
```   132
```
```   133 lemma keysFor_insert_MPair [simp]: "keysFor (insert \<lbrace>X,Y\<rbrace> H) = keysFor H"
```
```   134 by (unfold keysFor_def, auto)
```
```   135
```
```   136 lemma keysFor_insert_Crypt [simp]:
```
```   137     "keysFor (insert (Crypt K X) H) = insert (invKey K) (keysFor H)"
```
```   138 by (unfold keysFor_def, auto)
```
```   139
```
```   140 lemma keysFor_image_Key [simp]: "keysFor (Key`E) = {}"
```
```   141 by (unfold keysFor_def, auto)
```
```   142
```
```   143 lemma Crypt_imp_invKey_keysFor: "Crypt K X \<in> H ==> invKey K \<in> keysFor H"
```
```   144 by (unfold keysFor_def, blast)
```
```   145
```
```   146
```
```   147 subsection\<open>Inductive relation "parts"\<close>
```
```   148
```
```   149 lemma MPair_parts:
```
```   150      "[| \<lbrace>X,Y\<rbrace> \<in> parts H;
```
```   151          [| X \<in> parts H; Y \<in> parts H |] ==> P |] ==> P"
```
```   152 by (blast dest: parts.Fst parts.Snd)
```
```   153
```
```   154 declare MPair_parts [elim!] parts.Body [dest!]
```
```   155 text\<open>NB These two rules are UNSAFE in the formal sense, as they discard the
```
```   156      compound message.  They work well on THIS FILE.
```
```   157   \<open>MPair_parts\<close> is left as SAFE because it speeds up proofs.
```
```   158   The Crypt rule is normally kept UNSAFE to avoid breaking up certificates.\<close>
```
```   159
```
```   160 lemma parts_increasing: "H \<subseteq> parts(H)"
```
```   161 by blast
```
```   162
```
```   163 lemmas parts_insertI = subset_insertI [THEN parts_mono, THEN subsetD]
```
```   164
```
```   165 lemma parts_empty [simp]: "parts{} = {}"
```
```   166 apply safe
```
```   167 apply (erule parts.induct)
```
```   168 apply blast+
```
```   169 done
```
```   170
```
```   171 lemma parts_emptyE [elim!]: "X\<in> parts{} ==> P"
```
```   172 by simp
```
```   173
```
```   174 text\<open>WARNING: loops if H = {Y}, therefore must not be repeated!\<close>
```
```   175 lemma parts_singleton: "X\<in> parts H ==> \<exists>Y\<in>H. X\<in> parts {Y}"
```
```   176 apply (erule parts.induct)
```
```   177 apply fast+
```
```   178 done
```
```   179
```
```   180
```
```   181 subsubsection\<open>Unions\<close>
```
```   182
```
```   183 lemma parts_Un_subset1: "parts(G) \<union> parts(H) \<subseteq> parts(G \<union> H)"
```
```   184 by (intro Un_least parts_mono Un_upper1 Un_upper2)
```
```   185
```
```   186 lemma parts_Un_subset2: "parts(G \<union> H) \<subseteq> parts(G) \<union> parts(H)"
```
```   187 apply (rule subsetI)
```
```   188 apply (erule parts.induct, blast+)
```
```   189 done
```
```   190
```
```   191 lemma parts_Un [simp]: "parts(G \<union> H) = parts(G) \<union> parts(H)"
```
```   192 by (intro equalityI parts_Un_subset1 parts_Un_subset2)
```
```   193
```
```   194 lemma parts_insert: "parts (insert X H) = parts {X} \<union> parts H"
```
```   195 apply (subst insert_is_Un [of _ H])
```
```   196 apply (simp only: parts_Un)
```
```   197 done
```
```   198
```
```   199 lemma parts_insert2:
```
```   200      "parts (insert X (insert Y H)) = parts {X} \<union> parts {Y} \<union> parts H"
```
```   201 by (metis Un_commute Un_empty_left Un_empty_right Un_insert_left Un_insert_right parts_Un)
```
```   202
```
```   203
```
```   204 lemma parts_UN_subset1: "(\<Union>x\<in>A. parts(H x)) \<subseteq> parts(\<Union>x\<in>A. H x)"
```
```   205 by (intro UN_least parts_mono UN_upper)
```
```   206
```
```   207 lemma parts_UN_subset2: "parts(\<Union>x\<in>A. H x) \<subseteq> (\<Union>x\<in>A. parts(H x))"
```
```   208 apply (rule subsetI)
```
```   209 apply (erule parts.induct, blast+)
```
```   210 done
```
```   211
```
```   212 lemma parts_UN [simp]: "parts(\<Union>x\<in>A. H x) = (\<Union>x\<in>A. parts(H x))"
```
```   213 by (intro equalityI parts_UN_subset1 parts_UN_subset2)
```
```   214
```
```   215 text\<open>Added to simplify arguments to parts, analz and synth.
```
```   216   NOTE: the UN versions are no longer used!\<close>
```
```   217
```
```   218
```
```   219 text\<open>This allows \<open>blast\<close> to simplify occurrences of
```
```   220   @{term "parts(G\<union>H)"} in the assumption.\<close>
```
```   221 lemmas in_parts_UnE = parts_Un [THEN equalityD1, THEN subsetD, THEN UnE]
```
```   222 declare in_parts_UnE [elim!]
```
```   223
```
```   224 lemma parts_insert_subset: "insert X (parts H) \<subseteq> parts(insert X H)"
```
```   225 by (blast intro: parts_mono [THEN [2] rev_subsetD])
```
```   226
```
```   227 subsubsection\<open>Idempotence and transitivity\<close>
```
```   228
```
```   229 lemma parts_partsD [dest!]: "X\<in> parts (parts H) ==> X\<in> parts H"
```
```   230 by (erule parts.induct, blast+)
```
```   231
```
```   232 lemma parts_idem [simp]: "parts (parts H) = parts H"
```
```   233 by blast
```
```   234
```
```   235 lemma parts_subset_iff [simp]: "(parts G \<subseteq> parts H) = (G \<subseteq> parts H)"
```
```   236 apply (rule iffI)
```
```   237 apply (metis Un_absorb1 Un_subset_iff parts_Un parts_increasing)
```
```   238 apply (metis parts_idem parts_mono)
```
```   239 done
```
```   240
```
```   241 lemma parts_trans: "[| X\<in> parts G;  G \<subseteq> parts H |] ==> X\<in> parts H"
```
```   242 by (blast dest: parts_mono)
```
```   243
```
```   244 lemma parts_cut: "[|Y\<in> parts (insert X G);  X\<in> parts H|] ==> Y\<in> parts(G \<union> H)"
```
```   245 by (metis (no_types) Un_insert_left Un_insert_right insert_absorb le_supE
```
```   246           parts_Un parts_idem parts_increasing parts_trans)
```
```   247
```
```   248 subsubsection\<open>Rewrite rules for pulling out atomic messages\<close>
```
```   249
```
```   250 lemmas parts_insert_eq_I = equalityI [OF subsetI parts_insert_subset]
```
```   251
```
```   252
```
```   253 lemma parts_insert_Agent [simp]:
```
```   254      "parts (insert (Agent agt) H) = insert (Agent agt) (parts H)"
```
```   255 apply (rule parts_insert_eq_I)
```
```   256 apply (erule parts.induct, auto)
```
```   257 done
```
```   258
```
```   259 lemma parts_insert_Nonce [simp]:
```
```   260      "parts (insert (Nonce N) H) = insert (Nonce N) (parts H)"
```
```   261 apply (rule parts_insert_eq_I)
```
```   262 apply (erule parts.induct, auto)
```
```   263 done
```
```   264
```
```   265 lemma parts_insert_Number [simp]:
```
```   266      "parts (insert (Number N) H) = insert (Number N) (parts H)"
```
```   267 apply (rule parts_insert_eq_I)
```
```   268 apply (erule parts.induct, auto)
```
```   269 done
```
```   270
```
```   271 lemma parts_insert_Key [simp]:
```
```   272      "parts (insert (Key K) H) = insert (Key K) (parts H)"
```
```   273 apply (rule parts_insert_eq_I)
```
```   274 apply (erule parts.induct, auto)
```
```   275 done
```
```   276
```
```   277 lemma parts_insert_Hash [simp]:
```
```   278      "parts (insert (Hash X) H) = insert (Hash X) (parts H)"
```
```   279 apply (rule parts_insert_eq_I)
```
```   280 apply (erule parts.induct, auto)
```
```   281 done
```
```   282
```
```   283 lemma parts_insert_Crypt [simp]:
```
```   284      "parts (insert (Crypt K X) H) =
```
```   285           insert (Crypt K X) (parts (insert X H))"
```
```   286 apply (rule equalityI)
```
```   287 apply (rule subsetI)
```
```   288 apply (erule parts.induct, auto)
```
```   289 apply (blast intro: parts.Body)
```
```   290 done
```
```   291
```
```   292 lemma parts_insert_MPair [simp]:
```
```   293      "parts (insert \<lbrace>X,Y\<rbrace> H) =
```
```   294           insert \<lbrace>X,Y\<rbrace> (parts (insert X (insert Y H)))"
```
```   295 apply (rule equalityI)
```
```   296 apply (rule subsetI)
```
```   297 apply (erule parts.induct, auto)
```
```   298 apply (blast intro: parts.Fst parts.Snd)+
```
```   299 done
```
```   300
```
```   301 lemma parts_image_Key [simp]: "parts (Key`N) = Key`N"
```
```   302 apply auto
```
```   303 apply (erule parts.induct, auto)
```
```   304 done
```
```   305
```
```   306 lemma msg_Nonce_supply: "\<exists>N. \<forall>n. N\<le>n --> Nonce n \<notin> parts {msg}"
```
```   307 apply (induct_tac "msg")
```
```   308 apply (simp_all add: parts_insert2)
```
```   309 apply (metis Suc_n_not_le_n)
```
```   310 apply (metis le_trans linorder_linear)
```
```   311 done
```
```   312
```
```   313 subsection\<open>Inductive relation "analz"\<close>
```
```   314
```
```   315 text\<open>Inductive definition of "analz" -- what can be broken down from a set of
```
```   316     messages, including keys.  A form of downward closure.  Pairs can
```
```   317     be taken apart; messages decrypted with known keys.\<close>
```
```   318
```
```   319 inductive_set
```
```   320   analz :: "msg set => msg set"
```
```   321   for H :: "msg set"
```
```   322   where
```
```   323     Inj [intro,simp] :    "X \<in> H ==> X \<in> analz H"
```
```   324   | Fst:     "\<lbrace>X,Y\<rbrace> \<in> analz H ==> X \<in> analz H"
```
```   325   | Snd:     "\<lbrace>X,Y\<rbrace> \<in> analz H ==> Y \<in> analz H"
```
```   326   | Decrypt [dest]:
```
```   327              "[|Crypt K X \<in> analz H; Key(invKey K): analz H|] ==> X \<in> analz H"
```
```   328
```
```   329
```
```   330 text\<open>Monotonicity; Lemma 1 of Lowe's paper\<close>
```
```   331 lemma analz_mono: "G\<subseteq>H ==> analz(G) \<subseteq> analz(H)"
```
```   332 apply auto
```
```   333 apply (erule analz.induct)
```
```   334 apply (auto dest: analz.Fst analz.Snd)
```
```   335 done
```
```   336
```
```   337 text\<open>Making it safe speeds up proofs\<close>
```
```   338 lemma MPair_analz [elim!]:
```
```   339      "[| \<lbrace>X,Y\<rbrace> \<in> analz H;
```
```   340              [| X \<in> analz H; Y \<in> analz H |] ==> P
```
```   341           |] ==> P"
```
```   342 by (blast dest: analz.Fst analz.Snd)
```
```   343
```
```   344 lemma analz_increasing: "H \<subseteq> analz(H)"
```
```   345 by blast
```
```   346
```
```   347 lemma analz_subset_parts: "analz H \<subseteq> parts H"
```
```   348 apply (rule subsetI)
```
```   349 apply (erule analz.induct, blast+)
```
```   350 done
```
```   351
```
```   352 lemmas analz_into_parts = analz_subset_parts [THEN subsetD]
```
```   353
```
```   354 lemmas not_parts_not_analz = analz_subset_parts [THEN contra_subsetD]
```
```   355
```
```   356 lemma parts_analz [simp]: "parts (analz H) = parts H"
```
```   357 apply (rule equalityI)
```
```   358 apply (metis analz_subset_parts parts_subset_iff)
```
```   359 apply (metis analz_increasing parts_mono)
```
```   360 done
```
```   361
```
```   362
```
```   363 lemma analz_parts [simp]: "analz (parts H) = parts H"
```
```   364 apply auto
```
```   365 apply (erule analz.induct, auto)
```
```   366 done
```
```   367
```
```   368 lemmas analz_insertI = subset_insertI [THEN analz_mono, THEN [2] rev_subsetD]
```
```   369
```
```   370 subsubsection\<open>General equational properties\<close>
```
```   371
```
```   372 lemma analz_empty [simp]: "analz{} = {}"
```
```   373 apply safe
```
```   374 apply (erule analz.induct, blast+)
```
```   375 done
```
```   376
```
```   377 text\<open>Converse fails: we can analz more from the union than from the
```
```   378   separate parts, as a key in one might decrypt a message in the other\<close>
```
```   379 lemma analz_Un: "analz(G) \<union> analz(H) \<subseteq> analz(G \<union> H)"
```
```   380 by (intro Un_least analz_mono Un_upper1 Un_upper2)
```
```   381
```
```   382 lemma analz_insert: "insert X (analz H) \<subseteq> analz(insert X H)"
```
```   383 by (blast intro: analz_mono [THEN [2] rev_subsetD])
```
```   384
```
```   385 subsubsection\<open>Rewrite rules for pulling out atomic messages\<close>
```
```   386
```
```   387 lemmas analz_insert_eq_I = equalityI [OF subsetI analz_insert]
```
```   388
```
```   389 lemma analz_insert_Agent [simp]:
```
```   390      "analz (insert (Agent agt) H) = insert (Agent agt) (analz H)"
```
```   391 apply (rule analz_insert_eq_I)
```
```   392 apply (erule analz.induct, auto)
```
```   393 done
```
```   394
```
```   395 lemma analz_insert_Nonce [simp]:
```
```   396      "analz (insert (Nonce N) H) = insert (Nonce N) (analz H)"
```
```   397 apply (rule analz_insert_eq_I)
```
```   398 apply (erule analz.induct, auto)
```
```   399 done
```
```   400
```
```   401 lemma analz_insert_Number [simp]:
```
```   402      "analz (insert (Number N) H) = insert (Number N) (analz H)"
```
```   403 apply (rule analz_insert_eq_I)
```
```   404 apply (erule analz.induct, auto)
```
```   405 done
```
```   406
```
```   407 lemma analz_insert_Hash [simp]:
```
```   408      "analz (insert (Hash X) H) = insert (Hash X) (analz H)"
```
```   409 apply (rule analz_insert_eq_I)
```
```   410 apply (erule analz.induct, auto)
```
```   411 done
```
```   412
```
```   413 text\<open>Can only pull out Keys if they are not needed to decrypt the rest\<close>
```
```   414 lemma analz_insert_Key [simp]:
```
```   415     "K \<notin> keysFor (analz H) ==>
```
```   416           analz (insert (Key K) H) = insert (Key K) (analz H)"
```
```   417 apply (unfold keysFor_def)
```
```   418 apply (rule analz_insert_eq_I)
```
```   419 apply (erule analz.induct, auto)
```
```   420 done
```
```   421
```
```   422 lemma analz_insert_MPair [simp]:
```
```   423      "analz (insert \<lbrace>X,Y\<rbrace> H) =
```
```   424           insert \<lbrace>X,Y\<rbrace> (analz (insert X (insert Y H)))"
```
```   425 apply (rule equalityI)
```
```   426 apply (rule subsetI)
```
```   427 apply (erule analz.induct, auto)
```
```   428 apply (erule analz.induct)
```
```   429 apply (blast intro: analz.Fst analz.Snd)+
```
```   430 done
```
```   431
```
```   432 text\<open>Can pull out enCrypted message if the Key is not known\<close>
```
```   433 lemma analz_insert_Crypt:
```
```   434      "Key (invKey K) \<notin> analz H
```
```   435       ==> analz (insert (Crypt K X) H) = insert (Crypt K X) (analz H)"
```
```   436 apply (rule analz_insert_eq_I)
```
```   437 apply (erule analz.induct, auto)
```
```   438
```
```   439 done
```
```   440
```
```   441 lemma lemma1: "Key (invKey K) \<in> analz H ==>
```
```   442                analz (insert (Crypt K X) H) \<subseteq>
```
```   443                insert (Crypt K X) (analz (insert X H))"
```
```   444 apply (rule subsetI)
```
```   445 apply (erule_tac x = x in analz.induct, auto)
```
```   446 done
```
```   447
```
```   448 lemma lemma2: "Key (invKey K) \<in> analz H ==>
```
```   449                insert (Crypt K X) (analz (insert X H)) \<subseteq>
```
```   450                analz (insert (Crypt K X) H)"
```
```   451 apply auto
```
```   452 apply (erule_tac x = x in analz.induct, auto)
```
```   453 apply (blast intro: analz_insertI analz.Decrypt)
```
```   454 done
```
```   455
```
```   456 lemma analz_insert_Decrypt:
```
```   457      "Key (invKey K) \<in> analz H ==>
```
```   458                analz (insert (Crypt K X) H) =
```
```   459                insert (Crypt K X) (analz (insert X H))"
```
```   460 by (intro equalityI lemma1 lemma2)
```
```   461
```
```   462 text\<open>Case analysis: either the message is secure, or it is not! Effective,
```
```   463 but can cause subgoals to blow up! Use with \<open>if_split\<close>; apparently
```
```   464 \<open>split_tac\<close> does not cope with patterns such as @{term"analz (insert
```
```   465 (Crypt K X) H)"}\<close>
```
```   466 lemma analz_Crypt_if [simp]:
```
```   467      "analz (insert (Crypt K X) H) =
```
```   468           (if (Key (invKey K) \<in> analz H)
```
```   469            then insert (Crypt K X) (analz (insert X H))
```
```   470            else insert (Crypt K X) (analz H))"
```
```   471 by (simp add: analz_insert_Crypt analz_insert_Decrypt)
```
```   472
```
```   473
```
```   474 text\<open>This rule supposes "for the sake of argument" that we have the key.\<close>
```
```   475 lemma analz_insert_Crypt_subset:
```
```   476      "analz (insert (Crypt K X) H) \<subseteq>
```
```   477            insert (Crypt K X) (analz (insert X H))"
```
```   478 apply (rule subsetI)
```
```   479 apply (erule analz.induct, auto)
```
```   480 done
```
```   481
```
```   482
```
```   483 lemma analz_image_Key [simp]: "analz (Key`N) = Key`N"
```
```   484 apply auto
```
```   485 apply (erule analz.induct, auto)
```
```   486 done
```
```   487
```
```   488
```
```   489 subsubsection\<open>Idempotence and transitivity\<close>
```
```   490
```
```   491 lemma analz_analzD [dest!]: "X\<in> analz (analz H) ==> X\<in> analz H"
```
```   492 by (erule analz.induct, blast+)
```
```   493
```
```   494 lemma analz_idem [simp]: "analz (analz H) = analz H"
```
```   495 by blast
```
```   496
```
```   497 lemma analz_subset_iff [simp]: "(analz G \<subseteq> analz H) = (G \<subseteq> analz H)"
```
```   498 apply (rule iffI)
```
```   499 apply (iprover intro: subset_trans analz_increasing)
```
```   500 apply (frule analz_mono, simp)
```
```   501 done
```
```   502
```
```   503 lemma analz_trans: "[| X\<in> analz G;  G \<subseteq> analz H |] ==> X\<in> analz H"
```
```   504 by (drule analz_mono, blast)
```
```   505
```
```   506
```
```   507 declare analz_trans[intro]
```
```   508
```
```   509 lemma analz_cut: "[| Y\<in> analz (insert X H);  X\<in> analz H |] ==> Y\<in> analz H"
```
```   510 by (metis analz_idem analz_increasing analz_mono insert_absorb insert_mono insert_subset)
```
```   511
```
```   512 text\<open>This rewrite rule helps in the simplification of messages that involve
```
```   513   the forwarding of unknown components (X).  Without it, removing occurrences
```
```   514   of X can be very complicated.\<close>
```
```   515 lemma analz_insert_eq: "X\<in> analz H ==> analz (insert X H) = analz H"
```
```   516 by (blast intro: analz_cut analz_insertI)
```
```   517
```
```   518
```
```   519 text\<open>A congruence rule for "analz"\<close>
```
```   520
```
```   521 lemma analz_subset_cong:
```
```   522      "[| analz G \<subseteq> analz G'; analz H \<subseteq> analz H' |]
```
```   523       ==> analz (G \<union> H) \<subseteq> analz (G' \<union> H')"
```
```   524 apply simp
```
```   525 apply (metis Un_absorb2 Un_commute Un_subset_iff Un_upper1 Un_upper2 analz_mono)
```
```   526 done
```
```   527
```
```   528
```
```   529 lemma analz_cong:
```
```   530      "[| analz G = analz G'; analz H = analz H'
```
```   531                |] ==> analz (G \<union> H) = analz (G' \<union> H')"
```
```   532 by (intro equalityI analz_subset_cong, simp_all)
```
```   533
```
```   534 lemma analz_insert_cong:
```
```   535      "analz H = analz H' ==> analz(insert X H) = analz(insert X H')"
```
```   536 by (force simp only: insert_def intro!: analz_cong)
```
```   537
```
```   538 text\<open>If there are no pairs or encryptions then analz does nothing\<close>
```
```   539 lemma analz_trivial:
```
```   540      "[| \<forall>X Y. \<lbrace>X,Y\<rbrace> \<notin> H;  \<forall>X K. Crypt K X \<notin> H |] ==> analz H = H"
```
```   541 apply safe
```
```   542 apply (erule analz.induct, blast+)
```
```   543 done
```
```   544
```
```   545 text\<open>These two are obsolete (with a single Spy) but cost little to prove...\<close>
```
```   546 lemma analz_UN_analz_lemma:
```
```   547      "X\<in> analz (\<Union>i\<in>A. analz (H i)) ==> X\<in> analz (\<Union>i\<in>A. H i)"
```
```   548 apply (erule analz.induct)
```
```   549 apply (blast intro: analz_mono [THEN [2] rev_subsetD])+
```
```   550 done
```
```   551
```
```   552 lemma analz_UN_analz [simp]: "analz (\<Union>i\<in>A. analz (H i)) = analz (\<Union>i\<in>A. H i)"
```
```   553 by (blast intro: analz_UN_analz_lemma analz_mono [THEN [2] rev_subsetD])
```
```   554
```
```   555
```
```   556 subsection\<open>Inductive relation "synth"\<close>
```
```   557
```
```   558 text\<open>Inductive definition of "synth" -- what can be built up from a set of
```
```   559     messages.  A form of upward closure.  Pairs can be built, messages
```
```   560     encrypted with known keys.  Agent names are public domain.
```
```   561     Numbers can be guessed, but Nonces cannot be.\<close>
```
```   562
```
```   563 inductive_set
```
```   564   synth :: "msg set => msg set"
```
```   565   for H :: "msg set"
```
```   566   where
```
```   567     Inj    [intro]:   "X \<in> H ==> X \<in> synth H"
```
```   568   | Agent  [intro]:   "Agent agt \<in> synth H"
```
```   569   | Number [intro]:   "Number n  \<in> synth H"
```
```   570   | Hash   [intro]:   "X \<in> synth H ==> Hash X \<in> synth H"
```
```   571   | MPair  [intro]:   "[|X \<in> synth H;  Y \<in> synth H|] ==> \<lbrace>X,Y\<rbrace> \<in> synth H"
```
```   572   | Crypt  [intro]:   "[|X \<in> synth H;  Key(K) \<in> H|] ==> Crypt K X \<in> synth H"
```
```   573
```
```   574 text\<open>Monotonicity\<close>
```
```   575 lemma synth_mono: "G\<subseteq>H ==> synth(G) \<subseteq> synth(H)"
```
```   576   by (auto, erule synth.induct, auto)
```
```   577
```
```   578 text\<open>NO \<open>Agent_synth\<close>, as any Agent name can be synthesized.
```
```   579   The same holds for @{term Number}\<close>
```
```   580 inductive_cases Nonce_synth [elim!]: "Nonce n \<in> synth H"
```
```   581 inductive_cases Key_synth   [elim!]: "Key K \<in> synth H"
```
```   582 inductive_cases Hash_synth  [elim!]: "Hash X \<in> synth H"
```
```   583 inductive_cases MPair_synth [elim!]: "\<lbrace>X,Y\<rbrace> \<in> synth H"
```
```   584 inductive_cases Crypt_synth [elim!]: "Crypt K X \<in> synth H"
```
```   585
```
```   586
```
```   587 lemma synth_increasing: "H \<subseteq> synth(H)"
```
```   588 by blast
```
```   589
```
```   590 subsubsection\<open>Unions\<close>
```
```   591
```
```   592 text\<open>Converse fails: we can synth more from the union than from the
```
```   593   separate parts, building a compound message using elements of each.\<close>
```
```   594 lemma synth_Un: "synth(G) \<union> synth(H) \<subseteq> synth(G \<union> H)"
```
```   595 by (intro Un_least synth_mono Un_upper1 Un_upper2)
```
```   596
```
```   597 lemma synth_insert: "insert X (synth H) \<subseteq> synth(insert X H)"
```
```   598 by (metis insert_iff insert_subset subset_insertI synth.Inj synth_mono)
```
```   599
```
```   600 subsubsection\<open>Idempotence and transitivity\<close>
```
```   601
```
```   602 lemma synth_synthD [dest!]: "X\<in> synth (synth H) ==> X\<in> synth H"
```
```   603 by (erule synth.induct, blast+)
```
```   604
```
```   605 lemma synth_idem: "synth (synth H) = synth H"
```
```   606 by blast
```
```   607
```
```   608 lemma synth_subset_iff [simp]: "(synth G \<subseteq> synth H) = (G \<subseteq> synth H)"
```
```   609 apply (rule iffI)
```
```   610 apply (iprover intro: subset_trans synth_increasing)
```
```   611 apply (frule synth_mono, simp add: synth_idem)
```
```   612 done
```
```   613
```
```   614 lemma synth_trans: "[| X\<in> synth G;  G \<subseteq> synth H |] ==> X\<in> synth H"
```
```   615 by (drule synth_mono, blast)
```
```   616
```
```   617 lemma synth_cut: "[| Y\<in> synth (insert X H);  X\<in> synth H |] ==> Y\<in> synth H"
```
```   618 by (metis insert_absorb insert_mono insert_subset synth_idem synth_increasing synth_mono)
```
```   619
```
```   620 lemma Agent_synth [simp]: "Agent A \<in> synth H"
```
```   621 by blast
```
```   622
```
```   623 lemma Number_synth [simp]: "Number n \<in> synth H"
```
```   624 by blast
```
```   625
```
```   626 lemma Nonce_synth_eq [simp]: "(Nonce N \<in> synth H) = (Nonce N \<in> H)"
```
```   627 by blast
```
```   628
```
```   629 lemma Key_synth_eq [simp]: "(Key K \<in> synth H) = (Key K \<in> H)"
```
```   630 by blast
```
```   631
```
```   632 lemma Crypt_synth_eq [simp]:
```
```   633      "Key K \<notin> H ==> (Crypt K X \<in> synth H) = (Crypt K X \<in> H)"
```
```   634 by blast
```
```   635
```
```   636
```
```   637 lemma keysFor_synth [simp]:
```
```   638     "keysFor (synth H) = keysFor H \<union> invKey`{K. Key K \<in> H}"
```
```   639 by (unfold keysFor_def, blast)
```
```   640
```
```   641
```
```   642 subsubsection\<open>Combinations of parts, analz and synth\<close>
```
```   643
```
```   644 lemma parts_synth [simp]: "parts (synth H) = parts H \<union> synth H"
```
```   645 apply (rule equalityI)
```
```   646 apply (rule subsetI)
```
```   647 apply (erule parts.induct)
```
```   648 apply (metis UnCI)
```
```   649 apply (metis MPair_synth UnCI UnE insert_absorb insert_subset parts.Fst parts_increasing)
```
```   650 apply (metis MPair_synth UnCI UnE insert_absorb insert_subset parts.Snd parts_increasing)
```
```   651 apply (metis Body Crypt_synth UnCI UnE insert_absorb insert_subset parts_increasing)
```
```   652 apply (metis Un_subset_iff parts_increasing parts_mono synth_increasing)
```
```   653 done
```
```   654
```
```   655 lemma analz_analz_Un [simp]: "analz (analz G \<union> H) = analz (G \<union> H)"
```
```   656 apply (rule equalityI)
```
```   657 apply (metis analz_idem analz_subset_cong order_eq_refl)
```
```   658 apply (metis analz_increasing analz_subset_cong order_eq_refl)
```
```   659 done
```
```   660
```
```   661 declare analz_mono [intro] analz.Fst [intro] analz.Snd [intro] Un_least [intro]
```
```   662
```
```   663 lemma analz_synth_Un [simp]: "analz (synth G \<union> H) = analz (G \<union> H) \<union> synth G"
```
```   664 apply (rule equalityI)
```
```   665 apply (rule subsetI)
```
```   666 apply (erule analz.induct)
```
```   667 apply (metis UnCI UnE Un_commute analz.Inj)
```
```   668 apply (metis MPair_synth UnCI UnE Un_commute analz.Fst analz.Inj)
```
```   669 apply (metis MPair_synth UnCI UnE Un_commute analz.Inj analz.Snd)
```
```   670 apply (blast intro: analz.Decrypt)
```
```   671 apply blast
```
```   672 done
```
```   673
```
```   674 lemma analz_synth [simp]: "analz (synth H) = analz H \<union> synth H"
```
```   675 proof -
```
```   676   have "\<forall>x\<^sub>2 x\<^sub>1. synth x\<^sub>1 \<union> analz (x\<^sub>1 \<union> x\<^sub>2) = analz (synth x\<^sub>1 \<union> x\<^sub>2)" by (metis Un_commute analz_synth_Un)
```
```   677   hence "\<forall>x\<^sub>1. synth x\<^sub>1 \<union> analz x\<^sub>1 = analz (synth x\<^sub>1 \<union> {})" by (metis Un_empty_right)
```
```   678   hence "\<forall>x\<^sub>1. synth x\<^sub>1 \<union> analz x\<^sub>1 = analz (synth x\<^sub>1)" by (metis Un_empty_right)
```
```   679   hence "\<forall>x\<^sub>1. analz x\<^sub>1 \<union> synth x\<^sub>1 = analz (synth x\<^sub>1)" by (metis Un_commute)
```
```   680   thus "analz (synth H) = analz H \<union> synth H" by metis
```
```   681 qed
```
```   682
```
```   683
```
```   684 subsubsection\<open>For reasoning about the Fake rule in traces\<close>
```
```   685
```
```   686 lemma parts_insert_subset_Un: "X \<in> G ==> parts(insert X H) \<subseteq> parts G \<union> parts H"
```
```   687 proof -
```
```   688   assume "X \<in> G"
```
```   689   hence "\<forall>x\<^sub>1. G \<subseteq> x\<^sub>1 \<longrightarrow> X \<in> x\<^sub>1 " by auto
```
```   690   hence "\<forall>x\<^sub>1. X \<in> G \<union> x\<^sub>1" by (metis Un_upper1)
```
```   691   hence "insert X H \<subseteq> G \<union> H" by (metis Un_upper2 insert_subset)
```
```   692   hence "parts (insert X H) \<subseteq> parts (G \<union> H)" by (metis parts_mono)
```
```   693   thus "parts (insert X H) \<subseteq> parts G \<union> parts H" by (metis parts_Un)
```
```   694 qed
```
```   695
```
```   696 lemma Fake_parts_insert:
```
```   697      "X \<in> synth (analz H) ==>
```
```   698       parts (insert X H) \<subseteq> synth (analz H) \<union> parts H"
```
```   699 proof -
```
```   700   assume A1: "X \<in> synth (analz H)"
```
```   701   have F1: "\<forall>x\<^sub>1. analz x\<^sub>1 \<union> synth (analz x\<^sub>1) = analz (synth (analz x\<^sub>1))"
```
```   702     by (metis analz_idem analz_synth)
```
```   703   have F2: "\<forall>x\<^sub>1. parts x\<^sub>1 \<union> synth (analz x\<^sub>1) = parts (synth (analz x\<^sub>1))"
```
```   704     by (metis parts_analz parts_synth)
```
```   705   have F3: "X \<in> synth (analz H)" using A1 by metis
```
```   706   have "\<forall>x\<^sub>2 x\<^sub>1::msg set. x\<^sub>1 \<le> sup x\<^sub>1 x\<^sub>2" by (metis inf_sup_ord(3))
```
```   707   hence F4: "\<forall>x\<^sub>1. analz x\<^sub>1 \<subseteq> analz (synth x\<^sub>1)" by (metis analz_synth)
```
```   708   have F5: "X \<in> synth (analz H)" using F3 by metis
```
```   709   have "\<forall>x\<^sub>1. analz x\<^sub>1 \<subseteq> synth (analz x\<^sub>1)
```
```   710          \<longrightarrow> analz (synth (analz x\<^sub>1)) = synth (analz x\<^sub>1)"
```
```   711     using F1 by (metis subset_Un_eq)
```
```   712   hence F6: "\<forall>x\<^sub>1. analz (synth (analz x\<^sub>1)) = synth (analz x\<^sub>1)"
```
```   713     by (metis synth_increasing)
```
```   714   have "\<forall>x\<^sub>1. x\<^sub>1 \<subseteq> analz (synth x\<^sub>1)" using F4 by (metis analz_subset_iff)
```
```   715   hence "\<forall>x\<^sub>1. x\<^sub>1 \<subseteq> analz (synth (analz x\<^sub>1))" by (metis analz_subset_iff)
```
```   716   hence "\<forall>x\<^sub>1. x\<^sub>1 \<subseteq> synth (analz x\<^sub>1)" using F6 by metis
```
```   717   hence "H \<subseteq> synth (analz H)" by metis
```
```   718   hence "H \<subseteq> synth (analz H) \<and> X \<in> synth (analz H)" using F5 by metis
```
```   719   hence "insert X H \<subseteq> synth (analz H)" by (metis insert_subset)
```
```   720   hence "parts (insert X H) \<subseteq> parts (synth (analz H))" by (metis parts_mono)
```
```   721   hence "parts (insert X H) \<subseteq> parts H \<union> synth (analz H)" using F2 by metis
```
```   722   thus "parts (insert X H) \<subseteq> synth (analz H) \<union> parts H" by (metis Un_commute)
```
```   723 qed
```
```   724
```
```   725 lemma Fake_parts_insert_in_Un:
```
```   726      "[|Z \<in> parts (insert X H);  X: synth (analz H)|]
```
```   727       ==> Z \<in>  synth (analz H) \<union> parts H"
```
```   728 by (blast dest: Fake_parts_insert [THEN subsetD, dest])
```
```   729
```
```   730 declare synth_mono [intro]
```
```   731
```
```   732 lemma Fake_analz_insert:
```
```   733      "X \<in> synth (analz G) ==>
```
```   734       analz (insert X H) \<subseteq> synth (analz G) \<union> analz (G \<union> H)"
```
```   735 by (metis Un_commute Un_insert_left Un_insert_right Un_upper1 analz_analz_Un
```
```   736           analz_mono analz_synth_Un insert_absorb)
```
```   737
```
```   738 lemma Fake_analz_insert_simpler:
```
```   739      "X \<in> synth (analz G) ==>
```
```   740       analz (insert X H) \<subseteq> synth (analz G) \<union> analz (G \<union> H)"
```
```   741 apply (rule subsetI)
```
```   742 apply (subgoal_tac "x \<in> analz (synth (analz G) \<union> H) ")
```
```   743 apply (metis Un_commute analz_analz_Un analz_synth_Un)
```
```   744 by (metis Un_upper1 Un_upper2 analz_mono insert_absorb insert_subset)
```
```   745
```
```   746 end
```