src/HOL/Complete_Lattices.thy
author haftmann
Tue Mar 18 22:11:46 2014 +0100 (2014-03-18)
changeset 56212 3253aaf73a01
parent 56166 9a241bc276cd
child 56218 1c3f1f2431f9
permissions -rw-r--r--
consolidated theorem names containing INFI and SUPR: have INF and SUP instead uniformly
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Fun
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 begin
    19 
    20 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    21   INF_def: "INFI A f = \<Sqinter>(f ` A)"
    22 
    23 lemma Inf_image_eq [simp]:
    24   "\<Sqinter>(f ` A) = INFI A f"
    25   by (simp add: INF_def)
    26 
    27 lemma INF_image [simp]:
    28   "INFI (f ` A) g = INFI A (g \<circ> f)"
    29   by (simp only: INF_def image_comp)
    30 
    31 lemma INF_identity_eq [simp]:
    32   "INFI A (\<lambda>x. x) = \<Sqinter>A"
    33   by (simp add: INF_def)
    34 
    35 lemma INF_id_eq [simp]:
    36   "INFI A id = \<Sqinter>A"
    37   by (simp add: id_def)
    38 
    39 lemma INF_cong:
    40   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> INFI A C = INFI B D"
    41   by (simp add: INF_def image_def)
    42 
    43 end
    44 
    45 class Sup =
    46   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    47 begin
    48 
    49 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    50   SUP_def: "SUPR A f = \<Squnion>(f ` A)"
    51 
    52 lemma Sup_image_eq [simp]:
    53   "\<Squnion>(f ` A) = SUPR A f"
    54   by (simp add: SUP_def)
    55 
    56 lemma SUP_image [simp]:
    57   "SUPR (f ` A) g = SUPR A (g \<circ> f)"
    58   by (simp only: SUP_def image_comp)
    59 
    60 lemma SUP_identity_eq [simp]:
    61   "SUPR A (\<lambda>x. x) = \<Squnion>A"
    62   by (simp add: SUP_def)
    63 
    64 lemma SUP_id_eq [simp]:
    65   "SUPR A id = \<Squnion>A"
    66   by (simp add: id_def)
    67 
    68 lemma SUP_cong:
    69   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> SUPR A C = SUPR B D"
    70   by (simp add: SUP_def image_def)
    71 
    72 end
    73 
    74 text {*
    75   Note: must use names @{const INFI} and @{const SUPR} here instead of
    76   @{text INF} and @{text SUP} to allow the following syntax coexist
    77   with the plain constant names.
    78 *}
    79 
    80 syntax
    81   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    82   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    83   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    84   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    85 
    86 syntax (xsymbols)
    87   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    88   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    89   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    90   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    91 
    92 translations
    93   "INF x y. B"   == "INF x. INF y. B"
    94   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
    95   "INF x. B"     == "INF x:CONST UNIV. B"
    96   "INF x:A. B"   == "CONST INFI A (%x. B)"
    97   "SUP x y. B"   == "SUP x. SUP y. B"
    98   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
    99   "SUP x. B"     == "SUP x:CONST UNIV. B"
   100   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   101 
   102 print_translation {*
   103   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   104     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   105 *} -- {* to avoid eta-contraction of body *}
   106 
   107 subsection {* Abstract complete lattices *}
   108 
   109 text {* A complete lattice always has a bottom and a top,
   110 so we include them into the following type class,
   111 along with assumptions that define bottom and top
   112 in terms of infimum and supremum. *}
   113 
   114 class complete_lattice = lattice + Inf + Sup + bot + top +
   115   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
   116      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
   117   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
   118      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
   119   assumes Inf_empty [simp]: "\<Sqinter>{} = \<top>"
   120   assumes Sup_empty [simp]: "\<Squnion>{} = \<bottom>"
   121 begin
   122 
   123 subclass bounded_lattice
   124 proof
   125   fix a
   126   show "\<bottom> \<le> a" by (auto intro: Sup_least simp only: Sup_empty [symmetric])
   127   show "a \<le> \<top>" by (auto intro: Inf_greatest simp only: Inf_empty [symmetric])
   128 qed
   129 
   130 lemma dual_complete_lattice:
   131   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   132   by (auto intro!: class.complete_lattice.intro dual_lattice)
   133     (unfold_locales, (fact Inf_empty Sup_empty
   134         Sup_upper Sup_least Inf_lower Inf_greatest)+)
   135 
   136 end
   137 
   138 context complete_lattice
   139 begin
   140 
   141 lemma INF_foundation_dual:
   142   "Sup.SUPR Inf = INFI"
   143   by (simp add: fun_eq_iff Sup.SUP_def)
   144 
   145 lemma SUP_foundation_dual:
   146   "Inf.INFI Sup = SUPR"
   147   by (simp add: fun_eq_iff Inf.INF_def)
   148 
   149 lemma Sup_eqI:
   150   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
   151   by (blast intro: antisym Sup_least Sup_upper)
   152 
   153 lemma Inf_eqI:
   154   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
   155   by (blast intro: antisym Inf_greatest Inf_lower)
   156 
   157 lemma SUP_eqI:
   158   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   159   using Sup_eqI [of "f ` A" x] by auto
   160 
   161 lemma INF_eqI:
   162   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   163   using Inf_eqI [of "f ` A" x] by auto
   164 
   165 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   166   using Inf_lower [of _ "f ` A"] by simp
   167 
   168 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   169   using Inf_greatest [of "f ` A"] by auto
   170 
   171 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   172   using Sup_upper [of _ "f ` A"] by simp
   173 
   174 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   175   using Sup_least [of "f ` A"] by auto
   176 
   177 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   178   using Inf_lower [of u A] by auto
   179 
   180 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   181   using INF_lower [of i A f] by auto
   182 
   183 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   184   using Sup_upper [of u A] by auto
   185 
   186 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   187   using SUP_upper [of i A f] by auto
   188 
   189 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   190   by (auto intro: Inf_greatest dest: Inf_lower)
   191 
   192 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   193   using le_Inf_iff [of _ "f ` A"] by simp
   194 
   195 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   196   by (auto intro: Sup_least dest: Sup_upper)
   197 
   198 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   199   using Sup_le_iff [of "f ` A"] by simp
   200 
   201 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   202   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   203 
   204 lemma INF_insert [simp]: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFI A f"
   205   unfolding INF_def Inf_insert by simp
   206 
   207 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   208   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   209 
   210 lemma SUP_insert [simp]: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPR A f"
   211   unfolding SUP_def Sup_insert by simp
   212 
   213 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   214   by (simp add: INF_def)
   215 
   216 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   217   by (simp add: SUP_def)
   218 
   219 lemma Inf_UNIV [simp]:
   220   "\<Sqinter>UNIV = \<bottom>"
   221   by (auto intro!: antisym Inf_lower)
   222 
   223 lemma Sup_UNIV [simp]:
   224   "\<Squnion>UNIV = \<top>"
   225   by (auto intro!: antisym Sup_upper)
   226 
   227 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   228   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   229 
   230 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   231   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   232 
   233 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   234   by (auto intro: Inf_greatest Inf_lower)
   235 
   236 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   237   by (auto intro: Sup_least Sup_upper)
   238 
   239 lemma Inf_mono:
   240   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   241   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   242 proof (rule Inf_greatest)
   243   fix b assume "b \<in> B"
   244   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   245   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   246   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   247 qed
   248 
   249 lemma INF_mono:
   250   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   251   using Inf_mono [of "g ` B" "f ` A"] by auto
   252 
   253 lemma Sup_mono:
   254   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   255   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   256 proof (rule Sup_least)
   257   fix a assume "a \<in> A"
   258   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   259   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   260   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   261 qed
   262 
   263 lemma SUP_mono:
   264   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   265   using Sup_mono [of "f ` A" "g ` B"] by auto
   266 
   267 lemma INF_superset_mono:
   268   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   269   -- {* The last inclusion is POSITIVE! *}
   270   by (blast intro: INF_mono dest: subsetD)
   271 
   272 lemma SUP_subset_mono:
   273   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   274   by (blast intro: SUP_mono dest: subsetD)
   275 
   276 lemma Inf_less_eq:
   277   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   278     and "A \<noteq> {}"
   279   shows "\<Sqinter>A \<sqsubseteq> u"
   280 proof -
   281   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   282   moreover from `v \<in> A` assms(1) have "v \<sqsubseteq> u" by blast
   283   ultimately show ?thesis by (rule Inf_lower2)
   284 qed
   285 
   286 lemma less_eq_Sup:
   287   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   288     and "A \<noteq> {}"
   289   shows "u \<sqsubseteq> \<Squnion>A"
   290 proof -
   291   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   292   moreover from `v \<in> A` assms(1) have "u \<sqsubseteq> v" by blast
   293   ultimately show ?thesis by (rule Sup_upper2)
   294 qed
   295 
   296 lemma SUP_eq:
   297   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   298   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   299   shows "(\<Squnion>i\<in>A. f i) = (\<Squnion>j\<in>B. g j)"
   300   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   301 
   302 lemma INF_eq:
   303   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   304   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   305   shows "(\<Sqinter>i\<in>A. f i) = (\<Sqinter>j\<in>B. g j)"
   306   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   307 
   308 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   309   by (auto intro: Inf_greatest Inf_lower)
   310 
   311 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   312   by (auto intro: Sup_least Sup_upper)
   313 
   314 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   315   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   316 
   317 lemma INF_union:
   318   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   319   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   320 
   321 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   322   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   323 
   324 lemma SUP_union:
   325   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   326   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   327 
   328 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   329   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   330 
   331 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   332 proof (rule antisym)
   333   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   334 next
   335   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   336 qed
   337 
   338 lemma Inf_top_conv [simp]:
   339   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   340   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   341 proof -
   342   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   343   proof
   344     assume "\<forall>x\<in>A. x = \<top>"
   345     then have "A = {} \<or> A = {\<top>}" by auto
   346     then show "\<Sqinter>A = \<top>" by auto
   347   next
   348     assume "\<Sqinter>A = \<top>"
   349     show "\<forall>x\<in>A. x = \<top>"
   350     proof (rule ccontr)
   351       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   352       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   353       then obtain B where "A = insert x B" by blast
   354       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   355     qed
   356   qed
   357   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   358 qed
   359 
   360 lemma INF_top_conv [simp]:
   361   "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   362   "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   363   using Inf_top_conv [of "B ` A"] by simp_all
   364 
   365 lemma Sup_bot_conv [simp]:
   366   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   367   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   368   using dual_complete_lattice
   369   by (rule complete_lattice.Inf_top_conv)+
   370 
   371 lemma SUP_bot_conv [simp]:
   372  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   373  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   374   using Sup_bot_conv [of "B ` A"] by simp_all
   375 
   376 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   377   by (auto intro: antisym INF_lower INF_greatest)
   378 
   379 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   380   by (auto intro: antisym SUP_upper SUP_least)
   381 
   382 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   383   by (cases "A = {}") simp_all
   384 
   385 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   386   by (cases "A = {}") simp_all
   387 
   388 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   389   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   390 
   391 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   392   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   393 
   394 lemma INF_absorb:
   395   assumes "k \<in> I"
   396   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   397 proof -
   398   from assms obtain J where "I = insert k J" by blast
   399   then show ?thesis by simp
   400 qed
   401 
   402 lemma SUP_absorb:
   403   assumes "k \<in> I"
   404   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   405 proof -
   406   from assms obtain J where "I = insert k J" by blast
   407   then show ?thesis by simp
   408 qed
   409 
   410 lemma INF_constant:
   411   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   412   by simp
   413 
   414 lemma SUP_constant:
   415   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   416   by simp
   417 
   418 lemma less_INF_D:
   419   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   420 proof -
   421   note `y < (\<Sqinter>i\<in>A. f i)`
   422   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   423     by (rule INF_lower)
   424   finally show "y < f i" .
   425 qed
   426 
   427 lemma SUP_lessD:
   428   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   429 proof -
   430   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   431     by (rule SUP_upper)
   432   also note `(\<Squnion>i\<in>A. f i) < y`
   433   finally show "f i < y" .
   434 qed
   435 
   436 lemma INF_UNIV_bool_expand:
   437   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   438   by (simp add: UNIV_bool inf_commute)
   439 
   440 lemma SUP_UNIV_bool_expand:
   441   "(\<Squnion>b. A b) = A True \<squnion> A False"
   442   by (simp add: UNIV_bool sup_commute)
   443 
   444 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   445   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   446 
   447 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFI A f \<le> SUPR A f"
   448   using Inf_le_Sup [of "f ` A"] by simp
   449 
   450 lemma SUP_eq_const:
   451   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> SUPR I f = x"
   452   by (auto intro: SUP_eqI)
   453 
   454 lemma INF_eq_const:
   455   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> INFI I f = x"
   456   by (auto intro: INF_eqI)
   457 
   458 lemma SUP_eq_iff:
   459   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> c \<le> f i) \<Longrightarrow> (SUPR I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   460   using SUP_eq_const[of I f c] SUP_upper[of _ I f] by (auto intro: antisym)
   461 
   462 lemma INF_eq_iff:
   463   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i \<le> c) \<Longrightarrow> (INFI I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   464   using INF_eq_const[of I f c] INF_lower[of _ I f] by (auto intro: antisym)
   465 
   466 end
   467 
   468 class complete_distrib_lattice = complete_lattice +
   469   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   470   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   471 begin
   472 
   473 lemma sup_INF:
   474   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   475   by (simp only: INF_def sup_Inf image_image)
   476 
   477 lemma inf_SUP:
   478   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   479   by (simp only: SUP_def inf_Sup image_image)
   480 
   481 lemma dual_complete_distrib_lattice:
   482   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   483   apply (rule class.complete_distrib_lattice.intro)
   484   apply (fact dual_complete_lattice)
   485   apply (rule class.complete_distrib_lattice_axioms.intro)
   486   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   487   done
   488 
   489 subclass distrib_lattice proof
   490   fix a b c
   491   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   492   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   493 qed
   494 
   495 lemma Inf_sup:
   496   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   497   by (simp add: sup_Inf sup_commute)
   498 
   499 lemma Sup_inf:
   500   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   501   by (simp add: inf_Sup inf_commute)
   502 
   503 lemma INF_sup: 
   504   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   505   by (simp add: sup_INF sup_commute)
   506 
   507 lemma SUP_inf:
   508   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   509   by (simp add: inf_SUP inf_commute)
   510 
   511 lemma Inf_sup_eq_top_iff:
   512   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   513   by (simp only: Inf_sup INF_top_conv)
   514 
   515 lemma Sup_inf_eq_bot_iff:
   516   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   517   by (simp only: Sup_inf SUP_bot_conv)
   518 
   519 lemma INF_sup_distrib2:
   520   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   521   by (subst INF_commute) (simp add: sup_INF INF_sup)
   522 
   523 lemma SUP_inf_distrib2:
   524   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   525   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   526 
   527 context
   528   fixes f :: "'a \<Rightarrow> 'b::complete_lattice"
   529   assumes "mono f"
   530 begin
   531 
   532 lemma mono_Inf:
   533   shows "f (\<Sqinter>A) \<le> (\<Sqinter>x\<in>A. f x)"
   534   using `mono f` by (auto intro: complete_lattice_class.INF_greatest Inf_lower dest: monoD)
   535 
   536 lemma mono_Sup:
   537   shows "(\<Squnion>x\<in>A. f x) \<le> f (\<Squnion>A)"
   538   using `mono f` by (auto intro: complete_lattice_class.SUP_least Sup_upper dest: monoD)
   539 
   540 end
   541 
   542 end
   543 
   544 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   545 begin
   546 
   547 lemma dual_complete_boolean_algebra:
   548   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   549   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   550 
   551 lemma uminus_Inf:
   552   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   553 proof (rule antisym)
   554   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   555     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   556   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   557     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   558 qed
   559 
   560 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   561   by (simp only: INF_def SUP_def uminus_Inf image_image)
   562 
   563 lemma uminus_Sup:
   564   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   565 proof -
   566   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_INF)
   567   then show ?thesis by simp
   568 qed
   569   
   570 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   571   by (simp only: INF_def SUP_def uminus_Sup image_image)
   572 
   573 end
   574 
   575 class complete_linorder = linorder + complete_lattice
   576 begin
   577 
   578 lemma dual_complete_linorder:
   579   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   580   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   581 
   582 lemma complete_linorder_inf_min: "inf = min"
   583   by (auto intro: antisym simp add: min_def fun_eq_iff)
   584 
   585 lemma complete_linorder_sup_max: "sup = max"
   586   by (auto intro: antisym simp add: max_def fun_eq_iff)
   587 
   588 lemma Inf_less_iff:
   589   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   590   unfolding not_le [symmetric] le_Inf_iff by auto
   591 
   592 lemma INF_less_iff:
   593   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   594   using Inf_less_iff [of "f ` A"] by simp
   595 
   596 lemma less_Sup_iff:
   597   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   598   unfolding not_le [symmetric] Sup_le_iff by auto
   599 
   600 lemma less_SUP_iff:
   601   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   602   using less_Sup_iff [of _ "f ` A"] by simp
   603 
   604 lemma Sup_eq_top_iff [simp]:
   605   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   606 proof
   607   assume *: "\<Squnion>A = \<top>"
   608   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   609   proof (intro allI impI)
   610     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   611       unfolding less_Sup_iff by auto
   612   qed
   613 next
   614   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   615   show "\<Squnion>A = \<top>"
   616   proof (rule ccontr)
   617     assume "\<Squnion>A \<noteq> \<top>"
   618     with top_greatest [of "\<Squnion>A"]
   619     have "\<Squnion>A < \<top>" unfolding le_less by auto
   620     then have "\<Squnion>A < \<Squnion>A"
   621       using * unfolding less_Sup_iff by auto
   622     then show False by auto
   623   qed
   624 qed
   625 
   626 lemma SUP_eq_top_iff [simp]:
   627   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   628   using Sup_eq_top_iff [of "f ` A"] by simp
   629 
   630 lemma Inf_eq_bot_iff [simp]:
   631   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   632   using dual_complete_linorder
   633   by (rule complete_linorder.Sup_eq_top_iff)
   634 
   635 lemma INF_eq_bot_iff [simp]:
   636   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   637   using Inf_eq_bot_iff [of "f ` A"] by simp
   638 
   639 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   640 proof safe
   641   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   642   then have "y > \<Sqinter>A" by auto
   643   then show "\<exists>a\<in>A. y > a"
   644     unfolding Inf_less_iff .
   645 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   646 
   647 lemma INF_le_iff:
   648   "INFI A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   649   using Inf_le_iff [of "f ` A"] by simp
   650 
   651 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   652 proof safe
   653   fix y assume "x \<le> \<Squnion>A" "y < x"
   654   then have "y < \<Squnion>A" by auto
   655   then show "\<exists>a\<in>A. y < a"
   656     unfolding less_Sup_iff .
   657 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   658 
   659 lemma le_SUP_iff: "x \<le> SUPR A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   660   using le_Sup_iff [of _ "f ` A"] by simp
   661 
   662 subclass complete_distrib_lattice
   663 proof
   664   fix a and B
   665   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   666     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   667       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   668         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   669 qed
   670 
   671 end
   672 
   673 
   674 subsection {* Complete lattice on @{typ bool} *}
   675 
   676 instantiation bool :: complete_lattice
   677 begin
   678 
   679 definition
   680   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   681 
   682 definition
   683   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   684 
   685 instance proof
   686 qed (auto intro: bool_induct)
   687 
   688 end
   689 
   690 lemma not_False_in_image_Ball [simp]:
   691   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   692   by auto
   693 
   694 lemma True_in_image_Bex [simp]:
   695   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   696   by auto
   697 
   698 lemma INF_bool_eq [simp]:
   699   "INFI = Ball"
   700   by (simp add: fun_eq_iff INF_def)
   701 
   702 lemma SUP_bool_eq [simp]:
   703   "SUPR = Bex"
   704   by (simp add: fun_eq_iff SUP_def)
   705 
   706 instance bool :: complete_boolean_algebra proof
   707 qed (auto intro: bool_induct)
   708 
   709 
   710 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   711 
   712 instantiation "fun" :: (type, complete_lattice) complete_lattice
   713 begin
   714 
   715 definition
   716   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   717 
   718 lemma Inf_apply [simp, code]:
   719   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   720   by (simp add: Inf_fun_def)
   721 
   722 definition
   723   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   724 
   725 lemma Sup_apply [simp, code]:
   726   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   727   by (simp add: Sup_fun_def)
   728 
   729 instance proof
   730 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   731 
   732 end
   733 
   734 lemma INF_apply [simp]:
   735   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   736   using Inf_apply [of "f ` A"] by (simp add: comp_def)
   737 
   738 lemma SUP_apply [simp]:
   739   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   740   using Sup_apply [of "f ` A"] by (simp add: comp_def)
   741 
   742 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   743 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf fun_eq_iff image_image
   744   simp del: Inf_image_eq Sup_image_eq)
   745 
   746 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   747 
   748 
   749 subsection {* Complete lattice on unary and binary predicates *}
   750 
   751 lemma INF1_iff: "(\<Sqinter>x\<in>A. B x) b = (\<forall>x\<in>A. B x b)"
   752   by simp
   753 
   754 lemma INF2_iff: "(\<Sqinter>x\<in>A. B x) b c = (\<forall>x\<in>A. B x b c)"
   755   by simp
   756 
   757 lemma INF1_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   758   by auto
   759 
   760 lemma INF2_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   761   by auto
   762 
   763 lemma INF1_D: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   764   by auto
   765 
   766 lemma INF2_D: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   767   by auto
   768 
   769 lemma INF1_E: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> (B a b \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   770   by auto
   771 
   772 lemma INF2_E: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> (B a b c \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   773   by auto
   774 
   775 lemma SUP1_iff: "(\<Squnion>x\<in>A. B x) b = (\<exists>x\<in>A. B x b)"
   776   by simp
   777 
   778 lemma SUP2_iff: "(\<Squnion>x\<in>A. B x) b c = (\<exists>x\<in>A. B x b c)"
   779   by simp
   780 
   781 lemma SUP1_I: "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   782   by auto
   783 
   784 lemma SUP2_I: "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   785   by auto
   786 
   787 lemma SUP1_E: "(\<Squnion>x\<in>A. B x) b \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b \<Longrightarrow> R) \<Longrightarrow> R"
   788   by auto
   789 
   790 lemma SUP2_E: "(\<Squnion>x\<in>A. B x) b c \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b c \<Longrightarrow> R) \<Longrightarrow> R"
   791   by auto
   792 
   793 
   794 subsection {* Complete lattice on @{typ "_ set"} *}
   795 
   796 instantiation "set" :: (type) complete_lattice
   797 begin
   798 
   799 definition
   800   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   801 
   802 definition
   803   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   804 
   805 instance proof
   806 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   807 
   808 end
   809 
   810 instance "set" :: (type) complete_boolean_algebra
   811 proof
   812 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   813   
   814 
   815 subsubsection {* Inter *}
   816 
   817 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   818   "Inter S \<equiv> \<Sqinter>S"
   819   
   820 notation (xsymbols)
   821   Inter  ("\<Inter>_" [900] 900)
   822 
   823 lemma Inter_eq:
   824   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   825 proof (rule set_eqI)
   826   fix x
   827   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   828     by auto
   829   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   830     by (simp add: Inf_set_def image_def)
   831 qed
   832 
   833 lemma Inter_iff [simp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   834   by (unfold Inter_eq) blast
   835 
   836 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   837   by (simp add: Inter_eq)
   838 
   839 text {*
   840   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   841   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   842   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   843 *}
   844 
   845 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   846   by auto
   847 
   848 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   849   -- {* ``Classical'' elimination rule -- does not require proving
   850     @{prop "X \<in> C"}. *}
   851   by (unfold Inter_eq) blast
   852 
   853 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   854   by (fact Inf_lower)
   855 
   856 lemma Inter_subset:
   857   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   858   by (fact Inf_less_eq)
   859 
   860 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   861   by (fact Inf_greatest)
   862 
   863 lemma Inter_empty: "\<Inter>{} = UNIV"
   864   by (fact Inf_empty) (* already simp *)
   865 
   866 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   867   by (fact Inf_UNIV) (* already simp *)
   868 
   869 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   870   by (fact Inf_insert) (* already simp *)
   871 
   872 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   873   by (fact less_eq_Inf_inter)
   874 
   875 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   876   by (fact Inf_union_distrib)
   877 
   878 lemma Inter_UNIV_conv [simp]:
   879   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   880   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   881   by (fact Inf_top_conv)+
   882 
   883 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   884   by (fact Inf_superset_mono)
   885 
   886 
   887 subsubsection {* Intersections of families *}
   888 
   889 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   890   "INTER \<equiv> INFI"
   891 
   892 text {*
   893   Note: must use name @{const INTER} here instead of @{text INT}
   894   to allow the following syntax coexist with the plain constant name.
   895 *}
   896 
   897 syntax
   898   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   899   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   900 
   901 syntax (xsymbols)
   902   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   903   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   904 
   905 syntax (latex output)
   906   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   907   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   908 
   909 translations
   910   "INT x y. B"  == "INT x. INT y. B"
   911   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   912   "INT x. B"    == "INT x:CONST UNIV. B"
   913   "INT x:A. B"  == "CONST INTER A (%x. B)"
   914 
   915 print_translation {*
   916   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   917 *} -- {* to avoid eta-contraction of body *}
   918 
   919 lemma INTER_eq:
   920   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   921   by (auto intro!: INF_eqI)
   922 
   923 lemma Inter_image_eq:
   924   "\<Inter>(B ` A) = (\<Inter>x\<in>A. B x)"
   925   by (fact Inf_image_eq)
   926 
   927 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   928   using Inter_iff [of _ "B ` A"] by simp
   929 
   930 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   931   by (auto simp add: INF_def image_def)
   932 
   933 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   934   by auto
   935 
   936 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   937   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   938   by (auto simp add: INF_def image_def)
   939 
   940 lemma INT_cong [cong]:
   941   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   942   by (fact INF_cong)
   943 
   944 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   945   by blast
   946 
   947 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   948   by blast
   949 
   950 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   951   by (fact INF_lower)
   952 
   953 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   954   by (fact INF_greatest)
   955 
   956 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
   957   by (fact INF_empty)
   958 
   959 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   960   by (fact INF_absorb)
   961 
   962 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   963   by (fact le_INF_iff)
   964 
   965 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   966   by (fact INF_insert)
   967 
   968 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   969   by (fact INF_union)
   970 
   971 lemma INT_insert_distrib:
   972   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   973   by blast
   974 
   975 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   976   by (fact INF_constant)
   977 
   978 lemma INTER_UNIV_conv:
   979  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   980  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   981   by (fact INF_top_conv)+ (* already simp *)
   982 
   983 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   984   by (fact INF_UNIV_bool_expand)
   985 
   986 lemma INT_anti_mono:
   987   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   988   -- {* The last inclusion is POSITIVE! *}
   989   by (fact INF_superset_mono)
   990 
   991 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   992   by blast
   993 
   994 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   995   by blast
   996 
   997 
   998 subsubsection {* Union *}
   999 
  1000 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
  1001   "Union S \<equiv> \<Squnion>S"
  1002 
  1003 notation (xsymbols)
  1004   Union  ("\<Union>_" [900] 900)
  1005 
  1006 lemma Union_eq:
  1007   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
  1008 proof (rule set_eqI)
  1009   fix x
  1010   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
  1011     by auto
  1012   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
  1013     by (simp add: Sup_set_def image_def)
  1014 qed
  1015 
  1016 lemma Union_iff [simp]:
  1017   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
  1018   by (unfold Union_eq) blast
  1019 
  1020 lemma UnionI [intro]:
  1021   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
  1022   -- {* The order of the premises presupposes that @{term C} is rigid;
  1023     @{term A} may be flexible. *}
  1024   by auto
  1025 
  1026 lemma UnionE [elim!]:
  1027   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
  1028   by auto
  1029 
  1030 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
  1031   by (fact Sup_upper)
  1032 
  1033 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
  1034   by (fact Sup_least)
  1035 
  1036 lemma Union_empty: "\<Union>{} = {}"
  1037   by (fact Sup_empty) (* already simp *)
  1038 
  1039 lemma Union_UNIV: "\<Union>UNIV = UNIV"
  1040   by (fact Sup_UNIV) (* already simp *)
  1041 
  1042 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
  1043   by (fact Sup_insert) (* already simp *)
  1044 
  1045 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
  1046   by (fact Sup_union_distrib)
  1047 
  1048 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1049   by (fact Sup_inter_less_eq)
  1050 
  1051 lemma Union_empty_conv: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1052   by (fact Sup_bot_conv) (* already simp *)
  1053 
  1054 lemma empty_Union_conv: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1055   by (fact Sup_bot_conv) (* already simp *)
  1056 
  1057 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1058   by blast
  1059 
  1060 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1061   by blast
  1062 
  1063 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
  1064   by (fact Sup_subset_mono)
  1065 
  1066 
  1067 subsubsection {* Unions of families *}
  1068 
  1069 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1070   "UNION \<equiv> SUPR"
  1071 
  1072 text {*
  1073   Note: must use name @{const UNION} here instead of @{text UN}
  1074   to allow the following syntax coexist with the plain constant name.
  1075 *}
  1076 
  1077 syntax
  1078   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1079   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1080 
  1081 syntax (xsymbols)
  1082   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1083   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1084 
  1085 syntax (latex output)
  1086   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1087   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1088 
  1089 translations
  1090   "UN x y. B"   == "UN x. UN y. B"
  1091   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
  1092   "UN x. B"     == "UN x:CONST UNIV. B"
  1093   "UN x:A. B"   == "CONST UNION A (%x. B)"
  1094 
  1095 text {*
  1096   Note the difference between ordinary xsymbol syntax of indexed
  1097   unions and intersections (e.g.\ @{text"\<Union>a\<^sub>1\<in>A\<^sub>1. B"})
  1098   and their \LaTeX\ rendition: @{term"\<Union>a\<^sub>1\<in>A\<^sub>1. B"}. The
  1099   former does not make the index expression a subscript of the
  1100   union/intersection symbol because this leads to problems with nested
  1101   subscripts in Proof General.
  1102 *}
  1103 
  1104 print_translation {*
  1105   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1106 *} -- {* to avoid eta-contraction of body *}
  1107 
  1108 lemma UNION_eq:
  1109   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1110   by (auto intro!: SUP_eqI)
  1111 
  1112 lemma bind_UNION [code]:
  1113   "Set.bind A f = UNION A f"
  1114   by (simp add: bind_def UNION_eq)
  1115 
  1116 lemma member_bind [simp]:
  1117   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1118   by (simp add: bind_UNION)
  1119 
  1120 lemma Union_image_eq:
  1121   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
  1122   by (fact Sup_image_eq)
  1123 
  1124 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1125   using Union_iff [of _ "B ` A"] by simp
  1126 
  1127 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1128   -- {* The order of the premises presupposes that @{term A} is rigid;
  1129     @{term b} may be flexible. *}
  1130   by auto
  1131 
  1132 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1133   by (auto simp add: SUP_def image_def)
  1134 
  1135 lemma UN_cong [cong]:
  1136   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1137   by (fact SUP_cong)
  1138 
  1139 lemma strong_UN_cong:
  1140   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1141   by (unfold simp_implies_def) (fact UN_cong)
  1142 
  1143 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1144   by blast
  1145 
  1146 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1147   by (fact SUP_upper)
  1148 
  1149 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1150   by (fact SUP_least)
  1151 
  1152 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1153   by blast
  1154 
  1155 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1156   by blast
  1157 
  1158 lemma UN_empty: "(\<Union>x\<in>{}. B x) = {}"
  1159   by (fact SUP_empty)
  1160 
  1161 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1162   by (fact SUP_bot) (* already simp *)
  1163 
  1164 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1165   by (fact SUP_absorb)
  1166 
  1167 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1168   by (fact SUP_insert)
  1169 
  1170 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1171   by (fact SUP_union)
  1172 
  1173 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1174   by blast
  1175 
  1176 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1177   by (fact SUP_le_iff)
  1178 
  1179 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1180   by (fact SUP_constant)
  1181 
  1182 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1183   by blast
  1184 
  1185 lemma UNION_empty_conv:
  1186   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1187   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1188   by (fact SUP_bot_conv)+ (* already simp *)
  1189 
  1190 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1191   by blast
  1192 
  1193 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1194   by blast
  1195 
  1196 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1197   by blast
  1198 
  1199 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1200   by (auto simp add: split_if_mem2)
  1201 
  1202 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1203   by (fact SUP_UNIV_bool_expand)
  1204 
  1205 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1206   by blast
  1207 
  1208 lemma UN_mono:
  1209   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1210     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1211   by (fact SUP_subset_mono)
  1212 
  1213 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1214   by blast
  1215 
  1216 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1217   by blast
  1218 
  1219 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1220   -- {* NOT suitable for rewriting *}
  1221   by blast
  1222 
  1223 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1224   by blast
  1225 
  1226 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1227   by blast
  1228 
  1229 
  1230 subsubsection {* Distributive laws *}
  1231 
  1232 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1233   by (fact inf_Sup)
  1234 
  1235 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1236   by (fact sup_Inf)
  1237 
  1238 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1239   by (fact Sup_inf)
  1240 
  1241 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1242   by (rule sym) (rule INF_inf_distrib)
  1243 
  1244 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1245   by (rule sym) (rule SUP_sup_distrib)
  1246 
  1247 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)" -- {* FIXME drop *}
  1248   by (simp add: INT_Int_distrib)
  1249 
  1250 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)" -- {* FIXME drop *}
  1251   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1252   -- {* Union of a family of unions *}
  1253   by (simp add: UN_Un_distrib)
  1254 
  1255 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1256   by (fact sup_INF)
  1257 
  1258 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1259   -- {* Halmos, Naive Set Theory, page 35. *}
  1260   by (fact inf_SUP)
  1261 
  1262 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1263   by (fact SUP_inf_distrib2)
  1264 
  1265 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1266   by (fact INF_sup_distrib2)
  1267 
  1268 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1269   by (fact Sup_inf_eq_bot_iff)
  1270 
  1271 
  1272 subsection {* Injections and bijections *}
  1273 
  1274 lemma inj_on_Inter:
  1275   "S \<noteq> {} \<Longrightarrow> (\<And>A. A \<in> S \<Longrightarrow> inj_on f A) \<Longrightarrow> inj_on f (\<Inter>S)"
  1276   unfolding inj_on_def by blast
  1277 
  1278 lemma inj_on_INTER:
  1279   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> inj_on f (A i)) \<Longrightarrow> inj_on f (\<Inter>i \<in> I. A i)"
  1280   unfolding inj_on_def by blast
  1281 
  1282 lemma inj_on_UNION_chain:
  1283   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1284          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1285   shows "inj_on f (\<Union> i \<in> I. A i)"
  1286 proof -
  1287   {
  1288     fix i j x y
  1289     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
  1290       and ***: "f x = f y"
  1291     have "x = y"
  1292     proof -
  1293       {
  1294         assume "A i \<le> A j"
  1295         with ** have "x \<in> A j" by auto
  1296         with INJ * ** *** have ?thesis
  1297         by(auto simp add: inj_on_def)
  1298       }
  1299       moreover
  1300       {
  1301         assume "A j \<le> A i"
  1302         with ** have "y \<in> A i" by auto
  1303         with INJ * ** *** have ?thesis
  1304         by(auto simp add: inj_on_def)
  1305       }
  1306       ultimately show ?thesis using CH * by blast
  1307     qed
  1308   }
  1309   then show ?thesis by (unfold inj_on_def UNION_eq) auto
  1310 qed
  1311 
  1312 lemma bij_betw_UNION_chain:
  1313   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
  1314          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
  1315   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
  1316 proof (unfold bij_betw_def, auto)
  1317   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
  1318   using BIJ bij_betw_def[of f] by auto
  1319   thus "inj_on f (\<Union> i \<in> I. A i)"
  1320   using CH inj_on_UNION_chain[of I A f] by auto
  1321 next
  1322   fix i x
  1323   assume *: "i \<in> I" "x \<in> A i"
  1324   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
  1325   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
  1326 next
  1327   fix i x'
  1328   assume *: "i \<in> I" "x' \<in> A' i"
  1329   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
  1330   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
  1331     using * by blast
  1332   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by blast
  1333 qed
  1334 
  1335 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
  1336 lemma image_INT:
  1337    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
  1338     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1339 apply (simp add: inj_on_def, blast)
  1340 done
  1341 
  1342 (*Compare with image_INT: no use of inj_on, and if f is surjective then
  1343   it doesn't matter whether A is empty*)
  1344 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
  1345 apply (simp add: bij_def)
  1346 apply (simp add: inj_on_def surj_def, blast)
  1347 done
  1348 
  1349 lemma UNION_fun_upd:
  1350   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
  1351 by (auto split: if_splits)
  1352 
  1353 
  1354 subsubsection {* Complement *}
  1355 
  1356 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1357   by (fact uminus_INF)
  1358 
  1359 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1360   by (fact uminus_SUP)
  1361 
  1362 
  1363 subsubsection {* Miniscoping and maxiscoping *}
  1364 
  1365 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1366            and Intersections. *}
  1367 
  1368 lemma UN_simps [simp]:
  1369   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1370   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1371   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1372   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1373   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1374   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1375   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1376   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1377   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1378   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1379   by auto
  1380 
  1381 lemma INT_simps [simp]:
  1382   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1383   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1384   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1385   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1386   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1387   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1388   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1389   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1390   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1391   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1392   by auto
  1393 
  1394 lemma UN_ball_bex_simps [simp]:
  1395   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1396   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1397   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1398   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1399   by auto
  1400 
  1401 
  1402 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1403 
  1404 lemma UN_extend_simps:
  1405   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1406   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1407   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1408   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1409   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1410   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1411   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1412   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1413   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1414   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1415   by auto
  1416 
  1417 lemma INT_extend_simps:
  1418   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1419   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1420   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1421   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1422   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1423   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1424   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1425   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1426   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1427   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1428   by auto
  1429 
  1430 text {* Finally *}
  1431 
  1432 no_notation
  1433   less_eq (infix "\<sqsubseteq>" 50) and
  1434   less (infix "\<sqsubset>" 50)
  1435 
  1436 lemmas mem_simps =
  1437   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1438   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1439   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1440 
  1441 end
  1442