src/HOLCF/Cfun.thy
author huffman
Tue Jul 01 02:19:53 2008 +0200 (2008-07-01)
changeset 27413 3154f3765cc7
parent 27274 1c97c471db82
child 29049 4e5b9e508e1e
permissions -rw-r--r--
replace lub (range Y) with (LUB i. Y i)
     1 (*  Title:      HOLCF/Cfun.thy
     2     ID:         $Id$
     3     Author:     Franz Regensburger
     4 
     5 Definition of the type ->  of continuous functions.
     6 *)
     7 
     8 header {* The type of continuous functions *}
     9 
    10 theory Cfun
    11 imports Pcpodef Ffun
    12 uses ("Tools/cont_proc.ML")
    13 begin
    14 
    15 defaultsort cpo
    16 
    17 subsection {* Definition of continuous function type *}
    18 
    19 lemma Ex_cont: "\<exists>f. cont f"
    20 by (rule exI, rule cont_const)
    21 
    22 lemma adm_cont: "adm cont"
    23 by (rule admI, rule cont_lub_fun)
    24 
    25 cpodef (CFun)  ('a, 'b) "->" (infixr "->" 0) = "{f::'a => 'b. cont f}"
    26 by (simp add: Ex_cont adm_cont)
    27 
    28 syntax (xsymbols)
    29   "->"     :: "[type, type] => type"      ("(_ \<rightarrow>/ _)" [1,0]0)
    30 
    31 notation
    32   Rep_CFun  ("(_$/_)" [999,1000] 999)
    33 
    34 notation (xsymbols)
    35   Rep_CFun  ("(_\<cdot>/_)" [999,1000] 999)
    36 
    37 notation (HTML output)
    38   Rep_CFun  ("(_\<cdot>/_)" [999,1000] 999)
    39 
    40 subsection {* Syntax for continuous lambda abstraction *}
    41 
    42 syntax "_cabs" :: "'a"
    43 
    44 parse_translation {*
    45 (* rewrites (_cabs x t) => (Abs_CFun (%x. t)) *)
    46   [mk_binder_tr ("_cabs", @{const_syntax Abs_CFun})];
    47 *}
    48 
    49 text {* To avoid eta-contraction of body: *}
    50 typed_print_translation {*
    51   let
    52     fun cabs_tr' _ _ [Abs abs] = let
    53           val (x,t) = atomic_abs_tr' abs
    54         in Syntax.const "_cabs" $ x $ t end
    55 
    56       | cabs_tr' _ T [t] = let
    57           val xT = domain_type (domain_type T);
    58           val abs' = ("x",xT,(incr_boundvars 1 t)$Bound 0);
    59           val (x,t') = atomic_abs_tr' abs';
    60         in Syntax.const "_cabs" $ x $ t' end;
    61 
    62   in [(@{const_syntax Abs_CFun}, cabs_tr')] end;
    63 *}
    64 
    65 text {* Syntax for nested abstractions *}
    66 
    67 syntax
    68   "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic"  ("(3LAM _./ _)" [1000, 10] 10)
    69 
    70 syntax (xsymbols)
    71   "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic" ("(3\<Lambda> _./ _)" [1000, 10] 10)
    72 
    73 parse_ast_translation {*
    74 (* rewrites (LAM x y z. t) => (_cabs x (_cabs y (_cabs z t))) *)
    75 (* cf. Syntax.lambda_ast_tr from Syntax/syn_trans.ML *)
    76   let
    77     fun Lambda_ast_tr [pats, body] =
    78           Syntax.fold_ast_p "_cabs" (Syntax.unfold_ast "_cargs" pats, body)
    79       | Lambda_ast_tr asts = raise Syntax.AST ("Lambda_ast_tr", asts);
    80   in [("_Lambda", Lambda_ast_tr)] end;
    81 *}
    82 
    83 print_ast_translation {*
    84 (* rewrites (_cabs x (_cabs y (_cabs z t))) => (LAM x y z. t) *)
    85 (* cf. Syntax.abs_ast_tr' from Syntax/syn_trans.ML *)
    86   let
    87     fun cabs_ast_tr' asts =
    88       (case Syntax.unfold_ast_p "_cabs"
    89           (Syntax.Appl (Syntax.Constant "_cabs" :: asts)) of
    90         ([], _) => raise Syntax.AST ("cabs_ast_tr'", asts)
    91       | (xs, body) => Syntax.Appl
    92           [Syntax.Constant "_Lambda", Syntax.fold_ast "_cargs" xs, body]);
    93   in [("_cabs", cabs_ast_tr')] end;
    94 *}
    95 
    96 text {* Dummy patterns for continuous abstraction *}
    97 translations
    98   "\<Lambda> _. t" => "CONST Abs_CFun (\<lambda> _. t)"
    99 
   100 
   101 subsection {* Continuous function space is pointed *}
   102 
   103 lemma UU_CFun: "\<bottom> \<in> CFun"
   104 by (simp add: CFun_def inst_fun_pcpo cont_const)
   105 
   106 instance "->" :: (finite_po, finite_po) finite_po
   107 by (rule typedef_finite_po [OF type_definition_CFun])
   108 
   109 instance "->" :: (finite_po, chfin) chfin
   110 by (rule typedef_chfin [OF type_definition_CFun less_CFun_def])
   111 
   112 instance "->" :: (cpo, discrete_cpo) discrete_cpo
   113 by intro_classes (simp add: less_CFun_def Rep_CFun_inject)
   114 
   115 instance "->" :: (cpo, pcpo) pcpo
   116 by (rule typedef_pcpo [OF type_definition_CFun less_CFun_def UU_CFun])
   117 
   118 lemmas Rep_CFun_strict =
   119   typedef_Rep_strict [OF type_definition_CFun less_CFun_def UU_CFun]
   120 
   121 lemmas Abs_CFun_strict =
   122   typedef_Abs_strict [OF type_definition_CFun less_CFun_def UU_CFun]
   123 
   124 text {* function application is strict in its first argument *}
   125 
   126 lemma Rep_CFun_strict1 [simp]: "\<bottom>\<cdot>x = \<bottom>"
   127 by (simp add: Rep_CFun_strict)
   128 
   129 text {* for compatibility with old HOLCF-Version *}
   130 lemma inst_cfun_pcpo: "\<bottom> = (\<Lambda> x. \<bottom>)"
   131 by (simp add: inst_fun_pcpo [symmetric] Abs_CFun_strict)
   132 
   133 subsection {* Basic properties of continuous functions *}
   134 
   135 text {* Beta-equality for continuous functions *}
   136 
   137 lemma Abs_CFun_inverse2: "cont f \<Longrightarrow> Rep_CFun (Abs_CFun f) = f"
   138 by (simp add: Abs_CFun_inverse CFun_def)
   139 
   140 lemma beta_cfun [simp]: "cont f \<Longrightarrow> (\<Lambda> x. f x)\<cdot>u = f u"
   141 by (simp add: Abs_CFun_inverse2)
   142 
   143 text {* Eta-equality for continuous functions *}
   144 
   145 lemma eta_cfun: "(\<Lambda> x. f\<cdot>x) = f"
   146 by (rule Rep_CFun_inverse)
   147 
   148 text {* Extensionality for continuous functions *}
   149 
   150 lemma expand_cfun_eq: "(f = g) = (\<forall>x. f\<cdot>x = g\<cdot>x)"
   151 by (simp add: Rep_CFun_inject [symmetric] expand_fun_eq)
   152 
   153 lemma ext_cfun: "(\<And>x. f\<cdot>x = g\<cdot>x) \<Longrightarrow> f = g"
   154 by (simp add: expand_cfun_eq)
   155 
   156 text {* Extensionality wrt. ordering for continuous functions *}
   157 
   158 lemma expand_cfun_less: "f \<sqsubseteq> g = (\<forall>x. f\<cdot>x \<sqsubseteq> g\<cdot>x)" 
   159 by (simp add: less_CFun_def expand_fun_less)
   160 
   161 lemma less_cfun_ext: "(\<And>x. f\<cdot>x \<sqsubseteq> g\<cdot>x) \<Longrightarrow> f \<sqsubseteq> g"
   162 by (simp add: expand_cfun_less)
   163 
   164 text {* Congruence for continuous function application *}
   165 
   166 lemma cfun_cong: "\<lbrakk>f = g; x = y\<rbrakk> \<Longrightarrow> f\<cdot>x = g\<cdot>y"
   167 by simp
   168 
   169 lemma cfun_fun_cong: "f = g \<Longrightarrow> f\<cdot>x = g\<cdot>x"
   170 by simp
   171 
   172 lemma cfun_arg_cong: "x = y \<Longrightarrow> f\<cdot>x = f\<cdot>y"
   173 by simp
   174 
   175 subsection {* Continuity of application *}
   176 
   177 lemma cont_Rep_CFun1: "cont (\<lambda>f. f\<cdot>x)"
   178 by (rule cont_Rep_CFun [THEN cont2cont_fun])
   179 
   180 lemma cont_Rep_CFun2: "cont (\<lambda>x. f\<cdot>x)"
   181 apply (cut_tac x=f in Rep_CFun)
   182 apply (simp add: CFun_def)
   183 done
   184 
   185 lemmas monofun_Rep_CFun = cont_Rep_CFun [THEN cont2mono]
   186 lemmas contlub_Rep_CFun = cont_Rep_CFun [THEN cont2contlub]
   187 
   188 lemmas monofun_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2mono, standard]
   189 lemmas contlub_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2contlub, standard]
   190 lemmas monofun_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2mono, standard]
   191 lemmas contlub_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2contlub, standard]
   192 
   193 text {* contlub, cont properties of @{term Rep_CFun} in each argument *}
   194 
   195 lemma contlub_cfun_arg: "chain Y \<Longrightarrow> f\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. f\<cdot>(Y i))"
   196 by (rule contlub_Rep_CFun2 [THEN contlubE])
   197 
   198 lemma cont_cfun_arg: "chain Y \<Longrightarrow> range (\<lambda>i. f\<cdot>(Y i)) <<| f\<cdot>(\<Squnion>i. Y i)"
   199 by (rule cont_Rep_CFun2 [THEN contE])
   200 
   201 lemma contlub_cfun_fun: "chain F \<Longrightarrow> (\<Squnion>i. F i)\<cdot>x = (\<Squnion>i. F i\<cdot>x)"
   202 by (rule contlub_Rep_CFun1 [THEN contlubE])
   203 
   204 lemma cont_cfun_fun: "chain F \<Longrightarrow> range (\<lambda>i. F i\<cdot>x) <<| (\<Squnion>i. F i)\<cdot>x"
   205 by (rule cont_Rep_CFun1 [THEN contE])
   206 
   207 text {* monotonicity of application *}
   208 
   209 lemma monofun_cfun_fun: "f \<sqsubseteq> g \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>x"
   210 by (simp add: expand_cfun_less)
   211 
   212 lemma monofun_cfun_arg: "x \<sqsubseteq> y \<Longrightarrow> f\<cdot>x \<sqsubseteq> f\<cdot>y"
   213 by (rule monofun_Rep_CFun2 [THEN monofunE])
   214 
   215 lemma monofun_cfun: "\<lbrakk>f \<sqsubseteq> g; x \<sqsubseteq> y\<rbrakk> \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>y"
   216 by (rule trans_less [OF monofun_cfun_fun monofun_cfun_arg])
   217 
   218 text {* ch2ch - rules for the type @{typ "'a -> 'b"} *}
   219 
   220 lemma chain_monofun: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   221 by (erule monofun_Rep_CFun2 [THEN ch2ch_monofun])
   222 
   223 lemma ch2ch_Rep_CFunR: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   224 by (rule monofun_Rep_CFun2 [THEN ch2ch_monofun])
   225 
   226 lemma ch2ch_Rep_CFunL: "chain F \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>x)"
   227 by (rule monofun_Rep_CFun1 [THEN ch2ch_monofun])
   228 
   229 lemma ch2ch_Rep_CFun [simp]:
   230   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>(Y i))"
   231 by (simp add: chain_def monofun_cfun)
   232 
   233 lemma ch2ch_LAM [simp]:
   234   "\<lbrakk>\<And>x. chain (\<lambda>i. S i x); \<And>i. cont (\<lambda>x. S i x)\<rbrakk> \<Longrightarrow> chain (\<lambda>i. \<Lambda> x. S i x)"
   235 by (simp add: chain_def expand_cfun_less)
   236 
   237 text {* contlub, cont properties of @{term Rep_CFun} in both arguments *}
   238 
   239 lemma contlub_cfun: 
   240   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. F i\<cdot>(Y i))"
   241 by (simp add: contlub_cfun_fun contlub_cfun_arg diag_lub)
   242 
   243 lemma cont_cfun: 
   244   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> range (\<lambda>i. F i\<cdot>(Y i)) <<| (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i)"
   245 apply (rule thelubE)
   246 apply (simp only: ch2ch_Rep_CFun)
   247 apply (simp only: contlub_cfun)
   248 done
   249 
   250 lemma contlub_LAM:
   251   "\<lbrakk>\<And>x. chain (\<lambda>i. F i x); \<And>i. cont (\<lambda>x. F i x)\<rbrakk>
   252     \<Longrightarrow> (\<Lambda> x. \<Squnion>i. F i x) = (\<Squnion>i. \<Lambda> x. F i x)"
   253 apply (simp add: thelub_CFun)
   254 apply (simp add: Abs_CFun_inverse2)
   255 apply (simp add: thelub_fun ch2ch_lambda)
   256 done
   257 
   258 lemmas lub_distribs = 
   259   contlub_cfun [symmetric]
   260   contlub_LAM [symmetric]
   261 
   262 text {* strictness *}
   263 
   264 lemma strictI: "f\<cdot>x = \<bottom> \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   265 apply (rule UU_I)
   266 apply (erule subst)
   267 apply (rule minimal [THEN monofun_cfun_arg])
   268 done
   269 
   270 text {* the lub of a chain of continous functions is monotone *}
   271 
   272 lemma lub_cfun_mono: "chain F \<Longrightarrow> monofun (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
   273 apply (drule ch2ch_monofun [OF monofun_Rep_CFun])
   274 apply (simp add: thelub_fun [symmetric])
   275 apply (erule monofun_lub_fun)
   276 apply (simp add: monofun_Rep_CFun2)
   277 done
   278 
   279 text {* a lemma about the exchange of lubs for type @{typ "'a -> 'b"} *}
   280 
   281 lemma ex_lub_cfun:
   282   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>j. \<Squnion>i. F j\<cdot>(Y i)) = (\<Squnion>i. \<Squnion>j. F j\<cdot>(Y i))"
   283 by (simp add: diag_lub)
   284 
   285 text {* the lub of a chain of cont. functions is continuous *}
   286 
   287 lemma cont_lub_cfun: "chain F \<Longrightarrow> cont (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
   288 apply (rule cont2cont_lub)
   289 apply (erule monofun_Rep_CFun [THEN ch2ch_monofun])
   290 apply (rule cont_Rep_CFun2)
   291 done
   292 
   293 text {* type @{typ "'a -> 'b"} is chain complete *}
   294 
   295 lemma lub_cfun: "chain F \<Longrightarrow> range F <<| (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   296 by (simp only: contlub_cfun_fun [symmetric] eta_cfun thelubE)
   297 
   298 lemma thelub_cfun: "chain F \<Longrightarrow> (\<Squnion>i. F i) = (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   299 by (rule lub_cfun [THEN thelubI])
   300 
   301 subsection {* Continuity simplification procedure *}
   302 
   303 text {* cont2cont lemma for @{term Rep_CFun} *}
   304 
   305 lemma cont2cont_Rep_CFun:
   306   "\<lbrakk>cont f; cont t\<rbrakk> \<Longrightarrow> cont (\<lambda>x. (f x)\<cdot>(t x))"
   307 by (best intro: cont2cont_app2 cont_const cont_Rep_CFun cont_Rep_CFun2)
   308 
   309 text {* cont2mono Lemma for @{term "%x. LAM y. c1(x)(y)"} *}
   310 
   311 lemma cont2mono_LAM:
   312 assumes p1: "!!x. cont(c1 x)"
   313 assumes p2: "!!y. monofun(%x. c1 x y)"
   314 shows "monofun(%x. LAM y. c1 x y)"
   315 apply (rule monofunI)
   316 apply (rule less_cfun_ext)
   317 apply (simp add: p1)
   318 apply (erule p2 [THEN monofunE])
   319 done
   320 
   321 text {* cont2cont Lemma for @{term "%x. LAM y. c1 x y"} *}
   322 
   323 lemma cont2cont_LAM:
   324 assumes p1: "!!x. cont(c1 x)"
   325 assumes p2: "!!y. cont(%x. c1 x y)"
   326 shows "cont(%x. LAM y. c1 x y)"
   327 apply (rule cont_Abs_CFun)
   328 apply (simp add: p1 CFun_def)
   329 apply (simp add: p2 cont2cont_lambda)
   330 done
   331 
   332 text {* continuity simplification procedure *}
   333 
   334 lemmas cont_lemmas1 =
   335   cont_const cont_id cont_Rep_CFun2 cont2cont_Rep_CFun cont2cont_LAM
   336 
   337 use "Tools/cont_proc.ML";
   338 setup ContProc.setup;
   339 
   340 (*val cont_tac = (fn i => (resolve_tac cont_lemmas i));*)
   341 (*val cont_tacR = (fn i => (REPEAT (cont_tac i)));*)
   342 
   343 subsection {* Miscellaneous *}
   344 
   345 text {* Monotonicity of @{term Abs_CFun} *}
   346 
   347 lemma semi_monofun_Abs_CFun:
   348   "\<lbrakk>cont f; cont g; f \<sqsubseteq> g\<rbrakk> \<Longrightarrow> Abs_CFun f \<sqsubseteq> Abs_CFun g"
   349 by (simp add: less_CFun_def Abs_CFun_inverse2)
   350 
   351 text {* some lemmata for functions with flat/chfin domain/range types *}
   352 
   353 lemma chfin_Rep_CFunR: "chain (Y::nat => 'a::cpo->'b::chfin)  
   354       ==> !s. ? n. (LUB i. Y i)$s = Y n$s"
   355 apply (rule allI)
   356 apply (subst contlub_cfun_fun)
   357 apply assumption
   358 apply (fast intro!: thelubI chfin lub_finch2 chfin2finch ch2ch_Rep_CFunL)
   359 done
   360 
   361 lemma adm_chfindom: "adm (\<lambda>(u::'a::cpo \<rightarrow> 'b::chfin). P(u\<cdot>s))"
   362 by (rule adm_subst, simp, rule adm_chfin)
   363 
   364 subsection {* Continuous injection-retraction pairs *}
   365 
   366 text {* Continuous retractions are strict. *}
   367 
   368 lemma retraction_strict:
   369   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   370 apply (rule UU_I)
   371 apply (drule_tac x="\<bottom>" in spec)
   372 apply (erule subst)
   373 apply (rule monofun_cfun_arg)
   374 apply (rule minimal)
   375 done
   376 
   377 lemma injection_eq:
   378   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x = g\<cdot>y) = (x = y)"
   379 apply (rule iffI)
   380 apply (drule_tac f=f in cfun_arg_cong)
   381 apply simp
   382 apply simp
   383 done
   384 
   385 lemma injection_less:
   386   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x \<sqsubseteq> g\<cdot>y) = (x \<sqsubseteq> y)"
   387 apply (rule iffI)
   388 apply (drule_tac f=f in monofun_cfun_arg)
   389 apply simp
   390 apply (erule monofun_cfun_arg)
   391 done
   392 
   393 lemma injection_defined_rev:
   394   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; g\<cdot>z = \<bottom>\<rbrakk> \<Longrightarrow> z = \<bottom>"
   395 apply (drule_tac f=f in cfun_arg_cong)
   396 apply (simp add: retraction_strict)
   397 done
   398 
   399 lemma injection_defined:
   400   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; z \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> g\<cdot>z \<noteq> \<bottom>"
   401 by (erule contrapos_nn, rule injection_defined_rev)
   402 
   403 text {* propagation of flatness and chain-finiteness by retractions *}
   404 
   405 lemma chfin2chfin:
   406   "\<forall>y. (f::'a::chfin \<rightarrow> 'b)\<cdot>(g\<cdot>y) = y
   407     \<Longrightarrow> \<forall>Y::nat \<Rightarrow> 'b. chain Y \<longrightarrow> (\<exists>n. max_in_chain n Y)"
   408 apply clarify
   409 apply (drule_tac f=g in chain_monofun)
   410 apply (drule chfin)
   411 apply (unfold max_in_chain_def)
   412 apply (simp add: injection_eq)
   413 done
   414 
   415 lemma flat2flat:
   416   "\<forall>y. (f::'a::flat \<rightarrow> 'b::pcpo)\<cdot>(g\<cdot>y) = y
   417     \<Longrightarrow> \<forall>x y::'b. x \<sqsubseteq> y \<longrightarrow> x = \<bottom> \<or> x = y"
   418 apply clarify
   419 apply (drule_tac f=g in monofun_cfun_arg)
   420 apply (drule ax_flat)
   421 apply (erule disjE)
   422 apply (simp add: injection_defined_rev)
   423 apply (simp add: injection_eq)
   424 done
   425 
   426 text {* a result about functions with flat codomain *}
   427 
   428 lemma flat_eqI: "\<lbrakk>(x::'a::flat) \<sqsubseteq> y; x \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> x = y"
   429 by (drule ax_flat, simp)
   430 
   431 lemma flat_codom:
   432   "f\<cdot>x = (c::'b::flat) \<Longrightarrow> f\<cdot>\<bottom> = \<bottom> \<or> (\<forall>z. f\<cdot>z = c)"
   433 apply (case_tac "f\<cdot>x = \<bottom>")
   434 apply (rule disjI1)
   435 apply (rule UU_I)
   436 apply (erule_tac t="\<bottom>" in subst)
   437 apply (rule minimal [THEN monofun_cfun_arg])
   438 apply clarify
   439 apply (rule_tac a = "f\<cdot>\<bottom>" in refl [THEN box_equals])
   440 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   441 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   442 done
   443 
   444 
   445 subsection {* Identity and composition *}
   446 
   447 definition
   448   ID :: "'a \<rightarrow> 'a" where
   449   "ID = (\<Lambda> x. x)"
   450 
   451 definition
   452   cfcomp  :: "('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'c" where
   453   oo_def: "cfcomp = (\<Lambda> f g x. f\<cdot>(g\<cdot>x))"
   454 
   455 abbreviation
   456   cfcomp_syn :: "['b \<rightarrow> 'c, 'a \<rightarrow> 'b] \<Rightarrow> 'a \<rightarrow> 'c"  (infixr "oo" 100)  where
   457   "f oo g == cfcomp\<cdot>f\<cdot>g"
   458 
   459 lemma ID1 [simp]: "ID\<cdot>x = x"
   460 by (simp add: ID_def)
   461 
   462 lemma cfcomp1: "(f oo g) = (\<Lambda> x. f\<cdot>(g\<cdot>x))"
   463 by (simp add: oo_def)
   464 
   465 lemma cfcomp2 [simp]: "(f oo g)\<cdot>x = f\<cdot>(g\<cdot>x)"
   466 by (simp add: cfcomp1)
   467 
   468 lemma cfcomp_LAM: "cont g \<Longrightarrow> f oo (\<Lambda> x. g x) = (\<Lambda> x. f\<cdot>(g x))"
   469 by (simp add: cfcomp1)
   470 
   471 lemma cfcomp_strict [simp]: "\<bottom> oo f = \<bottom>"
   472 by (simp add: expand_cfun_eq)
   473 
   474 text {*
   475   Show that interpretation of (pcpo,@{text "_->_"}) is a category.
   476   The class of objects is interpretation of syntactical class pcpo.
   477   The class of arrows  between objects @{typ 'a} and @{typ 'b} is interpret. of @{typ "'a -> 'b"}.
   478   The identity arrow is interpretation of @{term ID}.
   479   The composition of f and g is interpretation of @{text "oo"}.
   480 *}
   481 
   482 lemma ID2 [simp]: "f oo ID = f"
   483 by (rule ext_cfun, simp)
   484 
   485 lemma ID3 [simp]: "ID oo f = f"
   486 by (rule ext_cfun, simp)
   487 
   488 lemma assoc_oo: "f oo (g oo h) = (f oo g) oo h"
   489 by (rule ext_cfun, simp)
   490 
   491 
   492 subsection {* Strictified functions *}
   493 
   494 defaultsort pcpo
   495 
   496 definition
   497   strictify  :: "('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'b" where
   498   "strictify = (\<Lambda> f x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   499 
   500 text {* results about strictify *}
   501 
   502 lemma cont_strictify1: "cont (\<lambda>f. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   503 by (simp add: cont_if)
   504 
   505 lemma monofun_strictify2: "monofun (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   506 apply (rule monofunI)
   507 apply (auto simp add: monofun_cfun_arg)
   508 done
   509 
   510 (*FIXME: long proof*)
   511 lemma contlub_strictify2: "contlub (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   512 apply (rule contlubI)
   513 apply (case_tac "(\<Squnion>i. Y i) = \<bottom>")
   514 apply (drule (1) chain_UU_I)
   515 apply simp
   516 apply (simp del: if_image_distrib)
   517 apply (simp only: contlub_cfun_arg)
   518 apply (rule lub_equal2)
   519 apply (rule chain_mono2 [THEN exE])
   520 apply (erule chain_UU_I_inverse2)
   521 apply (assumption)
   522 apply (rule_tac x=x in exI, clarsimp)
   523 apply (erule chain_monofun)
   524 apply (erule monofun_strictify2 [THEN ch2ch_monofun])
   525 done
   526 
   527 lemmas cont_strictify2 =
   528   monocontlub2cont [OF monofun_strictify2 contlub_strictify2, standard]
   529 
   530 lemma strictify_conv_if: "strictify\<cdot>f\<cdot>x = (if x = \<bottom> then \<bottom> else f\<cdot>x)"
   531 by (unfold strictify_def, simp add: cont_strictify1 cont_strictify2)
   532 
   533 lemma strictify1 [simp]: "strictify\<cdot>f\<cdot>\<bottom> = \<bottom>"
   534 by (simp add: strictify_conv_if)
   535 
   536 lemma strictify2 [simp]: "x \<noteq> \<bottom> \<Longrightarrow> strictify\<cdot>f\<cdot>x = f\<cdot>x"
   537 by (simp add: strictify_conv_if)
   538 
   539 subsection {* Continuous let-bindings *}
   540 
   541 definition
   542   CLet :: "'a \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'b" where
   543   "CLet = (\<Lambda> s f. f\<cdot>s)"
   544 
   545 syntax
   546   "_CLet" :: "[letbinds, 'a] => 'a" ("(Let (_)/ in (_))" 10)
   547 
   548 translations
   549   "_CLet (_binds b bs) e" == "_CLet b (_CLet bs e)"
   550   "Let x = a in e" == "CONST CLet\<cdot>a\<cdot>(\<Lambda> x. e)"
   551 
   552 end