src/HOL/Relation.thy
author haftmann
Mon Jun 05 15:59:41 2017 +0200 (2017-06-05)
changeset 66010 2f7d39285a1a
parent 64634 5bd30359e46e
child 66434 5d7e770c7d5d
permissions -rw-r--r--
executable domain membership checks
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer, TU Muenchen
     4 *)
     5 
     6 section \<open>Relations -- as sets of pairs, and binary predicates\<close>
     7 
     8 theory Relation
     9   imports Finite_Set
    10 begin
    11 
    12 text \<open>A preliminary: classical rules for reasoning on predicates\<close>
    13 
    14 declare predicate1I [Pure.intro!, intro!]
    15 declare predicate1D [Pure.dest, dest]
    16 declare predicate2I [Pure.intro!, intro!]
    17 declare predicate2D [Pure.dest, dest]
    18 declare bot1E [elim!]
    19 declare bot2E [elim!]
    20 declare top1I [intro!]
    21 declare top2I [intro!]
    22 declare inf1I [intro!]
    23 declare inf2I [intro!]
    24 declare inf1E [elim!]
    25 declare inf2E [elim!]
    26 declare sup1I1 [intro?]
    27 declare sup2I1 [intro?]
    28 declare sup1I2 [intro?]
    29 declare sup2I2 [intro?]
    30 declare sup1E [elim!]
    31 declare sup2E [elim!]
    32 declare sup1CI [intro!]
    33 declare sup2CI [intro!]
    34 declare Inf1_I [intro!]
    35 declare INF1_I [intro!]
    36 declare Inf2_I [intro!]
    37 declare INF2_I [intro!]
    38 declare Inf1_D [elim]
    39 declare INF1_D [elim]
    40 declare Inf2_D [elim]
    41 declare INF2_D [elim]
    42 declare Inf1_E [elim]
    43 declare INF1_E [elim]
    44 declare Inf2_E [elim]
    45 declare INF2_E [elim]
    46 declare Sup1_I [intro]
    47 declare SUP1_I [intro]
    48 declare Sup2_I [intro]
    49 declare SUP2_I [intro]
    50 declare Sup1_E [elim!]
    51 declare SUP1_E [elim!]
    52 declare Sup2_E [elim!]
    53 declare SUP2_E [elim!]
    54 
    55 
    56 subsection \<open>Fundamental\<close>
    57 
    58 subsubsection \<open>Relations as sets of pairs\<close>
    59 
    60 type_synonym 'a rel = "('a \<times> 'a) set"
    61 
    62 lemma subrelI: "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    63   \<comment> \<open>Version of @{thm [source] subsetI} for binary relations\<close>
    64   by auto
    65 
    66 lemma lfp_induct2:
    67   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    68     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    69   \<comment> \<open>Version of @{thm [source] lfp_induct} for binary relations\<close>
    70   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    71 
    72 
    73 subsubsection \<open>Conversions between set and predicate relations\<close>
    74 
    75 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    79   by (simp add: set_eq_iff fun_eq_iff)
    80 
    81 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    85   by (simp add: subset_iff le_fun_def)
    86 
    87 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    97   by (auto simp add: fun_eq_iff)
    98 
    99 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   103   by (simp add: inf_fun_def)
   104 
   105 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   109   by (simp add: sup_fun_def)
   110 
   111 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   142   by (simp add: fun_eq_iff)
   143 
   144 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   145   by (simp add: fun_eq_iff)
   146 
   147 
   148 subsection \<open>Properties of relations\<close>
   149 
   150 subsubsection \<open>Reflexivity\<close>
   151 
   152 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   153   where "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   154 
   155 abbreviation refl :: "'a rel \<Rightarrow> bool" \<comment> \<open>reflexivity over a type\<close>
   156   where "refl \<equiv> refl_on UNIV"
   157 
   158 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   159   where "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   160 
   161 lemma reflp_refl_eq [pred_set_conv]: "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r"
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI [intro?]: "r \<subseteq> A \<times> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> (x, x) \<in> r) \<Longrightarrow> refl_on A r"
   165   unfolding refl_on_def by (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r \<Longrightarrow> a \<in> A \<Longrightarrow> (a, a) \<in> r"
   168   unfolding refl_on_def by blast
   169 
   170 lemma refl_onD1: "refl_on A r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> x \<in> A"
   171   unfolding refl_on_def by blast
   172 
   173 lemma refl_onD2: "refl_on A r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> y \<in> A"
   174   unfolding refl_on_def by blast
   175 
   176 lemma reflpI [intro?]: "(\<And>x. r x x) \<Longrightarrow> reflp r"
   177   by (auto intro: refl_onI simp add: reflp_def)
   178 
   179 lemma reflpE:
   180   assumes "reflp r"
   181   obtains "r x x"
   182   using assms by (auto dest: refl_onD simp add: reflp_def)
   183 
   184 lemma reflpD [dest?]:
   185   assumes "reflp r"
   186   shows "r x x"
   187   using assms by (auto elim: reflpE)
   188 
   189 lemma refl_on_Int: "refl_on A r \<Longrightarrow> refl_on B s \<Longrightarrow> refl_on (A \<inter> B) (r \<inter> s)"
   190   unfolding refl_on_def by blast
   191 
   192 lemma reflp_inf: "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   193   by (auto intro: reflpI elim: reflpE)
   194 
   195 lemma refl_on_Un: "refl_on A r \<Longrightarrow> refl_on B s \<Longrightarrow> refl_on (A \<union> B) (r \<union> s)"
   196   unfolding refl_on_def by blast
   197 
   198 lemma reflp_sup: "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   199   by (auto intro: reflpI elim: reflpE)
   200 
   201 lemma refl_on_INTER: "\<forall>x\<in>S. refl_on (A x) (r x) \<Longrightarrow> refl_on (INTER S A) (INTER S r)"
   202   unfolding refl_on_def by fast
   203 
   204 lemma refl_on_UNION: "\<forall>x\<in>S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   205   unfolding refl_on_def by blast
   206 
   207 lemma refl_on_empty [simp]: "refl_on {} {}"
   208   by (simp add: refl_on_def)
   209 
   210 lemma refl_on_singleton [simp]: "refl_on {x} {(x, x)}"
   211 by (blast intro: refl_onI)
   212 
   213 lemma refl_on_def' [nitpick_unfold, code]:
   214   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   215   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   216 
   217 lemma reflp_equality [simp]: "reflp op ="
   218   by (simp add: reflp_def)
   219 
   220 lemma reflp_mono: "reflp R \<Longrightarrow> (\<And>x y. R x y \<longrightarrow> Q x y) \<Longrightarrow> reflp Q"
   221   by (auto intro: reflpI dest: reflpD)
   222 
   223 
   224 subsubsection \<open>Irreflexivity\<close>
   225 
   226 definition irrefl :: "'a rel \<Rightarrow> bool"
   227   where "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   228 
   229 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   230   where "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   231 
   232 lemma irreflp_irrefl_eq [pred_set_conv]: "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R"
   233   by (simp add: irrefl_def irreflp_def)
   234 
   235 lemma irreflI [intro?]: "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   236   by (simp add: irrefl_def)
   237 
   238 lemma irreflpI [intro?]: "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   239   by (fact irreflI [to_pred])
   240 
   241 lemma irrefl_distinct [code]: "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   242   by (auto simp add: irrefl_def)
   243 
   244 
   245 subsubsection \<open>Asymmetry\<close>
   246 
   247 inductive asym :: "'a rel \<Rightarrow> bool"
   248   where asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   249 
   250 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   251   where asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   252 
   253 lemma asymp_asym_eq [pred_set_conv]: "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R"
   254   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   255 
   256 
   257 subsubsection \<open>Symmetry\<close>
   258 
   259 definition sym :: "'a rel \<Rightarrow> bool"
   260   where "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   261 
   262 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   263   where "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   264 
   265 lemma symp_sym_eq [pred_set_conv]: "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r"
   266   by (simp add: sym_def symp_def)
   267 
   268 lemma symI [intro?]: "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   269   by (unfold sym_def) iprover
   270 
   271 lemma sympI [intro?]: "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   272   by (fact symI [to_pred])
   273 
   274 lemma symE:
   275   assumes "sym r" and "(b, a) \<in> r"
   276   obtains "(a, b) \<in> r"
   277   using assms by (simp add: sym_def)
   278 
   279 lemma sympE:
   280   assumes "symp r" and "r b a"
   281   obtains "r a b"
   282   using assms by (rule symE [to_pred])
   283 
   284 lemma symD [dest?]:
   285   assumes "sym r" and "(b, a) \<in> r"
   286   shows "(a, b) \<in> r"
   287   using assms by (rule symE)
   288 
   289 lemma sympD [dest?]:
   290   assumes "symp r" and "r b a"
   291   shows "r a b"
   292   using assms by (rule symD [to_pred])
   293 
   294 lemma sym_Int: "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   295   by (fast intro: symI elim: symE)
   296 
   297 lemma symp_inf: "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   298   by (fact sym_Int [to_pred])
   299 
   300 lemma sym_Un: "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   301   by (fast intro: symI elim: symE)
   302 
   303 lemma symp_sup: "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   304   by (fact sym_Un [to_pred])
   305 
   306 lemma sym_INTER: "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   307   by (fast intro: symI elim: symE)
   308 
   309 lemma symp_INF: "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   310   by (fact sym_INTER [to_pred])
   311 
   312 lemma sym_UNION: "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   313   by (fast intro: symI elim: symE)
   314 
   315 lemma symp_SUP: "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   316   by (fact sym_UNION [to_pred])
   317 
   318 
   319 subsubsection \<open>Antisymmetry\<close>
   320 
   321 definition antisym :: "'a rel \<Rightarrow> bool"
   322   where "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   323 
   324 definition antisymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   325   where "antisymp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x \<longrightarrow> x = y)"
   326 
   327 lemma antisymp_antisym_eq [pred_set_conv]: "antisymp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> antisym r"
   328   by (simp add: antisym_def antisymp_def)
   329 
   330 lemma antisymI [intro?]:
   331   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (y, x) \<in> r \<Longrightarrow> x = y) \<Longrightarrow> antisym r"
   332   unfolding antisym_def by iprover
   333 
   334 lemma antisympI [intro?]:
   335   "(\<And>x y. r x y \<Longrightarrow> r y x \<Longrightarrow> x = y) \<Longrightarrow> antisymp r"
   336   by (fact antisymI [to_pred])
   337     
   338 lemma antisymD [dest?]:
   339   "antisym r \<Longrightarrow> (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r \<Longrightarrow> a = b"
   340   unfolding antisym_def by iprover
   341 
   342 lemma antisympD [dest?]:
   343   "antisymp r \<Longrightarrow> r a b \<Longrightarrow> r b a \<Longrightarrow> a = b"
   344   by (fact antisymD [to_pred])
   345 
   346 lemma antisym_subset:
   347   "r \<subseteq> s \<Longrightarrow> antisym s \<Longrightarrow> antisym r"
   348   unfolding antisym_def by blast
   349 
   350 lemma antisymp_less_eq:
   351   "r \<le> s \<Longrightarrow> antisymp s \<Longrightarrow> antisymp r"
   352   by (fact antisym_subset [to_pred])
   353     
   354 lemma antisym_empty [simp]:
   355   "antisym {}"
   356   unfolding antisym_def by blast
   357 
   358 lemma antisym_bot [simp]:
   359   "antisymp \<bottom>"
   360   by (fact antisym_empty [to_pred])
   361     
   362 lemma antisymp_equality [simp]:
   363   "antisymp HOL.eq"
   364   by (auto intro: antisympI)
   365 
   366 lemma antisym_singleton [simp]:
   367   "antisym {x}"
   368   by (blast intro: antisymI)
   369 
   370 
   371 subsubsection \<open>Transitivity\<close>
   372 
   373 definition trans :: "'a rel \<Rightarrow> bool"
   374   where "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   375 
   376 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   377   where "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   378 
   379 lemma transp_trans_eq [pred_set_conv]: "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r"
   380   by (simp add: trans_def transp_def)
   381 
   382 lemma transI [intro?]: "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   383   by (unfold trans_def) iprover
   384 
   385 lemma transpI [intro?]: "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   386   by (fact transI [to_pred])
   387 
   388 lemma transE:
   389   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   390   obtains "(x, z) \<in> r"
   391   using assms by (unfold trans_def) iprover
   392 
   393 lemma transpE:
   394   assumes "transp r" and "r x y" and "r y z"
   395   obtains "r x z"
   396   using assms by (rule transE [to_pred])
   397 
   398 lemma transD [dest?]:
   399   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   400   shows "(x, z) \<in> r"
   401   using assms by (rule transE)
   402 
   403 lemma transpD [dest?]:
   404   assumes "transp r" and "r x y" and "r y z"
   405   shows "r x z"
   406   using assms by (rule transD [to_pred])
   407 
   408 lemma trans_Int: "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   409   by (fast intro: transI elim: transE)
   410 
   411 lemma transp_inf: "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   412   by (fact trans_Int [to_pred])
   413 
   414 lemma trans_INTER: "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   415   by (fast intro: transI elim: transD)
   416 
   417 lemma transp_INF: "\<forall>x\<in>S. transp (r x) \<Longrightarrow> transp (INFIMUM S r)"
   418   by (fact trans_INTER [to_pred])
   419     
   420 lemma trans_join [code]: "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   421   by (auto simp add: trans_def)
   422 
   423 lemma transp_trans: "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   424   by (simp add: trans_def transp_def)
   425 
   426 lemma transp_equality [simp]: "transp op ="
   427   by (auto intro: transpI)
   428 
   429 lemma trans_empty [simp]: "trans {}"
   430   by (blast intro: transI)
   431 
   432 lemma transp_empty [simp]: "transp (\<lambda>x y. False)"
   433   using trans_empty[to_pred] by (simp add: bot_fun_def)
   434 
   435 lemma trans_singleton [simp]: "trans {(a, a)}"
   436   by (blast intro: transI)
   437 
   438 lemma transp_singleton [simp]: "transp (\<lambda>x y. x = a \<and> y = a)"
   439   by (simp add: transp_def)
   440 
   441 
   442 subsubsection \<open>Totality\<close>
   443 
   444 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   445   where "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   446 
   447 lemma total_onI [intro?]:
   448   "(\<And>x y. \<lbrakk>x \<in> A; y \<in> A; x \<noteq> y\<rbrakk> \<Longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r) \<Longrightarrow> total_on A r"
   449   unfolding total_on_def by blast
   450 
   451 abbreviation "total \<equiv> total_on UNIV"
   452 
   453 lemma total_on_empty [simp]: "total_on {} r"
   454   by (simp add: total_on_def)
   455 
   456 lemma total_on_singleton [simp]: "total_on {x} {(x, x)}"
   457   unfolding total_on_def by blast
   458 
   459 
   460 subsubsection \<open>Single valued relations\<close>
   461 
   462 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   463   where "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   464 
   465 definition single_valuedp :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   466   where "single_valuedp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> (\<forall>z. r x z \<longrightarrow> y = z))"
   467 
   468 lemma single_valuedp_single_valued_eq [pred_set_conv]:
   469   "single_valuedp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> single_valued r"
   470   by (simp add: single_valued_def single_valuedp_def)
   471 
   472 lemma single_valuedI:
   473   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (\<And>z. (x, z) \<in> r \<Longrightarrow> y = z)) \<Longrightarrow> single_valued r"
   474   unfolding single_valued_def by blast
   475 
   476 lemma single_valuedpI:
   477   "(\<And>x y. r x y \<Longrightarrow> (\<And>z. r x z \<Longrightarrow> y = z)) \<Longrightarrow> single_valuedp r"
   478   by (fact single_valuedI [to_pred])
   479 
   480 lemma single_valuedD:
   481   "single_valued r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (x, z) \<in> r \<Longrightarrow> y = z"
   482   by (simp add: single_valued_def)
   483 
   484 lemma single_valuedpD:
   485   "single_valuedp r \<Longrightarrow> r x y \<Longrightarrow> r x z \<Longrightarrow> y = z"
   486   by (fact single_valuedD [to_pred])
   487 
   488 lemma single_valued_empty [simp]:
   489   "single_valued {}"
   490   by (simp add: single_valued_def)
   491 
   492 lemma single_valuedp_bot [simp]:
   493   "single_valuedp \<bottom>"
   494   by (fact single_valued_empty [to_pred])
   495 
   496 lemma single_valued_subset:
   497   "r \<subseteq> s \<Longrightarrow> single_valued s \<Longrightarrow> single_valued r"
   498   unfolding single_valued_def by blast
   499 
   500 lemma single_valuedp_less_eq:
   501   "r \<le> s \<Longrightarrow> single_valuedp s \<Longrightarrow> single_valuedp r"
   502   by (fact single_valued_subset [to_pred])
   503 
   504 
   505 subsection \<open>Relation operations\<close>
   506 
   507 subsubsection \<open>The identity relation\<close>
   508 
   509 definition Id :: "'a rel"
   510   where [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   511 
   512 lemma IdI [intro]: "(a, a) \<in> Id"
   513   by (simp add: Id_def)
   514 
   515 lemma IdE [elim!]: "p \<in> Id \<Longrightarrow> (\<And>x. p = (x, x) \<Longrightarrow> P) \<Longrightarrow> P"
   516   unfolding Id_def by (iprover elim: CollectE)
   517 
   518 lemma pair_in_Id_conv [iff]: "(a, b) \<in> Id \<longleftrightarrow> a = b"
   519   unfolding Id_def by blast
   520 
   521 lemma refl_Id: "refl Id"
   522   by (simp add: refl_on_def)
   523 
   524 lemma antisym_Id: "antisym Id"
   525   \<comment> \<open>A strange result, since \<open>Id\<close> is also symmetric.\<close>
   526   by (simp add: antisym_def)
   527 
   528 lemma sym_Id: "sym Id"
   529   by (simp add: sym_def)
   530 
   531 lemma trans_Id: "trans Id"
   532   by (simp add: trans_def)
   533 
   534 lemma single_valued_Id [simp]: "single_valued Id"
   535   by (unfold single_valued_def) blast
   536 
   537 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   538   by (simp add: irrefl_def)
   539 
   540 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   541   unfolding antisym_def trans_def by blast
   542 
   543 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   544   by (simp add: total_on_def)
   545 
   546 lemma Id_fstsnd_eq: "Id = {x. fst x = snd x}"
   547   by force
   548 
   549 
   550 subsubsection \<open>Diagonal: identity over a set\<close>
   551 
   552 definition Id_on :: "'a set \<Rightarrow> 'a rel"
   553   where "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   554 
   555 lemma Id_on_empty [simp]: "Id_on {} = {}"
   556   by (simp add: Id_on_def)
   557 
   558 lemma Id_on_eqI: "a = b \<Longrightarrow> a \<in> A \<Longrightarrow> (a, b) \<in> Id_on A"
   559   by (simp add: Id_on_def)
   560 
   561 lemma Id_onI [intro!]: "a \<in> A \<Longrightarrow> (a, a) \<in> Id_on A"
   562   by (rule Id_on_eqI) (rule refl)
   563 
   564 lemma Id_onE [elim!]: "c \<in> Id_on A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> c = (x, x) \<Longrightarrow> P) \<Longrightarrow> P"
   565   \<comment> \<open>The general elimination rule.\<close>
   566   unfolding Id_on_def by (iprover elim!: UN_E singletonE)
   567 
   568 lemma Id_on_iff: "(x, y) \<in> Id_on A \<longleftrightarrow> x = y \<and> x \<in> A"
   569   by blast
   570 
   571 lemma Id_on_def' [nitpick_unfold]: "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   572   by auto
   573 
   574 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   575   by blast
   576 
   577 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   578   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   579 
   580 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   581   unfolding antisym_def by blast
   582 
   583 lemma sym_Id_on [simp]: "sym (Id_on A)"
   584   by (rule symI) clarify
   585 
   586 lemma trans_Id_on [simp]: "trans (Id_on A)"
   587   by (fast intro: transI elim: transD)
   588 
   589 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   590   unfolding single_valued_def by blast
   591 
   592 
   593 subsubsection \<open>Composition\<close>
   594 
   595 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set"  (infixr "O" 75)
   596   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   597   where relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   598 
   599 notation relcompp (infixr "OO" 75)
   600 
   601 lemmas relcomppI = relcompp.intros
   602 
   603 text \<open>
   604   For historic reasons, the elimination rules are not wholly corresponding.
   605   Feel free to consolidate this.
   606 \<close>
   607 
   608 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   609 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   610 
   611 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   612   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   613   apply (cases xz)
   614   apply simp
   615   apply (erule relcompEpair)
   616   apply iprover
   617   done
   618 
   619 lemma R_O_Id [simp]: "R O Id = R"
   620   by fast
   621 
   622 lemma Id_O_R [simp]: "Id O R = R"
   623   by fast
   624 
   625 lemma relcomp_empty1 [simp]: "{} O R = {}"
   626   by blast
   627 
   628 lemma relcompp_bot1 [simp]: "\<bottom> OO R = \<bottom>"
   629   by (fact relcomp_empty1 [to_pred])
   630 
   631 lemma relcomp_empty2 [simp]: "R O {} = {}"
   632   by blast
   633 
   634 lemma relcompp_bot2 [simp]: "R OO \<bottom> = \<bottom>"
   635   by (fact relcomp_empty2 [to_pred])
   636 
   637 lemma O_assoc: "(R O S) O T = R O (S O T)"
   638   by blast
   639 
   640 lemma relcompp_assoc: "(r OO s) OO t = r OO (s OO t)"
   641   by (fact O_assoc [to_pred])
   642 
   643 lemma trans_O_subset: "trans r \<Longrightarrow> r O r \<subseteq> r"
   644   by (unfold trans_def) blast
   645 
   646 lemma transp_relcompp_less_eq: "transp r \<Longrightarrow> r OO r \<le> r "
   647   by (fact trans_O_subset [to_pred])
   648 
   649 lemma relcomp_mono: "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   650   by blast
   651 
   652 lemma relcompp_mono: "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   653   by (fact relcomp_mono [to_pred])
   654 
   655 lemma relcomp_subset_Sigma: "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   656   by blast
   657 
   658 lemma relcomp_distrib [simp]: "R O (S \<union> T) = (R O S) \<union> (R O T)"
   659   by auto
   660 
   661 lemma relcompp_distrib [simp]: "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   662   by (fact relcomp_distrib [to_pred])
   663 
   664 lemma relcomp_distrib2 [simp]: "(S \<union> T) O R = (S O R) \<union> (T O R)"
   665   by auto
   666 
   667 lemma relcompp_distrib2 [simp]: "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   668   by (fact relcomp_distrib2 [to_pred])
   669 
   670 lemma relcomp_UNION_distrib: "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   671   by auto
   672 
   673 lemma relcompp_SUP_distrib: "s OO SUPREMUM I r = (\<Squnion>i\<in>I. s OO r i)"
   674   by (fact relcomp_UNION_distrib [to_pred])
   675     
   676 lemma relcomp_UNION_distrib2: "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   677   by auto
   678 
   679 lemma relcompp_SUP_distrib2: "SUPREMUM I r OO s = (\<Squnion>i\<in>I. r i OO s)"
   680   by (fact relcomp_UNION_distrib2 [to_pred])
   681     
   682 lemma single_valued_relcomp: "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   683   unfolding single_valued_def by blast
   684 
   685 lemma relcomp_unfold: "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   686   by (auto simp add: set_eq_iff)
   687 
   688 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   689   unfolding relcomp_unfold [to_pred] ..
   690 
   691 lemma eq_OO: "op = OO R = R"
   692   by blast
   693 
   694 lemma OO_eq: "R OO op = = R"
   695   by blast
   696 
   697 
   698 subsubsection \<open>Converse\<close>
   699 
   700 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set"  ("(_\<inverse>)" [1000] 999)
   701   for r :: "('a \<times> 'b) set"
   702   where "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   703 
   704 notation conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   705 
   706 notation (ASCII)
   707   converse  ("(_^-1)" [1000] 999) and
   708   conversep ("(_^--1)" [1000] 1000)
   709 
   710 lemma converseI [sym]: "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   711   by (fact converse.intros)
   712 
   713 lemma conversepI (* CANDIDATE [sym] *): "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   714   by (fact conversep.intros)
   715 
   716 lemma converseD [sym]: "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   717   by (erule converse.cases) iprover
   718 
   719 lemma conversepD (* CANDIDATE [sym] *): "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   720   by (fact converseD [to_pred])
   721 
   722 lemma converseE [elim!]: "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   723   \<comment> \<open>More general than \<open>converseD\<close>, as it ``splits'' the member of the relation.\<close>
   724   apply (cases yx)
   725   apply simp
   726   apply (erule converse.cases)
   727   apply iprover
   728   done
   729 
   730 lemmas conversepE [elim!] = conversep.cases
   731 
   732 lemma converse_iff [iff]: "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   733   by (auto intro: converseI)
   734 
   735 lemma conversep_iff [iff]: "r\<inverse>\<inverse> a b = r b a"
   736   by (fact converse_iff [to_pred])
   737 
   738 lemma converse_converse [simp]: "(r\<inverse>)\<inverse> = r"
   739   by (simp add: set_eq_iff)
   740 
   741 lemma conversep_conversep [simp]: "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   742   by (fact converse_converse [to_pred])
   743 
   744 lemma converse_empty[simp]: "{}\<inverse> = {}"
   745   by auto
   746 
   747 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   748   by auto
   749 
   750 lemma converse_relcomp: "(r O s)\<inverse> = s\<inverse> O r\<inverse>"
   751   by blast
   752 
   753 lemma converse_relcompp: "(r OO s)\<inverse>\<inverse> = s\<inverse>\<inverse> OO r\<inverse>\<inverse>"
   754   by (iprover intro: order_antisym conversepI relcomppI elim: relcomppE dest: conversepD)
   755 
   756 lemma converse_Int: "(r \<inter> s)\<inverse> = r\<inverse> \<inter> s\<inverse>"
   757   by blast
   758 
   759 lemma converse_meet: "(r \<sqinter> s)\<inverse>\<inverse> = r\<inverse>\<inverse> \<sqinter> s\<inverse>\<inverse>"
   760   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   761 
   762 lemma converse_Un: "(r \<union> s)\<inverse> = r\<inverse> \<union> s\<inverse>"
   763   by blast
   764 
   765 lemma converse_join: "(r \<squnion> s)\<inverse>\<inverse> = r\<inverse>\<inverse> \<squnion> s\<inverse>\<inverse>"
   766   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   767 
   768 lemma converse_INTER: "(INTER S r)\<inverse> = (INT x:S. (r x)\<inverse>)"
   769   by fast
   770 
   771 lemma converse_UNION: "(UNION S r)\<inverse> = (UN x:S. (r x)\<inverse>)"
   772   by blast
   773 
   774 lemma converse_mono[simp]: "r\<inverse> \<subseteq> s \<inverse> \<longleftrightarrow> r \<subseteq> s"
   775   by auto
   776 
   777 lemma conversep_mono[simp]: "r\<inverse>\<inverse> \<le> s \<inverse>\<inverse> \<longleftrightarrow> r \<le> s"
   778   by (fact converse_mono[to_pred])
   779 
   780 lemma converse_inject[simp]: "r\<inverse> = s \<inverse> \<longleftrightarrow> r = s"
   781   by auto
   782 
   783 lemma conversep_inject[simp]: "r\<inverse>\<inverse> = s \<inverse>\<inverse> \<longleftrightarrow> r = s"
   784   by (fact converse_inject[to_pred])
   785 
   786 lemma converse_subset_swap: "r \<subseteq> s \<inverse> \<longleftrightarrow> r \<inverse> \<subseteq> s"
   787   by auto
   788 
   789 lemma conversep_le_swap: "r \<le> s \<inverse>\<inverse> \<longleftrightarrow> r \<inverse>\<inverse> \<le> s"
   790   by (fact converse_subset_swap[to_pred])
   791 
   792 lemma converse_Id [simp]: "Id\<inverse> = Id"
   793   by blast
   794 
   795 lemma converse_Id_on [simp]: "(Id_on A)\<inverse> = Id_on A"
   796   by blast
   797 
   798 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   799   by (auto simp: refl_on_def)
   800 
   801 lemma sym_converse [simp]: "sym (converse r) = sym r"
   802   unfolding sym_def by blast
   803 
   804 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   805   unfolding antisym_def by blast
   806 
   807 lemma trans_converse [simp]: "trans (converse r) = trans r"
   808   unfolding trans_def by blast
   809 
   810 lemma sym_conv_converse_eq: "sym r \<longleftrightarrow> r\<inverse> = r"
   811   unfolding sym_def by fast
   812 
   813 lemma sym_Un_converse: "sym (r \<union> r\<inverse>)"
   814   unfolding sym_def by blast
   815 
   816 lemma sym_Int_converse: "sym (r \<inter> r\<inverse>)"
   817   unfolding sym_def by blast
   818 
   819 lemma total_on_converse [simp]: "total_on A (r\<inverse>) = total_on A r"
   820   by (auto simp: total_on_def)
   821 
   822 lemma finite_converse [iff]: "finite (r\<inverse>) = finite r"
   823   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   824   by (auto elim: finite_imageD simp: inj_on_def)
   825 
   826 lemma conversep_noteq [simp]: "(op \<noteq>)\<inverse>\<inverse> = op \<noteq>"
   827   by (auto simp add: fun_eq_iff)
   828 
   829 lemma conversep_eq [simp]: "(op =)\<inverse>\<inverse> = op ="
   830   by (auto simp add: fun_eq_iff)
   831 
   832 lemma converse_unfold [code]: "r\<inverse> = {(y, x). (x, y) \<in> r}"
   833   by (simp add: set_eq_iff)
   834 
   835 
   836 subsubsection \<open>Domain, range and field\<close>
   837 
   838 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set" for r :: "('a \<times> 'b) set"
   839   where DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   840 
   841 lemmas DomainPI = Domainp.DomainI
   842 
   843 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   844 inductive_cases DomainpE [elim!]: "Domainp r a"
   845 
   846 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set" for r :: "('a \<times> 'b) set"
   847   where RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   848 
   849 lemmas RangePI = Rangep.RangeI
   850 
   851 inductive_cases RangeE [elim!]: "b \<in> Range r"
   852 inductive_cases RangepE [elim!]: "Rangep r b"
   853 
   854 definition Field :: "'a rel \<Rightarrow> 'a set"
   855   where "Field r = Domain r \<union> Range r"
   856 
   857 lemma FieldI1: "(i, j) \<in> R \<Longrightarrow> i \<in> Field R"
   858   unfolding Field_def by blast
   859 
   860 lemma FieldI2: "(i, j) \<in> R \<Longrightarrow> j \<in> Field R"
   861   unfolding Field_def by auto
   862 
   863 lemma Domain_fst [code]: "Domain r = fst ` r"
   864   by force
   865 
   866 lemma Range_snd [code]: "Range r = snd ` r"
   867   by force
   868 
   869 lemma fst_eq_Domain: "fst ` R = Domain R"
   870   by force
   871 
   872 lemma snd_eq_Range: "snd ` R = Range R"
   873   by force
   874 
   875 lemma range_fst [simp]: "range fst = UNIV"
   876   by (auto simp: fst_eq_Domain)
   877 
   878 lemma range_snd [simp]: "range snd = UNIV"
   879   by (auto simp: snd_eq_Range)
   880 
   881 lemma Domain_empty [simp]: "Domain {} = {}"
   882   by auto
   883 
   884 lemma Range_empty [simp]: "Range {} = {}"
   885   by auto
   886 
   887 lemma Field_empty [simp]: "Field {} = {}"
   888   by (simp add: Field_def)
   889 
   890 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   891   by auto
   892 
   893 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   894   by auto
   895 
   896 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   897   by blast
   898 
   899 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   900   by blast
   901 
   902 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   903   by (auto simp add: Field_def)
   904 
   905 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   906   by blast
   907 
   908 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   909   by blast
   910 
   911 lemma Domain_Id [simp]: "Domain Id = UNIV"
   912   by blast
   913 
   914 lemma Range_Id [simp]: "Range Id = UNIV"
   915   by blast
   916 
   917 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   918   by blast
   919 
   920 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   921   by blast
   922 
   923 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   924   by blast
   925 
   926 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   927   by blast
   928 
   929 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   930   by (auto simp: Field_def)
   931 
   932 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   933   by blast
   934 
   935 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   936   by blast
   937 
   938 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   939   by blast
   940 
   941 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   942   by blast
   943 
   944 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   945   by blast
   946 
   947 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   948   by blast
   949 
   950 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   951   by (auto simp: Field_def)
   952 
   953 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   954   by auto
   955 
   956 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   957   by blast
   958 
   959 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   960   by (auto simp: Field_def)
   961 
   962 lemma Domain_Collect_case_prod [simp]: "Domain {(x, y). P x y} = {x. \<exists>y. P x y}"
   963   by auto
   964 
   965 lemma Range_Collect_case_prod [simp]: "Range {(x, y). P x y} = {y. \<exists>x. P x y}"
   966   by auto
   967 
   968 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   969   by (induct set: finite) auto
   970 
   971 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   972   by (induct set: finite) auto
   973 
   974 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   975   by (simp add: Field_def finite_Domain finite_Range)
   976 
   977 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   978   by blast
   979 
   980 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   981   by blast
   982 
   983 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   984   by (auto simp: Field_def Domain_def Range_def)
   985 
   986 lemma Domain_unfold: "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   987   by blast
   988 
   989 lemma Field_square [simp]: "Field (x \<times> x) = x"
   990   unfolding Field_def by blast
   991 
   992 
   993 subsubsection \<open>Image of a set under a relation\<close>
   994 
   995 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set"  (infixr "``" 90)
   996   where "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   997 
   998 lemma Image_iff: "b \<in> r``A \<longleftrightarrow> (\<exists>x\<in>A. (x, b) \<in> r)"
   999   by (simp add: Image_def)
  1000 
  1001 lemma Image_singleton: "r``{a} = {b. (a, b) \<in> r}"
  1002   by (simp add: Image_def)
  1003 
  1004 lemma Image_singleton_iff [iff]: "b \<in> r``{a} \<longleftrightarrow> (a, b) \<in> r"
  1005   by (rule Image_iff [THEN trans]) simp
  1006 
  1007 lemma ImageI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> r``A"
  1008   unfolding Image_def by blast
  1009 
  1010 lemma ImageE [elim!]: "b \<in> r `` A \<Longrightarrow> (\<And>x. (x, b) \<in> r \<Longrightarrow> x \<in> A \<Longrightarrow> P) \<Longrightarrow> P"
  1011   unfolding Image_def by (iprover elim!: CollectE bexE)
  1012 
  1013 lemma rev_ImageI: "a \<in> A \<Longrightarrow> (a, b) \<in> r \<Longrightarrow> b \<in> r `` A"
  1014   \<comment> \<open>This version's more effective when we already have the required \<open>a\<close>\<close>
  1015   by blast
  1016 
  1017 lemma Image_empty [simp]: "R``{} = {}"
  1018   by blast
  1019 
  1020 lemma Image_Id [simp]: "Id `` A = A"
  1021   by blast
  1022 
  1023 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1024   by blast
  1025 
  1026 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1027   by blast
  1028 
  1029 lemma Image_Int_eq: "single_valued (converse R) \<Longrightarrow> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1030   by (auto simp: single_valued_def)
  1031 
  1032 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1033   by blast
  1034 
  1035 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1036   by blast
  1037 
  1038 lemma Image_subset: "r \<subseteq> A \<times> B \<Longrightarrow> r``C \<subseteq> B"
  1039   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1040 
  1041 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1042   \<comment> \<open>NOT suitable for rewriting\<close>
  1043   by blast
  1044 
  1045 lemma Image_mono: "r' \<subseteq> r \<Longrightarrow> A' \<subseteq> A \<Longrightarrow> (r' `` A') \<subseteq> (r `` A)"
  1046   by blast
  1047 
  1048 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1049   by blast
  1050 
  1051 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1052   by auto
  1053 
  1054 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1055   by blast
  1056 
  1057 text \<open>Converse inclusion requires some assumptions\<close>
  1058 lemma Image_INT_eq: "single_valued (r\<inverse>) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1059   apply (rule equalityI)
  1060    apply (rule Image_INT_subset)
  1061   apply (auto simp add: single_valued_def)
  1062   apply blast
  1063   done
  1064 
  1065 lemma Image_subset_eq: "r``A \<subseteq> B \<longleftrightarrow> A \<subseteq> - ((r\<inverse>) `` (- B))"
  1066   by blast
  1067 
  1068 lemma Image_Collect_case_prod [simp]: "{(x, y). P x y} `` A = {y. \<exists>x\<in>A. P x y}"
  1069   by auto
  1070 
  1071 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1072   by auto
  1073 
  1074 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1075   by auto
  1076 
  1077 
  1078 subsubsection \<open>Inverse image\<close>
  1079 
  1080 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1081   where "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1082 
  1083 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1084   where "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1085 
  1086 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1087   by (simp add: inv_image_def inv_imagep_def)
  1088 
  1089 lemma sym_inv_image: "sym r \<Longrightarrow> sym (inv_image r f)"
  1090   unfolding sym_def inv_image_def by blast
  1091 
  1092 lemma trans_inv_image: "trans r \<Longrightarrow> trans (inv_image r f)"
  1093   unfolding trans_def inv_image_def
  1094   apply (simp (no_asm))
  1095   apply blast
  1096   done
  1097 
  1098 lemma in_inv_image[simp]: "(x, y) \<in> inv_image r f \<longleftrightarrow> (f x, f y) \<in> r"
  1099   by (auto simp:inv_image_def)
  1100 
  1101 lemma converse_inv_image[simp]: "(inv_image R f)\<inverse> = inv_image (R\<inverse>) f"
  1102   unfolding inv_image_def converse_unfold by auto
  1103 
  1104 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1105   by (simp add: inv_imagep_def)
  1106 
  1107 
  1108 subsubsection \<open>Powerset\<close>
  1109 
  1110 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1111   where "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1112 
  1113 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1114   by (auto simp add: Powp_def fun_eq_iff)
  1115 
  1116 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1117 
  1118 
  1119 subsubsection \<open>Expressing relation operations via @{const Finite_Set.fold}\<close>
  1120 
  1121 lemma Id_on_fold:
  1122   assumes "finite A"
  1123   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1124 proof -
  1125   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)"
  1126     by standard auto
  1127   from assms show ?thesis
  1128     unfolding Id_on_def by (induct A) simp_all
  1129 qed
  1130 
  1131 lemma comp_fun_commute_Image_fold:
  1132   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1133 proof -
  1134   interpret comp_fun_idem Set.insert
  1135     by (fact comp_fun_idem_insert)
  1136   show ?thesis
  1137     by standard (auto simp: fun_eq_iff comp_fun_commute split: prod.split)
  1138 qed
  1139 
  1140 lemma Image_fold:
  1141   assumes "finite R"
  1142   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1143 proof -
  1144   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1145     by (rule comp_fun_commute_Image_fold)
  1146   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1147     by (force intro: rev_ImageI)
  1148   show ?thesis
  1149     using assms by (induct R) (auto simp: *)
  1150 qed
  1151 
  1152 lemma insert_relcomp_union_fold:
  1153   assumes "finite S"
  1154   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1155 proof -
  1156   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1157   proof -
  1158     interpret comp_fun_idem Set.insert
  1159       by (fact comp_fun_idem_insert)
  1160     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1161       by standard (auto simp add: fun_eq_iff split: prod.split)
  1162   qed
  1163   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x, z) \<in> S}"
  1164     by (auto simp: relcomp_unfold intro!: exI)
  1165   show ?thesis
  1166     unfolding * using \<open>finite S\<close> by (induct S) (auto split: prod.split)
  1167 qed
  1168 
  1169 lemma insert_relcomp_fold:
  1170   assumes "finite S"
  1171   shows "Set.insert x R O S =
  1172     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1173 proof -
  1174   have "Set.insert x R O S = ({x} O S) \<union> (R O S)"
  1175     by auto
  1176   then show ?thesis
  1177     by (auto simp: insert_relcomp_union_fold [OF assms])
  1178 qed
  1179 
  1180 lemma comp_fun_commute_relcomp_fold:
  1181   assumes "finite S"
  1182   shows "comp_fun_commute (\<lambda>(x,y) A.
  1183     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1184 proof -
  1185   have *: "\<And>a b A.
  1186     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1187     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1188   show ?thesis
  1189     by standard (auto simp: *)
  1190 qed
  1191 
  1192 lemma relcomp_fold:
  1193   assumes "finite R" "finite S"
  1194   shows "R O S = Finite_Set.fold
  1195     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1196   using assms
  1197   by (induct R)
  1198     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1199       cong: if_cong)
  1200 
  1201 end