src/HOL/Auth/TLS.thy
author paulson
Wed Sep 24 12:27:53 1997 +0200 (1997-09-24)
changeset 3704 2f99d7a0dccc
parent 3687 fb7d096d7884
child 3710 ea830f6e3c2d
permissions -rw-r--r--
sessionK now indexed by nat instead of bool.
Weaker Oops conditions on final guarantees
     1 (*  Title:      HOL/Auth/TLS
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1997  University of Cambridge
     5 
     6 Inductive relation "tls" for the baby TLS (Transport Layer Security) protocol.
     7 This protocol is essentially the same as SSL 3.0.
     8 
     9 Abstracted from "The TLS Protocol, Version 1.0" by Tim Dierks and Christopher
    10 Allen, Transport Layer Security Working Group, 21 May 1997,
    11 INTERNET-DRAFT draft-ietf-tls-protocol-03.txt.  Section numbers below refer
    12 to that memo.
    13 
    14 An RSA cryptosystem is assumed, and X.509v3 certificates are abstracted down
    15 to the trivial form {A, publicKey(A)}privateKey(Server), where Server is a
    16 global signing authority.
    17 
    18 A is the client and B is the server, not to be confused with the constant
    19 Server, who is in charge of all public keys.
    20 
    21 The model assumes that no fraudulent certificates are present, but it does
    22 assume that some private keys are to the spy.
    23 
    24 REMARK.  The event "Notes A {|Agent B, Nonce PMS|}" appears in ClientCertKeyEx,
    25 CertVerify, ClientFinished to record that A knows M.  It is a note from A to
    26 herself.  Nobody else can see it.  In ClientCertKeyEx, the Spy can substitute
    27 his own certificate for A's, but he cannot replace A's note by one for himself.
    28 
    29 The Note event avoids a weakness in the public-key model.  Each
    30 agent's state is recorded as the trace of messages.  When the true client (A)
    31 invents PMS, he encrypts PMS with B's public key before sending it.  The model
    32 does not distinguish the original occurrence of such a message from a replay.
    33 In the shared-key model, the ability to encrypt implies the ability to
    34 decrypt, so the problem does not arise.
    35 
    36 Proofs would be simpler if ClientCertKeyEx included A's name within
    37 Crypt KB (Nonce PMS).  As things stand, there is much overlap between proofs
    38 about that message (which B receives) and the stronger event
    39 	Notes A {|Agent B, Nonce PMS|}.
    40 *)
    41 
    42 TLS = Public + 
    43 
    44 consts
    45   (*Pseudo-random function of Section 5*)
    46   PRF  :: "nat*nat*nat => nat"
    47 
    48   (*Client, server write keys are generated uniformly by function sessionK
    49     to avoid duplicating their properties.  They are indexed by a further
    50     natural number, not a bool, to avoid the peculiarities of if-and-only-if.
    51     Session keys implicitly include MAC secrets.*)
    52   sessionK :: "(nat*nat*nat)*nat => key"
    53 
    54   certificate      :: "[agent,key] => msg"
    55 
    56 defs
    57   certificate_def
    58     "certificate A KA == Crypt (priK Server) {|Agent A, Key KA|}"
    59 
    60 syntax
    61     clientK, serverK :: "nat*nat*nat => key"
    62 
    63 translations
    64   "clientK (x)"	== "sessionK(x,0)"
    65   "serverK (x)"	== "sessionK(x,1)"
    66 
    67 rules
    68   inj_PRF       "inj PRF"	
    69 
    70   (*sessionK is collision-free and makes symmetric keys.  Also, no clientK
    71     clashes with any serverK.*)
    72   inj_sessionK  "inj sessionK"	
    73 
    74   isSym_sessionK "isSymKey (sessionK x)"
    75 
    76   (*serverK is similar*)
    77   inj_serverK   "inj serverK"	
    78   isSym_serverK "isSymKey (serverK x)"
    79 
    80 
    81 consts    tls :: event list set
    82 inductive tls
    83   intrs 
    84     Nil  (*Initial trace is empty*)
    85          "[]: tls"
    86 
    87     Fake (*The spy, an active attacker, MAY say anything he CAN say.*)
    88          "[| evs: tls;  B ~= Spy;  
    89              X: synth (analz (spies evs)) |]
    90           ==> Says Spy B X # evs : tls"
    91 
    92     SpyKeys (*The spy may apply PRF & sessionK to available nonces*)
    93          "[| evsSK: tls;
    94 	     Says Spy B {|Nonce NA, Nonce NB, Nonce M|} : set evsSK |]
    95           ==> Says Spy B {| Nonce (PRF(M,NA,NB)),
    96 			    Key (sessionK((NA,NB,M),b)) |} # evsSK : tls"
    97 
    98     ClientHello
    99 	 (*(7.4.1.2)
   100 	   XA represents CLIENT_VERSION, CIPHER_SUITES and COMPRESSION_METHODS.
   101 	   It is uninterpreted but will be confirmed in the FINISHED messages.
   102 	   NA is CLIENT RANDOM, while SID is SESSION_ID.
   103            UNIX TIME is omitted because the protocol doesn't use it.
   104            May assume NA ~: range PRF because CLIENT RANDOM is 28 bytes
   105 	   while MASTER SECRET is 48 byptes*)
   106          "[| evsCH: tls;  A ~= B;  Nonce NA ~: used evsCH;  NA ~: range PRF |]
   107           ==> Says A B {|Agent A, Nonce NA, Number SID, Number XA|}
   108 	        # evsCH  :  tls"
   109 
   110     ServerHello
   111          (*7.4.1.3 of the TLS Internet-Draft
   112 	   XB represents CLIENT_VERSION, CIPHER_SUITE and COMPRESSION_METHOD.
   113            SERVER CERTIFICATE (7.4.2) is always present.
   114            CERTIFICATE_REQUEST (7.4.4) is implied.*)
   115          "[| evsSH: tls;  A ~= B;  Nonce NB ~: used evsSH;  NB ~: range PRF;
   116              Says A' B {|Agent A, Nonce NA, Number SID, Number XA|}
   117 	       : set evsSH |]
   118           ==> Says B A {|Nonce NB, Number SID, Number XB,
   119 			 certificate B (pubK B)|}
   120                 # evsSH  :  tls"
   121 
   122     ClientCertKeyEx
   123          (*CLIENT CERTIFICATE (7.4.6) and KEY EXCHANGE (7.4.7).
   124            The client, A, chooses PMS, the PREMASTER SECRET.
   125            She encrypts PMS using the supplied KB, which ought to be pubK B.
   126            We assume PMS ~: range PRF because a clash betweem the PMS
   127            and another MASTER SECRET is highly unlikely (even though
   128 	   both items have the same length, 48 bytes).
   129            The Note event records in the trace that she knows PMS
   130                (see REMARK at top). *)
   131          "[| evsCX: tls;  A ~= B;  Nonce PMS ~: used evsCX;  PMS ~: range PRF;
   132              Says B' A {|Nonce NB, Number SID, Number XB, certificate B KB|}
   133 	       : set evsCX |]
   134           ==> Says A B {|certificate A (pubK A), Crypt KB (Nonce PMS)|}
   135 	      # Notes A {|Agent B, Nonce PMS|}
   136 	      # evsCX  :  tls"
   137 
   138     CertVerify
   139 	(*The optional Certificate Verify (7.4.8) message contains the
   140           specific components listed in the security analysis, F.1.1.2.
   141           It adds the pre-master-secret, which is also essential!
   142           Checking the signature, which is the only use of A's certificate,
   143           assures B of A's presence*)
   144          "[| evsCV: tls;  A ~= B;  
   145              Says B' A {|Nonce NB, Number SID, Number XB, certificate B KB|}
   146 	       : set evsCV;
   147 	     Notes A {|Agent B, Nonce PMS|} : set evsCV |]
   148           ==> Says A B (Crypt (priK A)
   149 			(Hash{|Nonce NB, certificate B KB, Nonce PMS|}))
   150               # evsCV  :  tls"
   151 
   152 	(*Finally come the FINISHED messages (7.4.8), confirming XA and XB
   153           among other things.  The master-secret is PRF(PMS,NA,NB).
   154           Either party may sent its message first.*)
   155 
   156     ClientFinished
   157         (*The occurrence of Notes A {|Agent B, Nonce PMS|} stops the 
   158           rule's applying when the Spy has satisfied the "Says A B" by
   159           repaying messages sent by the true client; in that case, the
   160           Spy does not know PMS and could not sent ClientFinished.  One
   161           could simply put A~=Spy into the rule, but one should not
   162           expect the spy to be well-behaved.*)
   163          "[| evsCF: tls;  
   164 	     Says A  B {|Agent A, Nonce NA, Number SID, Number XA|}
   165 	       : set evsCF;
   166              Says B' A {|Nonce NB, Number SID, Number XB, certificate B KB|}
   167 	       : set evsCF;
   168              Notes A {|Agent B, Nonce PMS|} : set evsCF;
   169 	     M = PRF(PMS,NA,NB) |]
   170           ==> Says A B (Crypt (clientK(NA,NB,M))
   171 			(Hash{|Nonce M, Number SID,
   172 			       Nonce NA, Number XA, Agent A, 
   173 			       Nonce NB, Number XB, Agent B|}))
   174               # evsCF  :  tls"
   175 
   176     ServerFinished
   177 	(*Keeping A' and A'' distinct means B cannot even check that the
   178           two messages originate from the same source. *)
   179          "[| evsSF: tls;
   180 	     Says A' B  {|Agent A, Nonce NA, Number SID, Number XA|}
   181 	       : set evsSF;
   182 	     Says B  A  {|Nonce NB, Number SID, Number XB,
   183 		 	  certificate B (pubK B)|}
   184 	       : set evsSF;
   185 	     Says A'' B {|certificate A KA, Crypt (pubK B) (Nonce PMS)|}
   186 	       : set evsSF;
   187 	     M = PRF(PMS,NA,NB) |]
   188           ==> Says B A (Crypt (serverK(NA,NB,M))
   189 			(Hash{|Nonce M, Number SID,
   190 			       Nonce NA, Number XA, Agent A, 
   191 			       Nonce NB, Number XB, Agent B|}))
   192               # evsSF  :  tls"
   193 
   194     ClientAccepts
   195 	(*Having transmitted ClientFinished and received an identical
   196           message encrypted with serverK, the client stores the parameters
   197           needed to resume this session.  The "Notes A ..." premise is
   198           used to prove Notes_master_imp_Crypt_PMS.*)
   199          "[| evsCA: tls;
   200 	     Notes A {|Agent B, Nonce PMS|} : set evsCA;
   201 	     M = PRF(PMS,NA,NB);  
   202 	     X = Hash{|Nonce M, Number SID,
   203 	               Nonce NA, Number XA, Agent A, 
   204 		       Nonce NB, Number XB, Agent B|};
   205              Says A  B (Crypt (clientK(NA,NB,M)) X) : set evsCA;
   206              Says B' A (Crypt (serverK(NA,NB,M)) X) : set evsCA |]
   207           ==> 
   208              Notes A {|Number SID, Agent A, Agent B, Nonce M|} # evsCA  :  tls"
   209 
   210     ServerAccepts
   211 	(*Having transmitted ServerFinished and received an identical
   212           message encrypted with clientK, the server stores the parameters
   213           needed to resume this session.  The "Says A'' B ..." premise is
   214           used to prove Notes_master_imp_Crypt_PMS.*)
   215          "[| evsSA: tls;
   216              Says A'' B {|certificate A KA, Crypt (pubK B) (Nonce PMS)|}
   217 	       : set evsSA;
   218 	     M = PRF(PMS,NA,NB);  
   219 	     X = Hash{|Nonce M, Number SID,
   220 	               Nonce NA, Number XA, Agent A, 
   221 		       Nonce NB, Number XB, Agent B|};
   222              Says B  A (Crypt (serverK(NA,NB,M)) X) : set evsSA;
   223              Says A' B (Crypt (clientK(NA,NB,M)) X) : set evsSA |]
   224           ==> 
   225              Notes B {|Number SID, Agent A, Agent B, Nonce M|} # evsSA  :  tls"
   226 
   227     ServerResume
   228          (*Resumption is described in 7.3.  If B finds the SESSION_ID
   229            then he sends HELLO and FINISHED messages, using the
   230            previously stored MASTER SECRET*)
   231          "[| evsSR: tls;  A ~= B;  Nonce NB ~: used evsSR;  NB ~: range PRF;
   232              Notes B {|Number SID, Agent A, Agent B, Nonce M|} : set evsSR;
   233 	     Says A' B {|Agent A, Nonce NA, Number SID, Number XA|}
   234 	       : set evsSR |]
   235           ==> Says B A (Crypt (serverK(NA,NB,M))
   236 			(Hash{|Nonce M, Number SID,
   237 			       Nonce NA, Number XA, Agent A, 
   238 			       Nonce NB, Number XB, Agent B|}))
   239               # Says B A {|Nonce NB, Number SID, Number XB|} # evsSR  :  tls"
   240 
   241     ClientResume
   242          (*If the response to ClientHello is ServerResume then send
   243            a FINISHED message using the new nonces and stored MASTER SECRET.*)
   244          "[| evsCR: tls;  
   245 	     Says A  B {|Agent A, Nonce NA, Number SID, Number XA|}
   246 	       : set evsCR;
   247              Says B' A {|Nonce NB, Number SID, Number XB|} : set evsCR;
   248              Notes A {|Number SID, Agent A, Agent B, Nonce M|} : set evsCR |]
   249           ==> Says A B (Crypt (clientK(NA,NB,M))
   250 			(Hash{|Nonce M, Number SID,
   251 			       Nonce NA, Number XA, Agent A, 
   252 			       Nonce NB, Number XB, Agent B|}))
   253               # evsCR  :  tls"
   254 
   255     Oops 
   256          (*The most plausible compromise is of an old session key.  Losing
   257            the MASTER SECRET or PREMASTER SECRET is more serious but
   258            rather unlikely.*)
   259          "[| evso: tls;  A ~= Spy;  
   260 	     Says A B (Crypt (sessionK((NA,NB,M),b)) X) : set evso |]
   261           ==> Says A Spy (Key (sessionK((NA,NB,M),b))) # evso  :  tls"
   262 
   263 end