src/HOL/Zorn.thy
 author haftmann Mon Jun 05 15:59:41 2017 +0200 (2017-06-05) changeset 66010 2f7d39285a1a parent 63572 c0cbfd2b5a45 child 67399 eab6ce8368fa permissions -rw-r--r--
executable domain membership checks
```     1 (*  Title:       HOL/Zorn.thy
```
```     2     Author:      Jacques D. Fleuriot
```
```     3     Author:      Tobias Nipkow, TUM
```
```     4     Author:      Christian Sternagel, JAIST
```
```     5
```
```     6 Zorn's Lemma (ported from Larry Paulson's Zorn.thy in ZF).
```
```     7 The well-ordering theorem.
```
```     8 *)
```
```     9
```
```    10 section \<open>Zorn's Lemma\<close>
```
```    11
```
```    12 theory Zorn
```
```    13   imports Order_Relation Hilbert_Choice
```
```    14 begin
```
```    15
```
```    16 subsection \<open>Zorn's Lemma for the Subset Relation\<close>
```
```    17
```
```    18 subsubsection \<open>Results that do not require an order\<close>
```
```    19
```
```    20 text \<open>Let \<open>P\<close> be a binary predicate on the set \<open>A\<close>.\<close>
```
```    21 locale pred_on =
```
```    22   fixes A :: "'a set"
```
```    23     and P :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
```
```    24 begin
```
```    25
```
```    26 abbreviation Peq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
```
```    27   where "x \<sqsubseteq> y \<equiv> P\<^sup>=\<^sup>= x y"
```
```    28
```
```    29 text \<open>A chain is a totally ordered subset of \<open>A\<close>.\<close>
```
```    30 definition chain :: "'a set \<Rightarrow> bool"
```
```    31   where "chain C \<longleftrightarrow> C \<subseteq> A \<and> (\<forall>x\<in>C. \<forall>y\<in>C. x \<sqsubseteq> y \<or> y \<sqsubseteq> x)"
```
```    32
```
```    33 text \<open>
```
```    34   We call a chain that is a proper superset of some set \<open>X\<close>,
```
```    35   but not necessarily a chain itself, a superchain of \<open>X\<close>.
```
```    36 \<close>
```
```    37 abbreviation superchain :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool"  (infix "<c" 50)
```
```    38   where "X <c C \<equiv> chain C \<and> X \<subset> C"
```
```    39
```
```    40 text \<open>A maximal chain is a chain that does not have a superchain.\<close>
```
```    41 definition maxchain :: "'a set \<Rightarrow> bool"
```
```    42   where "maxchain C \<longleftrightarrow> chain C \<and> (\<nexists>S. C <c S)"
```
```    43
```
```    44 text \<open>
```
```    45   We define the successor of a set to be an arbitrary
```
```    46   superchain, if such exists, or the set itself, otherwise.
```
```    47 \<close>
```
```    48 definition suc :: "'a set \<Rightarrow> 'a set"
```
```    49   where "suc C = (if \<not> chain C \<or> maxchain C then C else (SOME D. C <c D))"
```
```    50
```
```    51 lemma chainI [Pure.intro?]: "C \<subseteq> A \<Longrightarrow> (\<And>x y. x \<in> C \<Longrightarrow> y \<in> C \<Longrightarrow> x \<sqsubseteq> y \<or> y \<sqsubseteq> x) \<Longrightarrow> chain C"
```
```    52   unfolding chain_def by blast
```
```    53
```
```    54 lemma chain_total: "chain C \<Longrightarrow> x \<in> C \<Longrightarrow> y \<in> C \<Longrightarrow> x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
```
```    55   by (simp add: chain_def)
```
```    56
```
```    57 lemma not_chain_suc [simp]: "\<not> chain X \<Longrightarrow> suc X = X"
```
```    58   by (simp add: suc_def)
```
```    59
```
```    60 lemma maxchain_suc [simp]: "maxchain X \<Longrightarrow> suc X = X"
```
```    61   by (simp add: suc_def)
```
```    62
```
```    63 lemma suc_subset: "X \<subseteq> suc X"
```
```    64   by (auto simp: suc_def maxchain_def intro: someI2)
```
```    65
```
```    66 lemma chain_empty [simp]: "chain {}"
```
```    67   by (auto simp: chain_def)
```
```    68
```
```    69 lemma not_maxchain_Some: "chain C \<Longrightarrow> \<not> maxchain C \<Longrightarrow> C <c (SOME D. C <c D)"
```
```    70   by (rule someI_ex) (auto simp: maxchain_def)
```
```    71
```
```    72 lemma suc_not_equals: "chain C \<Longrightarrow> \<not> maxchain C \<Longrightarrow> suc C \<noteq> C"
```
```    73   using not_maxchain_Some by (auto simp: suc_def)
```
```    74
```
```    75 lemma subset_suc:
```
```    76   assumes "X \<subseteq> Y"
```
```    77   shows "X \<subseteq> suc Y"
```
```    78   using assms by (rule subset_trans) (rule suc_subset)
```
```    79
```
```    80 text \<open>
```
```    81   We build a set @{term \<C>} that is closed under applications
```
```    82   of @{term suc} and contains the union of all its subsets.
```
```    83 \<close>
```
```    84 inductive_set suc_Union_closed ("\<C>")
```
```    85   where
```
```    86     suc: "X \<in> \<C> \<Longrightarrow> suc X \<in> \<C>"
```
```    87   | Union [unfolded Pow_iff]: "X \<in> Pow \<C> \<Longrightarrow> \<Union>X \<in> \<C>"
```
```    88
```
```    89 text \<open>
```
```    90   Since the empty set as well as the set itself is a subset of
```
```    91   every set, @{term \<C>} contains at least @{term "{} \<in> \<C>"} and
```
```    92   @{term "\<Union>\<C> \<in> \<C>"}.
```
```    93 \<close>
```
```    94 lemma suc_Union_closed_empty: "{} \<in> \<C>"
```
```    95   and suc_Union_closed_Union: "\<Union>\<C> \<in> \<C>"
```
```    96   using Union [of "{}"] and Union [of "\<C>"] by simp_all
```
```    97
```
```    98 text \<open>Thus closure under @{term suc} will hit a maximal chain
```
```    99   eventually, as is shown below.\<close>
```
```   100
```
```   101 lemma suc_Union_closed_induct [consumes 1, case_names suc Union, induct pred: suc_Union_closed]:
```
```   102   assumes "X \<in> \<C>"
```
```   103     and "\<And>X. X \<in> \<C> \<Longrightarrow> Q X \<Longrightarrow> Q (suc X)"
```
```   104     and "\<And>X. X \<subseteq> \<C> \<Longrightarrow> \<forall>x\<in>X. Q x \<Longrightarrow> Q (\<Union>X)"
```
```   105   shows "Q X"
```
```   106   using assms by induct blast+
```
```   107
```
```   108 lemma suc_Union_closed_cases [consumes 1, case_names suc Union, cases pred: suc_Union_closed]:
```
```   109   assumes "X \<in> \<C>"
```
```   110     and "\<And>Y. X = suc Y \<Longrightarrow> Y \<in> \<C> \<Longrightarrow> Q"
```
```   111     and "\<And>Y. X = \<Union>Y \<Longrightarrow> Y \<subseteq> \<C> \<Longrightarrow> Q"
```
```   112   shows "Q"
```
```   113   using assms by cases simp_all
```
```   114
```
```   115 text \<open>On chains, @{term suc} yields a chain.\<close>
```
```   116 lemma chain_suc:
```
```   117   assumes "chain X"
```
```   118   shows "chain (suc X)"
```
```   119   using assms
```
```   120   by (cases "\<not> chain X \<or> maxchain X") (force simp: suc_def dest: not_maxchain_Some)+
```
```   121
```
```   122 lemma chain_sucD:
```
```   123   assumes "chain X"
```
```   124   shows "suc X \<subseteq> A \<and> chain (suc X)"
```
```   125 proof -
```
```   126   from \<open>chain X\<close> have *: "chain (suc X)"
```
```   127     by (rule chain_suc)
```
```   128   then have "suc X \<subseteq> A"
```
```   129     unfolding chain_def by blast
```
```   130   with * show ?thesis by blast
```
```   131 qed
```
```   132
```
```   133 lemma suc_Union_closed_total':
```
```   134   assumes "X \<in> \<C>" and "Y \<in> \<C>"
```
```   135     and *: "\<And>Z. Z \<in> \<C> \<Longrightarrow> Z \<subseteq> Y \<Longrightarrow> Z = Y \<or> suc Z \<subseteq> Y"
```
```   136   shows "X \<subseteq> Y \<or> suc Y \<subseteq> X"
```
```   137   using \<open>X \<in> \<C>\<close>
```
```   138 proof induct
```
```   139   case (suc X)
```
```   140   with * show ?case by (blast del: subsetI intro: subset_suc)
```
```   141 next
```
```   142   case Union
```
```   143   then show ?case by blast
```
```   144 qed
```
```   145
```
```   146 lemma suc_Union_closed_subsetD:
```
```   147   assumes "Y \<subseteq> X" and "X \<in> \<C>" and "Y \<in> \<C>"
```
```   148   shows "X = Y \<or> suc Y \<subseteq> X"
```
```   149   using assms(2,3,1)
```
```   150 proof (induct arbitrary: Y)
```
```   151   case (suc X)
```
```   152   note * = \<open>\<And>Y. Y \<in> \<C> \<Longrightarrow> Y \<subseteq> X \<Longrightarrow> X = Y \<or> suc Y \<subseteq> X\<close>
```
```   153   with suc_Union_closed_total' [OF \<open>Y \<in> \<C>\<close> \<open>X \<in> \<C>\<close>]
```
```   154   have "Y \<subseteq> X \<or> suc X \<subseteq> Y" by blast
```
```   155   then show ?case
```
```   156   proof
```
```   157     assume "Y \<subseteq> X"
```
```   158     with * and \<open>Y \<in> \<C>\<close> have "X = Y \<or> suc Y \<subseteq> X" by blast
```
```   159     then show ?thesis
```
```   160     proof
```
```   161       assume "X = Y"
```
```   162       then show ?thesis by simp
```
```   163     next
```
```   164       assume "suc Y \<subseteq> X"
```
```   165       then have "suc Y \<subseteq> suc X" by (rule subset_suc)
```
```   166       then show ?thesis by simp
```
```   167     qed
```
```   168   next
```
```   169     assume "suc X \<subseteq> Y"
```
```   170     with \<open>Y \<subseteq> suc X\<close> show ?thesis by blast
```
```   171   qed
```
```   172 next
```
```   173   case (Union X)
```
```   174   show ?case
```
```   175   proof (rule ccontr)
```
```   176     assume "\<not> ?thesis"
```
```   177     with \<open>Y \<subseteq> \<Union>X\<close> obtain x y z
```
```   178       where "\<not> suc Y \<subseteq> \<Union>X"
```
```   179         and "x \<in> X" and "y \<in> x" and "y \<notin> Y"
```
```   180         and "z \<in> suc Y" and "\<forall>x\<in>X. z \<notin> x" by blast
```
```   181     with \<open>X \<subseteq> \<C>\<close> have "x \<in> \<C>" by blast
```
```   182     from Union and \<open>x \<in> X\<close> have *: "\<And>y. y \<in> \<C> \<Longrightarrow> y \<subseteq> x \<Longrightarrow> x = y \<or> suc y \<subseteq> x"
```
```   183       by blast
```
```   184     with suc_Union_closed_total' [OF \<open>Y \<in> \<C>\<close> \<open>x \<in> \<C>\<close>] have "Y \<subseteq> x \<or> suc x \<subseteq> Y"
```
```   185       by blast
```
```   186     then show False
```
```   187     proof
```
```   188       assume "Y \<subseteq> x"
```
```   189       with * [OF \<open>Y \<in> \<C>\<close>] have "x = Y \<or> suc Y \<subseteq> x" by blast
```
```   190       then show False
```
```   191       proof
```
```   192         assume "x = Y"
```
```   193         with \<open>y \<in> x\<close> and \<open>y \<notin> Y\<close> show False by blast
```
```   194       next
```
```   195         assume "suc Y \<subseteq> x"
```
```   196         with \<open>x \<in> X\<close> have "suc Y \<subseteq> \<Union>X" by blast
```
```   197         with \<open>\<not> suc Y \<subseteq> \<Union>X\<close> show False by contradiction
```
```   198       qed
```
```   199     next
```
```   200       assume "suc x \<subseteq> Y"
```
```   201       moreover from suc_subset and \<open>y \<in> x\<close> have "y \<in> suc x" by blast
```
```   202       ultimately show False using \<open>y \<notin> Y\<close> by blast
```
```   203     qed
```
```   204   qed
```
```   205 qed
```
```   206
```
```   207 text \<open>The elements of @{term \<C>} are totally ordered by the subset relation.\<close>
```
```   208 lemma suc_Union_closed_total:
```
```   209   assumes "X \<in> \<C>" and "Y \<in> \<C>"
```
```   210   shows "X \<subseteq> Y \<or> Y \<subseteq> X"
```
```   211 proof (cases "\<forall>Z\<in>\<C>. Z \<subseteq> Y \<longrightarrow> Z = Y \<or> suc Z \<subseteq> Y")
```
```   212   case True
```
```   213   with suc_Union_closed_total' [OF assms]
```
```   214   have "X \<subseteq> Y \<or> suc Y \<subseteq> X" by blast
```
```   215   with suc_subset [of Y] show ?thesis by blast
```
```   216 next
```
```   217   case False
```
```   218   then obtain Z where "Z \<in> \<C>" and "Z \<subseteq> Y" and "Z \<noteq> Y" and "\<not> suc Z \<subseteq> Y"
```
```   219     by blast
```
```   220   with suc_Union_closed_subsetD and \<open>Y \<in> \<C>\<close> show ?thesis
```
```   221     by blast
```
```   222 qed
```
```   223
```
```   224 text \<open>Once we hit a fixed point w.r.t. @{term suc}, all other elements
```
```   225   of @{term \<C>} are subsets of this fixed point.\<close>
```
```   226 lemma suc_Union_closed_suc:
```
```   227   assumes "X \<in> \<C>" and "Y \<in> \<C>" and "suc Y = Y"
```
```   228   shows "X \<subseteq> Y"
```
```   229   using \<open>X \<in> \<C>\<close>
```
```   230 proof induct
```
```   231   case (suc X)
```
```   232   with \<open>Y \<in> \<C>\<close> and suc_Union_closed_subsetD have "X = Y \<or> suc X \<subseteq> Y"
```
```   233     by blast
```
```   234   then show ?case
```
```   235     by (auto simp: \<open>suc Y = Y\<close>)
```
```   236 next
```
```   237   case Union
```
```   238   then show ?case by blast
```
```   239 qed
```
```   240
```
```   241 lemma eq_suc_Union:
```
```   242   assumes "X \<in> \<C>"
```
```   243   shows "suc X = X \<longleftrightarrow> X = \<Union>\<C>"
```
```   244     (is "?lhs \<longleftrightarrow> ?rhs")
```
```   245 proof
```
```   246   assume ?lhs
```
```   247   then have "\<Union>\<C> \<subseteq> X"
```
```   248     by (rule suc_Union_closed_suc [OF suc_Union_closed_Union \<open>X \<in> \<C>\<close>])
```
```   249   with \<open>X \<in> \<C>\<close> show ?rhs
```
```   250     by blast
```
```   251 next
```
```   252   from \<open>X \<in> \<C>\<close> have "suc X \<in> \<C>" by (rule suc)
```
```   253   then have "suc X \<subseteq> \<Union>\<C>" by blast
```
```   254   moreover assume ?rhs
```
```   255   ultimately have "suc X \<subseteq> X" by simp
```
```   256   moreover have "X \<subseteq> suc X" by (rule suc_subset)
```
```   257   ultimately show ?lhs ..
```
```   258 qed
```
```   259
```
```   260 lemma suc_in_carrier:
```
```   261   assumes "X \<subseteq> A"
```
```   262   shows "suc X \<subseteq> A"
```
```   263   using assms
```
```   264   by (cases "\<not> chain X \<or> maxchain X") (auto dest: chain_sucD)
```
```   265
```
```   266 lemma suc_Union_closed_in_carrier:
```
```   267   assumes "X \<in> \<C>"
```
```   268   shows "X \<subseteq> A"
```
```   269   using assms
```
```   270   by induct (auto dest: suc_in_carrier)
```
```   271
```
```   272 text \<open>All elements of @{term \<C>} are chains.\<close>
```
```   273 lemma suc_Union_closed_chain:
```
```   274   assumes "X \<in> \<C>"
```
```   275   shows "chain X"
```
```   276   using assms
```
```   277 proof induct
```
```   278   case (suc X)
```
```   279   then show ?case
```
```   280     using not_maxchain_Some by (simp add: suc_def)
```
```   281 next
```
```   282   case (Union X)
```
```   283   then have "\<Union>X \<subseteq> A"
```
```   284     by (auto dest: suc_Union_closed_in_carrier)
```
```   285   moreover have "\<forall>x\<in>\<Union>X. \<forall>y\<in>\<Union>X. x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
```
```   286   proof (intro ballI)
```
```   287     fix x y
```
```   288     assume "x \<in> \<Union>X" and "y \<in> \<Union>X"
```
```   289     then obtain u v where "x \<in> u" and "u \<in> X" and "y \<in> v" and "v \<in> X"
```
```   290       by blast
```
```   291     with Union have "u \<in> \<C>" and "v \<in> \<C>" and "chain u" and "chain v"
```
```   292       by blast+
```
```   293     with suc_Union_closed_total have "u \<subseteq> v \<or> v \<subseteq> u"
```
```   294       by blast
```
```   295     then show "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
```
```   296     proof
```
```   297       assume "u \<subseteq> v"
```
```   298       from \<open>chain v\<close> show ?thesis
```
```   299       proof (rule chain_total)
```
```   300         show "y \<in> v" by fact
```
```   301         show "x \<in> v" using \<open>u \<subseteq> v\<close> and \<open>x \<in> u\<close> by blast
```
```   302       qed
```
```   303     next
```
```   304       assume "v \<subseteq> u"
```
```   305       from \<open>chain u\<close> show ?thesis
```
```   306       proof (rule chain_total)
```
```   307         show "x \<in> u" by fact
```
```   308         show "y \<in> u" using \<open>v \<subseteq> u\<close> and \<open>y \<in> v\<close> by blast
```
```   309       qed
```
```   310     qed
```
```   311   qed
```
```   312   ultimately show ?case unfolding chain_def ..
```
```   313 qed
```
```   314
```
```   315 subsubsection \<open>Hausdorff's Maximum Principle\<close>
```
```   316
```
```   317 text \<open>There exists a maximal totally ordered subset of \<open>A\<close>. (Note that we do not
```
```   318   require \<open>A\<close> to be partially ordered.)\<close>
```
```   319
```
```   320 theorem Hausdorff: "\<exists>C. maxchain C"
```
```   321 proof -
```
```   322   let ?M = "\<Union>\<C>"
```
```   323   have "maxchain ?M"
```
```   324   proof (rule ccontr)
```
```   325     assume "\<not> ?thesis"
```
```   326     then have "suc ?M \<noteq> ?M"
```
```   327       using suc_not_equals and suc_Union_closed_chain [OF suc_Union_closed_Union] by simp
```
```   328     moreover have "suc ?M = ?M"
```
```   329       using eq_suc_Union [OF suc_Union_closed_Union] by simp
```
```   330     ultimately show False by contradiction
```
```   331   qed
```
```   332   then show ?thesis by blast
```
```   333 qed
```
```   334
```
```   335 text \<open>Make notation @{term \<C>} available again.\<close>
```
```   336 no_notation suc_Union_closed  ("\<C>")
```
```   337
```
```   338 lemma chain_extend: "chain C \<Longrightarrow> z \<in> A \<Longrightarrow> \<forall>x\<in>C. x \<sqsubseteq> z \<Longrightarrow> chain ({z} \<union> C)"
```
```   339   unfolding chain_def by blast
```
```   340
```
```   341 lemma maxchain_imp_chain: "maxchain C \<Longrightarrow> chain C"
```
```   342   by (simp add: maxchain_def)
```
```   343
```
```   344 end
```
```   345
```
```   346 text \<open>Hide constant @{const pred_on.suc_Union_closed}, which was just needed
```
```   347   for the proof of Hausforff's maximum principle.\<close>
```
```   348 hide_const pred_on.suc_Union_closed
```
```   349
```
```   350 lemma chain_mono:
```
```   351   assumes "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> P x y \<Longrightarrow> Q x y"
```
```   352     and "pred_on.chain A P C"
```
```   353   shows "pred_on.chain A Q C"
```
```   354   using assms unfolding pred_on.chain_def by blast
```
```   355
```
```   356
```
```   357 subsubsection \<open>Results for the proper subset relation\<close>
```
```   358
```
```   359 interpretation subset: pred_on "A" "op \<subset>" for A .
```
```   360
```
```   361 lemma subset_maxchain_max:
```
```   362   assumes "subset.maxchain A C"
```
```   363     and "X \<in> A"
```
```   364     and "\<Union>C \<subseteq> X"
```
```   365   shows "\<Union>C = X"
```
```   366 proof (rule ccontr)
```
```   367   let ?C = "{X} \<union> C"
```
```   368   from \<open>subset.maxchain A C\<close> have "subset.chain A C"
```
```   369     and *: "\<And>S. subset.chain A S \<Longrightarrow> \<not> C \<subset> S"
```
```   370     by (auto simp: subset.maxchain_def)
```
```   371   moreover have "\<forall>x\<in>C. x \<subseteq> X" using \<open>\<Union>C \<subseteq> X\<close> by auto
```
```   372   ultimately have "subset.chain A ?C"
```
```   373     using subset.chain_extend [of A C X] and \<open>X \<in> A\<close> by auto
```
```   374   moreover assume **: "\<Union>C \<noteq> X"
```
```   375   moreover from ** have "C \<subset> ?C" using \<open>\<Union>C \<subseteq> X\<close> by auto
```
```   376   ultimately show False using * by blast
```
```   377 qed
```
```   378
```
```   379
```
```   380 subsubsection \<open>Zorn's lemma\<close>
```
```   381
```
```   382 text \<open>If every chain has an upper bound, then there is a maximal set.\<close>
```
```   383 lemma subset_Zorn:
```
```   384   assumes "\<And>C. subset.chain A C \<Longrightarrow> \<exists>U\<in>A. \<forall>X\<in>C. X \<subseteq> U"
```
```   385   shows "\<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
```
```   386 proof -
```
```   387   from subset.Hausdorff [of A] obtain M where "subset.maxchain A M" ..
```
```   388   then have "subset.chain A M"
```
```   389     by (rule subset.maxchain_imp_chain)
```
```   390   with assms obtain Y where "Y \<in> A" and "\<forall>X\<in>M. X \<subseteq> Y"
```
```   391     by blast
```
```   392   moreover have "\<forall>X\<in>A. Y \<subseteq> X \<longrightarrow> Y = X"
```
```   393   proof (intro ballI impI)
```
```   394     fix X
```
```   395     assume "X \<in> A" and "Y \<subseteq> X"
```
```   396     show "Y = X"
```
```   397     proof (rule ccontr)
```
```   398       assume "\<not> ?thesis"
```
```   399       with \<open>Y \<subseteq> X\<close> have "\<not> X \<subseteq> Y" by blast
```
```   400       from subset.chain_extend [OF \<open>subset.chain A M\<close> \<open>X \<in> A\<close>] and \<open>\<forall>X\<in>M. X \<subseteq> Y\<close>
```
```   401       have "subset.chain A ({X} \<union> M)"
```
```   402         using \<open>Y \<subseteq> X\<close> by auto
```
```   403       moreover have "M \<subset> {X} \<union> M"
```
```   404         using \<open>\<forall>X\<in>M. X \<subseteq> Y\<close> and \<open>\<not> X \<subseteq> Y\<close> by auto
```
```   405       ultimately show False
```
```   406         using \<open>subset.maxchain A M\<close> by (auto simp: subset.maxchain_def)
```
```   407     qed
```
```   408   qed
```
```   409   ultimately show ?thesis by blast
```
```   410 qed
```
```   411
```
```   412 text \<open>Alternative version of Zorn's lemma for the subset relation.\<close>
```
```   413 lemma subset_Zorn':
```
```   414   assumes "\<And>C. subset.chain A C \<Longrightarrow> \<Union>C \<in> A"
```
```   415   shows "\<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
```
```   416 proof -
```
```   417   from subset.Hausdorff [of A] obtain M where "subset.maxchain A M" ..
```
```   418   then have "subset.chain A M"
```
```   419     by (rule subset.maxchain_imp_chain)
```
```   420   with assms have "\<Union>M \<in> A" .
```
```   421   moreover have "\<forall>Z\<in>A. \<Union>M \<subseteq> Z \<longrightarrow> \<Union>M = Z"
```
```   422   proof (intro ballI impI)
```
```   423     fix Z
```
```   424     assume "Z \<in> A" and "\<Union>M \<subseteq> Z"
```
```   425     with subset_maxchain_max [OF \<open>subset.maxchain A M\<close>]
```
```   426       show "\<Union>M = Z" .
```
```   427   qed
```
```   428   ultimately show ?thesis by blast
```
```   429 qed
```
```   430
```
```   431
```
```   432 subsection \<open>Zorn's Lemma for Partial Orders\<close>
```
```   433
```
```   434 text \<open>Relate old to new definitions.\<close>
```
```   435
```
```   436 definition chain_subset :: "'a set set \<Rightarrow> bool"  ("chain\<^sub>\<subseteq>")  (* Define globally? In Set.thy? *)
```
```   437   where "chain\<^sub>\<subseteq> C \<longleftrightarrow> (\<forall>A\<in>C. \<forall>B\<in>C. A \<subseteq> B \<or> B \<subseteq> A)"
```
```   438
```
```   439 definition chains :: "'a set set \<Rightarrow> 'a set set set"
```
```   440   where "chains A = {C. C \<subseteq> A \<and> chain\<^sub>\<subseteq> C}"
```
```   441
```
```   442 definition Chains :: "('a \<times> 'a) set \<Rightarrow> 'a set set"  (* Define globally? In Relation.thy? *)
```
```   443   where "Chains r = {C. \<forall>a\<in>C. \<forall>b\<in>C. (a, b) \<in> r \<or> (b, a) \<in> r}"
```
```   444
```
```   445 lemma chains_extend: "c \<in> chains S \<Longrightarrow> z \<in> S \<Longrightarrow> \<forall>x \<in> c. x \<subseteq> z \<Longrightarrow> {z} \<union> c \<in> chains S"
```
```   446   for z :: "'a set"
```
```   447   unfolding chains_def chain_subset_def by blast
```
```   448
```
```   449 lemma mono_Chains: "r \<subseteq> s \<Longrightarrow> Chains r \<subseteq> Chains s"
```
```   450   unfolding Chains_def by blast
```
```   451
```
```   452 lemma chain_subset_alt_def: "chain\<^sub>\<subseteq> C = subset.chain UNIV C"
```
```   453   unfolding chain_subset_def subset.chain_def by fast
```
```   454
```
```   455 lemma chains_alt_def: "chains A = {C. subset.chain A C}"
```
```   456   by (simp add: chains_def chain_subset_alt_def subset.chain_def)
```
```   457
```
```   458 lemma Chains_subset: "Chains r \<subseteq> {C. pred_on.chain UNIV (\<lambda>x y. (x, y) \<in> r) C}"
```
```   459   by (force simp add: Chains_def pred_on.chain_def)
```
```   460
```
```   461 lemma Chains_subset':
```
```   462   assumes "refl r"
```
```   463   shows "{C. pred_on.chain UNIV (\<lambda>x y. (x, y) \<in> r) C} \<subseteq> Chains r"
```
```   464   using assms
```
```   465   by (auto simp add: Chains_def pred_on.chain_def refl_on_def)
```
```   466
```
```   467 lemma Chains_alt_def:
```
```   468   assumes "refl r"
```
```   469   shows "Chains r = {C. pred_on.chain UNIV (\<lambda>x y. (x, y) \<in> r) C}"
```
```   470   using assms Chains_subset Chains_subset' by blast
```
```   471
```
```   472 lemma Zorn_Lemma: "\<forall>C\<in>chains A. \<Union>C \<in> A \<Longrightarrow> \<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
```
```   473   using subset_Zorn' [of A] by (force simp: chains_alt_def)
```
```   474
```
```   475 lemma Zorn_Lemma2: "\<forall>C\<in>chains A. \<exists>U\<in>A. \<forall>X\<in>C. X \<subseteq> U \<Longrightarrow> \<exists>M\<in>A. \<forall>X\<in>A. M \<subseteq> X \<longrightarrow> X = M"
```
```   476   using subset_Zorn [of A] by (auto simp: chains_alt_def)
```
```   477
```
```   478 text \<open>Various other lemmas\<close>
```
```   479
```
```   480 lemma chainsD: "c \<in> chains S \<Longrightarrow> x \<in> c \<Longrightarrow> y \<in> c \<Longrightarrow> x \<subseteq> y \<or> y \<subseteq> x"
```
```   481   unfolding chains_def chain_subset_def by blast
```
```   482
```
```   483 lemma chainsD2: "c \<in> chains S \<Longrightarrow> c \<subseteq> S"
```
```   484   unfolding chains_def by blast
```
```   485
```
```   486 lemma Zorns_po_lemma:
```
```   487   assumes po: "Partial_order r"
```
```   488     and u: "\<forall>C\<in>Chains r. \<exists>u\<in>Field r. \<forall>a\<in>C. (a, u) \<in> r"
```
```   489   shows "\<exists>m\<in>Field r. \<forall>a\<in>Field r. (m, a) \<in> r \<longrightarrow> a = m"
```
```   490 proof -
```
```   491   have "Preorder r"
```
```   492     using po by (simp add: partial_order_on_def)
```
```   493   txt \<open>Mirror \<open>r\<close> in the set of subsets below (wrt \<open>r\<close>) elements of \<open>A\<close>.\<close>
```
```   494   let ?B = "\<lambda>x. r\<inverse> `` {x}"
```
```   495   let ?S = "?B ` Field r"
```
```   496   have "\<exists>u\<in>Field r. \<forall>A\<in>C. A \<subseteq> r\<inverse> `` {u}"  (is "\<exists>u\<in>Field r. ?P u")
```
```   497     if 1: "C \<subseteq> ?S" and 2: "\<forall>A\<in>C. \<forall>B\<in>C. A \<subseteq> B \<or> B \<subseteq> A" for C
```
```   498   proof -
```
```   499     let ?A = "{x\<in>Field r. \<exists>M\<in>C. M = ?B x}"
```
```   500     from 1 have "C = ?B ` ?A" by (auto simp: image_def)
```
```   501     have "?A \<in> Chains r"
```
```   502     proof (simp add: Chains_def, intro allI impI, elim conjE)
```
```   503       fix a b
```
```   504       assume "a \<in> Field r" and "?B a \<in> C" and "b \<in> Field r" and "?B b \<in> C"
```
```   505       with 2 have "?B a \<subseteq> ?B b \<or> ?B b \<subseteq> ?B a" by auto
```
```   506       then show "(a, b) \<in> r \<or> (b, a) \<in> r"
```
```   507         using \<open>Preorder r\<close> and \<open>a \<in> Field r\<close> and \<open>b \<in> Field r\<close>
```
```   508         by (simp add:subset_Image1_Image1_iff)
```
```   509     qed
```
```   510     with u obtain u where uA: "u \<in> Field r" "\<forall>a\<in>?A. (a, u) \<in> r" by auto
```
```   511     have "?P u"
```
```   512     proof auto
```
```   513       fix a B assume aB: "B \<in> C" "a \<in> B"
```
```   514       with 1 obtain x where "x \<in> Field r" and "B = r\<inverse> `` {x}" by auto
```
```   515       then show "(a, u) \<in> r"
```
```   516         using uA and aB and \<open>Preorder r\<close>
```
```   517         unfolding preorder_on_def refl_on_def by simp (fast dest: transD)
```
```   518     qed
```
```   519     then show ?thesis
```
```   520       using \<open>u \<in> Field r\<close> by blast
```
```   521   qed
```
```   522   then have "\<forall>C\<in>chains ?S. \<exists>U\<in>?S. \<forall>A\<in>C. A \<subseteq> U"
```
```   523     by (auto simp: chains_def chain_subset_def)
```
```   524   from Zorn_Lemma2 [OF this] obtain m B
```
```   525     where "m \<in> Field r"
```
```   526       and "B = r\<inverse> `` {m}"
```
```   527       and "\<forall>x\<in>Field r. B \<subseteq> r\<inverse> `` {x} \<longrightarrow> r\<inverse> `` {x} = B"
```
```   528     by auto
```
```   529   then have "\<forall>a\<in>Field r. (m, a) \<in> r \<longrightarrow> a = m"
```
```   530     using po and \<open>Preorder r\<close> and \<open>m \<in> Field r\<close>
```
```   531     by (auto simp: subset_Image1_Image1_iff Partial_order_eq_Image1_Image1_iff)
```
```   532   then show ?thesis
```
```   533     using \<open>m \<in> Field r\<close> by blast
```
```   534 qed
```
```   535
```
```   536
```
```   537 subsection \<open>The Well Ordering Theorem\<close>
```
```   538
```
```   539 (* The initial segment of a relation appears generally useful.
```
```   540    Move to Relation.thy?
```
```   541    Definition correct/most general?
```
```   542    Naming?
```
```   543 *)
```
```   544 definition init_seg_of :: "(('a \<times> 'a) set \<times> ('a \<times> 'a) set) set"
```
```   545   where "init_seg_of = {(r, s). r \<subseteq> s \<and> (\<forall>a b c. (a, b) \<in> s \<and> (b, c) \<in> r \<longrightarrow> (a, b) \<in> r)}"
```
```   546
```
```   547 abbreviation initial_segment_of_syntax :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> bool"
```
```   548     (infix "initial'_segment'_of" 55)
```
```   549   where "r initial_segment_of s \<equiv> (r, s) \<in> init_seg_of"
```
```   550
```
```   551 lemma refl_on_init_seg_of [simp]: "r initial_segment_of r"
```
```   552   by (simp add: init_seg_of_def)
```
```   553
```
```   554 lemma trans_init_seg_of:
```
```   555   "r initial_segment_of s \<Longrightarrow> s initial_segment_of t \<Longrightarrow> r initial_segment_of t"
```
```   556   by (simp (no_asm_use) add: init_seg_of_def) blast
```
```   557
```
```   558 lemma antisym_init_seg_of: "r initial_segment_of s \<Longrightarrow> s initial_segment_of r \<Longrightarrow> r = s"
```
```   559   unfolding init_seg_of_def by safe
```
```   560
```
```   561 lemma Chains_init_seg_of_Union: "R \<in> Chains init_seg_of \<Longrightarrow> r\<in>R \<Longrightarrow> r initial_segment_of \<Union>R"
```
```   562   by (auto simp: init_seg_of_def Ball_def Chains_def) blast
```
```   563
```
```   564 lemma chain_subset_trans_Union:
```
```   565   assumes "chain\<^sub>\<subseteq> R" "\<forall>r\<in>R. trans r"
```
```   566   shows "trans (\<Union>R)"
```
```   567 proof (intro transI, elim UnionE)
```
```   568   fix S1 S2 :: "'a rel" and x y z :: 'a
```
```   569   assume "S1 \<in> R" "S2 \<in> R"
```
```   570   with assms(1) have "S1 \<subseteq> S2 \<or> S2 \<subseteq> S1"
```
```   571     unfolding chain_subset_def by blast
```
```   572   moreover assume "(x, y) \<in> S1" "(y, z) \<in> S2"
```
```   573   ultimately have "((x, y) \<in> S1 \<and> (y, z) \<in> S1) \<or> ((x, y) \<in> S2 \<and> (y, z) \<in> S2)"
```
```   574     by blast
```
```   575   with \<open>S1 \<in> R\<close> \<open>S2 \<in> R\<close> assms(2) show "(x, z) \<in> \<Union>R"
```
```   576     by (auto elim: transE)
```
```   577 qed
```
```   578
```
```   579 lemma chain_subset_antisym_Union:
```
```   580   assumes "chain\<^sub>\<subseteq> R" "\<forall>r\<in>R. antisym r"
```
```   581   shows "antisym (\<Union>R)"
```
```   582 proof (intro antisymI, elim UnionE)
```
```   583   fix S1 S2 :: "'a rel" and x y :: 'a
```
```   584   assume "S1 \<in> R" "S2 \<in> R"
```
```   585   with assms(1) have "S1 \<subseteq> S2 \<or> S2 \<subseteq> S1"
```
```   586     unfolding chain_subset_def by blast
```
```   587   moreover assume "(x, y) \<in> S1" "(y, x) \<in> S2"
```
```   588   ultimately have "((x, y) \<in> S1 \<and> (y, x) \<in> S1) \<or> ((x, y) \<in> S2 \<and> (y, x) \<in> S2)"
```
```   589     by blast
```
```   590   with \<open>S1 \<in> R\<close> \<open>S2 \<in> R\<close> assms(2) show "x = y"
```
```   591     unfolding antisym_def by auto
```
```   592 qed
```
```   593
```
```   594 lemma chain_subset_Total_Union:
```
```   595   assumes "chain\<^sub>\<subseteq> R" and "\<forall>r\<in>R. Total r"
```
```   596   shows "Total (\<Union>R)"
```
```   597 proof (simp add: total_on_def Ball_def, auto del: disjCI)
```
```   598   fix r s a b
```
```   599   assume A: "r \<in> R" "s \<in> R" "a \<in> Field r" "b \<in> Field s" "a \<noteq> b"
```
```   600   from \<open>chain\<^sub>\<subseteq> R\<close> and \<open>r \<in> R\<close> and \<open>s \<in> R\<close> have "r \<subseteq> s \<or> s \<subseteq> r"
```
```   601     by (auto simp add: chain_subset_def)
```
```   602   then show "(\<exists>r\<in>R. (a, b) \<in> r) \<or> (\<exists>r\<in>R. (b, a) \<in> r)"
```
```   603   proof
```
```   604     assume "r \<subseteq> s"
```
```   605     then have "(a, b) \<in> s \<or> (b, a) \<in> s"
```
```   606       using assms(2) A mono_Field[of r s]
```
```   607       by (auto simp add: total_on_def)
```
```   608     then show ?thesis
```
```   609       using \<open>s \<in> R\<close> by blast
```
```   610   next
```
```   611     assume "s \<subseteq> r"
```
```   612     then have "(a, b) \<in> r \<or> (b, a) \<in> r"
```
```   613       using assms(2) A mono_Field[of s r]
```
```   614       by (fastforce simp add: total_on_def)
```
```   615     then show ?thesis
```
```   616       using \<open>r \<in> R\<close> by blast
```
```   617   qed
```
```   618 qed
```
```   619
```
```   620 lemma wf_Union_wf_init_segs:
```
```   621   assumes "R \<in> Chains init_seg_of"
```
```   622     and "\<forall>r\<in>R. wf r"
```
```   623   shows "wf (\<Union>R)"
```
```   624 proof (simp add: wf_iff_no_infinite_down_chain, rule ccontr, auto)
```
```   625   fix f
```
```   626   assume 1: "\<forall>i. \<exists>r\<in>R. (f (Suc i), f i) \<in> r"
```
```   627   then obtain r where "r \<in> R" and "(f (Suc 0), f 0) \<in> r" by auto
```
```   628   have "(f (Suc i), f i) \<in> r" for i
```
```   629   proof (induct i)
```
```   630     case 0
```
```   631     show ?case by fact
```
```   632   next
```
```   633     case (Suc i)
```
```   634     then obtain s where s: "s \<in> R" "(f (Suc (Suc i)), f(Suc i)) \<in> s"
```
```   635       using 1 by auto
```
```   636     then have "s initial_segment_of r \<or> r initial_segment_of s"
```
```   637       using assms(1) \<open>r \<in> R\<close> by (simp add: Chains_def)
```
```   638     with Suc s show ?case by (simp add: init_seg_of_def) blast
```
```   639   qed
```
```   640   then show False
```
```   641     using assms(2) and \<open>r \<in> R\<close>
```
```   642     by (simp add: wf_iff_no_infinite_down_chain) blast
```
```   643 qed
```
```   644
```
```   645 lemma initial_segment_of_Diff: "p initial_segment_of q \<Longrightarrow> p - s initial_segment_of q - s"
```
```   646   unfolding init_seg_of_def by blast
```
```   647
```
```   648 lemma Chains_inits_DiffI: "R \<in> Chains init_seg_of \<Longrightarrow> {r - s |r. r \<in> R} \<in> Chains init_seg_of"
```
```   649   unfolding Chains_def by (blast intro: initial_segment_of_Diff)
```
```   650
```
```   651 theorem well_ordering: "\<exists>r::'a rel. Well_order r \<and> Field r = UNIV"
```
```   652 proof -
```
```   653 \<comment> \<open>The initial segment relation on well-orders:\<close>
```
```   654   let ?WO = "{r::'a rel. Well_order r}"
```
```   655   define I where "I = init_seg_of \<inter> ?WO \<times> ?WO"
```
```   656   then have I_init: "I \<subseteq> init_seg_of" by simp
```
```   657   then have subch: "\<And>R. R \<in> Chains I \<Longrightarrow> chain\<^sub>\<subseteq> R"
```
```   658     unfolding init_seg_of_def chain_subset_def Chains_def by blast
```
```   659   have Chains_wo: "\<And>R r. R \<in> Chains I \<Longrightarrow> r \<in> R \<Longrightarrow> Well_order r"
```
```   660     by (simp add: Chains_def I_def) blast
```
```   661   have FI: "Field I = ?WO"
```
```   662     by (auto simp add: I_def init_seg_of_def Field_def)
```
```   663   then have 0: "Partial_order I"
```
```   664     by (auto simp: partial_order_on_def preorder_on_def antisym_def antisym_init_seg_of refl_on_def
```
```   665         trans_def I_def elim!: trans_init_seg_of)
```
```   666 \<comment> \<open>\<open>I\<close>-chains have upper bounds in \<open>?WO\<close> wrt \<open>I\<close>: their Union\<close>
```
```   667   have "\<Union>R \<in> ?WO \<and> (\<forall>r\<in>R. (r, \<Union>R) \<in> I)" if "R \<in> Chains I" for R
```
```   668   proof -
```
```   669     from that have Ris: "R \<in> Chains init_seg_of"
```
```   670       using mono_Chains [OF I_init] by blast
```
```   671     have subch: "chain\<^sub>\<subseteq> R"
```
```   672       using \<open>R : Chains I\<close> I_init by (auto simp: init_seg_of_def chain_subset_def Chains_def)
```
```   673     have "\<forall>r\<in>R. Refl r" and "\<forall>r\<in>R. trans r" and "\<forall>r\<in>R. antisym r"
```
```   674       and "\<forall>r\<in>R. Total r" and "\<forall>r\<in>R. wf (r - Id)"
```
```   675       using Chains_wo [OF \<open>R \<in> Chains I\<close>] by (simp_all add: order_on_defs)
```
```   676     have "Refl (\<Union>R)"
```
```   677       using \<open>\<forall>r\<in>R. Refl r\<close> unfolding refl_on_def by fastforce
```
```   678     moreover have "trans (\<Union>R)"
```
```   679       by (rule chain_subset_trans_Union [OF subch \<open>\<forall>r\<in>R. trans r\<close>])
```
```   680     moreover have "antisym (\<Union>R)"
```
```   681       by (rule chain_subset_antisym_Union [OF subch \<open>\<forall>r\<in>R. antisym r\<close>])
```
```   682     moreover have "Total (\<Union>R)"
```
```   683       by (rule chain_subset_Total_Union [OF subch \<open>\<forall>r\<in>R. Total r\<close>])
```
```   684     moreover have "wf ((\<Union>R) - Id)"
```
```   685     proof -
```
```   686       have "(\<Union>R) - Id = \<Union>{r - Id | r. r \<in> R}" by blast
```
```   687       with \<open>\<forall>r\<in>R. wf (r - Id)\<close> and wf_Union_wf_init_segs [OF Chains_inits_DiffI [OF Ris]]
```
```   688       show ?thesis by fastforce
```
```   689     qed
```
```   690     ultimately have "Well_order (\<Union>R)"
```
```   691       by (simp add:order_on_defs)
```
```   692     moreover have "\<forall>r \<in> R. r initial_segment_of \<Union>R"
```
```   693       using Ris by (simp add: Chains_init_seg_of_Union)
```
```   694     ultimately show ?thesis
```
```   695       using mono_Chains [OF I_init] Chains_wo[of R] and \<open>R \<in> Chains I\<close>
```
```   696       unfolding I_def by blast
```
```   697   qed
```
```   698   then have 1: "\<forall>R \<in> Chains I. \<exists>u\<in>Field I. \<forall>r\<in>R. (r, u) \<in> I"
```
```   699     by (subst FI) blast
```
```   700 \<comment>\<open>Zorn's Lemma yields a maximal well-order \<open>m\<close>:\<close>
```
```   701   then obtain m :: "'a rel"
```
```   702     where "Well_order m"
```
```   703       and max: "\<forall>r. Well_order r \<and> (m, r) \<in> I \<longrightarrow> r = m"
```
```   704     using Zorns_po_lemma[OF 0 1] unfolding FI by fastforce
```
```   705 \<comment>\<open>Now show by contradiction that \<open>m\<close> covers the whole type:\<close>
```
```   706   have False if "x \<notin> Field m" for x :: 'a
```
```   707   proof -
```
```   708 \<comment>\<open>Assuming that \<open>x\<close> is not covered and extend \<open>m\<close> at the top with \<open>x\<close>\<close>
```
```   709     have "m \<noteq> {}"
```
```   710     proof
```
```   711       assume "m = {}"
```
```   712       moreover have "Well_order {(x, x)}"
```
```   713         by (simp add: order_on_defs refl_on_def trans_def antisym_def total_on_def Field_def)
```
```   714       ultimately show False using max
```
```   715         by (auto simp: I_def init_seg_of_def simp del: Field_insert)
```
```   716     qed
```
```   717     then have "Field m \<noteq> {}" by (auto simp: Field_def)
```
```   718     moreover have "wf (m - Id)"
```
```   719       using \<open>Well_order m\<close> by (simp add: well_order_on_def)
```
```   720 \<comment>\<open>The extension of \<open>m\<close> by \<open>x\<close>:\<close>
```
```   721     let ?s = "{(a, x) | a. a \<in> Field m}"
```
```   722     let ?m = "insert (x, x) m \<union> ?s"
```
```   723     have Fm: "Field ?m = insert x (Field m)"
```
```   724       by (auto simp: Field_def)
```
```   725     have "Refl m" and "trans m" and "antisym m" and "Total m" and "wf (m - Id)"
```
```   726       using \<open>Well_order m\<close> by (simp_all add: order_on_defs)
```
```   727 \<comment>\<open>We show that the extension is a well-order\<close>
```
```   728     have "Refl ?m"
```
```   729       using \<open>Refl m\<close> Fm unfolding refl_on_def by blast
```
```   730     moreover have "trans ?m" using \<open>trans m\<close> and \<open>x \<notin> Field m\<close>
```
```   731       unfolding trans_def Field_def by blast
```
```   732     moreover have "antisym ?m"
```
```   733       using \<open>antisym m\<close> and \<open>x \<notin> Field m\<close> unfolding antisym_def Field_def by blast
```
```   734     moreover have "Total ?m"
```
```   735       using \<open>Total m\<close> and Fm by (auto simp: total_on_def)
```
```   736     moreover have "wf (?m - Id)"
```
```   737     proof -
```
```   738       have "wf ?s"
```
```   739         using \<open>x \<notin> Field m\<close> by (auto simp: wf_eq_minimal Field_def Bex_def)
```
```   740       then show ?thesis
```
```   741         using \<open>wf (m - Id)\<close> and \<open>x \<notin> Field m\<close> wf_subset [OF \<open>wf ?s\<close> Diff_subset]
```
```   742         by (auto simp: Un_Diff Field_def intro: wf_Un)
```
```   743     qed
```
```   744     ultimately have "Well_order ?m"
```
```   745       by (simp add: order_on_defs)
```
```   746 \<comment>\<open>We show that the extension is above \<open>m\<close>\<close>
```
```   747     moreover have "(m, ?m) \<in> I"
```
```   748       using \<open>Well_order ?m\<close> and \<open>Well_order m\<close> and \<open>x \<notin> Field m\<close>
```
```   749       by (fastforce simp: I_def init_seg_of_def Field_def)
```
```   750     ultimately
```
```   751 \<comment>\<open>This contradicts maximality of \<open>m\<close>:\<close>
```
```   752     show False
```
```   753       using max and \<open>x \<notin> Field m\<close> unfolding Field_def by blast
```
```   754   qed
```
```   755   then have "Field m = UNIV" by auto
```
```   756   with \<open>Well_order m\<close> show ?thesis by blast
```
```   757 qed
```
```   758
```
```   759 corollary well_order_on: "\<exists>r::'a rel. well_order_on A r"
```
```   760 proof -
```
```   761   obtain r :: "'a rel" where wo: "Well_order r" and univ: "Field r = UNIV"
```
```   762     using well_ordering [where 'a = "'a"] by blast
```
```   763   let ?r = "{(x, y). x \<in> A \<and> y \<in> A \<and> (x, y) \<in> r}"
```
```   764   have 1: "Field ?r = A"
```
```   765     using wo univ by (fastforce simp: Field_def order_on_defs refl_on_def)
```
```   766   from \<open>Well_order r\<close> have "Refl r" "trans r" "antisym r" "Total r" "wf (r - Id)"
```
```   767     by (simp_all add: order_on_defs)
```
```   768   from \<open>Refl r\<close> have "Refl ?r"
```
```   769     by (auto simp: refl_on_def 1 univ)
```
```   770   moreover from \<open>trans r\<close> have "trans ?r"
```
```   771     unfolding trans_def by blast
```
```   772   moreover from \<open>antisym r\<close> have "antisym ?r"
```
```   773     unfolding antisym_def by blast
```
```   774   moreover from \<open>Total r\<close> have "Total ?r"
```
```   775     by (simp add:total_on_def 1 univ)
```
```   776   moreover have "wf (?r - Id)"
```
```   777     by (rule wf_subset [OF \<open>wf (r - Id)\<close>]) blast
```
```   778   ultimately have "Well_order ?r"
```
```   779     by (simp add: order_on_defs)
```
```   780   with 1 show ?thesis by auto
```
```   781 qed
```
```   782
```
```   783 (* Move this to Hilbert Choice and wfrec to Wellfounded*)
```
```   784
```
```   785 lemma wfrec_def_adm: "f \<equiv> wfrec R F \<Longrightarrow> wf R \<Longrightarrow> adm_wf R F \<Longrightarrow> f = F f"
```
```   786   using wfrec_fixpoint by simp
```
```   787
```
```   788 lemma dependent_wf_choice:
```
```   789   fixes P :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
```
```   790   assumes "wf R"
```
```   791     and adm: "\<And>f g x r. (\<And>z. (z, x) \<in> R \<Longrightarrow> f z = g z) \<Longrightarrow> P f x r = P g x r"
```
```   792     and P: "\<And>x f. (\<And>y. (y, x) \<in> R \<Longrightarrow> P f y (f y)) \<Longrightarrow> \<exists>r. P f x r"
```
```   793   shows "\<exists>f. \<forall>x. P f x (f x)"
```
```   794 proof (intro exI allI)
```
```   795   fix x
```
```   796   define f where "f \<equiv> wfrec R (\<lambda>f x. SOME r. P f x r)"
```
```   797   from \<open>wf R\<close> show "P f x (f x)"
```
```   798   proof (induct x)
```
```   799     case (less x)
```
```   800     show "P f x (f x)"
```
```   801     proof (subst (2) wfrec_def_adm[OF f_def \<open>wf R\<close>])
```
```   802       show "adm_wf R (\<lambda>f x. SOME r. P f x r)"
```
```   803         by (auto simp add: adm_wf_def intro!: arg_cong[where f=Eps] ext adm)
```
```   804       show "P f x (Eps (P f x))"
```
```   805         using P by (rule someI_ex) fact
```
```   806     qed
```
```   807   qed
```
```   808 qed
```
```   809
```
```   810 lemma (in wellorder) dependent_wellorder_choice:
```
```   811   assumes "\<And>r f g x. (\<And>y. y < x \<Longrightarrow> f y = g y) \<Longrightarrow> P f x r = P g x r"
```
```   812     and P: "\<And>x f. (\<And>y. y < x \<Longrightarrow> P f y (f y)) \<Longrightarrow> \<exists>r. P f x r"
```
```   813   shows "\<exists>f. \<forall>x. P f x (f x)"
```
```   814   using wf by (rule dependent_wf_choice) (auto intro!: assms)
```
```   815
```
```   816 end
```