src/Pure/axclass.ML
author wenzelm
Fri Dec 29 17:24:41 2006 +0100 (2006-12-29)
changeset 21931 314f9e2a442c
parent 21925 5389dcd524e3
child 21953 ab834c5c3858
permissions -rw-r--r--
replaced Sign.classes by Sign.all_classes (topologically sorted);
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Type classes as parameter records and predicates, with explicit
     6 definitions and proofs.
     7 *)
     8 
     9 signature AX_CLASS =
    10 sig
    11   val get_definition: theory -> class -> {def: thm, intro: thm, axioms: thm list,
    12     params: (string * typ) list}
    13   val class_intros: theory -> thm list
    14   val class_of_param: theory -> string -> class option
    15   val params_of_class: theory -> class -> string * (string * typ) list
    16   val print_axclasses: theory -> unit
    17   val cert_classrel: theory -> class * class -> class * class
    18   val read_classrel: theory -> xstring * xstring -> class * class
    19   val add_classrel: thm -> theory -> theory
    20   val add_arity: thm -> theory -> theory
    21   val prove_classrel: class * class -> tactic -> theory -> theory
    22   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
    23   val define_class: bstring * xstring list -> string list ->
    24     ((bstring * Attrib.src list) * string list) list -> theory -> class * theory
    25   val define_class_i: bstring * class list -> string list ->
    26     ((bstring * attribute list) * term list) list -> theory -> class * theory
    27   val axiomatize_class: bstring * xstring list -> theory -> theory
    28   val axiomatize_class_i: bstring * class list -> theory -> theory
    29   val axiomatize_classrel: (xstring * xstring) list -> theory -> theory
    30   val axiomatize_classrel_i: (class * class) list -> theory -> theory
    31   val axiomatize_arity: xstring * string list * string -> theory -> theory
    32   val axiomatize_arity_i: arity -> theory -> theory
    33   type cache
    34   val cache: cache
    35   val of_sort: theory -> typ * sort -> cache -> thm list * cache  (*exception Sorts.CLASS_ERROR*)
    36 end;
    37 
    38 structure AxClass: AX_CLASS =
    39 struct
    40 
    41 (** theory data **)
    42 
    43 (* class parameters (canonical order) *)
    44 
    45 type param = string * class;
    46 
    47 fun add_param pp ((x, c): param) params =
    48   (case AList.lookup (op =) params x of
    49     NONE => (x, c) :: params
    50   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
    51       " for " ^ Pretty.string_of_sort pp [c] ^
    52       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
    53 
    54 fun merge_params _ ([], qs) = qs
    55   | merge_params pp (ps, qs) =
    56       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
    57 
    58 
    59 (* axclasses *)
    60 
    61 val introN = "intro";
    62 val superN = "super";
    63 val axiomsN = "axioms";
    64 
    65 val param_tyvarname = "'a";
    66 
    67 datatype axclass = AxClass of
    68  {def: thm,
    69   intro: thm,
    70   axioms: thm list,
    71   params: (string * typ) list};
    72 
    73 type axclasses = axclass Symtab.table * param list;
    74 
    75 fun make_axclass ((def, intro, axioms), params) =
    76   AxClass {def = def, intro = intro, axioms = axioms, params = params};
    77 
    78 fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
    79   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
    80 
    81 
    82 (* instances *)
    83 
    84 val classrel_prefix = "classrel_";
    85 val arity_prefix = "arity_";
    86 
    87 type instances =
    88   ((class * class) * thm) list *
    89   ((class * sort list) * thm) list Symtab.table;
    90 
    91 fun merge_instances ((classrel1, arities1): instances, (classrel2, arities2)) =
    92  (merge (eq_fst op =) (classrel1, classrel2),
    93   Symtab.join (K (merge (eq_fst op =))) (arities1, arities2));
    94 
    95 
    96 (* setup data *)
    97 
    98 structure AxClassData = TheoryDataFun
    99 (struct
   100   val name = "Pure/axclass";
   101   type T = axclasses * instances;
   102   val empty : T = ((Symtab.empty, []), ([], Symtab.empty));
   103   val copy = I;
   104   val extend = I;
   105   fun merge pp ((axclasses1, instances1), (axclasses2, instances2)) =
   106     (merge_axclasses pp (axclasses1, axclasses2), (merge_instances (instances1, instances2)));
   107   fun print _ _ = ();
   108 end);
   109 
   110 val _ = Context.add_setup AxClassData.init;
   111 
   112 
   113 (* maintain axclasses *)
   114 
   115 val get_axclasses = #1 o AxClassData.get;
   116 fun map_axclasses f = AxClassData.map (apfst f);
   117 
   118 val lookup_def = Symtab.lookup o #1 o get_axclasses;
   119 
   120 fun get_definition thy c =
   121   (case lookup_def thy c of
   122     SOME (AxClass info) => info
   123   | NONE => error ("No such axclass: " ^ quote c));
   124 
   125 fun class_intros thy =
   126   let
   127     fun add_intro c =
   128       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
   129     val classes = Sign.all_classes thy;
   130   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
   131 
   132 
   133 fun get_params thy pred =
   134   let val params = #2 (get_axclasses thy);
   135   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
   136 
   137 fun params_of thy c = get_params thy (fn c' => c' = c);
   138 fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
   139 
   140 fun class_of_param thy =
   141   AList.lookup (op =) (#2 (get_axclasses thy));
   142 
   143 fun params_of_class thy class =
   144   (param_tyvarname, (#params o get_definition thy) class);
   145 
   146 
   147 (* maintain instances *)
   148 
   149 val get_instances = #2 o AxClassData.get;
   150 fun map_instances f = AxClassData.map (apsnd f);
   151 
   152 
   153 fun the_classrel thy (c1, c2) =
   154   (case AList.lookup (op =) (#1 (get_instances thy)) (c1, c2) of
   155     SOME th => Thm.transfer thy th
   156   | NONE => error ("Unproven class relation " ^ Sign.string_of_classrel thy [c1, c2]));
   157 
   158 fun put_classrel arg = map_instances (fn (classrel, arities) =>
   159   (insert (eq_fst op =) arg classrel, arities));
   160 
   161 
   162 fun the_arity thy a (c, Ss) =
   163   (case AList.lookup (op =) (Symtab.lookup_list (#2 (get_instances thy)) a) (c, Ss)  of
   164     SOME th => Thm.transfer thy th
   165   | NONE => error ("Unproven type arity " ^ Sign.string_of_arity thy (a, Ss, [c])));
   166 
   167 fun put_arity ((t, Ss, c), th) = map_instances (fn (classrel, arities) =>
   168   (classrel, arities |> Symtab.insert_list (eq_fst op =) (t, ((c, Ss), th))));
   169 
   170 
   171 (* print data *)
   172 
   173 fun print_axclasses thy =
   174   let
   175     val axclasses = #1 (get_axclasses thy);
   176     val ctxt = ProofContext.init thy;
   177 
   178     fun pretty_axclass (class, AxClass {def, intro, axioms, params}) =
   179       Pretty.block (Pretty.fbreaks
   180        [Pretty.block
   181           [Pretty.str "class ", ProofContext.pretty_sort ctxt [class], Pretty.str ":"],
   182         Pretty.strs ("parameters:" :: params_of thy class),
   183         ProofContext.pretty_fact ctxt ("def", [def]),
   184         ProofContext.pretty_fact ctxt (introN, [intro]),
   185         ProofContext.pretty_fact ctxt (axiomsN, axioms)]);
   186   in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest axclasses))) end;
   187 
   188 
   189 
   190 (** instances **)
   191 
   192 (* class relations *)
   193 
   194 fun cert_classrel thy raw_rel =
   195   let
   196     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
   197     val _ = Type.add_classrel (Sign.pp thy) (c1, c2) (Sign.tsig_of thy);
   198     val _ =
   199       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
   200         [] => ()
   201       | xs => raise TYPE ("Class " ^ Sign.string_of_sort thy [c1] ^ " lacks parameter(s) " ^
   202           commas_quote xs ^ " of " ^ Sign.string_of_sort thy [c2], [], []));
   203   in (c1, c2) end;
   204 
   205 fun read_classrel thy raw_rel =
   206   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
   207     handle TYPE (msg, _, _) => error msg;
   208 
   209 
   210 (* primitive rules *)
   211 
   212 fun add_classrel th thy =
   213   let
   214     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
   215     val prop = Drule.plain_prop_of (Thm.transfer thy th);
   216     val rel = Logic.dest_classrel prop handle TERM _ => err ();
   217     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
   218   in
   219     thy
   220     |> Sign.primitive_classrel (c1, c2)
   221     |> put_classrel ((c1, c2), Drule.unconstrainTs th)
   222   end;
   223 
   224 fun add_arity th thy =
   225   let
   226     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
   227     val prop = Drule.plain_prop_of (Thm.transfer thy th);
   228     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
   229     val _ = if map (Sign.certify_sort thy) Ss = Ss then () else err ();
   230   in
   231     thy
   232     |> Sign.primitive_arity (t, Ss, [c])
   233     |> put_arity ((t, Ss, c), Drule.unconstrainTs th)
   234   end;
   235 
   236 
   237 (* tactical proofs *)
   238 
   239 fun prove_classrel raw_rel tac thy =
   240   let
   241     val (c1, c2) = cert_classrel thy raw_rel;
   242     val th = Goal.prove (ProofContext.init thy) [] []
   243         (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
   244       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
   245         quote (Sign.string_of_classrel thy [c1, c2]));
   246   in
   247     thy
   248     |> PureThy.add_thms [((prefix classrel_prefix (Logic.name_classrel (c1, c2)), th), [])]
   249     |-> (fn [th'] => add_classrel th')
   250   end;
   251 
   252 fun prove_arity raw_arity tac thy =
   253   let
   254     val arity = Sign.cert_arity thy raw_arity;
   255     val names = map (prefix arity_prefix) (Logic.name_arities arity);
   256     val props = Logic.mk_arities arity;
   257     val ths = Goal.prove_multi (ProofContext.init thy) [] [] props
   258       (fn _ => Goal.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
   259         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
   260           quote (Sign.string_of_arity thy arity));
   261   in
   262     thy
   263     |> PureThy.add_thms (map (rpair []) (names ~~ ths))
   264     |-> fold add_arity
   265   end;
   266 
   267 
   268 
   269 (** class definitions **)
   270 
   271 local
   272 
   273 fun read_param thy raw_t =
   274   let
   275     val t = Sign.read_term thy raw_t
   276   in case try dest_Const t
   277    of SOME (c, _) => c
   278     | NONE => error ("Not a constant: " ^ Sign.string_of_term thy t)
   279   end;
   280 
   281 fun def_class prep_class prep_att prep_param prep_propp
   282     (bclass, raw_super) raw_params raw_specs thy =
   283   let
   284     val ctxt = ProofContext.init thy;
   285     val pp = ProofContext.pp ctxt;
   286 
   287 
   288     (* prepare specification *)
   289 
   290     val bconst = Logic.const_of_class bclass;
   291     val class = Sign.full_name thy bclass;
   292     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
   293 
   294     fun prep_axiom t =
   295       (case Term.add_tfrees t [] of
   296         [(a, S)] =>
   297           if Sign.subsort thy (super, S) then t
   298           else error ("Sort constraint of type variable " ^
   299             setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
   300             " needs to be weaker than " ^ Pretty.string_of_sort pp super)
   301       | [] => t
   302       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t))
   303       |> map_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
   304       |> Logic.close_form;
   305 
   306     val axiomss = prep_propp (ctxt, map (map (rpair []) o snd) raw_specs)
   307       |> snd |> map (map (prep_axiom o fst));
   308     val name_atts = Attrib.map_specs (prep_att thy) raw_specs |> map fst;
   309 
   310 
   311     (* definition *)
   312 
   313     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
   314     val class_eq =
   315       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_list conjs);
   316 
   317     val ([def], def_thy) =
   318       thy
   319       |> Sign.primitive_class (bclass, super)
   320       |> PureThy.add_defs_i false [((Thm.def_name bconst, class_eq), [])];
   321     val (raw_intro, (raw_classrel, raw_axioms)) =
   322       (Conjunction.split_defined (length conjs) def) ||> chop (length super);
   323 
   324 
   325     (* facts *)
   326 
   327     val class_triv = Thm.class_triv def_thy class;
   328     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
   329       def_thy
   330       |> PureThy.note_thmss_qualified "" bconst
   331         [((introN, []), [([Drule.standard raw_intro], [])]),
   332          ((superN, []), [(map Drule.standard raw_classrel, [])]),
   333          ((axiomsN, []), [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])];
   334 
   335     (* params *)
   336 
   337     val params = map (prep_param thy) raw_params;
   338     val params_typs = map (fn param =>
   339       let
   340         val ty = Sign.the_const_type thy param;
   341         val _ = case Term.typ_tvars ty
   342          of [_] => ()
   343           | _ => error ("exactly one type variable required in parameter " ^ quote param);
   344         val ty' = Term.map_type_tvar (fn _ => TFree (param_tyvarname, [class])) ty;
   345       in (param, ty') end) params;
   346 
   347     (* result *)
   348 
   349     val axclass = make_axclass ((def, intro, axioms), params_typs);
   350     val result_thy =
   351       facts_thy
   352       |> fold put_classrel (map (pair class) super ~~ classrel)
   353       |> Sign.add_path bconst
   354       |> PureThy.note_thmss_i "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
   355       |> Sign.restore_naming facts_thy
   356       |> map_axclasses (fn (axclasses, parameters) =>
   357         (Symtab.update (class, axclass) axclasses,
   358           fold (fn x => add_param pp (x, class)) params parameters));
   359 
   360   in (class, result_thy) end;
   361 
   362 in
   363 
   364 val define_class = def_class Sign.read_class Attrib.attribute read_param ProofContext.read_propp;
   365 val define_class_i = def_class Sign.certify_class (K I) (K I) ProofContext.cert_propp;
   366 
   367 end;
   368 
   369 
   370 
   371 (** axiomatizations **)
   372 
   373 local
   374 
   375 fun axiomatize prep mk name add raw_args thy =
   376   let
   377     val args = prep thy raw_args;
   378     val specs = mk args;
   379     val names = name args;
   380   in thy |> PureThy.add_axioms_i (map (rpair []) (names ~~ specs)) |-> fold add end;
   381 
   382 fun ax_classrel prep =
   383   axiomatize (map o prep) (map Logic.mk_classrel)
   384     (map (prefix classrel_prefix o Logic.name_classrel)) add_classrel;
   385 
   386 fun ax_arity prep =
   387   axiomatize prep Logic.mk_arities
   388     (map (prefix arity_prefix) o Logic.name_arities) add_arity;
   389 
   390 fun class_const c =
   391   (Logic.const_of_class c, Term.itselfT (Term.aT []) --> propT);
   392 
   393 fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
   394   let
   395     val class = Sign.full_name thy bclass;
   396     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
   397   in
   398     thy
   399     |> Sign.primitive_class (bclass, super)
   400     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
   401     |> Theory.add_deps "" (class_const class) (map class_const super)
   402   end;
   403 
   404 in
   405 
   406 val axiomatize_class = ax_class Sign.read_class read_classrel;
   407 val axiomatize_class_i = ax_class Sign.certify_class cert_classrel;
   408 val axiomatize_classrel = ax_classrel read_classrel;
   409 val axiomatize_classrel_i = ax_classrel cert_classrel;
   410 val axiomatize_arity = ax_arity Sign.read_arity;
   411 val axiomatize_arity_i = ax_arity Sign.cert_arity;
   412 
   413 end;
   414 
   415 
   416 
   417 (** explicit derivations -- cached **)
   418 
   419 datatype cache = Types of (class * thm) list Typtab.table;
   420 val cache = Types Typtab.empty;
   421 
   422 local
   423 
   424 fun lookup_type (Types cache) = AList.lookup (op =) o Typtab.lookup_list cache;
   425 fun insert_type T der (Types cache) = Types (Typtab.insert_list (eq_fst op =) (T, der) cache);
   426 
   427 fun derive_type _ (_, []) = []
   428   | derive_type thy (typ, sort) =
   429       let
   430         val vars = Term.fold_atyps
   431             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
   432               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
   433               | _ => I) typ [];
   434         val hyps = vars
   435           |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
   436         val ths = (typ, sort) |> Sorts.of_sort_derivation (Sign.pp thy) (Sign.classes_of thy)
   437            {classrel =
   438               fn (th, c1) => fn c2 => th RS the_classrel thy (c1, c2),
   439             constructor =
   440               fn a => fn dom => fn c =>
   441                 let val Ss = map (map snd) dom and ths = maps (map fst) dom
   442                 in ths MRS the_arity thy a (c, Ss) end,
   443             variable =
   444               the_default [] o AList.lookup (op =) hyps};
   445       in ths end;
   446 
   447 in
   448 
   449 fun of_sort thy (typ, sort) cache =
   450   let
   451     val sort' = filter (is_none o lookup_type cache typ) sort;
   452     val ths' = derive_type thy (typ, sort')
   453       handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
   454         Sign.string_of_typ thy typ ^ " :: " ^ Sign.string_of_sort thy sort');
   455     val cache' = cache |> fold (insert_type typ) (sort' ~~ ths');
   456     val ths =
   457       sort |> map (fn c =>
   458         Goal.finish (the (lookup_type cache' typ c) RS
   459           Goal.init (Thm.cterm_of thy (Logic.mk_inclass (typ, c))))
   460         |> Thm.adjust_maxidx_thm ~1);
   461   in (ths, cache') end;
   462 
   463 end;
   464 
   465 end;