src/HOL/Product_Type.thy
author wenzelm
Fri Apr 08 13:31:16 2011 +0200 (2011-04-08)
changeset 42284 326f57825e1a
parent 42247 12fe41a92cd5
child 42411 ff997038e8eb
permissions -rw-r--r--
explicit structure Syntax_Trans;
discontinued old-style constrainAbsC;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    32   (Haskell infix 4 "==")
    33 
    34 code_instance bool :: equal
    35   (Haskell -)
    36 
    37 
    38 subsection {* The @{text unit} type *}
    39 
    40 typedef (open) unit = "{True}"
    41 proof
    42   show "True : ?unit" ..
    43 qed
    44 
    45 definition
    46   Unity :: unit    ("'(')")
    47 where
    48   "() = Abs_unit True"
    49 
    50 lemma unit_eq [no_atp]: "u = ()"
    51   by (induct u) (simp add: Unity_def)
    52 
    53 text {*
    54   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    55   this rule directly --- it loops!
    56 *}
    57 
    58 ML {*
    59   val unit_eq_proc =
    60     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    61       Simplifier.simproc_global @{theory} "unit_eq" ["x::unit"]
    62       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    63     end;
    64 
    65   Addsimprocs [unit_eq_proc];
    66 *}
    67 
    68 rep_datatype "()" by simp
    69 
    70 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    71   by simp
    72 
    73 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    74   by (rule triv_forall_equality)
    75 
    76 text {*
    77   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    78   [source] "%u::unit. f u"}, replacing it by @{term [source]
    79   f} rather than by @{term [source] "%u. f ()"}.
    80 *}
    81 
    82 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    83   by (rule ext) simp
    84 
    85 instantiation unit :: default
    86 begin
    87 
    88 definition "default = ()"
    89 
    90 instance ..
    91 
    92 end
    93 
    94 lemma [code]:
    95   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    96 
    97 code_type unit
    98   (SML "unit")
    99   (OCaml "unit")
   100   (Haskell "()")
   101   (Scala "Unit")
   102 
   103 code_const Unity
   104   (SML "()")
   105   (OCaml "()")
   106   (Haskell "()")
   107   (Scala "()")
   108 
   109 code_instance unit :: equal
   110   (Haskell -)
   111 
   112 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   113   (Haskell infix 4 "==")
   114 
   115 code_reserved SML
   116   unit
   117 
   118 code_reserved OCaml
   119   unit
   120 
   121 code_reserved Scala
   122   Unit
   123 
   124 
   125 subsection {* The product type *}
   126 
   127 subsubsection {* Type definition *}
   128 
   129 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   130   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   131 
   132 typedef ('a, 'b) prod (infixr "*" 20)
   133   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   134 proof
   135   fix a b show "Pair_Rep a b \<in> ?prod"
   136     by rule+
   137 qed
   138 
   139 type_notation (xsymbols)
   140   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   141 type_notation (HTML output)
   142   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   143 
   144 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   145   "Pair a b = Abs_prod (Pair_Rep a b)"
   146 
   147 rep_datatype Pair proof -
   148   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   149   assume "\<And>a b. P (Pair a b)"
   150   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   151 next
   152   fix a c :: 'a and b d :: 'b
   153   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   154     by (auto simp add: Pair_Rep_def fun_eq_iff)
   155   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   156     by (auto simp add: prod_def)
   157   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   158     by (simp add: Pair_def Abs_prod_inject)
   159 qed
   160 
   161 declare prod.simps(2) [nitpick_simp del]
   162 
   163 declare prod.weak_case_cong [cong del]
   164 
   165 
   166 subsubsection {* Tuple syntax *}
   167 
   168 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   169   "split \<equiv> prod_case"
   170 
   171 text {*
   172   Patterns -- extends pre-defined type @{typ pttrn} used in
   173   abstractions.
   174 *}
   175 
   176 nonterminal tuple_args and patterns
   177 
   178 syntax
   179   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   180   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   181   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   182   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   183   ""            :: "pttrn => patterns"                  ("_")
   184   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   185 
   186 translations
   187   "(x, y)" == "CONST Pair x y"
   188   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   189   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   190   "%(x, y). b" == "CONST prod_case (%x y. b)"
   191   "_abs (CONST Pair x y) t" => "%(x, y). t"
   192   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   193      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   194 
   195 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   196   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   197 print_translation {*
   198 let
   199   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   200         (* split (%x y. t) => %(x,y) t *)
   201         let
   202           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   203           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   204         in
   205           Syntax.const @{syntax_const "_abs"} $
   206             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   207         end
   208     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   209         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   210         let
   211           val Const (@{syntax_const "_abs"}, _) $
   212             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   213           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   214         in
   215           Syntax.const @{syntax_const "_abs"} $
   216             (Syntax.const @{syntax_const "_pattern"} $ x' $
   217               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   218         end
   219     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   220         (* split (split (%x y z. t)) => %((x, y), z). t *)
   221         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   222     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   223         (* split (%pttrn z. t) => %(pttrn,z). t *)
   224         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   225           Syntax.const @{syntax_const "_abs"} $
   226             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   227         end
   228     | split_tr' _ = raise Match;
   229 in [(@{const_syntax prod_case}, split_tr')] end
   230 *}
   231 
   232 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   233 typed_print_translation {*
   234 let
   235   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   236     | split_guess_names_tr' T [Abs (x, xT, t)] =
   237         (case (head_of t) of
   238           Const (@{const_syntax prod_case}, _) => raise Match
   239         | _ =>
   240           let 
   241             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   242             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   243             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   244           in
   245             Syntax.const @{syntax_const "_abs"} $
   246               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   247           end)
   248     | split_guess_names_tr' T [t] =
   249         (case head_of t of
   250           Const (@{const_syntax prod_case}, _) => raise Match
   251         | _ =>
   252           let
   253             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   254             val (y, t') =
   255               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   256             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   257           in
   258             Syntax.const @{syntax_const "_abs"} $
   259               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   260           end)
   261     | split_guess_names_tr' _ _ = raise Match;
   262 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   263 *}
   264 
   265 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   266    where Q is some bounded quantifier or set operator.
   267    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   268    whereas we want "Q (x,y):A. P x y".
   269    Otherwise prevent eta-contraction.
   270 *)
   271 print_translation {*
   272 let
   273   fun contract Q f ts =
   274     case ts of
   275       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   276       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   277     | _ => f ts;
   278   fun contract2 (Q,f) = (Q, contract Q f);
   279   val pairs =
   280     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   281      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   282      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   283      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   284 in map contract2 pairs end
   285 *}
   286 
   287 subsubsection {* Code generator setup *}
   288 
   289 code_type prod
   290   (SML infix 2 "*")
   291   (OCaml infix 2 "*")
   292   (Haskell "!((_),/ (_))")
   293   (Scala "((_),/ (_))")
   294 
   295 code_const Pair
   296   (SML "!((_),/ (_))")
   297   (OCaml "!((_),/ (_))")
   298   (Haskell "!((_),/ (_))")
   299   (Scala "!((_),/ (_))")
   300 
   301 code_instance prod :: equal
   302   (Haskell -)
   303 
   304 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   305   (Haskell infix 4 "==")
   306 
   307 types_code
   308   "prod"     ("(_ */ _)")
   309 attach (term_of) {*
   310 fun term_of_prod aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   311 *}
   312 attach (test) {*
   313 fun gen_prod aG aT bG bT i =
   314   let
   315     val (x, t) = aG i;
   316     val (y, u) = bG i
   317   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   318 *}
   319 
   320 consts_code
   321   "Pair"    ("(_,/ _)")
   322 
   323 setup {*
   324 let
   325 
   326 fun strip_abs_split 0 t = ([], t)
   327   | strip_abs_split i (Abs (s, T, t)) =
   328       let
   329         val s' = Codegen.new_name t s;
   330         val v = Free (s', T)
   331       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   332   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   333       (case strip_abs_split (i+1) t of
   334         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   335       | _ => ([], u))
   336   | strip_abs_split i t =
   337       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   338 
   339 fun let_codegen thy defs dep thyname brack t gr =
   340   (case strip_comb t of
   341     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   342     let
   343       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   344           (case strip_abs_split 1 u of
   345              ([p], u') => apfst (cons (p, t)) (dest_let u')
   346            | _ => ([], l))
   347         | dest_let t = ([], t);
   348       fun mk_code (l, r) gr =
   349         let
   350           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
   351           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
   352         in ((pl, pr), gr2) end
   353     in case dest_let (t1 $ t2 $ t3) of
   354         ([], _) => NONE
   355       | (ps, u) =>
   356           let
   357             val (qs, gr1) = fold_map mk_code ps gr;
   358             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   359             val (pargs, gr3) = fold_map
   360               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   361           in
   362             SOME (Codegen.mk_app brack
   363               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   364                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   365                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   366                        Pretty.brk 1, pr]]) qs))),
   367                 Pretty.brk 1, Codegen.str "in ", pu,
   368                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   369           end
   370     end
   371   | _ => NONE);
   372 
   373 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
   374     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   375       let
   376         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   377         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
   378         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   379         val (pargs, gr3) = fold_map
   380           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   381       in
   382         SOME (Codegen.mk_app brack
   383           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   384             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   385       end
   386   | _ => NONE);
   387 
   388 in
   389 
   390   Codegen.add_codegen "let_codegen" let_codegen
   391   #> Codegen.add_codegen "split_codegen" split_codegen
   392 
   393 end
   394 *}
   395 
   396 
   397 subsubsection {* Fundamental operations and properties *}
   398 
   399 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   400   by (cases p) simp
   401 
   402 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   403   "fst p = (case p of (a, b) \<Rightarrow> a)"
   404 
   405 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   406   "snd p = (case p of (a, b) \<Rightarrow> b)"
   407 
   408 lemma fst_conv [simp, code]: "fst (a, b) = a"
   409   unfolding fst_def by simp
   410 
   411 lemma snd_conv [simp, code]: "snd (a, b) = b"
   412   unfolding snd_def by simp
   413 
   414 code_const fst and snd
   415   (Haskell "fst" and "snd")
   416 
   417 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   418   by (simp add: fun_eq_iff split: prod.split)
   419 
   420 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   421   by simp
   422 
   423 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   424   by simp
   425 
   426 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   427   by (cases p) simp
   428 
   429 lemmas surjective_pairing = pair_collapse [symmetric]
   430 
   431 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   432   by (cases s, cases t) simp
   433 
   434 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   435   by (simp add: Pair_fst_snd_eq)
   436 
   437 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   438   by (fact prod.cases)
   439 
   440 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   441   by (rule split_conv [THEN iffD2])
   442 
   443 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   444   by (rule split_conv [THEN iffD1])
   445 
   446 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   447   by (simp add: fun_eq_iff split: prod.split)
   448 
   449 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   450   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   451   by (simp add: fun_eq_iff split: prod.split)
   452 
   453 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   454   by (cases x) simp
   455 
   456 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   457   by (cases p) simp
   458 
   459 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   460   by (simp add: prod_case_unfold)
   461 
   462 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   463   -- {* Prevents simplification of @{term c}: much faster *}
   464   by (fact prod.weak_case_cong)
   465 
   466 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   467   by (simp add: split_eta)
   468 
   469 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   470 proof
   471   fix a b
   472   assume "!!x. PROP P x"
   473   then show "PROP P (a, b)" .
   474 next
   475   fix x
   476   assume "!!a b. PROP P (a, b)"
   477   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   478 qed
   479 
   480 text {*
   481   The rule @{thm [source] split_paired_all} does not work with the
   482   Simplifier because it also affects premises in congrence rules,
   483   where this can lead to premises of the form @{text "!!a b. ... =
   484   ?P(a, b)"} which cannot be solved by reflexivity.
   485 *}
   486 
   487 lemmas split_tupled_all = split_paired_all unit_all_eq2
   488 
   489 ML {*
   490   (* replace parameters of product type by individual component parameters *)
   491   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   492   local (* filtering with exists_paired_all is an essential optimization *)
   493     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   494           can HOLogic.dest_prodT T orelse exists_paired_all t
   495       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   496       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   497       | exists_paired_all _ = false;
   498     val ss = HOL_basic_ss
   499       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   500       addsimprocs [unit_eq_proc];
   501   in
   502     val split_all_tac = SUBGOAL (fn (t, i) =>
   503       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   504     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   505       if exists_paired_all t then full_simp_tac ss i else no_tac);
   506     fun split_all th =
   507    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   508   end;
   509 *}
   510 
   511 declaration {* fn _ =>
   512   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   513 *}
   514 
   515 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   516   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   517   by fast
   518 
   519 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   520   by fast
   521 
   522 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   523   -- {* Can't be added to simpset: loops! *}
   524   by (simp add: split_eta)
   525 
   526 text {*
   527   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   528   @{thm [source] split_eta} as a rewrite rule is not general enough,
   529   and using @{thm [source] cond_split_eta} directly would render some
   530   existing proofs very inefficient; similarly for @{text
   531   split_beta}.
   532 *}
   533 
   534 ML {*
   535 local
   536   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   537   fun Pair_pat k 0 (Bound m) = (m = k)
   538     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   539         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   540     | Pair_pat _ _ _ = false;
   541   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   542     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   543     | no_args k i (Bound m) = m < k orelse m > k + i
   544     | no_args _ _ _ = true;
   545   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   546     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   547     | split_pat tp i _ = NONE;
   548   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   549         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   550         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   551 
   552   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   553     | beta_term_pat k i (t $ u) =
   554         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   555     | beta_term_pat k i t = no_args k i t;
   556   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   557     | eta_term_pat _ _ _ = false;
   558   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   559     | subst arg k i (t $ u) =
   560         if Pair_pat k i (t $ u) then incr_boundvars k arg
   561         else (subst arg k i t $ subst arg k i u)
   562     | subst arg k i t = t;
   563   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   564         (case split_pat beta_term_pat 1 t of
   565           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   566         | NONE => NONE)
   567     | beta_proc _ _ = NONE;
   568   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   569         (case split_pat eta_term_pat 1 t of
   570           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   571         | NONE => NONE)
   572     | eta_proc _ _ = NONE;
   573 in
   574   val split_beta_proc = Simplifier.simproc_global @{theory} "split_beta" ["split f z"] (K beta_proc);
   575   val split_eta_proc = Simplifier.simproc_global @{theory} "split_eta" ["split f"] (K eta_proc);
   576 end;
   577 
   578 Addsimprocs [split_beta_proc, split_eta_proc];
   579 *}
   580 
   581 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   582   by (subst surjective_pairing, rule split_conv)
   583 
   584 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   585   -- {* For use with @{text split} and the Simplifier. *}
   586   by (insert surj_pair [of p], clarify, simp)
   587 
   588 text {*
   589   @{thm [source] split_split} could be declared as @{text "[split]"}
   590   done after the Splitter has been speeded up significantly;
   591   precompute the constants involved and don't do anything unless the
   592   current goal contains one of those constants.
   593 *}
   594 
   595 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   596 by (subst split_split, simp)
   597 
   598 text {*
   599   \medskip @{term split} used as a logical connective or set former.
   600 
   601   \medskip These rules are for use with @{text blast}; could instead
   602   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   603 
   604 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   605   apply (simp only: split_tupled_all)
   606   apply (simp (no_asm_simp))
   607   done
   608 
   609 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   610   apply (simp only: split_tupled_all)
   611   apply (simp (no_asm_simp))
   612   done
   613 
   614 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   615   by (induct p) auto
   616 
   617 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   618   by (induct p) auto
   619 
   620 lemma splitE2:
   621   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   622 proof -
   623   assume q: "Q (split P z)"
   624   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   625   show R
   626     apply (rule r surjective_pairing)+
   627     apply (rule split_beta [THEN subst], rule q)
   628     done
   629 qed
   630 
   631 lemma splitD': "split R (a,b) c ==> R a b c"
   632   by simp
   633 
   634 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   635   by simp
   636 
   637 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   638 by (simp only: split_tupled_all, simp)
   639 
   640 lemma mem_splitE:
   641   assumes major: "z \<in> split c p"
   642     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   643   shows Q
   644   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   645 
   646 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   647 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   648 
   649 ML {*
   650 local (* filtering with exists_p_split is an essential optimization *)
   651   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   652     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   653     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   654     | exists_p_split _ = false;
   655   val ss = HOL_basic_ss addsimps @{thms split_conv};
   656 in
   657 val split_conv_tac = SUBGOAL (fn (t, i) =>
   658     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   659 end;
   660 *}
   661 
   662 (* This prevents applications of splitE for already splitted arguments leading
   663    to quite time-consuming computations (in particular for nested tuples) *)
   664 declaration {* fn _ =>
   665   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   666 *}
   667 
   668 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   669   by (rule ext) fast
   670 
   671 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   672   by (rule ext) fast
   673 
   674 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   675   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   676   by (rule ext) blast
   677 
   678 (* Do NOT make this a simp rule as it
   679    a) only helps in special situations
   680    b) can lead to nontermination in the presence of split_def
   681 *)
   682 lemma split_comp_eq: 
   683   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   684   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   685   by (rule ext) auto
   686 
   687 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   688   apply (rule_tac x = "(a, b)" in image_eqI)
   689    apply auto
   690   done
   691 
   692 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   693   by blast
   694 
   695 (*
   696 the following  would be slightly more general,
   697 but cannot be used as rewrite rule:
   698 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   699 ### ?y = .x
   700 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   701 by (rtac some_equality 1)
   702 by ( Simp_tac 1)
   703 by (split_all_tac 1)
   704 by (Asm_full_simp_tac 1)
   705 qed "The_split_eq";
   706 *)
   707 
   708 text {*
   709   Setup of internal @{text split_rule}.
   710 *}
   711 
   712 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   713 
   714 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   715   by (fact splitI2)
   716 
   717 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   718   by (fact splitI2')
   719 
   720 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   721   by (fact splitE)
   722 
   723 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   724   by (fact splitE')
   725 
   726 declare prod_caseI [intro!]
   727 
   728 lemma prod_case_beta:
   729   "prod_case f p = f (fst p) (snd p)"
   730   by (fact split_beta)
   731 
   732 lemma prod_cases3 [cases type]:
   733   obtains (fields) a b c where "y = (a, b, c)"
   734   by (cases y, case_tac b) blast
   735 
   736 lemma prod_induct3 [case_names fields, induct type]:
   737     "(!!a b c. P (a, b, c)) ==> P x"
   738   by (cases x) blast
   739 
   740 lemma prod_cases4 [cases type]:
   741   obtains (fields) a b c d where "y = (a, b, c, d)"
   742   by (cases y, case_tac c) blast
   743 
   744 lemma prod_induct4 [case_names fields, induct type]:
   745     "(!!a b c d. P (a, b, c, d)) ==> P x"
   746   by (cases x) blast
   747 
   748 lemma prod_cases5 [cases type]:
   749   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   750   by (cases y, case_tac d) blast
   751 
   752 lemma prod_induct5 [case_names fields, induct type]:
   753     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   754   by (cases x) blast
   755 
   756 lemma prod_cases6 [cases type]:
   757   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   758   by (cases y, case_tac e) blast
   759 
   760 lemma prod_induct6 [case_names fields, induct type]:
   761     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   762   by (cases x) blast
   763 
   764 lemma prod_cases7 [cases type]:
   765   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   766   by (cases y, case_tac f) blast
   767 
   768 lemma prod_induct7 [case_names fields, induct type]:
   769     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   770   by (cases x) blast
   771 
   772 lemma split_def:
   773   "split = (\<lambda>c p. c (fst p) (snd p))"
   774   by (fact prod_case_unfold)
   775 
   776 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   777   "internal_split == split"
   778 
   779 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   780   by (simp only: internal_split_def split_conv)
   781 
   782 use "Tools/split_rule.ML"
   783 setup Split_Rule.setup
   784 
   785 hide_const internal_split
   786 
   787 
   788 subsubsection {* Derived operations *}
   789 
   790 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   791   "curry = (\<lambda>c x y. c (x, y))"
   792 
   793 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   794   by (simp add: curry_def)
   795 
   796 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   797   by (simp add: curry_def)
   798 
   799 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   800   by (simp add: curry_def)
   801 
   802 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   803   by (simp add: curry_def)
   804 
   805 lemma curry_split [simp]: "curry (split f) = f"
   806   by (simp add: curry_def split_def)
   807 
   808 lemma split_curry [simp]: "split (curry f) = f"
   809   by (simp add: curry_def split_def)
   810 
   811 text {*
   812   The composition-uncurry combinator.
   813 *}
   814 
   815 notation fcomp (infixl "\<circ>>" 60)
   816 
   817 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   818   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   819 
   820 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   821   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   822 
   823 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   824   by (simp add: scomp_unfold prod_case_unfold)
   825 
   826 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   827   by (simp add: fun_eq_iff scomp_apply)
   828 
   829 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   830   by (simp add: fun_eq_iff scomp_apply)
   831 
   832 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   833   by (simp add: fun_eq_iff scomp_unfold)
   834 
   835 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   836   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   837 
   838 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   839   by (simp add: fun_eq_iff scomp_unfold fcomp_apply)
   840 
   841 code_const scomp
   842   (Eval infixl 3 "#->")
   843 
   844 no_notation fcomp (infixl "\<circ>>" 60)
   845 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   846 
   847 text {*
   848   @{term map_pair} --- action of the product functor upon
   849   functions.
   850 *}
   851 
   852 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   853   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   854 
   855 lemma map_pair_simp [simp, code]:
   856   "map_pair f g (a, b) = (f a, g b)"
   857   by (simp add: map_pair_def)
   858 
   859 enriched_type map_pair: map_pair
   860   by (auto simp add: split_paired_all intro: ext)
   861 
   862 lemma fst_map_pair [simp]:
   863   "fst (map_pair f g x) = f (fst x)"
   864   by (cases x) simp_all
   865 
   866 lemma snd_prod_fun [simp]:
   867   "snd (map_pair f g x) = g (snd x)"
   868   by (cases x) simp_all
   869 
   870 lemma fst_comp_map_pair [simp]:
   871   "fst \<circ> map_pair f g = f \<circ> fst"
   872   by (rule ext) simp_all
   873 
   874 lemma snd_comp_map_pair [simp]:
   875   "snd \<circ> map_pair f g = g \<circ> snd"
   876   by (rule ext) simp_all
   877 
   878 lemma map_pair_compose:
   879   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   880   by (rule ext) (simp add: map_pair.compositionality comp_def)
   881 
   882 lemma map_pair_ident [simp]:
   883   "map_pair (%x. x) (%y. y) = (%z. z)"
   884   by (rule ext) (simp add: map_pair.identity)
   885 
   886 lemma map_pair_imageI [intro]:
   887   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   888   by (rule image_eqI) simp_all
   889 
   890 lemma prod_fun_imageE [elim!]:
   891   assumes major: "c \<in> map_pair f g ` R"
   892     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   893   shows P
   894   apply (rule major [THEN imageE])
   895   apply (case_tac x)
   896   apply (rule cases)
   897   apply simp_all
   898   done
   899 
   900 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   901   "apfst f = map_pair f id"
   902 
   903 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   904   "apsnd f = map_pair id f"
   905 
   906 lemma apfst_conv [simp, code]:
   907   "apfst f (x, y) = (f x, y)" 
   908   by (simp add: apfst_def)
   909 
   910 lemma apsnd_conv [simp, code]:
   911   "apsnd f (x, y) = (x, f y)" 
   912   by (simp add: apsnd_def)
   913 
   914 lemma fst_apfst [simp]:
   915   "fst (apfst f x) = f (fst x)"
   916   by (cases x) simp
   917 
   918 lemma fst_apsnd [simp]:
   919   "fst (apsnd f x) = fst x"
   920   by (cases x) simp
   921 
   922 lemma snd_apfst [simp]:
   923   "snd (apfst f x) = snd x"
   924   by (cases x) simp
   925 
   926 lemma snd_apsnd [simp]:
   927   "snd (apsnd f x) = f (snd x)"
   928   by (cases x) simp
   929 
   930 lemma apfst_compose:
   931   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   932   by (cases x) simp
   933 
   934 lemma apsnd_compose:
   935   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   936   by (cases x) simp
   937 
   938 lemma apfst_apsnd [simp]:
   939   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   940   by (cases x) simp
   941 
   942 lemma apsnd_apfst [simp]:
   943   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   944   by (cases x) simp
   945 
   946 lemma apfst_id [simp] :
   947   "apfst id = id"
   948   by (simp add: fun_eq_iff)
   949 
   950 lemma apsnd_id [simp] :
   951   "apsnd id = id"
   952   by (simp add: fun_eq_iff)
   953 
   954 lemma apfst_eq_conv [simp]:
   955   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   956   by (cases x) simp
   957 
   958 lemma apsnd_eq_conv [simp]:
   959   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   960   by (cases x) simp
   961 
   962 lemma apsnd_apfst_commute:
   963   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   964   by simp
   965 
   966 text {*
   967   Disjoint union of a family of sets -- Sigma.
   968 *}
   969 
   970 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   971   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   972 
   973 abbreviation
   974   Times :: "['a set, 'b set] => ('a * 'b) set"
   975     (infixr "<*>" 80) where
   976   "A <*> B == Sigma A (%_. B)"
   977 
   978 notation (xsymbols)
   979   Times  (infixr "\<times>" 80)
   980 
   981 notation (HTML output)
   982   Times  (infixr "\<times>" 80)
   983 
   984 syntax
   985   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   986 translations
   987   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   988 
   989 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   990   by (unfold Sigma_def) blast
   991 
   992 lemma SigmaE [elim!]:
   993     "[| c: Sigma A B;
   994         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   995      |] ==> P"
   996   -- {* The general elimination rule. *}
   997   by (unfold Sigma_def) blast
   998 
   999 text {*
  1000   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1001   eigenvariables.
  1002 *}
  1003 
  1004 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1005   by blast
  1006 
  1007 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1008   by blast
  1009 
  1010 lemma SigmaE2:
  1011     "[| (a, b) : Sigma A B;
  1012         [| a:A;  b:B(a) |] ==> P
  1013      |] ==> P"
  1014   by blast
  1015 
  1016 lemma Sigma_cong:
  1017      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1018       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1019   by auto
  1020 
  1021 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1022   by blast
  1023 
  1024 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1025   by blast
  1026 
  1027 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1028   by blast
  1029 
  1030 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1031   by auto
  1032 
  1033 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1034   by auto
  1035 
  1036 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1037   by auto
  1038 
  1039 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1040   by blast
  1041 
  1042 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1043   by blast
  1044 
  1045 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1046   by (blast elim: equalityE)
  1047 
  1048 lemma SetCompr_Sigma_eq:
  1049     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1050   by blast
  1051 
  1052 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1053   by blast
  1054 
  1055 lemma UN_Times_distrib:
  1056   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1057   -- {* Suggested by Pierre Chartier *}
  1058   by blast
  1059 
  1060 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1061     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1062   by blast
  1063 
  1064 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1065     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1066   by blast
  1067 
  1068 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1069   by blast
  1070 
  1071 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1072   by blast
  1073 
  1074 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1075   by blast
  1076 
  1077 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1078   by blast
  1079 
  1080 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1081   by blast
  1082 
  1083 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1084   by blast
  1085 
  1086 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1087   by blast
  1088 
  1089 text {*
  1090   Non-dependent versions are needed to avoid the need for higher-order
  1091   matching, especially when the rules are re-oriented.
  1092 *}
  1093 
  1094 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1095 by blast
  1096 
  1097 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1098 by blast
  1099 
  1100 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1101 by blast
  1102 
  1103 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1104   by auto
  1105 
  1106 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1107   by (auto intro!: image_eqI)
  1108 
  1109 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1110   by (auto intro!: image_eqI)
  1111 
  1112 lemma insert_times_insert[simp]:
  1113   "insert a A \<times> insert b B =
  1114    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1115 by blast
  1116 
  1117 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1118   by (auto, case_tac "f x", auto)
  1119 
  1120 lemma swap_inj_on:
  1121   "inj_on (\<lambda>(i, j). (j, i)) A"
  1122   by (auto intro!: inj_onI)
  1123 
  1124 lemma swap_product:
  1125   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1126   by (simp add: split_def image_def) blast
  1127 
  1128 lemma image_split_eq_Sigma:
  1129   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1130 proof (safe intro!: imageI vimageI)
  1131   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1132   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1133     using * eq[symmetric] by auto
  1134 qed simp_all
  1135 
  1136 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1137 
  1138 lemma map_pair_inj_on:
  1139   assumes "inj_on f A" and "inj_on g B"
  1140   shows "inj_on (map_pair f g) (A \<times> B)"
  1141 proof (rule inj_onI)
  1142   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1143   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1144   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1145   assume "map_pair f g x = map_pair f g y"
  1146   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1147   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1148   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1149   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1150   moreover from `map_pair f g x = map_pair f g y`
  1151   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1152   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1153   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1154   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1155   ultimately show "x = y" by(rule prod_eqI)
  1156 qed
  1157 
  1158 lemma map_pair_surj:
  1159   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1160   assumes "surj f" and "surj g"
  1161   shows "surj (map_pair f g)"
  1162 unfolding surj_def
  1163 proof
  1164   fix y :: "'b \<times> 'd"
  1165   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1166   moreover
  1167   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1168   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1169   thus "\<exists>x. y = map_pair f g x" by auto
  1170 qed
  1171 
  1172 lemma map_pair_surj_on:
  1173   assumes "f ` A = A'" and "g ` B = B'"
  1174   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1175 unfolding image_def
  1176 proof(rule set_eqI,rule iffI)
  1177   fix x :: "'a \<times> 'c"
  1178   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1179   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1180   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1181   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1182   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1183   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1184 next
  1185   fix x :: "'a \<times> 'c"
  1186   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1187   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1188   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1189   moreover from `image g B = B'` and `snd x \<in> B'`
  1190   obtain b where "b \<in> B" and "snd x = g b" by auto
  1191   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1192   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1193   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1194   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1195 qed
  1196 
  1197 
  1198 subsection {* Inductively defined sets *}
  1199 
  1200 use "Tools/inductive_codegen.ML"
  1201 setup Inductive_Codegen.setup
  1202 
  1203 use "Tools/inductive_set.ML"
  1204 setup Inductive_Set.setup
  1205 
  1206 
  1207 subsection {* Legacy theorem bindings and duplicates *}
  1208 
  1209 lemma PairE:
  1210   obtains x y where "p = (x, y)"
  1211   by (fact prod.exhaust)
  1212 
  1213 lemma Pair_inject:
  1214   assumes "(a, b) = (a', b')"
  1215     and "a = a' ==> b = b' ==> R"
  1216   shows R
  1217   using assms by simp
  1218 
  1219 lemmas Pair_eq = prod.inject
  1220 
  1221 lemmas split = split_conv  -- {* for backwards compatibility *}
  1222 
  1223 end