src/Tools/quickcheck.ML
author haftmann
Fri Apr 24 17:45:17 2009 +0200 (2009-04-24)
changeset 30973 304ab57afa6e
parent 30824 bc6b24882834
child 30980 fe0855471964
permissions -rw-r--r--
observe distinction between Pure/Tools and Tools more closely
     1 (*  Title:      Tools/quickcheck.ML
     2     Author:     Stefan Berghofer, Florian Haftmann, TU Muenchen
     3 
     4 Generic counterexample search engine.
     5 *)
     6 
     7 signature QUICKCHECK =
     8 sig
     9   val test_term: Proof.context -> bool -> string option -> int -> int -> term -> (string * term) list option;
    10   val add_generator: string * (Proof.context -> term -> int -> term list option) -> theory -> theory
    11   val auto: bool ref
    12   val auto_time_limit: int ref
    13 end;
    14 
    15 structure Quickcheck : QUICKCHECK =
    16 struct
    17 
    18 open Quickcheck; (*c.f. Pure/Tools/ROOT.ML*)
    19 
    20 (* quickcheck configuration -- default parameters, test generators *)
    21 
    22 datatype test_params = Test_Params of
    23   { size: int, iterations: int, default_type: typ option };
    24 
    25 fun dest_test_params (Test_Params { size, iterations, default_type }) =
    26   ((size, iterations), default_type);
    27 fun mk_test_params ((size, iterations), default_type) =
    28   Test_Params { size = size, iterations = iterations, default_type = default_type };
    29 fun map_test_params f (Test_Params { size, iterations, default_type}) =
    30   mk_test_params (f ((size, iterations), default_type));
    31 fun merge_test_params (Test_Params { size = size1, iterations = iterations1, default_type = default_type1 },
    32   Test_Params { size = size2, iterations = iterations2, default_type = default_type2 }) =
    33   mk_test_params ((Int.max (size1, size2), Int.max (iterations1, iterations2)),
    34     case default_type1 of NONE => default_type2 | _ => default_type1);
    35 
    36 structure Data = TheoryDataFun(
    37   type T = (string * (Proof.context -> term -> int -> term list option)) list
    38     * test_params;
    39   val empty = ([], Test_Params { size = 10, iterations = 100, default_type = NONE });
    40   val copy = I;
    41   val extend = I;
    42   fun merge pp ((generators1, params1), (generators2, params2)) =
    43     (AList.merge (op = : string * string -> bool) (K true) (generators1, generators2),
    44       merge_test_params (params1, params2));
    45 )
    46 
    47 val add_generator = Data.map o apfst o AList.update (op =);
    48 
    49 
    50 (* generating tests *)
    51 
    52 fun mk_tester_select name ctxt =
    53   case AList.lookup (op =) ((fst o Data.get o ProofContext.theory_of) ctxt) name
    54    of NONE => error ("No such quickcheck generator: " ^ name)
    55     | SOME generator => generator ctxt;
    56 
    57 fun mk_testers ctxt t =
    58   (map snd o fst o Data.get o ProofContext.theory_of) ctxt
    59   |> map_filter (fn generator => try (generator ctxt) t);
    60 
    61 fun mk_testers_strict ctxt t =
    62   let
    63     val generators = ((map snd o fst o Data.get o ProofContext.theory_of) ctxt)
    64     val testers = map (fn generator => Exn.capture (generator ctxt) t) generators;
    65   in if forall (is_none o Exn.get_result) testers
    66     then [(Exn.release o snd o split_last) testers]
    67     else map_filter Exn.get_result testers
    68   end;
    69 
    70 
    71 (* testing propositions *)
    72 
    73 fun prep_test_term t =
    74   let
    75     val _ = (null (Term.add_tvars t []) andalso null (Term.add_tfrees t [])) orelse
    76       error "Term to be tested contains type variables";
    77     val _ = null (Term.add_vars t []) orelse
    78       error "Term to be tested contains schematic variables";
    79     val frees = map dest_Free (OldTerm.term_frees t);
    80   in (map fst frees, list_abs_free (frees, t)) end
    81 
    82 fun test_term ctxt quiet generator_name size i t =
    83   let
    84     val (names, t') = prep_test_term t;
    85     val testers = case generator_name
    86      of NONE => if quiet then mk_testers ctxt t' else mk_testers_strict ctxt t'
    87       | SOME name => [mk_tester_select name ctxt t'];
    88     fun iterate f 0 = NONE
    89       | iterate f k = case f () handle Match => (if quiet then ()
    90              else warning "Exception Match raised during quickcheck"; NONE)
    91           of NONE => iterate f (k - 1) | SOME q => SOME q;
    92     fun with_testers k [] = NONE
    93       | with_testers k (tester :: testers) =
    94           case iterate (fn () => tester k) i
    95            of NONE => with_testers k testers
    96             | SOME q => SOME q;
    97     fun with_size k = if k > size then NONE
    98       else (if quiet then () else priority ("Test data size: " ^ string_of_int k);
    99         case with_testers k testers
   100          of NONE => with_size (k + 1) | SOME q => SOME q);
   101   in case with_size 1
   102    of NONE => NONE
   103     | SOME ts => SOME (names ~~ ts)
   104   end;
   105 
   106 fun monomorphic_term thy insts default_T = 
   107   let
   108     fun subst (T as TFree (v, S)) =
   109           let
   110             val T' = AList.lookup (op =) insts v
   111               |> the_default (the_default T default_T)
   112           in if Sign.of_sort thy (T, S) then T'
   113             else error ("Type " ^ Syntax.string_of_typ_global thy T ^
   114               " to be substituted for variable " ^
   115               Syntax.string_of_typ_global thy T ^ "\ndoes not have sort " ^
   116               Syntax.string_of_sort_global thy S)
   117           end
   118       | subst T = T;
   119   in (map_types o map_atyps) subst end;
   120 
   121 fun test_goal quiet generator_name size iterations default_T insts i assms state =
   122   let
   123     val ctxt = Proof.context_of state;
   124     val thy = Proof.theory_of state;
   125     fun strip (Const ("all", _) $ Abs (_, _, t)) = strip t
   126       | strip t = t;
   127     val (_, (_, st)) = Proof.get_goal state;
   128     val (gi, frees) = Logic.goal_params (prop_of st) i;
   129     val gi' = Logic.list_implies (assms, subst_bounds (frees, strip gi))
   130       |> monomorphic_term thy insts default_T
   131       |> ObjectLogic.atomize_term thy;
   132   in test_term ctxt quiet generator_name size iterations gi' end;
   133 
   134 fun pretty_counterex ctxt NONE = Pretty.str "No counterexamples found."
   135   | pretty_counterex ctxt (SOME cex) =
   136       Pretty.chunks (Pretty.str "Counterexample found:\n" ::
   137         map (fn (s, t) =>
   138           Pretty.block [Pretty.str (s ^ " ="), Pretty.brk 1, Syntax.pretty_term ctxt t]) cex);
   139 
   140 
   141 (* automatic testing *)
   142 
   143 fun test_goal_auto int state =
   144   let
   145     val ctxt = Proof.context_of state;
   146     val assms = map term_of (Assumption.all_assms_of ctxt);
   147     val Test_Params { size, iterations, default_type } =
   148       (snd o Data.get o Proof.theory_of) state;
   149     fun test () =
   150       let
   151         val res = TimeLimit.timeLimit (Time.fromMilliseconds (!auto_time_limit))
   152           (try (test_goal true NONE size iterations default_type [] 1 assms)) state;
   153       in
   154         case res of
   155           NONE => state
   156         | SOME NONE => state
   157         | SOME cex => Proof.goal_message (fn () => Pretty.chunks [Pretty.str "",
   158             Pretty.mark Markup.hilite (pretty_counterex ctxt cex)]) state
   159       end handle TimeLimit.TimeOut => (warning "Auto quickcheck: timeout."; state);
   160   in
   161     if int andalso !auto andalso not (!Toplevel.quiet)
   162     then test ()
   163     else state
   164   end;
   165 
   166 val _ = Context.>> (Specification.add_theorem_hook test_goal_auto);
   167 
   168 
   169 (* Isar interfaces *)
   170 
   171 fun read_nat s = case (Library.read_int o Symbol.explode) s
   172  of (k, []) => if k >= 0 then k
   173       else error ("Not a natural number: " ^ s)
   174   | (_, _ :: _) => error ("Not a natural number: " ^ s);
   175 
   176 fun parse_test_param ctxt ("size", arg) =
   177       (apfst o apfst o K) (read_nat arg)
   178   | parse_test_param ctxt ("iterations", arg) =
   179       (apfst o apsnd o K) (read_nat arg)
   180   | parse_test_param ctxt ("default_type", arg) =
   181       (apsnd o K o SOME) (ProofContext.read_typ ctxt arg)
   182   | parse_test_param ctxt (name, _) =
   183       error ("Bad test parameter: " ^ name);
   184 
   185 fun parse_test_param_inst ctxt ("generator", arg) =
   186       (apsnd o apfst o K o SOME) arg
   187   | parse_test_param_inst ctxt (name, arg) =
   188       case try (ProofContext.read_typ ctxt) name
   189        of SOME (TFree (v, _)) => (apsnd o apsnd o AList.update (op =))
   190               (v, ProofContext.read_typ ctxt arg)
   191         | _ => (apfst o parse_test_param ctxt) (name, arg);
   192 
   193 fun quickcheck_params_cmd args thy =
   194   let
   195     val ctxt = ProofContext.init thy;
   196     val f = fold (parse_test_param ctxt) args;
   197   in
   198     thy
   199     |> (Data.map o apsnd o map_test_params) f
   200   end;
   201 
   202 fun quickcheck_cmd args i state =
   203   let
   204     val prf = Toplevel.proof_of state;
   205     val thy = Toplevel.theory_of state;
   206     val ctxt = Toplevel.context_of state;
   207     val default_params = (dest_test_params o snd o Data.get) thy;
   208     val f = fold (parse_test_param_inst ctxt) args;
   209     val (((size, iterations), default_type), (generator_name, insts)) =
   210       f (default_params, (NONE, []));
   211     val counterex = test_goal false generator_name size iterations
   212       default_type insts i [] prf;
   213   in (Pretty.writeln o pretty_counterex ctxt) counterex end;
   214 
   215 local structure P = OuterParse and K = OuterKeyword in
   216 
   217 val parse_arg = P.name --| P.$$$ "=" -- P.name;
   218 val parse_args = P.$$$ "[" |-- P.list1 parse_arg --| P.$$$ "]"
   219   || Scan.succeed [];
   220 
   221 val _ = OuterSyntax.command "quickcheck_params" "set parameters for random testing" K.thy_decl
   222   (parse_args >> (fn args => Toplevel.theory (quickcheck_params_cmd args)));
   223 
   224 val _ = OuterSyntax.improper_command "quickcheck" "try to find counterexample for subgoal" K.diag
   225   (parse_args -- Scan.optional P.nat 1
   226     >> (fn (args, i) => Toplevel.no_timing o Toplevel.keep (quickcheck_cmd args i)));
   227 
   228 end; (*local*)
   229 
   230 end;
   231 
   232 
   233 val auto_quickcheck = Quickcheck.auto;
   234 val auto_quickcheck_time_limit = Quickcheck.auto_time_limit;