src/Pure/drule.ML
author paulson
Thu Oct 17 10:52:59 2002 +0200 (2002-10-17)
changeset 13650 31bd2a8cdbe2
parent 13606 2f121149acfe
child 13659 3cf622f6b0b2
permissions -rw-r--r--
fixing the cut_tac method to work when there are no instantiations and the
supplied theorems have premises
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies        : cterm * cterm -> cterm
    14   val list_implies      : cterm list * cterm -> cterm
    15   val dest_implies      : cterm -> cterm * cterm
    16   val dest_equals       : cterm -> cterm * cterm
    17   val skip_flexpairs    : cterm -> cterm
    18   val strip_imp_prems   : cterm -> cterm list
    19   val strip_imp_concl   : cterm -> cterm
    20   val cprems_of         : thm -> cterm list
    21   val read_insts        :
    22           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    23                   -> (indexname -> typ option) * (indexname -> sort option)
    24                   -> string list -> (string*string)list
    25                   -> (indexname*ctyp)list * (cterm*cterm)list
    26   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    27   val strip_shyps_warning : thm -> thm
    28   val forall_intr_list  : cterm list -> thm -> thm
    29   val forall_intr_frees : thm -> thm
    30   val forall_intr_vars  : thm -> thm
    31   val forall_elim_list  : cterm list -> thm -> thm
    32   val forall_elim_var   : int -> thm -> thm
    33   val forall_elim_vars  : int -> thm -> thm
    34   val gen_all           : thm -> thm
    35   val freeze_thaw       : thm -> thm * (thm -> thm)
    36   val implies_elim_list : thm -> thm list -> thm
    37   val implies_intr_list : cterm list -> thm -> thm
    38   val instantiate       :
    39     (indexname * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes  : thm -> thm
    41   val standard          : thm -> thm
    42   val standard'         : thm -> thm
    43   val rotate_prems      : int -> thm -> thm
    44   val rearrange_prems   : int list -> thm -> thm
    45   val assume_ax         : theory -> string -> thm
    46   val RSN               : thm * (int * thm) -> thm
    47   val RS                : thm * thm -> thm
    48   val RLN               : thm list * (int * thm list) -> thm list
    49   val RL                : thm list * thm list -> thm list
    50   val MRS               : thm list * thm -> thm
    51   val MRL               : thm list list * thm list -> thm list
    52   val OF                : thm * thm list -> thm
    53   val compose           : thm * int * thm -> thm list
    54   val COMP              : thm * thm -> thm
    55   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    56   val read_instantiate  : (string*string)list -> thm -> thm
    57   val cterm_instantiate : (cterm*cterm)list -> thm -> thm
    58   val eq_thm_sg         : thm * thm -> bool
    59   val eq_thm_prop	: thm * thm -> bool
    60   val weak_eq_thm       : thm * thm -> bool
    61   val size_of_thm       : thm -> int
    62   val reflexive_thm     : thm
    63   val symmetric_thm     : thm
    64   val transitive_thm    : thm
    65   val refl_implies      : thm
    66   val symmetric_fun     : thm -> thm
    67   val extensional       : thm -> thm
    68   val imp_cong          : thm
    69   val swap_prems_eq     : thm
    70   val equal_abs_elim    : cterm  -> thm -> thm
    71   val equal_abs_elim_list: cterm list -> thm -> thm
    72   val flexpair_abs_elim_list: cterm list -> thm -> thm
    73   val asm_rl            : thm
    74   val cut_rl            : thm
    75   val revcut_rl         : thm
    76   val thin_rl           : thm
    77   val triv_forall_equality: thm
    78   val swap_prems_rl     : thm
    79   val equal_intr_rule   : thm
    80   val equal_elim_rule1  : thm
    81   val inst              : string -> string -> thm -> thm
    82   val instantiate'      : ctyp option list -> cterm option list -> thm -> thm
    83   val incr_indexes_wrt  : int list -> ctyp list -> cterm list -> thm list -> thm -> thm
    84 end;
    85 
    86 signature DRULE =
    87 sig
    88   include BASIC_DRULE
    89   val strip_comb: cterm -> cterm * cterm list
    90   val rule_attribute: ('a -> thm -> thm) -> 'a attribute
    91   val tag_rule: tag -> thm -> thm
    92   val untag_rule: string -> thm -> thm
    93   val tag: tag -> 'a attribute
    94   val untag: string -> 'a attribute
    95   val get_kind: thm -> string
    96   val kind: string -> 'a attribute
    97   val theoremK: string
    98   val lemmaK: string
    99   val corollaryK: string
   100   val internalK: string
   101   val kind_internal: 'a attribute
   102   val has_internal: tag list -> bool
   103   val impose_hyps: cterm list -> thm -> thm
   104   val satisfy_hyps: thm list -> thm -> thm
   105   val close_derivation: thm -> thm
   106   val local_standard: thm -> thm
   107   val compose_single: thm * int * thm -> thm
   108   val add_rule: thm -> thm list -> thm list
   109   val del_rule: thm -> thm list -> thm list
   110   val add_rules: thm list -> thm list -> thm list
   111   val del_rules: thm list -> thm list -> thm list
   112   val merge_rules: thm list * thm list -> thm list
   113   val norm_hhf_eq: thm
   114   val is_norm_hhf: term -> bool
   115   val norm_hhf: Sign.sg -> term -> term
   116   val triv_goal: thm
   117   val rev_triv_goal: thm
   118   val implies_intr_goals: cterm list -> thm -> thm
   119   val freeze_all: thm -> thm
   120   val mk_triv_goal: cterm -> thm
   121   val tvars_of_terms: term list -> (indexname * sort) list
   122   val vars_of_terms: term list -> (indexname * typ) list
   123   val tvars_of: thm -> (indexname * sort) list
   124   val vars_of: thm -> (indexname * typ) list
   125   val unvarifyT: thm -> thm
   126   val unvarify: thm -> thm
   127   val tvars_intr_list: string list -> thm -> thm * (string * indexname) list
   128   val remdups_rl: thm
   129   val conj_intr: thm -> thm -> thm
   130   val conj_intr_list: thm list -> thm
   131   val conj_elim: thm -> thm * thm
   132   val conj_elim_list: thm -> thm list
   133   val conj_elim_precise: int -> thm -> thm list
   134   val conj_intr_thm: thm
   135   val abs_def: thm -> thm
   136 end;
   137 
   138 structure Drule: DRULE =
   139 struct
   140 
   141 
   142 (** some cterm->cterm operations: much faster than calling cterm_of! **)
   143 
   144 (** SAME NAMES as in structure Logic: use compound identifiers! **)
   145 
   146 (*dest_implies for cterms. Note T=prop below*)
   147 fun dest_implies ct =
   148     case term_of ct of
   149         (Const("==>", _) $ _ $ _) =>
   150             let val (ct1,ct2) = Thm.dest_comb ct
   151             in  (#2 (Thm.dest_comb ct1), ct2)  end
   152       | _ => raise TERM ("dest_implies", [term_of ct]) ;
   153 
   154 fun dest_equals ct =
   155     case term_of ct of
   156         (Const("==", _) $ _ $ _) =>
   157             let val (ct1,ct2) = Thm.dest_comb ct
   158             in  (#2 (Thm.dest_comb ct1), ct2)  end
   159       | _ => raise TERM ("dest_equals", [term_of ct]) ;
   160 
   161 
   162 (*Discard flexflex pairs; return a cterm*)
   163 fun skip_flexpairs ct =
   164     case term_of ct of
   165         (Const("==>", _) $ (Const("=?=",_)$_$_) $ _) =>
   166             skip_flexpairs (#2 (dest_implies ct))
   167       | _ => ct;
   168 
   169 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   170 fun strip_imp_prems ct =
   171     let val (cA,cB) = dest_implies ct
   172     in  cA :: strip_imp_prems cB  end
   173     handle TERM _ => [];
   174 
   175 (* A1==>...An==>B  goes to B, where B is not an implication *)
   176 fun strip_imp_concl ct =
   177     case term_of ct of (Const("==>", _) $ _ $ _) =>
   178         strip_imp_concl (#2 (Thm.dest_comb ct))
   179   | _ => ct;
   180 
   181 (*The premises of a theorem, as a cterm list*)
   182 val cprems_of = strip_imp_prems o skip_flexpairs o cprop_of;
   183 
   184 val proto_sign = Theory.sign_of ProtoPure.thy;
   185 
   186 val implies = cterm_of proto_sign Term.implies;
   187 
   188 (*cterm version of mk_implies*)
   189 fun mk_implies(A,B) = Thm.capply (Thm.capply implies A) B;
   190 
   191 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   192 fun list_implies([], B) = B
   193   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   194 
   195 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   196 fun strip_comb ct = 
   197   let
   198     fun stripc (p as (ct, cts)) =
   199       let val (ct1, ct2) = Thm.dest_comb ct
   200       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   201   in stripc (ct, []) end;
   202 
   203 
   204 (** reading of instantiations **)
   205 
   206 fun absent ixn =
   207   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   208 
   209 fun inst_failure ixn =
   210   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   211 
   212 fun read_insts sign (rtypes,rsorts) (types,sorts) used insts =
   213 let
   214     fun split([],tvs,vs) = (tvs,vs)
   215       | split((sv,st)::l,tvs,vs) = (case Symbol.explode sv of
   216                   "'"::cs => split(l,(Syntax.indexname cs,st)::tvs,vs)
   217                 | cs => split(l,tvs,(Syntax.indexname cs,st)::vs));
   218     val (tvs,vs) = split(insts,[],[]);
   219     fun readT((a,i),st) =
   220         let val ixn = ("'" ^ a,i);
   221             val S = case rsorts ixn of Some S => S | None => absent ixn;
   222             val T = Sign.read_typ (sign,sorts) st;
   223         in if Sign.typ_instance sign (T, TVar(ixn,S)) then (ixn,T)
   224            else inst_failure ixn
   225         end
   226     val tye = map readT tvs;
   227     fun mkty(ixn,st) = (case rtypes ixn of
   228                           Some T => (ixn,(st,typ_subst_TVars tye T))
   229                         | None => absent ixn);
   230     val ixnsTs = map mkty vs;
   231     val ixns = map fst ixnsTs
   232     and sTs  = map snd ixnsTs
   233     val (cts,tye2) = read_def_cterms(sign,types,sorts) used false sTs;
   234     fun mkcVar(ixn,T) =
   235         let val U = typ_subst_TVars tye2 T
   236         in cterm_of sign (Var(ixn,U)) end
   237     val ixnTs = ListPair.zip(ixns, map snd sTs)
   238 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) (tye2 @ tye),
   239     ListPair.zip(map mkcVar ixnTs,cts))
   240 end;
   241 
   242 
   243 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   244      Used for establishing default types (of variables) and sorts (of
   245      type variables) when reading another term.
   246      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   247 ***)
   248 
   249 fun types_sorts thm =
   250     let val {prop,hyps,...} = rep_thm thm;
   251         val big = list_comb(prop,hyps); (* bogus term! *)
   252         val vars = map dest_Var (term_vars big);
   253         val frees = map dest_Free (term_frees big);
   254         val tvars = term_tvars big;
   255         val tfrees = term_tfrees big;
   256         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   257         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   258     in (typ,sort) end;
   259 
   260 
   261 
   262 (** basic attributes **)
   263 
   264 (* dependent rules *)
   265 
   266 fun rule_attribute f (x, thm) = (x, (f x thm));
   267 
   268 
   269 (* add / delete tags *)
   270 
   271 fun map_tags f thm =
   272   Thm.put_name_tags (Thm.name_of_thm thm, f (#2 (Thm.get_name_tags thm))) thm;
   273 
   274 fun tag_rule tg = map_tags (fn tgs => if tg mem tgs then tgs else tgs @ [tg]);
   275 fun untag_rule s = map_tags (filter_out (equal s o #1));
   276 
   277 fun tag tg x = rule_attribute (K (tag_rule tg)) x;
   278 fun untag s x = rule_attribute (K (untag_rule s)) x;
   279 
   280 fun simple_tag name x = tag (name, []) x;
   281 
   282 
   283 (* theorem kinds *)
   284 
   285 val theoremK = "theorem";
   286 val lemmaK = "lemma";
   287 val corollaryK = "corollary";
   288 val internalK = "internal";
   289 
   290 fun get_kind thm =
   291   (case Library.assoc (#2 (Thm.get_name_tags thm), "kind") of
   292     Some (k :: _) => k
   293   | _ => "unknown");
   294 
   295 fun kind_rule k = tag_rule ("kind", [k]) o untag_rule "kind";
   296 fun kind k x = if k = "" then x else rule_attribute (K (kind_rule k)) x;
   297 fun kind_internal x = kind internalK x;
   298 fun has_internal tags = exists (equal internalK o fst) tags;
   299 
   300 
   301 
   302 (** Standardization of rules **)
   303 
   304 (*Strip extraneous shyps as far as possible*)
   305 fun strip_shyps_warning thm =
   306   let
   307     val str_of_sort = Sign.str_of_sort (Thm.sign_of_thm thm);
   308     val thm' = Thm.strip_shyps thm;
   309     val xshyps = Thm.extra_shyps thm';
   310   in
   311     if null xshyps then ()
   312     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   313     thm'
   314   end;
   315 
   316 (*Generalization over a list of variables, IGNORING bad ones*)
   317 fun forall_intr_list [] th = th
   318   | forall_intr_list (y::ys) th =
   319         let val gth = forall_intr_list ys th
   320         in  forall_intr y gth   handle THM _ =>  gth  end;
   321 
   322 (*Generalization over all suitable Free variables*)
   323 fun forall_intr_frees th =
   324     let val {prop,sign,...} = rep_thm th
   325     in  forall_intr_list
   326          (map (cterm_of sign) (sort (make_ord atless) (term_frees prop)))
   327          th
   328     end;
   329 
   330 val forall_elim_var = PureThy.forall_elim_var;
   331 val forall_elim_vars = PureThy.forall_elim_vars;
   332 
   333 fun gen_all thm =
   334   let
   335     val {sign, prop, maxidx, ...} = Thm.rep_thm thm;
   336     fun elim (th, (x, T)) = Thm.forall_elim (Thm.cterm_of sign (Var ((x, maxidx + 1), T))) th;
   337     val vs = Term.strip_all_vars prop;
   338   in foldl elim (thm, Term.variantlist (map #1 vs, []) ~~ map #2 vs) end;
   339 
   340 (*Specialization over a list of cterms*)
   341 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   342 
   343 (* maps A1,...,An |- B   to   [| A1;...;An |] ==> B  *)
   344 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   345 
   346 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   347 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   348 
   349 (* maps |- B to A1,...,An |- B *)
   350 fun impose_hyps chyps th =
   351   let val chyps' = gen_rems (op aconv o apfst Thm.term_of) (chyps, #hyps (Thm.rep_thm th))
   352   in implies_elim_list (implies_intr_list chyps' th) (map Thm.assume chyps') end;
   353 
   354 (* maps A1,...,An and A1,...,An |- B to |- B *)
   355 fun satisfy_hyps ths th =
   356   implies_elim_list (implies_intr_list (map (#prop o Thm.crep_thm) ths) th) ths;
   357 
   358 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   359 fun zero_var_indexes th =
   360     let val {prop,sign,...} = rep_thm th;
   361         val vars = term_vars prop
   362         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   363         val inrs = add_term_tvars(prop,[]);
   364         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   365         val tye = ListPair.map (fn ((v,rs),a) => (v, TVar((a,0),rs)))
   366                      (inrs, nms')
   367         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   368         fun varpairs([],[]) = []
   369           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   370                 let val T' = typ_subst_TVars tye T
   371                 in (cterm_of sign (Var(v,T')),
   372                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   373                 end
   374           | varpairs _ = raise TERM("varpairs", []);
   375     in Thm.instantiate (ctye, varpairs(vars,rev bs)) th end;
   376 
   377 
   378 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   379     all generality expressed by Vars having index 0.*)
   380 
   381 fun close_derivation thm =
   382   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   383   else thm;
   384 
   385 fun standard' th =
   386   let val {maxidx,...} = rep_thm th in
   387     th
   388     |> implies_intr_hyps
   389     |> forall_intr_frees |> forall_elim_vars (maxidx + 1)
   390     |> strip_shyps_warning
   391     |> zero_var_indexes |> Thm.varifyT |> Thm.compress
   392   end;
   393 
   394 val standard = close_derivation o standard';
   395 
   396 fun local_standard th =
   397   th |> strip_shyps |> zero_var_indexes
   398   |> Thm.compress |> close_derivation;
   399 
   400 
   401 (*Convert all Vars in a theorem to Frees.  Also return a function for
   402   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   403   Similar code in type/freeze_thaw*)
   404 fun freeze_thaw th =
   405  let val fth = freezeT th
   406      val {prop,sign,...} = rep_thm fth
   407  in
   408    case term_vars prop of
   409        [] => (fth, fn x => x)
   410      | vars =>
   411          let fun newName (Var(ix,_), (pairs,used)) =
   412                    let val v = variant used (string_of_indexname ix)
   413                    in  ((ix,v)::pairs, v::used)  end;
   414              val (alist, _) = foldr newName
   415                                 (vars, ([], add_term_names (prop, [])))
   416              fun mk_inst (Var(v,T)) =
   417                  (cterm_of sign (Var(v,T)),
   418                   cterm_of sign (Free(the (assoc(alist,v)), T)))
   419              val insts = map mk_inst vars
   420              fun thaw th' =
   421                  th' |> forall_intr_list (map #2 insts)
   422                      |> forall_elim_list (map #1 insts)
   423          in  (Thm.instantiate ([],insts) fth, thaw)  end
   424  end;
   425 
   426 
   427 (*Rotates a rule's premises to the left by k*)
   428 val rotate_prems = permute_prems 0;
   429 
   430 (* permute prems, where the i-th position in the argument list (counting from 0)
   431    gives the position within the original thm to be transferred to position i.
   432    Any remaining trailing positions are left unchanged. *)
   433 val rearrange_prems = let
   434   fun rearr new []      thm = thm
   435   |   rearr new (p::ps) thm = rearr (new+1)
   436      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   437      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   438   in rearr 0 end;
   439 
   440 (*Assume a new formula, read following the same conventions as axioms.
   441   Generalizes over Free variables,
   442   creates the assumption, and then strips quantifiers.
   443   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   444              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   445 fun assume_ax thy sP =
   446     let val sign = Theory.sign_of thy
   447         val prop = Logic.close_form (term_of (read_cterm sign (sP, propT)))
   448     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   449 
   450 (*Resolution: exactly one resolvent must be produced.*)
   451 fun tha RSN (i,thb) =
   452   case Seq.chop (2, biresolution false [(false,tha)] i thb) of
   453       ([th],_) => th
   454     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   455     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   456 
   457 (*resolution: P==>Q, Q==>R gives P==>R. *)
   458 fun tha RS thb = tha RSN (1,thb);
   459 
   460 (*For joining lists of rules*)
   461 fun thas RLN (i,thbs) =
   462   let val resolve = biresolution false (map (pair false) thas) i
   463       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   464   in  List.concat (map resb thbs)  end;
   465 
   466 fun thas RL thbs = thas RLN (1,thbs);
   467 
   468 (*Resolve a list of rules against bottom_rl from right to left;
   469   makes proof trees*)
   470 fun rls MRS bottom_rl =
   471   let fun rs_aux i [] = bottom_rl
   472         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   473   in  rs_aux 1 rls  end;
   474 
   475 (*As above, but for rule lists*)
   476 fun rlss MRL bottom_rls =
   477   let fun rs_aux i [] = bottom_rls
   478         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   479   in  rs_aux 1 rlss  end;
   480 
   481 (*A version of MRS with more appropriate argument order*)
   482 fun bottom_rl OF rls = rls MRS bottom_rl;
   483 
   484 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   485   with no lifting or renaming!  Q may contain ==> or meta-quants
   486   ALWAYS deletes premise i *)
   487 fun compose(tha,i,thb) =
   488     Seq.list_of (bicompose false (false,tha,0) i thb);
   489 
   490 fun compose_single (tha,i,thb) =
   491   (case compose (tha,i,thb) of
   492     [th] => th
   493   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   494 
   495 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   496 fun tha COMP thb =
   497     case compose(tha,1,thb) of
   498         [th] => th
   499       | _ =>   raise THM("COMP", 1, [tha,thb]);
   500 
   501 
   502 (** theorem equality **)
   503 
   504 (*True if the two theorems have the same signature.*)
   505 val eq_thm_sg = Sign.eq_sg o pairself Thm.sign_of_thm;
   506 
   507 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   508 val eq_thm_prop = op aconv o pairself Thm.prop_of;
   509 
   510 (*Useful "distance" function for BEST_FIRST*)
   511 val size_of_thm = size_of_term o prop_of;
   512 
   513 (*maintain lists of theorems --- preserving canonical order*)
   514 fun del_rules rs rules = Library.gen_rems eq_thm_prop (rules, rs);
   515 fun add_rules rs rules = rs @ del_rules rs rules;
   516 val del_rule = del_rules o single;
   517 val add_rule = add_rules o single;
   518 fun merge_rules (rules1, rules2) = gen_merge_lists' eq_thm_prop rules1 rules2;
   519 
   520 
   521 (** Mark Staples's weaker version of eq_thm: ignores variable renaming and
   522     (some) type variable renaming **)
   523 
   524  (* Can't use term_vars, because it sorts the resulting list of variable names.
   525     We instead need the unique list noramlised by the order of appearance
   526     in the term. *)
   527 fun term_vars' (t as Var(v,T)) = [t]
   528   | term_vars' (Abs(_,_,b)) = term_vars' b
   529   | term_vars' (f$a) = (term_vars' f) @ (term_vars' a)
   530   | term_vars' _ = [];
   531 
   532 fun forall_intr_vars th =
   533   let val {prop,sign,...} = rep_thm th;
   534       val vars = distinct (term_vars' prop);
   535   in forall_intr_list (map (cterm_of sign) vars) th end;
   536 
   537 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   538 
   539 
   540 (*** Meta-Rewriting Rules ***)
   541 
   542 fun read_prop s = read_cterm proto_sign (s, propT);
   543 
   544 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   545 fun store_standard_thm name thm = store_thm name (standard thm);
   546 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   547 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   548 
   549 val reflexive_thm =
   550   let val cx = cterm_of proto_sign (Var(("x",0),TVar(("'a",0),logicS)))
   551   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   552 
   553 val symmetric_thm =
   554   let val xy = read_prop "x::'a::logic == y"
   555   in store_standard_thm_open "symmetric" (Thm.implies_intr_hyps (Thm.symmetric (Thm.assume xy))) end;
   556 
   557 val transitive_thm =
   558   let val xy = read_prop "x::'a::logic == y"
   559       val yz = read_prop "y::'a::logic == z"
   560       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   561   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   562 
   563 fun symmetric_fun thm = thm RS symmetric_thm;
   564 
   565 fun extensional eq =
   566   let val eq' =
   567     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   568   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   569 
   570 val imp_cong =
   571   let
   572     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   573     val AB = read_prop "PROP A ==> PROP B"
   574     val AC = read_prop "PROP A ==> PROP C"
   575     val A = read_prop "PROP A"
   576   in
   577     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   578       (implies_intr AB (implies_intr A
   579         (equal_elim (implies_elim (assume ABC) (assume A))
   580           (implies_elim (assume AB) (assume A)))))
   581       (implies_intr AC (implies_intr A
   582         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   583           (implies_elim (assume AC) (assume A)))))))
   584   end;
   585 
   586 val swap_prems_eq =
   587   let
   588     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   589     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   590     val A = read_prop "PROP A"
   591     val B = read_prop "PROP B"
   592   in
   593     store_standard_thm_open "swap_prems_eq" (equal_intr
   594       (implies_intr ABC (implies_intr B (implies_intr A
   595         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   596       (implies_intr BAC (implies_intr A (implies_intr B
   597         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   598   end;
   599 
   600 val refl_implies = reflexive implies;
   601 
   602 fun abs_def thm =
   603   let
   604     val (_, cvs) = strip_comb (fst (dest_equals (cprop_of thm)));
   605     val thm' = foldr (fn (ct, thm) => Thm.abstract_rule
   606       (case term_of ct of Var ((a, _), _) => a | Free (a, _) => a | _ => "x")
   607         ct thm) (cvs, thm)
   608   in transitive
   609     (symmetric (eta_conversion (fst (dest_equals (cprop_of thm'))))) thm'
   610   end;
   611 
   612 
   613 (*** Some useful meta-theorems ***)
   614 
   615 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   616 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   617 val _ = store_thm "_" asm_rl;
   618 
   619 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   620 val cut_rl =
   621   store_standard_thm_open "cut_rl"
   622     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   623 
   624 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   625      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   626 val revcut_rl =
   627   let val V = read_prop "PROP V"
   628       and VW = read_prop "PROP V ==> PROP W";
   629   in
   630     store_standard_thm_open "revcut_rl"
   631       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   632   end;
   633 
   634 (*for deleting an unwanted assumption*)
   635 val thin_rl =
   636   let val V = read_prop "PROP V"
   637       and W = read_prop "PROP W";
   638   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   639 
   640 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   641 val triv_forall_equality =
   642   let val V  = read_prop "PROP V"
   643       and QV = read_prop "!!x::'a. PROP V"
   644       and x  = read_cterm proto_sign ("x", TypeInfer.logicT);
   645   in
   646     store_standard_thm_open "triv_forall_equality"
   647       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   648         (implies_intr V  (forall_intr x (assume V))))
   649   end;
   650 
   651 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   652    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   653    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   654 *)
   655 val swap_prems_rl =
   656   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   657       val major = assume cmajor;
   658       val cminor1 = read_prop "PROP PhiA";
   659       val minor1 = assume cminor1;
   660       val cminor2 = read_prop "PROP PhiB";
   661       val minor2 = assume cminor2;
   662   in store_standard_thm_open "swap_prems_rl"
   663        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   664          (implies_elim (implies_elim major minor1) minor2))))
   665   end;
   666 
   667 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   668    ==> PROP ?phi == PROP ?psi
   669    Introduction rule for == as a meta-theorem.
   670 *)
   671 val equal_intr_rule =
   672   let val PQ = read_prop "PROP phi ==> PROP psi"
   673       and QP = read_prop "PROP psi ==> PROP phi"
   674   in
   675     store_standard_thm_open "equal_intr_rule"
   676       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   677   end;
   678 
   679 (* [| PROP ?phi == PROP ?psi; PROP ?phi |] ==> PROP ?psi *)
   680 val equal_elim_rule1 =
   681   let val eq = read_prop "PROP phi == PROP psi"
   682       and P = read_prop "PROP phi"
   683   in store_standard_thm_open "equal_elim_rule1"
   684     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   685   end;
   686 
   687 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   688 
   689 val remdups_rl =
   690   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   691   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   692 
   693 
   694 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   695   Rewrite rule for HHF normalization.*)
   696 
   697 val norm_hhf_eq =
   698   let
   699     val cert = Thm.cterm_of proto_sign;
   700     val aT = TFree ("'a", Term.logicS);
   701     val all = Term.all aT;
   702     val x = Free ("x", aT);
   703     val phi = Free ("phi", propT);
   704     val psi = Free ("psi", aT --> propT);
   705 
   706     val cx = cert x;
   707     val cphi = cert phi;
   708     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   709     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   710   in
   711     Thm.equal_intr
   712       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   713         |> Thm.forall_elim cx
   714         |> Thm.implies_intr cphi
   715         |> Thm.forall_intr cx
   716         |> Thm.implies_intr lhs)
   717       (Thm.implies_elim
   718           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   719         |> Thm.forall_intr cx
   720         |> Thm.implies_intr cphi
   721         |> Thm.implies_intr rhs)
   722     |> store_standard_thm_open "norm_hhf_eq"
   723   end;
   724 
   725 fun is_norm_hhf tm =
   726   let
   727     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   728       | is_norm (t $ u) = is_norm t andalso is_norm u
   729       | is_norm (Abs (_, _, t)) = is_norm t
   730       | is_norm _ = true;
   731   in is_norm (Pattern.beta_eta_contract tm) end;
   732 
   733 fun norm_hhf sg t =
   734   if is_norm_hhf t then t
   735   else Pattern.rewrite_term (Sign.tsig_of sg) [Logic.dest_equals (prop_of norm_hhf_eq)] [] t;
   736 
   737 
   738 (*** Instantiate theorem th, reading instantiations under signature sg ****)
   739 
   740 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   741 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   742 
   743 fun read_instantiate_sg sg sinsts th =
   744     let val ts = types_sorts th;
   745         val used = add_term_tvarnames (prop_of th, []);
   746     in  instantiate (read_insts sg ts ts used sinsts) th  end;
   747 
   748 (*Instantiate theorem th, reading instantiations under theory of th*)
   749 fun read_instantiate sinsts th =
   750     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   751 
   752 
   753 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   754   Instantiates distinct Vars by terms, inferring type instantiations. *)
   755 local
   756   fun add_types ((ct,cu), (sign,tye,maxidx)) =
   757     let val {sign=signt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   758         and {sign=signu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   759         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   760         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   761         val (tye',maxi') = Type.unify (#tsig(Sign.rep_sg sign')) (tye, maxi) (T, U)
   762           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   763     in  (sign', tye', maxi')  end;
   764 in
   765 fun cterm_instantiate ctpairs0 th =
   766   let val (sign,tye,_) = foldr add_types (ctpairs0, (#sign(rep_thm th), Vartab.empty, 0))
   767       fun instT(ct,cu) = let val inst = subst_TVars_Vartab tye
   768                          in (cterm_fun inst ct, cterm_fun inst cu) end
   769       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   770   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   771   handle TERM _ =>
   772            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   773        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   774 end;
   775 
   776 
   777 (** Derived rules mainly for METAHYPS **)
   778 
   779 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   780 fun equal_abs_elim ca eqth =
   781   let val {sign=signa, t=a, ...} = rep_cterm ca
   782       and combth = combination eqth (reflexive ca)
   783       val {sign,prop,...} = rep_thm eqth
   784       val (abst,absu) = Logic.dest_equals prop
   785       val cterm = cterm_of (Sign.merge (sign,signa))
   786   in  transitive (symmetric (beta_conversion false (cterm (abst$a))))
   787            (transitive combth (beta_conversion false (cterm (absu$a))))
   788   end
   789   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   790 
   791 (*Calling equal_abs_elim with multiple terms*)
   792 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   793 
   794 local
   795   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   796   fun err th = raise THM("flexpair_inst: ", 0, [th])
   797   fun flexpair_inst def th =
   798     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   799         val cterm = cterm_of sign
   800         fun cvar a = cterm(Var((a,0),alpha))
   801         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   802                    def
   803     in  equal_elim def' th
   804     end
   805     handle THM _ => err th | Bind => err th
   806 in
   807 val flexpair_intr = flexpair_inst (symmetric ProtoPure.flexpair_def)
   808 and flexpair_elim = flexpair_inst ProtoPure.flexpair_def
   809 end;
   810 
   811 (*Version for flexflex pairs -- this supports lifting.*)
   812 fun flexpair_abs_elim_list cts =
   813     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   814 
   815 
   816 (*** Goal (PROP A) <==> PROP A ***)
   817 
   818 local
   819   val cert = Thm.cterm_of proto_sign;
   820   val A = Free ("A", propT);
   821   val G = Logic.mk_goal A;
   822   val (G_def, _) = freeze_thaw ProtoPure.Goal_def;
   823 in
   824   val triv_goal = store_thm "triv_goal" (kind_rule internalK (standard
   825       (Thm.equal_elim (Thm.symmetric G_def) (Thm.assume (cert A)))));
   826   val rev_triv_goal = store_thm "rev_triv_goal" (kind_rule internalK (standard
   827       (Thm.equal_elim G_def (Thm.assume (cert G)))));
   828 end;
   829 
   830 val mk_cgoal = Thm.capply (Thm.cterm_of proto_sign Logic.goal_const);
   831 fun assume_goal ct = Thm.assume (mk_cgoal ct) RS rev_triv_goal;
   832 
   833 fun implies_intr_goals cprops thm =
   834   implies_elim_list (implies_intr_list cprops thm) (map assume_goal cprops)
   835   |> implies_intr_list (map mk_cgoal cprops);
   836 
   837 
   838 
   839 (** variations on instantiate **)
   840 
   841 (*shorthand for instantiating just one variable in the current theory*)
   842 fun inst x t = read_instantiate_sg (sign_of (the_context())) [(x,t)];
   843 
   844 
   845 (* collect vars in left-to-right order *)
   846 
   847 fun tvars_of_terms ts = rev (foldl Term.add_tvars ([], ts));
   848 fun vars_of_terms ts = rev (foldl Term.add_vars ([], ts));
   849 
   850 fun tvars_of thm = tvars_of_terms [prop_of thm];
   851 fun vars_of thm = vars_of_terms [prop_of thm];
   852 
   853 
   854 (* instantiate by left-to-right occurrence of variables *)
   855 
   856 fun instantiate' cTs cts thm =
   857   let
   858     fun err msg =
   859       raise TYPE ("instantiate': " ^ msg,
   860         mapfilter (apsome Thm.typ_of) cTs,
   861         mapfilter (apsome Thm.term_of) cts);
   862 
   863     fun inst_of (v, ct) =
   864       (Thm.cterm_of (#sign (Thm.rep_cterm ct)) (Var v), ct)
   865         handle TYPE (msg, _, _) => err msg;
   866 
   867     fun zip_vars _ [] = []
   868       | zip_vars (_ :: vs) (None :: opt_ts) = zip_vars vs opt_ts
   869       | zip_vars (v :: vs) (Some t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
   870       | zip_vars [] _ = err "more instantiations than variables in thm";
   871 
   872     (*instantiate types first!*)
   873     val thm' =
   874       if forall is_none cTs then thm
   875       else Thm.instantiate (zip_vars (map fst (tvars_of thm)) cTs, []) thm;
   876     in
   877       if forall is_none cts then thm'
   878       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
   879     end;
   880 
   881 
   882 (* unvarify(T) *)
   883 
   884 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
   885 
   886 fun unvarifyT thm =
   887   let
   888     val cT = Thm.ctyp_of (Thm.sign_of_thm thm);
   889     val tfrees = map (fn ((x, _), S) => Some (cT (TFree (x, S)))) (tvars_of thm);
   890   in instantiate' tfrees [] thm end;
   891 
   892 fun unvarify raw_thm =
   893   let
   894     val thm = unvarifyT raw_thm;
   895     val ct = Thm.cterm_of (Thm.sign_of_thm thm);
   896     val frees = map (fn ((x, _), T) => Some (ct (Free (x, T)))) (vars_of thm);
   897   in instantiate' [] frees thm end;
   898 
   899 
   900 (* tvars_intr_list *)
   901 
   902 fun tfrees_of thm =
   903   let val {hyps, prop, ...} = Thm.rep_thm thm
   904   in foldr Term.add_term_tfree_names (prop :: hyps, []) end;
   905 
   906 fun tvars_intr_list tfrees thm =
   907   Thm.varifyT' (tfrees_of thm \\ tfrees) thm;
   908 
   909 
   910 (* increment var indexes *)
   911 
   912 fun incr_indexes_wrt is cTs cts thms =
   913   let
   914     val maxidx =
   915       foldl Int.max (~1, is @
   916         map (maxidx_of_typ o #T o Thm.rep_ctyp) cTs @
   917         map (#maxidx o Thm.rep_cterm) cts @
   918         map (#maxidx o Thm.rep_thm) thms);
   919   in Thm.incr_indexes (maxidx + 1) end;
   920 
   921 
   922 (* freeze_all *)
   923 
   924 (*freeze all (T)Vars; assumes thm in standard form*)
   925 
   926 fun freeze_all_TVars thm =
   927   (case tvars_of thm of
   928     [] => thm
   929   | tvars =>
   930       let val cert = Thm.ctyp_of (Thm.sign_of_thm thm)
   931       in instantiate' (map (fn ((x, _), S) => Some (cert (TFree (x, S)))) tvars) [] thm end);
   932 
   933 fun freeze_all_Vars thm =
   934   (case vars_of thm of
   935     [] => thm
   936   | vars =>
   937       let val cert = Thm.cterm_of (Thm.sign_of_thm thm)
   938       in instantiate' [] (map (fn ((x, _), T) => Some (cert (Free (x, T)))) vars) thm end);
   939 
   940 val freeze_all = freeze_all_Vars o freeze_all_TVars;
   941 
   942 
   943 (* mk_triv_goal *)
   944 
   945 (*make an initial proof state, "PROP A ==> (PROP A)" *)
   946 fun mk_triv_goal ct = instantiate' [] [Some ct] triv_goal;
   947 
   948 
   949 
   950 (** meta-level conjunction **)
   951 
   952 local
   953   val A = read_prop "PROP A";
   954   val B = read_prop "PROP B";
   955   val C = read_prop "PROP C";
   956   val ABC = read_prop "PROP A ==> PROP B ==> PROP C";
   957 
   958   val proj1 =
   959     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume A))
   960     |> forall_elim_vars 0;
   961 
   962   val proj2 =
   963     forall_intr_list [A, B] (implies_intr_list [A, B] (Thm.assume B))
   964     |> forall_elim_vars 0;
   965 
   966   val conj_intr_rule =
   967     forall_intr_list [A, B] (implies_intr_list [A, B]
   968       (Thm.forall_intr C (Thm.implies_intr ABC
   969         (implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B]))))
   970     |> forall_elim_vars 0;
   971 
   972   val incr = incr_indexes_wrt [] [] [];
   973 in
   974 
   975 fun conj_intr tha thb = thb COMP (tha COMP incr [tha, thb] conj_intr_rule);
   976 
   977 fun conj_intr_list [] = asm_rl
   978   | conj_intr_list ths = foldr1 (uncurry conj_intr) ths;
   979 
   980 fun conj_elim th =
   981   let val th' = forall_elim_var (#maxidx (Thm.rep_thm th) + 1) th
   982   in (incr [th'] proj1 COMP th', incr [th'] proj2 COMP th') end;
   983 
   984 fun conj_elim_list th =
   985   let val (th1, th2) = conj_elim th
   986   in conj_elim_list th1 @ conj_elim_list th2 end handle THM _ => [th];
   987 
   988 fun conj_elim_precise 0 _ = []
   989   | conj_elim_precise 1 th = [th]
   990   | conj_elim_precise n th =
   991       let val (th1, th2) = conj_elim th
   992       in th1 :: conj_elim_precise (n - 1) th2 end;
   993 
   994 val conj_intr_thm = store_standard_thm_open "conjunctionI"
   995   (implies_intr_list [A, B] (conj_intr (Thm.assume A) (Thm.assume B)));
   996 
   997 end;
   998 
   999 end;
  1000 
  1001 structure BasicDrule: BASIC_DRULE = Drule;
  1002 open BasicDrule;