src/HOL/Set.ML
author paulson
Wed Nov 18 15:10:46 1998 +0100 (1998-11-18)
changeset 5931 325300576da7
parent 5649 1bac26652f45
child 6006 d2e271b8d651
permissions -rw-r--r--
Finally removing "Compl" from HOL
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 Addsimps [Collect_mem_eq];
    14 AddIffs  [mem_Collect_eq];
    15 
    16 Goal "P(a) ==> a : {x. P(x)}";
    17 by (Asm_simp_tac 1);
    18 qed "CollectI";
    19 
    20 Goal "a : {x. P(x)} ==> P(a)";
    21 by (Asm_full_simp_tac 1);
    22 qed "CollectD";
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 Goalw [Ball_def] "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 (* gives better instantiation for bound: *)
    63 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    64 			 (dtac bspec THEN' atac) APPEND' tac2);
    65 
    66 Goalw [Bex_def] "[| P(x);  x:A |] ==> ? x:A. P(x)";
    67 by (Blast_tac 1);
    68 qed "bexI";
    69 
    70 qed_goal "bexCI" Set.thy 
    71    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)" (fn prems =>
    72   [ (rtac classical 1),
    73     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    74 
    75 val major::prems = Goalw [Bex_def]
    76     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    77 by (rtac (major RS exE) 1);
    78 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    79 qed "bexE";
    80 
    81 AddIs  [bexI];
    82 AddSEs [bexE];
    83 
    84 (*Trival rewrite rule*)
    85 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    86 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    87 qed "ball_triv";
    88 
    89 (*Dual form for existentials*)
    90 Goal "(? x:A. P) = ((? x. x:A) & P)";
    91 by (simp_tac (simpset() addsimps [Bex_def]) 1);
    92 qed "bex_triv";
    93 
    94 Addsimps [ball_triv, bex_triv];
    95 
    96 (** Congruence rules **)
    97 
    98 val prems = Goal
    99     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   100 \    (! x:A. P(x)) = (! x:B. Q(x))";
   101 by (resolve_tac (prems RL [ssubst]) 1);
   102 by (REPEAT (ares_tac [ballI,iffI] 1
   103      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   104 qed "ball_cong";
   105 
   106 val prems = Goal
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (? x:A. P(x)) = (? x:B. Q(x))";
   109 by (resolve_tac (prems RL [ssubst]) 1);
   110 by (REPEAT (etac bexE 1
   111      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   112 qed "bex_cong";
   113 
   114 section "Subsets";
   115 
   116 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   117 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   118 qed "subsetI";
   119 
   120 (*Map the type ('a set => anything) to just 'a.
   121   For overloading constants whose first argument has type "'a set" *)
   122 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   123 
   124 (*While (:) is not, its type must be kept
   125   for overloading of = to work.*)
   126 Blast.overloaded ("op :", domain_type);
   127 
   128 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   129 overload_1st_set "Bex";
   130 
   131 (*Image: retain the type of the set being expressed*)
   132 Blast.overloaded ("op ``", domain_type);
   133 
   134 (*Rule in Modus Ponens style*)
   135 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   136 by (Blast_tac 1);
   137 qed "subsetD";
   138 
   139 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   140 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   141  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   142 
   143 (*Converts A<=B to x:A ==> x:B*)
   144 fun impOfSubs th = th RSN (2, rev_subsetD);
   145 
   146 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   147  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   148 
   149 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   150  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   151 
   152 (*Classical elimination rule*)
   153 val major::prems = Goalw [subset_def] 
   154     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   155 by (rtac (major RS ballE) 1);
   156 by (REPEAT (eresolve_tac prems 1));
   157 qed "subsetCE";
   158 
   159 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   160 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   161 
   162 AddSIs [subsetI];
   163 AddEs  [subsetD, subsetCE];
   164 
   165 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   166  (fn _=> [Fast_tac 1]);		(*Blast_tac would try order_refl and fail*)
   167 
   168 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   169 by (Blast_tac 1);
   170 qed "subset_trans";
   171 
   172 
   173 section "Equality";
   174 
   175 (*Anti-symmetry of the subset relation*)
   176 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   177 by (rtac set_ext 1);
   178 by (blast_tac (claset() addIs [subsetD]) 1);
   179 qed "subset_antisym";
   180 val equalityI = subset_antisym;
   181 
   182 AddSIs [equalityI];
   183 
   184 (* Equality rules from ZF set theory -- are they appropriate here? *)
   185 Goal "A = B ==> A<=(B::'a set)";
   186 by (etac ssubst 1);
   187 by (rtac subset_refl 1);
   188 qed "equalityD1";
   189 
   190 Goal "A = B ==> B<=(A::'a set)";
   191 by (etac ssubst 1);
   192 by (rtac subset_refl 1);
   193 qed "equalityD2";
   194 
   195 val prems = Goal
   196     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   197 by (resolve_tac prems 1);
   198 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   199 qed "equalityE";
   200 
   201 val major::prems = Goal
   202     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   203 by (rtac (major RS equalityE) 1);
   204 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   205 qed "equalityCE";
   206 
   207 (*Lemma for creating induction formulae -- for "pattern matching" on p
   208   To make the induction hypotheses usable, apply "spec" or "bspec" to
   209   put universal quantifiers over the free variables in p. *)
   210 val prems = Goal 
   211     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   212 by (rtac mp 1);
   213 by (REPEAT (resolve_tac (refl::prems) 1));
   214 qed "setup_induction";
   215 
   216 
   217 section "The universal set -- UNIV";
   218 
   219 qed_goalw "UNIV_I" Set.thy [UNIV_def] "x : UNIV"
   220   (fn _ => [rtac CollectI 1, rtac TrueI 1]);
   221 
   222 Addsimps [UNIV_I];
   223 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   224 
   225 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   226   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   227 
   228 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   229     because of their interaction with congruence rules. **)
   230 
   231 Goalw [Ball_def] "Ball UNIV P = All P";
   232 by (Simp_tac 1);
   233 qed "ball_UNIV";
   234 
   235 Goalw [Bex_def] "Bex UNIV P = Ex P";
   236 by (Simp_tac 1);
   237 qed "bex_UNIV";
   238 Addsimps [ball_UNIV, bex_UNIV];
   239 
   240 
   241 section "The empty set -- {}";
   242 
   243 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   244  (fn _ => [ (Blast_tac 1) ]);
   245 
   246 Addsimps [empty_iff];
   247 
   248 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   249  (fn _ => [Full_simp_tac 1]);
   250 
   251 AddSEs [emptyE];
   252 
   253 qed_goal "empty_subsetI" Set.thy "{} <= A"
   254  (fn _ => [ (Blast_tac 1) ]);
   255 
   256 (*One effect is to delete the ASSUMPTION {} <= A*)
   257 AddIffs [empty_subsetI];
   258 
   259 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   260  (fn [prem]=>
   261   [ (blast_tac (claset() addIs [prem RS FalseE]) 1) ]);
   262 
   263 (*Use for reasoning about disjointness: A Int B = {} *)
   264 qed_goal "equals0D" Set.thy "!!a. A={} ==> a ~: A"
   265  (fn _ => [ (Blast_tac 1) ]);
   266 
   267 AddDs [equals0D, sym RS equals0D];
   268 
   269 Goalw [Ball_def] "Ball {} P = True";
   270 by (Simp_tac 1);
   271 qed "ball_empty";
   272 
   273 Goalw [Bex_def] "Bex {} P = False";
   274 by (Simp_tac 1);
   275 qed "bex_empty";
   276 Addsimps [ball_empty, bex_empty];
   277 
   278 Goal "UNIV ~= {}";
   279 by (blast_tac (claset() addEs [equalityE]) 1);
   280 qed "UNIV_not_empty";
   281 AddIffs [UNIV_not_empty];
   282 
   283 
   284 
   285 section "The Powerset operator -- Pow";
   286 
   287 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   288  (fn _ => [ (Asm_simp_tac 1) ]);
   289 
   290 AddIffs [Pow_iff]; 
   291 
   292 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   293  (fn _ => [ (etac CollectI 1) ]);
   294 
   295 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   296  (fn _=> [ (etac CollectD 1) ]);
   297 
   298 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   299 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   300 
   301 
   302 section "Set complement";
   303 
   304 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : -A) = (c~:A)"
   305  (fn _ => [ (Blast_tac 1) ]);
   306 
   307 Addsimps [Compl_iff];
   308 
   309 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   310 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   311 qed "ComplI";
   312 
   313 (*This form, with negated conclusion, works well with the Classical prover.
   314   Negated assumptions behave like formulae on the right side of the notional
   315   turnstile...*)
   316 Goalw [Compl_def] "c : -A ==> c~:A";
   317 by (etac CollectD 1);
   318 qed "ComplD";
   319 
   320 val ComplE = make_elim ComplD;
   321 
   322 AddSIs [ComplI];
   323 AddSEs [ComplE];
   324 
   325 
   326 section "Binary union -- Un";
   327 
   328 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   329  (fn _ => [ Blast_tac 1 ]);
   330 
   331 Addsimps [Un_iff];
   332 
   333 Goal "c:A ==> c : A Un B";
   334 by (Asm_simp_tac 1);
   335 qed "UnI1";
   336 
   337 Goal "c:B ==> c : A Un B";
   338 by (Asm_simp_tac 1);
   339 qed "UnI2";
   340 
   341 (*Classical introduction rule: no commitment to A vs B*)
   342 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   343  (fn prems=>
   344   [ (Simp_tac 1),
   345     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   346 
   347 val major::prems = Goalw [Un_def]
   348     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   349 by (rtac (major RS CollectD RS disjE) 1);
   350 by (REPEAT (eresolve_tac prems 1));
   351 qed "UnE";
   352 
   353 AddSIs [UnCI];
   354 AddSEs [UnE];
   355 
   356 
   357 section "Binary intersection -- Int";
   358 
   359 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   360  (fn _ => [ (Blast_tac 1) ]);
   361 
   362 Addsimps [Int_iff];
   363 
   364 Goal "[| c:A;  c:B |] ==> c : A Int B";
   365 by (Asm_simp_tac 1);
   366 qed "IntI";
   367 
   368 Goal "c : A Int B ==> c:A";
   369 by (Asm_full_simp_tac 1);
   370 qed "IntD1";
   371 
   372 Goal "c : A Int B ==> c:B";
   373 by (Asm_full_simp_tac 1);
   374 qed "IntD2";
   375 
   376 val [major,minor] = Goal
   377     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   378 by (rtac minor 1);
   379 by (rtac (major RS IntD1) 1);
   380 by (rtac (major RS IntD2) 1);
   381 qed "IntE";
   382 
   383 AddSIs [IntI];
   384 AddSEs [IntE];
   385 
   386 section "Set difference";
   387 
   388 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   389  (fn _ => [ (Blast_tac 1) ]);
   390 
   391 Addsimps [Diff_iff];
   392 
   393 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   394  (fn _=> [ Asm_simp_tac 1 ]);
   395 
   396 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   397  (fn _=> [ (Asm_full_simp_tac 1) ]);
   398 
   399 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   400  (fn _=> [ (Asm_full_simp_tac 1) ]);
   401 
   402 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   403  (fn prems=>
   404   [ (resolve_tac prems 1),
   405     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   406 
   407 AddSIs [DiffI];
   408 AddSEs [DiffE];
   409 
   410 
   411 section "Augmenting a set -- insert";
   412 
   413 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   414  (fn _ => [Blast_tac 1]);
   415 
   416 Addsimps [insert_iff];
   417 
   418 qed_goal "insertI1" Set.thy "a : insert a B"
   419  (fn _ => [Simp_tac 1]);
   420 
   421 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   422  (fn _=> [Asm_simp_tac 1]);
   423 
   424 qed_goalw "insertE" Set.thy [insert_def]
   425     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   426  (fn major::prems=>
   427   [ (rtac (major RS UnE) 1),
   428     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   429 
   430 (*Classical introduction rule*)
   431 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   432  (fn prems=>
   433   [ (Simp_tac 1),
   434     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   435 
   436 AddSIs [insertCI]; 
   437 AddSEs [insertE];
   438 
   439 section "Singletons, using insert";
   440 
   441 qed_goal "singletonI" Set.thy "a : {a}"
   442  (fn _=> [ (rtac insertI1 1) ]);
   443 
   444 Goal "b : {a} ==> b=a";
   445 by (Blast_tac 1);
   446 qed "singletonD";
   447 
   448 bind_thm ("singletonE", make_elim singletonD);
   449 
   450 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   451 (fn _ => [Blast_tac 1]);
   452 
   453 Goal "{a}={b} ==> a=b";
   454 by (blast_tac (claset() addEs [equalityE]) 1);
   455 qed "singleton_inject";
   456 
   457 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   458 AddSIs [singletonI];   
   459 AddSDs [singleton_inject];
   460 AddSEs [singletonE];
   461 
   462 Goal "{x. x=a} = {a}";
   463 by (Blast_tac 1);
   464 qed "singleton_conv";
   465 Addsimps [singleton_conv];
   466 
   467 Goal "{x. a=x} = {a}";
   468 by(Blast_tac 1);
   469 qed "singleton_conv2";
   470 Addsimps [singleton_conv2];
   471 
   472 
   473 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   474 
   475 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   476 by (Blast_tac 1);
   477 qed "UN_iff";
   478 
   479 Addsimps [UN_iff];
   480 
   481 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   482 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   483 by Auto_tac;
   484 qed "UN_I";
   485 
   486 val major::prems = Goalw [UNION_def]
   487     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   488 by (rtac (major RS CollectD RS bexE) 1);
   489 by (REPEAT (ares_tac prems 1));
   490 qed "UN_E";
   491 
   492 AddIs  [UN_I];
   493 AddSEs [UN_E];
   494 
   495 val prems = Goal
   496     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   497 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   498 by (REPEAT (etac UN_E 1
   499      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   500                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   501 qed "UN_cong";
   502 
   503 
   504 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   505 
   506 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   507 by Auto_tac;
   508 qed "INT_iff";
   509 
   510 Addsimps [INT_iff];
   511 
   512 val prems = Goalw [INTER_def]
   513     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   514 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   515 qed "INT_I";
   516 
   517 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   518 by Auto_tac;
   519 qed "INT_D";
   520 
   521 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   522 val major::prems = Goalw [INTER_def]
   523     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   524 by (rtac (major RS CollectD RS ballE) 1);
   525 by (REPEAT (eresolve_tac prems 1));
   526 qed "INT_E";
   527 
   528 AddSIs [INT_I];
   529 AddEs  [INT_D, INT_E];
   530 
   531 val prems = Goal
   532     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   533 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   534 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   535 by (REPEAT (dtac INT_D 1
   536      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   537 qed "INT_cong";
   538 
   539 
   540 section "Union";
   541 
   542 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   543 by (Blast_tac 1);
   544 qed "Union_iff";
   545 
   546 Addsimps [Union_iff];
   547 
   548 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   549 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   550 by Auto_tac;
   551 qed "UnionI";
   552 
   553 val major::prems = Goalw [Union_def]
   554     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   555 by (rtac (major RS UN_E) 1);
   556 by (REPEAT (ares_tac prems 1));
   557 qed "UnionE";
   558 
   559 AddIs  [UnionI];
   560 AddSEs [UnionE];
   561 
   562 
   563 section "Inter";
   564 
   565 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   566 by (Blast_tac 1);
   567 qed "Inter_iff";
   568 
   569 Addsimps [Inter_iff];
   570 
   571 val prems = Goalw [Inter_def]
   572     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   573 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   574 qed "InterI";
   575 
   576 (*A "destruct" rule -- every X in C contains A as an element, but
   577   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   578 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   579 by Auto_tac;
   580 qed "InterD";
   581 
   582 (*"Classical" elimination rule -- does not require proving X:C *)
   583 val major::prems = Goalw [Inter_def]
   584     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   585 by (rtac (major RS INT_E) 1);
   586 by (REPEAT (eresolve_tac prems 1));
   587 qed "InterE";
   588 
   589 AddSIs [InterI];
   590 AddEs  [InterD, InterE];
   591 
   592 
   593 (*** Image of a set under a function ***)
   594 
   595 (*Frequently b does not have the syntactic form of f(x).*)
   596 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   597 by (Blast_tac 1);
   598 qed "image_eqI";
   599 Addsimps [image_eqI];
   600 
   601 bind_thm ("imageI", refl RS image_eqI);
   602 
   603 (*The eta-expansion gives variable-name preservation.*)
   604 val major::prems = Goalw [image_def]
   605     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   606 by (rtac (major RS CollectD RS bexE) 1);
   607 by (REPEAT (ares_tac prems 1));
   608 qed "imageE";
   609 
   610 AddIs  [image_eqI];
   611 AddSEs [imageE]; 
   612 
   613 Goal "f``(A Un B) = f``A Un f``B";
   614 by (Blast_tac 1);
   615 qed "image_Un";
   616 
   617 Goal "(z : f``A) = (EX x:A. z = f x)";
   618 by (Blast_tac 1);
   619 qed "image_iff";
   620 
   621 (*This rewrite rule would confuse users if made default.*)
   622 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   623 by (Blast_tac 1);
   624 qed "image_subset_iff";
   625 
   626 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   627   many existing proofs.*)
   628 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   629 by (blast_tac (claset() addIs prems) 1);
   630 qed "image_subsetI";
   631 
   632 
   633 (*** Range of a function -- just a translation for image! ***)
   634 
   635 Goal "b=f(x) ==> b : range(f)";
   636 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   637 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   638 
   639 bind_thm ("rangeI", UNIV_I RS imageI);
   640 
   641 val [major,minor] = Goal 
   642     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   643 by (rtac (major RS imageE) 1);
   644 by (etac minor 1);
   645 qed "rangeE";
   646 
   647 
   648 (*** Set reasoning tools ***)
   649 
   650 
   651 (** Rewrite rules for boolean case-splitting: faster than 
   652 	addsplits[split_if]
   653 **)
   654 
   655 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   656 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   657 
   658 (*Split ifs on either side of the membership relation.
   659 	Not for Addsimps -- can cause goals to blow up!*)
   660 bind_thm ("split_if_mem1", 
   661     read_instantiate_sg (sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   662 bind_thm ("split_if_mem2", 
   663     read_instantiate_sg (sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   664 
   665 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   666 		  split_if_mem1, split_if_mem2];
   667 
   668 
   669 (*Each of these has ALREADY been added to simpset() above.*)
   670 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   671                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   672 
   673 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   674 
   675 simpset_ref() := simpset() addcongs [ball_cong,bex_cong]
   676                     setmksimps (mksimps mksimps_pairs);
   677 
   678 Addsimps[subset_UNIV, subset_refl];
   679 
   680 
   681 (*** < ***)
   682 
   683 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   684 by (Blast_tac 1);
   685 qed "psubsetI";
   686 
   687 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   688 by Auto_tac;
   689 qed "psubset_insertD";
   690 
   691 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);