src/HOL/Power.thy
author haftmann
Sun Feb 24 20:29:13 2013 +0100 (2013-02-24)
changeset 51263 31e786e0e6a7
parent 49824 c26665a197dc
child 52435 6646bb548c6b
permissions -rw-r--r--
turned example into library for comparing growth of functions
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 header {* Exponentiation *}
     7 
     8 theory Power
     9 imports Num
    10 begin
    11 
    12 subsection {* Powers for Arbitrary Monoids *}
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    18     power_0: "a ^ 0 = 1"
    19   | power_Suc: "a ^ Suc n = a * a ^ n"
    20 
    21 notation (latex output)
    22   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    23 
    24 notation (HTML output)
    25   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    26 
    27 text {* Special syntax for squares. *}
    28 
    29 abbreviation (xsymbols)
    30   power2 :: "'a \<Rightarrow> 'a"  ("(_\<twosuperior>)" [1000] 999) where
    31   "x\<twosuperior> \<equiv> x ^ 2"
    32 
    33 notation (latex output)
    34   power2  ("(_\<twosuperior>)" [1000] 999)
    35 
    36 notation (HTML output)
    37   power2  ("(_\<twosuperior>)" [1000] 999)
    38 
    39 end
    40 
    41 context monoid_mult
    42 begin
    43 
    44 subclass power .
    45 
    46 lemma power_one [simp]:
    47   "1 ^ n = 1"
    48   by (induct n) simp_all
    49 
    50 lemma power_one_right [simp]:
    51   "a ^ 1 = a"
    52   by simp
    53 
    54 lemma power_commutes:
    55   "a ^ n * a = a * a ^ n"
    56   by (induct n) (simp_all add: mult_assoc)
    57 
    58 lemma power_Suc2:
    59   "a ^ Suc n = a ^ n * a"
    60   by (simp add: power_commutes)
    61 
    62 lemma power_add:
    63   "a ^ (m + n) = a ^ m * a ^ n"
    64   by (induct m) (simp_all add: algebra_simps)
    65 
    66 lemma power_mult:
    67   "a ^ (m * n) = (a ^ m) ^ n"
    68   by (induct n) (simp_all add: power_add)
    69 
    70 lemma power2_eq_square: "a\<twosuperior> = a * a"
    71   by (simp add: numeral_2_eq_2)
    72 
    73 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    74   by (simp add: numeral_3_eq_3 mult_assoc)
    75 
    76 lemma power_even_eq:
    77   "a ^ (2*n) = (a ^ n) ^ 2"
    78   by (subst mult_commute) (simp add: power_mult)
    79 
    80 lemma power_odd_eq:
    81   "a ^ Suc (2*n) = a * (a ^ n) ^ 2"
    82   by (simp add: power_even_eq)
    83 
    84 lemma power_numeral_even:
    85   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    86   unfolding numeral_Bit0 power_add Let_def ..
    87 
    88 lemma power_numeral_odd:
    89   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    90   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    91   unfolding power_Suc power_add Let_def mult_assoc ..
    92 
    93 lemma funpow_times_power:
    94   "(times x ^^ f x) = times (x ^ f x)"
    95 proof (induct "f x" arbitrary: f)
    96   case 0 then show ?case by (simp add: fun_eq_iff)
    97 next
    98   case (Suc n)
    99   def g \<equiv> "\<lambda>x. f x - 1"
   100   with Suc have "n = g x" by simp
   101   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   102   moreover from Suc g_def have "f x = g x + 1" by simp
   103   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult_assoc)
   104 qed
   105 
   106 end
   107 
   108 context comm_monoid_mult
   109 begin
   110 
   111 lemma power_mult_distrib:
   112   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   113   by (induct n) (simp_all add: mult_ac)
   114 
   115 end
   116 
   117 context semiring_numeral
   118 begin
   119 
   120 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   121   by (simp only: sqr_conv_mult numeral_mult)
   122 
   123 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   124   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   125     numeral_sqr numeral_mult power_add power_one_right)
   126 
   127 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   128   by (rule numeral_pow [symmetric])
   129 
   130 end
   131 
   132 context semiring_1
   133 begin
   134 
   135 lemma of_nat_power:
   136   "of_nat (m ^ n) = of_nat m ^ n"
   137   by (induct n) (simp_all add: of_nat_mult)
   138 
   139 lemma power_zero_numeral [simp]: "(0::'a) ^ numeral k = 0"
   140   by (simp add: numeral_eq_Suc)
   141 
   142 lemma zero_power2: "0\<twosuperior> = 0" (* delete? *)
   143   by (rule power_zero_numeral)
   144 
   145 lemma one_power2: "1\<twosuperior> = 1" (* delete? *)
   146   by (rule power_one)
   147 
   148 end
   149 
   150 context comm_semiring_1
   151 begin
   152 
   153 text {* The divides relation *}
   154 
   155 lemma le_imp_power_dvd:
   156   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   157 proof
   158   have "a ^ n = a ^ (m + (n - m))"
   159     using `m \<le> n` by simp
   160   also have "\<dots> = a ^ m * a ^ (n - m)"
   161     by (rule power_add)
   162   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   163 qed
   164 
   165 lemma power_le_dvd:
   166   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   167   by (rule dvd_trans [OF le_imp_power_dvd])
   168 
   169 lemma dvd_power_same:
   170   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   171   by (induct n) (auto simp add: mult_dvd_mono)
   172 
   173 lemma dvd_power_le:
   174   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   175   by (rule power_le_dvd [OF dvd_power_same])
   176 
   177 lemma dvd_power [simp]:
   178   assumes "n > (0::nat) \<or> x = 1"
   179   shows "x dvd (x ^ n)"
   180 using assms proof
   181   assume "0 < n"
   182   then have "x ^ n = x ^ Suc (n - 1)" by simp
   183   then show "x dvd (x ^ n)" by simp
   184 next
   185   assume "x = 1"
   186   then show "x dvd (x ^ n)" by simp
   187 qed
   188 
   189 end
   190 
   191 context ring_1
   192 begin
   193 
   194 lemma power_minus:
   195   "(- a) ^ n = (- 1) ^ n * a ^ n"
   196 proof (induct n)
   197   case 0 show ?case by simp
   198 next
   199   case (Suc n) then show ?case
   200     by (simp del: power_Suc add: power_Suc2 mult_assoc)
   201 qed
   202 
   203 lemma power_minus_Bit0:
   204   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   205   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   206     power_one_right mult_minus_left mult_minus_right minus_minus)
   207 
   208 lemma power_minus_Bit1:
   209   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   210   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   211 
   212 lemma power_neg_numeral_Bit0 [simp]:
   213   "neg_numeral k ^ numeral (Num.Bit0 l) = numeral (Num.pow k (Num.Bit0 l))"
   214   by (simp only: neg_numeral_def power_minus_Bit0 power_numeral)
   215 
   216 lemma power_neg_numeral_Bit1 [simp]:
   217   "neg_numeral k ^ numeral (Num.Bit1 l) = neg_numeral (Num.pow k (Num.Bit1 l))"
   218   by (simp only: neg_numeral_def power_minus_Bit1 power_numeral pow.simps)
   219 
   220 lemma power2_minus [simp]:
   221   "(- a)\<twosuperior> = a\<twosuperior>"
   222   by (rule power_minus_Bit0)
   223 
   224 lemma power_minus1_even [simp]:
   225   "-1 ^ (2*n) = 1"
   226 proof (induct n)
   227   case 0 show ?case by simp
   228 next
   229   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   230 qed
   231 
   232 lemma power_minus1_odd:
   233   "-1 ^ Suc (2*n) = -1"
   234   by simp
   235 
   236 lemma power_minus_even [simp]:
   237   "(-a) ^ (2*n) = a ^ (2*n)"
   238   by (simp add: power_minus [of a])
   239 
   240 end
   241 
   242 context ring_1_no_zero_divisors
   243 begin
   244 
   245 lemma field_power_not_zero:
   246   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   247   by (induct n) auto
   248 
   249 lemma zero_eq_power2 [simp]:
   250   "a\<twosuperior> = 0 \<longleftrightarrow> a = 0"
   251   unfolding power2_eq_square by simp
   252 
   253 lemma power2_eq_1_iff:
   254   "a\<twosuperior> = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   255   unfolding power2_eq_square by (rule square_eq_1_iff)
   256 
   257 end
   258 
   259 context idom
   260 begin
   261 
   262 lemma power2_eq_iff: "x\<twosuperior> = y\<twosuperior> \<longleftrightarrow> x = y \<or> x = - y"
   263   unfolding power2_eq_square by (rule square_eq_iff)
   264 
   265 end
   266 
   267 context division_ring
   268 begin
   269 
   270 text {* FIXME reorient or rename to @{text nonzero_inverse_power} *}
   271 lemma nonzero_power_inverse:
   272   "a \<noteq> 0 \<Longrightarrow> inverse (a ^ n) = (inverse a) ^ n"
   273   by (induct n)
   274     (simp_all add: nonzero_inverse_mult_distrib power_commutes field_power_not_zero)
   275 
   276 end
   277 
   278 context field
   279 begin
   280 
   281 lemma nonzero_power_divide:
   282   "b \<noteq> 0 \<Longrightarrow> (a / b) ^ n = a ^ n / b ^ n"
   283   by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   284 
   285 end
   286 
   287 
   288 subsection {* Exponentiation on ordered types *}
   289 
   290 context linordered_ring (* TODO: move *)
   291 begin
   292 
   293 lemma sum_squares_ge_zero:
   294   "0 \<le> x * x + y * y"
   295   by (intro add_nonneg_nonneg zero_le_square)
   296 
   297 lemma not_sum_squares_lt_zero:
   298   "\<not> x * x + y * y < 0"
   299   by (simp add: not_less sum_squares_ge_zero)
   300 
   301 end
   302 
   303 context linordered_semidom
   304 begin
   305 
   306 lemma zero_less_power [simp]:
   307   "0 < a \<Longrightarrow> 0 < a ^ n"
   308   by (induct n) (simp_all add: mult_pos_pos)
   309 
   310 lemma zero_le_power [simp]:
   311   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   312   by (induct n) (simp_all add: mult_nonneg_nonneg)
   313 
   314 lemma power_mono:
   315   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   316   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   317 
   318 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   319   using power_mono [of 1 a n] by simp
   320 
   321 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   322   using power_mono [of a 1 n] by simp
   323 
   324 lemma power_gt1_lemma:
   325   assumes gt1: "1 < a"
   326   shows "1 < a * a ^ n"
   327 proof -
   328   from gt1 have "0 \<le> a"
   329     by (fact order_trans [OF zero_le_one less_imp_le])
   330   have "1 * 1 < a * 1" using gt1 by simp
   331   also have "\<dots> \<le> a * a ^ n" using gt1
   332     by (simp only: mult_mono `0 \<le> a` one_le_power order_less_imp_le
   333         zero_le_one order_refl)
   334   finally show ?thesis by simp
   335 qed
   336 
   337 lemma power_gt1:
   338   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   339   by (simp add: power_gt1_lemma)
   340 
   341 lemma one_less_power [simp]:
   342   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   343   by (cases n) (simp_all add: power_gt1_lemma)
   344 
   345 lemma power_le_imp_le_exp:
   346   assumes gt1: "1 < a"
   347   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   348 proof (induct m arbitrary: n)
   349   case 0
   350   show ?case by simp
   351 next
   352   case (Suc m)
   353   show ?case
   354   proof (cases n)
   355     case 0
   356     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   357     with gt1 show ?thesis
   358       by (force simp only: power_gt1_lemma
   359           not_less [symmetric])
   360   next
   361     case (Suc n)
   362     with Suc.prems Suc.hyps show ?thesis
   363       by (force dest: mult_left_le_imp_le
   364           simp add: less_trans [OF zero_less_one gt1])
   365   qed
   366 qed
   367 
   368 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   369 lemma power_inject_exp [simp]:
   370   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   371   by (force simp add: order_antisym power_le_imp_le_exp)
   372 
   373 text{*Can relax the first premise to @{term "0<a"} in the case of the
   374 natural numbers.*}
   375 lemma power_less_imp_less_exp:
   376   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   377   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   378     power_le_imp_le_exp)
   379 
   380 lemma power_strict_mono [rule_format]:
   381   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   382   by (induct n)
   383    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   384 
   385 text{*Lemma for @{text power_strict_decreasing}*}
   386 lemma power_Suc_less:
   387   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   388   by (induct n)
   389     (auto simp add: mult_strict_left_mono)
   390 
   391 lemma power_strict_decreasing [rule_format]:
   392   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   393 proof (induct N)
   394   case 0 then show ?case by simp
   395 next
   396   case (Suc N) then show ?case 
   397   apply (auto simp add: power_Suc_less less_Suc_eq)
   398   apply (subgoal_tac "a * a^N < 1 * a^n")
   399   apply simp
   400   apply (rule mult_strict_mono) apply auto
   401   done
   402 qed
   403 
   404 text{*Proof resembles that of @{text power_strict_decreasing}*}
   405 lemma power_decreasing [rule_format]:
   406   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   407 proof (induct N)
   408   case 0 then show ?case by simp
   409 next
   410   case (Suc N) then show ?case 
   411   apply (auto simp add: le_Suc_eq)
   412   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   413   apply (rule mult_mono) apply auto
   414   done
   415 qed
   416 
   417 lemma power_Suc_less_one:
   418   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   419   using power_strict_decreasing [of 0 "Suc n" a] by simp
   420 
   421 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   422 lemma power_increasing [rule_format]:
   423   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   424 proof (induct N)
   425   case 0 then show ?case by simp
   426 next
   427   case (Suc N) then show ?case 
   428   apply (auto simp add: le_Suc_eq)
   429   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   430   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   431   done
   432 qed
   433 
   434 text{*Lemma for @{text power_strict_increasing}*}
   435 lemma power_less_power_Suc:
   436   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   437   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   438 
   439 lemma power_strict_increasing [rule_format]:
   440   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   441 proof (induct N)
   442   case 0 then show ?case by simp
   443 next
   444   case (Suc N) then show ?case 
   445   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   446   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   447   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   448   done
   449 qed
   450 
   451 lemma power_increasing_iff [simp]:
   452   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   453   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   454 
   455 lemma power_strict_increasing_iff [simp]:
   456   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   457 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   458 
   459 lemma power_le_imp_le_base:
   460   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   461     and ynonneg: "0 \<le> b"
   462   shows "a \<le> b"
   463 proof (rule ccontr)
   464   assume "~ a \<le> b"
   465   then have "b < a" by (simp only: linorder_not_le)
   466   then have "b ^ Suc n < a ^ Suc n"
   467     by (simp only: assms power_strict_mono)
   468   from le and this show False
   469     by (simp add: linorder_not_less [symmetric])
   470 qed
   471 
   472 lemma power_less_imp_less_base:
   473   assumes less: "a ^ n < b ^ n"
   474   assumes nonneg: "0 \<le> b"
   475   shows "a < b"
   476 proof (rule contrapos_pp [OF less])
   477   assume "~ a < b"
   478   hence "b \<le> a" by (simp only: linorder_not_less)
   479   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   480   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   481 qed
   482 
   483 lemma power_inject_base:
   484   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   485 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   486 
   487 lemma power_eq_imp_eq_base:
   488   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   489   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   490 
   491 lemma power2_le_imp_le:
   492   "x\<twosuperior> \<le> y\<twosuperior> \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   493   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   494 
   495 lemma power2_less_imp_less:
   496   "x\<twosuperior> < y\<twosuperior> \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   497   by (rule power_less_imp_less_base)
   498 
   499 lemma power2_eq_imp_eq:
   500   "x\<twosuperior> = y\<twosuperior> \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   501   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   502 
   503 end
   504 
   505 context linordered_ring_strict
   506 begin
   507 
   508 lemma sum_squares_eq_zero_iff:
   509   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   510   by (simp add: add_nonneg_eq_0_iff)
   511 
   512 lemma sum_squares_le_zero_iff:
   513   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   514   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   515 
   516 lemma sum_squares_gt_zero_iff:
   517   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   518   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   519 
   520 end
   521 
   522 context linordered_idom
   523 begin
   524 
   525 lemma power_abs:
   526   "abs (a ^ n) = abs a ^ n"
   527   by (induct n) (auto simp add: abs_mult)
   528 
   529 lemma abs_power_minus [simp]:
   530   "abs ((-a) ^ n) = abs (a ^ n)"
   531   by (simp add: power_abs)
   532 
   533 lemma zero_less_power_abs_iff [simp, no_atp]:
   534   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   535 proof (induct n)
   536   case 0 show ?case by simp
   537 next
   538   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   539 qed
   540 
   541 lemma zero_le_power_abs [simp]:
   542   "0 \<le> abs a ^ n"
   543   by (rule zero_le_power [OF abs_ge_zero])
   544 
   545 lemma zero_le_power2 [simp]:
   546   "0 \<le> a\<twosuperior>"
   547   by (simp add: power2_eq_square)
   548 
   549 lemma zero_less_power2 [simp]:
   550   "0 < a\<twosuperior> \<longleftrightarrow> a \<noteq> 0"
   551   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   552 
   553 lemma power2_less_0 [simp]:
   554   "\<not> a\<twosuperior> < 0"
   555   by (force simp add: power2_eq_square mult_less_0_iff)
   556 
   557 lemma abs_power2 [simp]:
   558   "abs (a\<twosuperior>) = a\<twosuperior>"
   559   by (simp add: power2_eq_square abs_mult abs_mult_self)
   560 
   561 lemma power2_abs [simp]:
   562   "(abs a)\<twosuperior> = a\<twosuperior>"
   563   by (simp add: power2_eq_square abs_mult_self)
   564 
   565 lemma odd_power_less_zero:
   566   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   567 proof (induct n)
   568   case 0
   569   then show ?case by simp
   570 next
   571   case (Suc n)
   572   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   573     by (simp add: mult_ac power_add power2_eq_square)
   574   thus ?case
   575     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   576 qed
   577 
   578 lemma odd_0_le_power_imp_0_le:
   579   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   580   using odd_power_less_zero [of a n]
   581     by (force simp add: linorder_not_less [symmetric]) 
   582 
   583 lemma zero_le_even_power'[simp]:
   584   "0 \<le> a ^ (2*n)"
   585 proof (induct n)
   586   case 0
   587     show ?case by simp
   588 next
   589   case (Suc n)
   590     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)" 
   591       by (simp add: mult_ac power_add power2_eq_square)
   592     thus ?case
   593       by (simp add: Suc zero_le_mult_iff)
   594 qed
   595 
   596 lemma sum_power2_ge_zero:
   597   "0 \<le> x\<twosuperior> + y\<twosuperior>"
   598   by (intro add_nonneg_nonneg zero_le_power2)
   599 
   600 lemma not_sum_power2_lt_zero:
   601   "\<not> x\<twosuperior> + y\<twosuperior> < 0"
   602   unfolding not_less by (rule sum_power2_ge_zero)
   603 
   604 lemma sum_power2_eq_zero_iff:
   605   "x\<twosuperior> + y\<twosuperior> = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   606   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   607 
   608 lemma sum_power2_le_zero_iff:
   609   "x\<twosuperior> + y\<twosuperior> \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   610   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   611 
   612 lemma sum_power2_gt_zero_iff:
   613   "0 < x\<twosuperior> + y\<twosuperior> \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   614   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   615 
   616 end
   617 
   618 
   619 subsection {* Miscellaneous rules *}
   620 
   621 lemma power_eq_if: "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   622   unfolding One_nat_def by (cases m) simp_all
   623 
   624 lemma power2_sum:
   625   fixes x y :: "'a::comm_semiring_1"
   626   shows "(x + y)\<twosuperior> = x\<twosuperior> + y\<twosuperior> + 2 * x * y"
   627   by (simp add: algebra_simps power2_eq_square mult_2_right)
   628 
   629 lemma power2_diff:
   630   fixes x y :: "'a::comm_ring_1"
   631   shows "(x - y)\<twosuperior> = x\<twosuperior> + y\<twosuperior> - 2 * x * y"
   632   by (simp add: ring_distribs power2_eq_square mult_2) (rule mult_commute)
   633 
   634 lemma power_0_Suc [simp]:
   635   "(0::'a::{power, semiring_0}) ^ Suc n = 0"
   636   by simp
   637 
   638 text{*It looks plausible as a simprule, but its effect can be strange.*}
   639 lemma power_0_left:
   640   "0 ^ n = (if n = 0 then 1 else (0::'a::{power, semiring_0}))"
   641   by (induct n) simp_all
   642 
   643 lemma power_eq_0_iff [simp]:
   644   "a ^ n = 0 \<longleftrightarrow>
   645      a = (0::'a::{mult_zero,zero_neq_one,no_zero_divisors,power}) \<and> n \<noteq> 0"
   646   by (induct n)
   647     (auto simp add: no_zero_divisors elim: contrapos_pp)
   648 
   649 lemma (in field) power_diff:
   650   assumes nz: "a \<noteq> 0"
   651   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   652   by (induct m n rule: diff_induct) (simp_all add: nz field_power_not_zero)
   653 
   654 text{*Perhaps these should be simprules.*}
   655 lemma power_inverse:
   656   fixes a :: "'a::division_ring_inverse_zero"
   657   shows "inverse (a ^ n) = inverse a ^ n"
   658 apply (cases "a = 0")
   659 apply (simp add: power_0_left)
   660 apply (simp add: nonzero_power_inverse)
   661 done (* TODO: reorient or rename to inverse_power *)
   662 
   663 lemma power_one_over:
   664   "1 / (a::'a::{field_inverse_zero, power}) ^ n =  (1 / a) ^ n"
   665   by (simp add: divide_inverse) (rule power_inverse)
   666 
   667 lemma power_divide:
   668   "(a / b) ^ n = (a::'a::field_inverse_zero) ^ n / b ^ n"
   669 apply (cases "b = 0")
   670 apply (simp add: power_0_left)
   671 apply (rule nonzero_power_divide)
   672 apply assumption
   673 done
   674 
   675 text {* Simprules for comparisons where common factors can be cancelled. *}
   676 
   677 lemmas zero_compare_simps =
   678     add_strict_increasing add_strict_increasing2 add_increasing
   679     zero_le_mult_iff zero_le_divide_iff 
   680     zero_less_mult_iff zero_less_divide_iff 
   681     mult_le_0_iff divide_le_0_iff 
   682     mult_less_0_iff divide_less_0_iff 
   683     zero_le_power2 power2_less_0
   684 
   685 
   686 subsection {* Exponentiation for the Natural Numbers *}
   687 
   688 lemma nat_one_le_power [simp]:
   689   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   690   by (rule one_le_power [of i n, unfolded One_nat_def])
   691 
   692 lemma nat_zero_less_power_iff [simp]:
   693   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   694   by (induct n) auto
   695 
   696 lemma nat_power_eq_Suc_0_iff [simp]: 
   697   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   698   by (induct m) auto
   699 
   700 lemma power_Suc_0 [simp]:
   701   "Suc 0 ^ n = Suc 0"
   702   by simp
   703 
   704 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   705 Premises cannot be weakened: consider the case where @{term "i=0"},
   706 @{term "m=1"} and @{term "n=0"}.*}
   707 lemma nat_power_less_imp_less:
   708   assumes nonneg: "0 < (i\<Colon>nat)"
   709   assumes less: "i ^ m < i ^ n"
   710   shows "m < n"
   711 proof (cases "i = 1")
   712   case True with less power_one [where 'a = nat] show ?thesis by simp
   713 next
   714   case False with nonneg have "1 < i" by auto
   715   from power_strict_increasing_iff [OF this] less show ?thesis ..
   716 qed
   717 
   718 lemma power_dvd_imp_le:
   719   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   720   apply (rule power_le_imp_le_exp, assumption)
   721   apply (erule dvd_imp_le, simp)
   722   done
   723 
   724 lemma power2_nat_le_eq_le:
   725   fixes m n :: nat
   726   shows "m\<twosuperior> \<le> n\<twosuperior> \<longleftrightarrow> m \<le> n"
   727   by (auto intro: power2_le_imp_le power_mono)
   728 
   729 lemma power2_nat_le_imp_le:
   730   fixes m n :: nat
   731   assumes "m\<twosuperior> \<le> n"
   732   shows "m \<le> n"
   733   using assms by (cases m) (simp_all add: power2_eq_square)
   734 
   735 
   736 
   737 subsection {* Code generator tweak *}
   738 
   739 lemma power_power_power [code]:
   740   "power = power.power (1::'a::{power}) (op *)"
   741   unfolding power_def power.power_def ..
   742 
   743 declare power.power.simps [code]
   744 
   745 code_modulename SML
   746   Power Arith
   747 
   748 code_modulename OCaml
   749   Power Arith
   750 
   751 code_modulename Haskell
   752   Power Arith
   753 
   754 end
   755