src/ZF/Constructible/Datatype_absolute.thy
author paulson
Wed Jul 17 15:48:54 2002 +0200 (2002-07-17)
changeset 13385 31df66ca0780
parent 13382 b37764a46b16
child 13386 f3e9e8b21aba
permissions -rw-r--r--
Expressing Lset and L without using length and arity; simplifies Separation
proofs
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   directed :: "i=>o"
    10    "directed(A) == A\<noteq>0 & (\<forall>x\<in>A. \<forall>y\<in>A. x \<union> y \<in> A)"
    11 
    12   contin :: "(i=>i) => o"
    13    "contin(h) == (\<forall>A. directed(A) --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    14 
    15 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    16 apply (induct_tac n) 
    17  apply (simp_all add: bnd_mono_def, blast) 
    18 done
    19 
    20 lemma bnd_mono_increasing [rule_format]:
    21      "[|i \<in> nat; j \<in> nat; bnd_mono(D,h)|] ==> i \<le> j --> h^i(0) \<subseteq> h^j(0)"
    22 apply (rule_tac m=i and n=j in diff_induct, simp_all)
    23 apply (blast del: subsetI
    24 	     intro: bnd_mono_iterates_subset bnd_monoD2 [of concl: h] ) 
    25 done
    26 
    27 lemma directed_iterates: "bnd_mono(D,h) ==> directed({h^n (0). n\<in>nat})"
    28 apply (simp add: directed_def, clarify) 
    29 apply (rename_tac i j)
    30 apply (rule_tac x="i \<union> j" in bexI) 
    31 apply (rule_tac i = i and j = j in Ord_linear_le)
    32 apply (simp_all add: subset_Un_iff [THEN iffD1] le_imp_subset
    33                      subset_Un_iff2 [THEN iffD1])
    34 apply (simp_all add: subset_Un_iff [THEN iff_sym] bnd_mono_increasing
    35                      subset_Un_iff2 [THEN iff_sym])
    36 done
    37 
    38 
    39 lemma contin_iterates_eq: 
    40     "[|bnd_mono(D, h); contin(h)|] 
    41      ==> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    42 apply (simp add: contin_def directed_iterates) 
    43 apply (rule trans) 
    44 apply (rule equalityI) 
    45  apply (simp_all add: UN_subset_iff)
    46  apply safe
    47  apply (erule_tac [2] natE) 
    48   apply (rule_tac a="succ(x)" in UN_I) 
    49    apply simp_all 
    50 apply blast 
    51 done
    52 
    53 lemma lfp_subset_Union:
    54      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    55 apply (rule lfp_lowerbound) 
    56  apply (simp add: contin_iterates_eq) 
    57 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    58 done
    59 
    60 lemma Union_subset_lfp:
    61      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    62 apply (simp add: UN_subset_iff)
    63 apply (rule ballI)  
    64 apply (induct_tac n, simp_all) 
    65 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    66  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset] )  
    67 apply (erule lfp_lemma2) 
    68 done
    69 
    70 lemma lfp_eq_Union:
    71      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    72 by (blast del: subsetI 
    73           intro: lfp_subset_Union Union_subset_lfp)
    74 
    75 
    76 subsubsection{*Some Standard Datatype Constructions Preserve Continuity*}
    77 
    78 lemma contin_imp_mono: "[|X\<subseteq>Y; contin(F)|] ==> F(X) \<subseteq> F(Y)"
    79 apply (simp add: contin_def) 
    80 apply (drule_tac x="{X,Y}" in spec) 
    81 apply (simp add: directed_def subset_Un_iff2 Un_commute) 
    82 done
    83 
    84 lemma sum_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) + G(X))"
    85 by (simp add: contin_def, blast)
    86 
    87 lemma prod_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) * G(X))" 
    88 apply (subgoal_tac "\<forall>B C. F(B) \<subseteq> F(B \<union> C)")
    89  prefer 2 apply (simp add: Un_upper1 contin_imp_mono) 
    90 apply (subgoal_tac "\<forall>B C. G(C) \<subseteq> G(B \<union> C)")
    91  prefer 2 apply (simp add: Un_upper2 contin_imp_mono) 
    92 apply (simp add: contin_def, clarify) 
    93 apply (rule equalityI) 
    94  prefer 2 apply blast 
    95 apply clarify 
    96 apply (rename_tac B C) 
    97 apply (rule_tac a="B \<union> C" in UN_I) 
    98  apply (simp add: directed_def, blast)  
    99 done
   100 
   101 lemma const_contin: "contin(\<lambda>X. A)"
   102 by (simp add: contin_def directed_def)
   103 
   104 lemma id_contin: "contin(\<lambda>X. X)"
   105 by (simp add: contin_def)
   106 
   107 
   108 
   109 subsection {*lists without univ*}
   110 
   111 lemmas datatype_univs = Inl_in_univ Inr_in_univ 
   112                         Pair_in_univ nat_into_univ A_into_univ 
   113 
   114 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
   115 apply (rule bnd_monoI)
   116  apply (intro subset_refl zero_subset_univ A_subset_univ 
   117 	      sum_subset_univ Sigma_subset_univ) 
   118 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   119 done
   120 
   121 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
   122 by (intro sum_contin prod_contin id_contin const_contin) 
   123 
   124 text{*Re-expresses lists using sum and product*}
   125 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
   126 apply (simp add: list_def) 
   127 apply (rule equalityI) 
   128  apply (rule lfp_lowerbound) 
   129   prefer 2 apply (rule lfp_subset)
   130  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
   131  apply (simp add: Nil_def Cons_def)
   132  apply blast 
   133 txt{*Opposite inclusion*}
   134 apply (rule lfp_lowerbound) 
   135  prefer 2 apply (rule lfp_subset) 
   136 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
   137 apply (simp add: Nil_def Cons_def)
   138 apply (blast intro: datatype_univs
   139              dest: lfp_subset [THEN subsetD])
   140 done
   141 
   142 text{*Re-expresses lists using "iterates", no univ.*}
   143 lemma list_eq_Union:
   144      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
   145 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
   146 
   147 
   148 subsection {*Absoluteness for "Iterates"*}
   149 
   150 constdefs
   151 
   152   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o"
   153    "iterates_MH(M,isF,v,n,g,z) ==
   154         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   155                     n, z)"
   156 
   157   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o"
   158    "iterates_replacement(M,isF,v) ==
   159       \<forall>n[M]. n\<in>nat --> 
   160          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   161 
   162 lemma (in M_axioms) iterates_MH_abs:
   163   "[| relativize1(M,isF,F); M(n); M(g); M(z) |] 
   164    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   165 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   166               relativize1_def iterates_MH_def)  
   167 
   168 lemma (in M_axioms) iterates_imp_wfrec_replacement:
   169   "[|relativize1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   170    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   171                        Memrel(succ(n)))" 
   172 by (simp add: iterates_replacement_def iterates_MH_abs)
   173 
   174 theorem (in M_trancl) iterates_abs:
   175   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   176       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   177    ==> is_wfrec(M, iterates_MH(M,isF,v), Memrel(succ(n)), n, z) <->
   178        z = iterates(F,n,v)" 
   179 apply (frule iterates_imp_wfrec_replacement, assumption+)
   180 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   181                  relativize2_def iterates_MH_abs 
   182                  iterates_nat_def recursor_def transrec_def 
   183                  eclose_sing_Ord_eq nat_into_M
   184          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   185 done
   186 
   187 
   188 lemma (in M_wfrank) iterates_closed [intro,simp]:
   189   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   190       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   191    ==> M(iterates(F,n,v))"
   192 apply (frule iterates_imp_wfrec_replacement, assumption+)
   193 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   194                  relativize2_def iterates_MH_abs 
   195                  iterates_nat_def recursor_def transrec_def 
   196                  eclose_sing_Ord_eq nat_into_M
   197          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   198 done
   199 
   200 
   201 constdefs
   202   is_list_functor :: "[i=>o,i,i,i] => o"
   203     "is_list_functor(M,A,X,Z) == 
   204         \<exists>n1[M]. \<exists>AX[M]. 
   205          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   206 
   207 lemma (in M_axioms) list_functor_abs [simp]: 
   208      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   209 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   210 
   211 
   212 locale (open) M_datatypes = M_wfrank +
   213  assumes list_replacement1: 
   214    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   215   and list_replacement2: 
   216    "M(A) ==> strong_replacement(M, 
   217          \<lambda>n y. n\<in>nat & 
   218                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   219                is_wfrec(M, iterates_MH(M,is_list_functor(M,A), 0), 
   220                         msn, n, y)))"
   221 
   222 lemma (in M_datatypes) list_replacement2': 
   223   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   224 apply (insert list_replacement2 [of A]) 
   225 apply (rule strong_replacement_cong [THEN iffD1])  
   226 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]]) 
   227 apply (simp_all add: list_replacement1 relativize1_def) 
   228 done
   229 
   230 lemma (in M_datatypes) list_closed [intro,simp]:
   231      "M(A) ==> M(list(A))"
   232 apply (insert list_replacement1)
   233 by  (simp add: RepFun_closed2 list_eq_Union 
   234                list_replacement2' relativize1_def
   235                iterates_closed [of "is_list_functor(M,A)"])
   236 
   237 
   238 end