src/HOL/hologic.ML
author nipkow
Wed Aug 18 11:09:40 2004 +0200 (2004-08-18)
changeset 15140 322485b816ac
parent 15062 8049f217428e
child 15151 429666b09783
permissions -rw-r--r--
import -> imports
     1 (*  Title:      HOL/hologic.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Abstract syntax operations for HOL.
     6 *)
     7 
     8 signature HOLOGIC =
     9 sig
    10   val typeS: sort
    11   val typeT: typ
    12   val read_cterm: Sign.sg -> string -> cterm
    13   val boolN: string
    14   val boolT: typ
    15   val false_const: term
    16   val true_const: term
    17   val not_const: term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val mk_Trueprop: term -> term
    21   val dest_Trueprop: term -> term
    22   val conj: term
    23   val disj: term
    24   val imp: term
    25   val Not: term
    26   val mk_conj: term * term -> term
    27   val mk_disj: term * term -> term
    28   val mk_imp: term * term -> term
    29   val dest_imp: term -> term * term
    30   val dest_conj: term -> term list
    31   val dest_concls: term -> term list
    32   val eq_const: typ -> term
    33   val all_const: typ -> term
    34   val exists_const: typ -> term
    35   val Collect_const: typ -> term
    36   val mk_eq: term * term -> term
    37   val dest_eq: term -> term * term
    38   val mk_all: string * typ * term -> term
    39   val list_all: (string * typ) list * term -> term
    40   val mk_exists: string * typ * term -> term
    41   val mk_Collect: string * typ * term -> term
    42   val mk_mem: term * term -> term
    43   val dest_mem: term -> term * term
    44   val mk_UNIV: typ -> term
    45   val mk_binop: string -> term * term -> term
    46   val mk_binrel: string -> term * term -> term
    47   val dest_bin: string -> typ -> term -> term * term
    48   val unitT: typ
    49   val is_unitT: typ -> bool
    50   val unit: term
    51   val is_unit: term -> bool
    52   val mk_prodT: typ * typ -> typ
    53   val dest_prodT: typ -> typ * typ
    54   val pair_const: typ -> typ -> term
    55   val mk_prod: term * term -> term
    56   val dest_prod: term -> term * term
    57   val mk_fst: term -> term
    58   val mk_snd: term -> term
    59   val prodT_factors: typ -> typ list
    60   val split_const: typ * typ * typ -> term
    61   val mk_tuple: typ -> term list -> term
    62   val natT: typ
    63   val zero: term
    64   val is_zero: term -> bool
    65   val mk_Suc: term -> term
    66   val dest_Suc: term -> term
    67   val mk_nat: int -> term
    68   val dest_nat: term -> int
    69   val intT: typ
    70   val mk_int: int -> term
    71   val realT: typ
    72   val binT: typ
    73   val pls_const: term
    74   val min_const: term
    75   val bit_const: term
    76   val number_of_const: typ -> term
    77   val int_of: int list -> int
    78   val dest_binum: term -> int
    79   val mk_bin: int -> term
    80   val mk_list: ('a -> term) -> typ -> 'a list -> term
    81   val dest_list: term -> term list
    82 end;
    83 
    84 
    85 structure HOLogic: HOLOGIC =
    86 struct
    87 
    88 (* HOL syntax *)
    89 
    90 val typeS: sort = ["HOL.type"];
    91 val typeT = TypeInfer.anyT typeS;
    92 
    93 fun read_cterm sg s = Thm.read_cterm sg (s, typeT);
    94 
    95 
    96 (* bool and set *)
    97 
    98 val boolN = "bool";
    99 val boolT = Type (boolN, []);
   100 
   101 val true_const =  Const ("True", boolT);
   102 val false_const = Const ("False", boolT);
   103 val not_const = Const ("Not", boolT --> boolT);
   104 
   105 fun mk_setT T = Type ("set", [T]);
   106 
   107 fun dest_setT (Type ("set", [T])) = T
   108   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   109 
   110 
   111 (* logic *)
   112 
   113 val Trueprop = Const ("Trueprop", boolT --> propT);
   114 
   115 fun mk_Trueprop P = Trueprop $ P;
   116 
   117 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   118   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   119 
   120 
   121 val conj = Const ("op &", [boolT, boolT] ---> boolT)
   122 and disj = Const ("op |", [boolT, boolT] ---> boolT)
   123 and imp = Const ("op -->", [boolT, boolT] ---> boolT)
   124 and Not = Const ("Not", boolT --> boolT);
   125 
   126 fun mk_conj (t1, t2) = conj $ t1 $ t2
   127 and mk_disj (t1, t2) = disj $ t1 $ t2
   128 and mk_imp (t1, t2) = imp $ t1 $ t2;
   129 
   130 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   131   | dest_imp  t = raise TERM ("dest_imp", [t]);
   132 
   133 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   134   | dest_conj t = [t];
   135 
   136 fun imp_concl_of t = imp_concl_of (#2 (dest_imp t)) handle TERM _ => t;
   137 val dest_concls = map imp_concl_of o dest_conj o dest_Trueprop;
   138 
   139 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   140 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   141 
   142 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   143   | dest_eq t = raise TERM ("dest_eq", [t])
   144 
   145 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   146 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   147 val list_all = foldr (fn ((x, T), P) => all_const T $ Abs (x, T, P));
   148 
   149 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   150 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   151 
   152 fun Collect_const T = Const ("Collect", [T --> boolT] ---> mk_setT T);
   153 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   154 
   155 fun mk_mem (x, A) =
   156   let val setT = fastype_of A in
   157     Const ("op :", [dest_setT setT, setT] ---> boolT) $ x $ A
   158   end;
   159 
   160 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   161   | dest_mem t = raise TERM ("dest_mem", [t]);
   162 
   163 fun mk_UNIV T = Const ("UNIV", mk_setT T);
   164 
   165 
   166 (* binary operations and relations *)
   167 
   168 fun mk_binop c (t, u) =
   169   let val T = fastype_of t in
   170     Const (c, [T, T] ---> T) $ t $ u
   171   end;
   172 
   173 fun mk_binrel c (t, u) =
   174   let val T = fastype_of t in
   175     Const (c, [T, T] ---> boolT) $ t $ u
   176   end;
   177 
   178 (*destruct the application of a binary operator. The dummyT case is a crude
   179   way of handling polymorphic operators.*)
   180 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   181       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   182       else raise TERM ("dest_bin " ^ c, [tm])
   183   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   184 
   185 
   186 (* unit *)
   187 
   188 val unitT = Type ("Product_Type.unit", []);
   189 
   190 fun is_unitT (Type ("Product_Type.unit", [])) = true
   191   | is_unitT _ = false;
   192 
   193 val unit = Const ("Product_Type.Unity", unitT);
   194 
   195 fun is_unit (Const ("Product_Type.Unity", _)) = true
   196   | is_unit _ = false;
   197 
   198 
   199 (* prod *)
   200 
   201 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   202 
   203 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   204   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   205 
   206 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   207 
   208 fun mk_prod (t1, t2) =
   209   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   210     pair_const T1 T2 $ t1 $ t2
   211   end;
   212 
   213 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   214   | dest_prod t = raise TERM ("dest_prod", [t]);
   215 
   216 fun mk_fst p =
   217   let val pT = fastype_of p in
   218     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   219   end;
   220 
   221 fun mk_snd p =
   222   let val pT = fastype_of p in
   223     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   224   end;
   225 
   226 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   227 fun prodT_factors (Type ("*", [T1, T2])) = prodT_factors T1 @ prodT_factors T2
   228   | prodT_factors T = [T];
   229 
   230 fun split_const (Ta, Tb, Tc) = 
   231     Const ("split", [[Ta, Tb] ---> Tc, mk_prodT (Ta, Tb)] ---> Tc);
   232 
   233 (*Makes a nested tuple from a list, following the product type structure*)
   234 fun mk_tuple (Type ("*", [T1, T2])) tms = 
   235         mk_prod (mk_tuple T1 tms, 
   236                  mk_tuple T2 (drop (length (prodT_factors T1), tms)))
   237   | mk_tuple T (t::_) = t;
   238 
   239 
   240 
   241 (* proper tuples *)
   242 
   243 local  (*currently unused*)
   244 
   245 fun mk_tupleT Ts = foldr mk_prodT (Ts, unitT);
   246 
   247 fun dest_tupleT (Type ("Product_Type.unit", [])) = []
   248   | dest_tupleT (Type ("*", [T, U])) = T :: dest_tupleT U
   249   | dest_tupleT T = raise TYPE ("dest_tupleT", [T], []);
   250 
   251 fun mk_tuple ts = foldr mk_prod (ts, unit);
   252 
   253 fun dest_tuple (Const ("Product_Type.Unity", _)) = []
   254   | dest_tuple (Const ("Pair", _) $ t $ u) = t :: dest_tuple u
   255   | dest_tuple t = raise TERM ("dest_tuple", [t]);
   256 
   257 in val _ = unit end;
   258 
   259 
   260 (* nat *)
   261 
   262 val natT = Type ("nat", []);
   263 
   264 val zero = Const ("0", natT);
   265 
   266 fun is_zero (Const ("0", _)) = true
   267   | is_zero _ = false;
   268 
   269 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   270 
   271 fun dest_Suc (Const ("Suc", _) $ t) = t
   272   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   273 
   274 fun mk_nat 0 = zero
   275   | mk_nat n = mk_Suc (mk_nat (n - 1));
   276 
   277 fun dest_nat (Const ("0", _)) = 0
   278   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   279   | dest_nat t = raise TERM ("dest_nat", [t]);
   280 
   281 
   282 (* binary numerals *)
   283 
   284 val binT = Type ("Numeral.bin", []);
   285 
   286 val pls_const = Const ("Numeral.Pls", binT)
   287 and min_const = Const ("Numeral.Min", binT)
   288 and bit_const = Const ("Numeral.Bit", [binT, boolT] ---> binT);
   289 
   290 fun number_of_const T = Const ("Numeral.number_of", binT --> T);
   291 
   292 
   293 fun int_of [] = 0
   294   | int_of (b :: bs) = b + 2 * int_of bs;
   295 
   296 fun dest_bit (Const ("False", _)) = 0
   297   | dest_bit (Const ("True", _)) = 1
   298   | dest_bit t = raise TERM("dest_bit", [t]);
   299 
   300 fun bin_of (Const ("Numeral.Pls", _)) = []
   301   | bin_of (Const ("Numeral.Min", _)) = [~1]
   302   | bin_of (Const ("Numeral.Bit", _) $ bs $ b) = dest_bit b :: bin_of bs
   303   | bin_of t = raise TERM("bin_of", [t]);
   304 
   305 val dest_binum = int_of o bin_of;
   306 
   307 fun mk_bit 0 = false_const
   308   | mk_bit 1 = true_const
   309   | mk_bit _ = sys_error "mk_bit";
   310 
   311 fun mk_bin n =
   312   let
   313     fun bin_of 0  = []
   314       | bin_of ~1 = [~1]
   315       | bin_of n  = (n mod 2) :: bin_of (n div 2);
   316 
   317     fun term_of []   = pls_const
   318       | term_of [~1] = min_const
   319       | term_of (b :: bs) = bit_const $ term_of bs $ mk_bit b;
   320     in term_of (bin_of n) end;
   321 
   322 
   323 (* int *)
   324 
   325 val intT = Type ("IntDef.int", []);
   326 
   327 fun mk_int 0 = Const ("0", intT)
   328   | mk_int 1 = Const ("1", intT)
   329   | mk_int i = number_of_const intT $ mk_bin i;
   330 
   331 
   332 (* real *)
   333 
   334 val realT = Type("RealDef.real", []);
   335 
   336 
   337 (* list *)
   338 
   339 fun mk_list f T [] = Const ("List.list.Nil", Type ("List.list", [T]))
   340   | mk_list f T (x :: xs) = Const ("List.list.Cons",
   341       T --> Type ("List.list", [T]) --> Type ("List.list", [T])) $ f x $
   342         mk_list f T xs;
   343 
   344 fun dest_list (Const ("List.list.Nil", _)) = []
   345   | dest_list (Const ("List.list.Cons", _) $ x $ xs) = x :: dest_list xs
   346   | dest_list t = raise TERM ("dest_list", [t]);
   347 
   348 end;