src/HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
author blanchet
Fri Mar 19 13:02:18 2010 +0100 (2010-03-19)
changeset 35865 2f8fb5242799
parent 35827 f552152d7747
child 36062 194cb6e3c13f
permissions -rw-r--r--
more Sledgehammer refactoring
     1 (*  Title:      HOL/Tools/Sledgehammer/sledgehammer_fol_clause.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory
     3 
     4 Storing/printing FOL clauses and arity clauses.  Typed equality is
     5 treated differently.
     6 
     7 FIXME: combine with res_hol_clause!
     8 *)
     9 
    10 signature SLEDGEHAMMER_FOL_CLAUSE =
    11 sig
    12   val schematic_var_prefix: string
    13   val fixed_var_prefix: string
    14   val tvar_prefix: string
    15   val tfree_prefix: string
    16   val clause_prefix: string
    17   val const_prefix: string
    18   val tconst_prefix: string
    19   val class_prefix: string
    20   val union_all: ''a list list -> ''a list
    21   val const_trans_table: string Symtab.table
    22   val type_const_trans_table: string Symtab.table
    23   val ascii_of: string -> string
    24   val undo_ascii_of: string -> string
    25   val paren_pack : string list -> string
    26   val make_schematic_var : string * int -> string
    27   val make_fixed_var : string -> string
    28   val make_schematic_type_var : string * int -> string
    29   val make_fixed_type_var : string -> string
    30   val make_fixed_const : bool -> string -> string
    31   val make_fixed_type_const : bool -> string -> string
    32   val make_type_class : string -> string
    33   datatype kind = Axiom | Conjecture
    34   type axiom_name = string
    35   datatype fol_type =
    36       AtomV of string
    37     | AtomF of string
    38     | Comp of string * fol_type list
    39   val string_of_fol_type : fol_type -> string
    40   datatype type_literal = LTVar of string * string | LTFree of string * string
    41   exception CLAUSE of string * term
    42   val add_typs : typ list -> type_literal list
    43   val get_tvar_strs: typ list -> string list
    44   datatype arLit =
    45       TConsLit of class * string * string list
    46     | TVarLit of class * string
    47   datatype arity_clause = ArityClause of
    48    {axiom_name: axiom_name, conclLit: arLit, premLits: arLit list}
    49   datatype classrel_clause = ClassrelClause of
    50    {axiom_name: axiom_name, subclass: class, superclass: class}
    51   val make_classrel_clauses: theory -> class list -> class list -> classrel_clause list
    52   val make_arity_clauses_dfg: bool -> theory -> string list -> class list -> class list * arity_clause list
    53   val make_arity_clauses: theory -> string list -> class list -> class list * arity_clause list
    54   val add_type_sort_preds: typ * int Symtab.table -> int Symtab.table
    55   val add_classrel_clause_preds : classrel_clause * int Symtab.table -> int Symtab.table
    56   val class_of_arityLit: arLit -> class
    57   val add_arity_clause_preds: arity_clause * int Symtab.table -> int Symtab.table
    58   val add_foltype_funcs: fol_type * int Symtab.table -> int Symtab.table
    59   val add_arity_clause_funcs: arity_clause * int Symtab.table -> int Symtab.table
    60   val init_functab: int Symtab.table
    61   val dfg_sign: bool -> string -> string
    62   val dfg_of_typeLit: bool -> type_literal -> string
    63   val gen_dfg_cls: int * string * kind * string list * string list * string list -> string
    64   val string_of_preds: (string * Int.int) list -> string
    65   val string_of_funcs: (string * int) list -> string
    66   val string_of_symbols: string -> string -> string
    67   val string_of_start: string -> string
    68   val string_of_descrip : string -> string
    69   val dfg_tfree_clause : string -> string
    70   val dfg_classrel_clause: classrel_clause -> string
    71   val dfg_arity_clause: arity_clause -> string
    72   val tptp_sign: bool -> string -> string
    73   val tptp_of_typeLit : bool -> type_literal -> string
    74   val gen_tptp_cls : int * string * kind * string list * string list -> string
    75   val tptp_tfree_clause : string -> string
    76   val tptp_arity_clause : arity_clause -> string
    77   val tptp_classrel_clause : classrel_clause -> string
    78 end
    79 
    80 structure Sledgehammer_FOL_Clause : SLEDGEHAMMER_FOL_CLAUSE =
    81 struct
    82 
    83 val schematic_var_prefix = "V_";
    84 val fixed_var_prefix = "v_";
    85 
    86 val tvar_prefix = "T_";
    87 val tfree_prefix = "t_";
    88 
    89 val clause_prefix = "cls_";
    90 val arclause_prefix = "clsarity_"
    91 val clrelclause_prefix = "clsrel_";
    92 
    93 val const_prefix = "c_";
    94 val tconst_prefix = "tc_";
    95 val class_prefix = "class_";
    96 
    97 fun union_all xss = List.foldl (uncurry (union (op =))) [] xss;
    98 
    99 (* Provide readable names for the more common symbolic functions *)
   100 val const_trans_table =
   101   Symtab.make [(@{const_name "op ="}, "equal"),
   102                (@{const_name Orderings.less_eq}, "lessequals"),
   103                (@{const_name "op &"}, "and"),
   104                (@{const_name "op |"}, "or"),
   105                (@{const_name "op -->"}, "implies"),
   106                (@{const_name "op :"}, "in"),
   107                (@{const_name fequal}, "fequal"),
   108                (@{const_name COMBI}, "COMBI"),
   109                (@{const_name COMBK}, "COMBK"),
   110                (@{const_name COMBB}, "COMBB"),
   111                (@{const_name COMBC}, "COMBC"),
   112                (@{const_name COMBS}, "COMBS")];
   113 
   114 val type_const_trans_table =
   115   Symtab.make [("*", "prod"), ("+", "sum"), ("~=>", "map")];
   116 
   117 (*Escaping of special characters.
   118   Alphanumeric characters are left unchanged.
   119   The character _ goes to __
   120   Characters in the range ASCII space to / go to _A to _P, respectively.
   121   Other printing characters go to _nnn where nnn is the decimal ASCII code.*)
   122 val A_minus_space = Char.ord #"A" - Char.ord #" ";
   123 
   124 fun stringN_of_int 0 _ = ""
   125   | stringN_of_int k n = stringN_of_int (k-1) (n div 10) ^ Int.toString (n mod 10);
   126 
   127 fun ascii_of_c c =
   128   if Char.isAlphaNum c then String.str c
   129   else if c = #"_" then "__"
   130   else if #" " <= c andalso c <= #"/"
   131        then "_" ^ String.str (Char.chr (Char.ord c + A_minus_space))
   132   else if Char.isPrint c
   133        then ("_" ^ stringN_of_int 3 (Char.ord c))  (*fixed width, in case more digits follow*)
   134   else ""
   135 
   136 val ascii_of = String.translate ascii_of_c;
   137 
   138 (** Remove ASCII armouring from names in proof files **)
   139 
   140 (*We don't raise error exceptions because this code can run inside the watcher.
   141   Also, the errors are "impossible" (hah!)*)
   142 fun undo_ascii_aux rcs [] = String.implode(rev rcs)
   143   | undo_ascii_aux rcs [#"_"] = undo_ascii_aux (#"_"::rcs) []  (*ERROR*)
   144       (*Three types of _ escapes: __, _A to _P, _nnn*)
   145   | undo_ascii_aux rcs (#"_" :: #"_" :: cs) = undo_ascii_aux (#"_"::rcs) cs
   146   | undo_ascii_aux rcs (#"_" :: c :: cs) =
   147       if #"A" <= c andalso c<= #"P"  (*translation of #" " to #"/"*)
   148       then undo_ascii_aux (Char.chr(Char.ord c - A_minus_space) :: rcs) cs
   149       else
   150         let val digits = List.take (c::cs, 3) handle Subscript => []
   151         in
   152             case Int.fromString (String.implode digits) of
   153                 NONE => undo_ascii_aux (c:: #"_"::rcs) cs  (*ERROR*)
   154               | SOME n => undo_ascii_aux (Char.chr n :: rcs) (List.drop (cs, 2))
   155         end
   156   | undo_ascii_aux rcs (c::cs) = undo_ascii_aux (c::rcs) cs;
   157 
   158 val undo_ascii_of = undo_ascii_aux [] o String.explode;
   159 
   160 (* convert a list of strings into one single string; surrounded by brackets *)
   161 fun paren_pack [] = ""   (*empty argument list*)
   162   | paren_pack strings = "(" ^ commas strings ^ ")";
   163 
   164 (*TSTP format uses (...) rather than the old [...]*)
   165 fun tptp_pack strings = "(" ^ space_implode " | " strings ^ ")";
   166 
   167 
   168 (*Remove the initial ' character from a type variable, if it is present*)
   169 fun trim_type_var s =
   170   if s <> "" andalso String.sub(s,0) = #"'" then String.extract(s,1,NONE)
   171   else error ("trim_type: Malformed type variable encountered: " ^ s);
   172 
   173 fun ascii_of_indexname (v,0) = ascii_of v
   174   | ascii_of_indexname (v,i) = ascii_of v ^ "_" ^ Int.toString i;
   175 
   176 fun make_schematic_var v = schematic_var_prefix ^ (ascii_of_indexname v);
   177 fun make_fixed_var x = fixed_var_prefix ^ (ascii_of x);
   178 
   179 fun make_schematic_type_var (x,i) =
   180       tvar_prefix ^ (ascii_of_indexname (trim_type_var x,i));
   181 fun make_fixed_type_var x = tfree_prefix ^ (ascii_of (trim_type_var x));
   182 
   183 (*HACK because SPASS truncates identifiers to 63 characters :-(( *)
   184 (*32-bit hash,so we expect no collisions unless there are around 65536 long identifiers...*)
   185 fun controlled_length dfg_format s =
   186   if size s > 60 andalso dfg_format
   187   then Word.toString (Polyhash.hashw_string(s,0w0))
   188   else s;
   189 
   190 fun lookup_const dfg c =
   191     case Symtab.lookup const_trans_table c of
   192         SOME c' => c'
   193       | NONE => controlled_length dfg (ascii_of c);
   194 
   195 fun lookup_type_const dfg c =
   196     case Symtab.lookup type_const_trans_table c of
   197         SOME c' => c'
   198       | NONE => controlled_length dfg (ascii_of c);
   199 
   200 fun make_fixed_const _ "op =" = "equal"   (*MUST BE "equal" because it's built-in to ATPs*)
   201   | make_fixed_const dfg c      = const_prefix ^ lookup_const dfg c;
   202 
   203 fun make_fixed_type_const dfg c = tconst_prefix ^ lookup_type_const dfg c;
   204 
   205 fun make_type_class clas = class_prefix ^ ascii_of clas;
   206 
   207 
   208 (***** definitions and functions for FOL clauses, for conversion to TPTP or DFG format. *****)
   209 
   210 datatype kind = Axiom | Conjecture;
   211 
   212 type axiom_name = string;
   213 
   214 (**** Isabelle FOL clauses ****)
   215 
   216 (*FIXME: give the constructors more sensible names*)
   217 datatype fol_type = AtomV of string
   218                   | AtomF of string
   219                   | Comp of string * fol_type list;
   220 
   221 fun string_of_fol_type (AtomV x) = x
   222   | string_of_fol_type (AtomF x) = x
   223   | string_of_fol_type (Comp(tcon,tps)) =
   224       tcon ^ (paren_pack (map string_of_fol_type tps));
   225 
   226 (*First string is the type class; the second is a TVar or TFfree*)
   227 datatype type_literal = LTVar of string * string | LTFree of string * string;
   228 
   229 exception CLAUSE of string * term;
   230 
   231 fun atomic_type (TFree (a,_)) = AtomF(make_fixed_type_var a)
   232   | atomic_type (TVar (v,_))  = AtomV(make_schematic_type_var v);
   233 
   234 (*Flatten a type to a fol_type while accumulating sort constraints on the TFrees and
   235   TVars it contains.*)
   236 fun type_of dfg (Type (a, Ts)) =
   237       let val (folTyps, ts) = types_of dfg Ts
   238           val t = make_fixed_type_const dfg a
   239       in (Comp(t,folTyps), ts) end
   240   | type_of dfg T = (atomic_type T, [T])
   241 and types_of dfg Ts =
   242       let val (folTyps,ts) = ListPair.unzip (map (type_of dfg) Ts)
   243       in (folTyps, union_all ts) end;
   244 
   245 (*Make literals for sorted type variables*)
   246 fun sorts_on_typs_aux (_, [])   = []
   247   | sorts_on_typs_aux ((x,i),  s::ss) =
   248       let val sorts = sorts_on_typs_aux ((x,i), ss)
   249       in
   250           if s = "HOL.type" then sorts
   251           else if i = ~1 then LTFree(make_type_class s, make_fixed_type_var x) :: sorts
   252           else LTVar(make_type_class s, make_schematic_type_var (x,i)) :: sorts
   253       end;
   254 
   255 fun sorts_on_typs (TFree (a,s)) = sorts_on_typs_aux ((a,~1),s)
   256   | sorts_on_typs (TVar (v,s))  = sorts_on_typs_aux (v,s);
   257 
   258 fun pred_of_sort (LTVar (s,ty)) = (s,1)
   259   | pred_of_sort (LTFree (s,ty)) = (s,1)
   260 
   261 (*Given a list of sorted type variables, return a list of type literals.*)
   262 fun add_typs Ts = List.foldl (uncurry (union (op =))) [] (map sorts_on_typs Ts);
   263 
   264 (*The correct treatment of TFrees like 'a in lemmas (axiom clauses) is not clear.
   265   * Ignoring them leads to unsound proofs, since we do nothing to ensure that 'a
   266     in a lemma has the same sort as 'a in the conjecture.
   267   * Deleting such clauses will lead to problems with locales in other use of local results
   268     where 'a is fixed. Probably we should delete clauses unless the sorts agree.
   269   * Currently we include a class constraint in the clause, exactly as with TVars.
   270 *)
   271 
   272 (** make axiom and conjecture clauses. **)
   273 
   274 fun get_tvar_strs [] = []
   275   | get_tvar_strs ((TVar (indx,s))::Ts) =
   276       insert (op =) (make_schematic_type_var indx) (get_tvar_strs Ts)
   277   | get_tvar_strs((TFree _)::Ts) = get_tvar_strs Ts
   278 
   279 
   280 
   281 (**** Isabelle arities ****)
   282 
   283 exception ARCLAUSE of string;
   284 
   285 datatype arLit = TConsLit of class * string * string list
   286                | TVarLit of class * string;
   287 
   288 datatype arity_clause =
   289          ArityClause of {axiom_name: axiom_name,
   290                          conclLit: arLit,
   291                          premLits: arLit list};
   292 
   293 
   294 fun gen_TVars 0 = []
   295   | gen_TVars n = ("T_" ^ Int.toString n) :: gen_TVars (n-1);
   296 
   297 fun pack_sort(_,[])  = []
   298   | pack_sort(tvar, "HOL.type"::srt) = pack_sort(tvar, srt)   (*IGNORE sort "type"*)
   299   | pack_sort(tvar, cls::srt) =  (cls, tvar) :: pack_sort(tvar, srt);
   300 
   301 (*Arity of type constructor tcon :: (arg1,...,argN)res*)
   302 fun make_axiom_arity_clause dfg (tcons, axiom_name, (cls,args)) =
   303    let val tvars = gen_TVars (length args)
   304        val tvars_srts = ListPair.zip (tvars,args)
   305    in
   306       ArityClause {axiom_name = axiom_name, 
   307                    conclLit = TConsLit (cls, make_fixed_type_const dfg tcons, tvars),
   308                    premLits = map TVarLit (union_all(map pack_sort tvars_srts))}
   309    end;
   310 
   311 
   312 (**** Isabelle class relations ****)
   313 
   314 datatype classrel_clause =
   315          ClassrelClause of {axiom_name: axiom_name,
   316                             subclass: class,
   317                             superclass: class};
   318 
   319 (*Generate all pairs (sub,super) such that sub is a proper subclass of super in theory thy.*)
   320 fun class_pairs thy [] supers = []
   321   | class_pairs thy subs supers =
   322       let val class_less = Sorts.class_less(Sign.classes_of thy)
   323           fun add_super sub (super,pairs) =
   324                 if class_less (sub,super) then (sub,super)::pairs else pairs
   325           fun add_supers (sub,pairs) = List.foldl (add_super sub) pairs supers
   326       in  List.foldl add_supers [] subs  end;
   327 
   328 fun make_classrel_clause (sub,super) =
   329   ClassrelClause {axiom_name = clrelclause_prefix ^ ascii_of sub ^ "_" ^ ascii_of super,
   330                   subclass = make_type_class sub,
   331                   superclass = make_type_class super};
   332 
   333 fun make_classrel_clauses thy subs supers =
   334   map make_classrel_clause (class_pairs thy subs supers);
   335 
   336 
   337 (** Isabelle arities **)
   338 
   339 fun arity_clause dfg _ _ (tcons, []) = []
   340   | arity_clause dfg seen n (tcons, ("HOL.type",_)::ars) =  (*ignore*)
   341       arity_clause dfg seen n (tcons,ars)
   342   | arity_clause dfg seen n (tcons, (ar as (class,_)) :: ars) =
   343       if class mem_string seen then (*multiple arities for the same tycon, class pair*)
   344           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class ^ "_" ^ Int.toString n, ar) ::
   345           arity_clause dfg seen (n+1) (tcons,ars)
   346       else
   347           make_axiom_arity_clause dfg (tcons, lookup_type_const dfg tcons ^ "_" ^ class, ar) ::
   348           arity_clause dfg (class::seen) n (tcons,ars)
   349 
   350 fun multi_arity_clause dfg [] = []
   351   | multi_arity_clause dfg ((tcons,ars) :: tc_arlists) =
   352       arity_clause dfg [] 1 (tcons, ars)  @  multi_arity_clause dfg tc_arlists
   353 
   354 (*Generate all pairs (tycon,class,sorts) such that tycon belongs to class in theory thy
   355   provided its arguments have the corresponding sorts.*)
   356 fun type_class_pairs thy tycons classes =
   357   let val alg = Sign.classes_of thy
   358       fun domain_sorts (tycon,class) = Sorts.mg_domain alg tycon [class]
   359       fun add_class tycon (class,pairs) =
   360             (class, domain_sorts(tycon,class))::pairs
   361             handle Sorts.CLASS_ERROR _ => pairs
   362       fun try_classes tycon = (tycon, List.foldl (add_class tycon) [] classes)
   363   in  map try_classes tycons  end;
   364 
   365 (*Proving one (tycon, class) membership may require proving others, so iterate.*)
   366 fun iter_type_class_pairs thy tycons [] = ([], [])
   367   | iter_type_class_pairs thy tycons classes =
   368       let val cpairs = type_class_pairs thy tycons classes
   369           val newclasses = union_all (union_all (union_all (map (map #2 o #2) cpairs)))
   370             |> subtract (op =) classes |> subtract (op =) HOLogic.typeS
   371           val (classes', cpairs') = iter_type_class_pairs thy tycons newclasses
   372       in (union (op =) classes' classes, union (op =) cpairs' cpairs) end;
   373 
   374 fun make_arity_clauses_dfg dfg thy tycons classes =
   375   let val (classes', cpairs) = iter_type_class_pairs thy tycons classes
   376   in  (classes', multi_arity_clause dfg cpairs)  end;
   377 val make_arity_clauses = make_arity_clauses_dfg false;
   378 
   379 (**** Find occurrences of predicates in clauses ****)
   380 
   381 (*FIXME: multiple-arity checking doesn't work, as update_new is the wrong
   382   function (it flags repeated declarations of a function, even with the same arity)*)
   383 
   384 fun update_many (tab, keypairs) = List.foldl (uncurry Symtab.update) tab keypairs;
   385 
   386 fun add_type_sort_preds (T, preds) =
   387       update_many (preds, map pred_of_sort (sorts_on_typs T));
   388 
   389 fun add_classrel_clause_preds (ClassrelClause {subclass,superclass,...}, preds) =
   390   Symtab.update (subclass,1) (Symtab.update (superclass,1) preds);
   391 
   392 fun class_of_arityLit (TConsLit (tclass, _, _)) = tclass
   393   | class_of_arityLit (TVarLit (tclass, _)) = tclass;
   394 
   395 fun add_arity_clause_preds (ArityClause {conclLit,premLits,...}, preds) =
   396   let val classes = map (make_type_class o class_of_arityLit) (conclLit::premLits)
   397       fun upd (class,preds) = Symtab.update (class,1) preds
   398   in  List.foldl upd preds classes  end;
   399 
   400 (*** Find occurrences of functions in clauses ***)
   401 
   402 fun add_foltype_funcs (AtomV _, funcs) = funcs
   403   | add_foltype_funcs (AtomF a, funcs) = Symtab.update (a,0) funcs
   404   | add_foltype_funcs (Comp(a,tys), funcs) =
   405       List.foldl add_foltype_funcs (Symtab.update (a, length tys) funcs) tys;
   406 
   407 (*TFrees are recorded as constants*)
   408 fun add_type_sort_funcs (TVar _, funcs) = funcs
   409   | add_type_sort_funcs (TFree (a, _), funcs) =
   410       Symtab.update (make_fixed_type_var a, 0) funcs
   411 
   412 fun add_arity_clause_funcs (ArityClause {conclLit,...}, funcs) =
   413   let val TConsLit (_, tcons, tvars) = conclLit
   414   in  Symtab.update (tcons, length tvars) funcs  end;
   415 
   416 (*This type can be overlooked because it is built-in...*)
   417 val init_functab = Symtab.update ("tc_itself", 1) Symtab.empty;
   418 
   419 
   420 (**** String-oriented operations ****)
   421 
   422 fun string_of_clausename (cls_id,ax_name) =
   423     clause_prefix ^ ascii_of ax_name ^ "_" ^ Int.toString cls_id;
   424 
   425 fun string_of_type_clsname (cls_id,ax_name,idx) =
   426     string_of_clausename (cls_id,ax_name) ^ "_tcs" ^ (Int.toString idx);
   427 
   428 
   429 (**** Producing DFG files ****)
   430 
   431 (*Attach sign in DFG syntax: false means negate.*)
   432 fun dfg_sign true s = s
   433   | dfg_sign false s = "not(" ^ s ^ ")"
   434 
   435 fun dfg_of_typeLit pos (LTVar (s,ty))  = dfg_sign pos (s ^ "(" ^ ty ^ ")")
   436   | dfg_of_typeLit pos (LTFree (s,ty)) = dfg_sign pos (s ^ "(" ^ ty ^ ")");
   437 
   438 (*Enclose the clause body by quantifiers, if necessary*)
   439 fun dfg_forall [] body = body
   440   | dfg_forall vars body = "forall([" ^ commas vars ^ "],\n" ^ body ^ ")"
   441 
   442 fun gen_dfg_cls (cls_id, ax_name, Axiom, lits, tylits, vars) =
   443       "clause( %(axiom)\n" ^
   444       dfg_forall vars ("or(" ^ commas (tylits@lits) ^ ")") ^ ",\n" ^
   445       string_of_clausename (cls_id,ax_name) ^  ").\n\n"
   446   | gen_dfg_cls (cls_id, ax_name, Conjecture, lits, _, vars) =
   447       "clause( %(negated_conjecture)\n" ^
   448       dfg_forall vars ("or(" ^ commas lits ^ ")") ^ ",\n" ^
   449       string_of_clausename (cls_id,ax_name) ^  ").\n\n";
   450 
   451 fun string_of_arity (name, num) =  "(" ^ name ^ "," ^ Int.toString num ^ ")"
   452 
   453 fun string_of_preds [] = ""
   454   | string_of_preds preds = "predicates[" ^ commas(map string_of_arity preds) ^ "].\n";
   455 
   456 fun string_of_funcs [] = ""
   457   | string_of_funcs funcs = "functions[" ^ commas(map string_of_arity funcs) ^ "].\n" ;
   458 
   459 fun string_of_symbols predstr funcstr =
   460   "list_of_symbols.\n" ^ predstr  ^ funcstr  ^ "end_of_list.\n\n";
   461 
   462 fun string_of_start name = "begin_problem(" ^ name ^ ").\n\n";
   463 
   464 fun string_of_descrip name =
   465   "list_of_descriptions.\nname({*" ^ name ^
   466   "*}).\nauthor({*Isabelle*}).\nstatus(unknown).\ndescription({*auto-generated*}).\nend_of_list.\n\n"
   467 
   468 fun dfg_tfree_clause tfree_lit =
   469   "clause( %(negated_conjecture)\n" ^ "or( " ^ tfree_lit ^ "),\n" ^ "tfree_tcs" ^ ").\n\n"
   470 
   471 fun dfg_of_arLit (TConsLit (c,t,args)) =
   472       dfg_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   473   | dfg_of_arLit (TVarLit (c,str)) =
   474       dfg_sign false (make_type_class c ^ "(" ^ str ^ ")")
   475 
   476 fun dfg_classrelLits sub sup =  "not(" ^ sub ^ "(T)), " ^ sup ^ "(T)";
   477 
   478 fun dfg_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   479   "clause(forall([T],\nor( " ^ dfg_classrelLits subclass superclass ^ ")),\n" ^
   480   axiom_name ^ ").\n\n";
   481 
   482 fun string_of_ar axiom_name = arclause_prefix ^ ascii_of axiom_name;
   483 
   484 fun dfg_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   485   let val TConsLit (_,_,tvars) = conclLit
   486       val lits = map dfg_of_arLit (conclLit :: premLits)
   487   in
   488       "clause( %(axiom)\n" ^
   489       dfg_forall tvars ("or( " ^ commas lits ^ ")") ^ ",\n" ^
   490       string_of_ar axiom_name ^ ").\n\n"
   491   end;
   492 
   493 
   494 (**** Produce TPTP files ****)
   495 
   496 (*Attach sign in TPTP syntax: false means negate.*)
   497 fun tptp_sign true s = s
   498   | tptp_sign false s = "~ " ^ s
   499 
   500 fun tptp_of_typeLit pos (LTVar (s,ty))  = tptp_sign pos (s ^ "(" ^ ty ^ ")")
   501   | tptp_of_typeLit pos (LTFree (s,ty)) = tptp_sign pos  (s ^ "(" ^ ty ^ ")");
   502 
   503 fun gen_tptp_cls (cls_id,ax_name,Axiom,lits,tylits) =
   504       "cnf(" ^ string_of_clausename (cls_id,ax_name) ^ ",axiom," ^ 
   505                tptp_pack (tylits@lits) ^ ").\n"
   506   | gen_tptp_cls (cls_id,ax_name,Conjecture,lits,_) =
   507       "cnf(" ^ string_of_clausename (cls_id,ax_name) ^ ",negated_conjecture," ^ 
   508                tptp_pack lits ^ ").\n";
   509 
   510 fun tptp_tfree_clause tfree_lit =
   511     "cnf(" ^ "tfree_tcs," ^ "negated_conjecture" ^ "," ^ tptp_pack[tfree_lit] ^ ").\n";
   512 
   513 fun tptp_of_arLit (TConsLit (c,t,args)) =
   514       tptp_sign true (make_type_class c ^ "(" ^ t ^ paren_pack args ^ ")")
   515   | tptp_of_arLit (TVarLit (c,str)) =
   516       tptp_sign false (make_type_class c ^ "(" ^ str ^ ")")
   517 
   518 fun tptp_arity_clause (ArityClause{axiom_name,conclLit,premLits,...}) =
   519   "cnf(" ^ string_of_ar axiom_name ^ ",axiom," ^
   520   tptp_pack (map tptp_of_arLit (conclLit :: premLits)) ^ ").\n";
   521 
   522 fun tptp_classrelLits sub sup =
   523   let val tvar = "(T)"
   524   in  tptp_pack [tptp_sign false (sub^tvar), tptp_sign true (sup^tvar)]  end;
   525 
   526 fun tptp_classrel_clause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   527   "cnf(" ^ axiom_name ^ ",axiom," ^ tptp_classrelLits subclass superclass ^ ").\n"
   528 
   529 end;