src/HOL/Library/Extended_Real.thy
author huffman
Thu Aug 25 11:56:20 2011 -0700 (2011-08-25)
changeset 44520 316256709a8c
parent 44170 510ac30f44c0
child 44669 8e6cdb9c00a7
permissions -rw-r--r--
remove duplicate simp declaration
     1 (*  Title:      HOL/Library/Extended_Real.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Robert Himmelmann, TU München
     4     Author:     Armin Heller, TU München
     5     Author:     Bogdan Grechuk, University of Edinburgh
     6 *)
     7 
     8 header {* Extended real number line *}
     9 
    10 theory Extended_Real
    11 imports Complex_Main Extended_Nat
    12 begin
    13 
    14 text {*
    15 
    16 For more lemmas about the extended real numbers go to
    17   @{text "src/HOL/Multivariate_Analysis/Extended_Real_Limits.thy"}
    18 
    19 *}
    20 
    21 lemma (in complete_lattice) atLeast_eq_UNIV_iff: "{x..} = UNIV \<longleftrightarrow> x = bot"
    22 proof
    23   assume "{x..} = UNIV"
    24   show "x = bot"
    25   proof (rule ccontr)
    26     assume "x \<noteq> bot" then have "bot \<notin> {x..}" by (simp add: le_less)
    27     then show False using `{x..} = UNIV` by simp
    28   qed
    29 qed auto
    30 
    31 lemma SUPR_pair:
    32   "(SUP i : A. SUP j : B. f i j) = (SUP p : A \<times> B. f (fst p) (snd p))"
    33   by (rule antisym) (auto intro!: SUP_leI le_SUPI2)
    34 
    35 lemma INFI_pair:
    36   "(INF i : A. INF j : B. f i j) = (INF p : A \<times> B. f (fst p) (snd p))"
    37   by (rule antisym) (auto intro!: le_INFI INF_leI2)
    38 
    39 subsection {* Definition and basic properties *}
    40 
    41 datatype ereal = ereal real | PInfty | MInfty
    42 
    43 instantiation ereal :: uminus
    44 begin
    45   fun uminus_ereal where
    46     "- (ereal r) = ereal (- r)"
    47   | "- PInfty = MInfty"
    48   | "- MInfty = PInfty"
    49   instance ..
    50 end
    51 
    52 instantiation ereal :: infinity
    53 begin
    54   definition "(\<infinity>::ereal) = PInfty"
    55   instance ..
    56 end
    57 
    58 definition "ereal_of_enat n = (case n of enat n \<Rightarrow> ereal (real n) | \<infinity> \<Rightarrow> \<infinity>)"
    59 
    60 declare [[coercion "ereal :: real \<Rightarrow> ereal"]]
    61 declare [[coercion "ereal_of_enat :: enat \<Rightarrow> ereal"]]
    62 declare [[coercion "(\<lambda>n. ereal (of_nat n)) :: nat \<Rightarrow> ereal"]]
    63 
    64 lemma ereal_uminus_uminus[simp]:
    65   fixes a :: ereal shows "- (- a) = a"
    66   by (cases a) simp_all
    67 
    68 lemma
    69   shows PInfty_eq_infinity[simp]: "PInfty = \<infinity>"
    70     and MInfty_eq_minfinity[simp]: "MInfty = - \<infinity>"
    71     and MInfty_neq_PInfty[simp]: "\<infinity> \<noteq> - (\<infinity>::ereal)" "- \<infinity> \<noteq> (\<infinity>::ereal)"
    72     and MInfty_neq_ereal[simp]: "ereal r \<noteq> - \<infinity>" "- \<infinity> \<noteq> ereal r"
    73     and PInfty_neq_ereal[simp]: "ereal r \<noteq> \<infinity>" "\<infinity> \<noteq> ereal r"
    74     and PInfty_cases[simp]: "(case \<infinity> of ereal r \<Rightarrow> f r | PInfty \<Rightarrow> y | MInfty \<Rightarrow> z) = y"
    75     and MInfty_cases[simp]: "(case - \<infinity> of ereal r \<Rightarrow> f r | PInfty \<Rightarrow> y | MInfty \<Rightarrow> z) = z"
    76   by (simp_all add: infinity_ereal_def)
    77 
    78 declare
    79   PInfty_eq_infinity[code_post]
    80   MInfty_eq_minfinity[code_post]
    81 
    82 lemma [code_unfold]:
    83   "\<infinity> = PInfty"
    84   "-PInfty = MInfty"
    85   by simp_all
    86 
    87 lemma inj_ereal[simp]: "inj_on ereal A"
    88   unfolding inj_on_def by auto
    89 
    90 lemma ereal_cases[case_names real PInf MInf, cases type: ereal]:
    91   assumes "\<And>r. x = ereal r \<Longrightarrow> P"
    92   assumes "x = \<infinity> \<Longrightarrow> P"
    93   assumes "x = -\<infinity> \<Longrightarrow> P"
    94   shows P
    95   using assms by (cases x) auto
    96 
    97 lemmas ereal2_cases = ereal_cases[case_product ereal_cases]
    98 lemmas ereal3_cases = ereal2_cases[case_product ereal_cases]
    99 
   100 lemma ereal_uminus_eq_iff[simp]:
   101   fixes a b :: ereal shows "-a = -b \<longleftrightarrow> a = b"
   102   by (cases rule: ereal2_cases[of a b]) simp_all
   103 
   104 function of_ereal :: "ereal \<Rightarrow> real" where
   105 "of_ereal (ereal r) = r" |
   106 "of_ereal \<infinity> = 0" |
   107 "of_ereal (-\<infinity>) = 0"
   108   by (auto intro: ereal_cases)
   109 termination proof qed (rule wf_empty)
   110 
   111 defs (overloaded)
   112   real_of_ereal_def [code_unfold]: "real \<equiv> of_ereal"
   113 
   114 lemma real_of_ereal[simp]:
   115     "real (- x :: ereal) = - (real x)"
   116     "real (ereal r) = r"
   117     "real (\<infinity>::ereal) = 0"
   118   by (cases x) (simp_all add: real_of_ereal_def)
   119 
   120 lemma range_ereal[simp]: "range ereal = UNIV - {\<infinity>, -\<infinity>}"
   121 proof safe
   122   fix x assume "x \<notin> range ereal" "x \<noteq> \<infinity>"
   123   then show "x = -\<infinity>" by (cases x) auto
   124 qed auto
   125 
   126 lemma ereal_range_uminus[simp]: "range uminus = (UNIV::ereal set)"
   127 proof safe
   128   fix x :: ereal show "x \<in> range uminus" by (intro image_eqI[of _ _ "-x"]) auto
   129 qed auto
   130 
   131 instantiation ereal :: number
   132 begin
   133 definition [simp]: "number_of x = ereal (number_of x)"
   134 instance proof qed
   135 end
   136 
   137 instantiation ereal :: abs
   138 begin
   139   function abs_ereal where
   140     "\<bar>ereal r\<bar> = ereal \<bar>r\<bar>"
   141   | "\<bar>-\<infinity>\<bar> = (\<infinity>::ereal)"
   142   | "\<bar>\<infinity>\<bar> = (\<infinity>::ereal)"
   143   by (auto intro: ereal_cases)
   144   termination proof qed (rule wf_empty)
   145   instance ..
   146 end
   147 
   148 lemma abs_eq_infinity_cases[elim!]: "\<lbrakk> \<bar>x :: ereal\<bar> = \<infinity> ; x = \<infinity> \<Longrightarrow> P ; x = -\<infinity> \<Longrightarrow> P \<rbrakk> \<Longrightarrow> P"
   149   by (cases x) auto
   150 
   151 lemma abs_neq_infinity_cases[elim!]: "\<lbrakk> \<bar>x :: ereal\<bar> \<noteq> \<infinity> ; \<And>r. x = ereal r \<Longrightarrow> P \<rbrakk> \<Longrightarrow> P"
   152   by (cases x) auto
   153 
   154 lemma abs_ereal_uminus[simp]: "\<bar>- x\<bar> = \<bar>x::ereal\<bar>"
   155   by (cases x) auto
   156 
   157 subsubsection "Addition"
   158 
   159 instantiation ereal :: comm_monoid_add
   160 begin
   161 
   162 definition "0 = ereal 0"
   163 
   164 function plus_ereal where
   165 "ereal r + ereal p = ereal (r + p)" |
   166 "\<infinity> + a = (\<infinity>::ereal)" |
   167 "a + \<infinity> = (\<infinity>::ereal)" |
   168 "ereal r + -\<infinity> = - \<infinity>" |
   169 "-\<infinity> + ereal p = -(\<infinity>::ereal)" |
   170 "-\<infinity> + -\<infinity> = -(\<infinity>::ereal)"
   171 proof -
   172   case (goal1 P x)
   173   moreover then obtain a b where "x = (a, b)" by (cases x) auto
   174   ultimately show P
   175    by (cases rule: ereal2_cases[of a b]) auto
   176 qed auto
   177 termination proof qed (rule wf_empty)
   178 
   179 lemma Infty_neq_0[simp]:
   180   "(\<infinity>::ereal) \<noteq> 0" "0 \<noteq> (\<infinity>::ereal)"
   181   "-(\<infinity>::ereal) \<noteq> 0" "0 \<noteq> -(\<infinity>::ereal)"
   182   by (simp_all add: zero_ereal_def)
   183 
   184 lemma ereal_eq_0[simp]:
   185   "ereal r = 0 \<longleftrightarrow> r = 0"
   186   "0 = ereal r \<longleftrightarrow> r = 0"
   187   unfolding zero_ereal_def by simp_all
   188 
   189 instance
   190 proof
   191   fix a :: ereal show "0 + a = a"
   192     by (cases a) (simp_all add: zero_ereal_def)
   193   fix b :: ereal show "a + b = b + a"
   194     by (cases rule: ereal2_cases[of a b]) simp_all
   195   fix c :: ereal show "a + b + c = a + (b + c)"
   196     by (cases rule: ereal3_cases[of a b c]) simp_all
   197 qed
   198 end
   199 
   200 lemma real_of_ereal_0[simp]: "real (0::ereal) = 0"
   201   unfolding real_of_ereal_def zero_ereal_def by simp
   202 
   203 lemma abs_ereal_zero[simp]: "\<bar>0\<bar> = (0::ereal)"
   204   unfolding zero_ereal_def abs_ereal.simps by simp
   205 
   206 lemma ereal_uminus_zero[simp]:
   207   "- 0 = (0::ereal)"
   208   by (simp add: zero_ereal_def)
   209 
   210 lemma ereal_uminus_zero_iff[simp]:
   211   fixes a :: ereal shows "-a = 0 \<longleftrightarrow> a = 0"
   212   by (cases a) simp_all
   213 
   214 lemma ereal_plus_eq_PInfty[simp]:
   215   fixes a b :: ereal shows "a + b = \<infinity> \<longleftrightarrow> a = \<infinity> \<or> b = \<infinity>"
   216   by (cases rule: ereal2_cases[of a b]) auto
   217 
   218 lemma ereal_plus_eq_MInfty[simp]:
   219   fixes a b :: ereal shows "a + b = -\<infinity> \<longleftrightarrow>
   220     (a = -\<infinity> \<or> b = -\<infinity>) \<and> a \<noteq> \<infinity> \<and> b \<noteq> \<infinity>"
   221   by (cases rule: ereal2_cases[of a b]) auto
   222 
   223 lemma ereal_add_cancel_left:
   224   fixes a b :: ereal assumes "a \<noteq> -\<infinity>"
   225   shows "a + b = a + c \<longleftrightarrow> (a = \<infinity> \<or> b = c)"
   226   using assms by (cases rule: ereal3_cases[of a b c]) auto
   227 
   228 lemma ereal_add_cancel_right:
   229   fixes a b :: ereal assumes "a \<noteq> -\<infinity>"
   230   shows "b + a = c + a \<longleftrightarrow> (a = \<infinity> \<or> b = c)"
   231   using assms by (cases rule: ereal3_cases[of a b c]) auto
   232 
   233 lemma ereal_real:
   234   "ereal (real x) = (if \<bar>x\<bar> = \<infinity> then 0 else x)"
   235   by (cases x) simp_all
   236 
   237 lemma real_of_ereal_add:
   238   fixes a b :: ereal
   239   shows "real (a + b) = (if (\<bar>a\<bar> = \<infinity>) \<and> (\<bar>b\<bar> = \<infinity>) \<or> (\<bar>a\<bar> \<noteq> \<infinity>) \<and> (\<bar>b\<bar> \<noteq> \<infinity>) then real a + real b else 0)"
   240   by (cases rule: ereal2_cases[of a b]) auto
   241 
   242 subsubsection "Linear order on @{typ ereal}"
   243 
   244 instantiation ereal :: linorder
   245 begin
   246 
   247 function less_ereal where
   248 "   ereal x < ereal y     \<longleftrightarrow> x < y" |
   249 "(\<infinity>::ereal) < a           \<longleftrightarrow> False" |
   250 "         a < -(\<infinity>::ereal) \<longleftrightarrow> False" |
   251 "ereal x    < \<infinity>           \<longleftrightarrow> True" |
   252 "        -\<infinity> < ereal r     \<longleftrightarrow> True" |
   253 "        -\<infinity> < (\<infinity>::ereal) \<longleftrightarrow> True"
   254 proof -
   255   case (goal1 P x)
   256   moreover then obtain a b where "x = (a,b)" by (cases x) auto
   257   ultimately show P by (cases rule: ereal2_cases[of a b]) auto
   258 qed simp_all
   259 termination by (relation "{}") simp
   260 
   261 definition "x \<le> (y::ereal) \<longleftrightarrow> x < y \<or> x = y"
   262 
   263 lemma ereal_infty_less[simp]:
   264   fixes x :: ereal
   265   shows "x < \<infinity> \<longleftrightarrow> (x \<noteq> \<infinity>)"
   266     "-\<infinity> < x \<longleftrightarrow> (x \<noteq> -\<infinity>)"
   267   by (cases x, simp_all) (cases x, simp_all)
   268 
   269 lemma ereal_infty_less_eq[simp]:
   270   fixes x :: ereal
   271   shows "\<infinity> \<le> x \<longleftrightarrow> x = \<infinity>"
   272   "x \<le> -\<infinity> \<longleftrightarrow> x = -\<infinity>"
   273   by (auto simp add: less_eq_ereal_def)
   274 
   275 lemma ereal_less[simp]:
   276   "ereal r < 0 \<longleftrightarrow> (r < 0)"
   277   "0 < ereal r \<longleftrightarrow> (0 < r)"
   278   "0 < (\<infinity>::ereal)"
   279   "-(\<infinity>::ereal) < 0"
   280   by (simp_all add: zero_ereal_def)
   281 
   282 lemma ereal_less_eq[simp]:
   283   "x \<le> (\<infinity>::ereal)"
   284   "-(\<infinity>::ereal) \<le> x"
   285   "ereal r \<le> ereal p \<longleftrightarrow> r \<le> p"
   286   "ereal r \<le> 0 \<longleftrightarrow> r \<le> 0"
   287   "0 \<le> ereal r \<longleftrightarrow> 0 \<le> r"
   288   by (auto simp add: less_eq_ereal_def zero_ereal_def)
   289 
   290 lemma ereal_infty_less_eq2:
   291   "a \<le> b \<Longrightarrow> a = \<infinity> \<Longrightarrow> b = (\<infinity>::ereal)"
   292   "a \<le> b \<Longrightarrow> b = -\<infinity> \<Longrightarrow> a = -(\<infinity>::ereal)"
   293   by simp_all
   294 
   295 instance
   296 proof
   297   fix x :: ereal show "x \<le> x"
   298     by (cases x) simp_all
   299   fix y :: ereal show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
   300     by (cases rule: ereal2_cases[of x y]) auto
   301   show "x \<le> y \<or> y \<le> x "
   302     by (cases rule: ereal2_cases[of x y]) auto
   303   { assume "x \<le> y" "y \<le> x" then show "x = y"
   304     by (cases rule: ereal2_cases[of x y]) auto }
   305   { fix z assume "x \<le> y" "y \<le> z" then show "x \<le> z"
   306     by (cases rule: ereal3_cases[of x y z]) auto }
   307 qed
   308 end
   309 
   310 instance ereal :: ordered_ab_semigroup_add
   311 proof
   312   fix a b c :: ereal assume "a \<le> b" then show "c + a \<le> c + b"
   313     by (cases rule: ereal3_cases[of a b c]) auto
   314 qed
   315 
   316 lemma real_of_ereal_positive_mono:
   317   fixes x y :: ereal shows "\<lbrakk>0 \<le> x; x \<le> y; y \<noteq> \<infinity>\<rbrakk> \<Longrightarrow> real x \<le> real y"
   318   by (cases rule: ereal2_cases[of x y]) auto
   319 
   320 lemma ereal_MInfty_lessI[intro, simp]:
   321   fixes a :: ereal shows "a \<noteq> -\<infinity> \<Longrightarrow> -\<infinity> < a"
   322   by (cases a) auto
   323 
   324 lemma ereal_less_PInfty[intro, simp]:
   325   fixes a :: ereal shows "a \<noteq> \<infinity> \<Longrightarrow> a < \<infinity>"
   326   by (cases a) auto
   327 
   328 lemma ereal_less_ereal_Ex:
   329   fixes a b :: ereal
   330   shows "x < ereal r \<longleftrightarrow> x = -\<infinity> \<or> (\<exists>p. p < r \<and> x = ereal p)"
   331   by (cases x) auto
   332 
   333 lemma less_PInf_Ex_of_nat: "x \<noteq> \<infinity> \<longleftrightarrow> (\<exists>n::nat. x < ereal (real n))"
   334 proof (cases x)
   335   case (real r) then show ?thesis
   336     using reals_Archimedean2[of r] by simp
   337 qed simp_all
   338 
   339 lemma ereal_add_mono:
   340   fixes a b c d :: ereal assumes "a \<le> b" "c \<le> d" shows "a + c \<le> b + d"
   341   using assms
   342   apply (cases a)
   343   apply (cases rule: ereal3_cases[of b c d], auto)
   344   apply (cases rule: ereal3_cases[of b c d], auto)
   345   done
   346 
   347 lemma ereal_minus_le_minus[simp]:
   348   fixes a b :: ereal shows "- a \<le> - b \<longleftrightarrow> b \<le> a"
   349   by (cases rule: ereal2_cases[of a b]) auto
   350 
   351 lemma ereal_minus_less_minus[simp]:
   352   fixes a b :: ereal shows "- a < - b \<longleftrightarrow> b < a"
   353   by (cases rule: ereal2_cases[of a b]) auto
   354 
   355 lemma ereal_le_real_iff:
   356   "x \<le> real y \<longleftrightarrow> ((\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> ereal x \<le> y) \<and> (\<bar>y\<bar> = \<infinity> \<longrightarrow> x \<le> 0))"
   357   by (cases y) auto
   358 
   359 lemma real_le_ereal_iff:
   360   "real y \<le> x \<longleftrightarrow> ((\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> y \<le> ereal x) \<and> (\<bar>y\<bar> = \<infinity> \<longrightarrow> 0 \<le> x))"
   361   by (cases y) auto
   362 
   363 lemma ereal_less_real_iff:
   364   "x < real y \<longleftrightarrow> ((\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> ereal x < y) \<and> (\<bar>y\<bar> = \<infinity> \<longrightarrow> x < 0))"
   365   by (cases y) auto
   366 
   367 lemma real_less_ereal_iff:
   368   "real y < x \<longleftrightarrow> ((\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> y < ereal x) \<and> (\<bar>y\<bar> = \<infinity> \<longrightarrow> 0 < x))"
   369   by (cases y) auto
   370 
   371 lemma real_of_ereal_pos:
   372   fixes x :: ereal shows "0 \<le> x \<Longrightarrow> 0 \<le> real x" by (cases x) auto
   373 
   374 lemmas real_of_ereal_ord_simps =
   375   ereal_le_real_iff real_le_ereal_iff ereal_less_real_iff real_less_ereal_iff
   376 
   377 lemma abs_ereal_ge0[simp]: "0 \<le> x \<Longrightarrow> \<bar>x :: ereal\<bar> = x"
   378   by (cases x) auto
   379 
   380 lemma abs_ereal_less0[simp]: "x < 0 \<Longrightarrow> \<bar>x :: ereal\<bar> = -x"
   381   by (cases x) auto
   382 
   383 lemma abs_ereal_pos[simp]: "0 \<le> \<bar>x :: ereal\<bar>"
   384   by (cases x) auto
   385 
   386 lemma real_of_ereal_le_0[simp]: "real (x :: ereal) \<le> 0 \<longleftrightarrow> (x \<le> 0 \<or> x = \<infinity>)"
   387   by (cases x) auto
   388 
   389 lemma abs_real_of_ereal[simp]: "\<bar>real (x :: ereal)\<bar> = real \<bar>x\<bar>"
   390   by (cases x) auto
   391 
   392 lemma zero_less_real_of_ereal:
   393   fixes x :: ereal shows "0 < real x \<longleftrightarrow> (0 < x \<and> x \<noteq> \<infinity>)"
   394   by (cases x) auto
   395 
   396 lemma ereal_0_le_uminus_iff[simp]:
   397   fixes a :: ereal shows "0 \<le> -a \<longleftrightarrow> a \<le> 0"
   398   by (cases rule: ereal2_cases[of a]) auto
   399 
   400 lemma ereal_uminus_le_0_iff[simp]:
   401   fixes a :: ereal shows "-a \<le> 0 \<longleftrightarrow> 0 \<le> a"
   402   by (cases rule: ereal2_cases[of a]) auto
   403 
   404 lemma ereal_dense2: "x < y \<Longrightarrow> \<exists>z. x < ereal z \<and> ereal z < y"
   405   using lt_ex gt_ex dense by (cases x y rule: ereal2_cases) auto
   406 
   407 lemma ereal_dense:
   408   fixes x y :: ereal assumes "x < y"
   409   shows "\<exists>z. x < z \<and> z < y"
   410   using ereal_dense2[OF `x < y`] by blast
   411 
   412 lemma ereal_add_strict_mono:
   413   fixes a b c d :: ereal
   414   assumes "a = b" "0 \<le> a" "a \<noteq> \<infinity>" "c < d"
   415   shows "a + c < b + d"
   416   using assms by (cases rule: ereal3_cases[case_product ereal_cases, of a b c d]) auto
   417 
   418 lemma ereal_less_add: 
   419   fixes a b c :: ereal shows "\<bar>a\<bar> \<noteq> \<infinity> \<Longrightarrow> c < b \<Longrightarrow> a + c < a + b"
   420   by (cases rule: ereal2_cases[of b c]) auto
   421 
   422 lemma ereal_uminus_eq_reorder: "- a = b \<longleftrightarrow> a = (-b::ereal)" by auto
   423 
   424 lemma ereal_uminus_less_reorder: "- a < b \<longleftrightarrow> -b < (a::ereal)"
   425   by (subst (3) ereal_uminus_uminus[symmetric]) (simp only: ereal_minus_less_minus)
   426 
   427 lemma ereal_uminus_le_reorder: "- a \<le> b \<longleftrightarrow> -b \<le> (a::ereal)"
   428   by (subst (3) ereal_uminus_uminus[symmetric]) (simp only: ereal_minus_le_minus)
   429 
   430 lemmas ereal_uminus_reorder =
   431   ereal_uminus_eq_reorder ereal_uminus_less_reorder ereal_uminus_le_reorder
   432 
   433 lemma ereal_bot:
   434   fixes x :: ereal assumes "\<And>B. x \<le> ereal B" shows "x = - \<infinity>"
   435 proof (cases x)
   436   case (real r) with assms[of "r - 1"] show ?thesis by auto
   437 next case PInf with assms[of 0] show ?thesis by auto
   438 next case MInf then show ?thesis by simp
   439 qed
   440 
   441 lemma ereal_top:
   442   fixes x :: ereal assumes "\<And>B. x \<ge> ereal B" shows "x = \<infinity>"
   443 proof (cases x)
   444   case (real r) with assms[of "r + 1"] show ?thesis by auto
   445 next case MInf with assms[of 0] show ?thesis by auto
   446 next case PInf then show ?thesis by simp
   447 qed
   448 
   449 lemma
   450   shows ereal_max[simp]: "ereal (max x y) = max (ereal x) (ereal y)"
   451     and ereal_min[simp]: "ereal (min x y) = min (ereal x) (ereal y)"
   452   by (simp_all add: min_def max_def)
   453 
   454 lemma ereal_max_0: "max 0 (ereal r) = ereal (max 0 r)"
   455   by (auto simp: zero_ereal_def)
   456 
   457 lemma
   458   fixes f :: "nat \<Rightarrow> ereal"
   459   shows incseq_uminus[simp]: "incseq (\<lambda>x. - f x) \<longleftrightarrow> decseq f"
   460   and decseq_uminus[simp]: "decseq (\<lambda>x. - f x) \<longleftrightarrow> incseq f"
   461   unfolding decseq_def incseq_def by auto
   462 
   463 lemma incseq_ereal: "incseq f \<Longrightarrow> incseq (\<lambda>x. ereal (f x))"
   464   unfolding incseq_def by auto
   465 
   466 lemma ereal_add_nonneg_nonneg:
   467   fixes a b :: ereal shows "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a + b"
   468   using add_mono[of 0 a 0 b] by simp
   469 
   470 lemma image_eqD: "f ` A = B \<Longrightarrow> (\<forall>x\<in>A. f x \<in> B)"
   471   by auto
   472 
   473 lemma incseq_setsumI:
   474   fixes f :: "nat \<Rightarrow> 'a::{comm_monoid_add, ordered_ab_semigroup_add}"
   475   assumes "\<And>i. 0 \<le> f i"
   476   shows "incseq (\<lambda>i. setsum f {..< i})"
   477 proof (intro incseq_SucI)
   478   fix n have "setsum f {..< n} + 0 \<le> setsum f {..<n} + f n"
   479     using assms by (rule add_left_mono)
   480   then show "setsum f {..< n} \<le> setsum f {..< Suc n}"
   481     by auto
   482 qed
   483 
   484 lemma incseq_setsumI2:
   485   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::{comm_monoid_add, ordered_ab_semigroup_add}"
   486   assumes "\<And>n. n \<in> A \<Longrightarrow> incseq (f n)"
   487   shows "incseq (\<lambda>i. \<Sum>n\<in>A. f n i)"
   488   using assms unfolding incseq_def by (auto intro: setsum_mono)
   489 
   490 subsubsection "Multiplication"
   491 
   492 instantiation ereal :: "{comm_monoid_mult, sgn}"
   493 begin
   494 
   495 definition "1 = ereal 1"
   496 
   497 function sgn_ereal where
   498   "sgn (ereal r) = ereal (sgn r)"
   499 | "sgn (\<infinity>::ereal) = 1"
   500 | "sgn (-\<infinity>::ereal) = -1"
   501 by (auto intro: ereal_cases)
   502 termination proof qed (rule wf_empty)
   503 
   504 function times_ereal where
   505 "ereal r * ereal p = ereal (r * p)" |
   506 "ereal r * \<infinity> = (if r = 0 then 0 else if r > 0 then \<infinity> else -\<infinity>)" |
   507 "\<infinity> * ereal r = (if r = 0 then 0 else if r > 0 then \<infinity> else -\<infinity>)" |
   508 "ereal r * -\<infinity> = (if r = 0 then 0 else if r > 0 then -\<infinity> else \<infinity>)" |
   509 "-\<infinity> * ereal r = (if r = 0 then 0 else if r > 0 then -\<infinity> else \<infinity>)" |
   510 "(\<infinity>::ereal) * \<infinity> = \<infinity>" |
   511 "-(\<infinity>::ereal) * \<infinity> = -\<infinity>" |
   512 "(\<infinity>::ereal) * -\<infinity> = -\<infinity>" |
   513 "-(\<infinity>::ereal) * -\<infinity> = \<infinity>"
   514 proof -
   515   case (goal1 P x)
   516   moreover then obtain a b where "x = (a, b)" by (cases x) auto
   517   ultimately show P by (cases rule: ereal2_cases[of a b]) auto
   518 qed simp_all
   519 termination by (relation "{}") simp
   520 
   521 instance
   522 proof
   523   fix a :: ereal show "1 * a = a"
   524     by (cases a) (simp_all add: one_ereal_def)
   525   fix b :: ereal show "a * b = b * a"
   526     by (cases rule: ereal2_cases[of a b]) simp_all
   527   fix c :: ereal show "a * b * c = a * (b * c)"
   528     by (cases rule: ereal3_cases[of a b c])
   529        (simp_all add: zero_ereal_def zero_less_mult_iff)
   530 qed
   531 end
   532 
   533 lemma real_of_ereal_le_1:
   534   fixes a :: ereal shows "a \<le> 1 \<Longrightarrow> real a \<le> 1"
   535   by (cases a) (auto simp: one_ereal_def)
   536 
   537 lemma abs_ereal_one[simp]: "\<bar>1\<bar> = (1::ereal)"
   538   unfolding one_ereal_def by simp
   539 
   540 lemma ereal_mult_zero[simp]:
   541   fixes a :: ereal shows "a * 0 = 0"
   542   by (cases a) (simp_all add: zero_ereal_def)
   543 
   544 lemma ereal_zero_mult[simp]:
   545   fixes a :: ereal shows "0 * a = 0"
   546   by (cases a) (simp_all add: zero_ereal_def)
   547 
   548 lemma ereal_m1_less_0[simp]:
   549   "-(1::ereal) < 0"
   550   by (simp add: zero_ereal_def one_ereal_def)
   551 
   552 lemma ereal_zero_m1[simp]:
   553   "1 \<noteq> (0::ereal)"
   554   by (simp add: zero_ereal_def one_ereal_def)
   555 
   556 lemma ereal_times_0[simp]:
   557   fixes x :: ereal shows "0 * x = 0"
   558   by (cases x) (auto simp: zero_ereal_def)
   559 
   560 lemma ereal_times[simp]:
   561   "1 \<noteq> (\<infinity>::ereal)" "(\<infinity>::ereal) \<noteq> 1"
   562   "1 \<noteq> -(\<infinity>::ereal)" "-(\<infinity>::ereal) \<noteq> 1"
   563   by (auto simp add: times_ereal_def one_ereal_def)
   564 
   565 lemma ereal_plus_1[simp]:
   566   "1 + ereal r = ereal (r + 1)" "ereal r + 1 = ereal (r + 1)"
   567   "1 + -(\<infinity>::ereal) = -\<infinity>" "-(\<infinity>::ereal) + 1 = -\<infinity>"
   568   unfolding one_ereal_def by auto
   569 
   570 lemma ereal_zero_times[simp]:
   571   fixes a b :: ereal shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   572   by (cases rule: ereal2_cases[of a b]) auto
   573 
   574 lemma ereal_mult_eq_PInfty[simp]:
   575   shows "a * b = (\<infinity>::ereal) \<longleftrightarrow>
   576     (a = \<infinity> \<and> b > 0) \<or> (a > 0 \<and> b = \<infinity>) \<or> (a = -\<infinity> \<and> b < 0) \<or> (a < 0 \<and> b = -\<infinity>)"
   577   by (cases rule: ereal2_cases[of a b]) auto
   578 
   579 lemma ereal_mult_eq_MInfty[simp]:
   580   shows "a * b = -(\<infinity>::ereal) \<longleftrightarrow>
   581     (a = \<infinity> \<and> b < 0) \<or> (a < 0 \<and> b = \<infinity>) \<or> (a = -\<infinity> \<and> b > 0) \<or> (a > 0 \<and> b = -\<infinity>)"
   582   by (cases rule: ereal2_cases[of a b]) auto
   583 
   584 lemma ereal_0_less_1[simp]: "0 < (1::ereal)"
   585   by (simp_all add: zero_ereal_def one_ereal_def)
   586 
   587 lemma ereal_zero_one[simp]: "0 \<noteq> (1::ereal)"
   588   by (simp_all add: zero_ereal_def one_ereal_def)
   589 
   590 lemma ereal_mult_minus_left[simp]:
   591   fixes a b :: ereal shows "-a * b = - (a * b)"
   592   by (cases rule: ereal2_cases[of a b]) auto
   593 
   594 lemma ereal_mult_minus_right[simp]:
   595   fixes a b :: ereal shows "a * -b = - (a * b)"
   596   by (cases rule: ereal2_cases[of a b]) auto
   597 
   598 lemma ereal_mult_infty[simp]:
   599   "a * (\<infinity>::ereal) = (if a = 0 then 0 else if 0 < a then \<infinity> else - \<infinity>)"
   600   by (cases a) auto
   601 
   602 lemma ereal_infty_mult[simp]:
   603   "(\<infinity>::ereal) * a = (if a = 0 then 0 else if 0 < a then \<infinity> else - \<infinity>)"
   604   by (cases a) auto
   605 
   606 lemma ereal_mult_strict_right_mono:
   607   assumes "a < b" and "0 < c" "c < (\<infinity>::ereal)"
   608   shows "a * c < b * c"
   609   using assms
   610   by (cases rule: ereal3_cases[of a b c])
   611      (auto simp: zero_le_mult_iff)
   612 
   613 lemma ereal_mult_strict_left_mono:
   614   "\<lbrakk> a < b ; 0 < c ; c < (\<infinity>::ereal)\<rbrakk> \<Longrightarrow> c * a < c * b"
   615   using ereal_mult_strict_right_mono by (simp add: mult_commute[of c])
   616 
   617 lemma ereal_mult_right_mono:
   618   fixes a b c :: ereal shows "\<lbrakk>a \<le> b; 0 \<le> c\<rbrakk> \<Longrightarrow> a*c \<le> b*c"
   619   using assms
   620   apply (cases "c = 0") apply simp
   621   by (cases rule: ereal3_cases[of a b c])
   622      (auto simp: zero_le_mult_iff)
   623 
   624 lemma ereal_mult_left_mono:
   625   fixes a b c :: ereal shows "\<lbrakk>a \<le> b; 0 \<le> c\<rbrakk> \<Longrightarrow> c * a \<le> c * b"
   626   using ereal_mult_right_mono by (simp add: mult_commute[of c])
   627 
   628 lemma zero_less_one_ereal[simp]: "0 \<le> (1::ereal)"
   629   by (simp add: one_ereal_def zero_ereal_def)
   630 
   631 lemma ereal_0_le_mult[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * (b :: ereal)"
   632   by (cases rule: ereal2_cases[of a b]) (auto simp: mult_nonneg_nonneg)
   633 
   634 lemma ereal_right_distrib:
   635   fixes r a b :: ereal shows "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> r * (a + b) = r * a + r * b"
   636   by (cases rule: ereal3_cases[of r a b]) (simp_all add: field_simps)
   637 
   638 lemma ereal_left_distrib:
   639   fixes r a b :: ereal shows "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> (a + b) * r = a * r + b * r"
   640   by (cases rule: ereal3_cases[of r a b]) (simp_all add: field_simps)
   641 
   642 lemma ereal_mult_le_0_iff:
   643   fixes a b :: ereal
   644   shows "a * b \<le> 0 \<longleftrightarrow> (0 \<le> a \<and> b \<le> 0) \<or> (a \<le> 0 \<and> 0 \<le> b)"
   645   by (cases rule: ereal2_cases[of a b]) (simp_all add: mult_le_0_iff)
   646 
   647 lemma ereal_zero_le_0_iff:
   648   fixes a b :: ereal
   649   shows "0 \<le> a * b \<longleftrightarrow> (0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0)"
   650   by (cases rule: ereal2_cases[of a b]) (simp_all add: zero_le_mult_iff)
   651 
   652 lemma ereal_mult_less_0_iff:
   653   fixes a b :: ereal
   654   shows "a * b < 0 \<longleftrightarrow> (0 < a \<and> b < 0) \<or> (a < 0 \<and> 0 < b)"
   655   by (cases rule: ereal2_cases[of a b]) (simp_all add: mult_less_0_iff)
   656 
   657 lemma ereal_zero_less_0_iff:
   658   fixes a b :: ereal
   659   shows "0 < a * b \<longleftrightarrow> (0 < a \<and> 0 < b) \<or> (a < 0 \<and> b < 0)"
   660   by (cases rule: ereal2_cases[of a b]) (simp_all add: zero_less_mult_iff)
   661 
   662 lemma ereal_distrib:
   663   fixes a b c :: ereal
   664   assumes "a \<noteq> \<infinity> \<or> b \<noteq> -\<infinity>" "a \<noteq> -\<infinity> \<or> b \<noteq> \<infinity>" "\<bar>c\<bar> \<noteq> \<infinity>"
   665   shows "(a + b) * c = a * c + b * c"
   666   using assms
   667   by (cases rule: ereal3_cases[of a b c]) (simp_all add: field_simps)
   668 
   669 lemma ereal_le_epsilon:
   670   fixes x y :: ereal
   671   assumes "ALL e. 0 < e --> x <= y + e"
   672   shows "x <= y"
   673 proof-
   674 { assume a: "EX r. y = ereal r"
   675   from this obtain r where r_def: "y = ereal r" by auto
   676   { assume "x=(-\<infinity>)" hence ?thesis by auto }
   677   moreover
   678   { assume "~(x=(-\<infinity>))"
   679     from this obtain p where p_def: "x = ereal p"
   680     using a assms[rule_format, of 1] by (cases x) auto
   681     { fix e have "0 < e --> p <= r + e"
   682       using assms[rule_format, of "ereal e"] p_def r_def by auto }
   683     hence "p <= r" apply (subst field_le_epsilon) by auto
   684     hence ?thesis using r_def p_def by auto
   685   } ultimately have ?thesis by blast
   686 }
   687 moreover
   688 { assume "y=(-\<infinity>) | y=\<infinity>" hence ?thesis
   689     using assms[rule_format, of 1] by (cases x) auto
   690 } ultimately show ?thesis by (cases y) auto
   691 qed
   692 
   693 
   694 lemma ereal_le_epsilon2:
   695   fixes x y :: ereal
   696   assumes "ALL e. 0 < e --> x <= y + ereal e"
   697   shows "x <= y"
   698 proof-
   699 { fix e :: ereal assume "e>0"
   700   { assume "e=\<infinity>" hence "x<=y+e" by auto }
   701   moreover
   702   { assume "e~=\<infinity>"
   703     from this obtain r where "e = ereal r" using `e>0` apply (cases e) by auto
   704     hence "x<=y+e" using assms[rule_format, of r] `e>0` by auto
   705   } ultimately have "x<=y+e" by blast
   706 } from this show ?thesis using ereal_le_epsilon by auto
   707 qed
   708 
   709 lemma ereal_le_real:
   710   fixes x y :: ereal
   711   assumes "ALL z. x <= ereal z --> y <= ereal z"
   712   shows "y <= x"
   713 by (metis assms ereal_bot ereal_cases ereal_infty_less_eq(2) ereal_less_eq(1) linorder_le_cases)
   714 
   715 lemma ereal_le_ereal:
   716   fixes x y :: ereal
   717   assumes "\<And>B. B < x \<Longrightarrow> B <= y"
   718   shows "x <= y"
   719 by (metis assms ereal_dense leD linorder_le_less_linear)
   720 
   721 lemma ereal_ge_ereal:
   722   fixes x y :: ereal
   723   assumes "ALL B. B>x --> B >= y"
   724   shows "x >= y"
   725 by (metis assms ereal_dense leD linorder_le_less_linear)
   726 
   727 lemma setprod_ereal_0:
   728   fixes f :: "'a \<Rightarrow> ereal"
   729   shows "(\<Prod>i\<in>A. f i) = 0 \<longleftrightarrow> (finite A \<and> (\<exists>i\<in>A. f i = 0))"
   730 proof cases
   731   assume "finite A"
   732   then show ?thesis by (induct A) auto
   733 qed auto
   734 
   735 lemma setprod_ereal_pos:
   736   fixes f :: "'a \<Rightarrow> ereal" assumes pos: "\<And>i. i \<in> I \<Longrightarrow> 0 \<le> f i" shows "0 \<le> (\<Prod>i\<in>I. f i)"
   737 proof cases
   738   assume "finite I" from this pos show ?thesis by induct auto
   739 qed simp
   740 
   741 lemma setprod_PInf:
   742   fixes f :: "'a \<Rightarrow> ereal"
   743   assumes "\<And>i. i \<in> I \<Longrightarrow> 0 \<le> f i"
   744   shows "(\<Prod>i\<in>I. f i) = \<infinity> \<longleftrightarrow> finite I \<and> (\<exists>i\<in>I. f i = \<infinity>) \<and> (\<forall>i\<in>I. f i \<noteq> 0)"
   745 proof cases
   746   assume "finite I" from this assms show ?thesis
   747   proof (induct I)
   748     case (insert i I)
   749     then have pos: "0 \<le> f i" "0 \<le> setprod f I" by (auto intro!: setprod_ereal_pos)
   750     from insert have "(\<Prod>j\<in>insert i I. f j) = \<infinity> \<longleftrightarrow> setprod f I * f i = \<infinity>" by auto
   751     also have "\<dots> \<longleftrightarrow> (setprod f I = \<infinity> \<or> f i = \<infinity>) \<and> f i \<noteq> 0 \<and> setprod f I \<noteq> 0"
   752       using setprod_ereal_pos[of I f] pos
   753       by (cases rule: ereal2_cases[of "f i" "setprod f I"]) auto
   754     also have "\<dots> \<longleftrightarrow> finite (insert i I) \<and> (\<exists>j\<in>insert i I. f j = \<infinity>) \<and> (\<forall>j\<in>insert i I. f j \<noteq> 0)"
   755       using insert by (auto simp: setprod_ereal_0)
   756     finally show ?case .
   757   qed simp
   758 qed simp
   759 
   760 lemma setprod_ereal: "(\<Prod>i\<in>A. ereal (f i)) = ereal (setprod f A)"
   761 proof cases
   762   assume "finite A" then show ?thesis
   763     by induct (auto simp: one_ereal_def)
   764 qed (simp add: one_ereal_def)
   765 
   766 subsubsection {* Power *}
   767 
   768 instantiation ereal :: power
   769 begin
   770 primrec power_ereal where
   771   "power_ereal x 0 = 1" |
   772   "power_ereal x (Suc n) = x * x ^ n"
   773 instance ..
   774 end
   775 
   776 lemma ereal_power[simp]: "(ereal x) ^ n = ereal (x^n)"
   777   by (induct n) (auto simp: one_ereal_def)
   778 
   779 lemma ereal_power_PInf[simp]: "(\<infinity>::ereal) ^ n = (if n = 0 then 1 else \<infinity>)"
   780   by (induct n) (auto simp: one_ereal_def)
   781 
   782 lemma ereal_power_uminus[simp]:
   783   fixes x :: ereal
   784   shows "(- x) ^ n = (if even n then x ^ n else - (x^n))"
   785   by (induct n) (auto simp: one_ereal_def)
   786 
   787 lemma ereal_power_number_of[simp]:
   788   "(number_of num :: ereal) ^ n = ereal (number_of num ^ n)"
   789   by (induct n) (auto simp: one_ereal_def)
   790 
   791 lemma zero_le_power_ereal[simp]:
   792   fixes a :: ereal assumes "0 \<le> a"
   793   shows "0 \<le> a ^ n"
   794   using assms by (induct n) (auto simp: ereal_zero_le_0_iff)
   795 
   796 subsubsection {* Subtraction *}
   797 
   798 lemma ereal_minus_minus_image[simp]:
   799   fixes S :: "ereal set"
   800   shows "uminus ` uminus ` S = S"
   801   by (auto simp: image_iff)
   802 
   803 lemma ereal_uminus_lessThan[simp]:
   804   fixes a :: ereal shows "uminus ` {..<a} = {-a<..}"
   805 proof (safe intro!: image_eqI)
   806   fix x assume "-a < x"
   807   then have "- x < - (- a)" by (simp del: ereal_uminus_uminus)
   808   then show "- x < a" by simp
   809 qed auto
   810 
   811 lemma ereal_uminus_greaterThan[simp]:
   812   "uminus ` {(a::ereal)<..} = {..<-a}"
   813   by (metis ereal_uminus_lessThan ereal_uminus_uminus
   814             ereal_minus_minus_image)
   815 
   816 instantiation ereal :: minus
   817 begin
   818 definition "x - y = x + -(y::ereal)"
   819 instance ..
   820 end
   821 
   822 lemma ereal_minus[simp]:
   823   "ereal r - ereal p = ereal (r - p)"
   824   "-\<infinity> - ereal r = -\<infinity>"
   825   "ereal r - \<infinity> = -\<infinity>"
   826   "(\<infinity>::ereal) - x = \<infinity>"
   827   "-(\<infinity>::ereal) - \<infinity> = -\<infinity>"
   828   "x - -y = x + y"
   829   "x - 0 = x"
   830   "0 - x = -x"
   831   by (simp_all add: minus_ereal_def)
   832 
   833 lemma ereal_x_minus_x[simp]:
   834   "x - x = (if \<bar>x\<bar> = \<infinity> then \<infinity> else 0::ereal)"
   835   by (cases x) simp_all
   836 
   837 lemma ereal_eq_minus_iff:
   838   fixes x y z :: ereal
   839   shows "x = z - y \<longleftrightarrow>
   840     (\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> x + y = z) \<and>
   841     (y = -\<infinity> \<longrightarrow> x = \<infinity>) \<and>
   842     (y = \<infinity> \<longrightarrow> z = \<infinity> \<longrightarrow> x = \<infinity>) \<and>
   843     (y = \<infinity> \<longrightarrow> z \<noteq> \<infinity> \<longrightarrow> x = -\<infinity>)"
   844   by (cases rule: ereal3_cases[of x y z]) auto
   845 
   846 lemma ereal_eq_minus:
   847   fixes x y z :: ereal
   848   shows "\<bar>y\<bar> \<noteq> \<infinity> \<Longrightarrow> x = z - y \<longleftrightarrow> x + y = z"
   849   by (auto simp: ereal_eq_minus_iff)
   850 
   851 lemma ereal_less_minus_iff:
   852   fixes x y z :: ereal
   853   shows "x < z - y \<longleftrightarrow>
   854     (y = \<infinity> \<longrightarrow> z = \<infinity> \<and> x \<noteq> \<infinity>) \<and>
   855     (y = -\<infinity> \<longrightarrow> x \<noteq> \<infinity>) \<and>
   856     (\<bar>y\<bar> \<noteq> \<infinity>\<longrightarrow> x + y < z)"
   857   by (cases rule: ereal3_cases[of x y z]) auto
   858 
   859 lemma ereal_less_minus:
   860   fixes x y z :: ereal
   861   shows "\<bar>y\<bar> \<noteq> \<infinity> \<Longrightarrow> x < z - y \<longleftrightarrow> x + y < z"
   862   by (auto simp: ereal_less_minus_iff)
   863 
   864 lemma ereal_le_minus_iff:
   865   fixes x y z :: ereal
   866   shows "x \<le> z - y \<longleftrightarrow>
   867     (y = \<infinity> \<longrightarrow> z \<noteq> \<infinity> \<longrightarrow> x = -\<infinity>) \<and>
   868     (\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> x + y \<le> z)"
   869   by (cases rule: ereal3_cases[of x y z]) auto
   870 
   871 lemma ereal_le_minus:
   872   fixes x y z :: ereal
   873   shows "\<bar>y\<bar> \<noteq> \<infinity> \<Longrightarrow> x \<le> z - y \<longleftrightarrow> x + y \<le> z"
   874   by (auto simp: ereal_le_minus_iff)
   875 
   876 lemma ereal_minus_less_iff:
   877   fixes x y z :: ereal
   878   shows "x - y < z \<longleftrightarrow>
   879     y \<noteq> -\<infinity> \<and> (y = \<infinity> \<longrightarrow> x \<noteq> \<infinity> \<and> z \<noteq> -\<infinity>) \<and>
   880     (y \<noteq> \<infinity> \<longrightarrow> x < z + y)"
   881   by (cases rule: ereal3_cases[of x y z]) auto
   882 
   883 lemma ereal_minus_less:
   884   fixes x y z :: ereal
   885   shows "\<bar>y\<bar> \<noteq> \<infinity> \<Longrightarrow> x - y < z \<longleftrightarrow> x < z + y"
   886   by (auto simp: ereal_minus_less_iff)
   887 
   888 lemma ereal_minus_le_iff:
   889   fixes x y z :: ereal
   890   shows "x - y \<le> z \<longleftrightarrow>
   891     (y = -\<infinity> \<longrightarrow> z = \<infinity>) \<and>
   892     (y = \<infinity> \<longrightarrow> x = \<infinity> \<longrightarrow> z = \<infinity>) \<and>
   893     (\<bar>y\<bar> \<noteq> \<infinity> \<longrightarrow> x \<le> z + y)"
   894   by (cases rule: ereal3_cases[of x y z]) auto
   895 
   896 lemma ereal_minus_le:
   897   fixes x y z :: ereal
   898   shows "\<bar>y\<bar> \<noteq> \<infinity> \<Longrightarrow> x - y \<le> z \<longleftrightarrow> x \<le> z + y"
   899   by (auto simp: ereal_minus_le_iff)
   900 
   901 lemma ereal_minus_eq_minus_iff:
   902   fixes a b c :: ereal
   903   shows "a - b = a - c \<longleftrightarrow>
   904     b = c \<or> a = \<infinity> \<or> (a = -\<infinity> \<and> b \<noteq> -\<infinity> \<and> c \<noteq> -\<infinity>)"
   905   by (cases rule: ereal3_cases[of a b c]) auto
   906 
   907 lemma ereal_add_le_add_iff:
   908   fixes a b c :: ereal
   909   shows "c + a \<le> c + b \<longleftrightarrow>
   910     a \<le> b \<or> c = \<infinity> \<or> (c = -\<infinity> \<and> a \<noteq> \<infinity> \<and> b \<noteq> \<infinity>)"
   911   by (cases rule: ereal3_cases[of a b c]) (simp_all add: field_simps)
   912 
   913 lemma ereal_mult_le_mult_iff:
   914   fixes a b c :: ereal
   915   shows "\<bar>c\<bar> \<noteq> \<infinity> \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   916   by (cases rule: ereal3_cases[of a b c]) (simp_all add: mult_le_cancel_left)
   917 
   918 lemma ereal_minus_mono:
   919   fixes A B C D :: ereal assumes "A \<le> B" "D \<le> C"
   920   shows "A - C \<le> B - D"
   921   using assms
   922   by (cases rule: ereal3_cases[case_product ereal_cases, of A B C D]) simp_all
   923 
   924 lemma real_of_ereal_minus:
   925   fixes a b :: ereal
   926   shows "real (a - b) = (if \<bar>a\<bar> = \<infinity> \<or> \<bar>b\<bar> = \<infinity> then 0 else real a - real b)"
   927   by (cases rule: ereal2_cases[of a b]) auto
   928 
   929 lemma ereal_diff_positive:
   930   fixes a b :: ereal shows "a \<le> b \<Longrightarrow> 0 \<le> b - a"
   931   by (cases rule: ereal2_cases[of a b]) auto
   932 
   933 lemma ereal_between:
   934   fixes x e :: ereal
   935   assumes "\<bar>x\<bar> \<noteq> \<infinity>" "0 < e"
   936   shows "x - e < x" "x < x + e"
   937 using assms apply (cases x, cases e) apply auto
   938 using assms by (cases x, cases e) auto
   939 
   940 subsubsection {* Division *}
   941 
   942 instantiation ereal :: inverse
   943 begin
   944 
   945 function inverse_ereal where
   946 "inverse (ereal r) = (if r = 0 then \<infinity> else ereal (inverse r))" |
   947 "inverse (\<infinity>::ereal) = 0" |
   948 "inverse (-\<infinity>::ereal) = 0"
   949   by (auto intro: ereal_cases)
   950 termination by (relation "{}") simp
   951 
   952 definition "x / y = x * inverse (y :: ereal)"
   953 
   954 instance proof qed
   955 end
   956 
   957 lemma real_of_ereal_inverse[simp]:
   958   fixes a :: ereal
   959   shows "real (inverse a) = 1 / real a"
   960   by (cases a) (auto simp: inverse_eq_divide)
   961 
   962 lemma ereal_inverse[simp]:
   963   "inverse (0::ereal) = \<infinity>"
   964   "inverse (1::ereal) = 1"
   965   by (simp_all add: one_ereal_def zero_ereal_def)
   966 
   967 lemma ereal_divide[simp]:
   968   "ereal r / ereal p = (if p = 0 then ereal r * \<infinity> else ereal (r / p))"
   969   unfolding divide_ereal_def by (auto simp: divide_real_def)
   970 
   971 lemma ereal_divide_same[simp]:
   972   fixes x :: ereal shows "x / x = (if \<bar>x\<bar> = \<infinity> \<or> x = 0 then 0 else 1)"
   973   by (cases x)
   974      (simp_all add: divide_real_def divide_ereal_def one_ereal_def)
   975 
   976 lemma ereal_inv_inv[simp]:
   977   fixes x :: ereal shows "inverse (inverse x) = (if x \<noteq> -\<infinity> then x else \<infinity>)"
   978   by (cases x) auto
   979 
   980 lemma ereal_inverse_minus[simp]:
   981   fixes x :: ereal shows "inverse (- x) = (if x = 0 then \<infinity> else -inverse x)"
   982   by (cases x) simp_all
   983 
   984 lemma ereal_uminus_divide[simp]:
   985   fixes x y :: ereal shows "- x / y = - (x / y)"
   986   unfolding divide_ereal_def by simp
   987 
   988 lemma ereal_divide_Infty[simp]:
   989   fixes x :: ereal shows "x / \<infinity> = 0" "x / -\<infinity> = 0"
   990   unfolding divide_ereal_def by simp_all
   991 
   992 lemma ereal_divide_one[simp]:
   993   "x / 1 = (x::ereal)"
   994   unfolding divide_ereal_def by simp
   995 
   996 lemma ereal_divide_ereal[simp]:
   997   "\<infinity> / ereal r = (if 0 \<le> r then \<infinity> else -\<infinity>)"
   998   unfolding divide_ereal_def by simp
   999 
  1000 lemma zero_le_divide_ereal[simp]:
  1001   fixes a :: ereal assumes "0 \<le> a" "0 \<le> b"
  1002   shows "0 \<le> a / b"
  1003   using assms by (cases rule: ereal2_cases[of a b]) (auto simp: zero_le_divide_iff)
  1004 
  1005 lemma ereal_le_divide_pos:
  1006   fixes x y z :: ereal shows "x > 0 \<Longrightarrow> x \<noteq> \<infinity> \<Longrightarrow> y \<le> z / x \<longleftrightarrow> x * y \<le> z"
  1007   by (cases rule: ereal3_cases[of x y z]) (auto simp: field_simps)
  1008 
  1009 lemma ereal_divide_le_pos:
  1010   fixes x y z :: ereal shows "x > 0 \<Longrightarrow> x \<noteq> \<infinity> \<Longrightarrow> z / x \<le> y \<longleftrightarrow> z \<le> x * y"
  1011   by (cases rule: ereal3_cases[of x y z]) (auto simp: field_simps)
  1012 
  1013 lemma ereal_le_divide_neg:
  1014   fixes x y z :: ereal shows "x < 0 \<Longrightarrow> x \<noteq> -\<infinity> \<Longrightarrow> y \<le> z / x \<longleftrightarrow> z \<le> x * y"
  1015   by (cases rule: ereal3_cases[of x y z]) (auto simp: field_simps)
  1016 
  1017 lemma ereal_divide_le_neg:
  1018   fixes x y z :: ereal shows "x < 0 \<Longrightarrow> x \<noteq> -\<infinity> \<Longrightarrow> z / x \<le> y \<longleftrightarrow> x * y \<le> z"
  1019   by (cases rule: ereal3_cases[of x y z]) (auto simp: field_simps)
  1020 
  1021 lemma ereal_inverse_antimono_strict:
  1022   fixes x y :: ereal
  1023   shows "0 \<le> x \<Longrightarrow> x < y \<Longrightarrow> inverse y < inverse x"
  1024   by (cases rule: ereal2_cases[of x y]) auto
  1025 
  1026 lemma ereal_inverse_antimono:
  1027   fixes x y :: ereal
  1028   shows "0 \<le> x \<Longrightarrow> x <= y \<Longrightarrow> inverse y <= inverse x"
  1029   by (cases rule: ereal2_cases[of x y]) auto
  1030 
  1031 lemma inverse_inverse_Pinfty_iff[simp]:
  1032   fixes x :: ereal shows "inverse x = \<infinity> \<longleftrightarrow> x = 0"
  1033   by (cases x) auto
  1034 
  1035 lemma ereal_inverse_eq_0:
  1036   fixes x :: ereal shows "inverse x = 0 \<longleftrightarrow> x = \<infinity> \<or> x = -\<infinity>"
  1037   by (cases x) auto
  1038 
  1039 lemma ereal_0_gt_inverse:
  1040   fixes x :: ereal shows "0 < inverse x \<longleftrightarrow> x \<noteq> \<infinity> \<and> 0 \<le> x"
  1041   by (cases x) auto
  1042 
  1043 lemma ereal_mult_less_right:
  1044   fixes a b c :: ereal
  1045   assumes "b * a < c * a" "0 < a" "a < \<infinity>"
  1046   shows "b < c"
  1047   using assms
  1048   by (cases rule: ereal3_cases[of a b c])
  1049      (auto split: split_if_asm simp: zero_less_mult_iff zero_le_mult_iff)
  1050 
  1051 lemma ereal_power_divide:
  1052   fixes x y :: ereal shows "y \<noteq> 0 \<Longrightarrow> (x / y) ^ n = x^n / y^n"
  1053   by (cases rule: ereal2_cases[of x y])
  1054      (auto simp: one_ereal_def zero_ereal_def power_divide not_le
  1055                  power_less_zero_eq zero_le_power_iff)
  1056 
  1057 lemma ereal_le_mult_one_interval:
  1058   fixes x y :: ereal
  1059   assumes y: "y \<noteq> -\<infinity>"
  1060   assumes z: "\<And>z. \<lbrakk> 0 < z ; z < 1 \<rbrakk> \<Longrightarrow> z * x \<le> y"
  1061   shows "x \<le> y"
  1062 proof (cases x)
  1063   case PInf with z[of "1 / 2"] show "x \<le> y" by (simp add: one_ereal_def)
  1064 next
  1065   case (real r) note r = this
  1066   show "x \<le> y"
  1067   proof (cases y)
  1068     case (real p) note p = this
  1069     have "r \<le> p"
  1070     proof (rule field_le_mult_one_interval)
  1071       fix z :: real assume "0 < z" and "z < 1"
  1072       with z[of "ereal z"]
  1073       show "z * r \<le> p" using p r by (auto simp: zero_le_mult_iff one_ereal_def)
  1074     qed
  1075     then show "x \<le> y" using p r by simp
  1076   qed (insert y, simp_all)
  1077 qed simp
  1078 
  1079 subsection "Complete lattice"
  1080 
  1081 instantiation ereal :: lattice
  1082 begin
  1083 definition [simp]: "sup x y = (max x y :: ereal)"
  1084 definition [simp]: "inf x y = (min x y :: ereal)"
  1085 instance proof qed simp_all
  1086 end
  1087 
  1088 instantiation ereal :: complete_lattice
  1089 begin
  1090 
  1091 definition "bot = (-\<infinity>::ereal)"
  1092 definition "top = (\<infinity>::ereal)"
  1093 
  1094 definition "Sup S = (LEAST z. \<forall>x\<in>S. x \<le> z :: ereal)"
  1095 definition "Inf S = (GREATEST z. \<forall>x\<in>S. z \<le> x :: ereal)"
  1096 
  1097 lemma ereal_complete_Sup:
  1098   fixes S :: "ereal set" assumes "S \<noteq> {}"
  1099   shows "\<exists>x. (\<forall>y\<in>S. y \<le> x) \<and> (\<forall>z. (\<forall>y\<in>S. y \<le> z) \<longrightarrow> x \<le> z)"
  1100 proof cases
  1101   assume "\<exists>x. \<forall>a\<in>S. a \<le> ereal x"
  1102   then obtain y where y: "\<And>a. a\<in>S \<Longrightarrow> a \<le> ereal y" by auto
  1103   then have "\<infinity> \<notin> S" by force
  1104   show ?thesis
  1105   proof cases
  1106     assume "S = {-\<infinity>}"
  1107     then show ?thesis by (auto intro!: exI[of _ "-\<infinity>"])
  1108   next
  1109     assume "S \<noteq> {-\<infinity>}"
  1110     with `S \<noteq> {}` `\<infinity> \<notin> S` obtain x where "x \<in> S - {-\<infinity>}" "x \<noteq> \<infinity>" by auto
  1111     with y `\<infinity> \<notin> S` have "\<forall>z\<in>real ` (S - {-\<infinity>}). z \<le> y"
  1112       by (auto simp: real_of_ereal_ord_simps)
  1113     with reals_complete2[of "real ` (S - {-\<infinity>})"] `x \<in> S - {-\<infinity>}`
  1114     obtain s where s:
  1115        "\<forall>y\<in>S - {-\<infinity>}. real y \<le> s" "\<And>z. (\<forall>y\<in>S - {-\<infinity>}. real y \<le> z) \<Longrightarrow> s \<le> z"
  1116        by auto
  1117     show ?thesis
  1118     proof (safe intro!: exI[of _ "ereal s"])
  1119       fix z assume "z \<in> S" with `\<infinity> \<notin> S` show "z \<le> ereal s"
  1120       proof (cases z)
  1121         case (real r)
  1122         then show ?thesis
  1123           using s(1)[rule_format, of z] `z \<in> S` `z = ereal r` by auto
  1124       qed auto
  1125     next
  1126       fix z assume *: "\<forall>y\<in>S. y \<le> z"
  1127       with `S \<noteq> {-\<infinity>}` `S \<noteq> {}` show "ereal s \<le> z"
  1128       proof (cases z)
  1129         case (real u)
  1130         with * have "s \<le> u"
  1131           by (intro s(2)[of u]) (auto simp: real_of_ereal_ord_simps)
  1132         then show ?thesis using real by simp
  1133       qed auto
  1134     qed
  1135   qed
  1136 next
  1137   assume *: "\<not> (\<exists>x. \<forall>a\<in>S. a \<le> ereal x)"
  1138   show ?thesis
  1139   proof (safe intro!: exI[of _ \<infinity>])
  1140     fix y assume **: "\<forall>z\<in>S. z \<le> y"
  1141     with * show "\<infinity> \<le> y"
  1142     proof (cases y)
  1143       case MInf with * ** show ?thesis by (force simp: not_le)
  1144     qed auto
  1145   qed simp
  1146 qed
  1147 
  1148 lemma ereal_complete_Inf:
  1149   fixes S :: "ereal set" assumes "S ~= {}"
  1150   shows "EX x. (ALL y:S. x <= y) & (ALL z. (ALL y:S. z <= y) --> z <= x)"
  1151 proof-
  1152 def S1 == "uminus ` S"
  1153 hence "S1 ~= {}" using assms by auto
  1154 from this obtain x where x_def: "(ALL y:S1. y <= x) & (ALL z. (ALL y:S1. y <= z) --> x <= z)"
  1155    using ereal_complete_Sup[of S1] by auto
  1156 { fix z assume "ALL y:S. z <= y"
  1157   hence "ALL y:S1. y <= -z" unfolding S1_def by auto
  1158   hence "x <= -z" using x_def by auto
  1159   hence "z <= -x"
  1160     apply (subst ereal_uminus_uminus[symmetric])
  1161     unfolding ereal_minus_le_minus . }
  1162 moreover have "(ALL y:S. -x <= y)"
  1163    using x_def unfolding S1_def
  1164    apply simp
  1165    apply (subst (3) ereal_uminus_uminus[symmetric])
  1166    unfolding ereal_minus_le_minus by simp
  1167 ultimately show ?thesis by auto
  1168 qed
  1169 
  1170 lemma ereal_complete_uminus_eq:
  1171   fixes S :: "ereal set"
  1172   shows "(\<forall>y\<in>uminus`S. y \<le> x) \<and> (\<forall>z. (\<forall>y\<in>uminus`S. y \<le> z) \<longrightarrow> x \<le> z)
  1173      \<longleftrightarrow> (\<forall>y\<in>S. -x \<le> y) \<and> (\<forall>z. (\<forall>y\<in>S. z \<le> y) \<longrightarrow> z \<le> -x)"
  1174   by simp (metis ereal_minus_le_minus ereal_uminus_uminus)
  1175 
  1176 lemma ereal_Sup_uminus_image_eq:
  1177   fixes S :: "ereal set"
  1178   shows "Sup (uminus ` S) = - Inf S"
  1179 proof cases
  1180   assume "S = {}"
  1181   moreover have "(THE x. All (op \<le> x)) = (-\<infinity>::ereal)"
  1182     by (rule the_equality) (auto intro!: ereal_bot)
  1183   moreover have "(SOME x. \<forall>y. y \<le> x) = (\<infinity>::ereal)"
  1184     by (rule some_equality) (auto intro!: ereal_top)
  1185   ultimately show ?thesis unfolding Inf_ereal_def Sup_ereal_def
  1186     Least_def Greatest_def GreatestM_def by simp
  1187 next
  1188   assume "S \<noteq> {}"
  1189   with ereal_complete_Sup[of "uminus`S"]
  1190   obtain x where x: "(\<forall>y\<in>S. -x \<le> y) \<and> (\<forall>z. (\<forall>y\<in>S. z \<le> y) \<longrightarrow> z \<le> -x)"
  1191     unfolding ereal_complete_uminus_eq by auto
  1192   show "Sup (uminus ` S) = - Inf S"
  1193     unfolding Inf_ereal_def Greatest_def GreatestM_def
  1194   proof (intro someI2[of _ _ "\<lambda>x. Sup (uminus`S) = - x"])
  1195     show "(\<forall>y\<in>S. -x \<le> y) \<and> (\<forall>y. (\<forall>z\<in>S. y \<le> z) \<longrightarrow> y \<le> -x)"
  1196       using x .
  1197     fix x' assume "(\<forall>y\<in>S. x' \<le> y) \<and> (\<forall>y. (\<forall>z\<in>S. y \<le> z) \<longrightarrow> y \<le> x')"
  1198     then have "(\<forall>y\<in>uminus`S. y \<le> - x') \<and> (\<forall>y. (\<forall>z\<in>uminus`S. z \<le> y) \<longrightarrow> - x' \<le> y)"
  1199       unfolding ereal_complete_uminus_eq by simp
  1200     then show "Sup (uminus ` S) = -x'"
  1201       unfolding Sup_ereal_def ereal_uminus_eq_iff
  1202       by (intro Least_equality) auto
  1203   qed
  1204 qed
  1205 
  1206 instance
  1207 proof
  1208   { fix x :: ereal and A
  1209     show "bot <= x" by (cases x) (simp_all add: bot_ereal_def)
  1210     show "x <= top" by (simp add: top_ereal_def) }
  1211 
  1212   { fix x :: ereal and A assume "x : A"
  1213     with ereal_complete_Sup[of A]
  1214     obtain s where s: "\<forall>y\<in>A. y <= s" "\<forall>z. (\<forall>y\<in>A. y <= z) \<longrightarrow> s <= z" by auto
  1215     hence "x <= s" using `x : A` by auto
  1216     also have "... = Sup A" using s unfolding Sup_ereal_def
  1217       by (auto intro!: Least_equality[symmetric])
  1218     finally show "x <= Sup A" . }
  1219   note le_Sup = this
  1220 
  1221   { fix x :: ereal and A assume *: "!!z. (z : A ==> z <= x)"
  1222     show "Sup A <= x"
  1223     proof (cases "A = {}")
  1224       case True
  1225       hence "Sup A = -\<infinity>" unfolding Sup_ereal_def
  1226         by (auto intro!: Least_equality)
  1227       thus "Sup A <= x" by simp
  1228     next
  1229       case False
  1230       with ereal_complete_Sup[of A]
  1231       obtain s where s: "\<forall>y\<in>A. y <= s" "\<forall>z. (\<forall>y\<in>A. y <= z) \<longrightarrow> s <= z" by auto
  1232       hence "Sup A = s"
  1233         unfolding Sup_ereal_def by (auto intro!: Least_equality)
  1234       also have "s <= x" using * s by auto
  1235       finally show "Sup A <= x" .
  1236     qed }
  1237   note Sup_le = this
  1238 
  1239   { fix x :: ereal and A assume "x \<in> A"
  1240     with le_Sup[of "-x" "uminus`A"] show "Inf A \<le> x"
  1241       unfolding ereal_Sup_uminus_image_eq by simp }
  1242 
  1243   { fix x :: ereal and A assume *: "!!z. (z : A ==> x <= z)"
  1244     with Sup_le[of "uminus`A" "-x"] show "x \<le> Inf A"
  1245       unfolding ereal_Sup_uminus_image_eq by force }
  1246 qed
  1247 
  1248 end
  1249 
  1250 instance ereal :: complete_linorder ..
  1251 
  1252 lemma ereal_SUPR_uminus:
  1253   fixes f :: "'a => ereal"
  1254   shows "(SUP i : R. -(f i)) = -(INF i : R. f i)"
  1255   unfolding SUPR_def INFI_def
  1256   using ereal_Sup_uminus_image_eq[of "f`R"]
  1257   by (simp add: image_image)
  1258 
  1259 lemma ereal_INFI_uminus:
  1260   fixes f :: "'a => ereal"
  1261   shows "(INF i : R. -(f i)) = -(SUP i : R. f i)"
  1262   using ereal_SUPR_uminus[of _ "\<lambda>x. - f x"] by simp
  1263 
  1264 lemma ereal_Inf_uminus_image_eq: "Inf (uminus ` S) = - Sup (S::ereal set)"
  1265   using ereal_Sup_uminus_image_eq[of "uminus ` S"] by (simp add: image_image)
  1266 
  1267 lemma ereal_inj_on_uminus[intro, simp]: "inj_on uminus (A :: ereal set)"
  1268   by (auto intro!: inj_onI)
  1269 
  1270 lemma ereal_image_uminus_shift:
  1271   fixes X Y :: "ereal set" shows "uminus ` X = Y \<longleftrightarrow> X = uminus ` Y"
  1272 proof
  1273   assume "uminus ` X = Y"
  1274   then have "uminus ` uminus ` X = uminus ` Y"
  1275     by (simp add: inj_image_eq_iff)
  1276   then show "X = uminus ` Y" by (simp add: image_image)
  1277 qed (simp add: image_image)
  1278 
  1279 lemma Inf_ereal_iff:
  1280   fixes z :: ereal
  1281   shows "(!!x. x:X ==> z <= x) ==> (EX x:X. x<y) <-> Inf X < y"
  1282   by (metis complete_lattice_class.Inf_greatest complete_lattice_class.Inf_lower less_le_not_le linear
  1283             order_less_le_trans)
  1284 
  1285 lemma Sup_eq_MInfty:
  1286   fixes S :: "ereal set" shows "Sup S = -\<infinity> \<longleftrightarrow> S = {} \<or> S = {-\<infinity>}"
  1287 proof
  1288   assume a: "Sup S = -\<infinity>"
  1289   with complete_lattice_class.Sup_upper[of _ S]
  1290   show "S={} \<or> S={-\<infinity>}" by auto
  1291 next
  1292   assume "S={} \<or> S={-\<infinity>}" then show "Sup S = -\<infinity>"
  1293     unfolding Sup_ereal_def by (auto intro!: Least_equality)
  1294 qed
  1295 
  1296 lemma Inf_eq_PInfty:
  1297   fixes S :: "ereal set" shows "Inf S = \<infinity> \<longleftrightarrow> S = {} \<or> S = {\<infinity>}"
  1298   using Sup_eq_MInfty[of "uminus`S"]
  1299   unfolding ereal_Sup_uminus_image_eq ereal_image_uminus_shift by simp
  1300 
  1301 lemma Inf_eq_MInfty: 
  1302   fixes S :: "ereal set" shows "-\<infinity> \<in> S \<Longrightarrow> Inf S = -\<infinity>"
  1303   unfolding Inf_ereal_def
  1304   by (auto intro!: Greatest_equality)
  1305 
  1306 lemma Sup_eq_PInfty:
  1307   fixes S :: "ereal set" shows "\<infinity> \<in> S \<Longrightarrow> Sup S = \<infinity>"
  1308   unfolding Sup_ereal_def
  1309   by (auto intro!: Least_equality)
  1310 
  1311 lemma ereal_SUPI:
  1312   fixes x :: ereal
  1313   assumes "!!i. i : A ==> f i <= x"
  1314   assumes "!!y. (!!i. i : A ==> f i <= y) ==> x <= y"
  1315   shows "(SUP i:A. f i) = x"
  1316   unfolding SUPR_def Sup_ereal_def
  1317   using assms by (auto intro!: Least_equality)
  1318 
  1319 lemma ereal_INFI:
  1320   fixes x :: ereal
  1321   assumes "!!i. i : A ==> f i >= x"
  1322   assumes "!!y. (!!i. i : A ==> f i >= y) ==> x >= y"
  1323   shows "(INF i:A. f i) = x"
  1324   unfolding INFI_def Inf_ereal_def
  1325   using assms by (auto intro!: Greatest_equality)
  1326 
  1327 lemma Sup_ereal_close:
  1328   fixes e :: ereal
  1329   assumes "0 < e" and S: "\<bar>Sup S\<bar> \<noteq> \<infinity>" "S \<noteq> {}"
  1330   shows "\<exists>x\<in>S. Sup S - e < x"
  1331   using assms by (cases e) (auto intro!: less_Sup_iff[THEN iffD1])
  1332 
  1333 lemma Inf_ereal_close:
  1334   fixes e :: ereal assumes "\<bar>Inf X\<bar> \<noteq> \<infinity>" "0 < e"
  1335   shows "\<exists>x\<in>X. x < Inf X + e"
  1336 proof (rule Inf_less_iff[THEN iffD1])
  1337   show "Inf X < Inf X + e" using assms
  1338     by (cases e) auto
  1339 qed
  1340 
  1341 lemma SUP_nat_Infty: "(SUP i::nat. ereal (real i)) = \<infinity>"
  1342 proof -
  1343   { fix x ::ereal assume "x \<noteq> \<infinity>"
  1344     then have "\<exists>k::nat. x < ereal (real k)"
  1345     proof (cases x)
  1346       case MInf then show ?thesis by (intro exI[of _ 0]) auto
  1347     next
  1348       case (real r)
  1349       moreover obtain k :: nat where "r < real k"
  1350         using ex_less_of_nat by (auto simp: real_eq_of_nat)
  1351       ultimately show ?thesis by auto
  1352     qed simp }
  1353   then show ?thesis
  1354     using SUP_eq_top_iff[of UNIV "\<lambda>n::nat. ereal (real n)"]
  1355     by (auto simp: top_ereal_def)
  1356 qed
  1357 
  1358 lemma ereal_le_Sup:
  1359   fixes x :: ereal
  1360   shows "(x <= (SUP i:A. f i)) <-> (ALL y. y < x --> (EX i. i : A & y <= f i))"
  1361 (is "?lhs <-> ?rhs")
  1362 proof-
  1363 { assume "?rhs"
  1364   { assume "~(x <= (SUP i:A. f i))" hence "(SUP i:A. f i)<x" by (simp add: not_le)
  1365     from this obtain y where y_def: "(SUP i:A. f i)<y & y<x" using ereal_dense by auto
  1366     from this obtain i where "i : A & y <= f i" using `?rhs` by auto
  1367     hence "y <= (SUP i:A. f i)" using le_SUPI[of i A f] by auto
  1368     hence False using y_def by auto
  1369   } hence "?lhs" by auto
  1370 }
  1371 moreover
  1372 { assume "?lhs" hence "?rhs"
  1373   by (metis SUP_leI assms atLeastatMost_empty atLeastatMost_empty_iff
  1374       inf_sup_ord(4) linorder_le_cases sup_absorb1 xt1(8))
  1375 } ultimately show ?thesis by auto
  1376 qed
  1377 
  1378 lemma ereal_Inf_le:
  1379   fixes x :: ereal
  1380   shows "((INF i:A. f i) <= x) <-> (ALL y. x < y --> (EX i. i : A & f i <= y))"
  1381 (is "?lhs <-> ?rhs")
  1382 proof-
  1383 { assume "?rhs"
  1384   { assume "~((INF i:A. f i) <= x)" hence "x < (INF i:A. f i)" by (simp add: not_le)
  1385     from this obtain y where y_def: "x<y & y<(INF i:A. f i)" using ereal_dense by auto
  1386     from this obtain i where "i : A & f i <= y" using `?rhs` by auto
  1387     hence "(INF i:A. f i) <= y" using INF_leI[of i A f] by auto
  1388     hence False using y_def by auto
  1389   } hence "?lhs" by auto
  1390 }
  1391 moreover
  1392 { assume "?lhs" hence "?rhs"
  1393   by (metis le_INFI assms atLeastatMost_empty atLeastatMost_empty_iff
  1394       inf_sup_ord(4) linorder_le_cases sup_absorb1 xt1(8))
  1395 } ultimately show ?thesis by auto
  1396 qed
  1397 
  1398 lemma Inf_less:
  1399   fixes x :: ereal
  1400   assumes "(INF i:A. f i) < x"
  1401   shows "EX i. i : A & f i <= x"
  1402 proof(rule ccontr)
  1403   assume "~ (EX i. i : A & f i <= x)"
  1404   hence "ALL i:A. f i > x" by auto
  1405   hence "(INF i:A. f i) >= x" apply (subst le_INFI) by auto
  1406   thus False using assms by auto
  1407 qed
  1408 
  1409 lemma same_INF:
  1410   assumes "ALL e:A. f e = g e"
  1411   shows "(INF e:A. f e) = (INF e:A. g e)"
  1412 proof-
  1413 have "f ` A = g ` A" unfolding image_def using assms by auto
  1414 thus ?thesis unfolding INFI_def by auto
  1415 qed
  1416 
  1417 lemma same_SUP:
  1418   assumes "ALL e:A. f e = g e"
  1419   shows "(SUP e:A. f e) = (SUP e:A. g e)"
  1420 proof-
  1421 have "f ` A = g ` A" unfolding image_def using assms by auto
  1422 thus ?thesis unfolding SUPR_def by auto
  1423 qed
  1424 
  1425 lemma SUPR_eq:
  1426   assumes "\<forall>i\<in>A. \<exists>j\<in>B. f i \<le> g j"
  1427   assumes "\<forall>j\<in>B. \<exists>i\<in>A. g j \<le> f i"
  1428   shows "(SUP i:A. f i) = (SUP j:B. g j)"
  1429 proof (intro antisym)
  1430   show "(SUP i:A. f i) \<le> (SUP j:B. g j)"
  1431     using assms by (metis SUP_leI le_SUPI2)
  1432   show "(SUP i:B. g i) \<le> (SUP j:A. f j)"
  1433     using assms by (metis SUP_leI le_SUPI2)
  1434 qed
  1435 
  1436 lemma SUP_ereal_le_addI:
  1437   fixes f :: "'i \<Rightarrow> ereal"
  1438   assumes "\<And>i. f i + y \<le> z" and "y \<noteq> -\<infinity>"
  1439   shows "SUPR UNIV f + y \<le> z"
  1440 proof (cases y)
  1441   case (real r)
  1442   then have "\<And>i. f i \<le> z - y" using assms by (simp add: ereal_le_minus_iff)
  1443   then have "SUPR UNIV f \<le> z - y" by (rule SUP_leI)
  1444   then show ?thesis using real by (simp add: ereal_le_minus_iff)
  1445 qed (insert assms, auto)
  1446 
  1447 lemma SUPR_ereal_add:
  1448   fixes f g :: "nat \<Rightarrow> ereal"
  1449   assumes "incseq f" "incseq g" and pos: "\<And>i. f i \<noteq> -\<infinity>" "\<And>i. g i \<noteq> -\<infinity>"
  1450   shows "(SUP i. f i + g i) = SUPR UNIV f + SUPR UNIV g"
  1451 proof (rule ereal_SUPI)
  1452   fix y assume *: "\<And>i. i \<in> UNIV \<Longrightarrow> f i + g i \<le> y"
  1453   have f: "SUPR UNIV f \<noteq> -\<infinity>" using pos
  1454     unfolding SUPR_def Sup_eq_MInfty by (auto dest: image_eqD)
  1455   { fix j
  1456     { fix i
  1457       have "f i + g j \<le> f i + g (max i j)"
  1458         using `incseq g`[THEN incseqD] by (rule add_left_mono) auto
  1459       also have "\<dots> \<le> f (max i j) + g (max i j)"
  1460         using `incseq f`[THEN incseqD] by (rule add_right_mono) auto
  1461       also have "\<dots> \<le> y" using * by auto
  1462       finally have "f i + g j \<le> y" . }
  1463     then have "SUPR UNIV f + g j \<le> y"
  1464       using assms(4)[of j] by (intro SUP_ereal_le_addI) auto
  1465     then have "g j + SUPR UNIV f \<le> y" by (simp add: ac_simps) }
  1466   then have "SUPR UNIV g + SUPR UNIV f \<le> y"
  1467     using f by (rule SUP_ereal_le_addI)
  1468   then show "SUPR UNIV f + SUPR UNIV g \<le> y" by (simp add: ac_simps)
  1469 qed (auto intro!: add_mono le_SUPI)
  1470 
  1471 lemma SUPR_ereal_add_pos:
  1472   fixes f g :: "nat \<Rightarrow> ereal"
  1473   assumes inc: "incseq f" "incseq g" and pos: "\<And>i. 0 \<le> f i" "\<And>i. 0 \<le> g i"
  1474   shows "(SUP i. f i + g i) = SUPR UNIV f + SUPR UNIV g"
  1475 proof (intro SUPR_ereal_add inc)
  1476   fix i show "f i \<noteq> -\<infinity>" "g i \<noteq> -\<infinity>" using pos[of i] by auto
  1477 qed
  1478 
  1479 lemma SUPR_ereal_setsum:
  1480   fixes f g :: "'a \<Rightarrow> nat \<Rightarrow> ereal"
  1481   assumes "\<And>n. n \<in> A \<Longrightarrow> incseq (f n)" and pos: "\<And>n i. n \<in> A \<Longrightarrow> 0 \<le> f n i"
  1482   shows "(SUP i. \<Sum>n\<in>A. f n i) = (\<Sum>n\<in>A. SUPR UNIV (f n))"
  1483 proof cases
  1484   assume "finite A" then show ?thesis using assms
  1485     by induct (auto simp: incseq_setsumI2 setsum_nonneg SUPR_ereal_add_pos)
  1486 qed simp
  1487 
  1488 lemma SUPR_ereal_cmult:
  1489   fixes f :: "nat \<Rightarrow> ereal" assumes "\<And>i. 0 \<le> f i" "0 \<le> c"
  1490   shows "(SUP i. c * f i) = c * SUPR UNIV f"
  1491 proof (rule ereal_SUPI)
  1492   fix i have "f i \<le> SUPR UNIV f" by (rule le_SUPI) auto
  1493   then show "c * f i \<le> c * SUPR UNIV f"
  1494     using `0 \<le> c` by (rule ereal_mult_left_mono)
  1495 next
  1496   fix y assume *: "\<And>i. i \<in> UNIV \<Longrightarrow> c * f i \<le> y"
  1497   show "c * SUPR UNIV f \<le> y"
  1498   proof cases
  1499     assume c: "0 < c \<and> c \<noteq> \<infinity>"
  1500     with * have "SUPR UNIV f \<le> y / c"
  1501       by (intro SUP_leI) (auto simp: ereal_le_divide_pos)
  1502     with c show ?thesis
  1503       by (auto simp: ereal_le_divide_pos)
  1504   next
  1505     { assume "c = \<infinity>" have ?thesis
  1506       proof cases
  1507         assume "\<forall>i. f i = 0"
  1508         moreover then have "range f = {0}" by auto
  1509         ultimately show "c * SUPR UNIV f \<le> y" using * by (auto simp: SUPR_def)
  1510       next
  1511         assume "\<not> (\<forall>i. f i = 0)"
  1512         then obtain i where "f i \<noteq> 0" by auto
  1513         with *[of i] `c = \<infinity>` `0 \<le> f i` show ?thesis by (auto split: split_if_asm)
  1514       qed }
  1515     moreover assume "\<not> (0 < c \<and> c \<noteq> \<infinity>)"
  1516     ultimately show ?thesis using * `0 \<le> c` by auto
  1517   qed
  1518 qed
  1519 
  1520 lemma SUP_PInfty:
  1521   fixes f :: "'a \<Rightarrow> ereal"
  1522   assumes "\<And>n::nat. \<exists>i\<in>A. ereal (real n) \<le> f i"
  1523   shows "(SUP i:A. f i) = \<infinity>"
  1524   unfolding SUPR_def Sup_eq_top_iff[where 'a=ereal, unfolded top_ereal_def]
  1525   apply simp
  1526 proof safe
  1527   fix x :: ereal assume "x \<noteq> \<infinity>"
  1528   show "\<exists>i\<in>A. x < f i"
  1529   proof (cases x)
  1530     case PInf with `x \<noteq> \<infinity>` show ?thesis by simp
  1531   next
  1532     case MInf with assms[of "0"] show ?thesis by force
  1533   next
  1534     case (real r)
  1535     with less_PInf_Ex_of_nat[of x] obtain n :: nat where "x < ereal (real n)" by auto
  1536     moreover from assms[of n] guess i ..
  1537     ultimately show ?thesis
  1538       by (auto intro!: bexI[of _ i])
  1539   qed
  1540 qed
  1541 
  1542 lemma Sup_countable_SUPR:
  1543   assumes "A \<noteq> {}"
  1544   shows "\<exists>f::nat \<Rightarrow> ereal. range f \<subseteq> A \<and> Sup A = SUPR UNIV f"
  1545 proof (cases "Sup A")
  1546   case (real r)
  1547   have "\<forall>n::nat. \<exists>x. x \<in> A \<and> Sup A < x + 1 / ereal (real n)"
  1548   proof
  1549     fix n ::nat have "\<exists>x\<in>A. Sup A - 1 / ereal (real n) < x"
  1550       using assms real by (intro Sup_ereal_close) (auto simp: one_ereal_def)
  1551     then guess x ..
  1552     then show "\<exists>x. x \<in> A \<and> Sup A < x + 1 / ereal (real n)"
  1553       by (auto intro!: exI[of _ x] simp: ereal_minus_less_iff)
  1554   qed
  1555   from choice[OF this] guess f .. note f = this
  1556   have "SUPR UNIV f = Sup A"
  1557   proof (rule ereal_SUPI)
  1558     fix i show "f i \<le> Sup A" using f
  1559       by (auto intro!: complete_lattice_class.Sup_upper)
  1560   next
  1561     fix y assume bound: "\<And>i. i \<in> UNIV \<Longrightarrow> f i \<le> y"
  1562     show "Sup A \<le> y"
  1563     proof (rule ereal_le_epsilon, intro allI impI)
  1564       fix e :: ereal assume "0 < e"
  1565       show "Sup A \<le> y + e"
  1566       proof (cases e)
  1567         case (real r)
  1568         hence "0 < r" using `0 < e` by auto
  1569         then obtain n ::nat where *: "1 / real n < r" "0 < n"
  1570           using ex_inverse_of_nat_less by (auto simp: real_eq_of_nat inverse_eq_divide)
  1571         have "Sup A \<le> f n + 1 / ereal (real n)" using f[THEN spec, of n] by auto
  1572         also have "1 / ereal (real n) \<le> e" using real * by (auto simp: one_ereal_def )
  1573         with bound have "f n + 1 / ereal (real n) \<le> y + e" by (rule add_mono) simp
  1574         finally show "Sup A \<le> y + e" .
  1575       qed (insert `0 < e`, auto)
  1576     qed
  1577   qed
  1578   with f show ?thesis by (auto intro!: exI[of _ f])
  1579 next
  1580   case PInf
  1581   from `A \<noteq> {}` obtain x where "x \<in> A" by auto
  1582   show ?thesis
  1583   proof cases
  1584     assume "\<infinity> \<in> A"
  1585     moreover then have "\<infinity> \<le> Sup A" by (intro complete_lattice_class.Sup_upper)
  1586     ultimately show ?thesis by (auto intro!: exI[of _ "\<lambda>x. \<infinity>"])
  1587   next
  1588     assume "\<infinity> \<notin> A"
  1589     have "\<exists>x\<in>A. 0 \<le> x"
  1590       by (metis Infty_neq_0 PInf complete_lattice_class.Sup_least ereal_infty_less_eq2 linorder_linear)
  1591     then obtain x where "x \<in> A" "0 \<le> x" by auto
  1592     have "\<forall>n::nat. \<exists>f. f \<in> A \<and> x + ereal (real n) \<le> f"
  1593     proof (rule ccontr)
  1594       assume "\<not> ?thesis"
  1595       then have "\<exists>n::nat. Sup A \<le> x + ereal (real n)"
  1596         by (simp add: Sup_le_iff not_le less_imp_le Ball_def) (metis less_imp_le)
  1597       then show False using `x \<in> A` `\<infinity> \<notin> A` PInf
  1598         by(cases x) auto
  1599     qed
  1600     from choice[OF this] guess f .. note f = this
  1601     have "SUPR UNIV f = \<infinity>"
  1602     proof (rule SUP_PInfty)
  1603       fix n :: nat show "\<exists>i\<in>UNIV. ereal (real n) \<le> f i"
  1604         using f[THEN spec, of n] `0 \<le> x`
  1605         by (cases rule: ereal2_cases[of "f n" x]) (auto intro!: exI[of _ n])
  1606     qed
  1607     then show ?thesis using f PInf by (auto intro!: exI[of _ f])
  1608   qed
  1609 next
  1610   case MInf
  1611   with `A \<noteq> {}` have "A = {-\<infinity>}" by (auto simp: Sup_eq_MInfty)
  1612   then show ?thesis using MInf by (auto intro!: exI[of _ "\<lambda>x. -\<infinity>"])
  1613 qed
  1614 
  1615 lemma SUPR_countable_SUPR:
  1616   "A \<noteq> {} \<Longrightarrow> \<exists>f::nat \<Rightarrow> ereal. range f \<subseteq> g`A \<and> SUPR A g = SUPR UNIV f"
  1617   using Sup_countable_SUPR[of "g`A"] by (auto simp: SUPR_def)
  1618 
  1619 lemma Sup_ereal_cadd:
  1620   fixes A :: "ereal set" assumes "A \<noteq> {}" and "a \<noteq> -\<infinity>"
  1621   shows "Sup ((\<lambda>x. a + x) ` A) = a + Sup A"
  1622 proof (rule antisym)
  1623   have *: "\<And>a::ereal. \<And>A. Sup ((\<lambda>x. a + x) ` A) \<le> a + Sup A"
  1624     by (auto intro!: add_mono complete_lattice_class.Sup_least complete_lattice_class.Sup_upper)
  1625   then show "Sup ((\<lambda>x. a + x) ` A) \<le> a + Sup A" .
  1626   show "a + Sup A \<le> Sup ((\<lambda>x. a + x) ` A)"
  1627   proof (cases a)
  1628     case PInf with `A \<noteq> {}` show ?thesis by (auto simp: image_constant)
  1629   next
  1630     case (real r)
  1631     then have **: "op + (- a) ` op + a ` A = A"
  1632       by (auto simp: image_iff ac_simps zero_ereal_def[symmetric])
  1633     from *[of "-a" "(\<lambda>x. a + x) ` A"] real show ?thesis unfolding **
  1634       by (cases rule: ereal2_cases[of "Sup A" "Sup (op + a ` A)"]) auto
  1635   qed (insert `a \<noteq> -\<infinity>`, auto)
  1636 qed
  1637 
  1638 lemma Sup_ereal_cminus:
  1639   fixes A :: "ereal set" assumes "A \<noteq> {}" and "a \<noteq> -\<infinity>"
  1640   shows "Sup ((\<lambda>x. a - x) ` A) = a - Inf A"
  1641   using Sup_ereal_cadd[of "uminus ` A" a] assms
  1642   by (simp add: comp_def image_image minus_ereal_def
  1643                  ereal_Sup_uminus_image_eq)
  1644 
  1645 lemma SUPR_ereal_cminus:
  1646   fixes f :: "'i \<Rightarrow> ereal"
  1647   fixes A assumes "A \<noteq> {}" and "a \<noteq> -\<infinity>"
  1648   shows "(SUP x:A. a - f x) = a - (INF x:A. f x)"
  1649   using Sup_ereal_cminus[of "f`A" a] assms
  1650   unfolding SUPR_def INFI_def image_image by auto
  1651 
  1652 lemma Inf_ereal_cminus:
  1653   fixes A :: "ereal set" assumes "A \<noteq> {}" and "\<bar>a\<bar> \<noteq> \<infinity>"
  1654   shows "Inf ((\<lambda>x. a - x) ` A) = a - Sup A"
  1655 proof -
  1656   { fix x have "-a - -x = -(a - x)" using assms by (cases x) auto }
  1657   moreover then have "(\<lambda>x. -a - x)`uminus`A = uminus ` (\<lambda>x. a - x) ` A"
  1658     by (auto simp: image_image)
  1659   ultimately show ?thesis
  1660     using Sup_ereal_cminus[of "uminus ` A" "-a"] assms
  1661     by (auto simp add: ereal_Sup_uminus_image_eq ereal_Inf_uminus_image_eq)
  1662 qed
  1663 
  1664 lemma INFI_ereal_cminus:
  1665   fixes a :: ereal assumes "A \<noteq> {}" and "\<bar>a\<bar> \<noteq> \<infinity>"
  1666   shows "(INF x:A. a - f x) = a - (SUP x:A. f x)"
  1667   using Inf_ereal_cminus[of "f`A" a] assms
  1668   unfolding SUPR_def INFI_def image_image
  1669   by auto
  1670 
  1671 lemma uminus_ereal_add_uminus_uminus:
  1672   fixes a b :: ereal shows "a \<noteq> \<infinity> \<Longrightarrow> b \<noteq> \<infinity> \<Longrightarrow> - (- a + - b) = a + b"
  1673   by (cases rule: ereal2_cases[of a b]) auto
  1674 
  1675 lemma INFI_ereal_add:
  1676   fixes f :: "nat \<Rightarrow> ereal"
  1677   assumes "decseq f" "decseq g" and fin: "\<And>i. f i \<noteq> \<infinity>" "\<And>i. g i \<noteq> \<infinity>"
  1678   shows "(INF i. f i + g i) = INFI UNIV f + INFI UNIV g"
  1679 proof -
  1680   have INF_less: "(INF i. f i) < \<infinity>" "(INF i. g i) < \<infinity>"
  1681     using assms unfolding INF_less_iff by auto
  1682   { fix i from fin[of i] have "- ((- f i) + (- g i)) = f i + g i"
  1683       by (rule uminus_ereal_add_uminus_uminus) }
  1684   then have "(INF i. f i + g i) = (INF i. - ((- f i) + (- g i)))"
  1685     by simp
  1686   also have "\<dots> = INFI UNIV f + INFI UNIV g"
  1687     unfolding ereal_INFI_uminus
  1688     using assms INF_less
  1689     by (subst SUPR_ereal_add)
  1690        (auto simp: ereal_SUPR_uminus intro!: uminus_ereal_add_uminus_uminus)
  1691   finally show ?thesis .
  1692 qed
  1693 
  1694 subsection "Limits on @{typ ereal}"
  1695 
  1696 subsubsection "Topological space"
  1697 
  1698 instantiation ereal :: topological_space
  1699 begin
  1700 
  1701 definition "open A \<longleftrightarrow> open (ereal -` A)
  1702        \<and> (\<infinity> \<in> A \<longrightarrow> (\<exists>x. {ereal x <..} \<subseteq> A))
  1703        \<and> (-\<infinity> \<in> A \<longrightarrow> (\<exists>x. {..<ereal x} \<subseteq> A))"
  1704 
  1705 lemma open_PInfty: "open A \<Longrightarrow> \<infinity> \<in> A \<Longrightarrow> (\<exists>x. {ereal x<..} \<subseteq> A)"
  1706   unfolding open_ereal_def by auto
  1707 
  1708 lemma open_MInfty: "open A \<Longrightarrow> -\<infinity> \<in> A \<Longrightarrow> (\<exists>x. {..<ereal x} \<subseteq> A)"
  1709   unfolding open_ereal_def by auto
  1710 
  1711 lemma open_PInfty2: assumes "open A" "\<infinity> \<in> A" obtains x where "{ereal x<..} \<subseteq> A"
  1712   using open_PInfty[OF assms] by auto
  1713 
  1714 lemma open_MInfty2: assumes "open A" "-\<infinity> \<in> A" obtains x where "{..<ereal x} \<subseteq> A"
  1715   using open_MInfty[OF assms] by auto
  1716 
  1717 lemma ereal_openE: assumes "open A" obtains x y where
  1718   "open (ereal -` A)"
  1719   "\<infinity> \<in> A \<Longrightarrow> {ereal x<..} \<subseteq> A"
  1720   "-\<infinity> \<in> A \<Longrightarrow> {..<ereal y} \<subseteq> A"
  1721   using assms open_ereal_def by auto
  1722 
  1723 instance
  1724 proof
  1725   let ?U = "UNIV::ereal set"
  1726   show "open ?U" unfolding open_ereal_def
  1727     by (auto intro!: exI[of _ 0])
  1728 next
  1729   fix S T::"ereal set" assume "open S" and "open T"
  1730   from `open S`[THEN ereal_openE] guess xS yS .
  1731   moreover from `open T`[THEN ereal_openE] guess xT yT .
  1732   ultimately have
  1733     "open (ereal -` (S \<inter> T))"
  1734     "\<infinity> \<in> S \<inter> T \<Longrightarrow> {ereal (max xS xT) <..} \<subseteq> S \<inter> T"
  1735     "-\<infinity> \<in> S \<inter> T \<Longrightarrow> {..< ereal (min yS yT)} \<subseteq> S \<inter> T"
  1736     by auto
  1737   then show "open (S Int T)" unfolding open_ereal_def by blast
  1738 next
  1739   fix K :: "ereal set set" assume "\<forall>S\<in>K. open S"
  1740   then have *: "\<forall>S. \<exists>x y. S \<in> K \<longrightarrow> open (ereal -` S) \<and>
  1741     (\<infinity> \<in> S \<longrightarrow> {ereal x <..} \<subseteq> S) \<and> (-\<infinity> \<in> S \<longrightarrow> {..< ereal y} \<subseteq> S)"
  1742     by (auto simp: open_ereal_def)
  1743   then show "open (Union K)" unfolding open_ereal_def
  1744   proof (intro conjI impI)
  1745     show "open (ereal -` \<Union>K)"
  1746       using *[THEN choice] by (auto simp: vimage_Union)
  1747   qed ((metis UnionE Union_upper subset_trans *)+)
  1748 qed
  1749 end
  1750 
  1751 lemma open_ereal: "open S \<Longrightarrow> open (ereal ` S)"
  1752   by (auto simp: inj_vimage_image_eq open_ereal_def)
  1753 
  1754 lemma open_ereal_vimage: "open S \<Longrightarrow> open (ereal -` S)"
  1755   unfolding open_ereal_def by auto
  1756 
  1757 lemma open_ereal_lessThan[intro, simp]: "open {..< a :: ereal}"
  1758 proof -
  1759   have "\<And>x. ereal -` {..<ereal x} = {..< x}"
  1760     "ereal -` {..< \<infinity>} = UNIV" "ereal -` {..< -\<infinity>} = {}" by auto
  1761   then show ?thesis by (cases a) (auto simp: open_ereal_def)
  1762 qed
  1763 
  1764 lemma open_ereal_greaterThan[intro, simp]:
  1765   "open {a :: ereal <..}"
  1766 proof -
  1767   have "\<And>x. ereal -` {ereal x<..} = {x<..}"
  1768     "ereal -` {\<infinity><..} = {}" "ereal -` {-\<infinity><..} = UNIV" by auto
  1769   then show ?thesis by (cases a) (auto simp: open_ereal_def)
  1770 qed
  1771 
  1772 lemma ereal_open_greaterThanLessThan[intro, simp]: "open {a::ereal <..< b}"
  1773   unfolding greaterThanLessThan_def by auto
  1774 
  1775 lemma closed_ereal_atLeast[simp, intro]: "closed {a :: ereal ..}"
  1776 proof -
  1777   have "- {a ..} = {..< a}" by auto
  1778   then show "closed {a ..}"
  1779     unfolding closed_def using open_ereal_lessThan by auto
  1780 qed
  1781 
  1782 lemma closed_ereal_atMost[simp, intro]: "closed {.. b :: ereal}"
  1783 proof -
  1784   have "- {.. b} = {b <..}" by auto
  1785   then show "closed {.. b}"
  1786     unfolding closed_def using open_ereal_greaterThan by auto
  1787 qed
  1788 
  1789 lemma closed_ereal_atLeastAtMost[simp, intro]:
  1790   shows "closed {a :: ereal .. b}"
  1791   unfolding atLeastAtMost_def by auto
  1792 
  1793 lemma closed_ereal_singleton:
  1794   "closed {a :: ereal}"
  1795 by (metis atLeastAtMost_singleton closed_ereal_atLeastAtMost)
  1796 
  1797 lemma ereal_open_cont_interval:
  1798   fixes S :: "ereal set"
  1799   assumes "open S" "x \<in> S" "\<bar>x\<bar> \<noteq> \<infinity>"
  1800   obtains e where "e>0" "{x-e <..< x+e} \<subseteq> S"
  1801 proof-
  1802   from `open S` have "open (ereal -` S)" by (rule ereal_openE)
  1803   then obtain e where "0 < e" and e: "\<And>y. dist y (real x) < e \<Longrightarrow> ereal y \<in> S"
  1804     using assms unfolding open_dist by force
  1805   show thesis
  1806   proof (intro that subsetI)
  1807     show "0 < ereal e" using `0 < e` by auto
  1808     fix y assume "y \<in> {x - ereal e<..<x + ereal e}"
  1809     with assms obtain t where "y = ereal t" "dist t (real x) < e"
  1810       apply (cases y) by (auto simp: dist_real_def)
  1811     then show "y \<in> S" using e[of t] by auto
  1812   qed
  1813 qed
  1814 
  1815 lemma ereal_open_cont_interval2:
  1816   fixes S :: "ereal set"
  1817   assumes "open S" "x \<in> S" and x: "\<bar>x\<bar> \<noteq> \<infinity>"
  1818   obtains a b where "a < x" "x < b" "{a <..< b} \<subseteq> S"
  1819 proof-
  1820   guess e using ereal_open_cont_interval[OF assms] .
  1821   with that[of "x-e" "x+e"] ereal_between[OF x, of e]
  1822   show thesis by auto
  1823 qed
  1824 
  1825 instance ereal :: t2_space
  1826 proof
  1827   fix x y :: ereal assume "x ~= y"
  1828   let "?P x (y::ereal)" = "EX U V. open U & open V & x : U & y : V & U Int V = {}"
  1829 
  1830   { fix x y :: ereal assume "x < y"
  1831     from ereal_dense[OF this] obtain z where z: "x < z" "z < y" by auto
  1832     have "?P x y"
  1833       apply (rule exI[of _ "{..<z}"])
  1834       apply (rule exI[of _ "{z<..}"])
  1835       using z by auto }
  1836   note * = this
  1837 
  1838   from `x ~= y`
  1839   show "EX U V. open U & open V & x : U & y : V & U Int V = {}"
  1840   proof (cases rule: linorder_cases)
  1841     assume "x = y" with `x ~= y` show ?thesis by simp
  1842   next assume "x < y" from *[OF this] show ?thesis by auto
  1843   next assume "y < x" from *[OF this] show ?thesis by auto
  1844   qed
  1845 qed
  1846 
  1847 subsubsection {* Convergent sequences *}
  1848 
  1849 lemma lim_ereal[simp]:
  1850   "((\<lambda>n. ereal (f n)) ---> ereal x) net \<longleftrightarrow> (f ---> x) net" (is "?l = ?r")
  1851 proof (intro iffI topological_tendstoI)
  1852   fix S assume "?l" "open S" "x \<in> S"
  1853   then show "eventually (\<lambda>x. f x \<in> S) net"
  1854     using `?l`[THEN topological_tendstoD, OF open_ereal, OF `open S`]
  1855     by (simp add: inj_image_mem_iff)
  1856 next
  1857   fix S assume "?r" "open S" "ereal x \<in> S"
  1858   show "eventually (\<lambda>x. ereal (f x) \<in> S) net"
  1859     using `?r`[THEN topological_tendstoD, OF open_ereal_vimage, OF `open S`]
  1860     using `ereal x \<in> S` by auto
  1861 qed
  1862 
  1863 lemma lim_real_of_ereal[simp]:
  1864   assumes lim: "(f ---> ereal x) net"
  1865   shows "((\<lambda>x. real (f x)) ---> x) net"
  1866 proof (intro topological_tendstoI)
  1867   fix S assume "open S" "x \<in> S"
  1868   then have S: "open S" "ereal x \<in> ereal ` S"
  1869     by (simp_all add: inj_image_mem_iff)
  1870   have "\<forall>x. f x \<in> ereal ` S \<longrightarrow> real (f x) \<in> S" by auto
  1871   from this lim[THEN topological_tendstoD, OF open_ereal, OF S]
  1872   show "eventually (\<lambda>x. real (f x) \<in> S) net"
  1873     by (rule eventually_mono)
  1874 qed
  1875 
  1876 lemma Lim_PInfty: "f ----> \<infinity> <-> (ALL B. EX N. ALL n>=N. f n >= ereal B)" (is "?l = ?r")
  1877 proof
  1878   assume ?r
  1879   show ?l
  1880     apply(rule topological_tendstoI)
  1881     unfolding eventually_sequentially
  1882   proof-
  1883     fix S :: "ereal set" assume "open S" "\<infinity> : S"
  1884     from open_PInfty[OF this] guess B .. note B=this
  1885     from `?r`[rule_format,of "B+1"] guess N .. note N=this
  1886     show "EX N. ALL n>=N. f n : S" apply(rule_tac x=N in exI)
  1887     proof safe case goal1
  1888       have "ereal B < ereal (B + 1)" by auto
  1889       also have "... <= f n" using goal1 N by auto
  1890       finally show ?case using B by fastsimp
  1891     qed
  1892   qed
  1893 next
  1894   assume ?l
  1895   show ?r
  1896   proof fix B::real have "open {ereal B<..}" "\<infinity> : {ereal B<..}" by auto
  1897     from topological_tendstoD[OF `?l` this,unfolded eventually_sequentially]
  1898     guess N .. note N=this
  1899     show "EX N. ALL n>=N. ereal B <= f n" apply(rule_tac x=N in exI) using N by auto
  1900   qed
  1901 qed
  1902 
  1903 
  1904 lemma Lim_MInfty: "f ----> (-\<infinity>) <-> (ALL B. EX N. ALL n>=N. f n <= ereal B)" (is "?l = ?r")
  1905 proof
  1906   assume ?r
  1907   show ?l
  1908     apply(rule topological_tendstoI)
  1909     unfolding eventually_sequentially
  1910   proof-
  1911     fix S :: "ereal set"
  1912     assume "open S" "(-\<infinity>) : S"
  1913     from open_MInfty[OF this] guess B .. note B=this
  1914     from `?r`[rule_format,of "B-(1::real)"] guess N .. note N=this
  1915     show "EX N. ALL n>=N. f n : S" apply(rule_tac x=N in exI)
  1916     proof safe case goal1
  1917       have "ereal (B - 1) >= f n" using goal1 N by auto
  1918       also have "... < ereal B" by auto
  1919       finally show ?case using B by fastsimp
  1920     qed
  1921   qed
  1922 next assume ?l show ?r
  1923   proof fix B::real have "open {..<ereal B}" "(-\<infinity>) : {..<ereal B}" by auto
  1924     from topological_tendstoD[OF `?l` this,unfolded eventually_sequentially]
  1925     guess N .. note N=this
  1926     show "EX N. ALL n>=N. ereal B >= f n" apply(rule_tac x=N in exI) using N by auto
  1927   qed
  1928 qed
  1929 
  1930 
  1931 lemma Lim_bounded_PInfty: assumes lim:"f ----> l" and "!!n. f n <= ereal B" shows "l ~= \<infinity>"
  1932 proof(rule ccontr,unfold not_not) let ?B = "B + 1" assume as:"l=\<infinity>"
  1933   from lim[unfolded this Lim_PInfty,rule_format,of "?B"]
  1934   guess N .. note N=this[rule_format,OF le_refl]
  1935   hence "ereal ?B <= ereal B" using assms(2)[of N] by(rule order_trans)
  1936   hence "ereal ?B < ereal ?B" apply (rule le_less_trans) by auto
  1937   thus False by auto
  1938 qed
  1939 
  1940 
  1941 lemma Lim_bounded_MInfty: assumes lim:"f ----> l" and "!!n. f n >= ereal B" shows "l ~= (-\<infinity>)"
  1942 proof(rule ccontr,unfold not_not) let ?B = "B - 1" assume as:"l=(-\<infinity>)"
  1943   from lim[unfolded this Lim_MInfty,rule_format,of "?B"]
  1944   guess N .. note N=this[rule_format,OF le_refl]
  1945   hence "ereal B <= ereal ?B" using assms(2)[of N] order_trans[of "ereal B" "f N" "ereal(B - 1)"] by blast
  1946   thus False by auto
  1947 qed
  1948 
  1949 
  1950 lemma tendsto_explicit:
  1951   "f ----> f0 <-> (ALL S. open S --> f0 : S --> (EX N. ALL n>=N. f n : S))"
  1952   unfolding tendsto_def eventually_sequentially by auto
  1953 
  1954 
  1955 lemma tendsto_obtains_N:
  1956   assumes "f ----> f0"
  1957   assumes "open S" "f0 : S"
  1958   obtains N where "ALL n>=N. f n : S"
  1959   using tendsto_explicit[of f f0] assms by auto
  1960 
  1961 
  1962 lemma tail_same_limit:
  1963   fixes X Y N
  1964   assumes "X ----> L" "ALL n>=N. X n = Y n"
  1965   shows "Y ----> L"
  1966 proof-
  1967 { fix S assume "open S" and "L:S"
  1968   from this obtain N1 where "ALL n>=N1. X n : S"
  1969      using assms unfolding tendsto_def eventually_sequentially by auto
  1970   hence "ALL n>=max N N1. Y n : S" using assms by auto
  1971   hence "EX N. ALL n>=N. Y n : S" apply(rule_tac x="max N N1" in exI) by auto
  1972 }
  1973 thus ?thesis using tendsto_explicit by auto
  1974 qed
  1975 
  1976 
  1977 lemma Lim_bounded_PInfty2:
  1978 assumes lim:"f ----> l" and "ALL n>=N. f n <= ereal B"
  1979 shows "l ~= \<infinity>"
  1980 proof-
  1981   def g == "(%n. if n>=N then f n else ereal B)"
  1982   hence "g ----> l" using tail_same_limit[of f l N g] lim by auto
  1983   moreover have "!!n. g n <= ereal B" using g_def assms by auto
  1984   ultimately show ?thesis using  Lim_bounded_PInfty by auto
  1985 qed
  1986 
  1987 lemma Lim_bounded_ereal:
  1988   assumes lim:"f ----> (l :: ereal)"
  1989   and "ALL n>=M. f n <= C"
  1990   shows "l<=C"
  1991 proof-
  1992 { assume "l=(-\<infinity>)" hence ?thesis by auto }
  1993 moreover
  1994 { assume "~(l=(-\<infinity>))"
  1995   { assume "C=\<infinity>" hence ?thesis by auto }
  1996   moreover
  1997   { assume "C=(-\<infinity>)" hence "ALL n>=M. f n = (-\<infinity>)" using assms by auto
  1998     hence "l=(-\<infinity>)" using assms
  1999        tendsto_unique[OF trivial_limit_sequentially] tail_same_limit[of "\<lambda>n. -\<infinity>" "-\<infinity>" M f, OF tendsto_const] by auto
  2000     hence ?thesis by auto }
  2001   moreover
  2002   { assume "EX B. C = ereal B"
  2003     from this obtain B where B_def: "C=ereal B" by auto
  2004     hence "~(l=\<infinity>)" using Lim_bounded_PInfty2 assms by auto
  2005     from this obtain m where m_def: "ereal m=l" using `~(l=(-\<infinity>))` by (cases l) auto
  2006     from this obtain N where N_def: "ALL n>=N. f n : {ereal(m - 1) <..< ereal(m+1)}"
  2007        apply (subst tendsto_obtains_N[of f l "{ereal(m - 1) <..< ereal(m+1)}"]) using assms by auto
  2008     { fix n assume "n>=N"
  2009       hence "EX r. ereal r = f n" using N_def by (cases "f n") auto
  2010     } from this obtain g where g_def: "ALL n>=N. ereal (g n) = f n" by metis
  2011     hence "(%n. ereal (g n)) ----> l" using tail_same_limit[of f l N] assms by auto
  2012     hence *: "(%n. g n) ----> m" using m_def by auto
  2013     { fix n assume "n>=max N M"
  2014       hence "ereal (g n) <= ereal B" using assms g_def B_def by auto
  2015       hence "g n <= B" by auto
  2016     } hence "EX N. ALL n>=N. g n <= B" by blast
  2017     hence "m<=B" using * LIMSEQ_le_const2[of g m B] by auto
  2018     hence ?thesis using m_def B_def by auto
  2019   } ultimately have ?thesis by (cases C) auto
  2020 } ultimately show ?thesis by blast
  2021 qed
  2022 
  2023 lemma real_of_ereal_mult[simp]:
  2024   fixes a b :: ereal shows "real (a * b) = real a * real b"
  2025   by (cases rule: ereal2_cases[of a b]) auto
  2026 
  2027 lemma real_of_ereal_eq_0:
  2028   fixes x :: ereal shows "real x = 0 \<longleftrightarrow> x = \<infinity> \<or> x = -\<infinity> \<or> x = 0"
  2029   by (cases x) auto
  2030 
  2031 lemma tendsto_ereal_realD:
  2032   fixes f :: "'a \<Rightarrow> ereal"
  2033   assumes "x \<noteq> 0" and tendsto: "((\<lambda>x. ereal (real (f x))) ---> x) net"
  2034   shows "(f ---> x) net"
  2035 proof (intro topological_tendstoI)
  2036   fix S assume S: "open S" "x \<in> S"
  2037   with `x \<noteq> 0` have "open (S - {0})" "x \<in> S - {0}" by auto
  2038   from tendsto[THEN topological_tendstoD, OF this]
  2039   show "eventually (\<lambda>x. f x \<in> S) net"
  2040     by (rule eventually_rev_mp) (auto simp: ereal_real)
  2041 qed
  2042 
  2043 lemma tendsto_ereal_realI:
  2044   fixes f :: "'a \<Rightarrow> ereal"
  2045   assumes x: "\<bar>x\<bar> \<noteq> \<infinity>" and tendsto: "(f ---> x) net"
  2046   shows "((\<lambda>x. ereal (real (f x))) ---> x) net"
  2047 proof (intro topological_tendstoI)
  2048   fix S assume "open S" "x \<in> S"
  2049   with x have "open (S - {\<infinity>, -\<infinity>})" "x \<in> S - {\<infinity>, -\<infinity>}" by auto
  2050   from tendsto[THEN topological_tendstoD, OF this]
  2051   show "eventually (\<lambda>x. ereal (real (f x)) \<in> S) net"
  2052     by (elim eventually_elim1) (auto simp: ereal_real)
  2053 qed
  2054 
  2055 lemma ereal_mult_cancel_left:
  2056   fixes a b c :: ereal shows "a * b = a * c \<longleftrightarrow>
  2057     ((\<bar>a\<bar> = \<infinity> \<and> 0 < b * c) \<or> a = 0 \<or> b = c)"
  2058   by (cases rule: ereal3_cases[of a b c])
  2059      (simp_all add: zero_less_mult_iff)
  2060 
  2061 lemma ereal_inj_affinity:
  2062   fixes m t :: ereal
  2063   assumes "\<bar>m\<bar> \<noteq> \<infinity>" "m \<noteq> 0" "\<bar>t\<bar> \<noteq> \<infinity>"
  2064   shows "inj_on (\<lambda>x. m * x + t) A"
  2065   using assms
  2066   by (cases rule: ereal2_cases[of m t])
  2067      (auto intro!: inj_onI simp: ereal_add_cancel_right ereal_mult_cancel_left)
  2068 
  2069 lemma ereal_PInfty_eq_plus[simp]:
  2070   fixes a b :: ereal
  2071   shows "\<infinity> = a + b \<longleftrightarrow> a = \<infinity> \<or> b = \<infinity>"
  2072   by (cases rule: ereal2_cases[of a b]) auto
  2073 
  2074 lemma ereal_MInfty_eq_plus[simp]:
  2075   fixes a b :: ereal
  2076   shows "-\<infinity> = a + b \<longleftrightarrow> (a = -\<infinity> \<and> b \<noteq> \<infinity>) \<or> (b = -\<infinity> \<and> a \<noteq> \<infinity>)"
  2077   by (cases rule: ereal2_cases[of a b]) auto
  2078 
  2079 lemma ereal_less_divide_pos:
  2080   fixes x y :: ereal
  2081   shows "x > 0 \<Longrightarrow> x \<noteq> \<infinity> \<Longrightarrow> y < z / x \<longleftrightarrow> x * y < z"
  2082   by (cases rule: ereal3_cases[of x y z]) (auto simp: field_simps)
  2083 
  2084 lemma ereal_divide_less_pos:
  2085   fixes x y z :: ereal
  2086   shows "x > 0 \<Longrightarrow> x \<noteq> \<infinity> \<Longrightarrow> y / x < z \<longleftrightarrow> y < x * z"
  2087   by (cases rule: ereal3_cases[of x y z]) (auto simp: field_simps)
  2088 
  2089 lemma ereal_divide_eq:
  2090   fixes a b c :: ereal
  2091   shows "b \<noteq> 0 \<Longrightarrow> \<bar>b\<bar> \<noteq> \<infinity> \<Longrightarrow> a / b = c \<longleftrightarrow> a = b * c"
  2092   by (cases rule: ereal3_cases[of a b c])
  2093      (simp_all add: field_simps)
  2094 
  2095 lemma ereal_inverse_not_MInfty[simp]: "inverse (a::ereal) \<noteq> -\<infinity>"
  2096   by (cases a) auto
  2097 
  2098 lemma ereal_mult_m1[simp]: "x * ereal (-1) = -x"
  2099   by (cases x) auto
  2100 
  2101 lemma ereal_LimI_finite:
  2102   fixes x :: ereal
  2103   assumes "\<bar>x\<bar> \<noteq> \<infinity>"
  2104   assumes "!!r. 0 < r ==> EX N. ALL n>=N. u n < x + r & x < u n + r"
  2105   shows "u ----> x"
  2106 proof (rule topological_tendstoI, unfold eventually_sequentially)
  2107   obtain rx where rx_def: "x=ereal rx" using assms by (cases x) auto
  2108   fix S assume "open S" "x : S"
  2109   then have "open (ereal -` S)" unfolding open_ereal_def by auto
  2110   with `x \<in> S` obtain r where "0 < r" and dist: "!!y. dist y rx < r ==> ereal y \<in> S"
  2111     unfolding open_real_def rx_def by auto
  2112   then obtain n where
  2113     upper: "!!N. n <= N ==> u N < x + ereal r" and
  2114     lower: "!!N. n <= N ==> x < u N + ereal r" using assms(2)[of "ereal r"] by auto
  2115   show "EX N. ALL n>=N. u n : S"
  2116   proof (safe intro!: exI[of _ n])
  2117     fix N assume "n <= N"
  2118     from upper[OF this] lower[OF this] assms `0 < r`
  2119     have "u N ~: {\<infinity>,(-\<infinity>)}" by auto
  2120     from this obtain ra where ra_def: "(u N) = ereal ra" by (cases "u N") auto
  2121     hence "rx < ra + r" and "ra < rx + r"
  2122        using rx_def assms `0 < r` lower[OF `n <= N`] upper[OF `n <= N`] by auto
  2123     hence "dist (real (u N)) rx < r"
  2124       using rx_def ra_def
  2125       by (auto simp: dist_real_def abs_diff_less_iff field_simps)
  2126     from dist[OF this] show "u N : S" using `u N  ~: {\<infinity>, -\<infinity>}`
  2127       by (auto simp: ereal_real split: split_if_asm)
  2128   qed
  2129 qed
  2130 
  2131 lemma ereal_LimI_finite_iff:
  2132   fixes x :: ereal
  2133   assumes "\<bar>x\<bar> \<noteq> \<infinity>"
  2134   shows "u ----> x <-> (ALL r. 0 < r --> (EX N. ALL n>=N. u n < x + r & x < u n + r))"
  2135   (is "?lhs <-> ?rhs")
  2136 proof
  2137   assume lim: "u ----> x"
  2138   { fix r assume "(r::ereal)>0"
  2139     from this obtain N where N_def: "ALL n>=N. u n : {x - r <..< x + r}"
  2140        apply (subst tendsto_obtains_N[of u x "{x - r <..< x + r}"])
  2141        using lim ereal_between[of x r] assms `r>0` by auto
  2142     hence "EX N. ALL n>=N. u n < x + r & x < u n + r"
  2143       using ereal_minus_less[of r x] by (cases r) auto
  2144   } then show "?rhs" by auto
  2145 next
  2146   assume ?rhs then show "u ----> x"
  2147     using ereal_LimI_finite[of x] assms by auto
  2148 qed
  2149 
  2150 
  2151 subsubsection {* @{text Liminf} and @{text Limsup} *}
  2152 
  2153 definition
  2154   "Liminf net f = (GREATEST l. \<forall>y<l. eventually (\<lambda>x. y < f x) net)"
  2155 
  2156 definition
  2157   "Limsup net f = (LEAST l. \<forall>y>l. eventually (\<lambda>x. f x < y) net)"
  2158 
  2159 lemma Liminf_Sup:
  2160   fixes f :: "'a => 'b::complete_linorder"
  2161   shows "Liminf net f = Sup {l. \<forall>y<l. eventually (\<lambda>x. y < f x) net}"
  2162   by (auto intro!: Greatest_equality complete_lattice_class.Sup_upper simp: less_Sup_iff Liminf_def)
  2163 
  2164 lemma Limsup_Inf:
  2165   fixes f :: "'a => 'b::complete_linorder"
  2166   shows "Limsup net f = Inf {l. \<forall>y>l. eventually (\<lambda>x. f x < y) net}"
  2167   by (auto intro!: Least_equality complete_lattice_class.Inf_lower simp: Inf_less_iff Limsup_def)
  2168 
  2169 lemma ereal_SupI:
  2170   fixes x :: ereal
  2171   assumes "\<And>y. y \<in> A \<Longrightarrow> y \<le> x"
  2172   assumes "\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y"
  2173   shows "Sup A = x"
  2174   unfolding Sup_ereal_def
  2175   using assms by (auto intro!: Least_equality)
  2176 
  2177 lemma ereal_InfI:
  2178   fixes x :: ereal
  2179   assumes "\<And>i. i \<in> A \<Longrightarrow> x \<le> i"
  2180   assumes "\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x"
  2181   shows "Inf A = x"
  2182   unfolding Inf_ereal_def
  2183   using assms by (auto intro!: Greatest_equality)
  2184 
  2185 lemma Limsup_const:
  2186   fixes c :: "'a::complete_linorder"
  2187   assumes ntriv: "\<not> trivial_limit net"
  2188   shows "Limsup net (\<lambda>x. c) = c"
  2189   unfolding Limsup_Inf
  2190 proof (safe intro!: antisym complete_lattice_class.Inf_greatest complete_lattice_class.Inf_lower)
  2191   fix x assume *: "\<forall>y>x. eventually (\<lambda>_. c < y) net"
  2192   show "c \<le> x"
  2193   proof (rule ccontr)
  2194     assume "\<not> c \<le> x" then have "x < c" by auto
  2195     then show False using ntriv * by (auto simp: trivial_limit_def)
  2196   qed
  2197 qed auto
  2198 
  2199 lemma Liminf_const:
  2200   fixes c :: "'a::complete_linorder"
  2201   assumes ntriv: "\<not> trivial_limit net"
  2202   shows "Liminf net (\<lambda>x. c) = c"
  2203   unfolding Liminf_Sup
  2204 proof (safe intro!: antisym complete_lattice_class.Sup_least complete_lattice_class.Sup_upper)
  2205   fix x assume *: "\<forall>y<x. eventually (\<lambda>_. y < c) net"
  2206   show "x \<le> c"
  2207   proof (rule ccontr)
  2208     assume "\<not> x \<le> c" then have "c < x" by auto
  2209     then show False using ntriv * by (auto simp: trivial_limit_def)
  2210   qed
  2211 qed auto
  2212 
  2213 definition (in order) mono_set:
  2214   "mono_set S \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> x \<in> S \<longrightarrow> y \<in> S)"
  2215 
  2216 lemma (in order) mono_greaterThan [intro, simp]: "mono_set {B<..}" unfolding mono_set by auto
  2217 lemma (in order) mono_atLeast [intro, simp]: "mono_set {B..}" unfolding mono_set by auto
  2218 lemma (in order) mono_UNIV [intro, simp]: "mono_set UNIV" unfolding mono_set by auto
  2219 lemma (in order) mono_empty [intro, simp]: "mono_set {}" unfolding mono_set by auto
  2220 
  2221 lemma (in complete_linorder) mono_set_iff:
  2222   fixes S :: "'a set"
  2223   defines "a \<equiv> Inf S"
  2224   shows "mono_set S \<longleftrightarrow> (S = {a <..} \<or> S = {a..})" (is "_ = ?c")
  2225 proof
  2226   assume "mono_set S"
  2227   then have mono: "\<And>x y. x \<le> y \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S" by (auto simp: mono_set)
  2228   show ?c
  2229   proof cases
  2230     assume "a \<in> S"
  2231     show ?c
  2232       using mono[OF _ `a \<in> S`]
  2233       by (auto intro: Inf_lower simp: a_def)
  2234   next
  2235     assume "a \<notin> S"
  2236     have "S = {a <..}"
  2237     proof safe
  2238       fix x assume "x \<in> S"
  2239       then have "a \<le> x" unfolding a_def by (rule Inf_lower)
  2240       then show "a < x" using `x \<in> S` `a \<notin> S` by (cases "a = x") auto
  2241     next
  2242       fix x assume "a < x"
  2243       then obtain y where "y < x" "y \<in> S" unfolding a_def Inf_less_iff ..
  2244       with mono[of y x] show "x \<in> S" by auto
  2245     qed
  2246     then show ?c ..
  2247   qed
  2248 qed auto
  2249 
  2250 lemma lim_imp_Liminf:
  2251   fixes f :: "'a \<Rightarrow> ereal"
  2252   assumes ntriv: "\<not> trivial_limit net"
  2253   assumes lim: "(f ---> f0) net"
  2254   shows "Liminf net f = f0"
  2255   unfolding Liminf_Sup
  2256 proof (safe intro!: ereal_SupI)
  2257   fix y assume *: "\<forall>y'<y. eventually (\<lambda>x. y' < f x) net"
  2258   show "y \<le> f0"
  2259   proof (rule ereal_le_ereal)
  2260     fix B assume "B < y"
  2261     { assume "f0 < B"
  2262       then have "eventually (\<lambda>x. f x < B \<and> B < f x) net"
  2263          using topological_tendstoD[OF lim, of "{..<B}"] *[rule_format, OF `B < y`]
  2264          by (auto intro: eventually_conj)
  2265       also have "(\<lambda>x. f x < B \<and> B < f x) = (\<lambda>x. False)" by (auto simp: fun_eq_iff)
  2266       finally have False using ntriv[unfolded trivial_limit_def] by auto
  2267     } then show "B \<le> f0" by (metis linorder_le_less_linear)
  2268   qed
  2269 next
  2270   fix y assume *: "\<forall>z. z \<in> {l. \<forall>y<l. eventually (\<lambda>x. y < f x) net} \<longrightarrow> z \<le> y"
  2271   show "f0 \<le> y"
  2272   proof (safe intro!: *[rule_format])
  2273     fix y assume "y < f0" then show "eventually (\<lambda>x. y < f x) net"
  2274       using lim[THEN topological_tendstoD, of "{y <..}"] by auto
  2275   qed
  2276 qed
  2277 
  2278 lemma ereal_Liminf_le_Limsup:
  2279   fixes f :: "'a \<Rightarrow> ereal"
  2280   assumes ntriv: "\<not> trivial_limit net"
  2281   shows "Liminf net f \<le> Limsup net f"
  2282   unfolding Limsup_Inf Liminf_Sup
  2283 proof (safe intro!: complete_lattice_class.Inf_greatest  complete_lattice_class.Sup_least)
  2284   fix u v assume *: "\<forall>y<u. eventually (\<lambda>x. y < f x) net" "\<forall>y>v. eventually (\<lambda>x. f x < y) net"
  2285   show "u \<le> v"
  2286   proof (rule ccontr)
  2287     assume "\<not> u \<le> v"
  2288     then obtain t where "t < u" "v < t"
  2289       using ereal_dense[of v u] by (auto simp: not_le)
  2290     then have "eventually (\<lambda>x. t < f x \<and> f x < t) net"
  2291       using * by (auto intro: eventually_conj)
  2292     also have "(\<lambda>x. t < f x \<and> f x < t) = (\<lambda>x. False)" by (auto simp: fun_eq_iff)
  2293     finally show False using ntriv by (auto simp: trivial_limit_def)
  2294   qed
  2295 qed
  2296 
  2297 lemma Liminf_mono:
  2298   fixes f g :: "'a => ereal"
  2299   assumes ev: "eventually (\<lambda>x. f x \<le> g x) net"
  2300   shows "Liminf net f \<le> Liminf net g"
  2301   unfolding Liminf_Sup
  2302 proof (safe intro!: Sup_mono bexI)
  2303   fix a y assume "\<forall>y<a. eventually (\<lambda>x. y < f x) net" and "y < a"
  2304   then have "eventually (\<lambda>x. y < f x) net" by auto
  2305   then show "eventually (\<lambda>x. y < g x) net"
  2306     by (rule eventually_rev_mp) (rule eventually_mono[OF _ ev], auto)
  2307 qed simp
  2308 
  2309 lemma Liminf_eq:
  2310   fixes f g :: "'a \<Rightarrow> ereal"
  2311   assumes "eventually (\<lambda>x. f x = g x) net"
  2312   shows "Liminf net f = Liminf net g"
  2313   by (intro antisym Liminf_mono eventually_mono[OF _ assms]) auto
  2314 
  2315 lemma Liminf_mono_all:
  2316   fixes f g :: "'a \<Rightarrow> ereal"
  2317   assumes "\<And>x. f x \<le> g x"
  2318   shows "Liminf net f \<le> Liminf net g"
  2319   using assms by (intro Liminf_mono always_eventually) auto
  2320 
  2321 lemma Limsup_mono:
  2322   fixes f g :: "'a \<Rightarrow> ereal"
  2323   assumes ev: "eventually (\<lambda>x. f x \<le> g x) net"
  2324   shows "Limsup net f \<le> Limsup net g"
  2325   unfolding Limsup_Inf
  2326 proof (safe intro!: Inf_mono bexI)
  2327   fix a y assume "\<forall>y>a. eventually (\<lambda>x. g x < y) net" and "a < y"
  2328   then have "eventually (\<lambda>x. g x < y) net" by auto
  2329   then show "eventually (\<lambda>x. f x < y) net"
  2330     by (rule eventually_rev_mp) (rule eventually_mono[OF _ ev], auto)
  2331 qed simp
  2332 
  2333 lemma Limsup_mono_all:
  2334   fixes f g :: "'a \<Rightarrow> ereal"
  2335   assumes "\<And>x. f x \<le> g x"
  2336   shows "Limsup net f \<le> Limsup net g"
  2337   using assms by (intro Limsup_mono always_eventually) auto
  2338 
  2339 lemma Limsup_eq:
  2340   fixes f g :: "'a \<Rightarrow> ereal"
  2341   assumes "eventually (\<lambda>x. f x = g x) net"
  2342   shows "Limsup net f = Limsup net g"
  2343   by (intro antisym Limsup_mono eventually_mono[OF _ assms]) auto
  2344 
  2345 abbreviation "liminf \<equiv> Liminf sequentially"
  2346 
  2347 abbreviation "limsup \<equiv> Limsup sequentially"
  2348 
  2349 lemma liminf_SUPR_INFI:
  2350   fixes f :: "nat \<Rightarrow> ereal"
  2351   shows "liminf f = (SUP n. INF m:{n..}. f m)"
  2352   unfolding Liminf_Sup eventually_sequentially
  2353 proof (safe intro!: antisym complete_lattice_class.Sup_least)
  2354   fix x assume *: "\<forall>y<x. \<exists>N. \<forall>n\<ge>N. y < f n" show "x \<le> (SUP n. INF m:{n..}. f m)"
  2355   proof (rule ereal_le_ereal)
  2356     fix y assume "y < x"
  2357     with * obtain N where "\<And>n. N \<le> n \<Longrightarrow> y < f n" by auto
  2358     then have "y \<le> (INF m:{N..}. f m)" by (force simp: le_INF_iff)
  2359     also have "\<dots> \<le> (SUP n. INF m:{n..}. f m)" by (intro le_SUPI) auto
  2360     finally show "y \<le> (SUP n. INF m:{n..}. f m)" .
  2361   qed
  2362 next
  2363   show "(SUP n. INF m:{n..}. f m) \<le> Sup {l. \<forall>y<l. \<exists>N. \<forall>n\<ge>N. y < f n}"
  2364   proof (unfold SUPR_def, safe intro!: Sup_mono bexI)
  2365     fix y n assume "y < INFI {n..} f"
  2366     from less_INFD[OF this] show "\<exists>N. \<forall>n\<ge>N. y < f n" by (intro exI[of _ n]) auto
  2367   qed (rule order_refl)
  2368 qed
  2369 
  2370 lemma tail_same_limsup:
  2371   fixes X Y :: "nat => ereal"
  2372   assumes "\<And>n. N \<le> n \<Longrightarrow> X n = Y n"
  2373   shows "limsup X = limsup Y"
  2374   using Limsup_eq[of X Y sequentially] eventually_sequentially assms by auto
  2375 
  2376 lemma tail_same_liminf:
  2377   fixes X Y :: "nat => ereal"
  2378   assumes "\<And>n. N \<le> n \<Longrightarrow> X n = Y n"
  2379   shows "liminf X = liminf Y"
  2380   using Liminf_eq[of X Y sequentially] eventually_sequentially assms by auto
  2381 
  2382 lemma liminf_mono:
  2383   fixes X Y :: "nat \<Rightarrow> ereal"
  2384   assumes "\<And>n. N \<le> n \<Longrightarrow> X n <= Y n"
  2385   shows "liminf X \<le> liminf Y"
  2386   using Liminf_mono[of X Y sequentially] eventually_sequentially assms by auto
  2387 
  2388 lemma limsup_mono:
  2389   fixes X Y :: "nat => ereal"
  2390   assumes "\<And>n. N \<le> n \<Longrightarrow> X n <= Y n"
  2391   shows "limsup X \<le> limsup Y"
  2392   using Limsup_mono[of X Y sequentially] eventually_sequentially assms by auto
  2393 
  2394 lemma
  2395   fixes X :: "nat \<Rightarrow> ereal"
  2396   shows ereal_incseq_uminus[simp]: "incseq (\<lambda>i. - X i) = decseq X"
  2397     and ereal_decseq_uminus[simp]: "decseq (\<lambda>i. - X i) = incseq X"
  2398   unfolding incseq_def decseq_def by auto
  2399 
  2400 lemma liminf_bounded:
  2401   fixes X Y :: "nat \<Rightarrow> ereal"
  2402   assumes "\<And>n. N \<le> n \<Longrightarrow> C \<le> X n"
  2403   shows "C \<le> liminf X"
  2404   using liminf_mono[of N "\<lambda>n. C" X] assms Liminf_const[of sequentially C] by simp
  2405 
  2406 lemma limsup_bounded:
  2407   fixes X Y :: "nat => ereal"
  2408   assumes "\<And>n. N \<le> n \<Longrightarrow> X n <= C"
  2409   shows "limsup X \<le> C"
  2410   using limsup_mono[of N X "\<lambda>n. C"] assms Limsup_const[of sequentially C] by simp
  2411 
  2412 lemma liminf_bounded_iff:
  2413   fixes x :: "nat \<Rightarrow> ereal"
  2414   shows "C \<le> liminf x \<longleftrightarrow> (\<forall>B<C. \<exists>N. \<forall>n\<ge>N. B < x n)" (is "?lhs <-> ?rhs")
  2415 proof safe
  2416   fix B assume "B < C" "C \<le> liminf x"
  2417   then have "B < liminf x" by auto
  2418   then obtain N where "B < (INF m:{N..}. x m)"
  2419     unfolding liminf_SUPR_INFI SUPR_def less_Sup_iff by auto
  2420   from less_INFD[OF this] show "\<exists>N. \<forall>n\<ge>N. B < x n" by auto
  2421 next
  2422   assume *: "\<forall>B<C. \<exists>N. \<forall>n\<ge>N. B < x n"
  2423   { fix B assume "B<C"
  2424     then obtain N where "\<forall>n\<ge>N. B < x n" using `?rhs` by auto
  2425     hence "B \<le> (INF m:{N..}. x m)" by (intro le_INFI) auto
  2426     also have "... \<le> liminf x" unfolding liminf_SUPR_INFI by (intro le_SUPI) simp
  2427     finally have "B \<le> liminf x" .
  2428   } then show "?lhs" by (metis * leD liminf_bounded linorder_le_less_linear)
  2429 qed
  2430 
  2431 lemma liminf_subseq_mono:
  2432   fixes X :: "nat \<Rightarrow> ereal"
  2433   assumes "subseq r"
  2434   shows "liminf X \<le> liminf (X \<circ> r) "
  2435 proof-
  2436   have "\<And>n. (INF m:{n..}. X m) \<le> (INF m:{n..}. (X \<circ> r) m)"
  2437   proof (safe intro!: INF_mono)
  2438     fix n m :: nat assume "n \<le> m" then show "\<exists>ma\<in>{n..}. X ma \<le> (X \<circ> r) m"
  2439       using seq_suble[OF `subseq r`, of m] by (intro bexI[of _ "r m"]) auto
  2440   qed
  2441   then show ?thesis by (auto intro!: SUP_mono simp: liminf_SUPR_INFI comp_def)
  2442 qed
  2443 
  2444 lemma ereal_real': assumes "\<bar>x\<bar> \<noteq> \<infinity>" shows "ereal (real x) = x"
  2445   using assms by auto
  2446 
  2447 lemma ereal_le_ereal_bounded:
  2448   fixes x y z :: ereal
  2449   assumes "z \<le> y"
  2450   assumes *: "\<And>B. z < B \<Longrightarrow> B < x \<Longrightarrow> B \<le> y"
  2451   shows "x \<le> y"
  2452 proof (rule ereal_le_ereal)
  2453   fix B assume "B < x"
  2454   show "B \<le> y"
  2455   proof cases
  2456     assume "z < B" from *[OF this `B < x`] show "B \<le> y" .
  2457   next
  2458     assume "\<not> z < B" with `z \<le> y` show "B \<le> y" by auto
  2459   qed
  2460 qed
  2461 
  2462 lemma fixes x y :: ereal
  2463   shows Sup_atMost[simp]: "Sup {.. y} = y"
  2464     and Sup_lessThan[simp]: "Sup {..< y} = y"
  2465     and Sup_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Sup { x .. y} = y"
  2466     and Sup_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Sup { x <.. y} = y"
  2467     and Sup_atLeastLessThan[simp]: "x < y \<Longrightarrow> Sup { x ..< y} = y"
  2468   by (auto simp: Sup_ereal_def intro!: Least_equality
  2469            intro: ereal_le_ereal ereal_le_ereal_bounded[of x])
  2470 
  2471 lemma Sup_greaterThanlessThan[simp]:
  2472   fixes x y :: ereal assumes "x < y" shows "Sup { x <..< y} = y"
  2473   unfolding Sup_ereal_def
  2474 proof (intro Least_equality ereal_le_ereal_bounded[of _ _ y])
  2475   fix z assume z: "\<forall>u\<in>{x<..<y}. u \<le> z"
  2476   from ereal_dense[OF `x < y`] guess w .. note w = this
  2477   with z[THEN bspec, of w] show "x \<le> z" by auto
  2478 qed auto
  2479 
  2480 lemma real_ereal_id: "real o ereal = id"
  2481 proof-
  2482 { fix x have "(real o ereal) x = id x" by auto }
  2483 from this show ?thesis using ext by blast
  2484 qed
  2485 
  2486 lemma open_image_ereal: "open(UNIV-{ \<infinity> , (-\<infinity> :: ereal)})"
  2487 by (metis range_ereal open_ereal open_UNIV)
  2488 
  2489 lemma ereal_le_distrib:
  2490   fixes a b c :: ereal shows "c * (a + b) \<le> c * a + c * b"
  2491   by (cases rule: ereal3_cases[of a b c])
  2492      (auto simp add: field_simps not_le mult_le_0_iff mult_less_0_iff)
  2493 
  2494 lemma ereal_pos_distrib:
  2495   fixes a b c :: ereal assumes "0 \<le> c" "c \<noteq> \<infinity>" shows "c * (a + b) = c * a + c * b"
  2496   using assms by (cases rule: ereal3_cases[of a b c])
  2497                  (auto simp add: field_simps not_le mult_le_0_iff mult_less_0_iff)
  2498 
  2499 lemma ereal_pos_le_distrib:
  2500 fixes a b c :: ereal
  2501 assumes "c>=0"
  2502 shows "c * (a + b) <= c * a + c * b"
  2503   using assms by (cases rule: ereal3_cases[of a b c])
  2504                  (auto simp add: field_simps)
  2505 
  2506 lemma ereal_max_mono:
  2507   "[| (a::ereal) <= b; c <= d |] ==> max a c <= max b d"
  2508   by (metis sup_ereal_def sup_mono)
  2509 
  2510 
  2511 lemma ereal_max_least:
  2512   "[| (a::ereal) <= x; c <= x |] ==> max a c <= x"
  2513   by (metis sup_ereal_def sup_least)
  2514 
  2515 subsubsection {* Tests for code generator *}
  2516 
  2517 (* A small list of simple arithmetic expressions *)
  2518 
  2519 value [code] "- \<infinity> :: ereal"
  2520 value [code] "\<bar>-\<infinity>\<bar> :: ereal"
  2521 value [code] "4 + 5 / 4 - ereal 2 :: ereal"
  2522 value [code] "ereal 3 < \<infinity>"
  2523 value [code] "real (\<infinity>::ereal) = 0"
  2524 
  2525 end